qcsrc/client/tturrets.qc

   1 string tid2info_base;
   2 string tid2info_head;
   3 string tid2info_name;
   4 vector  tid2info_min;
   5 vector  tid2info_max;
   6
   7 void turret_tid2info(float _tid);
   8 void turret_precache(float _tid);
   9 float turret_is_precache[TID_LAST];
  10
  11 void turrets_precache()
  12 {
  13     turret_precache(TID_COMMON);
  14 }
  15
  16 void turret_precache(float _tid)
  17 {
  18     if (!turret_is_precache[TID_COMMON])
  19     {
  20         precache_sound ("weapons/rocket_impact.wav");
  21         precache_model ("models/turrets/base-gib1.md3");
  22         precache_model ("models/turrets/base-gib2.md3");
  23         precache_model ("models/turrets/base-gib3.md3");
  24         precache_model ("models/turrets/base-gib4.md3");
  25         precache_model ("models/turrets/head-gib1.md3");
  26         precache_model ("models/turrets/head-gib2.md3");
  27         precache_model ("models/turrets/head-gib3.md3");
  28         precache_model ("models/turrets/head-gib4.md3");
  29         precache_model ("models/turrets/terrainbase.md3");
  30         precache_model ("models/turrets/base.md3");
  31         precache_model ("models/turrets/rocket.md3");
  32     }
  33     turret_tid2info(_tid);
  34     if(turret_is_precache[_tid])
  35         return;
  36
  37     switch(_tid)
  38     {
  39         case TID_EWHEEL:
  40             precache_model ("models/turrets/ewheel-base2.md3");
  41             precache_model ("models/turrets/ewheel-gun1.md3");
  42             break;
  43         case TID_FLAC:
  44             precache_model ("models/turrets/flac.md3");
  45             break;
  46         case TID_FUSION:
  47             precache_model ("models/turrets/reactor.md3");
  48             break;
  49         case TID_HELLION:
  50             precache_model ("models/turrets/hellion.md3");
  51             break;
  52         case TID_HK:
  53             precache_model ("models/turrets/hk.md3");
  54             break;
  55         case TID_MACHINEGUN:
  56             precache_model ("models/turrets/machinegun.md3");
  57             precache_sound ("weapons/uzi_fire.wav");
  58             break;
  59         case TID_MLRS:
  60             precache_model ("models/turrets/mlrs.md3");
  61             break;
  62         case TID_PHASER:
  63             precache_model ("models/turrets/phaser.md3");
  64             precache_model ("models/turrets/phaser_beam.md3");
  65             precache_sound ("turrets/phaser.wav");
  66             break;
  67         case TID_PLASMA:
  68             precache_model ("models/turrets/plasma.md3");
  69             break;
  70         case TID_PLASMA_DUAL:
  71             precache_model ("models/turrets/plasmad.md3");
  72             break;
  73         case TID_TESLA:
  74             precache_model ("models/turrets/tesla_head.md3");
  75             precache_model ("models/turrets/tesla_base.md3");
  76             break;
  77         case TID_WALKER:
  78             precache_model ("models/turrets/walker_head_minigun.md3");
  79             precache_model ("models/turrets/walker_body.md3");
  80             precache_sound ("weapons/uzi_fire.wav");
  81             break;
  82     }
  83     turret_is_precache[_tid] = TRUE;
  84 }
  85
  86 void turret_tid2info(float _tid)
  87 {
  88     tid2info_base = "models/turrets/base.md3";
  89     tid2info_min = '-32 -32 0';
  90     tid2info_max = '32 32 64';
  91
  92     switch(_tid)
  93     {
  94         case TID_EWHEEL:
  95             tid2info_base = "models/turrets/ewheel-base2.md3";
  96             tid2info_head = "models/turrets/ewheel-gun1.md3";
  97             tid2info_name = "eWheel";
  98             break;
  99         case TID_FLAC:
 100             tid2info_head = "models/turrets/flac.md3";
 101             tid2info_name = "Flac Cannon";
 102             break;
 103         case TID_FUSION:
 104             tid2info_head = "models/turrets/reactor.md3";
 105             tid2info_name = "Fusion Reactor";
 106             tid2info_min = '-34 -34 0';
 107             tid2info_max = '34 34 90';
 108             break;
 109         case TID_HELLION:
 110             tid2info_head = "models/turrets/hellion.md3";
 111             tid2info_name = "Hellion";
 112             break;
 113         case TID_HK:
 114             tid2info_head = "models/turrets/hk.md3";
 115             tid2info_name = "Hunter-Killer";
 116             break;
 117         case TID_MACHINEGUN:
 118             tid2info_head = "models/turrets/machinegun.md3";
 119             tid2info_name = "Machinegun";
 120             break;
 121         case TID_MLRS:
 122             tid2info_head = "models/turrets/mlrs.md3";
 123             tid2info_name = "MLRS";
 124             break;
 125         case TID_PHASER:
 126             tid2info_head = "models/turrets/phaser.md3";
 127             tid2info_name = "Phaser";
 128             break;
 129         case TID_PLASMA:
 130             tid2info_head = "models/turrets/plasma.md3";
 131             tid2info_name = "Plasma";
 132             break;
 133         case TID_PLASMA_DUAL:
 134             tid2info_head = "models/turrets/plasmad.md3";
 135             tid2info_name = "Dual Plasma";
 136             break;
 137         case TID_TESLA:
 138             tid2info_base = "models/turrets/tesla_base.md3";
 139             tid2info_head = "models/turrets/tesla_head.md3";
 140             tid2info_name = "Tesla coil";
 141             tid2info_min = '-60 -60 0';
 142             tid2info_max  ='60 60 128';
 143             break;
 144         case TID_WALKER:
 145             tid2info_base = "models/turrets/walker_body.md3";
 146             tid2info_head = "models/turrets/walker_head_minigun.md3";
 147             tid2info_name = "Walker";
 148             tid2info_min = '-70 -70 0';
 149             tid2info_max = '70 70 95';
 150             break;
 151     }
 152 }
 153
 154 void turret_remove()
 155 {
 156     remove(self.tur_head);
 157     //remove(self.enemy);
 158     self.tur_head = world;
 159 }
 160
 161 .vector glowmod;
 162 void turret_changeteam()
 163 {
 164         switch(self.team - 1)
 165         {
 166         case COLOR_TEAM1: // Red
 167             self.glowmod = '2 0 0';
 168             self.teamradar_color = '1 0 0';
 169             break;
 170
 171         case COLOR_TEAM2: // Blue
 172             self.glowmod = '0 0 2';
 173             self.teamradar_color = '0 0 1';
 174             break;
 175
 176         case COLOR_TEAM3: // Yellow
 177             self.glowmod = '1 1 0';
 178             self.teamradar_color = '1 1 0';
 179             break;
 180
 181         case COLOR_TEAM4: // Pink
 182             self.glowmod = '1 0 1';
 183             self.teamradar_color = '1 0 1';
 184             break;
 185         }
 186
 187         if(self.team)
 188         self.colormap = 1024 + (self.team - 1) * 17;
 189
 190         self.tur_head.colormap = self.colormap;
 191         self.tur_head.glowmod = self.glowmod;
 192
 193 }
 194
 195 void turret_head_draw()
 196 {
 197     self.drawmask = MASK_NORMAL;
 198 }
 199
 200 void turret_draw()
 201 {
 202     float dt;
 203
 204     dt = time - self.move_time;
 205     self.move_time = time;
 206     if(dt <= 0)
 207         return;
 208
 209     self.tur_head.angles += dt * self.tur_head.move_avelocity;
 210
 211     if (self.health < 127)
 212     {
 213         dt = random();
 214
 215         if(dt < 0.03)
 216             te_spark(self.origin + '0 0 40', randomvec() * 256 + '0 0 256', 16);
 217     }
 218
 219     if(self.health < 85)
 220     if(dt < 0.01)
 221         pointparticles(particleeffectnum("smoke_large"), (self.origin + (randomvec() * 80)), '0 0 0', 1);
 222
 223     if(self.health < 32)
 224     if(dt < 0.015)
 225         pointparticles(particleeffectnum("smoke_small"), (self.origin + (randomvec() * 80)), '0 0 0', 1);
 226
 227 }
 228
 229 void turret_draw2d()
 230 {
 231         if(self.netname == "")
 232             return;
 233
 234     if(autocvar_cl_hidewaypoints) // also check g_waypointsprites_turrets after next release (needs changed to clients default/config .cfg)
 235         return;
 236
 237         float dist = vlen(self.origin - view_origin);
 238     float t = (GetPlayerColor(player_localnum) + 1);
 239
 240         vector o;
 241         string txt;
 242
 243         if(autocvar_cl_vehicles_hud_tactical)
 244         if(dist < 10240 && t != self.team)
 245         {
 246         // TODO: Vehicle tactical hud
 247         o = project_3d_to_2d(self.origin + '0 0 32');
 248         if(o_z < 0
 249         || o_x < (vid_conwidth * waypointsprite_edgeoffset_left)
 250         || o_y < (vid_conheight * waypointsprite_edgeoffset_top)
 251         || o_x > (vid_conwidth - (vid_conwidth * waypointsprite_edgeoffset_right))
 252         || o_y > (vid_conheight - (vid_conheight * waypointsprite_edgeoffset_bottom)))
 253             return; // Dont draw wp's for turrets out of view
 254         o_z = 0;
 255         if(hud != HUD_NORMAL)
 256         {
 257             switch(hud)
 258             {
 259                 case HUD_SPIDERBOT:
 260                 case HUD_WAKIZASHI:
 261                 case HUD_RAPTOR:
 262                     if(self.turret_type == TID_EWHEEL || self.turret_type == TID_WALKER)
 263                         txt = "gfx/vehicles/vth-mover.tga";
 264                     else
 265                         txt = "gfx/vehicles/vth-stationary.tga";
 266
 267                     vector pz = drawgetimagesize(txt) * 0.25;
 268                     drawpic(o - pz * 0.5, txt, pz , '1 1 1', 0.75, DRAWFLAG_NORMAL);
 269                     break;
 270             }
 271         }
 272         }
 273
 274         if(dist > self.maxdistance)
 275         return;
 276
 277         string spriteimage = self.netname;
 278         float a = self.alpha * autocvar_hud_panel_fg_alpha;
 279         vector rgb = spritelookupcolor(spriteimage, self.teamradar_color);
 280
 281
 282         if(self.maxdistance > waypointsprite_normdistance)
 283                 a *= pow(bound(0, (self.maxdistance - dist) / (self.maxdistance - waypointsprite_normdistance), 1), waypointsprite_distancealphaexponent);
 284         else if(self.maxdistance > 0)
 285                 a *= pow(bound(0, (waypointsprite_fadedistance - dist) / (waypointsprite_fadedistance - waypointsprite_normdistance), 1), waypointsprite_distancealphaexponent) * (1 - waypointsprite_minalpha) + waypointsprite_minalpha;
 286
 287         if(rgb == '0 0 0')
 288         {
 289                 self.teamradar_color = '1 0 1';
 290                 print(sprintf("WARNING: sprite of name %s has no color, using pink so you notice it\n", spriteimage));
 291         }
 292
 293         txt = self.netname;
 294         if(autocvar_g_waypointsprite_spam && waypointsprite_count >= autocvar_g_waypointsprite_spam)
 295                 txt = _("Spam");
 296         else
 297                 txt = spritelookuptext(spriteimage);
 298
 299         if(time - floor(time) > 0.5 && t == self.team)
 300         {
 301                 if(self.helpme && time < self.helpme)
 302                 {
 303                     a *= SPRITE_HELPME_BLINK;
 304                     txt = sprintf(_("%s under attack!"), txt);
 305                 }
 306                 else
 307                         a *= spritelookupblinkvalue(spriteimage);
 308         }
 309
 310         if(autocvar_g_waypointsprite_uppercase)
 311                 txt = strtoupper(txt);
 312
 313         if(a > 1)
 314         {
 315                 rgb *= a;
 316                 a = 1;
 317         }
 318
 319         if(a <= 0)
 320             return;
 321
 322         rgb = fixrgbexcess(rgb);
 323
 324         o = project_3d_to_2d(self.origin + '0 0 64');
 325         if(o_z < 0
 326         || o_x < (vid_conwidth * waypointsprite_edgeoffset_left)
 327         || o_y < (vid_conheight * waypointsprite_edgeoffset_top)
 328         || o_x > (vid_conwidth - (vid_conwidth * waypointsprite_edgeoffset_right))
 329         || o_y > (vid_conheight - (vid_conheight * waypointsprite_edgeoffset_bottom)))
 330             return; // Dont draw wp's for turrets out of view
 331
 332         o_z = 0;
 333
 334         float edgedistance_min, crosshairdistance;
 335                 edgedistance_min = min((o_y - (vid_conheight * waypointsprite_edgeoffset_top)),
 336         (o_x - (vid_conwidth * waypointsprite_edgeoffset_left)),
 337         (vid_conwidth - (vid_conwidth * waypointsprite_edgeoffset_right)) - o_x,
 338         (vid_conheight - (vid_conheight * waypointsprite_edgeoffset_bottom)) - o_y);
 339
 340         float vidscale = max(vid_conwidth / vid_width, vid_conheight / vid_height);
 341
 342         crosshairdistance = sqrt( pow(o_x - vid_conwidth/2, 2) + pow(o_y - vid_conheight/2, 2) );
 343
 344         t = waypointsprite_scale * vidscale;
 345         a *= waypointsprite_alpha;
 346
 347         {
 348                 a = a * (1 - (1 - waypointsprite_distancefadealpha) * (bound(0, dist/waypointsprite_distancefadedistance, 1)));
 349                 t = t * (1 - (1 - waypointsprite_distancefadescale) * (bound(0, dist/waypointsprite_distancefadedistance, 1)));
 350         }
 351         if (edgedistance_min < waypointsprite_edgefadedistance) {
 352                 a = a * (1 - (1 - waypointsprite_edgefadealpha) * (1 - bound(0, edgedistance_min/waypointsprite_edgefadedistance, 1)));
 353                 t = t * (1 - (1 - waypointsprite_edgefadescale) * (1 - bound(0, edgedistance_min/waypointsprite_edgefadedistance, 1)));
 354         }
 355         if(crosshairdistance < waypointsprite_crosshairfadedistance) {
 356                 a = a * (1 - (1 - waypointsprite_crosshairfadealpha) * (1 - bound(0, crosshairdistance/waypointsprite_crosshairfadedistance, 1)));
 357                 t = t * (1 - (1 - waypointsprite_crosshairfadescale) * (1 - bound(0, crosshairdistance/waypointsprite_crosshairfadedistance, 1)));
 358         }
 359
 360         o = drawspritearrow(o, M_PI, rgb, a, SPRITE_ARROW_SCALE * t);
 361     o = drawspritetext(o, M_PI, (SPRITE_HEALTHBAR_WIDTH + 2 * SPRITE_HEALTHBAR_BORDER) * t, rgb, a, waypointsprite_fontsize * '1 1 0', txt);
 362     drawhealthbar(
 363             o,
 364             0,
 365             self.health / 255,
 366             '0 0 0',
 367             '0 0 0',
 368             0.5 * SPRITE_HEALTHBAR_WIDTH * t,
 369             0.5 * SPRITE_HEALTHBAR_HEIGHT * t,
 370             SPRITE_HEALTHBAR_MARGIN * t + 0.5 * waypointsprite_fontsize,
 371             SPRITE_HEALTHBAR_BORDER * t,
 372             0,
 373             rgb,
 374             a * SPRITE_HEALTHBAR_BORDERALPHA,
 375             rgb,
 376             a * SPRITE_HEALTHBAR_HEALTHALPHA,
 377             DRAWFLAG_NORMAL
 378             );
 379 }
 380
 381 void turret_walker_draw()
 382 {
 383     float dt;
 384
 385     dt = time - self.move_time;
 386     self.move_time = time;
 387     if(dt <= 0)
 388         return;
 389
 390     fixedmakevectors(self.angles);
 391     movelib_groundalign4point(300, 100, 0.25, 45);
 392     setorigin(self, self.origin + self.velocity * dt);
 393     self.tur_head.angles += dt * self.tur_head.move_avelocity;
 394     self.angles_y = self.move_angles_y;
 395
 396     if (self.health < 127)
 397     if(random() < 0.15)
 398         te_spark(self.origin + '0 0 40', randomvec() * 256 + '0 0 256', 16);
 399 }
 400
 401 void turret_ewheel_draw()
 402 {
 403     float dt;
 404
 405     dt = time - self.move_time;
 406     self.move_time = time;
 407     if(dt <= 0)
 408         return;
 409
 410     fixedmakevectors(self.angles);
 411     setorigin(self, self.origin + self.velocity * dt);
 412     self.tur_head.angles += dt * self.tur_head.move_avelocity;
 413     self.angles_y = self.move_angles_y;
 414
 415     if (self.health < 127)
 416     if(random() < 0.05)
 417         te_spark(self.origin + '0 0 40', randomvec() * 256 + '0 0 256', 16);
 418 }
 419
 420 void(entity e, entity tagentity, string tagname) setattachment = #443;
 421 void turret_construct()
 422 {
 423     if(self.tur_head == world)
 424         self.tur_head = spawn();
 425
 426     turret_tid2info(self.turret_type);
 427     self.netname = tid2info_name;
 428
 429     setorigin(self, self.origin);
 430     setmodel(self, tid2info_base);
 431     setmodel(self.tur_head, tid2info_head);
 432     setsize(self, tid2info_min, tid2info_max);
 433     setsize(self.tur_head, '0 0 0', '0 0 0');
 434
 435     if(self.turret_type == TID_EWHEEL)
 436         setattachment(self.tur_head, self, "");
 437     else
 438         setattachment(self.tur_head, self, "tag_head");
 439
 440     self.tur_head.classname     = "turret_head";
 441     self.tur_head.owner         = self;
 442     self.tur_head.move_movetype = MOVETYPE_NOCLIP;
 443     self.move_movetype          = MOVETYPE_NOCLIP;
 444     self.tur_head.angles        = self.angles;
 445     self.health                 = 255;
 446     self.solid                  = SOLID_BBOX;
 447     self.tur_head.solid         = SOLID_NOT;
 448     self.movetype               = MOVETYPE_NOCLIP;
 449     self.tur_head.movetype      = MOVETYPE_NOCLIP;
 450     self.draw                   = turret_draw;
 451     self.entremove              = turret_remove;
 452     self.drawmask               = MASK_NORMAL;
 453     self.tur_head.drawmask      = MASK_NORMAL;
 454     self.anim_start_time        = 0;
 455     self.draw2d = turret_draw2d;
 456     self.maxdistance = 4000; // use g_waypointsprites_turrets_maxdist after next release (needs changed to cleint's default)
 457     self.teamradar_color = '1 0 0';
 458     self.alpha = 1;
 459
 460     if(self.turret_type == TID_EWHEEL || self.turret_type == TID_WALKER)
 461     {
 462         self.gravity            = 1;
 463         self.movetype           = MOVETYPE_BOUNCE;
 464         self.move_movetype      = MOVETYPE_BOUNCE;
 465         self.move_origin        = self.origin;
 466         self.move_time          = time;
 467         switch(self.turret_type)
 468         {
 469             case TID_EWHEEL:
 470                 self.draw               = turret_ewheel_draw;
 471                 break;
 472             case TID_WALKER:
 473                 self.draw               = turret_walker_draw;
 474                 break;
 475
 476         }
 477     }
 478 }
 479
 480 entity turret_gibtoss(string _model, vector _from, vector _to, vector _cmod, float _explode);
 481 void turret_gibboom();
 482 void turret_gib_draw()
 483 {
 484     Movetype_Physics_MatchTicrate(autocvar_cl_gibs_ticrate, autocvar_cl_gibs_sloppy);
 485
 486     self.drawmask = MASK_NORMAL;
 487
 488         if(self.cnt)
 489         {
 490             if(time >= self.nextthink)
 491             {
 492             turret_gibboom();
 493             remove(self);
 494             }
 495         }
 496         else
 497         {
 498         self.alpha = bound(0, self.nextthink - time, 1);
 499         if(self.alpha < ALPHA_MIN_VISIBLE)
 500             remove(self);
 501         }
 502 }
 503
 504 void turret_gibboom()
 505 {
 506     float i;
 507
 508     sound (self, CH_SHOTS, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
 509     pointparticles(particleeffectnum("rocket_explode"), self.origin, '0 0 0', 1);
 510
 511     for (i = 1; i < 5; i = i + 1)
 512         turret_gibtoss(strcat("models/turrets/head-gib", ftos(i), ".md3"), self.origin + '0 0 2', self.velocity + randomvec() * 700, '0 0 0', FALSE);
 513 }
 514
 515 entity turret_gibtoss(string _model, vector _from, vector _to, vector _cmod, float _explode)
 516 {
 517     entity gib;
 518
 519     traceline(_from, _to, MOVE_NOMONSTERS, world);
 520     if(trace_startsolid)
 521         return world;
 522
 523     gib = spawn();
 524     setorigin(gib, _from);
 525     setmodel(gib, _model);
 526     gib.colormod    = _cmod;
 527         gib.solid       = SOLID_CORPSE;
 528     gib.draw        = turret_gib_draw;
 529     gib.cnt         = _explode;
 530     setsize(gib, '-1 -1 -1', '1 1 1');
 531     if(_explode)
 532     {
 533         gib.nextthink = time + 0.2 * (autocvar_cl_gibs_lifetime * (1 + prandom() * 0.15));
 534         gib.effects = EF_FLAME;
 535     }
 536     else
 537         gib.nextthink = time + autocvar_cl_gibs_lifetime * (1 + prandom() * 0.15);
 538
 539     gib.gravity         = 1;
 540         gib.move_movetype   = MOVETYPE_BOUNCE;
 541         gib.move_origin     = gib.origin = _from;
 542         gib.move_velocity   = _to;
 543         gib.move_avelocity  = prandomvec() * 32;
 544         gib.move_time       = time;
 545         gib.damageforcescale = 1;
 546         gib.classname = "turret_gib";
 547
 548         return gib;
 549 }
 550
 551 void turret_die()
 552 {
 553
 554     sound (self, CH_SHOTS, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
 555     pointparticles(particleeffectnum("rocket_explode"), self.origin, '0 0 0', 1);
 556     turret_tid2info(self.turret_type);
 557     if (!autocvar_cl_nogibs)
 558     {
 559         // Base
 560         if(self.turret_type == TID_EWHEEL)
 561             turret_gibtoss(tid2info_base, self.origin + '0 0 18', self.velocity + '0 0 400' + '0.1 0.1 1' * (random() * 400), '-1 -1 -1', TRUE);
 562         else if (self.turret_type == TID_WALKER)
 563             turret_gibtoss(tid2info_base, self.origin + '0 0 18', self.velocity + '0 0 300' + '0.1 0.1 1' * (random() * 200), '-1 -1 -1', TRUE);
 564         else if (self.turret_type == TID_TESLA)
 565             turret_gibtoss(tid2info_base, self.origin + '0 0 18', '0 0 200', '-1 -1 -1', FALSE);
 566         else
 567         {
 568             if (random() > 0.5)
 569             {
 570                 turret_gibtoss("models/turrets/base-gib2.md3", self.origin + '0 0 8', '0 0 50' + randomvec() * 150, '0 0 0', FALSE);
 571                 turret_gibtoss("models/turrets/base-gib3.md3", self.origin + '0 0 8', '0 0 50' + randomvec() * 150, '0 0 0', FALSE);
 572                 turret_gibtoss("models/turrets/base-gib4.md3", self.origin + '0 0 8', '0 0 50' + randomvec() * 150, '0 0 0', FALSE);
 573             }
 574             else
 575                 turret_gibtoss("models/turrets/base-gib1.md3", self.origin + '0 0 8', '0 0 0', '0 0 0', TRUE);
 576
 577             entity headgib = turret_gibtoss(tid2info_head, self.origin + '0 0 32', '0 0 200' + randomvec() * 200, '-1 -1 -1', TRUE);
 578             if(headgib)
 579             {
 580                 headgib.angles = headgib.move_angles = self.tur_head.angles;
 581                 headgib.avelocity = headgib.move_avelocity = self.tur_head.move_avelocity + randomvec() * 45;
 582                 headgib.avelocity_y = headgib.move_avelocity_y = headgib.move_avelocity_y * 5;
 583                 headgib.gravity = 0.5;
 584             }
 585         }
 586     }
 587
 588     setmodel(self, "null");
 589     setmodel(self.tur_head, "null");
 590 }
 591
 592 void ent_turret()
 593 {
 594     float sf;
 595     sf = ReadByte();
 596
 597         if(sf & TNSF_SETUP)
 598         {
 599             self.turret_type = ReadByte();
 600
 601             self.origin_x = ReadCoord();
 602             self.origin_y = ReadCoord();
 603             self.origin_z = ReadCoord();
 604
 605             self.angles_x = ReadAngle();
 606             self.angles_y = ReadAngle();
 607
 608             turret_precache(self.turret_type);
 609             turret_construct();
 610             self.colormap = 1024;
 611             self.glowmod = '0 1 1';
 612             self.tur_head.colormap = self.colormap;
 613             self.tur_head.glowmod = self.glowmod;
 614     }
 615
 616     if(sf & TNSF_ANG)
 617     {
 618         if(self.tur_head == world) // aparenly this can happpen before TNSF_SETUP. great.
 619             self.tur_head = spawn();
 620
 621         self.tur_head.move_angles_x = ReadShort();
 622         self.tur_head.move_angles_y = ReadShort();
 623         //self.tur_head.angles = self.angles + self.tur_head.move_angles;
 624         self.tur_head.angles = self.tur_head.move_angles;
 625     }
 626
 627     if(sf & TNSF_AVEL)
 628     {
 629         if(self.tur_head == world) // aparenly this can happpen before TNSF_SETUP. great.
 630             self.tur_head = spawn();
 631
 632         self.tur_head.move_avelocity_x = ReadShort();
 633         self.tur_head.move_avelocity_y = ReadShort();
 634     }
 635
 636     if(sf & TNSF_MOVE)
 637     {
 638         self.origin_x = ReadShort();
 639         self.origin_y = ReadShort();
 640         self.origin_z = ReadShort();
 641         setorigin(self, self.origin);
 642
 643         self.velocity_x = ReadShort();
 644         self.velocity_y = ReadShort();
 645         self.velocity_z = ReadShort();
 646
 647         self.move_angles_y = ReadShort();
 648
 649         self.move_time     = time;
 650         self.move_velocity = self.velocity;
 651         self.move_origin   = self.origin;
 652     }
 653
 654     if(sf & TNSF_ANIM)
 655     {
 656         self.frame1time = ReadCoord();
 657         self.frame      = ReadByte();
 658     }
 659
 660     if(sf & TNSF_STATUS)
 661     {
 662         float _tmp;
 663         _tmp = ReadByte();
 664         if(_tmp != self.team)
 665         {
 666             self.team = _tmp;
 667             turret_changeteam();
 668         }
 669
 670         _tmp = ReadByte();
 671         if(_tmp == 0 && self.health != 0)
 672             turret_die();
 673         else if(self.health && self.health != _tmp)
 674             self.helpme = servertime + 10;
 675
 676         self.health = _tmp;
 677     }
 678     //self.enemy.health = self.health / 255;
 679 }