qcsrc/client/view.qc

   1 #include "view.qh"
   2
   3 #include "announcer.qh"
   4 #include "hud/_mod.qh"
   5 #include "mapvoting.qh"
   6 #include "shownames.qh"
   7 #include "hud/panel/scoreboard.qh"
   8 #include "hud/panel/quickmenu.qh"
   9
  10 #include "mutators/events.qh"
  11
  12 #include <common/animdecide.qh>
  13 #include <common/ent_cs.qh>
  14 #include <common/anim.qh>
  15 #include <common/constants.qh>
  16 #include <common/net_linked.qh>
  17 #include <common/debug.qh>
  18 #include <common/mapinfo.qh>
  19 #include <common/gamemodes/_mod.qh>
  20 #include <common/physics/player.qh>
  21 #include <common/stats.qh>
  22 #include <common/triggers/target/music.qh>
  23 #include <common/teams.qh>
  24
  25 #include <common/weapons/weapon/tuba.qh>
  26
  27 #include <common/vehicles/all.qh>
  28 #include <common/weapons/_all.qh>
  29 #include <common/viewloc.qh>
  30 #include <common/minigames/cl_minigames.qh>
  31 #include <common/minigames/cl_minigames_hud.qh>
  32
  33 #include <lib/csqcmodel/cl_player.qh>
  34 #include <lib/csqcmodel/cl_model.qh>
  35 #include "csqcmodel_hooks.qh"
  36
  37 #include <lib/warpzone/client.qh>
  38 #include <lib/warpzone/common.qh>
  39
  40 #define EFMASK_CHEAP (EF_ADDITIVE | EF_DOUBLESIDED | EF_FULLBRIGHT | EF_NODEPTHTEST | EF_NODRAW | EF_NOSHADOW | EF_SELECTABLE | EF_TELEPORT_BIT)
  41
  42 float autocvar_cl_viewmodel_scale;
  43
  44 bool autocvar_cl_bobmodel;
  45 float autocvar_cl_bobmodel_speed;
  46 float autocvar_cl_bobmodel_side;
  47 float autocvar_cl_bobmodel_up;
  48
  49 float autocvar_cl_followmodel;
  50 float autocvar_cl_followmodel_speed = 0.3;
  51 float autocvar_cl_followmodel_limit = 135;
  52 float autocvar_cl_followmodel_velocity_lowpass = 0.05;
  53 float autocvar_cl_followmodel_highpass = 0.05;
  54 float autocvar_cl_followmodel_lowpass = 0.03;
  55 bool autocvar_cl_followmodel_velocity_absolute;
  56
  57 float autocvar_cl_leanmodel;
  58 float autocvar_cl_leanmodel_speed = 0.3;
  59 float autocvar_cl_leanmodel_limit = 30;
  60 float autocvar_cl_leanmodel_highpass1 = 0.2;
  61 float autocvar_cl_leanmodel_highpass = 0.2;
  62 float autocvar_cl_leanmodel_lowpass = 0.05;
  63
  64 #define avg_factor(avg_time) (1 - exp(-frametime / max(0.001, avg_time)))
  65 #define lowpass(value, frac, ref_store, ret) MACRO_BEGIN \
  66 { \
  67         ret = ref_store = ref_store * (1 - frac) + (value) * frac; \
  68 } MACRO_END
  69
  70 #define lowpass_limited(value, frac, limit, ref_store, ret) MACRO_BEGIN \
  71 { \
  72         float __ignore; lowpass(value, frac, ref_store, __ignore); \
  73         ret = ref_store = bound((value) - (limit), ref_store, (value) + (limit)); \
  74 } MACRO_END
  75
  76 #define highpass(value, frac, ref_store, ret) MACRO_BEGIN \
  77 { \
  78         float __f = 0; lowpass(value, frac, ref_store, __f); \
  79         ret = (value) - __f; \
  80 } MACRO_END
  81
  82 #define highpass_limited(value, frac, limit, ref_store, ret) MACRO_BEGIN \
  83 { \
  84         float __f = 0; lowpass_limited(value, frac, limit, ref_store, __f); \
  85         ret = (value) - __f; \
  86 } MACRO_END
  87
  88 #define lowpass2(value, frac, ref_store, ref_out) MACRO_BEGIN \
  89 { \
  90         lowpass(value.x, frac, ref_store.x, ref_out.x); \
  91         lowpass(value.y, frac, ref_store.y, ref_out.y); \
  92 } MACRO_END
  93
  94 #define highpass2(value, frac, ref_store, ref_out) MACRO_BEGIN \
  95 { \
  96         highpass(value.x, frac, ref_store.x, ref_out.x); \
  97         highpass(value.y, frac, ref_store.y, ref_out.y); \
  98 } MACRO_END
  99
 100 #define highpass2_limited(value, frac, limit, ref_store, ref_out) MACRO_BEGIN \
 101 { \
 102         highpass_limited(value.x, frac, limit, ref_store.x, ref_out.x); \
 103         highpass_limited(value.y, frac, limit, ref_store.y, ref_out.y); \
 104 } MACRO_END
 105
 106 #define lowpass3(value, frac, ref_store, ref_out) MACRO_BEGIN \
 107 { \
 108         lowpass(value.x, frac, ref_store.x, ref_out.x); \
 109         lowpass(value.y, frac, ref_store.y, ref_out.y); \
 110         lowpass(value.z, frac, ref_store.z, ref_out.z); \
 111 } MACRO_END
 112
 113 #define highpass3(value, frac, ref_store, ref_out) MACRO_BEGIN \
 114 { \
 115         highpass(value.x, frac, ref_store.x, ref_out.x); \
 116         highpass(value.y, frac, ref_store.y, ref_out.y); \
 117         highpass(value.z, frac, ref_store.z, ref_out.z); \
 118 } MACRO_END
 119
 120 void calc_followmodel_ofs(entity view)
 121 {
 122         if(cl_followmodel_time == time)
 123                 return; // cl_followmodel_ofs already calculated for this frame
 124
 125         float frac;
 126         vector gunorg = '0 0 0';
 127         static vector vel_average;
 128         static vector gunorg_adjustment_highpass;
 129         static vector gunorg_adjustment_lowpass;
 130
 131         vector vel;
 132         if (autocvar_cl_followmodel_velocity_absolute)
 133                 vel = view.velocity;
 134         else
 135         {
 136                 vector forward = '0 0 0', right = '0 0 0', up = '0 0 0';
 137                 MAKEVECTORS(makevectors, view_angles, forward, right, up);
 138                 vel.x = view.velocity * forward;
 139                 vel.y = view.velocity * right * -1;
 140                 vel.z = view.velocity * up;
 141         }
 142
 143         vel.x = bound(vel_average.x - autocvar_cl_followmodel_limit, vel.x, vel_average.x + autocvar_cl_followmodel_limit);
 144         vel.y = bound(vel_average.y - autocvar_cl_followmodel_limit, vel.y, vel_average.y + autocvar_cl_followmodel_limit);
 145         vel.z = bound(vel_average.z - autocvar_cl_followmodel_limit, vel.z, vel_average.z + autocvar_cl_followmodel_limit);
 146
 147         frac = avg_factor(autocvar_cl_followmodel_velocity_lowpass);
 148         lowpass3(vel, frac, vel_average, gunorg);
 149
 150         gunorg *= -autocvar_cl_followmodel_speed * 0.042;
 151
 152         // perform highpass/lowpass on the adjustment vectors (turning velocity into acceleration!)
 153         // trick: we must do the lowpass LAST, so the lowpass vector IS the final vector!
 154         frac = avg_factor(autocvar_cl_followmodel_highpass);
 155         highpass3(gunorg, frac, gunorg_adjustment_highpass, gunorg);
 156         frac = avg_factor(autocvar_cl_followmodel_lowpass);
 157         lowpass3(gunorg, frac, gunorg_adjustment_lowpass, gunorg);
 158
 159         if (autocvar_cl_followmodel_velocity_absolute)
 160         {
 161                 vector fixed_gunorg;
 162                 vector forward = '0 0 0', right = '0 0 0', up = '0 0 0';
 163                 MAKEVECTORS(makevectors, view_angles, forward, right, up);
 164                 fixed_gunorg.x = gunorg * forward;
 165                 fixed_gunorg.y = gunorg * right * -1;
 166                 fixed_gunorg.z = gunorg * up;
 167                 gunorg = fixed_gunorg;
 168         }
 169
 170         cl_followmodel_ofs = gunorg;
 171         cl_followmodel_time = time;
 172 }
 173
 174 vector leanmodel_ofs(entity view)
 175 {
 176         float frac;
 177         vector gunangles = '0 0 0';
 178         static vector gunangles_prev = '0 0 0';
 179         static vector gunangles_highpass = '0 0 0';
 180         static vector gunangles_adjustment_highpass;
 181         static vector gunangles_adjustment_lowpass;
 182
 183         if (view.csqcmodel_teleported)
 184                 gunangles_prev = view_angles;
 185
 186         // in the highpass, we _store_ the DIFFERENCE to the actual view angles...
 187         gunangles_highpass += gunangles_prev;
 188         PITCH(gunangles_highpass) += 360 * floor((PITCH(view_angles) - PITCH(gunangles_highpass)) / 360 + 0.5);
 189         YAW(gunangles_highpass) += 360 * floor((YAW(view_angles) - YAW(gunangles_highpass)) / 360 + 0.5);
 190         ROLL(gunangles_highpass) += 360 * floor((ROLL(view_angles) - ROLL(gunangles_highpass)) / 360 + 0.5);
 191         frac = avg_factor(autocvar_cl_leanmodel_highpass1);
 192         highpass2_limited(view_angles, frac, autocvar_cl_leanmodel_limit, gunangles_highpass, gunangles);
 193         gunangles_prev = view_angles;
 194         gunangles_highpass -= gunangles_prev;
 195
 196         PITCH(gunangles) *= -autocvar_cl_leanmodel_speed;
 197         YAW(gunangles) *= -autocvar_cl_leanmodel_speed;
 198
 199         // we assume here: PITCH = 0, YAW = 1, ROLL = 2
 200         frac = avg_factor(autocvar_cl_leanmodel_highpass);
 201         highpass2(gunangles, frac, gunangles_adjustment_highpass, gunangles);
 202         frac = avg_factor(autocvar_cl_leanmodel_lowpass);
 203         lowpass2(gunangles, frac, gunangles_adjustment_lowpass, gunangles);
 204
 205         gunangles.x = -gunangles.x; // pitch was inverted, now that actually matters
 206
 207         return gunangles;
 208 }
 209
 210 vector bobmodel_ofs(entity view)
 211 {
 212         bool clonground = !(view.anim_implicit_state & ANIMIMPLICITSTATE_INAIR);
 213         static bool oldonground;
 214         static float hitgroundtime;
 215         if (clonground)
 216         {
 217                 float f = time; // cl.movecmd[0].time
 218                 if (!oldonground)
 219                         hitgroundtime = f;
 220         }
 221         oldonground = clonground;
 222
 223         // calculate for swinging gun model
 224         // the gun bobs when running on the ground, but doesn't bob when you're in the air.
 225         vector gunorg = '0 0 0';
 226         static float bobmodel_scale = 0;
 227         static float time_ofs = 0; // makes the effect always restart in the same way
 228         if (clonground)
 229         {
 230                 if (time - hitgroundtime > 0.05)
 231                         bobmodel_scale = min(1, bobmodel_scale + frametime * 5);
 232         }
 233         else
 234                 bobmodel_scale = max(0, bobmodel_scale - frametime * 5);
 235
 236         float xyspeed = bound(0, vlen(vec2(view.velocity)), 400);
 237         if (bobmodel_scale && xyspeed)
 238         {
 239                 float bspeed = xyspeed * 0.01 * autocvar_cl_viewmodel_scale * bobmodel_scale;
 240                 float s = (time - time_ofs) * autocvar_cl_bobmodel_speed;
 241                 gunorg.y = bspeed * autocvar_cl_bobmodel_side * sin(s);
 242                 gunorg.z = bspeed * autocvar_cl_bobmodel_up * cos(s * 2);
 243         }
 244         else
 245                 time_ofs = time;
 246
 247         return gunorg;
 248 }
 249
 250 void viewmodel_animate(entity this)
 251 {
 252         if (autocvar_chase_active) return;
 253         if (STAT(HEALTH) <= 0) return;
 254
 255         entity view = CSQCModel_server2csqc(player_localentnum - 1);
 256
 257         if (autocvar_cl_followmodel)
 258         {
 259                 calc_followmodel_ofs(view);
 260                 this.origin += cl_followmodel_ofs;
 261         }
 262
 263         if (autocvar_cl_leanmodel)
 264                 this.angles += leanmodel_ofs(view);
 265
 266         // vertical view bobbing code
 267         // TODO: cl_bob
 268
 269         // horizontal view bobbing code
 270         // TODO: cl_bob2
 271
 272         // fall bobbing code
 273         // causes the view to swing down and back up when touching the ground
 274         // TODO: cl_bobfall
 275
 276         // gun model bobbing code
 277         if (autocvar_cl_bobmodel)
 278                 this.origin += bobmodel_ofs(view);
 279 }
 280
 281 .vector viewmodel_origin, viewmodel_angles;
 282 .float weapon_nextthink;
 283 .float weapon_eta_last;
 284 .float weapon_switchdelay;
 285
 286 .string name_last;
 287
 288 void viewmodel_draw(entity this)
 289 {
 290         if(!this.activeweapon || !autocvar_r_drawviewmodel)
 291                 return;
 292         int mask = (intermission || (STAT(HEALTH) <= 0) || autocvar_chase_active) ? 0 : MASK_NORMAL;
 293         float a = this.alpha;
 294         static bool wasinvehicle;
 295         bool invehicle = player_localentnum > maxclients;
 296         if (invehicle) a = -1;
 297         else if (wasinvehicle) a = 1;
 298         wasinvehicle = invehicle;
 299         Weapon wep = this.activeweapon;
 300         int c = entcs_GetClientColors(current_player);
 301         vector g = weaponentity_glowmod(wep, NULL, c, this);
 302         entity me = CSQCModel_server2csqc(player_localentnum - 1);
 303         int fx = ((me.csqcmodel_effects & EFMASK_CHEAP)
 304                 | EF_NODEPTHTEST)
 305                 &~ (EF_FULLBRIGHT); // can mask team color, so get rid of it
 306         for (entity e = this; e; e = e.weaponchild)
 307         {
 308                 e.drawmask = mask;
 309                 e.alpha = a;
 310                 e.colormap = 256 + c;  // colormap == 0 is black, c == 0 is white
 311                 e.glowmod = g;
 312                 e.csqcmodel_effects = fx;
 313                 CSQCModel_Effects_Apply(e);
 314         }
 315         {
 316                 string name = wep.mdl;
 317                 string newname = wep.wr_viewmodel(wep, this);
 318                 if(newname)
 319                         name = newname;
 320                 bool swap = name != this.name_last;
 321                 // if (swap)
 322                 {
 323                         this.name_last = name;
 324                         CL_WeaponEntity_SetModel(this, name, swap);
 325                         this.viewmodel_origin = this.origin;
 326                         this.viewmodel_angles = this.angles;
 327                 }
 328                 anim_update(this);
 329                 if ((!this.animstate_override && !this.animstate_looping) || time > this.animstate_endtime)
 330                         anim_set(this, this.anim_idle, true, false, false);
 331         }
 332         float f = 0; // 0..1; 0: fully active
 333         float rate = STAT(WEAPONRATEFACTOR);
 334         float eta = rate ? ((this.weapon_nextthink - time) / rate) : 0;
 335         if (eta <= 0) f = this.weapon_eta_last;
 336         else switch (this.state)
 337         {
 338                 case WS_RAISE:
 339                 {
 340                         f = eta / max(eta, this.weapon_switchdelay);
 341                         break;
 342                 }
 343                 case WS_DROP:
 344                 {
 345                         f = 1 - eta / max(eta, this.weapon_switchdelay);
 346                         break;
 347                 }
 348                 case WS_CLEAR:
 349                 {
 350                         f = 1;
 351                         break;
 352                 }
 353         }
 354         this.weapon_eta_last = f;
 355         this.origin = this.viewmodel_origin;
 356         this.angles = this.viewmodel_angles;
 357         this.angles_x = (-90 * f * f);
 358         viewmodel_animate(this);
 359         setorigin(this, this.origin);
 360 }
 361
 362 STATIC_INIT(viewmodel) {
 363     for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 364         viewmodels[slot] = new(viewmodel);
 365 }
 366
 367 void Porto_Draw(entity this);
 368 STATIC_INIT(Porto)
 369 {
 370         entity e = new_pure(porto);
 371         e.draw = Porto_Draw;
 372         IL_PUSH(g_drawables, e);
 373         e.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 374 }
 375
 376 const int polyline_length = 16;
 377 .vector polyline[polyline_length];
 378 void Porto_Draw(entity this)
 379 {
 380         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 381         {
 382                 entity wepent = viewmodels[slot];
 383
 384                 if (wepent.activeweapon != WEP_PORTO) continue;
 385                 if (spectatee_status) continue;
 386                 if (WEP_CVAR(porto, secondary)) continue;
 387                 if (intermission == 1) continue;
 388                 if (intermission == 2) continue;
 389                 if (STAT(HEALTH) <= 0) continue;
 390
 391                 vector pos = view_origin;
 392                 vector dir = view_forward;
 393                 if (wepent.angles_held_status)
 394                 {
 395                         makevectors(wepent.angles_held);
 396                         dir = v_forward;
 397                 }
 398
 399                 wepent.polyline[0] = pos;
 400
 401                 int portal_number = 0, portal1_idx = 1, portal_max = 2;
 402                 int n = 1 + 2;  // 2 lines == 3 points
 403                 for (int idx = 0; idx < n && idx < polyline_length - 1; )
 404                 {
 405                         traceline(pos, pos + 65536 * dir, true, this);
 406                         dir = reflect(dir, trace_plane_normal);
 407                         pos = trace_endpos;
 408                         wepent.polyline[++idx] = pos;
 409                         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
 410                         {
 411                                 n += 1;
 412                                 continue;
 413                         }
 414                         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
 415                         {
 416                                 n = max(2, idx);
 417                                 break;
 418                         }
 419                         // check size
 420                         {
 421                                 vector ang = vectoangles2(trace_plane_normal, dir);
 422                                 ang.x = -ang.x;
 423                                 makevectors(ang);
 424                                 if (!CheckWireframeBox(this, pos - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
 425                                 {
 426                                         n = max(2, idx);
 427                                         break;
 428                                 }
 429                         }
 430                         portal_number += 1;
 431                         if (portal_number >= portal_max) break;
 432                         if (portal_number == 1) portal1_idx = idx;
 433                 }
 434                 for (int idx = 0; idx < n - 1; ++idx)
 435                 {
 436                         vector p = wepent.polyline[idx], q = wepent.polyline[idx + 1];
 437                         if (idx == 0) p -= view_up * 16;  // line from player
 438                         vector rgb = (idx < portal1_idx) ? '1 0 0' : '0 0 1';
 439                         Draw_CylindricLine(p, q, 4, "", 1, 0, rgb, 0.5, DRAWFLAG_NORMAL, view_origin);
 440                 }
 441         }
 442 }
 443
 444 float drawtime;
 445 float avgspeed;
 446 vector GetCurrentFov(float fov)
 447 {
 448         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir;
 449         float velocityzoom, curspeed;
 450         vector v;
 451
 452         zoomsensitivity = autocvar_cl_zoomsensitivity;
 453         zoomfactor = autocvar_cl_zoomfactor;
 454         if(zoomfactor < 1 || zoomfactor > 30)
 455                 zoomfactor = 2.5;
 456         zoomspeed = autocvar_cl_zoomspeed;
 457         if(zoomspeed >= 0)
 458         if(zoomspeed < 0.5 || zoomspeed > 16)
 459                         zoomspeed = 3.5;
 460
 461         zoomdir = button_zoom;
 462
 463         if(hud == HUD_NORMAL && !spectatee_status)
 464         {
 465                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 466                 {
 467                         entity wepent = viewmodels[slot];
 468                         if(wepent.switchweapon == wepent.activeweapon)
 469                         if((wepent.activeweapon == WEP_VORTEX && !WEP_CVAR(vortex, secondary)) || (wepent.activeweapon == WEP_RIFLE && !WEP_CVAR(rifle, secondary))) // do NOT use switchweapon here
 470                                 zoomdir += button_attack2;
 471                 }
 472         }
 473         if(spectatee_status > 0 || isdemo())
 474         {
 475                 if(spectatorbutton_zoom)
 476                 {
 477                         if(zoomdir)
 478                                 zoomdir = 0;
 479                         else
 480                                 zoomdir = 1;
 481                 }
 482                 // fteqcc failed twice here already, don't optimize this
 483         }
 484
 485         if(zoomdir) { zoomin_effect = 0; }
 486
 487         if(camera_active)
 488         {
 489                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 490         }
 491         else if(autocvar_cl_spawnzoom && zoomin_effect)
 492         {
 493                 float spawnzoomfactor = bound(1, autocvar_cl_spawnzoom_factor, 30);
 494
 495                 current_viewzoom += (autocvar_cl_spawnzoom_speed * (spawnzoomfactor - current_viewzoom) * drawframetime);
 496                 current_viewzoom = bound(1 / spawnzoomfactor, current_viewzoom, 1);
 497                 if(current_viewzoom == 1) { zoomin_effect = 0; }
 498         }
 499         else
 500         {
 501                 if(zoomspeed < 0) // instant zoom
 502                 {
 503                         if(zoomdir)
 504                                 current_viewzoom = 1 / zoomfactor;
 505                         else
 506                                 current_viewzoom = 1;
 507                 }
 508                 else
 509                 {
 510                         if(zoomdir)
 511                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 512                         else
 513                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 514                 }
 515         }
 516
 517         if(almost_equals(current_viewzoom, 1))
 518                 current_zoomfraction = 0;
 519         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 520                 current_zoomfraction = 1;
 521         else
 522                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 523
 524         if(zoomsensitivity < 1)
 525                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
 526         else
 527                 setsensitivityscale(1);
 528
 529         if(autocvar_cl_velocityzoom_enabled && autocvar_cl_velocityzoom_type) // _type = 0 disables velocity zoom too
 530         {
 531                 if(intermission) { curspeed = 0; }
 532                 else
 533                 {
 534
 535                         makevectors(view_angles);
 536                         v = pmove_vel;
 537                         if(csqcplayer)
 538                                 v = csqcplayer.velocity;
 539
 540                         switch(autocvar_cl_velocityzoom_type)
 541                         {
 542                                 case 3: curspeed = max(0, v_forward * v); break;
 543                                 case 2: curspeed = (v_forward * v); break;
 544                                 case 1: default: curspeed = vlen(v); break;
 545                         }
 546                 }
 547
 548                 velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoom_time), 1); // speed at which the zoom adapts to player velocity
 549                 avgspeed = avgspeed * (1 - velocityzoom) + (curspeed / autocvar_cl_velocityzoom_speed) * velocityzoom;
 550                 velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom_factor / 1) * 1);
 551
 552                 //print(ftos(avgspeed), " avgspeed, ", ftos(curspeed), " curspeed, ", ftos(velocityzoom), " return\n"); // for debugging
 553         }
 554         else
 555                 velocityzoom = 1;
 556
 557         float frustumx, frustumy, fovx, fovy;
 558         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 559         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 560         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 561         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 562
 563         return '1 0 0' * fovx + '0 1 0' * fovy;
 564 }
 565
 566 vector GetViewLocationFOV(float fov)
 567 {
 568         float frustumy = tan(fov * M_PI / 360.0) * 0.75;
 569         float frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 570         float fovx = atan2(frustumx, 1) / M_PI * 360.0;
 571         float fovy = atan2(frustumy, 1) / M_PI * 360.0;
 572         return '1 0 0' * fovx + '0 1 0' * fovy;
 573 }
 574
 575 vector GetOrthoviewFOV(vector ov_worldmin, vector ov_worldmax, vector ov_mid, vector ov_org)
 576 {
 577         float fovx, fovy;
 578         float width = (ov_worldmax.x - ov_worldmin.x);
 579         float height = (ov_worldmax.y - ov_worldmin.y);
 580         float distance_to_middle_of_world = vlen(ov_mid - ov_org);
 581         fovx = atan2(width/2, distance_to_middle_of_world) / M_PI * 360.0;
 582         fovy = atan2(height/2, distance_to_middle_of_world) / M_PI * 360.0;
 583         return '1 0 0' * fovx + '0 1 0' * fovy;
 584 }
 585
 586 // this function must match W_SetupShot!
 587 float zoomscript_caught;
 588
 589 vector wcross_origin;
 590 float wcross_scale_prev, wcross_alpha_prev;
 591 vector wcross_color_prev;
 592 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 593 vector wcross_color_goal_prev;
 594 float wcross_changedonetime;
 595
 596 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 597 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 598 float wcross_name_changestarttime, wcross_name_changedonetime;
 599 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 600
 601 float wcross_ring_prev;
 602
 603 entity trueaim;
 604 entity trueaim_rifle;
 605
 606 const float SHOTTYPE_HITTEAM = 1;
 607 const float SHOTTYPE_HITOBSTRUCTION = 2;
 608 const float SHOTTYPE_HITWORLD = 3;
 609 const float SHOTTYPE_HITENEMY = 4;
 610
 611 void TrueAim_Init()
 612 {
 613         (trueaim = new_pure(trueaim)).dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 614         (trueaim_rifle = new_pure(trueaim_rifle)).dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 615 }
 616
 617 float EnemyHitCheck()
 618 {
 619         float t, n;
 620         wcross_origin = project_3d_to_2d(trace_endpos);
 621         wcross_origin.z = 0;
 622         if(trace_ent)
 623                 n = trace_ent.entnum;
 624         else
 625                 n = trace_networkentity;
 626         if(n < 1)
 627                 return SHOTTYPE_HITWORLD;
 628         if(n > maxclients)
 629                 return SHOTTYPE_HITWORLD;
 630         t = entcs_GetTeam(n - 1);
 631         if(teamplay)
 632                 if(t == myteam)
 633                         return SHOTTYPE_HITTEAM;
 634         if(t == NUM_SPECTATOR)
 635                 return SHOTTYPE_HITWORLD;
 636         return SHOTTYPE_HITENEMY;
 637 }
 638
 639 float TrueAimCheck(entity wepent)
 640 {
 641         float nudge = 1; // added to traceline target and subtracted from result TOOD(divVerent): do we still need this? Doesn't the engine do this now for us?
 642         vector vecs, trueaimpoint, w_shotorg;
 643         vector mi, ma, dv;
 644         float shottype;
 645         entity ta;
 646         float mv;
 647
 648         mi = ma = '0 0 0';
 649         ta = trueaim;
 650         mv = MOVE_NOMONSTERS;
 651
 652         switch(wepent.activeweapon) // WEAPONTODO
 653         {
 654                 case WEP_TUBA: // no aim
 655                 case WEP_PORTO: // shoots from eye
 656                 case WEP_NEXBALL: // shoots from eye
 657                 case WEP_HOOK: // no trueaim
 658                 case WEP_MORTAR: // toss curve
 659                         return SHOTTYPE_HITWORLD;
 660                 case WEP_VORTEX:
 661                 case WEP_VAPORIZER:
 662                         mv = MOVE_NORMAL;
 663                         break;
 664                 case WEP_RIFLE:
 665                         ta = trueaim_rifle;
 666                         mv = MOVE_NORMAL;
 667                         if(zoomscript_caught)
 668                         {
 669                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * max_shot_distance, mv, ta);
 670                                 return EnemyHitCheck();
 671                         }
 672                         break;
 673                 case WEP_DEVASTATOR: // projectile has a size!
 674                         mi = '-3 -3 -3';
 675                         ma = '3 3 3';
 676                         break;
 677                 case WEP_FIREBALL: // projectile has a size!
 678                         mi = '-16 -16 -16';
 679                         ma = '16 16 16';
 680                         break;
 681                 case WEP_SEEKER: // projectile has a size!
 682                         mi = '-2 -2 -2';
 683                         ma = '2 2 2';
 684                         break;
 685                 case WEP_ELECTRO: // projectile has a size!
 686                         mi = '0 0 -3';
 687                         ma = '0 0 -3';
 688                         break;
 689         }
 690
 691         vector traceorigin = entcs_receiver(player_localentnum - 1).origin + (eZ * STAT(VIEWHEIGHT));
 692
 693         vecs = decompressShotOrigin(STAT(SHOTORG));
 694
 695         traceline(traceorigin, traceorigin + view_forward * max_shot_distance, mv, ta);
 696         trueaimpoint = trace_endpos;
 697
 698         if(vdist((trueaimpoint - traceorigin), <, g_trueaim_minrange))
 699                 trueaimpoint = traceorigin + view_forward * g_trueaim_minrange;
 700
 701         if(vecs.x > 0)
 702                 vecs.y = -vecs.y;
 703         else
 704                 vecs = '0 0 0';
 705
 706         dv = view_right * vecs.y + view_up * vecs.z;
 707         w_shotorg = traceorigin + dv;
 708
 709         // now move the vecs forward as much as requested if possible
 710         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs.x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 711         w_shotorg = trace_endpos - view_forward * nudge;
 712
 713         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 714         shottype = EnemyHitCheck();
 715         if(shottype != SHOTTYPE_HITWORLD)
 716                 return shottype;
 717
 718 #if 0
 719         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 720         // or rather, I know why, but see no fix
 721         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 722                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 723                 return SHOTTYPE_HITOBSTRUCTION;
 724 #endif
 725
 726         return SHOTTYPE_HITWORLD;
 727 }
 728
 729 void PostInit();
 730 void CSQC_Demo_Camera();
 731 float camera_mode;
 732 const float CAMERA_FREE = 1;
 733 const float CAMERA_CHASE = 2;
 734 float reticle_type;
 735 string NextFrameCommand;
 736
 737 vector freeze_org, freeze_ang;
 738 entity nightvision_noise, nightvision_noise2;
 739
 740 const float MAX_TIME_DIFF = 5;
 741 float pickup_crosshair_time, pickup_crosshair_size;
 742 float hitindication_crosshair_size;
 743 float use_vortex_chargepool;
 744
 745 float myhealth, myhealth_prev;
 746 float myhealth_flash;
 747
 748 float old_blurradius, old_bluralpha;
 749 float old_sharpen_intensity;
 750
 751 vector myhealth_gentlergb;
 752
 753 float contentavgalpha, liquidalpha_prev;
 754 vector liquidcolor_prev;
 755
 756 float eventchase_current_distance;
 757 float eventchase_running;
 758 bool WantEventchase(entity this)
 759 {
 760         if(autocvar_cl_orthoview)
 761                 return false;
 762         if(STAT(GAME_STOPPED) || intermission)
 763                 return true;
 764         if(this.viewloc)
 765                 return true;
 766         if(spectatee_status >= 0)
 767         {
 768                 if(hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0))
 769                         return true;
 770                 if(MUTATOR_CALLHOOK(WantEventchase, this))
 771                         return true;
 772                 if(autocvar_cl_eventchase_death && (STAT(HEALTH) <= 0))
 773                 {
 774                         if(autocvar_cl_eventchase_death == 2)
 775                         {
 776                                 // don't stop eventchase once it's started (even if velocity changes afterwards)
 777                                 if(this.velocity == '0 0 0' || eventchase_running)
 778                                         return true;
 779                         }
 780                         else return true;
 781                 }
 782         }
 783         return false;
 784 }
 785
 786 void HUD_Crosshair_Vehicle(entity this)
 787 {
 788         if(hud != HUD_BUMBLEBEE_GUN)
 789         {
 790                 Vehicle info = Vehicles_from(hud);
 791                 info.vr_crosshair(info, this);
 792         }
 793 }
 794
 795 vector damage_blurpostprocess, content_blurpostprocess;
 796
 797 float unaccounted_damage = 0;
 798 void UpdateDamage()
 799 {
 800         // accumulate damage with each stat update
 801         static float damage_total_prev = 0;
 802         float damage_total = STAT(DAMAGE_DEALT_TOTAL);
 803         float unaccounted_damage_new = COMPARE_INCREASING(damage_total, damage_total_prev);
 804         damage_total_prev = damage_total;
 805
 806         static float damage_dealt_time_prev = 0;
 807         float damage_dealt_time = STAT(HIT_TIME);
 808         if (damage_dealt_time != damage_dealt_time_prev)
 809         {
 810                 unaccounted_damage += unaccounted_damage_new;
 811                 LOG_TRACE("dmg total: ", ftos(unaccounted_damage), " (+", ftos(unaccounted_damage_new), ")");
 812         }
 813         damage_dealt_time_prev = damage_dealt_time;
 814
 815         // prevent hitsound when switching spectatee
 816         static float spectatee_status_prev = 0;
 817         if (spectatee_status != spectatee_status_prev)
 818                 unaccounted_damage = 0;
 819         spectatee_status_prev = spectatee_status;
 820 }
 821
 822 void HitSound()
 823 {
 824         // varying sound pitch
 825
 826         bool have_arc = false;
 827         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 828         {
 829                 entity wepent = viewmodels[slot];
 830
 831                 if(wepent.activeweapon == WEP_ARC)
 832                         have_arc = true;
 833         }
 834
 835         static float hitsound_time_prev = 0;
 836         // HACK: the only way to get the arc to sound consistent with pitch shift is to ignore cl_hitsound_antispam_time
 837         bool arc_hack = have_arc && autocvar_cl_hitsound >= 2;
 838         if (arc_hack || COMPARE_INCREASING(time, hitsound_time_prev) > autocvar_cl_hitsound_antispam_time)
 839         {
 840                 if (autocvar_cl_hitsound && unaccounted_damage)
 841                 {
 842                         // customizable gradient function that crosses (0,a), (c,1) and asymptotically approaches b
 843                         float a = autocvar_cl_hitsound_max_pitch;
 844                         float b = autocvar_cl_hitsound_min_pitch;
 845                         float c = autocvar_cl_hitsound_nom_damage;
 846                         float d = unaccounted_damage;
 847                         float pitch_shift = (b*d*(a-1) + a*c*(1-b)) / (d*(a-1) + c*(1-b));
 848
 849                         // if sound variation is disabled, set pitch_shift to 1
 850                         if (autocvar_cl_hitsound == 1)
 851                                 pitch_shift = 1;
 852
 853                         // if pitch shift is reversed, mirror in (max-min)/2 + min
 854                         if (autocvar_cl_hitsound == 3)
 855                         {
 856                                 float mirror_value = (a-b)/2 + b;
 857                                 pitch_shift = mirror_value + (mirror_value - pitch_shift);
 858                         }
 859
 860                         LOG_TRACE("dmg total (dmg): ", ftos(unaccounted_damage), " , pitch shift: ", ftos(pitch_shift));
 861
 862                         // todo: avoid very long and very short sounds from wave stretching using different sound files? seems unnecessary
 863                         // todo: normalize sound pressure levels? seems unnecessary
 864
 865                         sound7(NULL, CH_INFO, SND(HIT), VOL_BASE, ATTN_NONE, pitch_shift * 100, 0);
 866                 }
 867                 unaccounted_damage = 0;
 868                 hitsound_time_prev = time;
 869         }
 870
 871         static float typehit_time_prev = 0;
 872         float typehit_time = STAT(TYPEHIT_TIME);
 873         if (COMPARE_INCREASING(typehit_time, typehit_time_prev) > autocvar_cl_hitsound_antispam_time)
 874         {
 875                 sound(NULL, CH_INFO, SND_TYPEHIT, VOL_BASE, ATTN_NONE);
 876                 typehit_time_prev = typehit_time;
 877         }
 878 }
 879
 880 vector crosshair_getcolor(entity this, float health_stat)
 881 {
 882         static float rainbow_last_flicker;
 883         static vector rainbow_prev_color;
 884         vector wcross_color = '0 0 0';
 885         switch(autocvar_crosshair_color_special)
 886         {
 887                 case 1: // crosshair_color_per_weapon
 888                 {
 889                         if(this != WEP_Null && hud == HUD_NORMAL)
 890                         {
 891                                 wcross_color = this.wpcolor;
 892                                 break;
 893                         }
 894                         else { goto normalcolor; }
 895                 }
 896
 897                 case 2: // crosshair_color_by_health
 898                 {
 899                         float hp = health_stat;
 900
 901                         //x = red
 902                         //y = green
 903                         //z = blue
 904
 905                         wcross_color.z = 0;
 906
 907                         if(hp > 200)
 908                         {
 909                                 wcross_color.x = 0;
 910                                 wcross_color.y = 1;
 911                         }
 912                         else if(hp > 150)
 913                         {
 914                                 wcross_color.x = 0.4 - (hp-150)*0.02 * 0.4;
 915                                 wcross_color.y = 0.9 + (hp-150)*0.02 * 0.1;
 916                         }
 917                         else if(hp > 100)
 918                         {
 919                                 wcross_color.x = 1 - (hp-100)*0.02 * 0.6;
 920                                 wcross_color.y = 1 - (hp-100)*0.02 * 0.1;
 921                                 wcross_color.z = 1 - (hp-100)*0.02;
 922                         }
 923                         else if(hp > 50)
 924                         {
 925                                 wcross_color.x = 1;
 926                                 wcross_color.y = 1;
 927                                 wcross_color.z = 0.2 + (hp-50)*0.02 * 0.8;
 928                         }
 929                         else if(hp > 20)
 930                         {
 931                                 wcross_color.x = 1;
 932                                 wcross_color.y = (hp-20)*90/27/100;
 933                                 wcross_color.z = (hp-20)*90/27/100 * 0.2;
 934                         }
 935                         else
 936                         {
 937                                 wcross_color.x = 1;
 938                                 wcross_color.y = 0;
 939                         }
 940                         break;
 941                 }
 942
 943                 case 3: // crosshair_color_rainbow
 944                 {
 945                         if(time >= rainbow_last_flicker)
 946                         {
 947                                 rainbow_prev_color = randomvec() * autocvar_crosshair_color_special_rainbow_brightness;
 948                                 rainbow_last_flicker = time + autocvar_crosshair_color_special_rainbow_delay;
 949                         }
 950                         wcross_color = rainbow_prev_color;
 951                         break;
 952                 }
 953 LABEL(normalcolor)
 954                 default: { wcross_color = stov(autocvar_crosshair_color); break; }
 955         }
 956
 957         return wcross_color;
 958 }
 959
 960 void HUD_Crosshair(entity this)
 961 {
 962         float f, i, j;
 963         vector v;
 964         if(!scoreboard_active && !camera_active && intermission != 2 && !STAT(GAME_STOPPED) &&
 965                 spectatee_status != -1 && !csqcplayer.viewloc && !MUTATOR_CALLHOOK(DrawCrosshair) &&
 966                 !HUD_MinigameMenu_IsOpened() )
 967         {
 968                 if (!autocvar_crosshair_enabled) // main toggle for crosshair rendering
 969                         return;
 970
 971                 if (spectatee_status > 0 && STAT(CAMERA_SPECTATOR) == 2)
 972                         return;
 973
 974                 if (hud != HUD_NORMAL)
 975                 {
 976                         HUD_Crosshair_Vehicle(this);
 977                         return;
 978                 }
 979
 980                 string wcross_style;
 981                 float wcross_alpha, wcross_resolution;
 982                 wcross_style = autocvar_crosshair;
 983                 if (wcross_style == "0")
 984                         return;
 985                 wcross_resolution = autocvar_crosshair_size;
 986                 if (wcross_resolution == 0)
 987                         return;
 988                 wcross_alpha = autocvar_crosshair_alpha;
 989                 if (wcross_alpha == 0)
 990                         return;
 991
 992                 // TrueAim check
 993                 float shottype;
 994
 995                 // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
 996                 wcross_origin = project_3d_to_2d(view_origin + max_shot_distance * view_forward);
 997                 wcross_origin.z = 0;
 998                 if(autocvar_crosshair_hittest)
 999                 {
1000                         vector wcross_oldorigin;
1001                         entity thiswep = viewmodels[0]; // TODO: unhardcode
1002                         wcross_oldorigin = wcross_origin;
1003                         shottype = TrueAimCheck(thiswep);
1004                         if(shottype == SHOTTYPE_HITWORLD)
1005                         {
1006                                 v = wcross_origin - wcross_oldorigin;
1007                                 v.x /= vid_conwidth;
1008                                 v.y /= vid_conheight;
1009                                 if(vdist(v, >, 0.01))
1010                                         shottype = SHOTTYPE_HITOBSTRUCTION;
1011                         }
1012                         if(!autocvar_crosshair_hittest_showimpact)
1013                                 wcross_origin = wcross_oldorigin;
1014                 }
1015                 else
1016                         shottype = SHOTTYPE_HITWORLD;
1017
1018                 vector wcross_color = '0 0 0', wcross_size = '0 0 0';
1019                 string wcross_name = "";
1020                 float wcross_scale, wcross_blur;
1021
1022         entity e = WEP_Null;
1023                 if(autocvar_crosshair_per_weapon || (autocvar_crosshair_color_special == 1))
1024                 {
1025                         entity wepent = viewmodels[0]; // TODO: unhardcode
1026                         e = wepent.switchingweapon;
1027                         if(e)
1028                         {
1029                                 if(autocvar_crosshair_per_weapon)
1030                                 {
1031                                         // WEAPONTODO: access these through some general settings (with non-balance config settings)
1032                                         //wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
1033                                         //if (wcross_resolution == 0)
1034                                                 //return;
1035
1036                                         //wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
1037                                         wcross_resolution *= e.w_crosshair_size;
1038                                         wcross_name = e.w_crosshair;
1039                                 }
1040                         }
1041                 }
1042
1043                 if(wcross_name == "")
1044                         wcross_name = strcat("gfx/crosshair", wcross_style);
1045
1046                 // MAIN CROSSHAIR COLOR DECISION
1047                 wcross_color = crosshair_getcolor(e, STAT(HEALTH));
1048
1049                 if(autocvar_crosshair_effect_scalefade)
1050                 {
1051                         wcross_scale = wcross_resolution;
1052                         wcross_resolution = 1;
1053                 }
1054                 else
1055                 {
1056                         wcross_scale = 1;
1057                 }
1058
1059                 if(autocvar_crosshair_pickup)
1060                 {
1061                         float stat_pickup_time = STAT(LAST_PICKUP);
1062
1063                         if(pickup_crosshair_time < stat_pickup_time)
1064                         {
1065                                 if(time - stat_pickup_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1066                                         pickup_crosshair_size = 1;
1067
1068                                 pickup_crosshair_time = stat_pickup_time;
1069                         }
1070
1071                         if(pickup_crosshair_size > 0)
1072                                 pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
1073                         else
1074                                 pickup_crosshair_size = 0;
1075
1076                         wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
1077                 }
1078
1079                 // todo: make crosshair hit indication dependent on damage dealt
1080                 if(autocvar_crosshair_hitindication)
1081                 {
1082                         vector hitindication_color = ((autocvar_crosshair_color_special == 1) ? stov(autocvar_crosshair_hitindication_per_weapon_color) : stov(autocvar_crosshair_hitindication_color));
1083
1084                         if(unaccounted_damage)
1085                         {
1086                                 hitindication_crosshair_size = 1;
1087                         }
1088
1089                         if(hitindication_crosshair_size > 0)
1090                                 hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
1091                         else
1092                                 hitindication_crosshair_size = 0;
1093
1094                         wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
1095                         wcross_color.x += sin(hitindication_crosshair_size) * hitindication_color.x;
1096                         wcross_color.y += sin(hitindication_crosshair_size) * hitindication_color.y;
1097                         wcross_color.z += sin(hitindication_crosshair_size) * hitindication_color.z;
1098                 }
1099
1100                 if(shottype == SHOTTYPE_HITENEMY)
1101                         wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
1102                 if(shottype == SHOTTYPE_HITTEAM)
1103                         wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
1104
1105                 f = fabs(autocvar_crosshair_effect_time);
1106                 if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
1107                 {
1108                         wcross_changedonetime = time + f;
1109                 }
1110                 if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
1111                 {
1112                         wcross_name_changestarttime = time;
1113                         wcross_name_changedonetime = time + f;
1114                         if(wcross_name_goal_prev_prev)
1115                                 strunzone(wcross_name_goal_prev_prev);
1116                         wcross_name_goal_prev_prev = wcross_name_goal_prev;
1117                         wcross_name_goal_prev = strzone(wcross_name);
1118                         wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
1119                         wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
1120                         wcross_resolution_goal_prev = wcross_resolution;
1121                 }
1122
1123                 wcross_scale_goal_prev = wcross_scale;
1124                 wcross_alpha_goal_prev = wcross_alpha;
1125                 wcross_color_goal_prev = wcross_color;
1126
1127                 if(spectatee_status == -1 && shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
1128                 {
1129                         wcross_blur = 1;
1130                         wcross_alpha *= 0.75;
1131                 }
1132                 else
1133                         wcross_blur = 0;
1134                 // *_prev is at time-frametime
1135                 // * is at wcross_changedonetime+f
1136                 // what do we have at time?
1137                 if(time < wcross_changedonetime)
1138                 {
1139                         f = frametime / (wcross_changedonetime - time + frametime);
1140                         wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
1141                         wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
1142                         wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
1143                 }
1144
1145                 wcross_scale_prev = wcross_scale;
1146                 wcross_alpha_prev = wcross_alpha;
1147                 wcross_color_prev = wcross_color;
1148
1149                 MUTATOR_CALLHOOK(UpdateCrosshair);
1150
1151                 wcross_scale *= 1 - autocvar__menu_alpha;
1152                 wcross_alpha *= 1 - autocvar__menu_alpha;
1153                 wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1154
1155                 if(wcross_scale >= 0.001 && wcross_alpha >= 0.001)
1156                 {
1157                         // crosshair rings for weapon stats
1158                         if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
1159                         {
1160                                 // declarations and stats
1161                                 float ring_value = 0, ring_scale = 0, ring_alpha = 0, ring_inner_value = 0, ring_inner_alpha = 0;
1162                                 string ring_image = string_null, ring_inner_image = string_null;
1163                                 vector ring_rgb = '0 0 0', ring_inner_rgb = '0 0 0';
1164
1165                                 ring_scale = autocvar_crosshair_ring_size;
1166
1167                                 float weapon_clipload, weapon_clipsize;
1168                                 weapon_clipload = STAT(WEAPON_CLIPLOAD);
1169                                 weapon_clipsize = STAT(WEAPON_CLIPSIZE);
1170
1171                                 float vortex_charge, vortex_chargepool;
1172                                 vortex_charge = STAT(VORTEX_CHARGE);
1173                                 vortex_chargepool = STAT(VORTEX_CHARGEPOOL);
1174
1175                                 float arc_heat = STAT(ARC_HEAT);
1176
1177                                 if(vortex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
1178                                         vortex_charge_movingavg = vortex_charge;
1179
1180                                 entity wepent = viewmodels[0]; // TODO: unhardcode
1181
1182                                 // handle the values
1183                                 if (autocvar_crosshair_ring && wepent.activeweapon == WEP_VORTEX && vortex_charge && autocvar_crosshair_ring_vortex) // ring around crosshair representing velocity-dependent damage for the vortex
1184                                 {
1185                                         if (vortex_chargepool || use_vortex_chargepool) {
1186                                                 use_vortex_chargepool = 1;
1187                                                 ring_inner_value = vortex_chargepool;
1188                                         } else {
1189                                                 vortex_charge_movingavg = (1 - autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate) * vortex_charge_movingavg + autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate * vortex_charge;
1190                                                 ring_inner_value = bound(0, autocvar_crosshair_ring_vortex_currentcharge_scale * (vortex_charge - vortex_charge_movingavg), 1);
1191                                         }
1192
1193                                         ring_inner_alpha = autocvar_crosshair_ring_vortex_inner_alpha;
1194                                         ring_inner_rgb = eX * autocvar_crosshair_ring_vortex_inner_color_red + eY * autocvar_crosshair_ring_vortex_inner_color_green + eZ * autocvar_crosshair_ring_vortex_inner_color_blue;
1195                                         ring_inner_image = "gfx/crosshair_ring_inner.tga";
1196
1197                                         // draw the outer ring to show the current charge of the weapon
1198                                         ring_value = vortex_charge;
1199                                         ring_alpha = autocvar_crosshair_ring_vortex_alpha;
1200                                         ring_rgb = wcross_color;
1201                                         ring_image = "gfx/crosshair_ring_nexgun.tga";
1202                                 }
1203                                 else if (autocvar_crosshair_ring && wepent.activeweapon == WEP_MINE_LAYER && WEP_CVAR(minelayer, limit) && autocvar_crosshair_ring_minelayer)
1204                                 {
1205                                         ring_value = bound(0, STAT(LAYED_MINES) / WEP_CVAR(minelayer, limit), 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
1206                                         ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
1207                                         ring_rgb = wcross_color;
1208                                         ring_image = "gfx/crosshair_ring.tga";
1209                                 }
1210                                 else if (wepent.activeweapon == WEP_HAGAR && STAT(HAGAR_LOAD) && autocvar_crosshair_ring_hagar)
1211                                 {
1212                                         ring_value = bound(0, STAT(HAGAR_LOAD) / WEP_CVAR_SEC(hagar, load_max), 1);
1213                                         ring_alpha = autocvar_crosshair_ring_hagar_alpha;
1214                                         ring_rgb = wcross_color;
1215                                         ring_image = "gfx/crosshair_ring.tga";
1216                                 }
1217                                 else if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
1218                                 {
1219                                         ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
1220                                         ring_scale = autocvar_crosshair_ring_reload_size;
1221                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
1222                                         ring_rgb = wcross_color;
1223
1224                                         // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
1225                                         // if a new image for another weapon is added, add the code (and its respective file/value) here
1226                                         if ((wepent.activeweapon == WEP_RIFLE) && (weapon_clipsize == 80))
1227                                                 ring_image = "gfx/crosshair_ring_rifle.tga";
1228                                         else
1229                                                 ring_image = "gfx/crosshair_ring.tga";
1230                                 }
1231                                 else if ( autocvar_crosshair_ring && autocvar_crosshair_ring_arc && arc_heat && wepent.activeweapon == WEP_ARC )
1232                                 {
1233                                         ring_value = arc_heat;
1234                                         ring_alpha = (1-arc_heat)*autocvar_crosshair_ring_arc_cold_alpha +
1235                                                 arc_heat*autocvar_crosshair_ring_arc_hot_alpha;
1236                                         ring_rgb = (1-arc_heat)*wcross_color + arc_heat*autocvar_crosshair_ring_arc_hot_color;
1237                                         ring_image = "gfx/crosshair_ring.tga";
1238                                 }
1239
1240                                 // if in weapon switch animation, fade ring out/in
1241                                 if(autocvar_crosshair_effect_time > 0)
1242                                 {
1243                                         f = (time - wcross_name_changestarttime) / autocvar_crosshair_effect_time;
1244                                         if (f >= 1)
1245                                         {
1246                                                 wcross_ring_prev = ((ring_image) ? true : false);
1247                                         }
1248
1249                                         if(wcross_ring_prev)
1250                                         {
1251                                                 if(f < 1)
1252                                                         ring_alpha *= fabs(1 - bound(0, f, 1));
1253                                         }
1254                                         else
1255                                         {
1256                                                 if(f < 1)
1257                                                         ring_alpha *= bound(0, f, 1);
1258                                         }
1259                                 }
1260
1261                                 if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
1262                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
1263
1264                                 if (ring_value)
1265                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
1266                         }
1267
1268 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
1269                         MACRO_BEGIN { \
1270                                 if(wcross_blur > 0) \
1271                                 { \
1272                                         for(i = -2; i <= 2; ++i) \
1273                                         for(j = -2; j <= 2; ++j) \
1274                                         M(i,j,sz,wcross_name,wcross_alpha*0.04); \
1275                                 } \
1276                                 else \
1277                                 { \
1278                                         M(0,0,sz,wcross_name,wcross_alpha); \
1279                                 } \
1280                         } MACRO_END
1281
1282 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
1283                         drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size.x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size.y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
1284
1285 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
1286                         CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
1287
1288                         if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
1289                         {
1290                                 f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
1291                                 wcross_size = draw_getimagesize(wcross_name_goal_prev_prev) * wcross_scale;
1292                                 CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
1293                                 f = 1 - f;
1294                         }
1295                         else
1296                         {
1297                                 f = 1;
1298                         }
1299                         wcross_name_alpha_goal_prev = f;
1300
1301                         wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1302                         CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
1303
1304                         if(autocvar_crosshair_dot)
1305                         {
1306                                 vector wcross_color_old;
1307                                 wcross_color_old = wcross_color;
1308
1309                                 if((autocvar_crosshair_dot_color_custom) && (autocvar_crosshair_dot_color != "0"))
1310                                         wcross_color = stov(autocvar_crosshair_dot_color);
1311
1312                                 CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
1313                                 // FIXME why don't we use wcross_alpha here?
1314                                 wcross_color = wcross_color_old;
1315                         }
1316                 }
1317         }
1318         else
1319         {
1320                 wcross_scale_prev = 0;
1321                 wcross_alpha_prev = 0;
1322                 wcross_scale_goal_prev = 0;
1323                 wcross_alpha_goal_prev = 0;
1324                 wcross_changedonetime = 0;
1325                 if(wcross_name_goal_prev)
1326                         strunzone(wcross_name_goal_prev);
1327                 wcross_name_goal_prev = string_null;
1328                 if(wcross_name_goal_prev_prev)
1329                         strunzone(wcross_name_goal_prev_prev);
1330                 wcross_name_goal_prev_prev = string_null;
1331                 wcross_name_changestarttime = 0;
1332                 wcross_name_changedonetime = 0;
1333                 wcross_name_alpha_goal_prev = 0;
1334                 wcross_name_alpha_goal_prev_prev = 0;
1335                 wcross_resolution_goal_prev = 0;
1336                 wcross_resolution_goal_prev_prev = 0;
1337         }
1338 }
1339
1340 void HUD_Draw(entity this)
1341 {
1342         // if we don't know gametype and scores yet avoid drawing the scoreboard
1343         // also in the very first frames, player state may be inconsistent so avoid drawing the hud at all
1344         // e.g. since initial player's health is 0 hud would display the hud_damage effect,
1345         // cl_deathscoreboard would show the scoreboard and so on
1346         if(!gametype)
1347                 return;
1348
1349         if(!intermission)
1350         if (MUTATOR_CALLHOOK(HUD_Draw_overlay))
1351         {
1352                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, M_ARGV(0, vector), autocvar_hud_colorflash_alpha * M_ARGV(1, float), DRAWFLAG_ADDITIVE);
1353         }
1354         else if(STAT(FROZEN))
1355         {
1356                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, ((STAT(REVIVE_PROGRESS)) ? ('0.25 0.90 1' + ('1 0 0' * STAT(REVIVE_PROGRESS)) + ('0 1 1' * STAT(REVIVE_PROGRESS) * -1)) : '0.25 0.90 1'), autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1357         }
1358         if(!intermission)
1359         if(STAT(NADE_TIMER) && autocvar_cl_nade_timer) // give nade top priority, as it's a matter of life and death
1360         {
1361                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(NADE_TIMER), '0.25 0.90 1' + ('1 0 0' * STAT(NADE_TIMER)) - ('0 1 1' * STAT(NADE_TIMER)), autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1362                 drawstring_aspect(eY * 0.64 * vid_conheight, ((autocvar_cl_nade_timer == 2) ? _("Nade timer") : ""), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
1363         }
1364         else if(STAT(CAPTURE_PROGRESS))
1365         {
1366                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(CAPTURE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1367                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Capture progress"), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
1368         }
1369         else if(STAT(REVIVE_PROGRESS))
1370         {
1371                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1372                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Revival progress"), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
1373         }
1374
1375         if(autocvar_r_letterbox == 0)
1376                 if(autocvar_viewsize < 120)
1377                 {
1378                         if(!(gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS))
1379                                 Accuracy_LoadLevels();
1380
1381                         HUD_Main();
1382                         HUD_Scale_Disable();
1383                 }
1384
1385         // crosshair goes VERY LAST
1386         UpdateDamage();
1387         HUD_Crosshair(this);
1388         HitSound();
1389 }
1390
1391 bool ov_enabled;
1392 float oldr_nearclip;
1393 float oldr_farclip_base;
1394 float oldr_farclip_world;
1395 float oldr_novis;
1396 float oldr_useportalculling;
1397 float oldr_useinfinitefarclip;
1398
1399 void cl_notice_run();
1400
1401 float prev_myteam;
1402 int lasthud;
1403 float vh_notice_time;
1404 void WaypointSprite_Load();
1405 void CSQC_UpdateView(entity this, float w, float h)
1406 {
1407     TC(int, w); TC(int, h);
1408         entity e;
1409         float fov;
1410         float f;
1411         vector vf_size, vf_min;
1412         float a;
1413
1414         execute_next_frame();
1415
1416         ++framecount;
1417
1418         stats_get();
1419         hud = STAT(HUD);
1420
1421         if(hud != HUD_NORMAL && lasthud == HUD_NORMAL)
1422                 vh_notice_time = time + autocvar_cl_vehicles_notify_time;
1423
1424         lasthud = hud;
1425
1426         HUD_Scale_Disable();
1427
1428         if(autocvar__hud_showbinds_reload) // menu can set this one
1429         {
1430                 db_close(binddb);
1431                 binddb = db_create();
1432                 cvar_set("_hud_showbinds_reload", "0");
1433         }
1434
1435         if(checkextension("DP_CSQC_MINFPS_QUALITY"))
1436                 view_quality = getproperty(VF_MINFPS_QUALITY);
1437         else
1438                 view_quality = 1;
1439
1440         button_attack2 = PHYS_INPUT_BUTTON_ATCK2(this);
1441         button_zoom = PHYS_INPUT_BUTTON_ZOOM(this);
1442
1443         vf_size = getpropertyvec(VF_SIZE);
1444         vf_min = getpropertyvec(VF_MIN);
1445         vid_width = vf_size.x;
1446         vid_height = vf_size.y;
1447
1448         vector reticle_pos = '0 0 0', reticle_size = '0 0 0';
1449         vector splash_pos = '0 0 0', splash_size = '0 0 0';
1450
1451         WaypointSprite_Load();
1452
1453         CSQCPlayer_SetCamera();
1454
1455         if(player_localentnum <= maxclients) // is it a client?
1456                 current_player = player_localentnum - 1;
1457         else // then player_localentnum is the vehicle I'm driving
1458                 current_player = player_localnum;
1459         myteam = entcs_GetTeam(current_player);
1460
1461         if(myteam != prev_myteam)
1462         {
1463                 myteamcolors = colormapPaletteColor(myteam, 1);
1464                 FOREACH(hud_panels, true, it.update_time = time);
1465                 prev_myteam = myteam;
1466         }
1467
1468         ticrate = STAT(MOVEVARS_TICRATE) * STAT(MOVEVARS_TIMESCALE);
1469
1470         float is_dead = (STAT(HEALTH) <= 0);
1471
1472         // FIXME do we need this hack?
1473         if(isdemo())
1474         {
1475                 // in demos, input_buttons do not work
1476                 button_zoom = (autocvar__togglezoom == "-");
1477         }
1478         else if(button_zoom
1479                 && autocvar_cl_unpress_zoom_on_death
1480                 && (spectatee_status >= 0)
1481                 && (is_dead || intermission))
1482         {
1483                 // no zoom while dead or in intermission please
1484                 localcmd("-zoom\n");
1485                 button_zoom = false;
1486         }
1487
1488         // event chase camera
1489         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
1490         {
1491                 if(STAT(CAMERA_SPECTATOR))
1492                 {
1493                         if(spectatee_status > 0)
1494                         {
1495                                 if(!autocvar_chase_active)
1496                                 {
1497                                         cvar_set("chase_active", "-2");
1498                                         goto skip_eventchase_death;
1499                                 }
1500                         }
1501                         else if(autocvar_chase_active == -2)
1502                                 cvar_set("chase_active", "0");
1503
1504                         if(autocvar_chase_active == -2)
1505                                 goto skip_eventchase_death;
1506                 }
1507                 else if(autocvar_chase_active == -2)
1508                         cvar_set("chase_active", "0");
1509
1510                 float vehicle_chase = (hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0));
1511
1512                 float vehicle_viewdist = 0;
1513                 vector vehicle_viewofs = '0 0 0';
1514
1515                 if(vehicle_chase)
1516                 {
1517                         if(hud != HUD_BUMBLEBEE_GUN)
1518                         {
1519                                 Vehicle info = Vehicles_from(hud);
1520                                 vehicle_viewdist = info.height;
1521                                 vehicle_viewofs = info.view_ofs;
1522                         }
1523                 }
1524
1525                 if(WantEventchase(this))
1526                 {
1527                         vector current_view_origin_override = '0 0 0';
1528                         vector view_offset_override = '0 0 0';
1529                         float chase_distance_override = 0;
1530                         bool custom_eventchase = MUTATOR_CALLHOOK(CustomizeEventchase, this);
1531                         if(custom_eventchase)
1532                         {
1533                                 current_view_origin_override = M_ARGV(0, vector);
1534                                 view_offset_override = M_ARGV(1, vector);
1535                                 chase_distance_override = M_ARGV(0, float);
1536                         }
1537                         eventchase_running = true;
1538
1539                         entity local_player = ((csqcplayer) ? csqcplayer : CSQCModel_server2csqc(player_localentnum - 1));
1540                         if(!local_player)
1541                                 local_player = this; // fall back!
1542
1543                         // make special vector since we can't use view_origin (It is one frame old as of this code, it gets set later with the results this code makes.)
1544                         vector current_view_origin = (csqcplayer ? csqcplayer.origin : pmove_org);
1545                         if (custom_eventchase)
1546                                 current_view_origin = current_view_origin_override;
1547
1548                         // detect maximum viewoffset and use it
1549                         vector view_offset = autocvar_cl_eventchase_viewoffset;
1550                         if(vehicle_chase)
1551                         {
1552                                 if(vehicle_viewofs)
1553                                         view_offset = vehicle_viewofs;
1554                                 else
1555                                         view_offset = autocvar_cl_eventchase_vehicle_viewoffset;
1556                         }
1557                         if (custom_eventchase)
1558                                 view_offset = view_offset_override;
1559
1560                         if(view_offset)
1561                         {
1562                                 WarpZone_TraceLine(current_view_origin, current_view_origin + view_offset + ('0 0 1' * autocvar_cl_eventchase_maxs.z), MOVE_WORLDONLY, this);
1563                                 if(trace_fraction == 1) { current_view_origin += view_offset; }
1564                                 else { current_view_origin.z += max(0, (trace_endpos.z - current_view_origin.z) - autocvar_cl_eventchase_maxs.z); }
1565                         }
1566
1567                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
1568                         // Ideally, there should be another way to enable third person cameras, such as through setproperty()
1569                         // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
1570                         if(!autocvar_chase_active) { cvar_set("chase_active", "-1"); }
1571
1572                         // make the camera smooth back
1573                         float chase_distance = autocvar_cl_eventchase_distance;
1574                         if(vehicle_chase)
1575                         {
1576                                 if(vehicle_viewofs)
1577                                         chase_distance = vehicle_viewdist;
1578                                 else
1579                                         chase_distance = autocvar_cl_eventchase_vehicle_distance;
1580                         }
1581                         if (custom_eventchase)
1582                                 chase_distance = chase_distance_override;
1583
1584                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < chase_distance)
1585                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (chase_distance - eventchase_current_distance) * frametime; // slow down the further we get
1586                         else if(eventchase_current_distance != chase_distance)
1587                                 eventchase_current_distance = chase_distance;
1588
1589                         makevectors(view_angles);
1590
1591                         vector eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1592                         WarpZone_TraceBox(current_view_origin, autocvar_cl_eventchase_mins, autocvar_cl_eventchase_maxs, eventchase_target_origin, MOVE_WORLDONLY, this);
1593
1594                         // If the boxtrace fails, revert back to line tracing.
1595                         if(!local_player.viewloc)
1596                         if(trace_startsolid)
1597                         {
1598                                 eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1599                                 WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, this);
1600                                 setproperty(VF_ORIGIN, (trace_endpos - (v_forward * autocvar_cl_eventchase_mins.z)));
1601                         }
1602                         else { setproperty(VF_ORIGIN, trace_endpos); }
1603
1604                         if(!local_player.viewloc)
1605                                 setproperty(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
1606                 }
1607                 else if(autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
1608                 {
1609                         eventchase_running = false;
1610                         cvar_set("chase_active", "0");
1611                         eventchase_current_distance = 0; // start from 0 next time
1612                 }
1613         }
1614         // workaround for camera stuck between player's legs when using chase_active 1
1615         // because the engine stops updating the chase_active camera when the game ends
1616         else if(intermission)
1617         {
1618                 cvar_settemp("chase_active", "-1");
1619                 eventchase_current_distance = 0;
1620         }
1621
1622         LABEL(skip_eventchase_death);
1623
1624         // do lockview after event chase camera so that it still applies whenever necessary.
1625         if(autocvar_cl_lockview || (!autocvar_hud_cursormode && (autocvar__hud_configure && spectatee_status <= 0 || intermission > 1 || QuickMenu_IsOpened())))
1626         {
1627                 setproperty(VF_ORIGIN, freeze_org);
1628                 setproperty(VF_ANGLES, freeze_ang);
1629         }
1630         else
1631         {
1632                 freeze_org = getpropertyvec(VF_ORIGIN);
1633                 freeze_ang = getpropertyvec(VF_ANGLES);
1634         }
1635
1636         WarpZone_FixView();
1637         //WarpZone_FixPMove();
1638
1639         vector ov_org = '0 0 0';
1640         vector ov_mid = '0 0 0';
1641         vector ov_worldmin = '0 0 0';
1642         vector ov_worldmax = '0 0 0';
1643         if(autocvar_cl_orthoview)
1644         {
1645                 ov_worldmin = mi_picmin;
1646                 ov_worldmax = mi_picmax;
1647
1648                 float ov_width = (ov_worldmax.x - ov_worldmin.x);
1649                 float ov_height = (ov_worldmax.y - ov_worldmin.y);
1650                 float ov_distance = (max(vid_width, vid_height) * max(ov_width, ov_height));
1651
1652                 ov_mid = ((ov_worldmax + ov_worldmin) * 0.5);
1653                 ov_org = vec3(ov_mid.x, ov_mid.y, (ov_mid.z + ov_distance));
1654
1655                 float ov_nearest = vlen(ov_org - vec3(
1656                         bound(ov_worldmin.x, ov_org.x, ov_worldmax.x),
1657                         bound(ov_worldmin.y, ov_org.y, ov_worldmax.y),
1658                         bound(ov_worldmin.z, ov_org.z, ov_worldmax.z)
1659                 ));
1660
1661                 float ov_furthest = 0;
1662                 float dist = 0;
1663
1664                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1665                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1666                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1667                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1668                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1669                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1670                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1671                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1672
1673                 if(!ov_enabled)
1674                 {
1675                         oldr_nearclip = cvar("r_nearclip");
1676                         oldr_farclip_base = cvar("r_farclip_base");
1677                         oldr_farclip_world = cvar("r_farclip_world");
1678                         oldr_novis = cvar("r_novis");
1679                         oldr_useportalculling = cvar("r_useportalculling");
1680                         oldr_useinfinitefarclip = cvar("r_useinfinitefarclip");
1681                 }
1682
1683                 cvar_settemp("r_nearclip", ftos(ov_nearest));
1684                 cvar_settemp("r_farclip_base", ftos(ov_furthest));
1685                 cvar_settemp("r_farclip_world", "0");
1686                 cvar_settemp("r_novis", "1");
1687                 cvar_settemp("r_useportalculling", "0");
1688                 cvar_settemp("r_useinfinitefarclip", "0");
1689
1690                 setproperty(VF_ORIGIN, ov_org);
1691                 setproperty(VF_ANGLES, '90 0 0');
1692
1693                 ov_enabled = true;
1694
1695                 #if 0
1696                 LOG_INFOF("OrthoView: org = %s, angles = %s, distance = %f, nearest = %f, furthest = %f\n",
1697                         vtos(ov_org),
1698                         vtos(getpropertyvec(VF_ANGLES)),
1699                         ov_distance,
1700                         ov_nearest,
1701                         ov_furthest);
1702                 #endif
1703         }
1704         else
1705         {
1706                 if(ov_enabled)
1707                 {
1708                         cvar_set("r_nearclip", ftos(oldr_nearclip));
1709                         cvar_set("r_farclip_base", ftos(oldr_farclip_base));
1710                         cvar_set("r_farclip_world", ftos(oldr_farclip_world));
1711                         cvar_set("r_novis", ftos(oldr_novis));
1712                         cvar_set("r_useportalculling", ftos(oldr_useportalculling));
1713                         cvar_set("r_useinfinitefarclip", ftos(oldr_useinfinitefarclip));
1714                 }
1715                 ov_enabled = false;
1716         }
1717
1718         // run viewmodel_draw before updating view_angles to the angles calculated by WarpZone_FixView
1719         // viewmodel_draw needs to use the view_angles set by the engine on every CSQC_UpdateView call
1720         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1721                 viewmodel_draw(viewmodels[slot]);
1722
1723         // Render the Scene
1724         view_origin = getpropertyvec(VF_ORIGIN);
1725         view_angles = getpropertyvec(VF_ANGLES);
1726         makevectors(view_angles);
1727         view_forward = v_forward;
1728         view_right = v_right;
1729         view_up = v_up;
1730
1731 #ifdef BLURTEST
1732         if(time > blurtest_time0 && time < blurtest_time1)
1733         {
1734                 float r, t;
1735
1736                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
1737                 r = t * blurtest_radius;
1738                 f = 1 / pow(t, blurtest_power) - 1;
1739
1740                 cvar_set("r_glsl_postprocess", "1");
1741                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
1742         }
1743         else
1744         {
1745                 cvar_set("r_glsl_postprocess", "0");
1746                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
1747         }
1748 #endif
1749
1750         TargetMusic_Advance();
1751         Fog_Force();
1752
1753         if(drawtime == 0)
1754                 drawframetime = 0.01666667; // when we don't know fps yet, we assume 60fps
1755         else
1756                 drawframetime = bound(0.000001, time - drawtime, 1);
1757         drawtime = time;
1758
1759         // watch for gametype changes here...
1760         // in ParseStuffCMD the cmd isn't executed yet :/
1761         // might even be better to add the gametype to TE_CSQC_INIT...?
1762         if(!postinit)
1763                 PostInit();
1764
1765         if(intermission && !intermission_time)
1766                 intermission_time = time;
1767
1768         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
1769         {
1770                 if(calledhooks & HOOK_START)
1771                 {
1772                         localcmd("\ncl_hook_gameend\n");
1773                         calledhooks |= HOOK_END;
1774                 }
1775         }
1776
1777         Announcer();
1778
1779         fov = autocvar_fov;
1780         if(fov <= 59.5)
1781         {
1782                 if(!zoomscript_caught)
1783                 {
1784                         localcmd("+button9\n");
1785                         zoomscript_caught = 1;
1786                 }
1787         }
1788         else
1789         {
1790                 if(zoomscript_caught)
1791                 {
1792                         localcmd("-button9\n");
1793                         zoomscript_caught = 0;
1794                 }
1795         }
1796
1797         ColorTranslateMode = autocvar_cl_stripcolorcodes;
1798
1799         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1800         {
1801                 entity wepent = viewmodels[slot];
1802
1803                 if(wepent.last_switchweapon != wepent.switchweapon)
1804                 {
1805                         weapontime = time;
1806                         wepent.last_switchweapon = wepent.switchweapon;
1807                         if(slot == 0 && button_zoom && autocvar_cl_unpress_zoom_on_weapon_switch)
1808                         {
1809                                 localcmd("-zoom\n");
1810                                 button_zoom = false;
1811                         }
1812                         if(slot == 0 && autocvar_cl_unpress_attack_on_weapon_switch)
1813                         {
1814                                 localcmd("-fire\n");
1815                                 localcmd("-fire2\n");
1816                                 button_attack2 = false;
1817                         }
1818                 }
1819                 if(wepent.last_activeweapon != wepent.activeweapon)
1820                 {
1821                         wepent.last_activeweapon = wepent.activeweapon;
1822
1823                         e = wepent.activeweapon;
1824                         if(e.netname != "")
1825                                 localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
1826                         else if(slot == 0)
1827                                 localcmd("\ncl_hook_activeweapon none\n");
1828                 }
1829         }
1830
1831         // ALWAYS Clear Current Scene First
1832         clearscene();
1833
1834         setproperty(VF_ORIGIN, view_origin);
1835         setproperty(VF_ANGLES, view_angles);
1836
1837         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
1838         setproperty(VF_SIZE, vf_size);
1839         setproperty(VF_MIN, vf_min);
1840
1841         // Assign Standard Viewflags
1842         // Draw the World (and sky)
1843         setproperty(VF_DRAWWORLD, 1);
1844
1845         // Set the console size vars
1846         vid_conwidth = autocvar_vid_conwidth;
1847         vid_conheight = autocvar_vid_conheight;
1848         vid_pixelheight = autocvar_vid_pixelheight;
1849
1850         if(autocvar_cl_orthoview) { setproperty(VF_FOV, GetOrthoviewFOV(ov_worldmin, ov_worldmax, ov_mid, ov_org)); }
1851         else if(csqcplayer.viewloc) { setproperty(VF_FOV, GetViewLocationFOV(110)); } // enforce 110 fov, so things dont look odd
1852         else { setproperty(VF_FOV, GetCurrentFov(fov)); }
1853
1854         if(camera_active) // Camera for demo playback
1855         {
1856                 if(autocvar_camera_enable)
1857                         CSQC_Demo_Camera();
1858                 else
1859                 {
1860                         cvar_set("chase_active", ftos(chase_active_backup));
1861                         cvar_set("cl_demo_mousegrab", "0");
1862                         camera_active = false;
1863                 }
1864         }
1865         else
1866         {
1867 #ifdef CAMERATEST
1868                 if(autocvar_camera_enable)
1869 #else
1870                 if(autocvar_camera_enable && isdemo())
1871 #endif
1872                 {
1873                         // Enable required Darkplaces cvars
1874                         chase_active_backup = autocvar_chase_active;
1875                         cvar_set("chase_active", "2");
1876                         cvar_set("cl_demo_mousegrab", "1");
1877                         camera_active = true;
1878                         camera_mode = false;
1879                 }
1880         }
1881
1882         // Draw the Crosshair
1883         setproperty(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
1884
1885         // Draw the Engine Status Bar (the default Quake HUD)
1886         setproperty(VF_DRAWENGINESBAR, 0);
1887
1888         // Update the mouse position
1889         /*
1890            mousepos_x = vid_conwidth;
1891            mousepos_y = vid_conheight;
1892            mousepos = mousepos*0.5 + getmousepos();
1893          */
1894
1895         IL_EACH(g_drawables, it.draw, it.draw(it));
1896
1897         addentities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
1898         renderscene();
1899
1900         // now switch to 2D drawing mode by calling a 2D drawing function
1901         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
1902         // next R_RenderScene call
1903         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
1904
1905         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
1906         if (!(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT))
1907         {
1908                 // apply night vision effect
1909                 vector tc_00, tc_01, tc_10, tc_11;
1910                 vector rgb = '0 0 0';
1911
1912                 if(!nightvision_noise)
1913                 {
1914                         nightvision_noise = new(nightvision_noise);
1915                 }
1916                 if(!nightvision_noise2)
1917                 {
1918                         nightvision_noise2 = new(nightvision_noise2);
1919                 }
1920
1921                 // color tint in yellow
1922                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
1923
1924                 // draw BG
1925                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
1926                 rgb = '1 1 1';
1927                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
1928                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
1929                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
1930                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
1931                 tc_11 = tc_01 + tc_10 - tc_00;
1932                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
1933                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
1934                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
1935                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
1936                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
1937                 R_EndPolygon();
1938
1939                 // draw FG
1940                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
1941                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
1942                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
1943                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
1944                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
1945                 tc_11 = tc_01 + tc_10 - tc_00;
1946                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
1947                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
1948                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
1949                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
1950                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
1951                 R_EndPolygon();
1952         }
1953
1954         if(autocvar_cl_reticle)
1955         {
1956                 string reticle_image = string_null;
1957                 bool wep_zoomed = false;
1958                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1959                 {
1960                         entity wepe = viewmodels[slot];
1961                         Weapon wep = wepe.activeweapon;
1962                         if(wep != WEP_Null && wep.wr_zoom)
1963                         {
1964                                 bool do_zoom = wep.wr_zoom(wep, NULL);
1965                                 if(!reticle_image && wep.w_reticle && wep.w_reticle != "")
1966                                         reticle_image = wep.w_reticle;
1967                                 wep_zoomed += do_zoom;
1968                         }
1969                 }
1970                 // Draw the aiming reticle for weapons that use it
1971                 // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
1972                 // It must be a persisted float for fading out to work properly (you let go of the zoom button for
1973                 // the view to go back to normal, so reticle_type would become 0 as we fade out)
1974                 if(spectatee_status || is_dead || hud != HUD_NORMAL)
1975                 {
1976                         // no zoom reticle while dead
1977                         reticle_type = 0;
1978                 }
1979                 else if(wep_zoomed && autocvar_cl_reticle_weapon)
1980                 {
1981                         if(reticle_image) { reticle_type = 2; }
1982                         else { reticle_type = 0; }
1983                 }
1984                 else if(button_zoom || zoomscript_caught)
1985                 {
1986                         // normal zoom
1987                         reticle_type = 1;
1988                 }
1989
1990                 if(reticle_type)
1991                 {
1992                         if(autocvar_cl_reticle_stretch)
1993                         {
1994                                 reticle_size.x = vid_conwidth;
1995                                 reticle_size.y = vid_conheight;
1996                                 reticle_pos.x = 0;
1997                                 reticle_pos.y = 0;
1998                         }
1999                         else
2000                         {
2001                                 reticle_size.x = max(vid_conwidth, vid_conheight);
2002                                 reticle_size.y = max(vid_conwidth, vid_conheight);
2003                                 reticle_pos.x = (vid_conwidth - reticle_size.x) / 2;
2004                                 reticle_pos.y = (vid_conheight - reticle_size.y) / 2;
2005                         }
2006
2007                         if(zoomscript_caught)
2008                                 f = 1;
2009                         else
2010                                 f = current_zoomfraction;
2011
2012                         if(f)
2013                         {
2014                                 switch(reticle_type)
2015                                 {
2016                                         case 1: drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_normal_alpha, DRAWFLAG_NORMAL); break;
2017                                         case 2: if(reticle_image) drawpic(reticle_pos, reticle_image, reticle_size, '1 1 1', f * autocvar_cl_reticle_weapon_alpha, DRAWFLAG_NORMAL); break;
2018                                 }
2019                         }
2020                 }
2021         }
2022         else
2023         {
2024                 if(reticle_type != 0) { reticle_type = 0; }
2025         }
2026
2027
2028         // improved polyblend
2029         if(autocvar_hud_contents)
2030         {
2031                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
2032                 vector liquidcolor;
2033
2034                 switch(pointcontents(view_origin))
2035                 {
2036                         case CONTENT_WATER:
2037                                 liquidalpha = autocvar_hud_contents_water_alpha;
2038                                 liquidcolor = stov(autocvar_hud_contents_water_color);
2039                                 incontent = 1;
2040                                 break;
2041
2042                         case CONTENT_LAVA:
2043                                 liquidalpha = autocvar_hud_contents_lava_alpha;
2044                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
2045                                 incontent = 1;
2046                                 break;
2047
2048                         case CONTENT_SLIME:
2049                                 liquidalpha = autocvar_hud_contents_slime_alpha;
2050                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
2051                                 incontent = 1;
2052                                 break;
2053
2054                         default:
2055                                 liquidalpha = 0;
2056                                 liquidcolor = '0 0 0';
2057                                 incontent = 0;
2058                                 break;
2059                 }
2060
2061                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
2062                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
2063                         contentfadetime = autocvar_hud_contents_fadeintime;
2064                         liquidalpha_prev = liquidalpha;
2065                         liquidcolor_prev = liquidcolor;
2066                 }
2067                 else
2068                         contentfadetime = autocvar_hud_contents_fadeouttime;
2069
2070                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
2071                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
2072
2073                 if(contentavgalpha)
2074                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
2075
2076                 if(autocvar_hud_postprocessing)
2077                 {
2078                         if(autocvar_hud_contents_blur && contentavgalpha)
2079                         {
2080                                 content_blurpostprocess.x = 1;
2081                                 content_blurpostprocess.y = contentavgalpha * autocvar_hud_contents_blur;
2082                                 content_blurpostprocess.z = contentavgalpha * autocvar_hud_contents_blur_alpha;
2083                         }
2084                         else
2085                         {
2086                                 content_blurpostprocess.x = 0;
2087                                 content_blurpostprocess.y = 0;
2088                                 content_blurpostprocess.z = 0;
2089                         }
2090                 }
2091         }
2092
2093         if(autocvar_hud_damage && !STAT(FROZEN))
2094         {
2095                 splash_size.x = max(vid_conwidth, vid_conheight);
2096                 splash_size.y = max(vid_conwidth, vid_conheight);
2097                 splash_pos.x = (vid_conwidth - splash_size.x) / 2;
2098                 splash_pos.y = (vid_conheight - splash_size.y) / 2;
2099
2100                 float myhealth_flash_temp;
2101                 myhealth = STAT(HEALTH);
2102
2103                 // fade out
2104                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
2105                 // add new damage
2106                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
2107
2108                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
2109                 pain_threshold = autocvar_hud_damage_pain_threshold;
2110                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
2111                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
2112
2113                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
2114                 {
2115                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
2116                 }
2117
2118                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
2119
2120                 if(myhealth_prev < 1)
2121                 {
2122                         if(myhealth >= 1)
2123                         {
2124                                 myhealth_flash = 0; // just spawned, clear the flash immediately
2125                                 myhealth_flash_temp = 0;
2126                         }
2127                         else
2128                         {
2129                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
2130                         }
2131                 }
2132
2133                 if(spectatee_status == -1 || intermission)
2134                 {
2135                         myhealth_flash = 0; // observing, or match ended
2136                         myhealth_flash_temp = 0;
2137                 }
2138
2139                 myhealth_prev = myhealth;
2140
2141                 // IDEA: change damage color/picture based on player model for robot/alien species?
2142                 // pro: matches model better
2143                 // contra: it's not red because blood is red, but because red is an alarming color, so red should stay
2144                 // maybe different reddish pics?
2145                 if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
2146                 {
2147                         if(autocvar_cl_gentle_damage == 2)
2148                         {
2149                                 if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
2150                                         myhealth_gentlergb = eX * random() + eY * random() + eZ * random();
2151                         }
2152                         else
2153                                 myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
2154
2155                         if(myhealth_flash_temp > 0)
2156                                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
2157                 }
2158                 else if(myhealth_flash_temp > 0)
2159                         drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
2160
2161                 if(autocvar_hud_postprocessing) // we still need to set this anyway even when chase_active is set, this way it doesn't get stuck on.
2162                 {
2163                         if(autocvar_hud_damage_blur && myhealth_flash_temp)
2164                         {
2165                                 damage_blurpostprocess.x = 1;
2166                                 damage_blurpostprocess.y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
2167                                 damage_blurpostprocess.z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
2168                         }
2169                         else
2170                         {
2171                                 damage_blurpostprocess.x = 0;
2172                                 damage_blurpostprocess.y = 0;
2173                                 damage_blurpostprocess.z = 0;
2174                         }
2175                 }
2176         }
2177
2178         float e1 = (autocvar_hud_postprocessing_maxbluralpha != 0);
2179         float e2 = (autocvar_hud_powerup != 0);
2180         if(autocvar_hud_postprocessing && (e1 || e2)) // TODO: Remove this code and re-do the postprocess handling in the engine, where it properly belongs.
2181         {
2182                 // enable or disable rendering types if they are used or not
2183                 if(cvar("r_glsl_postprocess_uservec1_enable") != e1) { cvar_set("r_glsl_postprocess_uservec1_enable", ftos(e1)); }
2184                 if(cvar("r_glsl_postprocess_uservec2_enable") != e2) { cvar_set("r_glsl_postprocess_uservec2_enable", ftos(e2)); }
2185
2186                 // blur postprocess handling done first (used by hud_damage and hud_contents)
2187                 if((damage_blurpostprocess.x || content_blurpostprocess.x))
2188                 {
2189                         float blurradius = bound(0, damage_blurpostprocess.y + content_blurpostprocess.y, autocvar_hud_postprocessing_maxblurradius);
2190                         float bluralpha = bound(0, damage_blurpostprocess.z + content_blurpostprocess.z, autocvar_hud_postprocessing_maxbluralpha);
2191                         if(blurradius != old_blurradius || bluralpha != old_bluralpha) // reduce cvar_set spam as much as possible
2192                         {
2193                                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
2194                                 old_blurradius = blurradius;
2195                                 old_bluralpha = bluralpha;
2196                         }
2197                 }
2198                 else if(cvar_string("r_glsl_postprocess_uservec1") != "0 0 0 0") // reduce cvar_set spam as much as possible
2199                 {
2200                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
2201                         old_blurradius = 0;
2202                         old_bluralpha = 0;
2203                 }
2204
2205                 // edge detection postprocess handling done second (used by hud_powerup)
2206                 float sharpen_intensity = 0, strength_finished = STAT(STRENGTH_FINISHED), invincible_finished = STAT(INVINCIBLE_FINISHED);
2207                 if (strength_finished - time > 0) { sharpen_intensity += (strength_finished - time); }
2208                 if (invincible_finished - time > 0) { sharpen_intensity += (invincible_finished - time); }
2209
2210                 sharpen_intensity = bound(0, ((STAT(HEALTH) > 0) ? sharpen_intensity : 0), 5); // Check to see if player is alive (if not, set 0) - also bound to fade out starting at 5 seconds.
2211
2212                 if(autocvar_hud_powerup && sharpen_intensity > 0)
2213                 {
2214                         if(sharpen_intensity != old_sharpen_intensity) // reduce cvar_set spam as much as possible
2215                         {
2216                                 cvar_set("r_glsl_postprocess_uservec2", strcat(ftos((sharpen_intensity / 5) * autocvar_hud_powerup), " ", ftos(-sharpen_intensity * autocvar_hud_powerup), " 0 0"));
2217                                 old_sharpen_intensity = sharpen_intensity;
2218                         }
2219                 }
2220                 else if(cvar_string("r_glsl_postprocess_uservec2") != "0 0 0 0") // reduce cvar_set spam as much as possible
2221                 {
2222                         cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
2223                         old_sharpen_intensity = 0;
2224                 }
2225
2226                 if(cvar("r_glsl_postprocess") == 0)
2227                         cvar_set("r_glsl_postprocess", "2");
2228         }
2229         else if(cvar("r_glsl_postprocess") == 2)
2230                 cvar_set("r_glsl_postprocess", "0");
2231
2232         /*if(gametype == MAPINFO_TYPE_CTF)
2233           {
2234           ctf_view();
2235           } else */
2236
2237         // draw 2D entities
2238         IL_EACH(g_drawables_2d, it.draw2d, it.draw2d(it));
2239         Draw_ShowNames_All();
2240         Debug_Draw();
2241
2242         scoreboard_active = Scoreboard_WouldDraw();
2243
2244         HUD_Draw(this); // this parameter for deep vehicle function
2245
2246         if(NextFrameCommand)
2247         {
2248                 localcmd("\n", NextFrameCommand, "\n");
2249                 NextFrameCommand = string_null;
2250         }
2251
2252         // we must do this check AFTER a frame was rendered, or it won't work
2253         if(cs_project_is_b0rked == 0)
2254         {
2255                 string w0, h0;
2256                 w0 = ftos(autocvar_vid_conwidth);
2257                 h0 = ftos(autocvar_vid_conheight);
2258                 //setproperty(VF_VIEWPORT, '0 0 0', '640 480 0');
2259                 //setproperty(VF_FOV, '90 90 0');
2260                 setproperty(VF_ORIGIN, '0 0 0');
2261                 setproperty(VF_ANGLES, '0 0 0');
2262                 setproperty(VF_PERSPECTIVE, 1);
2263                 makevectors('0 0 0');
2264                 vector v1, v2;
2265                 cvar_set("vid_conwidth", "800");
2266                 cvar_set("vid_conheight", "600");
2267                 v1 = cs_project(v_forward);
2268                 cvar_set("vid_conwidth", "640");
2269                 cvar_set("vid_conheight", "480");
2270                 v2 = cs_project(v_forward);
2271                 if(v1 == v2)
2272                         cs_project_is_b0rked = 1;
2273                 else
2274                         cs_project_is_b0rked = -1;
2275                 cvar_set("vid_conwidth", w0);
2276                 cvar_set("vid_conheight", h0);
2277         }
2278
2279         if(autocvar__hud_configure)
2280                 HUD_Panel_Mouse();
2281         else if (HUD_MinigameMenu_IsOpened() || active_minigame)
2282                 HUD_Minigame_Mouse();
2283         else if(QuickMenu_IsOpened())
2284                 QuickMenu_Mouse();
2285         else
2286                 HUD_Radar_Mouse();
2287
2288         cl_notice_run();
2289         unpause_update();
2290         Net_Flush();
2291
2292         // let's reset the view back to normal for the end
2293         setproperty(VF_MIN, '0 0 0');
2294         setproperty(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
2295
2296         IL_ENDFRAME();
2297 }
2298
2299
2300 // following vectors must be global to allow seamless switching between camera modes
2301 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
2302 void CSQC_Demo_Camera()
2303 {
2304         float speed, attenuation, dimensions;
2305         vector tmp, delta;
2306
2307         if( autocvar_camera_reset || !camera_mode )
2308         {
2309                 camera_offset = '0 0 0';
2310                 current_angles = '0 0 0';
2311                 camera_direction = '0 0 0';
2312                 camera_offset.z += 30;
2313                 camera_offset.x += 30 * -cos(current_angles.y * DEG2RAD);
2314                 camera_offset.y += 30 * -sin(current_angles.y * DEG2RAD);
2315                 current_origin = view_origin;
2316                 current_camera_offset  = camera_offset;
2317                 cvar_set("camera_reset", "0");
2318                 camera_mode = CAMERA_CHASE;
2319         }
2320
2321         // Camera angles
2322         if( camera_roll )
2323                 mouse_angles.z += camera_roll * autocvar_camera_speed_roll;
2324
2325         if(autocvar_camera_look_player)
2326         {
2327                 vector dir;
2328                 float n;
2329
2330                 dir = normalize(view_origin - current_position);
2331                 n = mouse_angles.z;
2332                 mouse_angles = vectoangles(dir);
2333                 mouse_angles.x = mouse_angles.x * -1;
2334                 mouse_angles.z = n;
2335         }
2336         else
2337         {
2338                 tmp = getmousepos() * 0.1;
2339                 if(vdist(tmp, >, autocvar_camera_mouse_threshold))
2340                 {
2341                         mouse_angles.x += tmp.y * cos(mouse_angles.z * DEG2RAD) + (tmp.x * sin(mouse_angles.z * DEG2RAD));
2342                         mouse_angles.y -= tmp.x * cos(mouse_angles.z * DEG2RAD) + (tmp.y * -sin(mouse_angles.z * DEG2RAD));
2343                 }
2344         }
2345
2346         while (mouse_angles.x < -180) mouse_angles.x = mouse_angles.x + 360;
2347         while (mouse_angles.x > 180) mouse_angles.x = mouse_angles.x - 360;
2348         while (mouse_angles.y < -180) mouse_angles.y = mouse_angles.y + 360;
2349         while (mouse_angles.y > 180) mouse_angles.y = mouse_angles.y - 360;
2350
2351         // Fix difference when angles don't have the same sign
2352         delta = '0 0 0';
2353         if(mouse_angles.y < -60 && current_angles.y > 60)
2354                 delta = '0 360 0';
2355         if(mouse_angles.y > 60 && current_angles.y < -60)
2356                 delta = '0 -360 0';
2357
2358         if(autocvar_camera_look_player)
2359                 attenuation = autocvar_camera_look_attenuation;
2360         else
2361                 attenuation = autocvar_camera_speed_attenuation;
2362
2363         attenuation = 1 / max(1, attenuation);
2364         current_angles += (mouse_angles - current_angles + delta) * attenuation;
2365
2366         while (current_angles.x < -180) current_angles.x = current_angles.x + 360;
2367         while (current_angles.x > 180) current_angles.x = current_angles.x - 360;
2368         while (current_angles.y < -180) current_angles.y = current_angles.y + 360;
2369         while (current_angles.y > 180) current_angles.y = current_angles.y - 360;
2370
2371         // Camera position
2372         tmp = '0 0 0';
2373         dimensions = 0;
2374
2375         if( camera_direction.x )
2376         {
2377                 tmp.x = camera_direction.x * cos(current_angles.y * DEG2RAD);
2378                 tmp.y = camera_direction.x * sin(current_angles.y * DEG2RAD);
2379                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
2380                         tmp.z = camera_direction.x * -sin(current_angles.x * DEG2RAD);
2381                 ++dimensions;
2382         }
2383
2384         if( camera_direction.y )
2385         {
2386                 tmp.x += camera_direction.y * -sin(current_angles.y * DEG2RAD);
2387                 tmp.y += camera_direction.y * cos(current_angles.y * DEG2RAD) * cos(current_angles.z * DEG2RAD);
2388                 tmp.z += camera_direction.y * sin(current_angles.z * DEG2RAD);
2389                 ++dimensions;
2390         }
2391
2392         if( camera_direction.z )
2393         {
2394                 tmp.z += camera_direction.z * cos(current_angles.z * DEG2RAD);
2395                 ++dimensions;
2396         }
2397
2398         if(autocvar_camera_free)
2399                 speed = autocvar_camera_speed_free;
2400         else
2401                 speed = autocvar_camera_speed_chase;
2402
2403         if(dimensions)
2404         {
2405                 speed = speed * sqrt(1 / dimensions);
2406                 camera_offset += tmp * speed;
2407         }
2408
2409         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
2410
2411         // Camera modes
2412         if( autocvar_camera_free )
2413         {
2414                 if ( camera_mode == CAMERA_CHASE )
2415                 {
2416                         current_camera_offset = current_origin + current_camera_offset;
2417                         camera_offset = current_origin + camera_offset;
2418                 }
2419
2420                 camera_mode = CAMERA_FREE;
2421                 current_position = current_camera_offset;
2422         }
2423         else
2424         {
2425                 if ( camera_mode == CAMERA_FREE )
2426                 {
2427                         current_origin = view_origin;
2428                         camera_offset = camera_offset - current_origin;
2429                         current_camera_offset = current_camera_offset - current_origin;
2430                 }
2431
2432                 camera_mode = CAMERA_CHASE;
2433
2434                 if(autocvar_camera_chase_smoothly)
2435                         current_origin += (view_origin - current_origin) * attenuation;
2436                 else
2437                         current_origin = view_origin;
2438
2439                 current_position = current_origin + current_camera_offset;
2440         }
2441
2442         setproperty(VF_ANGLES, current_angles);
2443         setproperty(VF_ORIGIN, current_position);
2444 }