qcsrc/client/view.qc

   1 #include "view.qh"
   2
   3 #include <client/announcer.qh>
   4 #include <client/csqcmodel_hooks.qh>
   5 #include <client/draw.qh>
   6 #include <client/hud/_mod.qh>
   7 #include <client/hud/panel/quickmenu.qh>
   8 #include <client/hud/panel/scoreboard.qh>
   9 #include <client/mapvoting.qh>
  10 #include <client/mutators/_mod.qh>
  11 #include <client/shownames.qh>
  12 #include <common/anim.qh>
  13 #include <common/animdecide.qh>
  14 #include <common/constants.qh>
  15 #include <common/deathtypes/all.qh>
  16 #include <common/debug.qh>
  17 #include <common/ent_cs.qh>
  18 #include <common/gamemodes/_mod.qh>
  19 #include <common/mapinfo.qh>
  20 #include <common/mapobjects/target/music.qh>
  21 #include <common/mapobjects/trigger/viewloc.qh>
  22 #include <common/minigames/cl_minigames.qh>
  23 #include <common/minigames/cl_minigames_hud.qh>
  24 #include <common/mutators/mutator/powerups/_mod.qh>
  25 #include <common/mutators/mutator/status_effects/_mod.qh>
  26 #include <common/mutators/mutator/waypoints/all.qh>
  27 #include <common/net_linked.qh>
  28 #include <common/net_notice.qh>
  29 #include <common/physics/player.qh>
  30 #include <common/stats.qh>
  31 #include <common/teams.qh>
  32 #include <common/vehicles/all.qh>
  33 #include <common/viewloc.qh>
  34 #include <common/weapons/_all.qh>
  35 #include <common/weapons/weapon/tuba.qh>
  36 #include <common/wepent.qh>
  37 #include <lib/csqcmodel/cl_model.qh>
  38 #include <lib/csqcmodel/cl_player.qh>
  39 #include <lib/warpzone/client.qh>
  40 #include <lib/warpzone/common.qh>
  41
  42 float autocvar_cl_viewmodel_scale;
  43 float autocvar_cl_viewmodel_alpha = 1;
  44
  45 bool autocvar_cl_bobmodel;
  46 float autocvar_cl_bobmodel_speed;
  47 float autocvar_cl_bobmodel_side;
  48 float autocvar_cl_bobmodel_up;
  49
  50 float autocvar_cl_followmodel;
  51 float autocvar_cl_followmodel_speed = 0.3;
  52 float autocvar_cl_followmodel_limit = 135;
  53 float autocvar_cl_followmodel_velocity_lowpass = 0.05;
  54 float autocvar_cl_followmodel_highpass = 0.05;
  55 float autocvar_cl_followmodel_lowpass = 0.03;
  56 bool autocvar_cl_followmodel_velocity_absolute;
  57
  58 float autocvar_cl_leanmodel;
  59 float autocvar_cl_leanmodel_speed = 0.3;
  60 float autocvar_cl_leanmodel_limit = 30;
  61 float autocvar_cl_leanmodel_highpass1 = 0.2;
  62 float autocvar_cl_leanmodel_highpass = 0.2;
  63 float autocvar_cl_leanmodel_lowpass = 0.05;
  64
  65 #define avg_factor(avg_time) (1 - exp(-frametime / max(0.001, avg_time)))
  66
  67 #define lowpass(value, frac, ref_store, ret) \
  68         ret = ref_store = ref_store * (1 - frac) + (value) * frac;
  69
  70 #define lowpass_limited(value, frac, limit, ref_store, ret) MACRO_BEGIN \
  71         float __ignore; lowpass(value, frac, ref_store, __ignore); \
  72         ret = ref_store = bound((value) - (limit), ref_store, (value) + (limit)); \
  73 MACRO_END
  74
  75 #define highpass(value, frac, ref_store, ret) MACRO_BEGIN \
  76         float __f = 0; lowpass(value, frac, ref_store, __f); \
  77         ret = (value) - __f; \
  78 MACRO_END
  79
  80 #define highpass_limited(value, frac, limit, ref_store, ret) MACRO_BEGIN \
  81         float __f = 0; lowpass_limited(value, frac, limit, ref_store, __f); \
  82         ret = (value) - __f; \
  83 MACRO_END
  84
  85 #define lowpass2(value, frac, ref_store, ref_out) MACRO_BEGIN \
  86         lowpass(value.x, frac, ref_store.x, ref_out.x); \
  87         lowpass(value.y, frac, ref_store.y, ref_out.y); \
  88 MACRO_END
  89
  90 #define highpass2(value, frac, ref_store, ref_out) MACRO_BEGIN \
  91         highpass(value.x, frac, ref_store.x, ref_out.x); \
  92         highpass(value.y, frac, ref_store.y, ref_out.y); \
  93 MACRO_END
  94
  95 #define highpass2_limited(value, frac, limit, ref_store, ref_out) MACRO_BEGIN \
  96         highpass_limited(value.x, frac, limit, ref_store.x, ref_out.x); \
  97         highpass_limited(value.y, frac, limit, ref_store.y, ref_out.y); \
  98 MACRO_END
  99
 100 #define lowpass3(value, frac, ref_store, ref_out) MACRO_BEGIN \
 101         lowpass(value.x, frac, ref_store.x, ref_out.x); \
 102         lowpass(value.y, frac, ref_store.y, ref_out.y); \
 103         lowpass(value.z, frac, ref_store.z, ref_out.z); \
 104 MACRO_END
 105
 106 #define highpass3(value, frac, ref_store, ref_out) MACRO_BEGIN \
 107         highpass(value.x, frac, ref_store.x, ref_out.x); \
 108         highpass(value.y, frac, ref_store.y, ref_out.y); \
 109         highpass(value.z, frac, ref_store.z, ref_out.z); \
 110 MACRO_END
 111
 112 void calc_followmodel_ofs(entity view)
 113 {
 114         if(cl_followmodel_time == time)
 115                 return; // cl_followmodel_ofs already calculated for this frame
 116
 117         float frac;
 118         vector gunorg = '0 0 0';
 119         static vector vel_average;
 120         static vector gunorg_adjustment_highpass;
 121         static vector gunorg_adjustment_lowpass;
 122
 123         vector vel;
 124         if (autocvar_cl_followmodel_velocity_absolute)
 125                 vel = view.velocity;
 126         else
 127         {
 128                 vector forward, right, up;
 129                 MAKE_VECTORS(view_angles, forward, right, up);
 130                 vel.x = view.velocity * forward;
 131                 vel.y = view.velocity * right * -1;
 132                 vel.z = view.velocity * up;
 133         }
 134
 135         vel.x = bound(vel_average.x - autocvar_cl_followmodel_limit, vel.x, vel_average.x + autocvar_cl_followmodel_limit);
 136         vel.y = bound(vel_average.y - autocvar_cl_followmodel_limit, vel.y, vel_average.y + autocvar_cl_followmodel_limit);
 137         vel.z = bound(vel_average.z - autocvar_cl_followmodel_limit, vel.z, vel_average.z + autocvar_cl_followmodel_limit);
 138
 139         frac = avg_factor(autocvar_cl_followmodel_velocity_lowpass);
 140         lowpass3(vel, frac, vel_average, gunorg);
 141
 142         gunorg *= -autocvar_cl_followmodel_speed * 0.042;
 143
 144         // perform highpass/lowpass on the adjustment vectors (turning velocity into acceleration!)
 145         // trick: we must do the lowpass LAST, so the lowpass vector IS the final vector!
 146         frac = avg_factor(autocvar_cl_followmodel_highpass);
 147         highpass3(gunorg, frac, gunorg_adjustment_highpass, gunorg);
 148         frac = avg_factor(autocvar_cl_followmodel_lowpass);
 149         lowpass3(gunorg, frac, gunorg_adjustment_lowpass, gunorg);
 150
 151         if (autocvar_cl_followmodel_velocity_absolute)
 152         {
 153                 vector fixed_gunorg;
 154                 vector forward, right, up;
 155                 MAKE_VECTORS(view_angles, forward, right, up);
 156                 fixed_gunorg.x = gunorg * forward;
 157                 fixed_gunorg.y = gunorg * right * -1;
 158                 fixed_gunorg.z = gunorg * up;
 159                 gunorg = fixed_gunorg;
 160         }
 161
 162         cl_followmodel_ofs = gunorg;
 163         cl_followmodel_time = time;
 164 }
 165
 166 vector leanmodel_ofs(entity view)
 167 {
 168         float frac;
 169         vector gunangles = '0 0 0';
 170         static vector gunangles_prev = '0 0 0';
 171         static vector gunangles_highpass = '0 0 0';
 172         static vector gunangles_adjustment_highpass;
 173         static vector gunangles_adjustment_lowpass;
 174
 175         if (view.csqcmodel_teleported)
 176                 gunangles_prev = view_angles;
 177
 178         // in the highpass, we _store_ the DIFFERENCE to the actual view angles...
 179         gunangles_highpass += gunangles_prev;
 180         PITCH(gunangles_highpass) += 360 * floor((PITCH(view_angles) - PITCH(gunangles_highpass)) / 360 + 0.5);
 181         YAW(gunangles_highpass) += 360 * floor((YAW(view_angles) - YAW(gunangles_highpass)) / 360 + 0.5);
 182         ROLL(gunangles_highpass) += 360 * floor((ROLL(view_angles) - ROLL(gunangles_highpass)) / 360 + 0.5);
 183         frac = avg_factor(autocvar_cl_leanmodel_highpass1);
 184         highpass2_limited(view_angles, frac, autocvar_cl_leanmodel_limit, gunangles_highpass, gunangles);
 185         gunangles_prev = view_angles;
 186         gunangles_highpass -= gunangles_prev;
 187
 188         PITCH(gunangles) *= -autocvar_cl_leanmodel_speed;
 189         YAW(gunangles) *= -autocvar_cl_leanmodel_speed;
 190
 191         // we assume here: PITCH = 0, YAW = 1, ROLL = 2
 192         frac = avg_factor(autocvar_cl_leanmodel_highpass);
 193         highpass2(gunangles, frac, gunangles_adjustment_highpass, gunangles);
 194         frac = avg_factor(autocvar_cl_leanmodel_lowpass);
 195         lowpass2(gunangles, frac, gunangles_adjustment_lowpass, gunangles);
 196
 197         gunangles.x = -gunangles.x; // pitch was inverted, now that actually matters
 198
 199         return gunangles;
 200 }
 201
 202 vector bobmodel_ofs(entity view)
 203 {
 204         bool clonground = !(view.anim_implicit_state & ANIMIMPLICITSTATE_INAIR);
 205         static bool oldonground;
 206         static float hitgroundtime;
 207         if (clonground)
 208         {
 209                 float f = time; // cl.movecmd[0].time
 210                 if (!oldonground)
 211                         hitgroundtime = f;
 212         }
 213         oldonground = clonground;
 214
 215         // calculate for swinging gun model
 216         // the gun bobs when running on the ground, but doesn't bob when you're in the air.
 217         vector gunorg = '0 0 0';
 218         static float bobmodel_scale = 0;
 219         static float time_ofs = 0; // makes the effect always restart in the same way
 220         if (clonground)
 221         {
 222                 if (time - hitgroundtime > 0.05)
 223                         bobmodel_scale = min(1, bobmodel_scale + frametime * 5);
 224         }
 225         else
 226                 bobmodel_scale = max(0, bobmodel_scale - frametime * 5);
 227
 228         float xyspeed = bound(0, vlen(vec2(view.velocity)), 400);
 229         if (bobmodel_scale && xyspeed)
 230         {
 231                 float bspeed = xyspeed * 0.01 * autocvar_cl_viewmodel_scale * bobmodel_scale;
 232                 float s = (time - time_ofs) * autocvar_cl_bobmodel_speed;
 233                 gunorg.y = bspeed * autocvar_cl_bobmodel_side * sin(s);
 234                 gunorg.z = bspeed * autocvar_cl_bobmodel_up * cos(s * 2);
 235         }
 236         else
 237                 time_ofs = time;
 238
 239         return gunorg;
 240 }
 241
 242 void viewmodel_animate(entity this)
 243 {
 244         if (autocvar_chase_active) return;
 245         if (STAT(HEALTH) <= 0) return;
 246
 247         entity view = CSQCModel_server2csqc(player_localentnum - 1);
 248
 249         if (autocvar_cl_followmodel)
 250         {
 251                 calc_followmodel_ofs(view);
 252                 this.origin += cl_followmodel_ofs;
 253         }
 254
 255         if (autocvar_cl_leanmodel)
 256                 this.angles += leanmodel_ofs(view);
 257
 258         // vertical view bobbing code
 259         // TODO: cl_bob
 260
 261         // horizontal view bobbing code
 262         // TODO: cl_bob2
 263
 264         // fall bobbing code
 265         // causes the view to swing down and back up when touching the ground
 266         // TODO: cl_bobfall
 267
 268         // gun model bobbing code
 269         if (autocvar_cl_bobmodel)
 270                 this.origin += bobmodel_ofs(view);
 271 }
 272
 273 .vector viewmodel_origin, viewmodel_angles;
 274 .float weapon_nextthink;
 275 .float weapon_eta_last;
 276 .float weapon_switchdelay;
 277
 278 .string name_last;
 279
 280 void viewmodel_draw(entity this)
 281 {
 282         if(!this.activeweapon || !autocvar_r_drawviewmodel)
 283                 return;
 284         int mask = (intermission || (STAT(HEALTH) <= 0) || autocvar_chase_active) ? 0 : MASK_NORMAL;
 285         float a = ((autocvar_cl_viewmodel_alpha) ? bound(-1, autocvar_cl_viewmodel_alpha, this.m_alpha) : this.m_alpha);
 286         int wepskin = this.m_skin;
 287         bool invehicle = player_localentnum > maxclients;
 288         if (invehicle) a = -1;
 289         Weapon wep = this.activeweapon;
 290         int c = entcs_GetClientColors(current_player);
 291         vector g = weaponentity_glowmod(wep, NULL, c, this);
 292         entity me = CSQCModel_server2csqc(player_localentnum - 1);
 293         int fx = ((me.csqcmodel_effects & EFMASK_CHEAP)
 294                 | EF_NODEPTHTEST)
 295                 &~ (EF_FULLBRIGHT); // can mask team color, so get rid of it
 296         for (entity e = this; e; e = e.weaponchild)
 297         {
 298                 e.drawmask = mask;
 299                 e.alpha = a;
 300                 e.skin = wepskin;
 301                 e.colormap = 256 + c;  // colormap == 0 is black, c == 0 is white
 302                 e.glowmod = g;
 303                 e.csqcmodel_effects = fx;
 304                 CSQCModel_Effects_Apply(e);
 305         }
 306         if(a >= 0)
 307         {
 308                 string name = wep.mdl;
 309                 string newname = wep.wr_viewmodel(wep, this);
 310                 if(newname)
 311                         name = newname;
 312                 bool swap = name != this.name_last;
 313                 // if (swap)
 314                 {
 315                         this.name_last = name;
 316                         CL_WeaponEntity_SetModel(this, name, swap);
 317                         this.viewmodel_origin = this.origin;
 318                         this.viewmodel_angles = this.angles;
 319                 }
 320                 anim_update(this);
 321                 if ((!this.animstate_override && !this.animstate_looping) || time > this.animstate_endtime)
 322                         anim_set(this, this.anim_idle, true, false, false);
 323         }
 324         float f = 0; // 0..1; 0: fully active
 325         float rate = STAT(WEAPONRATEFACTOR);
 326         float eta = rate ? ((this.weapon_nextthink - time) / rate) : 0;
 327         if (eta <= 0) f = this.weapon_eta_last;
 328         else switch (this.state)
 329         {
 330                 case WS_RAISE:
 331                 {
 332                         f = eta / max(eta, this.weapon_switchdelay);
 333                         break;
 334                 }
 335                 case WS_DROP:
 336                 {
 337                         f = 1 - eta / max(eta, this.weapon_switchdelay);
 338                         break;
 339                 }
 340                 case WS_CLEAR:
 341                 {
 342                         f = 1;
 343                         break;
 344                 }
 345         }
 346         this.weapon_eta_last = f;
 347         this.origin = this.viewmodel_origin;
 348         this.angles = this.viewmodel_angles;
 349         this.angles_x = (-90 * f * f);
 350         viewmodel_animate(this);
 351         MUTATOR_CALLHOOK(DrawViewModel, this);
 352         setorigin(this, this.origin);
 353 }
 354
 355 STATIC_INIT(viewmodel) {
 356     for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 357         viewmodels[slot] = new(viewmodel);
 358 }
 359
 360 vector project_3d_to_2d(vector vec)
 361 {
 362         vec = cs_project(vec);
 363         if(cs_project_is_b0rked > 0)
 364         {
 365                 vec.x *= vid_conwidth / vid_width;
 366                 vec.y *= vid_conheight / vid_height;
 367         }
 368         return vec;
 369 }
 370
 371 bool projected_on_screen(vector screen_pos)
 372 {
 373         return screen_pos.z >= 0
 374                 && screen_pos.x >= 0
 375                 && screen_pos.y >= 0
 376                 && screen_pos.x < vid_conwidth
 377                 && screen_pos.y < vid_conheight;
 378 }
 379
 380 void update_mousepos()
 381 {
 382         mousepos += getmousepos() * autocvar_menu_mouse_speed;
 383         mousepos.x = bound(0, mousepos.x, vid_conwidth);
 384         mousepos.y = bound(0, mousepos.y, vid_conheight);
 385 }
 386
 387 float showfps_prevfps_time;
 388 int showfps_framecounter;
 389
 390 void fpscounter_update()
 391 {
 392         if(!STAT(SHOWFPS))
 393                 return;
 394
 395         float currentTime = gettime(GETTIME_FRAMESTART);
 396
 397         showfps_framecounter += 1;
 398         if(currentTime - showfps_prevfps_time > STAT(SHOWFPS))
 399         {
 400                 float fps = showfps_framecounter / (currentTime - showfps_prevfps_time);
 401                 showfps_framecounter = 0;
 402                 showfps_prevfps_time = currentTime;
 403
 404                 int channel = MSG_C2S;
 405                 WriteHeader(channel, fpsreport);
 406                 WriteShort(channel, bound(0, rint(fps), 65535)); // prevent insane fps values
 407         }
 408 }
 409
 410 STATIC_INIT(fpscounter_init)
 411 {
 412         float currentTime = gettime(GETTIME_FRAMESTART);
 413         showfps_prevfps_time = currentTime; // we must initialize it to avoid an instant low frame sending
 414 }
 415
 416 float avgspeed;
 417 vector GetCurrentFov(float fov)
 418 {
 419         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir;
 420         float velocityzoom, curspeed;
 421         vector v;
 422
 423         zoomsensitivity = autocvar_cl_zoomsensitivity;
 424         zoomfactor = autocvar_cl_zoomfactor;
 425         if(zoomfactor < 1 || zoomfactor > 30)
 426                 zoomfactor = 2.5;
 427         zoomspeed = autocvar_cl_zoomspeed;
 428         if (zoomspeed >= 0 && (zoomspeed < 0.5 || zoomspeed > 16))
 429                 zoomspeed = 3.5;
 430
 431         zoomdir = button_zoom;
 432
 433         if(hud == HUD_NORMAL && !spectatee_status)
 434         {
 435                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 436                 {
 437                         entity wepent = viewmodels[slot];
 438                         if(wepent.switchweapon != wepent.activeweapon)
 439                                 continue;
 440                         Weapon wep = wepent.activeweapon;
 441                         if(wep != WEP_Null && wep.wr_zoomdir)
 442                         {
 443                                 bool do_zoom = wep.wr_zoomdir(wep); // TODO: merge this with wr_zoom?
 444                                 zoomdir += do_zoom;
 445                         }
 446                 }
 447         }
 448         if(spectatee_status > 0 || isdemo())
 449         {
 450                 if(spectatorbutton_zoom)
 451                 {
 452                         if(zoomdir)
 453                                 zoomdir = 0;
 454                         else
 455                                 zoomdir = 1;
 456                 }
 457                 // fteqcc failed twice here already, don't optimize this
 458         }
 459
 460         if(zoomdir) { zoomin_effect = 0; }
 461
 462         if (spectatee_status > 0 && STAT(CAMERA_SPECTATOR) == 2)
 463         {
 464                 current_viewzoom = 1;
 465         }
 466         else if (camera_active)
 467         {
 468                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 469         }
 470         else if(autocvar_cl_spawnzoom && zoomin_effect)
 471         {
 472                 float spawnzoomfactor = bound(1, autocvar_cl_spawnzoom_factor, 30);
 473
 474                 current_viewzoom += (autocvar_cl_spawnzoom_speed * (spawnzoomfactor - current_viewzoom) * drawframetime);
 475                 current_viewzoom = bound(1 / spawnzoomfactor, current_viewzoom, 1);
 476                 if(current_viewzoom == 1) { zoomin_effect = 0; }
 477         }
 478         else
 479         {
 480                 if(zoomspeed < 0) // instant zoom
 481                 {
 482                         if(zoomdir)
 483                                 current_viewzoom = 1 / zoomfactor;
 484                         else
 485                                 current_viewzoom = 1;
 486                 }
 487                 else
 488                 {
 489                         if(zoomdir)
 490                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 491                         else
 492                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 493                 }
 494         }
 495
 496         if(almost_equals(current_viewzoom, 1))
 497                 current_zoomfraction = 0;
 498         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 499                 current_zoomfraction = 1;
 500         else
 501                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 502
 503         if(zoomsensitivity < 1)
 504                 setsensitivityscale(current_viewzoom ** (1 - zoomsensitivity));
 505         else
 506                 setsensitivityscale(1);
 507
 508         if(autocvar_cl_velocityzoom_enabled && autocvar_cl_velocityzoom_type && !autocvar_cl_lockview) // _type = 0 disables velocity zoom too
 509         {
 510                 if (intermission || (spectatee_status > 0 && STAT(CAMERA_SPECTATOR) == 2))
 511                         curspeed = 0;
 512                 else
 513                 {
 514                         vector forward, right, up;
 515                         MAKE_VECTORS(view_angles, forward, right, up);
 516                         v = pmove_vel;
 517                         if(csqcplayer)
 518                                 v = csqcplayer.velocity;
 519
 520                         switch(autocvar_cl_velocityzoom_type)
 521                         {
 522                                 case 3: curspeed = max(0, forward * v); break;
 523                                 case 2: curspeed = (forward * v); break;
 524                                 case 1: default: curspeed = vlen(v); break;
 525                         }
 526                 }
 527
 528                 velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoom_time), 1); // speed at which the zoom adapts to player velocity
 529                 avgspeed = avgspeed * (1 - velocityzoom) + (curspeed / autocvar_cl_velocityzoom_speed) * velocityzoom;
 530                 velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom_factor / 1) * 1);
 531
 532                 //print(ftos(avgspeed), " avgspeed, ", ftos(curspeed), " curspeed, ", ftos(velocityzoom), " return\n"); // for debugging
 533         }
 534         else
 535                 velocityzoom = 1;
 536
 537         float frustumx, frustumy, fovx, fovy;
 538         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 539         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 540         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 541         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 542
 543         return '1 0 0' * fovx + '0 1 0' * fovy;
 544 }
 545
 546 vector GetViewLocationFOV(float fov)
 547 {
 548         float frustumy = tan(fov * M_PI / 360.0) * 0.75;
 549         float frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 550         float fovx = atan2(frustumx, 1) / M_PI * 360.0;
 551         float fovy = atan2(frustumy, 1) / M_PI * 360.0;
 552         return '1 0 0' * fovx + '0 1 0' * fovy;
 553 }
 554
 555 vector GetOrthoviewFOV(vector ov_worldmin, vector ov_worldmax, vector ov_mid, vector ov_org)
 556 {
 557         float fovx, fovy;
 558         float width = (ov_worldmax.x - ov_worldmin.x);
 559         float height = (ov_worldmax.y - ov_worldmin.y);
 560         float distance_to_middle_of_world = vlen(ov_mid - ov_org);
 561         fovx = atan2(width/2, distance_to_middle_of_world) / M_PI * 360.0;
 562         fovy = atan2(height/2, distance_to_middle_of_world) / M_PI * 360.0;
 563         return '1 0 0' * fovx + '0 1 0' * fovy;
 564 }
 565
 566 // this function must match W_SetupShot!
 567
 568 bool minigame_wasactive;
 569
 570 float camera_mode;
 571 const float CAMERA_FREE = 1;
 572 const float CAMERA_CHASE = 2;
 573 string NextFrameCommand;
 574
 575 vector freeze_org, freeze_ang;
 576 entity nightvision_noise, nightvision_noise2;
 577
 578 float myhealth, myhealth_prev;
 579 float myhealth_flash;
 580
 581 float old_blurradius, old_bluralpha;
 582 float old_sharpen_intensity;
 583
 584 vector myhealth_gentlergb;
 585
 586 float contentavgalpha, liquidalpha_prev;
 587 vector liquidcolor_prev;
 588
 589 float eventchase_current_distance;
 590 float eventchase_running;
 591 int WantEventchase(entity this, bool want_vehiclechase)
 592 {
 593         if(autocvar_cl_orthoview)
 594                 return 0;
 595         if(STAT(GAME_STOPPED) || intermission)
 596                 return 1;
 597         if(this.viewloc)
 598                 return 1;
 599         if(spectatee_status >= 0)
 600         {
 601                 if(want_vehiclechase)
 602                         return 1;
 603                 if(MUTATOR_CALLHOOK(WantEventchase, this))
 604                         return 1;
 605                 if(autocvar_cl_eventchase_frozen && STAT(FROZEN))
 606                         return 1;
 607                 if(autocvar_cl_eventchase_death && (STAT(HEALTH) <= 0))
 608                 {
 609                         if(autocvar_cl_eventchase_death == 2)
 610                         {
 611                                 // don't stop eventchase once it's started (even if velocity changes afterwards)
 612                                 if(this.velocity == '0 0 0' || eventchase_running)
 613                                         return 1;
 614                         }
 615                         else return 1;
 616                 }
 617                 if (spectatee_status > 0 && autocvar_cl_eventchase_spectated_change)
 618                 {
 619                         if (time <= spectatee_status_changed_time + min(3, autocvar_cl_eventchase_spectated_change_time))
 620                                 return 1;
 621                         else if (eventchase_running)
 622                                 return -1; // disable chase_active while eventchase is still enabled so to avoid a glicth
 623                 }
 624         }
 625         return 0;
 626 }
 627
 628 void View_EventChase(entity this)
 629 {
 630         // event chase camera
 631         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
 632         {
 633                 if(STAT(CAMERA_SPECTATOR))
 634                 {
 635                         if(spectatee_status > 0)
 636                         {
 637                                 if(!autocvar_chase_active)
 638                                 {
 639                                         cvar_set("chase_active", "-2");
 640                                         return;
 641                                 }
 642                         }
 643                         else if(autocvar_chase_active == -2)
 644                                 cvar_set("chase_active", "0");
 645
 646                         if(autocvar_chase_active == -2)
 647                                 return;
 648                 }
 649                 else if(autocvar_chase_active == -2)
 650                         cvar_set("chase_active", "0");
 651
 652                 bool vehicle_chase = (hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0));
 653
 654                 float vehicle_viewdist = 0;
 655                 vector vehicle_viewofs = '0 0 0';
 656
 657                 if(vehicle_chase)
 658                 {
 659                         if(hud != HUD_BUMBLEBEE_GUN)
 660                         {
 661                                 Vehicle info = REGISTRY_GET(Vehicles, hud);
 662                                 vehicle_viewdist = info.height;
 663                                 vehicle_viewofs = info.view_ofs;
 664                                 if(vehicle_viewdist < 0) // when set below 0, this vehicle doesn't use third person view (gunner slots)
 665                                         vehicle_chase = false;
 666                         }
 667                         else
 668                                 vehicle_chase = false;
 669                 }
 670
 671                 int eventchase = WantEventchase(this, vehicle_chase);
 672                 if (eventchase)
 673                 {
 674                         vector current_view_origin_override = '0 0 0';
 675                         vector view_offset_override = '0 0 0';
 676                         float chase_distance_override = 0;
 677                         bool custom_eventchase = MUTATOR_CALLHOOK(CustomizeEventchase, this);
 678                         if(custom_eventchase)
 679                         {
 680                                 current_view_origin_override = M_ARGV(0, vector);
 681                                 view_offset_override = M_ARGV(1, vector);
 682                                 chase_distance_override = M_ARGV(0, float);
 683                         }
 684                         eventchase_running = true;
 685
 686                         // make special vector since we can't use view_origin (It is one frame old as of this code, it gets set later with the results this code makes.)
 687                         vector current_view_origin = (csqcplayer ? csqcplayer.origin : pmove_org);
 688                         if (custom_eventchase)
 689                                 current_view_origin = current_view_origin_override;
 690
 691                         // detect maximum viewoffset and use it
 692                         vector view_offset = autocvar_cl_eventchase_viewoffset;
 693                         if(vehicle_chase)
 694                         {
 695                                 if(vehicle_viewofs)
 696                                         view_offset = vehicle_viewofs;
 697                                 else
 698                                         view_offset = autocvar_cl_eventchase_vehicle_viewoffset;
 699                         }
 700                         if (custom_eventchase)
 701                                 view_offset = view_offset_override;
 702
 703                         if(view_offset)
 704                         {
 705                                 WarpZone_TraceLine(current_view_origin, current_view_origin + view_offset + ('0 0 1' * autocvar_cl_eventchase_maxs.z), MOVE_WORLDONLY, this);
 706                                 if(trace_fraction == 1) { current_view_origin += view_offset; }
 707                                 else { current_view_origin.z += max(0, (trace_endpos.z - current_view_origin.z) - autocvar_cl_eventchase_maxs.z); }
 708                         }
 709
 710                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
 711                         // Ideally, there should be another way to enable third person cameras, such as through setproperty()
 712                         // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
 713                         if(!autocvar_chase_active) { cvar_set("chase_active", "-1"); }
 714
 715                         // make the camera smooth back
 716                         float chase_distance = autocvar_cl_eventchase_distance;
 717                         if(vehicle_chase)
 718                         {
 719                                 if(vehicle_viewofs)
 720                                         chase_distance = vehicle_viewdist;
 721                                 else
 722                                         chase_distance = autocvar_cl_eventchase_vehicle_distance;
 723                         }
 724                         if (custom_eventchase)
 725                                 chase_distance = chase_distance_override;
 726
 727                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < chase_distance)
 728                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (chase_distance - eventchase_current_distance) * frametime; // slow down the further we get
 729                         else if(eventchase_current_distance != chase_distance)
 730                                 eventchase_current_distance = chase_distance;
 731
 732                         vector forward, right, up;
 733                         MAKE_VECTORS(view_angles, forward, right, up);
 734
 735                         vector eventchase_target_origin = (current_view_origin - (forward * eventchase_current_distance));
 736                         WarpZone_TraceBox(current_view_origin, autocvar_cl_eventchase_mins, autocvar_cl_eventchase_maxs, eventchase_target_origin, MOVE_WORLDONLY, this);
 737
 738                         // If the boxtrace fails, revert back to line tracing.
 739                         if(!this.viewloc)
 740                         if(trace_startsolid)
 741                         {
 742                                 eventchase_target_origin = (current_view_origin - (forward * eventchase_current_distance));
 743                                 WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, this);
 744                                 setproperty(VF_ORIGIN, (trace_endpos - (forward * autocvar_cl_eventchase_mins.z)));
 745                         }
 746                         else { setproperty(VF_ORIGIN, trace_endpos); }
 747
 748                         if(!this.viewloc)
 749                                 setproperty(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
 750                 }
 751
 752                 if (eventchase <= 0 && autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
 753                 {
 754                         eventchase_running = false;
 755                         cvar_set("chase_active", "0");
 756                         eventchase_current_distance = 0; // start from 0 next time
 757                 }
 758         }
 759         // workaround for camera stuck between player's legs when using chase_active 1
 760         // because the engine stops updating the chase_active camera when the game ends
 761         else if(intermission)
 762         {
 763                 cvar_settemp("chase_active", "-1");
 764                 eventchase_current_distance = 0;
 765         }
 766 }
 767
 768 vector damage_blurpostprocess, content_blurpostprocess;
 769
 770 void UpdateDamage()
 771 {
 772         // accumulate damage with each stat update
 773         static float damage_total_prev = 0;
 774         float damage_total = STAT(DAMAGE_DEALT_TOTAL);
 775         float unaccounted_damage_new = COMPARE_INCREASING(damage_total, damage_total_prev);
 776         damage_total_prev = damage_total;
 777
 778         static float damage_dealt_time_prev = 0;
 779         float damage_dealt_time = STAT(HIT_TIME);
 780         if (damage_dealt_time != damage_dealt_time_prev)
 781         {
 782                 unaccounted_damage += unaccounted_damage_new;
 783                 //LOG_TRACE("dmg total: ", ftos(unaccounted_damage), " (+", ftos(unaccounted_damage_new), ")");
 784         }
 785         damage_dealt_time_prev = damage_dealt_time;
 786
 787         // prevent hitsound when switching spectatee
 788         static float spectatee_status_prev = 0;
 789         if (spectatee_status != spectatee_status_prev)
 790                 unaccounted_damage = 0;
 791         spectatee_status_prev = spectatee_status;
 792 }
 793
 794 void HitSound()
 795 {
 796         // varying sound pitch
 797
 798         bool have_arc = false;
 799         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 800         {
 801                 entity wepent = viewmodels[slot];
 802
 803                 if(wepent.activeweapon == WEP_ARC)
 804                         have_arc = true;
 805         }
 806
 807         static float hitsound_time_prev = 0;
 808         // HACK: the only way to get the arc to sound consistent with pitch shift is to ignore cl_hitsound_antispam_time
 809         bool arc_hack = have_arc && autocvar_cl_hitsound >= 2;
 810         if (arc_hack || COMPARE_INCREASING(time, hitsound_time_prev) > autocvar_cl_hitsound_antispam_time)
 811         {
 812                 if (autocvar_cl_hitsound && unaccounted_damage)
 813                 {
 814                         float pitch_shift = 1;
 815                         if (autocvar_cl_hitsound == 2 || autocvar_cl_hitsound == 3)
 816                         {
 817                                 // customizable gradient function that crosses (0,a), (c,1) and asymptotically approaches b
 818                                 float a = autocvar_cl_hitsound_max_pitch;
 819                                 float b = autocvar_cl_hitsound_min_pitch;
 820                                 float c = autocvar_cl_hitsound_nom_damage;
 821                                 float d = unaccounted_damage;
 822                                 pitch_shift = (b*d*(a-1) + a*c*(1-b)) / (d*(a-1) + c*(1-b));
 823
 824                                 // if pitch shift is reversed, mirror in (max-min)/2 + min
 825                                 if (autocvar_cl_hitsound == 3)
 826                                 {
 827                                         float mirror_value = (a-b)/2 + b;
 828                                         pitch_shift = mirror_value + (mirror_value - pitch_shift);
 829                                 }
 830                         }
 831
 832                         //LOG_TRACE("dmg total (dmg): ", ftos(unaccounted_damage), " , pitch shift: ", ftos(pitch_shift));
 833
 834                         // todo: avoid very long and very short sounds from wave stretching using different sound files? seems unnecessary
 835                         // todo: normalize sound pressure levels? seems unnecessary
 836
 837                         sound7(NULL, CH_INFO, SND(HIT), VOL_BASE, ATTN_NONE, pitch_shift * 100, 0);
 838                 }
 839                 unaccounted_damage = 0;
 840                 hitsound_time_prev = time;
 841         }
 842
 843         static float typehit_time_prev = 0;
 844         float typehit_time = STAT(TYPEHIT_TIME);
 845         if (COMPARE_INCREASING(typehit_time, typehit_time_prev) > autocvar_cl_hitsound_antispam_time)
 846         {
 847                 sound(NULL, CH_INFO, SND_TYPEHIT, VOL_BASE, ATTN_NONE);
 848                 typehit_time_prev = typehit_time;
 849         }
 850
 851         static float kill_time_prev = 0;
 852         float kill_time = STAT(KILL_TIME);
 853         if (COMPARE_INCREASING(kill_time, kill_time_prev) > autocvar_cl_hitsound_antispam_time)
 854         {
 855                 sound(NULL, CH_INFO, SND_KILL, VOL_BASE, ATTN_NONE);
 856                 kill_time_prev = kill_time;
 857         }
 858 }
 859
 860 const int MAX_SPECIALCOMMAND = 15;
 861 vector specialcommand_slots[MAX_SPECIALCOMMAND];
 862 vector specialcommand_colors[MAX_SPECIALCOMMAND];
 863 const float SPECIALCOMMAND_SPEED = 150;
 864 const float SPECIALCOMMAND_TURNSPEED = 2;
 865 const float SPECIALCOMMAND_SIZE = 0.025;
 866 const float SPECIALCOMMAND_CHANCE = 0.35;
 867 float sc_spawntime, sc_changetime;
 868 vector sc_color = '1 1 1';
 869 void SpecialCommand()
 870 {
 871         if(!STAT(MOVEVARS_SPECIALCOMMAND))
 872                 return;
 873
 874         if(time >= sc_changetime)
 875         {
 876                 sc_changetime = time + 1;
 877                 sc_color = randomvec() * 1.5;
 878                 sc_color.x = bound(0.2, sc_color.x, 0.75);
 879                 sc_color.y = bound(0.2, sc_color.y, 0.75);
 880                 sc_color.z = bound(0.2, sc_color.z, 0.75);
 881         }
 882         drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), sc_color, autocvar_hud_colorflash_alpha * bound(0.1, sc_changetime - time, 0.3), DRAWFLAG_ADDITIVE);
 883
 884         if(!precache_pic("gfx/smile"))
 885                 return; // damn party poopers
 886
 887         for(int j = MAX_SPECIALCOMMAND - 1; j >= 0; --j)
 888         {
 889                 vector slot = specialcommand_slots[j];
 890                 if(slot.y)
 891                         slot.y += SPECIALCOMMAND_SPEED * frametime;
 892                 //if(slot.z)
 893                         //slot.z = sin(SPECIALCOMMAND_TURNSPEED * M_PI * time);
 894                 if(slot.y >= vid_conheight)
 895                         slot = '0 0 0';
 896
 897                 if(slot == '0 0 0')
 898                 {
 899                         if(random() <= SPECIALCOMMAND_CHANCE && time > sc_spawntime) // low chance to spawn!
 900                         {
 901                                 slot.x = bound(0, (random() * vid_conwidth + 1), vid_conwidth);
 902                                 slot.y = 1; // start it off 0 so we can use it
 903                                 slot.z = floor(random() * REGISTRY_MAX(Weapons));
 904                                 sc_spawntime = time + bound(0.4, random(), 0.75); // prevent spawning another one for this amount of time!
 905                                 vector newcolor = randomvec() * 2;
 906                                 newcolor.x = bound(0.4, newcolor.x, 1);
 907                                 newcolor.y = bound(0.4, newcolor.y, 1);
 908                                 newcolor.z = bound(0.4, newcolor.z, 1);
 909                                 specialcommand_colors[j] = newcolor;
 910                         }
 911                 }
 912                 else
 913                 {
 914                         vector splash_size = '0 0 0';
 915                         splash_size.x = max(vid_conwidth, vid_conheight) * SPECIALCOMMAND_SIZE;
 916                         splash_size.y = max(vid_conwidth, vid_conheight) * SPECIALCOMMAND_SIZE;
 917                         entity wep = REGISTRY_GET(Weapons, slot.z);
 918                         if(wep == WEP_Null)
 919                                 drawpic(vec2(slot), "gfx/smile", vec2(splash_size), specialcommand_colors[j], 0.95, DRAWFLAG_NORMAL);
 920                         else
 921                                 drawpic_skin(vec2(slot), wep.model2, vec2(splash_size), specialcommand_colors[j], 0.95, DRAWFLAG_NORMAL);
 922                         //drawrotpic(vec2(slot), slot.z, "gfx/smile", vec2(splash_size), vec2(splash_size) / 2, specialcommand_colors[j], 0.95, DRAWFLAG_NORMAL);
 923                 }
 924
 925                 specialcommand_slots[j] = slot;
 926         }
 927 }
 928
 929 void HUD_Draw(entity this)
 930 {
 931         // if we don't know gametype and scores yet avoid drawing the scoreboard
 932         // also in the very first frames, player state may be inconsistent so avoid drawing the hud at all
 933         // e.g. since initial player's health is 0 hud would display the hud_damage effect,
 934         // cl_deathscoreboard would show the scoreboard and so on
 935         if(!gametype)
 936                 return;
 937
 938         Hud_Dynamic_Frame();
 939
 940         if(!intermission)
 941         if (MUTATOR_CALLHOOK(HUD_Draw_overlay))
 942         {
 943                 drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), M_ARGV(0, vector), autocvar_hud_colorflash_alpha * M_ARGV(1, float), DRAWFLAG_ADDITIVE);
 944         }
 945         else if(STAT(FROZEN))
 946         {
 947                 vector col = '0.25 0.90 1';
 948                 float col_fade = max(0, STAT(REVIVE_PROGRESS) * 2 - 1);
 949                 float alpha_fade = 0.3 + 0.7 * (1 - max(0, STAT(REVIVE_PROGRESS) * 4 - 3));
 950                 if(col_fade)
 951                         col += vec3(col_fade, -col_fade, -col_fade);
 952                 drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), col, autocvar_hud_colorflash_alpha * alpha_fade, DRAWFLAG_ADDITIVE);
 953         }
 954
 955         HUD_Scale_Enable();
 956         if(!intermission)
 957         if(STAT(NADE_TIMER) && autocvar_cl_nade_timer) // give nade top priority, as it's a matter of life and death
 958         {
 959                 vector col = '0.25 0.90 1' + vec3(STAT(NADE_TIMER), -STAT(NADE_TIMER), -STAT(NADE_TIMER));
 960                 DrawCircleClippedPic(vec2(0.5 * vid_conwidth, 0.6 * vid_conheight), 0.1 * vid_conheight, "gfx/crosshair_ring", STAT(NADE_TIMER), col, autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
 961                 drawstring_aspect(eY * 0.64 * vid_conheight, ((autocvar_cl_nade_timer == 2) ? _("Nade timer") : ""), vec2(vid_conwidth, 0.025 * vid_conheight), '1 1 1', 1, DRAWFLAG_NORMAL);
 962         }
 963         else if(STAT(CAPTURE_PROGRESS))
 964         {
 965                 DrawCircleClippedPic(vec2(0.5 * vid_conwidth, 0.6 * vid_conheight), 0.1 * vid_conheight, "gfx/crosshair_ring", STAT(CAPTURE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
 966                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Capture progress"), vec2(vid_conwidth, 0.025 * vid_conheight), '1 1 1', 1, DRAWFLAG_NORMAL);
 967         }
 968         else if(STAT(REVIVE_PROGRESS))
 969         {
 970                 DrawCircleClippedPic(vec2(0.5 * vid_conwidth, 0.6 * vid_conheight), 0.1 * vid_conheight, "gfx/crosshair_ring", STAT(REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
 971                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Revival progress"), vec2(vid_conwidth, 0.025 * vid_conheight), '1 1 1', 1, DRAWFLAG_NORMAL);
 972         }
 973         HUD_Scale_Disable();
 974
 975         if(autocvar_r_letterbox == 0)
 976                 if(autocvar_viewsize < 120)
 977                 {
 978                         if(!MUTATOR_CALLHOOK(DrawScoreboardAccuracy))
 979                                 Accuracy_LoadLevels();
 980
 981                         HUD_Main();
 982                         HUD_Scale_Disable();
 983                 }
 984
 985         // crosshair goes VERY LAST
 986         SpecialCommand();
 987         UpdateDamage();
 988         HUD_Crosshair(this);
 989         HitSound();
 990 }
 991
 992 void ViewLocation_Mouse()
 993 {
 994         if(spectatee_status)
 995                 return; // don't draw it as spectator!
 996
 997         viewloc_mousepos += getmousepos() * autocvar_menu_mouse_speed;
 998         viewloc_mousepos.x = bound(0, viewloc_mousepos.x, vid_conwidth);
 999         viewloc_mousepos.y = bound(0, viewloc_mousepos.y, vid_conheight);
1000
1001         //float cursor_alpha = 1 - autocvar__menu_alpha;
1002         //cursor_type = CURSOR_NORMAL;
1003         //draw_cursor(viewloc_mousepos, '0.5 0.5 0', "/cursor_move", '1 1 1', cursor_alpha);
1004 }
1005
1006 void HUD_Cursor_Show()
1007 {
1008         float cursor_alpha = 1 - autocvar__menu_alpha;
1009         if(cursor_type == CURSOR_NORMAL)
1010                 draw_cursor_normal(mousepos, '1 1 1', cursor_alpha);
1011         else if(cursor_type == CURSOR_MOVE)
1012                 draw_cursor(mousepos, '0.5 0.5 0', "/cursor_move", '1 1 1', cursor_alpha);
1013         else if(cursor_type == CURSOR_RESIZE)
1014                 draw_cursor(mousepos, '0.5 0.5 0', "/cursor_resize", '1 1 1', cursor_alpha);
1015         else if(cursor_type == CURSOR_RESIZE2)
1016                 draw_cursor(mousepos, '0.5 0.5 0', "/cursor_resize2", '1 1 1', cursor_alpha);
1017 }
1018
1019 void HUD_Mouse(entity player)
1020 {
1021         if(autocvar__menu_alpha == 1)
1022                 return;
1023
1024         if(!cursor_active)
1025         {
1026                 if(player.viewloc && (player.viewloc.spawnflags & VIEWLOC_FREEAIM))
1027                         ViewLocation_Mouse(); // NOTE: doesn't use cursormode
1028                 return;
1029         }
1030
1031         if (cursor_active == -1) // starting to display the cursor
1032         {
1033                 // since HUD_Mouse is called by CSQC_UpdateView before CSQC_InputEvent,
1034                 // in the first frame mousepos is the mouse position of the last time
1035                 // the cursor was displayed, thus we ignore it to avoid a glictch
1036                 cursor_active = 1;
1037                 return;
1038         }
1039
1040         if(!autocvar_hud_cursormode)
1041                 update_mousepos();
1042
1043         cursor_type = CURSOR_NORMAL;
1044         if(autocvar__hud_configure)
1045                 HUD_Panel_Mouse();
1046         else
1047         {
1048                 if (HUD_MinigameMenu_IsOpened())
1049                         HUD_Minigame_Mouse();
1050                 if (QuickMenu_IsOpened())
1051                         QuickMenu_Mouse();
1052                 if (HUD_Radar_Clickable())
1053                         HUD_Radar_Mouse();
1054         }
1055
1056         prevMouseClicked = mouseClicked;
1057
1058         HUD_Cursor_Show();
1059 }
1060
1061 void View_NightVision()
1062 {
1063         if(!(autocvar_r_fakelight >= 2 || autocvar_r_fullbright) || (serverflags & SERVERFLAG_ALLOW_FULLBRIGHT))
1064                 return;
1065
1066         // apply night vision effect
1067         vector tc_00, tc_01, tc_10, tc_11;
1068         vector rgb = '0 0 0';
1069         float a;
1070
1071         if(!nightvision_noise)
1072         {
1073                 nightvision_noise = new(nightvision_noise);
1074         }
1075         if(!nightvision_noise2)
1076         {
1077                 nightvision_noise2 = new(nightvision_noise2);
1078         }
1079
1080         // color tint in yellow
1081         drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
1082
1083         // draw BG
1084         a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
1085         rgb = '1 1 1';
1086         tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
1087         tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
1088         tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
1089         //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
1090         tc_11 = tc_01 + tc_10 - tc_00;
1091         R_BeginPolygon("gfx/nightvision-bg", DRAWFLAG_ADDITIVE, true);
1092         R_PolygonVertex('0 0 0', tc_00, rgb, a);
1093         R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
1094         R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
1095         R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
1096         R_EndPolygon();
1097
1098         // draw FG
1099         a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
1100         rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
1101         tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
1102         tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
1103         tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
1104         tc_11 = tc_01 + tc_10 - tc_00;
1105         R_BeginPolygon("gfx/nightvision-fg", DRAWFLAG_ADDITIVE, true);
1106         R_PolygonVertex('0 0 0', tc_00, rgb, a);
1107         R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
1108         R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
1109         R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
1110         R_EndPolygon();
1111 }
1112
1113 // visual overlay while in liquids
1114 // provides some effects to the postprocessing function
1115 void HUD_Contents()
1116 {
1117         if(!autocvar_hud_contents || MUTATOR_CALLHOOK(HUD_Contents))
1118                 return;
1119
1120         // improved polyblend
1121         float contentalpha_temp, incontent, liquidalpha, contentfadetime;
1122         vector liquidcolor;
1123
1124         switch(pointcontents(view_origin))
1125         {
1126                 case CONTENT_WATER:
1127                         liquidalpha = autocvar_hud_contents_water_alpha;
1128                         liquidcolor = stov(autocvar_hud_contents_water_color);
1129                         incontent = 1;
1130                         break;
1131
1132                 case CONTENT_LAVA:
1133                         liquidalpha = autocvar_hud_contents_lava_alpha;
1134                         liquidcolor = stov(autocvar_hud_contents_lava_color);
1135                         incontent = 1;
1136                         break;
1137
1138                 case CONTENT_SLIME:
1139                         liquidalpha = autocvar_hud_contents_slime_alpha;
1140                         liquidcolor = stov(autocvar_hud_contents_slime_color);
1141                         incontent = 1;
1142                         break;
1143
1144                 default:
1145                         liquidalpha = 0;
1146                         liquidcolor = '0 0 0';
1147                         incontent = 0;
1148                         break;
1149         }
1150
1151         if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
1152         { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
1153                 contentfadetime = autocvar_hud_contents_fadeintime;
1154                 liquidalpha_prev = liquidalpha;
1155                 liquidcolor_prev = liquidcolor;
1156         }
1157         else
1158                 contentfadetime = autocvar_hud_contents_fadeouttime;
1159
1160         contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
1161         contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
1162
1163         if(contentavgalpha)
1164                 drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
1165
1166         if(autocvar_hud_postprocessing)
1167         {
1168                 if(autocvar_hud_contents_blur && contentavgalpha)
1169                 {
1170                         content_blurpostprocess.x = 1;
1171                         content_blurpostprocess.y = contentavgalpha * autocvar_hud_contents_blur;
1172                         content_blurpostprocess.z = contentavgalpha * autocvar_hud_contents_blur_alpha;
1173                 }
1174                 else
1175                 {
1176                         content_blurpostprocess.x = 0;
1177                         content_blurpostprocess.y = 0;
1178                         content_blurpostprocess.z = 0;
1179                 }
1180         }
1181 }
1182
1183 // visual pain effects on the screen
1184 // provides some effects to the postprocessing function
1185 void HUD_Damage()
1186 {
1187         if(!autocvar_hud_damage || STAT(FROZEN))
1188                 return;
1189
1190         vector splash_pos = '0 0 0', splash_size = '0 0 0';
1191         splash_size.x = max(vid_conwidth, vid_conheight);
1192         splash_size.y = max(vid_conwidth, vid_conheight);
1193         splash_pos.x = (vid_conwidth - splash_size.x) / 2;
1194         splash_pos.y = (vid_conheight - splash_size.y) / 2;
1195
1196         float myhealth_flash_temp;
1197         myhealth = STAT(HEALTH);
1198
1199         // fade out
1200         myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
1201         // add new damage
1202         myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
1203
1204         float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
1205         pain_threshold = autocvar_hud_damage_pain_threshold;
1206         pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
1207         pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
1208
1209         if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
1210         {
1211                 pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
1212         }
1213
1214         myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
1215
1216         if(myhealth_prev < 1)
1217         {
1218                 if(myhealth >= 1)
1219                 {
1220                         myhealth_flash = 0; // just spawned, clear the flash immediately
1221                         myhealth_flash_temp = 0;
1222                 }
1223                 else
1224                 {
1225                         myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
1226                 }
1227         }
1228
1229         if(spectatee_status == -1 || intermission)
1230         {
1231                 myhealth_flash = 0; // observing, or match ended
1232                 myhealth_flash_temp = 0;
1233         }
1234
1235         myhealth_prev = myhealth;
1236
1237         // IDEA: change damage color/picture based on player model for robot/alien species?
1238         // pro: matches model better
1239         // contra: it's not red because blood is red, but because red is an alarming color, so red should stay
1240         // maybe different reddish pics?
1241         if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
1242         {
1243                 if(autocvar_cl_gentle_damage == 2)
1244                 {
1245                         if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
1246                                 myhealth_gentlergb = randomvec();
1247                 }
1248                 else
1249                         myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
1250
1251                 if(myhealth_flash_temp > 0)
1252                         drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
1253         }
1254         else if(myhealth_flash_temp > 0)
1255                 drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
1256
1257         if(autocvar_hud_postprocessing) // we still need to set this anyway even when chase_active is set, this way it doesn't get stuck on.
1258         {
1259                 if(autocvar_hud_damage_blur && myhealth_flash_temp)
1260                 {
1261                         damage_blurpostprocess.x = 1;
1262                         damage_blurpostprocess.y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
1263                         damage_blurpostprocess.z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
1264                 }
1265                 else
1266                 {
1267                         damage_blurpostprocess.x = 0;
1268                         damage_blurpostprocess.y = 0;
1269                         damage_blurpostprocess.z = 0;
1270                 }
1271         }
1272 }
1273
1274 void View_PostProcessing()
1275 {
1276         float e1 = (autocvar_hud_postprocessing_maxbluralpha != 0);
1277         float e2 = (autocvar_hud_powerup != 0);
1278         if(autocvar_hud_postprocessing && (e1 || e2)) // TODO: Remove this code and re-do the postprocess handling in the engine, where it properly belongs.
1279         {
1280                 // enable or disable rendering types if they are used or not
1281                 if(cvar("r_glsl_postprocess_uservec1_enable") != e1) { cvar_set("r_glsl_postprocess_uservec1_enable", ftos(e1)); }
1282                 if(cvar("r_glsl_postprocess_uservec2_enable") != e2) { cvar_set("r_glsl_postprocess_uservec2_enable", ftos(e2)); }
1283
1284                 // blur postprocess handling done first (used by hud_damage and hud_contents)
1285                 if((damage_blurpostprocess.x || content_blurpostprocess.x))
1286                 {
1287                         float blurradius = bound(0, damage_blurpostprocess.y + content_blurpostprocess.y, autocvar_hud_postprocessing_maxblurradius);
1288                         float bluralpha = bound(0, damage_blurpostprocess.z + content_blurpostprocess.z, autocvar_hud_postprocessing_maxbluralpha);
1289                         if(blurradius != old_blurradius || bluralpha != old_bluralpha) // reduce cvar_set spam as much as possible
1290                         {
1291                                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
1292                                 old_blurradius = blurradius;
1293                                 old_bluralpha = bluralpha;
1294                         }
1295                 }
1296                 else if(cvar_string("r_glsl_postprocess_uservec1") != "0 0 0 0") // reduce cvar_set spam as much as possible
1297                 {
1298                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
1299                         old_blurradius = 0;
1300                         old_bluralpha = 0;
1301                 }
1302
1303                 // edge detection postprocess handling done second (used by hud_powerup)
1304                 float sharpen_intensity = 0;
1305                 FOREACH(StatusEffect, it.instanceOfPowerups,
1306                 {
1307                         float powerup_finished = StatusEffects_gettime(it, g_statuseffects) - time;
1308                         if(powerup_finished > 0)
1309                                 sharpen_intensity += powerup_finished;
1310                 });
1311
1312                 sharpen_intensity = bound(0, ((STAT(HEALTH) > 0) ? sharpen_intensity : 0), 5); // Check to see if player is alive (if not, set 0) - also bound to fade out starting at 5 seconds.
1313
1314                 if(autocvar_hud_powerup && sharpen_intensity > 0)
1315                 {
1316                         if(sharpen_intensity != old_sharpen_intensity) // reduce cvar_set spam as much as possible
1317                         {
1318                                 cvar_set("r_glsl_postprocess_uservec2", strcat(ftos((sharpen_intensity / 5) * autocvar_hud_powerup), " ", ftos(-sharpen_intensity * autocvar_hud_powerup), " 0 0"));
1319                                 old_sharpen_intensity = sharpen_intensity;
1320                         }
1321                 }
1322                 else if(cvar_string("r_glsl_postprocess_uservec2") != "0 0 0 0") // reduce cvar_set spam as much as possible
1323                 {
1324                         cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
1325                         old_sharpen_intensity = 0;
1326                 }
1327
1328                 if(cvar("r_glsl_postprocess") == 0)
1329                         cvar_set("r_glsl_postprocess", "2");
1330         }
1331         else if(cvar("r_glsl_postprocess") == 2)
1332                 cvar_set("r_glsl_postprocess", "0");
1333 }
1334
1335 void View_Lock()
1336 {
1337         int lock_type = autocvar_cl_lockview;
1338
1339         if (!autocvar_hud_cursormode
1340                 && ((autocvar__hud_configure && spectatee_status <= 0)
1341                         || intermission > 1
1342                         || HUD_Radar_Clickable()
1343                         || HUD_MinigameMenu_IsOpened()
1344                         || QuickMenu_IsOpened()
1345                 )
1346         )
1347                 lock_type = 1;
1348
1349         // lock_type 1: lock origin and angles
1350         // lock_type 2: lock only origin
1351         if(lock_type >= 1)
1352                 setproperty(VF_ORIGIN, freeze_org);
1353         else
1354                 freeze_org = getpropertyvec(VF_ORIGIN);
1355         if(lock_type == 1)
1356                 setproperty(VF_ANGLES, freeze_ang);
1357         else
1358                 freeze_ang = getpropertyvec(VF_ANGLES);
1359 }
1360
1361 void View_DemoCamera()
1362 {
1363         if(camera_active) // Camera for demo playback
1364         {
1365                 if(autocvar_camera_enable)
1366                         CSQC_Demo_Camera();
1367                 else
1368                 {
1369                         cvar_set("chase_active", ftos(chase_active_backup));
1370                         cvar_set("cl_demo_mousegrab", "0");
1371                         camera_active = false;
1372                 }
1373         }
1374         else
1375         {
1376 #ifdef CAMERATEST
1377                 if(autocvar_camera_enable)
1378 #else
1379                 if(autocvar_camera_enable && isdemo())
1380 #endif
1381                 {
1382                         // Enable required Darkplaces cvars
1383                         chase_active_backup = autocvar_chase_active;
1384                         cvar_set("chase_active", "2");
1385                         cvar_set("cl_demo_mousegrab", "1");
1386                         camera_active = true;
1387                         camera_mode = false;
1388                 }
1389         }
1390 }
1391
1392 #ifdef BLURTEST
1393 void View_BlurTest()
1394 {
1395         if(time > blurtest_time0 && time < blurtest_time1)
1396         {
1397                 float t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
1398                 float r = t * blurtest_radius;
1399                 float f = 1 / (t ** blurtest_power) - 1;
1400
1401                 cvar_set("r_glsl_postprocess", "1");
1402                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
1403         }
1404         else
1405         {
1406                 cvar_set("r_glsl_postprocess", "0");
1407                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
1408         }
1409 }
1410 #endif
1411
1412 void View_CheckButtonStatus()
1413 {
1414         float is_dead = (STAT(HEALTH) <= 0);
1415
1416         // FIXME do we need this hack?
1417         if(isdemo())
1418         {
1419                 // in demos, input_buttons do not work
1420                 button_zoom = (autocvar__togglezoom == "-");
1421         }
1422         else if(button_zoom
1423                 && autocvar_cl_unpress_zoom_on_death
1424                 && (spectatee_status >= 0)
1425                 && (is_dead || intermission))
1426         {
1427                 // no zoom while dead or in intermission please
1428                 localcmd("-zoom\n");
1429                 button_zoom = false;
1430         }
1431
1432         if(autocvar_fov <= 59.5)
1433         {
1434                 if(!zoomscript_caught)
1435                 {
1436                         localcmd("+button9\n");
1437                         zoomscript_caught = 1;
1438                 }
1439         }
1440         else
1441         {
1442                 if(zoomscript_caught)
1443                 {
1444                         localcmd("-button9\n");
1445                         zoomscript_caught = 0;
1446                 }
1447         }
1448
1449         if(active_minigame && HUD_MinigameMenu_IsOpened())
1450         {
1451                 if(!minigame_wasactive)
1452                 {
1453                         localcmd("+button12\n");
1454                         minigame_wasactive = true;
1455                 }
1456         }
1457         else if(minigame_wasactive)
1458         {
1459                 localcmd("-button12\n");
1460                 minigame_wasactive = false;
1461         }
1462
1463         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1464         {
1465                 entity wepent = viewmodels[slot];
1466
1467                 if(wepent.last_switchweapon != wepent.switchweapon)
1468                 {
1469                         weapontime = time;
1470                         wepent.last_switchweapon = wepent.switchweapon;
1471                         if(slot == 0 && button_zoom && autocvar_cl_unpress_zoom_on_weapon_switch)
1472                         {
1473                                 localcmd("-zoom\n");
1474                                 button_zoom = false;
1475                         }
1476                         if(slot == 0 && autocvar_cl_unpress_attack_on_weapon_switch)
1477                         {
1478                                 localcmd("-fire\n");
1479                                 localcmd("-fire2\n");
1480                                 button_attack2 = false;
1481                         }
1482                 }
1483                 if(wepent.last_activeweapon != wepent.activeweapon)
1484                 {
1485                         wepent.last_activeweapon = wepent.activeweapon;
1486
1487                         entity e = wepent.activeweapon;
1488                         if(e.netname != "")
1489                                 localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
1490                         else if(slot == 0)
1491                                 localcmd("\ncl_hook_activeweapon none\n");
1492                 }
1493         }
1494 }
1495
1496 bool ov_enabled;
1497 float oldr_nearclip;
1498 float oldr_farclip_base;
1499 float oldr_farclip_world;
1500 float oldr_novis;
1501 float oldr_useportalculling;
1502 float oldr_useinfinitefarclip;
1503 vector ov_org = '0 0 0';
1504 vector ov_mid = '0 0 0';
1505 vector ov_worldmin = '0 0 0';
1506 vector ov_worldmax = '0 0 0';
1507
1508 void View_Ortho()
1509 {
1510         ov_org = '0 0 0';
1511         ov_mid = '0 0 0';
1512         ov_worldmin = '0 0 0';
1513         ov_worldmax = '0 0 0';
1514         if(autocvar_cl_orthoview)
1515         {
1516                 ov_worldmin = mi_picmin;
1517                 ov_worldmax = mi_picmax;
1518
1519                 float ov_width = (ov_worldmax.x - ov_worldmin.x);
1520                 float ov_height = (ov_worldmax.y - ov_worldmin.y);
1521                 float ov_distance = (max(vid_width, vid_height) * max(ov_width, ov_height));
1522
1523                 ov_mid = ((ov_worldmax + ov_worldmin) * 0.5);
1524                 ov_org = vec3(ov_mid.x, ov_mid.y, (ov_mid.z + ov_distance));
1525
1526                 float ov_nearest = vlen(ov_org - vec3(
1527                         bound(ov_worldmin.x, ov_org.x, ov_worldmax.x),
1528                         bound(ov_worldmin.y, ov_org.y, ov_worldmax.y),
1529                         bound(ov_worldmin.z, ov_org.z, ov_worldmax.z)
1530                 ));
1531
1532                 float ov_furthest = 0;
1533                 float dist = 0;
1534
1535                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1536                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1537                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1538                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1539                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1540                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1541                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1542                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1543
1544                 if(!ov_enabled)
1545                 {
1546                         oldr_nearclip = cvar("r_nearclip");
1547                         oldr_farclip_base = cvar("r_farclip_base");
1548                         oldr_farclip_world = cvar("r_farclip_world");
1549                         oldr_novis = cvar("r_novis");
1550                         oldr_useportalculling = cvar("r_useportalculling");
1551                         oldr_useinfinitefarclip = cvar("r_useinfinitefarclip");
1552                 }
1553
1554                 cvar_settemp("r_nearclip", ftos(ov_nearest));
1555                 cvar_settemp("r_farclip_base", ftos(ov_furthest));
1556                 cvar_settemp("r_farclip_world", "0");
1557                 cvar_settemp("r_novis", "1");
1558                 cvar_settemp("r_useportalculling", "0");
1559                 cvar_settemp("r_useinfinitefarclip", "0");
1560
1561                 setproperty(VF_ORIGIN, ov_org);
1562                 setproperty(VF_ANGLES, '90 0 0');
1563
1564                 ov_enabled = true;
1565
1566                 #if 0
1567                 LOG_INFOF("OrthoView: org = %s, angles = %s, distance = %f, nearest = %f, furthest = %f",
1568                         vtos(ov_org),
1569                         vtos(getpropertyvec(VF_ANGLES)),
1570                         ov_distance,
1571                         ov_nearest,
1572                         ov_furthest);
1573                 #endif
1574         }
1575         else
1576         {
1577                 if(ov_enabled)
1578                 {
1579                         cvar_set("r_nearclip", ftos(oldr_nearclip));
1580                         cvar_set("r_farclip_base", ftos(oldr_farclip_base));
1581                         cvar_set("r_farclip_world", ftos(oldr_farclip_world));
1582                         cvar_set("r_novis", ftos(oldr_novis));
1583                         cvar_set("r_useportalculling", ftos(oldr_useportalculling));
1584                         cvar_set("r_useinfinitefarclip", ftos(oldr_useinfinitefarclip));
1585                 }
1586                 ov_enabled = false;
1587         }
1588 }
1589
1590 void View_UpdateFov()
1591 {
1592         vector fov;
1593         if(autocvar_cl_orthoview)
1594                 fov = GetOrthoviewFOV(ov_worldmin, ov_worldmax, ov_mid, ov_org);
1595         else if(csqcplayer.viewloc)
1596                 fov = GetViewLocationFOV(110); // enforce 110 fov, so things don't look odd
1597         else
1598                 fov = GetCurrentFov(autocvar_fov);
1599
1600         setproperty(VF_FOV, fov);
1601 }
1602
1603 void CSQC_UpdateView(entity this, float w, float h)
1604 {
1605         TC(int, w); TC(int, h);
1606
1607         execute_next_frame();
1608
1609         ++framecount;
1610
1611         stats_get();
1612         hud = STAT(HUD);
1613
1614         ReplicateVars(false);
1615         if (ReplicateVars_NOT_SENDING())
1616                 ReplicateVars_DELAY(0.8 + random() * 0.4); // no need to check cvars every frame
1617
1618         HUD_Scale_Disable();
1619
1620         if(autocvar__hud_showbinds_reload) // menu can set this one
1621         {
1622                 db_close(binddb);
1623                 binddb = db_create();
1624                 cvar_set("_hud_showbinds_reload", "0");
1625         }
1626
1627         if(checkextension("DP_CSQC_MINFPS_QUALITY"))
1628                 view_quality = getproperty(VF_MINFPS_QUALITY);
1629         else
1630                 view_quality = 1;
1631
1632         button_attack2 = PHYS_INPUT_BUTTON_ATCK2(this);
1633         button_zoom = PHYS_INPUT_BUTTON_ZOOM(this);
1634
1635         vector vf_size = getpropertyvec(VF_SIZE);
1636         vector vf_min = getpropertyvec(VF_MIN);
1637         vid_width = vf_size.x;
1638         vid_height = vf_size.y;
1639
1640         ticrate = STAT(MOVEVARS_TICRATE) * STAT(MOVEVARS_TIMESCALE);
1641
1642         if (autocvar_chase_active)
1643         {
1644                 // in first person view if r_drawviewmodel is off weapon isn't visible
1645                 // and server doesn't throw any casing
1646                 // switching to 3rd person view r_drawviewmodel is set to -1 to let know the server casings
1647                 // can be thrown for self since own weapon model is visible
1648                 if (autocvar_r_drawviewmodel == 0 && STAT(HEALTH) > 0)
1649                         cvar_set("r_drawviewmodel", "-1");
1650         }
1651         else
1652         {
1653                 if (autocvar_r_drawviewmodel < 0)
1654                         cvar_set("r_drawviewmodel", "0");
1655         }
1656
1657         WaypointSprite_Load();
1658
1659         CSQCPlayer_SetCamera();
1660
1661         if(player_localentnum <= maxclients) // is it a client?
1662                 current_player = player_localentnum - 1;
1663         else // then player_localentnum is the vehicle I'm driving
1664                 current_player = player_localnum;
1665         myteam = entcs_GetTeam(current_player);
1666
1667         // abused multiple places below
1668         entity local_player = ((csqcplayer) ? csqcplayer : CSQCModel_server2csqc(player_localentnum - 1));
1669         if(!local_player)
1670                 local_player = this; // fall back!
1671
1672         View_EventChase(local_player);
1673
1674         // do lockview after event chase camera so that it still applies whenever necessary.
1675         View_Lock();
1676
1677         WarpZone_FixView();
1678         //WarpZone_FixPMove();
1679
1680         View_Ortho();
1681
1682         // run viewmodel_draw before updating view_angles to the angles calculated by WarpZone_FixView
1683         // viewmodel_draw needs to use the view_angles set by the engine on every CSQC_UpdateView call
1684         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1685                 viewmodel_draw(viewmodels[slot]);
1686
1687         // Render the Scene
1688         view_origin = getpropertyvec(VF_ORIGIN);
1689         view_angles = getpropertyvec(VF_ANGLES);
1690         MAKE_VECTORS(view_angles, view_forward, view_right, view_up);
1691
1692 #ifdef BLURTEST
1693         View_BlurTest();
1694 #endif
1695
1696         TargetMusic_Advance();
1697         Fog_Force();
1698         fpscounter_update();
1699
1700         if(drawtime == 0)
1701                 drawframetime = 0.01666667; // when we don't know fps yet, we assume 60fps
1702         else
1703                 drawframetime = bound(0.000001, time - drawtime, 1);
1704         drawtime = time;
1705
1706         // watch for gametype changes here...
1707         // in ParseStuffCMD the cmd isn't executed yet :/
1708         // might even be better to add the gametype to TE_CSQC_INIT...?
1709         if(!postinit)
1710                 PostInit();
1711
1712         if(intermission && !intermission_time)
1713                 intermission_time = time;
1714
1715         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
1716         {
1717                 if(calledhooks & HOOK_START)
1718                 {
1719                         localcmd("\ncl_hook_gameend\n");
1720                         calledhooks |= HOOK_END;
1721                 }
1722         }
1723
1724         Announcer();
1725
1726         View_CheckButtonStatus();
1727
1728         ColorTranslateMode = autocvar_cl_stripcolorcodes;
1729
1730         // ALWAYS Clear Current Scene First
1731         clearscene();
1732
1733         setproperty(VF_ORIGIN, view_origin);
1734         setproperty(VF_ANGLES, view_angles);
1735
1736         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
1737         setproperty(VF_SIZE, vf_size);
1738         setproperty(VF_MIN, vf_min);
1739
1740         // Assign Standard Viewflags
1741         // Draw the World (and sky)
1742         setproperty(VF_DRAWWORLD, 1);
1743
1744         // Set the console size vars
1745         vid_conwidth = autocvar_vid_conwidth;
1746         vid_conheight = autocvar_vid_conheight;
1747         vid_pixelheight = autocvar_vid_pixelheight;
1748
1749         View_UpdateFov();
1750
1751         View_DemoCamera();
1752
1753         // Draw the Crosshair
1754         setproperty(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
1755
1756         // Draw the Engine Status Bar (the default Quake HUD)
1757         setproperty(VF_DRAWENGINESBAR, 0);
1758
1759         // Update the mouse position
1760         /*
1761            mousepos_x = vid_conwidth;
1762            mousepos_y = vid_conheight;
1763            mousepos = mousepos*0.5 + getmousepos();
1764          */
1765
1766         IL_EACH(g_drawables, it.draw, it.draw(it));
1767
1768         addentities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS); // TODO: .health is used in cl_deathfade (a feature we have turned off currently)
1769         renderscene();
1770
1771         // Now the the scene has been rendered, begin with the 2D drawing functions
1772
1773         View_NightVision();
1774         DrawReticle(local_player);
1775         HUD_Contents();
1776         HUD_Damage();
1777         View_PostProcessing();
1778
1779         // draw 2D entities
1780         IL_EACH(g_drawables_2d, it.draw2d, it.draw2d(it));
1781         Draw_ShowNames_All();
1782 #if ENABLE_DEBUGDRAW
1783         Debug_Draw();
1784 #endif
1785
1786         scoreboard_active = Scoreboard_WouldDraw();
1787
1788         HUD_Draw(this); // this parameter for deep vehicle function
1789
1790         if(NextFrameCommand)
1791         {
1792                 localcmd("\n", NextFrameCommand, "\n");
1793                 NextFrameCommand = string_null;
1794         }
1795
1796         // we must do this check AFTER a frame was rendered, or it won't work
1797         if(cs_project_is_b0rked == 0)
1798         {
1799                 string w0, h0;
1800                 w0 = ftos(autocvar_vid_conwidth);
1801                 h0 = ftos(autocvar_vid_conheight);
1802                 //setproperty(VF_VIEWPORT, '0 0 0', '640 480 0');
1803                 //setproperty(VF_FOV, '90 90 0');
1804                 setproperty(VF_ORIGIN, '0 0 0');
1805                 setproperty(VF_ANGLES, '0 0 0');
1806                 setproperty(VF_PERSPECTIVE, 1);
1807                 vector forward, right, up;
1808                 MAKE_VECTORS('0 0 0', forward, right, up);
1809                 vector v1, v2;
1810                 cvar_set("vid_conwidth", "800");
1811                 cvar_set("vid_conheight", "600");
1812                 v1 = cs_project(forward);
1813                 cvar_set("vid_conwidth", "640");
1814                 cvar_set("vid_conheight", "480");
1815                 v2 = cs_project(forward);
1816                 if(v1 == v2)
1817                         cs_project_is_b0rked = 1;
1818                 else
1819                         cs_project_is_b0rked = -1;
1820                 cvar_set("vid_conwidth", w0);
1821                 cvar_set("vid_conheight", h0);
1822         }
1823
1824         HUD_Mouse(local_player);
1825
1826         cl_notice_run();
1827         unpause_update();
1828         Net_Flush();
1829
1830         // let's reset the view back to normal for the end
1831         setproperty(VF_MIN, '0 0 0');
1832         setproperty(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
1833
1834         IL_ENDFRAME();
1835 }
1836
1837
1838 // following vectors must be global to allow seamless switching between camera modes
1839 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
1840 void CSQC_Demo_Camera()
1841 {
1842         float speed, attenuation, dimensions;
1843         vector tmp, delta;
1844
1845         if( autocvar_camera_reset || !camera_mode )
1846         {
1847                 camera_offset = '0 0 0';
1848                 current_angles = '0 0 0';
1849                 camera_direction = '0 0 0';
1850                 camera_offset.z += 30;
1851                 camera_offset.x += 30 * -cos(current_angles.y * DEG2RAD);
1852                 camera_offset.y += 30 * -sin(current_angles.y * DEG2RAD);
1853                 current_origin = view_origin;
1854                 current_camera_offset  = camera_offset;
1855                 cvar_set("camera_reset", "0");
1856                 camera_mode = CAMERA_CHASE;
1857         }
1858
1859         // Camera angles
1860         if( camera_roll )
1861                 mouse_angles.z += camera_roll * autocvar_camera_speed_roll;
1862
1863         if(autocvar_camera_look_player)
1864         {
1865                 vector dir;
1866                 float n;
1867
1868                 dir = normalize(view_origin - current_position);
1869                 n = mouse_angles.z;
1870                 mouse_angles = vectoangles(dir);
1871                 mouse_angles.x = mouse_angles.x * -1;
1872                 mouse_angles.z = n;
1873         }
1874         else
1875         {
1876                 tmp = getmousepos() * 0.1;
1877                 if(vdist(tmp, >, autocvar_camera_mouse_threshold))
1878                 {
1879                         mouse_angles.x += tmp.y * cos(mouse_angles.z * DEG2RAD) + (tmp.x * sin(mouse_angles.z * DEG2RAD));
1880                         mouse_angles.y -= tmp.x * cos(mouse_angles.z * DEG2RAD) + (tmp.y * -sin(mouse_angles.z * DEG2RAD));
1881                 }
1882         }
1883
1884         while (mouse_angles.x < -180) mouse_angles.x = mouse_angles.x + 360;
1885         while (mouse_angles.x > 180) mouse_angles.x = mouse_angles.x - 360;
1886         while (mouse_angles.y < -180) mouse_angles.y = mouse_angles.y + 360;
1887         while (mouse_angles.y > 180) mouse_angles.y = mouse_angles.y - 360;
1888
1889         // Fix difference when angles don't have the same sign
1890         delta = '0 0 0';
1891         if(mouse_angles.y < -60 && current_angles.y > 60)
1892                 delta = '0 360 0';
1893         if(mouse_angles.y > 60 && current_angles.y < -60)
1894                 delta = '0 -360 0';
1895
1896         if(autocvar_camera_look_player)
1897                 attenuation = autocvar_camera_look_attenuation;
1898         else
1899                 attenuation = autocvar_camera_speed_attenuation;
1900
1901         attenuation = 1 / max(1, attenuation);
1902         current_angles += (mouse_angles - current_angles + delta) * attenuation;
1903
1904         while (current_angles.x < -180) current_angles.x = current_angles.x + 360;
1905         while (current_angles.x > 180) current_angles.x = current_angles.x - 360;
1906         while (current_angles.y < -180) current_angles.y = current_angles.y + 360;
1907         while (current_angles.y > 180) current_angles.y = current_angles.y - 360;
1908
1909         // Camera position
1910         tmp = '0 0 0';
1911         dimensions = 0;
1912
1913         if( camera_direction.x )
1914         {
1915                 tmp.x = camera_direction.x * cos(current_angles.y * DEG2RAD);
1916                 tmp.y = camera_direction.x * sin(current_angles.y * DEG2RAD);
1917                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
1918                         tmp.z = camera_direction.x * -sin(current_angles.x * DEG2RAD);
1919                 ++dimensions;
1920         }
1921
1922         if( camera_direction.y )
1923         {
1924                 tmp.x += camera_direction.y * -sin(current_angles.y * DEG2RAD);
1925                 tmp.y += camera_direction.y * cos(current_angles.y * DEG2RAD) * cos(current_angles.z * DEG2RAD);
1926                 tmp.z += camera_direction.y * sin(current_angles.z * DEG2RAD);
1927                 ++dimensions;
1928         }
1929
1930         if( camera_direction.z )
1931         {
1932                 tmp.z += camera_direction.z * cos(current_angles.z * DEG2RAD);
1933                 ++dimensions;
1934         }
1935
1936         if(autocvar_camera_free)
1937                 speed = autocvar_camera_speed_free;
1938         else
1939                 speed = autocvar_camera_speed_chase;
1940
1941         if(dimensions)
1942         {
1943                 speed = speed * sqrt(1 / dimensions);
1944                 camera_offset += tmp * speed;
1945         }
1946
1947         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
1948
1949         // Camera modes
1950         if( autocvar_camera_free )
1951         {
1952                 if ( camera_mode == CAMERA_CHASE )
1953                 {
1954                         current_camera_offset = current_origin + current_camera_offset;
1955                         camera_offset = current_origin + camera_offset;
1956                 }
1957
1958                 camera_mode = CAMERA_FREE;
1959                 current_position = current_camera_offset;
1960         }
1961         else
1962         {
1963                 if ( camera_mode == CAMERA_FREE )
1964                 {
1965                         current_origin = view_origin;
1966                         camera_offset = camera_offset - current_origin;
1967                         current_camera_offset = current_camera_offset - current_origin;
1968                 }
1969
1970                 camera_mode = CAMERA_CHASE;
1971
1972                 if(autocvar_camera_chase_smoothly)
1973                         current_origin += (view_origin - current_origin) * attenuation;
1974                 else
1975                         current_origin = view_origin;
1976
1977                 current_position = current_origin + current_camera_offset;
1978         }
1979
1980         setproperty(VF_ANGLES, current_angles);
1981         setproperty(VF_ORIGIN, current_position);
1982 }