Merge branch 'master' into terencehill/dynamic_hud
[xonotic/xonotic-data.pk3dir.git] / qcsrc / client / view.qc
1 #include "view.qh"
2
3 #include "announcer.qh"
4 #include "hud/all.qh"
5 #include "mapvoting.qh"
6 #include "scoreboard.qh"
7 #include "shownames.qh"
8 #include "quickmenu.qh"
9
10 #include "mutators/events.qh"
11
12 #include <common/animdecide.qh>
13 #include <common/ent_cs.qh>
14 #include <common/anim.qh>
15 #include <common/constants.qh>
16 #include <common/debug.qh>
17 #include <common/mapinfo.qh>
18 #include <common/gamemodes/all.qh>
19 #include <common/physics/player.qh>
20 #include <common/stats.qh>
21 #include <common/triggers/target/music.qh>
22 #include <common/teams.qh>
23
24 #include <common/vehicles/all.qh>
25 #include <common/weapons/all.qh>
26 #include <common/viewloc.qh>
27 #include <common/minigames/cl_minigames.qh>
28 #include <common/minigames/cl_minigames_hud.qh>
29
30 #include <lib/csqcmodel/cl_player.qh>
31 #include <lib/csqcmodel/cl_model.qh>
32 #include "csqcmodel_hooks.qh"
33
34 #include <lib/warpzone/client.qh>
35 #include <lib/warpzone/common.qh>
36
37 #define EFMASK_CHEAP (EF_ADDITIVE | EF_DOUBLESIDED | EF_FULLBRIGHT | EF_NODEPTHTEST | EF_NODRAW | EF_NOSHADOW | EF_SELECTABLE | EF_TELEPORT_BIT)
38
39 float autocvar_cl_viewmodel_scale;
40
41 bool autocvar_cl_bobmodel;
42 float autocvar_cl_bobmodel_speed;
43 float autocvar_cl_bobmodel_side;
44 float autocvar_cl_bobmodel_up;
45
46 float autocvar_cl_followmodel;
47 float autocvar_cl_followmodel_speed = 0.3;
48 float autocvar_cl_followmodel_limit = 135;
49 float autocvar_cl_followmodel_velocity_lowpass = 0.05;
50 float autocvar_cl_followmodel_highpass = 0.05;
51 float autocvar_cl_followmodel_lowpass = 0.03;
52 bool autocvar_cl_followmodel_velocity_absolute;
53
54 float autocvar_cl_leanmodel;
55 float autocvar_cl_leanmodel_speed = 0.3;
56 float autocvar_cl_leanmodel_limit = 30;
57 float autocvar_cl_leanmodel_highpass1 = 0.2;
58 float autocvar_cl_leanmodel_highpass = 0.2;
59 float autocvar_cl_leanmodel_lowpass = 0.05;
60
61 #define avg_factor(avg_time) (1 - exp(-frametime / max(0.001, avg_time)))
62 #define lowpass(value, frac, ref_store, ret) MACRO_BEGIN \
63 { \
64         ret = ref_store = ref_store * (1 - frac) + (value) * frac; \
65 } MACRO_END
66
67 #define lowpass_limited(value, frac, limit, ref_store, ret) MACRO_BEGIN \
68 { \
69         float __ignore; lowpass(value, frac, ref_store, __ignore); \
70         ret = ref_store = bound((value) - (limit), ref_store, (value) + (limit)); \
71 } MACRO_END
72
73 #define highpass(value, frac, ref_store, ret) MACRO_BEGIN \
74 { \
75         float __f = 0; lowpass(value, frac, ref_store, __f); \
76         ret = (value) - __f; \
77 } MACRO_END
78
79 #define highpass_limited(value, frac, limit, ref_store, ret) MACRO_BEGIN \
80 { \
81         float __f = 0; lowpass_limited(value, frac, limit, ref_store, __f); \
82         ret = (value) - __f; \
83 } MACRO_END
84
85 #define lowpass2(value, frac, ref_store, ref_out) MACRO_BEGIN \
86 { \
87         lowpass(value.x, frac, ref_store.x, ref_out.x); \
88         lowpass(value.y, frac, ref_store.y, ref_out.y); \
89 } MACRO_END
90
91 #define highpass2(value, frac, ref_store, ref_out) MACRO_BEGIN \
92 { \
93         highpass(value.x, frac, ref_store.x, ref_out.x); \
94         highpass(value.y, frac, ref_store.y, ref_out.y); \
95 } MACRO_END
96
97 #define highpass2_limited(value, frac, limit, ref_store, ref_out) MACRO_BEGIN \
98 { \
99         highpass_limited(value.x, frac, limit, ref_store.x, ref_out.x); \
100         highpass_limited(value.y, frac, limit, ref_store.y, ref_out.y); \
101 } MACRO_END
102
103 #define lowpass3(value, frac, ref_store, ref_out) MACRO_BEGIN \
104 { \
105         lowpass(value.x, frac, ref_store.x, ref_out.x); \
106         lowpass(value.y, frac, ref_store.y, ref_out.y); \
107         lowpass(value.z, frac, ref_store.z, ref_out.z); \
108 } MACRO_END
109
110 #define highpass3(value, frac, ref_store, ref_out) MACRO_BEGIN \
111 { \
112         highpass(value.x, frac, ref_store.x, ref_out.x); \
113         highpass(value.y, frac, ref_store.y, ref_out.y); \
114         highpass(value.z, frac, ref_store.z, ref_out.z); \
115 } MACRO_END
116
117 void calc_followmodel_ofs(entity view)
118 {
119         if(cl_followmodel_time == time)
120                 return; // cl_followmodel_ofs already calculated for this frame
121
122         float frac;
123         vector gunorg = '0 0 0';
124         static vector vel_average;
125         static vector gunorg_prev = '0 0 0';
126         static vector gunorg_adjustment_highpass;
127         static vector gunorg_adjustment_lowpass;
128
129         vector vel;
130         if (autocvar_cl_followmodel_velocity_absolute)
131                 vel = view.velocity;
132         else
133         {
134                 vector forward = '0 0 0', right = '0 0 0', up = '0 0 0';
135                 MAKEVECTORS(makevectors, view_angles, forward, right, up);
136                 vel.x = view.velocity * forward;
137                 vel.y = view.velocity * right * -1;
138                 vel.z = view.velocity * up;
139         }
140
141         vel.x = bound(vel_average.x - autocvar_cl_followmodel_limit, vel.x, vel_average.x + autocvar_cl_followmodel_limit);
142         vel.y = bound(vel_average.y - autocvar_cl_followmodel_limit, vel.y, vel_average.y + autocvar_cl_followmodel_limit);
143         vel.z = bound(vel_average.z - autocvar_cl_followmodel_limit, vel.z, vel_average.z + autocvar_cl_followmodel_limit);
144
145         frac = avg_factor(autocvar_cl_followmodel_velocity_lowpass);
146         lowpass3(vel, frac, vel_average, gunorg);
147
148         gunorg *= -autocvar_cl_followmodel_speed * 0.042;
149
150         // perform highpass/lowpass on the adjustment vectors (turning velocity into acceleration!)
151         // trick: we must do the lowpass LAST, so the lowpass vector IS the final vector!
152         frac = avg_factor(autocvar_cl_followmodel_highpass);
153         highpass3(gunorg, frac, gunorg_adjustment_highpass, gunorg);
154         frac = avg_factor(autocvar_cl_followmodel_lowpass);
155         lowpass3(gunorg, frac, gunorg_adjustment_lowpass, gunorg);
156
157         if (autocvar_cl_followmodel_velocity_absolute)
158         {
159                 vector fixed_gunorg;
160                 vector forward = '0 0 0', right = '0 0 0', up = '0 0 0';
161                 MAKEVECTORS(makevectors, view_angles, forward, right, up);
162                 fixed_gunorg.x = gunorg * forward;
163                 fixed_gunorg.y = gunorg * right * -1;
164                 fixed_gunorg.z = gunorg * up;
165                 gunorg = fixed_gunorg;
166         }
167
168         cl_followmodel_ofs = gunorg;
169         cl_followmodel_time = time;
170 }
171
172 vector leanmodel_ofs(entity view)
173 {
174         float frac;
175         vector gunangles = '0 0 0';
176         static vector gunangles_prev = '0 0 0';
177         static vector gunangles_highpass = '0 0 0';
178         static vector gunangles_adjustment_highpass;
179         static vector gunangles_adjustment_lowpass;
180
181         if (view.csqcmodel_teleported)
182                 gunangles_prev = view_angles;
183
184         // in the highpass, we _store_ the DIFFERENCE to the actual view angles...
185         gunangles_highpass += gunangles_prev;
186         PITCH(gunangles_highpass) += 360 * floor((PITCH(view_angles) - PITCH(gunangles_highpass)) / 360 + 0.5);
187         YAW(gunangles_highpass) += 360 * floor((YAW(view_angles) - YAW(gunangles_highpass)) / 360 + 0.5);
188         ROLL(gunangles_highpass) += 360 * floor((ROLL(view_angles) - ROLL(gunangles_highpass)) / 360 + 0.5);
189         frac = avg_factor(autocvar_cl_leanmodel_highpass1);
190         highpass2_limited(view_angles, frac, autocvar_cl_leanmodel_limit, gunangles_highpass, gunangles);
191         gunangles_prev = view_angles;
192         gunangles_highpass -= gunangles_prev;
193
194         PITCH(gunangles) *= -autocvar_cl_leanmodel_speed;
195         YAW(gunangles) *= -autocvar_cl_leanmodel_speed;
196
197         // we assume here: PITCH = 0, YAW = 1, ROLL = 2
198         frac = avg_factor(autocvar_cl_leanmodel_highpass);
199         highpass2(gunangles, frac, gunangles_adjustment_highpass, gunangles);
200         frac = avg_factor(autocvar_cl_leanmodel_lowpass);
201         lowpass2(gunangles, frac, gunangles_adjustment_lowpass, gunangles);
202
203         gunangles.x = -gunangles.x; // pitch was inverted, now that actually matters
204
205         return gunangles;
206 }
207
208 vector bobmodel_ofs(entity view)
209 {
210         bool clonground = !(view.anim_implicit_state & ANIMIMPLICITSTATE_INAIR);
211         static bool oldonground;
212         static float hitgroundtime;
213         if (clonground)
214         {
215                 float f = time; // cl.movecmd[0].time
216                 if (!oldonground)
217                         hitgroundtime = f;
218         }
219         oldonground = clonground;
220
221         // calculate for swinging gun model
222         // the gun bobs when running on the ground, but doesn't bob when you're in the air.
223         vector gunorg = '0 0 0';
224         static float bobmodel_scale = 0;
225         static float time_ofs = 0; // makes the effect always restart in the same way
226         if (clonground)
227         {
228                 if (time - hitgroundtime > 0.05)
229                         bobmodel_scale = min(1, bobmodel_scale + frametime * 5);
230         }
231         else
232                 bobmodel_scale = max(0, bobmodel_scale - frametime * 5);
233
234         float xyspeed = bound(0, vlen(vec2(view.velocity)), 400);
235         if (bobmodel_scale && xyspeed)
236         {
237                 float bspeed = xyspeed * 0.01 * autocvar_cl_viewmodel_scale * bobmodel_scale;
238                 float s = (time - time_ofs) * autocvar_cl_bobmodel_speed;
239                 gunorg.y = bspeed * autocvar_cl_bobmodel_side * sin(s);
240                 gunorg.z = bspeed * autocvar_cl_bobmodel_up * cos(s * 2);
241         }
242         else
243                 time_ofs = time;
244
245         return gunorg;
246 }
247
248 void viewmodel_animate(entity this)
249 {
250         if (autocvar_chase_active) return;
251         if (STAT(HEALTH) <= 0) return;
252
253         entity view = CSQCModel_server2csqc(player_localentnum - 1);
254
255         if (autocvar_cl_followmodel)
256         {
257                 calc_followmodel_ofs(view);
258                 this.origin += cl_followmodel_ofs;
259         }
260
261         if (autocvar_cl_leanmodel)
262                 this.angles += leanmodel_ofs(view);
263
264         // vertical view bobbing code
265         // TODO: cl_bob
266
267         // horizontal view bobbing code
268         // TODO: cl_bob2
269
270         // fall bobbing code
271         // causes the view to swing down and back up when touching the ground
272         // TODO: cl_bobfall
273
274         // gun model bobbing code
275         if (autocvar_cl_bobmodel)
276                 this.origin += bobmodel_ofs(view);
277 }
278
279 .vector viewmodel_origin, viewmodel_angles;
280 .float weapon_nextthink;
281 .float weapon_eta_last;
282 .float weapon_switchdelay;
283
284 void viewmodel_draw(entity this)
285 {
286         if(!activeweapon || !autocvar_r_drawviewmodel)
287                 return;
288         int mask = (intermission || (STAT(HEALTH) <= 0) || autocvar_chase_active) ? 0 : MASK_NORMAL;
289         float a = this.alpha;
290         static bool wasinvehicle;
291         bool invehicle = player_localentnum > maxclients;
292         if (invehicle) a = -1;
293         else if (wasinvehicle) a = 1;
294         wasinvehicle = invehicle;
295         Weapon wep = activeweapon;
296         int c = stof(getplayerkeyvalue(current_player, "colors"));
297         vector g = weaponentity_glowmod(wep, c);
298         entity me = CSQCModel_server2csqc(player_localentnum - 1);
299         int fx = ((me.csqcmodel_effects & EFMASK_CHEAP)
300                 | EF_NODEPTHTEST)
301                 &~ (EF_FULLBRIGHT); // can mask team color, so get rid of it
302         for (entity e = this; e; e = e.weaponchild)
303         {
304                 e.drawmask = mask;
305                 e.alpha = a;
306                 e.colormap = 256 + c;  // colormap == 0 is black, c == 0 is white
307                 e.glowmod = g;
308                 e.csqcmodel_effects = fx;
309                 CSQCModel_Effects_Apply(e);
310         }
311         {
312                 static string name_last;
313                 string name = wep.mdl;
314                 bool swap = name != name_last;
315                 // if (swap)
316                 {
317                         name_last = name;
318                         CL_WeaponEntity_SetModel(this, name, swap);
319                         this.viewmodel_origin = this.origin;
320                         this.viewmodel_angles = this.angles;
321                 }
322                 anim_update(this);
323                 if (!this.animstate_override)
324                         anim_set(this, this.anim_idle, true, false, false);
325         }
326         float f = 0; // 0..1; 0: fully active
327         float rate = STAT(WEAPONRATEFACTOR);
328         float eta = rate ? ((this.weapon_nextthink - time) / rate) : 0;
329         if (eta <= 0) f = this.weapon_eta_last;
330         else switch (this.state)
331         {
332                 case WS_RAISE:
333                 {
334                         f = eta / max(eta, this.weapon_switchdelay);
335                         break;
336                 }
337                 case WS_DROP:
338                 {
339                         f = 1 - eta / max(eta, this.weapon_switchdelay);
340                         break;
341                 }
342                 case WS_CLEAR:
343                 {
344                         f = 1;
345                         break;
346                 }
347         }
348         this.weapon_eta_last = f;
349         this.origin = this.viewmodel_origin;
350         this.angles = this.viewmodel_angles;
351         this.angles_x = (-90 * f * f);
352         viewmodel_animate(this);
353         setorigin(this, this.origin);
354 }
355
356 entity viewmodel;
357 STATIC_INIT(viewmodel) {
358     viewmodel = new(viewmodel);
359 }
360
361 void Porto_Draw(entity this);
362 STATIC_INIT(Porto)
363 {
364         entity e = new_pure(porto);
365         e.draw = Porto_Draw;
366         e.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
367 }
368
369 const int polyline_length = 16;
370 vector polyline[polyline_length];
371 void Porto_Draw(entity this)
372 {
373         if (activeweapon != WEP_PORTO) return;
374         if (spectatee_status) return;
375         if (WEP_CVAR(porto, secondary)) return;
376         if (intermission == 1) return;
377         if (intermission == 2) return;
378         if (STAT(HEALTH) <= 0) return;
379
380         vector pos = view_origin;
381         vector dir = view_forward;
382         if (angles_held_status)
383         {
384                 makevectors(angles_held);
385                 dir = v_forward;
386         }
387
388         polyline[0] = pos;
389
390         int portal_number = 0, portal1_idx = 1, portal_max = 2;
391         int n = 1 + 2;  // 2 lines == 3 points
392         for (int idx = 0; idx < n && idx < polyline_length - 1; )
393         {
394                 traceline(pos, pos + 65536 * dir, true, this);
395                 dir = reflect(dir, trace_plane_normal);
396                 pos = trace_endpos;
397                 polyline[++idx] = pos;
398                 if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
399                 {
400                         n += 1;
401                         continue;
402                 }
403                 if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
404                 {
405                         n = max(2, idx);
406                         break;
407                 }
408                 // check size
409                 {
410                         vector ang = vectoangles2(trace_plane_normal, dir);
411                         ang.x = -ang.x;
412                         makevectors(ang);
413                         if (!CheckWireframeBox(this, pos - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
414                         {
415                                 n = max(2, idx);
416                                 break;
417                         }
418                 }
419                 portal_number += 1;
420                 if (portal_number >= portal_max) break;
421                 if (portal_number == 1) portal1_idx = idx;
422         }
423         for (int idx = 0; idx < n - 1; ++idx)
424         {
425                 vector p = polyline[idx], q = polyline[idx + 1];
426                 if (idx == 0) p -= view_up * 16;  // line from player
427                 vector rgb = (idx < portal1_idx) ? '1 0 0' : '0 0 1';
428                 Draw_CylindricLine(p, q, 4, "", 1, 0, rgb, 0.5, DRAWFLAG_NORMAL, view_origin);
429         }
430 }
431
432 float drawtime;
433 float avgspeed;
434 vector GetCurrentFov(float fov)
435 {
436         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir;
437         float velocityzoom, curspeed;
438         vector v;
439
440         zoomsensitivity = autocvar_cl_zoomsensitivity;
441         zoomfactor = autocvar_cl_zoomfactor;
442         if(zoomfactor < 1 || zoomfactor > 30)
443                 zoomfactor = 2.5;
444         zoomspeed = autocvar_cl_zoomspeed;
445         if(zoomspeed >= 0)
446         if(zoomspeed < 0.5 || zoomspeed > 16)
447                         zoomspeed = 3.5;
448
449         zoomdir = button_zoom;
450         if(hud == HUD_NORMAL)
451         if(switchweapon == activeweapon)
452         if((activeweapon == WEP_VORTEX && !WEP_CVAR(vortex, secondary)) || (activeweapon == WEP_RIFLE && !WEP_CVAR(rifle, secondary))) // do NOT use switchweapon here
453                 zoomdir += button_attack2;
454         if(spectatee_status > 0 || isdemo())
455         {
456                 if(spectatorbutton_zoom)
457                 {
458                         if(zoomdir)
459                                 zoomdir = 0;
460                         else
461                                 zoomdir = 1;
462                 }
463                 // fteqcc failed twice here already, don't optimize this
464         }
465
466         if(zoomdir) { zoomin_effect = 0; }
467
468         if(camera_active)
469         {
470                 current_viewzoom = min(1, current_viewzoom + drawframetime);
471         }
472         else if(autocvar_cl_spawnzoom && zoomin_effect)
473         {
474                 float spawnzoomfactor = bound(1, autocvar_cl_spawnzoom_factor, 30);
475
476                 current_viewzoom += (autocvar_cl_spawnzoom_speed * (spawnzoomfactor - current_viewzoom) * drawframetime);
477                 current_viewzoom = bound(1 / spawnzoomfactor, current_viewzoom, 1);
478                 if(current_viewzoom == 1) { zoomin_effect = 0; }
479         }
480         else
481         {
482                 if(zoomspeed < 0) // instant zoom
483                 {
484                         if(zoomdir)
485                                 current_viewzoom = 1 / zoomfactor;
486                         else
487                                 current_viewzoom = 1;
488                 }
489                 else
490                 {
491                         if(zoomdir)
492                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
493                         else
494                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
495                 }
496         }
497
498         if(almost_equals(current_viewzoom, 1))
499                 current_zoomfraction = 0;
500         else if(almost_equals(current_viewzoom, 1/zoomfactor))
501                 current_zoomfraction = 1;
502         else
503                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
504
505         if(zoomsensitivity < 1)
506                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
507         else
508                 setsensitivityscale(1);
509
510         if(autocvar_cl_velocityzoom_enabled && autocvar_cl_velocityzoom_type) // _type = 0 disables velocity zoom too
511         {
512                 if(intermission) { curspeed = 0; }
513                 else
514                 {
515
516                         makevectors(view_angles);
517                         v = pmove_vel;
518                         if(csqcplayer)
519                                 v = csqcplayer.velocity;
520
521                         switch(autocvar_cl_velocityzoom_type)
522                         {
523                                 case 3: curspeed = max(0, v_forward * v); break;
524                                 case 2: curspeed = (v_forward * v); break;
525                                 case 1: default: curspeed = vlen(v); break;
526                         }
527                 }
528
529                 velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoom_time), 1); // speed at which the zoom adapts to player velocity
530                 avgspeed = avgspeed * (1 - velocityzoom) + (curspeed / autocvar_cl_velocityzoom_speed) * velocityzoom;
531                 velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom_factor / 1) * 1);
532
533                 //print(ftos(avgspeed), " avgspeed, ", ftos(curspeed), " curspeed, ", ftos(velocityzoom), " return\n"); // for debugging
534         }
535         else
536                 velocityzoom = 1;
537
538         float frustumx, frustumy, fovx, fovy;
539         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
540         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
541         fovx = atan2(frustumx, 1) / M_PI * 360.0;
542         fovy = atan2(frustumy, 1) / M_PI * 360.0;
543
544         return '1 0 0' * fovx + '0 1 0' * fovy;
545 }
546
547 vector GetViewLocationFOV(float fov)
548 {
549         float frustumy = tan(fov * M_PI / 360.0) * 0.75;
550         float frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
551         float fovx = atan2(frustumx, 1) / M_PI * 360.0;
552         float fovy = atan2(frustumy, 1) / M_PI * 360.0;
553         return '1 0 0' * fovx + '0 1 0' * fovy;
554 }
555
556 vector GetOrthoviewFOV(vector ov_worldmin, vector ov_worldmax, vector ov_mid, vector ov_org)
557 {
558         float fovx, fovy;
559         float width = (ov_worldmax.x - ov_worldmin.x);
560         float height = (ov_worldmax.y - ov_worldmin.y);
561         float distance_to_middle_of_world = vlen(ov_mid - ov_org);
562         fovx = atan2(width/2, distance_to_middle_of_world) / M_PI * 360.0;
563         fovy = atan2(height/2, distance_to_middle_of_world) / M_PI * 360.0;
564         return '1 0 0' * fovx + '0 1 0' * fovy;
565 }
566
567 // this function must match W_SetupShot!
568 float zoomscript_caught;
569
570 vector wcross_origin;
571 float wcross_scale_prev, wcross_alpha_prev;
572 vector wcross_color_prev;
573 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
574 vector wcross_color_goal_prev;
575 float wcross_changedonetime;
576
577 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
578 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
579 float wcross_name_changestarttime, wcross_name_changedonetime;
580 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
581
582 float wcross_ring_prev;
583
584 entity trueaim;
585 entity trueaim_rifle;
586
587 const float SHOTTYPE_HITTEAM = 1;
588 const float SHOTTYPE_HITOBSTRUCTION = 2;
589 const float SHOTTYPE_HITWORLD = 3;
590 const float SHOTTYPE_HITENEMY = 4;
591
592 void TrueAim_Init()
593 {
594         (trueaim = new_pure(trueaim)).dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
595         (trueaim_rifle = new_pure(trueaim_rifle)).dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
596 }
597
598 float EnemyHitCheck()
599 {
600         float t, n;
601         wcross_origin = project_3d_to_2d(trace_endpos);
602         wcross_origin.z = 0;
603         if(trace_ent)
604                 n = trace_ent.entnum;
605         else
606                 n = trace_networkentity;
607         if(n < 1)
608                 return SHOTTYPE_HITWORLD;
609         if(n > maxclients)
610                 return SHOTTYPE_HITWORLD;
611         t = entcs_GetTeam(n - 1);
612         if(teamplay)
613                 if(t == myteam)
614                         return SHOTTYPE_HITTEAM;
615         if(t == NUM_SPECTATOR)
616                 return SHOTTYPE_HITWORLD;
617         return SHOTTYPE_HITENEMY;
618 }
619
620 float TrueAimCheck()
621 {
622         float nudge = 1; // added to traceline target and subtracted from result TOOD(divVerent): do we still need this? Doesn't the engine do this now for us?
623         vector vecs, trueaimpoint, w_shotorg;
624         vector mi, ma, dv;
625         float shottype;
626         entity ta;
627         float mv;
628
629         mi = ma = '0 0 0';
630         ta = trueaim;
631         mv = MOVE_NOMONSTERS;
632
633         switch(activeweapon) // WEAPONTODO
634         {
635                 case WEP_TUBA: // no aim
636                 case WEP_PORTO: // shoots from eye
637                 case WEP_NEXBALL: // shoots from eye
638                 case WEP_HOOK: // no trueaim
639                 case WEP_MORTAR: // toss curve
640                         return SHOTTYPE_HITWORLD;
641                 case WEP_VORTEX:
642                 case WEP_VAPORIZER:
643                         mv = MOVE_NORMAL;
644                         break;
645                 case WEP_RIFLE:
646                         ta = trueaim_rifle;
647                         mv = MOVE_NORMAL;
648                         if(zoomscript_caught)
649                         {
650                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
651                                 return EnemyHitCheck();
652                         }
653                         break;
654                 case WEP_DEVASTATOR: // projectile has a size!
655                         mi = '-3 -3 -3';
656                         ma = '3 3 3';
657                         break;
658                 case WEP_FIREBALL: // projectile has a size!
659                         mi = '-16 -16 -16';
660                         ma = '16 16 16';
661                         break;
662                 case WEP_SEEKER: // projectile has a size!
663                         mi = '-2 -2 -2';
664                         ma = '2 2 2';
665                         break;
666                 case WEP_ELECTRO: // projectile has a size!
667                         mi = '0 0 -3';
668                         ma = '0 0 -3';
669                         break;
670         }
671
672         vector traceorigin = entcs_receiver(player_localentnum - 1).origin + (eZ * STAT(VIEWHEIGHT));
673
674         vecs = decompressShotOrigin(STAT(SHOTORG));
675
676         traceline(traceorigin, traceorigin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
677         trueaimpoint = trace_endpos;
678
679         if(vdist((trueaimpoint - traceorigin), <, g_trueaim_minrange))
680                 trueaimpoint = traceorigin + view_forward * g_trueaim_minrange;
681
682         if(vecs.x > 0)
683                 vecs.y = -vecs.y;
684         else
685                 vecs = '0 0 0';
686
687         dv = view_right * vecs.y + view_up * vecs.z;
688         w_shotorg = traceorigin + dv;
689
690         // now move the vecs forward as much as requested if possible
691         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs.x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
692         w_shotorg = trace_endpos - view_forward * nudge;
693
694         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
695         shottype = EnemyHitCheck();
696         if(shottype != SHOTTYPE_HITWORLD)
697                 return shottype;
698
699 #if 0
700         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
701         // or rather, I know why, but see no fix
702         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
703                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
704                 return SHOTTYPE_HITOBSTRUCTION;
705 #endif
706
707         return SHOTTYPE_HITWORLD;
708 }
709
710 void PostInit();
711 void CSQC_Demo_Camera();
712 float HUD_WouldDrawScoreboard();
713 float camera_mode;
714 const float CAMERA_FREE = 1;
715 const float CAMERA_CHASE = 2;
716 float reticle_type;
717 string reticle_image;
718 string NextFrameCommand;
719
720 vector freeze_org, freeze_ang;
721 entity nightvision_noise, nightvision_noise2;
722
723 const float MAX_TIME_DIFF = 5;
724 float pickup_crosshair_time, pickup_crosshair_size;
725 float hitindication_crosshair_size;
726 float use_vortex_chargepool;
727
728 float myhealth, myhealth_prev;
729 float myhealth_flash;
730
731 float old_blurradius, old_bluralpha;
732 float old_sharpen_intensity;
733
734 vector myhealth_gentlergb;
735
736 float contentavgalpha, liquidalpha_prev;
737 vector liquidcolor_prev;
738
739 float eventchase_current_distance;
740 float eventchase_running;
741 bool WantEventchase(entity this)
742 {
743         if(autocvar_cl_orthoview)
744                 return false;
745         if(intermission)
746                 return true;
747         if(this.viewloc)
748                 return true;
749         if(spectatee_status >= 0)
750         {
751                 if(hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0))
752                         return true;
753                 if(MUTATOR_CALLHOOK(WantEventchase, this))
754                         return true;
755                 if(autocvar_cl_eventchase_nexball && gametype == MAPINFO_TYPE_NEXBALL && !(WepSet_GetFromStat() & WEPSET(NEXBALL)))
756                         return true;
757                 if(autocvar_cl_eventchase_death && (STAT(HEALTH) <= 0))
758                 {
759                         if(autocvar_cl_eventchase_death == 2)
760                         {
761                                 // don't stop eventchase once it's started (even if velocity changes afterwards)
762                                 if(this.velocity == '0 0 0' || eventchase_running)
763                                         return true;
764                         }
765                         else return true;
766                 }
767         }
768         return false;
769 }
770
771 void HUD_Crosshair_Vehicle()
772 {
773         if(hud != HUD_BUMBLEBEE_GUN)
774         {
775                 Vehicle info = Vehicles_from(hud);
776                 info.vr_crosshair(info);
777         }
778 }
779
780 vector damage_blurpostprocess, content_blurpostprocess;
781
782 float unaccounted_damage = 0;
783 void UpdateDamage()
784 {
785         // accumulate damage with each stat update
786         static float damage_total_prev = 0;
787         float damage_total = STAT(DAMAGE_DEALT_TOTAL);
788         float unaccounted_damage_new = COMPARE_INCREASING(damage_total, damage_total_prev);
789         damage_total_prev = damage_total;
790
791         static float damage_dealt_time_prev = 0;
792         float damage_dealt_time = STAT(HIT_TIME);
793         if (damage_dealt_time != damage_dealt_time_prev)
794         {
795                 unaccounted_damage += unaccounted_damage_new;
796                 LOG_TRACE("dmg total: ", ftos(unaccounted_damage), " (+", ftos(unaccounted_damage_new), ")", "\n");
797         }
798         damage_dealt_time_prev = damage_dealt_time;
799
800         // prevent hitsound when switching spectatee
801         static float spectatee_status_prev = 0;
802         if (spectatee_status != spectatee_status_prev)
803                 unaccounted_damage = 0;
804         spectatee_status_prev = spectatee_status;
805 }
806
807 void HitSound()
808 {
809         // varying sound pitch
810
811         static float hitsound_time_prev = 0;
812         // HACK: the only way to get the arc to sound consistent with pitch shift is to ignore cl_hitsound_antispam_time
813         float arc_hack = activeweapon == WEP_ARC && autocvar_cl_hitsound >= 2;
814         if (arc_hack || COMPARE_INCREASING(time, hitsound_time_prev) > autocvar_cl_hitsound_antispam_time)
815         {
816                 if (autocvar_cl_hitsound && unaccounted_damage)
817                 {
818                         // customizable gradient function that crosses (0,a), (c,1) and asymptotically approaches b
819                         float a = autocvar_cl_hitsound_max_pitch;
820                         float b = autocvar_cl_hitsound_min_pitch;
821                         float c = autocvar_cl_hitsound_nom_damage;
822                         float x = unaccounted_damage;
823                         float pitch_shift = (b*x*(a-1) + a*c*(1-b)) / (x*(a-1) + c*(1-b));
824
825                         // if sound variation is disabled, set pitch_shift to 1
826                         if (autocvar_cl_hitsound == 1)
827                                 pitch_shift = 1;
828
829                         // if pitch shift is reversed, mirror in (max-min)/2 + min
830                         if (autocvar_cl_hitsound == 3)
831                         {
832                                 float mirror_value = (a-b)/2 + b;
833                                 pitch_shift = mirror_value + (mirror_value - pitch_shift);
834                         }
835
836                         LOG_TRACE("dmg total (dmg): ", ftos(unaccounted_damage), " , pitch shift: ", ftos(pitch_shift), "\n");
837
838                         // todo: avoid very long and very short sounds from wave stretching using different sound files? seems unnecessary
839                         // todo: normalize sound pressure levels? seems unnecessary
840
841                         sound7(world, CH_INFO, SND(HIT), VOL_BASE, ATTN_NONE, pitch_shift * 100, 0);
842                 }
843                 unaccounted_damage = 0;
844                 hitsound_time_prev = time;
845         }
846
847         static float typehit_time_prev = 0;
848         float typehit_time = STAT(TYPEHIT_TIME);
849         if (COMPARE_INCREASING(typehit_time, typehit_time_prev) > autocvar_cl_hitsound_antispam_time)
850         {
851                 sound(world, CH_INFO, SND_TYPEHIT, VOL_BASE, ATTN_NONE);
852                 typehit_time_prev = typehit_time;
853         }
854 }
855
856 void HUD_Crosshair()
857 {SELFPARAM();
858         static float rainbow_last_flicker;
859         static vector rainbow_prev_color;
860         entity e = this;
861         float f, i, j;
862         vector v;
863         if(!scoreboard_active && !camera_active && intermission != 2 &&
864                 spectatee_status != -1 && !csqcplayer.viewloc &&
865                 !HUD_MinigameMenu_IsOpened() )
866         {
867                 if (!autocvar_crosshair_enabled) // main toggle for crosshair rendering
868                         return;
869
870                 if (hud != HUD_NORMAL)
871                 {
872                         HUD_Crosshair_Vehicle();
873                         return;
874                 }
875
876                 string wcross_style;
877                 float wcross_alpha, wcross_resolution;
878                 wcross_style = autocvar_crosshair;
879                 if (wcross_style == "0")
880                         return;
881                 wcross_resolution = autocvar_crosshair_size;
882                 if (wcross_resolution == 0)
883                         return;
884                 wcross_alpha = autocvar_crosshair_alpha;
885                 if (wcross_alpha == 0)
886                         return;
887
888                 // TrueAim check
889                 float shottype;
890
891                 // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
892                 wcross_origin = project_3d_to_2d(view_origin + MAX_SHOT_DISTANCE * view_forward);
893                 wcross_origin.z = 0;
894                 if(autocvar_crosshair_hittest)
895                 {
896                         vector wcross_oldorigin;
897                         wcross_oldorigin = wcross_origin;
898                         shottype = TrueAimCheck();
899                         if(shottype == SHOTTYPE_HITWORLD)
900                         {
901                                 v = wcross_origin - wcross_oldorigin;
902                                 v.x /= vid_conwidth;
903                                 v.y /= vid_conheight;
904                                 if(vlen(v) > 0.01)
905                                         shottype = SHOTTYPE_HITOBSTRUCTION;
906                         }
907                         if(!autocvar_crosshair_hittest_showimpact)
908                                 wcross_origin = wcross_oldorigin;
909                 }
910                 else
911                         shottype = SHOTTYPE_HITWORLD;
912
913                 vector wcross_color = '0 0 0', wcross_size = '0 0 0';
914                 string wcross_name = "";
915                 float wcross_scale, wcross_blur;
916
917                 if(autocvar_crosshair_per_weapon || (autocvar_crosshair_color_special == 1))
918                 {
919                         e = switchingweapon;
920                         if(e)
921                         {
922                                 if(autocvar_crosshair_per_weapon)
923                                 {
924                                         // WEAPONTODO: access these through some general settings (with non-balance config settings)
925                                         //wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
926                                         //if (wcross_resolution == 0)
927                                                 //return;
928
929                                         //wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
930                                         wcross_resolution *= e.w_crosshair_size;
931                                         wcross_name = e.w_crosshair;
932                                 }
933                         }
934                 }
935
936                 if(wcross_name == "")
937                         wcross_name = strcat("gfx/crosshair", wcross_style);
938
939                 // MAIN CROSSHAIR COLOR DECISION
940                 switch(autocvar_crosshair_color_special)
941                 {
942                         case 1: // crosshair_color_per_weapon
943                         {
944                                 if(e)
945                                 {
946                                         wcross_color = e.wpcolor;
947                                         break;
948                                 }
949                                 else { goto normalcolor; }
950                         }
951
952                         case 2: // crosshair_color_by_health
953                         {
954                                 float x = STAT(HEALTH);
955
956                                 //x = red
957                                 //y = green
958                                 //z = blue
959
960                                 wcross_color.z = 0;
961
962                                 if(x > 200)
963                                 {
964                                         wcross_color.x = 0;
965                                         wcross_color.y = 1;
966                                 }
967                                 else if(x > 150)
968                                 {
969                                         wcross_color.x = 0.4 - (x-150)*0.02 * 0.4;
970                                         wcross_color.y = 0.9 + (x-150)*0.02 * 0.1;
971                                 }
972                                 else if(x > 100)
973                                 {
974                                         wcross_color.x = 1 - (x-100)*0.02 * 0.6;
975                                         wcross_color.y = 1 - (x-100)*0.02 * 0.1;
976                                         wcross_color.z = 1 - (x-100)*0.02;
977                                 }
978                                 else if(x > 50)
979                                 {
980                                         wcross_color.x = 1;
981                                         wcross_color.y = 1;
982                                         wcross_color.z = 0.2 + (x-50)*0.02 * 0.8;
983                                 }
984                                 else if(x > 20)
985                                 {
986                                         wcross_color.x = 1;
987                                         wcross_color.y = (x-20)*90/27/100;
988                                         wcross_color.z = (x-20)*90/27/100 * 0.2;
989                                 }
990                                 else
991                                 {
992                                         wcross_color.x = 1;
993                                         wcross_color.y = 0;
994                                 }
995                                 break;
996                         }
997
998                         case 3: // crosshair_color_rainbow
999                         {
1000                                 if(time >= rainbow_last_flicker)
1001                                 {
1002                                         rainbow_prev_color = randomvec() * autocvar_crosshair_color_special_rainbow_brightness;
1003                                         rainbow_last_flicker = time + autocvar_crosshair_color_special_rainbow_delay;
1004                                 }
1005                                 wcross_color = rainbow_prev_color;
1006                                 break;
1007                         }
1008 LABEL(normalcolor)
1009                         default: { wcross_color = stov(autocvar_crosshair_color); break; }
1010                 }
1011
1012                 if(autocvar_crosshair_effect_scalefade)
1013                 {
1014                         wcross_scale = wcross_resolution;
1015                         wcross_resolution = 1;
1016                 }
1017                 else
1018                 {
1019                         wcross_scale = 1;
1020                 }
1021
1022                 if(autocvar_crosshair_pickup)
1023                 {
1024                         float stat_pickup_time = STAT(LAST_PICKUP);
1025
1026                         if(pickup_crosshair_time < stat_pickup_time)
1027                         {
1028                                 if(time - stat_pickup_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1029                                         pickup_crosshair_size = 1;
1030
1031                                 pickup_crosshair_time = stat_pickup_time;
1032                         }
1033
1034                         if(pickup_crosshair_size > 0)
1035                                 pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
1036                         else
1037                                 pickup_crosshair_size = 0;
1038
1039                         wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
1040                 }
1041
1042                 // todo: make crosshair hit indication dependent on damage dealt
1043                 if(autocvar_crosshair_hitindication)
1044                 {
1045                         vector hitindication_color = ((autocvar_crosshair_color_special == 1) ? stov(autocvar_crosshair_hitindication_per_weapon_color) : stov(autocvar_crosshair_hitindication_color));
1046
1047                         if(unaccounted_damage)
1048                         {
1049                                 hitindication_crosshair_size = 1;
1050                         }
1051
1052                         if(hitindication_crosshair_size > 0)
1053                                 hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
1054                         else
1055                                 hitindication_crosshair_size = 0;
1056
1057                         wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
1058                         wcross_color.x += sin(hitindication_crosshair_size) * hitindication_color.x;
1059                         wcross_color.y += sin(hitindication_crosshair_size) * hitindication_color.y;
1060                         wcross_color.z += sin(hitindication_crosshair_size) * hitindication_color.z;
1061                 }
1062
1063                 if(shottype == SHOTTYPE_HITENEMY)
1064                         wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
1065                 if(shottype == SHOTTYPE_HITTEAM)
1066                         wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
1067
1068                 f = fabs(autocvar_crosshair_effect_time);
1069                 if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
1070                 {
1071                         wcross_changedonetime = time + f;
1072                 }
1073                 if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
1074                 {
1075                         wcross_name_changestarttime = time;
1076                         wcross_name_changedonetime = time + f;
1077                         if(wcross_name_goal_prev_prev)
1078                                 strunzone(wcross_name_goal_prev_prev);
1079                         wcross_name_goal_prev_prev = wcross_name_goal_prev;
1080                         wcross_name_goal_prev = strzone(wcross_name);
1081                         wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
1082                         wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
1083                         wcross_resolution_goal_prev = wcross_resolution;
1084                 }
1085
1086                 wcross_scale_goal_prev = wcross_scale;
1087                 wcross_alpha_goal_prev = wcross_alpha;
1088                 wcross_color_goal_prev = wcross_color;
1089
1090                 if(spectatee_status == -1 && shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
1091                 {
1092                         wcross_blur = 1;
1093                         wcross_alpha *= 0.75;
1094                 }
1095                 else
1096                         wcross_blur = 0;
1097                 // *_prev is at time-frametime
1098                 // * is at wcross_changedonetime+f
1099                 // what do we have at time?
1100                 if(time < wcross_changedonetime)
1101                 {
1102                         f = frametime / (wcross_changedonetime - time + frametime);
1103                         wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
1104                         wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
1105                         wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
1106                 }
1107
1108                 wcross_scale_prev = wcross_scale;
1109                 wcross_alpha_prev = wcross_alpha;
1110                 wcross_color_prev = wcross_color;
1111
1112                 MUTATOR_CALLHOOK(UpdateCrosshair);
1113
1114                 wcross_scale *= 1 - autocvar__menu_alpha;
1115                 wcross_alpha *= 1 - autocvar__menu_alpha;
1116                 wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1117
1118                 if(wcross_scale >= 0.001 && wcross_alpha >= 0.001)
1119                 {
1120                         // crosshair rings for weapon stats
1121                         if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
1122                         {
1123                                 // declarations and stats
1124                                 float ring_value = 0, ring_scale = 0, ring_alpha = 0, ring_inner_value = 0, ring_inner_alpha = 0;
1125                                 string ring_image = string_null, ring_inner_image = string_null;
1126                                 vector ring_rgb = '0 0 0', ring_inner_rgb = '0 0 0';
1127
1128                                 ring_scale = autocvar_crosshair_ring_size;
1129
1130                                 float weapon_clipload, weapon_clipsize;
1131                                 weapon_clipload = STAT(WEAPON_CLIPLOAD);
1132                                 weapon_clipsize = STAT(WEAPON_CLIPSIZE);
1133
1134                                 float ok_ammo_charge, ok_ammo_chargepool;
1135                                 ok_ammo_charge = STAT(OK_AMMO_CHARGE);
1136                                 ok_ammo_chargepool = STAT(OK_AMMO_CHARGEPOOL);
1137
1138                                 float vortex_charge, vortex_chargepool;
1139                                 vortex_charge = STAT(VORTEX_CHARGE);
1140                                 vortex_chargepool = STAT(VORTEX_CHARGEPOOL);
1141
1142                                 float arc_heat = STAT(ARC_HEAT);
1143
1144                                 if(vortex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
1145                                         vortex_charge_movingavg = vortex_charge;
1146
1147
1148                                 // handle the values
1149                                 if (autocvar_crosshair_ring && activeweapon == WEP_VORTEX && vortex_charge && autocvar_crosshair_ring_vortex) // ring around crosshair representing velocity-dependent damage for the vortex
1150                                 {
1151                                         if (vortex_chargepool || use_vortex_chargepool) {
1152                                                 use_vortex_chargepool = 1;
1153                                                 ring_inner_value = vortex_chargepool;
1154                                         } else {
1155                                                 vortex_charge_movingavg = (1 - autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate) * vortex_charge_movingavg + autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate * vortex_charge;
1156                                                 ring_inner_value = bound(0, autocvar_crosshair_ring_vortex_currentcharge_scale * (vortex_charge - vortex_charge_movingavg), 1);
1157                                         }
1158
1159                                         ring_inner_alpha = autocvar_crosshair_ring_vortex_inner_alpha;
1160                                         ring_inner_rgb = eX * autocvar_crosshair_ring_vortex_inner_color_red + eY * autocvar_crosshair_ring_vortex_inner_color_green + eZ * autocvar_crosshair_ring_vortex_inner_color_blue;
1161                                         ring_inner_image = "gfx/crosshair_ring_inner.tga";
1162
1163                                         // draw the outer ring to show the current charge of the weapon
1164                                         ring_value = vortex_charge;
1165                                         ring_alpha = autocvar_crosshair_ring_vortex_alpha;
1166                                         ring_rgb = wcross_color;
1167                                         ring_image = "gfx/crosshair_ring_nexgun.tga";
1168                                 }
1169                                 else if (autocvar_crosshair_ring && activeweapon == WEP_MINE_LAYER && WEP_CVAR(minelayer, limit) && autocvar_crosshair_ring_minelayer)
1170                                 {
1171                                         ring_value = bound(0, STAT(LAYED_MINES) / WEP_CVAR(minelayer, limit), 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
1172                                         ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
1173                                         ring_rgb = wcross_color;
1174                                         ring_image = "gfx/crosshair_ring.tga";
1175                                 }
1176                                 else if (activeweapon == WEP_HAGAR && STAT(HAGAR_LOAD) && autocvar_crosshair_ring_hagar)
1177                                 {
1178                                         ring_value = bound(0, STAT(HAGAR_LOAD) / WEP_CVAR_SEC(hagar, load_max), 1);
1179                                         ring_alpha = autocvar_crosshair_ring_hagar_alpha;
1180                                         ring_rgb = wcross_color;
1181                                         ring_image = "gfx/crosshair_ring.tga";
1182                                 }
1183                                 else if (ok_ammo_charge)
1184                                 {
1185                                         ring_value = ok_ammo_chargepool;
1186                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
1187                                         ring_rgb = wcross_color;
1188                                         ring_image = "gfx/crosshair_ring.tga";
1189                                 }
1190                                 else if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
1191                                 {
1192                                         ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
1193                                         ring_scale = autocvar_crosshair_ring_reload_size;
1194                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
1195                                         ring_rgb = wcross_color;
1196
1197                                         // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
1198                                         // if a new image for another weapon is added, add the code (and its respective file/value) here
1199                                         if ((activeweapon == WEP_RIFLE) && (weapon_clipsize == 80))
1200                                                 ring_image = "gfx/crosshair_ring_rifle.tga";
1201                                         else
1202                                                 ring_image = "gfx/crosshair_ring.tga";
1203                                 }
1204                                 else if ( autocvar_crosshair_ring && autocvar_crosshair_ring_arc && arc_heat && activeweapon == WEP_ARC )
1205                                 {
1206                                         ring_value = arc_heat;
1207                                         ring_alpha = (1-arc_heat)*autocvar_crosshair_ring_arc_cold_alpha +
1208                                                 arc_heat*autocvar_crosshair_ring_arc_hot_alpha;
1209                                         ring_rgb = (1-arc_heat)*wcross_color + arc_heat*autocvar_crosshair_ring_arc_hot_color;
1210                                         ring_image = "gfx/crosshair_ring.tga";
1211                                 }
1212
1213                                 // if in weapon switch animation, fade ring out/in
1214                                 if(autocvar_crosshair_effect_time > 0)
1215                                 {
1216                                         f = (time - wcross_name_changestarttime) / autocvar_crosshair_effect_time;
1217                                         if (f >= 1)
1218                                         {
1219                                                 wcross_ring_prev = ((ring_image) ? true : false);
1220                                         }
1221
1222                                         if(wcross_ring_prev)
1223                                         {
1224                                                 if(f < 1)
1225                                                         ring_alpha *= fabs(1 - bound(0, f, 1));
1226                                         }
1227                                         else
1228                                         {
1229                                                 if(f < 1)
1230                                                         ring_alpha *= bound(0, f, 1);
1231                                         }
1232                                 }
1233
1234                                 if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
1235                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
1236
1237                                 if (ring_value)
1238                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
1239                         }
1240
1241 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
1242                         MACRO_BEGIN { \
1243                                 if(wcross_blur > 0) \
1244                                 { \
1245                                         for(i = -2; i <= 2; ++i) \
1246                                         for(j = -2; j <= 2; ++j) \
1247                                         M(i,j,sz,wcross_name,wcross_alpha*0.04); \
1248                                 } \
1249                                 else \
1250                                 { \
1251                                         M(0,0,sz,wcross_name,wcross_alpha); \
1252                                 } \
1253                         } MACRO_END
1254
1255 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
1256                         drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size.x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size.y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
1257
1258 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
1259                         CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
1260
1261                         if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
1262                         {
1263                                 f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
1264                                 wcross_size = draw_getimagesize(wcross_name_goal_prev_prev) * wcross_scale;
1265                                 CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
1266                                 f = 1 - f;
1267                         }
1268                         else
1269                         {
1270                                 f = 1;
1271                         }
1272                         wcross_name_alpha_goal_prev = f;
1273
1274                         wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1275                         CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
1276
1277                         if(autocvar_crosshair_dot)
1278                         {
1279                                 vector wcross_color_old;
1280                                 wcross_color_old = wcross_color;
1281
1282                                 if((autocvar_crosshair_dot_color_custom) && (autocvar_crosshair_dot_color != "0"))
1283                                         wcross_color = stov(autocvar_crosshair_dot_color);
1284
1285                                 CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
1286                                 // FIXME why don't we use wcross_alpha here?
1287                                 wcross_color = wcross_color_old;
1288                         }
1289                 }
1290         }
1291         else
1292         {
1293                 wcross_scale_prev = 0;
1294                 wcross_alpha_prev = 0;
1295                 wcross_scale_goal_prev = 0;
1296                 wcross_alpha_goal_prev = 0;
1297                 wcross_changedonetime = 0;
1298                 if(wcross_name_goal_prev)
1299                         strunzone(wcross_name_goal_prev);
1300                 wcross_name_goal_prev = string_null;
1301                 if(wcross_name_goal_prev_prev)
1302                         strunzone(wcross_name_goal_prev_prev);
1303                 wcross_name_goal_prev_prev = string_null;
1304                 wcross_name_changestarttime = 0;
1305                 wcross_name_changedonetime = 0;
1306                 wcross_name_alpha_goal_prev = 0;
1307                 wcross_name_alpha_goal_prev_prev = 0;
1308                 wcross_resolution_goal_prev = 0;
1309                 wcross_resolution_goal_prev_prev = 0;
1310         }
1311 }
1312
1313 void HUD_Draw()
1314 {
1315         if (MUTATOR_CALLHOOK(HUD_Draw_overlay))
1316         {
1317                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, MUTATOR_ARGV(0, vector), autocvar_hud_colorflash_alpha * MUTATOR_ARGV(0, float), DRAWFLAG_ADDITIVE);
1318         }
1319         else if(STAT(FROZEN))
1320         {
1321                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, ((STAT(REVIVE_PROGRESS)) ? ('0.25 0.90 1' + ('1 0 0' * STAT(REVIVE_PROGRESS)) + ('0 1 1' * STAT(REVIVE_PROGRESS) * -1)) : '0.25 0.90 1'), autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1322         }
1323         if(!intermission)
1324         if(STAT(NADE_TIMER) && autocvar_cl_nade_timer) // give nade top priority, as it's a matter of life and death
1325         {
1326                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(NADE_TIMER), '0.25 0.90 1' + ('1 0 0' * STAT(NADE_TIMER)) - ('0 1 1' * STAT(NADE_TIMER)), autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1327                 drawstring_aspect(eY * 0.64 * vid_conheight, ((autocvar_cl_nade_timer == 2) ? _("Nade timer") : ""), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
1328         }
1329         else if(STAT(REVIVE_PROGRESS))
1330         {
1331                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1332                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Revival progress"), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
1333         }
1334
1335         if(autocvar_r_letterbox == 0)
1336                 if(autocvar_viewsize < 120)
1337                 {
1338                         if(!(gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS))
1339                                 Accuracy_LoadLevels();
1340
1341                         HUD_Main();
1342                         HUD_DrawScoreboard();
1343                 }
1344
1345         // crosshair goes VERY LAST
1346         UpdateDamage();
1347         HUD_Crosshair();
1348         HitSound();
1349 }
1350
1351 bool ov_enabled;
1352 float oldr_nearclip;
1353 float oldr_farclip_base;
1354 float oldr_farclip_world;
1355 float oldr_novis;
1356 float oldr_useportalculling;
1357 float oldr_useinfinitefarclip;
1358
1359 void cl_notice_run();
1360 float prev_myteam;
1361 int lasthud;
1362 float vh_notice_time;
1363 void WaypointSprite_Load();
1364 void CSQC_UpdateView(float w, float h)
1365 {SELFPARAM();
1366     TC(int, w); TC(int, h);
1367         entity e;
1368         float fov;
1369         float f;
1370         vector vf_size, vf_min;
1371         float a;
1372
1373         execute_next_frame();
1374
1375         ++framecount;
1376
1377         stats_get();
1378         hud = STAT(HUD);
1379
1380         if(hud != HUD_NORMAL && lasthud == HUD_NORMAL)
1381                 vh_notice_time = time + autocvar_cl_vehicles_notify_time;
1382
1383         lasthud = hud;
1384
1385         if(autocvar__hud_showbinds_reload) // menu can set this one
1386         {
1387                 db_close(binddb);
1388                 binddb = db_create();
1389                 cvar_set("_hud_showbinds_reload", "0");
1390         }
1391
1392         if(checkextension("DP_CSQC_MINFPS_QUALITY"))
1393                 view_quality = getproperty(VF_MINFPS_QUALITY);
1394         else
1395                 view_quality = 1;
1396
1397         button_attack2 = PHYS_INPUT_BUTTON_ATCK2(this);
1398         button_zoom = PHYS_INPUT_BUTTON_ZOOM(this);
1399
1400         vf_size = getpropertyvec(VF_SIZE);
1401         vf_min = getpropertyvec(VF_MIN);
1402         vid_width = vf_size.x;
1403         vid_height = vf_size.y;
1404
1405         vector reticle_pos = '0 0 0', reticle_size = '0 0 0';
1406         vector splash_pos = '0 0 0', splash_size = '0 0 0';
1407
1408         WaypointSprite_Load();
1409
1410         CSQCPlayer_SetCamera();
1411
1412         if(player_localentnum <= maxclients) // is it a client?
1413                 current_player = player_localentnum - 1;
1414         else // then player_localentnum is the vehicle I'm driving
1415                 current_player = player_localnum;
1416         myteam = entcs_GetTeam(current_player);
1417
1418         if(myteam != prev_myteam)
1419         {
1420                 myteamcolors = colormapPaletteColor(myteam, 1);
1421                 FOREACH(hud_panels, true, it.update_time = time);
1422                 prev_myteam = myteam;
1423         }
1424
1425         ticrate = STAT(MOVEVARS_TICRATE) * STAT(MOVEVARS_TIMESCALE);
1426
1427         float is_dead = (STAT(HEALTH) <= 0);
1428
1429         // FIXME do we need this hack?
1430         if(isdemo())
1431         {
1432                 // in demos, input_buttons do not work
1433                 button_zoom = (autocvar__togglezoom == "-");
1434         }
1435         else if(button_zoom
1436                 && autocvar_cl_unpress_zoom_on_death
1437                 && (spectatee_status >= 0)
1438                 && (is_dead || intermission))
1439         {
1440                 // no zoom while dead or in intermission please
1441                 localcmd("-zoom\n");
1442                 button_zoom = false;
1443         }
1444
1445         // event chase camera
1446         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
1447         {
1448                 float vehicle_chase = (hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0));
1449                 float ons_roundlost = (gametype == MAPINFO_TYPE_ONSLAUGHT && STAT(ROUNDLOST));
1450                 entity gen = world;
1451
1452                 float vehicle_viewdist = 0;
1453                 vector vehicle_viewofs = '0 0 0';
1454
1455                 if(vehicle_chase)
1456                 {
1457                         if(hud != HUD_BUMBLEBEE_GUN)
1458                         {
1459                                 Vehicle info = Vehicles_from(hud);
1460                                 vehicle_viewdist = info.height;
1461                                 vehicle_viewofs = info.view_ofs;
1462                         }
1463                 }
1464
1465                 if(ons_roundlost)
1466                 {
1467                         FOREACH_ENTITY_CLASS("onslaught_generator", it.health <= 0, {
1468                                 gen = it;
1469                                 break;
1470                         });
1471                         if(!gen)
1472                                 ons_roundlost = false; // don't enforce the 3rd person camera if there is no dead generator to show
1473                 }
1474                 if(WantEventchase(self) || (!autocvar_cl_orthoview && ons_roundlost))
1475                 {
1476                         eventchase_running = true;
1477
1478                         entity local_player = ((csqcplayer) ? csqcplayer : CSQCModel_server2csqc(player_localentnum - 1));
1479                         if(!local_player)
1480                                 local_player = self; // fall back!
1481
1482                         // make special vector since we can't use view_origin (It is one frame old as of this code, it gets set later with the results this code makes.)
1483                         vector current_view_origin = (csqcplayer ? csqcplayer.origin : pmove_org);
1484                         if(ons_roundlost) { current_view_origin = gen.origin; }
1485
1486                         // detect maximum viewoffset and use it
1487                         vector view_offset = autocvar_cl_eventchase_viewoffset;
1488                         if(vehicle_chase)
1489                         {
1490                                 if(vehicle_viewofs)
1491                                         view_offset = vehicle_viewofs;
1492                                 else
1493                                         view_offset = autocvar_cl_eventchase_vehicle_viewoffset;
1494                         }
1495                         if(ons_roundlost) { view_offset = autocvar_cl_eventchase_generator_viewoffset; }
1496
1497                         if(view_offset)
1498                         {
1499                                 WarpZone_TraceLine(current_view_origin, current_view_origin + view_offset + ('0 0 1' * autocvar_cl_eventchase_maxs.z), MOVE_WORLDONLY, self);
1500                                 if(trace_fraction == 1) { current_view_origin += view_offset; }
1501                                 else { current_view_origin.z += max(0, (trace_endpos.z - current_view_origin.z) - autocvar_cl_eventchase_maxs.z); }
1502                         }
1503
1504                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
1505                         // Ideally, there should be another way to enable third person cameras, such as through setproperty()
1506                         // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
1507                         if(!autocvar_chase_active) { cvar_set("chase_active", "-1"); }
1508
1509                         // make the camera smooth back
1510                         float chase_distance = autocvar_cl_eventchase_distance;
1511                         if(vehicle_chase)
1512                         {
1513                                 if(vehicle_viewofs)
1514                                         chase_distance = vehicle_viewdist;
1515                                 else
1516                                         chase_distance = autocvar_cl_eventchase_vehicle_distance;
1517                         }
1518                         if(ons_roundlost) { chase_distance = autocvar_cl_eventchase_generator_distance; }
1519
1520                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < chase_distance)
1521                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (chase_distance - eventchase_current_distance) * frametime; // slow down the further we get
1522                         else if(eventchase_current_distance != chase_distance)
1523                                 eventchase_current_distance = chase_distance;
1524
1525                         makevectors(view_angles);
1526
1527                         vector eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1528                         WarpZone_TraceBox(current_view_origin, autocvar_cl_eventchase_mins, autocvar_cl_eventchase_maxs, eventchase_target_origin, MOVE_WORLDONLY, self);
1529
1530                         // If the boxtrace fails, revert back to line tracing.
1531                         if(!local_player.viewloc)
1532                         if(trace_startsolid)
1533                         {
1534                                 eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1535                                 WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, self);
1536                                 setproperty(VF_ORIGIN, (trace_endpos - (v_forward * autocvar_cl_eventchase_mins.z)));
1537                         }
1538                         else { setproperty(VF_ORIGIN, trace_endpos); }
1539
1540                         if(!local_player.viewloc)
1541                                 setproperty(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
1542                 }
1543                 else if(autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
1544                 {
1545                         eventchase_running = false;
1546                         cvar_set("chase_active", "0");
1547                         eventchase_current_distance = 0; // start from 0 next time
1548                 }
1549         }
1550         // workaround for camera stuck between player's legs when using chase_active 1
1551         // because the engine stops updating the chase_active camera when the game ends
1552         else if(intermission)
1553         {
1554                 cvar_settemp("chase_active", "-1");
1555                 eventchase_current_distance = 0;
1556         }
1557
1558         // do lockview after event chase camera so that it still applies whenever necessary.
1559         if(autocvar_cl_lockview || (!autocvar_hud_cursormode && (autocvar__hud_configure && spectatee_status <= 0 || intermission > 1 || QuickMenu_IsOpened())))
1560         {
1561                 setproperty(VF_ORIGIN, freeze_org);
1562                 setproperty(VF_ANGLES, freeze_ang);
1563         }
1564         else
1565         {
1566                 freeze_org = getpropertyvec(VF_ORIGIN);
1567                 freeze_ang = getpropertyvec(VF_ANGLES);
1568         }
1569
1570         WarpZone_FixView();
1571         //WarpZone_FixPMove();
1572
1573         vector ov_org = '0 0 0';
1574         vector ov_mid = '0 0 0';
1575         vector ov_worldmin = '0 0 0';
1576         vector ov_worldmax = '0 0 0';
1577         if(autocvar_cl_orthoview)
1578         {
1579                 ov_worldmin = mi_picmin;
1580                 ov_worldmax = mi_picmax;
1581
1582                 float ov_width = (ov_worldmax.x - ov_worldmin.x);
1583                 float ov_height = (ov_worldmax.y - ov_worldmin.y);
1584                 float ov_distance = (max(vid_width, vid_height) * max(ov_width, ov_height));
1585
1586                 ov_mid = ((ov_worldmax + ov_worldmin) * 0.5);
1587                 ov_org = vec3(ov_mid.x, ov_mid.y, (ov_mid.z + ov_distance));
1588
1589                 float ov_nearest = vlen(ov_org - vec3(
1590                         bound(ov_worldmin.x, ov_org.x, ov_worldmax.x),
1591                         bound(ov_worldmin.y, ov_org.y, ov_worldmax.y),
1592                         bound(ov_worldmin.z, ov_org.z, ov_worldmax.z)
1593                 ));
1594
1595                 float ov_furthest = 0;
1596                 float dist = 0;
1597
1598                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1599                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1600                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1601                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1602                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1603                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1604                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1605                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1606
1607                 if(!ov_enabled)
1608                 {
1609                         oldr_nearclip = cvar("r_nearclip");
1610                         oldr_farclip_base = cvar("r_farclip_base");
1611                         oldr_farclip_world = cvar("r_farclip_world");
1612                         oldr_novis = cvar("r_novis");
1613                         oldr_useportalculling = cvar("r_useportalculling");
1614                         oldr_useinfinitefarclip = cvar("r_useinfinitefarclip");
1615                 }
1616
1617                 cvar_settemp("r_nearclip", ftos(ov_nearest));
1618                 cvar_settemp("r_farclip_base", ftos(ov_furthest));
1619                 cvar_settemp("r_farclip_world", "0");
1620                 cvar_settemp("r_novis", "1");
1621                 cvar_settemp("r_useportalculling", "0");
1622                 cvar_settemp("r_useinfinitefarclip", "0");
1623
1624                 setproperty(VF_ORIGIN, ov_org);
1625                 setproperty(VF_ANGLES, '90 0 0');
1626
1627                 ov_enabled = true;
1628
1629                 #if 0
1630                 LOG_INFOF("OrthoView: org = %s, angles = %s, distance = %f, nearest = %f, furthest = %f\n",
1631                         vtos(ov_org),
1632                         vtos(getpropertyvec(VF_ANGLES)),
1633                         ov_distance,
1634                         ov_nearest,
1635                         ov_furthest);
1636                 #endif
1637         }
1638         else
1639         {
1640                 if(ov_enabled)
1641                 {
1642                         cvar_set("r_nearclip", ftos(oldr_nearclip));
1643                         cvar_set("r_farclip_base", ftos(oldr_farclip_base));
1644                         cvar_set("r_farclip_world", ftos(oldr_farclip_world));
1645                         cvar_set("r_novis", ftos(oldr_novis));
1646                         cvar_set("r_useportalculling", ftos(oldr_useportalculling));
1647                         cvar_set("r_useinfinitefarclip", ftos(oldr_useinfinitefarclip));
1648                 }
1649                 ov_enabled = false;
1650         }
1651
1652         // run viewmodel_draw before updating view_angles to the angles calculated by WarpZone_FixView
1653         // viewmodel_draw needs to use the view_angles set by the engine on every CSQC_UpdateView call
1654         viewmodel_draw(viewmodel);
1655
1656         // Render the Scene
1657         view_origin = getpropertyvec(VF_ORIGIN);
1658         view_angles = getpropertyvec(VF_ANGLES);
1659         makevectors(view_angles);
1660         view_forward = v_forward;
1661         view_right = v_right;
1662         view_up = v_up;
1663
1664 #ifdef BLURTEST
1665         if(time > blurtest_time0 && time < blurtest_time1)
1666         {
1667                 float r, t;
1668
1669                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
1670                 r = t * blurtest_radius;
1671                 f = 1 / pow(t, blurtest_power) - 1;
1672
1673                 cvar_set("r_glsl_postprocess", "1");
1674                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
1675         }
1676         else
1677         {
1678                 cvar_set("r_glsl_postprocess", "0");
1679                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
1680         }
1681 #endif
1682
1683         TargetMusic_Advance();
1684         Fog_Force();
1685
1686         if(drawtime == 0)
1687                 drawframetime = 0.01666667; // when we don't know fps yet, we assume 60fps
1688         else
1689                 drawframetime = bound(0.000001, time - drawtime, 1);
1690         drawtime = time;
1691
1692         // watch for gametype changes here...
1693         // in ParseStuffCMD the cmd isn't executed yet :/
1694         // might even be better to add the gametype to TE_CSQC_INIT...?
1695         if(!postinit)
1696                 PostInit();
1697
1698         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
1699         {
1700                 if(calledhooks & HOOK_START)
1701                 {
1702                         localcmd("\ncl_hook_gameend\n");
1703                         calledhooks |= HOOK_END;
1704                 }
1705         }
1706
1707         Announcer();
1708
1709         fov = autocvar_fov;
1710         if(fov <= 59.5)
1711         {
1712                 if(!zoomscript_caught)
1713                 {
1714                         localcmd("+button9\n");
1715                         zoomscript_caught = 1;
1716                 }
1717         }
1718         else
1719         {
1720                 if(zoomscript_caught)
1721                 {
1722                         localcmd("-button9\n");
1723                         zoomscript_caught = 0;
1724                 }
1725         }
1726
1727         ColorTranslateMode = autocvar_cl_stripcolorcodes;
1728
1729         // currently switching-to weapon (for crosshair)
1730         switchingweapon = Weapons_from(STAT(SWITCHINGWEAPON));
1731
1732         // actually active weapon (for zoom)
1733         activeweapon = Weapons_from(STAT(ACTIVEWEAPON));
1734
1735         switchweapon = Weapons_from(STAT(SWITCHWEAPON));
1736
1737         f = (serverflags & SERVERFLAG_TEAMPLAY);
1738         if(f != teamplay)
1739         {
1740                 teamplay = f;
1741                 HUD_InitScores();
1742         }
1743
1744         if(last_switchweapon != switchweapon)
1745         {
1746                 weapontime = time;
1747                 last_switchweapon = switchweapon;
1748                 if(button_zoom && autocvar_cl_unpress_zoom_on_weapon_switch)
1749                 {
1750                         localcmd("-zoom\n");
1751                         button_zoom = false;
1752                 }
1753                 if(autocvar_cl_unpress_attack_on_weapon_switch)
1754                 {
1755                         localcmd("-fire\n");
1756                         localcmd("-fire2\n");
1757                         button_attack2 = false;
1758                 }
1759         }
1760         if(last_activeweapon != activeweapon)
1761         {
1762                 last_activeweapon = activeweapon;
1763
1764                 e = activeweapon;
1765                 if(e.netname != "")
1766                         localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
1767                 else
1768                         localcmd("\ncl_hook_activeweapon none\n");
1769         }
1770
1771         // ALWAYS Clear Current Scene First
1772         clearscene();
1773
1774         setproperty(VF_ORIGIN, view_origin);
1775         setproperty(VF_ANGLES, view_angles);
1776
1777         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
1778         setproperty(VF_SIZE, vf_size);
1779         setproperty(VF_MIN, vf_min);
1780
1781         // Assign Standard Viewflags
1782         // Draw the World (and sky)
1783         setproperty(VF_DRAWWORLD, 1);
1784
1785         // Set the console size vars
1786         vid_conwidth = autocvar_vid_conwidth;
1787         vid_conheight = autocvar_vid_conheight;
1788         vid_pixelheight = autocvar_vid_pixelheight;
1789
1790         if(autocvar_cl_orthoview) { setproperty(VF_FOV, GetOrthoviewFOV(ov_worldmin, ov_worldmax, ov_mid, ov_org)); }
1791         else if(csqcplayer.viewloc) { setproperty(VF_FOV, GetViewLocationFOV(110)); } // enforce 110 fov, so things dont look odd
1792         else { setproperty(VF_FOV, GetCurrentFov(fov)); }
1793
1794         // Camera for demo playback
1795         if(camera_active)
1796         {
1797                 if(autocvar_camera_enable)
1798                         CSQC_Demo_Camera();
1799                 else
1800                 {
1801                         cvar_set("chase_active", ftos(chase_active_backup));
1802                         cvar_set("cl_demo_mousegrab", "0");
1803                         camera_active = false;
1804                 }
1805         }
1806         else
1807         {
1808 #ifdef CAMERATEST
1809                 if(autocvar_camera_enable)
1810 #else
1811                 if(autocvar_camera_enable && isdemo())
1812 #endif
1813                 {
1814                         // Enable required Darkplaces cvars
1815                         chase_active_backup = autocvar_chase_active;
1816                         cvar_set("chase_active", "2");
1817                         cvar_set("cl_demo_mousegrab", "1");
1818                         camera_active = true;
1819                         camera_mode = false;
1820                 }
1821         }
1822
1823         // Draw the Crosshair
1824         setproperty(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
1825
1826         // Draw the Engine Status Bar (the default Quake HUD)
1827         setproperty(VF_DRAWENGINESBAR, 0);
1828
1829         // Update the mouse position
1830         /*
1831            mousepos_x = vid_conwidth;
1832            mousepos_y = vid_conheight;
1833            mousepos = mousepos*0.5 + getmousepos();
1834          */
1835
1836         FOREACH_ENTITY(it.draw, it.draw(it));
1837
1838         addentities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
1839         renderscene();
1840
1841         // now switch to 2D drawing mode by calling a 2D drawing function
1842         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
1843         // next R_RenderScene call
1844         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
1845
1846         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
1847         if (!(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT))
1848         {
1849                 // apply night vision effect
1850                 vector tc_00, tc_01, tc_10, tc_11;
1851                 vector rgb = '0 0 0';
1852
1853                 if(!nightvision_noise)
1854                 {
1855                         nightvision_noise = new(nightvision_noise);
1856                 }
1857                 if(!nightvision_noise2)
1858                 {
1859                         nightvision_noise2 = new(nightvision_noise2);
1860                 }
1861
1862                 // color tint in yellow
1863                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
1864
1865                 // draw BG
1866                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
1867                 rgb = '1 1 1';
1868                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
1869                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
1870                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
1871                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
1872                 tc_11 = tc_01 + tc_10 - tc_00;
1873                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
1874                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
1875                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
1876                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
1877                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
1878                 R_EndPolygon();
1879
1880                 // draw FG
1881                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
1882                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
1883                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
1884                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
1885                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
1886                 tc_11 = tc_01 + tc_10 - tc_00;
1887                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
1888                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
1889                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
1890                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
1891                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
1892                 R_EndPolygon();
1893         }
1894
1895         if(autocvar_cl_reticle)
1896         {
1897                 Weapon wep = activeweapon;
1898                 // Draw the aiming reticle for weapons that use it
1899                 // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
1900                 // It must be a persisted float for fading out to work properly (you let go of the zoom button for
1901                 // the view to go back to normal, so reticle_type would become 0 as we fade out)
1902                 if(spectatee_status || is_dead || hud != HUD_NORMAL)
1903                 {
1904                         // no zoom reticle while dead
1905                         reticle_type = 0;
1906                 }
1907                 else if(wep.wr_zoomreticle(wep) && autocvar_cl_reticle_weapon)
1908                 {
1909                         if(reticle_image != "") { reticle_type = 2; }
1910                         else { reticle_type = 0; }
1911                 }
1912                 else if(button_zoom || zoomscript_caught)
1913                 {
1914                         // normal zoom
1915                         reticle_type = 1;
1916                 }
1917
1918                 if(reticle_type)
1919                 {
1920                         if(autocvar_cl_reticle_stretch)
1921                         {
1922                                 reticle_size.x = vid_conwidth;
1923                                 reticle_size.y = vid_conheight;
1924                                 reticle_pos.x = 0;
1925                                 reticle_pos.y = 0;
1926                         }
1927                         else
1928                         {
1929                                 reticle_size.x = max(vid_conwidth, vid_conheight);
1930                                 reticle_size.y = max(vid_conwidth, vid_conheight);
1931                                 reticle_pos.x = (vid_conwidth - reticle_size.x) / 2;
1932                                 reticle_pos.y = (vid_conheight - reticle_size.y) / 2;
1933                         }
1934
1935                         if(zoomscript_caught)
1936                                 f = 1;
1937                         else
1938                                 f = current_zoomfraction;
1939
1940                         if(f)
1941                         {
1942                                 switch(reticle_type)
1943                                 {
1944                                         case 1: drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_normal_alpha, DRAWFLAG_NORMAL); break;
1945                                         case 2: drawpic(reticle_pos, reticle_image, reticle_size, '1 1 1', f * autocvar_cl_reticle_weapon_alpha, DRAWFLAG_NORMAL); break;
1946                                 }
1947                         }
1948                 }
1949         }
1950         else
1951         {
1952                 if(reticle_type != 0) { reticle_type = 0; }
1953         }
1954
1955
1956         // improved polyblend
1957         if(autocvar_hud_contents)
1958         {
1959                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
1960                 vector liquidcolor;
1961
1962                 switch(pointcontents(view_origin))
1963                 {
1964                         case CONTENT_WATER:
1965                                 liquidalpha = autocvar_hud_contents_water_alpha;
1966                                 liquidcolor = stov(autocvar_hud_contents_water_color);
1967                                 incontent = 1;
1968                                 break;
1969
1970                         case CONTENT_LAVA:
1971                                 liquidalpha = autocvar_hud_contents_lava_alpha;
1972                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
1973                                 incontent = 1;
1974                                 break;
1975
1976                         case CONTENT_SLIME:
1977                                 liquidalpha = autocvar_hud_contents_slime_alpha;
1978                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
1979                                 incontent = 1;
1980                                 break;
1981
1982                         default:
1983                                 liquidalpha = 0;
1984                                 liquidcolor = '0 0 0';
1985                                 incontent = 0;
1986                                 break;
1987                 }
1988
1989                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
1990                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
1991                         contentfadetime = autocvar_hud_contents_fadeintime;
1992                         liquidalpha_prev = liquidalpha;
1993                         liquidcolor_prev = liquidcolor;
1994                 }
1995                 else
1996                         contentfadetime = autocvar_hud_contents_fadeouttime;
1997
1998                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
1999                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
2000
2001                 if(contentavgalpha)
2002                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
2003
2004                 if(autocvar_hud_postprocessing)
2005                 {
2006                         if(autocvar_hud_contents_blur && contentavgalpha)
2007                         {
2008                                 content_blurpostprocess.x = 1;
2009                                 content_blurpostprocess.y = contentavgalpha * autocvar_hud_contents_blur;
2010                                 content_blurpostprocess.z = contentavgalpha * autocvar_hud_contents_blur_alpha;
2011                         }
2012                         else
2013                         {
2014                                 content_blurpostprocess.x = 0;
2015                                 content_blurpostprocess.y = 0;
2016                                 content_blurpostprocess.z = 0;
2017                         }
2018                 }
2019         }
2020
2021         if(autocvar_hud_damage && !STAT(FROZEN))
2022         {
2023                 splash_size.x = max(vid_conwidth, vid_conheight);
2024                 splash_size.y = max(vid_conwidth, vid_conheight);
2025                 splash_pos.x = (vid_conwidth - splash_size.x) / 2;
2026                 splash_pos.y = (vid_conheight - splash_size.y) / 2;
2027
2028                 float myhealth_flash_temp;
2029                 myhealth = STAT(HEALTH);
2030
2031                 // fade out
2032                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
2033                 // add new damage
2034                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
2035
2036                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
2037                 pain_threshold = autocvar_hud_damage_pain_threshold;
2038                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
2039                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
2040
2041                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
2042                 {
2043                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
2044                 }
2045
2046                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
2047
2048                 if(myhealth_prev < 1)
2049                 {
2050                         if(myhealth >= 1)
2051                         {
2052                                 myhealth_flash = 0; // just spawned, clear the flash immediately
2053                                 myhealth_flash_temp = 0;
2054                         }
2055                         else
2056                         {
2057                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
2058                         }
2059                 }
2060
2061                 if(spectatee_status == -1 || intermission)
2062                 {
2063                         myhealth_flash = 0; // observing, or match ended
2064                         myhealth_flash_temp = 0;
2065                 }
2066
2067                 myhealth_prev = myhealth;
2068
2069                 // IDEA: change damage color/picture based on player model for robot/alien species?
2070                 // pro: matches model better
2071                 // contra: it's not red because blood is red, but because red is an alarming color, so red should stay
2072                 // maybe different reddish pics?
2073                 if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
2074                 {
2075                         if(autocvar_cl_gentle_damage == 2)
2076                         {
2077                                 if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
2078                                         myhealth_gentlergb = eX * random() + eY * random() + eZ * random();
2079                         }
2080                         else
2081                                 myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
2082
2083                         if(myhealth_flash_temp > 0)
2084                                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
2085                 }
2086                 else if(myhealth_flash_temp > 0)
2087                         drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
2088
2089                 if(autocvar_hud_postprocessing) // we still need to set this anyway even when chase_active is set, this way it doesn't get stuck on.
2090                 {
2091                         if(autocvar_hud_damage_blur && myhealth_flash_temp)
2092                         {
2093                                 damage_blurpostprocess.x = 1;
2094                                 damage_blurpostprocess.y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
2095                                 damage_blurpostprocess.z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
2096                         }
2097                         else
2098                         {
2099                                 damage_blurpostprocess.x = 0;
2100                                 damage_blurpostprocess.y = 0;
2101                                 damage_blurpostprocess.z = 0;
2102                         }
2103                 }
2104         }
2105
2106         float e1 = (autocvar_hud_postprocessing_maxbluralpha != 0);
2107         float e2 = (autocvar_hud_powerup != 0);
2108         if(autocvar_hud_postprocessing && (e1 || e2)) // TODO: Remove this code and re-do the postprocess handling in the engine, where it properly belongs.
2109         {
2110                 // enable or disable rendering types if they are used or not
2111                 if(cvar("r_glsl_postprocess_uservec1_enable") != e1) { cvar_set("r_glsl_postprocess_uservec1_enable", ftos(e1)); }
2112                 if(cvar("r_glsl_postprocess_uservec2_enable") != e2) { cvar_set("r_glsl_postprocess_uservec2_enable", ftos(e2)); }
2113
2114                 // blur postprocess handling done first (used by hud_damage and hud_contents)
2115                 if((damage_blurpostprocess.x || content_blurpostprocess.x))
2116                 {
2117                         float blurradius = bound(0, damage_blurpostprocess.y + content_blurpostprocess.y, autocvar_hud_postprocessing_maxblurradius);
2118                         float bluralpha = bound(0, damage_blurpostprocess.z + content_blurpostprocess.z, autocvar_hud_postprocessing_maxbluralpha);
2119                         if(blurradius != old_blurradius || bluralpha != old_bluralpha) // reduce cvar_set spam as much as possible
2120                         {
2121                                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
2122                                 old_blurradius = blurradius;
2123                                 old_bluralpha = bluralpha;
2124                         }
2125                 }
2126                 else if(cvar_string("r_glsl_postprocess_uservec1") != "0 0 0 0") // reduce cvar_set spam as much as possible
2127                 {
2128                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
2129                         old_blurradius = 0;
2130                         old_bluralpha = 0;
2131                 }
2132
2133                 // edge detection postprocess handling done second (used by hud_powerup)
2134                 float sharpen_intensity = 0, strength_finished = STAT(STRENGTH_FINISHED), invincible_finished = STAT(INVINCIBLE_FINISHED);
2135                 if (strength_finished - time > 0) { sharpen_intensity += (strength_finished - time); }
2136                 if (invincible_finished - time > 0) { sharpen_intensity += (invincible_finished - time); }
2137
2138                 sharpen_intensity = bound(0, ((STAT(HEALTH) > 0) ? sharpen_intensity : 0), 5); // Check to see if player is alive (if not, set 0) - also bound to fade out starting at 5 seconds.
2139
2140                 if(autocvar_hud_powerup && sharpen_intensity > 0)
2141                 {
2142                         if(sharpen_intensity != old_sharpen_intensity) // reduce cvar_set spam as much as possible
2143                         {
2144                                 cvar_set("r_glsl_postprocess_uservec2", strcat(ftos((sharpen_intensity / 5) * autocvar_hud_powerup), " ", ftos(-sharpen_intensity * autocvar_hud_powerup), " 0 0"));
2145                                 old_sharpen_intensity = sharpen_intensity;
2146                         }
2147                 }
2148                 else if(cvar_string("r_glsl_postprocess_uservec2") != "0 0 0 0") // reduce cvar_set spam as much as possible
2149                 {
2150                         cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
2151                         old_sharpen_intensity = 0;
2152                 }
2153
2154                 if(cvar("r_glsl_postprocess") == 0)
2155                         cvar_set("r_glsl_postprocess", "2");
2156         }
2157         else if(cvar("r_glsl_postprocess") == 2)
2158                 cvar_set("r_glsl_postprocess", "0");
2159
2160         /*if(gametype == MAPINFO_TYPE_CTF)
2161           {
2162           ctf_view();
2163           } else */
2164
2165         // draw 2D entities
2166         FOREACH_ENTITY(it.draw2d, it.draw2d(it));
2167         Draw_ShowNames_All();
2168         Debug_Draw();
2169
2170         scoreboard_active = HUD_WouldDrawScoreboard();
2171
2172         HUD_Draw();
2173
2174         if(NextFrameCommand)
2175         {
2176                 localcmd("\n", NextFrameCommand, "\n");
2177                 NextFrameCommand = string_null;
2178         }
2179
2180         // we must do this check AFTER a frame was rendered, or it won't work
2181         if(cs_project_is_b0rked == 0)
2182         {
2183                 string w0, h0;
2184                 w0 = ftos(autocvar_vid_conwidth);
2185                 h0 = ftos(autocvar_vid_conheight);
2186                 //setproperty(VF_VIEWPORT, '0 0 0', '640 480 0');
2187                 //setproperty(VF_FOV, '90 90 0');
2188                 setproperty(VF_ORIGIN, '0 0 0');
2189                 setproperty(VF_ANGLES, '0 0 0');
2190                 setproperty(VF_PERSPECTIVE, 1);
2191                 makevectors('0 0 0');
2192                 vector v1, v2;
2193                 cvar_set("vid_conwidth", "800");
2194                 cvar_set("vid_conheight", "600");
2195                 v1 = cs_project(v_forward);
2196                 cvar_set("vid_conwidth", "640");
2197                 cvar_set("vid_conheight", "480");
2198                 v2 = cs_project(v_forward);
2199                 if(v1 == v2)
2200                         cs_project_is_b0rked = 1;
2201                 else
2202                         cs_project_is_b0rked = -1;
2203                 cvar_set("vid_conwidth", w0);
2204                 cvar_set("vid_conheight", h0);
2205         }
2206
2207         if(autocvar__hud_configure)
2208                 HUD_Panel_Mouse();
2209         else if ( HUD_MinigameMenu_IsOpened() || minigame_isactive() )
2210                 HUD_Minigame_Mouse();
2211         else if(QuickMenu_IsOpened())
2212                 QuickMenu_Mouse();
2213         else
2214                 HUD_Radar_Mouse();
2215
2216         cl_notice_run();
2217         unpause_update();
2218         Net_Flush();
2219
2220         // let's reset the view back to normal for the end
2221         setproperty(VF_MIN, '0 0 0');
2222         setproperty(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
2223 }
2224
2225
2226 // following vectors must be global to allow seamless switching between camera modes
2227 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
2228 void CSQC_Demo_Camera()
2229 {
2230         float speed, attenuation, dimensions;
2231         vector tmp, delta;
2232
2233         if( autocvar_camera_reset || !camera_mode )
2234         {
2235                 camera_offset = '0 0 0';
2236                 current_angles = '0 0 0';
2237                 camera_direction = '0 0 0';
2238                 camera_offset.z += 30;
2239                 camera_offset.x += 30 * -cos(current_angles.y * DEG2RAD);
2240                 camera_offset.y += 30 * -sin(current_angles.y * DEG2RAD);
2241                 current_origin = view_origin;
2242                 current_camera_offset  = camera_offset;
2243                 cvar_set("camera_reset", "0");
2244                 camera_mode = CAMERA_CHASE;
2245         }
2246
2247         // Camera angles
2248         if( camera_roll )
2249                 mouse_angles.z += camera_roll * autocvar_camera_speed_roll;
2250
2251         if(autocvar_camera_look_player)
2252         {
2253                 vector dir;
2254                 float n;
2255
2256                 dir = normalize(view_origin - current_position);
2257                 n = mouse_angles.z;
2258                 mouse_angles = vectoangles(dir);
2259                 mouse_angles.x = mouse_angles.x * -1;
2260                 mouse_angles.z = n;
2261         }
2262         else
2263         {
2264                 tmp = getmousepos() * 0.1;
2265                 if(vdist(tmp, >, autocvar_camera_mouse_threshold))
2266                 {
2267                         mouse_angles.x += tmp.y * cos(mouse_angles.z * DEG2RAD) + (tmp.x * sin(mouse_angles.z * DEG2RAD));
2268                         mouse_angles.y -= tmp.x * cos(mouse_angles.z * DEG2RAD) + (tmp.y * -sin(mouse_angles.z * DEG2RAD));
2269                 }
2270         }
2271
2272         while (mouse_angles.x < -180) mouse_angles.x = mouse_angles.x + 360;
2273         while (mouse_angles.x > 180) mouse_angles.x = mouse_angles.x - 360;
2274         while (mouse_angles.y < -180) mouse_angles.y = mouse_angles.y + 360;
2275         while (mouse_angles.y > 180) mouse_angles.y = mouse_angles.y - 360;
2276
2277         // Fix difference when angles don't have the same sign
2278         delta = '0 0 0';
2279         if(mouse_angles.y < -60 && current_angles.y > 60)
2280                 delta = '0 360 0';
2281         if(mouse_angles.y > 60 && current_angles.y < -60)
2282                 delta = '0 -360 0';
2283
2284         if(autocvar_camera_look_player)
2285                 attenuation = autocvar_camera_look_attenuation;
2286         else
2287                 attenuation = autocvar_camera_speed_attenuation;
2288
2289         attenuation = 1 / max(1, attenuation);
2290         current_angles += (mouse_angles - current_angles + delta) * attenuation;
2291
2292         while (current_angles.x < -180) current_angles.x = current_angles.x + 360;
2293         while (current_angles.x > 180) current_angles.x = current_angles.x - 360;
2294         while (current_angles.y < -180) current_angles.y = current_angles.y + 360;
2295         while (current_angles.y > 180) current_angles.y = current_angles.y - 360;
2296
2297         // Camera position
2298         tmp = '0 0 0';
2299         dimensions = 0;
2300
2301         if( camera_direction.x )
2302         {
2303                 tmp.x = camera_direction.x * cos(current_angles.y * DEG2RAD);
2304                 tmp.y = camera_direction.x * sin(current_angles.y * DEG2RAD);
2305                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
2306                         tmp.z = camera_direction.x * -sin(current_angles.x * DEG2RAD);
2307                 ++dimensions;
2308         }
2309
2310         if( camera_direction.y )
2311         {
2312                 tmp.x += camera_direction.y * -sin(current_angles.y * DEG2RAD);
2313                 tmp.y += camera_direction.y * cos(current_angles.y * DEG2RAD) * cos(current_angles.z * DEG2RAD);
2314                 tmp.z += camera_direction.y * sin(current_angles.z * DEG2RAD);
2315                 ++dimensions;
2316         }
2317
2318         if( camera_direction.z )
2319         {
2320                 tmp.z += camera_direction.z * cos(current_angles.z * DEG2RAD);
2321                 ++dimensions;
2322         }
2323
2324         if(autocvar_camera_free)
2325                 speed = autocvar_camera_speed_free;
2326         else
2327                 speed = autocvar_camera_speed_chase;
2328
2329         if(dimensions)
2330         {
2331                 speed = speed * sqrt(1 / dimensions);
2332                 camera_offset += tmp * speed;
2333         }
2334
2335         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
2336
2337         // Camera modes
2338         if( autocvar_camera_free )
2339         {
2340                 if ( camera_mode == CAMERA_CHASE )
2341                 {
2342                         current_camera_offset = current_origin + current_camera_offset;
2343                         camera_offset = current_origin + camera_offset;
2344                 }
2345
2346                 camera_mode = CAMERA_FREE;
2347                 current_position = current_camera_offset;
2348         }
2349         else
2350         {
2351                 if ( camera_mode == CAMERA_FREE )
2352                 {
2353                         current_origin = view_origin;
2354                         camera_offset = camera_offset - current_origin;
2355                         current_camera_offset = current_camera_offset - current_origin;
2356                 }
2357
2358                 camera_mode = CAMERA_CHASE;
2359
2360                 if(autocvar_camera_chase_smoothly)
2361                         current_origin += (view_origin - current_origin) * attenuation;
2362                 else
2363                         current_origin = view_origin;
2364
2365                 current_position = current_origin + current_camera_offset;
2366         }
2367
2368         setproperty(VF_ANGLES, current_angles);
2369         setproperty(VF_ORIGIN, current_position);
2370 }