qcsrc/client/view.qc

   1 #include "view.qh"
   2
   3 #include "announcer.qh"
   4 #include "hud/_mod.qh"
   5 #include "mapvoting.qh"
   6 #include "shownames.qh"
   7 #include "hud/panel/scoreboard.qh"
   8 #include "hud/panel/quickmenu.qh"
   9
  10 #include "mutators/events.qh"
  11
  12 #include <common/animdecide.qh>
  13 #include <common/ent_cs.qh>
  14 #include <common/anim.qh>
  15 #include <common/constants.qh>
  16 #include <common/debug.qh>
  17 #include <common/mapinfo.qh>
  18 #include <common/gamemodes/_mod.qh>
  19 #include <common/physics/player.qh>
  20 #include <common/stats.qh>
  21 #include <common/triggers/target/music.qh>
  22 #include <common/teams.qh>
  23
  24 #include <common/vehicles/all.qh>
  25 #include <common/weapons/_all.qh>
  26 #include <common/viewloc.qh>
  27 #include <common/minigames/cl_minigames.qh>
  28 #include <common/minigames/cl_minigames_hud.qh>
  29
  30 #include <lib/csqcmodel/cl_player.qh>
  31 #include <lib/csqcmodel/cl_model.qh>
  32 #include "csqcmodel_hooks.qh"
  33
  34 #include <lib/warpzone/client.qh>
  35 #include <lib/warpzone/common.qh>
  36
  37 #define EFMASK_CHEAP (EF_ADDITIVE | EF_DOUBLESIDED | EF_FULLBRIGHT | EF_NODEPTHTEST | EF_NODRAW | EF_NOSHADOW | EF_SELECTABLE | EF_TELEPORT_BIT)
  38
  39 float autocvar_cl_viewmodel_scale;
  40
  41 bool autocvar_cl_bobmodel;
  42 float autocvar_cl_bobmodel_speed;
  43 float autocvar_cl_bobmodel_side;
  44 float autocvar_cl_bobmodel_up;
  45
  46 float autocvar_cl_followmodel;
  47 float autocvar_cl_followmodel_speed = 0.3;
  48 float autocvar_cl_followmodel_limit = 135;
  49 float autocvar_cl_followmodel_velocity_lowpass = 0.05;
  50 float autocvar_cl_followmodel_highpass = 0.05;
  51 float autocvar_cl_followmodel_lowpass = 0.03;
  52 bool autocvar_cl_followmodel_velocity_absolute;
  53
  54 float autocvar_cl_leanmodel;
  55 float autocvar_cl_leanmodel_speed = 0.3;
  56 float autocvar_cl_leanmodel_limit = 30;
  57 float autocvar_cl_leanmodel_highpass1 = 0.2;
  58 float autocvar_cl_leanmodel_highpass = 0.2;
  59 float autocvar_cl_leanmodel_lowpass = 0.05;
  60
  61 #define avg_factor(avg_time) (1 - exp(-frametime / max(0.001, avg_time)))
  62 #define lowpass(value, frac, ref_store, ret) MACRO_BEGIN \
  63 { \
  64         ret = ref_store = ref_store * (1 - frac) + (value) * frac; \
  65 } MACRO_END
  66
  67 #define lowpass_limited(value, frac, limit, ref_store, ret) MACRO_BEGIN \
  68 { \
  69         float __ignore; lowpass(value, frac, ref_store, __ignore); \
  70         ret = ref_store = bound((value) - (limit), ref_store, (value) + (limit)); \
  71 } MACRO_END
  72
  73 #define highpass(value, frac, ref_store, ret) MACRO_BEGIN \
  74 { \
  75         float __f = 0; lowpass(value, frac, ref_store, __f); \
  76         ret = (value) - __f; \
  77 } MACRO_END
  78
  79 #define highpass_limited(value, frac, limit, ref_store, ret) MACRO_BEGIN \
  80 { \
  81         float __f = 0; lowpass_limited(value, frac, limit, ref_store, __f); \
  82         ret = (value) - __f; \
  83 } MACRO_END
  84
  85 #define lowpass2(value, frac, ref_store, ref_out) MACRO_BEGIN \
  86 { \
  87         lowpass(value.x, frac, ref_store.x, ref_out.x); \
  88         lowpass(value.y, frac, ref_store.y, ref_out.y); \
  89 } MACRO_END
  90
  91 #define highpass2(value, frac, ref_store, ref_out) MACRO_BEGIN \
  92 { \
  93         highpass(value.x, frac, ref_store.x, ref_out.x); \
  94         highpass(value.y, frac, ref_store.y, ref_out.y); \
  95 } MACRO_END
  96
  97 #define highpass2_limited(value, frac, limit, ref_store, ref_out) MACRO_BEGIN \
  98 { \
  99         highpass_limited(value.x, frac, limit, ref_store.x, ref_out.x); \
 100         highpass_limited(value.y, frac, limit, ref_store.y, ref_out.y); \
 101 } MACRO_END
 102
 103 #define lowpass3(value, frac, ref_store, ref_out) MACRO_BEGIN \
 104 { \
 105         lowpass(value.x, frac, ref_store.x, ref_out.x); \
 106         lowpass(value.y, frac, ref_store.y, ref_out.y); \
 107         lowpass(value.z, frac, ref_store.z, ref_out.z); \
 108 } MACRO_END
 109
 110 #define highpass3(value, frac, ref_store, ref_out) MACRO_BEGIN \
 111 { \
 112         highpass(value.x, frac, ref_store.x, ref_out.x); \
 113         highpass(value.y, frac, ref_store.y, ref_out.y); \
 114         highpass(value.z, frac, ref_store.z, ref_out.z); \
 115 } MACRO_END
 116
 117 void calc_followmodel_ofs(entity view)
 118 {
 119         if(cl_followmodel_time == time)
 120                 return; // cl_followmodel_ofs already calculated for this frame
 121
 122         float frac;
 123         vector gunorg = '0 0 0';
 124         static vector vel_average;
 125         static vector gunorg_prev = '0 0 0';
 126         static vector gunorg_adjustment_highpass;
 127         static vector gunorg_adjustment_lowpass;
 128
 129         vector vel;
 130         if (autocvar_cl_followmodel_velocity_absolute)
 131                 vel = view.velocity;
 132         else
 133         {
 134                 vector forward = '0 0 0', right = '0 0 0', up = '0 0 0';
 135                 MAKEVECTORS(makevectors, view_angles, forward, right, up);
 136                 vel.x = view.velocity * forward;
 137                 vel.y = view.velocity * right * -1;
 138                 vel.z = view.velocity * up;
 139         }
 140
 141         vel.x = bound(vel_average.x - autocvar_cl_followmodel_limit, vel.x, vel_average.x + autocvar_cl_followmodel_limit);
 142         vel.y = bound(vel_average.y - autocvar_cl_followmodel_limit, vel.y, vel_average.y + autocvar_cl_followmodel_limit);
 143         vel.z = bound(vel_average.z - autocvar_cl_followmodel_limit, vel.z, vel_average.z + autocvar_cl_followmodel_limit);
 144
 145         frac = avg_factor(autocvar_cl_followmodel_velocity_lowpass);
 146         lowpass3(vel, frac, vel_average, gunorg);
 147
 148         gunorg *= -autocvar_cl_followmodel_speed * 0.042;
 149
 150         // perform highpass/lowpass on the adjustment vectors (turning velocity into acceleration!)
 151         // trick: we must do the lowpass LAST, so the lowpass vector IS the final vector!
 152         frac = avg_factor(autocvar_cl_followmodel_highpass);
 153         highpass3(gunorg, frac, gunorg_adjustment_highpass, gunorg);
 154         frac = avg_factor(autocvar_cl_followmodel_lowpass);
 155         lowpass3(gunorg, frac, gunorg_adjustment_lowpass, gunorg);
 156
 157         if (autocvar_cl_followmodel_velocity_absolute)
 158         {
 159                 vector fixed_gunorg;
 160                 vector forward = '0 0 0', right = '0 0 0', up = '0 0 0';
 161                 MAKEVECTORS(makevectors, view_angles, forward, right, up);
 162                 fixed_gunorg.x = gunorg * forward;
 163                 fixed_gunorg.y = gunorg * right * -1;
 164                 fixed_gunorg.z = gunorg * up;
 165                 gunorg = fixed_gunorg;
 166         }
 167
 168         cl_followmodel_ofs = gunorg;
 169         cl_followmodel_time = time;
 170 }
 171
 172 vector leanmodel_ofs(entity view)
 173 {
 174         float frac;
 175         vector gunangles = '0 0 0';
 176         static vector gunangles_prev = '0 0 0';
 177         static vector gunangles_highpass = '0 0 0';
 178         static vector gunangles_adjustment_highpass;
 179         static vector gunangles_adjustment_lowpass;
 180
 181         if (view.csqcmodel_teleported)
 182                 gunangles_prev = view_angles;
 183
 184         // in the highpass, we _store_ the DIFFERENCE to the actual view angles...
 185         gunangles_highpass += gunangles_prev;
 186         PITCH(gunangles_highpass) += 360 * floor((PITCH(view_angles) - PITCH(gunangles_highpass)) / 360 + 0.5);
 187         YAW(gunangles_highpass) += 360 * floor((YAW(view_angles) - YAW(gunangles_highpass)) / 360 + 0.5);
 188         ROLL(gunangles_highpass) += 360 * floor((ROLL(view_angles) - ROLL(gunangles_highpass)) / 360 + 0.5);
 189         frac = avg_factor(autocvar_cl_leanmodel_highpass1);
 190         highpass2_limited(view_angles, frac, autocvar_cl_leanmodel_limit, gunangles_highpass, gunangles);
 191         gunangles_prev = view_angles;
 192         gunangles_highpass -= gunangles_prev;
 193
 194         PITCH(gunangles) *= -autocvar_cl_leanmodel_speed;
 195         YAW(gunangles) *= -autocvar_cl_leanmodel_speed;
 196
 197         // we assume here: PITCH = 0, YAW = 1, ROLL = 2
 198         frac = avg_factor(autocvar_cl_leanmodel_highpass);
 199         highpass2(gunangles, frac, gunangles_adjustment_highpass, gunangles);
 200         frac = avg_factor(autocvar_cl_leanmodel_lowpass);
 201         lowpass2(gunangles, frac, gunangles_adjustment_lowpass, gunangles);
 202
 203         gunangles.x = -gunangles.x; // pitch was inverted, now that actually matters
 204
 205         return gunangles;
 206 }
 207
 208 vector bobmodel_ofs(entity view)
 209 {
 210         bool clonground = !(view.anim_implicit_state & ANIMIMPLICITSTATE_INAIR);
 211         static bool oldonground;
 212         static float hitgroundtime;
 213         if (clonground)
 214         {
 215                 float f = time; // cl.movecmd[0].time
 216                 if (!oldonground)
 217                         hitgroundtime = f;
 218         }
 219         oldonground = clonground;
 220
 221         // calculate for swinging gun model
 222         // the gun bobs when running on the ground, but doesn't bob when you're in the air.
 223         vector gunorg = '0 0 0';
 224         static float bobmodel_scale = 0;
 225         static float time_ofs = 0; // makes the effect always restart in the same way
 226         if (clonground)
 227         {
 228                 if (time - hitgroundtime > 0.05)
 229                         bobmodel_scale = min(1, bobmodel_scale + frametime * 5);
 230         }
 231         else
 232                 bobmodel_scale = max(0, bobmodel_scale - frametime * 5);
 233
 234         float xyspeed = bound(0, vlen(vec2(view.velocity)), 400);
 235         if (bobmodel_scale && xyspeed)
 236         {
 237                 float bspeed = xyspeed * 0.01 * autocvar_cl_viewmodel_scale * bobmodel_scale;
 238                 float s = (time - time_ofs) * autocvar_cl_bobmodel_speed;
 239                 gunorg.y = bspeed * autocvar_cl_bobmodel_side * sin(s);
 240                 gunorg.z = bspeed * autocvar_cl_bobmodel_up * cos(s * 2);
 241         }
 242         else
 243                 time_ofs = time;
 244
 245         return gunorg;
 246 }
 247
 248 void viewmodel_animate(entity this)
 249 {
 250         if (autocvar_chase_active) return;
 251         if (STAT(HEALTH) <= 0) return;
 252
 253         entity view = CSQCModel_server2csqc(player_localentnum - 1);
 254
 255         if (autocvar_cl_followmodel)
 256         {
 257                 calc_followmodel_ofs(view);
 258                 this.origin += cl_followmodel_ofs;
 259         }
 260
 261         if (autocvar_cl_leanmodel)
 262                 this.angles += leanmodel_ofs(view);
 263
 264         // vertical view bobbing code
 265         // TODO: cl_bob
 266
 267         // horizontal view bobbing code
 268         // TODO: cl_bob2
 269
 270         // fall bobbing code
 271         // causes the view to swing down and back up when touching the ground
 272         // TODO: cl_bobfall
 273
 274         // gun model bobbing code
 275         if (autocvar_cl_bobmodel)
 276                 this.origin += bobmodel_ofs(view);
 277 }
 278
 279 .vector viewmodel_origin, viewmodel_angles;
 280 .float weapon_nextthink;
 281 .float weapon_eta_last;
 282 .float weapon_switchdelay;
 283
 284 void viewmodel_draw(entity this)
 285 {
 286         if(!this.activeweapon || !autocvar_r_drawviewmodel)
 287                 return;
 288         int mask = (intermission || (STAT(HEALTH) <= 0) || autocvar_chase_active) ? 0 : MASK_NORMAL;
 289         float a = this.alpha;
 290         static bool wasinvehicle;
 291         bool invehicle = player_localentnum > maxclients;
 292         if (invehicle) a = -1;
 293         else if (wasinvehicle) a = 1;
 294         wasinvehicle = invehicle;
 295         Weapon wep = this.activeweapon;
 296         int c = entcs_GetClientColors(current_player);
 297         vector g = weaponentity_glowmod(wep, NULL, c);
 298         entity me = CSQCModel_server2csqc(player_localentnum - 1);
 299         int fx = ((me.csqcmodel_effects & EFMASK_CHEAP)
 300                 | EF_NODEPTHTEST)
 301                 &~ (EF_FULLBRIGHT); // can mask team color, so get rid of it
 302         for (entity e = this; e; e = e.weaponchild)
 303         {
 304                 e.drawmask = mask;
 305                 e.alpha = a;
 306                 e.colormap = 256 + c;  // colormap == 0 is black, c == 0 is white
 307                 e.glowmod = g;
 308                 e.csqcmodel_effects = fx;
 309                 CSQCModel_Effects_Apply(e);
 310         }
 311         {
 312                 static string name_last;
 313                 string name = wep.mdl;
 314                 bool swap = name != name_last;
 315                 // if (swap)
 316                 {
 317                         name_last = name;
 318                         CL_WeaponEntity_SetModel(this, name, swap);
 319                         this.viewmodel_origin = this.origin;
 320                         this.viewmodel_angles = this.angles;
 321                 }
 322                 anim_update(this);
 323                 if (!this.animstate_override && !this.animstate_looping)
 324                         anim_set(this, this.anim_idle, true, false, false);
 325         }
 326         float f = 0; // 0..1; 0: fully active
 327         float rate = STAT(WEAPONRATEFACTOR);
 328         float eta = rate ? ((this.weapon_nextthink - time) / rate) : 0;
 329         if (eta <= 0) f = this.weapon_eta_last;
 330         else switch (this.state)
 331         {
 332                 case WS_RAISE:
 333                 {
 334                         f = eta / max(eta, this.weapon_switchdelay);
 335                         break;
 336                 }
 337                 case WS_DROP:
 338                 {
 339                         f = 1 - eta / max(eta, this.weapon_switchdelay);
 340                         break;
 341                 }
 342                 case WS_CLEAR:
 343                 {
 344                         f = 1;
 345                         break;
 346                 }
 347         }
 348         this.weapon_eta_last = f;
 349         this.origin = this.viewmodel_origin;
 350         this.angles = this.viewmodel_angles;
 351         this.angles_x = (-90 * f * f);
 352         viewmodel_animate(this);
 353         setorigin(this, this.origin);
 354 }
 355
 356 entity viewmodels[MAX_WEAPONSLOTS];
 357 STATIC_INIT(viewmodel) {
 358     for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 359         viewmodels[slot] = new(viewmodel);
 360 }
 361
 362 void Porto_Draw(entity this);
 363 STATIC_INIT(Porto)
 364 {
 365         entity e = new_pure(porto);
 366         e.draw = Porto_Draw;
 367         IL_PUSH(g_drawables, e);
 368         e.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 369 }
 370
 371 const int polyline_length = 16;
 372 vector polyline[polyline_length];
 373 void Porto_Draw(entity this)
 374 {
 375         entity wepent = viewmodels[0]; // TODO: unhardcode
 376         if (wepent.activeweapon != WEP_PORTO) return;
 377         if (spectatee_status) return;
 378         if (WEP_CVAR(porto, secondary)) return;
 379         if (intermission == 1) return;
 380         if (intermission == 2) return;
 381         if (STAT(HEALTH) <= 0) return;
 382
 383         vector pos = view_origin;
 384         vector dir = view_forward;
 385         if (angles_held_status)
 386         {
 387                 makevectors(angles_held);
 388                 dir = v_forward;
 389         }
 390
 391         polyline[0] = pos;
 392
 393         int portal_number = 0, portal1_idx = 1, portal_max = 2;
 394         int n = 1 + 2;  // 2 lines == 3 points
 395         for (int idx = 0; idx < n && idx < polyline_length - 1; )
 396         {
 397                 traceline(pos, pos + 65536 * dir, true, this);
 398                 dir = reflect(dir, trace_plane_normal);
 399                 pos = trace_endpos;
 400                 polyline[++idx] = pos;
 401                 if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
 402                 {
 403                         n += 1;
 404                         continue;
 405                 }
 406                 if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
 407                 {
 408                         n = max(2, idx);
 409                         break;
 410                 }
 411                 // check size
 412                 {
 413                         vector ang = vectoangles2(trace_plane_normal, dir);
 414                         ang.x = -ang.x;
 415                         makevectors(ang);
 416                         if (!CheckWireframeBox(this, pos - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
 417                         {
 418                                 n = max(2, idx);
 419                                 break;
 420                         }
 421                 }
 422                 portal_number += 1;
 423                 if (portal_number >= portal_max) break;
 424                 if (portal_number == 1) portal1_idx = idx;
 425         }
 426         for (int idx = 0; idx < n - 1; ++idx)
 427         {
 428                 vector p = polyline[idx], q = polyline[idx + 1];
 429                 if (idx == 0) p -= view_up * 16;  // line from player
 430                 vector rgb = (idx < portal1_idx) ? '1 0 0' : '0 0 1';
 431                 Draw_CylindricLine(p, q, 4, "", 1, 0, rgb, 0.5, DRAWFLAG_NORMAL, view_origin);
 432         }
 433 }
 434
 435 float drawtime;
 436 float avgspeed;
 437 vector GetCurrentFov(float fov)
 438 {
 439         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir;
 440         float velocityzoom, curspeed;
 441         vector v;
 442
 443         zoomsensitivity = autocvar_cl_zoomsensitivity;
 444         zoomfactor = autocvar_cl_zoomfactor;
 445         if(zoomfactor < 1 || zoomfactor > 30)
 446                 zoomfactor = 2.5;
 447         zoomspeed = autocvar_cl_zoomspeed;
 448         if(zoomspeed >= 0)
 449         if(zoomspeed < 0.5 || zoomspeed > 16)
 450                         zoomspeed = 3.5;
 451
 452         zoomdir = button_zoom;
 453         entity wepent = viewmodels[0]; // TODO: unhardcode
 454
 455         if(hud == HUD_NORMAL && !spectatee_status)
 456         if(wepent.switchweapon == wepent.activeweapon)
 457         if((wepent.activeweapon == WEP_VORTEX && !WEP_CVAR(vortex, secondary)) || (wepent.activeweapon == WEP_RIFLE && !WEP_CVAR(rifle, secondary))) // do NOT use switchweapon here
 458                 zoomdir += button_attack2;
 459         if(spectatee_status > 0 || isdemo())
 460         {
 461                 if(spectatorbutton_zoom)
 462                 {
 463                         if(zoomdir)
 464                                 zoomdir = 0;
 465                         else
 466                                 zoomdir = 1;
 467                 }
 468                 // fteqcc failed twice here already, don't optimize this
 469         }
 470
 471         if(zoomdir) { zoomin_effect = 0; }
 472
 473         if(camera_active)
 474         {
 475                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 476         }
 477         else if(autocvar_cl_spawnzoom && zoomin_effect)
 478         {
 479                 float spawnzoomfactor = bound(1, autocvar_cl_spawnzoom_factor, 30);
 480
 481                 current_viewzoom += (autocvar_cl_spawnzoom_speed * (spawnzoomfactor - current_viewzoom) * drawframetime);
 482                 current_viewzoom = bound(1 / spawnzoomfactor, current_viewzoom, 1);
 483                 if(current_viewzoom == 1) { zoomin_effect = 0; }
 484         }
 485         else
 486         {
 487                 if(zoomspeed < 0) // instant zoom
 488                 {
 489                         if(zoomdir)
 490                                 current_viewzoom = 1 / zoomfactor;
 491                         else
 492                                 current_viewzoom = 1;
 493                 }
 494                 else
 495                 {
 496                         if(zoomdir)
 497                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 498                         else
 499                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 500                 }
 501         }
 502
 503         if(almost_equals(current_viewzoom, 1))
 504                 current_zoomfraction = 0;
 505         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 506                 current_zoomfraction = 1;
 507         else
 508                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 509
 510         if(zoomsensitivity < 1)
 511                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
 512         else
 513                 setsensitivityscale(1);
 514
 515         if(autocvar_cl_velocityzoom_enabled && autocvar_cl_velocityzoom_type) // _type = 0 disables velocity zoom too
 516         {
 517                 if(intermission) { curspeed = 0; }
 518                 else
 519                 {
 520
 521                         makevectors(view_angles);
 522                         v = pmove_vel;
 523                         if(csqcplayer)
 524                                 v = csqcplayer.velocity;
 525
 526                         switch(autocvar_cl_velocityzoom_type)
 527                         {
 528                                 case 3: curspeed = max(0, v_forward * v); break;
 529                                 case 2: curspeed = (v_forward * v); break;
 530                                 case 1: default: curspeed = vlen(v); break;
 531                         }
 532                 }
 533
 534                 velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoom_time), 1); // speed at which the zoom adapts to player velocity
 535                 avgspeed = avgspeed * (1 - velocityzoom) + (curspeed / autocvar_cl_velocityzoom_speed) * velocityzoom;
 536                 velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom_factor / 1) * 1);
 537
 538                 //print(ftos(avgspeed), " avgspeed, ", ftos(curspeed), " curspeed, ", ftos(velocityzoom), " return\n"); // for debugging
 539         }
 540         else
 541                 velocityzoom = 1;
 542
 543         float frustumx, frustumy, fovx, fovy;
 544         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 545         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 546         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 547         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 548
 549         return '1 0 0' * fovx + '0 1 0' * fovy;
 550 }
 551
 552 vector GetViewLocationFOV(float fov)
 553 {
 554         float frustumy = tan(fov * M_PI / 360.0) * 0.75;
 555         float frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 556         float fovx = atan2(frustumx, 1) / M_PI * 360.0;
 557         float fovy = atan2(frustumy, 1) / M_PI * 360.0;
 558         return '1 0 0' * fovx + '0 1 0' * fovy;
 559 }
 560
 561 vector GetOrthoviewFOV(vector ov_worldmin, vector ov_worldmax, vector ov_mid, vector ov_org)
 562 {
 563         float fovx, fovy;
 564         float width = (ov_worldmax.x - ov_worldmin.x);
 565         float height = (ov_worldmax.y - ov_worldmin.y);
 566         float distance_to_middle_of_world = vlen(ov_mid - ov_org);
 567         fovx = atan2(width/2, distance_to_middle_of_world) / M_PI * 360.0;
 568         fovy = atan2(height/2, distance_to_middle_of_world) / M_PI * 360.0;
 569         return '1 0 0' * fovx + '0 1 0' * fovy;
 570 }
 571
 572 // this function must match W_SetupShot!
 573 float zoomscript_caught;
 574
 575 vector wcross_origin;
 576 float wcross_scale_prev, wcross_alpha_prev;
 577 vector wcross_color_prev;
 578 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 579 vector wcross_color_goal_prev;
 580 float wcross_changedonetime;
 581
 582 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 583 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 584 float wcross_name_changestarttime, wcross_name_changedonetime;
 585 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 586
 587 float wcross_ring_prev;
 588
 589 entity trueaim;
 590 entity trueaim_rifle;
 591
 592 const float SHOTTYPE_HITTEAM = 1;
 593 const float SHOTTYPE_HITOBSTRUCTION = 2;
 594 const float SHOTTYPE_HITWORLD = 3;
 595 const float SHOTTYPE_HITENEMY = 4;
 596
 597 void TrueAim_Init()
 598 {
 599         (trueaim = new_pure(trueaim)).dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 600         (trueaim_rifle = new_pure(trueaim_rifle)).dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 601 }
 602
 603 float EnemyHitCheck()
 604 {
 605         float t, n;
 606         wcross_origin = project_3d_to_2d(trace_endpos);
 607         wcross_origin.z = 0;
 608         if(trace_ent)
 609                 n = trace_ent.entnum;
 610         else
 611                 n = trace_networkentity;
 612         if(n < 1)
 613                 return SHOTTYPE_HITWORLD;
 614         if(n > maxclients)
 615                 return SHOTTYPE_HITWORLD;
 616         t = entcs_GetTeam(n - 1);
 617         if(teamplay)
 618                 if(t == myteam)
 619                         return SHOTTYPE_HITTEAM;
 620         if(t == NUM_SPECTATOR)
 621                 return SHOTTYPE_HITWORLD;
 622         return SHOTTYPE_HITENEMY;
 623 }
 624
 625 float TrueAimCheck()
 626 {
 627         float nudge = 1; // added to traceline target and subtracted from result TOOD(divVerent): do we still need this? Doesn't the engine do this now for us?
 628         vector vecs, trueaimpoint, w_shotorg;
 629         vector mi, ma, dv;
 630         float shottype;
 631         entity ta;
 632         float mv;
 633
 634         mi = ma = '0 0 0';
 635         ta = trueaim;
 636         mv = MOVE_NOMONSTERS;
 637
 638         entity wepent = viewmodels[0]; // TODO: unhardcode
 639
 640         switch(wepent.activeweapon) // WEAPONTODO
 641         {
 642                 case WEP_TUBA: // no aim
 643                 case WEP_PORTO: // shoots from eye
 644                 case WEP_NEXBALL: // shoots from eye
 645                 case WEP_HOOK: // no trueaim
 646                 case WEP_MORTAR: // toss curve
 647                         return SHOTTYPE_HITWORLD;
 648                 case WEP_VORTEX:
 649                 case WEP_VAPORIZER:
 650                         mv = MOVE_NORMAL;
 651                         break;
 652                 case WEP_RIFLE:
 653                         ta = trueaim_rifle;
 654                         mv = MOVE_NORMAL;
 655                         if(zoomscript_caught)
 656                         {
 657                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 658                                 return EnemyHitCheck();
 659                         }
 660                         break;
 661                 case WEP_DEVASTATOR: // projectile has a size!
 662                         mi = '-3 -3 -3';
 663                         ma = '3 3 3';
 664                         break;
 665                 case WEP_FIREBALL: // projectile has a size!
 666                         mi = '-16 -16 -16';
 667                         ma = '16 16 16';
 668                         break;
 669                 case WEP_SEEKER: // projectile has a size!
 670                         mi = '-2 -2 -2';
 671                         ma = '2 2 2';
 672                         break;
 673                 case WEP_ELECTRO: // projectile has a size!
 674                         mi = '0 0 -3';
 675                         ma = '0 0 -3';
 676                         break;
 677         }
 678
 679         vector traceorigin = entcs_receiver(player_localentnum - 1).origin + (eZ * STAT(VIEWHEIGHT));
 680
 681         vecs = decompressShotOrigin(STAT(SHOTORG));
 682
 683         traceline(traceorigin, traceorigin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 684         trueaimpoint = trace_endpos;
 685
 686         if(vdist((trueaimpoint - traceorigin), <, g_trueaim_minrange))
 687                 trueaimpoint = traceorigin + view_forward * g_trueaim_minrange;
 688
 689         if(vecs.x > 0)
 690                 vecs.y = -vecs.y;
 691         else
 692                 vecs = '0 0 0';
 693
 694         dv = view_right * vecs.y + view_up * vecs.z;
 695         w_shotorg = traceorigin + dv;
 696
 697         // now move the vecs forward as much as requested if possible
 698         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs.x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 699         w_shotorg = trace_endpos - view_forward * nudge;
 700
 701         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 702         shottype = EnemyHitCheck();
 703         if(shottype != SHOTTYPE_HITWORLD)
 704                 return shottype;
 705
 706 #if 0
 707         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 708         // or rather, I know why, but see no fix
 709         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 710                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 711                 return SHOTTYPE_HITOBSTRUCTION;
 712 #endif
 713
 714         return SHOTTYPE_HITWORLD;
 715 }
 716
 717 void PostInit();
 718 void CSQC_Demo_Camera();
 719 float camera_mode;
 720 const float CAMERA_FREE = 1;
 721 const float CAMERA_CHASE = 2;
 722 float reticle_type;
 723 string reticle_image;
 724 string NextFrameCommand;
 725
 726 vector freeze_org, freeze_ang;
 727 entity nightvision_noise, nightvision_noise2;
 728
 729 const float MAX_TIME_DIFF = 5;
 730 float pickup_crosshair_time, pickup_crosshair_size;
 731 float hitindication_crosshair_size;
 732 float use_vortex_chargepool;
 733
 734 float myhealth, myhealth_prev;
 735 float myhealth_flash;
 736
 737 float old_blurradius, old_bluralpha;
 738 float old_sharpen_intensity;
 739
 740 vector myhealth_gentlergb;
 741
 742 float contentavgalpha, liquidalpha_prev;
 743 vector liquidcolor_prev;
 744
 745 float eventchase_current_distance;
 746 float eventchase_running;
 747 bool WantEventchase(entity this)
 748 {
 749         if(autocvar_cl_orthoview)
 750                 return false;
 751         if(intermission)
 752                 return true;
 753         if(this.viewloc)
 754                 return true;
 755         if(spectatee_status >= 0)
 756         {
 757                 if(hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0))
 758                         return true;
 759                 if(MUTATOR_CALLHOOK(WantEventchase, this))
 760                         return true;
 761                 if(autocvar_cl_eventchase_death && (STAT(HEALTH) <= 0))
 762                 {
 763                         if(autocvar_cl_eventchase_death == 2)
 764                         {
 765                                 // don't stop eventchase once it's started (even if velocity changes afterwards)
 766                                 if(this.velocity == '0 0 0' || eventchase_running)
 767                                         return true;
 768                         }
 769                         else return true;
 770                 }
 771         }
 772         return false;
 773 }
 774
 775 void HUD_Crosshair_Vehicle(entity this)
 776 {
 777         if(hud != HUD_BUMBLEBEE_GUN)
 778         {
 779                 Vehicle info = Vehicles_from(hud);
 780                 info.vr_crosshair(info, this);
 781         }
 782 }
 783
 784 vector damage_blurpostprocess, content_blurpostprocess;
 785
 786 float unaccounted_damage = 0;
 787 void UpdateDamage()
 788 {
 789         // accumulate damage with each stat update
 790         static float damage_total_prev = 0;
 791         float damage_total = STAT(DAMAGE_DEALT_TOTAL);
 792         float unaccounted_damage_new = COMPARE_INCREASING(damage_total, damage_total_prev);
 793         damage_total_prev = damage_total;
 794
 795         static float damage_dealt_time_prev = 0;
 796         float damage_dealt_time = STAT(HIT_TIME);
 797         if (damage_dealt_time != damage_dealt_time_prev)
 798         {
 799                 unaccounted_damage += unaccounted_damage_new;
 800                 LOG_TRACE("dmg total: ", ftos(unaccounted_damage), " (+", ftos(unaccounted_damage_new), ")");
 801         }
 802         damage_dealt_time_prev = damage_dealt_time;
 803
 804         // prevent hitsound when switching spectatee
 805         static float spectatee_status_prev = 0;
 806         if (spectatee_status != spectatee_status_prev)
 807                 unaccounted_damage = 0;
 808         spectatee_status_prev = spectatee_status;
 809 }
 810
 811 void HitSound()
 812 {
 813         // varying sound pitch
 814
 815         entity wepent = viewmodels[0]; // TODO: unhardcode
 816
 817         static float hitsound_time_prev = 0;
 818         // HACK: the only way to get the arc to sound consistent with pitch shift is to ignore cl_hitsound_antispam_time
 819         float arc_hack = wepent.activeweapon == WEP_ARC && autocvar_cl_hitsound >= 2;
 820         if (arc_hack || COMPARE_INCREASING(time, hitsound_time_prev) > autocvar_cl_hitsound_antispam_time)
 821         {
 822                 if (autocvar_cl_hitsound && unaccounted_damage)
 823                 {
 824                         // customizable gradient function that crosses (0,a), (c,1) and asymptotically approaches b
 825                         float a = autocvar_cl_hitsound_max_pitch;
 826                         float b = autocvar_cl_hitsound_min_pitch;
 827                         float c = autocvar_cl_hitsound_nom_damage;
 828                         float x = unaccounted_damage;
 829                         float pitch_shift = (b*x*(a-1) + a*c*(1-b)) / (x*(a-1) + c*(1-b));
 830
 831                         // if sound variation is disabled, set pitch_shift to 1
 832                         if (autocvar_cl_hitsound == 1)
 833                                 pitch_shift = 1;
 834
 835                         // if pitch shift is reversed, mirror in (max-min)/2 + min
 836                         if (autocvar_cl_hitsound == 3)
 837                         {
 838                                 float mirror_value = (a-b)/2 + b;
 839                                 pitch_shift = mirror_value + (mirror_value - pitch_shift);
 840                         }
 841
 842                         LOG_TRACE("dmg total (dmg): ", ftos(unaccounted_damage), " , pitch shift: ", ftos(pitch_shift));
 843
 844                         // todo: avoid very long and very short sounds from wave stretching using different sound files? seems unnecessary
 845                         // todo: normalize sound pressure levels? seems unnecessary
 846
 847                         sound7(NULL, CH_INFO, SND(HIT), VOL_BASE, ATTN_NONE, pitch_shift * 100, 0);
 848                 }
 849                 unaccounted_damage = 0;
 850                 hitsound_time_prev = time;
 851         }
 852
 853         static float typehit_time_prev = 0;
 854         float typehit_time = STAT(TYPEHIT_TIME);
 855         if (COMPARE_INCREASING(typehit_time, typehit_time_prev) > autocvar_cl_hitsound_antispam_time)
 856         {
 857                 sound(NULL, CH_INFO, SND_TYPEHIT, VOL_BASE, ATTN_NONE);
 858                 typehit_time_prev = typehit_time;
 859         }
 860 }
 861
 862 vector crosshair_getcolor(entity this, float health_stat)
 863 {
 864         static float rainbow_last_flicker;
 865         static vector rainbow_prev_color;
 866         vector wcross_color = '0 0 0';
 867         switch(autocvar_crosshair_color_special)
 868         {
 869                 case 1: // crosshair_color_per_weapon
 870                 {
 871                         if(this != WEP_Null && hud == HUD_NORMAL)
 872                         {
 873                                 wcross_color = this.wpcolor;
 874                                 break;
 875                         }
 876                         else { goto normalcolor; }
 877                 }
 878
 879                 case 2: // crosshair_color_by_health
 880                 {
 881                         float x = health_stat;
 882
 883                         //x = red
 884                         //y = green
 885                         //z = blue
 886
 887                         wcross_color.z = 0;
 888
 889                         if(x > 200)
 890                         {
 891                                 wcross_color.x = 0;
 892                                 wcross_color.y = 1;
 893                         }
 894                         else if(x > 150)
 895                         {
 896                                 wcross_color.x = 0.4 - (x-150)*0.02 * 0.4;
 897                                 wcross_color.y = 0.9 + (x-150)*0.02 * 0.1;
 898                         }
 899                         else if(x > 100)
 900                         {
 901                                 wcross_color.x = 1 - (x-100)*0.02 * 0.6;
 902                                 wcross_color.y = 1 - (x-100)*0.02 * 0.1;
 903                                 wcross_color.z = 1 - (x-100)*0.02;
 904                         }
 905                         else if(x > 50)
 906                         {
 907                                 wcross_color.x = 1;
 908                                 wcross_color.y = 1;
 909                                 wcross_color.z = 0.2 + (x-50)*0.02 * 0.8;
 910                         }
 911                         else if(x > 20)
 912                         {
 913                                 wcross_color.x = 1;
 914                                 wcross_color.y = (x-20)*90/27/100;
 915                                 wcross_color.z = (x-20)*90/27/100 * 0.2;
 916                         }
 917                         else
 918                         {
 919                                 wcross_color.x = 1;
 920                                 wcross_color.y = 0;
 921                         }
 922                         break;
 923                 }
 924
 925                 case 3: // crosshair_color_rainbow
 926                 {
 927                         if(time >= rainbow_last_flicker)
 928                         {
 929                                 rainbow_prev_color = randomvec() * autocvar_crosshair_color_special_rainbow_brightness;
 930                                 rainbow_last_flicker = time + autocvar_crosshair_color_special_rainbow_delay;
 931                         }
 932                         wcross_color = rainbow_prev_color;
 933                         break;
 934                 }
 935 LABEL(normalcolor)
 936                 default: { wcross_color = stov(autocvar_crosshair_color); break; }
 937         }
 938
 939         return wcross_color;
 940 }
 941
 942 void HUD_Crosshair(entity this)
 943 {
 944         float f, i, j;
 945         vector v;
 946         if(!scoreboard_active && !camera_active && intermission != 2 &&
 947                 spectatee_status != -1 && !csqcplayer.viewloc && !MUTATOR_CALLHOOK(DrawCrosshair) &&
 948                 !HUD_MinigameMenu_IsOpened() )
 949         {
 950                 if (!autocvar_crosshair_enabled) // main toggle for crosshair rendering
 951                         return;
 952
 953                 if (spectatee_status > 0 && STAT(CAMERA_SPECTATOR) == 2)
 954                         return;
 955
 956                 if (hud != HUD_NORMAL)
 957                 {
 958                         HUD_Crosshair_Vehicle(this);
 959                         return;
 960                 }
 961
 962                 string wcross_style;
 963                 float wcross_alpha, wcross_resolution;
 964                 wcross_style = autocvar_crosshair;
 965                 if (wcross_style == "0")
 966                         return;
 967                 wcross_resolution = autocvar_crosshair_size;
 968                 if (wcross_resolution == 0)
 969                         return;
 970                 wcross_alpha = autocvar_crosshair_alpha;
 971                 if (wcross_alpha == 0)
 972                         return;
 973
 974                 // TrueAim check
 975                 float shottype;
 976
 977                 // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
 978                 wcross_origin = project_3d_to_2d(view_origin + MAX_SHOT_DISTANCE * view_forward);
 979                 wcross_origin.z = 0;
 980                 if(autocvar_crosshair_hittest)
 981                 {
 982                         vector wcross_oldorigin;
 983                         wcross_oldorigin = wcross_origin;
 984                         shottype = TrueAimCheck();
 985                         if(shottype == SHOTTYPE_HITWORLD)
 986                         {
 987                                 v = wcross_origin - wcross_oldorigin;
 988                                 v.x /= vid_conwidth;
 989                                 v.y /= vid_conheight;
 990                                 if(vdist(v, >, 0.01))
 991                                         shottype = SHOTTYPE_HITOBSTRUCTION;
 992                         }
 993                         if(!autocvar_crosshair_hittest_showimpact)
 994                                 wcross_origin = wcross_oldorigin;
 995                 }
 996                 else
 997                         shottype = SHOTTYPE_HITWORLD;
 998
 999                 vector wcross_color = '0 0 0', wcross_size = '0 0 0';
1000                 string wcross_name = "";
1001                 float wcross_scale, wcross_blur;
1002
1003         entity e = WEP_Null;
1004                 if(autocvar_crosshair_per_weapon || (autocvar_crosshair_color_special == 1))
1005                 {
1006                         entity wepent = viewmodels[0]; // TODO: unhardcode
1007                         e = wepent.switchingweapon;
1008                         if(e)
1009                         {
1010                                 if(autocvar_crosshair_per_weapon)
1011                                 {
1012                                         // WEAPONTODO: access these through some general settings (with non-balance config settings)
1013                                         //wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
1014                                         //if (wcross_resolution == 0)
1015                                                 //return;
1016
1017                                         //wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
1018                                         wcross_resolution *= e.w_crosshair_size;
1019                                         wcross_name = e.w_crosshair;
1020                                 }
1021                         }
1022                 }
1023
1024                 if(wcross_name == "")
1025                         wcross_name = strcat("gfx/crosshair", wcross_style);
1026
1027                 // MAIN CROSSHAIR COLOR DECISION
1028                 wcross_color = crosshair_getcolor(e, STAT(HEALTH));
1029
1030                 if(autocvar_crosshair_effect_scalefade)
1031                 {
1032                         wcross_scale = wcross_resolution;
1033                         wcross_resolution = 1;
1034                 }
1035                 else
1036                 {
1037                         wcross_scale = 1;
1038                 }
1039
1040                 if(autocvar_crosshair_pickup)
1041                 {
1042                         float stat_pickup_time = STAT(LAST_PICKUP);
1043
1044                         if(pickup_crosshair_time < stat_pickup_time)
1045                         {
1046                                 if(time - stat_pickup_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1047                                         pickup_crosshair_size = 1;
1048
1049                                 pickup_crosshair_time = stat_pickup_time;
1050                         }
1051
1052                         if(pickup_crosshair_size > 0)
1053                                 pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
1054                         else
1055                                 pickup_crosshair_size = 0;
1056
1057                         wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
1058                 }
1059
1060                 // todo: make crosshair hit indication dependent on damage dealt
1061                 if(autocvar_crosshair_hitindication)
1062                 {
1063                         vector hitindication_color = ((autocvar_crosshair_color_special == 1) ? stov(autocvar_crosshair_hitindication_per_weapon_color) : stov(autocvar_crosshair_hitindication_color));
1064
1065                         if(unaccounted_damage)
1066                         {
1067                                 hitindication_crosshair_size = 1;
1068                         }
1069
1070                         if(hitindication_crosshair_size > 0)
1071                                 hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
1072                         else
1073                                 hitindication_crosshair_size = 0;
1074
1075                         wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
1076                         wcross_color.x += sin(hitindication_crosshair_size) * hitindication_color.x;
1077                         wcross_color.y += sin(hitindication_crosshair_size) * hitindication_color.y;
1078                         wcross_color.z += sin(hitindication_crosshair_size) * hitindication_color.z;
1079                 }
1080
1081                 if(shottype == SHOTTYPE_HITENEMY)
1082                         wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
1083                 if(shottype == SHOTTYPE_HITTEAM)
1084                         wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
1085
1086                 f = fabs(autocvar_crosshair_effect_time);
1087                 if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
1088                 {
1089                         wcross_changedonetime = time + f;
1090                 }
1091                 if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
1092                 {
1093                         wcross_name_changestarttime = time;
1094                         wcross_name_changedonetime = time + f;
1095                         if(wcross_name_goal_prev_prev)
1096                                 strunzone(wcross_name_goal_prev_prev);
1097                         wcross_name_goal_prev_prev = wcross_name_goal_prev;
1098                         wcross_name_goal_prev = strzone(wcross_name);
1099                         wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
1100                         wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
1101                         wcross_resolution_goal_prev = wcross_resolution;
1102                 }
1103
1104                 wcross_scale_goal_prev = wcross_scale;
1105                 wcross_alpha_goal_prev = wcross_alpha;
1106                 wcross_color_goal_prev = wcross_color;
1107
1108                 if(spectatee_status == -1 && shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
1109                 {
1110                         wcross_blur = 1;
1111                         wcross_alpha *= 0.75;
1112                 }
1113                 else
1114                         wcross_blur = 0;
1115                 // *_prev is at time-frametime
1116                 // * is at wcross_changedonetime+f
1117                 // what do we have at time?
1118                 if(time < wcross_changedonetime)
1119                 {
1120                         f = frametime / (wcross_changedonetime - time + frametime);
1121                         wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
1122                         wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
1123                         wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
1124                 }
1125
1126                 wcross_scale_prev = wcross_scale;
1127                 wcross_alpha_prev = wcross_alpha;
1128                 wcross_color_prev = wcross_color;
1129
1130                 MUTATOR_CALLHOOK(UpdateCrosshair);
1131
1132                 wcross_scale *= 1 - autocvar__menu_alpha;
1133                 wcross_alpha *= 1 - autocvar__menu_alpha;
1134                 wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1135
1136                 if(wcross_scale >= 0.001 && wcross_alpha >= 0.001)
1137                 {
1138                         // crosshair rings for weapon stats
1139                         if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
1140                         {
1141                                 // declarations and stats
1142                                 float ring_value = 0, ring_scale = 0, ring_alpha = 0, ring_inner_value = 0, ring_inner_alpha = 0;
1143                                 string ring_image = string_null, ring_inner_image = string_null;
1144                                 vector ring_rgb = '0 0 0', ring_inner_rgb = '0 0 0';
1145
1146                                 ring_scale = autocvar_crosshair_ring_size;
1147
1148                                 float weapon_clipload, weapon_clipsize;
1149                                 weapon_clipload = STAT(WEAPON_CLIPLOAD);
1150                                 weapon_clipsize = STAT(WEAPON_CLIPSIZE);
1151
1152                                 float ok_ammo_charge, ok_ammo_chargepool;
1153                                 ok_ammo_charge = STAT(OK_AMMO_CHARGE);
1154                                 ok_ammo_chargepool = STAT(OK_AMMO_CHARGEPOOL);
1155
1156                                 float vortex_charge, vortex_chargepool;
1157                                 vortex_charge = STAT(VORTEX_CHARGE);
1158                                 vortex_chargepool = STAT(VORTEX_CHARGEPOOL);
1159
1160                                 float arc_heat = STAT(ARC_HEAT);
1161
1162                                 if(vortex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
1163                                         vortex_charge_movingavg = vortex_charge;
1164
1165                                 entity wepent = viewmodels[0]; // TODO: unhardcode
1166
1167                                 // handle the values
1168                                 if (autocvar_crosshair_ring && wepent.activeweapon == WEP_VORTEX && vortex_charge && autocvar_crosshair_ring_vortex) // ring around crosshair representing velocity-dependent damage for the vortex
1169                                 {
1170                                         if (vortex_chargepool || use_vortex_chargepool) {
1171                                                 use_vortex_chargepool = 1;
1172                                                 ring_inner_value = vortex_chargepool;
1173                                         } else {
1174                                                 vortex_charge_movingavg = (1 - autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate) * vortex_charge_movingavg + autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate * vortex_charge;
1175                                                 ring_inner_value = bound(0, autocvar_crosshair_ring_vortex_currentcharge_scale * (vortex_charge - vortex_charge_movingavg), 1);
1176                                         }
1177
1178                                         ring_inner_alpha = autocvar_crosshair_ring_vortex_inner_alpha;
1179                                         ring_inner_rgb = eX * autocvar_crosshair_ring_vortex_inner_color_red + eY * autocvar_crosshair_ring_vortex_inner_color_green + eZ * autocvar_crosshair_ring_vortex_inner_color_blue;
1180                                         ring_inner_image = "gfx/crosshair_ring_inner.tga";
1181
1182                                         // draw the outer ring to show the current charge of the weapon
1183                                         ring_value = vortex_charge;
1184                                         ring_alpha = autocvar_crosshair_ring_vortex_alpha;
1185                                         ring_rgb = wcross_color;
1186                                         ring_image = "gfx/crosshair_ring_nexgun.tga";
1187                                 }
1188                                 else if (autocvar_crosshair_ring && wepent.activeweapon == WEP_MINE_LAYER && WEP_CVAR(minelayer, limit) && autocvar_crosshair_ring_minelayer)
1189                                 {
1190                                         ring_value = bound(0, STAT(LAYED_MINES) / WEP_CVAR(minelayer, limit), 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
1191                                         ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
1192                                         ring_rgb = wcross_color;
1193                                         ring_image = "gfx/crosshair_ring.tga";
1194                                 }
1195                                 else if (wepent.activeweapon == WEP_HAGAR && STAT(HAGAR_LOAD) && autocvar_crosshair_ring_hagar)
1196                                 {
1197                                         ring_value = bound(0, STAT(HAGAR_LOAD) / WEP_CVAR_SEC(hagar, load_max), 1);
1198                                         ring_alpha = autocvar_crosshair_ring_hagar_alpha;
1199                                         ring_rgb = wcross_color;
1200                                         ring_image = "gfx/crosshair_ring.tga";
1201                                 }
1202                                 else if (ok_ammo_charge)
1203                                 {
1204                                         ring_value = ok_ammo_chargepool;
1205                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
1206                                         ring_rgb = wcross_color;
1207                                         ring_image = "gfx/crosshair_ring.tga";
1208                                 }
1209                                 else if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
1210                                 {
1211                                         ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
1212                                         ring_scale = autocvar_crosshair_ring_reload_size;
1213                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
1214                                         ring_rgb = wcross_color;
1215
1216                                         // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
1217                                         // if a new image for another weapon is added, add the code (and its respective file/value) here
1218                                         if ((wepent.activeweapon == WEP_RIFLE) && (weapon_clipsize == 80))
1219                                                 ring_image = "gfx/crosshair_ring_rifle.tga";
1220                                         else
1221                                                 ring_image = "gfx/crosshair_ring.tga";
1222                                 }
1223                                 else if ( autocvar_crosshair_ring && autocvar_crosshair_ring_arc && arc_heat && wepent.activeweapon == WEP_ARC )
1224                                 {
1225                                         ring_value = arc_heat;
1226                                         ring_alpha = (1-arc_heat)*autocvar_crosshair_ring_arc_cold_alpha +
1227                                                 arc_heat*autocvar_crosshair_ring_arc_hot_alpha;
1228                                         ring_rgb = (1-arc_heat)*wcross_color + arc_heat*autocvar_crosshair_ring_arc_hot_color;
1229                                         ring_image = "gfx/crosshair_ring.tga";
1230                                 }
1231
1232                                 // if in weapon switch animation, fade ring out/in
1233                                 if(autocvar_crosshair_effect_time > 0)
1234                                 {
1235                                         f = (time - wcross_name_changestarttime) / autocvar_crosshair_effect_time;
1236                                         if (f >= 1)
1237                                         {
1238                                                 wcross_ring_prev = ((ring_image) ? true : false);
1239                                         }
1240
1241                                         if(wcross_ring_prev)
1242                                         {
1243                                                 if(f < 1)
1244                                                         ring_alpha *= fabs(1 - bound(0, f, 1));
1245                                         }
1246                                         else
1247                                         {
1248                                                 if(f < 1)
1249                                                         ring_alpha *= bound(0, f, 1);
1250                                         }
1251                                 }
1252
1253                                 if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
1254                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
1255
1256                                 if (ring_value)
1257                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
1258                         }
1259
1260 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
1261                         MACRO_BEGIN { \
1262                                 if(wcross_blur > 0) \
1263                                 { \
1264                                         for(i = -2; i <= 2; ++i) \
1265                                         for(j = -2; j <= 2; ++j) \
1266                                         M(i,j,sz,wcross_name,wcross_alpha*0.04); \
1267                                 } \
1268                                 else \
1269                                 { \
1270                                         M(0,0,sz,wcross_name,wcross_alpha); \
1271                                 } \
1272                         } MACRO_END
1273
1274 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
1275                         drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size.x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size.y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
1276
1277 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
1278                         CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
1279
1280                         if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
1281                         {
1282                                 f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
1283                                 wcross_size = draw_getimagesize(wcross_name_goal_prev_prev) * wcross_scale;
1284                                 CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
1285                                 f = 1 - f;
1286                         }
1287                         else
1288                         {
1289                                 f = 1;
1290                         }
1291                         wcross_name_alpha_goal_prev = f;
1292
1293                         wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1294                         CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
1295
1296                         if(autocvar_crosshair_dot)
1297                         {
1298                                 vector wcross_color_old;
1299                                 wcross_color_old = wcross_color;
1300
1301                                 if((autocvar_crosshair_dot_color_custom) && (autocvar_crosshair_dot_color != "0"))
1302                                         wcross_color = stov(autocvar_crosshair_dot_color);
1303
1304                                 CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
1305                                 // FIXME why don't we use wcross_alpha here?
1306                                 wcross_color = wcross_color_old;
1307                         }
1308                 }
1309         }
1310         else
1311         {
1312                 wcross_scale_prev = 0;
1313                 wcross_alpha_prev = 0;
1314                 wcross_scale_goal_prev = 0;
1315                 wcross_alpha_goal_prev = 0;
1316                 wcross_changedonetime = 0;
1317                 if(wcross_name_goal_prev)
1318                         strunzone(wcross_name_goal_prev);
1319                 wcross_name_goal_prev = string_null;
1320                 if(wcross_name_goal_prev_prev)
1321                         strunzone(wcross_name_goal_prev_prev);
1322                 wcross_name_goal_prev_prev = string_null;
1323                 wcross_name_changestarttime = 0;
1324                 wcross_name_changedonetime = 0;
1325                 wcross_name_alpha_goal_prev = 0;
1326                 wcross_name_alpha_goal_prev_prev = 0;
1327                 wcross_resolution_goal_prev = 0;
1328                 wcross_resolution_goal_prev_prev = 0;
1329         }
1330 }
1331
1332 void HUD_Draw(entity this)
1333 {
1334         // if we don't know gametype and scores yet avoid drawing the scoreboard
1335         // also in the very first frames, player state may be inconsistent so avoid drawing the hud at all
1336         // e.g. since initial player's health is 0 hud would display the hud_damage effect,
1337         // cl_deathscoreboard would show the scoreboard and so on
1338         if(!gametype)
1339                 return;
1340
1341         if(!intermission)
1342         if (MUTATOR_CALLHOOK(HUD_Draw_overlay))
1343         {
1344                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, M_ARGV(0, vector), autocvar_hud_colorflash_alpha * M_ARGV(1, float), DRAWFLAG_ADDITIVE);
1345         }
1346         else if(STAT(FROZEN))
1347         {
1348                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, ((STAT(REVIVE_PROGRESS)) ? ('0.25 0.90 1' + ('1 0 0' * STAT(REVIVE_PROGRESS)) + ('0 1 1' * STAT(REVIVE_PROGRESS) * -1)) : '0.25 0.90 1'), autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1349         }
1350         if(!intermission)
1351         if(STAT(NADE_TIMER) && autocvar_cl_nade_timer) // give nade top priority, as it's a matter of life and death
1352         {
1353                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(NADE_TIMER), '0.25 0.90 1' + ('1 0 0' * STAT(NADE_TIMER)) - ('0 1 1' * STAT(NADE_TIMER)), autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1354                 drawstring_aspect(eY * 0.64 * vid_conheight, ((autocvar_cl_nade_timer == 2) ? _("Nade timer") : ""), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
1355         }
1356         else if(STAT(CAPTURE_PROGRESS))
1357         {
1358                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(CAPTURE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1359                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Capture progress"), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
1360         }
1361         else if(STAT(REVIVE_PROGRESS))
1362         {
1363                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1364                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Revival progress"), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
1365         }
1366
1367         if(autocvar_r_letterbox == 0)
1368                 if(autocvar_viewsize < 120)
1369                 {
1370                         if(!(gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS))
1371                                 Accuracy_LoadLevels();
1372
1373                         HUD_Main();
1374                         HUD_Scale_Disable();
1375                 }
1376
1377         // crosshair goes VERY LAST
1378         UpdateDamage();
1379         HUD_Crosshair(this);
1380         HitSound();
1381 }
1382
1383 bool ov_enabled;
1384 float oldr_nearclip;
1385 float oldr_farclip_base;
1386 float oldr_farclip_world;
1387 float oldr_novis;
1388 float oldr_useportalculling;
1389 float oldr_useinfinitefarclip;
1390
1391 void cl_notice_run();
1392
1393 float prev_myteam;
1394 int lasthud;
1395 float vh_notice_time;
1396 void WaypointSprite_Load();
1397 void CSQC_UpdateView(entity this, float w, float h)
1398 {
1399     TC(int, w); TC(int, h);
1400         entity e;
1401         float fov;
1402         float f;
1403         vector vf_size, vf_min;
1404         float a;
1405
1406         execute_next_frame();
1407
1408         ++framecount;
1409
1410         stats_get();
1411         hud = STAT(HUD);
1412
1413         if(hud != HUD_NORMAL && lasthud == HUD_NORMAL)
1414                 vh_notice_time = time + autocvar_cl_vehicles_notify_time;
1415
1416         lasthud = hud;
1417
1418         HUD_Scale_Disable();
1419
1420         if(autocvar__hud_showbinds_reload) // menu can set this one
1421         {
1422                 db_close(binddb);
1423                 binddb = db_create();
1424                 cvar_set("_hud_showbinds_reload", "0");
1425         }
1426
1427         if(checkextension("DP_CSQC_MINFPS_QUALITY"))
1428                 view_quality = getproperty(VF_MINFPS_QUALITY);
1429         else
1430                 view_quality = 1;
1431
1432         button_attack2 = PHYS_INPUT_BUTTON_ATCK2(this);
1433         button_zoom = PHYS_INPUT_BUTTON_ZOOM(this);
1434
1435         vf_size = getpropertyvec(VF_SIZE);
1436         vf_min = getpropertyvec(VF_MIN);
1437         vid_width = vf_size.x;
1438         vid_height = vf_size.y;
1439
1440         vector reticle_pos = '0 0 0', reticle_size = '0 0 0';
1441         vector splash_pos = '0 0 0', splash_size = '0 0 0';
1442
1443         WaypointSprite_Load();
1444
1445         CSQCPlayer_SetCamera();
1446
1447         if(player_localentnum <= maxclients) // is it a client?
1448                 current_player = player_localentnum - 1;
1449         else // then player_localentnum is the vehicle I'm driving
1450                 current_player = player_localnum;
1451         myteam = entcs_GetTeam(current_player);
1452
1453         if(myteam != prev_myteam)
1454         {
1455                 myteamcolors = colormapPaletteColor(myteam, 1);
1456                 FOREACH(hud_panels, true, it.update_time = time);
1457                 prev_myteam = myteam;
1458         }
1459
1460         ticrate = STAT(MOVEVARS_TICRATE) * STAT(MOVEVARS_TIMESCALE);
1461
1462         float is_dead = (STAT(HEALTH) <= 0);
1463
1464         // FIXME do we need this hack?
1465         if(isdemo())
1466         {
1467                 // in demos, input_buttons do not work
1468                 button_zoom = (autocvar__togglezoom == "-");
1469         }
1470         else if(button_zoom
1471                 && autocvar_cl_unpress_zoom_on_death
1472                 && (spectatee_status >= 0)
1473                 && (is_dead || intermission))
1474         {
1475                 // no zoom while dead or in intermission please
1476                 localcmd("-zoom\n");
1477                 button_zoom = false;
1478         }
1479
1480         // event chase camera
1481         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
1482         {
1483                 if(STAT(CAMERA_SPECTATOR))
1484                 {
1485                         if(spectatee_status > 0)
1486                         {
1487                                 if(!autocvar_chase_active)
1488                                 {
1489                                         cvar_set("chase_active", "-2");
1490                                         goto skip_eventchase_death;
1491                                 }
1492                         }
1493                         else if(autocvar_chase_active == -2)
1494                                 cvar_set("chase_active", "0");
1495
1496                         if(autocvar_chase_active == -2)
1497                                 goto skip_eventchase_death;
1498                 }
1499                 else if(autocvar_chase_active == -2)
1500                         cvar_set("chase_active", "0");
1501
1502                 float vehicle_chase = (hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0));
1503
1504                 float vehicle_viewdist = 0;
1505                 vector vehicle_viewofs = '0 0 0';
1506
1507                 if(vehicle_chase)
1508                 {
1509                         if(hud != HUD_BUMBLEBEE_GUN)
1510                         {
1511                                 Vehicle info = Vehicles_from(hud);
1512                                 vehicle_viewdist = info.height;
1513                                 vehicle_viewofs = info.view_ofs;
1514                         }
1515                 }
1516
1517                 if(WantEventchase(this))
1518                 {
1519                         vector current_view_origin_override = '0 0 0';
1520                         vector view_offset_override = '0 0 0';
1521                         float chase_distance_override = 0;
1522                         bool custom_eventchase = MUTATOR_CALLHOOK(CustomizeEventchase, this);
1523                         if(custom_eventchase)
1524                         {
1525                                 current_view_origin_override = M_ARGV(0, vector);
1526                                 view_offset_override = M_ARGV(1, vector);
1527                                 chase_distance_override = M_ARGV(0, float);
1528                         }
1529                         eventchase_running = true;
1530
1531                         entity local_player = ((csqcplayer) ? csqcplayer : CSQCModel_server2csqc(player_localentnum - 1));
1532                         if(!local_player)
1533                                 local_player = this; // fall back!
1534
1535                         // make special vector since we can't use view_origin (It is one frame old as of this code, it gets set later with the results this code makes.)
1536                         vector current_view_origin = (csqcplayer ? csqcplayer.origin : pmove_org);
1537                         if (custom_eventchase)
1538                                 current_view_origin = current_view_origin_override;
1539
1540                         // detect maximum viewoffset and use it
1541                         vector view_offset = autocvar_cl_eventchase_viewoffset;
1542                         if(vehicle_chase)
1543                         {
1544                                 if(vehicle_viewofs)
1545                                         view_offset = vehicle_viewofs;
1546                                 else
1547                                         view_offset = autocvar_cl_eventchase_vehicle_viewoffset;
1548                         }
1549                         if (custom_eventchase)
1550                                 view_offset = view_offset_override;
1551
1552                         if(view_offset)
1553                         {
1554                                 WarpZone_TraceLine(current_view_origin, current_view_origin + view_offset + ('0 0 1' * autocvar_cl_eventchase_maxs.z), MOVE_WORLDONLY, this);
1555                                 if(trace_fraction == 1) { current_view_origin += view_offset; }
1556                                 else { current_view_origin.z += max(0, (trace_endpos.z - current_view_origin.z) - autocvar_cl_eventchase_maxs.z); }
1557                         }
1558
1559                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
1560                         // Ideally, there should be another way to enable third person cameras, such as through setproperty()
1561                         // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
1562                         if(!autocvar_chase_active) { cvar_set("chase_active", "-1"); }
1563
1564                         // make the camera smooth back
1565                         float chase_distance = autocvar_cl_eventchase_distance;
1566                         if(vehicle_chase)
1567                         {
1568                                 if(vehicle_viewofs)
1569                                         chase_distance = vehicle_viewdist;
1570                                 else
1571                                         chase_distance = autocvar_cl_eventchase_vehicle_distance;
1572                         }
1573                         if (custom_eventchase)
1574                                 chase_distance = chase_distance_override;
1575
1576                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < chase_distance)
1577                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (chase_distance - eventchase_current_distance) * frametime; // slow down the further we get
1578                         else if(eventchase_current_distance != chase_distance)
1579                                 eventchase_current_distance = chase_distance;
1580
1581                         makevectors(view_angles);
1582
1583                         vector eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1584                         WarpZone_TraceBox(current_view_origin, autocvar_cl_eventchase_mins, autocvar_cl_eventchase_maxs, eventchase_target_origin, MOVE_WORLDONLY, this);
1585
1586                         // If the boxtrace fails, revert back to line tracing.
1587                         if(!local_player.viewloc)
1588                         if(trace_startsolid)
1589                         {
1590                                 eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1591                                 WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, this);
1592                                 setproperty(VF_ORIGIN, (trace_endpos - (v_forward * autocvar_cl_eventchase_mins.z)));
1593                         }
1594                         else { setproperty(VF_ORIGIN, trace_endpos); }
1595
1596                         if(!local_player.viewloc)
1597                                 setproperty(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
1598                 }
1599                 else if(autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
1600                 {
1601                         eventchase_running = false;
1602                         cvar_set("chase_active", "0");
1603                         eventchase_current_distance = 0; // start from 0 next time
1604                 }
1605         }
1606         // workaround for camera stuck between player's legs when using chase_active 1
1607         // because the engine stops updating the chase_active camera when the game ends
1608         else if(intermission)
1609         {
1610                 cvar_settemp("chase_active", "-1");
1611                 eventchase_current_distance = 0;
1612         }
1613
1614         LABEL(skip_eventchase_death);
1615
1616         // do lockview after event chase camera so that it still applies whenever necessary.
1617         if(autocvar_cl_lockview || (!autocvar_hud_cursormode && (autocvar__hud_configure && spectatee_status <= 0 || intermission > 1 || QuickMenu_IsOpened())))
1618         {
1619                 setproperty(VF_ORIGIN, freeze_org);
1620                 setproperty(VF_ANGLES, freeze_ang);
1621         }
1622         else
1623         {
1624                 freeze_org = getpropertyvec(VF_ORIGIN);
1625                 freeze_ang = getpropertyvec(VF_ANGLES);
1626         }
1627
1628         WarpZone_FixView();
1629         //WarpZone_FixPMove();
1630
1631         vector ov_org = '0 0 0';
1632         vector ov_mid = '0 0 0';
1633         vector ov_worldmin = '0 0 0';
1634         vector ov_worldmax = '0 0 0';
1635         if(autocvar_cl_orthoview)
1636         {
1637                 ov_worldmin = mi_picmin;
1638                 ov_worldmax = mi_picmax;
1639
1640                 float ov_width = (ov_worldmax.x - ov_worldmin.x);
1641                 float ov_height = (ov_worldmax.y - ov_worldmin.y);
1642                 float ov_distance = (max(vid_width, vid_height) * max(ov_width, ov_height));
1643
1644                 ov_mid = ((ov_worldmax + ov_worldmin) * 0.5);
1645                 ov_org = vec3(ov_mid.x, ov_mid.y, (ov_mid.z + ov_distance));
1646
1647                 float ov_nearest = vlen(ov_org - vec3(
1648                         bound(ov_worldmin.x, ov_org.x, ov_worldmax.x),
1649                         bound(ov_worldmin.y, ov_org.y, ov_worldmax.y),
1650                         bound(ov_worldmin.z, ov_org.z, ov_worldmax.z)
1651                 ));
1652
1653                 float ov_furthest = 0;
1654                 float dist = 0;
1655
1656                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1657                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1658                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1659                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1660                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1661                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1662                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1663                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1664
1665                 if(!ov_enabled)
1666                 {
1667                         oldr_nearclip = cvar("r_nearclip");
1668                         oldr_farclip_base = cvar("r_farclip_base");
1669                         oldr_farclip_world = cvar("r_farclip_world");
1670                         oldr_novis = cvar("r_novis");
1671                         oldr_useportalculling = cvar("r_useportalculling");
1672                         oldr_useinfinitefarclip = cvar("r_useinfinitefarclip");
1673                 }
1674
1675                 cvar_settemp("r_nearclip", ftos(ov_nearest));
1676                 cvar_settemp("r_farclip_base", ftos(ov_furthest));
1677                 cvar_settemp("r_farclip_world", "0");
1678                 cvar_settemp("r_novis", "1");
1679                 cvar_settemp("r_useportalculling", "0");
1680                 cvar_settemp("r_useinfinitefarclip", "0");
1681
1682                 setproperty(VF_ORIGIN, ov_org);
1683                 setproperty(VF_ANGLES, '90 0 0');
1684
1685                 ov_enabled = true;
1686
1687                 #if 0
1688                 LOG_INFOF("OrthoView: org = %s, angles = %s, distance = %f, nearest = %f, furthest = %f\n",
1689                         vtos(ov_org),
1690                         vtos(getpropertyvec(VF_ANGLES)),
1691                         ov_distance,
1692                         ov_nearest,
1693                         ov_furthest);
1694                 #endif
1695         }
1696         else
1697         {
1698                 if(ov_enabled)
1699                 {
1700                         cvar_set("r_nearclip", ftos(oldr_nearclip));
1701                         cvar_set("r_farclip_base", ftos(oldr_farclip_base));
1702                         cvar_set("r_farclip_world", ftos(oldr_farclip_world));
1703                         cvar_set("r_novis", ftos(oldr_novis));
1704                         cvar_set("r_useportalculling", ftos(oldr_useportalculling));
1705                         cvar_set("r_useinfinitefarclip", ftos(oldr_useinfinitefarclip));
1706                 }
1707                 ov_enabled = false;
1708         }
1709
1710         // run viewmodel_draw before updating view_angles to the angles calculated by WarpZone_FixView
1711         // viewmodel_draw needs to use the view_angles set by the engine on every CSQC_UpdateView call
1712         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1713                 viewmodel_draw(viewmodels[slot]);
1714
1715         // Render the Scene
1716         view_origin = getpropertyvec(VF_ORIGIN);
1717         view_angles = getpropertyvec(VF_ANGLES);
1718         makevectors(view_angles);
1719         view_forward = v_forward;
1720         view_right = v_right;
1721         view_up = v_up;
1722
1723 #ifdef BLURTEST
1724         if(time > blurtest_time0 && time < blurtest_time1)
1725         {
1726                 float r, t;
1727
1728                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
1729                 r = t * blurtest_radius;
1730                 f = 1 / pow(t, blurtest_power) - 1;
1731
1732                 cvar_set("r_glsl_postprocess", "1");
1733                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
1734         }
1735         else
1736         {
1737                 cvar_set("r_glsl_postprocess", "0");
1738                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
1739         }
1740 #endif
1741
1742         TargetMusic_Advance();
1743         Fog_Force();
1744
1745         if(drawtime == 0)
1746                 drawframetime = 0.01666667; // when we don't know fps yet, we assume 60fps
1747         else
1748                 drawframetime = bound(0.000001, time - drawtime, 1);
1749         drawtime = time;
1750
1751         // watch for gametype changes here...
1752         // in ParseStuffCMD the cmd isn't executed yet :/
1753         // might even be better to add the gametype to TE_CSQC_INIT...?
1754         if(!postinit)
1755                 PostInit();
1756
1757         if(intermission && !gameover_time)
1758                 gameover_time = time;
1759
1760         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
1761         {
1762                 if(calledhooks & HOOK_START)
1763                 {
1764                         localcmd("\ncl_hook_gameend\n");
1765                         calledhooks |= HOOK_END;
1766                 }
1767         }
1768
1769         Announcer();
1770
1771         fov = autocvar_fov;
1772         if(fov <= 59.5)
1773         {
1774                 if(!zoomscript_caught)
1775                 {
1776                         localcmd("+button9\n");
1777                         zoomscript_caught = 1;
1778                 }
1779         }
1780         else
1781         {
1782                 if(zoomscript_caught)
1783                 {
1784                         localcmd("-button9\n");
1785                         zoomscript_caught = 0;
1786                 }
1787         }
1788
1789         ColorTranslateMode = autocvar_cl_stripcolorcodes;
1790
1791         entity wepent = viewmodels[0]; // TODO: unhardcode
1792
1793         if(last_switchweapon != wepent.switchweapon)
1794         {
1795                 weapontime = time;
1796                 last_switchweapon = wepent.switchweapon;
1797                 if(button_zoom && autocvar_cl_unpress_zoom_on_weapon_switch)
1798                 {
1799                         localcmd("-zoom\n");
1800                         button_zoom = false;
1801                 }
1802                 if(autocvar_cl_unpress_attack_on_weapon_switch)
1803                 {
1804                         localcmd("-fire\n");
1805                         localcmd("-fire2\n");
1806                         button_attack2 = false;
1807                 }
1808         }
1809         if(last_activeweapon != wepent.activeweapon)
1810         {
1811                 last_activeweapon = wepent.activeweapon;
1812
1813                 e = wepent.activeweapon;
1814                 if(e.netname != "")
1815                         localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
1816                 else
1817                         localcmd("\ncl_hook_activeweapon none\n");
1818         }
1819
1820         // ALWAYS Clear Current Scene First
1821         clearscene();
1822
1823         setproperty(VF_ORIGIN, view_origin);
1824         setproperty(VF_ANGLES, view_angles);
1825
1826         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
1827         setproperty(VF_SIZE, vf_size);
1828         setproperty(VF_MIN, vf_min);
1829
1830         // Assign Standard Viewflags
1831         // Draw the World (and sky)
1832         setproperty(VF_DRAWWORLD, 1);
1833
1834         // Set the console size vars
1835         vid_conwidth = autocvar_vid_conwidth;
1836         vid_conheight = autocvar_vid_conheight;
1837         vid_pixelheight = autocvar_vid_pixelheight;
1838
1839         if(autocvar_cl_orthoview) { setproperty(VF_FOV, GetOrthoviewFOV(ov_worldmin, ov_worldmax, ov_mid, ov_org)); }
1840         else if(csqcplayer.viewloc) { setproperty(VF_FOV, GetViewLocationFOV(110)); } // enforce 110 fov, so things dont look odd
1841         else { setproperty(VF_FOV, GetCurrentFov(fov)); }
1842
1843         if(camera_active) // Camera for demo playback
1844         {
1845                 if(autocvar_camera_enable)
1846                         CSQC_Demo_Camera();
1847                 else
1848                 {
1849                         cvar_set("chase_active", ftos(chase_active_backup));
1850                         cvar_set("cl_demo_mousegrab", "0");
1851                         camera_active = false;
1852                 }
1853         }
1854         else
1855         {
1856 #ifdef CAMERATEST
1857                 if(autocvar_camera_enable)
1858 #else
1859                 if(autocvar_camera_enable && isdemo())
1860 #endif
1861                 {
1862                         // Enable required Darkplaces cvars
1863                         chase_active_backup = autocvar_chase_active;
1864                         cvar_set("chase_active", "2");
1865                         cvar_set("cl_demo_mousegrab", "1");
1866                         camera_active = true;
1867                         camera_mode = false;
1868                 }
1869         }
1870
1871         // Draw the Crosshair
1872         setproperty(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
1873
1874         // Draw the Engine Status Bar (the default Quake HUD)
1875         setproperty(VF_DRAWENGINESBAR, 0);
1876
1877         // Update the mouse position
1878         /*
1879            mousepos_x = vid_conwidth;
1880            mousepos_y = vid_conheight;
1881            mousepos = mousepos*0.5 + getmousepos();
1882          */
1883
1884         IL_EACH(g_drawables, it.draw, it.draw(it));
1885
1886         addentities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
1887         renderscene();
1888
1889         // now switch to 2D drawing mode by calling a 2D drawing function
1890         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
1891         // next R_RenderScene call
1892         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
1893
1894         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
1895         if (!(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT))
1896         {
1897                 // apply night vision effect
1898                 vector tc_00, tc_01, tc_10, tc_11;
1899                 vector rgb = '0 0 0';
1900
1901                 if(!nightvision_noise)
1902                 {
1903                         nightvision_noise = new(nightvision_noise);
1904                 }
1905                 if(!nightvision_noise2)
1906                 {
1907                         nightvision_noise2 = new(nightvision_noise2);
1908                 }
1909
1910                 // color tint in yellow
1911                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
1912
1913                 // draw BG
1914                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
1915                 rgb = '1 1 1';
1916                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
1917                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
1918                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
1919                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
1920                 tc_11 = tc_01 + tc_10 - tc_00;
1921                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
1922                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
1923                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
1924                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
1925                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
1926                 R_EndPolygon();
1927
1928                 // draw FG
1929                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
1930                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
1931                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
1932                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
1933                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
1934                 tc_11 = tc_01 + tc_10 - tc_00;
1935                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
1936                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
1937                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
1938                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
1939                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
1940                 R_EndPolygon();
1941         }
1942
1943         if(autocvar_cl_reticle)
1944         {
1945                 Weapon wep = wepent.activeweapon;
1946                 // Draw the aiming reticle for weapons that use it
1947                 // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
1948                 // It must be a persisted float for fading out to work properly (you let go of the zoom button for
1949                 // the view to go back to normal, so reticle_type would become 0 as we fade out)
1950                 if(spectatee_status || is_dead || hud != HUD_NORMAL)
1951                 {
1952                         // no zoom reticle while dead
1953                         reticle_type = 0;
1954                 }
1955                 else if(wep.wr_zoomreticle(wep) && autocvar_cl_reticle_weapon)
1956                 {
1957                         if(reticle_image != "") { reticle_type = 2; }
1958                         else { reticle_type = 0; }
1959                 }
1960                 else if(button_zoom || zoomscript_caught)
1961                 {
1962                         // normal zoom
1963                         reticle_type = 1;
1964                 }
1965
1966                 if(reticle_type)
1967                 {
1968                         if(autocvar_cl_reticle_stretch)
1969                         {
1970                                 reticle_size.x = vid_conwidth;
1971                                 reticle_size.y = vid_conheight;
1972                                 reticle_pos.x = 0;
1973                                 reticle_pos.y = 0;
1974                         }
1975                         else
1976                         {
1977                                 reticle_size.x = max(vid_conwidth, vid_conheight);
1978                                 reticle_size.y = max(vid_conwidth, vid_conheight);
1979                                 reticle_pos.x = (vid_conwidth - reticle_size.x) / 2;
1980                                 reticle_pos.y = (vid_conheight - reticle_size.y) / 2;
1981                         }
1982
1983                         if(zoomscript_caught)
1984                                 f = 1;
1985                         else
1986                                 f = current_zoomfraction;
1987
1988                         if(f)
1989                         {
1990                                 switch(reticle_type)
1991                                 {
1992                                         case 1: drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_normal_alpha, DRAWFLAG_NORMAL); break;
1993                                         case 2: drawpic(reticle_pos, reticle_image, reticle_size, '1 1 1', f * autocvar_cl_reticle_weapon_alpha, DRAWFLAG_NORMAL); break;
1994                                 }
1995                         }
1996                 }
1997         }
1998         else
1999         {
2000                 if(reticle_type != 0) { reticle_type = 0; }
2001         }
2002
2003
2004         // improved polyblend
2005         if(autocvar_hud_contents)
2006         {
2007                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
2008                 vector liquidcolor;
2009
2010                 switch(pointcontents(view_origin))
2011                 {
2012                         case CONTENT_WATER:
2013                                 liquidalpha = autocvar_hud_contents_water_alpha;
2014                                 liquidcolor = stov(autocvar_hud_contents_water_color);
2015                                 incontent = 1;
2016                                 break;
2017
2018                         case CONTENT_LAVA:
2019                                 liquidalpha = autocvar_hud_contents_lava_alpha;
2020                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
2021                                 incontent = 1;
2022                                 break;
2023
2024                         case CONTENT_SLIME:
2025                                 liquidalpha = autocvar_hud_contents_slime_alpha;
2026                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
2027                                 incontent = 1;
2028                                 break;
2029
2030                         default:
2031                                 liquidalpha = 0;
2032                                 liquidcolor = '0 0 0';
2033                                 incontent = 0;
2034                                 break;
2035                 }
2036
2037                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
2038                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
2039                         contentfadetime = autocvar_hud_contents_fadeintime;
2040                         liquidalpha_prev = liquidalpha;
2041                         liquidcolor_prev = liquidcolor;
2042                 }
2043                 else
2044                         contentfadetime = autocvar_hud_contents_fadeouttime;
2045
2046                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
2047                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
2048
2049                 if(contentavgalpha)
2050                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
2051
2052                 if(autocvar_hud_postprocessing)
2053                 {
2054                         if(autocvar_hud_contents_blur && contentavgalpha)
2055                         {
2056                                 content_blurpostprocess.x = 1;
2057                                 content_blurpostprocess.y = contentavgalpha * autocvar_hud_contents_blur;
2058                                 content_blurpostprocess.z = contentavgalpha * autocvar_hud_contents_blur_alpha;
2059                         }
2060                         else
2061                         {
2062                                 content_blurpostprocess.x = 0;
2063                                 content_blurpostprocess.y = 0;
2064                                 content_blurpostprocess.z = 0;
2065                         }
2066                 }
2067         }
2068
2069         if(autocvar_hud_damage && !STAT(FROZEN))
2070         {
2071                 splash_size.x = max(vid_conwidth, vid_conheight);
2072                 splash_size.y = max(vid_conwidth, vid_conheight);
2073                 splash_pos.x = (vid_conwidth - splash_size.x) / 2;
2074                 splash_pos.y = (vid_conheight - splash_size.y) / 2;
2075
2076                 float myhealth_flash_temp;
2077                 myhealth = STAT(HEALTH);
2078
2079                 // fade out
2080                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
2081                 // add new damage
2082                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
2083
2084                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
2085                 pain_threshold = autocvar_hud_damage_pain_threshold;
2086                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
2087                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
2088
2089                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
2090                 {
2091                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
2092                 }
2093
2094                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
2095
2096                 if(myhealth_prev < 1)
2097                 {
2098                         if(myhealth >= 1)
2099                         {
2100                                 myhealth_flash = 0; // just spawned, clear the flash immediately
2101                                 myhealth_flash_temp = 0;
2102                         }
2103                         else
2104                         {
2105                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
2106                         }
2107                 }
2108
2109                 if(spectatee_status == -1 || intermission)
2110                 {
2111                         myhealth_flash = 0; // observing, or match ended
2112                         myhealth_flash_temp = 0;
2113                 }
2114
2115                 myhealth_prev = myhealth;
2116
2117                 // IDEA: change damage color/picture based on player model for robot/alien species?
2118                 // pro: matches model better
2119                 // contra: it's not red because blood is red, but because red is an alarming color, so red should stay
2120                 // maybe different reddish pics?
2121                 if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
2122                 {
2123                         if(autocvar_cl_gentle_damage == 2)
2124                         {
2125                                 if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
2126                                         myhealth_gentlergb = eX * random() + eY * random() + eZ * random();
2127                         }
2128                         else
2129                                 myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
2130
2131                         if(myhealth_flash_temp > 0)
2132                                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
2133                 }
2134                 else if(myhealth_flash_temp > 0)
2135                         drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
2136
2137                 if(autocvar_hud_postprocessing) // we still need to set this anyway even when chase_active is set, this way it doesn't get stuck on.
2138                 {
2139                         if(autocvar_hud_damage_blur && myhealth_flash_temp)
2140                         {
2141                                 damage_blurpostprocess.x = 1;
2142                                 damage_blurpostprocess.y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
2143                                 damage_blurpostprocess.z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
2144                         }
2145                         else
2146                         {
2147                                 damage_blurpostprocess.x = 0;
2148                                 damage_blurpostprocess.y = 0;
2149                                 damage_blurpostprocess.z = 0;
2150                         }
2151                 }
2152         }
2153
2154         float e1 = (autocvar_hud_postprocessing_maxbluralpha != 0);
2155         float e2 = (autocvar_hud_powerup != 0);
2156         if(autocvar_hud_postprocessing && (e1 || e2)) // TODO: Remove this code and re-do the postprocess handling in the engine, where it properly belongs.
2157         {
2158                 // enable or disable rendering types if they are used or not
2159                 if(cvar("r_glsl_postprocess_uservec1_enable") != e1) { cvar_set("r_glsl_postprocess_uservec1_enable", ftos(e1)); }
2160                 if(cvar("r_glsl_postprocess_uservec2_enable") != e2) { cvar_set("r_glsl_postprocess_uservec2_enable", ftos(e2)); }
2161
2162                 // blur postprocess handling done first (used by hud_damage and hud_contents)
2163                 if((damage_blurpostprocess.x || content_blurpostprocess.x))
2164                 {
2165                         float blurradius = bound(0, damage_blurpostprocess.y + content_blurpostprocess.y, autocvar_hud_postprocessing_maxblurradius);
2166                         float bluralpha = bound(0, damage_blurpostprocess.z + content_blurpostprocess.z, autocvar_hud_postprocessing_maxbluralpha);
2167                         if(blurradius != old_blurradius || bluralpha != old_bluralpha) // reduce cvar_set spam as much as possible
2168                         {
2169                                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
2170                                 old_blurradius = blurradius;
2171                                 old_bluralpha = bluralpha;
2172                         }
2173                 }
2174                 else if(cvar_string("r_glsl_postprocess_uservec1") != "0 0 0 0") // reduce cvar_set spam as much as possible
2175                 {
2176                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
2177                         old_blurradius = 0;
2178                         old_bluralpha = 0;
2179                 }
2180
2181                 // edge detection postprocess handling done second (used by hud_powerup)
2182                 float sharpen_intensity = 0, strength_finished = STAT(STRENGTH_FINISHED), invincible_finished = STAT(INVINCIBLE_FINISHED);
2183                 if (strength_finished - time > 0) { sharpen_intensity += (strength_finished - time); }
2184                 if (invincible_finished - time > 0) { sharpen_intensity += (invincible_finished - time); }
2185
2186                 sharpen_intensity = bound(0, ((STAT(HEALTH) > 0) ? sharpen_intensity : 0), 5); // Check to see if player is alive (if not, set 0) - also bound to fade out starting at 5 seconds.
2187
2188                 if(autocvar_hud_powerup && sharpen_intensity > 0)
2189                 {
2190                         if(sharpen_intensity != old_sharpen_intensity) // reduce cvar_set spam as much as possible
2191                         {
2192                                 cvar_set("r_glsl_postprocess_uservec2", strcat(ftos((sharpen_intensity / 5) * autocvar_hud_powerup), " ", ftos(-sharpen_intensity * autocvar_hud_powerup), " 0 0"));
2193                                 old_sharpen_intensity = sharpen_intensity;
2194                         }
2195                 }
2196                 else if(cvar_string("r_glsl_postprocess_uservec2") != "0 0 0 0") // reduce cvar_set spam as much as possible
2197                 {
2198                         cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
2199                         old_sharpen_intensity = 0;
2200                 }
2201
2202                 if(cvar("r_glsl_postprocess") == 0)
2203                         cvar_set("r_glsl_postprocess", "2");
2204         }
2205         else if(cvar("r_glsl_postprocess") == 2)
2206                 cvar_set("r_glsl_postprocess", "0");
2207
2208         /*if(gametype == MAPINFO_TYPE_CTF)
2209           {
2210           ctf_view();
2211           } else */
2212
2213         // draw 2D entities
2214         IL_EACH(g_drawables_2d, it.draw2d, it.draw2d(it));
2215         Draw_ShowNames_All();
2216         Debug_Draw();
2217
2218         scoreboard_active = Scoreboard_WouldDraw();
2219
2220         HUD_Draw(this); // this parameter for deep vehicle function
2221
2222         if(NextFrameCommand)
2223         {
2224                 localcmd("\n", NextFrameCommand, "\n");
2225                 NextFrameCommand = string_null;
2226         }
2227
2228         // we must do this check AFTER a frame was rendered, or it won't work
2229         if(cs_project_is_b0rked == 0)
2230         {
2231                 string w0, h0;
2232                 w0 = ftos(autocvar_vid_conwidth);
2233                 h0 = ftos(autocvar_vid_conheight);
2234                 //setproperty(VF_VIEWPORT, '0 0 0', '640 480 0');
2235                 //setproperty(VF_FOV, '90 90 0');
2236                 setproperty(VF_ORIGIN, '0 0 0');
2237                 setproperty(VF_ANGLES, '0 0 0');
2238                 setproperty(VF_PERSPECTIVE, 1);
2239                 makevectors('0 0 0');
2240                 vector v1, v2;
2241                 cvar_set("vid_conwidth", "800");
2242                 cvar_set("vid_conheight", "600");
2243                 v1 = cs_project(v_forward);
2244                 cvar_set("vid_conwidth", "640");
2245                 cvar_set("vid_conheight", "480");
2246                 v2 = cs_project(v_forward);
2247                 if(v1 == v2)
2248                         cs_project_is_b0rked = 1;
2249                 else
2250                         cs_project_is_b0rked = -1;
2251                 cvar_set("vid_conwidth", w0);
2252                 cvar_set("vid_conheight", h0);
2253         }
2254
2255         if(autocvar__hud_configure)
2256                 HUD_Panel_Mouse();
2257         else if (HUD_MinigameMenu_IsOpened() || active_minigame)
2258                 HUD_Minigame_Mouse();
2259         else if(QuickMenu_IsOpened())
2260                 QuickMenu_Mouse();
2261         else
2262                 HUD_Radar_Mouse();
2263
2264         cl_notice_run();
2265         unpause_update();
2266         Net_Flush();
2267
2268         // let's reset the view back to normal for the end
2269         setproperty(VF_MIN, '0 0 0');
2270         setproperty(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
2271
2272         IL_ENDFRAME();
2273 }
2274
2275
2276 // following vectors must be global to allow seamless switching between camera modes
2277 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
2278 void CSQC_Demo_Camera()
2279 {
2280         float speed, attenuation, dimensions;
2281         vector tmp, delta;
2282
2283         if( autocvar_camera_reset || !camera_mode )
2284         {
2285                 camera_offset = '0 0 0';
2286                 current_angles = '0 0 0';
2287                 camera_direction = '0 0 0';
2288                 camera_offset.z += 30;
2289                 camera_offset.x += 30 * -cos(current_angles.y * DEG2RAD);
2290                 camera_offset.y += 30 * -sin(current_angles.y * DEG2RAD);
2291                 current_origin = view_origin;
2292                 current_camera_offset  = camera_offset;
2293                 cvar_set("camera_reset", "0");
2294                 camera_mode = CAMERA_CHASE;
2295         }
2296
2297         // Camera angles
2298         if( camera_roll )
2299                 mouse_angles.z += camera_roll * autocvar_camera_speed_roll;
2300
2301         if(autocvar_camera_look_player)
2302         {
2303                 vector dir;
2304                 float n;
2305
2306                 dir = normalize(view_origin - current_position);
2307                 n = mouse_angles.z;
2308                 mouse_angles = vectoangles(dir);
2309                 mouse_angles.x = mouse_angles.x * -1;
2310                 mouse_angles.z = n;
2311         }
2312         else
2313         {
2314                 tmp = getmousepos() * 0.1;
2315                 if(vdist(tmp, >, autocvar_camera_mouse_threshold))
2316                 {
2317                         mouse_angles.x += tmp.y * cos(mouse_angles.z * DEG2RAD) + (tmp.x * sin(mouse_angles.z * DEG2RAD));
2318                         mouse_angles.y -= tmp.x * cos(mouse_angles.z * DEG2RAD) + (tmp.y * -sin(mouse_angles.z * DEG2RAD));
2319                 }
2320         }
2321
2322         while (mouse_angles.x < -180) mouse_angles.x = mouse_angles.x + 360;
2323         while (mouse_angles.x > 180) mouse_angles.x = mouse_angles.x - 360;
2324         while (mouse_angles.y < -180) mouse_angles.y = mouse_angles.y + 360;
2325         while (mouse_angles.y > 180) mouse_angles.y = mouse_angles.y - 360;
2326
2327         // Fix difference when angles don't have the same sign
2328         delta = '0 0 0';
2329         if(mouse_angles.y < -60 && current_angles.y > 60)
2330                 delta = '0 360 0';
2331         if(mouse_angles.y > 60 && current_angles.y < -60)
2332                 delta = '0 -360 0';
2333
2334         if(autocvar_camera_look_player)
2335                 attenuation = autocvar_camera_look_attenuation;
2336         else
2337                 attenuation = autocvar_camera_speed_attenuation;
2338
2339         attenuation = 1 / max(1, attenuation);
2340         current_angles += (mouse_angles - current_angles + delta) * attenuation;
2341
2342         while (current_angles.x < -180) current_angles.x = current_angles.x + 360;
2343         while (current_angles.x > 180) current_angles.x = current_angles.x - 360;
2344         while (current_angles.y < -180) current_angles.y = current_angles.y + 360;
2345         while (current_angles.y > 180) current_angles.y = current_angles.y - 360;
2346
2347         // Camera position
2348         tmp = '0 0 0';
2349         dimensions = 0;
2350
2351         if( camera_direction.x )
2352         {
2353                 tmp.x = camera_direction.x * cos(current_angles.y * DEG2RAD);
2354                 tmp.y = camera_direction.x * sin(current_angles.y * DEG2RAD);
2355                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
2356                         tmp.z = camera_direction.x * -sin(current_angles.x * DEG2RAD);
2357                 ++dimensions;
2358         }
2359
2360         if( camera_direction.y )
2361         {
2362                 tmp.x += camera_direction.y * -sin(current_angles.y * DEG2RAD);
2363                 tmp.y += camera_direction.y * cos(current_angles.y * DEG2RAD) * cos(current_angles.z * DEG2RAD);
2364                 tmp.z += camera_direction.y * sin(current_angles.z * DEG2RAD);
2365                 ++dimensions;
2366         }
2367
2368         if( camera_direction.z )
2369         {
2370                 tmp.z += camera_direction.z * cos(current_angles.z * DEG2RAD);
2371                 ++dimensions;
2372         }
2373
2374         if(autocvar_camera_free)
2375                 speed = autocvar_camera_speed_free;
2376         else
2377                 speed = autocvar_camera_speed_chase;
2378
2379         if(dimensions)
2380         {
2381                 speed = speed * sqrt(1 / dimensions);
2382                 camera_offset += tmp * speed;
2383         }
2384
2385         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
2386
2387         // Camera modes
2388         if( autocvar_camera_free )
2389         {
2390                 if ( camera_mode == CAMERA_CHASE )
2391                 {
2392                         current_camera_offset = current_origin + current_camera_offset;
2393                         camera_offset = current_origin + camera_offset;
2394                 }
2395
2396                 camera_mode = CAMERA_FREE;
2397                 current_position = current_camera_offset;
2398         }
2399         else
2400         {
2401                 if ( camera_mode == CAMERA_FREE )
2402                 {
2403                         current_origin = view_origin;
2404                         camera_offset = camera_offset - current_origin;
2405                         current_camera_offset = current_camera_offset - current_origin;
2406                 }
2407
2408                 camera_mode = CAMERA_CHASE;
2409
2410                 if(autocvar_camera_chase_smoothly)
2411                         current_origin += (view_origin - current_origin) * attenuation;
2412                 else
2413                         current_origin = view_origin;
2414
2415                 current_position = current_origin + current_camera_offset;
2416         }
2417
2418         setproperty(VF_ANGLES, current_angles);
2419         setproperty(VF_ORIGIN, current_position);
2420 }