qcsrc/client/view.qc

   1 #include "view.qh"
   2
   3 #include "autocvars.qh"
   4 #include "miscfunctions.qh"
   5 #include "announcer.qh"
   6 #include "hud/_mod.qh"
   7 #include "mapvoting.qh"
   8 #include "shownames.qh"
   9 #include "hud/panel/scoreboard.qh"
  10 #include "hud/panel/quickmenu.qh"
  11
  12 #include <client/mutators/_mod.qh>
  13
  14 #include <common/animdecide.qh>
  15 #include <common/deathtypes/all.qh>
  16 #include <common/ent_cs.qh>
  17 #include <common/anim.qh>
  18 #include <common/constants.qh>
  19 #include <common/net_linked.qh>
  20 #include <common/net_notice.qh>
  21 #include <common/debug.qh>
  22 #include <common/mapinfo.qh>
  23 #include <common/gamemodes/_mod.qh>
  24 #include <common/physics/player.qh>
  25 #include <common/stats.qh>
  26 #include <common/mapobjects/target/music.qh>
  27 #include <common/teams.qh>
  28 #include <common/wepent.qh>
  29
  30 #include <common/weapons/weapon/tuba.qh>
  31
  32 #include <common/vehicles/all.qh>
  33 #include <common/weapons/_all.qh>
  34 #include <common/mutators/mutator/overkill/oknex.qh>
  35 #include <common/mutators/mutator/waypoints/all.qh>
  36 #include <common/viewloc.qh>
  37 #include <common/mapobjects/trigger/viewloc.qh>
  38 #include <common/minigames/cl_minigames.qh>
  39 #include <common/minigames/cl_minigames_hud.qh>
  40
  41 #include <lib/csqcmodel/cl_player.qh>
  42 #include <lib/csqcmodel/cl_model.qh>
  43 #include "csqcmodel_hooks.qh"
  44
  45 #include <lib/warpzone/client.qh>
  46 #include <lib/warpzone/common.qh>
  47
  48 #define EFMASK_CHEAP (EF_ADDITIVE | EF_DOUBLESIDED | EF_FULLBRIGHT | EF_NODEPTHTEST | EF_NODRAW | EF_NOSHADOW | EF_SELECTABLE | EF_TELEPORT_BIT)
  49
  50 float autocvar_cl_viewmodel_scale;
  51 float autocvar_cl_viewmodel_alpha;
  52
  53 bool autocvar_cl_bobmodel;
  54 float autocvar_cl_bobmodel_speed;
  55 float autocvar_cl_bobmodel_side;
  56 float autocvar_cl_bobmodel_up;
  57
  58 float autocvar_cl_followmodel;
  59 float autocvar_cl_followmodel_speed = 0.3;
  60 float autocvar_cl_followmodel_limit = 135;
  61 float autocvar_cl_followmodel_velocity_lowpass = 0.05;
  62 float autocvar_cl_followmodel_highpass = 0.05;
  63 float autocvar_cl_followmodel_lowpass = 0.03;
  64 bool autocvar_cl_followmodel_velocity_absolute;
  65
  66 float autocvar_cl_leanmodel;
  67 float autocvar_cl_leanmodel_speed = 0.3;
  68 float autocvar_cl_leanmodel_limit = 30;
  69 float autocvar_cl_leanmodel_highpass1 = 0.2;
  70 float autocvar_cl_leanmodel_highpass = 0.2;
  71 float autocvar_cl_leanmodel_lowpass = 0.05;
  72
  73 #define avg_factor(avg_time) (1 - exp(-frametime / max(0.001, avg_time)))
  74
  75 #define lowpass(value, frac, ref_store, ret) \
  76         ret = ref_store = ref_store * (1 - frac) + (value) * frac;
  77
  78 #define lowpass_limited(value, frac, limit, ref_store, ret) MACRO_BEGIN \
  79 { \
  80         float __ignore; lowpass(value, frac, ref_store, __ignore); \
  81         ret = ref_store = bound((value) - (limit), ref_store, (value) + (limit)); \
  82 } MACRO_END
  83
  84 #define highpass(value, frac, ref_store, ret) MACRO_BEGIN \
  85 { \
  86         float __f = 0; lowpass(value, frac, ref_store, __f); \
  87         ret = (value) - __f; \
  88 } MACRO_END
  89
  90 #define highpass_limited(value, frac, limit, ref_store, ret) MACRO_BEGIN \
  91 { \
  92         float __f = 0; lowpass_limited(value, frac, limit, ref_store, __f); \
  93         ret = (value) - __f; \
  94 } MACRO_END
  95
  96 #define lowpass2(value, frac, ref_store, ref_out) MACRO_BEGIN \
  97 { \
  98         lowpass(value.x, frac, ref_store.x, ref_out.x); \
  99         lowpass(value.y, frac, ref_store.y, ref_out.y); \
 100 } MACRO_END
 101
 102 #define highpass2(value, frac, ref_store, ref_out) MACRO_BEGIN \
 103 { \
 104         highpass(value.x, frac, ref_store.x, ref_out.x); \
 105         highpass(value.y, frac, ref_store.y, ref_out.y); \
 106 } MACRO_END
 107
 108 #define highpass2_limited(value, frac, limit, ref_store, ref_out) MACRO_BEGIN \
 109 { \
 110         highpass_limited(value.x, frac, limit, ref_store.x, ref_out.x); \
 111         highpass_limited(value.y, frac, limit, ref_store.y, ref_out.y); \
 112 } MACRO_END
 113
 114 #define lowpass3(value, frac, ref_store, ref_out) MACRO_BEGIN \
 115 { \
 116         lowpass(value.x, frac, ref_store.x, ref_out.x); \
 117         lowpass(value.y, frac, ref_store.y, ref_out.y); \
 118         lowpass(value.z, frac, ref_store.z, ref_out.z); \
 119 } MACRO_END
 120
 121 #define highpass3(value, frac, ref_store, ref_out) MACRO_BEGIN \
 122 { \
 123         highpass(value.x, frac, ref_store.x, ref_out.x); \
 124         highpass(value.y, frac, ref_store.y, ref_out.y); \
 125         highpass(value.z, frac, ref_store.z, ref_out.z); \
 126 } MACRO_END
 127
 128 void calc_followmodel_ofs(entity view)
 129 {
 130         if(cl_followmodel_time == time)
 131                 return; // cl_followmodel_ofs already calculated for this frame
 132
 133         float frac;
 134         vector gunorg = '0 0 0';
 135         static vector vel_average;
 136         static vector gunorg_adjustment_highpass;
 137         static vector gunorg_adjustment_lowpass;
 138
 139         vector vel;
 140         if (autocvar_cl_followmodel_velocity_absolute)
 141                 vel = view.velocity;
 142         else
 143         {
 144                 vector forward = '0 0 0', right = '0 0 0', up = '0 0 0';
 145                 MAKEVECTORS(makevectors, view_angles, forward, right, up);
 146                 vel.x = view.velocity * forward;
 147                 vel.y = view.velocity * right * -1;
 148                 vel.z = view.velocity * up;
 149         }
 150
 151         vel.x = bound(vel_average.x - autocvar_cl_followmodel_limit, vel.x, vel_average.x + autocvar_cl_followmodel_limit);
 152         vel.y = bound(vel_average.y - autocvar_cl_followmodel_limit, vel.y, vel_average.y + autocvar_cl_followmodel_limit);
 153         vel.z = bound(vel_average.z - autocvar_cl_followmodel_limit, vel.z, vel_average.z + autocvar_cl_followmodel_limit);
 154
 155         frac = avg_factor(autocvar_cl_followmodel_velocity_lowpass);
 156         lowpass3(vel, frac, vel_average, gunorg);
 157
 158         gunorg *= -autocvar_cl_followmodel_speed * 0.042;
 159
 160         // perform highpass/lowpass on the adjustment vectors (turning velocity into acceleration!)
 161         // trick: we must do the lowpass LAST, so the lowpass vector IS the final vector!
 162         frac = avg_factor(autocvar_cl_followmodel_highpass);
 163         highpass3(gunorg, frac, gunorg_adjustment_highpass, gunorg);
 164         frac = avg_factor(autocvar_cl_followmodel_lowpass);
 165         lowpass3(gunorg, frac, gunorg_adjustment_lowpass, gunorg);
 166
 167         if (autocvar_cl_followmodel_velocity_absolute)
 168         {
 169                 vector fixed_gunorg;
 170                 vector forward = '0 0 0', right = '0 0 0', up = '0 0 0';
 171                 MAKEVECTORS(makevectors, view_angles, forward, right, up);
 172                 fixed_gunorg.x = gunorg * forward;
 173                 fixed_gunorg.y = gunorg * right * -1;
 174                 fixed_gunorg.z = gunorg * up;
 175                 gunorg = fixed_gunorg;
 176         }
 177
 178         cl_followmodel_ofs = gunorg;
 179         cl_followmodel_time = time;
 180 }
 181
 182 vector leanmodel_ofs(entity view)
 183 {
 184         float frac;
 185         vector gunangles = '0 0 0';
 186         static vector gunangles_prev = '0 0 0';
 187         static vector gunangles_highpass = '0 0 0';
 188         static vector gunangles_adjustment_highpass;
 189         static vector gunangles_adjustment_lowpass;
 190
 191         if (view.csqcmodel_teleported)
 192                 gunangles_prev = view_angles;
 193
 194         // in the highpass, we _store_ the DIFFERENCE to the actual view angles...
 195         gunangles_highpass += gunangles_prev;
 196         PITCH(gunangles_highpass) += 360 * floor((PITCH(view_angles) - PITCH(gunangles_highpass)) / 360 + 0.5);
 197         YAW(gunangles_highpass) += 360 * floor((YAW(view_angles) - YAW(gunangles_highpass)) / 360 + 0.5);
 198         ROLL(gunangles_highpass) += 360 * floor((ROLL(view_angles) - ROLL(gunangles_highpass)) / 360 + 0.5);
 199         frac = avg_factor(autocvar_cl_leanmodel_highpass1);
 200         highpass2_limited(view_angles, frac, autocvar_cl_leanmodel_limit, gunangles_highpass, gunangles);
 201         gunangles_prev = view_angles;
 202         gunangles_highpass -= gunangles_prev;
 203
 204         PITCH(gunangles) *= -autocvar_cl_leanmodel_speed;
 205         YAW(gunangles) *= -autocvar_cl_leanmodel_speed;
 206
 207         // we assume here: PITCH = 0, YAW = 1, ROLL = 2
 208         frac = avg_factor(autocvar_cl_leanmodel_highpass);
 209         highpass2(gunangles, frac, gunangles_adjustment_highpass, gunangles);
 210         frac = avg_factor(autocvar_cl_leanmodel_lowpass);
 211         lowpass2(gunangles, frac, gunangles_adjustment_lowpass, gunangles);
 212
 213         gunangles.x = -gunangles.x; // pitch was inverted, now that actually matters
 214
 215         return gunangles;
 216 }
 217
 218 vector bobmodel_ofs(entity view)
 219 {
 220         bool clonground = !(view.anim_implicit_state & ANIMIMPLICITSTATE_INAIR);
 221         static bool oldonground;
 222         static float hitgroundtime;
 223         if (clonground)
 224         {
 225                 float f = time; // cl.movecmd[0].time
 226                 if (!oldonground)
 227                         hitgroundtime = f;
 228         }
 229         oldonground = clonground;
 230
 231         // calculate for swinging gun model
 232         // the gun bobs when running on the ground, but doesn't bob when you're in the air.
 233         vector gunorg = '0 0 0';
 234         static float bobmodel_scale = 0;
 235         static float time_ofs = 0; // makes the effect always restart in the same way
 236         if (clonground)
 237         {
 238                 if (time - hitgroundtime > 0.05)
 239                         bobmodel_scale = min(1, bobmodel_scale + frametime * 5);
 240         }
 241         else
 242                 bobmodel_scale = max(0, bobmodel_scale - frametime * 5);
 243
 244         float xyspeed = bound(0, vlen(vec2(view.velocity)), 400);
 245         if (bobmodel_scale && xyspeed)
 246         {
 247                 float bspeed = xyspeed * 0.01 * autocvar_cl_viewmodel_scale * bobmodel_scale;
 248                 float s = (time - time_ofs) * autocvar_cl_bobmodel_speed;
 249                 gunorg.y = bspeed * autocvar_cl_bobmodel_side * sin(s);
 250                 gunorg.z = bspeed * autocvar_cl_bobmodel_up * cos(s * 2);
 251         }
 252         else
 253                 time_ofs = time;
 254
 255         return gunorg;
 256 }
 257
 258 void viewmodel_animate(entity this)
 259 {
 260         if (autocvar_chase_active) return;
 261         if (STAT(HEALTH) <= 0) return;
 262
 263         entity view = CSQCModel_server2csqc(player_localentnum - 1);
 264
 265         if (autocvar_cl_followmodel)
 266         {
 267                 calc_followmodel_ofs(view);
 268                 this.origin += cl_followmodel_ofs;
 269         }
 270
 271         if (autocvar_cl_leanmodel)
 272                 this.angles += leanmodel_ofs(view);
 273
 274         // vertical view bobbing code
 275         // TODO: cl_bob
 276
 277         // horizontal view bobbing code
 278         // TODO: cl_bob2
 279
 280         // fall bobbing code
 281         // causes the view to swing down and back up when touching the ground
 282         // TODO: cl_bobfall
 283
 284         // gun model bobbing code
 285         if (autocvar_cl_bobmodel)
 286                 this.origin += bobmodel_ofs(view);
 287 }
 288
 289 .vector viewmodel_origin, viewmodel_angles;
 290 .float weapon_nextthink;
 291 .float weapon_eta_last;
 292 .float weapon_switchdelay;
 293
 294 .string name_last;
 295
 296 void viewmodel_draw(entity this)
 297 {
 298         if(!this.activeweapon || !autocvar_r_drawviewmodel)
 299                 return;
 300         int mask = (intermission || (STAT(HEALTH) <= 0) || autocvar_chase_active) ? 0 : MASK_NORMAL;
 301         float a = ((autocvar_cl_viewmodel_alpha) ? bound(-1, autocvar_cl_viewmodel_alpha, this.m_alpha) : this.m_alpha);
 302         bool invehicle = player_localentnum > maxclients;
 303         if (invehicle) a = -1;
 304         Weapon wep = this.activeweapon;
 305         int c = entcs_GetClientColors(current_player);
 306         vector g = weaponentity_glowmod(wep, NULL, c, this);
 307         entity me = CSQCModel_server2csqc(player_localentnum - 1);
 308         int fx = ((me.csqcmodel_effects & EFMASK_CHEAP)
 309                 | EF_NODEPTHTEST)
 310                 &~ (EF_FULLBRIGHT); // can mask team color, so get rid of it
 311         for (entity e = this; e; e = e.weaponchild)
 312         {
 313                 e.drawmask = mask;
 314                 e.alpha = a;
 315                 e.colormap = 256 + c;  // colormap == 0 is black, c == 0 is white
 316                 e.glowmod = g;
 317                 e.csqcmodel_effects = fx;
 318                 CSQCModel_Effects_Apply(e);
 319         }
 320         if(a >= 0)
 321         {
 322                 string name = wep.mdl;
 323                 string newname = wep.wr_viewmodel(wep, this);
 324                 if(newname)
 325                         name = newname;
 326                 bool swap = name != this.name_last;
 327                 // if (swap)
 328                 {
 329                         this.name_last = name;
 330                         CL_WeaponEntity_SetModel(this, name, swap);
 331                         this.viewmodel_origin = this.origin;
 332                         this.viewmodel_angles = this.angles;
 333                 }
 334                 anim_update(this);
 335                 if ((!this.animstate_override && !this.animstate_looping) || time > this.animstate_endtime)
 336                         anim_set(this, this.anim_idle, true, false, false);
 337         }
 338         float f = 0; // 0..1; 0: fully active
 339         float rate = STAT(WEAPONRATEFACTOR);
 340         float eta = rate ? ((this.weapon_nextthink - time) / rate) : 0;
 341         if (eta <= 0) f = this.weapon_eta_last;
 342         else switch (this.state)
 343         {
 344                 case WS_RAISE:
 345                 {
 346                         f = eta / max(eta, this.weapon_switchdelay);
 347                         break;
 348                 }
 349                 case WS_DROP:
 350                 {
 351                         f = 1 - eta / max(eta, this.weapon_switchdelay);
 352                         break;
 353                 }
 354                 case WS_CLEAR:
 355                 {
 356                         f = 1;
 357                         break;
 358                 }
 359         }
 360         this.weapon_eta_last = f;
 361         this.origin = this.viewmodel_origin;
 362         this.angles = this.viewmodel_angles;
 363         this.angles_x = (-90 * f * f);
 364         viewmodel_animate(this);
 365         MUTATOR_CALLHOOK(DrawViewModel, this);
 366         setorigin(this, this.origin);
 367 }
 368
 369 STATIC_INIT(viewmodel) {
 370     for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 371         viewmodels[slot] = new(viewmodel);
 372 }
 373
 374 float showfps_prevfps;
 375 float showfps_prevfps_time;
 376 int showfps_framecounter;
 377
 378 void fpscounter_update()
 379 {
 380         if(!STAT(SHOWFPS))
 381                 return;
 382
 383         float currentTime = gettime(GETTIME_REALTIME);
 384         showfps_framecounter += 1;
 385         if(currentTime - showfps_prevfps_time > STAT(SHOWFPS))
 386         {
 387                 showfps_prevfps = showfps_framecounter/(currentTime - showfps_prevfps_time);
 388                 showfps_framecounter = 0;
 389                 showfps_prevfps_time = currentTime;
 390
 391                 int channel = MSG_C2S;
 392                 WriteHeader(channel, fpsreport);
 393                 WriteShort(channel, bound(0, rint(showfps_prevfps), 65535)); // prevent insane fps values
 394         }
 395 }
 396
 397 STATIC_INIT(fpscounter_init)
 398 {
 399         float currentTime = gettime(GETTIME_REALTIME);
 400         showfps_prevfps_time = currentTime; // we must initialize it to avoid an instant low frame sending
 401 }
 402
 403 STATIC_INIT(Porto)
 404 {
 405         entity e = new_pure(porto);
 406         e.draw = Porto_Draw;
 407         IL_PUSH(g_drawables, e);
 408         e.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 409 }
 410
 411 const int polyline_length = 16;
 412 .vector polyline[polyline_length];
 413 void Porto_Draw(entity this)
 414 {
 415         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 416         {
 417                 entity wepent = viewmodels[slot];
 418
 419                 if (wepent.activeweapon != WEP_PORTO) continue;
 420                 if (spectatee_status) continue;
 421                 if (WEP_CVAR(porto, secondary)) continue;
 422                 if (intermission == 1) continue;
 423                 if (intermission == 2) continue;
 424                 if (STAT(HEALTH) <= 0) continue;
 425
 426                 vector pos = view_origin;
 427                 vector dir = view_forward;
 428                 makevectors(((autocvar_chase_active) ? warpzone_save_view_angles : view_angles));
 429                 pos += v_right * -wepent.movedir.y
 430                         +  v_up * wepent.movedir.z;
 431
 432                 if (wepent.angles_held_status)
 433                 {
 434                         makevectors(wepent.angles_held);
 435                         dir = v_forward;
 436                 }
 437
 438                 wepent.polyline[0] = pos;
 439
 440                 int portal_number = 0, portal1_idx = 1, portal_max = 2;
 441                 int n = 1 + 2;  // 2 lines == 3 points
 442                 for (int idx = 0; idx < n && idx < polyline_length - 1; )
 443                 {
 444                         traceline(pos, pos + 65536 * dir, true, this);
 445                         dir = reflect(dir, trace_plane_normal);
 446                         pos = trace_endpos;
 447                         wepent.polyline[++idx] = pos;
 448                         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
 449                         {
 450                                 n += 1;
 451                                 continue;
 452                         }
 453                         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
 454                         {
 455                                 n = max(2, idx);
 456                                 break;
 457                         }
 458                         // check size
 459                         {
 460                                 vector ang = vectoangles2(trace_plane_normal, dir);
 461                                 ang.x = -ang.x;
 462                                 makevectors(ang);
 463                                 if (!CheckWireframeBox(this, pos - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
 464                                 {
 465                                         n = max(2, idx);
 466                                         break;
 467                                 }
 468                         }
 469                         portal_number += 1;
 470                         if (portal_number >= portal_max) break;
 471                         if (portal_number == 1) portal1_idx = idx;
 472                 }
 473                 for (int idx = 0; idx < n - 1; ++idx)
 474                 {
 475                         vector p = wepent.polyline[idx], q = wepent.polyline[idx + 1];
 476                         if (idx == 0) p -= view_up * 16;  // line from player
 477                         vector rgb = (idx < portal1_idx) ? '1 0 0' : '0 0 1';
 478                         Draw_CylindricLine(p, q, 4, "", 1, 0, rgb, 0.5, DRAWFLAG_NORMAL, view_origin);
 479                 }
 480         }
 481 }
 482
 483 float drawtime;
 484 float avgspeed;
 485 vector GetCurrentFov(float fov)
 486 {
 487         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir;
 488         float velocityzoom, curspeed;
 489         vector v;
 490
 491         zoomsensitivity = autocvar_cl_zoomsensitivity;
 492         zoomfactor = autocvar_cl_zoomfactor;
 493         if(zoomfactor < 1 || zoomfactor > 30)
 494                 zoomfactor = 2.5;
 495         zoomspeed = autocvar_cl_zoomspeed;
 496         if (zoomspeed >= 0 && (zoomspeed < 0.5 || zoomspeed > 16))
 497                 zoomspeed = 3.5;
 498
 499         zoomdir = button_zoom;
 500
 501         if(hud == HUD_NORMAL && !spectatee_status)
 502         {
 503                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 504                 {
 505                         entity wepent = viewmodels[slot];
 506                         if(wepent.switchweapon != wepent.activeweapon)
 507                                 continue;
 508                         Weapon wep = wepent.activeweapon;
 509                         if(wep != WEP_Null && wep.wr_zoomdir)
 510                         {
 511                                 bool do_zoom = wep.wr_zoomdir(wep); // TODO: merge this with wr_zoom?
 512                                 zoomdir += do_zoom;
 513                         }
 514                 }
 515         }
 516         if(spectatee_status > 0 || isdemo())
 517         {
 518                 if(spectatorbutton_zoom)
 519                 {
 520                         if(zoomdir)
 521                                 zoomdir = 0;
 522                         else
 523                                 zoomdir = 1;
 524                 }
 525                 // fteqcc failed twice here already, don't optimize this
 526         }
 527
 528         if(zoomdir) { zoomin_effect = 0; }
 529
 530         if (spectatee_status > 0 && STAT(CAMERA_SPECTATOR) == 2)
 531         {
 532                 current_viewzoom = 1;
 533         }
 534         else if (camera_active)
 535         {
 536                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 537         }
 538         else if(autocvar_cl_spawnzoom && zoomin_effect)
 539         {
 540                 float spawnzoomfactor = bound(1, autocvar_cl_spawnzoom_factor, 30);
 541
 542                 current_viewzoom += (autocvar_cl_spawnzoom_speed * (spawnzoomfactor - current_viewzoom) * drawframetime);
 543                 current_viewzoom = bound(1 / spawnzoomfactor, current_viewzoom, 1);
 544                 if(current_viewzoom == 1) { zoomin_effect = 0; }
 545         }
 546         else
 547         {
 548                 if(zoomspeed < 0) // instant zoom
 549                 {
 550                         if(zoomdir)
 551                                 current_viewzoom = 1 / zoomfactor;
 552                         else
 553                                 current_viewzoom = 1;
 554                 }
 555                 else
 556                 {
 557                         if(zoomdir)
 558                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 559                         else
 560                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 561                 }
 562         }
 563
 564         if(almost_equals(current_viewzoom, 1))
 565                 current_zoomfraction = 0;
 566         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 567                 current_zoomfraction = 1;
 568         else
 569                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 570
 571         if(zoomsensitivity < 1)
 572                 setsensitivityscale(current_viewzoom ** (1 - zoomsensitivity));
 573         else
 574                 setsensitivityscale(1);
 575
 576         if(autocvar_cl_velocityzoom_enabled && autocvar_cl_velocityzoom_type) // _type = 0 disables velocity zoom too
 577         {
 578                 if (intermission || (spectatee_status > 0 && STAT(CAMERA_SPECTATOR) == 2))
 579                         curspeed = 0;
 580                 else
 581                 {
 582                         makevectors(view_angles);
 583                         v = pmove_vel;
 584                         if(csqcplayer)
 585                                 v = csqcplayer.velocity;
 586
 587                         switch(autocvar_cl_velocityzoom_type)
 588                         {
 589                                 case 3: curspeed = max(0, v_forward * v); break;
 590                                 case 2: curspeed = (v_forward * v); break;
 591                                 case 1: default: curspeed = vlen(v); break;
 592                         }
 593                 }
 594
 595                 velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoom_time), 1); // speed at which the zoom adapts to player velocity
 596                 avgspeed = avgspeed * (1 - velocityzoom) + (curspeed / autocvar_cl_velocityzoom_speed) * velocityzoom;
 597                 velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom_factor / 1) * 1);
 598
 599                 //print(ftos(avgspeed), " avgspeed, ", ftos(curspeed), " curspeed, ", ftos(velocityzoom), " return\n"); // for debugging
 600         }
 601         else
 602                 velocityzoom = 1;
 603
 604         float frustumx, frustumy, fovx, fovy;
 605         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 606         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 607         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 608         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 609
 610         return '1 0 0' * fovx + '0 1 0' * fovy;
 611 }
 612
 613 vector GetViewLocationFOV(float fov)
 614 {
 615         float frustumy = tan(fov * M_PI / 360.0) * 0.75;
 616         float frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 617         float fovx = atan2(frustumx, 1) / M_PI * 360.0;
 618         float fovy = atan2(frustumy, 1) / M_PI * 360.0;
 619         return '1 0 0' * fovx + '0 1 0' * fovy;
 620 }
 621
 622 vector GetOrthoviewFOV(vector ov_worldmin, vector ov_worldmax, vector ov_mid, vector ov_org)
 623 {
 624         float fovx, fovy;
 625         float width = (ov_worldmax.x - ov_worldmin.x);
 626         float height = (ov_worldmax.y - ov_worldmin.y);
 627         float distance_to_middle_of_world = vlen(ov_mid - ov_org);
 628         fovx = atan2(width/2, distance_to_middle_of_world) / M_PI * 360.0;
 629         fovy = atan2(height/2, distance_to_middle_of_world) / M_PI * 360.0;
 630         return '1 0 0' * fovx + '0 1 0' * fovy;
 631 }
 632
 633 // this function must match W_SetupShot!
 634 float zoomscript_caught;
 635
 636 bool minigame_wasactive;
 637
 638 vector wcross_origin;
 639 float wcross_scale_prev, wcross_alpha_prev;
 640 vector wcross_color_prev;
 641 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 642 vector wcross_color_goal_prev;
 643 float wcross_changedonetime;
 644
 645 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 646 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 647 float wcross_name_changestarttime, wcross_name_changedonetime;
 648 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 649
 650 float wcross_ring_prev;
 651
 652 entity trueaim;
 653 entity trueaim_rifle;
 654
 655 const float SHOTTYPE_HITTEAM = 1;
 656 const float SHOTTYPE_HITOBSTRUCTION = 2;
 657 const float SHOTTYPE_HITWORLD = 3;
 658 const float SHOTTYPE_HITENEMY = 4;
 659
 660 void TrueAim_Init()
 661 {
 662         (trueaim = new_pure(trueaim)).dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 663         (trueaim_rifle = new_pure(trueaim_rifle)).dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 664 }
 665
 666 float EnemyHitCheck()
 667 {
 668         float t, n;
 669         wcross_origin = project_3d_to_2d(trace_endpos);
 670         wcross_origin.z = 0;
 671         if(trace_ent)
 672                 n = trace_ent.entnum;
 673         else
 674                 n = trace_networkentity;
 675         if(n < 1)
 676                 return SHOTTYPE_HITWORLD;
 677         if(n > maxclients)
 678                 return SHOTTYPE_HITWORLD;
 679         t = entcs_GetTeam(n - 1);
 680         if(teamplay)
 681                 if(t == myteam)
 682                         return SHOTTYPE_HITTEAM;
 683         if(t == NUM_SPECTATOR)
 684                 return SHOTTYPE_HITWORLD;
 685         return SHOTTYPE_HITENEMY;
 686 }
 687
 688 float TrueAimCheck(entity wepent)
 689 {
 690         float nudge = 1; // added to traceline target and subtracted from result TOOD(divVerent): do we still need this? Doesn't the engine do this now for us?
 691         vector vecs, trueaimpoint, w_shotorg;
 692         vector mi, ma, dv;
 693         float shottype;
 694         entity ta;
 695         float mv;
 696
 697         mi = ma = '0 0 0';
 698         ta = trueaim;
 699         mv = MOVE_NOMONSTERS;
 700
 701         switch(wepent.activeweapon) // WEAPONTODO
 702         {
 703                 case WEP_TUBA: // no aim
 704                 case WEP_PORTO: // shoots from eye
 705                 case WEP_NEXBALL: // shoots from eye
 706                 case WEP_HOOK: // no trueaim
 707                 case WEP_MORTAR: // toss curve
 708                         return SHOTTYPE_HITWORLD;
 709                 case WEP_VORTEX:
 710                 case WEP_OVERKILL_NEX:
 711                 case WEP_VAPORIZER:
 712                         mv = MOVE_NORMAL;
 713                         break;
 714                 case WEP_RIFLE:
 715                         ta = trueaim_rifle;
 716                         mv = MOVE_NORMAL;
 717                         if(zoomscript_caught)
 718                         {
 719                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * max_shot_distance, mv, ta);
 720                                 return EnemyHitCheck();
 721                         }
 722                         break;
 723                 case WEP_DEVASTATOR: // projectile has a size!
 724                         mi = '-3 -3 -3';
 725                         ma = '3 3 3';
 726                         break;
 727                 case WEP_FIREBALL: // projectile has a size!
 728                         mi = '-16 -16 -16';
 729                         ma = '16 16 16';
 730                         break;
 731                 case WEP_SEEKER: // projectile has a size!
 732                         mi = '-2 -2 -2';
 733                         ma = '2 2 2';
 734                         break;
 735                 case WEP_ELECTRO: // projectile has a size!
 736                         mi = '0 0 -3';
 737                         ma = '0 0 -3';
 738                         break;
 739         }
 740
 741         vector traceorigin = entcs_receiver(player_localentnum - 1).origin + (eZ * STAT(VIEWHEIGHT));
 742
 743         vecs = decompressShotOrigin(STAT(SHOTORG));
 744
 745         traceline(traceorigin, traceorigin + view_forward * max_shot_distance, mv, ta);
 746         trueaimpoint = trace_endpos;
 747
 748         if(vdist((trueaimpoint - traceorigin), <, g_trueaim_minrange))
 749                 trueaimpoint = traceorigin + view_forward * g_trueaim_minrange;
 750
 751         if(vecs.x > 0)
 752                 vecs.y = -vecs.y;
 753         else
 754                 vecs = '0 0 0';
 755
 756         dv = view_right * vecs.y + view_up * vecs.z;
 757         w_shotorg = traceorigin + dv;
 758
 759         // now move the vecs forward as much as requested if possible
 760         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs.x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 761         w_shotorg = trace_endpos - view_forward * nudge;
 762
 763         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 764         shottype = EnemyHitCheck();
 765         if(shottype != SHOTTYPE_HITWORLD)
 766                 return shottype;
 767
 768 #if 0
 769         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 770         // or rather, I know why, but see no fix
 771         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 772                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 773                 return SHOTTYPE_HITOBSTRUCTION;
 774 #endif
 775
 776         return SHOTTYPE_HITWORLD;
 777 }
 778
 779 float camera_mode;
 780 const float CAMERA_FREE = 1;
 781 const float CAMERA_CHASE = 2;
 782 float reticle_type;
 783 string NextFrameCommand;
 784
 785 vector freeze_org, freeze_ang;
 786 entity nightvision_noise, nightvision_noise2;
 787
 788 const float MAX_TIME_DIFF = 5;
 789 float pickup_crosshair_time, pickup_crosshair_size;
 790 float hitindication_crosshair_size;
 791 float use_vortex_chargepool;
 792
 793 float myhealth, myhealth_prev;
 794 float myhealth_flash;
 795
 796 float old_blurradius, old_bluralpha;
 797 float old_sharpen_intensity;
 798
 799 vector myhealth_gentlergb;
 800
 801 float contentavgalpha, liquidalpha_prev;
 802 vector liquidcolor_prev;
 803
 804 float eventchase_current_distance;
 805 float eventchase_running;
 806 bool WantEventchase(entity this)
 807 {
 808         if(autocvar_cl_orthoview)
 809                 return false;
 810         if(STAT(GAME_STOPPED) || intermission)
 811                 return true;
 812         if(this.viewloc)
 813                 return true;
 814         if(spectatee_status >= 0)
 815         {
 816                 if(hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0))
 817                         return true;
 818                 if(MUTATOR_CALLHOOK(WantEventchase, this))
 819                         return true;
 820                 if(autocvar_cl_eventchase_frozen && STAT(FROZEN))
 821                         return true;
 822                 if(autocvar_cl_eventchase_death && (STAT(HEALTH) <= 0))
 823                 {
 824                         if(autocvar_cl_eventchase_death == 2)
 825                         {
 826                                 // don't stop eventchase once it's started (even if velocity changes afterwards)
 827                                 if(this.velocity == '0 0 0' || eventchase_running)
 828                                         return true;
 829                         }
 830                         else return true;
 831                 }
 832                 if (spectatee_status > 0 && autocvar_cl_eventchase_spectated_change
 833                         && time <= spectatee_status_changed_time + 0.5)
 834                         return true;
 835         }
 836         return false;
 837 }
 838
 839 void HUD_Crosshair_Vehicle(entity this)
 840 {
 841         if(hud != HUD_BUMBLEBEE_GUN)
 842         {
 843                 Vehicle info = Vehicles_from(hud);
 844                 info.vr_crosshair(info, this);
 845         }
 846 }
 847
 848 vector damage_blurpostprocess, content_blurpostprocess;
 849
 850 float unaccounted_damage = 0;
 851 void UpdateDamage()
 852 {
 853         // accumulate damage with each stat update
 854         static float damage_total_prev = 0;
 855         float damage_total = STAT(DAMAGE_DEALT_TOTAL);
 856         float unaccounted_damage_new = COMPARE_INCREASING(damage_total, damage_total_prev);
 857         damage_total_prev = damage_total;
 858
 859         static float damage_dealt_time_prev = 0;
 860         float damage_dealt_time = STAT(HIT_TIME);
 861         if (damage_dealt_time != damage_dealt_time_prev)
 862         {
 863                 unaccounted_damage += unaccounted_damage_new;
 864                 LOG_TRACE("dmg total: ", ftos(unaccounted_damage), " (+", ftos(unaccounted_damage_new), ")");
 865         }
 866         damage_dealt_time_prev = damage_dealt_time;
 867
 868         // prevent hitsound when switching spectatee
 869         static float spectatee_status_prev = 0;
 870         if (spectatee_status != spectatee_status_prev)
 871                 unaccounted_damage = 0;
 872         spectatee_status_prev = spectatee_status;
 873 }
 874
 875 void HitSound()
 876 {
 877         // varying sound pitch
 878
 879         bool have_arc = false;
 880         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 881         {
 882                 entity wepent = viewmodels[slot];
 883
 884                 if(wepent.activeweapon == WEP_ARC)
 885                         have_arc = true;
 886         }
 887
 888         static float hitsound_time_prev = 0;
 889         // HACK: the only way to get the arc to sound consistent with pitch shift is to ignore cl_hitsound_antispam_time
 890         bool arc_hack = have_arc && autocvar_cl_hitsound >= 2;
 891         if (arc_hack || COMPARE_INCREASING(time, hitsound_time_prev) > autocvar_cl_hitsound_antispam_time)
 892         {
 893                 if (autocvar_cl_hitsound && unaccounted_damage)
 894                 {
 895                         // customizable gradient function that crosses (0,a), (c,1) and asymptotically approaches b
 896                         float a = autocvar_cl_hitsound_max_pitch;
 897                         float b = autocvar_cl_hitsound_min_pitch;
 898                         float c = autocvar_cl_hitsound_nom_damage;
 899                         float d = unaccounted_damage;
 900                         float pitch_shift = (b*d*(a-1) + a*c*(1-b)) / (d*(a-1) + c*(1-b));
 901
 902                         // if sound variation is disabled, set pitch_shift to 1
 903                         if (autocvar_cl_hitsound == 1)
 904                                 pitch_shift = 1;
 905
 906                         // if pitch shift is reversed, mirror in (max-min)/2 + min
 907                         if (autocvar_cl_hitsound == 3)
 908                         {
 909                                 float mirror_value = (a-b)/2 + b;
 910                                 pitch_shift = mirror_value + (mirror_value - pitch_shift);
 911                         }
 912
 913                         LOG_TRACE("dmg total (dmg): ", ftos(unaccounted_damage), " , pitch shift: ", ftos(pitch_shift));
 914
 915                         // todo: avoid very long and very short sounds from wave stretching using different sound files? seems unnecessary
 916                         // todo: normalize sound pressure levels? seems unnecessary
 917
 918                         sound7(NULL, CH_INFO, SND(HIT), VOL_BASE, ATTN_NONE, pitch_shift * 100, 0);
 919                 }
 920                 unaccounted_damage = 0;
 921                 hitsound_time_prev = time;
 922         }
 923
 924         static float typehit_time_prev = 0;
 925         float typehit_time = STAT(TYPEHIT_TIME);
 926         if (COMPARE_INCREASING(typehit_time, typehit_time_prev) > autocvar_cl_hitsound_antispam_time)
 927         {
 928                 sound(NULL, CH_INFO, SND_TYPEHIT, VOL_BASE, ATTN_NONE);
 929                 typehit_time_prev = typehit_time;
 930         }
 931
 932         static float kill_time_prev = 0;
 933         float kill_time = STAT(KILL_TIME);
 934         if (COMPARE_INCREASING(kill_time, kill_time_prev) > autocvar_cl_hitsound_antispam_time)
 935         {
 936                 sound(NULL, CH_INFO, SND_KILL, VOL_BASE, ATTN_NONE);
 937                 kill_time_prev = kill_time;
 938         }
 939 }
 940
 941 vector crosshair_getcolor(entity this, float health_stat)
 942 {
 943         static float rainbow_last_flicker;
 944         static vector rainbow_prev_color;
 945         vector wcross_color = '0 0 0';
 946         switch(autocvar_crosshair_color_special)
 947         {
 948                 case 1: // crosshair_color_per_weapon
 949                 {
 950                         if(this != WEP_Null && hud == HUD_NORMAL)
 951                         {
 952                                 wcross_color = this.wpcolor;
 953                                 break;
 954                         }
 955                         else { goto normalcolor; }
 956                 }
 957
 958                 case 2: // crosshair_color_by_health
 959                 {
 960                         vector v = healtharmor_maxdamage(health_stat, STAT(ARMOR), armorblockpercent, DEATH_WEAPON.m_id);
 961                         float hp = floor(v.x + 1);
 962
 963                         //x = red
 964                         //y = green
 965                         //z = blue
 966
 967                         wcross_color.z = 0;
 968
 969                         if(hp > 200)
 970                         {
 971                                 wcross_color.x = 0;
 972                                 wcross_color.y = 1;
 973                         }
 974                         else if(hp > 150)
 975                         {
 976                                 wcross_color.x = 0.4 - (hp-150)*0.02 * 0.4;
 977                                 wcross_color.y = 0.9 + (hp-150)*0.02 * 0.1;
 978                         }
 979                         else if(hp > 100)
 980                         {
 981                                 wcross_color.x = 1 - (hp-100)*0.02 * 0.6;
 982                                 wcross_color.y = 1 - (hp-100)*0.02 * 0.1;
 983                                 wcross_color.z = 1 - (hp-100)*0.02;
 984                         }
 985                         else if(hp > 50)
 986                         {
 987                                 wcross_color.x = 1;
 988                                 wcross_color.y = 1;
 989                                 wcross_color.z = 0.2 + (hp-50)*0.02 * 0.8;
 990                         }
 991                         else if(hp > 20)
 992                         {
 993                                 wcross_color.x = 1;
 994                                 wcross_color.y = (hp-20)*90/27/100;
 995                                 wcross_color.z = (hp-20)*90/27/100 * 0.2;
 996                         }
 997                         else
 998                         {
 999                                 wcross_color.x = 1;
1000                                 wcross_color.y = 0;
1001                         }
1002                         break;
1003                 }
1004
1005                 case 3: // crosshair_color_rainbow
1006                 {
1007                         if(time >= rainbow_last_flicker)
1008                         {
1009                                 rainbow_prev_color = randomvec() * autocvar_crosshair_color_special_rainbow_brightness;
1010                                 rainbow_last_flicker = time + autocvar_crosshair_color_special_rainbow_delay;
1011                         }
1012                         wcross_color = rainbow_prev_color;
1013                         break;
1014                 }
1015 LABEL(normalcolor)
1016                 default: { wcross_color = stov(autocvar_crosshair_color); break; }
1017         }
1018
1019         return wcross_color;
1020 }
1021
1022 void HUD_Crosshair(entity this)
1023 {
1024         float f, i, j;
1025         vector v;
1026         if(!scoreboard_active && !camera_active && intermission != 2 && !STAT(GAME_STOPPED) &&
1027                 spectatee_status != -1 && (!csqcplayer.viewloc || (!spectatee_status && (csqcplayer.viewloc.spawnflags & VIEWLOC_FREEAIM))) && !MUTATOR_CALLHOOK(DrawCrosshair) &&
1028                 !HUD_MinigameMenu_IsOpened() )
1029         {
1030                 if (!autocvar_crosshair_enabled) // main toggle for crosshair rendering
1031                         return;
1032
1033                 if (spectatee_status > 0 && STAT(CAMERA_SPECTATOR) == 2)
1034                         return;
1035
1036                 if (hud != HUD_NORMAL)
1037                 {
1038                         HUD_Crosshair_Vehicle(this);
1039                         return;
1040                 }
1041
1042                 string wcross_style;
1043                 float wcross_alpha, wcross_resolution;
1044                 wcross_style = autocvar_crosshair;
1045                 if (csqcplayer.viewloc && (csqcplayer.viewloc.spawnflags & VIEWLOC_FREEAIM) && autocvar_crosshair_2d != "")
1046                         wcross_style = autocvar_crosshair_2d;
1047                 if (wcross_style == "0")
1048                         return;
1049                 wcross_resolution = autocvar_crosshair_size;
1050                 if (wcross_resolution == 0)
1051                         return;
1052                 wcross_alpha = autocvar_crosshair_alpha;
1053                 if (wcross_alpha == 0)
1054                         return;
1055
1056                 // TrueAim check
1057                 float shottype;
1058
1059                 // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
1060                 if(csqcplayer.viewloc && (csqcplayer.viewloc.spawnflags & VIEWLOC_FREEAIM))
1061                         wcross_origin = viewloc_mousepos;
1062                 else
1063                         wcross_origin = project_3d_to_2d(view_origin + max_shot_distance * view_forward);
1064                 wcross_origin.z = 0;
1065                 if(autocvar_crosshair_hittest)
1066                 {
1067                         vector wcross_oldorigin;
1068                         entity thiswep = viewmodels[0]; // TODO: unhardcode
1069                         wcross_oldorigin = wcross_origin;
1070                         shottype = TrueAimCheck(thiswep);
1071                         if(shottype == SHOTTYPE_HITWORLD)
1072                         {
1073                                 v = wcross_origin - wcross_oldorigin;
1074                                 v.x /= vid_conwidth;
1075                                 v.y /= vid_conheight;
1076                                 if(vdist(v, >, 0.01))
1077                                         shottype = SHOTTYPE_HITOBSTRUCTION;
1078                         }
1079                         if(!autocvar_crosshair_hittest_showimpact)
1080                                 wcross_origin = wcross_oldorigin;
1081                 }
1082                 else
1083                         shottype = SHOTTYPE_HITWORLD;
1084
1085                 vector wcross_color = '0 0 0', wcross_size = '0 0 0';
1086                 string wcross_name = "";
1087                 float wcross_scale, wcross_blur;
1088
1089         entity e = WEP_Null;
1090                 if(autocvar_crosshair_per_weapon || (autocvar_crosshair_color_special == 1))
1091                 {
1092                         entity wepent = viewmodels[0]; // TODO: unhardcode
1093                         e = wepent.switchingweapon;
1094                         if(e)
1095                         {
1096                                 if(autocvar_crosshair_per_weapon)
1097                                 {
1098                                         // WEAPONTODO: access these through some general settings (with non-balance config settings)
1099                                         //wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
1100                                         //if (wcross_resolution == 0)
1101                                                 //return;
1102
1103                                         //wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
1104                                         wcross_resolution *= e.w_crosshair_size;
1105                                         wcross_name = e.w_crosshair;
1106                                 }
1107                         }
1108                 }
1109
1110                 if(wcross_name == "")
1111                         wcross_name = strcat("gfx/crosshair", wcross_style);
1112
1113                 // MAIN CROSSHAIR COLOR DECISION
1114                 wcross_color = crosshair_getcolor(e, STAT(HEALTH));
1115
1116                 if(autocvar_crosshair_effect_scalefade)
1117                 {
1118                         wcross_scale = wcross_resolution;
1119                         wcross_resolution = 1;
1120                 }
1121                 else
1122                 {
1123                         wcross_scale = 1;
1124                 }
1125
1126                 if(autocvar_crosshair_pickup)
1127                 {
1128                         float stat_pickup_time = STAT(LAST_PICKUP);
1129
1130                         if(pickup_crosshair_time < stat_pickup_time)
1131                         {
1132                                 if(time - stat_pickup_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1133                                         pickup_crosshair_size = 1;
1134
1135                                 pickup_crosshair_time = stat_pickup_time;
1136                         }
1137
1138                         if(pickup_crosshair_size > 0)
1139                                 pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
1140                         else
1141                                 pickup_crosshair_size = 0;
1142
1143                         wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
1144                 }
1145
1146                 // todo: make crosshair hit indication dependent on damage dealt
1147                 if(autocvar_crosshair_hitindication)
1148                 {
1149                         vector hitindication_color = ((autocvar_crosshair_color_special == 1) ? stov(autocvar_crosshair_hitindication_per_weapon_color) : stov(autocvar_crosshair_hitindication_color));
1150
1151                         if(unaccounted_damage)
1152                         {
1153                                 hitindication_crosshair_size = 1;
1154                         }
1155
1156                         if(hitindication_crosshair_size > 0)
1157                                 hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
1158                         else
1159                                 hitindication_crosshair_size = 0;
1160
1161                         wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
1162                         wcross_color.x += sin(hitindication_crosshair_size) * hitindication_color.x;
1163                         wcross_color.y += sin(hitindication_crosshair_size) * hitindication_color.y;
1164                         wcross_color.z += sin(hitindication_crosshair_size) * hitindication_color.z;
1165                 }
1166
1167                 if(shottype == SHOTTYPE_HITENEMY)
1168                         wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
1169                 if(shottype == SHOTTYPE_HITTEAM)
1170                         wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
1171
1172                 f = fabs(autocvar_crosshair_effect_time);
1173                 if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
1174                 {
1175                         wcross_changedonetime = time + f;
1176                 }
1177                 if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
1178                 {
1179                         wcross_name_changestarttime = time;
1180                         wcross_name_changedonetime = time + f;
1181                         if(wcross_name_goal_prev_prev)
1182                                 strunzone(wcross_name_goal_prev_prev);
1183                         wcross_name_goal_prev_prev = wcross_name_goal_prev;
1184                         wcross_name_goal_prev = strzone(wcross_name);
1185                         wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
1186                         wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
1187                         wcross_resolution_goal_prev = wcross_resolution;
1188                 }
1189
1190                 wcross_scale_goal_prev = wcross_scale;
1191                 wcross_alpha_goal_prev = wcross_alpha;
1192                 wcross_color_goal_prev = wcross_color;
1193
1194                 if(spectatee_status == -1 && shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
1195                 {
1196                         wcross_blur = 1;
1197                         wcross_alpha *= 0.75;
1198                 }
1199                 else
1200                         wcross_blur = 0;
1201                 // *_prev is at time-frametime
1202                 // * is at wcross_changedonetime+f
1203                 // what do we have at time?
1204                 if(time < wcross_changedonetime)
1205                 {
1206                         f = frametime / (wcross_changedonetime - time + frametime);
1207                         wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
1208                         wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
1209                         wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
1210                 }
1211
1212                 wcross_scale_prev = wcross_scale;
1213                 wcross_alpha_prev = wcross_alpha;
1214                 wcross_color_prev = wcross_color;
1215
1216                 MUTATOR_CALLHOOK(UpdateCrosshair);
1217
1218                 wcross_scale *= 1 - autocvar__menu_alpha;
1219                 wcross_alpha *= 1 - autocvar__menu_alpha;
1220                 wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1221
1222                 if(wcross_scale >= 0.001 && wcross_alpha >= 0.001)
1223                 {
1224                         // crosshair rings for weapon stats
1225                         if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
1226                         {
1227                                 // declarations and stats
1228                                 float ring_value = 0, ring_scale = 0, ring_alpha = 0, ring_inner_value = 0, ring_inner_alpha = 0;
1229                                 string ring_image = string_null, ring_inner_image = string_null;
1230                                 vector ring_rgb = '0 0 0', ring_inner_rgb = '0 0 0';
1231
1232                                 ring_scale = autocvar_crosshair_ring_size;
1233
1234                                 entity wepent = viewmodels[0]; // TODO: unhardcode
1235
1236                                 int weapon_clipload = wepent.clip_load;
1237                                 int weapon_clipsize = wepent.clip_size;
1238
1239                                 float arc_heat = wepent.arc_heat_percent;
1240                                 float vcharge = wepent.vortex_charge;
1241                                 float vchargepool = wepent.vortex_chargepool_ammo;
1242                                 float oknex_charge_ = wepent.oknex_charge;
1243                                 float oknex_chargepool_ = wepent.oknex_chargepool_ammo;
1244
1245                                 if(vortex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
1246                                         vortex_charge_movingavg = vcharge;
1247
1248                                 // handle the values
1249                                 if (autocvar_crosshair_ring && wepent.activeweapon == WEP_VORTEX && vcharge && autocvar_crosshair_ring_vortex) // ring around crosshair representing velocity-dependent damage for the vortex
1250                                 {
1251                                         if (vchargepool || use_vortex_chargepool) {
1252                                                 use_vortex_chargepool = 1;
1253                                                 ring_inner_value = vchargepool;
1254                                         } else {
1255                                                 vortex_charge_movingavg = (1 - autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate) * vortex_charge_movingavg + autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate * vcharge;
1256                                                 ring_inner_value = bound(0, autocvar_crosshair_ring_vortex_currentcharge_scale * (vcharge - vortex_charge_movingavg), 1);
1257                                         }
1258
1259                                         ring_inner_alpha = autocvar_crosshair_ring_vortex_inner_alpha;
1260                                         ring_inner_rgb = vec3(autocvar_crosshair_ring_vortex_inner_color_red, autocvar_crosshair_ring_vortex_inner_color_green, autocvar_crosshair_ring_vortex_inner_color_blue);
1261                                         ring_inner_image = "gfx/crosshair_ring_inner.tga";
1262
1263                                         // draw the outer ring to show the current charge of the weapon
1264                                         ring_value = vcharge;
1265                                         ring_alpha = autocvar_crosshair_ring_vortex_alpha;
1266                                         ring_rgb = wcross_color;
1267                                         ring_image = "gfx/crosshair_ring_nexgun.tga";
1268                                 }
1269                                 else if (autocvar_crosshair_ring && (wepent.activeweapon == WEP_OVERKILL_NEX) && oknex_charge_ && autocvar_crosshair_ring_vortex)
1270                                 {
1271                                         if (oknex_chargepool_ || use_vortex_chargepool) {
1272                                                 use_vortex_chargepool = 1;
1273                                                 ring_inner_value = oknex_chargepool_;
1274                                         } else {
1275                                                 vortex_charge_movingavg = (1 - autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate) * vortex_charge_movingavg + autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate * oknex_charge_;
1276                                                 ring_inner_value = bound(0, autocvar_crosshair_ring_vortex_currentcharge_scale * (oknex_charge_ - vortex_charge_movingavg), 1);
1277                                         }
1278
1279                                         ring_inner_alpha = autocvar_crosshair_ring_vortex_inner_alpha;
1280                                         ring_inner_rgb = eX * autocvar_crosshair_ring_vortex_inner_color_red + eY * autocvar_crosshair_ring_vortex_inner_color_green + eZ * autocvar_crosshair_ring_vortex_inner_color_blue;
1281                                         ring_inner_image = "gfx/crosshair_ring_inner.tga";
1282
1283                                         // draw the outer ring to show the current charge of the weapon
1284                                         ring_value = oknex_charge_;
1285                                         ring_alpha = autocvar_crosshair_ring_vortex_alpha;
1286                                         ring_rgb = wcross_color;
1287                                         ring_image = "gfx/crosshair_ring_nexgun.tga";
1288                                 }
1289                                 else if (autocvar_crosshair_ring && wepent.activeweapon == WEP_MINE_LAYER && WEP_CVAR(minelayer, limit) && autocvar_crosshair_ring_minelayer)
1290                                 {
1291                                         ring_value = bound(0, wepent.minelayer_mines / WEP_CVAR(minelayer, limit), 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
1292                                         ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
1293                                         ring_rgb = wcross_color;
1294                                         ring_image = "gfx/crosshair_ring.tga";
1295                                 }
1296                                 else if (wepent.activeweapon == WEP_HAGAR && wepent.hagar_load && autocvar_crosshair_ring_hagar)
1297                                 {
1298                                         ring_value = bound(0, wepent.hagar_load / WEP_CVAR_SEC(hagar, load_max), 1);
1299                                         ring_alpha = autocvar_crosshair_ring_hagar_alpha;
1300                                         ring_rgb = wcross_color;
1301                                         ring_image = "gfx/crosshair_ring.tga";
1302                                 }
1303                                 else if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
1304                                 {
1305                                         ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
1306                                         ring_scale = autocvar_crosshair_ring_reload_size;
1307                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
1308                                         ring_rgb = wcross_color;
1309
1310                                         // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
1311                                         // if a new image for another weapon is added, add the code (and its respective file/value) here
1312                                         if ((wepent.activeweapon == WEP_RIFLE) && (weapon_clipsize == 80))
1313                                                 ring_image = "gfx/crosshair_ring_rifle.tga";
1314                                         else
1315                                                 ring_image = "gfx/crosshair_ring.tga";
1316                                 }
1317                                 else if ( autocvar_crosshair_ring && autocvar_crosshair_ring_arc && arc_heat && wepent.activeweapon == WEP_ARC )
1318                                 {
1319                                         ring_value = arc_heat;
1320                                         ring_alpha = (1-arc_heat)*autocvar_crosshair_ring_arc_cold_alpha +
1321                                                 arc_heat*autocvar_crosshair_ring_arc_hot_alpha;
1322                                         ring_rgb = (1-arc_heat)*wcross_color + arc_heat*autocvar_crosshair_ring_arc_hot_color;
1323                                         ring_image = "gfx/crosshair_ring.tga";
1324                                 }
1325
1326                                 // if in weapon switch animation, fade ring out/in
1327                                 if(autocvar_crosshair_effect_time > 0)
1328                                 {
1329                                         f = (time - wcross_name_changestarttime) / autocvar_crosshair_effect_time;
1330                                         if (f >= 1)
1331                                         {
1332                                                 wcross_ring_prev = ((ring_image) ? true : false);
1333                                         }
1334
1335                                         if(wcross_ring_prev)
1336                                         {
1337                                                 if(f < 1)
1338                                                         ring_alpha *= fabs(1 - bound(0, f, 1));
1339                                         }
1340                                         else
1341                                         {
1342                                                 if(f < 1)
1343                                                         ring_alpha *= bound(0, f, 1);
1344                                         }
1345                                 }
1346
1347                                 if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
1348                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
1349
1350                                 if (ring_value)
1351                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
1352                         }
1353
1354 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
1355                         MACRO_BEGIN { \
1356                                 if(wcross_blur > 0) \
1357                                 { \
1358                                         for(i = -2; i <= 2; ++i) \
1359                                         for(j = -2; j <= 2; ++j) \
1360                                         M(i,j,sz,wcross_name,wcross_alpha*0.04); \
1361                                 } \
1362                                 else \
1363                                 { \
1364                                         M(0,0,sz,wcross_name,wcross_alpha); \
1365                                 } \
1366                         } MACRO_END
1367
1368 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
1369                         drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size.x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size.y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
1370
1371 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
1372                         CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
1373
1374                         if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
1375                         {
1376                                 f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
1377                                 wcross_size = draw_getimagesize(wcross_name_goal_prev_prev) * wcross_scale;
1378                                 CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
1379                                 f = 1 - f;
1380                         }
1381                         else
1382                         {
1383                                 f = 1;
1384                         }
1385                         wcross_name_alpha_goal_prev = f;
1386
1387                         wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1388                         CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
1389
1390                         if(autocvar_crosshair_dot)
1391                         {
1392                                 vector wcross_color_old;
1393                                 wcross_color_old = wcross_color;
1394
1395                                 if((autocvar_crosshair_dot_color_custom) && (autocvar_crosshair_dot_color != "0"))
1396                                         wcross_color = stov(autocvar_crosshair_dot_color);
1397
1398                                 CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
1399                                 // FIXME why don't we use wcross_alpha here?
1400                                 wcross_color = wcross_color_old;
1401                         }
1402                 }
1403         }
1404         else
1405         {
1406                 wcross_scale_prev = 0;
1407                 wcross_alpha_prev = 0;
1408                 wcross_scale_goal_prev = 0;
1409                 wcross_alpha_goal_prev = 0;
1410                 wcross_changedonetime = 0;
1411                 strfree(wcross_name_goal_prev);
1412                 strfree(wcross_name_goal_prev_prev);
1413                 wcross_name_changestarttime = 0;
1414                 wcross_name_changedonetime = 0;
1415                 wcross_name_alpha_goal_prev = 0;
1416                 wcross_name_alpha_goal_prev_prev = 0;
1417                 wcross_resolution_goal_prev = 0;
1418                 wcross_resolution_goal_prev_prev = 0;
1419         }
1420 }
1421
1422 const int MAX_SPECIALCOMMAND = 15;
1423 vector specialcommand_slots[MAX_SPECIALCOMMAND];
1424 vector specialcommand_colors[MAX_SPECIALCOMMAND];
1425 const float SPECIALCOMMAND_SPEED = 150;
1426 const float SPECIALCOMMAND_TURNSPEED = 2;
1427 const float SPECIALCOMMAND_SIZE = 0.025;
1428 const float SPECIALCOMMAND_CHANCE = 0.35;
1429 float sc_spawntime, sc_changetime;
1430 vector sc_color = '1 1 1';
1431 void SpecialCommand()
1432 {
1433         if(!STAT(MOVEVARS_SPECIALCOMMAND))
1434                 return;
1435
1436         if(time >= sc_changetime)
1437         {
1438                 sc_changetime = time + 1;
1439                 sc_color = randomvec() * 1.5;
1440                 sc_color.x = bound(0.2, sc_color.x, 0.75);
1441                 sc_color.y = bound(0.2, sc_color.y, 0.75);
1442                 sc_color.z = bound(0.2, sc_color.z, 0.75);
1443         }
1444         drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), sc_color, autocvar_hud_colorflash_alpha * bound(0.1, sc_changetime - time, 0.3), DRAWFLAG_ADDITIVE);
1445
1446         if(!precache_pic("gfx/smile"))
1447                 return; // damn party poopers
1448
1449         for(int j = MAX_SPECIALCOMMAND - 1; j >= 0; --j)
1450         {
1451                 vector slot = specialcommand_slots[j];
1452                 if(slot.y)
1453                         slot.y += SPECIALCOMMAND_SPEED * frametime;
1454                 //if(slot.z)
1455                         //slot.z = sin(SPECIALCOMMAND_TURNSPEED * M_PI * time);
1456                 if(slot.y >= vid_conheight)
1457                         slot = '0 0 0';
1458
1459                 if(slot == '0 0 0')
1460                 {
1461                         if(random() <= SPECIALCOMMAND_CHANCE && time > sc_spawntime) // low chance to spawn!
1462                         {
1463                                 slot.x = bound(0, (random() * vid_conwidth + 1), vid_conwidth);
1464                                 slot.y = 1; // start it off 0 so we can use it
1465                                 slot.z = floor(random() * Weapons_MAX);
1466                                 sc_spawntime = time + bound(0.4, random(), 0.75); // prevent spawning another one for this amount of time!
1467                                 vector newcolor = randomvec() * 2;
1468                                 newcolor.x = bound(0.4, newcolor.x, 1);
1469                                 newcolor.y = bound(0.4, newcolor.y, 1);
1470                                 newcolor.z = bound(0.4, newcolor.z, 1);
1471                                 specialcommand_colors[j] = newcolor;
1472                         }
1473                 }
1474                 else
1475                 {
1476                         vector splash_size = '0 0 0';
1477                         splash_size.x = max(vid_conwidth, vid_conheight) * SPECIALCOMMAND_SIZE;
1478                         splash_size.y = max(vid_conwidth, vid_conheight) * SPECIALCOMMAND_SIZE;
1479                         entity wep = Weapons_from(slot.z);
1480                         if(wep == WEP_Null)
1481                                 drawpic(vec2(slot), "gfx/smile", vec2(splash_size), specialcommand_colors[j], 0.95, DRAWFLAG_NORMAL);
1482                         else
1483                                 drawpic_skin(vec2(slot), wep.model2, vec2(splash_size), specialcommand_colors[j], 0.95, DRAWFLAG_NORMAL);
1484                         //drawrotpic(vec2(slot), slot.z, "gfx/smile", vec2(splash_size), vec2(splash_size) / 2, specialcommand_colors[j], 0.95, DRAWFLAG_NORMAL);
1485                 }
1486
1487                 specialcommand_slots[j] = slot;
1488         }
1489 }
1490
1491 void HUD_Draw(entity this)
1492 {
1493         // if we don't know gametype and scores yet avoid drawing the scoreboard
1494         // also in the very first frames, player state may be inconsistent so avoid drawing the hud at all
1495         // e.g. since initial player's health is 0 hud would display the hud_damage effect,
1496         // cl_deathscoreboard would show the scoreboard and so on
1497         if(!gametype)
1498                 return;
1499
1500         Hud_Dynamic_Frame();
1501
1502         if(!intermission)
1503         if (MUTATOR_CALLHOOK(HUD_Draw_overlay))
1504         {
1505                 drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), M_ARGV(0, vector), autocvar_hud_colorflash_alpha * M_ARGV(1, float), DRAWFLAG_ADDITIVE);
1506         }
1507         else if(STAT(FROZEN))
1508         {
1509                 vector col = '0.25 0.90 1';
1510                 if(STAT(REVIVE_PROGRESS))
1511                         col += vec3(STAT(REVIVE_PROGRESS), -STAT(REVIVE_PROGRESS), -STAT(REVIVE_PROGRESS));
1512                 drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), col, autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1513         }
1514
1515         HUD_Scale_Enable();
1516         if(!intermission)
1517         if(STAT(NADE_TIMER) && autocvar_cl_nade_timer) // give nade top priority, as it's a matter of life and death
1518         {
1519                 vector col = '0.25 0.90 1' + vec3(STAT(NADE_TIMER), -STAT(NADE_TIMER), -STAT(NADE_TIMER));
1520                 DrawCircleClippedPic(vec2(0.5 * vid_conwidth, 0.6 * vid_conheight), 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(NADE_TIMER), col, autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1521                 drawstring_aspect(eY * 0.64 * vid_conheight, ((autocvar_cl_nade_timer == 2) ? _("Nade timer") : ""), vec2(vid_conwidth, 0.025 * vid_conheight), '1 1 1', 1, DRAWFLAG_NORMAL);
1522         }
1523         else if(STAT(CAPTURE_PROGRESS))
1524         {
1525                 DrawCircleClippedPic(vec2(0.5 * vid_conwidth, 0.6 * vid_conheight), 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(CAPTURE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1526                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Capture progress"), vec2(vid_conwidth, 0.025 * vid_conheight), '1 1 1', 1, DRAWFLAG_NORMAL);
1527         }
1528         else if(STAT(REVIVE_PROGRESS))
1529         {
1530                 DrawCircleClippedPic(vec2(0.5 * vid_conwidth, 0.6 * vid_conheight), 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1531                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Revival progress"), vec2(vid_conwidth, 0.025 * vid_conheight), '1 1 1', 1, DRAWFLAG_NORMAL);
1532         }
1533         HUD_Scale_Disable();
1534
1535         if(autocvar_r_letterbox == 0)
1536                 if(autocvar_viewsize < 120)
1537                 {
1538                         if(!(gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS))
1539                                 Accuracy_LoadLevels();
1540
1541                         HUD_Main();
1542                         HUD_Scale_Disable();
1543                 }
1544
1545         // crosshair goes VERY LAST
1546         SpecialCommand();
1547         UpdateDamage();
1548         HUD_Crosshair(this);
1549         HitSound();
1550 }
1551
1552 void ViewLocation_Mouse()
1553 {
1554         if(spectatee_status)
1555                 return; // don't draw it as spectator!
1556
1557         viewloc_mousepos += getmousepos() * autocvar_menu_mouse_speed;
1558         viewloc_mousepos.x = bound(0, viewloc_mousepos.x, vid_conwidth);
1559         viewloc_mousepos.y = bound(0, viewloc_mousepos.y, vid_conheight);
1560
1561         //float cursor_alpha = 1 - autocvar__menu_alpha;
1562         //draw_cursor(viewloc_mousepos, '0.5 0.5 0', "/cursor_move", '1 1 1', cursor_alpha);
1563 }
1564
1565 void HUD_Cursor_Show()
1566 {
1567         float cursor_alpha = 1 - autocvar__menu_alpha;
1568         if(cursor_type == CURSOR_NORMAL)
1569                 draw_cursor_normal(mousepos, '1 1 1', cursor_alpha);
1570         else if(cursor_type == CURSOR_MOVE)
1571                 draw_cursor(mousepos, '0.5 0.5 0', "/cursor_move", '1 1 1', cursor_alpha);
1572         else if(cursor_type == CURSOR_RESIZE)
1573                 draw_cursor(mousepos, '0.5 0.5 0', "/cursor_resize", '1 1 1', cursor_alpha);
1574         else if(cursor_type == CURSOR_RESIZE2)
1575                 draw_cursor(mousepos, '0.5 0.5 0', "/cursor_resize2", '1 1 1', cursor_alpha);
1576 }
1577
1578 void HUD_Mouse(entity player)
1579 {
1580         if(autocvar__menu_alpha == 1)
1581                 return;
1582
1583         if(!cursor_active)
1584         {
1585                 if(player.viewloc && (player.viewloc.spawnflags & VIEWLOC_FREEAIM))
1586                         ViewLocation_Mouse(); // NOTE: doesn't use cursormode
1587                 return;
1588         }
1589
1590         if(!autocvar_hud_cursormode)
1591                 update_mousepos();
1592
1593         if(autocvar__hud_configure)
1594                 HUD_Panel_Mouse();
1595         else
1596         {
1597                 if (HUD_MinigameMenu_IsOpened())
1598                         HUD_Minigame_Mouse();
1599                 if (QuickMenu_IsOpened())
1600                         QuickMenu_Mouse();
1601                 if (HUD_Radar_Clickable())
1602                         HUD_Radar_Mouse();
1603         }
1604
1605         prevMouseClicked = mouseClicked;
1606
1607         HUD_Cursor_Show();
1608 }
1609
1610 bool ov_enabled;
1611 float oldr_nearclip;
1612 float oldr_farclip_base;
1613 float oldr_farclip_world;
1614 float oldr_novis;
1615 float oldr_useportalculling;
1616 float oldr_useinfinitefarclip;
1617
1618 float prev_myteam;
1619 int lasthud;
1620 float vh_notice_time;
1621 void CSQC_UpdateView(entity this, float w, float h)
1622 {
1623         TC(int, w); TC(int, h);
1624         entity e;
1625         float fov;
1626         float f;
1627         vector vf_size, vf_min;
1628         float a;
1629
1630         execute_next_frame();
1631
1632         ++framecount;
1633
1634         stats_get();
1635         hud = STAT(HUD);
1636
1637         if(hud != HUD_NORMAL && lasthud == HUD_NORMAL)
1638                 vh_notice_time = time + autocvar_cl_vehicles_notify_time;
1639
1640         lasthud = hud;
1641
1642         HUD_Scale_Disable();
1643
1644         if(autocvar__hud_showbinds_reload) // menu can set this one
1645         {
1646                 db_close(binddb);
1647                 binddb = db_create();
1648                 cvar_set("_hud_showbinds_reload", "0");
1649         }
1650
1651         if(checkextension("DP_CSQC_MINFPS_QUALITY"))
1652                 view_quality = getproperty(VF_MINFPS_QUALITY);
1653         else
1654                 view_quality = 1;
1655
1656         button_attack2 = PHYS_INPUT_BUTTON_ATCK2(this);
1657         button_zoom = PHYS_INPUT_BUTTON_ZOOM(this);
1658
1659         vf_size = getpropertyvec(VF_SIZE);
1660         vf_min = getpropertyvec(VF_MIN);
1661         vid_width = vf_size.x;
1662         vid_height = vf_size.y;
1663
1664         vector reticle_pos = '0 0 0', reticle_size = '0 0 0';
1665         vector splash_pos = '0 0 0', splash_size = '0 0 0';
1666
1667         WaypointSprite_Load();
1668
1669         CSQCPlayer_SetCamera();
1670
1671         if(player_localentnum <= maxclients) // is it a client?
1672                 current_player = player_localentnum - 1;
1673         else // then player_localentnum is the vehicle I'm driving
1674                 current_player = player_localnum;
1675         myteam = entcs_GetTeam(current_player);
1676
1677         if(myteam != prev_myteam)
1678         {
1679                 myteamcolors = colormapPaletteColor(myteam, 1);
1680                 FOREACH(hud_panels, true, it.update_time = time);
1681                 prev_myteam = myteam;
1682         }
1683
1684         ticrate = STAT(MOVEVARS_TICRATE) * STAT(MOVEVARS_TIMESCALE);
1685
1686         float is_dead = (STAT(HEALTH) <= 0);
1687
1688         // FIXME do we need this hack?
1689         if(isdemo())
1690         {
1691                 // in demos, input_buttons do not work
1692                 button_zoom = (autocvar__togglezoom == "-");
1693         }
1694         else if(button_zoom
1695                 && autocvar_cl_unpress_zoom_on_death
1696                 && (spectatee_status >= 0)
1697                 && (is_dead || intermission))
1698         {
1699                 // no zoom while dead or in intermission please
1700                 localcmd("-zoom\n");
1701                 button_zoom = false;
1702         }
1703
1704         // abused multiple places below
1705         entity local_player = ((csqcplayer) ? csqcplayer : CSQCModel_server2csqc(player_localentnum - 1));
1706         if(!local_player)
1707                 local_player = this; // fall back!
1708
1709         // event chase camera
1710         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
1711         {
1712                 if(STAT(CAMERA_SPECTATOR))
1713                 {
1714                         if(spectatee_status > 0)
1715                         {
1716                                 if(!autocvar_chase_active)
1717                                 {
1718                                         cvar_set("chase_active", "-2");
1719                                         goto skip_eventchase_death;
1720                                 }
1721                         }
1722                         else if(autocvar_chase_active == -2)
1723                                 cvar_set("chase_active", "0");
1724
1725                         if(autocvar_chase_active == -2)
1726                                 goto skip_eventchase_death;
1727                 }
1728                 else if(autocvar_chase_active == -2)
1729                         cvar_set("chase_active", "0");
1730
1731                 float vehicle_chase = (hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0));
1732
1733                 float vehicle_viewdist = 0;
1734                 vector vehicle_viewofs = '0 0 0';
1735
1736                 if(vehicle_chase)
1737                 {
1738                         if(hud != HUD_BUMBLEBEE_GUN)
1739                         {
1740                                 Vehicle info = Vehicles_from(hud);
1741                                 vehicle_viewdist = info.height;
1742                                 vehicle_viewofs = info.view_ofs;
1743                         }
1744                 }
1745
1746                 if(WantEventchase(this))
1747                 {
1748                         vector current_view_origin_override = '0 0 0';
1749                         vector view_offset_override = '0 0 0';
1750                         float chase_distance_override = 0;
1751                         bool custom_eventchase = MUTATOR_CALLHOOK(CustomizeEventchase, this);
1752                         if(custom_eventchase)
1753                         {
1754                                 current_view_origin_override = M_ARGV(0, vector);
1755                                 view_offset_override = M_ARGV(1, vector);
1756                                 chase_distance_override = M_ARGV(0, float);
1757                         }
1758                         eventchase_running = true;
1759
1760                         // make special vector since we can't use view_origin (It is one frame old as of this code, it gets set later with the results this code makes.)
1761                         vector current_view_origin = (csqcplayer ? csqcplayer.origin : pmove_org);
1762                         if (custom_eventchase)
1763                                 current_view_origin = current_view_origin_override;
1764
1765                         // detect maximum viewoffset and use it
1766                         vector view_offset = autocvar_cl_eventchase_viewoffset;
1767                         if(vehicle_chase)
1768                         {
1769                                 if(vehicle_viewofs)
1770                                         view_offset = vehicle_viewofs;
1771                                 else
1772                                         view_offset = autocvar_cl_eventchase_vehicle_viewoffset;
1773                         }
1774                         if (custom_eventchase)
1775                                 view_offset = view_offset_override;
1776
1777                         if(view_offset)
1778                         {
1779                                 WarpZone_TraceLine(current_view_origin, current_view_origin + view_offset + ('0 0 1' * autocvar_cl_eventchase_maxs.z), MOVE_WORLDONLY, this);
1780                                 if(trace_fraction == 1) { current_view_origin += view_offset; }
1781                                 else { current_view_origin.z += max(0, (trace_endpos.z - current_view_origin.z) - autocvar_cl_eventchase_maxs.z); }
1782                         }
1783
1784                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
1785                         // Ideally, there should be another way to enable third person cameras, such as through setproperty()
1786                         // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
1787                         if(!autocvar_chase_active) { cvar_set("chase_active", "-1"); }
1788
1789                         // make the camera smooth back
1790                         float chase_distance = autocvar_cl_eventchase_distance;
1791                         if(vehicle_chase)
1792                         {
1793                                 if(vehicle_viewofs)
1794                                         chase_distance = vehicle_viewdist;
1795                                 else
1796                                         chase_distance = autocvar_cl_eventchase_vehicle_distance;
1797                         }
1798                         if (custom_eventchase)
1799                                 chase_distance = chase_distance_override;
1800
1801                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < chase_distance)
1802                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (chase_distance - eventchase_current_distance) * frametime; // slow down the further we get
1803                         else if(eventchase_current_distance != chase_distance)
1804                                 eventchase_current_distance = chase_distance;
1805
1806                         makevectors(view_angles);
1807
1808                         vector eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1809                         WarpZone_TraceBox(current_view_origin, autocvar_cl_eventchase_mins, autocvar_cl_eventchase_maxs, eventchase_target_origin, MOVE_WORLDONLY, this);
1810
1811                         // If the boxtrace fails, revert back to line tracing.
1812                         if(!local_player.viewloc)
1813                         if(trace_startsolid)
1814                         {
1815                                 eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1816                                 WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, this);
1817                                 setproperty(VF_ORIGIN, (trace_endpos - (v_forward * autocvar_cl_eventchase_mins.z)));
1818                         }
1819                         else { setproperty(VF_ORIGIN, trace_endpos); }
1820
1821                         if(!local_player.viewloc)
1822                                 setproperty(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
1823                 }
1824                 else if(autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
1825                 {
1826                         eventchase_running = false;
1827                         cvar_set("chase_active", "0");
1828                         eventchase_current_distance = 0; // start from 0 next time
1829                 }
1830         }
1831         // workaround for camera stuck between player's legs when using chase_active 1
1832         // because the engine stops updating the chase_active camera when the game ends
1833         else if(intermission)
1834         {
1835                 cvar_settemp("chase_active", "-1");
1836                 eventchase_current_distance = 0;
1837         }
1838
1839         LABEL(skip_eventchase_death);
1840
1841         // do lockview after event chase camera so that it still applies whenever necessary.
1842         if(autocvar_cl_lockview || (!autocvar_hud_cursormode && (autocvar__hud_configure && spectatee_status <= 0 || intermission > 1 || QuickMenu_IsOpened())))
1843         {
1844                 setproperty(VF_ORIGIN, freeze_org);
1845                 setproperty(VF_ANGLES, freeze_ang);
1846         }
1847         else
1848         {
1849                 freeze_org = getpropertyvec(VF_ORIGIN);
1850                 freeze_ang = getpropertyvec(VF_ANGLES);
1851         }
1852
1853         WarpZone_FixView();
1854         //WarpZone_FixPMove();
1855
1856         vector ov_org = '0 0 0';
1857         vector ov_mid = '0 0 0';
1858         vector ov_worldmin = '0 0 0';
1859         vector ov_worldmax = '0 0 0';
1860         if(autocvar_cl_orthoview)
1861         {
1862                 ov_worldmin = mi_picmin;
1863                 ov_worldmax = mi_picmax;
1864
1865                 float ov_width = (ov_worldmax.x - ov_worldmin.x);
1866                 float ov_height = (ov_worldmax.y - ov_worldmin.y);
1867                 float ov_distance = (max(vid_width, vid_height) * max(ov_width, ov_height));
1868
1869                 ov_mid = ((ov_worldmax + ov_worldmin) * 0.5);
1870                 ov_org = vec3(ov_mid.x, ov_mid.y, (ov_mid.z + ov_distance));
1871
1872                 float ov_nearest = vlen(ov_org - vec3(
1873                         bound(ov_worldmin.x, ov_org.x, ov_worldmax.x),
1874                         bound(ov_worldmin.y, ov_org.y, ov_worldmax.y),
1875                         bound(ov_worldmin.z, ov_org.z, ov_worldmax.z)
1876                 ));
1877
1878                 float ov_furthest = 0;
1879                 float dist = 0;
1880
1881                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1882                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1883                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1884                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1885                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1886                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1887                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1888                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1889
1890                 if(!ov_enabled)
1891                 {
1892                         oldr_nearclip = cvar("r_nearclip");
1893                         oldr_farclip_base = cvar("r_farclip_base");
1894                         oldr_farclip_world = cvar("r_farclip_world");
1895                         oldr_novis = cvar("r_novis");
1896                         oldr_useportalculling = cvar("r_useportalculling");
1897                         oldr_useinfinitefarclip = cvar("r_useinfinitefarclip");
1898                 }
1899
1900                 cvar_settemp("r_nearclip", ftos(ov_nearest));
1901                 cvar_settemp("r_farclip_base", ftos(ov_furthest));
1902                 cvar_settemp("r_farclip_world", "0");
1903                 cvar_settemp("r_novis", "1");
1904                 cvar_settemp("r_useportalculling", "0");
1905                 cvar_settemp("r_useinfinitefarclip", "0");
1906
1907                 setproperty(VF_ORIGIN, ov_org);
1908                 setproperty(VF_ANGLES, '90 0 0');
1909
1910                 ov_enabled = true;
1911
1912                 #if 0
1913                 LOG_INFOF("OrthoView: org = %s, angles = %s, distance = %f, nearest = %f, furthest = %f",
1914                         vtos(ov_org),
1915                         vtos(getpropertyvec(VF_ANGLES)),
1916                         ov_distance,
1917                         ov_nearest,
1918                         ov_furthest);
1919                 #endif
1920         }
1921         else
1922         {
1923                 if(ov_enabled)
1924                 {
1925                         cvar_set("r_nearclip", ftos(oldr_nearclip));
1926                         cvar_set("r_farclip_base", ftos(oldr_farclip_base));
1927                         cvar_set("r_farclip_world", ftos(oldr_farclip_world));
1928                         cvar_set("r_novis", ftos(oldr_novis));
1929                         cvar_set("r_useportalculling", ftos(oldr_useportalculling));
1930                         cvar_set("r_useinfinitefarclip", ftos(oldr_useinfinitefarclip));
1931                 }
1932                 ov_enabled = false;
1933         }
1934
1935         // run viewmodel_draw before updating view_angles to the angles calculated by WarpZone_FixView
1936         // viewmodel_draw needs to use the view_angles set by the engine on every CSQC_UpdateView call
1937         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1938                 viewmodel_draw(viewmodels[slot]);
1939
1940         // Render the Scene
1941         view_origin = getpropertyvec(VF_ORIGIN);
1942         view_angles = getpropertyvec(VF_ANGLES);
1943         makevectors(view_angles);
1944         view_forward = v_forward;
1945         view_right = v_right;
1946         view_up = v_up;
1947
1948 #ifdef BLURTEST
1949         if(time > blurtest_time0 && time < blurtest_time1)
1950         {
1951                 float r, t;
1952
1953                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
1954                 r = t * blurtest_radius;
1955                 f = 1 / (t ** blurtest_power) - 1;
1956
1957                 cvar_set("r_glsl_postprocess", "1");
1958                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
1959         }
1960         else
1961         {
1962                 cvar_set("r_glsl_postprocess", "0");
1963                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
1964         }
1965 #endif
1966
1967         TargetMusic_Advance();
1968         Fog_Force();
1969         fpscounter_update();
1970
1971         if(drawtime == 0)
1972                 drawframetime = 0.01666667; // when we don't know fps yet, we assume 60fps
1973         else
1974                 drawframetime = bound(0.000001, time - drawtime, 1);
1975         drawtime = time;
1976
1977         // watch for gametype changes here...
1978         // in ParseStuffCMD the cmd isn't executed yet :/
1979         // might even be better to add the gametype to TE_CSQC_INIT...?
1980         if(!postinit)
1981                 PostInit();
1982
1983         if(intermission && !intermission_time)
1984                 intermission_time = time;
1985
1986         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
1987         {
1988                 if(calledhooks & HOOK_START)
1989                 {
1990                         localcmd("\ncl_hook_gameend\n");
1991                         calledhooks |= HOOK_END;
1992                 }
1993         }
1994
1995         Announcer();
1996
1997         fov = autocvar_fov;
1998         if(fov <= 59.5)
1999         {
2000                 if(!zoomscript_caught)
2001                 {
2002                         localcmd("+button9\n");
2003                         zoomscript_caught = 1;
2004                 }
2005         }
2006         else
2007         {
2008                 if(zoomscript_caught)
2009                 {
2010                         localcmd("-button9\n");
2011                         zoomscript_caught = 0;
2012                 }
2013         }
2014
2015         if(active_minigame && HUD_MinigameMenu_IsOpened())
2016         {
2017                 if(!minigame_wasactive)
2018                 {
2019                         localcmd("+button14\n");
2020                         minigame_wasactive = true;
2021                 }
2022         }
2023         else if(minigame_wasactive)
2024         {
2025                 localcmd("-button14\n");
2026                 minigame_wasactive = false;
2027         }
2028
2029         ColorTranslateMode = autocvar_cl_stripcolorcodes;
2030
2031         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2032         {
2033                 entity wepent = viewmodels[slot];
2034
2035                 if(wepent.last_switchweapon != wepent.switchweapon)
2036                 {
2037                         weapontime = time;
2038                         wepent.last_switchweapon = wepent.switchweapon;
2039                         if(slot == 0 && button_zoom && autocvar_cl_unpress_zoom_on_weapon_switch)
2040                         {
2041                                 localcmd("-zoom\n");
2042                                 button_zoom = false;
2043                         }
2044                         if(slot == 0 && autocvar_cl_unpress_attack_on_weapon_switch)
2045                         {
2046                                 localcmd("-fire\n");
2047                                 localcmd("-fire2\n");
2048                                 button_attack2 = false;
2049                         }
2050                 }
2051                 if(wepent.last_activeweapon != wepent.activeweapon)
2052                 {
2053                         wepent.last_activeweapon = wepent.activeweapon;
2054
2055                         e = wepent.activeweapon;
2056                         if(e.netname != "")
2057                                 localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
2058                         else if(slot == 0)
2059                                 localcmd("\ncl_hook_activeweapon none\n");
2060                 }
2061         }
2062
2063         // ALWAYS Clear Current Scene First
2064         clearscene();
2065
2066         setproperty(VF_ORIGIN, view_origin);
2067         setproperty(VF_ANGLES, view_angles);
2068
2069         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
2070         setproperty(VF_SIZE, vf_size);
2071         setproperty(VF_MIN, vf_min);
2072
2073         // Assign Standard Viewflags
2074         // Draw the World (and sky)
2075         setproperty(VF_DRAWWORLD, 1);
2076
2077         // Set the console size vars
2078         vid_conwidth = autocvar_vid_conwidth;
2079         vid_conheight = autocvar_vid_conheight;
2080         vid_pixelheight = autocvar_vid_pixelheight;
2081
2082         if(autocvar_cl_orthoview) { setproperty(VF_FOV, GetOrthoviewFOV(ov_worldmin, ov_worldmax, ov_mid, ov_org)); }
2083         else if(csqcplayer.viewloc) { setproperty(VF_FOV, GetViewLocationFOV(110)); } // enforce 110 fov, so things dont look odd
2084         else { setproperty(VF_FOV, GetCurrentFov(fov)); }
2085
2086         if(camera_active) // Camera for demo playback
2087         {
2088                 if(autocvar_camera_enable)
2089                         CSQC_Demo_Camera();
2090                 else
2091                 {
2092                         cvar_set("chase_active", ftos(chase_active_backup));
2093                         cvar_set("cl_demo_mousegrab", "0");
2094                         camera_active = false;
2095                 }
2096         }
2097         else
2098         {
2099 #ifdef CAMERATEST
2100                 if(autocvar_camera_enable)
2101 #else
2102                 if(autocvar_camera_enable && isdemo())
2103 #endif
2104                 {
2105                         // Enable required Darkplaces cvars
2106                         chase_active_backup = autocvar_chase_active;
2107                         cvar_set("chase_active", "2");
2108                         cvar_set("cl_demo_mousegrab", "1");
2109                         camera_active = true;
2110                         camera_mode = false;
2111                 }
2112         }
2113
2114         // Draw the Crosshair
2115         setproperty(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
2116
2117         // Draw the Engine Status Bar (the default Quake HUD)
2118         setproperty(VF_DRAWENGINESBAR, 0);
2119
2120         // Update the mouse position
2121         /*
2122            mousepos_x = vid_conwidth;
2123            mousepos_y = vid_conheight;
2124            mousepos = mousepos*0.5 + getmousepos();
2125          */
2126
2127         IL_EACH(g_drawables, it.draw, it.draw(it));
2128
2129         addentities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS); // TODO: .health is used in cl_deathfade (a feature we have turned off currently)
2130         renderscene();
2131
2132         // now switch to 2D drawing mode by calling a 2D drawing function
2133         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
2134         // next R_RenderScene call
2135         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
2136
2137         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
2138         if (!(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT))
2139         {
2140                 // apply night vision effect
2141                 vector tc_00, tc_01, tc_10, tc_11;
2142                 vector rgb = '0 0 0';
2143
2144                 if(!nightvision_noise)
2145                 {
2146                         nightvision_noise = new(nightvision_noise);
2147                 }
2148                 if(!nightvision_noise2)
2149                 {
2150                         nightvision_noise2 = new(nightvision_noise2);
2151                 }
2152
2153                 // color tint in yellow
2154                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
2155
2156                 // draw BG
2157                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
2158                 rgb = '1 1 1';
2159                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
2160                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
2161                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
2162                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
2163                 tc_11 = tc_01 + tc_10 - tc_00;
2164                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
2165                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
2166                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
2167                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
2168                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
2169                 R_EndPolygon();
2170
2171                 // draw FG
2172                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
2173                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
2174                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
2175                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
2176                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
2177                 tc_11 = tc_01 + tc_10 - tc_00;
2178                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
2179                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
2180                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
2181                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
2182                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
2183                 R_EndPolygon();
2184         }
2185
2186         if(autocvar_cl_reticle)
2187         {
2188                 string reticle_image = string_null;
2189                 bool wep_zoomed = false;
2190                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2191                 {
2192                         entity wepe = viewmodels[slot];
2193                         Weapon wep = wepe.activeweapon;
2194                         if(wep != WEP_Null && wep.wr_zoom)
2195                         {
2196                                 bool do_zoom = wep.wr_zoom(wep, NULL);
2197                                 if(!reticle_image && wep.w_reticle && wep.w_reticle != "")
2198                                         reticle_image = wep.w_reticle;
2199                                 wep_zoomed += do_zoom;
2200                         }
2201                 }
2202                 // Draw the aiming reticle for weapons that use it
2203                 // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
2204                 // It must be a persisted float for fading out to work properly (you let go of the zoom button for
2205                 // the view to go back to normal, so reticle_type would become 0 as we fade out)
2206                 if(spectatee_status || is_dead || hud != HUD_NORMAL || local_player.viewloc)
2207                 {
2208                         // no zoom reticle while dead
2209                         reticle_type = 0;
2210                 }
2211                 else if(wep_zoomed && autocvar_cl_reticle_weapon)
2212                 {
2213                         if(reticle_image) { reticle_type = 2; }
2214                         else { reticle_type = 0; }
2215                 }
2216                 else if(button_zoom || zoomscript_caught)
2217                 {
2218                         // normal zoom
2219                         reticle_type = 1;
2220                 }
2221
2222                 if(reticle_type)
2223                 {
2224                         if(autocvar_cl_reticle_stretch)
2225                         {
2226                                 reticle_size.x = vid_conwidth;
2227                                 reticle_size.y = vid_conheight;
2228                                 reticle_pos.x = 0;
2229                                 reticle_pos.y = 0;
2230                         }
2231                         else
2232                         {
2233                                 reticle_size.x = max(vid_conwidth, vid_conheight);
2234                                 reticle_size.y = max(vid_conwidth, vid_conheight);
2235                                 reticle_pos.x = (vid_conwidth - reticle_size.x) / 2;
2236                                 reticle_pos.y = (vid_conheight - reticle_size.y) / 2;
2237                         }
2238
2239                         if(zoomscript_caught)
2240                                 f = 1;
2241                         else
2242                                 f = current_zoomfraction;
2243
2244                         if(f)
2245                         {
2246                                 switch(reticle_type)
2247                                 {
2248                                         case 1: drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_normal_alpha, DRAWFLAG_NORMAL); break;
2249                                         case 2: if(reticle_image) drawpic(reticle_pos, reticle_image, reticle_size, '1 1 1', f * autocvar_cl_reticle_weapon_alpha, DRAWFLAG_NORMAL); break;
2250                                 }
2251                         }
2252                 }
2253         }
2254         else
2255         {
2256                 if(reticle_type != 0) { reticle_type = 0; }
2257         }
2258
2259
2260         // improved polyblend
2261         if(autocvar_hud_contents && !MUTATOR_CALLHOOK(HUD_Contents))
2262         {
2263                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
2264                 vector liquidcolor;
2265
2266                 switch(pointcontents(view_origin))
2267                 {
2268                         case CONTENT_WATER:
2269                                 liquidalpha = autocvar_hud_contents_water_alpha;
2270                                 liquidcolor = stov(autocvar_hud_contents_water_color);
2271                                 incontent = 1;
2272                                 break;
2273
2274                         case CONTENT_LAVA:
2275                                 liquidalpha = autocvar_hud_contents_lava_alpha;
2276                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
2277                                 incontent = 1;
2278                                 break;
2279
2280                         case CONTENT_SLIME:
2281                                 liquidalpha = autocvar_hud_contents_slime_alpha;
2282                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
2283                                 incontent = 1;
2284                                 break;
2285
2286                         default:
2287                                 liquidalpha = 0;
2288                                 liquidcolor = '0 0 0';
2289                                 incontent = 0;
2290                                 break;
2291                 }
2292
2293                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
2294                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
2295                         contentfadetime = autocvar_hud_contents_fadeintime;
2296                         liquidalpha_prev = liquidalpha;
2297                         liquidcolor_prev = liquidcolor;
2298                 }
2299                 else
2300                         contentfadetime = autocvar_hud_contents_fadeouttime;
2301
2302                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
2303                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
2304
2305                 if(contentavgalpha)
2306                         drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
2307
2308                 if(autocvar_hud_postprocessing)
2309                 {
2310                         if(autocvar_hud_contents_blur && contentavgalpha)
2311                         {
2312                                 content_blurpostprocess.x = 1;
2313                                 content_blurpostprocess.y = contentavgalpha * autocvar_hud_contents_blur;
2314                                 content_blurpostprocess.z = contentavgalpha * autocvar_hud_contents_blur_alpha;
2315                         }
2316                         else
2317                         {
2318                                 content_blurpostprocess.x = 0;
2319                                 content_blurpostprocess.y = 0;
2320                                 content_blurpostprocess.z = 0;
2321                         }
2322                 }
2323         }
2324
2325         if(autocvar_hud_damage && !STAT(FROZEN))
2326         {
2327                 splash_size.x = max(vid_conwidth, vid_conheight);
2328                 splash_size.y = max(vid_conwidth, vid_conheight);
2329                 splash_pos.x = (vid_conwidth - splash_size.x) / 2;
2330                 splash_pos.y = (vid_conheight - splash_size.y) / 2;
2331
2332                 float myhealth_flash_temp;
2333                 myhealth = STAT(HEALTH);
2334
2335                 // fade out
2336                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
2337                 // add new damage
2338                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
2339
2340                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
2341                 pain_threshold = autocvar_hud_damage_pain_threshold;
2342                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
2343                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
2344
2345                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
2346                 {
2347                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
2348                 }
2349
2350                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
2351
2352                 if(myhealth_prev < 1)
2353                 {
2354                         if(myhealth >= 1)
2355                         {
2356                                 myhealth_flash = 0; // just spawned, clear the flash immediately
2357                                 myhealth_flash_temp = 0;
2358                         }
2359                         else
2360                         {
2361                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
2362                         }
2363                 }
2364
2365                 if(spectatee_status == -1 || intermission)
2366                 {
2367                         myhealth_flash = 0; // observing, or match ended
2368                         myhealth_flash_temp = 0;
2369                 }
2370
2371                 myhealth_prev = myhealth;
2372
2373                 // IDEA: change damage color/picture based on player model for robot/alien species?
2374                 // pro: matches model better
2375                 // contra: it's not red because blood is red, but because red is an alarming color, so red should stay
2376                 // maybe different reddish pics?
2377                 if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
2378                 {
2379                         if(autocvar_cl_gentle_damage == 2)
2380                         {
2381                                 if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
2382                                         myhealth_gentlergb = randomvec();
2383                         }
2384                         else
2385                                 myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
2386
2387                         if(myhealth_flash_temp > 0)
2388                                 drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
2389                 }
2390                 else if(myhealth_flash_temp > 0)
2391                         drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
2392
2393                 if(autocvar_hud_postprocessing) // we still need to set this anyway even when chase_active is set, this way it doesn't get stuck on.
2394                 {
2395                         if(autocvar_hud_damage_blur && myhealth_flash_temp)
2396                         {
2397                                 damage_blurpostprocess.x = 1;
2398                                 damage_blurpostprocess.y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
2399                                 damage_blurpostprocess.z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
2400                         }
2401                         else
2402                         {
2403                                 damage_blurpostprocess.x = 0;
2404                                 damage_blurpostprocess.y = 0;
2405                                 damage_blurpostprocess.z = 0;
2406                         }
2407                 }
2408         }
2409
2410         float e1 = (autocvar_hud_postprocessing_maxbluralpha != 0);
2411         float e2 = (autocvar_hud_powerup != 0);
2412         if(autocvar_hud_postprocessing && (e1 || e2)) // TODO: Remove this code and re-do the postprocess handling in the engine, where it properly belongs.
2413         {
2414                 // enable or disable rendering types if they are used or not
2415                 if(cvar("r_glsl_postprocess_uservec1_enable") != e1) { cvar_set("r_glsl_postprocess_uservec1_enable", ftos(e1)); }
2416                 if(cvar("r_glsl_postprocess_uservec2_enable") != e2) { cvar_set("r_glsl_postprocess_uservec2_enable", ftos(e2)); }
2417
2418                 // blur postprocess handling done first (used by hud_damage and hud_contents)
2419                 if((damage_blurpostprocess.x || content_blurpostprocess.x))
2420                 {
2421                         float blurradius = bound(0, damage_blurpostprocess.y + content_blurpostprocess.y, autocvar_hud_postprocessing_maxblurradius);
2422                         float bluralpha = bound(0, damage_blurpostprocess.z + content_blurpostprocess.z, autocvar_hud_postprocessing_maxbluralpha);
2423                         if(blurradius != old_blurradius || bluralpha != old_bluralpha) // reduce cvar_set spam as much as possible
2424                         {
2425                                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
2426                                 old_blurradius = blurradius;
2427                                 old_bluralpha = bluralpha;
2428                         }
2429                 }
2430                 else if(cvar_string("r_glsl_postprocess_uservec1") != "0 0 0 0") // reduce cvar_set spam as much as possible
2431                 {
2432                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
2433                         old_blurradius = 0;
2434                         old_bluralpha = 0;
2435                 }
2436
2437                 // edge detection postprocess handling done second (used by hud_powerup)
2438                 float sharpen_intensity = 0, strength_finished = STAT(STRENGTH_FINISHED), invincible_finished = STAT(INVINCIBLE_FINISHED);
2439                 if (strength_finished - time > 0) { sharpen_intensity += (strength_finished - time); }
2440                 if (invincible_finished - time > 0) { sharpen_intensity += (invincible_finished - time); }
2441
2442                 sharpen_intensity = bound(0, ((STAT(HEALTH) > 0) ? sharpen_intensity : 0), 5); // Check to see if player is alive (if not, set 0) - also bound to fade out starting at 5 seconds.
2443
2444                 if(autocvar_hud_powerup && sharpen_intensity > 0)
2445                 {
2446                         if(sharpen_intensity != old_sharpen_intensity) // reduce cvar_set spam as much as possible
2447                         {
2448                                 cvar_set("r_glsl_postprocess_uservec2", strcat(ftos((sharpen_intensity / 5) * autocvar_hud_powerup), " ", ftos(-sharpen_intensity * autocvar_hud_powerup), " 0 0"));
2449                                 old_sharpen_intensity = sharpen_intensity;
2450                         }
2451                 }
2452                 else if(cvar_string("r_glsl_postprocess_uservec2") != "0 0 0 0") // reduce cvar_set spam as much as possible
2453                 {
2454                         cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
2455                         old_sharpen_intensity = 0;
2456                 }
2457
2458                 if(cvar("r_glsl_postprocess") == 0)
2459                         cvar_set("r_glsl_postprocess", "2");
2460         }
2461         else if(cvar("r_glsl_postprocess") == 2)
2462                 cvar_set("r_glsl_postprocess", "0");
2463
2464         /*if(gametype == MAPINFO_TYPE_CTF)
2465           {
2466           ctf_view();
2467           } else */
2468
2469         // draw 2D entities
2470         IL_EACH(g_drawables_2d, it.draw2d, it.draw2d(it));
2471         Draw_ShowNames_All();
2472 #if ENABLE_DEBUGDRAW
2473         Debug_Draw();
2474 #endif
2475
2476         scoreboard_active = Scoreboard_WouldDraw();
2477
2478         HUD_Draw(this); // this parameter for deep vehicle function
2479
2480         if(NextFrameCommand)
2481         {
2482                 localcmd("\n", NextFrameCommand, "\n");
2483                 NextFrameCommand = string_null;
2484         }
2485
2486         // we must do this check AFTER a frame was rendered, or it won't work
2487         if(cs_project_is_b0rked == 0)
2488         {
2489                 string w0, h0;
2490                 w0 = ftos(autocvar_vid_conwidth);
2491                 h0 = ftos(autocvar_vid_conheight);
2492                 //setproperty(VF_VIEWPORT, '0 0 0', '640 480 0');
2493                 //setproperty(VF_FOV, '90 90 0');
2494                 setproperty(VF_ORIGIN, '0 0 0');
2495                 setproperty(VF_ANGLES, '0 0 0');
2496                 setproperty(VF_PERSPECTIVE, 1);
2497                 makevectors('0 0 0');
2498                 vector v1, v2;
2499                 cvar_set("vid_conwidth", "800");
2500                 cvar_set("vid_conheight", "600");
2501                 v1 = cs_project(v_forward);
2502                 cvar_set("vid_conwidth", "640");
2503                 cvar_set("vid_conheight", "480");
2504                 v2 = cs_project(v_forward);
2505                 if(v1 == v2)
2506                         cs_project_is_b0rked = 1;
2507                 else
2508                         cs_project_is_b0rked = -1;
2509                 cvar_set("vid_conwidth", w0);
2510                 cvar_set("vid_conheight", h0);
2511         }
2512
2513         HUD_Mouse(local_player);
2514
2515         cl_notice_run();
2516         unpause_update();
2517         Net_Flush();
2518
2519         // let's reset the view back to normal for the end
2520         setproperty(VF_MIN, '0 0 0');
2521         setproperty(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
2522
2523         IL_ENDFRAME();
2524 }
2525
2526
2527 // following vectors must be global to allow seamless switching between camera modes
2528 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
2529 void CSQC_Demo_Camera()
2530 {
2531         float speed, attenuation, dimensions;
2532         vector tmp, delta;
2533
2534         if( autocvar_camera_reset || !camera_mode )
2535         {
2536                 camera_offset = '0 0 0';
2537                 current_angles = '0 0 0';
2538                 camera_direction = '0 0 0';
2539                 camera_offset.z += 30;
2540                 camera_offset.x += 30 * -cos(current_angles.y * DEG2RAD);
2541                 camera_offset.y += 30 * -sin(current_angles.y * DEG2RAD);
2542                 current_origin = view_origin;
2543                 current_camera_offset  = camera_offset;
2544                 cvar_set("camera_reset", "0");
2545                 camera_mode = CAMERA_CHASE;
2546         }
2547
2548         // Camera angles
2549         if( camera_roll )
2550                 mouse_angles.z += camera_roll * autocvar_camera_speed_roll;
2551
2552         if(autocvar_camera_look_player)
2553         {
2554                 vector dir;
2555                 float n;
2556
2557                 dir = normalize(view_origin - current_position);
2558                 n = mouse_angles.z;
2559                 mouse_angles = vectoangles(dir);
2560                 mouse_angles.x = mouse_angles.x * -1;
2561                 mouse_angles.z = n;
2562         }
2563         else
2564         {
2565                 tmp = getmousepos() * 0.1;
2566                 if(vdist(tmp, >, autocvar_camera_mouse_threshold))
2567                 {
2568                         mouse_angles.x += tmp.y * cos(mouse_angles.z * DEG2RAD) + (tmp.x * sin(mouse_angles.z * DEG2RAD));
2569                         mouse_angles.y -= tmp.x * cos(mouse_angles.z * DEG2RAD) + (tmp.y * -sin(mouse_angles.z * DEG2RAD));
2570                 }
2571         }
2572
2573         while (mouse_angles.x < -180) mouse_angles.x = mouse_angles.x + 360;
2574         while (mouse_angles.x > 180) mouse_angles.x = mouse_angles.x - 360;
2575         while (mouse_angles.y < -180) mouse_angles.y = mouse_angles.y + 360;
2576         while (mouse_angles.y > 180) mouse_angles.y = mouse_angles.y - 360;
2577
2578         // Fix difference when angles don't have the same sign
2579         delta = '0 0 0';
2580         if(mouse_angles.y < -60 && current_angles.y > 60)
2581                 delta = '0 360 0';
2582         if(mouse_angles.y > 60 && current_angles.y < -60)
2583                 delta = '0 -360 0';
2584
2585         if(autocvar_camera_look_player)
2586                 attenuation = autocvar_camera_look_attenuation;
2587         else
2588                 attenuation = autocvar_camera_speed_attenuation;
2589
2590         attenuation = 1 / max(1, attenuation);
2591         current_angles += (mouse_angles - current_angles + delta) * attenuation;
2592
2593         while (current_angles.x < -180) current_angles.x = current_angles.x + 360;
2594         while (current_angles.x > 180) current_angles.x = current_angles.x - 360;
2595         while (current_angles.y < -180) current_angles.y = current_angles.y + 360;
2596         while (current_angles.y > 180) current_angles.y = current_angles.y - 360;
2597
2598         // Camera position
2599         tmp = '0 0 0';
2600         dimensions = 0;
2601
2602         if( camera_direction.x )
2603         {
2604                 tmp.x = camera_direction.x * cos(current_angles.y * DEG2RAD);
2605                 tmp.y = camera_direction.x * sin(current_angles.y * DEG2RAD);
2606                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
2607                         tmp.z = camera_direction.x * -sin(current_angles.x * DEG2RAD);
2608                 ++dimensions;
2609         }
2610
2611         if( camera_direction.y )
2612         {
2613                 tmp.x += camera_direction.y * -sin(current_angles.y * DEG2RAD);
2614                 tmp.y += camera_direction.y * cos(current_angles.y * DEG2RAD) * cos(current_angles.z * DEG2RAD);
2615                 tmp.z += camera_direction.y * sin(current_angles.z * DEG2RAD);
2616                 ++dimensions;
2617         }
2618
2619         if( camera_direction.z )
2620         {
2621                 tmp.z += camera_direction.z * cos(current_angles.z * DEG2RAD);
2622                 ++dimensions;
2623         }
2624
2625         if(autocvar_camera_free)
2626                 speed = autocvar_camera_speed_free;
2627         else
2628                 speed = autocvar_camera_speed_chase;
2629
2630         if(dimensions)
2631         {
2632                 speed = speed * sqrt(1 / dimensions);
2633                 camera_offset += tmp * speed;
2634         }
2635
2636         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
2637
2638         // Camera modes
2639         if( autocvar_camera_free )
2640         {
2641                 if ( camera_mode == CAMERA_CHASE )
2642                 {
2643                         current_camera_offset = current_origin + current_camera_offset;
2644                         camera_offset = current_origin + camera_offset;
2645                 }
2646
2647                 camera_mode = CAMERA_FREE;
2648                 current_position = current_camera_offset;
2649         }
2650         else
2651         {
2652                 if ( camera_mode == CAMERA_FREE )
2653                 {
2654                         current_origin = view_origin;
2655                         camera_offset = camera_offset - current_origin;
2656                         current_camera_offset = current_camera_offset - current_origin;
2657                 }
2658
2659                 camera_mode = CAMERA_CHASE;
2660
2661                 if(autocvar_camera_chase_smoothly)
2662                         current_origin += (view_origin - current_origin) * attenuation;
2663                 else
2664                         current_origin = view_origin;
2665
2666                 current_position = current_origin + current_camera_offset;
2667         }
2668
2669         setproperty(VF_ANGLES, current_angles);
2670         setproperty(VF_ORIGIN, current_position);
2671 }