qcsrc/client/view.qc

   1 #include "view.qh"
   2
   3 #include "autocvars.qh"
   4 #include "miscfunctions.qh"
   5 #include "announcer.qh"
   6 #include "hud/_mod.qh"
   7 #include "mapvoting.qh"
   8 #include "shownames.qh"
   9 #include "hud/panel/scoreboard.qh"
  10 #include "hud/panel/quickmenu.qh"
  11
  12 #include <client/mutators/_mod.qh>
  13
  14 #include <common/animdecide.qh>
  15 #include <common/deathtypes/all.qh>
  16 #include <common/ent_cs.qh>
  17 #include <common/anim.qh>
  18 #include <common/constants.qh>
  19 #include <common/net_linked.qh>
  20 #include <common/net_notice.qh>
  21 #include <common/debug.qh>
  22 #include <common/mapinfo.qh>
  23 #include <common/gamemodes/_mod.qh>
  24 #include <common/physics/player.qh>
  25 #include <common/stats.qh>
  26 #include <common/mapobjects/target/music.qh>
  27 #include <common/teams.qh>
  28 #include <common/wepent.qh>
  29
  30 #include <common/weapons/weapon/tuba.qh>
  31
  32 #include <common/vehicles/all.qh>
  33 #include <common/weapons/_all.qh>
  34 #include <common/mutators/mutator/overkill/oknex.qh>
  35 #include <common/mutators/mutator/waypoints/all.qh>
  36 #include <common/viewloc.qh>
  37 #include <common/mapobjects/trigger/viewloc.qh>
  38 #include <common/minigames/cl_minigames.qh>
  39 #include <common/minigames/cl_minigames_hud.qh>
  40
  41 #include <lib/csqcmodel/cl_player.qh>
  42 #include <lib/csqcmodel/cl_model.qh>
  43 #include "csqcmodel_hooks.qh"
  44
  45 #include <lib/warpzone/client.qh>
  46 #include <lib/warpzone/common.qh>
  47
  48 #define EFMASK_CHEAP (EF_ADDITIVE | EF_DOUBLESIDED | EF_FULLBRIGHT | EF_NODEPTHTEST | EF_NODRAW | EF_NOSHADOW | EF_SELECTABLE | EF_TELEPORT_BIT)
  49
  50 float autocvar_cl_viewmodel_scale;
  51 float autocvar_cl_viewmodel_alpha;
  52
  53 bool autocvar_cl_bobmodel;
  54 float autocvar_cl_bobmodel_speed;
  55 float autocvar_cl_bobmodel_side;
  56 float autocvar_cl_bobmodel_up;
  57
  58 float autocvar_cl_followmodel;
  59 float autocvar_cl_followmodel_speed = 0.3;
  60 float autocvar_cl_followmodel_limit = 135;
  61 float autocvar_cl_followmodel_velocity_lowpass = 0.05;
  62 float autocvar_cl_followmodel_highpass = 0.05;
  63 float autocvar_cl_followmodel_lowpass = 0.03;
  64 bool autocvar_cl_followmodel_velocity_absolute;
  65
  66 float autocvar_cl_leanmodel;
  67 float autocvar_cl_leanmodel_speed = 0.3;
  68 float autocvar_cl_leanmodel_limit = 30;
  69 float autocvar_cl_leanmodel_highpass1 = 0.2;
  70 float autocvar_cl_leanmodel_highpass = 0.2;
  71 float autocvar_cl_leanmodel_lowpass = 0.05;
  72
  73 #define avg_factor(avg_time) (1 - exp(-frametime / max(0.001, avg_time)))
  74
  75 #define lowpass(value, frac, ref_store, ret) \
  76         ret = ref_store = ref_store * (1 - frac) + (value) * frac;
  77
  78 #define lowpass_limited(value, frac, limit, ref_store, ret) MACRO_BEGIN \
  79         float __ignore; lowpass(value, frac, ref_store, __ignore); \
  80         ret = ref_store = bound((value) - (limit), ref_store, (value) + (limit)); \
  81 MACRO_END
  82
  83 #define highpass(value, frac, ref_store, ret) MACRO_BEGIN \
  84         float __f = 0; lowpass(value, frac, ref_store, __f); \
  85         ret = (value) - __f; \
  86 MACRO_END
  87
  88 #define highpass_limited(value, frac, limit, ref_store, ret) MACRO_BEGIN \
  89         float __f = 0; lowpass_limited(value, frac, limit, ref_store, __f); \
  90         ret = (value) - __f; \
  91 MACRO_END
  92
  93 #define lowpass2(value, frac, ref_store, ref_out) MACRO_BEGIN \
  94         lowpass(value.x, frac, ref_store.x, ref_out.x); \
  95         lowpass(value.y, frac, ref_store.y, ref_out.y); \
  96 MACRO_END
  97
  98 #define highpass2(value, frac, ref_store, ref_out) MACRO_BEGIN \
  99         highpass(value.x, frac, ref_store.x, ref_out.x); \
 100         highpass(value.y, frac, ref_store.y, ref_out.y); \
 101 MACRO_END
 102
 103 #define highpass2_limited(value, frac, limit, ref_store, ref_out) MACRO_BEGIN \
 104         highpass_limited(value.x, frac, limit, ref_store.x, ref_out.x); \
 105         highpass_limited(value.y, frac, limit, ref_store.y, ref_out.y); \
 106 MACRO_END
 107
 108 #define lowpass3(value, frac, ref_store, ref_out) MACRO_BEGIN \
 109         lowpass(value.x, frac, ref_store.x, ref_out.x); \
 110         lowpass(value.y, frac, ref_store.y, ref_out.y); \
 111         lowpass(value.z, frac, ref_store.z, ref_out.z); \
 112 MACRO_END
 113
 114 #define highpass3(value, frac, ref_store, ref_out) MACRO_BEGIN \
 115         highpass(value.x, frac, ref_store.x, ref_out.x); \
 116         highpass(value.y, frac, ref_store.y, ref_out.y); \
 117         highpass(value.z, frac, ref_store.z, ref_out.z); \
 118 MACRO_END
 119
 120 void calc_followmodel_ofs(entity view)
 121 {
 122         if(cl_followmodel_time == time)
 123                 return; // cl_followmodel_ofs already calculated for this frame
 124
 125         float frac;
 126         vector gunorg = '0 0 0';
 127         static vector vel_average;
 128         static vector gunorg_adjustment_highpass;
 129         static vector gunorg_adjustment_lowpass;
 130
 131         vector vel;
 132         if (autocvar_cl_followmodel_velocity_absolute)
 133                 vel = view.velocity;
 134         else
 135         {
 136                 vector forward = '0 0 0', right = '0 0 0', up = '0 0 0';
 137                 MAKEVECTORS(makevectors, view_angles, forward, right, up);
 138                 vel.x = view.velocity * forward;
 139                 vel.y = view.velocity * right * -1;
 140                 vel.z = view.velocity * up;
 141         }
 142
 143         vel.x = bound(vel_average.x - autocvar_cl_followmodel_limit, vel.x, vel_average.x + autocvar_cl_followmodel_limit);
 144         vel.y = bound(vel_average.y - autocvar_cl_followmodel_limit, vel.y, vel_average.y + autocvar_cl_followmodel_limit);
 145         vel.z = bound(vel_average.z - autocvar_cl_followmodel_limit, vel.z, vel_average.z + autocvar_cl_followmodel_limit);
 146
 147         frac = avg_factor(autocvar_cl_followmodel_velocity_lowpass);
 148         lowpass3(vel, frac, vel_average, gunorg);
 149
 150         gunorg *= -autocvar_cl_followmodel_speed * 0.042;
 151
 152         // perform highpass/lowpass on the adjustment vectors (turning velocity into acceleration!)
 153         // trick: we must do the lowpass LAST, so the lowpass vector IS the final vector!
 154         frac = avg_factor(autocvar_cl_followmodel_highpass);
 155         highpass3(gunorg, frac, gunorg_adjustment_highpass, gunorg);
 156         frac = avg_factor(autocvar_cl_followmodel_lowpass);
 157         lowpass3(gunorg, frac, gunorg_adjustment_lowpass, gunorg);
 158
 159         if (autocvar_cl_followmodel_velocity_absolute)
 160         {
 161                 vector fixed_gunorg;
 162                 vector forward = '0 0 0', right = '0 0 0', up = '0 0 0';
 163                 MAKEVECTORS(makevectors, view_angles, forward, right, up);
 164                 fixed_gunorg.x = gunorg * forward;
 165                 fixed_gunorg.y = gunorg * right * -1;
 166                 fixed_gunorg.z = gunorg * up;
 167                 gunorg = fixed_gunorg;
 168         }
 169
 170         cl_followmodel_ofs = gunorg;
 171         cl_followmodel_time = time;
 172 }
 173
 174 vector leanmodel_ofs(entity view)
 175 {
 176         float frac;
 177         vector gunangles = '0 0 0';
 178         static vector gunangles_prev = '0 0 0';
 179         static vector gunangles_highpass = '0 0 0';
 180         static vector gunangles_adjustment_highpass;
 181         static vector gunangles_adjustment_lowpass;
 182
 183         if (view.csqcmodel_teleported)
 184                 gunangles_prev = view_angles;
 185
 186         // in the highpass, we _store_ the DIFFERENCE to the actual view angles...
 187         gunangles_highpass += gunangles_prev;
 188         PITCH(gunangles_highpass) += 360 * floor((PITCH(view_angles) - PITCH(gunangles_highpass)) / 360 + 0.5);
 189         YAW(gunangles_highpass) += 360 * floor((YAW(view_angles) - YAW(gunangles_highpass)) / 360 + 0.5);
 190         ROLL(gunangles_highpass) += 360 * floor((ROLL(view_angles) - ROLL(gunangles_highpass)) / 360 + 0.5);
 191         frac = avg_factor(autocvar_cl_leanmodel_highpass1);
 192         highpass2_limited(view_angles, frac, autocvar_cl_leanmodel_limit, gunangles_highpass, gunangles);
 193         gunangles_prev = view_angles;
 194         gunangles_highpass -= gunangles_prev;
 195
 196         PITCH(gunangles) *= -autocvar_cl_leanmodel_speed;
 197         YAW(gunangles) *= -autocvar_cl_leanmodel_speed;
 198
 199         // we assume here: PITCH = 0, YAW = 1, ROLL = 2
 200         frac = avg_factor(autocvar_cl_leanmodel_highpass);
 201         highpass2(gunangles, frac, gunangles_adjustment_highpass, gunangles);
 202         frac = avg_factor(autocvar_cl_leanmodel_lowpass);
 203         lowpass2(gunangles, frac, gunangles_adjustment_lowpass, gunangles);
 204
 205         gunangles.x = -gunangles.x; // pitch was inverted, now that actually matters
 206
 207         return gunangles;
 208 }
 209
 210 vector bobmodel_ofs(entity view)
 211 {
 212         bool clonground = !(view.anim_implicit_state & ANIMIMPLICITSTATE_INAIR);
 213         static bool oldonground;
 214         static float hitgroundtime;
 215         if (clonground)
 216         {
 217                 float f = time; // cl.movecmd[0].time
 218                 if (!oldonground)
 219                         hitgroundtime = f;
 220         }
 221         oldonground = clonground;
 222
 223         // calculate for swinging gun model
 224         // the gun bobs when running on the ground, but doesn't bob when you're in the air.
 225         vector gunorg = '0 0 0';
 226         static float bobmodel_scale = 0;
 227         static float time_ofs = 0; // makes the effect always restart in the same way
 228         if (clonground)
 229         {
 230                 if (time - hitgroundtime > 0.05)
 231                         bobmodel_scale = min(1, bobmodel_scale + frametime * 5);
 232         }
 233         else
 234                 bobmodel_scale = max(0, bobmodel_scale - frametime * 5);
 235
 236         float xyspeed = bound(0, vlen(vec2(view.velocity)), 400);
 237         if (bobmodel_scale && xyspeed)
 238         {
 239                 float bspeed = xyspeed * 0.01 * autocvar_cl_viewmodel_scale * bobmodel_scale;
 240                 float s = (time - time_ofs) * autocvar_cl_bobmodel_speed;
 241                 gunorg.y = bspeed * autocvar_cl_bobmodel_side * sin(s);
 242                 gunorg.z = bspeed * autocvar_cl_bobmodel_up * cos(s * 2);
 243         }
 244         else
 245                 time_ofs = time;
 246
 247         return gunorg;
 248 }
 249
 250 void viewmodel_animate(entity this)
 251 {
 252         if (autocvar_chase_active) return;
 253         if (STAT(HEALTH) <= 0) return;
 254
 255         entity view = CSQCModel_server2csqc(player_localentnum - 1);
 256
 257         if (autocvar_cl_followmodel)
 258         {
 259                 calc_followmodel_ofs(view);
 260                 this.origin += cl_followmodel_ofs;
 261         }
 262
 263         if (autocvar_cl_leanmodel)
 264                 this.angles += leanmodel_ofs(view);
 265
 266         // vertical view bobbing code
 267         // TODO: cl_bob
 268
 269         // horizontal view bobbing code
 270         // TODO: cl_bob2
 271
 272         // fall bobbing code
 273         // causes the view to swing down and back up when touching the ground
 274         // TODO: cl_bobfall
 275
 276         // gun model bobbing code
 277         if (autocvar_cl_bobmodel)
 278                 this.origin += bobmodel_ofs(view);
 279 }
 280
 281 .vector viewmodel_origin, viewmodel_angles;
 282 .float weapon_nextthink;
 283 .float weapon_eta_last;
 284 .float weapon_switchdelay;
 285
 286 .string name_last;
 287
 288 void viewmodel_draw(entity this)
 289 {
 290         if(!this.activeweapon || !autocvar_r_drawviewmodel)
 291                 return;
 292         int mask = (intermission || (STAT(HEALTH) <= 0) || autocvar_chase_active) ? 0 : MASK_NORMAL;
 293         float a = ((autocvar_cl_viewmodel_alpha) ? bound(-1, autocvar_cl_viewmodel_alpha, this.m_alpha) : this.m_alpha);
 294         bool invehicle = player_localentnum > maxclients;
 295         if (invehicle) a = -1;
 296         Weapon wep = this.activeweapon;
 297         int c = entcs_GetClientColors(current_player);
 298         vector g = weaponentity_glowmod(wep, NULL, c, this);
 299         entity me = CSQCModel_server2csqc(player_localentnum - 1);
 300         int fx = ((me.csqcmodel_effects & EFMASK_CHEAP)
 301                 | EF_NODEPTHTEST)
 302                 &~ (EF_FULLBRIGHT); // can mask team color, so get rid of it
 303         for (entity e = this; e; e = e.weaponchild)
 304         {
 305                 e.drawmask = mask;
 306                 e.alpha = a;
 307                 e.colormap = 256 + c;  // colormap == 0 is black, c == 0 is white
 308                 e.glowmod = g;
 309                 e.csqcmodel_effects = fx;
 310                 CSQCModel_Effects_Apply(e);
 311         }
 312         if(a >= 0)
 313         {
 314                 string name = wep.mdl;
 315                 string newname = wep.wr_viewmodel(wep, this);
 316                 if(newname)
 317                         name = newname;
 318                 bool swap = name != this.name_last;
 319                 // if (swap)
 320                 {
 321                         this.name_last = name;
 322                         CL_WeaponEntity_SetModel(this, name, swap);
 323                         this.viewmodel_origin = this.origin;
 324                         this.viewmodel_angles = this.angles;
 325                 }
 326                 anim_update(this);
 327                 if ((!this.animstate_override && !this.animstate_looping) || time > this.animstate_endtime)
 328                         anim_set(this, this.anim_idle, true, false, false);
 329         }
 330         float f = 0; // 0..1; 0: fully active
 331         float rate = STAT(WEAPONRATEFACTOR);
 332         float eta = rate ? ((this.weapon_nextthink - time) / rate) : 0;
 333         if (eta <= 0) f = this.weapon_eta_last;
 334         else switch (this.state)
 335         {
 336                 case WS_RAISE:
 337                 {
 338                         f = eta / max(eta, this.weapon_switchdelay);
 339                         break;
 340                 }
 341                 case WS_DROP:
 342                 {
 343                         f = 1 - eta / max(eta, this.weapon_switchdelay);
 344                         break;
 345                 }
 346                 case WS_CLEAR:
 347                 {
 348                         f = 1;
 349                         break;
 350                 }
 351         }
 352         this.weapon_eta_last = f;
 353         this.origin = this.viewmodel_origin;
 354         this.angles = this.viewmodel_angles;
 355         this.angles_x = (-90 * f * f);
 356         viewmodel_animate(this);
 357         MUTATOR_CALLHOOK(DrawViewModel, this);
 358         setorigin(this, this.origin);
 359 }
 360
 361 STATIC_INIT(viewmodel) {
 362     for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 363         viewmodels[slot] = new(viewmodel);
 364 }
 365
 366 float showfps_prevfps;
 367 float showfps_prevfps_time;
 368 int showfps_framecounter;
 369
 370 void fpscounter_update()
 371 {
 372         if(!STAT(SHOWFPS))
 373                 return;
 374
 375         float currentTime = gettime(GETTIME_REALTIME);
 376         showfps_framecounter += 1;
 377         if(currentTime - showfps_prevfps_time > STAT(SHOWFPS))
 378         {
 379                 showfps_prevfps = showfps_framecounter/(currentTime - showfps_prevfps_time);
 380                 showfps_framecounter = 0;
 381                 showfps_prevfps_time = currentTime;
 382
 383                 int channel = MSG_C2S;
 384                 WriteHeader(channel, fpsreport);
 385                 WriteShort(channel, bound(0, rint(showfps_prevfps), 65535)); // prevent insane fps values
 386         }
 387 }
 388
 389 STATIC_INIT(fpscounter_init)
 390 {
 391         float currentTime = gettime(GETTIME_REALTIME);
 392         showfps_prevfps_time = currentTime; // we must initialize it to avoid an instant low frame sending
 393 }
 394
 395 STATIC_INIT(Porto)
 396 {
 397         entity e = new_pure(porto);
 398         e.draw = Porto_Draw;
 399         IL_PUSH(g_drawables, e);
 400         e.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 401 }
 402
 403 const int polyline_length = 16;
 404 .vector polyline[polyline_length];
 405 void Porto_Draw(entity this)
 406 {
 407         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 408         {
 409                 entity wepent = viewmodels[slot];
 410
 411                 if (wepent.activeweapon != WEP_PORTO) continue;
 412                 if (spectatee_status) continue;
 413                 if (WEP_CVAR(porto, secondary)) continue;
 414                 if (intermission == 1) continue;
 415                 if (intermission == 2) continue;
 416                 if (STAT(HEALTH) <= 0) continue;
 417
 418                 vector pos = view_origin;
 419                 vector dir = view_forward;
 420                 makevectors(((autocvar_chase_active) ? warpzone_save_view_angles : view_angles));
 421                 pos += v_right * -wepent.movedir.y
 422                         +  v_up * wepent.movedir.z;
 423
 424                 if (wepent.angles_held_status)
 425                 {
 426                         makevectors(wepent.angles_held);
 427                         dir = v_forward;
 428                 }
 429
 430                 wepent.polyline[0] = pos;
 431
 432                 int portal_number = 0, portal1_idx = 1, portal_max = 2;
 433                 int n = 1 + 2;  // 2 lines == 3 points
 434                 for (int idx = 0; idx < n && idx < polyline_length - 1; )
 435                 {
 436                         traceline(pos, pos + 65536 * dir, true, this);
 437                         dir = reflect(dir, trace_plane_normal);
 438                         pos = trace_endpos;
 439                         wepent.polyline[++idx] = pos;
 440                         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
 441                         {
 442                                 n += 1;
 443                                 continue;
 444                         }
 445                         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
 446                         {
 447                                 n = max(2, idx);
 448                                 break;
 449                         }
 450                         // check size
 451                         {
 452                                 vector ang = vectoangles2(trace_plane_normal, dir);
 453                                 ang.x = -ang.x;
 454                                 makevectors(ang);
 455                                 if (!CheckWireframeBox(this, pos - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
 456                                 {
 457                                         n = max(2, idx);
 458                                         break;
 459                                 }
 460                         }
 461                         portal_number += 1;
 462                         if (portal_number >= portal_max) break;
 463                         if (portal_number == 1) portal1_idx = idx;
 464                 }
 465                 for (int idx = 0; idx < n - 1; ++idx)
 466                 {
 467                         vector p = wepent.polyline[idx], q = wepent.polyline[idx + 1];
 468                         if (idx == 0) p -= view_up * 16;  // line from player
 469                         vector rgb = (idx < portal1_idx) ? '1 0 0' : '0 0 1';
 470                         Draw_CylindricLine(p, q, 4, "", 1, 0, rgb, 0.5, DRAWFLAG_NORMAL, view_origin);
 471                 }
 472         }
 473 }
 474
 475 float drawtime;
 476 float avgspeed;
 477 vector GetCurrentFov(float fov)
 478 {
 479         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir;
 480         float velocityzoom, curspeed;
 481         vector v;
 482
 483         zoomsensitivity = autocvar_cl_zoomsensitivity;
 484         zoomfactor = autocvar_cl_zoomfactor;
 485         if(zoomfactor < 1 || zoomfactor > 30)
 486                 zoomfactor = 2.5;
 487         zoomspeed = autocvar_cl_zoomspeed;
 488         if (zoomspeed >= 0 && (zoomspeed < 0.5 || zoomspeed > 16))
 489                 zoomspeed = 3.5;
 490
 491         zoomdir = button_zoom;
 492
 493         if(hud == HUD_NORMAL && !spectatee_status)
 494         {
 495                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 496                 {
 497                         entity wepent = viewmodels[slot];
 498                         if(wepent.switchweapon != wepent.activeweapon)
 499                                 continue;
 500                         Weapon wep = wepent.activeweapon;
 501                         if(wep != WEP_Null && wep.wr_zoomdir)
 502                         {
 503                                 bool do_zoom = wep.wr_zoomdir(wep); // TODO: merge this with wr_zoom?
 504                                 zoomdir += do_zoom;
 505                         }
 506                 }
 507         }
 508         if(spectatee_status > 0 || isdemo())
 509         {
 510                 if(spectatorbutton_zoom)
 511                 {
 512                         if(zoomdir)
 513                                 zoomdir = 0;
 514                         else
 515                                 zoomdir = 1;
 516                 }
 517                 // fteqcc failed twice here already, don't optimize this
 518         }
 519
 520         if(zoomdir) { zoomin_effect = 0; }
 521
 522         if (spectatee_status > 0 && STAT(CAMERA_SPECTATOR) == 2)
 523         {
 524                 current_viewzoom = 1;
 525         }
 526         else if (camera_active)
 527         {
 528                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 529         }
 530         else if(autocvar_cl_spawnzoom && zoomin_effect)
 531         {
 532                 float spawnzoomfactor = bound(1, autocvar_cl_spawnzoom_factor, 30);
 533
 534                 current_viewzoom += (autocvar_cl_spawnzoom_speed * (spawnzoomfactor - current_viewzoom) * drawframetime);
 535                 current_viewzoom = bound(1 / spawnzoomfactor, current_viewzoom, 1);
 536                 if(current_viewzoom == 1) { zoomin_effect = 0; }
 537         }
 538         else
 539         {
 540                 if(zoomspeed < 0) // instant zoom
 541                 {
 542                         if(zoomdir)
 543                                 current_viewzoom = 1 / zoomfactor;
 544                         else
 545                                 current_viewzoom = 1;
 546                 }
 547                 else
 548                 {
 549                         if(zoomdir)
 550                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 551                         else
 552                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 553                 }
 554         }
 555
 556         if(almost_equals(current_viewzoom, 1))
 557                 current_zoomfraction = 0;
 558         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 559                 current_zoomfraction = 1;
 560         else
 561                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 562
 563         if(zoomsensitivity < 1)
 564                 setsensitivityscale(current_viewzoom ** (1 - zoomsensitivity));
 565         else
 566                 setsensitivityscale(1);
 567
 568         if(autocvar_cl_velocityzoom_enabled && autocvar_cl_velocityzoom_type) // _type = 0 disables velocity zoom too
 569         {
 570                 if (intermission || (spectatee_status > 0 && STAT(CAMERA_SPECTATOR) == 2))
 571                         curspeed = 0;
 572                 else
 573                 {
 574                         makevectors(view_angles);
 575                         v = pmove_vel;
 576                         if(csqcplayer)
 577                                 v = csqcplayer.velocity;
 578
 579                         switch(autocvar_cl_velocityzoom_type)
 580                         {
 581                                 case 3: curspeed = max(0, v_forward * v); break;
 582                                 case 2: curspeed = (v_forward * v); break;
 583                                 case 1: default: curspeed = vlen(v); break;
 584                         }
 585                 }
 586
 587                 velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoom_time), 1); // speed at which the zoom adapts to player velocity
 588                 avgspeed = avgspeed * (1 - velocityzoom) + (curspeed / autocvar_cl_velocityzoom_speed) * velocityzoom;
 589                 velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom_factor / 1) * 1);
 590
 591                 //print(ftos(avgspeed), " avgspeed, ", ftos(curspeed), " curspeed, ", ftos(velocityzoom), " return\n"); // for debugging
 592         }
 593         else
 594                 velocityzoom = 1;
 595
 596         float frustumx, frustumy, fovx, fovy;
 597         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 598         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 599         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 600         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 601
 602         return '1 0 0' * fovx + '0 1 0' * fovy;
 603 }
 604
 605 vector GetViewLocationFOV(float fov)
 606 {
 607         float frustumy = tan(fov * M_PI / 360.0) * 0.75;
 608         float frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 609         float fovx = atan2(frustumx, 1) / M_PI * 360.0;
 610         float fovy = atan2(frustumy, 1) / M_PI * 360.0;
 611         return '1 0 0' * fovx + '0 1 0' * fovy;
 612 }
 613
 614 vector GetOrthoviewFOV(vector ov_worldmin, vector ov_worldmax, vector ov_mid, vector ov_org)
 615 {
 616         float fovx, fovy;
 617         float width = (ov_worldmax.x - ov_worldmin.x);
 618         float height = (ov_worldmax.y - ov_worldmin.y);
 619         float distance_to_middle_of_world = vlen(ov_mid - ov_org);
 620         fovx = atan2(width/2, distance_to_middle_of_world) / M_PI * 360.0;
 621         fovy = atan2(height/2, distance_to_middle_of_world) / M_PI * 360.0;
 622         return '1 0 0' * fovx + '0 1 0' * fovy;
 623 }
 624
 625 // this function must match W_SetupShot!
 626 float zoomscript_caught;
 627
 628 bool minigame_wasactive;
 629
 630 vector wcross_origin;
 631 float wcross_scale_prev, wcross_alpha_prev;
 632 vector wcross_color_prev;
 633 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 634 vector wcross_color_goal_prev;
 635 float wcross_changedonetime;
 636
 637 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 638 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 639 float wcross_name_changestarttime, wcross_name_changedonetime;
 640 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 641
 642 float wcross_ring_prev;
 643
 644 entity trueaim;
 645 entity trueaim_rifle;
 646
 647 const float SHOTTYPE_HITTEAM = 1;
 648 const float SHOTTYPE_HITOBSTRUCTION = 2;
 649 const float SHOTTYPE_HITWORLD = 3;
 650 const float SHOTTYPE_HITENEMY = 4;
 651
 652 void TrueAim_Init()
 653 {
 654         (trueaim = new_pure(trueaim)).dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 655         (trueaim_rifle = new_pure(trueaim_rifle)).dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 656 }
 657
 658 float EnemyHitCheck()
 659 {
 660         float t, n;
 661         wcross_origin = project_3d_to_2d(trace_endpos);
 662         wcross_origin.z = 0;
 663         if(trace_ent)
 664                 n = trace_ent.entnum;
 665         else
 666                 n = trace_networkentity;
 667         if(n < 1)
 668                 return SHOTTYPE_HITWORLD;
 669         if(n > maxclients)
 670                 return SHOTTYPE_HITWORLD;
 671         t = entcs_GetTeam(n - 1);
 672         if(teamplay)
 673                 if(t == myteam)
 674                         return SHOTTYPE_HITTEAM;
 675         if(t == NUM_SPECTATOR)
 676                 return SHOTTYPE_HITWORLD;
 677         return SHOTTYPE_HITENEMY;
 678 }
 679
 680 float TrueAimCheck(entity wepent)
 681 {
 682         float nudge = 1; // added to traceline target and subtracted from result TOOD(divVerent): do we still need this? Doesn't the engine do this now for us?
 683         vector vecs, trueaimpoint, w_shotorg;
 684         vector mi, ma, dv;
 685         float shottype;
 686         entity ta;
 687         float mv;
 688
 689         mi = ma = '0 0 0';
 690         ta = trueaim;
 691         mv = MOVE_NOMONSTERS;
 692
 693         switch(wepent.activeweapon) // WEAPONTODO
 694         {
 695                 case WEP_TUBA: // no aim
 696                 case WEP_PORTO: // shoots from eye
 697                 case WEP_NEXBALL: // shoots from eye
 698                 case WEP_HOOK: // no trueaim
 699                 case WEP_MORTAR: // toss curve
 700                         return SHOTTYPE_HITWORLD;
 701                 case WEP_VORTEX:
 702                 case WEP_OVERKILL_NEX:
 703                 case WEP_VAPORIZER:
 704                         mv = MOVE_NORMAL;
 705                         break;
 706                 case WEP_RIFLE:
 707                         ta = trueaim_rifle;
 708                         mv = MOVE_NORMAL;
 709                         if(zoomscript_caught)
 710                         {
 711                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * max_shot_distance, mv, ta);
 712                                 return EnemyHitCheck();
 713                         }
 714                         break;
 715                 case WEP_DEVASTATOR: // projectile has a size!
 716                         mi = '-3 -3 -3';
 717                         ma = '3 3 3';
 718                         break;
 719                 case WEP_FIREBALL: // projectile has a size!
 720                         mi = '-16 -16 -16';
 721                         ma = '16 16 16';
 722                         break;
 723                 case WEP_SEEKER: // projectile has a size!
 724                         mi = '-2 -2 -2';
 725                         ma = '2 2 2';
 726                         break;
 727                 case WEP_ELECTRO: // projectile has a size!
 728                         mi = '0 0 -3';
 729                         ma = '0 0 -3';
 730                         break;
 731         }
 732
 733         vector traceorigin = entcs_receiver(player_localentnum - 1).origin + (eZ * STAT(VIEWHEIGHT));
 734
 735         vecs = decompressShotOrigin(STAT(SHOTORG));
 736
 737         traceline(traceorigin, traceorigin + view_forward * max_shot_distance, mv, ta);
 738         trueaimpoint = trace_endpos;
 739
 740         if(vdist((trueaimpoint - traceorigin), <, g_trueaim_minrange))
 741                 trueaimpoint = traceorigin + view_forward * g_trueaim_minrange;
 742
 743         if(vecs.x > 0)
 744                 vecs.y = -vecs.y;
 745         else
 746                 vecs = '0 0 0';
 747
 748         dv = view_right * vecs.y + view_up * vecs.z;
 749         w_shotorg = traceorigin + dv;
 750
 751         // now move the vecs forward as much as requested if possible
 752         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs.x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 753         w_shotorg = trace_endpos - view_forward * nudge;
 754
 755         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 756         shottype = EnemyHitCheck();
 757         if(shottype != SHOTTYPE_HITWORLD)
 758                 return shottype;
 759
 760 #if 0
 761         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 762         // or rather, I know why, but see no fix
 763         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 764                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 765                 return SHOTTYPE_HITOBSTRUCTION;
 766 #endif
 767
 768         return SHOTTYPE_HITWORLD;
 769 }
 770
 771 float camera_mode;
 772 const float CAMERA_FREE = 1;
 773 const float CAMERA_CHASE = 2;
 774 float reticle_type;
 775 string NextFrameCommand;
 776
 777 vector freeze_org, freeze_ang;
 778 entity nightvision_noise, nightvision_noise2;
 779
 780 const float MAX_TIME_DIFF = 5;
 781 float pickup_crosshair_time, pickup_crosshair_size;
 782 float hitindication_crosshair_size;
 783 float use_vortex_chargepool;
 784
 785 float myhealth, myhealth_prev;
 786 float myhealth_flash;
 787
 788 float old_blurradius, old_bluralpha;
 789 float old_sharpen_intensity;
 790
 791 vector myhealth_gentlergb;
 792
 793 float contentavgalpha, liquidalpha_prev;
 794 vector liquidcolor_prev;
 795
 796 float eventchase_current_distance;
 797 float eventchase_running;
 798 int WantEventchase(entity this)
 799 {
 800         if(autocvar_cl_orthoview)
 801                 return 0;
 802         if(STAT(GAME_STOPPED) || intermission)
 803                 return 1;
 804         if(this.viewloc)
 805                 return 1;
 806         if(spectatee_status >= 0)
 807         {
 808                 if(hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0))
 809                         return 1;
 810                 if(MUTATOR_CALLHOOK(WantEventchase, this))
 811                         return 1;
 812                 if(autocvar_cl_eventchase_frozen && STAT(FROZEN))
 813                         return 1;
 814                 if(autocvar_cl_eventchase_death && (STAT(HEALTH) <= 0))
 815                 {
 816                         if(autocvar_cl_eventchase_death == 2)
 817                         {
 818                                 // don't stop eventchase once it's started (even if velocity changes afterwards)
 819                                 if(this.velocity == '0 0 0' || eventchase_running)
 820                                         return 1;
 821                         }
 822                         else return 1;
 823                 }
 824                 if (spectatee_status > 0 && autocvar_cl_eventchase_spectated_change)
 825                 {
 826                         if (time <= spectatee_status_changed_time + min(3, autocvar_cl_eventchase_spectated_change_time))
 827                                 return 1;
 828                         else if (eventchase_running)
 829                                 return -1; // disable chase_active while eventchase is still enabled so to avoid a glicth
 830                 }
 831         }
 832         return 0;
 833 }
 834
 835 void HUD_Crosshair_Vehicle(entity this)
 836 {
 837         if(hud != HUD_BUMBLEBEE_GUN)
 838         {
 839                 Vehicle info = Vehicles_from(hud);
 840                 info.vr_crosshair(info, this);
 841         }
 842 }
 843
 844 vector damage_blurpostprocess, content_blurpostprocess;
 845
 846 float unaccounted_damage = 0;
 847 void UpdateDamage()
 848 {
 849         // accumulate damage with each stat update
 850         static float damage_total_prev = 0;
 851         float damage_total = STAT(DAMAGE_DEALT_TOTAL);
 852         float unaccounted_damage_new = COMPARE_INCREASING(damage_total, damage_total_prev);
 853         damage_total_prev = damage_total;
 854
 855         static float damage_dealt_time_prev = 0;
 856         float damage_dealt_time = STAT(HIT_TIME);
 857         if (damage_dealt_time != damage_dealt_time_prev)
 858         {
 859                 unaccounted_damage += unaccounted_damage_new;
 860                 LOG_TRACE("dmg total: ", ftos(unaccounted_damage), " (+", ftos(unaccounted_damage_new), ")");
 861         }
 862         damage_dealt_time_prev = damage_dealt_time;
 863
 864         // prevent hitsound when switching spectatee
 865         static float spectatee_status_prev = 0;
 866         if (spectatee_status != spectatee_status_prev)
 867                 unaccounted_damage = 0;
 868         spectatee_status_prev = spectatee_status;
 869 }
 870
 871 void HitSound()
 872 {
 873         // varying sound pitch
 874
 875         bool have_arc = false;
 876         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 877         {
 878                 entity wepent = viewmodels[slot];
 879
 880                 if(wepent.activeweapon == WEP_ARC)
 881                         have_arc = true;
 882         }
 883
 884         static float hitsound_time_prev = 0;
 885         // HACK: the only way to get the arc to sound consistent with pitch shift is to ignore cl_hitsound_antispam_time
 886         bool arc_hack = have_arc && autocvar_cl_hitsound >= 2;
 887         if (arc_hack || COMPARE_INCREASING(time, hitsound_time_prev) > autocvar_cl_hitsound_antispam_time)
 888         {
 889                 if (autocvar_cl_hitsound && unaccounted_damage)
 890                 {
 891                         // customizable gradient function that crosses (0,a), (c,1) and asymptotically approaches b
 892                         float a = autocvar_cl_hitsound_max_pitch;
 893                         float b = autocvar_cl_hitsound_min_pitch;
 894                         float c = autocvar_cl_hitsound_nom_damage;
 895                         float d = unaccounted_damage;
 896                         float pitch_shift = (b*d*(a-1) + a*c*(1-b)) / (d*(a-1) + c*(1-b));
 897
 898                         // if sound variation is disabled, set pitch_shift to 1
 899                         if (autocvar_cl_hitsound == 1)
 900                                 pitch_shift = 1;
 901
 902                         // if pitch shift is reversed, mirror in (max-min)/2 + min
 903                         if (autocvar_cl_hitsound == 3)
 904                         {
 905                                 float mirror_value = (a-b)/2 + b;
 906                                 pitch_shift = mirror_value + (mirror_value - pitch_shift);
 907                         }
 908
 909                         LOG_TRACE("dmg total (dmg): ", ftos(unaccounted_damage), " , pitch shift: ", ftos(pitch_shift));
 910
 911                         // todo: avoid very long and very short sounds from wave stretching using different sound files? seems unnecessary
 912                         // todo: normalize sound pressure levels? seems unnecessary
 913
 914                         sound7(NULL, CH_INFO, SND(HIT), VOL_BASE, ATTN_NONE, pitch_shift * 100, 0);
 915                 }
 916                 unaccounted_damage = 0;
 917                 hitsound_time_prev = time;
 918         }
 919
 920         static float typehit_time_prev = 0;
 921         float typehit_time = STAT(TYPEHIT_TIME);
 922         if (COMPARE_INCREASING(typehit_time, typehit_time_prev) > autocvar_cl_hitsound_antispam_time)
 923         {
 924                 sound(NULL, CH_INFO, SND_TYPEHIT, VOL_BASE, ATTN_NONE);
 925                 typehit_time_prev = typehit_time;
 926         }
 927
 928         static float kill_time_prev = 0;
 929         float kill_time = STAT(KILL_TIME);
 930         if (COMPARE_INCREASING(kill_time, kill_time_prev) > autocvar_cl_hitsound_antispam_time)
 931         {
 932                 sound(NULL, CH_INFO, SND_KILL, VOL_BASE, ATTN_NONE);
 933                 kill_time_prev = kill_time;
 934         }
 935 }
 936
 937 vector crosshair_getcolor(entity this, float health_stat)
 938 {
 939         static float rainbow_last_flicker;
 940         static vector rainbow_prev_color;
 941         vector wcross_color = '0 0 0';
 942         switch(autocvar_crosshair_color_special)
 943         {
 944                 case 1: // crosshair_color_per_weapon
 945                 {
 946                         if(this != WEP_Null && hud == HUD_NORMAL)
 947                         {
 948                                 wcross_color = this.wpcolor;
 949                                 break;
 950                         }
 951                         else { goto normalcolor; }
 952                 }
 953
 954                 case 2: // crosshair_color_by_health
 955                 {
 956                         vector v = healtharmor_maxdamage(health_stat, STAT(ARMOR), armorblockpercent, DEATH_WEAPON.m_id);
 957                         float hp = floor(v.x + 1);
 958
 959                         //x = red
 960                         //y = green
 961                         //z = blue
 962
 963                         wcross_color.z = 0;
 964
 965                         if(hp > 200)
 966                         {
 967                                 wcross_color.x = 0;
 968                                 wcross_color.y = 1;
 969                         }
 970                         else if(hp > 150)
 971                         {
 972                                 wcross_color.x = 0.4 - (hp-150)*0.02 * 0.4;
 973                                 wcross_color.y = 0.9 + (hp-150)*0.02 * 0.1;
 974                         }
 975                         else if(hp > 100)
 976                         {
 977                                 wcross_color.x = 1 - (hp-100)*0.02 * 0.6;
 978                                 wcross_color.y = 1 - (hp-100)*0.02 * 0.1;
 979                                 wcross_color.z = 1 - (hp-100)*0.02;
 980                         }
 981                         else if(hp > 50)
 982                         {
 983                                 wcross_color.x = 1;
 984                                 wcross_color.y = 1;
 985                                 wcross_color.z = 0.2 + (hp-50)*0.02 * 0.8;
 986                         }
 987                         else if(hp > 20)
 988                         {
 989                                 wcross_color.x = 1;
 990                                 wcross_color.y = (hp-20)*90/27/100;
 991                                 wcross_color.z = (hp-20)*90/27/100 * 0.2;
 992                         }
 993                         else
 994                         {
 995                                 wcross_color.x = 1;
 996                                 wcross_color.y = 0;
 997                         }
 998                         break;
 999                 }
1000
1001                 case 3: // crosshair_color_rainbow
1002                 {
1003                         if(time >= rainbow_last_flicker)
1004                         {
1005                                 rainbow_prev_color = randomvec() * autocvar_crosshair_color_special_rainbow_brightness;
1006                                 rainbow_last_flicker = time + autocvar_crosshair_color_special_rainbow_delay;
1007                         }
1008                         wcross_color = rainbow_prev_color;
1009                         break;
1010                 }
1011 LABEL(normalcolor)
1012                 default: { wcross_color = stov(autocvar_crosshair_color); break; }
1013         }
1014
1015         return wcross_color;
1016 }
1017
1018 void HUD_Crosshair(entity this)
1019 {
1020         float f, i, j;
1021         vector v;
1022         if(!scoreboard_active && !camera_active && intermission != 2 && !STAT(GAME_STOPPED) &&
1023                 spectatee_status != -1 && (!csqcplayer.viewloc || (!spectatee_status && (csqcplayer.viewloc.spawnflags & VIEWLOC_FREEAIM))) && !MUTATOR_CALLHOOK(DrawCrosshair) &&
1024                 !HUD_MinigameMenu_IsOpened() )
1025         {
1026                 if (!autocvar_crosshair_enabled) // main toggle for crosshair rendering
1027                         return;
1028
1029                 if (spectatee_status > 0 && STAT(CAMERA_SPECTATOR) == 2)
1030                         return;
1031
1032                 if (hud != HUD_NORMAL)
1033                 {
1034                         HUD_Crosshair_Vehicle(this);
1035                         return;
1036                 }
1037
1038                 string wcross_style;
1039                 float wcross_alpha, wcross_resolution;
1040                 wcross_style = autocvar_crosshair;
1041                 if (csqcplayer.viewloc && (csqcplayer.viewloc.spawnflags & VIEWLOC_FREEAIM) && autocvar_crosshair_2d != "")
1042                         wcross_style = autocvar_crosshair_2d;
1043                 if (wcross_style == "0")
1044                         return;
1045                 wcross_resolution = autocvar_crosshair_size;
1046                 if (wcross_resolution == 0)
1047                         return;
1048                 wcross_alpha = autocvar_crosshair_alpha;
1049                 if (wcross_alpha == 0)
1050                         return;
1051
1052                 // TrueAim check
1053                 float shottype;
1054
1055                 // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
1056                 if(csqcplayer.viewloc && (csqcplayer.viewloc.spawnflags & VIEWLOC_FREEAIM))
1057                         wcross_origin = viewloc_mousepos;
1058                 else
1059                         wcross_origin = project_3d_to_2d(view_origin + max_shot_distance * view_forward);
1060                 wcross_origin.z = 0;
1061                 if(autocvar_crosshair_hittest)
1062                 {
1063                         vector wcross_oldorigin;
1064                         entity thiswep = viewmodels[0]; // TODO: unhardcode
1065                         wcross_oldorigin = wcross_origin;
1066                         shottype = TrueAimCheck(thiswep);
1067                         if(shottype == SHOTTYPE_HITWORLD)
1068                         {
1069                                 v = wcross_origin - wcross_oldorigin;
1070                                 v.x /= vid_conwidth;
1071                                 v.y /= vid_conheight;
1072                                 if(vdist(v, >, 0.01))
1073                                         shottype = SHOTTYPE_HITOBSTRUCTION;
1074                         }
1075                         if(!autocvar_crosshair_hittest_showimpact)
1076                                 wcross_origin = wcross_oldorigin;
1077                 }
1078                 else
1079                         shottype = SHOTTYPE_HITWORLD;
1080
1081                 vector wcross_color = '0 0 0', wcross_size = '0 0 0';
1082                 string wcross_name = "";
1083                 float wcross_scale, wcross_blur;
1084
1085         entity e = WEP_Null;
1086                 if(autocvar_crosshair_per_weapon || (autocvar_crosshair_color_special == 1))
1087                 {
1088                         entity wepent = viewmodels[0]; // TODO: unhardcode
1089                         e = wepent.switchingweapon;
1090                         if(e)
1091                         {
1092                                 if(autocvar_crosshair_per_weapon)
1093                                 {
1094                                         // WEAPONTODO: access these through some general settings (with non-balance config settings)
1095                                         //wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
1096                                         //if (wcross_resolution == 0)
1097                                                 //return;
1098
1099                                         //wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
1100                                         wcross_resolution *= e.w_crosshair_size;
1101                                         wcross_name = e.w_crosshair;
1102                                 }
1103                         }
1104                 }
1105
1106                 if(wcross_name == "")
1107                         wcross_name = strcat("gfx/crosshair", wcross_style);
1108
1109                 // MAIN CROSSHAIR COLOR DECISION
1110                 wcross_color = crosshair_getcolor(e, STAT(HEALTH));
1111
1112                 if(autocvar_crosshair_effect_scalefade)
1113                 {
1114                         wcross_scale = wcross_resolution;
1115                         wcross_resolution = 1;
1116                 }
1117                 else
1118                 {
1119                         wcross_scale = 1;
1120                 }
1121
1122                 if(autocvar_crosshair_pickup)
1123                 {
1124                         float stat_pickup_time = STAT(LAST_PICKUP);
1125
1126                         if(pickup_crosshair_time < stat_pickup_time)
1127                         {
1128                                 if(time - stat_pickup_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1129                                         pickup_crosshair_size = 1;
1130
1131                                 pickup_crosshair_time = stat_pickup_time;
1132                         }
1133
1134                         if(pickup_crosshair_size > 0)
1135                                 pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
1136                         else
1137                                 pickup_crosshair_size = 0;
1138
1139                         wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
1140                 }
1141
1142                 // todo: make crosshair hit indication dependent on damage dealt
1143                 if(autocvar_crosshair_hitindication)
1144                 {
1145                         vector hitindication_color = ((autocvar_crosshair_color_special == 1) ? stov(autocvar_crosshair_hitindication_per_weapon_color) : stov(autocvar_crosshair_hitindication_color));
1146
1147                         if(unaccounted_damage)
1148                         {
1149                                 hitindication_crosshair_size = 1;
1150                         }
1151
1152                         if(hitindication_crosshair_size > 0)
1153                                 hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
1154                         else
1155                                 hitindication_crosshair_size = 0;
1156
1157                         wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
1158                         wcross_color.x += sin(hitindication_crosshair_size) * hitindication_color.x;
1159                         wcross_color.y += sin(hitindication_crosshair_size) * hitindication_color.y;
1160                         wcross_color.z += sin(hitindication_crosshair_size) * hitindication_color.z;
1161                 }
1162
1163                 if(shottype == SHOTTYPE_HITENEMY)
1164                         wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
1165                 if(shottype == SHOTTYPE_HITTEAM)
1166                         wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
1167
1168                 f = fabs(autocvar_crosshair_effect_time);
1169                 if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
1170                 {
1171                         wcross_changedonetime = time + f;
1172                 }
1173                 if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
1174                 {
1175                         wcross_name_changestarttime = time;
1176                         wcross_name_changedonetime = time + f;
1177                         if(wcross_name_goal_prev_prev)
1178                                 strunzone(wcross_name_goal_prev_prev);
1179                         wcross_name_goal_prev_prev = wcross_name_goal_prev;
1180                         wcross_name_goal_prev = strzone(wcross_name);
1181                         wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
1182                         wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
1183                         wcross_resolution_goal_prev = wcross_resolution;
1184                 }
1185
1186                 wcross_scale_goal_prev = wcross_scale;
1187                 wcross_alpha_goal_prev = wcross_alpha;
1188                 wcross_color_goal_prev = wcross_color;
1189
1190                 if(spectatee_status == -1 && shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
1191                 {
1192                         wcross_blur = 1;
1193                         wcross_alpha *= 0.75;
1194                 }
1195                 else
1196                         wcross_blur = 0;
1197                 // *_prev is at time-frametime
1198                 // * is at wcross_changedonetime+f
1199                 // what do we have at time?
1200                 if(time < wcross_changedonetime)
1201                 {
1202                         f = frametime / (wcross_changedonetime - time + frametime);
1203                         wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
1204                         wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
1205                         wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
1206                 }
1207
1208                 wcross_scale_prev = wcross_scale;
1209                 wcross_alpha_prev = wcross_alpha;
1210                 wcross_color_prev = wcross_color;
1211
1212                 MUTATOR_CALLHOOK(UpdateCrosshair);
1213
1214                 wcross_scale *= 1 - autocvar__menu_alpha;
1215                 wcross_alpha *= 1 - autocvar__menu_alpha;
1216                 wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1217
1218                 if(wcross_scale >= 0.001 && wcross_alpha >= 0.001)
1219                 {
1220                         // crosshair rings for weapon stats
1221                         if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
1222                         {
1223                                 // declarations and stats
1224                                 float ring_value = 0, ring_scale = 0, ring_alpha = 0, ring_inner_value = 0, ring_inner_alpha = 0;
1225                                 string ring_image = string_null, ring_inner_image = string_null;
1226                                 vector ring_rgb = '0 0 0', ring_inner_rgb = '0 0 0';
1227
1228                                 ring_scale = autocvar_crosshair_ring_size;
1229
1230                                 entity wepent = viewmodels[0]; // TODO: unhardcode
1231
1232                                 int weapon_clipload = wepent.clip_load;
1233                                 int weapon_clipsize = wepent.clip_size;
1234
1235                                 float arc_heat = wepent.arc_heat_percent;
1236                                 float vcharge = wepent.vortex_charge;
1237                                 float vchargepool = wepent.vortex_chargepool_ammo;
1238                                 float oknex_charge_ = wepent.oknex_charge;
1239                                 float oknex_chargepool_ = wepent.oknex_chargepool_ammo;
1240
1241                                 if(vortex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
1242                                         vortex_charge_movingavg = vcharge;
1243
1244                                 // handle the values
1245                                 if (autocvar_crosshair_ring && wepent.activeweapon == WEP_VORTEX && vcharge && autocvar_crosshair_ring_vortex) // ring around crosshair representing velocity-dependent damage for the vortex
1246                                 {
1247                                         if (vchargepool || use_vortex_chargepool) {
1248                                                 use_vortex_chargepool = 1;
1249                                                 ring_inner_value = vchargepool;
1250                                         } else {
1251                                                 vortex_charge_movingavg = (1 - autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate) * vortex_charge_movingavg + autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate * vcharge;
1252                                                 ring_inner_value = bound(0, autocvar_crosshair_ring_vortex_currentcharge_scale * (vcharge - vortex_charge_movingavg), 1);
1253                                         }
1254
1255                                         ring_inner_alpha = autocvar_crosshair_ring_vortex_inner_alpha;
1256                                         ring_inner_rgb = vec3(autocvar_crosshair_ring_vortex_inner_color_red, autocvar_crosshair_ring_vortex_inner_color_green, autocvar_crosshair_ring_vortex_inner_color_blue);
1257                                         ring_inner_image = "gfx/crosshair_ring_inner.tga";
1258
1259                                         // draw the outer ring to show the current charge of the weapon
1260                                         ring_value = vcharge;
1261                                         ring_alpha = autocvar_crosshair_ring_vortex_alpha;
1262                                         ring_rgb = wcross_color;
1263                                         ring_image = "gfx/crosshair_ring_nexgun.tga";
1264                                 }
1265                                 else if (autocvar_crosshair_ring && (wepent.activeweapon == WEP_OVERKILL_NEX) && oknex_charge_ && autocvar_crosshair_ring_vortex)
1266                                 {
1267                                         if (oknex_chargepool_ || use_vortex_chargepool) {
1268                                                 use_vortex_chargepool = 1;
1269                                                 ring_inner_value = oknex_chargepool_;
1270                                         } else {
1271                                                 vortex_charge_movingavg = (1 - autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate) * vortex_charge_movingavg + autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate * oknex_charge_;
1272                                                 ring_inner_value = bound(0, autocvar_crosshair_ring_vortex_currentcharge_scale * (oknex_charge_ - vortex_charge_movingavg), 1);
1273                                         }
1274
1275                                         ring_inner_alpha = autocvar_crosshair_ring_vortex_inner_alpha;
1276                                         ring_inner_rgb = eX * autocvar_crosshair_ring_vortex_inner_color_red + eY * autocvar_crosshair_ring_vortex_inner_color_green + eZ * autocvar_crosshair_ring_vortex_inner_color_blue;
1277                                         ring_inner_image = "gfx/crosshair_ring_inner.tga";
1278
1279                                         // draw the outer ring to show the current charge of the weapon
1280                                         ring_value = oknex_charge_;
1281                                         ring_alpha = autocvar_crosshair_ring_vortex_alpha;
1282                                         ring_rgb = wcross_color;
1283                                         ring_image = "gfx/crosshair_ring_nexgun.tga";
1284                                 }
1285                                 else if (autocvar_crosshair_ring && wepent.activeweapon == WEP_MINE_LAYER && WEP_CVAR(minelayer, limit) && autocvar_crosshair_ring_minelayer)
1286                                 {
1287                                         ring_value = bound(0, wepent.minelayer_mines / WEP_CVAR(minelayer, limit), 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
1288                                         ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
1289                                         ring_rgb = wcross_color;
1290                                         ring_image = "gfx/crosshair_ring.tga";
1291                                 }
1292                                 else if (wepent.activeweapon == WEP_HAGAR && wepent.hagar_load && autocvar_crosshair_ring_hagar)
1293                                 {
1294                                         ring_value = bound(0, wepent.hagar_load / WEP_CVAR_SEC(hagar, load_max), 1);
1295                                         ring_alpha = autocvar_crosshair_ring_hagar_alpha;
1296                                         ring_rgb = wcross_color;
1297                                         ring_image = "gfx/crosshair_ring.tga";
1298                                 }
1299                                 else if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
1300                                 {
1301                                         ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
1302                                         ring_scale = autocvar_crosshair_ring_reload_size;
1303                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
1304                                         ring_rgb = wcross_color;
1305
1306                                         // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
1307                                         // if a new image for another weapon is added, add the code (and its respective file/value) here
1308                                         if ((wepent.activeweapon == WEP_RIFLE) && (weapon_clipsize == 80))
1309                                                 ring_image = "gfx/crosshair_ring_rifle.tga";
1310                                         else
1311                                                 ring_image = "gfx/crosshair_ring.tga";
1312                                 }
1313                                 else if ( autocvar_crosshair_ring && autocvar_crosshair_ring_arc && arc_heat && wepent.activeweapon == WEP_ARC )
1314                                 {
1315                                         ring_value = arc_heat;
1316                                         ring_alpha = (1-arc_heat)*autocvar_crosshair_ring_arc_cold_alpha +
1317                                                 arc_heat*autocvar_crosshair_ring_arc_hot_alpha;
1318                                         ring_rgb = (1-arc_heat)*wcross_color + arc_heat*autocvar_crosshair_ring_arc_hot_color;
1319                                         ring_image = "gfx/crosshair_ring.tga";
1320                                 }
1321
1322                                 // if in weapon switch animation, fade ring out/in
1323                                 if(autocvar_crosshair_effect_time > 0)
1324                                 {
1325                                         f = (time - wcross_name_changestarttime) / autocvar_crosshair_effect_time;
1326                                         if (f >= 1)
1327                                         {
1328                                                 wcross_ring_prev = ((ring_image) ? true : false);
1329                                         }
1330
1331                                         if(wcross_ring_prev)
1332                                         {
1333                                                 if(f < 1)
1334                                                         ring_alpha *= fabs(1 - bound(0, f, 1));
1335                                         }
1336                                         else
1337                                         {
1338                                                 if(f < 1)
1339                                                         ring_alpha *= bound(0, f, 1);
1340                                         }
1341                                 }
1342
1343                                 if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
1344                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
1345
1346                                 if (ring_value)
1347                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
1348                         }
1349
1350 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
1351                         MACRO_BEGIN \
1352                                 vector scaled_sz = sz * wcross_size; \
1353                                 if(wcross_blur > 0) \
1354                                 { \
1355                                         for(i = -2; i <= 2; ++i) \
1356                                         for(j = -2; j <= 2; ++j) \
1357                                         M(i,j,sz,scaled_sz,wcross_name,wcross_alpha*0.04); \
1358                                 } \
1359                                 else \
1360                                 { \
1361                                         M(0,0,sz,scaled_sz,wcross_name,wcross_alpha); \
1362                                 } \
1363                         MACRO_END
1364
1365 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,scaled_sz,wcross_name,wcross_alpha) \
1366                         drawpic(wcross_origin - ('0.5 0 0' * (scaled_sz.x + i * wcross_blur) + '0 0.5 0' * (scaled_sz.y + j * wcross_blur)), wcross_name, scaled_sz, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
1367
1368 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
1369                         CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
1370
1371                         if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
1372                         {
1373                                 f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
1374                                 wcross_size = draw_getimagesize(wcross_name_goal_prev_prev) * wcross_scale;
1375                                 CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
1376                                 f = 1 - f;
1377                         }
1378                         else
1379                         {
1380                                 f = 1;
1381                         }
1382                         wcross_name_alpha_goal_prev = f;
1383
1384                         wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1385                         CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
1386
1387                         if(autocvar_crosshair_dot)
1388                         {
1389                                 vector wcross_color_old;
1390                                 wcross_color_old = wcross_color;
1391
1392                                 if((autocvar_crosshair_dot_color_custom) && (autocvar_crosshair_dot_color != "0"))
1393                                         wcross_color = stov(autocvar_crosshair_dot_color);
1394
1395                                 CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
1396                                 // FIXME why don't we use wcross_alpha here?
1397                                 wcross_color = wcross_color_old;
1398                         }
1399                 }
1400         }
1401         else
1402         {
1403                 wcross_scale_prev = 0;
1404                 wcross_alpha_prev = 0;
1405                 wcross_scale_goal_prev = 0;
1406                 wcross_alpha_goal_prev = 0;
1407                 wcross_changedonetime = 0;
1408                 strfree(wcross_name_goal_prev);
1409                 strfree(wcross_name_goal_prev_prev);
1410                 wcross_name_changestarttime = 0;
1411                 wcross_name_changedonetime = 0;
1412                 wcross_name_alpha_goal_prev = 0;
1413                 wcross_name_alpha_goal_prev_prev = 0;
1414                 wcross_resolution_goal_prev = 0;
1415                 wcross_resolution_goal_prev_prev = 0;
1416         }
1417 }
1418
1419 const int MAX_SPECIALCOMMAND = 15;
1420 vector specialcommand_slots[MAX_SPECIALCOMMAND];
1421 vector specialcommand_colors[MAX_SPECIALCOMMAND];
1422 const float SPECIALCOMMAND_SPEED = 150;
1423 const float SPECIALCOMMAND_TURNSPEED = 2;
1424 const float SPECIALCOMMAND_SIZE = 0.025;
1425 const float SPECIALCOMMAND_CHANCE = 0.35;
1426 float sc_spawntime, sc_changetime;
1427 vector sc_color = '1 1 1';
1428 void SpecialCommand()
1429 {
1430         if(!STAT(MOVEVARS_SPECIALCOMMAND))
1431                 return;
1432
1433         if(time >= sc_changetime)
1434         {
1435                 sc_changetime = time + 1;
1436                 sc_color = randomvec() * 1.5;
1437                 sc_color.x = bound(0.2, sc_color.x, 0.75);
1438                 sc_color.y = bound(0.2, sc_color.y, 0.75);
1439                 sc_color.z = bound(0.2, sc_color.z, 0.75);
1440         }
1441         drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), sc_color, autocvar_hud_colorflash_alpha * bound(0.1, sc_changetime - time, 0.3), DRAWFLAG_ADDITIVE);
1442
1443         if(!precache_pic("gfx/smile"))
1444                 return; // damn party poopers
1445
1446         for(int j = MAX_SPECIALCOMMAND - 1; j >= 0; --j)
1447         {
1448                 vector slot = specialcommand_slots[j];
1449                 if(slot.y)
1450                         slot.y += SPECIALCOMMAND_SPEED * frametime;
1451                 //if(slot.z)
1452                         //slot.z = sin(SPECIALCOMMAND_TURNSPEED * M_PI * time);
1453                 if(slot.y >= vid_conheight)
1454                         slot = '0 0 0';
1455
1456                 if(slot == '0 0 0')
1457                 {
1458                         if(random() <= SPECIALCOMMAND_CHANCE && time > sc_spawntime) // low chance to spawn!
1459                         {
1460                                 slot.x = bound(0, (random() * vid_conwidth + 1), vid_conwidth);
1461                                 slot.y = 1; // start it off 0 so we can use it
1462                                 slot.z = floor(random() * Weapons_MAX);
1463                                 sc_spawntime = time + bound(0.4, random(), 0.75); // prevent spawning another one for this amount of time!
1464                                 vector newcolor = randomvec() * 2;
1465                                 newcolor.x = bound(0.4, newcolor.x, 1);
1466                                 newcolor.y = bound(0.4, newcolor.y, 1);
1467                                 newcolor.z = bound(0.4, newcolor.z, 1);
1468                                 specialcommand_colors[j] = newcolor;
1469                         }
1470                 }
1471                 else
1472                 {
1473                         vector splash_size = '0 0 0';
1474                         splash_size.x = max(vid_conwidth, vid_conheight) * SPECIALCOMMAND_SIZE;
1475                         splash_size.y = max(vid_conwidth, vid_conheight) * SPECIALCOMMAND_SIZE;
1476                         entity wep = Weapons_from(slot.z);
1477                         if(wep == WEP_Null)
1478                                 drawpic(vec2(slot), "gfx/smile", vec2(splash_size), specialcommand_colors[j], 0.95, DRAWFLAG_NORMAL);
1479                         else
1480                                 drawpic_skin(vec2(slot), wep.model2, vec2(splash_size), specialcommand_colors[j], 0.95, DRAWFLAG_NORMAL);
1481                         //drawrotpic(vec2(slot), slot.z, "gfx/smile", vec2(splash_size), vec2(splash_size) / 2, specialcommand_colors[j], 0.95, DRAWFLAG_NORMAL);
1482                 }
1483
1484                 specialcommand_slots[j] = slot;
1485         }
1486 }
1487
1488 void HUD_Draw(entity this)
1489 {
1490         // if we don't know gametype and scores yet avoid drawing the scoreboard
1491         // also in the very first frames, player state may be inconsistent so avoid drawing the hud at all
1492         // e.g. since initial player's health is 0 hud would display the hud_damage effect,
1493         // cl_deathscoreboard would show the scoreboard and so on
1494         if(!gametype)
1495                 return;
1496
1497         Hud_Dynamic_Frame();
1498
1499         if(!intermission)
1500         if (MUTATOR_CALLHOOK(HUD_Draw_overlay))
1501         {
1502                 drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), M_ARGV(0, vector), autocvar_hud_colorflash_alpha * M_ARGV(1, float), DRAWFLAG_ADDITIVE);
1503         }
1504         else if(STAT(FROZEN))
1505         {
1506                 vector col = '0.25 0.90 1';
1507                 if(STAT(REVIVE_PROGRESS))
1508                         col += vec3(STAT(REVIVE_PROGRESS), -STAT(REVIVE_PROGRESS), -STAT(REVIVE_PROGRESS));
1509                 drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), col, autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1510         }
1511
1512         HUD_Scale_Enable();
1513         if(!intermission)
1514         if(STAT(NADE_TIMER) && autocvar_cl_nade_timer) // give nade top priority, as it's a matter of life and death
1515         {
1516                 vector col = '0.25 0.90 1' + vec3(STAT(NADE_TIMER), -STAT(NADE_TIMER), -STAT(NADE_TIMER));
1517                 DrawCircleClippedPic(vec2(0.5 * vid_conwidth, 0.6 * vid_conheight), 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(NADE_TIMER), col, autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1518                 drawstring_aspect(eY * 0.64 * vid_conheight, ((autocvar_cl_nade_timer == 2) ? _("Nade timer") : ""), vec2(vid_conwidth, 0.025 * vid_conheight), '1 1 1', 1, DRAWFLAG_NORMAL);
1519         }
1520         else if(STAT(CAPTURE_PROGRESS))
1521         {
1522                 DrawCircleClippedPic(vec2(0.5 * vid_conwidth, 0.6 * vid_conheight), 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(CAPTURE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1523                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Capture progress"), vec2(vid_conwidth, 0.025 * vid_conheight), '1 1 1', 1, DRAWFLAG_NORMAL);
1524         }
1525         else if(STAT(REVIVE_PROGRESS))
1526         {
1527                 DrawCircleClippedPic(vec2(0.5 * vid_conwidth, 0.6 * vid_conheight), 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1528                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Revival progress"), vec2(vid_conwidth, 0.025 * vid_conheight), '1 1 1', 1, DRAWFLAG_NORMAL);
1529         }
1530         HUD_Scale_Disable();
1531
1532         if(autocvar_r_letterbox == 0)
1533                 if(autocvar_viewsize < 120)
1534                 {
1535                         if(!(ISGAMETYPE(RACE) || ISGAMETYPE(CTS)))
1536                                 Accuracy_LoadLevels();
1537
1538                         HUD_Main();
1539                         HUD_Scale_Disable();
1540                 }
1541
1542         // crosshair goes VERY LAST
1543         SpecialCommand();
1544         UpdateDamage();
1545         HUD_Crosshair(this);
1546         HitSound();
1547 }
1548
1549 void ViewLocation_Mouse()
1550 {
1551         if(spectatee_status)
1552                 return; // don't draw it as spectator!
1553
1554         viewloc_mousepos += getmousepos() * autocvar_menu_mouse_speed;
1555         viewloc_mousepos.x = bound(0, viewloc_mousepos.x, vid_conwidth);
1556         viewloc_mousepos.y = bound(0, viewloc_mousepos.y, vid_conheight);
1557
1558         //float cursor_alpha = 1 - autocvar__menu_alpha;
1559         //draw_cursor(viewloc_mousepos, '0.5 0.5 0', "/cursor_move", '1 1 1', cursor_alpha);
1560 }
1561
1562 void HUD_Cursor_Show()
1563 {
1564         float cursor_alpha = 1 - autocvar__menu_alpha;
1565         if(cursor_type == CURSOR_NORMAL)
1566                 draw_cursor_normal(mousepos, '1 1 1', cursor_alpha);
1567         else if(cursor_type == CURSOR_MOVE)
1568                 draw_cursor(mousepos, '0.5 0.5 0', "/cursor_move", '1 1 1', cursor_alpha);
1569         else if(cursor_type == CURSOR_RESIZE)
1570                 draw_cursor(mousepos, '0.5 0.5 0', "/cursor_resize", '1 1 1', cursor_alpha);
1571         else if(cursor_type == CURSOR_RESIZE2)
1572                 draw_cursor(mousepos, '0.5 0.5 0', "/cursor_resize2", '1 1 1', cursor_alpha);
1573 }
1574
1575 void HUD_Mouse(entity player)
1576 {
1577         if(autocvar__menu_alpha == 1)
1578                 return;
1579
1580         if(!cursor_active)
1581         {
1582                 if(player.viewloc && (player.viewloc.spawnflags & VIEWLOC_FREEAIM))
1583                         ViewLocation_Mouse(); // NOTE: doesn't use cursormode
1584                 return;
1585         }
1586
1587         if (cursor_active == -1) // starting to display the cursor
1588         {
1589                 // since HUD_Mouse is called by CSQC_UpdateView before CSQC_InputEvent,
1590                 // in the first frame mousepos is the mouse position of the last time
1591                 // the cursor was displayed, thus we ignore it to avoid a glictch
1592                 cursor_active = 1;
1593                 return;
1594         }
1595
1596         if(!autocvar_hud_cursormode)
1597                 update_mousepos();
1598
1599         if(autocvar__hud_configure)
1600                 HUD_Panel_Mouse();
1601         else
1602         {
1603                 if (HUD_MinigameMenu_IsOpened())
1604                         HUD_Minigame_Mouse();
1605                 if (QuickMenu_IsOpened())
1606                         QuickMenu_Mouse();
1607                 if (HUD_Radar_Clickable())
1608                         HUD_Radar_Mouse();
1609         }
1610
1611         prevMouseClicked = mouseClicked;
1612
1613         HUD_Cursor_Show();
1614 }
1615
1616 bool ov_enabled;
1617 float oldr_nearclip;
1618 float oldr_farclip_base;
1619 float oldr_farclip_world;
1620 float oldr_novis;
1621 float oldr_useportalculling;
1622 float oldr_useinfinitefarclip;
1623
1624 float prev_myteam;
1625 int lasthud;
1626 float vh_notice_time;
1627 void CSQC_UpdateView(entity this, float w, float h)
1628 {
1629         TC(int, w); TC(int, h);
1630         entity e;
1631         float fov;
1632         float f;
1633         vector vf_size, vf_min;
1634         float a;
1635
1636         execute_next_frame();
1637
1638         ++framecount;
1639
1640         stats_get();
1641         hud = STAT(HUD);
1642
1643         if(hud != HUD_NORMAL && lasthud == HUD_NORMAL)
1644                 vh_notice_time = time + autocvar_cl_vehicles_notify_time;
1645
1646         lasthud = hud;
1647
1648         HUD_Scale_Disable();
1649
1650         if(autocvar__hud_showbinds_reload) // menu can set this one
1651         {
1652                 db_close(binddb);
1653                 binddb = db_create();
1654                 cvar_set("_hud_showbinds_reload", "0");
1655         }
1656
1657         if(checkextension("DP_CSQC_MINFPS_QUALITY"))
1658                 view_quality = getproperty(VF_MINFPS_QUALITY);
1659         else
1660                 view_quality = 1;
1661
1662         button_attack2 = PHYS_INPUT_BUTTON_ATCK2(this);
1663         button_zoom = PHYS_INPUT_BUTTON_ZOOM(this);
1664
1665         vf_size = getpropertyvec(VF_SIZE);
1666         vf_min = getpropertyvec(VF_MIN);
1667         vid_width = vf_size.x;
1668         vid_height = vf_size.y;
1669
1670         vector reticle_pos = '0 0 0', reticle_size = '0 0 0';
1671         vector splash_pos = '0 0 0', splash_size = '0 0 0';
1672
1673         WaypointSprite_Load();
1674
1675         CSQCPlayer_SetCamera();
1676
1677         if(player_localentnum <= maxclients) // is it a client?
1678                 current_player = player_localentnum - 1;
1679         else // then player_localentnum is the vehicle I'm driving
1680                 current_player = player_localnum;
1681         myteam = entcs_GetTeam(current_player);
1682
1683         if(myteam != prev_myteam)
1684         {
1685                 myteamcolors = colormapPaletteColor(myteam, 1);
1686                 FOREACH(hud_panels, true, it.update_time = time);
1687                 prev_myteam = myteam;
1688         }
1689
1690         ticrate = STAT(MOVEVARS_TICRATE) * STAT(MOVEVARS_TIMESCALE);
1691
1692         float is_dead = (STAT(HEALTH) <= 0);
1693
1694         // FIXME do we need this hack?
1695         if(isdemo())
1696         {
1697                 // in demos, input_buttons do not work
1698                 button_zoom = (autocvar__togglezoom == "-");
1699         }
1700         else if(button_zoom
1701                 && autocvar_cl_unpress_zoom_on_death
1702                 && (spectatee_status >= 0)
1703                 && (is_dead || intermission))
1704         {
1705                 // no zoom while dead or in intermission please
1706                 localcmd("-zoom\n");
1707                 button_zoom = false;
1708         }
1709
1710         // abused multiple places below
1711         entity local_player = ((csqcplayer) ? csqcplayer : CSQCModel_server2csqc(player_localentnum - 1));
1712         if(!local_player)
1713                 local_player = this; // fall back!
1714
1715         // event chase camera
1716         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
1717         {
1718                 if(STAT(CAMERA_SPECTATOR))
1719                 {
1720                         if(spectatee_status > 0)
1721                         {
1722                                 if(!autocvar_chase_active)
1723                                 {
1724                                         cvar_set("chase_active", "-2");
1725                                         goto skip_eventchase_death;
1726                                 }
1727                         }
1728                         else if(autocvar_chase_active == -2)
1729                                 cvar_set("chase_active", "0");
1730
1731                         if(autocvar_chase_active == -2)
1732                                 goto skip_eventchase_death;
1733                 }
1734                 else if(autocvar_chase_active == -2)
1735                         cvar_set("chase_active", "0");
1736
1737                 float vehicle_chase = (hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0));
1738
1739                 float vehicle_viewdist = 0;
1740                 vector vehicle_viewofs = '0 0 0';
1741
1742                 if(vehicle_chase)
1743                 {
1744                         if(hud != HUD_BUMBLEBEE_GUN)
1745                         {
1746                                 Vehicle info = Vehicles_from(hud);
1747                                 vehicle_viewdist = info.height;
1748                                 vehicle_viewofs = info.view_ofs;
1749                         }
1750                 }
1751
1752                 int eventchase = WantEventchase(this);
1753                 if (eventchase)
1754                 {
1755                         vector current_view_origin_override = '0 0 0';
1756                         vector view_offset_override = '0 0 0';
1757                         float chase_distance_override = 0;
1758                         bool custom_eventchase = MUTATOR_CALLHOOK(CustomizeEventchase, this);
1759                         if(custom_eventchase)
1760                         {
1761                                 current_view_origin_override = M_ARGV(0, vector);
1762                                 view_offset_override = M_ARGV(1, vector);
1763                                 chase_distance_override = M_ARGV(0, float);
1764                         }
1765                         eventchase_running = true;
1766
1767                         // make special vector since we can't use view_origin (It is one frame old as of this code, it gets set later with the results this code makes.)
1768                         vector current_view_origin = (csqcplayer ? csqcplayer.origin : pmove_org);
1769                         if (custom_eventchase)
1770                                 current_view_origin = current_view_origin_override;
1771
1772                         // detect maximum viewoffset and use it
1773                         vector view_offset = autocvar_cl_eventchase_viewoffset;
1774                         if(vehicle_chase)
1775                         {
1776                                 if(vehicle_viewofs)
1777                                         view_offset = vehicle_viewofs;
1778                                 else
1779                                         view_offset = autocvar_cl_eventchase_vehicle_viewoffset;
1780                         }
1781                         if (custom_eventchase)
1782                                 view_offset = view_offset_override;
1783
1784                         if(view_offset)
1785                         {
1786                                 WarpZone_TraceLine(current_view_origin, current_view_origin + view_offset + ('0 0 1' * autocvar_cl_eventchase_maxs.z), MOVE_WORLDONLY, this);
1787                                 if(trace_fraction == 1) { current_view_origin += view_offset; }
1788                                 else { current_view_origin.z += max(0, (trace_endpos.z - current_view_origin.z) - autocvar_cl_eventchase_maxs.z); }
1789                         }
1790
1791                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
1792                         // Ideally, there should be another way to enable third person cameras, such as through setproperty()
1793                         // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
1794                         if(!autocvar_chase_active) { cvar_set("chase_active", "-1"); }
1795
1796                         // make the camera smooth back
1797                         float chase_distance = autocvar_cl_eventchase_distance;
1798                         if(vehicle_chase)
1799                         {
1800                                 if(vehicle_viewofs)
1801                                         chase_distance = vehicle_viewdist;
1802                                 else
1803                                         chase_distance = autocvar_cl_eventchase_vehicle_distance;
1804                         }
1805                         if (custom_eventchase)
1806                                 chase_distance = chase_distance_override;
1807
1808                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < chase_distance)
1809                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (chase_distance - eventchase_current_distance) * frametime; // slow down the further we get
1810                         else if(eventchase_current_distance != chase_distance)
1811                                 eventchase_current_distance = chase_distance;
1812
1813                         makevectors(view_angles);
1814
1815                         vector eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1816                         WarpZone_TraceBox(current_view_origin, autocvar_cl_eventchase_mins, autocvar_cl_eventchase_maxs, eventchase_target_origin, MOVE_WORLDONLY, this);
1817
1818                         // If the boxtrace fails, revert back to line tracing.
1819                         if(!local_player.viewloc)
1820                         if(trace_startsolid)
1821                         {
1822                                 eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1823                                 WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, this);
1824                                 setproperty(VF_ORIGIN, (trace_endpos - (v_forward * autocvar_cl_eventchase_mins.z)));
1825                         }
1826                         else { setproperty(VF_ORIGIN, trace_endpos); }
1827
1828                         if(!local_player.viewloc)
1829                                 setproperty(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
1830                 }
1831
1832                 if (eventchase <= 0 && autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
1833                 {
1834                         eventchase_running = false;
1835                         cvar_set("chase_active", "0");
1836                         eventchase_current_distance = 0; // start from 0 next time
1837                 }
1838         }
1839         // workaround for camera stuck between player's legs when using chase_active 1
1840         // because the engine stops updating the chase_active camera when the game ends
1841         else if(intermission)
1842         {
1843                 cvar_settemp("chase_active", "-1");
1844                 eventchase_current_distance = 0;
1845         }
1846
1847         LABEL(skip_eventchase_death);
1848
1849         // do lockview after event chase camera so that it still applies whenever necessary.
1850         if(autocvar_cl_lockview || (!autocvar_hud_cursormode && (autocvar__hud_configure && spectatee_status <= 0 || intermission > 1 || QuickMenu_IsOpened())))
1851         {
1852                 setproperty(VF_ORIGIN, freeze_org);
1853                 setproperty(VF_ANGLES, freeze_ang);
1854         }
1855         else
1856         {
1857                 freeze_org = getpropertyvec(VF_ORIGIN);
1858                 freeze_ang = getpropertyvec(VF_ANGLES);
1859         }
1860
1861         WarpZone_FixView();
1862         //WarpZone_FixPMove();
1863
1864         vector ov_org = '0 0 0';
1865         vector ov_mid = '0 0 0';
1866         vector ov_worldmin = '0 0 0';
1867         vector ov_worldmax = '0 0 0';
1868         if(autocvar_cl_orthoview)
1869         {
1870                 ov_worldmin = mi_picmin;
1871                 ov_worldmax = mi_picmax;
1872
1873                 float ov_width = (ov_worldmax.x - ov_worldmin.x);
1874                 float ov_height = (ov_worldmax.y - ov_worldmin.y);
1875                 float ov_distance = (max(vid_width, vid_height) * max(ov_width, ov_height));
1876
1877                 ov_mid = ((ov_worldmax + ov_worldmin) * 0.5);
1878                 ov_org = vec3(ov_mid.x, ov_mid.y, (ov_mid.z + ov_distance));
1879
1880                 float ov_nearest = vlen(ov_org - vec3(
1881                         bound(ov_worldmin.x, ov_org.x, ov_worldmax.x),
1882                         bound(ov_worldmin.y, ov_org.y, ov_worldmax.y),
1883                         bound(ov_worldmin.z, ov_org.z, ov_worldmax.z)
1884                 ));
1885
1886                 float ov_furthest = 0;
1887                 float dist = 0;
1888
1889                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1890                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1891                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1892                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1893                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1894                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1895                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1896                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1897
1898                 if(!ov_enabled)
1899                 {
1900                         oldr_nearclip = cvar("r_nearclip");
1901                         oldr_farclip_base = cvar("r_farclip_base");
1902                         oldr_farclip_world = cvar("r_farclip_world");
1903                         oldr_novis = cvar("r_novis");
1904                         oldr_useportalculling = cvar("r_useportalculling");
1905                         oldr_useinfinitefarclip = cvar("r_useinfinitefarclip");
1906                 }
1907
1908                 cvar_settemp("r_nearclip", ftos(ov_nearest));
1909                 cvar_settemp("r_farclip_base", ftos(ov_furthest));
1910                 cvar_settemp("r_farclip_world", "0");
1911                 cvar_settemp("r_novis", "1");
1912                 cvar_settemp("r_useportalculling", "0");
1913                 cvar_settemp("r_useinfinitefarclip", "0");
1914
1915                 setproperty(VF_ORIGIN, ov_org);
1916                 setproperty(VF_ANGLES, '90 0 0');
1917
1918                 ov_enabled = true;
1919
1920                 #if 0
1921                 LOG_INFOF("OrthoView: org = %s, angles = %s, distance = %f, nearest = %f, furthest = %f",
1922                         vtos(ov_org),
1923                         vtos(getpropertyvec(VF_ANGLES)),
1924                         ov_distance,
1925                         ov_nearest,
1926                         ov_furthest);
1927                 #endif
1928         }
1929         else
1930         {
1931                 if(ov_enabled)
1932                 {
1933                         cvar_set("r_nearclip", ftos(oldr_nearclip));
1934                         cvar_set("r_farclip_base", ftos(oldr_farclip_base));
1935                         cvar_set("r_farclip_world", ftos(oldr_farclip_world));
1936                         cvar_set("r_novis", ftos(oldr_novis));
1937                         cvar_set("r_useportalculling", ftos(oldr_useportalculling));
1938                         cvar_set("r_useinfinitefarclip", ftos(oldr_useinfinitefarclip));
1939                 }
1940                 ov_enabled = false;
1941         }
1942
1943         // run viewmodel_draw before updating view_angles to the angles calculated by WarpZone_FixView
1944         // viewmodel_draw needs to use the view_angles set by the engine on every CSQC_UpdateView call
1945         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1946                 viewmodel_draw(viewmodels[slot]);
1947
1948         // Render the Scene
1949         view_origin = getpropertyvec(VF_ORIGIN);
1950         view_angles = getpropertyvec(VF_ANGLES);
1951         MAKEVECTORS(makevectors, view_angles, view_forward, view_right, view_up);
1952
1953 #ifdef BLURTEST
1954         if(time > blurtest_time0 && time < blurtest_time1)
1955         {
1956                 float r, t;
1957
1958                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
1959                 r = t * blurtest_radius;
1960                 f = 1 / (t ** blurtest_power) - 1;
1961
1962                 cvar_set("r_glsl_postprocess", "1");
1963                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
1964         }
1965         else
1966         {
1967                 cvar_set("r_glsl_postprocess", "0");
1968                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
1969         }
1970 #endif
1971
1972         TargetMusic_Advance();
1973         Fog_Force();
1974         fpscounter_update();
1975
1976         if(drawtime == 0)
1977                 drawframetime = 0.01666667; // when we don't know fps yet, we assume 60fps
1978         else
1979                 drawframetime = bound(0.000001, time - drawtime, 1);
1980         drawtime = time;
1981
1982         // watch for gametype changes here...
1983         // in ParseStuffCMD the cmd isn't executed yet :/
1984         // might even be better to add the gametype to TE_CSQC_INIT...?
1985         if(!postinit)
1986                 PostInit();
1987
1988         if(intermission && !intermission_time)
1989                 intermission_time = time;
1990
1991         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
1992         {
1993                 if(calledhooks & HOOK_START)
1994                 {
1995                         localcmd("\ncl_hook_gameend\n");
1996                         calledhooks |= HOOK_END;
1997                 }
1998         }
1999
2000         Announcer();
2001
2002         fov = autocvar_fov;
2003         if(fov <= 59.5)
2004         {
2005                 if(!zoomscript_caught)
2006                 {
2007                         localcmd("+button9\n");
2008                         zoomscript_caught = 1;
2009                 }
2010         }
2011         else
2012         {
2013                 if(zoomscript_caught)
2014                 {
2015                         localcmd("-button9\n");
2016                         zoomscript_caught = 0;
2017                 }
2018         }
2019
2020         if(active_minigame && HUD_MinigameMenu_IsOpened())
2021         {
2022                 if(!minigame_wasactive)
2023                 {
2024                         localcmd("+button12\n");
2025                         minigame_wasactive = true;
2026                 }
2027         }
2028         else if(minigame_wasactive)
2029         {
2030                 localcmd("-button12\n");
2031                 minigame_wasactive = false;
2032         }
2033
2034         ColorTranslateMode = autocvar_cl_stripcolorcodes;
2035
2036         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2037         {
2038                 entity wepent = viewmodels[slot];
2039
2040                 if(wepent.last_switchweapon != wepent.switchweapon)
2041                 {
2042                         weapontime = time;
2043                         wepent.last_switchweapon = wepent.switchweapon;
2044                         if(slot == 0 && button_zoom && autocvar_cl_unpress_zoom_on_weapon_switch)
2045                         {
2046                                 localcmd("-zoom\n");
2047                                 button_zoom = false;
2048                         }
2049                         if(slot == 0 && autocvar_cl_unpress_attack_on_weapon_switch)
2050                         {
2051                                 localcmd("-fire\n");
2052                                 localcmd("-fire2\n");
2053                                 button_attack2 = false;
2054                         }
2055                 }
2056                 if(wepent.last_activeweapon != wepent.activeweapon)
2057                 {
2058                         wepent.last_activeweapon = wepent.activeweapon;
2059
2060                         e = wepent.activeweapon;
2061                         if(e.netname != "")
2062                                 localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
2063                         else if(slot == 0)
2064                                 localcmd("\ncl_hook_activeweapon none\n");
2065                 }
2066         }
2067
2068         // ALWAYS Clear Current Scene First
2069         clearscene();
2070
2071         setproperty(VF_ORIGIN, view_origin);
2072         setproperty(VF_ANGLES, view_angles);
2073
2074         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
2075         setproperty(VF_SIZE, vf_size);
2076         setproperty(VF_MIN, vf_min);
2077
2078         // Assign Standard Viewflags
2079         // Draw the World (and sky)
2080         setproperty(VF_DRAWWORLD, 1);
2081
2082         // Set the console size vars
2083         vid_conwidth = autocvar_vid_conwidth;
2084         vid_conheight = autocvar_vid_conheight;
2085         vid_pixelheight = autocvar_vid_pixelheight;
2086
2087         if(autocvar_cl_orthoview) { setproperty(VF_FOV, GetOrthoviewFOV(ov_worldmin, ov_worldmax, ov_mid, ov_org)); }
2088         else if(csqcplayer.viewloc) { setproperty(VF_FOV, GetViewLocationFOV(110)); } // enforce 110 fov, so things dont look odd
2089         else { setproperty(VF_FOV, GetCurrentFov(fov)); }
2090
2091         if(camera_active) // Camera for demo playback
2092         {
2093                 if(autocvar_camera_enable)
2094                         CSQC_Demo_Camera();
2095                 else
2096                 {
2097                         cvar_set("chase_active", ftos(chase_active_backup));
2098                         cvar_set("cl_demo_mousegrab", "0");
2099                         camera_active = false;
2100                 }
2101         }
2102         else
2103         {
2104 #ifdef CAMERATEST
2105                 if(autocvar_camera_enable)
2106 #else
2107                 if(autocvar_camera_enable && isdemo())
2108 #endif
2109                 {
2110                         // Enable required Darkplaces cvars
2111                         chase_active_backup = autocvar_chase_active;
2112                         cvar_set("chase_active", "2");
2113                         cvar_set("cl_demo_mousegrab", "1");
2114                         camera_active = true;
2115                         camera_mode = false;
2116                 }
2117         }
2118
2119         // Draw the Crosshair
2120         setproperty(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
2121
2122         // Draw the Engine Status Bar (the default Quake HUD)
2123         setproperty(VF_DRAWENGINESBAR, 0);
2124
2125         // Update the mouse position
2126         /*
2127            mousepos_x = vid_conwidth;
2128            mousepos_y = vid_conheight;
2129            mousepos = mousepos*0.5 + getmousepos();
2130          */
2131
2132         IL_EACH(g_drawables, it.draw, it.draw(it));
2133
2134         addentities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS); // TODO: .health is used in cl_deathfade (a feature we have turned off currently)
2135         renderscene();
2136
2137         // now switch to 2D drawing mode by calling a 2D drawing function
2138         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
2139         // next R_RenderScene call
2140         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
2141
2142         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
2143         if (!(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT))
2144         {
2145                 // apply night vision effect
2146                 vector tc_00, tc_01, tc_10, tc_11;
2147                 vector rgb = '0 0 0';
2148
2149                 if(!nightvision_noise)
2150                 {
2151                         nightvision_noise = new(nightvision_noise);
2152                 }
2153                 if(!nightvision_noise2)
2154                 {
2155                         nightvision_noise2 = new(nightvision_noise2);
2156                 }
2157
2158                 // color tint in yellow
2159                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
2160
2161                 // draw BG
2162                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
2163                 rgb = '1 1 1';
2164                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
2165                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
2166                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
2167                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
2168                 tc_11 = tc_01 + tc_10 - tc_00;
2169                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
2170                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
2171                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
2172                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
2173                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
2174                 R_EndPolygon();
2175
2176                 // draw FG
2177                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
2178                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
2179                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
2180                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
2181                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
2182                 tc_11 = tc_01 + tc_10 - tc_00;
2183                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
2184                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
2185                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
2186                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
2187                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
2188                 R_EndPolygon();
2189         }
2190
2191         if(autocvar_cl_reticle && !MUTATOR_CALLHOOK(DrawReticle))
2192         {
2193                 string reticle_image = string_null;
2194                 bool wep_zoomed = false;
2195                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2196                 {
2197                         entity wepe = viewmodels[slot];
2198                         Weapon wep = wepe.activeweapon;
2199                         if(wep != WEP_Null && wep.wr_zoom)
2200                         {
2201                                 bool do_zoom = wep.wr_zoom(wep, NULL);
2202                                 if(!reticle_image && wep.w_reticle && wep.w_reticle != "")
2203                                         reticle_image = wep.w_reticle;
2204                                 wep_zoomed += do_zoom;
2205                         }
2206                 }
2207                 // Draw the aiming reticle for weapons that use it
2208                 // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
2209                 // It must be a persisted float for fading out to work properly (you let go of the zoom button for
2210                 // the view to go back to normal, so reticle_type would become 0 as we fade out)
2211                 if(spectatee_status || is_dead || hud != HUD_NORMAL || local_player.viewloc)
2212                 {
2213                         // no zoom reticle while dead
2214                         reticle_type = 0;
2215                 }
2216                 else if(wep_zoomed && autocvar_cl_reticle_weapon)
2217                 {
2218                         if(reticle_image) { reticle_type = 2; }
2219                         else { reticle_type = 0; }
2220                 }
2221                 else if(button_zoom || zoomscript_caught)
2222                 {
2223                         // normal zoom
2224                         reticle_type = 1;
2225                 }
2226
2227                 if(reticle_type)
2228                 {
2229                         if(autocvar_cl_reticle_stretch)
2230                         {
2231                                 reticle_size.x = vid_conwidth;
2232                                 reticle_size.y = vid_conheight;
2233                                 reticle_pos.x = 0;
2234                                 reticle_pos.y = 0;
2235                         }
2236                         else
2237                         {
2238                                 reticle_size.x = max(vid_conwidth, vid_conheight);
2239                                 reticle_size.y = max(vid_conwidth, vid_conheight);
2240                                 reticle_pos.x = (vid_conwidth - reticle_size.x) / 2;
2241                                 reticle_pos.y = (vid_conheight - reticle_size.y) / 2;
2242                         }
2243
2244                         if(zoomscript_caught)
2245                                 f = 1;
2246                         else
2247                                 f = current_zoomfraction;
2248
2249                         if(f)
2250                         {
2251                                 switch(reticle_type)
2252                                 {
2253                                         case 1: drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_normal_alpha, DRAWFLAG_NORMAL); break;
2254                                         case 2: if(reticle_image) drawpic(reticle_pos, reticle_image, reticle_size, '1 1 1', f * autocvar_cl_reticle_weapon_alpha, DRAWFLAG_NORMAL); break;
2255                                 }
2256                         }
2257                 }
2258         }
2259         else
2260         {
2261                 if(reticle_type != 0) { reticle_type = 0; }
2262         }
2263
2264
2265         // improved polyblend
2266         if(autocvar_hud_contents && !MUTATOR_CALLHOOK(HUD_Contents))
2267         {
2268                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
2269                 vector liquidcolor;
2270
2271                 switch(pointcontents(view_origin))
2272                 {
2273                         case CONTENT_WATER:
2274                                 liquidalpha = autocvar_hud_contents_water_alpha;
2275                                 liquidcolor = stov(autocvar_hud_contents_water_color);
2276                                 incontent = 1;
2277                                 break;
2278
2279                         case CONTENT_LAVA:
2280                                 liquidalpha = autocvar_hud_contents_lava_alpha;
2281                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
2282                                 incontent = 1;
2283                                 break;
2284
2285                         case CONTENT_SLIME:
2286                                 liquidalpha = autocvar_hud_contents_slime_alpha;
2287                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
2288                                 incontent = 1;
2289                                 break;
2290
2291                         default:
2292                                 liquidalpha = 0;
2293                                 liquidcolor = '0 0 0';
2294                                 incontent = 0;
2295                                 break;
2296                 }
2297
2298                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
2299                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
2300                         contentfadetime = autocvar_hud_contents_fadeintime;
2301                         liquidalpha_prev = liquidalpha;
2302                         liquidcolor_prev = liquidcolor;
2303                 }
2304                 else
2305                         contentfadetime = autocvar_hud_contents_fadeouttime;
2306
2307                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
2308                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
2309
2310                 if(contentavgalpha)
2311                         drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
2312
2313                 if(autocvar_hud_postprocessing)
2314                 {
2315                         if(autocvar_hud_contents_blur && contentavgalpha)
2316                         {
2317                                 content_blurpostprocess.x = 1;
2318                                 content_blurpostprocess.y = contentavgalpha * autocvar_hud_contents_blur;
2319                                 content_blurpostprocess.z = contentavgalpha * autocvar_hud_contents_blur_alpha;
2320                         }
2321                         else
2322                         {
2323                                 content_blurpostprocess.x = 0;
2324                                 content_blurpostprocess.y = 0;
2325                                 content_blurpostprocess.z = 0;
2326                         }
2327                 }
2328         }
2329
2330         if(autocvar_hud_damage && !STAT(FROZEN))
2331         {
2332                 splash_size.x = max(vid_conwidth, vid_conheight);
2333                 splash_size.y = max(vid_conwidth, vid_conheight);
2334                 splash_pos.x = (vid_conwidth - splash_size.x) / 2;
2335                 splash_pos.y = (vid_conheight - splash_size.y) / 2;
2336
2337                 float myhealth_flash_temp;
2338                 myhealth = STAT(HEALTH);
2339
2340                 // fade out
2341                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
2342                 // add new damage
2343                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
2344
2345                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
2346                 pain_threshold = autocvar_hud_damage_pain_threshold;
2347                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
2348                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
2349
2350                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
2351                 {
2352                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
2353                 }
2354
2355                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
2356
2357                 if(myhealth_prev < 1)
2358                 {
2359                         if(myhealth >= 1)
2360                         {
2361                                 myhealth_flash = 0; // just spawned, clear the flash immediately
2362                                 myhealth_flash_temp = 0;
2363                         }
2364                         else
2365                         {
2366                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
2367                         }
2368                 }
2369
2370                 if(spectatee_status == -1 || intermission)
2371                 {
2372                         myhealth_flash = 0; // observing, or match ended
2373                         myhealth_flash_temp = 0;
2374                 }
2375
2376                 myhealth_prev = myhealth;
2377
2378                 // IDEA: change damage color/picture based on player model for robot/alien species?
2379                 // pro: matches model better
2380                 // contra: it's not red because blood is red, but because red is an alarming color, so red should stay
2381                 // maybe different reddish pics?
2382                 if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
2383                 {
2384                         if(autocvar_cl_gentle_damage == 2)
2385                         {
2386                                 if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
2387                                         myhealth_gentlergb = randomvec();
2388                         }
2389                         else
2390                                 myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
2391
2392                         if(myhealth_flash_temp > 0)
2393                                 drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
2394                 }
2395                 else if(myhealth_flash_temp > 0)
2396                         drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
2397
2398                 if(autocvar_hud_postprocessing) // we still need to set this anyway even when chase_active is set, this way it doesn't get stuck on.
2399                 {
2400                         if(autocvar_hud_damage_blur && myhealth_flash_temp)
2401                         {
2402                                 damage_blurpostprocess.x = 1;
2403                                 damage_blurpostprocess.y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
2404                                 damage_blurpostprocess.z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
2405                         }
2406                         else
2407                         {
2408                                 damage_blurpostprocess.x = 0;
2409                                 damage_blurpostprocess.y = 0;
2410                                 damage_blurpostprocess.z = 0;
2411                         }
2412                 }
2413         }
2414
2415         float e1 = (autocvar_hud_postprocessing_maxbluralpha != 0);
2416         float e2 = (autocvar_hud_powerup != 0);
2417         if(autocvar_hud_postprocessing && (e1 || e2)) // TODO: Remove this code and re-do the postprocess handling in the engine, where it properly belongs.
2418         {
2419                 // enable or disable rendering types if they are used or not
2420                 if(cvar("r_glsl_postprocess_uservec1_enable") != e1) { cvar_set("r_glsl_postprocess_uservec1_enable", ftos(e1)); }
2421                 if(cvar("r_glsl_postprocess_uservec2_enable") != e2) { cvar_set("r_glsl_postprocess_uservec2_enable", ftos(e2)); }
2422
2423                 // blur postprocess handling done first (used by hud_damage and hud_contents)
2424                 if((damage_blurpostprocess.x || content_blurpostprocess.x))
2425                 {
2426                         float blurradius = bound(0, damage_blurpostprocess.y + content_blurpostprocess.y, autocvar_hud_postprocessing_maxblurradius);
2427                         float bluralpha = bound(0, damage_blurpostprocess.z + content_blurpostprocess.z, autocvar_hud_postprocessing_maxbluralpha);
2428                         if(blurradius != old_blurradius || bluralpha != old_bluralpha) // reduce cvar_set spam as much as possible
2429                         {
2430                                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
2431                                 old_blurradius = blurradius;
2432                                 old_bluralpha = bluralpha;
2433                         }
2434                 }
2435                 else if(cvar_string("r_glsl_postprocess_uservec1") != "0 0 0 0") // reduce cvar_set spam as much as possible
2436                 {
2437                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
2438                         old_blurradius = 0;
2439                         old_bluralpha = 0;
2440                 }
2441
2442                 // edge detection postprocess handling done second (used by hud_powerup)
2443                 float sharpen_intensity = 0, strength_finished = STAT(STRENGTH_FINISHED), invincible_finished = STAT(INVINCIBLE_FINISHED);
2444                 if (strength_finished - time > 0) { sharpen_intensity += (strength_finished - time); }
2445                 if (invincible_finished - time > 0) { sharpen_intensity += (invincible_finished - time); }
2446
2447                 sharpen_intensity = bound(0, ((STAT(HEALTH) > 0) ? sharpen_intensity : 0), 5); // Check to see if player is alive (if not, set 0) - also bound to fade out starting at 5 seconds.
2448
2449                 if(autocvar_hud_powerup && sharpen_intensity > 0)
2450                 {
2451                         if(sharpen_intensity != old_sharpen_intensity) // reduce cvar_set spam as much as possible
2452                         {
2453                                 cvar_set("r_glsl_postprocess_uservec2", strcat(ftos((sharpen_intensity / 5) * autocvar_hud_powerup), " ", ftos(-sharpen_intensity * autocvar_hud_powerup), " 0 0"));
2454                                 old_sharpen_intensity = sharpen_intensity;
2455                         }
2456                 }
2457                 else if(cvar_string("r_glsl_postprocess_uservec2") != "0 0 0 0") // reduce cvar_set spam as much as possible
2458                 {
2459                         cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
2460                         old_sharpen_intensity = 0;
2461                 }
2462
2463                 if(cvar("r_glsl_postprocess") == 0)
2464                         cvar_set("r_glsl_postprocess", "2");
2465         }
2466         else if(cvar("r_glsl_postprocess") == 2)
2467                 cvar_set("r_glsl_postprocess", "0");
2468
2469         /*if(ISGAMETYPE(CTF))
2470           {
2471           ctf_view();
2472           } else */
2473
2474         // draw 2D entities
2475         IL_EACH(g_drawables_2d, it.draw2d, it.draw2d(it));
2476         Draw_ShowNames_All();
2477 #if ENABLE_DEBUGDRAW
2478         Debug_Draw();
2479 #endif
2480
2481         scoreboard_active = Scoreboard_WouldDraw();
2482
2483         HUD_Draw(this); // this parameter for deep vehicle function
2484
2485         if(NextFrameCommand)
2486         {
2487                 localcmd("\n", NextFrameCommand, "\n");
2488                 NextFrameCommand = string_null;
2489         }
2490
2491         // we must do this check AFTER a frame was rendered, or it won't work
2492         if(cs_project_is_b0rked == 0)
2493         {
2494                 string w0, h0;
2495                 w0 = ftos(autocvar_vid_conwidth);
2496                 h0 = ftos(autocvar_vid_conheight);
2497                 //setproperty(VF_VIEWPORT, '0 0 0', '640 480 0');
2498                 //setproperty(VF_FOV, '90 90 0');
2499                 setproperty(VF_ORIGIN, '0 0 0');
2500                 setproperty(VF_ANGLES, '0 0 0');
2501                 setproperty(VF_PERSPECTIVE, 1);
2502                 makevectors('0 0 0');
2503                 vector v1, v2;
2504                 cvar_set("vid_conwidth", "800");
2505                 cvar_set("vid_conheight", "600");
2506                 v1 = cs_project(v_forward);
2507                 cvar_set("vid_conwidth", "640");
2508                 cvar_set("vid_conheight", "480");
2509                 v2 = cs_project(v_forward);
2510                 if(v1 == v2)
2511                         cs_project_is_b0rked = 1;
2512                 else
2513                         cs_project_is_b0rked = -1;
2514                 cvar_set("vid_conwidth", w0);
2515                 cvar_set("vid_conheight", h0);
2516         }
2517
2518         HUD_Mouse(local_player);
2519
2520         cl_notice_run();
2521         unpause_update();
2522         Net_Flush();
2523
2524         // let's reset the view back to normal for the end
2525         setproperty(VF_MIN, '0 0 0');
2526         setproperty(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
2527
2528         IL_ENDFRAME();
2529 }
2530
2531
2532 // following vectors must be global to allow seamless switching between camera modes
2533 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
2534 void CSQC_Demo_Camera()
2535 {
2536         float speed, attenuation, dimensions;
2537         vector tmp, delta;
2538
2539         if( autocvar_camera_reset || !camera_mode )
2540         {
2541                 camera_offset = '0 0 0';
2542                 current_angles = '0 0 0';
2543                 camera_direction = '0 0 0';
2544                 camera_offset.z += 30;
2545                 camera_offset.x += 30 * -cos(current_angles.y * DEG2RAD);
2546                 camera_offset.y += 30 * -sin(current_angles.y * DEG2RAD);
2547                 current_origin = view_origin;
2548                 current_camera_offset  = camera_offset;
2549                 cvar_set("camera_reset", "0");
2550                 camera_mode = CAMERA_CHASE;
2551         }
2552
2553         // Camera angles
2554         if( camera_roll )
2555                 mouse_angles.z += camera_roll * autocvar_camera_speed_roll;
2556
2557         if(autocvar_camera_look_player)
2558         {
2559                 vector dir;
2560                 float n;
2561
2562                 dir = normalize(view_origin - current_position);
2563                 n = mouse_angles.z;
2564                 mouse_angles = vectoangles(dir);
2565                 mouse_angles.x = mouse_angles.x * -1;
2566                 mouse_angles.z = n;
2567         }
2568         else
2569         {
2570                 tmp = getmousepos() * 0.1;
2571                 if(vdist(tmp, >, autocvar_camera_mouse_threshold))
2572                 {
2573                         mouse_angles.x += tmp.y * cos(mouse_angles.z * DEG2RAD) + (tmp.x * sin(mouse_angles.z * DEG2RAD));
2574                         mouse_angles.y -= tmp.x * cos(mouse_angles.z * DEG2RAD) + (tmp.y * -sin(mouse_angles.z * DEG2RAD));
2575                 }
2576         }
2577
2578         while (mouse_angles.x < -180) mouse_angles.x = mouse_angles.x + 360;
2579         while (mouse_angles.x > 180) mouse_angles.x = mouse_angles.x - 360;
2580         while (mouse_angles.y < -180) mouse_angles.y = mouse_angles.y + 360;
2581         while (mouse_angles.y > 180) mouse_angles.y = mouse_angles.y - 360;
2582
2583         // Fix difference when angles don't have the same sign
2584         delta = '0 0 0';
2585         if(mouse_angles.y < -60 && current_angles.y > 60)
2586                 delta = '0 360 0';
2587         if(mouse_angles.y > 60 && current_angles.y < -60)
2588                 delta = '0 -360 0';
2589
2590         if(autocvar_camera_look_player)
2591                 attenuation = autocvar_camera_look_attenuation;
2592         else
2593                 attenuation = autocvar_camera_speed_attenuation;
2594
2595         attenuation = 1 / max(1, attenuation);
2596         current_angles += (mouse_angles - current_angles + delta) * attenuation;
2597
2598         while (current_angles.x < -180) current_angles.x = current_angles.x + 360;
2599         while (current_angles.x > 180) current_angles.x = current_angles.x - 360;
2600         while (current_angles.y < -180) current_angles.y = current_angles.y + 360;
2601         while (current_angles.y > 180) current_angles.y = current_angles.y - 360;
2602
2603         // Camera position
2604         tmp = '0 0 0';
2605         dimensions = 0;
2606
2607         if( camera_direction.x )
2608         {
2609                 tmp.x = camera_direction.x * cos(current_angles.y * DEG2RAD);
2610                 tmp.y = camera_direction.x * sin(current_angles.y * DEG2RAD);
2611                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
2612                         tmp.z = camera_direction.x * -sin(current_angles.x * DEG2RAD);
2613                 ++dimensions;
2614         }
2615
2616         if( camera_direction.y )
2617         {
2618                 tmp.x += camera_direction.y * -sin(current_angles.y * DEG2RAD);
2619                 tmp.y += camera_direction.y * cos(current_angles.y * DEG2RAD) * cos(current_angles.z * DEG2RAD);
2620                 tmp.z += camera_direction.y * sin(current_angles.z * DEG2RAD);
2621                 ++dimensions;
2622         }
2623
2624         if( camera_direction.z )
2625         {
2626                 tmp.z += camera_direction.z * cos(current_angles.z * DEG2RAD);
2627                 ++dimensions;
2628         }
2629
2630         if(autocvar_camera_free)
2631                 speed = autocvar_camera_speed_free;
2632         else
2633                 speed = autocvar_camera_speed_chase;
2634
2635         if(dimensions)
2636         {
2637                 speed = speed * sqrt(1 / dimensions);
2638                 camera_offset += tmp * speed;
2639         }
2640
2641         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
2642
2643         // Camera modes
2644         if( autocvar_camera_free )
2645         {
2646                 if ( camera_mode == CAMERA_CHASE )
2647                 {
2648                         current_camera_offset = current_origin + current_camera_offset;
2649                         camera_offset = current_origin + camera_offset;
2650                 }
2651
2652                 camera_mode = CAMERA_FREE;
2653                 current_position = current_camera_offset;
2654         }
2655         else
2656         {
2657                 if ( camera_mode == CAMERA_FREE )
2658                 {
2659                         current_origin = view_origin;
2660                         camera_offset = camera_offset - current_origin;
2661                         current_camera_offset = current_camera_offset - current_origin;
2662                 }
2663
2664                 camera_mode = CAMERA_CHASE;
2665
2666                 if(autocvar_camera_chase_smoothly)
2667                         current_origin += (view_origin - current_origin) * attenuation;
2668                 else
2669                         current_origin = view_origin;
2670
2671                 current_position = current_origin + current_camera_offset;
2672         }
2673
2674         setproperty(VF_ANGLES, current_angles);
2675         setproperty(VF_ORIGIN, current_position);
2676 }