qcsrc/client/view.qc

   1 #include "view.qh"
   2
   3 #include "autocvars.qh"
   4 #include "miscfunctions.qh"
   5 #include "announcer.qh"
   6 #include "hud/_mod.qh"
   7 #include "mapvoting.qh"
   8 #include "shownames.qh"
   9 #include "hud/panel/scoreboard.qh"
  10 #include "hud/panel/quickmenu.qh"
  11
  12 #include <client/mutators/_mod.qh>
  13
  14 #include <common/animdecide.qh>
  15 #include <common/deathtypes/all.qh>
  16 #include <common/ent_cs.qh>
  17 #include <common/anim.qh>
  18 #include <common/constants.qh>
  19 #include <common/net_linked.qh>
  20 #include <common/net_notice.qh>
  21 #include <common/debug.qh>
  22 #include <common/mapinfo.qh>
  23 #include <common/gamemodes/_mod.qh>
  24 #include <common/physics/player.qh>
  25 #include <common/stats.qh>
  26 #include <common/mapobjects/target/music.qh>
  27 #include <common/teams.qh>
  28 #include <common/wepent.qh>
  29
  30 #include <common/weapons/weapon/tuba.qh>
  31
  32 #include <common/vehicles/all.qh>
  33 #include <common/weapons/_all.qh>
  34 #include <common/mutators/mutator/overkill/oknex.qh>
  35 #include <common/mutators/mutator/waypoints/all.qh>
  36 #include <common/viewloc.qh>
  37 #include <common/mapobjects/trigger/viewloc.qh>
  38 #include <common/minigames/cl_minigames.qh>
  39 #include <common/minigames/cl_minigames_hud.qh>
  40
  41 #include <lib/csqcmodel/cl_player.qh>
  42 #include <lib/csqcmodel/cl_model.qh>
  43 #include "csqcmodel_hooks.qh"
  44
  45 #include <lib/warpzone/client.qh>
  46 #include <lib/warpzone/common.qh>
  47
  48 #define EFMASK_CHEAP (EF_ADDITIVE | EF_DOUBLESIDED | EF_FULLBRIGHT | EF_NODEPTHTEST | EF_NODRAW | EF_NOSHADOW | EF_SELECTABLE | EF_TELEPORT_BIT)
  49
  50 float autocvar_cl_viewmodel_scale;
  51 float autocvar_cl_viewmodel_alpha;
  52
  53 bool autocvar_cl_bobmodel;
  54 float autocvar_cl_bobmodel_speed;
  55 float autocvar_cl_bobmodel_side;
  56 float autocvar_cl_bobmodel_up;
  57
  58 float autocvar_cl_followmodel;
  59 float autocvar_cl_followmodel_speed = 0.3;
  60 float autocvar_cl_followmodel_limit = 135;
  61 float autocvar_cl_followmodel_velocity_lowpass = 0.05;
  62 float autocvar_cl_followmodel_highpass = 0.05;
  63 float autocvar_cl_followmodel_lowpass = 0.03;
  64 bool autocvar_cl_followmodel_velocity_absolute;
  65
  66 float autocvar_cl_leanmodel;
  67 float autocvar_cl_leanmodel_speed = 0.3;
  68 float autocvar_cl_leanmodel_limit = 30;
  69 float autocvar_cl_leanmodel_highpass1 = 0.2;
  70 float autocvar_cl_leanmodel_highpass = 0.2;
  71 float autocvar_cl_leanmodel_lowpass = 0.05;
  72
  73 #define avg_factor(avg_time) (1 - exp(-frametime / max(0.001, avg_time)))
  74
  75 #define lowpass(value, frac, ref_store, ret) \
  76         ret = ref_store = ref_store * (1 - frac) + (value) * frac;
  77
  78 #define lowpass_limited(value, frac, limit, ref_store, ret) MACRO_BEGIN \
  79         float __ignore; lowpass(value, frac, ref_store, __ignore); \
  80         ret = ref_store = bound((value) - (limit), ref_store, (value) + (limit)); \
  81 MACRO_END
  82
  83 #define highpass(value, frac, ref_store, ret) MACRO_BEGIN \
  84         float __f = 0; lowpass(value, frac, ref_store, __f); \
  85         ret = (value) - __f; \
  86 MACRO_END
  87
  88 #define highpass_limited(value, frac, limit, ref_store, ret) MACRO_BEGIN \
  89         float __f = 0; lowpass_limited(value, frac, limit, ref_store, __f); \
  90         ret = (value) - __f; \
  91 MACRO_END
  92
  93 #define lowpass2(value, frac, ref_store, ref_out) MACRO_BEGIN \
  94         lowpass(value.x, frac, ref_store.x, ref_out.x); \
  95         lowpass(value.y, frac, ref_store.y, ref_out.y); \
  96 MACRO_END
  97
  98 #define highpass2(value, frac, ref_store, ref_out) MACRO_BEGIN \
  99         highpass(value.x, frac, ref_store.x, ref_out.x); \
 100         highpass(value.y, frac, ref_store.y, ref_out.y); \
 101 MACRO_END
 102
 103 #define highpass2_limited(value, frac, limit, ref_store, ref_out) MACRO_BEGIN \
 104         highpass_limited(value.x, frac, limit, ref_store.x, ref_out.x); \
 105         highpass_limited(value.y, frac, limit, ref_store.y, ref_out.y); \
 106 MACRO_END
 107
 108 #define lowpass3(value, frac, ref_store, ref_out) MACRO_BEGIN \
 109         lowpass(value.x, frac, ref_store.x, ref_out.x); \
 110         lowpass(value.y, frac, ref_store.y, ref_out.y); \
 111         lowpass(value.z, frac, ref_store.z, ref_out.z); \
 112 MACRO_END
 113
 114 #define highpass3(value, frac, ref_store, ref_out) MACRO_BEGIN \
 115         highpass(value.x, frac, ref_store.x, ref_out.x); \
 116         highpass(value.y, frac, ref_store.y, ref_out.y); \
 117         highpass(value.z, frac, ref_store.z, ref_out.z); \
 118 MACRO_END
 119
 120 void calc_followmodel_ofs(entity view)
 121 {
 122         if(cl_followmodel_time == time)
 123                 return; // cl_followmodel_ofs already calculated for this frame
 124
 125         float frac;
 126         vector gunorg = '0 0 0';
 127         static vector vel_average;
 128         static vector gunorg_adjustment_highpass;
 129         static vector gunorg_adjustment_lowpass;
 130
 131         vector vel;
 132         if (autocvar_cl_followmodel_velocity_absolute)
 133                 vel = view.velocity;
 134         else
 135         {
 136                 vector forward, right, up;
 137                 MAKE_VECTORS(view_angles, forward, right, up);
 138                 vel.x = view.velocity * forward;
 139                 vel.y = view.velocity * right * -1;
 140                 vel.z = view.velocity * up;
 141         }
 142
 143         vel.x = bound(vel_average.x - autocvar_cl_followmodel_limit, vel.x, vel_average.x + autocvar_cl_followmodel_limit);
 144         vel.y = bound(vel_average.y - autocvar_cl_followmodel_limit, vel.y, vel_average.y + autocvar_cl_followmodel_limit);
 145         vel.z = bound(vel_average.z - autocvar_cl_followmodel_limit, vel.z, vel_average.z + autocvar_cl_followmodel_limit);
 146
 147         frac = avg_factor(autocvar_cl_followmodel_velocity_lowpass);
 148         lowpass3(vel, frac, vel_average, gunorg);
 149
 150         gunorg *= -autocvar_cl_followmodel_speed * 0.042;
 151
 152         // perform highpass/lowpass on the adjustment vectors (turning velocity into acceleration!)
 153         // trick: we must do the lowpass LAST, so the lowpass vector IS the final vector!
 154         frac = avg_factor(autocvar_cl_followmodel_highpass);
 155         highpass3(gunorg, frac, gunorg_adjustment_highpass, gunorg);
 156         frac = avg_factor(autocvar_cl_followmodel_lowpass);
 157         lowpass3(gunorg, frac, gunorg_adjustment_lowpass, gunorg);
 158
 159         if (autocvar_cl_followmodel_velocity_absolute)
 160         {
 161                 vector fixed_gunorg;
 162                 vector forward, right, up;
 163                 MAKE_VECTORS(view_angles, forward, right, up);
 164                 fixed_gunorg.x = gunorg * forward;
 165                 fixed_gunorg.y = gunorg * right * -1;
 166                 fixed_gunorg.z = gunorg * up;
 167                 gunorg = fixed_gunorg;
 168         }
 169
 170         cl_followmodel_ofs = gunorg;
 171         cl_followmodel_time = time;
 172 }
 173
 174 vector leanmodel_ofs(entity view)
 175 {
 176         float frac;
 177         vector gunangles = '0 0 0';
 178         static vector gunangles_prev = '0 0 0';
 179         static vector gunangles_highpass = '0 0 0';
 180         static vector gunangles_adjustment_highpass;
 181         static vector gunangles_adjustment_lowpass;
 182
 183         if (view.csqcmodel_teleported)
 184                 gunangles_prev = view_angles;
 185
 186         // in the highpass, we _store_ the DIFFERENCE to the actual view angles...
 187         gunangles_highpass += gunangles_prev;
 188         PITCH(gunangles_highpass) += 360 * floor((PITCH(view_angles) - PITCH(gunangles_highpass)) / 360 + 0.5);
 189         YAW(gunangles_highpass) += 360 * floor((YAW(view_angles) - YAW(gunangles_highpass)) / 360 + 0.5);
 190         ROLL(gunangles_highpass) += 360 * floor((ROLL(view_angles) - ROLL(gunangles_highpass)) / 360 + 0.5);
 191         frac = avg_factor(autocvar_cl_leanmodel_highpass1);
 192         highpass2_limited(view_angles, frac, autocvar_cl_leanmodel_limit, gunangles_highpass, gunangles);
 193         gunangles_prev = view_angles;
 194         gunangles_highpass -= gunangles_prev;
 195
 196         PITCH(gunangles) *= -autocvar_cl_leanmodel_speed;
 197         YAW(gunangles) *= -autocvar_cl_leanmodel_speed;
 198
 199         // we assume here: PITCH = 0, YAW = 1, ROLL = 2
 200         frac = avg_factor(autocvar_cl_leanmodel_highpass);
 201         highpass2(gunangles, frac, gunangles_adjustment_highpass, gunangles);
 202         frac = avg_factor(autocvar_cl_leanmodel_lowpass);
 203         lowpass2(gunangles, frac, gunangles_adjustment_lowpass, gunangles);
 204
 205         gunangles.x = -gunangles.x; // pitch was inverted, now that actually matters
 206
 207         return gunangles;
 208 }
 209
 210 vector bobmodel_ofs(entity view)
 211 {
 212         bool clonground = !(view.anim_implicit_state & ANIMIMPLICITSTATE_INAIR);
 213         static bool oldonground;
 214         static float hitgroundtime;
 215         if (clonground)
 216         {
 217                 float f = time; // cl.movecmd[0].time
 218                 if (!oldonground)
 219                         hitgroundtime = f;
 220         }
 221         oldonground = clonground;
 222
 223         // calculate for swinging gun model
 224         // the gun bobs when running on the ground, but doesn't bob when you're in the air.
 225         vector gunorg = '0 0 0';
 226         static float bobmodel_scale = 0;
 227         static float time_ofs = 0; // makes the effect always restart in the same way
 228         if (clonground)
 229         {
 230                 if (time - hitgroundtime > 0.05)
 231                         bobmodel_scale = min(1, bobmodel_scale + frametime * 5);
 232         }
 233         else
 234                 bobmodel_scale = max(0, bobmodel_scale - frametime * 5);
 235
 236         float xyspeed = bound(0, vlen(vec2(view.velocity)), 400);
 237         if (bobmodel_scale && xyspeed)
 238         {
 239                 float bspeed = xyspeed * 0.01 * autocvar_cl_viewmodel_scale * bobmodel_scale;
 240                 float s = (time - time_ofs) * autocvar_cl_bobmodel_speed;
 241                 gunorg.y = bspeed * autocvar_cl_bobmodel_side * sin(s);
 242                 gunorg.z = bspeed * autocvar_cl_bobmodel_up * cos(s * 2);
 243         }
 244         else
 245                 time_ofs = time;
 246
 247         return gunorg;
 248 }
 249
 250 void viewmodel_animate(entity this)
 251 {
 252         if (autocvar_chase_active) return;
 253         if (STAT(HEALTH) <= 0) return;
 254
 255         entity view = CSQCModel_server2csqc(player_localentnum - 1);
 256
 257         if (autocvar_cl_followmodel)
 258         {
 259                 calc_followmodel_ofs(view);
 260                 this.origin += cl_followmodel_ofs;
 261         }
 262
 263         if (autocvar_cl_leanmodel)
 264                 this.angles += leanmodel_ofs(view);
 265
 266         // vertical view bobbing code
 267         // TODO: cl_bob
 268
 269         // horizontal view bobbing code
 270         // TODO: cl_bob2
 271
 272         // fall bobbing code
 273         // causes the view to swing down and back up when touching the ground
 274         // TODO: cl_bobfall
 275
 276         // gun model bobbing code
 277         if (autocvar_cl_bobmodel)
 278                 this.origin += bobmodel_ofs(view);
 279 }
 280
 281 .vector viewmodel_origin, viewmodel_angles;
 282 .float weapon_nextthink;
 283 .float weapon_eta_last;
 284 .float weapon_switchdelay;
 285
 286 .string name_last;
 287
 288 void viewmodel_draw(entity this)
 289 {
 290         if(!this.activeweapon || !autocvar_r_drawviewmodel)
 291                 return;
 292         int mask = (intermission || (STAT(HEALTH) <= 0) || autocvar_chase_active) ? 0 : MASK_NORMAL;
 293         float a = ((autocvar_cl_viewmodel_alpha) ? bound(-1, autocvar_cl_viewmodel_alpha, this.m_alpha) : this.m_alpha);
 294         int wepskin = this.m_skin;
 295         bool invehicle = player_localentnum > maxclients;
 296         if (invehicle) a = -1;
 297         Weapon wep = this.activeweapon;
 298         int c = entcs_GetClientColors(current_player);
 299         vector g = weaponentity_glowmod(wep, NULL, c, this);
 300         entity me = CSQCModel_server2csqc(player_localentnum - 1);
 301         int fx = ((me.csqcmodel_effects & EFMASK_CHEAP)
 302                 | EF_NODEPTHTEST)
 303                 &~ (EF_FULLBRIGHT); // can mask team color, so get rid of it
 304         for (entity e = this; e; e = e.weaponchild)
 305         {
 306                 e.drawmask = mask;
 307                 e.alpha = a;
 308                 e.skin = wepskin;
 309                 e.colormap = 256 + c;  // colormap == 0 is black, c == 0 is white
 310                 e.glowmod = g;
 311                 e.csqcmodel_effects = fx;
 312                 CSQCModel_Effects_Apply(e);
 313         }
 314         if(a >= 0)
 315         {
 316                 string name = wep.mdl;
 317                 string newname = wep.wr_viewmodel(wep, this);
 318                 if(newname)
 319                         name = newname;
 320                 bool swap = name != this.name_last;
 321                 // if (swap)
 322                 {
 323                         this.name_last = name;
 324                         CL_WeaponEntity_SetModel(this, name, swap);
 325                         this.viewmodel_origin = this.origin;
 326                         this.viewmodel_angles = this.angles;
 327                 }
 328                 anim_update(this);
 329                 if ((!this.animstate_override && !this.animstate_looping) || time > this.animstate_endtime)
 330                         anim_set(this, this.anim_idle, true, false, false);
 331         }
 332         float f = 0; // 0..1; 0: fully active
 333         float rate = STAT(WEAPONRATEFACTOR);
 334         float eta = rate ? ((this.weapon_nextthink - time) / rate) : 0;
 335         if (eta <= 0) f = this.weapon_eta_last;
 336         else switch (this.state)
 337         {
 338                 case WS_RAISE:
 339                 {
 340                         f = eta / max(eta, this.weapon_switchdelay);
 341                         break;
 342                 }
 343                 case WS_DROP:
 344                 {
 345                         f = 1 - eta / max(eta, this.weapon_switchdelay);
 346                         break;
 347                 }
 348                 case WS_CLEAR:
 349                 {
 350                         f = 1;
 351                         break;
 352                 }
 353         }
 354         this.weapon_eta_last = f;
 355         this.origin = this.viewmodel_origin;
 356         this.angles = this.viewmodel_angles;
 357         this.angles_x = (-90 * f * f);
 358         viewmodel_animate(this);
 359         MUTATOR_CALLHOOK(DrawViewModel, this);
 360         setorigin(this, this.origin);
 361 }
 362
 363 STATIC_INIT(viewmodel) {
 364     for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 365         viewmodels[slot] = new(viewmodel);
 366 }
 367
 368 float showfps_prevfps;
 369 float showfps_prevfps_time;
 370 int showfps_framecounter;
 371
 372 void fpscounter_update()
 373 {
 374         if(!STAT(SHOWFPS))
 375                 return;
 376
 377         float currentTime = gettime(GETTIME_REALTIME);
 378         showfps_framecounter += 1;
 379         if(currentTime - showfps_prevfps_time > STAT(SHOWFPS))
 380         {
 381                 showfps_prevfps = showfps_framecounter/(currentTime - showfps_prevfps_time);
 382                 showfps_framecounter = 0;
 383                 showfps_prevfps_time = currentTime;
 384
 385                 int channel = MSG_C2S;
 386                 WriteHeader(channel, fpsreport);
 387                 WriteShort(channel, bound(0, rint(showfps_prevfps), 65535)); // prevent insane fps values
 388         }
 389 }
 390
 391 STATIC_INIT(fpscounter_init)
 392 {
 393         float currentTime = gettime(GETTIME_REALTIME);
 394         showfps_prevfps_time = currentTime; // we must initialize it to avoid an instant low frame sending
 395 }
 396
 397 float drawtime;
 398 float avgspeed;
 399 vector GetCurrentFov(float fov)
 400 {
 401         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir;
 402         float velocityzoom, curspeed;
 403         vector v;
 404
 405         zoomsensitivity = autocvar_cl_zoomsensitivity;
 406         zoomfactor = autocvar_cl_zoomfactor;
 407         if(zoomfactor < 1 || zoomfactor > 30)
 408                 zoomfactor = 2.5;
 409         zoomspeed = autocvar_cl_zoomspeed;
 410         if (zoomspeed >= 0 && (zoomspeed < 0.5 || zoomspeed > 16))
 411                 zoomspeed = 3.5;
 412
 413         zoomdir = button_zoom;
 414
 415         if(hud == HUD_NORMAL && !spectatee_status)
 416         {
 417                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 418                 {
 419                         entity wepent = viewmodels[slot];
 420                         if(wepent.switchweapon != wepent.activeweapon)
 421                                 continue;
 422                         Weapon wep = wepent.activeweapon;
 423                         if(wep != WEP_Null && wep.wr_zoomdir)
 424                         {
 425                                 bool do_zoom = wep.wr_zoomdir(wep); // TODO: merge this with wr_zoom?
 426                                 zoomdir += do_zoom;
 427                         }
 428                 }
 429         }
 430         if(spectatee_status > 0 || isdemo())
 431         {
 432                 if(spectatorbutton_zoom)
 433                 {
 434                         if(zoomdir)
 435                                 zoomdir = 0;
 436                         else
 437                                 zoomdir = 1;
 438                 }
 439                 // fteqcc failed twice here already, don't optimize this
 440         }
 441
 442         if(zoomdir) { zoomin_effect = 0; }
 443
 444         if (spectatee_status > 0 && STAT(CAMERA_SPECTATOR) == 2)
 445         {
 446                 current_viewzoom = 1;
 447         }
 448         else if (camera_active)
 449         {
 450                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 451         }
 452         else if(autocvar_cl_spawnzoom && zoomin_effect)
 453         {
 454                 float spawnzoomfactor = bound(1, autocvar_cl_spawnzoom_factor, 30);
 455
 456                 current_viewzoom += (autocvar_cl_spawnzoom_speed * (spawnzoomfactor - current_viewzoom) * drawframetime);
 457                 current_viewzoom = bound(1 / spawnzoomfactor, current_viewzoom, 1);
 458                 if(current_viewzoom == 1) { zoomin_effect = 0; }
 459         }
 460         else
 461         {
 462                 if(zoomspeed < 0) // instant zoom
 463                 {
 464                         if(zoomdir)
 465                                 current_viewzoom = 1 / zoomfactor;
 466                         else
 467                                 current_viewzoom = 1;
 468                 }
 469                 else
 470                 {
 471                         if(zoomdir)
 472                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 473                         else
 474                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 475                 }
 476         }
 477
 478         if(almost_equals(current_viewzoom, 1))
 479                 current_zoomfraction = 0;
 480         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 481                 current_zoomfraction = 1;
 482         else
 483                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 484
 485         if(zoomsensitivity < 1)
 486                 setsensitivityscale(current_viewzoom ** (1 - zoomsensitivity));
 487         else
 488                 setsensitivityscale(1);
 489
 490         if(autocvar_cl_velocityzoom_enabled && autocvar_cl_velocityzoom_type) // _type = 0 disables velocity zoom too
 491         {
 492                 if (intermission || (spectatee_status > 0 && STAT(CAMERA_SPECTATOR) == 2))
 493                         curspeed = 0;
 494                 else
 495                 {
 496                         vector forward, right, up;
 497                         MAKE_VECTORS(view_angles, forward, right, up);
 498                         v = pmove_vel;
 499                         if(csqcplayer)
 500                                 v = csqcplayer.velocity;
 501
 502                         switch(autocvar_cl_velocityzoom_type)
 503                         {
 504                                 case 3: curspeed = max(0, forward * v); break;
 505                                 case 2: curspeed = (forward * v); break;
 506                                 case 1: default: curspeed = vlen(v); break;
 507                         }
 508                 }
 509
 510                 velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoom_time), 1); // speed at which the zoom adapts to player velocity
 511                 avgspeed = avgspeed * (1 - velocityzoom) + (curspeed / autocvar_cl_velocityzoom_speed) * velocityzoom;
 512                 velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom_factor / 1) * 1);
 513
 514                 //print(ftos(avgspeed), " avgspeed, ", ftos(curspeed), " curspeed, ", ftos(velocityzoom), " return\n"); // for debugging
 515         }
 516         else
 517                 velocityzoom = 1;
 518
 519         float frustumx, frustumy, fovx, fovy;
 520         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 521         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 522         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 523         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 524
 525         return '1 0 0' * fovx + '0 1 0' * fovy;
 526 }
 527
 528 vector GetViewLocationFOV(float fov)
 529 {
 530         float frustumy = tan(fov * M_PI / 360.0) * 0.75;
 531         float frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 532         float fovx = atan2(frustumx, 1) / M_PI * 360.0;
 533         float fovy = atan2(frustumy, 1) / M_PI * 360.0;
 534         return '1 0 0' * fovx + '0 1 0' * fovy;
 535 }
 536
 537 vector GetOrthoviewFOV(vector ov_worldmin, vector ov_worldmax, vector ov_mid, vector ov_org)
 538 {
 539         float fovx, fovy;
 540         float width = (ov_worldmax.x - ov_worldmin.x);
 541         float height = (ov_worldmax.y - ov_worldmin.y);
 542         float distance_to_middle_of_world = vlen(ov_mid - ov_org);
 543         fovx = atan2(width/2, distance_to_middle_of_world) / M_PI * 360.0;
 544         fovy = atan2(height/2, distance_to_middle_of_world) / M_PI * 360.0;
 545         return '1 0 0' * fovx + '0 1 0' * fovy;
 546 }
 547
 548 // this function must match W_SetupShot!
 549 float zoomscript_caught;
 550
 551 bool minigame_wasactive;
 552
 553 vector wcross_origin;
 554 float wcross_scale_prev, wcross_alpha_prev;
 555 vector wcross_color_prev;
 556 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 557 vector wcross_color_goal_prev;
 558 float wcross_changedonetime;
 559
 560 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 561 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 562 float wcross_name_changestarttime, wcross_name_changedonetime;
 563 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 564
 565 float wcross_ring_prev;
 566
 567 entity trueaim;
 568 entity trueaim_rifle;
 569
 570 const float SHOTTYPE_HITTEAM = 1;
 571 const float SHOTTYPE_HITOBSTRUCTION = 2;
 572 const float SHOTTYPE_HITWORLD = 3;
 573 const float SHOTTYPE_HITENEMY = 4;
 574
 575 void TrueAim_Init()
 576 {
 577         (trueaim = new_pure(trueaim)).dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 578         (trueaim_rifle = new_pure(trueaim_rifle)).dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 579 }
 580
 581 float EnemyHitCheck()
 582 {
 583         float t, n;
 584         wcross_origin = project_3d_to_2d(trace_endpos);
 585         wcross_origin.z = 0;
 586         if(trace_ent)
 587                 n = trace_ent.entnum;
 588         else
 589                 n = trace_networkentity;
 590         if(n < 1)
 591                 return SHOTTYPE_HITWORLD;
 592         if(n > maxclients)
 593                 return SHOTTYPE_HITWORLD;
 594         t = entcs_GetTeam(n - 1);
 595         if(teamplay)
 596                 if(t == myteam)
 597                         return SHOTTYPE_HITTEAM;
 598         if(t == NUM_SPECTATOR)
 599                 return SHOTTYPE_HITWORLD;
 600         return SHOTTYPE_HITENEMY;
 601 }
 602
 603 float TrueAimCheck(entity wepent)
 604 {
 605         if(wepent.activeweapon.spawnflags & WEP_FLAG_NOTRUEAIM)
 606                 return SHOTTYPE_HITWORLD;
 607
 608         float nudge = 1; // added to traceline target and subtracted from result TOOD(divVerent): do we still need this? Doesn't the engine do this now for us?
 609         vector vecs, trueaimpoint, w_shotorg;
 610         vector mi, ma, dv;
 611         float shottype;
 612         entity ta;
 613         float mv;
 614
 615         mi = ma = '0 0 0';
 616         ta = trueaim;
 617         mv = MOVE_NOMONSTERS;
 618
 619         switch(wepent.activeweapon) // WEAPONTODO
 620         {
 621                 case WEP_VORTEX:
 622                 case WEP_OVERKILL_NEX:
 623                 case WEP_VAPORIZER:
 624                         mv = MOVE_NORMAL;
 625                         break;
 626                 case WEP_RIFLE:
 627                         ta = trueaim_rifle;
 628                         mv = MOVE_NORMAL;
 629                         if(zoomscript_caught)
 630                         {
 631                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * max_shot_distance, mv, ta);
 632                                 return EnemyHitCheck();
 633                         }
 634                         break;
 635                 case WEP_DEVASTATOR: // projectile has a size!
 636                         mi = '-3 -3 -3';
 637                         ma = '3 3 3';
 638                         break;
 639                 case WEP_FIREBALL: // projectile has a size!
 640                         mi = '-16 -16 -16';
 641                         ma = '16 16 16';
 642                         break;
 643                 case WEP_SEEKER: // projectile has a size!
 644                         mi = '-2 -2 -2';
 645                         ma = '2 2 2';
 646                         break;
 647                 case WEP_ELECTRO: // projectile has a size!
 648                         mi = '0 0 -3';
 649                         ma = '0 0 -3';
 650                         break;
 651         }
 652
 653         vector traceorigin = entcs_receiver(player_localentnum - 1).origin + (eZ * STAT(VIEWHEIGHT));
 654
 655         vecs = decompressShotOrigin(STAT(SHOTORG));
 656
 657         traceline(traceorigin, traceorigin + view_forward * max_shot_distance, mv, ta);
 658         trueaimpoint = trace_endpos;
 659         // move trueaimpoint a little bit forward to make the final tracebox reliable
 660         // since it sometimes doesn't reach a teammate by a hair
 661         trueaimpoint += view_forward;
 662
 663         if(vdist((trueaimpoint - traceorigin), <, g_trueaim_minrange))
 664                 trueaimpoint = traceorigin + view_forward * g_trueaim_minrange;
 665
 666         if(vecs.x > 0)
 667                 vecs.y = -vecs.y;
 668         else
 669                 vecs = '0 0 0';
 670
 671         dv = view_right * vecs.y + view_up * vecs.z;
 672         w_shotorg = traceorigin + dv;
 673
 674         // now move the vecs forward as much as requested if possible
 675         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs.x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 676         w_shotorg = trace_endpos - view_forward * nudge;
 677
 678         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 679         shottype = EnemyHitCheck();
 680         if(shottype != SHOTTYPE_HITWORLD)
 681                 return shottype;
 682
 683 #if 0
 684         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 685         // or rather, I know why, but see no fix
 686         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 687                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 688                 return SHOTTYPE_HITOBSTRUCTION;
 689 #endif
 690
 691         return SHOTTYPE_HITWORLD;
 692 }
 693
 694 float camera_mode;
 695 const float CAMERA_FREE = 1;
 696 const float CAMERA_CHASE = 2;
 697 float reticle_type;
 698 string NextFrameCommand;
 699
 700 vector freeze_org, freeze_ang;
 701 entity nightvision_noise, nightvision_noise2;
 702
 703 const float MAX_TIME_DIFF = 5;
 704 float pickup_crosshair_time, pickup_crosshair_size;
 705 float hitindication_crosshair_size;
 706 float use_vortex_chargepool;
 707
 708 float myhealth, myhealth_prev;
 709 float myhealth_flash;
 710
 711 float old_blurradius, old_bluralpha;
 712 float old_sharpen_intensity;
 713
 714 vector myhealth_gentlergb;
 715
 716 float contentavgalpha, liquidalpha_prev;
 717 vector liquidcolor_prev;
 718
 719 float eventchase_current_distance;
 720 float eventchase_running;
 721 int WantEventchase(entity this, bool want_vehiclechase)
 722 {
 723         if(autocvar_cl_orthoview)
 724                 return 0;
 725         if(STAT(GAME_STOPPED) || intermission)
 726                 return 1;
 727         if(this.viewloc)
 728                 return 1;
 729         if(spectatee_status >= 0)
 730         {
 731                 if(want_vehiclechase)
 732                         return 1;
 733                 if(MUTATOR_CALLHOOK(WantEventchase, this))
 734                         return 1;
 735                 if(autocvar_cl_eventchase_frozen && STAT(FROZEN))
 736                         return 1;
 737                 if(autocvar_cl_eventchase_death && (STAT(HEALTH) <= 0))
 738                 {
 739                         if(autocvar_cl_eventchase_death == 2)
 740                         {
 741                                 // don't stop eventchase once it's started (even if velocity changes afterwards)
 742                                 if(this.velocity == '0 0 0' || eventchase_running)
 743                                         return 1;
 744                         }
 745                         else return 1;
 746                 }
 747                 if (spectatee_status > 0 && autocvar_cl_eventchase_spectated_change)
 748                 {
 749                         if (time <= spectatee_status_changed_time + min(3, autocvar_cl_eventchase_spectated_change_time))
 750                                 return 1;
 751                         else if (eventchase_running)
 752                                 return -1; // disable chase_active while eventchase is still enabled so to avoid a glicth
 753                 }
 754         }
 755         return 0;
 756 }
 757
 758 void View_EventChase(entity this)
 759 {
 760         // event chase camera
 761         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
 762         {
 763                 if(STAT(CAMERA_SPECTATOR))
 764                 {
 765                         if(spectatee_status > 0)
 766                         {
 767                                 if(!autocvar_chase_active)
 768                                 {
 769                                         cvar_set("chase_active", "-2");
 770                                         return;
 771                                 }
 772                         }
 773                         else if(autocvar_chase_active == -2)
 774                                 cvar_set("chase_active", "0");
 775
 776                         if(autocvar_chase_active == -2)
 777                                 return;
 778                 }
 779                 else if(autocvar_chase_active == -2)
 780                         cvar_set("chase_active", "0");
 781
 782                 bool vehicle_chase = (hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0));
 783
 784                 float vehicle_viewdist = 0;
 785                 vector vehicle_viewofs = '0 0 0';
 786
 787                 if(vehicle_chase)
 788                 {
 789                         if(hud != HUD_BUMBLEBEE_GUN)
 790                         {
 791                                 Vehicle info = Vehicles_from(hud);
 792                                 vehicle_viewdist = info.height;
 793                                 vehicle_viewofs = info.view_ofs;
 794                                 if(vehicle_viewdist < 0) // when set below 0, this vehicle doesn't use third person view (gunner slots)
 795                                         vehicle_chase = false;
 796                         }
 797                         else
 798                                 vehicle_chase = false;
 799                 }
 800
 801                 int eventchase = WantEventchase(this, vehicle_chase);
 802                 if (eventchase)
 803                 {
 804                         vector current_view_origin_override = '0 0 0';
 805                         vector view_offset_override = '0 0 0';
 806                         float chase_distance_override = 0;
 807                         bool custom_eventchase = MUTATOR_CALLHOOK(CustomizeEventchase, this);
 808                         if(custom_eventchase)
 809                         {
 810                                 current_view_origin_override = M_ARGV(0, vector);
 811                                 view_offset_override = M_ARGV(1, vector);
 812                                 chase_distance_override = M_ARGV(0, float);
 813                         }
 814                         eventchase_running = true;
 815
 816                         // make special vector since we can't use view_origin (It is one frame old as of this code, it gets set later with the results this code makes.)
 817                         vector current_view_origin = (csqcplayer ? csqcplayer.origin : pmove_org);
 818                         if (custom_eventchase)
 819                                 current_view_origin = current_view_origin_override;
 820
 821                         // detect maximum viewoffset and use it
 822                         vector view_offset = autocvar_cl_eventchase_viewoffset;
 823                         if(vehicle_chase)
 824                         {
 825                                 if(vehicle_viewofs)
 826                                         view_offset = vehicle_viewofs;
 827                                 else
 828                                         view_offset = autocvar_cl_eventchase_vehicle_viewoffset;
 829                         }
 830                         if (custom_eventchase)
 831                                 view_offset = view_offset_override;
 832
 833                         if(view_offset)
 834                         {
 835                                 WarpZone_TraceLine(current_view_origin, current_view_origin + view_offset + ('0 0 1' * autocvar_cl_eventchase_maxs.z), MOVE_WORLDONLY, this);
 836                                 if(trace_fraction == 1) { current_view_origin += view_offset; }
 837                                 else { current_view_origin.z += max(0, (trace_endpos.z - current_view_origin.z) - autocvar_cl_eventchase_maxs.z); }
 838                         }
 839
 840                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
 841                         // Ideally, there should be another way to enable third person cameras, such as through setproperty()
 842                         // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
 843                         if(!autocvar_chase_active) { cvar_set("chase_active", "-1"); }
 844
 845                         // make the camera smooth back
 846                         float chase_distance = autocvar_cl_eventchase_distance;
 847                         if(vehicle_chase)
 848                         {
 849                                 if(vehicle_viewofs)
 850                                         chase_distance = vehicle_viewdist;
 851                                 else
 852                                         chase_distance = autocvar_cl_eventchase_vehicle_distance;
 853                         }
 854                         if (custom_eventchase)
 855                                 chase_distance = chase_distance_override;
 856
 857                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < chase_distance)
 858                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (chase_distance - eventchase_current_distance) * frametime; // slow down the further we get
 859                         else if(eventchase_current_distance != chase_distance)
 860                                 eventchase_current_distance = chase_distance;
 861
 862                         vector forward, right, up;
 863                         MAKE_VECTORS(view_angles, forward, right, up);
 864
 865                         vector eventchase_target_origin = (current_view_origin - (forward * eventchase_current_distance));
 866                         WarpZone_TraceBox(current_view_origin, autocvar_cl_eventchase_mins, autocvar_cl_eventchase_maxs, eventchase_target_origin, MOVE_WORLDONLY, this);
 867
 868                         // If the boxtrace fails, revert back to line tracing.
 869                         if(!this.viewloc)
 870                         if(trace_startsolid)
 871                         {
 872                                 eventchase_target_origin = (current_view_origin - (forward * eventchase_current_distance));
 873                                 WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, this);
 874                                 setproperty(VF_ORIGIN, (trace_endpos - (forward * autocvar_cl_eventchase_mins.z)));
 875                         }
 876                         else { setproperty(VF_ORIGIN, trace_endpos); }
 877
 878                         if(!this.viewloc)
 879                                 setproperty(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
 880                 }
 881
 882                 if (eventchase <= 0 && autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
 883                 {
 884                         eventchase_running = false;
 885                         cvar_set("chase_active", "0");
 886                         eventchase_current_distance = 0; // start from 0 next time
 887                 }
 888         }
 889         // workaround for camera stuck between player's legs when using chase_active 1
 890         // because the engine stops updating the chase_active camera when the game ends
 891         else if(intermission)
 892         {
 893                 cvar_settemp("chase_active", "-1");
 894                 eventchase_current_distance = 0;
 895         }
 896 }
 897
 898 void HUD_Crosshair_Vehicle(entity this)
 899 {
 900         if(hud != HUD_BUMBLEBEE_GUN)
 901         {
 902                 Vehicle info = Vehicles_from(hud);
 903                 info.vr_crosshair(info, this);
 904         }
 905 }
 906
 907 vector damage_blurpostprocess, content_blurpostprocess;
 908
 909 float unaccounted_damage = 0;
 910 void UpdateDamage()
 911 {
 912         // accumulate damage with each stat update
 913         static float damage_total_prev = 0;
 914         float damage_total = STAT(DAMAGE_DEALT_TOTAL);
 915         float unaccounted_damage_new = COMPARE_INCREASING(damage_total, damage_total_prev);
 916         damage_total_prev = damage_total;
 917
 918         static float damage_dealt_time_prev = 0;
 919         float damage_dealt_time = STAT(HIT_TIME);
 920         if (damage_dealt_time != damage_dealt_time_prev)
 921         {
 922                 unaccounted_damage += unaccounted_damage_new;
 923                 //LOG_TRACE("dmg total: ", ftos(unaccounted_damage), " (+", ftos(unaccounted_damage_new), ")");
 924         }
 925         damage_dealt_time_prev = damage_dealt_time;
 926
 927         // prevent hitsound when switching spectatee
 928         static float spectatee_status_prev = 0;
 929         if (spectatee_status != spectatee_status_prev)
 930                 unaccounted_damage = 0;
 931         spectatee_status_prev = spectatee_status;
 932 }
 933
 934 void HitSound()
 935 {
 936         // varying sound pitch
 937
 938         bool have_arc = false;
 939         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 940         {
 941                 entity wepent = viewmodels[slot];
 942
 943                 if(wepent.activeweapon == WEP_ARC)
 944                         have_arc = true;
 945         }
 946
 947         static float hitsound_time_prev = 0;
 948         // HACK: the only way to get the arc to sound consistent with pitch shift is to ignore cl_hitsound_antispam_time
 949         bool arc_hack = have_arc && autocvar_cl_hitsound >= 2;
 950         if (arc_hack || COMPARE_INCREASING(time, hitsound_time_prev) > autocvar_cl_hitsound_antispam_time)
 951         {
 952                 if (autocvar_cl_hitsound && unaccounted_damage)
 953                 {
 954                         // customizable gradient function that crosses (0,a), (c,1) and asymptotically approaches b
 955                         float a = autocvar_cl_hitsound_max_pitch;
 956                         float b = autocvar_cl_hitsound_min_pitch;
 957                         float c = autocvar_cl_hitsound_nom_damage;
 958                         float d = unaccounted_damage;
 959                         float pitch_shift = (b*d*(a-1) + a*c*(1-b)) / (d*(a-1) + c*(1-b));
 960
 961                         // if sound variation is disabled, set pitch_shift to 1
 962                         if (autocvar_cl_hitsound == 1)
 963                                 pitch_shift = 1;
 964
 965                         // if pitch shift is reversed, mirror in (max-min)/2 + min
 966                         if (autocvar_cl_hitsound == 3)
 967                         {
 968                                 float mirror_value = (a-b)/2 + b;
 969                                 pitch_shift = mirror_value + (mirror_value - pitch_shift);
 970                         }
 971
 972                         //LOG_TRACE("dmg total (dmg): ", ftos(unaccounted_damage), " , pitch shift: ", ftos(pitch_shift));
 973
 974                         // todo: avoid very long and very short sounds from wave stretching using different sound files? seems unnecessary
 975                         // todo: normalize sound pressure levels? seems unnecessary
 976
 977                         sound7(NULL, CH_INFO, SND(HIT), VOL_BASE, ATTN_NONE, pitch_shift * 100, 0);
 978                 }
 979                 unaccounted_damage = 0;
 980                 hitsound_time_prev = time;
 981         }
 982
 983         static float typehit_time_prev = 0;
 984         float typehit_time = STAT(TYPEHIT_TIME);
 985         if (COMPARE_INCREASING(typehit_time, typehit_time_prev) > autocvar_cl_hitsound_antispam_time)
 986         {
 987                 sound(NULL, CH_INFO, SND_TYPEHIT, VOL_BASE, ATTN_NONE);
 988                 typehit_time_prev = typehit_time;
 989         }
 990
 991         static float kill_time_prev = 0;
 992         float kill_time = STAT(KILL_TIME);
 993         if (COMPARE_INCREASING(kill_time, kill_time_prev) > autocvar_cl_hitsound_antispam_time)
 994         {
 995                 sound(NULL, CH_INFO, SND_KILL, VOL_BASE, ATTN_NONE);
 996                 kill_time_prev = kill_time;
 997         }
 998 }
 999
1000 vector crosshair_getcolor(entity this, float health_stat)
1001 {
1002         static float rainbow_last_flicker;
1003         static vector rainbow_prev_color;
1004         vector wcross_color = '0 0 0';
1005         switch(autocvar_crosshair_color_special)
1006         {
1007                 case 1: // crosshair_color_per_weapon
1008                 {
1009                         if(this != WEP_Null && hud == HUD_NORMAL)
1010                         {
1011                                 wcross_color = this.wpcolor;
1012                                 break;
1013                         }
1014                         else { goto normalcolor; }
1015                 }
1016
1017                 case 2: // crosshair_color_by_health
1018                 {
1019                         vector v = healtharmor_maxdamage(health_stat, STAT(ARMOR), armorblockpercent, DEATH_WEAPON.m_id);
1020                         float hp = floor(v.x + 1);
1021
1022                         //x = red
1023                         //y = green
1024                         //z = blue
1025
1026                         wcross_color.z = 0;
1027
1028                         if(hp > 200)
1029                         {
1030                                 wcross_color.x = 0;
1031                                 wcross_color.y = 1;
1032                         }
1033                         else if(hp > 150)
1034                         {
1035                                 wcross_color.x = 0.4 - (hp-150)*0.02 * 0.4;
1036                                 wcross_color.y = 0.9 + (hp-150)*0.02 * 0.1;
1037                         }
1038                         else if(hp > 100)
1039                         {
1040                                 wcross_color.x = 1 - (hp-100)*0.02 * 0.6;
1041                                 wcross_color.y = 1 - (hp-100)*0.02 * 0.1;
1042                                 wcross_color.z = 1 - (hp-100)*0.02;
1043                         }
1044                         else if(hp > 50)
1045                         {
1046                                 wcross_color.x = 1;
1047                                 wcross_color.y = 1;
1048                                 wcross_color.z = 0.2 + (hp-50)*0.02 * 0.8;
1049                         }
1050                         else if(hp > 20)
1051                         {
1052                                 wcross_color.x = 1;
1053                                 wcross_color.y = (hp-20)*90/27/100;
1054                                 wcross_color.z = (hp-20)*90/27/100 * 0.2;
1055                         }
1056                         else
1057                         {
1058                                 wcross_color.x = 1;
1059                                 wcross_color.y = 0;
1060                         }
1061                         break;
1062                 }
1063
1064                 case 3: // crosshair_color_rainbow
1065                 {
1066                         if(time >= rainbow_last_flicker)
1067                         {
1068                                 rainbow_prev_color = randomvec() * autocvar_crosshair_color_special_rainbow_brightness;
1069                                 rainbow_last_flicker = time + autocvar_crosshair_color_special_rainbow_delay;
1070                         }
1071                         wcross_color = rainbow_prev_color;
1072                         break;
1073                 }
1074 LABEL(normalcolor)
1075                 default: { wcross_color = stov(autocvar_crosshair_color); break; }
1076         }
1077
1078         return wcross_color;
1079 }
1080
1081 void HUD_Crosshair(entity this)
1082 {
1083         float f, i, j;
1084         vector v;
1085         if(!scoreboard_active && !camera_active && intermission != 2 && !STAT(GAME_STOPPED) &&
1086                 spectatee_status != -1 && (!csqcplayer.viewloc || (!spectatee_status && (csqcplayer.viewloc.spawnflags & VIEWLOC_FREEAIM))) && !MUTATOR_CALLHOOK(DrawCrosshair) &&
1087                 !HUD_MinigameMenu_IsOpened() )
1088         {
1089                 if (!autocvar_crosshair_enabled) // main toggle for crosshair rendering
1090                         return;
1091
1092                 if (spectatee_status > 0 && STAT(CAMERA_SPECTATOR) == 2)
1093                         return;
1094
1095                 if (hud != HUD_NORMAL)
1096                 {
1097                         HUD_Crosshair_Vehicle(this);
1098                         return;
1099                 }
1100
1101                 string wcross_style;
1102                 float wcross_alpha, wcross_resolution;
1103                 wcross_style = autocvar_crosshair;
1104                 if (csqcplayer.viewloc && (csqcplayer.viewloc.spawnflags & VIEWLOC_FREEAIM) && autocvar_crosshair_2d != "")
1105                         wcross_style = autocvar_crosshair_2d;
1106                 if (wcross_style == "0")
1107                         return;
1108                 wcross_resolution = autocvar_crosshair_size;
1109                 if (wcross_resolution == 0)
1110                         return;
1111                 wcross_alpha = autocvar_crosshair_alpha;
1112                 if (wcross_alpha == 0)
1113                         return;
1114
1115                 // TrueAim check
1116                 float shottype;
1117
1118                 // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
1119                 if(csqcplayer.viewloc && (csqcplayer.viewloc.spawnflags & VIEWLOC_FREEAIM))
1120                         wcross_origin = viewloc_mousepos;
1121                 else if(autocvar_chase_active > 0 && autocvar_crosshair_chase)
1122                 {
1123                         vector player_org = ((csqcplayer) ? csqcplayer.origin + csqcplayer.view_ofs : view_origin);
1124                         if(csqcplayer && crosshair_chase_playeralpha && crosshair_chase_playeralpha < 1)
1125                         {
1126                                 traceline(view_origin, view_origin + max_shot_distance * view_forward, MOVE_NORMAL, NULL);
1127                                 float myalpha = (!csqcplayer.m_alpha) ? 1 : csqcplayer.m_alpha;
1128                                 if(trace_ent == csqcplayer && STAT(HEALTH) > 0)
1129                                         csqcplayer.alpha = min(crosshair_chase_playeralpha, myalpha);
1130                                 else
1131                                         csqcplayer.alpha = csqcplayer.m_alpha;
1132                         }
1133                         traceline(player_org, player_org + max_shot_distance * view_forward, MOVE_WORLDONLY, NULL);
1134                         wcross_origin = project_3d_to_2d(trace_endpos);
1135                 }
1136                 else
1137                         wcross_origin = project_3d_to_2d(view_origin + max_shot_distance * view_forward);
1138                 wcross_origin.z = 0;
1139                 if(autocvar_crosshair_hittest)
1140                 {
1141                         vector wcross_oldorigin;
1142                         entity thiswep = viewmodels[0]; // TODO: unhardcode
1143                         wcross_oldorigin = wcross_origin;
1144                         shottype = TrueAimCheck(thiswep);
1145                         if(shottype == SHOTTYPE_HITWORLD)
1146                         {
1147                                 v = wcross_origin - wcross_oldorigin;
1148                                 v.x /= vid_conwidth;
1149                                 v.y /= vid_conheight;
1150                                 if(vdist(v, >, 0.01))
1151                                         shottype = SHOTTYPE_HITOBSTRUCTION;
1152                         }
1153                         if(!autocvar_crosshair_hittest_showimpact)
1154                                 wcross_origin = wcross_oldorigin;
1155                 }
1156                 else
1157                         shottype = SHOTTYPE_HITWORLD;
1158
1159                 vector wcross_color = '0 0 0', wcross_size = '0 0 0';
1160                 string wcross_name = "";
1161                 float wcross_scale, wcross_blur;
1162
1163         entity e = WEP_Null;
1164                 if(autocvar_crosshair_per_weapon || (autocvar_crosshair_color_special == 1))
1165                 {
1166                         entity wepent = viewmodels[0]; // TODO: unhardcode
1167                         e = wepent.switchingweapon;
1168                         if(e)
1169                         {
1170                                 if(autocvar_crosshair_per_weapon)
1171                                 {
1172                                         // WEAPONTODO: access these through some general settings (with non-balance config settings)
1173                                         //wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
1174                                         //if (wcross_resolution == 0)
1175                                                 //return;
1176
1177                                         //wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
1178                                         wcross_resolution *= e.w_crosshair_size;
1179                                         wcross_name = e.w_crosshair;
1180                                 }
1181                         }
1182                 }
1183
1184                 if(wcross_name == "")
1185                         wcross_name = strcat("gfx/crosshair", wcross_style);
1186
1187                 // MAIN CROSSHAIR COLOR DECISION
1188                 wcross_color = crosshair_getcolor(e, STAT(HEALTH));
1189
1190                 if(autocvar_crosshair_effect_scalefade)
1191                 {
1192                         wcross_scale = wcross_resolution;
1193                         wcross_resolution = 1;
1194                 }
1195                 else
1196                 {
1197                         wcross_scale = 1;
1198                 }
1199
1200                 if(autocvar_crosshair_pickup)
1201                 {
1202                         float stat_pickup_time = STAT(LAST_PICKUP);
1203
1204                         if(pickup_crosshair_time < stat_pickup_time)
1205                         {
1206                                 if(time - stat_pickup_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1207                                         pickup_crosshair_size = 1;
1208
1209                                 pickup_crosshair_time = stat_pickup_time;
1210                         }
1211
1212                         if(pickup_crosshair_size > 0)
1213                                 pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
1214                         else
1215                                 pickup_crosshair_size = 0;
1216
1217                         wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
1218                 }
1219
1220                 // todo: make crosshair hit indication dependent on damage dealt
1221                 if(autocvar_crosshair_hitindication)
1222                 {
1223                         vector hitindication_color = ((autocvar_crosshair_color_special == 1) ? stov(autocvar_crosshair_hitindication_per_weapon_color) : stov(autocvar_crosshair_hitindication_color));
1224
1225                         if(unaccounted_damage)
1226                         {
1227                                 hitindication_crosshair_size = 1;
1228                         }
1229
1230                         if(hitindication_crosshair_size > 0)
1231                                 hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
1232                         else
1233                                 hitindication_crosshair_size = 0;
1234
1235                         wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
1236                         wcross_color.x += sin(hitindication_crosshair_size) * hitindication_color.x;
1237                         wcross_color.y += sin(hitindication_crosshair_size) * hitindication_color.y;
1238                         wcross_color.z += sin(hitindication_crosshair_size) * hitindication_color.z;
1239                 }
1240
1241                 // no effects needed for targeting enemies, this can't possibly span all valid targets!
1242                 // just show for teammates to give a sign that they're an invalid target
1243                 //if(shottype == SHOTTYPE_HITENEMY)
1244                         //wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
1245                 if(shottype == SHOTTYPE_HITTEAM)
1246                         wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
1247
1248                 f = fabs(autocvar_crosshair_effect_time);
1249                 if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
1250                 {
1251                         wcross_changedonetime = time + f;
1252                 }
1253                 if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
1254                 {
1255                         wcross_name_changestarttime = time;
1256                         wcross_name_changedonetime = time + f;
1257                         if(wcross_name_goal_prev_prev)
1258                                 strunzone(wcross_name_goal_prev_prev);
1259                         wcross_name_goal_prev_prev = wcross_name_goal_prev;
1260                         wcross_name_goal_prev = strzone(wcross_name);
1261                         wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
1262                         wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
1263                         wcross_resolution_goal_prev = wcross_resolution;
1264                 }
1265
1266                 wcross_scale_goal_prev = wcross_scale;
1267                 wcross_alpha_goal_prev = wcross_alpha;
1268                 wcross_color_goal_prev = wcross_color;
1269
1270                 if(spectatee_status == 0 && (shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active)))
1271                 {
1272                         wcross_blur = 1;
1273                         wcross_alpha *= 0.75;
1274                 }
1275                 else
1276                         wcross_blur = 0;
1277                 // *_prev is at time-frametime
1278                 // * is at wcross_changedonetime+f
1279                 // what do we have at time?
1280                 if(time < wcross_changedonetime)
1281                 {
1282                         f = frametime / (wcross_changedonetime - time + frametime);
1283                         wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
1284                         wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
1285                         wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
1286                 }
1287
1288                 wcross_scale_prev = wcross_scale;
1289                 wcross_alpha_prev = wcross_alpha;
1290                 wcross_color_prev = wcross_color;
1291
1292                 MUTATOR_CALLHOOK(UpdateCrosshair);
1293
1294                 wcross_scale *= 1 - autocvar__menu_alpha;
1295                 wcross_alpha *= 1 - autocvar__menu_alpha;
1296                 wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1297
1298                 if(wcross_scale >= 0.001 && wcross_alpha >= 0.001)
1299                 {
1300                         // crosshair rings for weapon stats
1301                         if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
1302                         {
1303                                 // declarations and stats
1304                                 float ring_value = 0, ring_scale = 0, ring_alpha = 0, ring_inner_value = 0, ring_inner_alpha = 0;
1305                                 string ring_image = string_null, ring_inner_image = string_null;
1306                                 vector ring_rgb = '0 0 0', ring_inner_rgb = '0 0 0';
1307
1308                                 ring_scale = autocvar_crosshair_ring_size;
1309
1310                                 entity wepent = viewmodels[0]; // TODO: unhardcode
1311
1312                                 int weapon_clipload = wepent.clip_load;
1313                                 int weapon_clipsize = wepent.clip_size;
1314
1315                                 float arc_heat = wepent.arc_heat_percent;
1316                                 float vcharge = wepent.vortex_charge;
1317                                 float vchargepool = wepent.vortex_chargepool_ammo;
1318                                 float oknex_charge_ = wepent.oknex_charge;
1319                                 float oknex_chargepool_ = wepent.oknex_chargepool_ammo;
1320
1321                                 if(vortex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
1322                                         vortex_charge_movingavg = vcharge;
1323
1324                                 // handle the values
1325                                 if (autocvar_crosshair_ring && wepent.activeweapon == WEP_VORTEX && vcharge && autocvar_crosshair_ring_vortex) // ring around crosshair representing velocity-dependent damage for the vortex
1326                                 {
1327                                         if (vchargepool || use_vortex_chargepool) {
1328                                                 use_vortex_chargepool = 1;
1329                                                 ring_inner_value = vchargepool;
1330                                         } else {
1331                                                 vortex_charge_movingavg = (1 - autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate) * vortex_charge_movingavg + autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate * vcharge;
1332                                                 ring_inner_value = bound(0, autocvar_crosshair_ring_vortex_currentcharge_scale * (vcharge - vortex_charge_movingavg), 1);
1333                                         }
1334
1335                                         ring_inner_alpha = autocvar_crosshair_ring_vortex_inner_alpha;
1336                                         ring_inner_rgb = vec3(autocvar_crosshair_ring_vortex_inner_color_red, autocvar_crosshair_ring_vortex_inner_color_green, autocvar_crosshair_ring_vortex_inner_color_blue);
1337                                         ring_inner_image = "gfx/crosshair_ring_inner.tga";
1338
1339                                         // draw the outer ring to show the current charge of the weapon
1340                                         ring_value = vcharge;
1341                                         ring_alpha = autocvar_crosshair_ring_vortex_alpha;
1342                                         ring_rgb = wcross_color;
1343                                         ring_image = "gfx/crosshair_ring_nexgun.tga";
1344                                 }
1345                                 else if (autocvar_crosshair_ring && (wepent.activeweapon == WEP_OVERKILL_NEX) && oknex_charge_ && autocvar_crosshair_ring_vortex)
1346                                 {
1347                                         if (oknex_chargepool_ || use_vortex_chargepool) {
1348                                                 use_vortex_chargepool = 1;
1349                                                 ring_inner_value = oknex_chargepool_;
1350                                         } else {
1351                                                 vortex_charge_movingavg = (1 - autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate) * vortex_charge_movingavg + autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate * oknex_charge_;
1352                                                 ring_inner_value = bound(0, autocvar_crosshair_ring_vortex_currentcharge_scale * (oknex_charge_ - vortex_charge_movingavg), 1);
1353                                         }
1354
1355                                         ring_inner_alpha = autocvar_crosshair_ring_vortex_inner_alpha;
1356                                         ring_inner_rgb = eX * autocvar_crosshair_ring_vortex_inner_color_red + eY * autocvar_crosshair_ring_vortex_inner_color_green + eZ * autocvar_crosshair_ring_vortex_inner_color_blue;
1357                                         ring_inner_image = "gfx/crosshair_ring_inner.tga";
1358
1359                                         // draw the outer ring to show the current charge of the weapon
1360                                         ring_value = oknex_charge_;
1361                                         ring_alpha = autocvar_crosshair_ring_vortex_alpha;
1362                                         ring_rgb = wcross_color;
1363                                         ring_image = "gfx/crosshair_ring_nexgun.tga";
1364                                 }
1365                                 else if (autocvar_crosshair_ring && wepent.activeweapon == WEP_MINE_LAYER && WEP_CVAR(minelayer, limit) && autocvar_crosshair_ring_minelayer)
1366                                 {
1367                                         ring_value = bound(0, wepent.minelayer_mines / WEP_CVAR(minelayer, limit), 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
1368                                         ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
1369                                         ring_rgb = wcross_color;
1370                                         ring_image = "gfx/crosshair_ring.tga";
1371                                 }
1372                                 else if (wepent.activeweapon == WEP_HAGAR && wepent.hagar_load && autocvar_crosshair_ring_hagar)
1373                                 {
1374                                         ring_value = bound(0, wepent.hagar_load / WEP_CVAR_SEC(hagar, load_max), 1);
1375                                         ring_alpha = autocvar_crosshair_ring_hagar_alpha;
1376                                         ring_rgb = wcross_color;
1377                                         ring_image = "gfx/crosshair_ring.tga";
1378                                 }
1379                                 else if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
1380                                 {
1381                                         ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
1382                                         ring_scale = autocvar_crosshair_ring_reload_size;
1383                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
1384                                         ring_rgb = wcross_color;
1385
1386                                         // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
1387                                         // if a new image for another weapon is added, add the code (and its respective file/value) here
1388                                         if ((wepent.activeweapon == WEP_RIFLE) && (weapon_clipsize == 80))
1389                                                 ring_image = "gfx/crosshair_ring_rifle.tga";
1390                                         else
1391                                                 ring_image = "gfx/crosshair_ring.tga";
1392                                 }
1393                                 else if ( autocvar_crosshair_ring && autocvar_crosshair_ring_arc && arc_heat && wepent.activeweapon == WEP_ARC )
1394                                 {
1395                                         ring_value = arc_heat;
1396                                         ring_alpha = (1-arc_heat)*autocvar_crosshair_ring_arc_cold_alpha +
1397                                                 arc_heat*autocvar_crosshair_ring_arc_hot_alpha;
1398                                         ring_rgb = (1-arc_heat)*wcross_color + arc_heat*autocvar_crosshair_ring_arc_hot_color;
1399                                         ring_image = "gfx/crosshair_ring.tga";
1400                                 }
1401
1402                                 // if in weapon switch animation, fade ring out/in
1403                                 if(autocvar_crosshair_effect_time > 0)
1404                                 {
1405                                         f = (time - wcross_name_changestarttime) / autocvar_crosshair_effect_time;
1406                                         if (f >= 1)
1407                                         {
1408                                                 wcross_ring_prev = ((ring_image) ? true : false);
1409                                         }
1410
1411                                         if(wcross_ring_prev)
1412                                         {
1413                                                 if(f < 1)
1414                                                         ring_alpha *= fabs(1 - bound(0, f, 1));
1415                                         }
1416                                         else
1417                                         {
1418                                                 if(f < 1)
1419                                                         ring_alpha *= bound(0, f, 1);
1420                                         }
1421                                 }
1422
1423                                 if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
1424                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
1425
1426                                 if (ring_value)
1427                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
1428                         }
1429
1430 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
1431                         MACRO_BEGIN \
1432                                 vector scaled_sz = sz * wcross_size; \
1433                                 if(wcross_blur > 0) \
1434                                 { \
1435                                         for(i = -2; i <= 2; ++i) \
1436                                         for(j = -2; j <= 2; ++j) \
1437                                         M(i,j,sz,scaled_sz,wcross_name,wcross_alpha*0.04); \
1438                                 } \
1439                                 else \
1440                                 { \
1441                                         M(0,0,sz,scaled_sz,wcross_name,wcross_alpha); \
1442                                 } \
1443                         MACRO_END
1444
1445 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,scaled_sz,wcross_name,wcross_alpha) \
1446                         drawpic(wcross_origin - ('0.5 0 0' * (scaled_sz.x + i * wcross_blur) + '0 0.5 0' * (scaled_sz.y + j * wcross_blur)), wcross_name, scaled_sz, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
1447
1448 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
1449                         CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
1450
1451                         if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
1452                         {
1453                                 f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
1454                                 wcross_size = draw_getimagesize(wcross_name_goal_prev_prev) * wcross_scale;
1455                                 CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
1456                                 f = 1 - f;
1457                         }
1458                         else
1459                         {
1460                                 f = 1;
1461                         }
1462                         wcross_name_alpha_goal_prev = f;
1463
1464                         wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1465                         CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
1466
1467                         if(autocvar_crosshair_dot)
1468                         {
1469                                 vector wcross_color_old;
1470                                 wcross_color_old = wcross_color;
1471
1472                                 if((autocvar_crosshair_dot_color_custom) && (autocvar_crosshair_dot_color != "0"))
1473                                         wcross_color = stov(autocvar_crosshair_dot_color);
1474
1475                                 CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
1476                                 // FIXME why don't we use wcross_alpha here?
1477                                 wcross_color = wcross_color_old;
1478                         }
1479                 }
1480         }
1481         else
1482         {
1483                 wcross_scale_prev = 0;
1484                 wcross_alpha_prev = 0;
1485                 wcross_scale_goal_prev = 0;
1486                 wcross_alpha_goal_prev = 0;
1487                 wcross_changedonetime = 0;
1488                 strfree(wcross_name_goal_prev);
1489                 strfree(wcross_name_goal_prev_prev);
1490                 wcross_name_changestarttime = 0;
1491                 wcross_name_changedonetime = 0;
1492                 wcross_name_alpha_goal_prev = 0;
1493                 wcross_name_alpha_goal_prev_prev = 0;
1494                 wcross_resolution_goal_prev = 0;
1495                 wcross_resolution_goal_prev_prev = 0;
1496         }
1497 }
1498
1499 const int MAX_SPECIALCOMMAND = 15;
1500 vector specialcommand_slots[MAX_SPECIALCOMMAND];
1501 vector specialcommand_colors[MAX_SPECIALCOMMAND];
1502 const float SPECIALCOMMAND_SPEED = 150;
1503 const float SPECIALCOMMAND_TURNSPEED = 2;
1504 const float SPECIALCOMMAND_SIZE = 0.025;
1505 const float SPECIALCOMMAND_CHANCE = 0.35;
1506 float sc_spawntime, sc_changetime;
1507 vector sc_color = '1 1 1';
1508 void SpecialCommand()
1509 {
1510         if(!STAT(MOVEVARS_SPECIALCOMMAND))
1511                 return;
1512
1513         if(time >= sc_changetime)
1514         {
1515                 sc_changetime = time + 1;
1516                 sc_color = randomvec() * 1.5;
1517                 sc_color.x = bound(0.2, sc_color.x, 0.75);
1518                 sc_color.y = bound(0.2, sc_color.y, 0.75);
1519                 sc_color.z = bound(0.2, sc_color.z, 0.75);
1520         }
1521         drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), sc_color, autocvar_hud_colorflash_alpha * bound(0.1, sc_changetime - time, 0.3), DRAWFLAG_ADDITIVE);
1522
1523         if(!precache_pic("gfx/smile"))
1524                 return; // damn party poopers
1525
1526         for(int j = MAX_SPECIALCOMMAND - 1; j >= 0; --j)
1527         {
1528                 vector slot = specialcommand_slots[j];
1529                 if(slot.y)
1530                         slot.y += SPECIALCOMMAND_SPEED * frametime;
1531                 //if(slot.z)
1532                         //slot.z = sin(SPECIALCOMMAND_TURNSPEED * M_PI * time);
1533                 if(slot.y >= vid_conheight)
1534                         slot = '0 0 0';
1535
1536                 if(slot == '0 0 0')
1537                 {
1538                         if(random() <= SPECIALCOMMAND_CHANCE && time > sc_spawntime) // low chance to spawn!
1539                         {
1540                                 slot.x = bound(0, (random() * vid_conwidth + 1), vid_conwidth);
1541                                 slot.y = 1; // start it off 0 so we can use it
1542                                 slot.z = floor(random() * Weapons_MAX);
1543                                 sc_spawntime = time + bound(0.4, random(), 0.75); // prevent spawning another one for this amount of time!
1544                                 vector newcolor = randomvec() * 2;
1545                                 newcolor.x = bound(0.4, newcolor.x, 1);
1546                                 newcolor.y = bound(0.4, newcolor.y, 1);
1547                                 newcolor.z = bound(0.4, newcolor.z, 1);
1548                                 specialcommand_colors[j] = newcolor;
1549                         }
1550                 }
1551                 else
1552                 {
1553                         vector splash_size = '0 0 0';
1554                         splash_size.x = max(vid_conwidth, vid_conheight) * SPECIALCOMMAND_SIZE;
1555                         splash_size.y = max(vid_conwidth, vid_conheight) * SPECIALCOMMAND_SIZE;
1556                         entity wep = Weapons_from(slot.z);
1557                         if(wep == WEP_Null)
1558                                 drawpic(vec2(slot), "gfx/smile", vec2(splash_size), specialcommand_colors[j], 0.95, DRAWFLAG_NORMAL);
1559                         else
1560                                 drawpic_skin(vec2(slot), wep.model2, vec2(splash_size), specialcommand_colors[j], 0.95, DRAWFLAG_NORMAL);
1561                         //drawrotpic(vec2(slot), slot.z, "gfx/smile", vec2(splash_size), vec2(splash_size) / 2, specialcommand_colors[j], 0.95, DRAWFLAG_NORMAL);
1562                 }
1563
1564                 specialcommand_slots[j] = slot;
1565         }
1566 }
1567
1568 void HUD_Draw(entity this)
1569 {
1570         // if we don't know gametype and scores yet avoid drawing the scoreboard
1571         // also in the very first frames, player state may be inconsistent so avoid drawing the hud at all
1572         // e.g. since initial player's health is 0 hud would display the hud_damage effect,
1573         // cl_deathscoreboard would show the scoreboard and so on
1574         if(!gametype)
1575                 return;
1576
1577         Hud_Dynamic_Frame();
1578
1579         if(!intermission)
1580         if (MUTATOR_CALLHOOK(HUD_Draw_overlay))
1581         {
1582                 drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), M_ARGV(0, vector), autocvar_hud_colorflash_alpha * M_ARGV(1, float), DRAWFLAG_ADDITIVE);
1583         }
1584         else if(STAT(FROZEN))
1585         {
1586                 vector col = '0.25 0.90 1';
1587                 if(STAT(REVIVE_PROGRESS))
1588                         col += vec3(STAT(REVIVE_PROGRESS), -STAT(REVIVE_PROGRESS), -STAT(REVIVE_PROGRESS));
1589                 drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), col, autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1590         }
1591
1592         HUD_Scale_Enable();
1593         if(!intermission)
1594         if(STAT(NADE_TIMER) && autocvar_cl_nade_timer) // give nade top priority, as it's a matter of life and death
1595         {
1596                 vector col = '0.25 0.90 1' + vec3(STAT(NADE_TIMER), -STAT(NADE_TIMER), -STAT(NADE_TIMER));
1597                 DrawCircleClippedPic(vec2(0.5 * vid_conwidth, 0.6 * vid_conheight), 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(NADE_TIMER), col, autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1598                 drawstring_aspect(eY * 0.64 * vid_conheight, ((autocvar_cl_nade_timer == 2) ? _("Nade timer") : ""), vec2(vid_conwidth, 0.025 * vid_conheight), '1 1 1', 1, DRAWFLAG_NORMAL);
1599         }
1600         else if(STAT(CAPTURE_PROGRESS))
1601         {
1602                 DrawCircleClippedPic(vec2(0.5 * vid_conwidth, 0.6 * vid_conheight), 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(CAPTURE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1603                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Capture progress"), vec2(vid_conwidth, 0.025 * vid_conheight), '1 1 1', 1, DRAWFLAG_NORMAL);
1604         }
1605         else if(STAT(REVIVE_PROGRESS))
1606         {
1607                 DrawCircleClippedPic(vec2(0.5 * vid_conwidth, 0.6 * vid_conheight), 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1608                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Revival progress"), vec2(vid_conwidth, 0.025 * vid_conheight), '1 1 1', 1, DRAWFLAG_NORMAL);
1609         }
1610         HUD_Scale_Disable();
1611
1612         if(autocvar_r_letterbox == 0)
1613                 if(autocvar_viewsize < 120)
1614                 {
1615                         if(!(ISGAMETYPE(RACE) || ISGAMETYPE(CTS)))
1616                                 Accuracy_LoadLevels();
1617
1618                         HUD_Main();
1619                         HUD_Scale_Disable();
1620                 }
1621
1622         // crosshair goes VERY LAST
1623         SpecialCommand();
1624         UpdateDamage();
1625         HUD_Crosshair(this);
1626         HitSound();
1627 }
1628
1629 void ViewLocation_Mouse()
1630 {
1631         if(spectatee_status)
1632                 return; // don't draw it as spectator!
1633
1634         viewloc_mousepos += getmousepos() * autocvar_menu_mouse_speed;
1635         viewloc_mousepos.x = bound(0, viewloc_mousepos.x, vid_conwidth);
1636         viewloc_mousepos.y = bound(0, viewloc_mousepos.y, vid_conheight);
1637
1638         //float cursor_alpha = 1 - autocvar__menu_alpha;
1639         //draw_cursor(viewloc_mousepos, '0.5 0.5 0', "/cursor_move", '1 1 1', cursor_alpha);
1640 }
1641
1642 void HUD_Cursor_Show()
1643 {
1644         float cursor_alpha = 1 - autocvar__menu_alpha;
1645         if(cursor_type == CURSOR_NORMAL)
1646                 draw_cursor_normal(mousepos, '1 1 1', cursor_alpha);
1647         else if(cursor_type == CURSOR_MOVE)
1648                 draw_cursor(mousepos, '0.5 0.5 0', "/cursor_move", '1 1 1', cursor_alpha);
1649         else if(cursor_type == CURSOR_RESIZE)
1650                 draw_cursor(mousepos, '0.5 0.5 0', "/cursor_resize", '1 1 1', cursor_alpha);
1651         else if(cursor_type == CURSOR_RESIZE2)
1652                 draw_cursor(mousepos, '0.5 0.5 0', "/cursor_resize2", '1 1 1', cursor_alpha);
1653 }
1654
1655 void HUD_Mouse(entity player)
1656 {
1657         if(autocvar__menu_alpha == 1)
1658                 return;
1659
1660         if(!cursor_active)
1661         {
1662                 if(player.viewloc && (player.viewloc.spawnflags & VIEWLOC_FREEAIM))
1663                         ViewLocation_Mouse(); // NOTE: doesn't use cursormode
1664                 return;
1665         }
1666
1667         if (cursor_active == -1) // starting to display the cursor
1668         {
1669                 // since HUD_Mouse is called by CSQC_UpdateView before CSQC_InputEvent,
1670                 // in the first frame mousepos is the mouse position of the last time
1671                 // the cursor was displayed, thus we ignore it to avoid a glictch
1672                 cursor_active = 1;
1673                 return;
1674         }
1675
1676         if(!autocvar_hud_cursormode)
1677                 update_mousepos();
1678
1679         if(autocvar__hud_configure)
1680                 HUD_Panel_Mouse();
1681         else
1682         {
1683                 if (HUD_MinigameMenu_IsOpened())
1684                         HUD_Minigame_Mouse();
1685                 if (QuickMenu_IsOpened())
1686                         QuickMenu_Mouse();
1687                 if (HUD_Radar_Clickable())
1688                         HUD_Radar_Mouse();
1689         }
1690
1691         prevMouseClicked = mouseClicked;
1692
1693         HUD_Cursor_Show();
1694 }
1695
1696 void View_NightVision()
1697 {
1698         if(!(autocvar_r_fakelight >= 2 || autocvar_r_fullbright) || (serverflags & SERVERFLAG_ALLOW_FULLBRIGHT))
1699                 return;
1700
1701         // apply night vision effect
1702         vector tc_00, tc_01, tc_10, tc_11;
1703         vector rgb = '0 0 0';
1704         float a;
1705
1706         if(!nightvision_noise)
1707         {
1708                 nightvision_noise = new(nightvision_noise);
1709         }
1710         if(!nightvision_noise2)
1711         {
1712                 nightvision_noise2 = new(nightvision_noise2);
1713         }
1714
1715         // color tint in yellow
1716         drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
1717
1718         // draw BG
1719         a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
1720         rgb = '1 1 1';
1721         tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
1722         tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
1723         tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
1724         //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
1725         tc_11 = tc_01 + tc_10 - tc_00;
1726         R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
1727         R_PolygonVertex('0 0 0', tc_00, rgb, a);
1728         R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
1729         R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
1730         R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
1731         R_EndPolygon();
1732
1733         // draw FG
1734         a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
1735         rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
1736         tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
1737         tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
1738         tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
1739         tc_11 = tc_01 + tc_10 - tc_00;
1740         R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
1741         R_PolygonVertex('0 0 0', tc_00, rgb, a);
1742         R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
1743         R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
1744         R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
1745         R_EndPolygon();
1746 }
1747
1748 void DrawReticle(entity this)
1749 {
1750         if(!autocvar_cl_reticle || MUTATOR_CALLHOOK(DrawReticle))
1751         {
1752                 reticle_type = 0;
1753                 return;
1754         }
1755
1756         float is_dead = (STAT(HEALTH) <= 0);
1757         string reticle_image = string_null;
1758         bool wep_zoomed = false;
1759         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1760         {
1761                 entity wepe = viewmodels[slot];
1762                 Weapon wep = wepe.activeweapon;
1763                 if(wep != WEP_Null && wep.wr_zoom)
1764                 {
1765                         bool do_zoom = wep.wr_zoom(wep, NULL);
1766                         if(!reticle_image && wep.w_reticle && wep.w_reticle != "")
1767                                 reticle_image = wep.w_reticle;
1768                         wep_zoomed += do_zoom;
1769                 }
1770         }
1771         // Draw the aiming reticle for weapons that use it
1772         // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
1773         // It must be a persisted float for fading out to work properly (you let go of the zoom button for
1774         // the view to go back to normal, so reticle_type would become 0 as we fade out)
1775         if(spectatee_status || is_dead || hud != HUD_NORMAL || this.viewloc)
1776         {
1777                 // no zoom reticle while dead
1778                 reticle_type = 0;
1779         }
1780         else if(wep_zoomed && autocvar_cl_reticle_weapon)
1781         {
1782                 if(reticle_image) { reticle_type = 2; }
1783                 else { reticle_type = 0; }
1784         }
1785         else if(button_zoom || zoomscript_caught)
1786         {
1787                 // normal zoom
1788                 reticle_type = 1;
1789         }
1790
1791         if(reticle_type)
1792         {
1793                 vector reticle_pos = '0 0 0', reticle_size = '0 0 0';
1794                 if(autocvar_cl_reticle_stretch)
1795                 {
1796                         reticle_size.x = vid_conwidth;
1797                         reticle_size.y = vid_conheight;
1798                         reticle_pos.x = 0;
1799                         reticle_pos.y = 0;
1800                 }
1801                 else
1802                 {
1803                         reticle_size.x = max(vid_conwidth, vid_conheight);
1804                         reticle_size.y = max(vid_conwidth, vid_conheight);
1805                         reticle_pos.x = (vid_conwidth - reticle_size.x) / 2;
1806                         reticle_pos.y = (vid_conheight - reticle_size.y) / 2;
1807                 }
1808
1809                 float f = (zoomscript_caught) ? 1 : current_zoomfraction;
1810
1811                 if(f)
1812                 {
1813                         switch(reticle_type)
1814                         {
1815                                 case 1: drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_normal_alpha, DRAWFLAG_NORMAL); break;
1816                                 case 2: if(reticle_image) drawpic(reticle_pos, reticle_image, reticle_size, '1 1 1', f * autocvar_cl_reticle_weapon_alpha, DRAWFLAG_NORMAL); break;
1817                         }
1818                 }
1819         }
1820 }
1821
1822 // visual overlay while in liquids
1823 // provides some effects to the postprocessing function
1824 void HUD_Contents()
1825 {
1826         if(!autocvar_hud_contents || MUTATOR_CALLHOOK(HUD_Contents))
1827                 return;
1828
1829         // improved polyblend
1830         float contentalpha_temp, incontent, liquidalpha, contentfadetime;
1831         vector liquidcolor;
1832
1833         switch(pointcontents(view_origin))
1834         {
1835                 case CONTENT_WATER:
1836                         liquidalpha = autocvar_hud_contents_water_alpha;
1837                         liquidcolor = stov(autocvar_hud_contents_water_color);
1838                         incontent = 1;
1839                         break;
1840
1841                 case CONTENT_LAVA:
1842                         liquidalpha = autocvar_hud_contents_lava_alpha;
1843                         liquidcolor = stov(autocvar_hud_contents_lava_color);
1844                         incontent = 1;
1845                         break;
1846
1847                 case CONTENT_SLIME:
1848                         liquidalpha = autocvar_hud_contents_slime_alpha;
1849                         liquidcolor = stov(autocvar_hud_contents_slime_color);
1850                         incontent = 1;
1851                         break;
1852
1853                 default:
1854                         liquidalpha = 0;
1855                         liquidcolor = '0 0 0';
1856                         incontent = 0;
1857                         break;
1858         }
1859
1860         if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
1861         { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
1862                 contentfadetime = autocvar_hud_contents_fadeintime;
1863                 liquidalpha_prev = liquidalpha;
1864                 liquidcolor_prev = liquidcolor;
1865         }
1866         else
1867                 contentfadetime = autocvar_hud_contents_fadeouttime;
1868
1869         contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
1870         contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
1871
1872         if(contentavgalpha)
1873                 drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
1874
1875         if(autocvar_hud_postprocessing)
1876         {
1877                 if(autocvar_hud_contents_blur && contentavgalpha)
1878                 {
1879                         content_blurpostprocess.x = 1;
1880                         content_blurpostprocess.y = contentavgalpha * autocvar_hud_contents_blur;
1881                         content_blurpostprocess.z = contentavgalpha * autocvar_hud_contents_blur_alpha;
1882                 }
1883                 else
1884                 {
1885                         content_blurpostprocess.x = 0;
1886                         content_blurpostprocess.y = 0;
1887                         content_blurpostprocess.z = 0;
1888                 }
1889         }
1890 }
1891
1892 // visual pain effects on the screen
1893 // provides some effects to the postprocessing function
1894 void HUD_Damage()
1895 {
1896         if(!autocvar_hud_damage || STAT(FROZEN))
1897                 return;
1898
1899         vector splash_pos = '0 0 0', splash_size = '0 0 0';
1900         splash_size.x = max(vid_conwidth, vid_conheight);
1901         splash_size.y = max(vid_conwidth, vid_conheight);
1902         splash_pos.x = (vid_conwidth - splash_size.x) / 2;
1903         splash_pos.y = (vid_conheight - splash_size.y) / 2;
1904
1905         float myhealth_flash_temp;
1906         myhealth = STAT(HEALTH);
1907
1908         // fade out
1909         myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
1910         // add new damage
1911         myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
1912
1913         float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
1914         pain_threshold = autocvar_hud_damage_pain_threshold;
1915         pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
1916         pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
1917
1918         if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
1919         {
1920                 pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
1921         }
1922
1923         myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
1924
1925         if(myhealth_prev < 1)
1926         {
1927                 if(myhealth >= 1)
1928                 {
1929                         myhealth_flash = 0; // just spawned, clear the flash immediately
1930                         myhealth_flash_temp = 0;
1931                 }
1932                 else
1933                 {
1934                         myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
1935                 }
1936         }
1937
1938         if(spectatee_status == -1 || intermission)
1939         {
1940                 myhealth_flash = 0; // observing, or match ended
1941                 myhealth_flash_temp = 0;
1942         }
1943
1944         myhealth_prev = myhealth;
1945
1946         // IDEA: change damage color/picture based on player model for robot/alien species?
1947         // pro: matches model better
1948         // contra: it's not red because blood is red, but because red is an alarming color, so red should stay
1949         // maybe different reddish pics?
1950         if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
1951         {
1952                 if(autocvar_cl_gentle_damage == 2)
1953                 {
1954                         if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
1955                                 myhealth_gentlergb = randomvec();
1956                 }
1957                 else
1958                         myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
1959
1960                 if(myhealth_flash_temp > 0)
1961                         drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
1962         }
1963         else if(myhealth_flash_temp > 0)
1964                 drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
1965
1966         if(autocvar_hud_postprocessing) // we still need to set this anyway even when chase_active is set, this way it doesn't get stuck on.
1967         {
1968                 if(autocvar_hud_damage_blur && myhealth_flash_temp)
1969                 {
1970                         damage_blurpostprocess.x = 1;
1971                         damage_blurpostprocess.y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
1972                         damage_blurpostprocess.z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
1973                 }
1974                 else
1975                 {
1976                         damage_blurpostprocess.x = 0;
1977                         damage_blurpostprocess.y = 0;
1978                         damage_blurpostprocess.z = 0;
1979                 }
1980         }
1981 }
1982
1983 void View_PostProcessing()
1984 {
1985         float e1 = (autocvar_hud_postprocessing_maxbluralpha != 0);
1986         float e2 = (autocvar_hud_powerup != 0);
1987         if(autocvar_hud_postprocessing && (e1 || e2)) // TODO: Remove this code and re-do the postprocess handling in the engine, where it properly belongs.
1988         {
1989                 // enable or disable rendering types if they are used or not
1990                 if(cvar("r_glsl_postprocess_uservec1_enable") != e1) { cvar_set("r_glsl_postprocess_uservec1_enable", ftos(e1)); }
1991                 if(cvar("r_glsl_postprocess_uservec2_enable") != e2) { cvar_set("r_glsl_postprocess_uservec2_enable", ftos(e2)); }
1992
1993                 // blur postprocess handling done first (used by hud_damage and hud_contents)
1994                 if((damage_blurpostprocess.x || content_blurpostprocess.x))
1995                 {
1996                         float blurradius = bound(0, damage_blurpostprocess.y + content_blurpostprocess.y, autocvar_hud_postprocessing_maxblurradius);
1997                         float bluralpha = bound(0, damage_blurpostprocess.z + content_blurpostprocess.z, autocvar_hud_postprocessing_maxbluralpha);
1998                         if(blurradius != old_blurradius || bluralpha != old_bluralpha) // reduce cvar_set spam as much as possible
1999                         {
2000                                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
2001                                 old_blurradius = blurradius;
2002                                 old_bluralpha = bluralpha;
2003                         }
2004                 }
2005                 else if(cvar_string("r_glsl_postprocess_uservec1") != "0 0 0 0") // reduce cvar_set spam as much as possible
2006                 {
2007                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
2008                         old_blurradius = 0;
2009                         old_bluralpha = 0;
2010                 }
2011
2012                 // edge detection postprocess handling done second (used by hud_powerup)
2013                 float sharpen_intensity = 0, strength_finished = STAT(STRENGTH_FINISHED), invincible_finished = STAT(INVINCIBLE_FINISHED);
2014                 if (strength_finished - time > 0) { sharpen_intensity += (strength_finished - time); }
2015                 if (invincible_finished - time > 0) { sharpen_intensity += (invincible_finished - time); }
2016
2017                 sharpen_intensity = bound(0, ((STAT(HEALTH) > 0) ? sharpen_intensity : 0), 5); // Check to see if player is alive (if not, set 0) - also bound to fade out starting at 5 seconds.
2018
2019                 if(autocvar_hud_powerup && sharpen_intensity > 0)
2020                 {
2021                         if(sharpen_intensity != old_sharpen_intensity) // reduce cvar_set spam as much as possible
2022                         {
2023                                 cvar_set("r_glsl_postprocess_uservec2", strcat(ftos((sharpen_intensity / 5) * autocvar_hud_powerup), " ", ftos(-sharpen_intensity * autocvar_hud_powerup), " 0 0"));
2024                                 old_sharpen_intensity = sharpen_intensity;
2025                         }
2026                 }
2027                 else if(cvar_string("r_glsl_postprocess_uservec2") != "0 0 0 0") // reduce cvar_set spam as much as possible
2028                 {
2029                         cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
2030                         old_sharpen_intensity = 0;
2031                 }
2032
2033                 if(cvar("r_glsl_postprocess") == 0)
2034                         cvar_set("r_glsl_postprocess", "2");
2035         }
2036         else if(cvar("r_glsl_postprocess") == 2)
2037                 cvar_set("r_glsl_postprocess", "0");
2038 }
2039
2040 void View_Lock()
2041 {
2042         if(autocvar_cl_lockview || (!autocvar_hud_cursormode && (autocvar__hud_configure && spectatee_status <= 0 || intermission > 1 || QuickMenu_IsOpened())))
2043         {
2044                 setproperty(VF_ORIGIN, freeze_org);
2045                 setproperty(VF_ANGLES, freeze_ang);
2046         }
2047         else
2048         {
2049                 freeze_org = getpropertyvec(VF_ORIGIN);
2050                 freeze_ang = getpropertyvec(VF_ANGLES);
2051         }
2052 }
2053
2054 void View_DemoCamera()
2055 {
2056         if(camera_active) // Camera for demo playback
2057         {
2058                 if(autocvar_camera_enable)
2059                         CSQC_Demo_Camera();
2060                 else
2061                 {
2062                         cvar_set("chase_active", ftos(chase_active_backup));
2063                         cvar_set("cl_demo_mousegrab", "0");
2064                         camera_active = false;
2065                 }
2066         }
2067         else
2068         {
2069 #ifdef CAMERATEST
2070                 if(autocvar_camera_enable)
2071 #else
2072                 if(autocvar_camera_enable && isdemo())
2073 #endif
2074                 {
2075                         // Enable required Darkplaces cvars
2076                         chase_active_backup = autocvar_chase_active;
2077                         cvar_set("chase_active", "2");
2078                         cvar_set("cl_demo_mousegrab", "1");
2079                         camera_active = true;
2080                         camera_mode = false;
2081                 }
2082         }
2083 }
2084
2085 #ifdef BLURTEST
2086 void View_BlurTest()
2087 {
2088         if(time > blurtest_time0 && time < blurtest_time1)
2089         {
2090                 float t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
2091                 float r = t * blurtest_radius;
2092                 float f = 1 / (t ** blurtest_power) - 1;
2093
2094                 cvar_set("r_glsl_postprocess", "1");
2095                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
2096         }
2097         else
2098         {
2099                 cvar_set("r_glsl_postprocess", "0");
2100                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
2101         }
2102 }
2103 #endif
2104
2105 void View_CheckButtonStatus()
2106 {
2107         float is_dead = (STAT(HEALTH) <= 0);
2108
2109         // FIXME do we need this hack?
2110         if(isdemo())
2111         {
2112                 // in demos, input_buttons do not work
2113                 button_zoom = (autocvar__togglezoom == "-");
2114         }
2115         else if(button_zoom
2116                 && autocvar_cl_unpress_zoom_on_death
2117                 && (spectatee_status >= 0)
2118                 && (is_dead || intermission))
2119         {
2120                 // no zoom while dead or in intermission please
2121                 localcmd("-zoom\n");
2122                 button_zoom = false;
2123         }
2124
2125         if(autocvar_fov <= 59.5)
2126         {
2127                 if(!zoomscript_caught)
2128                 {
2129                         localcmd("+button9\n");
2130                         zoomscript_caught = 1;
2131                 }
2132         }
2133         else
2134         {
2135                 if(zoomscript_caught)
2136                 {
2137                         localcmd("-button9\n");
2138                         zoomscript_caught = 0;
2139                 }
2140         }
2141
2142         if(active_minigame && HUD_MinigameMenu_IsOpened())
2143         {
2144                 if(!minigame_wasactive)
2145                 {
2146                         localcmd("+button12\n");
2147                         minigame_wasactive = true;
2148                 }
2149         }
2150         else if(minigame_wasactive)
2151         {
2152                 localcmd("-button12\n");
2153                 minigame_wasactive = false;
2154         }
2155
2156         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2157         {
2158                 entity wepent = viewmodels[slot];
2159
2160                 if(wepent.last_switchweapon != wepent.switchweapon)
2161                 {
2162                         weapontime = time;
2163                         wepent.last_switchweapon = wepent.switchweapon;
2164                         if(slot == 0 && button_zoom && autocvar_cl_unpress_zoom_on_weapon_switch)
2165                         {
2166                                 localcmd("-zoom\n");
2167                                 button_zoom = false;
2168                         }
2169                         if(slot == 0 && autocvar_cl_unpress_attack_on_weapon_switch)
2170                         {
2171                                 localcmd("-fire\n");
2172                                 localcmd("-fire2\n");
2173                                 button_attack2 = false;
2174                         }
2175                 }
2176                 if(wepent.last_activeweapon != wepent.activeweapon)
2177                 {
2178                         wepent.last_activeweapon = wepent.activeweapon;
2179
2180                         entity e = wepent.activeweapon;
2181                         if(e.netname != "")
2182                                 localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
2183                         else if(slot == 0)
2184                                 localcmd("\ncl_hook_activeweapon none\n");
2185                 }
2186         }
2187 }
2188
2189 bool ov_enabled;
2190 float oldr_nearclip;
2191 float oldr_farclip_base;
2192 float oldr_farclip_world;
2193 float oldr_novis;
2194 float oldr_useportalculling;
2195 float oldr_useinfinitefarclip;
2196 vector ov_org = '0 0 0';
2197 vector ov_mid = '0 0 0';
2198 vector ov_worldmin = '0 0 0';
2199 vector ov_worldmax = '0 0 0';
2200
2201 void View_Ortho()
2202 {
2203         ov_org = '0 0 0';
2204         ov_mid = '0 0 0';
2205         ov_worldmin = '0 0 0';
2206         ov_worldmax = '0 0 0';
2207         if(autocvar_cl_orthoview)
2208         {
2209                 ov_worldmin = mi_picmin;
2210                 ov_worldmax = mi_picmax;
2211
2212                 float ov_width = (ov_worldmax.x - ov_worldmin.x);
2213                 float ov_height = (ov_worldmax.y - ov_worldmin.y);
2214                 float ov_distance = (max(vid_width, vid_height) * max(ov_width, ov_height));
2215
2216                 ov_mid = ((ov_worldmax + ov_worldmin) * 0.5);
2217                 ov_org = vec3(ov_mid.x, ov_mid.y, (ov_mid.z + ov_distance));
2218
2219                 float ov_nearest = vlen(ov_org - vec3(
2220                         bound(ov_worldmin.x, ov_org.x, ov_worldmax.x),
2221                         bound(ov_worldmin.y, ov_org.y, ov_worldmax.y),
2222                         bound(ov_worldmin.z, ov_org.z, ov_worldmax.z)
2223                 ));
2224
2225                 float ov_furthest = 0;
2226                 float dist = 0;
2227
2228                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
2229                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
2230                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
2231                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
2232                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
2233                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
2234                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
2235                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
2236
2237                 if(!ov_enabled)
2238                 {
2239                         oldr_nearclip = cvar("r_nearclip");
2240                         oldr_farclip_base = cvar("r_farclip_base");
2241                         oldr_farclip_world = cvar("r_farclip_world");
2242                         oldr_novis = cvar("r_novis");
2243                         oldr_useportalculling = cvar("r_useportalculling");
2244                         oldr_useinfinitefarclip = cvar("r_useinfinitefarclip");
2245                 }
2246
2247                 cvar_settemp("r_nearclip", ftos(ov_nearest));
2248                 cvar_settemp("r_farclip_base", ftos(ov_furthest));
2249                 cvar_settemp("r_farclip_world", "0");
2250                 cvar_settemp("r_novis", "1");
2251                 cvar_settemp("r_useportalculling", "0");
2252                 cvar_settemp("r_useinfinitefarclip", "0");
2253
2254                 setproperty(VF_ORIGIN, ov_org);
2255                 setproperty(VF_ANGLES, '90 0 0');
2256
2257                 ov_enabled = true;
2258
2259                 #if 0
2260                 LOG_INFOF("OrthoView: org = %s, angles = %s, distance = %f, nearest = %f, furthest = %f",
2261                         vtos(ov_org),
2262                         vtos(getpropertyvec(VF_ANGLES)),
2263                         ov_distance,
2264                         ov_nearest,
2265                         ov_furthest);
2266                 #endif
2267         }
2268         else
2269         {
2270                 if(ov_enabled)
2271                 {
2272                         cvar_set("r_nearclip", ftos(oldr_nearclip));
2273                         cvar_set("r_farclip_base", ftos(oldr_farclip_base));
2274                         cvar_set("r_farclip_world", ftos(oldr_farclip_world));
2275                         cvar_set("r_novis", ftos(oldr_novis));
2276                         cvar_set("r_useportalculling", ftos(oldr_useportalculling));
2277                         cvar_set("r_useinfinitefarclip", ftos(oldr_useinfinitefarclip));
2278                 }
2279                 ov_enabled = false;
2280         }
2281 }
2282
2283 void View_UpdateFov()
2284 {
2285         vector fov;
2286         if(autocvar_cl_orthoview)
2287                 fov = GetOrthoviewFOV(ov_worldmin, ov_worldmax, ov_mid, ov_org);
2288         else if(csqcplayer.viewloc)
2289                 fov = GetViewLocationFOV(110); // enforce 110 fov, so things don't look odd
2290         else
2291                 fov = GetCurrentFov(autocvar_fov);
2292
2293         setproperty(VF_FOV, fov);
2294 }
2295
2296 void CSQC_UpdateView(entity this, float w, float h)
2297 {
2298         TC(int, w); TC(int, h);
2299
2300         execute_next_frame();
2301
2302         ++framecount;
2303
2304         stats_get();
2305         hud = STAT(HUD);
2306
2307         ReplicateVars(false);
2308         if (ReplicateVars_NOT_SENDING())
2309                 ReplicateVars_DELAY(0.8 + random() * 0.4); // no need to check cvars every frame
2310
2311         HUD_Scale_Disable();
2312
2313         if(autocvar__hud_showbinds_reload) // menu can set this one
2314         {
2315                 db_close(binddb);
2316                 binddb = db_create();
2317                 cvar_set("_hud_showbinds_reload", "0");
2318         }
2319
2320         if(checkextension("DP_CSQC_MINFPS_QUALITY"))
2321                 view_quality = getproperty(VF_MINFPS_QUALITY);
2322         else
2323                 view_quality = 1;
2324
2325         button_attack2 = PHYS_INPUT_BUTTON_ATCK2(this);
2326         button_zoom = PHYS_INPUT_BUTTON_ZOOM(this);
2327
2328         vector vf_size = getpropertyvec(VF_SIZE);
2329         vector vf_min = getpropertyvec(VF_MIN);
2330         vid_width = vf_size.x;
2331         vid_height = vf_size.y;
2332
2333         WaypointSprite_Load();
2334
2335         CSQCPlayer_SetCamera();
2336
2337         if(player_localentnum <= maxclients) // is it a client?
2338                 current_player = player_localentnum - 1;
2339         else // then player_localentnum is the vehicle I'm driving
2340                 current_player = player_localnum;
2341         myteam = entcs_GetTeam(current_player);
2342
2343         ticrate = STAT(MOVEVARS_TICRATE) * STAT(MOVEVARS_TIMESCALE);
2344
2345         // abused multiple places below
2346         entity local_player = ((csqcplayer) ? csqcplayer : CSQCModel_server2csqc(player_localentnum - 1));
2347         if(!local_player)
2348                 local_player = this; // fall back!
2349
2350         View_EventChase(local_player);
2351
2352         // do lockview after event chase camera so that it still applies whenever necessary.
2353         View_Lock();
2354
2355         WarpZone_FixView();
2356         //WarpZone_FixPMove();
2357
2358         View_Ortho();
2359
2360         // run viewmodel_draw before updating view_angles to the angles calculated by WarpZone_FixView
2361         // viewmodel_draw needs to use the view_angles set by the engine on every CSQC_UpdateView call
2362         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2363                 viewmodel_draw(viewmodels[slot]);
2364
2365         // Render the Scene
2366         view_origin = getpropertyvec(VF_ORIGIN);
2367         view_angles = getpropertyvec(VF_ANGLES);
2368         MAKE_VECTORS(view_angles, view_forward, view_right, view_up);
2369
2370 #ifdef BLURTEST
2371         View_BlurTest();
2372 #endif
2373
2374         TargetMusic_Advance();
2375         Fog_Force();
2376         fpscounter_update();
2377
2378         if(drawtime == 0)
2379                 drawframetime = 0.01666667; // when we don't know fps yet, we assume 60fps
2380         else
2381                 drawframetime = bound(0.000001, time - drawtime, 1);
2382         drawtime = time;
2383
2384         // watch for gametype changes here...
2385         // in ParseStuffCMD the cmd isn't executed yet :/
2386         // might even be better to add the gametype to TE_CSQC_INIT...?
2387         if(!postinit)
2388                 PostInit();
2389
2390         if(intermission && !intermission_time)
2391                 intermission_time = time;
2392
2393         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
2394         {
2395                 if(calledhooks & HOOK_START)
2396                 {
2397                         localcmd("\ncl_hook_gameend\n");
2398                         calledhooks |= HOOK_END;
2399                 }
2400         }
2401
2402         Announcer();
2403
2404         View_CheckButtonStatus();
2405
2406         ColorTranslateMode = autocvar_cl_stripcolorcodes;
2407
2408         // ALWAYS Clear Current Scene First
2409         clearscene();
2410
2411         setproperty(VF_ORIGIN, view_origin);
2412         setproperty(VF_ANGLES, view_angles);
2413
2414         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
2415         setproperty(VF_SIZE, vf_size);
2416         setproperty(VF_MIN, vf_min);
2417
2418         // Assign Standard Viewflags
2419         // Draw the World (and sky)
2420         setproperty(VF_DRAWWORLD, 1);
2421
2422         // Set the console size vars
2423         vid_conwidth = autocvar_vid_conwidth;
2424         vid_conheight = autocvar_vid_conheight;
2425         vid_pixelheight = autocvar_vid_pixelheight;
2426
2427         View_UpdateFov();
2428
2429         View_DemoCamera();
2430
2431         // Draw the Crosshair
2432         setproperty(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
2433
2434         // Draw the Engine Status Bar (the default Quake HUD)
2435         setproperty(VF_DRAWENGINESBAR, 0);
2436
2437         // Update the mouse position
2438         /*
2439            mousepos_x = vid_conwidth;
2440            mousepos_y = vid_conheight;
2441            mousepos = mousepos*0.5 + getmousepos();
2442          */
2443
2444         IL_EACH(g_drawables, it.draw, it.draw(it));
2445
2446         addentities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS); // TODO: .health is used in cl_deathfade (a feature we have turned off currently)
2447         renderscene();
2448
2449         // now switch to 2D drawing mode by calling a 2D drawing function
2450         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
2451         // next R_RenderScene call
2452         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
2453
2454         View_NightVision();
2455         DrawReticle(local_player);
2456         HUD_Contents();
2457         HUD_Damage();
2458         View_PostProcessing();
2459
2460         // draw 2D entities
2461         IL_EACH(g_drawables_2d, it.draw2d, it.draw2d(it));
2462         Draw_ShowNames_All();
2463 #if ENABLE_DEBUGDRAW
2464         Debug_Draw();
2465 #endif
2466
2467         scoreboard_active = Scoreboard_WouldDraw();
2468
2469         HUD_Draw(this); // this parameter for deep vehicle function
2470
2471         if(NextFrameCommand)
2472         {
2473                 localcmd("\n", NextFrameCommand, "\n");
2474                 NextFrameCommand = string_null;
2475         }
2476
2477         // we must do this check AFTER a frame was rendered, or it won't work
2478         if(cs_project_is_b0rked == 0)
2479         {
2480                 string w0, h0;
2481                 w0 = ftos(autocvar_vid_conwidth);
2482                 h0 = ftos(autocvar_vid_conheight);
2483                 //setproperty(VF_VIEWPORT, '0 0 0', '640 480 0');
2484                 //setproperty(VF_FOV, '90 90 0');
2485                 setproperty(VF_ORIGIN, '0 0 0');
2486                 setproperty(VF_ANGLES, '0 0 0');
2487                 setproperty(VF_PERSPECTIVE, 1);
2488                 vector forward, right, up;
2489                 MAKE_VECTORS('0 0 0', forward, right, up);
2490                 vector v1, v2;
2491                 cvar_set("vid_conwidth", "800");
2492                 cvar_set("vid_conheight", "600");
2493                 v1 = cs_project(forward);
2494                 cvar_set("vid_conwidth", "640");
2495                 cvar_set("vid_conheight", "480");
2496                 v2 = cs_project(forward);
2497                 if(v1 == v2)
2498                         cs_project_is_b0rked = 1;
2499                 else
2500                         cs_project_is_b0rked = -1;
2501                 cvar_set("vid_conwidth", w0);
2502                 cvar_set("vid_conheight", h0);
2503         }
2504
2505         HUD_Mouse(local_player);
2506
2507         cl_notice_run();
2508         unpause_update();
2509         Net_Flush();
2510
2511         // let's reset the view back to normal for the end
2512         setproperty(VF_MIN, '0 0 0');
2513         setproperty(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
2514
2515         IL_ENDFRAME();
2516 }
2517
2518
2519 // following vectors must be global to allow seamless switching between camera modes
2520 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
2521 void CSQC_Demo_Camera()
2522 {
2523         float speed, attenuation, dimensions;
2524         vector tmp, delta;
2525
2526         if( autocvar_camera_reset || !camera_mode )
2527         {
2528                 camera_offset = '0 0 0';
2529                 current_angles = '0 0 0';
2530                 camera_direction = '0 0 0';
2531                 camera_offset.z += 30;
2532                 camera_offset.x += 30 * -cos(current_angles.y * DEG2RAD);
2533                 camera_offset.y += 30 * -sin(current_angles.y * DEG2RAD);
2534                 current_origin = view_origin;
2535                 current_camera_offset  = camera_offset;
2536                 cvar_set("camera_reset", "0");
2537                 camera_mode = CAMERA_CHASE;
2538         }
2539
2540         // Camera angles
2541         if( camera_roll )
2542                 mouse_angles.z += camera_roll * autocvar_camera_speed_roll;
2543
2544         if(autocvar_camera_look_player)
2545         {
2546                 vector dir;
2547                 float n;
2548
2549                 dir = normalize(view_origin - current_position);
2550                 n = mouse_angles.z;
2551                 mouse_angles = vectoangles(dir);
2552                 mouse_angles.x = mouse_angles.x * -1;
2553                 mouse_angles.z = n;
2554         }
2555         else
2556         {
2557                 tmp = getmousepos() * 0.1;
2558                 if(vdist(tmp, >, autocvar_camera_mouse_threshold))
2559                 {
2560                         mouse_angles.x += tmp.y * cos(mouse_angles.z * DEG2RAD) + (tmp.x * sin(mouse_angles.z * DEG2RAD));
2561                         mouse_angles.y -= tmp.x * cos(mouse_angles.z * DEG2RAD) + (tmp.y * -sin(mouse_angles.z * DEG2RAD));
2562                 }
2563         }
2564
2565         while (mouse_angles.x < -180) mouse_angles.x = mouse_angles.x + 360;
2566         while (mouse_angles.x > 180) mouse_angles.x = mouse_angles.x - 360;
2567         while (mouse_angles.y < -180) mouse_angles.y = mouse_angles.y + 360;
2568         while (mouse_angles.y > 180) mouse_angles.y = mouse_angles.y - 360;
2569
2570         // Fix difference when angles don't have the same sign
2571         delta = '0 0 0';
2572         if(mouse_angles.y < -60 && current_angles.y > 60)
2573                 delta = '0 360 0';
2574         if(mouse_angles.y > 60 && current_angles.y < -60)
2575                 delta = '0 -360 0';
2576
2577         if(autocvar_camera_look_player)
2578                 attenuation = autocvar_camera_look_attenuation;
2579         else
2580                 attenuation = autocvar_camera_speed_attenuation;
2581
2582         attenuation = 1 / max(1, attenuation);
2583         current_angles += (mouse_angles - current_angles + delta) * attenuation;
2584
2585         while (current_angles.x < -180) current_angles.x = current_angles.x + 360;
2586         while (current_angles.x > 180) current_angles.x = current_angles.x - 360;
2587         while (current_angles.y < -180) current_angles.y = current_angles.y + 360;
2588         while (current_angles.y > 180) current_angles.y = current_angles.y - 360;
2589
2590         // Camera position
2591         tmp = '0 0 0';
2592         dimensions = 0;
2593
2594         if( camera_direction.x )
2595         {
2596                 tmp.x = camera_direction.x * cos(current_angles.y * DEG2RAD);
2597                 tmp.y = camera_direction.x * sin(current_angles.y * DEG2RAD);
2598                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
2599                         tmp.z = camera_direction.x * -sin(current_angles.x * DEG2RAD);
2600                 ++dimensions;
2601         }
2602
2603         if( camera_direction.y )
2604         {
2605                 tmp.x += camera_direction.y * -sin(current_angles.y * DEG2RAD);
2606                 tmp.y += camera_direction.y * cos(current_angles.y * DEG2RAD) * cos(current_angles.z * DEG2RAD);
2607                 tmp.z += camera_direction.y * sin(current_angles.z * DEG2RAD);
2608                 ++dimensions;
2609         }
2610
2611         if( camera_direction.z )
2612         {
2613                 tmp.z += camera_direction.z * cos(current_angles.z * DEG2RAD);
2614                 ++dimensions;
2615         }
2616
2617         if(autocvar_camera_free)
2618                 speed = autocvar_camera_speed_free;
2619         else
2620                 speed = autocvar_camera_speed_chase;
2621
2622         if(dimensions)
2623         {
2624                 speed = speed * sqrt(1 / dimensions);
2625                 camera_offset += tmp * speed;
2626         }
2627
2628         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
2629
2630         // Camera modes
2631         if( autocvar_camera_free )
2632         {
2633                 if ( camera_mode == CAMERA_CHASE )
2634                 {
2635                         current_camera_offset = current_origin + current_camera_offset;
2636                         camera_offset = current_origin + camera_offset;
2637                 }
2638
2639                 camera_mode = CAMERA_FREE;
2640                 current_position = current_camera_offset;
2641         }
2642         else
2643         {
2644                 if ( camera_mode == CAMERA_FREE )
2645                 {
2646                         current_origin = view_origin;
2647                         camera_offset = camera_offset - current_origin;
2648                         current_camera_offset = current_camera_offset - current_origin;
2649                 }
2650
2651                 camera_mode = CAMERA_CHASE;
2652
2653                 if(autocvar_camera_chase_smoothly)
2654                         current_origin += (view_origin - current_origin) * attenuation;
2655                 else
2656                         current_origin = view_origin;
2657
2658                 current_position = current_origin + current_camera_offset;
2659         }
2660
2661         setproperty(VF_ANGLES, current_angles);
2662         setproperty(VF_ORIGIN, current_position);
2663 }