qcsrc/client/view.qc

   1 #include "view.qh"
   2
   3 #include "announcer.qh"
   4 #include "hud/_mod.qh"
   5 #include "mapvoting.qh"
   6 #include "shownames.qh"
   7 #include "hud/panel/scoreboard.qh"
   8 #include "hud/panel/quickmenu.qh"
   9
  10 #include "mutators/events.qh"
  11
  12 #include <common/animdecide.qh>
  13 #include <common/ent_cs.qh>
  14 #include <common/anim.qh>
  15 #include <common/constants.qh>
  16 #include <common/net_linked.qh>
  17 #include <common/debug.qh>
  18 #include <common/mapinfo.qh>
  19 #include <common/gamemodes/_mod.qh>
  20 #include <common/physics/player.qh>
  21 #include <common/stats.qh>
  22 #include <common/triggers/target/music.qh>
  23 #include <common/teams.qh>
  24
  25 #include <common/weapons/weapon/tuba.qh>
  26
  27 #include <common/vehicles/all.qh>
  28 #include <common/weapons/_all.qh>
  29 #include <common/viewloc.qh>
  30 #include <common/minigames/cl_minigames.qh>
  31 #include <common/minigames/cl_minigames_hud.qh>
  32
  33 #include <lib/csqcmodel/cl_player.qh>
  34 #include <lib/csqcmodel/cl_model.qh>
  35 #include "csqcmodel_hooks.qh"
  36
  37 #include <lib/warpzone/client.qh>
  38 #include <lib/warpzone/common.qh>
  39
  40 #define EFMASK_CHEAP (EF_ADDITIVE | EF_DOUBLESIDED | EF_FULLBRIGHT | EF_NODEPTHTEST | EF_NODRAW | EF_NOSHADOW | EF_SELECTABLE | EF_TELEPORT_BIT)
  41
  42 float autocvar_cl_viewmodel_scale;
  43
  44 bool autocvar_cl_bobmodel;
  45 float autocvar_cl_bobmodel_speed;
  46 float autocvar_cl_bobmodel_side;
  47 float autocvar_cl_bobmodel_up;
  48
  49 float autocvar_cl_followmodel;
  50 float autocvar_cl_followmodel_speed = 0.3;
  51 float autocvar_cl_followmodel_limit = 135;
  52 float autocvar_cl_followmodel_velocity_lowpass = 0.05;
  53 float autocvar_cl_followmodel_highpass = 0.05;
  54 float autocvar_cl_followmodel_lowpass = 0.03;
  55 bool autocvar_cl_followmodel_velocity_absolute;
  56
  57 float autocvar_cl_leanmodel;
  58 float autocvar_cl_leanmodel_speed = 0.3;
  59 float autocvar_cl_leanmodel_limit = 30;
  60 float autocvar_cl_leanmodel_highpass1 = 0.2;
  61 float autocvar_cl_leanmodel_highpass = 0.2;
  62 float autocvar_cl_leanmodel_lowpass = 0.05;
  63
  64 #define avg_factor(avg_time) (1 - exp(-frametime / max(0.001, avg_time)))
  65 #define lowpass(value, frac, ref_store, ret) MACRO_BEGIN \
  66 { \
  67         ret = ref_store = ref_store * (1 - frac) + (value) * frac; \
  68 } MACRO_END
  69
  70 #define lowpass_limited(value, frac, limit, ref_store, ret) MACRO_BEGIN \
  71 { \
  72         float __ignore; lowpass(value, frac, ref_store, __ignore); \
  73         ret = ref_store = bound((value) - (limit), ref_store, (value) + (limit)); \
  74 } MACRO_END
  75
  76 #define highpass(value, frac, ref_store, ret) MACRO_BEGIN \
  77 { \
  78         float __f = 0; lowpass(value, frac, ref_store, __f); \
  79         ret = (value) - __f; \
  80 } MACRO_END
  81
  82 #define highpass_limited(value, frac, limit, ref_store, ret) MACRO_BEGIN \
  83 { \
  84         float __f = 0; lowpass_limited(value, frac, limit, ref_store, __f); \
  85         ret = (value) - __f; \
  86 } MACRO_END
  87
  88 #define lowpass2(value, frac, ref_store, ref_out) MACRO_BEGIN \
  89 { \
  90         lowpass(value.x, frac, ref_store.x, ref_out.x); \
  91         lowpass(value.y, frac, ref_store.y, ref_out.y); \
  92 } MACRO_END
  93
  94 #define highpass2(value, frac, ref_store, ref_out) MACRO_BEGIN \
  95 { \
  96         highpass(value.x, frac, ref_store.x, ref_out.x); \
  97         highpass(value.y, frac, ref_store.y, ref_out.y); \
  98 } MACRO_END
  99
 100 #define highpass2_limited(value, frac, limit, ref_store, ref_out) MACRO_BEGIN \
 101 { \
 102         highpass_limited(value.x, frac, limit, ref_store.x, ref_out.x); \
 103         highpass_limited(value.y, frac, limit, ref_store.y, ref_out.y); \
 104 } MACRO_END
 105
 106 #define lowpass3(value, frac, ref_store, ref_out) MACRO_BEGIN \
 107 { \
 108         lowpass(value.x, frac, ref_store.x, ref_out.x); \
 109         lowpass(value.y, frac, ref_store.y, ref_out.y); \
 110         lowpass(value.z, frac, ref_store.z, ref_out.z); \
 111 } MACRO_END
 112
 113 #define highpass3(value, frac, ref_store, ref_out) MACRO_BEGIN \
 114 { \
 115         highpass(value.x, frac, ref_store.x, ref_out.x); \
 116         highpass(value.y, frac, ref_store.y, ref_out.y); \
 117         highpass(value.z, frac, ref_store.z, ref_out.z); \
 118 } MACRO_END
 119
 120 void calc_followmodel_ofs(entity view)
 121 {
 122         if(cl_followmodel_time == time)
 123                 return; // cl_followmodel_ofs already calculated for this frame
 124
 125         float frac;
 126         vector gunorg = '0 0 0';
 127         static vector vel_average;
 128         static vector gunorg_adjustment_highpass;
 129         static vector gunorg_adjustment_lowpass;
 130
 131         vector vel;
 132         if (autocvar_cl_followmodel_velocity_absolute)
 133                 vel = view.velocity;
 134         else
 135         {
 136                 vector forward = '0 0 0', right = '0 0 0', up = '0 0 0';
 137                 MAKEVECTORS(makevectors, view_angles, forward, right, up);
 138                 vel.x = view.velocity * forward;
 139                 vel.y = view.velocity * right * -1;
 140                 vel.z = view.velocity * up;
 141         }
 142
 143         vel.x = bound(vel_average.x - autocvar_cl_followmodel_limit, vel.x, vel_average.x + autocvar_cl_followmodel_limit);
 144         vel.y = bound(vel_average.y - autocvar_cl_followmodel_limit, vel.y, vel_average.y + autocvar_cl_followmodel_limit);
 145         vel.z = bound(vel_average.z - autocvar_cl_followmodel_limit, vel.z, vel_average.z + autocvar_cl_followmodel_limit);
 146
 147         frac = avg_factor(autocvar_cl_followmodel_velocity_lowpass);
 148         lowpass3(vel, frac, vel_average, gunorg);
 149
 150         gunorg *= -autocvar_cl_followmodel_speed * 0.042;
 151
 152         // perform highpass/lowpass on the adjustment vectors (turning velocity into acceleration!)
 153         // trick: we must do the lowpass LAST, so the lowpass vector IS the final vector!
 154         frac = avg_factor(autocvar_cl_followmodel_highpass);
 155         highpass3(gunorg, frac, gunorg_adjustment_highpass, gunorg);
 156         frac = avg_factor(autocvar_cl_followmodel_lowpass);
 157         lowpass3(gunorg, frac, gunorg_adjustment_lowpass, gunorg);
 158
 159         if (autocvar_cl_followmodel_velocity_absolute)
 160         {
 161                 vector fixed_gunorg;
 162                 vector forward = '0 0 0', right = '0 0 0', up = '0 0 0';
 163                 MAKEVECTORS(makevectors, view_angles, forward, right, up);
 164                 fixed_gunorg.x = gunorg * forward;
 165                 fixed_gunorg.y = gunorg * right * -1;
 166                 fixed_gunorg.z = gunorg * up;
 167                 gunorg = fixed_gunorg;
 168         }
 169
 170         cl_followmodel_ofs = gunorg;
 171         cl_followmodel_time = time;
 172 }
 173
 174 vector leanmodel_ofs(entity view)
 175 {
 176         float frac;
 177         vector gunangles = '0 0 0';
 178         static vector gunangles_prev = '0 0 0';
 179         static vector gunangles_highpass = '0 0 0';
 180         static vector gunangles_adjustment_highpass;
 181         static vector gunangles_adjustment_lowpass;
 182
 183         if (view.csqcmodel_teleported)
 184                 gunangles_prev = view_angles;
 185
 186         // in the highpass, we _store_ the DIFFERENCE to the actual view angles...
 187         gunangles_highpass += gunangles_prev;
 188         PITCH(gunangles_highpass) += 360 * floor((PITCH(view_angles) - PITCH(gunangles_highpass)) / 360 + 0.5);
 189         YAW(gunangles_highpass) += 360 * floor((YAW(view_angles) - YAW(gunangles_highpass)) / 360 + 0.5);
 190         ROLL(gunangles_highpass) += 360 * floor((ROLL(view_angles) - ROLL(gunangles_highpass)) / 360 + 0.5);
 191         frac = avg_factor(autocvar_cl_leanmodel_highpass1);
 192         highpass2_limited(view_angles, frac, autocvar_cl_leanmodel_limit, gunangles_highpass, gunangles);
 193         gunangles_prev = view_angles;
 194         gunangles_highpass -= gunangles_prev;
 195
 196         PITCH(gunangles) *= -autocvar_cl_leanmodel_speed;
 197         YAW(gunangles) *= -autocvar_cl_leanmodel_speed;
 198
 199         // we assume here: PITCH = 0, YAW = 1, ROLL = 2
 200         frac = avg_factor(autocvar_cl_leanmodel_highpass);
 201         highpass2(gunangles, frac, gunangles_adjustment_highpass, gunangles);
 202         frac = avg_factor(autocvar_cl_leanmodel_lowpass);
 203         lowpass2(gunangles, frac, gunangles_adjustment_lowpass, gunangles);
 204
 205         gunangles.x = -gunangles.x; // pitch was inverted, now that actually matters
 206
 207         return gunangles;
 208 }
 209
 210 vector bobmodel_ofs(entity view)
 211 {
 212         bool clonground = !(view.anim_implicit_state & ANIMIMPLICITSTATE_INAIR);
 213         static bool oldonground;
 214         static float hitgroundtime;
 215         if (clonground)
 216         {
 217                 float f = time; // cl.movecmd[0].time
 218                 if (!oldonground)
 219                         hitgroundtime = f;
 220         }
 221         oldonground = clonground;
 222
 223         // calculate for swinging gun model
 224         // the gun bobs when running on the ground, but doesn't bob when you're in the air.
 225         vector gunorg = '0 0 0';
 226         static float bobmodel_scale = 0;
 227         static float time_ofs = 0; // makes the effect always restart in the same way
 228         if (clonground)
 229         {
 230                 if (time - hitgroundtime > 0.05)
 231                         bobmodel_scale = min(1, bobmodel_scale + frametime * 5);
 232         }
 233         else
 234                 bobmodel_scale = max(0, bobmodel_scale - frametime * 5);
 235
 236         float xyspeed = bound(0, vlen(vec2(view.velocity)), 400);
 237         if (bobmodel_scale && xyspeed)
 238         {
 239                 float bspeed = xyspeed * 0.01 * autocvar_cl_viewmodel_scale * bobmodel_scale;
 240                 float s = (time - time_ofs) * autocvar_cl_bobmodel_speed;
 241                 gunorg.y = bspeed * autocvar_cl_bobmodel_side * sin(s);
 242                 gunorg.z = bspeed * autocvar_cl_bobmodel_up * cos(s * 2);
 243         }
 244         else
 245                 time_ofs = time;
 246
 247         return gunorg;
 248 }
 249
 250 void viewmodel_animate(entity this)
 251 {
 252         if (autocvar_chase_active) return;
 253         if (STAT(HEALTH) <= 0) return;
 254
 255         entity view = CSQCModel_server2csqc(player_localentnum - 1);
 256
 257         if (autocvar_cl_followmodel)
 258         {
 259                 calc_followmodel_ofs(view);
 260                 this.origin += cl_followmodel_ofs;
 261         }
 262
 263         if (autocvar_cl_leanmodel)
 264                 this.angles += leanmodel_ofs(view);
 265
 266         // vertical view bobbing code
 267         // TODO: cl_bob
 268
 269         // horizontal view bobbing code
 270         // TODO: cl_bob2
 271
 272         // fall bobbing code
 273         // causes the view to swing down and back up when touching the ground
 274         // TODO: cl_bobfall
 275
 276         // gun model bobbing code
 277         if (autocvar_cl_bobmodel)
 278                 this.origin += bobmodel_ofs(view);
 279 }
 280
 281 .vector viewmodel_origin, viewmodel_angles;
 282 .float weapon_nextthink;
 283 .float weapon_eta_last;
 284 .float weapon_switchdelay;
 285
 286 void viewmodel_draw(entity this)
 287 {
 288         if(!activeweapon || !autocvar_r_drawviewmodel)
 289                 return;
 290         int mask = (intermission || (STAT(HEALTH) <= 0) || autocvar_chase_active) ? 0 : MASK_NORMAL;
 291         float a = this.alpha;
 292         static bool wasinvehicle;
 293         bool invehicle = player_localentnum > maxclients;
 294         if (invehicle) a = -1;
 295         else if (wasinvehicle) a = 1;
 296         wasinvehicle = invehicle;
 297         Weapon wep = activeweapon;
 298         int c = entcs_GetClientColors(current_player);
 299         vector g = weaponentity_glowmod(wep, NULL, c);
 300         entity me = CSQCModel_server2csqc(player_localentnum - 1);
 301         int fx = ((me.csqcmodel_effects & EFMASK_CHEAP)
 302                 | EF_NODEPTHTEST)
 303                 &~ (EF_FULLBRIGHT); // can mask team color, so get rid of it
 304         for (entity e = this; e; e = e.weaponchild)
 305         {
 306                 e.drawmask = mask;
 307                 e.alpha = a;
 308                 e.colormap = 256 + c;  // colormap == 0 is black, c == 0 is white
 309                 e.glowmod = g;
 310                 e.csqcmodel_effects = fx;
 311                 CSQCModel_Effects_Apply(e);
 312         }
 313         {
 314                 static string name_last;
 315                 string name = wep.mdl;
 316                 string newname = wep.wr_viewmodel(wep, this);
 317                 if(newname)
 318                         name = newname;
 319                 bool swap = name != name_last;
 320                 // if (swap)
 321                 {
 322                         name_last = name;
 323                         CL_WeaponEntity_SetModel(this, name, swap);
 324                         this.viewmodel_origin = this.origin;
 325                         this.viewmodel_angles = this.angles;
 326                 }
 327                 anim_update(this);
 328                 if (!this.animstate_override && !this.animstate_looping)
 329                         anim_set(this, this.anim_idle, true, false, false);
 330         }
 331         float f = 0; // 0..1; 0: fully active
 332         float rate = STAT(WEAPONRATEFACTOR);
 333         float eta = rate ? ((this.weapon_nextthink - time) / rate) : 0;
 334         if (eta <= 0) f = this.weapon_eta_last;
 335         else switch (this.state)
 336         {
 337                 case WS_RAISE:
 338                 {
 339                         f = eta / max(eta, this.weapon_switchdelay);
 340                         break;
 341                 }
 342                 case WS_DROP:
 343                 {
 344                         f = 1 - eta / max(eta, this.weapon_switchdelay);
 345                         break;
 346                 }
 347                 case WS_CLEAR:
 348                 {
 349                         f = 1;
 350                         break;
 351                 }
 352         }
 353         this.weapon_eta_last = f;
 354         this.origin = this.viewmodel_origin;
 355         this.angles = this.viewmodel_angles;
 356         this.angles_x = (-90 * f * f);
 357         viewmodel_animate(this);
 358         setorigin(this, this.origin);
 359 }
 360
 361 entity viewmodel;
 362 STATIC_INIT(viewmodel) {
 363     viewmodel = new(viewmodel);
 364 }
 365
 366 void Porto_Draw(entity this);
 367 STATIC_INIT(Porto)
 368 {
 369         entity e = new_pure(porto);
 370         e.draw = Porto_Draw;
 371         IL_PUSH(g_drawables, e);
 372         e.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 373 }
 374
 375 const int polyline_length = 16;
 376 vector polyline[polyline_length];
 377 void Porto_Draw(entity this)
 378 {
 379         if (activeweapon != WEP_PORTO) return;
 380         if (spectatee_status) return;
 381         if (WEP_CVAR(porto, secondary)) return;
 382         if (intermission == 1) return;
 383         if (intermission == 2) return;
 384         if (STAT(HEALTH) <= 0) return;
 385
 386         vector pos = view_origin;
 387         vector dir = view_forward;
 388         if (angles_held_status)
 389         {
 390                 makevectors(angles_held);
 391                 dir = v_forward;
 392         }
 393
 394         polyline[0] = pos;
 395
 396         int portal_number = 0, portal1_idx = 1, portal_max = 2;
 397         int n = 1 + 2;  // 2 lines == 3 points
 398         for (int idx = 0; idx < n && idx < polyline_length - 1; )
 399         {
 400                 traceline(pos, pos + 65536 * dir, true, this);
 401                 dir = reflect(dir, trace_plane_normal);
 402                 pos = trace_endpos;
 403                 polyline[++idx] = pos;
 404                 if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
 405                 {
 406                         n += 1;
 407                         continue;
 408                 }
 409                 if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
 410                 {
 411                         n = max(2, idx);
 412                         break;
 413                 }
 414                 // check size
 415                 {
 416                         vector ang = vectoangles2(trace_plane_normal, dir);
 417                         ang.x = -ang.x;
 418                         makevectors(ang);
 419                         if (!CheckWireframeBox(this, pos - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
 420                         {
 421                                 n = max(2, idx);
 422                                 break;
 423                         }
 424                 }
 425                 portal_number += 1;
 426                 if (portal_number >= portal_max) break;
 427                 if (portal_number == 1) portal1_idx = idx;
 428         }
 429         for (int idx = 0; idx < n - 1; ++idx)
 430         {
 431                 vector p = polyline[idx], q = polyline[idx + 1];
 432                 if (idx == 0) p -= view_up * 16;  // line from player
 433                 vector rgb = (idx < portal1_idx) ? '1 0 0' : '0 0 1';
 434                 Draw_CylindricLine(p, q, 4, "", 1, 0, rgb, 0.5, DRAWFLAG_NORMAL, view_origin);
 435         }
 436 }
 437
 438 float drawtime;
 439 float avgspeed;
 440 vector GetCurrentFov(float fov)
 441 {
 442         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir;
 443         float velocityzoom, curspeed;
 444         vector v;
 445
 446         zoomsensitivity = autocvar_cl_zoomsensitivity;
 447         zoomfactor = autocvar_cl_zoomfactor;
 448         if(zoomfactor < 1 || zoomfactor > 30)
 449                 zoomfactor = 2.5;
 450         zoomspeed = autocvar_cl_zoomspeed;
 451         if(zoomspeed >= 0)
 452         if(zoomspeed < 0.5 || zoomspeed > 16)
 453                         zoomspeed = 3.5;
 454
 455         zoomdir = button_zoom;
 456         if(hud == HUD_NORMAL && !spectatee_status)
 457         if(switchweapon == activeweapon)
 458         if((activeweapon == WEP_VORTEX && !WEP_CVAR(vortex, secondary)) || (activeweapon == WEP_RIFLE && !WEP_CVAR(rifle, secondary))) // do NOT use switchweapon here
 459                 zoomdir += button_attack2;
 460         if(spectatee_status > 0 || isdemo())
 461         {
 462                 if(spectatorbutton_zoom)
 463                 {
 464                         if(zoomdir)
 465                                 zoomdir = 0;
 466                         else
 467                                 zoomdir = 1;
 468                 }
 469                 // fteqcc failed twice here already, don't optimize this
 470         }
 471
 472         if(zoomdir) { zoomin_effect = 0; }
 473
 474         if(camera_active)
 475         {
 476                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 477         }
 478         else if(autocvar_cl_spawnzoom && zoomin_effect)
 479         {
 480                 float spawnzoomfactor = bound(1, autocvar_cl_spawnzoom_factor, 30);
 481
 482                 current_viewzoom += (autocvar_cl_spawnzoom_speed * (spawnzoomfactor - current_viewzoom) * drawframetime);
 483                 current_viewzoom = bound(1 / spawnzoomfactor, current_viewzoom, 1);
 484                 if(current_viewzoom == 1) { zoomin_effect = 0; }
 485         }
 486         else
 487         {
 488                 if(zoomspeed < 0) // instant zoom
 489                 {
 490                         if(zoomdir)
 491                                 current_viewzoom = 1 / zoomfactor;
 492                         else
 493                                 current_viewzoom = 1;
 494                 }
 495                 else
 496                 {
 497                         if(zoomdir)
 498                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 499                         else
 500                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 501                 }
 502         }
 503
 504         if(almost_equals(current_viewzoom, 1))
 505                 current_zoomfraction = 0;
 506         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 507                 current_zoomfraction = 1;
 508         else
 509                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 510
 511         if(zoomsensitivity < 1)
 512                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
 513         else
 514                 setsensitivityscale(1);
 515
 516         if(autocvar_cl_velocityzoom_enabled && autocvar_cl_velocityzoom_type) // _type = 0 disables velocity zoom too
 517         {
 518                 if(intermission) { curspeed = 0; }
 519                 else
 520                 {
 521
 522                         makevectors(view_angles);
 523                         v = pmove_vel;
 524                         if(csqcplayer)
 525                                 v = csqcplayer.velocity;
 526
 527                         switch(autocvar_cl_velocityzoom_type)
 528                         {
 529                                 case 3: curspeed = max(0, v_forward * v); break;
 530                                 case 2: curspeed = (v_forward * v); break;
 531                                 case 1: default: curspeed = vlen(v); break;
 532                         }
 533                 }
 534
 535                 velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoom_time), 1); // speed at which the zoom adapts to player velocity
 536                 avgspeed = avgspeed * (1 - velocityzoom) + (curspeed / autocvar_cl_velocityzoom_speed) * velocityzoom;
 537                 velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom_factor / 1) * 1);
 538
 539                 //print(ftos(avgspeed), " avgspeed, ", ftos(curspeed), " curspeed, ", ftos(velocityzoom), " return\n"); // for debugging
 540         }
 541         else
 542                 velocityzoom = 1;
 543
 544         float frustumx, frustumy, fovx, fovy;
 545         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 546         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 547         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 548         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 549
 550         return '1 0 0' * fovx + '0 1 0' * fovy;
 551 }
 552
 553 vector GetViewLocationFOV(float fov)
 554 {
 555         float frustumy = tan(fov * M_PI / 360.0) * 0.75;
 556         float frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 557         float fovx = atan2(frustumx, 1) / M_PI * 360.0;
 558         float fovy = atan2(frustumy, 1) / M_PI * 360.0;
 559         return '1 0 0' * fovx + '0 1 0' * fovy;
 560 }
 561
 562 vector GetOrthoviewFOV(vector ov_worldmin, vector ov_worldmax, vector ov_mid, vector ov_org)
 563 {
 564         float fovx, fovy;
 565         float width = (ov_worldmax.x - ov_worldmin.x);
 566         float height = (ov_worldmax.y - ov_worldmin.y);
 567         float distance_to_middle_of_world = vlen(ov_mid - ov_org);
 568         fovx = atan2(width/2, distance_to_middle_of_world) / M_PI * 360.0;
 569         fovy = atan2(height/2, distance_to_middle_of_world) / M_PI * 360.0;
 570         return '1 0 0' * fovx + '0 1 0' * fovy;
 571 }
 572
 573 // this function must match W_SetupShot!
 574 float zoomscript_caught;
 575
 576 vector wcross_origin;
 577 float wcross_scale_prev, wcross_alpha_prev;
 578 vector wcross_color_prev;
 579 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 580 vector wcross_color_goal_prev;
 581 float wcross_changedonetime;
 582
 583 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 584 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 585 float wcross_name_changestarttime, wcross_name_changedonetime;
 586 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 587
 588 float wcross_ring_prev;
 589
 590 entity trueaim;
 591 entity trueaim_rifle;
 592
 593 const float SHOTTYPE_HITTEAM = 1;
 594 const float SHOTTYPE_HITOBSTRUCTION = 2;
 595 const float SHOTTYPE_HITWORLD = 3;
 596 const float SHOTTYPE_HITENEMY = 4;
 597
 598 void TrueAim_Init()
 599 {
 600         (trueaim = new_pure(trueaim)).dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 601         (trueaim_rifle = new_pure(trueaim_rifle)).dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 602 }
 603
 604 float EnemyHitCheck()
 605 {
 606         float t, n;
 607         wcross_origin = project_3d_to_2d(trace_endpos);
 608         wcross_origin.z = 0;
 609         if(trace_ent)
 610                 n = trace_ent.entnum;
 611         else
 612                 n = trace_networkentity;
 613         if(n < 1)
 614                 return SHOTTYPE_HITWORLD;
 615         if(n > maxclients)
 616                 return SHOTTYPE_HITWORLD;
 617         t = entcs_GetTeam(n - 1);
 618         if(teamplay)
 619                 if(t == myteam)
 620                         return SHOTTYPE_HITTEAM;
 621         if(t == NUM_SPECTATOR)
 622                 return SHOTTYPE_HITWORLD;
 623         return SHOTTYPE_HITENEMY;
 624 }
 625
 626 float TrueAimCheck()
 627 {
 628         float nudge = 1; // added to traceline target and subtracted from result TOOD(divVerent): do we still need this? Doesn't the engine do this now for us?
 629         vector vecs, trueaimpoint, w_shotorg;
 630         vector mi, ma, dv;
 631         float shottype;
 632         entity ta;
 633         float mv;
 634
 635         mi = ma = '0 0 0';
 636         ta = trueaim;
 637         mv = MOVE_NOMONSTERS;
 638
 639         switch(activeweapon) // WEAPONTODO
 640         {
 641                 case WEP_TUBA: // no aim
 642                 case WEP_PORTO: // shoots from eye
 643                 case WEP_NEXBALL: // shoots from eye
 644                 case WEP_HOOK: // no trueaim
 645                 case WEP_MORTAR: // toss curve
 646                         return SHOTTYPE_HITWORLD;
 647                 case WEP_VORTEX:
 648                 case WEP_VAPORIZER:
 649                         mv = MOVE_NORMAL;
 650                         break;
 651                 case WEP_RIFLE:
 652                         ta = trueaim_rifle;
 653                         mv = MOVE_NORMAL;
 654                         if(zoomscript_caught)
 655                         {
 656                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 657                                 return EnemyHitCheck();
 658                         }
 659                         break;
 660                 case WEP_DEVASTATOR: // projectile has a size!
 661                         mi = '-3 -3 -3';
 662                         ma = '3 3 3';
 663                         break;
 664                 case WEP_FIREBALL: // projectile has a size!
 665                         mi = '-16 -16 -16';
 666                         ma = '16 16 16';
 667                         break;
 668                 case WEP_SEEKER: // projectile has a size!
 669                         mi = '-2 -2 -2';
 670                         ma = '2 2 2';
 671                         break;
 672                 case WEP_ELECTRO: // projectile has a size!
 673                         mi = '0 0 -3';
 674                         ma = '0 0 -3';
 675                         break;
 676         }
 677
 678         vector traceorigin = entcs_receiver(player_localentnum - 1).origin + (eZ * STAT(VIEWHEIGHT));
 679
 680         vecs = decompressShotOrigin(STAT(SHOTORG));
 681
 682         traceline(traceorigin, traceorigin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 683         trueaimpoint = trace_endpos;
 684
 685         if(vdist((trueaimpoint - traceorigin), <, g_trueaim_minrange))
 686                 trueaimpoint = traceorigin + view_forward * g_trueaim_minrange;
 687
 688         if(vecs.x > 0)
 689                 vecs.y = -vecs.y;
 690         else
 691                 vecs = '0 0 0';
 692
 693         dv = view_right * vecs.y + view_up * vecs.z;
 694         w_shotorg = traceorigin + dv;
 695
 696         // now move the vecs forward as much as requested if possible
 697         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs.x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 698         w_shotorg = trace_endpos - view_forward * nudge;
 699
 700         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 701         shottype = EnemyHitCheck();
 702         if(shottype != SHOTTYPE_HITWORLD)
 703                 return shottype;
 704
 705 #if 0
 706         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 707         // or rather, I know why, but see no fix
 708         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 709                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 710                 return SHOTTYPE_HITOBSTRUCTION;
 711 #endif
 712
 713         return SHOTTYPE_HITWORLD;
 714 }
 715
 716 void PostInit();
 717 void CSQC_Demo_Camera();
 718 float camera_mode;
 719 const float CAMERA_FREE = 1;
 720 const float CAMERA_CHASE = 2;
 721 float reticle_type;
 722 string reticle_image;
 723 string NextFrameCommand;
 724
 725 vector freeze_org, freeze_ang;
 726 entity nightvision_noise, nightvision_noise2;
 727
 728 const float MAX_TIME_DIFF = 5;
 729 float pickup_crosshair_time, pickup_crosshair_size;
 730 float hitindication_crosshair_size;
 731 float use_vortex_chargepool;
 732
 733 float myhealth, myhealth_prev;
 734 float myhealth_flash;
 735
 736 float old_blurradius, old_bluralpha;
 737 float old_sharpen_intensity;
 738
 739 vector myhealth_gentlergb;
 740
 741 float contentavgalpha, liquidalpha_prev;
 742 vector liquidcolor_prev;
 743
 744 float eventchase_current_distance;
 745 float eventchase_running;
 746 bool WantEventchase(entity this)
 747 {
 748         if(autocvar_cl_orthoview)
 749                 return false;
 750         if(STAT(GAMEOVER) || intermission)
 751                 return true;
 752         if(this.viewloc)
 753                 return true;
 754         if(spectatee_status >= 0)
 755         {
 756                 if(hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0))
 757                         return true;
 758                 if(MUTATOR_CALLHOOK(WantEventchase, this))
 759                         return true;
 760                 if(autocvar_cl_eventchase_death && (STAT(HEALTH) <= 0))
 761                 {
 762                         if(autocvar_cl_eventchase_death == 2)
 763                         {
 764                                 // don't stop eventchase once it's started (even if velocity changes afterwards)
 765                                 if(this.velocity == '0 0 0' || eventchase_running)
 766                                         return true;
 767                         }
 768                         else return true;
 769                 }
 770         }
 771         return false;
 772 }
 773
 774 void HUD_Crosshair_Vehicle(entity this)
 775 {
 776         if(hud != HUD_BUMBLEBEE_GUN)
 777         {
 778                 Vehicle info = Vehicles_from(hud);
 779                 info.vr_crosshair(info, this);
 780         }
 781 }
 782
 783 vector damage_blurpostprocess, content_blurpostprocess;
 784
 785 float unaccounted_damage = 0;
 786 void UpdateDamage()
 787 {
 788         // accumulate damage with each stat update
 789         static float damage_total_prev = 0;
 790         float damage_total = STAT(DAMAGE_DEALT_TOTAL);
 791         float unaccounted_damage_new = COMPARE_INCREASING(damage_total, damage_total_prev);
 792         damage_total_prev = damage_total;
 793
 794         static float damage_dealt_time_prev = 0;
 795         float damage_dealt_time = STAT(HIT_TIME);
 796         if (damage_dealt_time != damage_dealt_time_prev)
 797         {
 798                 unaccounted_damage += unaccounted_damage_new;
 799                 LOG_TRACE("dmg total: ", ftos(unaccounted_damage), " (+", ftos(unaccounted_damage_new), ")");
 800         }
 801         damage_dealt_time_prev = damage_dealt_time;
 802
 803         // prevent hitsound when switching spectatee
 804         static float spectatee_status_prev = 0;
 805         if (spectatee_status != spectatee_status_prev)
 806                 unaccounted_damage = 0;
 807         spectatee_status_prev = spectatee_status;
 808 }
 809
 810 void HitSound()
 811 {
 812         // varying sound pitch
 813
 814         static float hitsound_time_prev = 0;
 815         // HACK: the only way to get the arc to sound consistent with pitch shift is to ignore cl_hitsound_antispam_time
 816         float arc_hack = activeweapon == WEP_ARC && autocvar_cl_hitsound >= 2;
 817         if (arc_hack || COMPARE_INCREASING(time, hitsound_time_prev) > autocvar_cl_hitsound_antispam_time)
 818         {
 819                 if (autocvar_cl_hitsound && unaccounted_damage)
 820                 {
 821                         // customizable gradient function that crosses (0,a), (c,1) and asymptotically approaches b
 822                         float a = autocvar_cl_hitsound_max_pitch;
 823                         float b = autocvar_cl_hitsound_min_pitch;
 824                         float c = autocvar_cl_hitsound_nom_damage;
 825                         float d = unaccounted_damage;
 826                         float pitch_shift = (b*d*(a-1) + a*c*(1-b)) / (d*(a-1) + c*(1-b));
 827
 828                         // if sound variation is disabled, set pitch_shift to 1
 829                         if (autocvar_cl_hitsound == 1)
 830                                 pitch_shift = 1;
 831
 832                         // if pitch shift is reversed, mirror in (max-min)/2 + min
 833                         if (autocvar_cl_hitsound == 3)
 834                         {
 835                                 float mirror_value = (a-b)/2 + b;
 836                                 pitch_shift = mirror_value + (mirror_value - pitch_shift);
 837                         }
 838
 839                         LOG_TRACE("dmg total (dmg): ", ftos(unaccounted_damage), " , pitch shift: ", ftos(pitch_shift));
 840
 841                         // todo: avoid very long and very short sounds from wave stretching using different sound files? seems unnecessary
 842                         // todo: normalize sound pressure levels? seems unnecessary
 843
 844                         sound7(NULL, CH_INFO, SND(HIT), VOL_BASE, ATTN_NONE, pitch_shift * 100, 0);
 845                 }
 846                 unaccounted_damage = 0;
 847                 hitsound_time_prev = time;
 848         }
 849
 850         static float typehit_time_prev = 0;
 851         float typehit_time = STAT(TYPEHIT_TIME);
 852         if (COMPARE_INCREASING(typehit_time, typehit_time_prev) > autocvar_cl_hitsound_antispam_time)
 853         {
 854                 sound(NULL, CH_INFO, SND_TYPEHIT, VOL_BASE, ATTN_NONE);
 855                 typehit_time_prev = typehit_time;
 856         }
 857
 858         static float kill_time_prev = 0;
 859         float kill_time = STAT(KILL_TIME);
 860         if (COMPARE_INCREASING(kill_time, kill_time_prev) > autocvar_cl_hitsound_antispam_time)
 861         {
 862                 sound(NULL, CH_INFO, SND_KILL, VOL_BASE, ATTN_NONE);
 863                 kill_time_prev = kill_time;
 864         }
 865 }
 866
 867 vector crosshair_getcolor(entity this, float health_stat)
 868 {
 869         static float rainbow_last_flicker;
 870         static vector rainbow_prev_color;
 871         vector wcross_color = '0 0 0';
 872         switch(autocvar_crosshair_color_special)
 873         {
 874                 case 1: // crosshair_color_per_weapon
 875                 {
 876                         if(this != WEP_Null && hud == HUD_NORMAL)
 877                         {
 878                                 wcross_color = this.wpcolor;
 879                                 break;
 880                         }
 881                         else { goto normalcolor; }
 882                 }
 883
 884                 case 2: // crosshair_color_by_health
 885                 {
 886                         float hp = health_stat;
 887
 888                         //x = red
 889                         //y = green
 890                         //z = blue
 891
 892                         wcross_color.z = 0;
 893
 894                         if(hp > 200)
 895                         {
 896                                 wcross_color.x = 0;
 897                                 wcross_color.y = 1;
 898                         }
 899                         else if(hp > 150)
 900                         {
 901                                 wcross_color.x = 0.4 - (hp-150)*0.02 * 0.4;
 902                                 wcross_color.y = 0.9 + (hp-150)*0.02 * 0.1;
 903                         }
 904                         else if(hp > 100)
 905                         {
 906                                 wcross_color.x = 1 - (hp-100)*0.02 * 0.6;
 907                                 wcross_color.y = 1 - (hp-100)*0.02 * 0.1;
 908                                 wcross_color.z = 1 - (hp-100)*0.02;
 909                         }
 910                         else if(hp > 50)
 911                         {
 912                                 wcross_color.x = 1;
 913                                 wcross_color.y = 1;
 914                                 wcross_color.z = 0.2 + (hp-50)*0.02 * 0.8;
 915                         }
 916                         else if(hp > 20)
 917                         {
 918                                 wcross_color.x = 1;
 919                                 wcross_color.y = (hp-20)*90/27/100;
 920                                 wcross_color.z = (hp-20)*90/27/100 * 0.2;
 921                         }
 922                         else
 923                         {
 924                                 wcross_color.x = 1;
 925                                 wcross_color.y = 0;
 926                         }
 927                         break;
 928                 }
 929
 930                 case 3: // crosshair_color_rainbow
 931                 {
 932                         if(time >= rainbow_last_flicker)
 933                         {
 934                                 rainbow_prev_color = randomvec() * autocvar_crosshair_color_special_rainbow_brightness;
 935                                 rainbow_last_flicker = time + autocvar_crosshair_color_special_rainbow_delay;
 936                         }
 937                         wcross_color = rainbow_prev_color;
 938                         break;
 939                 }
 940 LABEL(normalcolor)
 941                 default: { wcross_color = stov(autocvar_crosshair_color); break; }
 942         }
 943
 944         return wcross_color;
 945 }
 946
 947 void HUD_Crosshair(entity this)
 948 {
 949         float f, i, j;
 950         vector v;
 951         if(!scoreboard_active && !camera_active && intermission != 2 && !STAT(GAMEOVER) &&
 952                 spectatee_status != -1 && !csqcplayer.viewloc && !MUTATOR_CALLHOOK(DrawCrosshair) &&
 953                 !HUD_MinigameMenu_IsOpened() )
 954         {
 955                 if (!autocvar_crosshair_enabled) // main toggle for crosshair rendering
 956                         return;
 957
 958                 if (spectatee_status > 0 && STAT(CAMERA_SPECTATOR) == 2)
 959                         return;
 960
 961                 if (hud != HUD_NORMAL)
 962                 {
 963                         HUD_Crosshair_Vehicle(this);
 964                         return;
 965                 }
 966
 967                 string wcross_style;
 968                 float wcross_alpha, wcross_resolution;
 969                 wcross_style = autocvar_crosshair;
 970                 if (wcross_style == "0")
 971                         return;
 972                 wcross_resolution = autocvar_crosshair_size;
 973                 if (wcross_resolution == 0)
 974                         return;
 975                 wcross_alpha = autocvar_crosshair_alpha;
 976                 if (wcross_alpha == 0)
 977                         return;
 978
 979                 // TrueAim check
 980                 float shottype;
 981
 982                 // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
 983                 wcross_origin = project_3d_to_2d(view_origin + MAX_SHOT_DISTANCE * view_forward);
 984                 wcross_origin.z = 0;
 985                 if(autocvar_crosshair_hittest)
 986                 {
 987                         vector wcross_oldorigin;
 988                         wcross_oldorigin = wcross_origin;
 989                         shottype = TrueAimCheck();
 990                         if(shottype == SHOTTYPE_HITWORLD)
 991                         {
 992                                 v = wcross_origin - wcross_oldorigin;
 993                                 v.x /= vid_conwidth;
 994                                 v.y /= vid_conheight;
 995                                 if(vdist(v, >, 0.01))
 996                                         shottype = SHOTTYPE_HITOBSTRUCTION;
 997                         }
 998                         if(!autocvar_crosshair_hittest_showimpact)
 999                                 wcross_origin = wcross_oldorigin;
1000                 }
1001                 else
1002                         shottype = SHOTTYPE_HITWORLD;
1003
1004                 vector wcross_color = '0 0 0', wcross_size = '0 0 0';
1005                 string wcross_name = "";
1006                 float wcross_scale, wcross_blur;
1007
1008         entity e = WEP_Null;
1009                 if(autocvar_crosshair_per_weapon || (autocvar_crosshair_color_special == 1))
1010                 {
1011                         e = switchingweapon;
1012                         if(e)
1013                         {
1014                                 if(autocvar_crosshair_per_weapon)
1015                                 {
1016                                         // WEAPONTODO: access these through some general settings (with non-balance config settings)
1017                                         //wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
1018                                         //if (wcross_resolution == 0)
1019                                                 //return;
1020
1021                                         //wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
1022                                         wcross_resolution *= e.w_crosshair_size;
1023                                         wcross_name = e.w_crosshair;
1024                                 }
1025                         }
1026                 }
1027
1028                 if(wcross_name == "")
1029                         wcross_name = strcat("gfx/crosshair", wcross_style);
1030
1031                 // MAIN CROSSHAIR COLOR DECISION
1032                 wcross_color = crosshair_getcolor(e, STAT(HEALTH));
1033
1034                 if(autocvar_crosshair_effect_scalefade)
1035                 {
1036                         wcross_scale = wcross_resolution;
1037                         wcross_resolution = 1;
1038                 }
1039                 else
1040                 {
1041                         wcross_scale = 1;
1042                 }
1043
1044                 if(autocvar_crosshair_pickup)
1045                 {
1046                         float stat_pickup_time = STAT(LAST_PICKUP);
1047
1048                         if(pickup_crosshair_time < stat_pickup_time)
1049                         {
1050                                 if(time - stat_pickup_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1051                                         pickup_crosshair_size = 1;
1052
1053                                 pickup_crosshair_time = stat_pickup_time;
1054                         }
1055
1056                         if(pickup_crosshair_size > 0)
1057                                 pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
1058                         else
1059                                 pickup_crosshair_size = 0;
1060
1061                         wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
1062                 }
1063
1064                 // todo: make crosshair hit indication dependent on damage dealt
1065                 if(autocvar_crosshair_hitindication)
1066                 {
1067                         vector hitindication_color = ((autocvar_crosshair_color_special == 1) ? stov(autocvar_crosshair_hitindication_per_weapon_color) : stov(autocvar_crosshair_hitindication_color));
1068
1069                         if(unaccounted_damage)
1070                         {
1071                                 hitindication_crosshair_size = 1;
1072                         }
1073
1074                         if(hitindication_crosshair_size > 0)
1075                                 hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
1076                         else
1077                                 hitindication_crosshair_size = 0;
1078
1079                         wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
1080                         wcross_color.x += sin(hitindication_crosshair_size) * hitindication_color.x;
1081                         wcross_color.y += sin(hitindication_crosshair_size) * hitindication_color.y;
1082                         wcross_color.z += sin(hitindication_crosshair_size) * hitindication_color.z;
1083                 }
1084
1085                 if(shottype == SHOTTYPE_HITENEMY)
1086                         wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
1087                 if(shottype == SHOTTYPE_HITTEAM)
1088                         wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
1089
1090                 f = fabs(autocvar_crosshair_effect_time);
1091                 if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
1092                 {
1093                         wcross_changedonetime = time + f;
1094                 }
1095                 if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
1096                 {
1097                         wcross_name_changestarttime = time;
1098                         wcross_name_changedonetime = time + f;
1099                         if(wcross_name_goal_prev_prev)
1100                                 strunzone(wcross_name_goal_prev_prev);
1101                         wcross_name_goal_prev_prev = wcross_name_goal_prev;
1102                         wcross_name_goal_prev = strzone(wcross_name);
1103                         wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
1104                         wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
1105                         wcross_resolution_goal_prev = wcross_resolution;
1106                 }
1107
1108                 wcross_scale_goal_prev = wcross_scale;
1109                 wcross_alpha_goal_prev = wcross_alpha;
1110                 wcross_color_goal_prev = wcross_color;
1111
1112                 if(spectatee_status == -1 && shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
1113                 {
1114                         wcross_blur = 1;
1115                         wcross_alpha *= 0.75;
1116                 }
1117                 else
1118                         wcross_blur = 0;
1119                 // *_prev is at time-frametime
1120                 // * is at wcross_changedonetime+f
1121                 // what do we have at time?
1122                 if(time < wcross_changedonetime)
1123                 {
1124                         f = frametime / (wcross_changedonetime - time + frametime);
1125                         wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
1126                         wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
1127                         wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
1128                 }
1129
1130                 wcross_scale_prev = wcross_scale;
1131                 wcross_alpha_prev = wcross_alpha;
1132                 wcross_color_prev = wcross_color;
1133
1134                 MUTATOR_CALLHOOK(UpdateCrosshair);
1135
1136                 wcross_scale *= 1 - autocvar__menu_alpha;
1137                 wcross_alpha *= 1 - autocvar__menu_alpha;
1138                 wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1139
1140                 if(wcross_scale >= 0.001 && wcross_alpha >= 0.001)
1141                 {
1142                         // crosshair rings for weapon stats
1143                         if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
1144                         {
1145                                 // declarations and stats
1146                                 float ring_value = 0, ring_scale = 0, ring_alpha = 0, ring_inner_value = 0, ring_inner_alpha = 0;
1147                                 string ring_image = string_null, ring_inner_image = string_null;
1148                                 vector ring_rgb = '0 0 0', ring_inner_rgb = '0 0 0';
1149
1150                                 ring_scale = autocvar_crosshair_ring_size;
1151
1152                                 float weapon_clipload, weapon_clipsize;
1153                                 weapon_clipload = STAT(WEAPON_CLIPLOAD);
1154                                 weapon_clipsize = STAT(WEAPON_CLIPSIZE);
1155
1156                                 float ok_ammo_charge, ok_ammo_chargepool;
1157                                 ok_ammo_charge = STAT(OK_AMMO_CHARGE);
1158                                 ok_ammo_chargepool = STAT(OK_AMMO_CHARGEPOOL);
1159
1160                                 float vortex_charge, vortex_chargepool;
1161                                 vortex_charge = STAT(VORTEX_CHARGE);
1162                                 vortex_chargepool = STAT(VORTEX_CHARGEPOOL);
1163
1164                                 float arc_heat = STAT(ARC_HEAT);
1165
1166                                 if(vortex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
1167                                         vortex_charge_movingavg = vortex_charge;
1168
1169
1170                                 // handle the values
1171                                 if (autocvar_crosshair_ring && activeweapon == WEP_VORTEX && vortex_charge && autocvar_crosshair_ring_vortex) // ring around crosshair representing velocity-dependent damage for the vortex
1172                                 {
1173                                         if (vortex_chargepool || use_vortex_chargepool) {
1174                                                 use_vortex_chargepool = 1;
1175                                                 ring_inner_value = vortex_chargepool;
1176                                         } else {
1177                                                 vortex_charge_movingavg = (1 - autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate) * vortex_charge_movingavg + autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate * vortex_charge;
1178                                                 ring_inner_value = bound(0, autocvar_crosshair_ring_vortex_currentcharge_scale * (vortex_charge - vortex_charge_movingavg), 1);
1179                                         }
1180
1181                                         ring_inner_alpha = autocvar_crosshair_ring_vortex_inner_alpha;
1182                                         ring_inner_rgb = eX * autocvar_crosshair_ring_vortex_inner_color_red + eY * autocvar_crosshair_ring_vortex_inner_color_green + eZ * autocvar_crosshair_ring_vortex_inner_color_blue;
1183                                         ring_inner_image = "gfx/crosshair_ring_inner.tga";
1184
1185                                         // draw the outer ring to show the current charge of the weapon
1186                                         ring_value = vortex_charge;
1187                                         ring_alpha = autocvar_crosshair_ring_vortex_alpha;
1188                                         ring_rgb = wcross_color;
1189                                         ring_image = "gfx/crosshair_ring_nexgun.tga";
1190                                 }
1191                                 else if (autocvar_crosshair_ring && activeweapon == WEP_MINE_LAYER && WEP_CVAR(minelayer, limit) && autocvar_crosshair_ring_minelayer)
1192                                 {
1193                                         ring_value = bound(0, STAT(LAYED_MINES) / WEP_CVAR(minelayer, limit), 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
1194                                         ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
1195                                         ring_rgb = wcross_color;
1196                                         ring_image = "gfx/crosshair_ring.tga";
1197                                 }
1198                                 else if (activeweapon == WEP_HAGAR && STAT(HAGAR_LOAD) && autocvar_crosshair_ring_hagar)
1199                                 {
1200                                         ring_value = bound(0, STAT(HAGAR_LOAD) / WEP_CVAR_SEC(hagar, load_max), 1);
1201                                         ring_alpha = autocvar_crosshair_ring_hagar_alpha;
1202                                         ring_rgb = wcross_color;
1203                                         ring_image = "gfx/crosshair_ring.tga";
1204                                 }
1205                                 else if (ok_ammo_charge)
1206                                 {
1207                                         ring_value = ok_ammo_chargepool;
1208                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
1209                                         ring_rgb = wcross_color;
1210                                         ring_image = "gfx/crosshair_ring.tga";
1211                                 }
1212                                 else if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
1213                                 {
1214                                         ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
1215                                         ring_scale = autocvar_crosshair_ring_reload_size;
1216                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
1217                                         ring_rgb = wcross_color;
1218
1219                                         // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
1220                                         // if a new image for another weapon is added, add the code (and its respective file/value) here
1221                                         if ((activeweapon == WEP_RIFLE) && (weapon_clipsize == 80))
1222                                                 ring_image = "gfx/crosshair_ring_rifle.tga";
1223                                         else
1224                                                 ring_image = "gfx/crosshair_ring.tga";
1225                                 }
1226                                 else if ( autocvar_crosshair_ring && autocvar_crosshair_ring_arc && arc_heat && activeweapon == WEP_ARC )
1227                                 {
1228                                         ring_value = arc_heat;
1229                                         ring_alpha = (1-arc_heat)*autocvar_crosshair_ring_arc_cold_alpha +
1230                                                 arc_heat*autocvar_crosshair_ring_arc_hot_alpha;
1231                                         ring_rgb = (1-arc_heat)*wcross_color + arc_heat*autocvar_crosshair_ring_arc_hot_color;
1232                                         ring_image = "gfx/crosshair_ring.tga";
1233                                 }
1234
1235                                 // if in weapon switch animation, fade ring out/in
1236                                 if(autocvar_crosshair_effect_time > 0)
1237                                 {
1238                                         f = (time - wcross_name_changestarttime) / autocvar_crosshair_effect_time;
1239                                         if (f >= 1)
1240                                         {
1241                                                 wcross_ring_prev = ((ring_image) ? true : false);
1242                                         }
1243
1244                                         if(wcross_ring_prev)
1245                                         {
1246                                                 if(f < 1)
1247                                                         ring_alpha *= fabs(1 - bound(0, f, 1));
1248                                         }
1249                                         else
1250                                         {
1251                                                 if(f < 1)
1252                                                         ring_alpha *= bound(0, f, 1);
1253                                         }
1254                                 }
1255
1256                                 if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
1257                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
1258
1259                                 if (ring_value)
1260                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
1261                         }
1262
1263 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
1264                         MACRO_BEGIN { \
1265                                 if(wcross_blur > 0) \
1266                                 { \
1267                                         for(i = -2; i <= 2; ++i) \
1268                                         for(j = -2; j <= 2; ++j) \
1269                                         M(i,j,sz,wcross_name,wcross_alpha*0.04); \
1270                                 } \
1271                                 else \
1272                                 { \
1273                                         M(0,0,sz,wcross_name,wcross_alpha); \
1274                                 } \
1275                         } MACRO_END
1276
1277 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
1278                         drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size.x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size.y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
1279
1280 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
1281                         CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
1282
1283                         if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
1284                         {
1285                                 f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
1286                                 wcross_size = draw_getimagesize(wcross_name_goal_prev_prev) * wcross_scale;
1287                                 CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
1288                                 f = 1 - f;
1289                         }
1290                         else
1291                         {
1292                                 f = 1;
1293                         }
1294                         wcross_name_alpha_goal_prev = f;
1295
1296                         wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1297                         CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
1298
1299                         if(autocvar_crosshair_dot)
1300                         {
1301                                 vector wcross_color_old;
1302                                 wcross_color_old = wcross_color;
1303
1304                                 if((autocvar_crosshair_dot_color_custom) && (autocvar_crosshair_dot_color != "0"))
1305                                         wcross_color = stov(autocvar_crosshair_dot_color);
1306
1307                                 CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
1308                                 // FIXME why don't we use wcross_alpha here?
1309                                 wcross_color = wcross_color_old;
1310                         }
1311                 }
1312         }
1313         else
1314         {
1315                 wcross_scale_prev = 0;
1316                 wcross_alpha_prev = 0;
1317                 wcross_scale_goal_prev = 0;
1318                 wcross_alpha_goal_prev = 0;
1319                 wcross_changedonetime = 0;
1320                 if(wcross_name_goal_prev)
1321                         strunzone(wcross_name_goal_prev);
1322                 wcross_name_goal_prev = string_null;
1323                 if(wcross_name_goal_prev_prev)
1324                         strunzone(wcross_name_goal_prev_prev);
1325                 wcross_name_goal_prev_prev = string_null;
1326                 wcross_name_changestarttime = 0;
1327                 wcross_name_changedonetime = 0;
1328                 wcross_name_alpha_goal_prev = 0;
1329                 wcross_name_alpha_goal_prev_prev = 0;
1330                 wcross_resolution_goal_prev = 0;
1331                 wcross_resolution_goal_prev_prev = 0;
1332         }
1333 }
1334
1335 void HUD_Draw(entity this)
1336 {
1337         // if we don't know gametype and scores yet avoid drawing the scoreboard
1338         // also in the very first frames, player state may be inconsistent so avoid drawing the hud at all
1339         // e.g. since initial player's health is 0 hud would display the hud_damage effect,
1340         // cl_deathscoreboard would show the scoreboard and so on
1341         if(!gametype)
1342                 return;
1343
1344         if(!intermission)
1345         if (MUTATOR_CALLHOOK(HUD_Draw_overlay))
1346         {
1347                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, M_ARGV(0, vector), autocvar_hud_colorflash_alpha * M_ARGV(1, float), DRAWFLAG_ADDITIVE);
1348         }
1349         else if(STAT(FROZEN))
1350         {
1351                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, ((STAT(REVIVE_PROGRESS)) ? ('0.25 0.90 1' + ('1 0 0' * STAT(REVIVE_PROGRESS)) + ('0 1 1' * STAT(REVIVE_PROGRESS) * -1)) : '0.25 0.90 1'), autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1352         }
1353         if(!intermission)
1354         if(STAT(NADE_TIMER) && autocvar_cl_nade_timer) // give nade top priority, as it's a matter of life and death
1355         {
1356                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(NADE_TIMER), '0.25 0.90 1' + ('1 0 0' * STAT(NADE_TIMER)) - ('0 1 1' * STAT(NADE_TIMER)), autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1357                 drawstring_aspect(eY * 0.64 * vid_conheight, ((autocvar_cl_nade_timer == 2) ? _("Nade timer") : ""), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
1358         }
1359         else if(STAT(CAPTURE_PROGRESS))
1360         {
1361                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(CAPTURE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1362                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Capture progress"), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
1363         }
1364         else if(STAT(REVIVE_PROGRESS))
1365         {
1366                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1367                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Revival progress"), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
1368         }
1369
1370         if(autocvar_r_letterbox == 0)
1371                 if(autocvar_viewsize < 120)
1372                 {
1373                         if(!(gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS))
1374                                 Accuracy_LoadLevels();
1375
1376                         HUD_Main();
1377                         HUD_Scale_Disable();
1378                 }
1379
1380         // crosshair goes VERY LAST
1381         UpdateDamage();
1382         HUD_Crosshair(this);
1383         HitSound();
1384 }
1385
1386 bool ov_enabled;
1387 float oldr_nearclip;
1388 float oldr_farclip_base;
1389 float oldr_farclip_world;
1390 float oldr_novis;
1391 float oldr_useportalculling;
1392 float oldr_useinfinitefarclip;
1393
1394 void cl_notice_run();
1395
1396 float prev_myteam;
1397 int lasthud;
1398 float vh_notice_time;
1399 void WaypointSprite_Load();
1400 void CSQC_UpdateView(entity this, float w, float h)
1401 {
1402     TC(int, w); TC(int, h);
1403         entity e;
1404         float fov;
1405         float f;
1406         vector vf_size, vf_min;
1407         float a;
1408
1409         execute_next_frame();
1410
1411         ++framecount;
1412
1413         stats_get();
1414         hud = STAT(HUD);
1415
1416         if(hud != HUD_NORMAL && lasthud == HUD_NORMAL)
1417                 vh_notice_time = time + autocvar_cl_vehicles_notify_time;
1418
1419         lasthud = hud;
1420
1421         HUD_Scale_Disable();
1422
1423         if(autocvar__hud_showbinds_reload) // menu can set this one
1424         {
1425                 db_close(binddb);
1426                 binddb = db_create();
1427                 cvar_set("_hud_showbinds_reload", "0");
1428         }
1429
1430         if(checkextension("DP_CSQC_MINFPS_QUALITY"))
1431                 view_quality = getproperty(VF_MINFPS_QUALITY);
1432         else
1433                 view_quality = 1;
1434
1435         button_attack2 = PHYS_INPUT_BUTTON_ATCK2(this);
1436         button_zoom = PHYS_INPUT_BUTTON_ZOOM(this);
1437
1438         vf_size = getpropertyvec(VF_SIZE);
1439         vf_min = getpropertyvec(VF_MIN);
1440         vid_width = vf_size.x;
1441         vid_height = vf_size.y;
1442
1443         vector reticle_pos = '0 0 0', reticle_size = '0 0 0';
1444         vector splash_pos = '0 0 0', splash_size = '0 0 0';
1445
1446         WaypointSprite_Load();
1447
1448         CSQCPlayer_SetCamera();
1449
1450         if(player_localentnum <= maxclients) // is it a client?
1451                 current_player = player_localentnum - 1;
1452         else // then player_localentnum is the vehicle I'm driving
1453                 current_player = player_localnum;
1454         myteam = entcs_GetTeam(current_player);
1455
1456         if(myteam != prev_myteam)
1457         {
1458                 myteamcolors = colormapPaletteColor(myteam, 1);
1459                 FOREACH(hud_panels, true, it.update_time = time);
1460                 prev_myteam = myteam;
1461         }
1462
1463         ticrate = STAT(MOVEVARS_TICRATE) * STAT(MOVEVARS_TIMESCALE);
1464
1465         float is_dead = (STAT(HEALTH) <= 0);
1466
1467         // FIXME do we need this hack?
1468         if(isdemo())
1469         {
1470                 // in demos, input_buttons do not work
1471                 button_zoom = (autocvar__togglezoom == "-");
1472         }
1473         else if(button_zoom
1474                 && autocvar_cl_unpress_zoom_on_death
1475                 && (spectatee_status >= 0)
1476                 && (is_dead || intermission))
1477         {
1478                 // no zoom while dead or in intermission please
1479                 localcmd("-zoom\n");
1480                 button_zoom = false;
1481         }
1482
1483         // event chase camera
1484         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
1485         {
1486                 if(STAT(CAMERA_SPECTATOR))
1487                 {
1488                         if(spectatee_status > 0)
1489                         {
1490                                 if(!autocvar_chase_active)
1491                                 {
1492                                         cvar_set("chase_active", "-2");
1493                                         goto skip_eventchase_death;
1494                                 }
1495                         }
1496                         else if(autocvar_chase_active == -2)
1497                                 cvar_set("chase_active", "0");
1498
1499                         if(autocvar_chase_active == -2)
1500                                 goto skip_eventchase_death;
1501                 }
1502                 else if(autocvar_chase_active == -2)
1503                         cvar_set("chase_active", "0");
1504
1505                 float vehicle_chase = (hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0));
1506
1507                 float vehicle_viewdist = 0;
1508                 vector vehicle_viewofs = '0 0 0';
1509
1510                 if(vehicle_chase)
1511                 {
1512                         if(hud != HUD_BUMBLEBEE_GUN)
1513                         {
1514                                 Vehicle info = Vehicles_from(hud);
1515                                 vehicle_viewdist = info.height;
1516                                 vehicle_viewofs = info.view_ofs;
1517                         }
1518                 }
1519
1520                 if(WantEventchase(this))
1521                 {
1522                         vector current_view_origin_override = '0 0 0';
1523                         vector view_offset_override = '0 0 0';
1524                         float chase_distance_override = 0;
1525                         bool custom_eventchase = MUTATOR_CALLHOOK(CustomizeEventchase, this);
1526                         if(custom_eventchase)
1527                         {
1528                                 current_view_origin_override = M_ARGV(0, vector);
1529                                 view_offset_override = M_ARGV(1, vector);
1530                                 chase_distance_override = M_ARGV(0, float);
1531                         }
1532                         eventchase_running = true;
1533
1534                         entity local_player = ((csqcplayer) ? csqcplayer : CSQCModel_server2csqc(player_localentnum - 1));
1535                         if(!local_player)
1536                                 local_player = this; // fall back!
1537
1538                         // make special vector since we can't use view_origin (It is one frame old as of this code, it gets set later with the results this code makes.)
1539                         vector current_view_origin = (csqcplayer ? csqcplayer.origin : pmove_org);
1540                         if (custom_eventchase)
1541                                 current_view_origin = current_view_origin_override;
1542
1543                         // detect maximum viewoffset and use it
1544                         vector view_offset = autocvar_cl_eventchase_viewoffset;
1545                         if(vehicle_chase)
1546                         {
1547                                 if(vehicle_viewofs)
1548                                         view_offset = vehicle_viewofs;
1549                                 else
1550                                         view_offset = autocvar_cl_eventchase_vehicle_viewoffset;
1551                         }
1552                         if (custom_eventchase)
1553                                 view_offset = view_offset_override;
1554
1555                         if(view_offset)
1556                         {
1557                                 WarpZone_TraceLine(current_view_origin, current_view_origin + view_offset + ('0 0 1' * autocvar_cl_eventchase_maxs.z), MOVE_WORLDONLY, this);
1558                                 if(trace_fraction == 1) { current_view_origin += view_offset; }
1559                                 else { current_view_origin.z += max(0, (trace_endpos.z - current_view_origin.z) - autocvar_cl_eventchase_maxs.z); }
1560                         }
1561
1562                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
1563                         // Ideally, there should be another way to enable third person cameras, such as through setproperty()
1564                         // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
1565                         if(!autocvar_chase_active) { cvar_set("chase_active", "-1"); }
1566
1567                         // make the camera smooth back
1568                         float chase_distance = autocvar_cl_eventchase_distance;
1569                         if(vehicle_chase)
1570                         {
1571                                 if(vehicle_viewofs)
1572                                         chase_distance = vehicle_viewdist;
1573                                 else
1574                                         chase_distance = autocvar_cl_eventchase_vehicle_distance;
1575                         }
1576                         if (custom_eventchase)
1577                                 chase_distance = chase_distance_override;
1578
1579                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < chase_distance)
1580                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (chase_distance - eventchase_current_distance) * frametime; // slow down the further we get
1581                         else if(eventchase_current_distance != chase_distance)
1582                                 eventchase_current_distance = chase_distance;
1583
1584                         makevectors(view_angles);
1585
1586                         vector eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1587                         WarpZone_TraceBox(current_view_origin, autocvar_cl_eventchase_mins, autocvar_cl_eventchase_maxs, eventchase_target_origin, MOVE_WORLDONLY, this);
1588
1589                         // If the boxtrace fails, revert back to line tracing.
1590                         if(!local_player.viewloc)
1591                         if(trace_startsolid)
1592                         {
1593                                 eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1594                                 WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, this);
1595                                 setproperty(VF_ORIGIN, (trace_endpos - (v_forward * autocvar_cl_eventchase_mins.z)));
1596                         }
1597                         else { setproperty(VF_ORIGIN, trace_endpos); }
1598
1599                         if(!local_player.viewloc)
1600                                 setproperty(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
1601                 }
1602                 else if(autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
1603                 {
1604                         eventchase_running = false;
1605                         cvar_set("chase_active", "0");
1606                         eventchase_current_distance = 0; // start from 0 next time
1607                 }
1608         }
1609         // workaround for camera stuck between player's legs when using chase_active 1
1610         // because the engine stops updating the chase_active camera when the game ends
1611         else if(intermission)
1612         {
1613                 cvar_settemp("chase_active", "-1");
1614                 eventchase_current_distance = 0;
1615         }
1616
1617         LABEL(skip_eventchase_death);
1618
1619         // do lockview after event chase camera so that it still applies whenever necessary.
1620         if(autocvar_cl_lockview || (!autocvar_hud_cursormode && (autocvar__hud_configure && spectatee_status <= 0 || intermission > 1 || QuickMenu_IsOpened())))
1621         {
1622                 setproperty(VF_ORIGIN, freeze_org);
1623                 setproperty(VF_ANGLES, freeze_ang);
1624         }
1625         else
1626         {
1627                 freeze_org = getpropertyvec(VF_ORIGIN);
1628                 freeze_ang = getpropertyvec(VF_ANGLES);
1629         }
1630
1631         WarpZone_FixView();
1632         //WarpZone_FixPMove();
1633
1634         vector ov_org = '0 0 0';
1635         vector ov_mid = '0 0 0';
1636         vector ov_worldmin = '0 0 0';
1637         vector ov_worldmax = '0 0 0';
1638         if(autocvar_cl_orthoview)
1639         {
1640                 ov_worldmin = mi_picmin;
1641                 ov_worldmax = mi_picmax;
1642
1643                 float ov_width = (ov_worldmax.x - ov_worldmin.x);
1644                 float ov_height = (ov_worldmax.y - ov_worldmin.y);
1645                 float ov_distance = (max(vid_width, vid_height) * max(ov_width, ov_height));
1646
1647                 ov_mid = ((ov_worldmax + ov_worldmin) * 0.5);
1648                 ov_org = vec3(ov_mid.x, ov_mid.y, (ov_mid.z + ov_distance));
1649
1650                 float ov_nearest = vlen(ov_org - vec3(
1651                         bound(ov_worldmin.x, ov_org.x, ov_worldmax.x),
1652                         bound(ov_worldmin.y, ov_org.y, ov_worldmax.y),
1653                         bound(ov_worldmin.z, ov_org.z, ov_worldmax.z)
1654                 ));
1655
1656                 float ov_furthest = 0;
1657                 float dist = 0;
1658
1659                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1660                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1661                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1662                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1663                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1664                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1665                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1666                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1667
1668                 if(!ov_enabled)
1669                 {
1670                         oldr_nearclip = cvar("r_nearclip");
1671                         oldr_farclip_base = cvar("r_farclip_base");
1672                         oldr_farclip_world = cvar("r_farclip_world");
1673                         oldr_novis = cvar("r_novis");
1674                         oldr_useportalculling = cvar("r_useportalculling");
1675                         oldr_useinfinitefarclip = cvar("r_useinfinitefarclip");
1676                 }
1677
1678                 cvar_settemp("r_nearclip", ftos(ov_nearest));
1679                 cvar_settemp("r_farclip_base", ftos(ov_furthest));
1680                 cvar_settemp("r_farclip_world", "0");
1681                 cvar_settemp("r_novis", "1");
1682                 cvar_settemp("r_useportalculling", "0");
1683                 cvar_settemp("r_useinfinitefarclip", "0");
1684
1685                 setproperty(VF_ORIGIN, ov_org);
1686                 setproperty(VF_ANGLES, '90 0 0');
1687
1688                 ov_enabled = true;
1689
1690                 #if 0
1691                 LOG_INFOF("OrthoView: org = %s, angles = %s, distance = %f, nearest = %f, furthest = %f\n",
1692                         vtos(ov_org),
1693                         vtos(getpropertyvec(VF_ANGLES)),
1694                         ov_distance,
1695                         ov_nearest,
1696                         ov_furthest);
1697                 #endif
1698         }
1699         else
1700         {
1701                 if(ov_enabled)
1702                 {
1703                         cvar_set("r_nearclip", ftos(oldr_nearclip));
1704                         cvar_set("r_farclip_base", ftos(oldr_farclip_base));
1705                         cvar_set("r_farclip_world", ftos(oldr_farclip_world));
1706                         cvar_set("r_novis", ftos(oldr_novis));
1707                         cvar_set("r_useportalculling", ftos(oldr_useportalculling));
1708                         cvar_set("r_useinfinitefarclip", ftos(oldr_useinfinitefarclip));
1709                 }
1710                 ov_enabled = false;
1711         }
1712
1713         // run viewmodel_draw before updating view_angles to the angles calculated by WarpZone_FixView
1714         // viewmodel_draw needs to use the view_angles set by the engine on every CSQC_UpdateView call
1715         viewmodel_draw(viewmodel);
1716
1717         // Render the Scene
1718         view_origin = getpropertyvec(VF_ORIGIN);
1719         view_angles = getpropertyvec(VF_ANGLES);
1720         makevectors(view_angles);
1721         view_forward = v_forward;
1722         view_right = v_right;
1723         view_up = v_up;
1724
1725 #ifdef BLURTEST
1726         if(time > blurtest_time0 && time < blurtest_time1)
1727         {
1728                 float r, t;
1729
1730                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
1731                 r = t * blurtest_radius;
1732                 f = 1 / pow(t, blurtest_power) - 1;
1733
1734                 cvar_set("r_glsl_postprocess", "1");
1735                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
1736         }
1737         else
1738         {
1739                 cvar_set("r_glsl_postprocess", "0");
1740                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
1741         }
1742 #endif
1743
1744         TargetMusic_Advance();
1745         Fog_Force();
1746
1747         if(drawtime == 0)
1748                 drawframetime = 0.01666667; // when we don't know fps yet, we assume 60fps
1749         else
1750                 drawframetime = bound(0.000001, time - drawtime, 1);
1751         drawtime = time;
1752
1753         // watch for gametype changes here...
1754         // in ParseStuffCMD the cmd isn't executed yet :/
1755         // might even be better to add the gametype to TE_CSQC_INIT...?
1756         if(!postinit)
1757                 PostInit();
1758
1759         if(intermission && !intermission_time)
1760                 intermission_time = time;
1761
1762         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
1763         {
1764                 if(calledhooks & HOOK_START)
1765                 {
1766                         localcmd("\ncl_hook_gameend\n");
1767                         calledhooks |= HOOK_END;
1768                 }
1769         }
1770
1771         Announcer();
1772
1773         fov = autocvar_fov;
1774         if(fov <= 59.5)
1775         {
1776                 if(!zoomscript_caught)
1777                 {
1778                         localcmd("+button9\n");
1779                         zoomscript_caught = 1;
1780                 }
1781         }
1782         else
1783         {
1784                 if(zoomscript_caught)
1785                 {
1786                         localcmd("-button9\n");
1787                         zoomscript_caught = 0;
1788                 }
1789         }
1790
1791         ColorTranslateMode = autocvar_cl_stripcolorcodes;
1792
1793         // currently switching-to weapon (for crosshair)
1794         switchingweapon = Weapons_from(STAT(SWITCHINGWEAPON));
1795
1796         // actually active weapon (for zoom)
1797         activeweapon = Weapons_from(STAT(ACTIVEWEAPON));
1798
1799         switchweapon = Weapons_from(STAT(SWITCHWEAPON));
1800
1801         if(last_switchweapon != switchweapon)
1802         {
1803                 weapontime = time;
1804                 last_switchweapon = switchweapon;
1805                 if(button_zoom && autocvar_cl_unpress_zoom_on_weapon_switch)
1806                 {
1807                         localcmd("-zoom\n");
1808                         button_zoom = false;
1809                 }
1810                 if(autocvar_cl_unpress_attack_on_weapon_switch)
1811                 {
1812                         localcmd("-fire\n");
1813                         localcmd("-fire2\n");
1814                         button_attack2 = false;
1815                 }
1816         }
1817         if(last_activeweapon != activeweapon)
1818         {
1819                 last_activeweapon = activeweapon;
1820
1821                 e = activeweapon;
1822                 if(e.netname != "")
1823                         localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
1824                 else
1825                         localcmd("\ncl_hook_activeweapon none\n");
1826         }
1827
1828         // ALWAYS Clear Current Scene First
1829         clearscene();
1830
1831         setproperty(VF_ORIGIN, view_origin);
1832         setproperty(VF_ANGLES, view_angles);
1833
1834         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
1835         setproperty(VF_SIZE, vf_size);
1836         setproperty(VF_MIN, vf_min);
1837
1838         // Assign Standard Viewflags
1839         // Draw the World (and sky)
1840         setproperty(VF_DRAWWORLD, 1);
1841
1842         // Set the console size vars
1843         vid_conwidth = autocvar_vid_conwidth;
1844         vid_conheight = autocvar_vid_conheight;
1845         vid_pixelheight = autocvar_vid_pixelheight;
1846
1847         if(autocvar_cl_orthoview) { setproperty(VF_FOV, GetOrthoviewFOV(ov_worldmin, ov_worldmax, ov_mid, ov_org)); }
1848         else if(csqcplayer.viewloc) { setproperty(VF_FOV, GetViewLocationFOV(110)); } // enforce 110 fov, so things dont look odd
1849         else { setproperty(VF_FOV, GetCurrentFov(fov)); }
1850
1851         if(camera_active) // Camera for demo playback
1852         {
1853                 if(autocvar_camera_enable)
1854                         CSQC_Demo_Camera();
1855                 else
1856                 {
1857                         cvar_set("chase_active", ftos(chase_active_backup));
1858                         cvar_set("cl_demo_mousegrab", "0");
1859                         camera_active = false;
1860                 }
1861         }
1862         else
1863         {
1864 #ifdef CAMERATEST
1865                 if(autocvar_camera_enable)
1866 #else
1867                 if(autocvar_camera_enable && isdemo())
1868 #endif
1869                 {
1870                         // Enable required Darkplaces cvars
1871                         chase_active_backup = autocvar_chase_active;
1872                         cvar_set("chase_active", "2");
1873                         cvar_set("cl_demo_mousegrab", "1");
1874                         camera_active = true;
1875                         camera_mode = false;
1876                 }
1877         }
1878
1879         // Draw the Crosshair
1880         setproperty(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
1881
1882         // Draw the Engine Status Bar (the default Quake HUD)
1883         setproperty(VF_DRAWENGINESBAR, 0);
1884
1885         // Update the mouse position
1886         /*
1887            mousepos_x = vid_conwidth;
1888            mousepos_y = vid_conheight;
1889            mousepos = mousepos*0.5 + getmousepos();
1890          */
1891
1892         IL_EACH(g_drawables, it.draw, it.draw(it));
1893
1894         addentities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
1895         renderscene();
1896
1897         // now switch to 2D drawing mode by calling a 2D drawing function
1898         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
1899         // next R_RenderScene call
1900         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
1901
1902         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
1903         if (!(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT))
1904         {
1905                 // apply night vision effect
1906                 vector tc_00, tc_01, tc_10, tc_11;
1907                 vector rgb = '0 0 0';
1908
1909                 if(!nightvision_noise)
1910                 {
1911                         nightvision_noise = new(nightvision_noise);
1912                 }
1913                 if(!nightvision_noise2)
1914                 {
1915                         nightvision_noise2 = new(nightvision_noise2);
1916                 }
1917
1918                 // color tint in yellow
1919                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
1920
1921                 // draw BG
1922                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
1923                 rgb = '1 1 1';
1924                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
1925                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
1926                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
1927                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
1928                 tc_11 = tc_01 + tc_10 - tc_00;
1929                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
1930                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
1931                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
1932                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
1933                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
1934                 R_EndPolygon();
1935
1936                 // draw FG
1937                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
1938                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
1939                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
1940                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
1941                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
1942                 tc_11 = tc_01 + tc_10 - tc_00;
1943                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
1944                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
1945                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
1946                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
1947                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
1948                 R_EndPolygon();
1949         }
1950
1951         if(autocvar_cl_reticle)
1952         {
1953                 Weapon wep = activeweapon;
1954                 // Draw the aiming reticle for weapons that use it
1955                 // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
1956                 // It must be a persisted float for fading out to work properly (you let go of the zoom button for
1957                 // the view to go back to normal, so reticle_type would become 0 as we fade out)
1958                 if(spectatee_status || is_dead || hud != HUD_NORMAL)
1959                 {
1960                         // no zoom reticle while dead
1961                         reticle_type = 0;
1962                 }
1963                 else if(wep.wr_zoomreticle(wep) && autocvar_cl_reticle_weapon)
1964                 {
1965                         if(reticle_image != "") { reticle_type = 2; }
1966                         else { reticle_type = 0; }
1967                 }
1968                 else if(button_zoom || zoomscript_caught)
1969                 {
1970                         // normal zoom
1971                         reticle_type = 1;
1972                 }
1973
1974                 if(reticle_type)
1975                 {
1976                         if(autocvar_cl_reticle_stretch)
1977                         {
1978                                 reticle_size.x = vid_conwidth;
1979                                 reticle_size.y = vid_conheight;
1980                                 reticle_pos.x = 0;
1981                                 reticle_pos.y = 0;
1982                         }
1983                         else
1984                         {
1985                                 reticle_size.x = max(vid_conwidth, vid_conheight);
1986                                 reticle_size.y = max(vid_conwidth, vid_conheight);
1987                                 reticle_pos.x = (vid_conwidth - reticle_size.x) / 2;
1988                                 reticle_pos.y = (vid_conheight - reticle_size.y) / 2;
1989                         }
1990
1991                         if(zoomscript_caught)
1992                                 f = 1;
1993                         else
1994                                 f = current_zoomfraction;
1995
1996                         if(f)
1997                         {
1998                                 switch(reticle_type)
1999                                 {
2000                                         case 1: drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_normal_alpha, DRAWFLAG_NORMAL); break;
2001                                         case 2: drawpic(reticle_pos, reticle_image, reticle_size, '1 1 1', f * autocvar_cl_reticle_weapon_alpha, DRAWFLAG_NORMAL); break;
2002                                 }
2003                         }
2004                 }
2005         }
2006         else
2007         {
2008                 if(reticle_type != 0) { reticle_type = 0; }
2009         }
2010
2011
2012         // improved polyblend
2013         if(autocvar_hud_contents)
2014         {
2015                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
2016                 vector liquidcolor;
2017
2018                 switch(pointcontents(view_origin))
2019                 {
2020                         case CONTENT_WATER:
2021                                 liquidalpha = autocvar_hud_contents_water_alpha;
2022                                 liquidcolor = stov(autocvar_hud_contents_water_color);
2023                                 incontent = 1;
2024                                 break;
2025
2026                         case CONTENT_LAVA:
2027                                 liquidalpha = autocvar_hud_contents_lava_alpha;
2028                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
2029                                 incontent = 1;
2030                                 break;
2031
2032                         case CONTENT_SLIME:
2033                                 liquidalpha = autocvar_hud_contents_slime_alpha;
2034                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
2035                                 incontent = 1;
2036                                 break;
2037
2038                         default:
2039                                 liquidalpha = 0;
2040                                 liquidcolor = '0 0 0';
2041                                 incontent = 0;
2042                                 break;
2043                 }
2044
2045                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
2046                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
2047                         contentfadetime = autocvar_hud_contents_fadeintime;
2048                         liquidalpha_prev = liquidalpha;
2049                         liquidcolor_prev = liquidcolor;
2050                 }
2051                 else
2052                         contentfadetime = autocvar_hud_contents_fadeouttime;
2053
2054                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
2055                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
2056
2057                 if(contentavgalpha)
2058                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
2059
2060                 if(autocvar_hud_postprocessing)
2061                 {
2062                         if(autocvar_hud_contents_blur && contentavgalpha)
2063                         {
2064                                 content_blurpostprocess.x = 1;
2065                                 content_blurpostprocess.y = contentavgalpha * autocvar_hud_contents_blur;
2066                                 content_blurpostprocess.z = contentavgalpha * autocvar_hud_contents_blur_alpha;
2067                         }
2068                         else
2069                         {
2070                                 content_blurpostprocess.x = 0;
2071                                 content_blurpostprocess.y = 0;
2072                                 content_blurpostprocess.z = 0;
2073                         }
2074                 }
2075         }
2076
2077         if(autocvar_hud_damage && !STAT(FROZEN))
2078         {
2079                 splash_size.x = max(vid_conwidth, vid_conheight);
2080                 splash_size.y = max(vid_conwidth, vid_conheight);
2081                 splash_pos.x = (vid_conwidth - splash_size.x) / 2;
2082                 splash_pos.y = (vid_conheight - splash_size.y) / 2;
2083
2084                 float myhealth_flash_temp;
2085                 myhealth = STAT(HEALTH);
2086
2087                 // fade out
2088                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
2089                 // add new damage
2090                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
2091
2092                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
2093                 pain_threshold = autocvar_hud_damage_pain_threshold;
2094                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
2095                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
2096
2097                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
2098                 {
2099                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
2100                 }
2101
2102                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
2103
2104                 if(myhealth_prev < 1)
2105                 {
2106                         if(myhealth >= 1)
2107                         {
2108                                 myhealth_flash = 0; // just spawned, clear the flash immediately
2109                                 myhealth_flash_temp = 0;
2110                         }
2111                         else
2112                         {
2113                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
2114                         }
2115                 }
2116
2117                 if(spectatee_status == -1 || intermission)
2118                 {
2119                         myhealth_flash = 0; // observing, or match ended
2120                         myhealth_flash_temp = 0;
2121                 }
2122
2123                 myhealth_prev = myhealth;
2124
2125                 // IDEA: change damage color/picture based on player model for robot/alien species?
2126                 // pro: matches model better
2127                 // contra: it's not red because blood is red, but because red is an alarming color, so red should stay
2128                 // maybe different reddish pics?
2129                 if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
2130                 {
2131                         if(autocvar_cl_gentle_damage == 2)
2132                         {
2133                                 if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
2134                                         myhealth_gentlergb = eX * random() + eY * random() + eZ * random();
2135                         }
2136                         else
2137                                 myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
2138
2139                         if(myhealth_flash_temp > 0)
2140                                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
2141                 }
2142                 else if(myhealth_flash_temp > 0)
2143                         drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
2144
2145                 if(autocvar_hud_postprocessing) // we still need to set this anyway even when chase_active is set, this way it doesn't get stuck on.
2146                 {
2147                         if(autocvar_hud_damage_blur && myhealth_flash_temp)
2148                         {
2149                                 damage_blurpostprocess.x = 1;
2150                                 damage_blurpostprocess.y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
2151                                 damage_blurpostprocess.z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
2152                         }
2153                         else
2154                         {
2155                                 damage_blurpostprocess.x = 0;
2156                                 damage_blurpostprocess.y = 0;
2157                                 damage_blurpostprocess.z = 0;
2158                         }
2159                 }
2160         }
2161
2162         float e1 = (autocvar_hud_postprocessing_maxbluralpha != 0);
2163         float e2 = (autocvar_hud_powerup != 0);
2164         if(autocvar_hud_postprocessing && (e1 || e2)) // TODO: Remove this code and re-do the postprocess handling in the engine, where it properly belongs.
2165         {
2166                 // enable or disable rendering types if they are used or not
2167                 if(cvar("r_glsl_postprocess_uservec1_enable") != e1) { cvar_set("r_glsl_postprocess_uservec1_enable", ftos(e1)); }
2168                 if(cvar("r_glsl_postprocess_uservec2_enable") != e2) { cvar_set("r_glsl_postprocess_uservec2_enable", ftos(e2)); }
2169
2170                 // blur postprocess handling done first (used by hud_damage and hud_contents)
2171                 if((damage_blurpostprocess.x || content_blurpostprocess.x))
2172                 {
2173                         float blurradius = bound(0, damage_blurpostprocess.y + content_blurpostprocess.y, autocvar_hud_postprocessing_maxblurradius);
2174                         float bluralpha = bound(0, damage_blurpostprocess.z + content_blurpostprocess.z, autocvar_hud_postprocessing_maxbluralpha);
2175                         if(blurradius != old_blurradius || bluralpha != old_bluralpha) // reduce cvar_set spam as much as possible
2176                         {
2177                                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
2178                                 old_blurradius = blurradius;
2179                                 old_bluralpha = bluralpha;
2180                         }
2181                 }
2182                 else if(cvar_string("r_glsl_postprocess_uservec1") != "0 0 0 0") // reduce cvar_set spam as much as possible
2183                 {
2184                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
2185                         old_blurradius = 0;
2186                         old_bluralpha = 0;
2187                 }
2188
2189                 // edge detection postprocess handling done second (used by hud_powerup)
2190                 float sharpen_intensity = 0, strength_finished = STAT(STRENGTH_FINISHED), invincible_finished = STAT(INVINCIBLE_FINISHED);
2191                 if (strength_finished - time > 0) { sharpen_intensity += (strength_finished - time); }
2192                 if (invincible_finished - time > 0) { sharpen_intensity += (invincible_finished - time); }
2193
2194                 sharpen_intensity = bound(0, ((STAT(HEALTH) > 0) ? sharpen_intensity : 0), 5); // Check to see if player is alive (if not, set 0) - also bound to fade out starting at 5 seconds.
2195
2196                 if(autocvar_hud_powerup && sharpen_intensity > 0)
2197                 {
2198                         if(sharpen_intensity != old_sharpen_intensity) // reduce cvar_set spam as much as possible
2199                         {
2200                                 cvar_set("r_glsl_postprocess_uservec2", strcat(ftos((sharpen_intensity / 5) * autocvar_hud_powerup), " ", ftos(-sharpen_intensity * autocvar_hud_powerup), " 0 0"));
2201                                 old_sharpen_intensity = sharpen_intensity;
2202                         }
2203                 }
2204                 else if(cvar_string("r_glsl_postprocess_uservec2") != "0 0 0 0") // reduce cvar_set spam as much as possible
2205                 {
2206                         cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
2207                         old_sharpen_intensity = 0;
2208                 }
2209
2210                 if(cvar("r_glsl_postprocess") == 0)
2211                         cvar_set("r_glsl_postprocess", "2");
2212         }
2213         else if(cvar("r_glsl_postprocess") == 2)
2214                 cvar_set("r_glsl_postprocess", "0");
2215
2216         /*if(gametype == MAPINFO_TYPE_CTF)
2217           {
2218           ctf_view();
2219           } else */
2220
2221         // draw 2D entities
2222         IL_EACH(g_drawables_2d, it.draw2d, it.draw2d(it));
2223         Draw_ShowNames_All();
2224         Debug_Draw();
2225
2226         scoreboard_active = Scoreboard_WouldDraw();
2227
2228         HUD_Draw(this); // this parameter for deep vehicle function
2229
2230         if(NextFrameCommand)
2231         {
2232                 localcmd("\n", NextFrameCommand, "\n");
2233                 NextFrameCommand = string_null;
2234         }
2235
2236         // we must do this check AFTER a frame was rendered, or it won't work
2237         if(cs_project_is_b0rked == 0)
2238         {
2239                 string w0, h0;
2240                 w0 = ftos(autocvar_vid_conwidth);
2241                 h0 = ftos(autocvar_vid_conheight);
2242                 //setproperty(VF_VIEWPORT, '0 0 0', '640 480 0');
2243                 //setproperty(VF_FOV, '90 90 0');
2244                 setproperty(VF_ORIGIN, '0 0 0');
2245                 setproperty(VF_ANGLES, '0 0 0');
2246                 setproperty(VF_PERSPECTIVE, 1);
2247                 makevectors('0 0 0');
2248                 vector v1, v2;
2249                 cvar_set("vid_conwidth", "800");
2250                 cvar_set("vid_conheight", "600");
2251                 v1 = cs_project(v_forward);
2252                 cvar_set("vid_conwidth", "640");
2253                 cvar_set("vid_conheight", "480");
2254                 v2 = cs_project(v_forward);
2255                 if(v1 == v2)
2256                         cs_project_is_b0rked = 1;
2257                 else
2258                         cs_project_is_b0rked = -1;
2259                 cvar_set("vid_conwidth", w0);
2260                 cvar_set("vid_conheight", h0);
2261         }
2262
2263         if(autocvar__hud_configure)
2264                 HUD_Panel_Mouse();
2265         else if (HUD_MinigameMenu_IsOpened() || active_minigame)
2266                 HUD_Minigame_Mouse();
2267         else if(QuickMenu_IsOpened())
2268                 QuickMenu_Mouse();
2269         else
2270                 HUD_Radar_Mouse();
2271
2272         cl_notice_run();
2273         unpause_update();
2274         Net_Flush();
2275
2276         // let's reset the view back to normal for the end
2277         setproperty(VF_MIN, '0 0 0');
2278         setproperty(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
2279
2280         IL_ENDFRAME();
2281 }
2282
2283
2284 // following vectors must be global to allow seamless switching between camera modes
2285 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
2286 void CSQC_Demo_Camera()
2287 {
2288         float speed, attenuation, dimensions;
2289         vector tmp, delta;
2290
2291         if( autocvar_camera_reset || !camera_mode )
2292         {
2293                 camera_offset = '0 0 0';
2294                 current_angles = '0 0 0';
2295                 camera_direction = '0 0 0';
2296                 camera_offset.z += 30;
2297                 camera_offset.x += 30 * -cos(current_angles.y * DEG2RAD);
2298                 camera_offset.y += 30 * -sin(current_angles.y * DEG2RAD);
2299                 current_origin = view_origin;
2300                 current_camera_offset  = camera_offset;
2301                 cvar_set("camera_reset", "0");
2302                 camera_mode = CAMERA_CHASE;
2303         }
2304
2305         // Camera angles
2306         if( camera_roll )
2307                 mouse_angles.z += camera_roll * autocvar_camera_speed_roll;
2308
2309         if(autocvar_camera_look_player)
2310         {
2311                 vector dir;
2312                 float n;
2313
2314                 dir = normalize(view_origin - current_position);
2315                 n = mouse_angles.z;
2316                 mouse_angles = vectoangles(dir);
2317                 mouse_angles.x = mouse_angles.x * -1;
2318                 mouse_angles.z = n;
2319         }
2320         else
2321         {
2322                 tmp = getmousepos() * 0.1;
2323                 if(vdist(tmp, >, autocvar_camera_mouse_threshold))
2324                 {
2325                         mouse_angles.x += tmp.y * cos(mouse_angles.z * DEG2RAD) + (tmp.x * sin(mouse_angles.z * DEG2RAD));
2326                         mouse_angles.y -= tmp.x * cos(mouse_angles.z * DEG2RAD) + (tmp.y * -sin(mouse_angles.z * DEG2RAD));
2327                 }
2328         }
2329
2330         while (mouse_angles.x < -180) mouse_angles.x = mouse_angles.x + 360;
2331         while (mouse_angles.x > 180) mouse_angles.x = mouse_angles.x - 360;
2332         while (mouse_angles.y < -180) mouse_angles.y = mouse_angles.y + 360;
2333         while (mouse_angles.y > 180) mouse_angles.y = mouse_angles.y - 360;
2334
2335         // Fix difference when angles don't have the same sign
2336         delta = '0 0 0';
2337         if(mouse_angles.y < -60 && current_angles.y > 60)
2338                 delta = '0 360 0';
2339         if(mouse_angles.y > 60 && current_angles.y < -60)
2340                 delta = '0 -360 0';
2341
2342         if(autocvar_camera_look_player)
2343                 attenuation = autocvar_camera_look_attenuation;
2344         else
2345                 attenuation = autocvar_camera_speed_attenuation;
2346
2347         attenuation = 1 / max(1, attenuation);
2348         current_angles += (mouse_angles - current_angles + delta) * attenuation;
2349
2350         while (current_angles.x < -180) current_angles.x = current_angles.x + 360;
2351         while (current_angles.x > 180) current_angles.x = current_angles.x - 360;
2352         while (current_angles.y < -180) current_angles.y = current_angles.y + 360;
2353         while (current_angles.y > 180) current_angles.y = current_angles.y - 360;
2354
2355         // Camera position
2356         tmp = '0 0 0';
2357         dimensions = 0;
2358
2359         if( camera_direction.x )
2360         {
2361                 tmp.x = camera_direction.x * cos(current_angles.y * DEG2RAD);
2362                 tmp.y = camera_direction.x * sin(current_angles.y * DEG2RAD);
2363                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
2364                         tmp.z = camera_direction.x * -sin(current_angles.x * DEG2RAD);
2365                 ++dimensions;
2366         }
2367
2368         if( camera_direction.y )
2369         {
2370                 tmp.x += camera_direction.y * -sin(current_angles.y * DEG2RAD);
2371                 tmp.y += camera_direction.y * cos(current_angles.y * DEG2RAD) * cos(current_angles.z * DEG2RAD);
2372                 tmp.z += camera_direction.y * sin(current_angles.z * DEG2RAD);
2373                 ++dimensions;
2374         }
2375
2376         if( camera_direction.z )
2377         {
2378                 tmp.z += camera_direction.z * cos(current_angles.z * DEG2RAD);
2379                 ++dimensions;
2380         }
2381
2382         if(autocvar_camera_free)
2383                 speed = autocvar_camera_speed_free;
2384         else
2385                 speed = autocvar_camera_speed_chase;
2386
2387         if(dimensions)
2388         {
2389                 speed = speed * sqrt(1 / dimensions);
2390                 camera_offset += tmp * speed;
2391         }
2392
2393         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
2394
2395         // Camera modes
2396         if( autocvar_camera_free )
2397         {
2398                 if ( camera_mode == CAMERA_CHASE )
2399                 {
2400                         current_camera_offset = current_origin + current_camera_offset;
2401                         camera_offset = current_origin + camera_offset;
2402                 }
2403
2404                 camera_mode = CAMERA_FREE;
2405                 current_position = current_camera_offset;
2406         }
2407         else
2408         {
2409                 if ( camera_mode == CAMERA_FREE )
2410                 {
2411                         current_origin = view_origin;
2412                         camera_offset = camera_offset - current_origin;
2413                         current_camera_offset = current_camera_offset - current_origin;
2414                 }
2415
2416                 camera_mode = CAMERA_CHASE;
2417
2418                 if(autocvar_camera_chase_smoothly)
2419                         current_origin += (view_origin - current_origin) * attenuation;
2420                 else
2421                         current_origin = view_origin;
2422
2423                 current_position = current_origin + current_camera_offset;
2424         }
2425
2426         setproperty(VF_ANGLES, current_angles);
2427         setproperty(VF_ORIGIN, current_position);
2428 }