qcsrc/client/view.qc

   1 #include "view.qh"
   2
   3 #include <client/announcer.qh>
   4 #include <client/csqcmodel_hooks.qh>
   5 #include <client/draw.qh>
   6 #include <client/hud/_mod.qh>
   7 #include <client/hud/panel/quickmenu.qh>
   8 #include <client/hud/panel/scoreboard.qh>
   9 #include <client/mapvoting.qh>
  10 #include <client/mutators/_mod.qh>
  11 #include <client/shownames.qh>
  12 #include <common/anim.qh>
  13 #include <common/animdecide.qh>
  14 #include <common/constants.qh>
  15 #include <common/deathtypes/all.qh>
  16 #include <common/debug.qh>
  17 #include <common/ent_cs.qh>
  18 #include <common/gamemodes/_mod.qh>
  19 #include <common/mapinfo.qh>
  20 #include <common/mapobjects/target/music.qh>
  21 #include <common/mapobjects/trigger/viewloc.qh>
  22 #include <common/minigames/cl_minigames.qh>
  23 #include <common/minigames/cl_minigames_hud.qh>
  24 #include <common/mutators/mutator/powerups/_mod.qh>
  25 #include <common/mutators/mutator/status_effects/_mod.qh>
  26 #include <common/mutators/mutator/waypoints/all.qh>
  27 #include <common/net_linked.qh>
  28 #include <common/net_notice.qh>
  29 #include <common/physics/player.qh>
  30 #include <common/stats.qh>
  31 #include <common/teams.qh>
  32 #include <common/vehicles/all.qh>
  33 #include <common/viewloc.qh>
  34 #include <common/weapons/_all.qh>
  35 #include <common/weapons/weapon/tuba.qh>
  36 #include <common/wepent.qh>
  37 #include <lib/csqcmodel/cl_model.qh>
  38 #include <lib/csqcmodel/cl_player.qh>
  39 #include <lib/warpzone/client.qh>
  40 #include <lib/warpzone/common.qh>
  41
  42 float autocvar_cl_viewmodel_scale;
  43 float autocvar_cl_viewmodel_alpha = 1;
  44
  45 bool autocvar_cl_bobmodel;
  46 float autocvar_cl_bobmodel_speed;
  47 float autocvar_cl_bobmodel_side;
  48 float autocvar_cl_bobmodel_up;
  49
  50 float autocvar_cl_followmodel;
  51 float autocvar_cl_followmodel_speed = 0.3;
  52 float autocvar_cl_followmodel_limit = 135;
  53 float autocvar_cl_followmodel_velocity_lowpass = 0.05;
  54 float autocvar_cl_followmodel_highpass = 0.05;
  55 float autocvar_cl_followmodel_lowpass = 0.03;
  56 bool autocvar_cl_followmodel_velocity_absolute;
  57
  58 float autocvar_cl_leanmodel;
  59 float autocvar_cl_leanmodel_speed = 0.3;
  60 float autocvar_cl_leanmodel_limit = 30;
  61 float autocvar_cl_leanmodel_highpass1 = 0.2;
  62 float autocvar_cl_leanmodel_highpass = 0.2;
  63 float autocvar_cl_leanmodel_lowpass = 0.05;
  64
  65 #define avg_factor(avg_time) (1 - exp(-frametime / max(0.001, avg_time)))
  66
  67 #define lowpass(value, frac, ref_store, ret) \
  68         ret = ref_store = ref_store * (1 - frac) + (value) * frac;
  69
  70 #define lowpass_limited(value, frac, limit, ref_store, ret) MACRO_BEGIN \
  71         float __ignore; lowpass(value, frac, ref_store, __ignore); \
  72         ret = ref_store = bound((value) - (limit), ref_store, (value) + (limit)); \
  73 MACRO_END
  74
  75 #define highpass(value, frac, ref_store, ret) MACRO_BEGIN \
  76         float __f = 0; lowpass(value, frac, ref_store, __f); \
  77         ret = (value) - __f; \
  78 MACRO_END
  79
  80 #define highpass_limited(value, frac, limit, ref_store, ret) MACRO_BEGIN \
  81         float __f = 0; lowpass_limited(value, frac, limit, ref_store, __f); \
  82         ret = (value) - __f; \
  83 MACRO_END
  84
  85 #define lowpass2(value, frac, ref_store, ref_out) MACRO_BEGIN \
  86         lowpass(value.x, frac, ref_store.x, ref_out.x); \
  87         lowpass(value.y, frac, ref_store.y, ref_out.y); \
  88 MACRO_END
  89
  90 #define highpass2(value, frac, ref_store, ref_out) MACRO_BEGIN \
  91         highpass(value.x, frac, ref_store.x, ref_out.x); \
  92         highpass(value.y, frac, ref_store.y, ref_out.y); \
  93 MACRO_END
  94
  95 #define highpass2_limited(value, frac, limit, ref_store, ref_out) MACRO_BEGIN \
  96         highpass_limited(value.x, frac, limit, ref_store.x, ref_out.x); \
  97         highpass_limited(value.y, frac, limit, ref_store.y, ref_out.y); \
  98 MACRO_END
  99
 100 #define lowpass3(value, frac, ref_store, ref_out) MACRO_BEGIN \
 101         lowpass(value.x, frac, ref_store.x, ref_out.x); \
 102         lowpass(value.y, frac, ref_store.y, ref_out.y); \
 103         lowpass(value.z, frac, ref_store.z, ref_out.z); \
 104 MACRO_END
 105
 106 #define highpass3(value, frac, ref_store, ref_out) MACRO_BEGIN \
 107         highpass(value.x, frac, ref_store.x, ref_out.x); \
 108         highpass(value.y, frac, ref_store.y, ref_out.y); \
 109         highpass(value.z, frac, ref_store.z, ref_out.z); \
 110 MACRO_END
 111
 112 void calc_followmodel_ofs(entity view)
 113 {
 114         if(cl_followmodel_time == time)
 115                 return; // cl_followmodel_ofs already calculated for this frame
 116
 117         float frac;
 118         vector gunorg = '0 0 0';
 119         static vector vel_average;
 120         static vector gunorg_adjustment_highpass;
 121         static vector gunorg_adjustment_lowpass;
 122
 123         vector vel;
 124         if (autocvar_cl_followmodel_velocity_absolute)
 125                 vel = view.velocity;
 126         else
 127         {
 128                 vector forward, right, up;
 129                 MAKE_VECTORS(view_angles, forward, right, up);
 130                 vel.x = view.velocity * forward;
 131                 vel.y = view.velocity * right * -1;
 132                 vel.z = view.velocity * up;
 133         }
 134
 135         vel.x = bound(vel_average.x - autocvar_cl_followmodel_limit, vel.x, vel_average.x + autocvar_cl_followmodel_limit);
 136         vel.y = bound(vel_average.y - autocvar_cl_followmodel_limit, vel.y, vel_average.y + autocvar_cl_followmodel_limit);
 137         vel.z = bound(vel_average.z - autocvar_cl_followmodel_limit, vel.z, vel_average.z + autocvar_cl_followmodel_limit);
 138
 139         frac = avg_factor(autocvar_cl_followmodel_velocity_lowpass);
 140         lowpass3(vel, frac, vel_average, gunorg);
 141
 142         gunorg *= -autocvar_cl_followmodel_speed * 0.042;
 143
 144         // perform highpass/lowpass on the adjustment vectors (turning velocity into acceleration!)
 145         // trick: we must do the lowpass LAST, so the lowpass vector IS the final vector!
 146         frac = avg_factor(autocvar_cl_followmodel_highpass);
 147         highpass3(gunorg, frac, gunorg_adjustment_highpass, gunorg);
 148         frac = avg_factor(autocvar_cl_followmodel_lowpass);
 149         lowpass3(gunorg, frac, gunorg_adjustment_lowpass, gunorg);
 150
 151         if (autocvar_cl_followmodel_velocity_absolute)
 152         {
 153                 vector fixed_gunorg;
 154                 vector forward, right, up;
 155                 MAKE_VECTORS(view_angles, forward, right, up);
 156                 fixed_gunorg.x = gunorg * forward;
 157                 fixed_gunorg.y = gunorg * right * -1;
 158                 fixed_gunorg.z = gunorg * up;
 159                 gunorg = fixed_gunorg;
 160         }
 161
 162         cl_followmodel_ofs = gunorg;
 163         cl_followmodel_time = time;
 164 }
 165
 166 vector leanmodel_ofs(entity view)
 167 {
 168         float frac;
 169         vector gunangles = '0 0 0';
 170         static vector gunangles_prev = '0 0 0';
 171         static vector gunangles_highpass = '0 0 0';
 172         static vector gunangles_adjustment_highpass;
 173         static vector gunangles_adjustment_lowpass;
 174
 175         if (view.csqcmodel_teleported)
 176                 gunangles_prev = view_angles;
 177
 178         // in the highpass, we _store_ the DIFFERENCE to the actual view angles...
 179         gunangles_highpass += gunangles_prev;
 180         PITCH(gunangles_highpass) += 360 * floor((PITCH(view_angles) - PITCH(gunangles_highpass)) / 360 + 0.5);
 181         YAW(gunangles_highpass) += 360 * floor((YAW(view_angles) - YAW(gunangles_highpass)) / 360 + 0.5);
 182         ROLL(gunangles_highpass) += 360 * floor((ROLL(view_angles) - ROLL(gunangles_highpass)) / 360 + 0.5);
 183         frac = avg_factor(autocvar_cl_leanmodel_highpass1);
 184         highpass2_limited(view_angles, frac, autocvar_cl_leanmodel_limit, gunangles_highpass, gunangles);
 185         gunangles_prev = view_angles;
 186         gunangles_highpass -= gunangles_prev;
 187
 188         PITCH(gunangles) *= -autocvar_cl_leanmodel_speed;
 189         YAW(gunangles) *= -autocvar_cl_leanmodel_speed;
 190
 191         // we assume here: PITCH = 0, YAW = 1, ROLL = 2
 192         frac = avg_factor(autocvar_cl_leanmodel_highpass);
 193         highpass2(gunangles, frac, gunangles_adjustment_highpass, gunangles);
 194         frac = avg_factor(autocvar_cl_leanmodel_lowpass);
 195         lowpass2(gunangles, frac, gunangles_adjustment_lowpass, gunangles);
 196
 197         gunangles.x = -gunangles.x; // pitch was inverted, now that actually matters
 198
 199         return gunangles;
 200 }
 201
 202 vector bobmodel_ofs(entity view)
 203 {
 204         bool clonground = !(view.anim_implicit_state & ANIMIMPLICITSTATE_INAIR);
 205         static bool oldonground;
 206         static float hitgroundtime;
 207         if (clonground)
 208         {
 209                 float f = time; // cl.movecmd[0].time
 210                 if (!oldonground)
 211                         hitgroundtime = f;
 212         }
 213         oldonground = clonground;
 214
 215         // calculate for swinging gun model
 216         // the gun bobs when running on the ground, but doesn't bob when you're in the air.
 217         vector gunorg = '0 0 0';
 218         static float bobmodel_scale = 0;
 219         static float time_ofs = 0; // makes the effect always restart in the same way
 220         if (clonground)
 221         {
 222                 if (time - hitgroundtime > 0.05)
 223                         bobmodel_scale = min(1, bobmodel_scale + frametime * 5);
 224         }
 225         else
 226                 bobmodel_scale = max(0, bobmodel_scale - frametime * 5);
 227
 228         float xyspeed = bound(0, vlen(vec2(view.velocity)), 400);
 229         if (bobmodel_scale && xyspeed)
 230         {
 231                 float bspeed = xyspeed * 0.01 * autocvar_cl_viewmodel_scale * bobmodel_scale;
 232                 float s = (time - time_ofs) * autocvar_cl_bobmodel_speed;
 233                 gunorg.y = bspeed * autocvar_cl_bobmodel_side * sin(s);
 234                 gunorg.z = bspeed * autocvar_cl_bobmodel_up * cos(s * 2);
 235         }
 236         else
 237                 time_ofs = time;
 238
 239         return gunorg;
 240 }
 241
 242 void viewmodel_animate(entity this)
 243 {
 244         if (autocvar_chase_active || STAT(HEALTH) <= 0) return;
 245
 246         entity view = CSQCModel_server2csqc(player_localentnum - 1);
 247
 248         if (autocvar_cl_followmodel)
 249         {
 250                 calc_followmodel_ofs(view);
 251                 this.origin += cl_followmodel_ofs;
 252         }
 253
 254         if (autocvar_cl_leanmodel)
 255                 this.angles += leanmodel_ofs(view);
 256
 257         // vertical view bobbing code
 258         // TODO: cl_bob
 259
 260         // horizontal view bobbing code
 261         // TODO: cl_bob2
 262
 263         // fall bobbing code
 264         // causes the view to swing down and back up when touching the ground
 265         // TODO: cl_bobfall
 266
 267         // gun model bobbing code
 268         if (autocvar_cl_bobmodel)
 269                 this.origin += bobmodel_ofs(view);
 270 }
 271
 272 .vector viewmodel_origin, viewmodel_angles;
 273 .float weapon_nextthink;
 274 .float weapon_eta_last;
 275 .float weapon_switchdelay;
 276
 277 .string name_last;
 278
 279 void viewmodel_draw(entity this)
 280 {
 281         if(!this.activeweapon || !autocvar_r_drawviewmodel)
 282                 return;
 283         int mask = (intermission || (STAT(HEALTH) <= 0) || autocvar_chase_active) ? 0 : MASK_NORMAL;
 284         float a = ((autocvar_cl_viewmodel_alpha) ? bound(-1, autocvar_cl_viewmodel_alpha, this.m_alpha) : this.m_alpha);
 285         int wepskin = this.m_skin;
 286         bool invehicle = player_localentnum > maxclients;
 287         if (invehicle) a = -1;
 288         Weapon wep = this.activeweapon;
 289         int c = entcs_GetClientColors(current_player);
 290         vector g = weaponentity_glowmod(wep, NULL, c, this);
 291         entity me = CSQCModel_server2csqc(player_localentnum - 1);
 292         int fx = ((me.csqcmodel_effects & EFMASK_CHEAP)
 293                 | EF_NODEPTHTEST)
 294                 &~ (EF_FULLBRIGHT); // can mask team color, so get rid of it
 295         for (entity e = this; e; e = e.weaponchild)
 296         {
 297                 e.drawmask = mask;
 298                 e.alpha = a;
 299                 e.skin = wepskin;
 300                 e.colormap = 256 + c;  // colormap == 0 is black, c == 0 is white
 301                 e.glowmod = g;
 302                 e.csqcmodel_effects = fx;
 303                 CSQCModel_Effects_Apply(e);
 304         }
 305         if(a >= 0)
 306         {
 307                 string name = wep.mdl;
 308                 string newname = wep.wr_viewmodel(wep, this);
 309                 if(newname)
 310                         name = newname;
 311                 bool swap = name != this.name_last;
 312                 // if (swap)
 313                 {
 314                         this.name_last = name;
 315                         CL_WeaponEntity_SetModel(this, name, swap);
 316                         this.viewmodel_origin = this.origin;
 317                         this.viewmodel_angles = this.angles;
 318                 }
 319                 anim_update(this);
 320                 if ((!this.animstate_override && !this.animstate_looping) || time > this.animstate_endtime)
 321                         anim_set(this, this.anim_idle, true, false, false);
 322         }
 323         float f = 0; // 0..1; 0: fully active
 324         float rate = STAT(WEAPONRATEFACTOR);
 325         float eta = rate ? ((this.weapon_nextthink - time) / rate) : 0;
 326         if (eta <= 0) f = this.weapon_eta_last;
 327         else switch (this.state)
 328         {
 329                 case WS_RAISE:
 330                 {
 331                         f = eta / max(eta, this.weapon_switchdelay);
 332                         break;
 333                 }
 334                 case WS_DROP:
 335                 {
 336                         f = 1 - eta / max(eta, this.weapon_switchdelay);
 337                         break;
 338                 }
 339                 case WS_CLEAR:
 340                 {
 341                         f = 1;
 342                         break;
 343                 }
 344         }
 345         this.weapon_eta_last = f;
 346         this.origin = this.viewmodel_origin;
 347         this.angles = this.viewmodel_angles;
 348         this.angles_x = (-90 * f * f);
 349         viewmodel_animate(this);
 350         MUTATOR_CALLHOOK(DrawViewModel, this);
 351         setorigin(this, this.origin);
 352 }
 353
 354 STATIC_INIT(viewmodel) {
 355     for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 356         viewmodels[slot] = new(viewmodel);
 357 }
 358
 359 vector project_3d_to_2d(vector vec)
 360 {
 361         vec = cs_project(vec);
 362         if(cs_project_is_b0rked > 0)
 363         {
 364                 vec.x *= vid_conwidth / vid_width;
 365                 vec.y *= vid_conheight / vid_height;
 366         }
 367         return vec;
 368 }
 369
 370 bool projected_on_screen(vector screen_pos)
 371 {
 372         return screen_pos.z >= 0
 373                 && screen_pos.x >= 0
 374                 && screen_pos.y >= 0
 375                 && screen_pos.x < vid_conwidth
 376                 && screen_pos.y < vid_conheight;
 377 }
 378
 379 void update_mousepos()
 380 {
 381         mousepos += getmousepos() * autocvar_menu_mouse_speed;
 382         mousepos.x = bound(0, mousepos.x, vid_conwidth);
 383         mousepos.y = bound(0, mousepos.y, vid_conheight);
 384 }
 385
 386 float showfps_prevfps_time;
 387 int showfps_framecounter;
 388
 389 void fpscounter_update()
 390 {
 391         if(!STAT(SHOWFPS))
 392                 return;
 393
 394         float currentTime = gettime(GETTIME_FRAMESTART);
 395
 396         showfps_framecounter += 1;
 397         if(currentTime - showfps_prevfps_time > STAT(SHOWFPS))
 398         {
 399                 float fps = showfps_framecounter / (currentTime - showfps_prevfps_time);
 400                 showfps_framecounter = 0;
 401                 showfps_prevfps_time = currentTime;
 402
 403                 int channel = MSG_C2S;
 404                 WriteHeader(channel, fpsreport);
 405                 WriteShort(channel, bound(0, rint(fps), 32767)); // prevent insane fps values
 406         }
 407 }
 408
 409 STATIC_INIT(fpscounter_init)
 410 {
 411         float currentTime = gettime(GETTIME_FRAMESTART);
 412         showfps_prevfps_time = currentTime; // we must initialize it to avoid an instant low frame sending
 413 }
 414
 415 float avgspeed;
 416 vector GetCurrentFov(float fov)
 417 {
 418         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir;
 419         float velocityzoom, curspeed;
 420         vector v;
 421
 422         zoomsensitivity = autocvar_cl_zoomsensitivity;
 423         zoomfactor = autocvar_cl_zoomfactor;
 424         if(zoomfactor < 1 || zoomfactor > 30)
 425                 zoomfactor = 2.5;
 426         zoomspeed = autocvar_cl_zoomspeed;
 427         if (zoomspeed >= 0 && (zoomspeed < 0.5 || zoomspeed > 16))
 428                 zoomspeed = 3.5;
 429
 430         zoomdir = button_zoom;
 431
 432         if(hud == HUD_NORMAL && !spectatee_status)
 433         {
 434                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 435                 {
 436                         entity wepent = viewmodels[slot];
 437                         if(wepent.switchweapon != wepent.activeweapon)
 438                                 continue;
 439                         Weapon wep = wepent.activeweapon;
 440                         if(wep != WEP_Null && wep.wr_zoomdir)
 441                         {
 442                                 bool do_zoom = wep.wr_zoomdir(wep); // TODO: merge this with wr_zoom?
 443                                 zoomdir += do_zoom;
 444                         }
 445                 }
 446         }
 447         if(spectatee_status > 0 || isdemo())
 448         {
 449                 if(spectatorbutton_zoom)
 450                 {
 451                         if(zoomdir)
 452                                 zoomdir = 0;
 453                         else
 454                                 zoomdir = 1;
 455                 }
 456                 // fteqcc failed twice here already, don't optimize this
 457         }
 458
 459         if(zoomdir) { zoomin_effect = 0; }
 460
 461         if (spectatee_status > 0 && STAT(CAMERA_SPECTATOR) == 2)
 462         {
 463                 current_viewzoom = 1;
 464         }
 465         else if (camera_active)
 466         {
 467                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 468         }
 469         else if(autocvar_cl_spawnzoom && zoomin_effect)
 470         {
 471                 float spawnzoomfactor = bound(1, autocvar_cl_spawnzoom_factor, 30);
 472
 473                 current_viewzoom += (autocvar_cl_spawnzoom_speed * (spawnzoomfactor - current_viewzoom) * drawframetime);
 474                 current_viewzoom = bound(1 / spawnzoomfactor, current_viewzoom, 1);
 475                 if(current_viewzoom == 1) { zoomin_effect = 0; }
 476         }
 477         else
 478         {
 479                 if(zoomspeed < 0) // instant zoom
 480                 {
 481                         if(zoomdir)
 482                                 current_viewzoom = 1 / zoomfactor;
 483                         else
 484                                 current_viewzoom = 1;
 485                 }
 486                 else
 487                 {
 488                         if(zoomdir)
 489                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 490                         else
 491                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 492                 }
 493         }
 494
 495         if(almost_equals(current_viewzoom, 1))
 496                 current_zoomfraction = 0;
 497         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 498                 current_zoomfraction = 1;
 499         else
 500                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 501
 502         if(zoomsensitivity < 1)
 503                 setsensitivityscale(current_viewzoom ** (1 - zoomsensitivity));
 504         else
 505                 setsensitivityscale(1);
 506
 507         if(autocvar_cl_velocityzoom_enabled && autocvar_cl_velocityzoom_type && !autocvar_cl_lockview) // _type = 0 disables velocity zoom too
 508         {
 509                 if (intermission || (spectatee_status > 0 && STAT(CAMERA_SPECTATOR) == 2))
 510                         curspeed = 0;
 511                 else
 512                 {
 513                         vector forward, right, up;
 514                         MAKE_VECTORS(view_angles, forward, right, up);
 515                         v = pmove_vel;
 516                         if(csqcplayer)
 517                                 v = csqcplayer.velocity;
 518
 519                         switch(autocvar_cl_velocityzoom_type)
 520                         {
 521                                 case 3: curspeed = max(0, forward * v); break;
 522                                 case 2: curspeed = (forward * v); break;
 523                                 case 1: default: curspeed = vlen(v); break;
 524                         }
 525                 }
 526
 527                 velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoom_time), 1); // speed at which the zoom adapts to player velocity
 528                 avgspeed = avgspeed * (1 - velocityzoom) + (curspeed / autocvar_cl_velocityzoom_speed) * velocityzoom;
 529                 velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom_factor / 1) * 1);
 530
 531                 //print(ftos(avgspeed), " avgspeed, ", ftos(curspeed), " curspeed, ", ftos(velocityzoom), " return\n"); // for debugging
 532         }
 533         else
 534                 velocityzoom = 1;
 535
 536         float frustumx, frustumy, fovx, fovy;
 537         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 538         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 539         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 540         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 541
 542         return '1 0 0' * fovx + '0 1 0' * fovy;
 543 }
 544
 545 vector GetViewLocationFOV(float fov)
 546 {
 547         float frustumy = tan(fov * M_PI / 360.0) * 0.75;
 548         float frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 549         float fovx = atan2(frustumx, 1) / M_PI * 360.0;
 550         float fovy = atan2(frustumy, 1) / M_PI * 360.0;
 551         return '1 0 0' * fovx + '0 1 0' * fovy;
 552 }
 553
 554 vector GetOrthoviewFOV(vector ov_worldmin, vector ov_worldmax, vector ov_mid, vector ov_org)
 555 {
 556         float fovx, fovy;
 557         float width = (ov_worldmax.x - ov_worldmin.x);
 558         float height = (ov_worldmax.y - ov_worldmin.y);
 559         float distance_to_middle_of_world = vlen(ov_mid - ov_org);
 560         fovx = atan2(width/2, distance_to_middle_of_world) / M_PI * 360.0;
 561         fovy = atan2(height/2, distance_to_middle_of_world) / M_PI * 360.0;
 562         return '1 0 0' * fovx + '0 1 0' * fovy;
 563 }
 564
 565 // this function must match W_SetupShot!
 566
 567 bool minigame_wasactive;
 568
 569 float camera_mode;
 570 const float CAMERA_FREE = 1;
 571 const float CAMERA_CHASE = 2;
 572 string NextFrameCommand;
 573
 574 vector freeze_org, freeze_ang;
 575 entity nightvision_noise, nightvision_noise2;
 576
 577 float myhealth, myhealth_prev;
 578 float myhealth_flash;
 579
 580 float old_blurradius, old_bluralpha;
 581 float old_sharpen_intensity;
 582
 583 vector myhealth_gentlergb;
 584
 585 float contentavgalpha, liquidalpha_prev;
 586 vector liquidcolor_prev;
 587
 588 float eventchase_current_distance;
 589 float eventchase_running;
 590 int WantEventchase(entity this, bool want_vehiclechase)
 591 {
 592         if(autocvar_cl_orthoview)
 593                 return 0;
 594         if(STAT(GAME_STOPPED) || intermission)
 595                 return 1;
 596         if(this.viewloc)
 597                 return 1;
 598         if(spectatee_status >= 0)
 599         {
 600                 if(want_vehiclechase)
 601                         return 1;
 602                 if(MUTATOR_CALLHOOK(WantEventchase, this))
 603                         return 1;
 604                 if(autocvar_cl_eventchase_frozen && STAT(FROZEN))
 605                         return 1;
 606                 if(autocvar_cl_eventchase_death && (STAT(HEALTH) <= 0))
 607                 {
 608                         if(autocvar_cl_eventchase_death == 2)
 609                         {
 610                                 // don't stop eventchase once it's started (even if velocity changes afterwards)
 611                                 if(this.velocity == '0 0 0' || eventchase_running)
 612                                         return 1;
 613                         }
 614                         else return 1;
 615                 }
 616                 if (spectatee_status > 0 && autocvar_cl_eventchase_spectated_change)
 617                 {
 618                         if (time <= spectatee_status_changed_time + min(3, autocvar_cl_eventchase_spectated_change_time))
 619                                 return 1;
 620                         else if (eventchase_running)
 621                                 return -1; // disable chase_active while eventchase is still enabled so to avoid a glicth
 622                 }
 623         }
 624         return 0;
 625 }
 626
 627 void View_EventChase(entity this)
 628 {
 629         // event chase camera
 630         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
 631         {
 632                 if(STAT(CAMERA_SPECTATOR))
 633                 {
 634                         if(spectatee_status > 0)
 635                         {
 636                                 if(!autocvar_chase_active)
 637                                 {
 638                                         cvar_set("chase_active", "-2");
 639                                         return;
 640                                 }
 641                         }
 642                         else if(autocvar_chase_active == -2)
 643                                 cvar_set("chase_active", "0");
 644
 645                         if(autocvar_chase_active == -2)
 646                                 return;
 647                 }
 648                 else if(autocvar_chase_active == -2)
 649                         cvar_set("chase_active", "0");
 650
 651                 bool vehicle_chase = (hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0));
 652
 653                 float vehicle_viewdist = 0;
 654                 vector vehicle_viewofs = '0 0 0';
 655
 656                 if(vehicle_chase)
 657                 {
 658                         if(hud != HUD_BUMBLEBEE_GUN)
 659                         {
 660                                 Vehicle info = REGISTRY_GET(Vehicles, hud);
 661                                 vehicle_viewdist = info.height;
 662                                 vehicle_viewofs = info.view_ofs;
 663                                 if(vehicle_viewdist < 0) // when set below 0, this vehicle doesn't use third person view (gunner slots)
 664                                         vehicle_chase = false;
 665                         }
 666                         else
 667                                 vehicle_chase = false;
 668                 }
 669
 670                 int eventchase = WantEventchase(this, vehicle_chase);
 671                 if (eventchase)
 672                 {
 673                         vector current_view_origin_override = '0 0 0';
 674                         vector view_offset_override = '0 0 0';
 675                         float chase_distance_override = 0;
 676                         bool custom_eventchase = MUTATOR_CALLHOOK(CustomizeEventchase, this);
 677                         if(custom_eventchase)
 678                         {
 679                                 current_view_origin_override = M_ARGV(0, vector);
 680                                 view_offset_override = M_ARGV(1, vector);
 681                                 chase_distance_override = M_ARGV(0, float);
 682                         }
 683                         eventchase_running = true;
 684
 685                         // make special vector since we can't use view_origin (It is one frame old as of this code, it gets set later with the results this code makes.)
 686                         vector current_view_origin = (csqcplayer ? csqcplayer.origin : pmove_org);
 687                         if (custom_eventchase)
 688                                 current_view_origin = current_view_origin_override;
 689
 690                         // detect maximum viewoffset and use it
 691                         vector view_offset = autocvar_cl_eventchase_viewoffset;
 692                         if(vehicle_chase)
 693                         {
 694                                 if(vehicle_viewofs)
 695                                         view_offset = vehicle_viewofs;
 696                                 else
 697                                         view_offset = autocvar_cl_eventchase_vehicle_viewoffset;
 698                         }
 699                         if (custom_eventchase)
 700                                 view_offset = view_offset_override;
 701
 702                         if(view_offset)
 703                         {
 704                                 WarpZone_TraceLine(current_view_origin, current_view_origin + view_offset + ('0 0 1' * autocvar_cl_eventchase_maxs.z), MOVE_WORLDONLY, this);
 705                                 if(trace_fraction == 1) { current_view_origin += view_offset; }
 706                                 else { current_view_origin.z += max(0, (trace_endpos.z - current_view_origin.z) - autocvar_cl_eventchase_maxs.z); }
 707                         }
 708
 709                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
 710                         // Ideally, there should be another way to enable third person cameras, such as through setproperty()
 711                         // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
 712                         if(!autocvar_chase_active) { cvar_set("chase_active", "-1"); }
 713
 714                         // make the camera smooth back
 715                         float chase_distance = autocvar_cl_eventchase_distance;
 716                         if(vehicle_chase)
 717                         {
 718                                 if(vehicle_viewofs)
 719                                         chase_distance = vehicle_viewdist;
 720                                 else
 721                                         chase_distance = autocvar_cl_eventchase_vehicle_distance;
 722                         }
 723                         if (custom_eventchase)
 724                                 chase_distance = chase_distance_override;
 725
 726                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < chase_distance)
 727                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (chase_distance - eventchase_current_distance) * frametime; // slow down the further we get
 728                         else if(eventchase_current_distance != chase_distance)
 729                                 eventchase_current_distance = chase_distance;
 730
 731                         vector forward, right, up;
 732                         MAKE_VECTORS(view_angles, forward, right, up);
 733
 734                         vector eventchase_target_origin = (current_view_origin - (forward * eventchase_current_distance));
 735                         WarpZone_TraceBox(current_view_origin, autocvar_cl_eventchase_mins, autocvar_cl_eventchase_maxs, eventchase_target_origin, MOVE_WORLDONLY, this);
 736
 737                         // If the boxtrace fails, revert back to line tracing.
 738                         if(!this.viewloc)
 739                         if(trace_startsolid)
 740                         {
 741                                 eventchase_target_origin = (current_view_origin - (forward * eventchase_current_distance));
 742                                 WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, this);
 743                                 setproperty(VF_ORIGIN, (trace_endpos - (forward * autocvar_cl_eventchase_mins.z)));
 744                         }
 745                         else { setproperty(VF_ORIGIN, trace_endpos); }
 746
 747                         if(!this.viewloc)
 748                                 setproperty(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
 749                 }
 750
 751                 if (eventchase <= 0 && autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
 752                 {
 753                         eventchase_running = false;
 754                         cvar_set("chase_active", "0");
 755                         eventchase_current_distance = 0; // start from 0 next time
 756                 }
 757         }
 758         // workaround for camera stuck between player's legs when using chase_active 1
 759         // because the engine stops updating the chase_active camera when the game ends
 760         else if(intermission)
 761         {
 762                 cvar_settemp("chase_active", "-1");
 763                 eventchase_current_distance = 0;
 764         }
 765 }
 766
 767 vector damage_blurpostprocess, content_blurpostprocess;
 768
 769 void UpdateDamage()
 770 {
 771         // accumulate damage with each stat update
 772         static float damage_total_prev = 0;
 773         float damage_total = STAT(DAMAGE_DEALT_TOTAL);
 774         float unaccounted_damage_new = COMPARE_INCREASING(damage_total, damage_total_prev);
 775         damage_total_prev = damage_total;
 776
 777         static float damage_dealt_time_prev = 0;
 778         float damage_dealt_time = STAT(HIT_TIME);
 779         if (damage_dealt_time != damage_dealt_time_prev)
 780         {
 781                 unaccounted_damage += unaccounted_damage_new;
 782                 //LOG_TRACE("dmg total: ", ftos(unaccounted_damage), " (+", ftos(unaccounted_damage_new), ")");
 783         }
 784         damage_dealt_time_prev = damage_dealt_time;
 785
 786         // prevent hitsound when switching spectatee
 787         static float spectatee_status_prev = 0;
 788         if (spectatee_status != spectatee_status_prev)
 789                 unaccounted_damage = 0;
 790         spectatee_status_prev = spectatee_status;
 791 }
 792
 793 void HitSound()
 794 {
 795         // varying sound pitch
 796
 797         bool have_arc = false;
 798         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 799         {
 800                 entity wepent = viewmodels[slot];
 801
 802                 if(wepent.activeweapon == WEP_ARC)
 803                         have_arc = true;
 804         }
 805
 806         static float hitsound_time_prev = 0;
 807         // HACK: the only way to get the arc to sound consistent with pitch shift is to ignore cl_hitsound_antispam_time
 808         bool arc_hack = have_arc && autocvar_cl_hitsound >= 2;
 809         if (arc_hack || COMPARE_INCREASING(time, hitsound_time_prev) > autocvar_cl_hitsound_antispam_time)
 810         {
 811                 if (autocvar_cl_hitsound && unaccounted_damage)
 812                 {
 813                         float pitch_shift = 1;
 814                         if (autocvar_cl_hitsound == 2 || autocvar_cl_hitsound == 3)
 815                         {
 816                                 // customizable gradient function that crosses (0,a), (c,1) and asymptotically approaches b
 817                                 float a = autocvar_cl_hitsound_max_pitch;
 818                                 float b = autocvar_cl_hitsound_min_pitch;
 819                                 float c = autocvar_cl_hitsound_nom_damage;
 820                                 float d = unaccounted_damage;
 821                                 pitch_shift = (b*d*(a-1) + a*c*(1-b)) / (d*(a-1) + c*(1-b));
 822
 823                                 // if pitch shift is reversed, mirror in (max-min)/2 + min
 824                                 if (autocvar_cl_hitsound == 3)
 825                                 {
 826                                         float mirror_value = (a-b)/2 + b;
 827                                         pitch_shift = mirror_value + (mirror_value - pitch_shift);
 828                                 }
 829                         }
 830
 831                         //LOG_TRACE("dmg total (dmg): ", ftos(unaccounted_damage), " , pitch shift: ", ftos(pitch_shift));
 832
 833                         // todo: avoid very long and very short sounds from wave stretching using different sound files? seems unnecessary
 834                         // todo: normalize sound pressure levels? seems unnecessary
 835
 836                         sound7(NULL, CH_INFO, SND(HIT), VOL_BASE, ATTN_NONE, pitch_shift * 100, 0);
 837                 }
 838                 unaccounted_damage = 0;
 839                 hitsound_time_prev = time;
 840         }
 841
 842         static float typehit_time_prev = 0;
 843         float typehit_time = STAT(TYPEHIT_TIME);
 844         if (COMPARE_INCREASING(typehit_time, typehit_time_prev) > autocvar_cl_hitsound_antispam_time)
 845         {
 846                 sound(NULL, CH_INFO, SND_TYPEHIT, VOL_BASE, ATTN_NONE);
 847                 typehit_time_prev = typehit_time;
 848         }
 849
 850         static float kill_time_prev = 0;
 851         float kill_time = STAT(KILL_TIME);
 852         if (COMPARE_INCREASING(kill_time, kill_time_prev) > autocvar_cl_hitsound_antispam_time)
 853         {
 854                 sound(NULL, CH_INFO, SND_KILL, VOL_BASE, ATTN_NONE);
 855                 kill_time_prev = kill_time;
 856         }
 857 }
 858
 859 void HUD_Draw(entity this)
 860 {
 861         // if we don't know gametype and scores yet avoid drawing the scoreboard
 862         // also in the very first frames, player state may be inconsistent so avoid drawing the hud at all
 863         // e.g. since initial player's health is 0 hud would display the hud_damage effect,
 864         // cl_deathscoreboard would show the scoreboard and so on
 865         if(!gametype)
 866                 return;
 867
 868         Hud_Dynamic_Frame();
 869
 870         if(!intermission)
 871         if (MUTATOR_CALLHOOK(HUD_Draw_overlay))
 872         {
 873                 drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), M_ARGV(0, vector), autocvar_hud_colorflash_alpha * M_ARGV(1, float), DRAWFLAG_ADDITIVE);
 874         }
 875         else if(STAT(FROZEN))
 876         {
 877                 vector col = '0.25 0.90 1';
 878                 float col_fade = max(0, STAT(REVIVE_PROGRESS) * 2 - 1);
 879                 float alpha_fade = 0.3 + 0.7 * (1 - max(0, STAT(REVIVE_PROGRESS) * 4 - 3));
 880                 if(col_fade)
 881                         col += vec3(col_fade, -col_fade, -col_fade);
 882                 drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), col, autocvar_hud_colorflash_alpha * alpha_fade, DRAWFLAG_ADDITIVE);
 883         }
 884
 885         HUD_Scale_Enable();
 886         if(!intermission)
 887         if(STAT(NADE_TIMER) && autocvar_cl_nade_timer) // give nade top priority, as it's a matter of life and death
 888         {
 889                 vector col = '0.25 0.90 1' + vec3(STAT(NADE_TIMER), -STAT(NADE_TIMER), -STAT(NADE_TIMER));
 890                 DrawCircleClippedPic(vec2(0.5 * vid_conwidth, 0.6 * vid_conheight), 0.1 * vid_conheight, "gfx/crosshair_ring", STAT(NADE_TIMER), col, autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
 891                 drawstring_aspect(eY * 0.64 * vid_conheight, ((autocvar_cl_nade_timer == 2) ? _("Nade timer") : ""), vec2(vid_conwidth, 0.025 * vid_conheight), '1 1 1', 1, DRAWFLAG_NORMAL);
 892         }
 893         else if(STAT(CAPTURE_PROGRESS))
 894         {
 895                 DrawCircleClippedPic(vec2(0.5 * vid_conwidth, 0.6 * vid_conheight), 0.1 * vid_conheight, "gfx/crosshair_ring", STAT(CAPTURE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
 896                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Capture progress"), vec2(vid_conwidth, 0.025 * vid_conheight), '1 1 1', 1, DRAWFLAG_NORMAL);
 897         }
 898         else if(STAT(REVIVE_PROGRESS))
 899         {
 900                 DrawCircleClippedPic(vec2(0.5 * vid_conwidth, 0.6 * vid_conheight), 0.1 * vid_conheight, "gfx/crosshair_ring", STAT(REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
 901                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Revival progress"), vec2(vid_conwidth, 0.025 * vid_conheight), '1 1 1', 1, DRAWFLAG_NORMAL);
 902         }
 903         HUD_Scale_Disable();
 904
 905         if(autocvar_r_letterbox == 0)
 906                 if(autocvar_viewsize < 120)
 907                 {
 908                         if(!MUTATOR_CALLHOOK(DrawScoreboardAccuracy))
 909                                 Accuracy_LoadLevels();
 910
 911                         HUD_Main();
 912                         HUD_Scale_Disable();
 913                 }
 914
 915         // crosshair goes VERY LAST
 916         UpdateDamage();
 917         HUD_Crosshair(this);
 918         HitSound();
 919 }
 920
 921 void ViewLocation_Mouse()
 922 {
 923         if(spectatee_status)
 924                 return; // don't draw it as spectator!
 925
 926         viewloc_mousepos += getmousepos() * autocvar_menu_mouse_speed;
 927         viewloc_mousepos.x = bound(0, viewloc_mousepos.x, vid_conwidth);
 928         viewloc_mousepos.y = bound(0, viewloc_mousepos.y, vid_conheight);
 929
 930         //float cursor_alpha = 1 - autocvar__menu_alpha;
 931         //cursor_type = CURSOR_NORMAL;
 932         //draw_cursor(viewloc_mousepos, '0.5 0.5 0', "/cursor_move", '1 1 1', cursor_alpha);
 933 }
 934
 935 void HUD_Cursor_Show()
 936 {
 937         float cursor_alpha = 1 - autocvar__menu_alpha;
 938         if(cursor_type == CURSOR_NORMAL)
 939                 draw_cursor_normal(mousepos, '1 1 1', cursor_alpha);
 940         else if(cursor_type == CURSOR_MOVE)
 941                 draw_cursor(mousepos, '0.5 0.5 0', "/cursor_move", '1 1 1', cursor_alpha);
 942         else if(cursor_type == CURSOR_RESIZE)
 943                 draw_cursor(mousepos, '0.5 0.5 0', "/cursor_resize", '1 1 1', cursor_alpha);
 944         else if(cursor_type == CURSOR_RESIZE2)
 945                 draw_cursor(mousepos, '0.5 0.5 0', "/cursor_resize2", '1 1 1', cursor_alpha);
 946 }
 947
 948 void HUD_Mouse(entity player)
 949 {
 950         if(autocvar__menu_alpha == 1)
 951                 return;
 952
 953         if(!cursor_active)
 954         {
 955                 if(player.viewloc && (player.viewloc.spawnflags & VIEWLOC_FREEAIM))
 956                         ViewLocation_Mouse(); // NOTE: doesn't use cursormode
 957                 return;
 958         }
 959
 960         if (cursor_active == -1) // starting to display the cursor
 961         {
 962                 // since HUD_Mouse is called by CSQC_UpdateView before CSQC_InputEvent,
 963                 // in the first frame mousepos is the mouse position of the last time
 964                 // the cursor was displayed, thus we ignore it to avoid a glictch
 965                 cursor_active = 1;
 966                 return;
 967         }
 968
 969         if(!autocvar_hud_cursormode)
 970                 update_mousepos();
 971
 972         cursor_type = CURSOR_NORMAL;
 973         if(autocvar__hud_configure)
 974                 HUD_Panel_Mouse();
 975         else
 976         {
 977                 if (HUD_MinigameMenu_IsOpened())
 978                         HUD_Minigame_Mouse();
 979                 if (QuickMenu_IsOpened())
 980                         QuickMenu_Mouse();
 981                 if (HUD_Radar_Clickable())
 982                         HUD_Radar_Mouse();
 983         }
 984
 985         prevMouseClicked = mouseClicked;
 986
 987         HUD_Cursor_Show();
 988 }
 989
 990 void View_NightVision()
 991 {
 992         if(!(autocvar_r_fakelight >= 2 || autocvar_r_fullbright) || (serverflags & SERVERFLAG_ALLOW_FULLBRIGHT))
 993                 return;
 994
 995         // apply night vision effect
 996         vector tc_00, tc_01, tc_10, tc_11;
 997         vector rgb = '0 0 0';
 998         float a;
 999
1000         if(!nightvision_noise)
1001         {
1002                 nightvision_noise = new(nightvision_noise);
1003         }
1004         if(!nightvision_noise2)
1005         {
1006                 nightvision_noise2 = new(nightvision_noise2);
1007         }
1008
1009         // color tint in yellow
1010         drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
1011
1012         // draw BG
1013         a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
1014         rgb = '1 1 1';
1015         tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
1016         tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
1017         tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
1018         //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
1019         tc_11 = tc_01 + tc_10 - tc_00;
1020         R_BeginPolygon("gfx/nightvision-bg", DRAWFLAG_ADDITIVE, true);
1021         R_PolygonVertex('0 0 0', tc_00, rgb, a);
1022         R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
1023         R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
1024         R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
1025         R_EndPolygon();
1026
1027         // draw FG
1028         a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
1029         rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
1030         tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
1031         tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
1032         tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
1033         tc_11 = tc_01 + tc_10 - tc_00;
1034         R_BeginPolygon("gfx/nightvision-fg", DRAWFLAG_ADDITIVE, true);
1035         R_PolygonVertex('0 0 0', tc_00, rgb, a);
1036         R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
1037         R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
1038         R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
1039         R_EndPolygon();
1040 }
1041
1042 // visual overlay while in liquids
1043 // provides some effects to the postprocessing function
1044 void HUD_Contents()
1045 {
1046         if(!autocvar_hud_contents || MUTATOR_CALLHOOK(HUD_Contents))
1047                 return;
1048
1049         // improved polyblend
1050         float contentalpha_temp, incontent, liquidalpha, contentfadetime;
1051         vector liquidcolor;
1052
1053         switch(pointcontents(view_origin))
1054         {
1055                 case CONTENT_WATER:
1056                         liquidalpha = autocvar_hud_contents_water_alpha;
1057                         liquidcolor = stov(autocvar_hud_contents_water_color);
1058                         incontent = 1;
1059                         break;
1060
1061                 case CONTENT_LAVA:
1062                         liquidalpha = autocvar_hud_contents_lava_alpha;
1063                         liquidcolor = stov(autocvar_hud_contents_lava_color);
1064                         incontent = 1;
1065                         break;
1066
1067                 case CONTENT_SLIME:
1068                         liquidalpha = autocvar_hud_contents_slime_alpha;
1069                         liquidcolor = stov(autocvar_hud_contents_slime_color);
1070                         incontent = 1;
1071                         break;
1072
1073                 default:
1074                         liquidalpha = 0;
1075                         liquidcolor = '0 0 0';
1076                         incontent = 0;
1077                         break;
1078         }
1079
1080         if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
1081         { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
1082                 contentfadetime = autocvar_hud_contents_fadeintime;
1083                 liquidalpha_prev = liquidalpha;
1084                 liquidcolor_prev = liquidcolor;
1085         }
1086         else
1087                 contentfadetime = autocvar_hud_contents_fadeouttime;
1088
1089         contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
1090         contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
1091
1092         if(contentavgalpha)
1093                 drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
1094
1095         if(autocvar_hud_postprocessing)
1096         {
1097                 if(autocvar_hud_contents_blur && contentavgalpha)
1098                 {
1099                         content_blurpostprocess.x = 1;
1100                         content_blurpostprocess.y = contentavgalpha * autocvar_hud_contents_blur;
1101                         content_blurpostprocess.z = contentavgalpha * autocvar_hud_contents_blur_alpha;
1102                 }
1103                 else
1104                 {
1105                         content_blurpostprocess.x = 0;
1106                         content_blurpostprocess.y = 0;
1107                         content_blurpostprocess.z = 0;
1108                 }
1109         }
1110 }
1111
1112 // visual pain effects on the screen
1113 // provides some effects to the postprocessing function
1114 void HUD_Damage()
1115 {
1116         if(!autocvar_hud_damage || STAT(FROZEN))
1117                 return;
1118
1119         vector splash_pos = '0 0 0', splash_size = '0 0 0';
1120         splash_size.x = max(vid_conwidth, vid_conheight);
1121         splash_size.y = max(vid_conwidth, vid_conheight);
1122         splash_pos.x = (vid_conwidth - splash_size.x) / 2;
1123         splash_pos.y = (vid_conheight - splash_size.y) / 2;
1124
1125         float myhealth_flash_temp;
1126         myhealth = STAT(HEALTH);
1127
1128         // fade out
1129         myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
1130         // add new damage
1131         myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
1132
1133         float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
1134         pain_threshold = autocvar_hud_damage_pain_threshold;
1135         pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
1136         pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
1137
1138         if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
1139         {
1140                 pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
1141         }
1142
1143         myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
1144
1145         if(myhealth_prev < 1)
1146         {
1147                 if(myhealth >= 1)
1148                 {
1149                         myhealth_flash = 0; // just spawned, clear the flash immediately
1150                         myhealth_flash_temp = 0;
1151                 }
1152                 else
1153                 {
1154                         myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
1155                 }
1156         }
1157
1158         if(spectatee_status == -1 || intermission)
1159         {
1160                 myhealth_flash = 0; // observing, or match ended
1161                 myhealth_flash_temp = 0;
1162         }
1163
1164         myhealth_prev = myhealth;
1165
1166         // IDEA: change damage color/picture based on player model for robot/alien species?
1167         // pro: matches model better
1168         // contra: it's not red because blood is red, but because red is an alarming color, so red should stay
1169         // maybe different reddish pics?
1170         if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
1171         {
1172                 if(autocvar_cl_gentle_damage == 2)
1173                 {
1174                         if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
1175                                 myhealth_gentlergb = randomvec();
1176                 }
1177                 else
1178                         myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
1179
1180                 if(myhealth_flash_temp > 0)
1181                         drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
1182         }
1183         else if(myhealth_flash_temp > 0)
1184                 drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
1185
1186         if(autocvar_hud_postprocessing) // we still need to set this anyway even when chase_active is set, this way it doesn't get stuck on.
1187         {
1188                 if(autocvar_hud_damage_blur && myhealth_flash_temp)
1189                 {
1190                         damage_blurpostprocess.x = 1;
1191                         damage_blurpostprocess.y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
1192                         damage_blurpostprocess.z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
1193                 }
1194                 else
1195                 {
1196                         damage_blurpostprocess.x = 0;
1197                         damage_blurpostprocess.y = 0;
1198                         damage_blurpostprocess.z = 0;
1199                 }
1200         }
1201 }
1202
1203 void View_PostProcessing()
1204 {
1205         float e1 = (autocvar_hud_postprocessing_maxbluralpha != 0);
1206         float e2 = (autocvar_hud_powerup != 0);
1207         if(autocvar_hud_postprocessing && (e1 || e2)) // TODO: Remove this code and re-do the postprocess handling in the engine, where it properly belongs.
1208         {
1209                 // enable or disable rendering types if they are used or not
1210                 if(cvar("r_glsl_postprocess_uservec1_enable") != e1) { cvar_set("r_glsl_postprocess_uservec1_enable", ftos(e1)); }
1211                 if(cvar("r_glsl_postprocess_uservec2_enable") != e2) { cvar_set("r_glsl_postprocess_uservec2_enable", ftos(e2)); }
1212
1213                 // blur postprocess handling done first (used by hud_damage and hud_contents)
1214                 if((damage_blurpostprocess.x || content_blurpostprocess.x))
1215                 {
1216                         float blurradius = bound(0, damage_blurpostprocess.y + content_blurpostprocess.y, autocvar_hud_postprocessing_maxblurradius);
1217                         float bluralpha = bound(0, damage_blurpostprocess.z + content_blurpostprocess.z, autocvar_hud_postprocessing_maxbluralpha);
1218                         if(blurradius != old_blurradius || bluralpha != old_bluralpha) // reduce cvar_set spam as much as possible
1219                         {
1220                                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
1221                                 old_blurradius = blurradius;
1222                                 old_bluralpha = bluralpha;
1223                         }
1224                 }
1225                 else if(cvar_string("r_glsl_postprocess_uservec1") != "0 0 0 0") // reduce cvar_set spam as much as possible
1226                 {
1227                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
1228                         old_blurradius = 0;
1229                         old_bluralpha = 0;
1230                 }
1231
1232                 // edge detection postprocess handling done second (used by hud_powerup)
1233                 float sharpen_intensity = 0;
1234                 FOREACH(StatusEffect, it.instanceOfPowerups,
1235                 {
1236                         float powerup_finished = StatusEffects_gettime(it, g_statuseffects) - time;
1237                         if(powerup_finished > 0)
1238                                 sharpen_intensity += powerup_finished;
1239                 });
1240
1241                 sharpen_intensity = bound(0, ((STAT(HEALTH) > 0) ? sharpen_intensity : 0), 5); // Check to see if player is alive (if not, set 0) - also bound to fade out starting at 5 seconds.
1242
1243                 if(autocvar_hud_powerup && sharpen_intensity > 0)
1244                 {
1245                         if(sharpen_intensity != old_sharpen_intensity) // reduce cvar_set spam as much as possible
1246                         {
1247                                 cvar_set("r_glsl_postprocess_uservec2", strcat(ftos((sharpen_intensity / 5) * autocvar_hud_powerup), " ", ftos(-sharpen_intensity * autocvar_hud_powerup), " 0 0"));
1248                                 old_sharpen_intensity = sharpen_intensity;
1249                         }
1250                 }
1251                 else if(cvar_string("r_glsl_postprocess_uservec2") != "0 0 0 0") // reduce cvar_set spam as much as possible
1252                 {
1253                         cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
1254                         old_sharpen_intensity = 0;
1255                 }
1256
1257                 if(cvar("r_glsl_postprocess") == 0)
1258                         cvar_set("r_glsl_postprocess", "2");
1259         }
1260         else if(cvar("r_glsl_postprocess") == 2)
1261                 cvar_set("r_glsl_postprocess", "0");
1262 }
1263
1264 void View_Lock()
1265 {
1266         int lock_type = autocvar_cl_lockview;
1267
1268         if (!autocvar_hud_cursormode
1269                 && ((autocvar__hud_configure && spectatee_status <= 0)
1270                         || intermission > 1
1271                         || HUD_Radar_Clickable()
1272                         || HUD_MinigameMenu_IsOpened()
1273                         || QuickMenu_IsOpened()
1274                 )
1275         )
1276                 lock_type = 1;
1277
1278         // lock_type 1: lock origin and angles
1279         // lock_type 2: lock only origin
1280         if(lock_type >= 1)
1281                 setproperty(VF_ORIGIN, freeze_org);
1282         else
1283                 freeze_org = getpropertyvec(VF_ORIGIN);
1284         if(lock_type == 1)
1285                 setproperty(VF_ANGLES, freeze_ang);
1286         else
1287                 freeze_ang = getpropertyvec(VF_ANGLES);
1288 }
1289
1290 void View_DemoCamera()
1291 {
1292         if(camera_active) // Camera for demo playback
1293         {
1294                 if(autocvar_camera_enable)
1295                         CSQC_Demo_Camera();
1296                 else
1297                 {
1298                         cvar_set("chase_active", ftos(chase_active_backup));
1299                         cvar_set("cl_demo_mousegrab", "0");
1300                         camera_active = false;
1301                 }
1302         }
1303         else
1304         {
1305 #ifdef CAMERATEST
1306                 if(autocvar_camera_enable)
1307 #else
1308                 if(autocvar_camera_enable && isdemo())
1309 #endif
1310                 {
1311                         // Enable required Darkplaces cvars
1312                         chase_active_backup = autocvar_chase_active;
1313                         cvar_set("chase_active", "2");
1314                         cvar_set("cl_demo_mousegrab", "1");
1315                         camera_active = true;
1316                         camera_mode = false;
1317                 }
1318         }
1319 }
1320
1321 #ifdef BLURTEST
1322 void View_BlurTest()
1323 {
1324         if(time > blurtest_time0 && time < blurtest_time1)
1325         {
1326                 float t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
1327                 float r = t * blurtest_radius;
1328                 float f = 1 / (t ** blurtest_power) - 1;
1329
1330                 cvar_set("r_glsl_postprocess", "1");
1331                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
1332         }
1333         else
1334         {
1335                 cvar_set("r_glsl_postprocess", "0");
1336                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
1337         }
1338 }
1339 #endif
1340
1341 void View_CheckButtonStatus()
1342 {
1343         float is_dead = (STAT(HEALTH) <= 0);
1344
1345         // FIXME do we need this hack?
1346         if(isdemo())
1347         {
1348                 // in demos, input_buttons do not work
1349                 button_zoom = (autocvar__togglezoom == "-");
1350         }
1351         else if(button_zoom
1352                 && autocvar_cl_unpress_zoom_on_death
1353                 && (spectatee_status >= 0)
1354                 && (is_dead || intermission))
1355         {
1356                 // no zoom while dead or in intermission please
1357                 localcmd("-zoom\n");
1358                 button_zoom = false;
1359         }
1360
1361         if(autocvar_fov <= 59.5)
1362         {
1363                 if(!zoomscript_caught)
1364                 {
1365                         localcmd("+button9\n");
1366                         zoomscript_caught = 1;
1367                 }
1368         }
1369         else
1370         {
1371                 if(zoomscript_caught)
1372                 {
1373                         localcmd("-button9\n");
1374                         zoomscript_caught = 0;
1375                 }
1376         }
1377
1378         if(active_minigame && HUD_MinigameMenu_IsOpened())
1379         {
1380                 if(!minigame_wasactive)
1381                 {
1382                         localcmd("+button12\n");
1383                         minigame_wasactive = true;
1384                 }
1385         }
1386         else if(minigame_wasactive)
1387         {
1388                 localcmd("-button12\n");
1389                 minigame_wasactive = false;
1390         }
1391
1392         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1393         {
1394                 entity wepent = viewmodels[slot];
1395
1396                 if(wepent.last_switchweapon != wepent.switchweapon)
1397                 {
1398                         weapontime = time;
1399                         wepent.last_switchweapon = wepent.switchweapon;
1400                         if(slot == 0 && button_zoom && autocvar_cl_unpress_zoom_on_weapon_switch)
1401                         {
1402                                 localcmd("-zoom\n");
1403                                 button_zoom = false;
1404                         }
1405                         if(slot == 0 && autocvar_cl_unpress_attack_on_weapon_switch)
1406                         {
1407                                 localcmd("-fire\n");
1408                                 localcmd("-fire2\n");
1409                                 button_attack2 = false;
1410                         }
1411                 }
1412                 if(wepent.last_activeweapon != wepent.activeweapon)
1413                 {
1414                         wepent.last_activeweapon = wepent.activeweapon;
1415
1416                         entity e = wepent.activeweapon;
1417                         if(e.netname != "")
1418                                 localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
1419                         else if(slot == 0)
1420                                 localcmd("\ncl_hook_activeweapon none\n");
1421                 }
1422         }
1423 }
1424
1425 bool ov_enabled;
1426 float oldr_nearclip;
1427 float oldr_farclip_base;
1428 float oldr_farclip_world;
1429 float oldr_novis;
1430 float oldr_useportalculling;
1431 float oldr_useinfinitefarclip;
1432 vector ov_org = '0 0 0';
1433 vector ov_mid = '0 0 0';
1434 vector ov_worldmin = '0 0 0';
1435 vector ov_worldmax = '0 0 0';
1436
1437 void View_Ortho()
1438 {
1439         ov_org = '0 0 0';
1440         ov_mid = '0 0 0';
1441         ov_worldmin = '0 0 0';
1442         ov_worldmax = '0 0 0';
1443         if(autocvar_cl_orthoview)
1444         {
1445                 ov_worldmin = mi_picmin;
1446                 ov_worldmax = mi_picmax;
1447
1448                 float ov_width = (ov_worldmax.x - ov_worldmin.x);
1449                 float ov_height = (ov_worldmax.y - ov_worldmin.y);
1450                 float ov_distance = (max(vid_width, vid_height) * max(ov_width, ov_height));
1451
1452                 ov_mid = ((ov_worldmax + ov_worldmin) * 0.5);
1453                 ov_org = vec3(ov_mid.x, ov_mid.y, (ov_mid.z + ov_distance));
1454
1455                 float ov_nearest = vlen(ov_org - vec3(
1456                         bound(ov_worldmin.x, ov_org.x, ov_worldmax.x),
1457                         bound(ov_worldmin.y, ov_org.y, ov_worldmax.y),
1458                         bound(ov_worldmin.z, ov_org.z, ov_worldmax.z)
1459                 ));
1460
1461                 float ov_furthest = 0;
1462                 float dist = 0;
1463
1464                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1465                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1466                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1467                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1468                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1469                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1470                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1471                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1472
1473                 if(!ov_enabled)
1474                 {
1475                         oldr_nearclip = cvar("r_nearclip");
1476                         oldr_farclip_base = cvar("r_farclip_base");
1477                         oldr_farclip_world = cvar("r_farclip_world");
1478                         oldr_novis = cvar("r_novis");
1479                         oldr_useportalculling = cvar("r_useportalculling");
1480                         oldr_useinfinitefarclip = cvar("r_useinfinitefarclip");
1481                 }
1482
1483                 cvar_settemp("r_nearclip", ftos(ov_nearest));
1484                 cvar_settemp("r_farclip_base", ftos(ov_furthest));
1485                 cvar_settemp("r_farclip_world", "0");
1486                 cvar_settemp("r_novis", "1");
1487                 cvar_settemp("r_useportalculling", "0");
1488                 cvar_settemp("r_useinfinitefarclip", "0");
1489
1490                 setproperty(VF_ORIGIN, ov_org);
1491                 setproperty(VF_ANGLES, '90 0 0');
1492
1493                 ov_enabled = true;
1494
1495                 #if 0
1496                 LOG_INFOF("OrthoView: org = %s, angles = %s, distance = %f, nearest = %f, furthest = %f",
1497                         vtos(ov_org),
1498                         vtos(getpropertyvec(VF_ANGLES)),
1499                         ov_distance,
1500                         ov_nearest,
1501                         ov_furthest);
1502                 #endif
1503         }
1504         else
1505         {
1506                 if(ov_enabled)
1507                 {
1508                         cvar_set("r_nearclip", ftos(oldr_nearclip));
1509                         cvar_set("r_farclip_base", ftos(oldr_farclip_base));
1510                         cvar_set("r_farclip_world", ftos(oldr_farclip_world));
1511                         cvar_set("r_novis", ftos(oldr_novis));
1512                         cvar_set("r_useportalculling", ftos(oldr_useportalculling));
1513                         cvar_set("r_useinfinitefarclip", ftos(oldr_useinfinitefarclip));
1514                 }
1515                 ov_enabled = false;
1516         }
1517 }
1518
1519 void View_UpdateFov()
1520 {
1521         vector fov;
1522         if(autocvar_cl_orthoview)
1523                 fov = GetOrthoviewFOV(ov_worldmin, ov_worldmax, ov_mid, ov_org);
1524         else if(csqcplayer.viewloc)
1525                 fov = GetViewLocationFOV(110); // enforce 110 fov, so things don't look odd
1526         else
1527                 fov = GetCurrentFov(autocvar_fov);
1528
1529         setproperty(VF_FOV, fov);
1530 }
1531
1532 void CSQC_UpdateView(entity this, float w, float h)
1533 {
1534         TC(int, w); TC(int, h);
1535
1536         execute_next_frame();
1537
1538         ++framecount;
1539
1540         stats_get();
1541         hud = STAT(HUD);
1542
1543         ReplicateVars(false);
1544         if (ReplicateVars_NOT_SENDING())
1545                 ReplicateVars_DELAY(0.8 + random() * 0.4); // no need to check cvars every frame
1546
1547         HUD_Scale_Disable();
1548
1549         if(autocvar__hud_showbinds_reload) // menu can set this one
1550         {
1551                 db_close(binddb);
1552                 binddb = db_create();
1553                 cvar_set("_hud_showbinds_reload", "0");
1554         }
1555
1556         if(checkextension("DP_CSQC_MINFPS_QUALITY"))
1557                 view_quality = getproperty(VF_MINFPS_QUALITY);
1558         else
1559                 view_quality = 1;
1560
1561         button_attack2 = PHYS_INPUT_BUTTON_ATCK2(this);
1562         button_zoom = PHYS_INPUT_BUTTON_ZOOM(this);
1563
1564         vector vf_size = getpropertyvec(VF_SIZE);
1565         vector vf_min = getpropertyvec(VF_MIN);
1566         vid_width = vf_size.x;
1567         vid_height = vf_size.y;
1568
1569         ticrate = STAT(MOVEVARS_TICRATE) * STAT(MOVEVARS_TIMESCALE);
1570
1571         if (autocvar_chase_active)
1572         {
1573                 // in first person view if r_drawviewmodel is off weapon isn't visible
1574                 // and server doesn't throw any casing
1575                 // switching to 3rd person view r_drawviewmodel is set to -1 to let know the server casings
1576                 // can be thrown for self since own weapon model is visible
1577                 if (autocvar_r_drawviewmodel == 0 && STAT(HEALTH) > 0)
1578                         cvar_set("r_drawviewmodel", "-1");
1579         }
1580         else
1581         {
1582                 if (autocvar_r_drawviewmodel < 0)
1583                         cvar_set("r_drawviewmodel", "0");
1584         }
1585
1586         WaypointSprite_Load();
1587
1588         CSQCPlayer_SetCamera();
1589
1590         if(player_localentnum <= maxclients) // is it a client?
1591                 current_player = player_localentnum - 1;
1592         else // then player_localentnum is the vehicle I'm driving
1593                 current_player = player_localnum;
1594         myteam = entcs_GetTeam(current_player);
1595
1596         // abused multiple places below
1597         entity local_player = ((csqcplayer) ? csqcplayer : CSQCModel_server2csqc(player_localentnum - 1));
1598         if(!local_player)
1599                 local_player = this; // fall back!
1600
1601         View_EventChase(local_player);
1602
1603         // do lockview after event chase camera so that it still applies whenever necessary.
1604         View_Lock();
1605
1606         WarpZone_FixView();
1607         //WarpZone_FixPMove();
1608
1609         View_Ortho();
1610
1611         // run viewmodel_draw before updating view_angles to the angles calculated by WarpZone_FixView
1612         // viewmodel_draw needs to use the view_angles set by the engine on every CSQC_UpdateView call
1613         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1614                 viewmodel_draw(viewmodels[slot]);
1615
1616         // Render the Scene
1617         view_origin = getpropertyvec(VF_ORIGIN);
1618         view_angles = getpropertyvec(VF_ANGLES);
1619         MAKE_VECTORS(view_angles, view_forward, view_right, view_up);
1620
1621 #ifdef BLURTEST
1622         View_BlurTest();
1623 #endif
1624
1625         TargetMusic_Advance();
1626         Fog_Force();
1627         fpscounter_update();
1628
1629         if(drawtime == 0)
1630                 drawframetime = 0.01666667; // when we don't know fps yet, we assume 60fps
1631         else
1632                 drawframetime = bound(0.000001, time - drawtime, 1);
1633         drawtime = time;
1634
1635         // watch for gametype changes here...
1636         // in ParseStuffCMD the cmd isn't executed yet :/
1637         // might even be better to add the gametype to TE_CSQC_INIT...?
1638         if(!postinit)
1639                 PostInit();
1640
1641         if(intermission && !intermission_time)
1642                 intermission_time = time;
1643
1644         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
1645         {
1646                 if(calledhooks & HOOK_START)
1647                 {
1648                         localcmd("\ncl_hook_gameend\n");
1649                         calledhooks |= HOOK_END;
1650                 }
1651         }
1652
1653         Announcer();
1654
1655         View_CheckButtonStatus();
1656
1657         ColorTranslateMode = autocvar_cl_stripcolorcodes;
1658
1659         // ALWAYS Clear Current Scene First
1660         clearscene();
1661
1662         setproperty(VF_ORIGIN, view_origin);
1663         setproperty(VF_ANGLES, view_angles);
1664
1665         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
1666         setproperty(VF_SIZE, vf_size);
1667         setproperty(VF_MIN, vf_min);
1668
1669         // Assign Standard Viewflags
1670         // Draw the World (and sky)
1671         setproperty(VF_DRAWWORLD, 1);
1672
1673         // Set the console size vars
1674         vid_conwidth = autocvar_vid_conwidth;
1675         vid_conheight = autocvar_vid_conheight;
1676         vid_pixelheight = autocvar_vid_pixelheight;
1677
1678         View_UpdateFov();
1679
1680         View_DemoCamera();
1681
1682         // Draw the Crosshair
1683         setproperty(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
1684
1685         // Draw the Engine Status Bar (the default Quake HUD)
1686         setproperty(VF_DRAWENGINESBAR, 0);
1687
1688         // Update the mouse position
1689         /*
1690            mousepos_x = vid_conwidth;
1691            mousepos_y = vid_conheight;
1692            mousepos = mousepos*0.5 + getmousepos();
1693          */
1694
1695         IL_EACH(g_drawables, it.draw, it.draw(it));
1696
1697         addentities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS); // TODO: .health is used in cl_deathfade (a feature we have turned off currently)
1698         renderscene();
1699
1700         // Now the the scene has been rendered, begin with the 2D drawing functions
1701
1702         View_NightVision();
1703         DrawReticle(local_player);
1704         HUD_Contents();
1705         HUD_Damage();
1706         View_PostProcessing();
1707
1708         // draw 2D entities
1709         IL_EACH(g_drawables_2d, it.draw2d, it.draw2d(it));
1710         Draw_ShowNames_All();
1711 #if ENABLE_DEBUGDRAW
1712         Debug_Draw();
1713 #endif
1714
1715         scoreboard_active = Scoreboard_WouldDraw();
1716
1717         HUD_Draw(this); // this parameter for deep vehicle function
1718
1719         if(NextFrameCommand)
1720         {
1721                 localcmd("\n", NextFrameCommand, "\n");
1722                 NextFrameCommand = string_null;
1723         }
1724
1725         // we must do this check AFTER a frame was rendered, or it won't work
1726         if(cs_project_is_b0rked == 0)
1727         {
1728                 string w0, h0;
1729                 w0 = ftos(autocvar_vid_conwidth);
1730                 h0 = ftos(autocvar_vid_conheight);
1731                 //setproperty(VF_VIEWPORT, '0 0 0', '640 480 0');
1732                 //setproperty(VF_FOV, '90 90 0');
1733                 setproperty(VF_ORIGIN, '0 0 0');
1734                 setproperty(VF_ANGLES, '0 0 0');
1735                 setproperty(VF_PERSPECTIVE, 1);
1736                 vector forward, right, up;
1737                 MAKE_VECTORS('0 0 0', forward, right, up);
1738                 vector v1, v2;
1739                 cvar_set("vid_conwidth", "800");
1740                 cvar_set("vid_conheight", "600");
1741                 v1 = cs_project(forward);
1742                 cvar_set("vid_conwidth", "640");
1743                 cvar_set("vid_conheight", "480");
1744                 v2 = cs_project(forward);
1745                 if(v1 == v2)
1746                         cs_project_is_b0rked = 1;
1747                 else
1748                         cs_project_is_b0rked = -1;
1749                 cvar_set("vid_conwidth", w0);
1750                 cvar_set("vid_conheight", h0);
1751         }
1752
1753         HUD_Mouse(local_player);
1754
1755         cl_notice_run();
1756         unpause_update();
1757         Net_Flush();
1758
1759         // let's reset the view back to normal for the end
1760         setproperty(VF_MIN, '0 0 0');
1761         setproperty(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
1762
1763         IL_ENDFRAME();
1764 }
1765
1766
1767 // following vectors must be global to allow seamless switching between camera modes
1768 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
1769 void CSQC_Demo_Camera()
1770 {
1771         float speed, attenuation, dimensions;
1772         vector tmp, delta;
1773
1774         if( autocvar_camera_reset || !camera_mode )
1775         {
1776                 camera_offset = '0 0 0';
1777                 current_angles = '0 0 0';
1778                 camera_direction = '0 0 0';
1779                 camera_offset.z += 30;
1780                 camera_offset.x += 30 * -cos(current_angles.y * DEG2RAD);
1781                 camera_offset.y += 30 * -sin(current_angles.y * DEG2RAD);
1782                 current_origin = view_origin;
1783                 current_camera_offset  = camera_offset;
1784                 cvar_set("camera_reset", "0");
1785                 camera_mode = CAMERA_CHASE;
1786         }
1787
1788         // Camera angles
1789         if( camera_roll )
1790                 mouse_angles.z += camera_roll * autocvar_camera_speed_roll;
1791
1792         if(autocvar_camera_look_player)
1793         {
1794                 vector dir;
1795                 float n;
1796
1797                 dir = normalize(view_origin - current_position);
1798                 n = mouse_angles.z;
1799                 mouse_angles = vectoangles(dir);
1800                 mouse_angles.x = mouse_angles.x * -1;
1801                 mouse_angles.z = n;
1802         }
1803         else
1804         {
1805                 tmp = getmousepos() * 0.1;
1806                 if(vdist(tmp, >, autocvar_camera_mouse_threshold))
1807                 {
1808                         mouse_angles.x += tmp.y * cos(mouse_angles.z * DEG2RAD) + (tmp.x * sin(mouse_angles.z * DEG2RAD));
1809                         mouse_angles.y -= tmp.x * cos(mouse_angles.z * DEG2RAD) + (tmp.y * -sin(mouse_angles.z * DEG2RAD));
1810                 }
1811         }
1812
1813         while (mouse_angles.x < -180) mouse_angles.x = mouse_angles.x + 360;
1814         while (mouse_angles.x > 180) mouse_angles.x = mouse_angles.x - 360;
1815         while (mouse_angles.y < -180) mouse_angles.y = mouse_angles.y + 360;
1816         while (mouse_angles.y > 180) mouse_angles.y = mouse_angles.y - 360;
1817
1818         // Fix difference when angles don't have the same sign
1819         delta = '0 0 0';
1820         if(mouse_angles.y < -60 && current_angles.y > 60)
1821                 delta = '0 360 0';
1822         if(mouse_angles.y > 60 && current_angles.y < -60)
1823                 delta = '0 -360 0';
1824
1825         if(autocvar_camera_look_player)
1826                 attenuation = autocvar_camera_look_attenuation;
1827         else
1828                 attenuation = autocvar_camera_speed_attenuation;
1829
1830         attenuation = 1 / max(1, attenuation);
1831         current_angles += (mouse_angles - current_angles + delta) * attenuation;
1832
1833         while (current_angles.x < -180) current_angles.x = current_angles.x + 360;
1834         while (current_angles.x > 180) current_angles.x = current_angles.x - 360;
1835         while (current_angles.y < -180) current_angles.y = current_angles.y + 360;
1836         while (current_angles.y > 180) current_angles.y = current_angles.y - 360;
1837
1838         // Camera position
1839         tmp = '0 0 0';
1840         dimensions = 0;
1841
1842         if( camera_direction.x )
1843         {
1844                 tmp.x = camera_direction.x * cos(current_angles.y * DEG2RAD);
1845                 tmp.y = camera_direction.x * sin(current_angles.y * DEG2RAD);
1846                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
1847                         tmp.z = camera_direction.x * -sin(current_angles.x * DEG2RAD);
1848                 ++dimensions;
1849         }
1850
1851         if( camera_direction.y )
1852         {
1853                 tmp.x += camera_direction.y * -sin(current_angles.y * DEG2RAD);
1854                 tmp.y += camera_direction.y * cos(current_angles.y * DEG2RAD) * cos(current_angles.z * DEG2RAD);
1855                 tmp.z += camera_direction.y * sin(current_angles.z * DEG2RAD);
1856                 ++dimensions;
1857         }
1858
1859         if( camera_direction.z )
1860         {
1861                 tmp.z += camera_direction.z * cos(current_angles.z * DEG2RAD);
1862                 ++dimensions;
1863         }
1864
1865         if(autocvar_camera_free)
1866                 speed = autocvar_camera_speed_free;
1867         else
1868                 speed = autocvar_camera_speed_chase;
1869
1870         if(dimensions)
1871         {
1872                 speed = speed * sqrt(1 / dimensions);
1873                 camera_offset += tmp * speed;
1874         }
1875
1876         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
1877
1878         // Camera modes
1879         if( autocvar_camera_free )
1880         {
1881                 if ( camera_mode == CAMERA_CHASE )
1882                 {
1883                         current_camera_offset = current_origin + current_camera_offset;
1884                         camera_offset = current_origin + camera_offset;
1885                 }
1886
1887                 camera_mode = CAMERA_FREE;
1888                 current_position = current_camera_offset;
1889         }
1890         else
1891         {
1892                 if ( camera_mode == CAMERA_FREE )
1893                 {
1894                         current_origin = view_origin;
1895                         camera_offset = camera_offset - current_origin;
1896                         current_camera_offset = current_camera_offset - current_origin;
1897                 }
1898
1899                 camera_mode = CAMERA_CHASE;
1900
1901                 if(autocvar_camera_chase_smoothly)
1902                         current_origin += (view_origin - current_origin) * attenuation;
1903                 else
1904                         current_origin = view_origin;
1905
1906                 current_position = current_origin + current_camera_offset;
1907         }
1908
1909         setproperty(VF_ANGLES, current_angles);
1910         setproperty(VF_ORIGIN, current_position);
1911 }