qcsrc/client/target_music.qc

   1 entity music_default;
   2 entity music_target;
   3 entity music_trigger;
   4
   5 .float state;
   6
   7 void Net_AdvanceMusic()
   8 {
   9         // run AFTER all the thinks!
  10         entity best, e;
  11         float s0;
  12         best = music_default;
  13         if(music_target && time < music_target.lifetime)
  14                 best = music_target;
  15         if(music_trigger)
  16                 best = music_trigger;
  17         for(e = world; (e = findfloat(e, enttype, ENT_CLIENT_TRIGGER_MUSIC)); )
  18         {
  19                 s0 = e.state;
  20                 if(e == best)
  21                 {
  22                         // increase volume
  23                         if(e.fade_time > 0)
  24                                 e.state = min(1, e.state + frametime / e.fade_time);
  25                         else
  26                                 e.state = 1;
  27                 }
  28                 else
  29                 {
  30                         // decrease volume
  31                         if(e.fade_rate > 0)
  32                                 e.state = max(1, e.state - frametime / e.fade_rate);
  33                         else
  34                                 e.state = 0;
  35                 }
  36                 if(e.state != s0)
  37                         sound(e, CHAN_VOICE, "", e.volume * e.state, ATTN_NONE);
  38         }
  39         music_trigger = world;
  40 }
  41
  42 void Net_TargetMusic()
  43 {
  44         float vol, fai, fao, tim, id;
  45         string noi;
  46         entity e;
  47
  48         id = ReadShort();
  49         vol = ReadByte() / 255.0;
  50         fai = ReadByte() / 16.0;
  51         fao = ReadByte() / 16.0;
  52         tim = ReadByte();
  53         noi = ReadString();
  54
  55         for(e = world; (e = findfloat(e, enttype, ENT_CLIENT_TRIGGER_MUSIC)); )
  56         {
  57                 if(e.count == id)
  58                         break;
  59         }
  60         if(!e)
  61         {
  62                 e = spawn();
  63                 e.enttype = ENT_CLIENT_TRIGGER_MUSIC;
  64                 if(e.noise)
  65                         strunzone(e.noise);
  66                 e.noise = strzone(noi);
  67                 sound(e, CHAN_VOICE, self.noise, 0, ATTN_NONE);
  68         }
  69         e.volume = vol;
  70         e.fade_time = fai;
  71         e.fade_rate = fao;
  72         if(vol > 0)
  73         {
  74                 if(tim == 0)
  75                 {
  76                         music_default = e;
  77                 }
  78                 else
  79                 {
  80                         music_target = e;
  81                         e.lifetime = time + tim;
  82                 }
  83         }
  84 }
  85
  86 void Ent_TriggerMusic_Think()
  87 {
  88         if(WarpZoneLib_BoxTouchesBrush(view_origin, view_origin, self, world))
  89                 music_trigger = self;
  90         self.nextthink = time;
  91 }
  92
  93 void Ent_TriggerMusic_Remove()
  94 {
  95         if(self.noise)
  96                 strunzone(self.noise);
  97         self.noise = string_null;
  98 }
  99
 100 void Ent_ReadTriggerMusic()
 101 {
 102         float f;
 103         f = ReadByte();
 104         if(f & 4)
 105         {
 106                 self.origin_x = ReadCoord();
 107                 self.origin_y = ReadCoord();
 108                 self.origin_z = ReadCoord();
 109         }
 110         if(f & 1)
 111         {
 112                 self.modelindex = ReadShort();
 113                 if(self.modelindex)
 114                 {
 115                         self.mins_x = ReadCoord();
 116                         self.mins_y = ReadCoord();
 117                         self.mins_z = ReadCoord();
 118                         self.maxs_x = ReadCoord();
 119                         self.maxs_y = ReadCoord();
 120                         self.maxs_z = ReadCoord();
 121                 }
 122                 else
 123                 {
 124                         self.mins    = '0 0 0';
 125                         self.maxs_x = ReadCoord();
 126                         self.maxs_y = ReadCoord();
 127                         self.maxs_z = ReadCoord();
 128                 }
 129
 130                 self.volume = ReadByte() / 255.0;
 131                 self.fade_time = ReadByte() / 16.0;
 132                 self.fade_rate = ReadByte() / 16.0;
 133                 if(self.noise)
 134                         strunzone(self.noise);
 135                 self.noise = strzone(ReadString());
 136         }
 137
 138         self.cnt = 1;
 139         self.think = Ent_TriggerMusic_Think;
 140         self.nextthink = time;
 141 }