qcsrc/client/teamradar.qc

   1 #include "teamradar.qh"
   2
   3 #include "hud/_mod.qh"
   4
   5 #include <common/mutators/mutator/waypoints/all.qh>
   6
   7 #include "../lib/csqcmodel/interpolate.qh"
   8
   9 vector teamradar_3dcoord_to_texcoord(vector in)
  10 {
  11         vector out;
  12         out.x = (in.x - mi_picmin.x) / (mi_picmax.x - mi_picmin.x);
  13         out.y = (in.y - mi_picmin.y) / (mi_picmax.y - mi_picmin.y);
  14         out.z = 0;
  15         return out;
  16 }
  17
  18 vector teamradar_texcoord_to_2dcoord(vector in)
  19 {
  20         vector out;
  21         in -= teamradar_origin3d_in_texcoord;
  22
  23         out = Rotate(in, teamradar_angle * DEG2RAD);
  24         out.y = - out.y; // screen space is reversed
  25
  26         out = out * teamradar_size;
  27         if(v_flipped)
  28                 out.x = -out.x;
  29         out += teamradar_origin2d;
  30         return out;
  31 }
  32
  33
  34 vector teamradar_2dcoord_to_texcoord(vector in)
  35 {
  36         vector out;
  37         out = in;
  38
  39         out -= teamradar_origin2d;
  40         if(v_flipped)
  41                 out_x = -out_x;
  42         out = out / teamradar_size;
  43
  44         out_y = - out_y; // screen space is reversed
  45         out = Rotate(out, -teamradar_angle * DEG2RAD);
  46
  47         out += teamradar_origin3d_in_texcoord;
  48
  49         return out;
  50 }
  51
  52 vector teamradar_texcoord_to_3dcoord(vector in,float oz)
  53 {
  54         vector out;
  55         out_x = in_x * (mi_picmax_x - mi_picmin_x) + mi_picmin_x;
  56         out_y = in_y * (mi_picmax_y - mi_picmin_y) + mi_picmin_y;
  57         out_z = oz;
  58         return out;
  59 }
  60
  61 void draw_teamradar_background(float fg)
  62 {
  63         float fga;
  64         vector fgc;
  65
  66         if(fg > 0 && minimapname != "")
  67         {
  68                 fga = 1;
  69                 fgc = '1 1 1' * fg;
  70                 R_BeginPolygon(minimapname, DRAWFLAG_SCREEN | DRAWFLAG_MIPMAP);
  71                 if(v_flipped)
  72                 {
  73                         R_PolygonVertex(teamradar_texcoord_to_2dcoord(mi_pictexcoord3), yinvert(mi_pictexcoord3), fgc, fga);
  74                         R_PolygonVertex(teamradar_texcoord_to_2dcoord(mi_pictexcoord2), yinvert(mi_pictexcoord2), fgc, fga);
  75                         R_PolygonVertex(teamradar_texcoord_to_2dcoord(mi_pictexcoord1), yinvert(mi_pictexcoord1), fgc, fga);
  76                         R_PolygonVertex(teamradar_texcoord_to_2dcoord(mi_pictexcoord0), yinvert(mi_pictexcoord0), fgc, fga);
  77                 }
  78                 else
  79                 {
  80                         R_PolygonVertex(teamradar_texcoord_to_2dcoord(mi_pictexcoord0), yinvert(mi_pictexcoord0), fgc, fga);
  81                         R_PolygonVertex(teamradar_texcoord_to_2dcoord(mi_pictexcoord1), yinvert(mi_pictexcoord1), fgc, fga);
  82                         R_PolygonVertex(teamradar_texcoord_to_2dcoord(mi_pictexcoord2), yinvert(mi_pictexcoord2), fgc, fga);
  83                         R_PolygonVertex(teamradar_texcoord_to_2dcoord(mi_pictexcoord3), yinvert(mi_pictexcoord3), fgc, fga);
  84                 }
  85                 R_EndPolygon();
  86         }
  87 }
  88
  89 void draw_teamradar_player(vector coord3d, vector pangles, vector rgb)
  90 {
  91         vector coord, rgb2;
  92
  93         coord = teamradar_texcoord_to_2dcoord(teamradar_3dcoord_to_texcoord(coord3d));
  94
  95         makevectors(pangles - '0 1 0' * teamradar_angle);
  96         if(v_flipped)
  97         {
  98                 v_forward.x = -v_forward.x;
  99                 v_right.x = -v_right.x;
 100                 v_up.x = -v_up.x;
 101         }
 102         v_forward.z = 0;
 103         v_forward = normalize(v_forward);
 104         v_forward.y *= -1.0;
 105         v_right.x = -v_forward.y;
 106         v_right.y = v_forward.x;
 107
 108         if(rgb == '1 1 1')
 109                 rgb2 = '0 0 0';
 110         else
 111                 rgb2 = '1 1 1';
 112
 113         R_BeginPolygon("", 0);
 114         R_PolygonVertex(coord+v_forward*3, '0 0 0', rgb2, panel_fg_alpha);
 115         R_PolygonVertex(coord+v_right*4-v_forward*2.5, '0 1 0', rgb2, panel_fg_alpha);
 116         R_PolygonVertex(coord-v_forward*2, '1 0 0', rgb2, panel_fg_alpha);
 117         R_PolygonVertex(coord-v_right*4-v_forward*2.5, '1 1 0', rgb2, panel_fg_alpha);
 118         R_EndPolygon();
 119
 120         R_BeginPolygon("", 0);
 121         R_PolygonVertex(coord+v_forward*2, '0 0 0', rgb, panel_fg_alpha);
 122         R_PolygonVertex(coord+v_right*3-v_forward*2, '0 1 0', rgb, panel_fg_alpha);
 123         R_PolygonVertex(coord-v_forward, '1 0 0', rgb, panel_fg_alpha);
 124         R_PolygonVertex(coord-v_right*3-v_forward*2, '1 1 0', rgb, panel_fg_alpha);
 125         R_EndPolygon();
 126 }
 127
 128 void draw_teamradar_icon(vector coord, entity icon, entity pingdata, vector rgb, float a)
 129 {
 130         coord = teamradar_texcoord_to_2dcoord(teamradar_3dcoord_to_texcoord(coord));
 131         drawpic_builtin(coord - '4 4 0', strcat("gfx/teamradar_icon_", ftos(icon.m_radaricon)), '8 8 0', rgb, a, 0);
 132
 133         if(pingdata)
 134         {
 135                 for(int i = 0; i < MAX_TEAMRADAR_TIMES; ++i)
 136                 {
 137                         float dt = pingdata.(teamradar_times[i]);
 138                         if(dt == 0)
 139                                 continue;
 140                         dt = time - dt;
 141                         if(dt >= 1 || dt <= 0)
 142                                 continue;
 143                         vector v = '2 2 0' * teamradar_size * dt;
 144                         drawpic_builtin(coord - 0.5 * v, "gfx/teamradar_ping", v, '1 1 1', (1 - dt) * a, DRAWFLAG_ADDITIVE);
 145                 }
 146         }
 147 }
 148
 149 void draw_teamradar_link(vector start, vector end, int colors)
 150 {
 151     TC(int, colors);
 152         vector c0, c1, norm;
 153
 154         start = teamradar_texcoord_to_2dcoord(teamradar_3dcoord_to_texcoord(start));
 155         end = teamradar_texcoord_to_2dcoord(teamradar_3dcoord_to_texcoord(end));
 156         norm = normalize(start - end);
 157         norm.z = norm.x;
 158         norm.x = -norm.y;
 159         norm.y = norm.z;
 160         norm.z = 0;
 161
 162         c0 = colormapPaletteColor(colors & 0x0F, false);
 163         c1 = colormapPaletteColor((colors & 0xF0) / 0x10, false);
 164
 165         R_BeginPolygon("", 0);
 166         R_PolygonVertex(start - norm, '0 0 0', c0, panel_fg_alpha);
 167         R_PolygonVertex(start + norm, '0 1 0', c0, panel_fg_alpha);
 168         R_PolygonVertex(end + norm, '1 1 0', c1, panel_fg_alpha);
 169         R_PolygonVertex(end - norm, '1 0 0', c1, panel_fg_alpha);
 170         R_EndPolygon();
 171 }
 172
 173 void teamradar_loadcvars()
 174 {
 175         v_flipped = autocvar_v_flipped;
 176         hud_panel_radar_scale = autocvar_hud_panel_radar_scale;
 177         if (hud_panel_radar_maximized && !autocvar__hud_configure)
 178         {
 179                 if (autocvar_hud_panel_radar_maximized_scale > 0)
 180                         hud_panel_radar_scale = autocvar_hud_panel_radar_maximized_scale;
 181         }
 182         hud_panel_radar_foreground_alpha = autocvar_hud_panel_radar_foreground_alpha * panel_fg_alpha;
 183         hud_panel_radar_rotation = autocvar_hud_panel_radar_rotation;
 184         hud_panel_radar_zoommode = autocvar_hud_panel_radar_zoommode;
 185         hud_panel_radar_maximized_rotation = autocvar_hud_panel_radar_maximized_rotation;
 186         hud_panel_radar_maximized_zoommode = autocvar_hud_panel_radar_maximized_zoommode;
 187
 188         // others default to 0
 189         // match this to defaultXonotic.cfg!
 190         if(!hud_panel_radar_scale) hud_panel_radar_scale = 4096;
 191         if(!hud_panel_radar_foreground_alpha) hud_panel_radar_foreground_alpha = 0.8 * panel_fg_alpha;
 192         if(!hud_panel_radar_size.x) hud_panel_radar_size.x = 128;
 193         if(!hud_panel_radar_size.y) hud_panel_radar_size.y = hud_panel_radar_size.x;
 194 }
 195
 196 // radar links
 197
 198 NET_HANDLE(ENT_CLIENT_RADARLINK, bool isnew)
 199 {
 200         int sendflags = ReadByte();
 201
 202         InterpolateOrigin_Undo(this);
 203
 204         this.iflags = IFLAG_VELOCITY | IFLAG_ORIGIN;
 205         this.classname = "radarlink";
 206         if (isnew) IL_PUSH(g_radarlinks, this);
 207
 208         if(sendflags & 1)
 209         {
 210                 this.origin_x = ReadCoord();
 211                 this.origin_y = ReadCoord();
 212                 this.origin_z = ReadCoord();
 213                 setorigin(this, this.origin);
 214         }
 215
 216         if(sendflags & 2)
 217         {
 218                 this.velocity_x = ReadCoord();
 219                 this.velocity_y = ReadCoord();
 220                 this.velocity_z = ReadCoord();
 221         }
 222
 223         if(sendflags & 4)
 224         {
 225                 this.team = ReadByte();
 226         }
 227
 228         return = true;
 229
 230         InterpolateOrigin_Note(this);
 231 }