qcsrc/client/view.qc

   1
   2 #include "announcer.qh"
   3 #include "hud/all.qh"
   4 #include "mapvoting.qh"
   5 #include "scoreboard.qh"
   6 #include "shownames.qh"
   7 #include "quickmenu.qh"
   8
   9 #include "mutators/events.qh"
  10
  11 #include "../common/anim.qh"
  12 #include "../common/constants.qh"
  13 #include "../common/debug.qh"
  14 #include "../common/mapinfo.qh"
  15 #include <common/gamemodes/all.qh>
  16 #include "../common/physics/player.qh"
  17 #include "../common/stats.qh"
  18 #include "../common/triggers/target/music.qh"
  19 #include "../common/teams.qh"
  20
  21 #include <common/vehicles/all.qh>
  22 #include <common/weapons/all.qh>
  23 #include "../common/viewloc.qh"
  24 #include "../common/minigames/cl_minigames.qh"
  25 #include "../common/minigames/cl_minigames_hud.qh"
  26
  27 #include "../lib/csqcmodel/cl_player.qh"
  28
  29 #include "../lib/warpzone/client.qh"
  30 #include "../lib/warpzone/common.qh"
  31
  32 #define EFMASK_CHEAP (EF_ADDITIVE | EF_DOUBLESIDED | EF_FULLBRIGHT | EF_NODEPTHTEST | EF_NODRAW | EF_NOSHADOW | EF_SELECTABLE | EF_TELEPORT_BIT)
  33
  34 float autocvar_cl_viewmodel_scale;
  35
  36 bool autocvar_cl_bobmodel;
  37 float autocvar_cl_bobmodel_speed;
  38 float autocvar_cl_bobmodel_side;
  39 float autocvar_cl_bobmodel_up;
  40
  41 float autocvar_cl_followmodel;
  42 float autocvar_cl_followmodel_speed = 0.3;
  43 float autocvar_cl_followmodel_limit = 1000;
  44 float autocvar_cl_followmodel_highpass1 = 0.05;
  45 float autocvar_cl_followmodel_highpass = 0.05;
  46 float autocvar_cl_followmodel_lowpass = 0.03;
  47
  48 float autocvar_cl_leanmodel;
  49 float autocvar_cl_leanmodel_speed = 0.3;
  50 float autocvar_cl_leanmodel_limit = 1000;
  51 float autocvar_cl_leanmodel_highpass1 = 0.2;
  52 float autocvar_cl_leanmodel_highpass = 0.2;
  53 float autocvar_cl_leanmodel_lowpass = 0.05;
  54
  55 #define lowpass(value, frac, ref_store, ret) MACRO_BEGIN \
  56 { \
  57         float __frac = 1 - exp(-frac); \
  58         ret = ref_store = ref_store * (1 - __frac) + (value) * __frac; \
  59 } MACRO_END
  60
  61 #define lowpass_limited(value, frac, limit, ref_store, ret) MACRO_BEGIN \
  62 { \
  63         float __ignore; lowpass(value, frac, ref_store, __ignore); \
  64         ret = ref_store = bound((value) - (limit), ref_store, (value) + (limit)); \
  65 } MACRO_END
  66
  67 #define highpass(value, frac, ref_store, ret) MACRO_BEGIN \
  68 { \
  69         float __f = 0; lowpass(value, frac, ref_store, __f); \
  70         ret = (value) - __f; \
  71 } MACRO_END
  72
  73 #define highpass_limited(value, frac, limit, ref_store, ret) MACRO_BEGIN \
  74 { \
  75         float __f = 0; lowpass_limited(value, frac, limit, ref_store, __f); \
  76         ret = (value) - __f; \
  77 } MACRO_END
  78
  79 #define lowpass3(value, fracx, fracy, fracz, ref_store, ref_out) MACRO_BEGIN \
  80 { \
  81         lowpass(value.x, fracx, ref_store.x, ref_out.x); \
  82         lowpass(value.y, fracy, ref_store.y, ref_out.y); \
  83         lowpass(value.z, fracz, ref_store.z, ref_out.z); \
  84 } MACRO_END
  85
  86 #define highpass3(value, fracx, fracy, fracz, ref_store, ref_out) MACRO_BEGIN \
  87 { \
  88         highpass(value.x, fracx, ref_store.x, ref_out.x); \
  89         highpass(value.y, fracy, ref_store.y, ref_out.y); \
  90         highpass(value.z, fracz, ref_store.z, ref_out.z); \
  91 } MACRO_END
  92
  93 #define highpass3_limited(value, fracx, limitx, fracy, limity, fracz, limitz, ref_store, ref_out) MACRO_BEGIN \
  94 { \
  95         highpass_limited(value.x, fracx, limitx, ref_store.x, ref_out.x); \
  96         highpass_limited(value.y, fracy, limity, ref_store.y, ref_out.y); \
  97         highpass_limited(value.z, fracz, limitz, ref_store.z, ref_out.z); \
  98 } MACRO_END
  99
 100 void viewmodel_animate(entity this)
 101 {
 102         static float prevtime;
 103         float frametime = (time - prevtime) * STAT(MOVEVARS_TIMESCALE);
 104         prevtime = time;
 105
 106         if (autocvar_chase_active) return;
 107         if (STAT(HEALTH) <= 0) return;
 108
 109         entity view = CSQCModel_server2csqc(player_localentnum - 1);
 110
 111         bool clonground = !(view.anim_implicit_state & ANIMIMPLICITSTATE_INAIR);
 112         static bool oldonground;
 113         static float hitgroundtime;
 114         static float lastongroundtime;
 115         if (clonground)
 116         {
 117                 float f = time; // cl.movecmd[0].time
 118                 if (!oldonground)
 119                         hitgroundtime = f;
 120                 lastongroundtime = f;
 121         }
 122         oldonground = clonground;
 123
 124         vector gunorg = '0 0 0', gunangles = '0 0 0';
 125         static vector gunorg_prev = '0 0 0', gunangles_prev = '0 0 0';
 126
 127         bool teleported = view.csqcmodel_teleported;
 128
 129         // 1. if we teleported, clear the frametime... the lowpass will recover the previous value then
 130         if (teleported)
 131         {
 132                 // try to fix the first highpass; result is NOT
 133                 // perfect! TODO find a better fix
 134                 gunangles_prev = view_angles;
 135                 gunorg_prev = view_origin;
 136         }
 137
 138         static vector gunorg_highpass = '0 0 0';
 139
 140         // 2. for the gun origin, only keep the high frequency (non-DC) parts, which is "somewhat like velocity"
 141         gunorg_highpass += gunorg_prev;
 142         highpass3_limited(view_origin,
 143                 frametime / max(0.001, autocvar_cl_followmodel_highpass1), autocvar_cl_followmodel_limit,
 144                 frametime / max(0.001, autocvar_cl_followmodel_highpass1), autocvar_cl_followmodel_limit,
 145                 frametime / max(0.001, autocvar_cl_followmodel_highpass1), autocvar_cl_followmodel_limit,
 146                 gunorg_highpass, gunorg);
 147         gunorg_prev = view_origin;
 148         gunorg_highpass -= gunorg_prev;
 149
 150         static vector gunangles_highpass = '0 0 0';
 151
 152         // in the highpass, we _store_ the DIFFERENCE to the actual view angles...
 153         gunangles_highpass += gunangles_prev;
 154         PITCH(gunangles_highpass) += 360 * floor((PITCH(view_angles) - PITCH(gunangles_highpass)) / 360 + 0.5);
 155         YAW(gunangles_highpass) += 360 * floor((YAW(view_angles) - YAW(gunangles_highpass)) / 360 + 0.5);
 156         ROLL(gunangles_highpass) += 360 * floor((ROLL(view_angles) - ROLL(gunangles_highpass)) / 360 + 0.5);
 157         highpass3_limited(view_angles,
 158                 frametime / max(0.001, autocvar_cl_leanmodel_highpass1), autocvar_cl_leanmodel_limit,
 159                 frametime / max(0.001, autocvar_cl_leanmodel_highpass1), autocvar_cl_leanmodel_limit,
 160                 0, 0,
 161                 gunangles_highpass, gunangles);
 162         gunangles_prev = view_angles;
 163         gunangles_highpass -= gunangles_prev;
 164
 165         // 3. calculate the RAW adjustment vectors
 166         gunorg.x *= (autocvar_cl_followmodel ? -autocvar_cl_followmodel_speed : 0);
 167         gunorg.y *= (autocvar_cl_followmodel ? -autocvar_cl_followmodel_speed : 0);
 168         gunorg.z *= (autocvar_cl_followmodel ? -autocvar_cl_followmodel_speed : 0);
 169
 170         PITCH(gunangles) *= (autocvar_cl_leanmodel ? -autocvar_cl_leanmodel_speed : 0);
 171         YAW(gunangles) *= (autocvar_cl_leanmodel ? -autocvar_cl_leanmodel_speed : 0);
 172         ROLL(gunangles) = 0;
 173
 174         static vector gunorg_adjustment_highpass;
 175         static vector gunorg_adjustment_lowpass;
 176         static vector gunangles_adjustment_highpass;
 177         static vector gunangles_adjustment_lowpass;
 178
 179         // 4. perform highpass/lowpass on the adjustment vectors (turning velocity into acceleration!)
 180         //    trick: we must do the lowpass LAST, so the lowpass vector IS the final vector!
 181         highpass3(gunorg,
 182                 frametime / max(0.001, autocvar_cl_followmodel_highpass),
 183                 frametime / max(0.001, autocvar_cl_followmodel_highpass),
 184                 frametime / max(0.001, autocvar_cl_followmodel_highpass),
 185                 gunorg_adjustment_highpass, gunorg);
 186         lowpass3(gunorg,
 187                 frametime / max(0.001, autocvar_cl_followmodel_lowpass),
 188                 frametime / max(0.001, autocvar_cl_followmodel_lowpass),
 189                 frametime / max(0.001, autocvar_cl_followmodel_lowpass),
 190                 gunorg_adjustment_lowpass, gunorg);
 191         // we assume here: PITCH = 0, YAW = 1, ROLL = 2
 192         highpass3(gunangles,
 193                 frametime / max(0.001, autocvar_cl_leanmodel_highpass),
 194                 frametime / max(0.001, autocvar_cl_leanmodel_highpass),
 195                 0,
 196                 gunangles_adjustment_highpass, gunangles);
 197         lowpass3(gunangles,
 198                 frametime / max(0.001, autocvar_cl_leanmodel_lowpass),
 199                 frametime / max(0.001, autocvar_cl_leanmodel_lowpass),
 200                 0,
 201                 gunangles_adjustment_lowpass, gunangles);
 202
 203         float xyspeed = bound(0, vlen(vec2(view.velocity)), 400);
 204
 205         // vertical view bobbing code
 206         // TODO: cl_bob
 207
 208         // horizontal view bobbing code
 209         // TODO: cl_bob2
 210
 211         // fall bobbing code
 212         // causes the view to swing down and back up when touching the ground
 213         // TODO: cl_bobfall
 214
 215         // gun model bobbing code
 216         if (autocvar_cl_bobmodel)
 217         {
 218                 // calculate for swinging gun model
 219                 // the gun bobs when running on the ground, but doesn't bob when you're in the air.
 220                 // Sajt: I tried to smooth out the transitions between bob and no bob, which works
 221                 // for the most part, but for some reason when you go through a message trigger or
 222                 // pick up an item or anything like that it will momentarily jolt the gun.
 223                 vector forward, right = '0 0 0', up = '0 0 0';
 224                 float bspeed;
 225                 float t = 1;
 226                 float s = time * autocvar_cl_bobmodel_speed;
 227                 if (clonground)
 228                 {
 229                         if (time - hitgroundtime < 0.2)
 230                         {
 231                                 // just hit the ground, speed the bob back up over the next 0.2 seconds
 232                                 t = time - hitgroundtime;
 233                                 t = bound(0, t, 0.2);
 234                                 t *= 5;
 235                         }
 236                 }
 237                 else
 238                 {
 239                         // recently left the ground, slow the bob down over the next 0.2 seconds
 240                         t = time - lastongroundtime;
 241                         t = 0.2 - bound(0, t, 0.2);
 242                         t *= 5;
 243                 }
 244                 bspeed = xyspeed * 0.01;
 245                 MAKEVECTORS(makevectors, view_angles, forward, right, up);
 246                 float bobr = bspeed * autocvar_cl_bobmodel_side * autocvar_cl_viewmodel_scale * sin(s) * t;
 247                 gunorg += bobr * right;
 248                 float bobu = bspeed * autocvar_cl_bobmodel_up * autocvar_cl_viewmodel_scale * cos(s * 2) * t;
 249                 gunorg += bobu * up;
 250         }
 251         vector v = rotate(gunorg, YAW(view_angles) * DEG2RAD); // rotate world coordinates to relative ones
 252         v.z = gunorg.z;
 253         this.origin += v;
 254         gunangles.x = -gunangles.x; // pitch was inverted, now that actually matters
 255         this.angles += gunangles;
 256 }
 257
 258 .vector viewmodel_origin, viewmodel_angles;
 259 .float weapon_nextthink;
 260 .float weapon_eta_last;
 261 .float weapon_switchdelay;
 262
 263 void viewmodel_draw(entity this)
 264 {
 265         int mask = (intermission || (STAT(HEALTH) <= 0) || autocvar_chase_active) ? 0 : MASK_NORMAL;
 266         float a = this.alpha;
 267         static bool wasinvehicle;
 268         bool invehicle = player_localentnum > maxclients;
 269         if (invehicle) a = -1;
 270         else if (wasinvehicle) a = 1;
 271         wasinvehicle = invehicle;
 272         Weapon wep = activeweapon;
 273         int c = stof(getplayerkeyvalue(current_player, "colors"));
 274         vector g = weaponentity_glowmod(wep, c);
 275         entity me = CSQCModel_server2csqc(player_localentnum - 1);
 276         int fx = ((me.csqcmodel_effects & EFMASK_CHEAP)
 277                 | EF_NODEPTHTEST)
 278                 &~ (EF_FULLBRIGHT); // can mask team color, so get rid of it
 279         for (entity e = this; e; e = e.weaponchild)
 280         {
 281                 e.drawmask = mask;
 282                 e.alpha = a;
 283                 e.colormap = 256 + c;  // colormap == 0 is black, c == 0 is white
 284                 e.glowmod = g;
 285                 e.csqcmodel_effects = fx;
 286                 CSQCModel_Effects_Apply(e);
 287         }
 288         {
 289                 static string name_last;
 290                 string name = wep.mdl;
 291                 if (name != name_last)
 292                 {
 293                         name_last = name;
 294                         CL_WeaponEntity_SetModel(this, name);
 295                         this.viewmodel_origin = this.origin;
 296                         this.viewmodel_angles = this.angles;
 297                 }
 298                 anim_update(this);
 299                 if (!this.animstate_override)
 300                         anim_set(this, this.anim_idle, true, false, false);
 301         }
 302         float f = 0; // 0..1; 0: fully active
 303         float eta = (this.weapon_nextthink - time) / STAT(WEAPONRATEFACTOR);
 304         if (eta <= 0) f = this.weapon_eta_last;
 305         else switch (this.state)
 306         {
 307                 case WS_RAISE:
 308                 {
 309                         f = eta / max(eta, this.weapon_switchdelay);
 310                         break;
 311                 }
 312                 case WS_DROP:
 313                 {
 314                         f = 1 - eta / max(eta, this.weapon_switchdelay);
 315                         break;
 316                 }
 317                 case WS_CLEAR:
 318                 {
 319                         f = 1;
 320                         break;
 321                 }
 322         }
 323         this.weapon_eta_last = f;
 324         this.origin = this.viewmodel_origin;
 325         this.angles = this.viewmodel_angles;
 326         this.angles_x = (-90 * f * f);
 327         viewmodel_animate(this);
 328         setorigin(this, this.origin);
 329 }
 330
 331 entity viewmodel;
 332 STATIC_INIT(viewmodel) {
 333     viewmodel = new(viewmodel);
 334     make_pure(viewmodel);
 335         viewmodel.draw = viewmodel_draw;
 336 }
 337
 338 entity porto;
 339 vector polyline[16];
 340 void Porto_Draw(entity this)
 341 {
 342         vector p, dir, ang, q, nextdir;
 343         float portal_number, portal1_idx;
 344
 345         if(activeweapon != WEP_PORTO || spectatee_status || gametype == MAPINFO_TYPE_NEXBALL)
 346                 return;
 347         if(WEP_CVAR(porto, secondary))
 348                 return;
 349         if(intermission == 1)
 350                 return;
 351         if(intermission == 2)
 352                 return;
 353         if (STAT(HEALTH) <= 0)
 354                 return;
 355
 356         dir = view_forward;
 357
 358         if(angles_held_status)
 359         {
 360                 makevectors(angles_held);
 361                 dir = v_forward;
 362         }
 363
 364         p = view_origin;
 365
 366         polyline[0] = p;
 367         int idx = 1;
 368         portal_number = 0;
 369         nextdir = dir;
 370
 371         for (;;)
 372         {
 373                 dir = nextdir;
 374                 traceline(p, p + 65536 * dir, true, porto);
 375                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
 376                         return;
 377                 nextdir = dir - 2 * (dir * trace_plane_normal) * trace_plane_normal; // mirror dir at trace_plane_normal
 378                 p = trace_endpos;
 379                 polyline[idx] = p;
 380                 ++idx;
 381                 if(idx >= 16)
 382                         return;
 383                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
 384                         continue;
 385                 ++portal_number;
 386                 ang = vectoangles2(trace_plane_normal, dir);
 387                 ang.x = -ang.x;
 388                 makevectors(ang);
 389                 if(!CheckWireframeBox(porto, p - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
 390                         return;
 391                 if(portal_number == 1)
 392                 {
 393                         portal1_idx = idx;
 394                         if(portal_number >= 2)
 395                                 break;
 396                 }
 397         }
 398
 399         while(idx >= 2)
 400         {
 401                 p = polyline[idx-2];
 402                 q = polyline[idx-1];
 403                 if(idx == 2)
 404                         p = p - view_up * 16;
 405                 if(idx-1 >= portal1_idx)
 406                 {
 407                         Draw_CylindricLine(p, q, 4, "", 1, 0, '0 0 1', 0.5, DRAWFLAG_NORMAL, view_origin);
 408                 }
 409                 else
 410                 {
 411                         Draw_CylindricLine(p, q, 4, "", 1, 0, '1 0 0', 0.5, DRAWFLAG_NORMAL, view_origin);
 412                 }
 413                 --idx;
 414         }
 415 }
 416
 417 void Porto_Init()
 418 {
 419         porto = new(porto);
 420         make_pure(porto);
 421         porto.draw = Porto_Draw;
 422         porto.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 423 }
 424
 425 float drawtime;
 426 float avgspeed;
 427 vector GetCurrentFov(float fov)
 428 {
 429         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir;
 430         float velocityzoom, curspeed;
 431         vector v;
 432
 433         zoomsensitivity = autocvar_cl_zoomsensitivity;
 434         zoomfactor = autocvar_cl_zoomfactor;
 435         if(zoomfactor < 1 || zoomfactor > 30)
 436                 zoomfactor = 2.5;
 437         zoomspeed = autocvar_cl_zoomspeed;
 438         if(zoomspeed >= 0)
 439         if(zoomspeed < 0.5 || zoomspeed > 16)
 440                         zoomspeed = 3.5;
 441
 442         zoomdir = button_zoom;
 443         if(hud == HUD_NORMAL)
 444         if(switchweapon == activeweapon)
 445         if((activeweapon == WEP_VORTEX && !WEP_CVAR(vortex, secondary)) || (activeweapon == WEP_RIFLE && !WEP_CVAR(rifle, secondary))) // do NOT use switchweapon here
 446                 zoomdir += button_attack2;
 447         if(spectatee_status > 0 || isdemo())
 448         {
 449                 if(spectatorbutton_zoom)
 450                 {
 451                         if(zoomdir)
 452                                 zoomdir = 0;
 453                         else
 454                                 zoomdir = 1;
 455                 }
 456                 // fteqcc failed twice here already, don't optimize this
 457         }
 458
 459         if(zoomdir) { zoomin_effect = 0; }
 460
 461         if(camera_active)
 462         {
 463                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 464         }
 465         else if(autocvar_cl_spawnzoom && zoomin_effect)
 466         {
 467                 float spawnzoomfactor = bound(1, autocvar_cl_spawnzoom_factor, 30);
 468
 469                 current_viewzoom += (autocvar_cl_spawnzoom_speed * (spawnzoomfactor - current_viewzoom) * drawframetime);
 470                 current_viewzoom = bound(1 / spawnzoomfactor, current_viewzoom, 1);
 471                 if(current_viewzoom == 1) { zoomin_effect = 0; }
 472         }
 473         else
 474         {
 475                 if(zoomspeed < 0) // instant zoom
 476                 {
 477                         if(zoomdir)
 478                                 current_viewzoom = 1 / zoomfactor;
 479                         else
 480                                 current_viewzoom = 1;
 481                 }
 482                 else
 483                 {
 484                         if(zoomdir)
 485                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 486                         else
 487                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 488                 }
 489         }
 490
 491         if(almost_equals(current_viewzoom, 1))
 492                 current_zoomfraction = 0;
 493         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 494                 current_zoomfraction = 1;
 495         else
 496                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 497
 498         if(zoomsensitivity < 1)
 499                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
 500         else
 501                 setsensitivityscale(1);
 502
 503         if(autocvar_cl_velocityzoom_enabled && autocvar_cl_velocityzoom_type) // _type = 0 disables velocity zoom too
 504         {
 505                 if(intermission) { curspeed = 0; }
 506                 else
 507                 {
 508
 509                         makevectors(view_angles);
 510                         v = pmove_vel;
 511                         if(csqcplayer)
 512                                 v = csqcplayer.velocity;
 513
 514                         switch(autocvar_cl_velocityzoom_type)
 515                         {
 516                                 case 3: curspeed = max(0, v_forward * v); break;
 517                                 case 2: curspeed = (v_forward * v); break;
 518                                 case 1: default: curspeed = vlen(v); break;
 519                         }
 520                 }
 521
 522                 velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoom_time), 1); // speed at which the zoom adapts to player velocity
 523                 avgspeed = avgspeed * (1 - velocityzoom) + (curspeed / autocvar_cl_velocityzoom_speed) * velocityzoom;
 524                 velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom_factor / 1) * 1);
 525
 526                 //print(ftos(avgspeed), " avgspeed, ", ftos(curspeed), " curspeed, ", ftos(velocityzoom), " return\n"); // for debugging
 527         }
 528         else
 529                 velocityzoom = 1;
 530
 531         float frustumx, frustumy, fovx, fovy;
 532         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 533         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 534         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 535         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 536
 537         return '1 0 0' * fovx + '0 1 0' * fovy;
 538 }
 539
 540 vector GetViewLocationFOV(float fov)
 541 {
 542         float frustumy = tan(fov * M_PI / 360.0) * 0.75;
 543         float frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 544         float fovx = atan2(frustumx, 1) / M_PI * 360.0;
 545         float fovy = atan2(frustumy, 1) / M_PI * 360.0;
 546         return '1 0 0' * fovx + '0 1 0' * fovy;
 547 }
 548
 549 vector GetOrthoviewFOV(vector ov_worldmin, vector ov_worldmax, vector ov_mid, vector ov_org)
 550 {
 551         float fovx, fovy;
 552         float width = (ov_worldmax.x - ov_worldmin.x);
 553         float height = (ov_worldmax.y - ov_worldmin.y);
 554         float distance_to_middle_of_world = vlen(ov_mid - ov_org);
 555         fovx = atan2(width/2, distance_to_middle_of_world) / M_PI * 360.0;
 556         fovy = atan2(height/2, distance_to_middle_of_world) / M_PI * 360.0;
 557         return '1 0 0' * fovx + '0 1 0' * fovy;
 558 }
 559
 560 // this function must match W_SetupShot!
 561 float zoomscript_caught;
 562
 563 vector wcross_origin;
 564 float wcross_scale_prev, wcross_alpha_prev;
 565 vector wcross_color_prev;
 566 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 567 vector wcross_color_goal_prev;
 568 float wcross_changedonetime;
 569
 570 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 571 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 572 float wcross_name_changestarttime, wcross_name_changedonetime;
 573 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 574
 575 float wcross_ring_prev;
 576
 577 entity trueaim;
 578 entity trueaim_rifle;
 579
 580 const float SHOTTYPE_HITTEAM = 1;
 581 const float SHOTTYPE_HITOBSTRUCTION = 2;
 582 const float SHOTTYPE_HITWORLD = 3;
 583 const float SHOTTYPE_HITENEMY = 4;
 584
 585 void TrueAim_Init()
 586 {
 587         trueaim = new(trueaim);
 588         make_pure(trueaim);
 589         trueaim.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 590         trueaim_rifle = new(trueaim_rifle);
 591         make_pure(trueaim_rifle);
 592         trueaim_rifle.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 593 }
 594
 595 float EnemyHitCheck()
 596 {
 597         float t, n;
 598         wcross_origin = project_3d_to_2d(trace_endpos);
 599         wcross_origin.z = 0;
 600         if(trace_ent)
 601                 n = trace_ent.entnum;
 602         else
 603                 n = trace_networkentity;
 604         if(n < 1)
 605                 return SHOTTYPE_HITWORLD;
 606         if(n > maxclients)
 607                 return SHOTTYPE_HITWORLD;
 608         t = entcs_GetTeam(n - 1);
 609         if(teamplay)
 610                 if(t == myteam)
 611                         return SHOTTYPE_HITTEAM;
 612         if(t == NUM_SPECTATOR)
 613                 return SHOTTYPE_HITWORLD;
 614         return SHOTTYPE_HITENEMY;
 615 }
 616
 617 float TrueAimCheck()
 618 {
 619         float nudge = 1; // added to traceline target and subtracted from result TOOD(divVerent): do we still need this? Doesn't the engine do this now for us?
 620         vector vecs, trueaimpoint, w_shotorg;
 621         vector mi, ma, dv;
 622         float shottype;
 623         entity ta;
 624         float mv;
 625
 626         mi = ma = '0 0 0';
 627         ta = trueaim;
 628         mv = MOVE_NOMONSTERS;
 629
 630         switch(activeweapon) // WEAPONTODO
 631         {
 632                 case WEP_TUBA: // no aim
 633                 case WEP_PORTO: // shoots from eye
 634                 case WEP_NEXBALL: // shoots from eye
 635                 case WEP_HOOK: // no trueaim
 636                 case WEP_MORTAR: // toss curve
 637                         return SHOTTYPE_HITWORLD;
 638                 case WEP_VORTEX:
 639                 case WEP_VAPORIZER:
 640                         mv = MOVE_NORMAL;
 641                         break;
 642                 case WEP_RIFLE:
 643                         ta = trueaim_rifle;
 644                         mv = MOVE_NORMAL;
 645                         if(zoomscript_caught)
 646                         {
 647                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 648                                 return EnemyHitCheck();
 649                         }
 650                         break;
 651                 case WEP_DEVASTATOR: // projectile has a size!
 652                         mi = '-3 -3 -3';
 653                         ma = '3 3 3';
 654                         break;
 655                 case WEP_FIREBALL: // projectile has a size!
 656                         mi = '-16 -16 -16';
 657                         ma = '16 16 16';
 658                         break;
 659                 case WEP_SEEKER: // projectile has a size!
 660                         mi = '-2 -2 -2';
 661                         ma = '2 2 2';
 662                         break;
 663                 case WEP_ELECTRO: // projectile has a size!
 664                         mi = '0 0 -3';
 665                         ma = '0 0 -3';
 666                         break;
 667         }
 668
 669         vector traceorigin = entcs_receiver(player_localentnum - 1).origin + (eZ * STAT(VIEWHEIGHT));
 670
 671         vecs = decompressShotOrigin(STAT(SHOTORG));
 672
 673         traceline(traceorigin, traceorigin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 674         trueaimpoint = trace_endpos;
 675
 676         if(vdist((trueaimpoint - traceorigin), <, g_trueaim_minrange))
 677                 trueaimpoint = traceorigin + view_forward * g_trueaim_minrange;
 678
 679         if(vecs.x > 0)
 680                 vecs.y = -vecs.y;
 681         else
 682                 vecs = '0 0 0';
 683
 684         dv = view_right * vecs.y + view_up * vecs.z;
 685         w_shotorg = traceorigin + dv;
 686
 687         // now move the vecs forward as much as requested if possible
 688         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs.x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 689         w_shotorg = trace_endpos - view_forward * nudge;
 690
 691         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 692         shottype = EnemyHitCheck();
 693         if(shottype != SHOTTYPE_HITWORLD)
 694                 return shottype;
 695
 696 #if 0
 697         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 698         // or rather, I know why, but see no fix
 699         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 700                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 701                 return SHOTTYPE_HITOBSTRUCTION;
 702 #endif
 703
 704         return SHOTTYPE_HITWORLD;
 705 }
 706
 707 void PostInit();
 708 void CSQC_Demo_Camera();
 709 float HUD_WouldDrawScoreboard();
 710 float camera_mode;
 711 const float CAMERA_FREE = 1;
 712 const float CAMERA_CHASE = 2;
 713 float reticle_type;
 714 string reticle_image;
 715 string NextFrameCommand;
 716
 717 vector freeze_org, freeze_ang;
 718 entity nightvision_noise, nightvision_noise2;
 719
 720 const float MAX_TIME_DIFF = 5;
 721 float pickup_crosshair_time, pickup_crosshair_size;
 722 float hitindication_crosshair_size;
 723 float use_vortex_chargepool;
 724
 725 float myhealth, myhealth_prev;
 726 float myhealth_flash;
 727
 728 float old_blurradius, old_bluralpha;
 729 float old_sharpen_intensity;
 730
 731 vector myhealth_gentlergb;
 732
 733 float contentavgalpha, liquidalpha_prev;
 734 vector liquidcolor_prev;
 735
 736 float eventchase_current_distance;
 737 float eventchase_running;
 738 bool WantEventchase(entity this)
 739 {
 740         if(autocvar_cl_orthoview)
 741                 return false;
 742         if(intermission)
 743                 return true;
 744         if(this.viewloc)
 745                 return true;
 746         if(spectatee_status >= 0)
 747         {
 748                 if(hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0))
 749                         return true;
 750                 if(MUTATOR_CALLHOOK(WantEventchase, this))
 751                         return true;
 752                 if(autocvar_cl_eventchase_nexball && gametype == MAPINFO_TYPE_NEXBALL && !(WepSet_GetFromStat() & WEPSET(NEXBALL)))
 753                         return true;
 754                 if(autocvar_cl_eventchase_death && (STAT(HEALTH) <= 0))
 755                 {
 756                         if(autocvar_cl_eventchase_death == 2)
 757                         {
 758                                 // don't stop eventchase once it's started (even if velocity changes afterwards)
 759                                 if(this.velocity == '0 0 0' || eventchase_running)
 760                                         return true;
 761                         }
 762                         else return true;
 763                 }
 764         }
 765         return false;
 766 }
 767
 768 void HUD_Crosshair_Vehicle()
 769 {
 770         if(hud != HUD_BUMBLEBEE_GUN)
 771         {
 772                 Vehicle info = Vehicles_from(hud);
 773                 info.vr_crosshair(info);
 774         }
 775 }
 776
 777 vector damage_blurpostprocess, content_blurpostprocess;
 778
 779 float unaccounted_damage = 0;
 780 void UpdateDamage()
 781 {
 782         // accumulate damage with each stat update
 783         static float damage_total_prev = 0;
 784         float damage_total = STAT(DAMAGE_DEALT_TOTAL);
 785         float unaccounted_damage_new = COMPARE_INCREASING(damage_total, damage_total_prev);
 786         damage_total_prev = damage_total;
 787
 788         static float damage_dealt_time_prev = 0;
 789         float damage_dealt_time = STAT(HIT_TIME);
 790         if (damage_dealt_time != damage_dealt_time_prev)
 791         {
 792                 unaccounted_damage += unaccounted_damage_new;
 793                 LOG_TRACE("dmg total: ", ftos(unaccounted_damage), " (+", ftos(unaccounted_damage_new), ")", "\n");
 794         }
 795         damage_dealt_time_prev = damage_dealt_time;
 796
 797         // prevent hitsound when switching spectatee
 798         static float spectatee_status_prev = 0;
 799         if (spectatee_status != spectatee_status_prev)
 800                 unaccounted_damage = 0;
 801         spectatee_status_prev = spectatee_status;
 802 }
 803
 804 void HitSound()
 805 {
 806         // varying sound pitch
 807
 808         static float hitsound_time_prev = 0;
 809         // HACK: the only way to get the arc to sound consistent with pitch shift is to ignore cl_hitsound_antispam_time
 810         float arc_hack = activeweapon == WEP_ARC && autocvar_cl_hitsound >= 2;
 811         if (arc_hack || COMPARE_INCREASING(time, hitsound_time_prev) > autocvar_cl_hitsound_antispam_time)
 812         {
 813                 if (autocvar_cl_hitsound && unaccounted_damage)
 814                 {
 815                         // customizable gradient function that crosses (0,a), (c,1) and asymptotically approaches b
 816                         float a = autocvar_cl_hitsound_max_pitch;
 817                         float b = autocvar_cl_hitsound_min_pitch;
 818                         float c = autocvar_cl_hitsound_nom_damage;
 819                         float x = unaccounted_damage;
 820                         float pitch_shift = (b*x*(a-1) + a*c*(1-b)) / (x*(a-1) + c*(1-b));
 821
 822                         // if sound variation is disabled, set pitch_shift to 1
 823                         if (autocvar_cl_hitsound == 1)
 824                                 pitch_shift = 1;
 825
 826                         // if pitch shift is reversed, mirror in (max-min)/2 + min
 827                         if (autocvar_cl_hitsound == 3)
 828                         {
 829                                 float mirror_value = (a-b)/2 + b;
 830                                 pitch_shift = mirror_value + (mirror_value - pitch_shift);
 831                         }
 832
 833                         LOG_TRACE("dmg total (dmg): ", ftos(unaccounted_damage), " , pitch shift: ", ftos(pitch_shift), "\n");
 834
 835                         // todo: avoid very long and very short sounds from wave stretching using different sound files? seems unnecessary
 836                         // todo: normalize sound pressure levels? seems unnecessary
 837
 838                         sound7(world, CH_INFO, SND(HIT), VOL_BASE, ATTN_NONE, pitch_shift * 100, 0);
 839                 }
 840                 unaccounted_damage = 0;
 841                 hitsound_time_prev = time;
 842         }
 843
 844         static float typehit_time_prev = 0;
 845         float typehit_time = STAT(TYPEHIT_TIME);
 846         if (COMPARE_INCREASING(typehit_time, typehit_time_prev) > autocvar_cl_hitsound_antispam_time)
 847         {
 848                 sound(world, CH_INFO, SND_TYPEHIT, VOL_BASE, ATTN_NONE);
 849                 typehit_time_prev = typehit_time;
 850         }
 851 }
 852
 853 void HUD_Crosshair()
 854 {SELFPARAM();
 855         static float rainbow_last_flicker;
 856         static vector rainbow_prev_color;
 857         entity e = this;
 858         float f, i, j;
 859         vector v;
 860         if(!scoreboard_active && !camera_active && intermission != 2 &&
 861                 spectatee_status != -1 && !csqcplayer.viewloc &&
 862                 !HUD_MinigameMenu_IsOpened() )
 863         {
 864                 if (!autocvar_crosshair_enabled) // main toggle for crosshair rendering
 865                         return;
 866
 867                 if (hud != HUD_NORMAL)
 868                 {
 869                         HUD_Crosshair_Vehicle();
 870                         return;
 871                 }
 872
 873                 string wcross_style;
 874                 float wcross_alpha, wcross_resolution;
 875                 wcross_style = autocvar_crosshair;
 876                 if (wcross_style == "0")
 877                         return;
 878                 wcross_resolution = autocvar_crosshair_size;
 879                 if (wcross_resolution == 0)
 880                         return;
 881                 wcross_alpha = autocvar_crosshair_alpha;
 882                 if (wcross_alpha == 0)
 883                         return;
 884
 885                 // TrueAim check
 886                 float shottype;
 887
 888                 // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
 889                 wcross_origin = project_3d_to_2d(view_origin + MAX_SHOT_DISTANCE * view_forward);
 890                 wcross_origin.z = 0;
 891                 if(autocvar_crosshair_hittest)
 892                 {
 893                         vector wcross_oldorigin;
 894                         wcross_oldorigin = wcross_origin;
 895                         shottype = TrueAimCheck();
 896                         if(shottype == SHOTTYPE_HITWORLD)
 897                         {
 898                                 v = wcross_origin - wcross_oldorigin;
 899                                 v.x /= vid_conwidth;
 900                                 v.y /= vid_conheight;
 901                                 if(vlen(v) > 0.01)
 902                                         shottype = SHOTTYPE_HITOBSTRUCTION;
 903                         }
 904                         if(!autocvar_crosshair_hittest_showimpact)
 905                                 wcross_origin = wcross_oldorigin;
 906                 }
 907                 else
 908                         shottype = SHOTTYPE_HITWORLD;
 909
 910                 vector wcross_color = '0 0 0', wcross_size = '0 0 0';
 911                 string wcross_name = "";
 912                 float wcross_scale, wcross_blur;
 913
 914                 if(autocvar_crosshair_per_weapon || (autocvar_crosshair_color_special == 1))
 915                 {
 916                         e = switchingweapon;
 917                         if(e)
 918                         {
 919                                 if(autocvar_crosshair_per_weapon)
 920                                 {
 921                                         // WEAPONTODO: access these through some general settings (with non-balance config settings)
 922                                         //wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
 923                                         //if (wcross_resolution == 0)
 924                                                 //return;
 925
 926                                         //wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
 927                                         wcross_resolution *= e.w_crosshair_size;
 928                                         wcross_name = e.w_crosshair;
 929                                 }
 930                         }
 931                 }
 932
 933                 if(wcross_name == "")
 934                         wcross_name = strcat("gfx/crosshair", wcross_style);
 935
 936                 // MAIN CROSSHAIR COLOR DECISION
 937                 switch(autocvar_crosshair_color_special)
 938                 {
 939                         case 1: // crosshair_color_per_weapon
 940                         {
 941                                 if(e)
 942                                 {
 943                                         wcross_color = e.wpcolor;
 944                                         break;
 945                                 }
 946                                 else { goto normalcolor; }
 947                         }
 948
 949                         case 2: // crosshair_color_by_health
 950                         {
 951                                 float x = STAT(HEALTH);
 952
 953                                 //x = red
 954                                 //y = green
 955                                 //z = blue
 956
 957                                 wcross_color.z = 0;
 958
 959                                 if(x > 200)
 960                                 {
 961                                         wcross_color.x = 0;
 962                                         wcross_color.y = 1;
 963                                 }
 964                                 else if(x > 150)
 965                                 {
 966                                         wcross_color.x = 0.4 - (x-150)*0.02 * 0.4;
 967                                         wcross_color.y = 0.9 + (x-150)*0.02 * 0.1;
 968                                 }
 969                                 else if(x > 100)
 970                                 {
 971                                         wcross_color.x = 1 - (x-100)*0.02 * 0.6;
 972                                         wcross_color.y = 1 - (x-100)*0.02 * 0.1;
 973                                         wcross_color.z = 1 - (x-100)*0.02;
 974                                 }
 975                                 else if(x > 50)
 976                                 {
 977                                         wcross_color.x = 1;
 978                                         wcross_color.y = 1;
 979                                         wcross_color.z = 0.2 + (x-50)*0.02 * 0.8;
 980                                 }
 981                                 else if(x > 20)
 982                                 {
 983                                         wcross_color.x = 1;
 984                                         wcross_color.y = (x-20)*90/27/100;
 985                                         wcross_color.z = (x-20)*90/27/100 * 0.2;
 986                                 }
 987                                 else
 988                                 {
 989                                         wcross_color.x = 1;
 990                                         wcross_color.y = 0;
 991                                 }
 992                                 break;
 993                         }
 994
 995                         case 3: // crosshair_color_rainbow
 996                         {
 997                                 if(time >= rainbow_last_flicker)
 998                                 {
 999                                         rainbow_prev_color = randomvec() * autocvar_crosshair_color_special_rainbow_brightness;
1000                                         rainbow_last_flicker = time + autocvar_crosshair_color_special_rainbow_delay;
1001                                 }
1002                                 wcross_color = rainbow_prev_color;
1003                                 break;
1004                         }
1005                         :normalcolor
1006                         default: { wcross_color = stov(autocvar_crosshair_color); break; }
1007                 }
1008
1009                 if(autocvar_crosshair_effect_scalefade)
1010                 {
1011                         wcross_scale = wcross_resolution;
1012                         wcross_resolution = 1;
1013                 }
1014                 else
1015                 {
1016                         wcross_scale = 1;
1017                 }
1018
1019                 if(autocvar_crosshair_pickup)
1020                 {
1021                         float stat_pickup_time = STAT(LAST_PICKUP);
1022
1023                         if(pickup_crosshair_time < stat_pickup_time)
1024                         {
1025                                 if(time - stat_pickup_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1026                                         pickup_crosshair_size = 1;
1027
1028                                 pickup_crosshair_time = stat_pickup_time;
1029                         }
1030
1031                         if(pickup_crosshair_size > 0)
1032                                 pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
1033                         else
1034                                 pickup_crosshair_size = 0;
1035
1036                         wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
1037                 }
1038
1039                 // todo: make crosshair hit indication dependent on damage dealt
1040                 if(autocvar_crosshair_hitindication)
1041                 {
1042                         vector hitindication_color = ((autocvar_crosshair_color_special == 1) ? stov(autocvar_crosshair_hitindication_per_weapon_color) : stov(autocvar_crosshair_hitindication_color));
1043
1044                         if(unaccounted_damage)
1045                         {
1046                                 hitindication_crosshair_size = 1;
1047                         }
1048
1049                         if(hitindication_crosshair_size > 0)
1050                                 hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
1051                         else
1052                                 hitindication_crosshair_size = 0;
1053
1054                         wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
1055                         wcross_color.x += sin(hitindication_crosshair_size) * hitindication_color.x;
1056                         wcross_color.y += sin(hitindication_crosshair_size) * hitindication_color.y;
1057                         wcross_color.z += sin(hitindication_crosshair_size) * hitindication_color.z;
1058                 }
1059
1060                 if(shottype == SHOTTYPE_HITENEMY)
1061                         wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
1062                 if(shottype == SHOTTYPE_HITTEAM)
1063                         wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
1064
1065                 f = fabs(autocvar_crosshair_effect_time);
1066                 if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
1067                 {
1068                         wcross_changedonetime = time + f;
1069                 }
1070                 if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
1071                 {
1072                         wcross_name_changestarttime = time;
1073                         wcross_name_changedonetime = time + f;
1074                         if(wcross_name_goal_prev_prev)
1075                                 strunzone(wcross_name_goal_prev_prev);
1076                         wcross_name_goal_prev_prev = wcross_name_goal_prev;
1077                         wcross_name_goal_prev = strzone(wcross_name);
1078                         wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
1079                         wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
1080                         wcross_resolution_goal_prev = wcross_resolution;
1081                 }
1082
1083                 wcross_scale_goal_prev = wcross_scale;
1084                 wcross_alpha_goal_prev = wcross_alpha;
1085                 wcross_color_goal_prev = wcross_color;
1086
1087                 if(spectatee_status == -1 && shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
1088                 {
1089                         wcross_blur = 1;
1090                         wcross_alpha *= 0.75;
1091                 }
1092                 else
1093                         wcross_blur = 0;
1094                 // *_prev is at time-frametime
1095                 // * is at wcross_changedonetime+f
1096                 // what do we have at time?
1097                 if(time < wcross_changedonetime)
1098                 {
1099                         f = frametime / (wcross_changedonetime - time + frametime);
1100                         wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
1101                         wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
1102                         wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
1103                 }
1104
1105                 wcross_scale_prev = wcross_scale;
1106                 wcross_alpha_prev = wcross_alpha;
1107                 wcross_color_prev = wcross_color;
1108
1109                 MUTATOR_CALLHOOK(UpdateCrosshair);
1110
1111                 wcross_scale *= 1 - autocvar__menu_alpha;
1112                 wcross_alpha *= 1 - autocvar__menu_alpha;
1113                 wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1114
1115                 if(wcross_scale >= 0.001 && wcross_alpha >= 0.001)
1116                 {
1117                         // crosshair rings for weapon stats
1118                         if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
1119                         {
1120                                 // declarations and stats
1121                                 float ring_value = 0, ring_scale = 0, ring_alpha = 0, ring_inner_value = 0, ring_inner_alpha = 0;
1122                                 string ring_image = string_null, ring_inner_image = string_null;
1123                                 vector ring_rgb = '0 0 0', ring_inner_rgb = '0 0 0';
1124
1125                                 ring_scale = autocvar_crosshair_ring_size;
1126
1127                                 float weapon_clipload, weapon_clipsize;
1128                                 weapon_clipload = STAT(WEAPON_CLIPLOAD);
1129                                 weapon_clipsize = STAT(WEAPON_CLIPSIZE);
1130
1131                                 float ok_ammo_charge, ok_ammo_chargepool;
1132                                 ok_ammo_charge = STAT(OK_AMMO_CHARGE);
1133                                 ok_ammo_chargepool = STAT(OK_AMMO_CHARGEPOOL);
1134
1135                                 float vortex_charge, vortex_chargepool;
1136                                 vortex_charge = STAT(VORTEX_CHARGE);
1137                                 vortex_chargepool = STAT(VORTEX_CHARGEPOOL);
1138
1139                                 float arc_heat = STAT(ARC_HEAT);
1140
1141                                 if(vortex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
1142                                         vortex_charge_movingavg = vortex_charge;
1143
1144
1145                                 // handle the values
1146                                 if (autocvar_crosshair_ring && activeweapon == WEP_VORTEX && vortex_charge && autocvar_crosshair_ring_vortex) // ring around crosshair representing velocity-dependent damage for the vortex
1147                                 {
1148                                         if (vortex_chargepool || use_vortex_chargepool) {
1149                                                 use_vortex_chargepool = 1;
1150                                                 ring_inner_value = vortex_chargepool;
1151                                         } else {
1152                                                 vortex_charge_movingavg = (1 - autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate) * vortex_charge_movingavg + autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate * vortex_charge;
1153                                                 ring_inner_value = bound(0, autocvar_crosshair_ring_vortex_currentcharge_scale * (vortex_charge - vortex_charge_movingavg), 1);
1154                                         }
1155
1156                                         ring_inner_alpha = autocvar_crosshair_ring_vortex_inner_alpha;
1157                                         ring_inner_rgb = eX * autocvar_crosshair_ring_vortex_inner_color_red + eY * autocvar_crosshair_ring_vortex_inner_color_green + eZ * autocvar_crosshair_ring_vortex_inner_color_blue;
1158                                         ring_inner_image = "gfx/crosshair_ring_inner.tga";
1159
1160                                         // draw the outer ring to show the current charge of the weapon
1161                                         ring_value = vortex_charge;
1162                                         ring_alpha = autocvar_crosshair_ring_vortex_alpha;
1163                                         ring_rgb = wcross_color;
1164                                         ring_image = "gfx/crosshair_ring_nexgun.tga";
1165                                 }
1166                                 else if (autocvar_crosshair_ring && activeweapon == WEP_MINE_LAYER && WEP_CVAR(minelayer, limit) && autocvar_crosshair_ring_minelayer)
1167                                 {
1168                                         ring_value = bound(0, STAT(LAYED_MINES) / WEP_CVAR(minelayer, limit), 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
1169                                         ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
1170                                         ring_rgb = wcross_color;
1171                                         ring_image = "gfx/crosshair_ring.tga";
1172                                 }
1173                                 else if (activeweapon == WEP_HAGAR && STAT(HAGAR_LOAD) && autocvar_crosshair_ring_hagar)
1174                                 {
1175                                         ring_value = bound(0, STAT(HAGAR_LOAD) / WEP_CVAR_SEC(hagar, load_max), 1);
1176                                         ring_alpha = autocvar_crosshair_ring_hagar_alpha;
1177                                         ring_rgb = wcross_color;
1178                                         ring_image = "gfx/crosshair_ring.tga";
1179                                 }
1180                                 else if (ok_ammo_charge)
1181                                 {
1182                                         ring_value = ok_ammo_chargepool;
1183                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
1184                                         ring_rgb = wcross_color;
1185                                         ring_image = "gfx/crosshair_ring.tga";
1186                                 }
1187                                 else if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
1188                                 {
1189                                         ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
1190                                         ring_scale = autocvar_crosshair_ring_reload_size;
1191                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
1192                                         ring_rgb = wcross_color;
1193
1194                                         // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
1195                                         // if a new image for another weapon is added, add the code (and its respective file/value) here
1196                                         if ((activeweapon == WEP_RIFLE) && (weapon_clipsize == 80))
1197                                                 ring_image = "gfx/crosshair_ring_rifle.tga";
1198                                         else
1199                                                 ring_image = "gfx/crosshair_ring.tga";
1200                                 }
1201                                 else if ( autocvar_crosshair_ring && autocvar_crosshair_ring_arc && arc_heat && activeweapon == WEP_ARC )
1202                                 {
1203                                         ring_value = arc_heat;
1204                                         ring_alpha = (1-arc_heat)*autocvar_crosshair_ring_arc_cold_alpha +
1205                                                 arc_heat*autocvar_crosshair_ring_arc_hot_alpha;
1206                                         ring_rgb = (1-arc_heat)*wcross_color + arc_heat*autocvar_crosshair_ring_arc_hot_color;
1207                                         ring_image = "gfx/crosshair_ring.tga";
1208                                 }
1209
1210                                 // if in weapon switch animation, fade ring out/in
1211                                 if(autocvar_crosshair_effect_time > 0)
1212                                 {
1213                                         f = (time - wcross_name_changestarttime) / autocvar_crosshair_effect_time;
1214                                         if (f >= 1)
1215                                         {
1216                                                 wcross_ring_prev = ((ring_image) ? true : false);
1217                                         }
1218
1219                                         if(wcross_ring_prev)
1220                                         {
1221                                                 if(f < 1)
1222                                                         ring_alpha *= fabs(1 - bound(0, f, 1));
1223                                         }
1224                                         else
1225                                         {
1226                                                 if(f < 1)
1227                                                         ring_alpha *= bound(0, f, 1);
1228                                         }
1229                                 }
1230
1231                                 if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
1232                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
1233
1234                                 if (ring_value)
1235                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
1236                         }
1237
1238 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
1239                         MACRO_BEGIN { \
1240                                 if(wcross_blur > 0) \
1241                                 { \
1242                                         for(i = -2; i <= 2; ++i) \
1243                                         for(j = -2; j <= 2; ++j) \
1244                                         M(i,j,sz,wcross_name,wcross_alpha*0.04); \
1245                                 } \
1246                                 else \
1247                                 { \
1248                                         M(0,0,sz,wcross_name,wcross_alpha); \
1249                                 } \
1250                         } MACRO_END
1251
1252 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
1253                         drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size.x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size.y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
1254
1255 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
1256                         CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
1257
1258                         if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
1259                         {
1260                                 f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
1261                                 wcross_size = draw_getimagesize(wcross_name_goal_prev_prev) * wcross_scale;
1262                                 CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
1263                                 f = 1 - f;
1264                         }
1265                         else
1266                         {
1267                                 f = 1;
1268                         }
1269                         wcross_name_alpha_goal_prev = f;
1270
1271                         wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1272                         CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
1273
1274                         if(autocvar_crosshair_dot)
1275                         {
1276                                 vector wcross_color_old;
1277                                 wcross_color_old = wcross_color;
1278
1279                                 if((autocvar_crosshair_dot_color_custom) && (autocvar_crosshair_dot_color != "0"))
1280                                         wcross_color = stov(autocvar_crosshair_dot_color);
1281
1282                                 CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
1283                                 // FIXME why don't we use wcross_alpha here?
1284                                 wcross_color = wcross_color_old;
1285                         }
1286                 }
1287         }
1288         else
1289         {
1290                 wcross_scale_prev = 0;
1291                 wcross_alpha_prev = 0;
1292                 wcross_scale_goal_prev = 0;
1293                 wcross_alpha_goal_prev = 0;
1294                 wcross_changedonetime = 0;
1295                 if(wcross_name_goal_prev)
1296                         strunzone(wcross_name_goal_prev);
1297                 wcross_name_goal_prev = string_null;
1298                 if(wcross_name_goal_prev_prev)
1299                         strunzone(wcross_name_goal_prev_prev);
1300                 wcross_name_goal_prev_prev = string_null;
1301                 wcross_name_changestarttime = 0;
1302                 wcross_name_changedonetime = 0;
1303                 wcross_name_alpha_goal_prev = 0;
1304                 wcross_name_alpha_goal_prev_prev = 0;
1305                 wcross_resolution_goal_prev = 0;
1306                 wcross_resolution_goal_prev_prev = 0;
1307         }
1308 }
1309
1310 void HUD_Draw()
1311 {
1312         vector rgb = '0 0 0';
1313         float a = 1;
1314         if (MUTATOR_CALLHOOK(HUD_Draw_overlay))
1315         {
1316                 rgb = MUTATOR_ARGV(0, vector);
1317                 a = MUTATOR_ARGV(0, float);
1318         }
1319         else if(STAT(FROZEN))
1320         {
1321                 rgb = ((STAT(REVIVE_PROGRESS)) ? ('0.25 0.90 1' + ('1 0 0' * STAT(REVIVE_PROGRESS)) + ('0 1 1' * STAT(REVIVE_PROGRESS) * -1)) : '0.25 0.90 1');
1322         }
1323         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, rgb, autocvar_hud_colorflash_alpha * a, DRAWFLAG_ADDITIVE);
1324         if(!intermission)
1325         if(STAT(NADE_TIMER) && autocvar_cl_nade_timer) // give nade top priority, as it's a matter of life and death
1326         {
1327                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(NADE_TIMER), '0.25 0.90 1' + ('1 0 0' * STAT(NADE_TIMER)) - ('0 1 1' * STAT(NADE_TIMER)), autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1328                 drawstring_aspect(eY * 0.64 * vid_conheight, ((autocvar_cl_nade_timer == 2) ? _("Nade timer") : ""), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
1329         }
1330         else if(STAT(REVIVE_PROGRESS))
1331         {
1332                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1333                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Revival progress"), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
1334         }
1335
1336         if(autocvar_r_letterbox == 0)
1337                 if(autocvar_viewsize < 120)
1338                 {
1339                         if(!(gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS))
1340                                 Accuracy_LoadLevels();
1341
1342                         HUD_Main();
1343                         HUD_DrawScoreboard();
1344                 }
1345
1346         // crosshair goes VERY LAST
1347         UpdateDamage();
1348         HUD_Crosshair();
1349         HitSound();
1350 }
1351
1352 bool ov_enabled;
1353 float oldr_nearclip;
1354 float oldr_farclip_base;
1355 float oldr_farclip_world;
1356 float oldr_novis;
1357 float oldr_useportalculling;
1358 float oldr_useinfinitefarclip;
1359
1360 void cl_notice_run();
1361 float prev_myteam;
1362 int lasthud;
1363 float vh_notice_time;
1364 void WaypointSprite_Load();
1365 void CSQC_UpdateView(float w, float h)
1366 {SELFPARAM();
1367         entity e;
1368         float fov;
1369         float f;
1370         vector vf_size, vf_min;
1371         float a;
1372
1373         execute_next_frame();
1374
1375         ++framecount;
1376
1377         stats_get();
1378         hud = STAT(HUD);
1379
1380         if(hud != HUD_NORMAL && lasthud == HUD_NORMAL)
1381                 vh_notice_time = time + autocvar_cl_vehicles_notify_time;
1382
1383         lasthud = hud;
1384
1385         if(autocvar__hud_showbinds_reload) // menu can set this one
1386         {
1387                 db_close(binddb);
1388                 binddb = db_create();
1389                 cvar_set("_hud_showbinds_reload", "0");
1390         }
1391
1392         if(checkextension("DP_CSQC_MINFPS_QUALITY"))
1393                 view_quality = getproperty(VF_MINFPS_QUALITY);
1394         else
1395                 view_quality = 1;
1396
1397         button_attack2 = PHYS_INPUT_BUTTON_ATCK2(this);
1398         button_zoom = PHYS_INPUT_BUTTON_ZOOM(this);
1399
1400         vf_size = getpropertyvec(VF_SIZE);
1401         vf_min = getpropertyvec(VF_MIN);
1402         vid_width = vf_size.x;
1403         vid_height = vf_size.y;
1404
1405         vector reticle_pos = '0 0 0', reticle_size = '0 0 0';
1406         vector splash_pos = '0 0 0', splash_size = '0 0 0';
1407
1408         WaypointSprite_Load();
1409
1410         CSQCPlayer_SetCamera();
1411
1412         if(player_localentnum <= maxclients) // is it a client?
1413                 current_player = player_localentnum - 1;
1414         else // then player_localentnum is the vehicle I'm driving
1415                 current_player = player_localnum;
1416         myteam = entcs_GetTeam(current_player);
1417
1418         if(myteam != prev_myteam)
1419         {
1420                 myteamcolors = colormapPaletteColor(myteam, 1);
1421                 FOREACH(hud_panels, true, LAMBDA(it.update_time = time));
1422                 prev_myteam = myteam;
1423         }
1424
1425         ticrate = STAT(MOVEVARS_TICRATE) * STAT(MOVEVARS_TIMESCALE);
1426
1427         float is_dead = (STAT(HEALTH) <= 0);
1428
1429         // FIXME do we need this hack?
1430         if(isdemo())
1431         {
1432                 // in demos, input_buttons do not work
1433                 button_zoom = (autocvar__togglezoom == "-");
1434         }
1435         else if(button_zoom
1436                 && autocvar_cl_unpress_zoom_on_death
1437                 && (spectatee_status >= 0)
1438                 && (is_dead || intermission))
1439         {
1440                 // no zoom while dead or in intermission please
1441                 localcmd("-zoom\n");
1442                 button_zoom = false;
1443         }
1444
1445         // event chase camera
1446         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
1447         {
1448                 float vehicle_chase = (hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0));
1449                 float ons_roundlost = (gametype == MAPINFO_TYPE_ONSLAUGHT && STAT(ROUNDLOST));
1450                 entity gen = world;
1451
1452                 float vehicle_viewdist = 0;
1453                 vector vehicle_viewofs = '0 0 0';
1454
1455                 if(vehicle_chase)
1456                 {
1457                         if(hud != HUD_BUMBLEBEE_GUN)
1458                         {
1459                                 Vehicle info = Vehicles_from(hud);
1460                                 vehicle_viewdist = info.height;
1461                                 vehicle_viewofs = info.view_ofs;
1462                         }
1463                 }
1464
1465                 if(ons_roundlost)
1466                 {
1467                         FOREACH_ENTITY_CLASS("onslaught_generator", it.health <= 0, LAMBDA(
1468                                 gen = it;
1469                                 break;
1470                         ));
1471                         if(!gen)
1472                                 ons_roundlost = false; // don't enforce the 3rd person camera if there is no dead generator to show
1473                 }
1474                 if(WantEventchase(self) || (!autocvar_cl_orthoview && ons_roundlost))
1475                 {
1476                         eventchase_running = true;
1477
1478                         entity local_player = ((csqcplayer) ? csqcplayer : CSQCModel_server2csqc(player_localentnum - 1));
1479                         if(!local_player)
1480                                 local_player = self; // fall back!
1481
1482                         // make special vector since we can't use view_origin (It is one frame old as of this code, it gets set later with the results this code makes.)
1483                         vector current_view_origin = (csqcplayer ? csqcplayer.origin : pmove_org);
1484                         if(ons_roundlost) { current_view_origin = gen.origin; }
1485
1486                         // detect maximum viewoffset and use it
1487                         vector view_offset = autocvar_cl_eventchase_viewoffset;
1488                         if(vehicle_chase)
1489                         {
1490                                 if(vehicle_viewofs)
1491                                         view_offset = vehicle_viewofs;
1492                                 else
1493                                         view_offset = autocvar_cl_eventchase_vehicle_viewoffset;
1494                         }
1495                         if(ons_roundlost) { view_offset = autocvar_cl_eventchase_generator_viewoffset; }
1496
1497                         if(view_offset)
1498                         {
1499                                 WarpZone_TraceLine(current_view_origin, current_view_origin + view_offset + ('0 0 1' * autocvar_cl_eventchase_maxs.z), MOVE_WORLDONLY, self);
1500                                 if(trace_fraction == 1) { current_view_origin += view_offset; }
1501                                 else { current_view_origin.z += max(0, (trace_endpos.z - current_view_origin.z) - autocvar_cl_eventchase_maxs.z); }
1502                         }
1503
1504                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
1505                         // Ideally, there should be another way to enable third person cameras, such as through setproperty()
1506                         // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
1507                         if(!autocvar_chase_active) { cvar_set("chase_active", "-1"); }
1508
1509                         // make the camera smooth back
1510                         float chase_distance = autocvar_cl_eventchase_distance;
1511                         if(vehicle_chase)
1512                         {
1513                                 if(vehicle_viewofs)
1514                                         chase_distance = vehicle_viewdist;
1515                                 else
1516                                         chase_distance = autocvar_cl_eventchase_vehicle_distance;
1517                         }
1518                         if(ons_roundlost) { chase_distance = autocvar_cl_eventchase_generator_distance; }
1519
1520                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < chase_distance)
1521                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (chase_distance - eventchase_current_distance) * frametime; // slow down the further we get
1522                         else if(eventchase_current_distance != chase_distance)
1523                                 eventchase_current_distance = chase_distance;
1524
1525                         makevectors(view_angles);
1526
1527                         vector eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1528                         WarpZone_TraceBox(current_view_origin, autocvar_cl_eventchase_mins, autocvar_cl_eventchase_maxs, eventchase_target_origin, MOVE_WORLDONLY, self);
1529
1530                         // If the boxtrace fails, revert back to line tracing.
1531                         if(!local_player.viewloc)
1532                         if(trace_startsolid)
1533                         {
1534                                 eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1535                                 WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, self);
1536                                 setproperty(VF_ORIGIN, (trace_endpos - (v_forward * autocvar_cl_eventchase_mins.z)));
1537                         }
1538                         else { setproperty(VF_ORIGIN, trace_endpos); }
1539
1540                         if(!local_player.viewloc)
1541                                 setproperty(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
1542                 }
1543                 else if(autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
1544                 {
1545                         eventchase_running = false;
1546                         cvar_set("chase_active", "0");
1547                         eventchase_current_distance = 0; // start from 0 next time
1548                 }
1549         }
1550         // workaround for camera stuck between player's legs when using chase_active 1
1551         // because the engine stops updating the chase_active camera when the game ends
1552         else if(intermission)
1553         {
1554                 cvar_settemp("chase_active", "-1");
1555                 eventchase_current_distance = 0;
1556         }
1557
1558         // do lockview after event chase camera so that it still applies whenever necessary.
1559         if(autocvar_cl_lockview || (!autocvar_hud_cursormode && (autocvar__hud_configure && spectatee_status <= 0 || intermission > 1 || QuickMenu_IsOpened())))
1560         {
1561                 setproperty(VF_ORIGIN, freeze_org);
1562                 setproperty(VF_ANGLES, freeze_ang);
1563         }
1564         else
1565         {
1566                 freeze_org = getpropertyvec(VF_ORIGIN);
1567                 freeze_ang = getpropertyvec(VF_ANGLES);
1568         }
1569
1570         WarpZone_FixView();
1571         //WarpZone_FixPMove();
1572
1573         vector ov_org = '0 0 0';
1574         vector ov_mid = '0 0 0';
1575         vector ov_worldmin = '0 0 0';
1576         vector ov_worldmax = '0 0 0';
1577         if(autocvar_cl_orthoview)
1578         {
1579                 ov_worldmin = mi_picmin;
1580                 ov_worldmax = mi_picmax;
1581
1582                 float ov_width = (ov_worldmax.x - ov_worldmin.x);
1583                 float ov_height = (ov_worldmax.y - ov_worldmin.y);
1584                 float ov_distance = (max(vid_width, vid_height) * max(ov_width, ov_height));
1585
1586                 ov_mid = ((ov_worldmax + ov_worldmin) * 0.5);
1587                 ov_org = vec3(ov_mid.x, ov_mid.y, (ov_mid.z + ov_distance));
1588
1589                 float ov_nearest = vlen(ov_org - vec3(
1590                         bound(ov_worldmin.x, ov_org.x, ov_worldmax.x),
1591                         bound(ov_worldmin.y, ov_org.y, ov_worldmax.y),
1592                         bound(ov_worldmin.z, ov_org.z, ov_worldmax.z)
1593                 ));
1594
1595                 float ov_furthest = 0;
1596                 float dist = 0;
1597
1598                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1599                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1600                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1601                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1602                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1603                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1604                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1605                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1606
1607                 if(!ov_enabled)
1608                 {
1609                         oldr_nearclip = cvar("r_nearclip");
1610                         oldr_farclip_base = cvar("r_farclip_base");
1611                         oldr_farclip_world = cvar("r_farclip_world");
1612                         oldr_novis = cvar("r_novis");
1613                         oldr_useportalculling = cvar("r_useportalculling");
1614                         oldr_useinfinitefarclip = cvar("r_useinfinitefarclip");
1615                 }
1616
1617                 cvar_settemp("r_nearclip", ftos(ov_nearest));
1618                 cvar_settemp("r_farclip_base", ftos(ov_furthest));
1619                 cvar_settemp("r_farclip_world", "0");
1620                 cvar_settemp("r_novis", "1");
1621                 cvar_settemp("r_useportalculling", "0");
1622                 cvar_settemp("r_useinfinitefarclip", "0");
1623
1624                 setproperty(VF_ORIGIN, ov_org);
1625                 setproperty(VF_ANGLES, '90 0 0');
1626
1627                 ov_enabled = true;
1628
1629                 #if 0
1630                 LOG_INFOF("OrthoView: org = %s, angles = %s, distance = %f, nearest = %f, furthest = %f\n",
1631                         vtos(ov_org),
1632                         vtos(getpropertyvec(VF_ANGLES)),
1633                         ov_distance,
1634                         ov_nearest,
1635                         ov_furthest);
1636                 #endif
1637         }
1638         else
1639         {
1640                 if(ov_enabled)
1641                 {
1642                         cvar_set("r_nearclip", ftos(oldr_nearclip));
1643                         cvar_set("r_farclip_base", ftos(oldr_farclip_base));
1644                         cvar_set("r_farclip_world", ftos(oldr_farclip_world));
1645                         cvar_set("r_novis", ftos(oldr_novis));
1646                         cvar_set("r_useportalculling", ftos(oldr_useportalculling));
1647                         cvar_set("r_useinfinitefarclip", ftos(oldr_useinfinitefarclip));
1648                 }
1649                 ov_enabled = false;
1650         }
1651
1652         // Render the Scene
1653         view_origin = getpropertyvec(VF_ORIGIN);
1654         view_angles = getpropertyvec(VF_ANGLES);
1655         makevectors(view_angles);
1656         view_forward = v_forward;
1657         view_right = v_right;
1658         view_up = v_up;
1659
1660 #ifdef BLURTEST
1661         if(time > blurtest_time0 && time < blurtest_time1)
1662         {
1663                 float r, t;
1664
1665                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
1666                 r = t * blurtest_radius;
1667                 f = 1 / pow(t, blurtest_power) - 1;
1668
1669                 cvar_set("r_glsl_postprocess", "1");
1670                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
1671         }
1672         else
1673         {
1674                 cvar_set("r_glsl_postprocess", "0");
1675                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
1676         }
1677 #endif
1678
1679         TargetMusic_Advance();
1680         Fog_Force();
1681
1682         if(drawtime == 0)
1683                 drawframetime = 0.01666667; // when we don't know fps yet, we assume 60fps
1684         else
1685                 drawframetime = bound(0.000001, time - drawtime, 1);
1686         drawtime = time;
1687
1688         // watch for gametype changes here...
1689         // in ParseStuffCMD the cmd isn't executed yet :/
1690         // might even be better to add the gametype to TE_CSQC_INIT...?
1691         if(!postinit)
1692                 PostInit();
1693
1694         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
1695         {
1696                 if(calledhooks & HOOK_START)
1697                 {
1698                         localcmd("\ncl_hook_gameend\n");
1699                         calledhooks |= HOOK_END;
1700                 }
1701         }
1702
1703         Announcer();
1704
1705         fov = autocvar_fov;
1706         if(fov <= 59.5)
1707         {
1708                 if(!zoomscript_caught)
1709                 {
1710                         localcmd("+button9\n");
1711                         zoomscript_caught = 1;
1712                 }
1713         }
1714         else
1715         {
1716                 if(zoomscript_caught)
1717                 {
1718                         localcmd("-button9\n");
1719                         zoomscript_caught = 0;
1720                 }
1721         }
1722
1723         ColorTranslateMode = autocvar_cl_stripcolorcodes;
1724
1725         // currently switching-to weapon (for crosshair)
1726         switchingweapon = Weapons_from(STAT(SWITCHINGWEAPON));
1727
1728         // actually active weapon (for zoom)
1729         activeweapon = Weapons_from(STAT(ACTIVEWEAPON));
1730
1731         switchweapon = Weapons_from(STAT(SWITCHWEAPON));
1732
1733         f = (serverflags & SERVERFLAG_TEAMPLAY);
1734         if(f != teamplay)
1735         {
1736                 teamplay = f;
1737                 HUD_InitScores();
1738         }
1739
1740         if(last_switchweapon != switchweapon)
1741         {
1742                 weapontime = time;
1743                 last_switchweapon = switchweapon;
1744                 if(button_zoom && autocvar_cl_unpress_zoom_on_weapon_switch)
1745                 {
1746                         localcmd("-zoom\n");
1747                         button_zoom = false;
1748                 }
1749                 if(autocvar_cl_unpress_attack_on_weapon_switch)
1750                 {
1751                         localcmd("-fire\n");
1752                         localcmd("-fire2\n");
1753                         button_attack2 = false;
1754                 }
1755         }
1756         if(last_activeweapon != activeweapon)
1757         {
1758                 last_activeweapon = activeweapon;
1759
1760                 e = activeweapon;
1761                 if(e.netname != "")
1762                         localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
1763                 else
1764                         localcmd("\ncl_hook_activeweapon none\n");
1765         }
1766
1767         // ALWAYS Clear Current Scene First
1768         clearscene();
1769
1770         setproperty(VF_ORIGIN, view_origin);
1771         setproperty(VF_ANGLES, view_angles);
1772
1773         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
1774         setproperty(VF_SIZE, vf_size);
1775         setproperty(VF_MIN, vf_min);
1776
1777         // Assign Standard Viewflags
1778         // Draw the World (and sky)
1779         setproperty(VF_DRAWWORLD, 1);
1780
1781         // Set the console size vars
1782         vid_conwidth = autocvar_vid_conwidth;
1783         vid_conheight = autocvar_vid_conheight;
1784         vid_pixelheight = autocvar_vid_pixelheight;
1785
1786         if(autocvar_cl_orthoview) { setproperty(VF_FOV, GetOrthoviewFOV(ov_worldmin, ov_worldmax, ov_mid, ov_org)); }
1787         else if(csqcplayer.viewloc) { setproperty(VF_FOV, GetViewLocationFOV(110)); } // enforce 110 fov, so things dont look odd
1788         else { setproperty(VF_FOV, GetCurrentFov(fov)); }
1789
1790         // Camera for demo playback
1791         if(camera_active)
1792         {
1793                 if(autocvar_camera_enable)
1794                         CSQC_Demo_Camera();
1795                 else
1796                 {
1797                         cvar_set("chase_active", ftos(chase_active_backup));
1798                         cvar_set("cl_demo_mousegrab", "0");
1799                         camera_active = false;
1800                 }
1801         }
1802         else
1803         {
1804 #ifdef CAMERATEST
1805                 if(autocvar_camera_enable)
1806 #else
1807                 if(autocvar_camera_enable && isdemo())
1808 #endif
1809                 {
1810                         // Enable required Darkplaces cvars
1811                         chase_active_backup = autocvar_chase_active;
1812                         cvar_set("chase_active", "2");
1813                         cvar_set("cl_demo_mousegrab", "1");
1814                         camera_active = true;
1815                         camera_mode = false;
1816                 }
1817         }
1818
1819         // Draw the Crosshair
1820         setproperty(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
1821
1822         // Draw the Engine Status Bar (the default Quake HUD)
1823         setproperty(VF_DRAWENGINESBAR, 0);
1824
1825         // Update the mouse position
1826         /*
1827            mousepos_x = vid_conwidth;
1828            mousepos_y = vid_conheight;
1829            mousepos = mousepos*0.5 + getmousepos();
1830          */
1831
1832         FOREACH_ENTITY(it.draw, LAMBDA(it.draw(it)));
1833
1834         addentities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
1835         renderscene();
1836
1837         // now switch to 2D drawing mode by calling a 2D drawing function
1838         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
1839         // next R_RenderScene call
1840         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
1841
1842         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
1843         if (!(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT))
1844         {
1845                 // apply night vision effect
1846                 vector tc_00, tc_01, tc_10, tc_11;
1847                 vector rgb = '0 0 0';
1848
1849                 if(!nightvision_noise)
1850                 {
1851                         nightvision_noise = new(nightvision_noise);
1852                 }
1853                 if(!nightvision_noise2)
1854                 {
1855                         nightvision_noise2 = new(nightvision_noise2);
1856                 }
1857
1858                 // color tint in yellow
1859                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
1860
1861                 // draw BG
1862                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
1863                 rgb = '1 1 1';
1864                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
1865                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
1866                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
1867                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
1868                 tc_11 = tc_01 + tc_10 - tc_00;
1869                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
1870                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
1871                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
1872                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
1873                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
1874                 R_EndPolygon();
1875
1876                 // draw FG
1877                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
1878                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
1879                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
1880                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
1881                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
1882                 tc_11 = tc_01 + tc_10 - tc_00;
1883                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
1884                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
1885                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
1886                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
1887                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
1888                 R_EndPolygon();
1889         }
1890
1891         if(autocvar_cl_reticle)
1892         {
1893                 Weapon wep = activeweapon;
1894                 // Draw the aiming reticle for weapons that use it
1895                 // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
1896                 // It must be a persisted float for fading out to work properly (you let go of the zoom button for
1897                 // the view to go back to normal, so reticle_type would become 0 as we fade out)
1898                 if(spectatee_status || is_dead || hud != HUD_NORMAL)
1899                 {
1900                         // no zoom reticle while dead
1901                         reticle_type = 0;
1902                 }
1903                 else if(wep.wr_zoomreticle(wep) && autocvar_cl_reticle_weapon)
1904                 {
1905                         if(reticle_image != "") { reticle_type = 2; }
1906                         else { reticle_type = 0; }
1907                 }
1908                 else if(button_zoom || zoomscript_caught)
1909                 {
1910                         // normal zoom
1911                         reticle_type = 1;
1912                 }
1913
1914                 if(reticle_type)
1915                 {
1916                         if(autocvar_cl_reticle_stretch)
1917                         {
1918                                 reticle_size.x = vid_conwidth;
1919                                 reticle_size.y = vid_conheight;
1920                                 reticle_pos.x = 0;
1921                                 reticle_pos.y = 0;
1922                         }
1923                         else
1924                         {
1925                                 reticle_size.x = max(vid_conwidth, vid_conheight);
1926                                 reticle_size.y = max(vid_conwidth, vid_conheight);
1927                                 reticle_pos.x = (vid_conwidth - reticle_size.x) / 2;
1928                                 reticle_pos.y = (vid_conheight - reticle_size.y) / 2;
1929                         }
1930
1931                         if(zoomscript_caught)
1932                                 f = 1;
1933                         else
1934                                 f = current_zoomfraction;
1935
1936                         if(f)
1937                         {
1938                                 switch(reticle_type)
1939                                 {
1940                                         case 1: drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_normal_alpha, DRAWFLAG_NORMAL); break;
1941                                         case 2: drawpic(reticle_pos, reticle_image, reticle_size, '1 1 1', f * autocvar_cl_reticle_weapon_alpha, DRAWFLAG_NORMAL); break;
1942                                 }
1943                         }
1944                 }
1945         }
1946         else
1947         {
1948                 if(reticle_type != 0) { reticle_type = 0; }
1949         }
1950
1951
1952         // improved polyblend
1953         if(autocvar_hud_contents)
1954         {
1955                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
1956                 vector liquidcolor;
1957
1958                 switch(pointcontents(view_origin))
1959                 {
1960                         case CONTENT_WATER:
1961                                 liquidalpha = autocvar_hud_contents_water_alpha;
1962                                 liquidcolor = stov(autocvar_hud_contents_water_color);
1963                                 incontent = 1;
1964                                 break;
1965
1966                         case CONTENT_LAVA:
1967                                 liquidalpha = autocvar_hud_contents_lava_alpha;
1968                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
1969                                 incontent = 1;
1970                                 break;
1971
1972                         case CONTENT_SLIME:
1973                                 liquidalpha = autocvar_hud_contents_slime_alpha;
1974                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
1975                                 incontent = 1;
1976                                 break;
1977
1978                         default:
1979                                 liquidalpha = 0;
1980                                 liquidcolor = '0 0 0';
1981                                 incontent = 0;
1982                                 break;
1983                 }
1984
1985                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
1986                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
1987                         contentfadetime = autocvar_hud_contents_fadeintime;
1988                         liquidalpha_prev = liquidalpha;
1989                         liquidcolor_prev = liquidcolor;
1990                 }
1991                 else
1992                         contentfadetime = autocvar_hud_contents_fadeouttime;
1993
1994                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
1995                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
1996
1997                 if(contentavgalpha)
1998                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
1999
2000                 if(autocvar_hud_postprocessing)
2001                 {
2002                         if(autocvar_hud_contents_blur && contentavgalpha)
2003                         {
2004                                 content_blurpostprocess.x = 1;
2005                                 content_blurpostprocess.y = contentavgalpha * autocvar_hud_contents_blur;
2006                                 content_blurpostprocess.z = contentavgalpha * autocvar_hud_contents_blur_alpha;
2007                         }
2008                         else
2009                         {
2010                                 content_blurpostprocess.x = 0;
2011                                 content_blurpostprocess.y = 0;
2012                                 content_blurpostprocess.z = 0;
2013                         }
2014                 }
2015         }
2016
2017         if(autocvar_hud_damage && !STAT(FROZEN))
2018         {
2019                 splash_size.x = max(vid_conwidth, vid_conheight);
2020                 splash_size.y = max(vid_conwidth, vid_conheight);
2021                 splash_pos.x = (vid_conwidth - splash_size.x) / 2;
2022                 splash_pos.y = (vid_conheight - splash_size.y) / 2;
2023
2024                 float myhealth_flash_temp;
2025                 myhealth = STAT(HEALTH);
2026
2027                 // fade out
2028                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
2029                 // add new damage
2030                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
2031
2032                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
2033                 pain_threshold = autocvar_hud_damage_pain_threshold;
2034                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
2035                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
2036
2037                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
2038                 {
2039                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
2040                 }
2041
2042                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
2043
2044                 if(myhealth_prev < 1)
2045                 {
2046                         if(myhealth >= 1)
2047                         {
2048                                 myhealth_flash = 0; // just spawned, clear the flash immediately
2049                                 myhealth_flash_temp = 0;
2050                         }
2051                         else
2052                         {
2053                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
2054                         }
2055                 }
2056
2057                 if(spectatee_status == -1 || intermission)
2058                 {
2059                         myhealth_flash = 0; // observing, or match ended
2060                         myhealth_flash_temp = 0;
2061                 }
2062
2063                 myhealth_prev = myhealth;
2064
2065                 // IDEA: change damage color/picture based on player model for robot/alien species?
2066                 // pro: matches model better
2067                 // contra: it's not red because blood is red, but because red is an alarming color, so red should stay
2068                 // maybe different reddish pics?
2069                 if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
2070                 {
2071                         if(autocvar_cl_gentle_damage == 2)
2072                         {
2073                                 if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
2074                                         myhealth_gentlergb = eX * random() + eY * random() + eZ * random();
2075                         }
2076                         else
2077                                 myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
2078
2079                         if(myhealth_flash_temp > 0)
2080                                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
2081                 }
2082                 else if(myhealth_flash_temp > 0)
2083                         drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
2084
2085                 if(autocvar_hud_postprocessing) // we still need to set this anyway even when chase_active is set, this way it doesn't get stuck on.
2086                 {
2087                         if(autocvar_hud_damage_blur && myhealth_flash_temp)
2088                         {
2089                                 damage_blurpostprocess.x = 1;
2090                                 damage_blurpostprocess.y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
2091                                 damage_blurpostprocess.z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
2092                         }
2093                         else
2094                         {
2095                                 damage_blurpostprocess.x = 0;
2096                                 damage_blurpostprocess.y = 0;
2097                                 damage_blurpostprocess.z = 0;
2098                         }
2099                 }
2100         }
2101
2102         float e1 = (autocvar_hud_postprocessing_maxbluralpha != 0);
2103         float e2 = (autocvar_hud_powerup != 0);
2104         if(autocvar_hud_postprocessing && (e1 || e2)) // TODO: Remove this code and re-do the postprocess handling in the engine, where it properly belongs.
2105         {
2106                 // enable or disable rendering types if they are used or not
2107                 if(cvar("r_glsl_postprocess_uservec1_enable") != e1) { cvar_set("r_glsl_postprocess_uservec1_enable", ftos(e1)); }
2108                 if(cvar("r_glsl_postprocess_uservec2_enable") != e2) { cvar_set("r_glsl_postprocess_uservec2_enable", ftos(e2)); }
2109
2110                 // blur postprocess handling done first (used by hud_damage and hud_contents)
2111                 if((damage_blurpostprocess.x || content_blurpostprocess.x))
2112                 {
2113                         float blurradius = bound(0, damage_blurpostprocess.y + content_blurpostprocess.y, autocvar_hud_postprocessing_maxblurradius);
2114                         float bluralpha = bound(0, damage_blurpostprocess.z + content_blurpostprocess.z, autocvar_hud_postprocessing_maxbluralpha);
2115                         if(blurradius != old_blurradius || bluralpha != old_bluralpha) // reduce cvar_set spam as much as possible
2116                         {
2117                                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
2118                                 old_blurradius = blurradius;
2119                                 old_bluralpha = bluralpha;
2120                         }
2121                 }
2122                 else if(cvar_string("r_glsl_postprocess_uservec1") != "0 0 0 0") // reduce cvar_set spam as much as possible
2123                 {
2124                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
2125                         old_blurradius = 0;
2126                         old_bluralpha = 0;
2127                 }
2128
2129                 // edge detection postprocess handling done second (used by hud_powerup)
2130                 float sharpen_intensity = 0, strength_finished = STAT(STRENGTH_FINISHED), invincible_finished = STAT(INVINCIBLE_FINISHED);
2131                 if (strength_finished - time > 0) { sharpen_intensity += (strength_finished - time); }
2132                 if (invincible_finished - time > 0) { sharpen_intensity += (invincible_finished - time); }
2133
2134                 sharpen_intensity = bound(0, ((STAT(HEALTH) > 0) ? sharpen_intensity : 0), 5); // Check to see if player is alive (if not, set 0) - also bound to fade out starting at 5 seconds.
2135
2136                 if(autocvar_hud_powerup && sharpen_intensity > 0)
2137                 {
2138                         if(sharpen_intensity != old_sharpen_intensity) // reduce cvar_set spam as much as possible
2139                         {
2140                                 cvar_set("r_glsl_postprocess_uservec2", strcat(ftos((sharpen_intensity / 5) * autocvar_hud_powerup), " ", ftos(-sharpen_intensity * autocvar_hud_powerup), " 0 0"));
2141                                 old_sharpen_intensity = sharpen_intensity;
2142                         }
2143                 }
2144                 else if(cvar_string("r_glsl_postprocess_uservec2") != "0 0 0 0") // reduce cvar_set spam as much as possible
2145                 {
2146                         cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
2147                         old_sharpen_intensity = 0;
2148                 }
2149
2150                 if(cvar("r_glsl_postprocess") == 0)
2151                         cvar_set("r_glsl_postprocess", "2");
2152         }
2153         else if(cvar("r_glsl_postprocess") == 2)
2154                 cvar_set("r_glsl_postprocess", "0");
2155
2156         /*if(gametype == MAPINFO_TYPE_CTF)
2157           {
2158           ctf_view();
2159           } else */
2160
2161         // draw 2D entities
2162         FOREACH_ENTITY(it.draw2d, LAMBDA(it.draw2d(it)));
2163         Draw_ShowNames_All();
2164         Debug_Draw();
2165
2166         scoreboard_active = HUD_WouldDrawScoreboard();
2167
2168         HUD_Draw();
2169
2170         if(NextFrameCommand)
2171         {
2172                 localcmd("\n", NextFrameCommand, "\n");
2173                 NextFrameCommand = string_null;
2174         }
2175
2176         // we must do this check AFTER a frame was rendered, or it won't work
2177         if(cs_project_is_b0rked == 0)
2178         {
2179                 string w0, h0;
2180                 w0 = ftos(autocvar_vid_conwidth);
2181                 h0 = ftos(autocvar_vid_conheight);
2182                 //setproperty(VF_VIEWPORT, '0 0 0', '640 480 0');
2183                 //setproperty(VF_FOV, '90 90 0');
2184                 setproperty(VF_ORIGIN, '0 0 0');
2185                 setproperty(VF_ANGLES, '0 0 0');
2186                 setproperty(VF_PERSPECTIVE, 1);
2187                 makevectors('0 0 0');
2188                 vector v1, v2;
2189                 cvar_set("vid_conwidth", "800");
2190                 cvar_set("vid_conheight", "600");
2191                 v1 = cs_project(v_forward);
2192                 cvar_set("vid_conwidth", "640");
2193                 cvar_set("vid_conheight", "480");
2194                 v2 = cs_project(v_forward);
2195                 if(v1 == v2)
2196                         cs_project_is_b0rked = 1;
2197                 else
2198                         cs_project_is_b0rked = -1;
2199                 cvar_set("vid_conwidth", w0);
2200                 cvar_set("vid_conheight", h0);
2201         }
2202
2203         if(autocvar__hud_configure)
2204                 HUD_Panel_Mouse();
2205         else if ( HUD_MinigameMenu_IsOpened() || minigame_isactive() )
2206                 HUD_Minigame_Mouse();
2207         else if(QuickMenu_IsOpened())
2208                 QuickMenu_Mouse();
2209         else
2210                 HUD_Radar_Mouse();
2211
2212         cl_notice_run();
2213         unpause_update();
2214         Net_Flush();
2215
2216         // let's reset the view back to normal for the end
2217         setproperty(VF_MIN, '0 0 0');
2218         setproperty(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
2219 }
2220
2221
2222 // following vectors must be global to allow seamless switching between camera modes
2223 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
2224 void CSQC_Demo_Camera()
2225 {
2226         float speed, attenuation, dimensions;
2227         vector tmp, delta;
2228
2229         if( autocvar_camera_reset || !camera_mode )
2230         {
2231                 camera_offset = '0 0 0';
2232                 current_angles = '0 0 0';
2233                 camera_direction = '0 0 0';
2234                 camera_offset.z += 30;
2235                 camera_offset.x += 30 * -cos(current_angles.y * DEG2RAD);
2236                 camera_offset.y += 30 * -sin(current_angles.y * DEG2RAD);
2237                 current_origin = view_origin;
2238                 current_camera_offset  = camera_offset;
2239                 cvar_set("camera_reset", "0");
2240                 camera_mode = CAMERA_CHASE;
2241         }
2242
2243         // Camera angles
2244         if( camera_roll )
2245                 mouse_angles.z += camera_roll * autocvar_camera_speed_roll;
2246
2247         if(autocvar_camera_look_player)
2248         {
2249                 vector dir;
2250                 float n;
2251
2252                 dir = normalize(view_origin - current_position);
2253                 n = mouse_angles.z;
2254                 mouse_angles = vectoangles(dir);
2255                 mouse_angles.x = mouse_angles.x * -1;
2256                 mouse_angles.z = n;
2257         }
2258         else
2259         {
2260                 tmp = getmousepos() * 0.1;
2261                 if(vdist(tmp, >, autocvar_camera_mouse_threshold))
2262                 {
2263                         mouse_angles.x += tmp.y * cos(mouse_angles.z * DEG2RAD) + (tmp.x * sin(mouse_angles.z * DEG2RAD));
2264                         mouse_angles.y -= tmp.x * cos(mouse_angles.z * DEG2RAD) + (tmp.y * -sin(mouse_angles.z * DEG2RAD));
2265                 }
2266         }
2267
2268         while (mouse_angles.x < -180) mouse_angles.x = mouse_angles.x + 360;
2269         while (mouse_angles.x > 180) mouse_angles.x = mouse_angles.x - 360;
2270         while (mouse_angles.y < -180) mouse_angles.y = mouse_angles.y + 360;
2271         while (mouse_angles.y > 180) mouse_angles.y = mouse_angles.y - 360;
2272
2273         // Fix difference when angles don't have the same sign
2274         delta = '0 0 0';
2275         if(mouse_angles.y < -60 && current_angles.y > 60)
2276                 delta = '0 360 0';
2277         if(mouse_angles.y > 60 && current_angles.y < -60)
2278                 delta = '0 -360 0';
2279
2280         if(autocvar_camera_look_player)
2281                 attenuation = autocvar_camera_look_attenuation;
2282         else
2283                 attenuation = autocvar_camera_speed_attenuation;
2284
2285         attenuation = 1 / max(1, attenuation);
2286         current_angles += (mouse_angles - current_angles + delta) * attenuation;
2287
2288         while (current_angles.x < -180) current_angles.x = current_angles.x + 360;
2289         while (current_angles.x > 180) current_angles.x = current_angles.x - 360;
2290         while (current_angles.y < -180) current_angles.y = current_angles.y + 360;
2291         while (current_angles.y > 180) current_angles.y = current_angles.y - 360;
2292
2293         // Camera position
2294         tmp = '0 0 0';
2295         dimensions = 0;
2296
2297         if( camera_direction.x )
2298         {
2299                 tmp.x = camera_direction.x * cos(current_angles.y * DEG2RAD);
2300                 tmp.y = camera_direction.x * sin(current_angles.y * DEG2RAD);
2301                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
2302                         tmp.z = camera_direction.x * -sin(current_angles.x * DEG2RAD);
2303                 ++dimensions;
2304         }
2305
2306         if( camera_direction.y )
2307         {
2308                 tmp.x += camera_direction.y * -sin(current_angles.y * DEG2RAD);
2309                 tmp.y += camera_direction.y * cos(current_angles.y * DEG2RAD) * cos(current_angles.z * DEG2RAD);
2310                 tmp.z += camera_direction.y * sin(current_angles.z * DEG2RAD);
2311                 ++dimensions;
2312         }
2313
2314         if( camera_direction.z )
2315         {
2316                 tmp.z += camera_direction.z * cos(current_angles.z * DEG2RAD);
2317                 ++dimensions;
2318         }
2319
2320         if(autocvar_camera_free)
2321                 speed = autocvar_camera_speed_free;
2322         else
2323                 speed = autocvar_camera_speed_chase;
2324
2325         if(dimensions)
2326         {
2327                 speed = speed * sqrt(1 / dimensions);
2328                 camera_offset += tmp * speed;
2329         }
2330
2331         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
2332
2333         // Camera modes
2334         if( autocvar_camera_free )
2335         {
2336                 if ( camera_mode == CAMERA_CHASE )
2337                 {
2338                         current_camera_offset = current_origin + current_camera_offset;
2339                         camera_offset = current_origin + camera_offset;
2340                 }
2341
2342                 camera_mode = CAMERA_FREE;
2343                 current_position = current_camera_offset;
2344         }
2345         else
2346         {
2347                 if ( camera_mode == CAMERA_FREE )
2348                 {
2349                         current_origin = view_origin;
2350                         camera_offset = camera_offset - current_origin;
2351                         current_camera_offset = current_camera_offset - current_origin;
2352                 }
2353
2354                 camera_mode = CAMERA_CHASE;
2355
2356                 if(autocvar_camera_chase_smoothly)
2357                         current_origin += (view_origin - current_origin) * attenuation;
2358                 else
2359                         current_origin = view_origin;
2360
2361                 current_position = current_origin + current_camera_offset;
2362         }
2363
2364         setproperty(VF_ANGLES, current_angles);
2365         setproperty(VF_ORIGIN, current_position);
2366 }