qcsrc/client/tturrets.qc

   1 string tid2info_base;
   2 string tid2info_head;
   3 string tid2info_name;
   4 vector  tid2info_min;
   5 vector  tid2info_max;
   6
   7 void turret_tid2info(float _tid);
   8 void turret_precache(float _tid);
   9 float turret_is_precache[TID_LAST];
  10
  11 void turrets_precache()
  12 {
  13     turret_precache(TID_COMMON);
  14 }
  15
  16 void turret_precache(float _tid)
  17 {
  18     if (!turret_is_precache[TID_COMMON])
  19     {
  20         precache_sound ("weapons/rocket_impact.wav");
  21         precache_model ("models/turrets/base-gib1.md3");
  22         precache_model ("models/turrets/base-gib2.md3");
  23         precache_model ("models/turrets/base-gib3.md3");
  24         precache_model ("models/turrets/base-gib4.md3");
  25         precache_model ("models/turrets/head-gib1.md3");
  26         precache_model ("models/turrets/head-gib2.md3");
  27         precache_model ("models/turrets/head-gib3.md3");
  28         precache_model ("models/turrets/head-gib4.md3");
  29         precache_model ("models/turrets/terrainbase.md3");
  30         precache_model ("models/turrets/base.md3");
  31         precache_model ("models/turrets/rocket.md3");
  32     }
  33     turret_tid2info(_tid);
  34     if(turret_is_precache[_tid])
  35         return;
  36
  37     switch(_tid)
  38     {
  39         case TID_EWHEEL:
  40             precache_model ("models/turrets/ewheel-base2.md3");
  41             precache_model ("models/turrets/ewheel-gun1.md3");
  42             break;
  43         case TID_FLAC:
  44             precache_model ("models/turrets/flac.md3");
  45             break;
  46         case TID_FUSION:
  47             precache_model ("models/turrets/reactor.md3");
  48             break;
  49         case TID_HELLION:
  50             precache_model ("models/turrets/hellion.md3");
  51             break;
  52         case TID_HK:
  53             precache_model ("models/turrets/hk.md3");
  54             break;
  55         case TID_MACHINEGUN:
  56             precache_model ("models/turrets/machinegun.md3");
  57             precache_sound ("weapons/uzi_fire.wav");
  58             break;
  59         case TID_MLRS:
  60             precache_model ("models/turrets/mlrs.md3");
  61             break;
  62         case TID_PHASER:
  63             precache_model ("models/turrets/phaser.md3");
  64             precache_model ("models/turrets/phaser_beam.md3");
  65             precache_sound ("turrets/phaser.wav");
  66             break;
  67         case TID_PLASMA:
  68             precache_model ("models/turrets/plasma.md3");
  69             break;
  70         case TID_PLASMA_DUAL:
  71             precache_model ("models/turrets/plasmad.md3");
  72             break;
  73         case TID_TESLA:
  74             precache_model ("models/turrets/tesla_head.md3");
  75             precache_model ("models/turrets/tesla_base.md3");
  76             break;
  77         case TID_WALKER:
  78             precache_model ("models/turrets/walker_head_minigun.md3");
  79             precache_model ("models/turrets/walker_body.md3");
  80             precache_sound ("weapons/uzi_fire.wav");
  81             break;
  82     }
  83     turret_is_precache[_tid] = TRUE;
  84 }
  85
  86 void turret_tid2info(float _tid)
  87 {
  88     tid2info_base = "models/turrets/base.md3";
  89     tid2info_min = '-32 -32 0';
  90     tid2info_max = '32 32 64';
  91
  92     switch(_tid)
  93     {
  94         case TID_EWHEEL:
  95             tid2info_base = "models/turrets/ewheel-base2.md3";
  96             tid2info_head = "models/turrets/ewheel-gun1.md3";
  97             tid2info_name = "eWheel";
  98             break;
  99         case TID_FLAC:
 100             tid2info_head = "models/turrets/flac.md3";
 101             tid2info_name = "Flac Cannon";
 102             break;
 103         case TID_FUSION:
 104             tid2info_head = "models/turrets/reactor.md3";
 105             tid2info_name = "Fusion Reactor";
 106             tid2info_min = '-34 -34 0';
 107             tid2info_max = '34 34 90';
 108             break;
 109         case TID_HELLION:
 110             tid2info_head = "models/turrets/hellion.md3";
 111             tid2info_name = "Hellion";
 112             break;
 113         case TID_HK:
 114             tid2info_head = "models/turrets/hk.md3";
 115             tid2info_name = "Hunter-Killer";
 116             break;
 117         case TID_MACHINEGUN:
 118             tid2info_head = "models/turrets/machinegun.md3";
 119             tid2info_name = "Machinegun";
 120             break;
 121         case TID_MLRS:
 122             tid2info_head = "models/turrets/mlrs.md3";
 123             tid2info_name = "MLRS";
 124             break;
 125         case TID_PHASER:
 126             tid2info_head = "models/turrets/phaser.md3";
 127             tid2info_name = "Phaser";
 128             break;
 129         case TID_PLASMA:
 130             tid2info_head = "models/turrets/plasma.md3";
 131             tid2info_name = "Plasma";
 132             break;
 133         case TID_PLASMA_DUAL:
 134             tid2info_head = "models/turrets/plasmad.md3";
 135             tid2info_name = "Dual Plasma";
 136             break;
 137         case TID_TESLA:
 138             tid2info_base = "models/turrets/tesla_base.md3";
 139             tid2info_head = "models/turrets/tesla_head.md3";
 140             tid2info_name = "Tesla coil";
 141             tid2info_min = '-60 -60 0';
 142             tid2info_max  ='60 60 128';
 143             break;
 144         case TID_WALKER:
 145             tid2info_base = "models/turrets/walker_body.md3";
 146             tid2info_head = "models/turrets/walker_head_minigun.md3";
 147             tid2info_name = "Walker";
 148             tid2info_min = '-70 -70 0';
 149             tid2info_max = '70 70 95';
 150             break;
 151     }
 152 }
 153
 154 void turret_remove()
 155 {
 156     remove(self.tur_head);
 157     //remove(self.enemy);
 158     self.tur_head = world;
 159 }
 160
 161 .vector glowmod;
 162 void turret_changeteam()
 163 {
 164         switch(self.team - 1)
 165         {
 166         case COLOR_TEAM1: // Red
 167             self.glowmod = '2 0 0';
 168             self.teamradar_color = '1 0 0';
 169             break;
 170
 171         case COLOR_TEAM2: // Blue
 172             self.glowmod = '0 0 2';
 173             self.teamradar_color = '0 0 1';
 174             break;
 175
 176         case COLOR_TEAM3: // Yellow
 177             self.glowmod = '1 1 0';
 178             self.teamradar_color = '1 1 0';
 179             break;
 180
 181         case COLOR_TEAM4: // Pink
 182             self.glowmod = '1 0 1';
 183             self.teamradar_color = '1 0 1';
 184             break;
 185         }
 186
 187         if(self.team)
 188         self.colormap = 1024 + (self.team - 1) * 17;
 189
 190         self.tur_head.colormap = self.colormap;
 191         self.tur_head.glowmod = self.glowmod;
 192
 193 }
 194
 195 void turret_head_draw()
 196 {
 197     self.drawmask = MASK_NORMAL;
 198 }
 199
 200 void turret_draw()
 201 {
 202     float dt;
 203
 204     dt = time - self.move_time;
 205     self.move_time = time;
 206     if(dt <= 0)
 207         return;
 208
 209     self.tur_head.angles += dt * self.tur_head.move_avelocity;
 210
 211     if (self.health < 127)
 212     {
 213         dt = random();
 214
 215         if(dt < 0.03)
 216             te_spark(self.origin + '0 0 40', randomvec() * 256 + '0 0 256', 16);
 217     }
 218
 219     if(self.health < 85)
 220     if(dt < 0.01)
 221         pointparticles(particleeffectnum("smoke_large"), (self.origin + (randomvec() * 80)), '0 0 0', 1);
 222
 223     if(self.health < 32)
 224     if(dt < 0.015)
 225         pointparticles(particleeffectnum("smoke_small"), (self.origin + (randomvec() * 80)), '0 0 0', 1);
 226
 227 }
 228
 229 void turret_draw2d()
 230 {
 231         if(self.netname == "")
 232             return;
 233
 234     if(autocvar_cl_hidewaypoints) // also check g_waypointsprites_turrets after next release (needs changed to clients default/config .cfg)
 235         return;
 236
 237         float dist = vlen(self.origin - view_origin);
 238         vector o;
 239         /*
 240         // TODO: Vehicle tactical hud
 241         o = project_3d_to_2d(self.origin + '0 0 32');
 242         if(o_z < 0
 243         || o_x < (vid_conwidth * waypointsprite_edgeoffset_left)
 244         || o_y < (vid_conheight * waypointsprite_edgeoffset_top)
 245         || o_x > (vid_conwidth - (vid_conwidth * waypointsprite_edgeoffset_right))
 246         || o_y > (vid_conheight - (vid_conheight * waypointsprite_edgeoffset_bottom)))
 247             return; // Dont draw wp's for turrets out of view
 248     o_z = 0;
 249     if(hud != HUD_NORMAL)
 250     {
 251         switch(hud)
 252         {
 253             case HUD_SPIDERBOT:
 254             case HUD_WAKIZASHI:
 255             case HUD_RAPTOR:
 256                 vector pz = drawgetimagesize("gfx/vehicles/axh-bracket.tga") * 0.25;
 257                 drawpic(o - pz * 0.5 , "gfx/vehicles/axh-bracket.tga", pz , '1 1 1', 0.75, DRAWFLAG_NORMAL);
 258                 break;
 259         }
 260     }
 261     */
 262
 263         if(dist > self.maxdistance)
 264         return;
 265
 266         string spriteimage = self.netname;
 267         float t = (GetPlayerColor(player_localnum) + 1);
 268         float a = self.alpha * autocvar_hud_panel_fg_alpha;
 269         vector rgb = spritelookupcolor(spriteimage, self.teamradar_color);
 270
 271
 272         if(self.maxdistance > waypointsprite_normdistance)
 273                 a *= pow(bound(0, (self.maxdistance - dist) / (self.maxdistance - waypointsprite_normdistance), 1), waypointsprite_distancealphaexponent);
 274         else if(self.maxdistance > 0)
 275                 a *= pow(bound(0, (waypointsprite_fadedistance - dist) / (waypointsprite_fadedistance - waypointsprite_normdistance), 1), waypointsprite_distancealphaexponent) * (1 - waypointsprite_minalpha) + waypointsprite_minalpha;
 276
 277         if(rgb == '0 0 0')
 278         {
 279                 self.teamradar_color = '1 0 1';
 280                 print(sprintf("WARNING: sprite of name %s has no color, using pink so you notice it\n", spriteimage));
 281         }
 282
 283         string txt = self.netname;
 284         if(autocvar_g_waypointsprite_spam && waypointsprite_count >= autocvar_g_waypointsprite_spam)
 285                 txt = _("Spam");
 286         else
 287                 txt = spritelookuptext(spriteimage);
 288
 289         if(time - floor(time) > 0.5 && t == self.team)
 290         {
 291                 if(self.helpme && time < self.helpme)
 292                 {
 293                     a *= SPRITE_HELPME_BLINK;
 294                     txt = sprintf(_("%s under attack!"), txt);
 295                 }
 296                 else
 297                         a *= spritelookupblinkvalue(spriteimage);
 298         }
 299
 300         if(autocvar_g_waypointsprite_uppercase)
 301                 txt = strtoupper(txt);
 302
 303         if(a > 1)
 304         {
 305                 rgb *= a;
 306                 a = 1;
 307         }
 308
 309         if(a <= 0)
 310             return;
 311
 312         rgb = fixrgbexcess(rgb);
 313
 314         o = project_3d_to_2d(self.origin + '0 0 64');
 315         if(o_z < 0
 316         || o_x < (vid_conwidth * waypointsprite_edgeoffset_left)
 317         || o_y < (vid_conheight * waypointsprite_edgeoffset_top)
 318         || o_x > (vid_conwidth - (vid_conwidth * waypointsprite_edgeoffset_right))
 319         || o_y > (vid_conheight - (vid_conheight * waypointsprite_edgeoffset_bottom)))
 320             return; // Dont draw wp's for turrets out of view
 321
 322         o_z = 0;
 323
 324         float edgedistance_min, crosshairdistance;
 325                 edgedistance_min = min((o_y - (vid_conheight * waypointsprite_edgeoffset_top)),
 326         (o_x - (vid_conwidth * waypointsprite_edgeoffset_left)),
 327         (vid_conwidth - (vid_conwidth * waypointsprite_edgeoffset_right)) - o_x,
 328         (vid_conheight - (vid_conheight * waypointsprite_edgeoffset_bottom)) - o_y);
 329
 330         float vidscale = max(vid_conwidth / vid_width, vid_conheight / vid_height);
 331
 332         crosshairdistance = sqrt( pow(o_x - vid_conwidth/2, 2) + pow(o_y - vid_conheight/2, 2) );
 333
 334         t = waypointsprite_scale * vidscale;
 335         a *= waypointsprite_alpha;
 336
 337         {
 338                 a = a * (1 - (1 - waypointsprite_distancefadealpha) * (bound(0, dist/waypointsprite_distancefadedistance, 1)));
 339                 t = t * (1 - (1 - waypointsprite_distancefadescale) * (bound(0, dist/waypointsprite_distancefadedistance, 1)));
 340         }
 341         if (edgedistance_min < waypointsprite_edgefadedistance) {
 342                 a = a * (1 - (1 - waypointsprite_edgefadealpha) * (1 - bound(0, edgedistance_min/waypointsprite_edgefadedistance, 1)));
 343                 t = t * (1 - (1 - waypointsprite_edgefadescale) * (1 - bound(0, edgedistance_min/waypointsprite_edgefadedistance, 1)));
 344         }
 345         if(crosshairdistance < waypointsprite_crosshairfadedistance) {
 346                 a = a * (1 - (1 - waypointsprite_crosshairfadealpha) * (1 - bound(0, crosshairdistance/waypointsprite_crosshairfadedistance, 1)));
 347                 t = t * (1 - (1 - waypointsprite_crosshairfadescale) * (1 - bound(0, crosshairdistance/waypointsprite_crosshairfadedistance, 1)));
 348         }
 349
 350         o = drawspritearrow(o, M_PI, rgb, a, SPRITE_ARROW_SCALE * t);
 351     o = drawspritetext(o, M_PI, (SPRITE_HEALTHBAR_WIDTH + 2 * SPRITE_HEALTHBAR_BORDER) * t, rgb, a, waypointsprite_fontsize * '1 1 0', txt);
 352     drawhealthbar(
 353             o,
 354             0,
 355             self.health / 255,
 356             '0 0 0',
 357             '0 0 0',
 358             0.5 * SPRITE_HEALTHBAR_WIDTH * t,
 359             0.5 * SPRITE_HEALTHBAR_HEIGHT * t,
 360             SPRITE_HEALTHBAR_MARGIN * t + 0.5 * waypointsprite_fontsize,
 361             SPRITE_HEALTHBAR_BORDER * t,
 362             0,
 363             rgb,
 364             a * SPRITE_HEALTHBAR_BORDERALPHA,
 365             rgb,
 366             a * SPRITE_HEALTHBAR_HEALTHALPHA,
 367             DRAWFLAG_NORMAL
 368             );
 369 }
 370
 371 void turret_walker_draw()
 372 {
 373     float dt;
 374
 375     dt = time - self.move_time;
 376     self.move_time = time;
 377     if(dt <= 0)
 378         return;
 379
 380     fixedmakevectors(self.angles);
 381     movelib_groundalign4point(300, 100, 0.25);
 382     setorigin(self, self.origin + self.velocity * dt);
 383     self.tur_head.angles += dt * self.tur_head.move_avelocity;
 384     self.angles_y = self.move_angles_y;
 385
 386     if (self.health < 127)
 387     if(random() < 0.15)
 388         te_spark(self.origin + '0 0 40', randomvec() * 256 + '0 0 256', 16);
 389 }
 390
 391 void turret_ewheel_draw()
 392 {
 393     float dt;
 394
 395     dt = time - self.move_time;
 396     self.move_time = time;
 397     if(dt <= 0)
 398         return;
 399
 400     fixedmakevectors(self.angles);
 401     setorigin(self, self.origin + self.velocity * dt);
 402     self.tur_head.angles += dt * self.tur_head.move_avelocity;
 403     self.angles_y = self.move_angles_y;
 404
 405     if (self.health < 127)
 406     if(random() < 0.05)
 407         te_spark(self.origin + '0 0 40', randomvec() * 256 + '0 0 256', 16);
 408 }
 409
 410 void(entity e, entity tagentity, string tagname) setattachment = #443;
 411 void turret_construct()
 412 {
 413     if(self.tur_head == world)
 414         self.tur_head = spawn();
 415
 416     turret_tid2info(self.turret_type);
 417     self.netname = tid2info_name;
 418
 419     setorigin(self, self.origin);
 420     setmodel(self, tid2info_base);
 421     setmodel(self.tur_head, tid2info_head);
 422     setsize(self, tid2info_min, tid2info_max);
 423     setsize(self.tur_head, '0 0 0', '0 0 0');
 424
 425     if(self.turret_type == TID_EWHEEL)
 426         setattachment(self.tur_head, self, "");
 427     else
 428         setattachment(self.tur_head, self, "tag_head");
 429
 430     self.tur_head.classname     = "turret_head";
 431     self.tur_head.owner         = self;
 432     self.tur_head.move_movetype = MOVETYPE_NOCLIP;
 433     self.move_movetype          = MOVETYPE_NOCLIP;
 434     self.tur_head.angles        = self.angles;
 435     self.health                 = 255;
 436     self.solid                  = SOLID_BBOX;
 437     self.tur_head.solid         = SOLID_NOT;
 438     self.movetype               = MOVETYPE_NOCLIP;
 439     self.tur_head.movetype      = MOVETYPE_NOCLIP;
 440     self.draw                   = turret_draw;
 441     self.entremove              = turret_remove;
 442     self.drawmask               = MASK_NORMAL;
 443     self.tur_head.drawmask      = MASK_NORMAL;
 444     self.anim_start_time        = 0;
 445     self.draw2d = turret_draw2d;
 446     self.maxdistance = 4000; // use g_waypointsprites_turrets_maxdist after next release (needs changed to cleint's default)
 447     self.teamradar_color = '1 0 0';
 448     self.alpha = 1;
 449
 450     if(self.turret_type == TID_EWHEEL || self.turret_type == TID_WALKER)
 451     {
 452         self.gravity            = 1;
 453         self.movetype           = MOVETYPE_BOUNCE;
 454         self.move_movetype      = MOVETYPE_BOUNCE;
 455         self.move_origin        = self.origin;
 456         self.move_time          = time;
 457         switch(self.turret_type)
 458         {
 459             case TID_EWHEEL:
 460                 self.draw               = turret_ewheel_draw;
 461                 break;
 462             case TID_WALKER:
 463                 self.draw               = turret_walker_draw;
 464                 break;
 465
 466         }
 467     }
 468 }
 469
 470 entity turret_gibtoss(string _model, vector _from, vector _to, vector _cmod, float _explode);
 471 void turret_gibboom();
 472 void turret_gib_draw()
 473 {
 474     Movetype_Physics_MatchTicrate(autocvar_cl_gibs_ticrate, autocvar_cl_gibs_sloppy);
 475
 476     self.drawmask = MASK_NORMAL;
 477
 478         if(self.cnt)
 479         {
 480             if(time >= self.nextthink)
 481             {
 482             turret_gibboom();
 483             remove(self);
 484             }
 485         }
 486         else
 487         {
 488         self.alpha = bound(0, self.nextthink - time, 1);
 489         if(self.alpha < ALPHA_MIN_VISIBLE)
 490             remove(self);
 491         }
 492 }
 493
 494 void turret_gibboom()
 495 {
 496     float i;
 497
 498     sound (self, CH_SHOTS, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
 499     pointparticles(particleeffectnum("rocket_explode"), self.origin, '0 0 0', 1);
 500
 501     for (i = 1; i < 5; i = i + 1)
 502         turret_gibtoss(strcat("models/turrets/head-gib", ftos(i), ".md3"), self.origin + '0 0 2', self.velocity + randomvec() * 700, '0 0 0', FALSE);
 503 }
 504
 505 entity turret_gibtoss(string _model, vector _from, vector _to, vector _cmod, float _explode)
 506 {
 507     entity gib;
 508
 509     traceline(_from, _to, MOVE_NOMONSTERS, world);
 510     if(trace_startsolid)
 511         return world;
 512
 513     gib = spawn();
 514     setorigin(gib, _from);
 515     setmodel(gib, _model);
 516     gib.colormod    = _cmod;
 517         gib.solid       = SOLID_CORPSE;
 518     gib.draw        = turret_gib_draw;
 519     gib.cnt         = _explode;
 520     setsize(gib, '-1 -1 -1', '1 1 1');
 521     if(_explode)
 522     {
 523         gib.nextthink = time + 0.2 * (autocvar_cl_gibs_lifetime * (1 + prandom() * 0.15));
 524         gib.effects = EF_FLAME;
 525     }
 526     else
 527         gib.nextthink = time + autocvar_cl_gibs_lifetime * (1 + prandom() * 0.15);
 528
 529     gib.gravity         = 1;
 530         gib.move_movetype   = MOVETYPE_BOUNCE;
 531         gib.move_origin     = gib.origin = _from;
 532         gib.move_velocity   = _to;
 533         gib.move_avelocity  = prandomvec() * 32;
 534         gib.move_time       = time;
 535         gib.damageforcescale = 1;
 536         gib.classname = "turret_gib";
 537
 538         return gib;
 539 }
 540
 541 void turret_die()
 542 {
 543     entity headgib;
 544
 545     sound (self, CH_SHOTS, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
 546     pointparticles(particleeffectnum("rocket_explode"), self.origin, '0 0 0', 1);
 547     turret_tid2info(self.turret_type);
 548
 549     // Base
 550     if(self.turret_type == TID_EWHEEL)
 551         turret_gibtoss(tid2info_base, self.origin + '0 0 18', self.velocity + '0 0 400' + '0.1 0.1 1' * (random() * 400), '-1 -1 -1', TRUE);
 552     else if (self.turret_type == TID_WALKER)
 553         turret_gibtoss(tid2info_base, self.origin + '0 0 18', self.velocity + '0 0 300' + '0.1 0.1 1' * (random() * 200), '-1 -1 -1', TRUE);
 554     else if (self.turret_type == TID_TESLA)
 555         turret_gibtoss(tid2info_base, self.origin + '0 0 18', '0 0 200', '-1 -1 -1', FALSE);
 556     else
 557     {
 558         if (random() > 0.5)
 559         {
 560             turret_gibtoss("models/turrets/base-gib2.md3", self.origin + '0 0 8', '0 0 50' + randomvec() * 150, '0 0 0', FALSE);
 561             turret_gibtoss("models/turrets/base-gib3.md3", self.origin + '0 0 8', '0 0 50' + randomvec() * 150, '0 0 0', FALSE);
 562             turret_gibtoss("models/turrets/base-gib4.md3", self.origin + '0 0 8', '0 0 50' + randomvec() * 150, '0 0 0', FALSE);
 563         }
 564         else
 565             turret_gibtoss("models/turrets/base-gib1.md3", self.origin + '0 0 8', '0 0 0', '0 0 0', TRUE);
 566
 567         headgib = turret_gibtoss(tid2info_head, self.origin + '0 0 32', '0 0 200' + randomvec() * 200, '-1 -1 -1', TRUE);
 568         if(headgib)
 569         {
 570             headgib.angles = headgib.move_angles = self.tur_head.angles;
 571             headgib.avelocity = headgib.move_avelocity = self.tur_head.move_avelocity + randomvec() * 45;
 572             headgib.avelocity_y = headgib.move_avelocity_y = headgib.move_avelocity_y * 5;
 573             headgib.gravity = 0.5;
 574         }
 575     }
 576
 577     setmodel(self, "null");
 578     setmodel(self.tur_head, "null");
 579 }
 580
 581 void ent_turret()
 582 {
 583     float sf;
 584     sf = ReadByte();
 585
 586         if(sf & TNSF_SETUP)
 587         {
 588             self.turret_type = ReadByte();
 589
 590             self.origin_x = ReadCoord();
 591             self.origin_y = ReadCoord();
 592             self.origin_z = ReadCoord();
 593
 594             self.angles_x = ReadAngle();
 595             self.angles_y = ReadAngle();
 596
 597             turret_precache(self.turret_type);
 598             turret_construct();
 599             self.colormap = 1024;
 600             self.glowmod = '0 1 1';
 601             self.tur_head.colormap = self.colormap;
 602             self.tur_head.glowmod = self.glowmod;
 603     }
 604
 605     if(sf & TNSF_ANG)
 606     {
 607         if(self.tur_head == world) // aparenly this can happpen before TNSF_SETUP. great.
 608             self.tur_head = spawn();
 609
 610         self.tur_head.move_angles_x = ReadShort();
 611         self.tur_head.move_angles_y = ReadShort();
 612         //self.tur_head.angles = self.angles + self.tur_head.move_angles;
 613         self.tur_head.angles = self.tur_head.move_angles;
 614     }
 615
 616     if(sf & TNSF_AVEL)
 617     {
 618         if(self.tur_head == world) // aparenly this can happpen before TNSF_SETUP. great.
 619             self.tur_head = spawn();
 620
 621         self.tur_head.move_avelocity_x = ReadShort();
 622         self.tur_head.move_avelocity_y = ReadShort();
 623     }
 624
 625     if(sf & TNSF_MOVE)
 626     {
 627         self.origin_x = ReadShort();
 628         self.origin_y = ReadShort();
 629         self.origin_z = ReadShort();
 630         setorigin(self, self.origin);
 631
 632         self.velocity_x = ReadShort();
 633         self.velocity_y = ReadShort();
 634         self.velocity_z = ReadShort();
 635
 636         self.move_angles_y = ReadShort();
 637
 638         self.move_time     = time;
 639         self.move_velocity = self.velocity;
 640         self.move_origin   = self.origin;
 641     }
 642
 643     if(sf & TNSF_ANIM)
 644     {
 645         self.frame1time = ReadCoord();
 646         self.frame      = ReadByte();
 647     }
 648
 649     if(sf & TNSF_STATUS)
 650     {
 651         float _tmp;
 652         _tmp = ReadByte();
 653         if(_tmp != self.team)
 654         {
 655             self.team = _tmp;
 656             turret_changeteam();
 657         }
 658
 659         _tmp = ReadByte();
 660         if(_tmp == 0 && self.health != 0)
 661             turret_die();
 662         else if(self.health && self.health != _tmp)
 663             self.helpme = servertime + 10;
 664
 665         self.health = _tmp;
 666     }
 667     //self.enemy.health = self.health / 255;
 668 }