qcsrc/client/view.qc

   1 #include "view.qh"
   2
   3 #include "autocvars.qh"
   4 #include "miscfunctions.qh"
   5 #include "announcer.qh"
   6 #include "hud/_mod.qh"
   7 #include "main.qh"
   8 #include "mapvoting.qh"
   9 #include "shownames.qh"
  10 #include "hud/panel/scoreboard.qh"
  11 #include "hud/panel/quickmenu.qh"
  12
  13 #include <client/mutators/_mod.qh>
  14
  15 #include <common/animdecide.qh>
  16 #include <common/deathtypes/all.qh>
  17 #include <common/ent_cs.qh>
  18 #include <common/anim.qh>
  19 #include <common/constants.qh>
  20 #include <common/net_linked.qh>
  21 #include <common/net_notice.qh>
  22 #include <common/debug.qh>
  23 #include <common/mapinfo.qh>
  24 #include <common/gamemodes/_mod.qh>
  25 #include <common/physics/player.qh>
  26 #include <common/stats.qh>
  27 #include <common/mapobjects/target/music.qh>
  28 #include <common/teams.qh>
  29 #include <common/wepent.qh>
  30
  31 #include <common/weapons/weapon/tuba.qh>
  32
  33 #include <common/vehicles/all.qh>
  34 #include <common/weapons/_all.qh>
  35 #include <common/mutators/mutator/waypoints/all.qh>
  36 #include <common/viewloc.qh>
  37 #include <common/mapobjects/trigger/viewloc.qh>
  38 #include <common/minigames/cl_minigames.qh>
  39 #include <common/minigames/cl_minigames_hud.qh>
  40
  41 #include <lib/csqcmodel/cl_player.qh>
  42 #include <lib/csqcmodel/cl_model.qh>
  43 #include "csqcmodel_hooks.qh"
  44
  45 #include <lib/warpzone/client.qh>
  46 #include <lib/warpzone/common.qh>
  47
  48 float autocvar_cl_viewmodel_scale;
  49 float autocvar_cl_viewmodel_alpha = 1;
  50
  51 bool autocvar_cl_bobmodel;
  52 float autocvar_cl_bobmodel_speed;
  53 float autocvar_cl_bobmodel_side;
  54 float autocvar_cl_bobmodel_up;
  55
  56 float autocvar_cl_followmodel;
  57 float autocvar_cl_followmodel_speed = 0.3;
  58 float autocvar_cl_followmodel_limit = 135;
  59 float autocvar_cl_followmodel_velocity_lowpass = 0.05;
  60 float autocvar_cl_followmodel_highpass = 0.05;
  61 float autocvar_cl_followmodel_lowpass = 0.03;
  62 bool autocvar_cl_followmodel_velocity_absolute;
  63
  64 float autocvar_cl_leanmodel;
  65 float autocvar_cl_leanmodel_speed = 0.3;
  66 float autocvar_cl_leanmodel_limit = 30;
  67 float autocvar_cl_leanmodel_highpass1 = 0.2;
  68 float autocvar_cl_leanmodel_highpass = 0.2;
  69 float autocvar_cl_leanmodel_lowpass = 0.05;
  70
  71 #define avg_factor(avg_time) (1 - exp(-frametime / max(0.001, avg_time)))
  72
  73 #define lowpass(value, frac, ref_store, ret) \
  74         ret = ref_store = ref_store * (1 - frac) + (value) * frac;
  75
  76 #define lowpass_limited(value, frac, limit, ref_store, ret) MACRO_BEGIN \
  77         float __ignore; lowpass(value, frac, ref_store, __ignore); \
  78         ret = ref_store = bound((value) - (limit), ref_store, (value) + (limit)); \
  79 MACRO_END
  80
  81 #define highpass(value, frac, ref_store, ret) MACRO_BEGIN \
  82         float __f = 0; lowpass(value, frac, ref_store, __f); \
  83         ret = (value) - __f; \
  84 MACRO_END
  85
  86 #define highpass_limited(value, frac, limit, ref_store, ret) MACRO_BEGIN \
  87         float __f = 0; lowpass_limited(value, frac, limit, ref_store, __f); \
  88         ret = (value) - __f; \
  89 MACRO_END
  90
  91 #define lowpass2(value, frac, ref_store, ref_out) MACRO_BEGIN \
  92         lowpass(value.x, frac, ref_store.x, ref_out.x); \
  93         lowpass(value.y, frac, ref_store.y, ref_out.y); \
  94 MACRO_END
  95
  96 #define highpass2(value, frac, ref_store, ref_out) MACRO_BEGIN \
  97         highpass(value.x, frac, ref_store.x, ref_out.x); \
  98         highpass(value.y, frac, ref_store.y, ref_out.y); \
  99 MACRO_END
 100
 101 #define highpass2_limited(value, frac, limit, ref_store, ref_out) MACRO_BEGIN \
 102         highpass_limited(value.x, frac, limit, ref_store.x, ref_out.x); \
 103         highpass_limited(value.y, frac, limit, ref_store.y, ref_out.y); \
 104 MACRO_END
 105
 106 #define lowpass3(value, frac, ref_store, ref_out) MACRO_BEGIN \
 107         lowpass(value.x, frac, ref_store.x, ref_out.x); \
 108         lowpass(value.y, frac, ref_store.y, ref_out.y); \
 109         lowpass(value.z, frac, ref_store.z, ref_out.z); \
 110 MACRO_END
 111
 112 #define highpass3(value, frac, ref_store, ref_out) MACRO_BEGIN \
 113         highpass(value.x, frac, ref_store.x, ref_out.x); \
 114         highpass(value.y, frac, ref_store.y, ref_out.y); \
 115         highpass(value.z, frac, ref_store.z, ref_out.z); \
 116 MACRO_END
 117
 118 void calc_followmodel_ofs(entity view)
 119 {
 120         if(cl_followmodel_time == time)
 121                 return; // cl_followmodel_ofs already calculated for this frame
 122
 123         float frac;
 124         vector gunorg = '0 0 0';
 125         static vector vel_average;
 126         static vector gunorg_adjustment_highpass;
 127         static vector gunorg_adjustment_lowpass;
 128
 129         vector vel;
 130         if (autocvar_cl_followmodel_velocity_absolute)
 131                 vel = view.velocity;
 132         else
 133         {
 134                 vector forward, right, up;
 135                 MAKE_VECTORS(view_angles, forward, right, up);
 136                 vel.x = view.velocity * forward;
 137                 vel.y = view.velocity * right * -1;
 138                 vel.z = view.velocity * up;
 139         }
 140
 141         vel.x = bound(vel_average.x - autocvar_cl_followmodel_limit, vel.x, vel_average.x + autocvar_cl_followmodel_limit);
 142         vel.y = bound(vel_average.y - autocvar_cl_followmodel_limit, vel.y, vel_average.y + autocvar_cl_followmodel_limit);
 143         vel.z = bound(vel_average.z - autocvar_cl_followmodel_limit, vel.z, vel_average.z + autocvar_cl_followmodel_limit);
 144
 145         frac = avg_factor(autocvar_cl_followmodel_velocity_lowpass);
 146         lowpass3(vel, frac, vel_average, gunorg);
 147
 148         gunorg *= -autocvar_cl_followmodel_speed * 0.042;
 149
 150         // perform highpass/lowpass on the adjustment vectors (turning velocity into acceleration!)
 151         // trick: we must do the lowpass LAST, so the lowpass vector IS the final vector!
 152         frac = avg_factor(autocvar_cl_followmodel_highpass);
 153         highpass3(gunorg, frac, gunorg_adjustment_highpass, gunorg);
 154         frac = avg_factor(autocvar_cl_followmodel_lowpass);
 155         lowpass3(gunorg, frac, gunorg_adjustment_lowpass, gunorg);
 156
 157         if (autocvar_cl_followmodel_velocity_absolute)
 158         {
 159                 vector fixed_gunorg;
 160                 vector forward, right, up;
 161                 MAKE_VECTORS(view_angles, forward, right, up);
 162                 fixed_gunorg.x = gunorg * forward;
 163                 fixed_gunorg.y = gunorg * right * -1;
 164                 fixed_gunorg.z = gunorg * up;
 165                 gunorg = fixed_gunorg;
 166         }
 167
 168         cl_followmodel_ofs = gunorg;
 169         cl_followmodel_time = time;
 170 }
 171
 172 vector leanmodel_ofs(entity view)
 173 {
 174         float frac;
 175         vector gunangles = '0 0 0';
 176         static vector gunangles_prev = '0 0 0';
 177         static vector gunangles_highpass = '0 0 0';
 178         static vector gunangles_adjustment_highpass;
 179         static vector gunangles_adjustment_lowpass;
 180
 181         if (view.csqcmodel_teleported)
 182                 gunangles_prev = view_angles;
 183
 184         // in the highpass, we _store_ the DIFFERENCE to the actual view angles...
 185         gunangles_highpass += gunangles_prev;
 186         PITCH(gunangles_highpass) += 360 * floor((PITCH(view_angles) - PITCH(gunangles_highpass)) / 360 + 0.5);
 187         YAW(gunangles_highpass) += 360 * floor((YAW(view_angles) - YAW(gunangles_highpass)) / 360 + 0.5);
 188         ROLL(gunangles_highpass) += 360 * floor((ROLL(view_angles) - ROLL(gunangles_highpass)) / 360 + 0.5);
 189         frac = avg_factor(autocvar_cl_leanmodel_highpass1);
 190         highpass2_limited(view_angles, frac, autocvar_cl_leanmodel_limit, gunangles_highpass, gunangles);
 191         gunangles_prev = view_angles;
 192         gunangles_highpass -= gunangles_prev;
 193
 194         PITCH(gunangles) *= -autocvar_cl_leanmodel_speed;
 195         YAW(gunangles) *= -autocvar_cl_leanmodel_speed;
 196
 197         // we assume here: PITCH = 0, YAW = 1, ROLL = 2
 198         frac = avg_factor(autocvar_cl_leanmodel_highpass);
 199         highpass2(gunangles, frac, gunangles_adjustment_highpass, gunangles);
 200         frac = avg_factor(autocvar_cl_leanmodel_lowpass);
 201         lowpass2(gunangles, frac, gunangles_adjustment_lowpass, gunangles);
 202
 203         gunangles.x = -gunangles.x; // pitch was inverted, now that actually matters
 204
 205         return gunangles;
 206 }
 207
 208 vector bobmodel_ofs(entity view)
 209 {
 210         bool clonground = !(view.anim_implicit_state & ANIMIMPLICITSTATE_INAIR);
 211         static bool oldonground;
 212         static float hitgroundtime;
 213         if (clonground)
 214         {
 215                 float f = time; // cl.movecmd[0].time
 216                 if (!oldonground)
 217                         hitgroundtime = f;
 218         }
 219         oldonground = clonground;
 220
 221         // calculate for swinging gun model
 222         // the gun bobs when running on the ground, but doesn't bob when you're in the air.
 223         vector gunorg = '0 0 0';
 224         static float bobmodel_scale = 0;
 225         static float time_ofs = 0; // makes the effect always restart in the same way
 226         if (clonground)
 227         {
 228                 if (time - hitgroundtime > 0.05)
 229                         bobmodel_scale = min(1, bobmodel_scale + frametime * 5);
 230         }
 231         else
 232                 bobmodel_scale = max(0, bobmodel_scale - frametime * 5);
 233
 234         float xyspeed = bound(0, vlen(vec2(view.velocity)), 400);
 235         if (bobmodel_scale && xyspeed)
 236         {
 237                 float bspeed = xyspeed * 0.01 * autocvar_cl_viewmodel_scale * bobmodel_scale;
 238                 float s = (time - time_ofs) * autocvar_cl_bobmodel_speed;
 239                 gunorg.y = bspeed * autocvar_cl_bobmodel_side * sin(s);
 240                 gunorg.z = bspeed * autocvar_cl_bobmodel_up * cos(s * 2);
 241         }
 242         else
 243                 time_ofs = time;
 244
 245         return gunorg;
 246 }
 247
 248 void viewmodel_animate(entity this)
 249 {
 250         if (autocvar_chase_active) return;
 251         if (STAT(HEALTH) <= 0) return;
 252
 253         entity view = CSQCModel_server2csqc(player_localentnum - 1);
 254
 255         if (autocvar_cl_followmodel)
 256         {
 257                 calc_followmodel_ofs(view);
 258                 this.origin += cl_followmodel_ofs;
 259         }
 260
 261         if (autocvar_cl_leanmodel)
 262                 this.angles += leanmodel_ofs(view);
 263
 264         // vertical view bobbing code
 265         // TODO: cl_bob
 266
 267         // horizontal view bobbing code
 268         // TODO: cl_bob2
 269
 270         // fall bobbing code
 271         // causes the view to swing down and back up when touching the ground
 272         // TODO: cl_bobfall
 273
 274         // gun model bobbing code
 275         if (autocvar_cl_bobmodel)
 276                 this.origin += bobmodel_ofs(view);
 277 }
 278
 279 .vector viewmodel_origin, viewmodel_angles;
 280 .float weapon_nextthink;
 281 .float weapon_eta_last;
 282 .float weapon_switchdelay;
 283
 284 .string name_last;
 285
 286 void viewmodel_draw(entity this)
 287 {
 288         if(!this.activeweapon || !autocvar_r_drawviewmodel)
 289                 return;
 290         int mask = (intermission || (STAT(HEALTH) <= 0) || autocvar_chase_active) ? 0 : MASK_NORMAL;
 291         float a = ((autocvar_cl_viewmodel_alpha) ? bound(-1, autocvar_cl_viewmodel_alpha, this.m_alpha) : this.m_alpha);
 292         int wepskin = this.m_skin;
 293         bool invehicle = player_localentnum > maxclients;
 294         if (invehicle) a = -1;
 295         Weapon wep = this.activeweapon;
 296         int c = entcs_GetClientColors(current_player);
 297         vector g = weaponentity_glowmod(wep, NULL, c, this);
 298         entity me = CSQCModel_server2csqc(player_localentnum - 1);
 299         int fx = ((me.csqcmodel_effects & EFMASK_CHEAP)
 300                 | EF_NODEPTHTEST)
 301                 &~ (EF_FULLBRIGHT); // can mask team color, so get rid of it
 302         for (entity e = this; e; e = e.weaponchild)
 303         {
 304                 e.drawmask = mask;
 305                 e.alpha = a;
 306                 e.skin = wepskin;
 307                 e.colormap = 256 + c;  // colormap == 0 is black, c == 0 is white
 308                 e.glowmod = g;
 309                 e.csqcmodel_effects = fx;
 310                 CSQCModel_Effects_Apply(e);
 311         }
 312         if(a >= 0)
 313         {
 314                 string name = wep.mdl;
 315                 string newname = wep.wr_viewmodel(wep, this);
 316                 if(newname)
 317                         name = newname;
 318                 bool swap = name != this.name_last;
 319                 // if (swap)
 320                 {
 321                         this.name_last = name;
 322                         CL_WeaponEntity_SetModel(this, name, swap);
 323                         this.viewmodel_origin = this.origin;
 324                         this.viewmodel_angles = this.angles;
 325                 }
 326                 anim_update(this);
 327                 if ((!this.animstate_override && !this.animstate_looping) || time > this.animstate_endtime)
 328                         anim_set(this, this.anim_idle, true, false, false);
 329         }
 330         float f = 0; // 0..1; 0: fully active
 331         float rate = STAT(WEAPONRATEFACTOR);
 332         float eta = rate ? ((this.weapon_nextthink - time) / rate) : 0;
 333         if (eta <= 0) f = this.weapon_eta_last;
 334         else switch (this.state)
 335         {
 336                 case WS_RAISE:
 337                 {
 338                         f = eta / max(eta, this.weapon_switchdelay);
 339                         break;
 340                 }
 341                 case WS_DROP:
 342                 {
 343                         f = 1 - eta / max(eta, this.weapon_switchdelay);
 344                         break;
 345                 }
 346                 case WS_CLEAR:
 347                 {
 348                         f = 1;
 349                         break;
 350                 }
 351         }
 352         this.weapon_eta_last = f;
 353         this.origin = this.viewmodel_origin;
 354         this.angles = this.viewmodel_angles;
 355         this.angles_x = (-90 * f * f);
 356         viewmodel_animate(this);
 357         MUTATOR_CALLHOOK(DrawViewModel, this);
 358         setorigin(this, this.origin);
 359 }
 360
 361 STATIC_INIT(viewmodel) {
 362     for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 363         viewmodels[slot] = new(viewmodel);
 364 }
 365
 366 float showfps_prevfps;
 367 float showfps_prevfps_time;
 368 int showfps_framecounter;
 369
 370 void fpscounter_update()
 371 {
 372         if(!STAT(SHOWFPS))
 373                 return;
 374
 375         float currentTime = gettime(GETTIME_REALTIME);
 376         showfps_framecounter += 1;
 377         if(currentTime - showfps_prevfps_time > STAT(SHOWFPS))
 378         {
 379                 showfps_prevfps = showfps_framecounter/(currentTime - showfps_prevfps_time);
 380                 showfps_framecounter = 0;
 381                 showfps_prevfps_time = currentTime;
 382
 383                 int channel = MSG_C2S;
 384                 WriteHeader(channel, fpsreport);
 385                 WriteShort(channel, bound(0, rint(showfps_prevfps), 65535)); // prevent insane fps values
 386         }
 387 }
 388
 389 STATIC_INIT(fpscounter_init)
 390 {
 391         float currentTime = gettime(GETTIME_REALTIME);
 392         showfps_prevfps_time = currentTime; // we must initialize it to avoid an instant low frame sending
 393 }
 394
 395 float avgspeed;
 396 vector GetCurrentFov(float fov)
 397 {
 398         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir;
 399         float velocityzoom, curspeed;
 400         vector v;
 401
 402         zoomsensitivity = autocvar_cl_zoomsensitivity;
 403         zoomfactor = autocvar_cl_zoomfactor;
 404         if(zoomfactor < 1 || zoomfactor > 30)
 405                 zoomfactor = 2.5;
 406         zoomspeed = autocvar_cl_zoomspeed;
 407         if (zoomspeed >= 0 && (zoomspeed < 0.5 || zoomspeed > 16))
 408                 zoomspeed = 3.5;
 409
 410         zoomdir = button_zoom;
 411
 412         if(hud == HUD_NORMAL && !spectatee_status)
 413         {
 414                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 415                 {
 416                         entity wepent = viewmodels[slot];
 417                         if(wepent.switchweapon != wepent.activeweapon)
 418                                 continue;
 419                         Weapon wep = wepent.activeweapon;
 420                         if(wep != WEP_Null && wep.wr_zoomdir)
 421                         {
 422                                 bool do_zoom = wep.wr_zoomdir(wep); // TODO: merge this with wr_zoom?
 423                                 zoomdir += do_zoom;
 424                         }
 425                 }
 426         }
 427         if(spectatee_status > 0 || isdemo())
 428         {
 429                 if(spectatorbutton_zoom)
 430                 {
 431                         if(zoomdir)
 432                                 zoomdir = 0;
 433                         else
 434                                 zoomdir = 1;
 435                 }
 436                 // fteqcc failed twice here already, don't optimize this
 437         }
 438
 439         if(zoomdir) { zoomin_effect = 0; }
 440
 441         if (spectatee_status > 0 && STAT(CAMERA_SPECTATOR) == 2)
 442         {
 443                 current_viewzoom = 1;
 444         }
 445         else if (camera_active)
 446         {
 447                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 448         }
 449         else if(autocvar_cl_spawnzoom && zoomin_effect)
 450         {
 451                 float spawnzoomfactor = bound(1, autocvar_cl_spawnzoom_factor, 30);
 452
 453                 current_viewzoom += (autocvar_cl_spawnzoom_speed * (spawnzoomfactor - current_viewzoom) * drawframetime);
 454                 current_viewzoom = bound(1 / spawnzoomfactor, current_viewzoom, 1);
 455                 if(current_viewzoom == 1) { zoomin_effect = 0; }
 456         }
 457         else
 458         {
 459                 if(zoomspeed < 0) // instant zoom
 460                 {
 461                         if(zoomdir)
 462                                 current_viewzoom = 1 / zoomfactor;
 463                         else
 464                                 current_viewzoom = 1;
 465                 }
 466                 else
 467                 {
 468                         if(zoomdir)
 469                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 470                         else
 471                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 472                 }
 473         }
 474
 475         if(almost_equals(current_viewzoom, 1))
 476                 current_zoomfraction = 0;
 477         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 478                 current_zoomfraction = 1;
 479         else
 480                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 481
 482         if(zoomsensitivity < 1)
 483                 setsensitivityscale(current_viewzoom ** (1 - zoomsensitivity));
 484         else
 485                 setsensitivityscale(1);
 486
 487         if(autocvar_cl_velocityzoom_enabled && autocvar_cl_velocityzoom_type && !autocvar_cl_lockview) // _type = 0 disables velocity zoom too
 488         {
 489                 if (intermission || (spectatee_status > 0 && STAT(CAMERA_SPECTATOR) == 2))
 490                         curspeed = 0;
 491                 else
 492                 {
 493                         vector forward, right, up;
 494                         MAKE_VECTORS(view_angles, forward, right, up);
 495                         v = pmove_vel;
 496                         if(csqcplayer)
 497                                 v = csqcplayer.velocity;
 498
 499                         switch(autocvar_cl_velocityzoom_type)
 500                         {
 501                                 case 3: curspeed = max(0, forward * v); break;
 502                                 case 2: curspeed = (forward * v); break;
 503                                 case 1: default: curspeed = vlen(v); break;
 504                         }
 505                 }
 506
 507                 velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoom_time), 1); // speed at which the zoom adapts to player velocity
 508                 avgspeed = avgspeed * (1 - velocityzoom) + (curspeed / autocvar_cl_velocityzoom_speed) * velocityzoom;
 509                 velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom_factor / 1) * 1);
 510
 511                 //print(ftos(avgspeed), " avgspeed, ", ftos(curspeed), " curspeed, ", ftos(velocityzoom), " return\n"); // for debugging
 512         }
 513         else
 514                 velocityzoom = 1;
 515
 516         float frustumx, frustumy, fovx, fovy;
 517         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 518         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 519         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 520         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 521
 522         return '1 0 0' * fovx + '0 1 0' * fovy;
 523 }
 524
 525 vector GetViewLocationFOV(float fov)
 526 {
 527         float frustumy = tan(fov * M_PI / 360.0) * 0.75;
 528         float frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 529         float fovx = atan2(frustumx, 1) / M_PI * 360.0;
 530         float fovy = atan2(frustumy, 1) / M_PI * 360.0;
 531         return '1 0 0' * fovx + '0 1 0' * fovy;
 532 }
 533
 534 vector GetOrthoviewFOV(vector ov_worldmin, vector ov_worldmax, vector ov_mid, vector ov_org)
 535 {
 536         float fovx, fovy;
 537         float width = (ov_worldmax.x - ov_worldmin.x);
 538         float height = (ov_worldmax.y - ov_worldmin.y);
 539         float distance_to_middle_of_world = vlen(ov_mid - ov_org);
 540         fovx = atan2(width/2, distance_to_middle_of_world) / M_PI * 360.0;
 541         fovy = atan2(height/2, distance_to_middle_of_world) / M_PI * 360.0;
 542         return '1 0 0' * fovx + '0 1 0' * fovy;
 543 }
 544
 545 // this function must match W_SetupShot!
 546
 547 bool minigame_wasactive;
 548
 549 float camera_mode;
 550 const float CAMERA_FREE = 1;
 551 const float CAMERA_CHASE = 2;
 552 string NextFrameCommand;
 553
 554 vector freeze_org, freeze_ang;
 555 entity nightvision_noise, nightvision_noise2;
 556
 557 float myhealth, myhealth_prev;
 558 float myhealth_flash;
 559
 560 float old_blurradius, old_bluralpha;
 561 float old_sharpen_intensity;
 562
 563 vector myhealth_gentlergb;
 564
 565 float contentavgalpha, liquidalpha_prev;
 566 vector liquidcolor_prev;
 567
 568 float eventchase_current_distance;
 569 float eventchase_running;
 570 int WantEventchase(entity this, bool want_vehiclechase)
 571 {
 572         if(autocvar_cl_orthoview)
 573                 return 0;
 574         if(STAT(GAME_STOPPED) || intermission)
 575                 return 1;
 576         if(this.viewloc)
 577                 return 1;
 578         if(spectatee_status >= 0)
 579         {
 580                 if(want_vehiclechase)
 581                         return 1;
 582                 if(MUTATOR_CALLHOOK(WantEventchase, this))
 583                         return 1;
 584                 if(autocvar_cl_eventchase_frozen && STAT(FROZEN))
 585                         return 1;
 586                 if(autocvar_cl_eventchase_death && (STAT(HEALTH) <= 0))
 587                 {
 588                         if(autocvar_cl_eventchase_death == 2)
 589                         {
 590                                 // don't stop eventchase once it's started (even if velocity changes afterwards)
 591                                 if(this.velocity == '0 0 0' || eventchase_running)
 592                                         return 1;
 593                         }
 594                         else return 1;
 595                 }
 596                 if (spectatee_status > 0 && autocvar_cl_eventchase_spectated_change)
 597                 {
 598                         if (time <= spectatee_status_changed_time + min(3, autocvar_cl_eventchase_spectated_change_time))
 599                                 return 1;
 600                         else if (eventchase_running)
 601                                 return -1; // disable chase_active while eventchase is still enabled so to avoid a glicth
 602                 }
 603         }
 604         return 0;
 605 }
 606
 607 void View_EventChase(entity this)
 608 {
 609         // event chase camera
 610         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
 611         {
 612                 if(STAT(CAMERA_SPECTATOR))
 613                 {
 614                         if(spectatee_status > 0)
 615                         {
 616                                 if(!autocvar_chase_active)
 617                                 {
 618                                         cvar_set("chase_active", "-2");
 619                                         return;
 620                                 }
 621                         }
 622                         else if(autocvar_chase_active == -2)
 623                                 cvar_set("chase_active", "0");
 624
 625                         if(autocvar_chase_active == -2)
 626                                 return;
 627                 }
 628                 else if(autocvar_chase_active == -2)
 629                         cvar_set("chase_active", "0");
 630
 631                 bool vehicle_chase = (hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0));
 632
 633                 float vehicle_viewdist = 0;
 634                 vector vehicle_viewofs = '0 0 0';
 635
 636                 if(vehicle_chase)
 637                 {
 638                         if(hud != HUD_BUMBLEBEE_GUN)
 639                         {
 640                                 Vehicle info = REGISTRY_GET(Vehicles, hud);
 641                                 vehicle_viewdist = info.height;
 642                                 vehicle_viewofs = info.view_ofs;
 643                                 if(vehicle_viewdist < 0) // when set below 0, this vehicle doesn't use third person view (gunner slots)
 644                                         vehicle_chase = false;
 645                         }
 646                         else
 647                                 vehicle_chase = false;
 648                 }
 649
 650                 int eventchase = WantEventchase(this, vehicle_chase);
 651                 if (eventchase)
 652                 {
 653                         vector current_view_origin_override = '0 0 0';
 654                         vector view_offset_override = '0 0 0';
 655                         float chase_distance_override = 0;
 656                         bool custom_eventchase = MUTATOR_CALLHOOK(CustomizeEventchase, this);
 657                         if(custom_eventchase)
 658                         {
 659                                 current_view_origin_override = M_ARGV(0, vector);
 660                                 view_offset_override = M_ARGV(1, vector);
 661                                 chase_distance_override = M_ARGV(0, float);
 662                         }
 663                         eventchase_running = true;
 664
 665                         // make special vector since we can't use view_origin (It is one frame old as of this code, it gets set later with the results this code makes.)
 666                         vector current_view_origin = (csqcplayer ? csqcplayer.origin : pmove_org);
 667                         if (custom_eventchase)
 668                                 current_view_origin = current_view_origin_override;
 669
 670                         // detect maximum viewoffset and use it
 671                         vector view_offset = autocvar_cl_eventchase_viewoffset;
 672                         if(vehicle_chase)
 673                         {
 674                                 if(vehicle_viewofs)
 675                                         view_offset = vehicle_viewofs;
 676                                 else
 677                                         view_offset = autocvar_cl_eventchase_vehicle_viewoffset;
 678                         }
 679                         if (custom_eventchase)
 680                                 view_offset = view_offset_override;
 681
 682                         if(view_offset)
 683                         {
 684                                 WarpZone_TraceLine(current_view_origin, current_view_origin + view_offset + ('0 0 1' * autocvar_cl_eventchase_maxs.z), MOVE_WORLDONLY, this);
 685                                 if(trace_fraction == 1) { current_view_origin += view_offset; }
 686                                 else { current_view_origin.z += max(0, (trace_endpos.z - current_view_origin.z) - autocvar_cl_eventchase_maxs.z); }
 687                         }
 688
 689                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
 690                         // Ideally, there should be another way to enable third person cameras, such as through setproperty()
 691                         // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
 692                         if(!autocvar_chase_active) { cvar_set("chase_active", "-1"); }
 693
 694                         // make the camera smooth back
 695                         float chase_distance = autocvar_cl_eventchase_distance;
 696                         if(vehicle_chase)
 697                         {
 698                                 if(vehicle_viewofs)
 699                                         chase_distance = vehicle_viewdist;
 700                                 else
 701                                         chase_distance = autocvar_cl_eventchase_vehicle_distance;
 702                         }
 703                         if (custom_eventchase)
 704                                 chase_distance = chase_distance_override;
 705
 706                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < chase_distance)
 707                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (chase_distance - eventchase_current_distance) * frametime; // slow down the further we get
 708                         else if(eventchase_current_distance != chase_distance)
 709                                 eventchase_current_distance = chase_distance;
 710
 711                         vector forward, right, up;
 712                         MAKE_VECTORS(view_angles, forward, right, up);
 713
 714                         vector eventchase_target_origin = (current_view_origin - (forward * eventchase_current_distance));
 715                         WarpZone_TraceBox(current_view_origin, autocvar_cl_eventchase_mins, autocvar_cl_eventchase_maxs, eventchase_target_origin, MOVE_WORLDONLY, this);
 716
 717                         // If the boxtrace fails, revert back to line tracing.
 718                         if(!this.viewloc)
 719                         if(trace_startsolid)
 720                         {
 721                                 eventchase_target_origin = (current_view_origin - (forward * eventchase_current_distance));
 722                                 WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, this);
 723                                 setproperty(VF_ORIGIN, (trace_endpos - (forward * autocvar_cl_eventchase_mins.z)));
 724                         }
 725                         else { setproperty(VF_ORIGIN, trace_endpos); }
 726
 727                         if(!this.viewloc)
 728                                 setproperty(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
 729                 }
 730
 731                 if (eventchase <= 0 && autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
 732                 {
 733                         eventchase_running = false;
 734                         cvar_set("chase_active", "0");
 735                         eventchase_current_distance = 0; // start from 0 next time
 736                 }
 737         }
 738         // workaround for camera stuck between player's legs when using chase_active 1
 739         // because the engine stops updating the chase_active camera when the game ends
 740         else if(intermission)
 741         {
 742                 cvar_settemp("chase_active", "-1");
 743                 eventchase_current_distance = 0;
 744         }
 745 }
 746
 747 vector damage_blurpostprocess, content_blurpostprocess;
 748
 749 void UpdateDamage()
 750 {
 751         // accumulate damage with each stat update
 752         static float damage_total_prev = 0;
 753         float damage_total = STAT(DAMAGE_DEALT_TOTAL);
 754         float unaccounted_damage_new = COMPARE_INCREASING(damage_total, damage_total_prev);
 755         damage_total_prev = damage_total;
 756
 757         static float damage_dealt_time_prev = 0;
 758         float damage_dealt_time = STAT(HIT_TIME);
 759         if (damage_dealt_time != damage_dealt_time_prev)
 760         {
 761                 unaccounted_damage += unaccounted_damage_new;
 762                 //LOG_TRACE("dmg total: ", ftos(unaccounted_damage), " (+", ftos(unaccounted_damage_new), ")");
 763         }
 764         damage_dealt_time_prev = damage_dealt_time;
 765
 766         // prevent hitsound when switching spectatee
 767         static float spectatee_status_prev = 0;
 768         if (spectatee_status != spectatee_status_prev)
 769                 unaccounted_damage = 0;
 770         spectatee_status_prev = spectatee_status;
 771 }
 772
 773 void HitSound()
 774 {
 775         // varying sound pitch
 776
 777         bool have_arc = false;
 778         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 779         {
 780                 entity wepent = viewmodels[slot];
 781
 782                 if(wepent.activeweapon == WEP_ARC)
 783                         have_arc = true;
 784         }
 785
 786         static float hitsound_time_prev = 0;
 787         // HACK: the only way to get the arc to sound consistent with pitch shift is to ignore cl_hitsound_antispam_time
 788         bool arc_hack = have_arc && autocvar_cl_hitsound >= 2;
 789         if (arc_hack || COMPARE_INCREASING(time, hitsound_time_prev) > autocvar_cl_hitsound_antispam_time)
 790         {
 791                 if (autocvar_cl_hitsound && unaccounted_damage)
 792                 {
 793                         // customizable gradient function that crosses (0,a), (c,1) and asymptotically approaches b
 794                         float a = autocvar_cl_hitsound_max_pitch;
 795                         float b = autocvar_cl_hitsound_min_pitch;
 796                         float c = autocvar_cl_hitsound_nom_damage;
 797                         float d = unaccounted_damage;
 798                         float pitch_shift = (b*d*(a-1) + a*c*(1-b)) / (d*(a-1) + c*(1-b));
 799
 800                         // if sound variation is disabled, set pitch_shift to 1
 801                         if (autocvar_cl_hitsound == 1)
 802                                 pitch_shift = 1;
 803
 804                         // if pitch shift is reversed, mirror in (max-min)/2 + min
 805                         if (autocvar_cl_hitsound == 3)
 806                         {
 807                                 float mirror_value = (a-b)/2 + b;
 808                                 pitch_shift = mirror_value + (mirror_value - pitch_shift);
 809                         }
 810
 811                         //LOG_TRACE("dmg total (dmg): ", ftos(unaccounted_damage), " , pitch shift: ", ftos(pitch_shift));
 812
 813                         // todo: avoid very long and very short sounds from wave stretching using different sound files? seems unnecessary
 814                         // todo: normalize sound pressure levels? seems unnecessary
 815
 816                         sound7(NULL, CH_INFO, SND(HIT), VOL_BASE, ATTN_NONE, pitch_shift * 100, 0);
 817                 }
 818                 unaccounted_damage = 0;
 819                 hitsound_time_prev = time;
 820         }
 821
 822         static float typehit_time_prev = 0;
 823         float typehit_time = STAT(TYPEHIT_TIME);
 824         if (COMPARE_INCREASING(typehit_time, typehit_time_prev) > autocvar_cl_hitsound_antispam_time)
 825         {
 826                 sound(NULL, CH_INFO, SND_TYPEHIT, VOL_BASE, ATTN_NONE);
 827                 typehit_time_prev = typehit_time;
 828         }
 829
 830         static float kill_time_prev = 0;
 831         float kill_time = STAT(KILL_TIME);
 832         if (COMPARE_INCREASING(kill_time, kill_time_prev) > autocvar_cl_hitsound_antispam_time)
 833         {
 834                 sound(NULL, CH_INFO, SND_KILL, VOL_BASE, ATTN_NONE);
 835                 kill_time_prev = kill_time;
 836         }
 837 }
 838
 839 const int MAX_SPECIALCOMMAND = 15;
 840 vector specialcommand_slots[MAX_SPECIALCOMMAND];
 841 vector specialcommand_colors[MAX_SPECIALCOMMAND];
 842 const float SPECIALCOMMAND_SPEED = 150;
 843 const float SPECIALCOMMAND_TURNSPEED = 2;
 844 const float SPECIALCOMMAND_SIZE = 0.025;
 845 const float SPECIALCOMMAND_CHANCE = 0.35;
 846 float sc_spawntime, sc_changetime;
 847 vector sc_color = '1 1 1';
 848 void SpecialCommand()
 849 {
 850         if(!STAT(MOVEVARS_SPECIALCOMMAND))
 851                 return;
 852
 853         if(time >= sc_changetime)
 854         {
 855                 sc_changetime = time + 1;
 856                 sc_color = randomvec() * 1.5;
 857                 sc_color.x = bound(0.2, sc_color.x, 0.75);
 858                 sc_color.y = bound(0.2, sc_color.y, 0.75);
 859                 sc_color.z = bound(0.2, sc_color.z, 0.75);
 860         }
 861         drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), sc_color, autocvar_hud_colorflash_alpha * bound(0.1, sc_changetime - time, 0.3), DRAWFLAG_ADDITIVE);
 862
 863         if(!precache_pic("gfx/smile"))
 864                 return; // damn party poopers
 865
 866         for(int j = MAX_SPECIALCOMMAND - 1; j >= 0; --j)
 867         {
 868                 vector slot = specialcommand_slots[j];
 869                 if(slot.y)
 870                         slot.y += SPECIALCOMMAND_SPEED * frametime;
 871                 //if(slot.z)
 872                         //slot.z = sin(SPECIALCOMMAND_TURNSPEED * M_PI * time);
 873                 if(slot.y >= vid_conheight)
 874                         slot = '0 0 0';
 875
 876                 if(slot == '0 0 0')
 877                 {
 878                         if(random() <= SPECIALCOMMAND_CHANCE && time > sc_spawntime) // low chance to spawn!
 879                         {
 880                                 slot.x = bound(0, (random() * vid_conwidth + 1), vid_conwidth);
 881                                 slot.y = 1; // start it off 0 so we can use it
 882                                 slot.z = floor(random() * REGISTRY_MAX(Weapons));
 883                                 sc_spawntime = time + bound(0.4, random(), 0.75); // prevent spawning another one for this amount of time!
 884                                 vector newcolor = randomvec() * 2;
 885                                 newcolor.x = bound(0.4, newcolor.x, 1);
 886                                 newcolor.y = bound(0.4, newcolor.y, 1);
 887                                 newcolor.z = bound(0.4, newcolor.z, 1);
 888                                 specialcommand_colors[j] = newcolor;
 889                         }
 890                 }
 891                 else
 892                 {
 893                         vector splash_size = '0 0 0';
 894                         splash_size.x = max(vid_conwidth, vid_conheight) * SPECIALCOMMAND_SIZE;
 895                         splash_size.y = max(vid_conwidth, vid_conheight) * SPECIALCOMMAND_SIZE;
 896                         entity wep = REGISTRY_GET(Weapons, slot.z);
 897                         if(wep == WEP_Null)
 898                                 drawpic(vec2(slot), "gfx/smile", vec2(splash_size), specialcommand_colors[j], 0.95, DRAWFLAG_NORMAL);
 899                         else
 900                                 drawpic_skin(vec2(slot), wep.model2, vec2(splash_size), specialcommand_colors[j], 0.95, DRAWFLAG_NORMAL);
 901                         //drawrotpic(vec2(slot), slot.z, "gfx/smile", vec2(splash_size), vec2(splash_size) / 2, specialcommand_colors[j], 0.95, DRAWFLAG_NORMAL);
 902                 }
 903
 904                 specialcommand_slots[j] = slot;
 905         }
 906 }
 907
 908 void HUD_Draw(entity this)
 909 {
 910         // if we don't know gametype and scores yet avoid drawing the scoreboard
 911         // also in the very first frames, player state may be inconsistent so avoid drawing the hud at all
 912         // e.g. since initial player's health is 0 hud would display the hud_damage effect,
 913         // cl_deathscoreboard would show the scoreboard and so on
 914         if(!gametype)
 915                 return;
 916
 917         Hud_Dynamic_Frame();
 918
 919         if(!intermission)
 920         if (MUTATOR_CALLHOOK(HUD_Draw_overlay))
 921         {
 922                 drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), M_ARGV(0, vector), autocvar_hud_colorflash_alpha * M_ARGV(1, float), DRAWFLAG_ADDITIVE);
 923         }
 924         else if(STAT(FROZEN))
 925         {
 926                 vector col = '0.25 0.90 1';
 927                 if(STAT(REVIVE_PROGRESS))
 928                         col += vec3(STAT(REVIVE_PROGRESS), -STAT(REVIVE_PROGRESS), -STAT(REVIVE_PROGRESS));
 929                 drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), col, autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
 930         }
 931
 932         HUD_Scale_Enable();
 933         if(!intermission)
 934         if(STAT(NADE_TIMER) && autocvar_cl_nade_timer) // give nade top priority, as it's a matter of life and death
 935         {
 936                 vector col = '0.25 0.90 1' + vec3(STAT(NADE_TIMER), -STAT(NADE_TIMER), -STAT(NADE_TIMER));
 937                 DrawCircleClippedPic(vec2(0.5 * vid_conwidth, 0.6 * vid_conheight), 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(NADE_TIMER), col, autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
 938                 drawstring_aspect(eY * 0.64 * vid_conheight, ((autocvar_cl_nade_timer == 2) ? _("Nade timer") : ""), vec2(vid_conwidth, 0.025 * vid_conheight), '1 1 1', 1, DRAWFLAG_NORMAL);
 939         }
 940         else if(STAT(CAPTURE_PROGRESS))
 941         {
 942                 DrawCircleClippedPic(vec2(0.5 * vid_conwidth, 0.6 * vid_conheight), 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(CAPTURE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
 943                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Capture progress"), vec2(vid_conwidth, 0.025 * vid_conheight), '1 1 1', 1, DRAWFLAG_NORMAL);
 944         }
 945         else if(STAT(REVIVE_PROGRESS))
 946         {
 947                 DrawCircleClippedPic(vec2(0.5 * vid_conwidth, 0.6 * vid_conheight), 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
 948                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Revival progress"), vec2(vid_conwidth, 0.025 * vid_conheight), '1 1 1', 1, DRAWFLAG_NORMAL);
 949         }
 950         HUD_Scale_Disable();
 951
 952         if(autocvar_r_letterbox == 0)
 953                 if(autocvar_viewsize < 120)
 954                 {
 955                         if(!MUTATOR_CALLHOOK(DrawScoreboardAccuracy))
 956                                 Accuracy_LoadLevels();
 957
 958                         HUD_Main();
 959                         HUD_Scale_Disable();
 960                 }
 961
 962         // crosshair goes VERY LAST
 963         SpecialCommand();
 964         UpdateDamage();
 965         HUD_Crosshair(this);
 966         HitSound();
 967 }
 968
 969 void ViewLocation_Mouse()
 970 {
 971         if(spectatee_status)
 972                 return; // don't draw it as spectator!
 973
 974         viewloc_mousepos += getmousepos() * autocvar_menu_mouse_speed;
 975         viewloc_mousepos.x = bound(0, viewloc_mousepos.x, vid_conwidth);
 976         viewloc_mousepos.y = bound(0, viewloc_mousepos.y, vid_conheight);
 977
 978         //float cursor_alpha = 1 - autocvar__menu_alpha;
 979         //cursor_type = CURSOR_NORMAL;
 980         //draw_cursor(viewloc_mousepos, '0.5 0.5 0', "/cursor_move", '1 1 1', cursor_alpha);
 981 }
 982
 983 void HUD_Cursor_Show()
 984 {
 985         float cursor_alpha = 1 - autocvar__menu_alpha;
 986         if(cursor_type == CURSOR_NORMAL)
 987                 draw_cursor_normal(mousepos, '1 1 1', cursor_alpha);
 988         else if(cursor_type == CURSOR_MOVE)
 989                 draw_cursor(mousepos, '0.5 0.5 0', "/cursor_move", '1 1 1', cursor_alpha);
 990         else if(cursor_type == CURSOR_RESIZE)
 991                 draw_cursor(mousepos, '0.5 0.5 0', "/cursor_resize", '1 1 1', cursor_alpha);
 992         else if(cursor_type == CURSOR_RESIZE2)
 993                 draw_cursor(mousepos, '0.5 0.5 0', "/cursor_resize2", '1 1 1', cursor_alpha);
 994 }
 995
 996 void HUD_Mouse(entity player)
 997 {
 998         if(autocvar__menu_alpha == 1)
 999                 return;
1000
1001         if(!cursor_active)
1002         {
1003                 if(player.viewloc && (player.viewloc.spawnflags & VIEWLOC_FREEAIM))
1004                         ViewLocation_Mouse(); // NOTE: doesn't use cursormode
1005                 return;
1006         }
1007
1008         if (cursor_active == -1) // starting to display the cursor
1009         {
1010                 // since HUD_Mouse is called by CSQC_UpdateView before CSQC_InputEvent,
1011                 // in the first frame mousepos is the mouse position of the last time
1012                 // the cursor was displayed, thus we ignore it to avoid a glictch
1013                 cursor_active = 1;
1014                 return;
1015         }
1016
1017         if(!autocvar_hud_cursormode)
1018                 update_mousepos();
1019
1020         cursor_type = CURSOR_NORMAL;
1021         if(autocvar__hud_configure)
1022                 HUD_Panel_Mouse();
1023         else
1024         {
1025                 if (HUD_MinigameMenu_IsOpened())
1026                         HUD_Minigame_Mouse();
1027                 if (QuickMenu_IsOpened())
1028                         QuickMenu_Mouse();
1029                 if (HUD_Radar_Clickable())
1030                         HUD_Radar_Mouse();
1031         }
1032
1033         prevMouseClicked = mouseClicked;
1034
1035         HUD_Cursor_Show();
1036 }
1037
1038 void View_NightVision()
1039 {
1040         if(!(autocvar_r_fakelight >= 2 || autocvar_r_fullbright) || (serverflags & SERVERFLAG_ALLOW_FULLBRIGHT))
1041                 return;
1042
1043         // apply night vision effect
1044         vector tc_00, tc_01, tc_10, tc_11;
1045         vector rgb = '0 0 0';
1046         float a;
1047
1048         if(!nightvision_noise)
1049         {
1050                 nightvision_noise = new(nightvision_noise);
1051         }
1052         if(!nightvision_noise2)
1053         {
1054                 nightvision_noise2 = new(nightvision_noise2);
1055         }
1056
1057         // color tint in yellow
1058         drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
1059
1060         // draw BG
1061         a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
1062         rgb = '1 1 1';
1063         tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
1064         tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
1065         tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
1066         //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
1067         tc_11 = tc_01 + tc_10 - tc_00;
1068         R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE, true);
1069         R_PolygonVertex('0 0 0', tc_00, rgb, a);
1070         R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
1071         R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
1072         R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
1073         R_EndPolygon();
1074
1075         // draw FG
1076         a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
1077         rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
1078         tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
1079         tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
1080         tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
1081         tc_11 = tc_01 + tc_10 - tc_00;
1082         R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE, true);
1083         R_PolygonVertex('0 0 0', tc_00, rgb, a);
1084         R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
1085         R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
1086         R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
1087         R_EndPolygon();
1088 }
1089
1090 // visual overlay while in liquids
1091 // provides some effects to the postprocessing function
1092 void HUD_Contents()
1093 {
1094         if(!autocvar_hud_contents || MUTATOR_CALLHOOK(HUD_Contents))
1095                 return;
1096
1097         // improved polyblend
1098         float contentalpha_temp, incontent, liquidalpha, contentfadetime;
1099         vector liquidcolor;
1100
1101         switch(pointcontents(view_origin))
1102         {
1103                 case CONTENT_WATER:
1104                         liquidalpha = autocvar_hud_contents_water_alpha;
1105                         liquidcolor = stov(autocvar_hud_contents_water_color);
1106                         incontent = 1;
1107                         break;
1108
1109                 case CONTENT_LAVA:
1110                         liquidalpha = autocvar_hud_contents_lava_alpha;
1111                         liquidcolor = stov(autocvar_hud_contents_lava_color);
1112                         incontent = 1;
1113                         break;
1114
1115                 case CONTENT_SLIME:
1116                         liquidalpha = autocvar_hud_contents_slime_alpha;
1117                         liquidcolor = stov(autocvar_hud_contents_slime_color);
1118                         incontent = 1;
1119                         break;
1120
1121                 default:
1122                         liquidalpha = 0;
1123                         liquidcolor = '0 0 0';
1124                         incontent = 0;
1125                         break;
1126         }
1127
1128         if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
1129         { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
1130                 contentfadetime = autocvar_hud_contents_fadeintime;
1131                 liquidalpha_prev = liquidalpha;
1132                 liquidcolor_prev = liquidcolor;
1133         }
1134         else
1135                 contentfadetime = autocvar_hud_contents_fadeouttime;
1136
1137         contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
1138         contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
1139
1140         if(contentavgalpha)
1141                 drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
1142
1143         if(autocvar_hud_postprocessing)
1144         {
1145                 if(autocvar_hud_contents_blur && contentavgalpha)
1146                 {
1147                         content_blurpostprocess.x = 1;
1148                         content_blurpostprocess.y = contentavgalpha * autocvar_hud_contents_blur;
1149                         content_blurpostprocess.z = contentavgalpha * autocvar_hud_contents_blur_alpha;
1150                 }
1151                 else
1152                 {
1153                         content_blurpostprocess.x = 0;
1154                         content_blurpostprocess.y = 0;
1155                         content_blurpostprocess.z = 0;
1156                 }
1157         }
1158 }
1159
1160 // visual pain effects on the screen
1161 // provides some effects to the postprocessing function
1162 void HUD_Damage()
1163 {
1164         if(!autocvar_hud_damage || STAT(FROZEN))
1165                 return;
1166
1167         vector splash_pos = '0 0 0', splash_size = '0 0 0';
1168         splash_size.x = max(vid_conwidth, vid_conheight);
1169         splash_size.y = max(vid_conwidth, vid_conheight);
1170         splash_pos.x = (vid_conwidth - splash_size.x) / 2;
1171         splash_pos.y = (vid_conheight - splash_size.y) / 2;
1172
1173         float myhealth_flash_temp;
1174         myhealth = STAT(HEALTH);
1175
1176         // fade out
1177         myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
1178         // add new damage
1179         myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
1180
1181         float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
1182         pain_threshold = autocvar_hud_damage_pain_threshold;
1183         pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
1184         pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
1185
1186         if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
1187         {
1188                 pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
1189         }
1190
1191         myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
1192
1193         if(myhealth_prev < 1)
1194         {
1195                 if(myhealth >= 1)
1196                 {
1197                         myhealth_flash = 0; // just spawned, clear the flash immediately
1198                         myhealth_flash_temp = 0;
1199                 }
1200                 else
1201                 {
1202                         myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
1203                 }
1204         }
1205
1206         if(spectatee_status == -1 || intermission)
1207         {
1208                 myhealth_flash = 0; // observing, or match ended
1209                 myhealth_flash_temp = 0;
1210         }
1211
1212         myhealth_prev = myhealth;
1213
1214         // IDEA: change damage color/picture based on player model for robot/alien species?
1215         // pro: matches model better
1216         // contra: it's not red because blood is red, but because red is an alarming color, so red should stay
1217         // maybe different reddish pics?
1218         if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
1219         {
1220                 if(autocvar_cl_gentle_damage == 2)
1221                 {
1222                         if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
1223                                 myhealth_gentlergb = randomvec();
1224                 }
1225                 else
1226                         myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
1227
1228                 if(myhealth_flash_temp > 0)
1229                         drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
1230         }
1231         else if(myhealth_flash_temp > 0)
1232                 drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
1233
1234         if(autocvar_hud_postprocessing) // we still need to set this anyway even when chase_active is set, this way it doesn't get stuck on.
1235         {
1236                 if(autocvar_hud_damage_blur && myhealth_flash_temp)
1237                 {
1238                         damage_blurpostprocess.x = 1;
1239                         damage_blurpostprocess.y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
1240                         damage_blurpostprocess.z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
1241                 }
1242                 else
1243                 {
1244                         damage_blurpostprocess.x = 0;
1245                         damage_blurpostprocess.y = 0;
1246                         damage_blurpostprocess.z = 0;
1247                 }
1248         }
1249 }
1250
1251 void View_PostProcessing()
1252 {
1253         float e1 = (autocvar_hud_postprocessing_maxbluralpha != 0);
1254         float e2 = (autocvar_hud_powerup != 0);
1255         if(autocvar_hud_postprocessing && (e1 || e2)) // TODO: Remove this code and re-do the postprocess handling in the engine, where it properly belongs.
1256         {
1257                 // enable or disable rendering types if they are used or not
1258                 if(cvar("r_glsl_postprocess_uservec1_enable") != e1) { cvar_set("r_glsl_postprocess_uservec1_enable", ftos(e1)); }
1259                 if(cvar("r_glsl_postprocess_uservec2_enable") != e2) { cvar_set("r_glsl_postprocess_uservec2_enable", ftos(e2)); }
1260
1261                 // blur postprocess handling done first (used by hud_damage and hud_contents)
1262                 if((damage_blurpostprocess.x || content_blurpostprocess.x))
1263                 {
1264                         float blurradius = bound(0, damage_blurpostprocess.y + content_blurpostprocess.y, autocvar_hud_postprocessing_maxblurradius);
1265                         float bluralpha = bound(0, damage_blurpostprocess.z + content_blurpostprocess.z, autocvar_hud_postprocessing_maxbluralpha);
1266                         if(blurradius != old_blurradius || bluralpha != old_bluralpha) // reduce cvar_set spam as much as possible
1267                         {
1268                                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
1269                                 old_blurradius = blurradius;
1270                                 old_bluralpha = bluralpha;
1271                         }
1272                 }
1273                 else if(cvar_string("r_glsl_postprocess_uservec1") != "0 0 0 0") // reduce cvar_set spam as much as possible
1274                 {
1275                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
1276                         old_blurradius = 0;
1277                         old_bluralpha = 0;
1278                 }
1279
1280                 // edge detection postprocess handling done second (used by hud_powerup)
1281                 float sharpen_intensity = 0, strength_finished = STAT(STRENGTH_FINISHED), invincible_finished = STAT(INVINCIBLE_FINISHED);
1282                 if (strength_finished - time > 0) { sharpen_intensity += (strength_finished - time); }
1283                 if (invincible_finished - time > 0) { sharpen_intensity += (invincible_finished - time); }
1284
1285                 sharpen_intensity = bound(0, ((STAT(HEALTH) > 0) ? sharpen_intensity : 0), 5); // Check to see if player is alive (if not, set 0) - also bound to fade out starting at 5 seconds.
1286
1287                 if(autocvar_hud_powerup && sharpen_intensity > 0)
1288                 {
1289                         if(sharpen_intensity != old_sharpen_intensity) // reduce cvar_set spam as much as possible
1290                         {
1291                                 cvar_set("r_glsl_postprocess_uservec2", strcat(ftos((sharpen_intensity / 5) * autocvar_hud_powerup), " ", ftos(-sharpen_intensity * autocvar_hud_powerup), " 0 0"));
1292                                 old_sharpen_intensity = sharpen_intensity;
1293                         }
1294                 }
1295                 else if(cvar_string("r_glsl_postprocess_uservec2") != "0 0 0 0") // reduce cvar_set spam as much as possible
1296                 {
1297                         cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
1298                         old_sharpen_intensity = 0;
1299                 }
1300
1301                 if(cvar("r_glsl_postprocess") == 0)
1302                         cvar_set("r_glsl_postprocess", "2");
1303         }
1304         else if(cvar("r_glsl_postprocess") == 2)
1305                 cvar_set("r_glsl_postprocess", "0");
1306 }
1307
1308 void View_Lock()
1309 {
1310         int lock_type = autocvar_cl_lockview;
1311
1312         if (!autocvar_hud_cursormode
1313                 && ((autocvar__hud_configure && spectatee_status <= 0)
1314                         || intermission > 1
1315                         || HUD_Radar_Clickable()
1316                         || HUD_MinigameMenu_IsOpened()
1317                         || QuickMenu_IsOpened()
1318                 )
1319         )
1320                 lock_type = 1;
1321
1322         // lock_type 1: lock origin and angles
1323         // lock_type 2: lock only origin
1324         if(lock_type >= 1)
1325                 setproperty(VF_ORIGIN, freeze_org);
1326         else
1327                 freeze_org = getpropertyvec(VF_ORIGIN);
1328         if(lock_type == 1)
1329                 setproperty(VF_ANGLES, freeze_ang);
1330         else
1331                 freeze_ang = getpropertyvec(VF_ANGLES);
1332 }
1333
1334 void View_DemoCamera()
1335 {
1336         if(camera_active) // Camera for demo playback
1337         {
1338                 if(autocvar_camera_enable)
1339                         CSQC_Demo_Camera();
1340                 else
1341                 {
1342                         cvar_set("chase_active", ftos(chase_active_backup));
1343                         cvar_set("cl_demo_mousegrab", "0");
1344                         camera_active = false;
1345                 }
1346         }
1347         else
1348         {
1349 #ifdef CAMERATEST
1350                 if(autocvar_camera_enable)
1351 #else
1352                 if(autocvar_camera_enable && isdemo())
1353 #endif
1354                 {
1355                         // Enable required Darkplaces cvars
1356                         chase_active_backup = autocvar_chase_active;
1357                         cvar_set("chase_active", "2");
1358                         cvar_set("cl_demo_mousegrab", "1");
1359                         camera_active = true;
1360                         camera_mode = false;
1361                 }
1362         }
1363 }
1364
1365 #ifdef BLURTEST
1366 void View_BlurTest()
1367 {
1368         if(time > blurtest_time0 && time < blurtest_time1)
1369         {
1370                 float t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
1371                 float r = t * blurtest_radius;
1372                 float f = 1 / (t ** blurtest_power) - 1;
1373
1374                 cvar_set("r_glsl_postprocess", "1");
1375                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
1376         }
1377         else
1378         {
1379                 cvar_set("r_glsl_postprocess", "0");
1380                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
1381         }
1382 }
1383 #endif
1384
1385 void View_CheckButtonStatus()
1386 {
1387         float is_dead = (STAT(HEALTH) <= 0);
1388
1389         // FIXME do we need this hack?
1390         if(isdemo())
1391         {
1392                 // in demos, input_buttons do not work
1393                 button_zoom = (autocvar__togglezoom == "-");
1394         }
1395         else if(button_zoom
1396                 && autocvar_cl_unpress_zoom_on_death
1397                 && (spectatee_status >= 0)
1398                 && (is_dead || intermission))
1399         {
1400                 // no zoom while dead or in intermission please
1401                 localcmd("-zoom\n");
1402                 button_zoom = false;
1403         }
1404
1405         if(autocvar_fov <= 59.5)
1406         {
1407                 if(!zoomscript_caught)
1408                 {
1409                         localcmd("+button9\n");
1410                         zoomscript_caught = 1;
1411                 }
1412         }
1413         else
1414         {
1415                 if(zoomscript_caught)
1416                 {
1417                         localcmd("-button9\n");
1418                         zoomscript_caught = 0;
1419                 }
1420         }
1421
1422         if(active_minigame && HUD_MinigameMenu_IsOpened())
1423         {
1424                 if(!minigame_wasactive)
1425                 {
1426                         localcmd("+button12\n");
1427                         minigame_wasactive = true;
1428                 }
1429         }
1430         else if(minigame_wasactive)
1431         {
1432                 localcmd("-button12\n");
1433                 minigame_wasactive = false;
1434         }
1435
1436         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1437         {
1438                 entity wepent = viewmodels[slot];
1439
1440                 if(wepent.last_switchweapon != wepent.switchweapon)
1441                 {
1442                         weapontime = time;
1443                         wepent.last_switchweapon = wepent.switchweapon;
1444                         if(slot == 0 && button_zoom && autocvar_cl_unpress_zoom_on_weapon_switch)
1445                         {
1446                                 localcmd("-zoom\n");
1447                                 button_zoom = false;
1448                         }
1449                         if(slot == 0 && autocvar_cl_unpress_attack_on_weapon_switch)
1450                         {
1451                                 localcmd("-fire\n");
1452                                 localcmd("-fire2\n");
1453                                 button_attack2 = false;
1454                         }
1455                 }
1456                 if(wepent.last_activeweapon != wepent.activeweapon)
1457                 {
1458                         wepent.last_activeweapon = wepent.activeweapon;
1459
1460                         entity e = wepent.activeweapon;
1461                         if(e.netname != "")
1462                                 localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
1463                         else if(slot == 0)
1464                                 localcmd("\ncl_hook_activeweapon none\n");
1465                 }
1466         }
1467 }
1468
1469 bool ov_enabled;
1470 float oldr_nearclip;
1471 float oldr_farclip_base;
1472 float oldr_farclip_world;
1473 float oldr_novis;
1474 float oldr_useportalculling;
1475 float oldr_useinfinitefarclip;
1476 vector ov_org = '0 0 0';
1477 vector ov_mid = '0 0 0';
1478 vector ov_worldmin = '0 0 0';
1479 vector ov_worldmax = '0 0 0';
1480
1481 void View_Ortho()
1482 {
1483         ov_org = '0 0 0';
1484         ov_mid = '0 0 0';
1485         ov_worldmin = '0 0 0';
1486         ov_worldmax = '0 0 0';
1487         if(autocvar_cl_orthoview)
1488         {
1489                 ov_worldmin = mi_picmin;
1490                 ov_worldmax = mi_picmax;
1491
1492                 float ov_width = (ov_worldmax.x - ov_worldmin.x);
1493                 float ov_height = (ov_worldmax.y - ov_worldmin.y);
1494                 float ov_distance = (max(vid_width, vid_height) * max(ov_width, ov_height));
1495
1496                 ov_mid = ((ov_worldmax + ov_worldmin) * 0.5);
1497                 ov_org = vec3(ov_mid.x, ov_mid.y, (ov_mid.z + ov_distance));
1498
1499                 float ov_nearest = vlen(ov_org - vec3(
1500                         bound(ov_worldmin.x, ov_org.x, ov_worldmax.x),
1501                         bound(ov_worldmin.y, ov_org.y, ov_worldmax.y),
1502                         bound(ov_worldmin.z, ov_org.z, ov_worldmax.z)
1503                 ));
1504
1505                 float ov_furthest = 0;
1506                 float dist = 0;
1507
1508                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1509                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1510                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1511                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1512                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1513                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1514                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1515                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1516
1517                 if(!ov_enabled)
1518                 {
1519                         oldr_nearclip = cvar("r_nearclip");
1520                         oldr_farclip_base = cvar("r_farclip_base");
1521                         oldr_farclip_world = cvar("r_farclip_world");
1522                         oldr_novis = cvar("r_novis");
1523                         oldr_useportalculling = cvar("r_useportalculling");
1524                         oldr_useinfinitefarclip = cvar("r_useinfinitefarclip");
1525                 }
1526
1527                 cvar_settemp("r_nearclip", ftos(ov_nearest));
1528                 cvar_settemp("r_farclip_base", ftos(ov_furthest));
1529                 cvar_settemp("r_farclip_world", "0");
1530                 cvar_settemp("r_novis", "1");
1531                 cvar_settemp("r_useportalculling", "0");
1532                 cvar_settemp("r_useinfinitefarclip", "0");
1533
1534                 setproperty(VF_ORIGIN, ov_org);
1535                 setproperty(VF_ANGLES, '90 0 0');
1536
1537                 ov_enabled = true;
1538
1539                 #if 0
1540                 LOG_INFOF("OrthoView: org = %s, angles = %s, distance = %f, nearest = %f, furthest = %f",
1541                         vtos(ov_org),
1542                         vtos(getpropertyvec(VF_ANGLES)),
1543                         ov_distance,
1544                         ov_nearest,
1545                         ov_furthest);
1546                 #endif
1547         }
1548         else
1549         {
1550                 if(ov_enabled)
1551                 {
1552                         cvar_set("r_nearclip", ftos(oldr_nearclip));
1553                         cvar_set("r_farclip_base", ftos(oldr_farclip_base));
1554                         cvar_set("r_farclip_world", ftos(oldr_farclip_world));
1555                         cvar_set("r_novis", ftos(oldr_novis));
1556                         cvar_set("r_useportalculling", ftos(oldr_useportalculling));
1557                         cvar_set("r_useinfinitefarclip", ftos(oldr_useinfinitefarclip));
1558                 }
1559                 ov_enabled = false;
1560         }
1561 }
1562
1563 void View_UpdateFov()
1564 {
1565         vector fov;
1566         if(autocvar_cl_orthoview)
1567                 fov = GetOrthoviewFOV(ov_worldmin, ov_worldmax, ov_mid, ov_org);
1568         else if(csqcplayer.viewloc)
1569                 fov = GetViewLocationFOV(110); // enforce 110 fov, so things don't look odd
1570         else
1571                 fov = GetCurrentFov(autocvar_fov);
1572
1573         setproperty(VF_FOV, fov);
1574 }
1575
1576 void CSQC_UpdateView(entity this, float w, float h)
1577 {
1578         TC(int, w); TC(int, h);
1579
1580         execute_next_frame();
1581
1582         ++framecount;
1583
1584         stats_get();
1585         hud = STAT(HUD);
1586
1587         ReplicateVars(false);
1588         if (ReplicateVars_NOT_SENDING())
1589                 ReplicateVars_DELAY(0.8 + random() * 0.4); // no need to check cvars every frame
1590
1591         HUD_Scale_Disable();
1592
1593         if(autocvar__hud_showbinds_reload) // menu can set this one
1594         {
1595                 db_close(binddb);
1596                 binddb = db_create();
1597                 cvar_set("_hud_showbinds_reload", "0");
1598         }
1599
1600         if(checkextension("DP_CSQC_MINFPS_QUALITY"))
1601                 view_quality = getproperty(VF_MINFPS_QUALITY);
1602         else
1603                 view_quality = 1;
1604
1605         button_attack2 = PHYS_INPUT_BUTTON_ATCK2(this);
1606         button_zoom = PHYS_INPUT_BUTTON_ZOOM(this);
1607
1608         vector vf_size = getpropertyvec(VF_SIZE);
1609         vector vf_min = getpropertyvec(VF_MIN);
1610         vid_width = vf_size.x;
1611         vid_height = vf_size.y;
1612
1613         ticrate = STAT(MOVEVARS_TICRATE) * STAT(MOVEVARS_TIMESCALE);
1614
1615         WaypointSprite_Load();
1616
1617         CSQCPlayer_SetCamera();
1618
1619         if(player_localentnum <= maxclients) // is it a client?
1620                 current_player = player_localentnum - 1;
1621         else // then player_localentnum is the vehicle I'm driving
1622                 current_player = player_localnum;
1623         myteam = entcs_GetTeam(current_player);
1624
1625         // abused multiple places below
1626         entity local_player = ((csqcplayer) ? csqcplayer : CSQCModel_server2csqc(player_localentnum - 1));
1627         if(!local_player)
1628                 local_player = this; // fall back!
1629
1630         View_EventChase(local_player);
1631
1632         // do lockview after event chase camera so that it still applies whenever necessary.
1633         View_Lock();
1634
1635         WarpZone_FixView();
1636         //WarpZone_FixPMove();
1637
1638         View_Ortho();
1639
1640         // run viewmodel_draw before updating view_angles to the angles calculated by WarpZone_FixView
1641         // viewmodel_draw needs to use the view_angles set by the engine on every CSQC_UpdateView call
1642         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1643                 viewmodel_draw(viewmodels[slot]);
1644
1645         // Render the Scene
1646         view_origin = getpropertyvec(VF_ORIGIN);
1647         view_angles = getpropertyvec(VF_ANGLES);
1648         MAKE_VECTORS(view_angles, view_forward, view_right, view_up);
1649
1650 #ifdef BLURTEST
1651         View_BlurTest();
1652 #endif
1653
1654         TargetMusic_Advance();
1655         Fog_Force();
1656         fpscounter_update();
1657
1658         if(drawtime == 0)
1659                 drawframetime = 0.01666667; // when we don't know fps yet, we assume 60fps
1660         else
1661                 drawframetime = bound(0.000001, time - drawtime, 1);
1662         drawtime = time;
1663
1664         // watch for gametype changes here...
1665         // in ParseStuffCMD the cmd isn't executed yet :/
1666         // might even be better to add the gametype to TE_CSQC_INIT...?
1667         if(!postinit)
1668                 PostInit();
1669
1670         if(intermission && !intermission_time)
1671                 intermission_time = time;
1672
1673         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
1674         {
1675                 if(calledhooks & HOOK_START)
1676                 {
1677                         localcmd("\ncl_hook_gameend\n");
1678                         calledhooks |= HOOK_END;
1679                 }
1680         }
1681
1682         Announcer();
1683
1684         View_CheckButtonStatus();
1685
1686         ColorTranslateMode = autocvar_cl_stripcolorcodes;
1687
1688         // ALWAYS Clear Current Scene First
1689         clearscene();
1690
1691         setproperty(VF_ORIGIN, view_origin);
1692         setproperty(VF_ANGLES, view_angles);
1693
1694         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
1695         setproperty(VF_SIZE, vf_size);
1696         setproperty(VF_MIN, vf_min);
1697
1698         // Assign Standard Viewflags
1699         // Draw the World (and sky)
1700         setproperty(VF_DRAWWORLD, 1);
1701
1702         // Set the console size vars
1703         vid_conwidth = autocvar_vid_conwidth;
1704         vid_conheight = autocvar_vid_conheight;
1705         vid_pixelheight = autocvar_vid_pixelheight;
1706
1707         View_UpdateFov();
1708
1709         View_DemoCamera();
1710
1711         // Draw the Crosshair
1712         setproperty(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
1713
1714         // Draw the Engine Status Bar (the default Quake HUD)
1715         setproperty(VF_DRAWENGINESBAR, 0);
1716
1717         // Update the mouse position
1718         /*
1719            mousepos_x = vid_conwidth;
1720            mousepos_y = vid_conheight;
1721            mousepos = mousepos*0.5 + getmousepos();
1722          */
1723
1724         IL_EACH(g_drawables, it.draw, it.draw(it));
1725
1726         addentities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS); // TODO: .health is used in cl_deathfade (a feature we have turned off currently)
1727         renderscene();
1728
1729         // Now the the scene has been rendered, begin with the 2D drawing functions
1730
1731         View_NightVision();
1732         DrawReticle(local_player);
1733         HUD_Contents();
1734         HUD_Damage();
1735         View_PostProcessing();
1736
1737         // draw 2D entities
1738         IL_EACH(g_drawables_2d, it.draw2d, it.draw2d(it));
1739         Draw_ShowNames_All();
1740 #if ENABLE_DEBUGDRAW
1741         Debug_Draw();
1742 #endif
1743
1744         scoreboard_active = Scoreboard_WouldDraw();
1745
1746         HUD_Draw(this); // this parameter for deep vehicle function
1747
1748         if(NextFrameCommand)
1749         {
1750                 localcmd("\n", NextFrameCommand, "\n");
1751                 NextFrameCommand = string_null;
1752         }
1753
1754         // we must do this check AFTER a frame was rendered, or it won't work
1755         if(cs_project_is_b0rked == 0)
1756         {
1757                 string w0, h0;
1758                 w0 = ftos(autocvar_vid_conwidth);
1759                 h0 = ftos(autocvar_vid_conheight);
1760                 //setproperty(VF_VIEWPORT, '0 0 0', '640 480 0');
1761                 //setproperty(VF_FOV, '90 90 0');
1762                 setproperty(VF_ORIGIN, '0 0 0');
1763                 setproperty(VF_ANGLES, '0 0 0');
1764                 setproperty(VF_PERSPECTIVE, 1);
1765                 vector forward, right, up;
1766                 MAKE_VECTORS('0 0 0', forward, right, up);
1767                 vector v1, v2;
1768                 cvar_set("vid_conwidth", "800");
1769                 cvar_set("vid_conheight", "600");
1770                 v1 = cs_project(forward);
1771                 cvar_set("vid_conwidth", "640");
1772                 cvar_set("vid_conheight", "480");
1773                 v2 = cs_project(forward);
1774                 if(v1 == v2)
1775                         cs_project_is_b0rked = 1;
1776                 else
1777                         cs_project_is_b0rked = -1;
1778                 cvar_set("vid_conwidth", w0);
1779                 cvar_set("vid_conheight", h0);
1780         }
1781
1782         HUD_Mouse(local_player);
1783
1784         cl_notice_run();
1785         unpause_update();
1786         Net_Flush();
1787
1788         // let's reset the view back to normal for the end
1789         setproperty(VF_MIN, '0 0 0');
1790         setproperty(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
1791
1792         IL_ENDFRAME();
1793 }
1794
1795
1796 // following vectors must be global to allow seamless switching between camera modes
1797 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
1798 void CSQC_Demo_Camera()
1799 {
1800         float speed, attenuation, dimensions;
1801         vector tmp, delta;
1802
1803         if( autocvar_camera_reset || !camera_mode )
1804         {
1805                 camera_offset = '0 0 0';
1806                 current_angles = '0 0 0';
1807                 camera_direction = '0 0 0';
1808                 camera_offset.z += 30;
1809                 camera_offset.x += 30 * -cos(current_angles.y * DEG2RAD);
1810                 camera_offset.y += 30 * -sin(current_angles.y * DEG2RAD);
1811                 current_origin = view_origin;
1812                 current_camera_offset  = camera_offset;
1813                 cvar_set("camera_reset", "0");
1814                 camera_mode = CAMERA_CHASE;
1815         }
1816
1817         // Camera angles
1818         if( camera_roll )
1819                 mouse_angles.z += camera_roll * autocvar_camera_speed_roll;
1820
1821         if(autocvar_camera_look_player)
1822         {
1823                 vector dir;
1824                 float n;
1825
1826                 dir = normalize(view_origin - current_position);
1827                 n = mouse_angles.z;
1828                 mouse_angles = vectoangles(dir);
1829                 mouse_angles.x = mouse_angles.x * -1;
1830                 mouse_angles.z = n;
1831         }
1832         else
1833         {
1834                 tmp = getmousepos() * 0.1;
1835                 if(vdist(tmp, >, autocvar_camera_mouse_threshold))
1836                 {
1837                         mouse_angles.x += tmp.y * cos(mouse_angles.z * DEG2RAD) + (tmp.x * sin(mouse_angles.z * DEG2RAD));
1838                         mouse_angles.y -= tmp.x * cos(mouse_angles.z * DEG2RAD) + (tmp.y * -sin(mouse_angles.z * DEG2RAD));
1839                 }
1840         }
1841
1842         while (mouse_angles.x < -180) mouse_angles.x = mouse_angles.x + 360;
1843         while (mouse_angles.x > 180) mouse_angles.x = mouse_angles.x - 360;
1844         while (mouse_angles.y < -180) mouse_angles.y = mouse_angles.y + 360;
1845         while (mouse_angles.y > 180) mouse_angles.y = mouse_angles.y - 360;
1846
1847         // Fix difference when angles don't have the same sign
1848         delta = '0 0 0';
1849         if(mouse_angles.y < -60 && current_angles.y > 60)
1850                 delta = '0 360 0';
1851         if(mouse_angles.y > 60 && current_angles.y < -60)
1852                 delta = '0 -360 0';
1853
1854         if(autocvar_camera_look_player)
1855                 attenuation = autocvar_camera_look_attenuation;
1856         else
1857                 attenuation = autocvar_camera_speed_attenuation;
1858
1859         attenuation = 1 / max(1, attenuation);
1860         current_angles += (mouse_angles - current_angles + delta) * attenuation;
1861
1862         while (current_angles.x < -180) current_angles.x = current_angles.x + 360;
1863         while (current_angles.x > 180) current_angles.x = current_angles.x - 360;
1864         while (current_angles.y < -180) current_angles.y = current_angles.y + 360;
1865         while (current_angles.y > 180) current_angles.y = current_angles.y - 360;
1866
1867         // Camera position
1868         tmp = '0 0 0';
1869         dimensions = 0;
1870
1871         if( camera_direction.x )
1872         {
1873                 tmp.x = camera_direction.x * cos(current_angles.y * DEG2RAD);
1874                 tmp.y = camera_direction.x * sin(current_angles.y * DEG2RAD);
1875                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
1876                         tmp.z = camera_direction.x * -sin(current_angles.x * DEG2RAD);
1877                 ++dimensions;
1878         }
1879
1880         if( camera_direction.y )
1881         {
1882                 tmp.x += camera_direction.y * -sin(current_angles.y * DEG2RAD);
1883                 tmp.y += camera_direction.y * cos(current_angles.y * DEG2RAD) * cos(current_angles.z * DEG2RAD);
1884                 tmp.z += camera_direction.y * sin(current_angles.z * DEG2RAD);
1885                 ++dimensions;
1886         }
1887
1888         if( camera_direction.z )
1889         {
1890                 tmp.z += camera_direction.z * cos(current_angles.z * DEG2RAD);
1891                 ++dimensions;
1892         }
1893
1894         if(autocvar_camera_free)
1895                 speed = autocvar_camera_speed_free;
1896         else
1897                 speed = autocvar_camera_speed_chase;
1898
1899         if(dimensions)
1900         {
1901                 speed = speed * sqrt(1 / dimensions);
1902                 camera_offset += tmp * speed;
1903         }
1904
1905         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
1906
1907         // Camera modes
1908         if( autocvar_camera_free )
1909         {
1910                 if ( camera_mode == CAMERA_CHASE )
1911                 {
1912                         current_camera_offset = current_origin + current_camera_offset;
1913                         camera_offset = current_origin + camera_offset;
1914                 }
1915
1916                 camera_mode = CAMERA_FREE;
1917                 current_position = current_camera_offset;
1918         }
1919         else
1920         {
1921                 if ( camera_mode == CAMERA_FREE )
1922                 {
1923                         current_origin = view_origin;
1924                         camera_offset = camera_offset - current_origin;
1925                         current_camera_offset = current_camera_offset - current_origin;
1926                 }
1927
1928                 camera_mode = CAMERA_CHASE;
1929
1930                 if(autocvar_camera_chase_smoothly)
1931                         current_origin += (view_origin - current_origin) * attenuation;
1932                 else
1933                         current_origin = view_origin;
1934
1935                 current_position = current_origin + current_camera_offset;
1936         }
1937
1938         setproperty(VF_ANGLES, current_angles);
1939         setproperty(VF_ORIGIN, current_position);
1940 }