qcsrc/client/view.qc

   1
   2 #include "announcer.qh"
   3 #include "hook.qh"
   4 #include "hud/all.qh"
   5 #include "mapvoting.qh"
   6 #include "scoreboard.qh"
   7 #include "shownames.qh"
   8 #include "quickmenu.qh"
   9
  10 #include "mutators/events.qh"
  11
  12 #include "../common/anim.qh"
  13 #include "../common/constants.qh"
  14 #include "../common/debug.qh"
  15 #include "../common/mapinfo.qh"
  16 #include "../common/gamemodes/all.qh"
  17 #include "../common/physics.qh"
  18 #include "../common/stats.qh"
  19 #include "../common/triggers/target/music.qh"
  20 #include "../common/teams.qh"
  21
  22 #include "../common/vehicles/all.qh"
  23 #include "../common/weapons/all.qh"
  24 #include "../common/viewloc.qh"
  25 #include "../common/minigames/cl_minigames.qh"
  26 #include "../common/minigames/cl_minigames_hud.qh"
  27
  28 #include "../lib/csqcmodel/cl_player.qh"
  29
  30 #include "../lib/warpzone/client.qh"
  31 #include "../lib/warpzone/common.qh"
  32
  33 #define EFMASK_CHEAP (EF_ADDITIVE | EF_DOUBLESIDED | EF_FULLBRIGHT | EF_NODEPTHTEST | EF_NODRAW | EF_NOSHADOW | EF_SELECTABLE | EF_TELEPORT_BIT)
  34
  35 float autocvar_cl_viewmodel_scale;
  36
  37 bool autocvar_cl_bobmodel;
  38 float autocvar_cl_bobmodel_speed;
  39 float autocvar_cl_bobmodel_side;
  40 float autocvar_cl_bobmodel_up;
  41
  42 float autocvar_cl_followmodel;
  43 float autocvar_cl_followmodel_side_speed;
  44 float autocvar_cl_followmodel_side_highpass;
  45 float autocvar_cl_followmodel_side_highpass1;
  46 float autocvar_cl_followmodel_side_limit;
  47 float autocvar_cl_followmodel_side_lowpass;
  48 float autocvar_cl_followmodel_up_speed;
  49 float autocvar_cl_followmodel_up_highpass;
  50 float autocvar_cl_followmodel_up_highpass1;
  51 float autocvar_cl_followmodel_up_limit;
  52 float autocvar_cl_followmodel_up_lowpass;
  53
  54 float autocvar_cl_leanmodel;
  55 float autocvar_cl_leanmodel_side_speed;
  56 float autocvar_cl_leanmodel_side_highpass;
  57 float autocvar_cl_leanmodel_side_highpass1;
  58 float autocvar_cl_leanmodel_side_lowpass;
  59 float autocvar_cl_leanmodel_side_limit;
  60 float autocvar_cl_leanmodel_up_speed;
  61 float autocvar_cl_leanmodel_up_highpass;
  62 float autocvar_cl_leanmodel_up_highpass1;
  63 float autocvar_cl_leanmodel_up_lowpass;
  64 float autocvar_cl_leanmodel_up_limit;
  65
  66 #define lowpass(value, frac, ref_store, ret) do \
  67 { \
  68         float __frac = bound(0, frac, 1); \
  69         ret = ref_store = ref_store * (1 - __frac) + (value) * __frac; \
  70 } while (0)
  71
  72 #define lowpass_limited(value, frac, limit, ref_store, ret) do \
  73 { \
  74         float __ignore; lowpass(value, frac, ref_store, __ignore); \
  75         ret = ref_store = bound((value) - (limit), ref_store, (value) + (limit)); \
  76 } while (0)
  77
  78 #define highpass(value, frac, ref_store, ret) do \
  79 { \
  80         float __f; lowpass(value, frac, ref_store, __f); \
  81         ret = (value) - __f; \
  82 } while (0)
  83
  84 #define highpass_limited(value, frac, limit, ref_store, ret) do \
  85 { \
  86         float __f; lowpass_limited(value, frac, limit, ref_store, __f); \
  87         ret = (value) - __f; \
  88 } while (0)
  89
  90 #define lowpass3(value, fracx, fracy, fracz, ref_store, ref_out) do \
  91 { \
  92         lowpass(value.x, fracx, ref_store.x, ref_out.x); \
  93         lowpass(value.y, fracy, ref_store.y, ref_out.y); \
  94         lowpass(value.z, fracz, ref_store.z, ref_out.z); \
  95 } while (0)
  96
  97 #define highpass3(value, fracx, fracy, fracz, ref_store, ref_out) do \
  98 { \
  99         highpass(value.x, fracx, ref_store.x, ref_out.x); \
 100         highpass(value.y, fracy, ref_store.y, ref_out.y); \
 101         highpass(value.z, fracz, ref_store.z, ref_out.z); \
 102 } while (0)
 103
 104 #define highpass3_limited(value, fracx, limitx, fracy, limity, fracz, limitz, ref_store, ref_out) do \
 105 { \
 106         highpass_limited(value.x, fracx, limitx, ref_store.x, ref_out.x); \
 107         highpass_limited(value.y, fracy, limity, ref_store.y, ref_out.y); \
 108         highpass_limited(value.z, fracz, limitz, ref_store.z, ref_out.z); \
 109 } while (0)
 110
 111 void viewmodel_animate(entity this)
 112 {
 113         static float prevtime;
 114         float frametime = (time - prevtime) * STAT(MOVEVARS_TIMESCALE);
 115         prevtime = time;
 116
 117         if (autocvar_chase_active) return;
 118         if (getstati(STAT_HEALTH) <= 0) return;
 119
 120         entity view = CSQCModel_server2csqc(player_localentnum - 1);
 121
 122         bool clonground = !(view.anim_implicit_state & ANIMIMPLICITSTATE_INAIR);
 123         static bool oldonground;
 124         static float hitgroundtime;
 125         static float lastongroundtime;
 126         if (clonground)
 127         {
 128                 float f = time; // cl.movecmd[0].time
 129                 if (!oldonground)
 130                         hitgroundtime = f;
 131                 lastongroundtime = f;
 132         }
 133         oldonground = clonground;
 134
 135         vector gunorg = '0 0 0', gunangles = '0 0 0';
 136         static vector gunorg_prev = '0 0 0', gunangles_prev = '0 0 0';
 137
 138         bool teleported = view.csqcmodel_teleported;
 139
 140         // 1. if we teleported, clear the frametime... the lowpass will recover the previous value then
 141         if (teleported)
 142         {
 143                 // try to fix the first highpass; result is NOT
 144                 // perfect! TODO find a better fix
 145                 gunangles_prev = view_angles;
 146                 gunorg_prev = view_origin;
 147         }
 148
 149         static vector gunorg_highpass = '0 0 0';
 150
 151         // 2. for the gun origin, only keep the high frequency (non-DC) parts, which is "somewhat like velocity"
 152         gunorg_highpass += gunorg_prev;
 153         highpass3_limited(view_origin,
 154                 frametime * autocvar_cl_followmodel_side_highpass1, autocvar_cl_followmodel_side_limit,
 155                 frametime * autocvar_cl_followmodel_side_highpass1, autocvar_cl_followmodel_side_limit,
 156                 frametime * autocvar_cl_followmodel_up_highpass1, autocvar_cl_followmodel_up_limit,
 157                 gunorg_highpass, gunorg);
 158         gunorg_prev = view_origin;
 159         gunorg_highpass -= gunorg_prev;
 160
 161         static vector gunangles_highpass = '0 0 0';
 162
 163         // in the highpass, we _store_ the DIFFERENCE to the actual view angles...
 164         gunangles_highpass += gunangles_prev;
 165         PITCH(gunangles_highpass) += 360 * floor((PITCH(view_angles) - PITCH(gunangles_highpass)) / 360 + 0.5);
 166         YAW(gunangles_highpass) += 360 * floor((YAW(view_angles) - YAW(gunangles_highpass)) / 360 + 0.5);
 167         ROLL(gunangles_highpass) += 360 * floor((ROLL(view_angles) - ROLL(gunangles_highpass)) / 360 + 0.5);
 168         highpass3_limited(view_angles,
 169                 frametime * autocvar_cl_leanmodel_up_highpass1, autocvar_cl_leanmodel_up_limit,
 170                 frametime * autocvar_cl_leanmodel_side_highpass1, autocvar_cl_leanmodel_side_limit,
 171                 0, 0,
 172                 gunangles_highpass, gunangles);
 173         gunangles_prev = view_angles;
 174         gunangles_highpass -= gunangles_prev;
 175
 176         // 3. calculate the RAW adjustment vectors
 177         gunorg.x *= (autocvar_cl_followmodel ? -autocvar_cl_followmodel_side_speed : 0);
 178         gunorg.y *= (autocvar_cl_followmodel ? -autocvar_cl_followmodel_side_speed : 0);
 179         gunorg.z *= (autocvar_cl_followmodel ? -autocvar_cl_followmodel_up_speed : 0);
 180
 181         PITCH(gunangles) *= (autocvar_cl_leanmodel ? -autocvar_cl_leanmodel_up_speed : 0);
 182         YAW(gunangles) *= (autocvar_cl_leanmodel ? -autocvar_cl_leanmodel_side_speed : 0);
 183         ROLL(gunangles) = 0;
 184
 185         static vector gunorg_adjustment_highpass;
 186         static vector gunorg_adjustment_lowpass;
 187         static vector gunangles_adjustment_highpass;
 188         static vector gunangles_adjustment_lowpass;
 189
 190         // 4. perform highpass/lowpass on the adjustment vectors (turning velocity into acceleration!)
 191         //    trick: we must do the lowpass LAST, so the lowpass vector IS the final vector!
 192         highpass3(gunorg,
 193                 frametime * autocvar_cl_followmodel_side_highpass,
 194                 frametime * autocvar_cl_followmodel_side_highpass,
 195                 frametime * autocvar_cl_followmodel_up_highpass,
 196                 gunorg_adjustment_highpass, gunorg);
 197         lowpass3(gunorg,
 198                 frametime * autocvar_cl_followmodel_side_lowpass,
 199                 frametime * autocvar_cl_followmodel_side_lowpass,
 200                 frametime * autocvar_cl_followmodel_up_lowpass,
 201                 gunorg_adjustment_lowpass, gunorg);
 202         // we assume here: PITCH = 0, YAW = 1, ROLL = 2
 203         highpass3(gunangles,
 204                 frametime * autocvar_cl_leanmodel_up_highpass,
 205                 frametime * autocvar_cl_leanmodel_side_highpass,
 206                 0,
 207                 gunangles_adjustment_highpass, gunangles);
 208         lowpass3(gunangles,
 209                 frametime * autocvar_cl_leanmodel_up_lowpass,
 210                 frametime * autocvar_cl_leanmodel_side_lowpass,
 211                 0,
 212                 gunangles_adjustment_lowpass, gunangles);
 213         float xyspeed = bound(0, vlen(vec2(view.velocity)), 400);
 214
 215         // vertical view bobbing code
 216         // TODO: cl_bob
 217
 218         // horizontal view bobbing code
 219         // TODO: cl_bob2
 220
 221         // fall bobbing code
 222         // causes the view to swing down and back up when touching the ground
 223         // TODO: cl_bobfall
 224
 225         // gun model bobbing code
 226         if (autocvar_cl_bobmodel)
 227         {
 228                 // calculate for swinging gun model
 229                 // the gun bobs when running on the ground, but doesn't bob when you're in the air.
 230                 // Sajt: I tried to smooth out the transitions between bob and no bob, which works
 231                 // for the most part, but for some reason when you go through a message trigger or
 232                 // pick up an item or anything like that it will momentarily jolt the gun.
 233                 vector forward, right, up;
 234                 float bspeed;
 235                 float t = 1;
 236                 float s = time * autocvar_cl_bobmodel_speed;
 237                 if (clonground)
 238                 {
 239                         if (time - hitgroundtime < 0.2)
 240                         {
 241                                 // just hit the ground, speed the bob back up over the next 0.2 seconds
 242                                 t = time - hitgroundtime;
 243                                 t = bound(0, t, 0.2);
 244                                 t *= 5;
 245                         }
 246                 }
 247                 else
 248                 {
 249                         // recently left the ground, slow the bob down over the next 0.2 seconds
 250                         t = time - lastongroundtime;
 251                         t = 0.2 - bound(0, t, 0.2);
 252                         t *= 5;
 253                 }
 254                 bspeed = xyspeed * 0.01;
 255                 MAKEVECTORS(makevectors, view_angles, forward, right, up);
 256                 float bobr = bspeed * autocvar_cl_bobmodel_side * autocvar_cl_viewmodel_scale * sin(s) * t;
 257                 gunorg += bobr * right;
 258                 float bobu = bspeed * autocvar_cl_bobmodel_up * autocvar_cl_viewmodel_scale * cos(s * 2) * t;
 259                 gunorg += bobu * up;
 260         }
 261         vector v = rotate(gunorg, YAW(view_angles) * DEG2RAD); // rotate world coordinates to relative ones
 262         v.z = gunorg.z;
 263         this.origin += v;
 264         gunangles.x = -gunangles.x; // pitch was inverted, now that actually matters
 265         this.angles += gunangles;
 266 }
 267
 268 .vector viewmodel_origin, viewmodel_angles;
 269 .float weapon_nextthink;
 270 .float weapon_eta_last;
 271 .float weapon_switchdelay;
 272
 273 void viewmodel_draw(entity this)
 274 {
 275         int mask = (intermission || (getstati(STAT_HEALTH) <= 0) || autocvar_chase_active) ? 0 : MASK_NORMAL;
 276         float a = this.alpha;
 277         int c = stof(getplayerkeyvalue(current_player, "colors"));
 278         vector g;
 279         Weapon wep = Weapons_from(activeweapon);
 280         if (!(g = wep.wr_glow(wep))) g = colormapPaletteColor(c & 0x0F, true) * 2;
 281         entity me = CSQCModel_server2csqc(player_localentnum - 1);
 282         int fx = ((me.csqcmodel_effects & EFMASK_CHEAP)
 283                 | EF_NODEPTHTEST)
 284                 &~ (EF_FULLBRIGHT); // can mask team color, so get rid of it
 285         for (entity e = this; e; e = e.weaponchild)
 286         {
 287                 e.drawmask = mask;
 288                 e.alpha = a;
 289                 e.colormap = c;
 290                 e.glowmod = g;
 291                 e.csqcmodel_effects = fx;
 292                 WITH(entity, self, e, CSQCModel_Effects_Apply());
 293         }
 294         {
 295                 static string name_last;
 296                 string name = Weapons_from(activeweapon).mdl;
 297                 if (name != name_last)
 298                 {
 299                         name_last = name;
 300                         CL_WeaponEntity_SetModel(this, name);
 301                         this.viewmodel_origin = this.origin;
 302                         this.viewmodel_angles = this.angles;
 303                 }
 304                 anim_update(this);
 305                 if (!this.animstate_override)
 306                         anim_set(this, this.anim_idle, true, false, false);
 307         }
 308         float f = 0; // 0..1; 0: fully active
 309         float eta = (this.weapon_nextthink - time) / STAT(WEAPONRATEFACTOR);
 310         if (eta <= 0) f = this.weapon_eta_last;
 311         else switch (this.state)
 312         {
 313                 case WS_RAISE:
 314                 {
 315                         f = eta / max(eta, this.weapon_switchdelay);
 316                         break;
 317                 }
 318                 case WS_DROP:
 319                 {
 320                         f = 1 - eta / max(eta, this.weapon_switchdelay);
 321                         break;
 322                 }
 323                 case WS_CLEAR:
 324                 {
 325                         f = 1;
 326                         break;
 327                 }
 328         }
 329         this.weapon_eta_last = f;
 330         this.origin = this.viewmodel_origin;
 331         this.angles = this.viewmodel_angles;
 332         this.angles_x = (-90 * f * f);
 333         viewmodel_animate(this);
 334         setorigin(this, this.origin);
 335 }
 336
 337 entity viewmodel;
 338 STATIC_INIT(viewmodel) {
 339     viewmodel = new(viewmodel);
 340         viewmodel.draw = viewmodel_draw;
 341 }
 342
 343 entity porto;
 344 vector polyline[16];
 345 void Porto_Draw(entity this)
 346 {
 347         vector p, dir, ang, q, nextdir;
 348         float portal_number, portal1_idx;
 349
 350         if(activeweapon != WEP_PORTO.m_id || spectatee_status || gametype == MAPINFO_TYPE_NEXBALL)
 351                 return;
 352         if(g_balance_porto_secondary)
 353                 return;
 354         if(intermission == 1)
 355                 return;
 356         if(intermission == 2)
 357                 return;
 358         if (getstati(STAT_HEALTH) <= 0)
 359                 return;
 360
 361         dir = view_forward;
 362
 363         if(angles_held_status)
 364         {
 365                 makevectors(angles_held);
 366                 dir = v_forward;
 367         }
 368
 369         p = view_origin;
 370
 371         polyline[0] = p;
 372         int idx = 1;
 373         portal_number = 0;
 374         nextdir = dir;
 375
 376         for (;;)
 377         {
 378                 dir = nextdir;
 379                 traceline(p, p + 65536 * dir, true, porto);
 380                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
 381                         return;
 382                 nextdir = dir - 2 * (dir * trace_plane_normal) * trace_plane_normal; // mirror dir at trace_plane_normal
 383                 p = trace_endpos;
 384                 polyline[idx] = p;
 385                 ++idx;
 386                 if(idx >= 16)
 387                         return;
 388                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
 389                         continue;
 390                 ++portal_number;
 391                 ang = vectoangles2(trace_plane_normal, dir);
 392                 ang.x = -ang.x;
 393                 makevectors(ang);
 394                 if(!CheckWireframeBox(porto, p - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
 395                         return;
 396                 if(portal_number == 1)
 397                 {
 398                         portal1_idx = idx;
 399                         if(portal_number >= 2)
 400                                 break;
 401                 }
 402         }
 403
 404         while(idx >= 2)
 405         {
 406                 p = polyline[idx-2];
 407                 q = polyline[idx-1];
 408                 if(idx == 2)
 409                         p = p - view_up * 16;
 410                 if(idx-1 >= portal1_idx)
 411                 {
 412                         Draw_CylindricLine(p, q, 4, "", 1, 0, '0 0 1', 0.5, DRAWFLAG_NORMAL, view_origin);
 413                 }
 414                 else
 415                 {
 416                         Draw_CylindricLine(p, q, 4, "", 1, 0, '1 0 0', 0.5, DRAWFLAG_NORMAL, view_origin);
 417                 }
 418                 --idx;
 419         }
 420 }
 421
 422 void Porto_Init()
 423 {
 424         porto = new(porto);
 425         make_pure(porto);
 426         porto.draw = Porto_Draw;
 427         porto.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 428 }
 429
 430 float drawtime;
 431 float avgspeed;
 432 vector GetCurrentFov(float fov)
 433 {
 434         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir;
 435         float velocityzoom, curspeed;
 436         vector v;
 437
 438         zoomsensitivity = autocvar_cl_zoomsensitivity;
 439         zoomfactor = autocvar_cl_zoomfactor;
 440         if(zoomfactor < 1 || zoomfactor > 30)
 441                 zoomfactor = 2.5;
 442         zoomspeed = autocvar_cl_zoomspeed;
 443         if(zoomspeed >= 0)
 444         if(zoomspeed < 0.5 || zoomspeed > 16)
 445                         zoomspeed = 3.5;
 446
 447         zoomdir = button_zoom;
 448         if(hud == HUD_NORMAL)
 449         if(switchweapon == activeweapon)
 450         if((activeweapon == WEP_VORTEX.m_id && vortex_scope) || (activeweapon == WEP_RIFLE.m_id && rifle_scope)) // do NOT use switchweapon here
 451                 zoomdir += button_attack2;
 452         if(spectatee_status > 0 || isdemo())
 453         {
 454                 if(spectatorbutton_zoom)
 455                 {
 456                         if(zoomdir)
 457                                 zoomdir = 0;
 458                         else
 459                                 zoomdir = 1;
 460                 }
 461                 // fteqcc failed twice here already, don't optimize this
 462         }
 463
 464         if(zoomdir) { zoomin_effect = 0; }
 465
 466         if(camera_active)
 467         {
 468                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 469         }
 470         else if(autocvar_cl_spawnzoom && zoomin_effect)
 471         {
 472                 float spawnzoomfactor = bound(1, autocvar_cl_spawnzoom_factor, 30);
 473
 474                 current_viewzoom += (autocvar_cl_spawnzoom_speed * (spawnzoomfactor - current_viewzoom) * drawframetime);
 475                 current_viewzoom = bound(1 / spawnzoomfactor, current_viewzoom, 1);
 476                 if(current_viewzoom == 1) { zoomin_effect = 0; }
 477         }
 478         else
 479         {
 480                 if(zoomspeed < 0) // instant zoom
 481                 {
 482                         if(zoomdir)
 483                                 current_viewzoom = 1 / zoomfactor;
 484                         else
 485                                 current_viewzoom = 1;
 486                 }
 487                 else
 488                 {
 489                         if(zoomdir)
 490                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 491                         else
 492                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 493                 }
 494         }
 495
 496         if(almost_equals(current_viewzoom, 1))
 497                 current_zoomfraction = 0;
 498         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 499                 current_zoomfraction = 1;
 500         else
 501                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 502
 503         if(zoomsensitivity < 1)
 504                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
 505         else
 506                 setsensitivityscale(1);
 507
 508         if(autocvar_cl_velocityzoom_enabled && autocvar_cl_velocityzoom_type) // _type = 0 disables velocity zoom too
 509         {
 510                 if(intermission) { curspeed = 0; }
 511                 else
 512                 {
 513
 514                         makevectors(view_angles);
 515                         v = pmove_vel;
 516                         if(csqcplayer)
 517                                 v = csqcplayer.velocity;
 518
 519                         switch(autocvar_cl_velocityzoom_type)
 520                         {
 521                                 case 3: curspeed = max(0, v_forward * v); break;
 522                                 case 2: curspeed = (v_forward * v); break;
 523                                 case 1: default: curspeed = vlen(v); break;
 524                         }
 525                 }
 526
 527                 velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoom_time), 1); // speed at which the zoom adapts to player velocity
 528                 avgspeed = avgspeed * (1 - velocityzoom) + (curspeed / autocvar_cl_velocityzoom_speed) * velocityzoom;
 529                 velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom_factor / 1) * 1);
 530
 531                 //print(ftos(avgspeed), " avgspeed, ", ftos(curspeed), " curspeed, ", ftos(velocityzoom), " return\n"); // for debugging
 532         }
 533         else
 534                 velocityzoom = 1;
 535
 536         float frustumx, frustumy, fovx, fovy;
 537         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 538         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 539         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 540         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 541
 542         return '1 0 0' * fovx + '0 1 0' * fovy;
 543 }
 544
 545 vector GetViewLocationFOV(float fov)
 546 {
 547         float frustumy = tan(fov * M_PI / 360.0) * 0.75;
 548         float frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 549         float fovx = atan2(frustumx, 1) / M_PI * 360.0;
 550         float fovy = atan2(frustumy, 1) / M_PI * 360.0;
 551         return '1 0 0' * fovx + '0 1 0' * fovy;
 552 }
 553
 554 vector GetOrthoviewFOV(vector ov_worldmin, vector ov_worldmax, vector ov_mid, vector ov_org)
 555 {
 556         float fovx, fovy;
 557         float width = (ov_worldmax.x - ov_worldmin.x);
 558         float height = (ov_worldmax.y - ov_worldmin.y);
 559         float distance_to_middle_of_world = vlen(ov_mid - ov_org);
 560         fovx = atan2(width/2, distance_to_middle_of_world) / M_PI * 360.0;
 561         fovy = atan2(height/2, distance_to_middle_of_world) / M_PI * 360.0;
 562         return '1 0 0' * fovx + '0 1 0' * fovy;
 563 }
 564
 565 // this function must match W_SetupShot!
 566 float zoomscript_caught;
 567
 568 vector wcross_origin;
 569 float wcross_scale_prev, wcross_alpha_prev;
 570 vector wcross_color_prev;
 571 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 572 vector wcross_color_goal_prev;
 573 float wcross_changedonetime;
 574
 575 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 576 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 577 float wcross_name_changestarttime, wcross_name_changedonetime;
 578 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 579
 580 float wcross_ring_prev;
 581
 582 entity trueaim;
 583 entity trueaim_rifle;
 584
 585 const float SHOTTYPE_HITTEAM = 1;
 586 const float SHOTTYPE_HITOBSTRUCTION = 2;
 587 const float SHOTTYPE_HITWORLD = 3;
 588 const float SHOTTYPE_HITENEMY = 4;
 589
 590 void TrueAim_Init()
 591 {
 592         trueaim = new(trueaim);
 593         make_pure(trueaim);
 594         trueaim.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 595         trueaim_rifle = new(trueaim_rifle);
 596         make_pure(trueaim_rifle);
 597         trueaim_rifle.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 598 }
 599
 600 float EnemyHitCheck()
 601 {
 602         float t, n;
 603         wcross_origin = project_3d_to_2d(trace_endpos);
 604         wcross_origin.z = 0;
 605         if(trace_ent)
 606                 n = trace_ent.entnum;
 607         else
 608                 n = trace_networkentity;
 609         if(n < 1)
 610                 return SHOTTYPE_HITWORLD;
 611         if(n > maxclients)
 612                 return SHOTTYPE_HITWORLD;
 613         t = GetPlayerColor(n - 1);
 614         if(teamplay)
 615                 if(t == myteam)
 616                         return SHOTTYPE_HITTEAM;
 617         if(t == NUM_SPECTATOR)
 618                 return SHOTTYPE_HITWORLD;
 619         return SHOTTYPE_HITENEMY;
 620 }
 621
 622 float TrueAimCheck()
 623 {
 624         float nudge = 1; // added to traceline target and subtracted from result TOOD(divVerent): do we still need this? Doesn't the engine do this now for us?
 625         vector vecs, trueaimpoint, w_shotorg;
 626         vector mi, ma, dv;
 627         float shottype;
 628         entity ta;
 629         float mv;
 630
 631         mi = ma = '0 0 0';
 632         ta = trueaim;
 633         mv = MOVE_NOMONSTERS;
 634
 635         switch(activeweapon) // WEAPONTODO
 636         {
 637                 case WEP_TUBA.m_id: // no aim
 638                 case WEP_PORTO.m_id: // shoots from eye
 639                 case WEP_NEXBALL.m_id: // shoots from eye
 640                 case WEP_HOOK.m_id: // no trueaim
 641                 case WEP_MORTAR.m_id: // toss curve
 642                         return SHOTTYPE_HITWORLD;
 643                 case WEP_VORTEX.m_id:
 644                 case WEP_VAPORIZER.m_id:
 645                         mv = MOVE_NORMAL;
 646                         break;
 647                 case WEP_RIFLE.m_id:
 648                         ta = trueaim_rifle;
 649                         mv = MOVE_NORMAL;
 650                         if(zoomscript_caught)
 651                         {
 652                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 653                                 return EnemyHitCheck();
 654                         }
 655                         break;
 656                 case WEP_DEVASTATOR.m_id: // projectile has a size!
 657                         mi = '-3 -3 -3';
 658                         ma = '3 3 3';
 659                         break;
 660                 case WEP_FIREBALL.m_id: // projectile has a size!
 661                         mi = '-16 -16 -16';
 662                         ma = '16 16 16';
 663                         break;
 664                 case WEP_SEEKER.m_id: // projectile has a size!
 665                         mi = '-2 -2 -2';
 666                         ma = '2 2 2';
 667                         break;
 668                 case WEP_ELECTRO.m_id: // projectile has a size!
 669                         mi = '0 0 -3';
 670                         ma = '0 0 -3';
 671                         break;
 672         }
 673
 674         vector traceorigin = entcs_receiver(player_localentnum - 1).origin + (eZ * getstati(STAT_VIEWHEIGHT));
 675
 676         vecs = decompressShotOrigin(STAT(SHOTORG));
 677
 678         traceline(traceorigin, traceorigin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 679         trueaimpoint = trace_endpos;
 680
 681         if(vlen(trueaimpoint - traceorigin) < g_trueaim_minrange)
 682                 trueaimpoint = traceorigin + view_forward * g_trueaim_minrange;
 683
 684         if(vecs.x > 0)
 685                 vecs.y = -vecs.y;
 686         else
 687                 vecs = '0 0 0';
 688
 689         dv = view_right * vecs.y + view_up * vecs.z;
 690         w_shotorg = traceorigin + dv;
 691
 692         // now move the vecs forward as much as requested if possible
 693         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs.x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 694         w_shotorg = trace_endpos - view_forward * nudge;
 695
 696         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 697         shottype = EnemyHitCheck();
 698         if(shottype != SHOTTYPE_HITWORLD)
 699                 return shottype;
 700
 701 #if 0
 702         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 703         // or rather, I know why, but see no fix
 704         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 705                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 706                 return SHOTTYPE_HITOBSTRUCTION;
 707 #endif
 708
 709         return SHOTTYPE_HITWORLD;
 710 }
 711
 712 void PostInit();
 713 void CSQC_Demo_Camera();
 714 float HUD_WouldDrawScoreboard();
 715 float camera_mode;
 716 const float CAMERA_FREE = 1;
 717 const float CAMERA_CHASE = 2;
 718 float reticle_type;
 719 string reticle_image;
 720 string NextFrameCommand;
 721
 722 vector freeze_org, freeze_ang;
 723 entity nightvision_noise, nightvision_noise2;
 724
 725 const float MAX_TIME_DIFF = 5;
 726 float pickup_crosshair_time, pickup_crosshair_size;
 727 float hitindication_crosshair_size;
 728 float use_vortex_chargepool;
 729
 730 float myhealth, myhealth_prev;
 731 float myhealth_flash;
 732
 733 float old_blurradius, old_bluralpha;
 734 float old_sharpen_intensity;
 735
 736 vector myhealth_gentlergb;
 737
 738 float contentavgalpha, liquidalpha_prev;
 739 vector liquidcolor_prev;
 740
 741 float eventchase_current_distance;
 742 float eventchase_running;
 743 bool WantEventchase()
 744 {SELFPARAM();
 745         if(autocvar_cl_orthoview)
 746                 return false;
 747         if(intermission)
 748                 return true;
 749         if(self.viewloc)
 750                 return true;
 751         if(spectatee_status >= 0)
 752         {
 753                 if(hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0))
 754                         return true;
 755                 if(MUTATOR_CALLHOOK(WantEventchase, self))
 756                         return true;
 757                 if(autocvar_cl_eventchase_nexball && gametype == MAPINFO_TYPE_NEXBALL && !(WepSet_GetFromStat() & WEPSET(NEXBALL)))
 758                         return true;
 759                 if(autocvar_cl_eventchase_death && (getstati(STAT_HEALTH) <= 0))
 760                 {
 761                         if(autocvar_cl_eventchase_death == 2)
 762                         {
 763                                 // don't stop eventchase once it's started (even if velocity changes afterwards)
 764                                 if(self.velocity == '0 0 0' || eventchase_running)
 765                                         return true;
 766                         }
 767                         else return true;
 768                 }
 769         }
 770         return false;
 771 }
 772
 773 void HUD_Crosshair_Vehicle()
 774 {
 775         if(hud != HUD_BUMBLEBEE_GUN)
 776         {
 777                 Vehicle info = get_vehicleinfo(hud);
 778                 info.vr_crosshair(info);
 779         }
 780 }
 781
 782 vector damage_blurpostprocess, content_blurpostprocess;
 783
 784 float unaccounted_damage = 0;
 785 void UpdateDamage()
 786 {
 787         // accumulate damage with each stat update
 788         static float damage_total_prev = 0;
 789         float damage_total = STAT(DAMAGE_DEALT_TOTAL);
 790         float unaccounted_damage_new = COMPARE_INCREASING(damage_total, damage_total_prev);
 791         damage_total_prev = damage_total;
 792
 793         static float damage_dealt_time_prev = 0;
 794         float damage_dealt_time = STAT(HIT_TIME);
 795         if (damage_dealt_time != damage_dealt_time_prev)
 796         {
 797                 unaccounted_damage += unaccounted_damage_new;
 798                 LOG_TRACE("dmg total: ", ftos(unaccounted_damage), " (+", ftos(unaccounted_damage_new), ")", "\n");
 799         }
 800         damage_dealt_time_prev = damage_dealt_time;
 801
 802         // prevent hitsound when switching spectatee
 803         static float spectatee_status_prev = 0;
 804         if (spectatee_status != spectatee_status_prev)
 805                 unaccounted_damage = 0;
 806         spectatee_status_prev = spectatee_status;
 807 }
 808
 809 void HitSound()
 810 {
 811         // varying sound pitch
 812
 813         static float hitsound_time_prev = 0;
 814         // HACK: the only way to get the arc to sound consistent with pitch shift is to ignore cl_hitsound_antispam_time
 815         float arc_hack = activeweapon == WEP_ARC.m_id && autocvar_cl_hitsound >= 2;
 816         if (arc_hack || COMPARE_INCREASING(time, hitsound_time_prev) > autocvar_cl_hitsound_antispam_time)
 817         {
 818                 if (autocvar_cl_hitsound && unaccounted_damage)
 819                 {
 820                         // customizable gradient function that crosses (0,a), (c,1) and asymptotically approaches b
 821                         float a = autocvar_cl_hitsound_max_pitch;
 822                         float b = autocvar_cl_hitsound_min_pitch;
 823                         float c = autocvar_cl_hitsound_nom_damage;
 824                         float x = unaccounted_damage;
 825                         float pitch_shift = (b*x*(a-1) + a*c*(1-b)) / (x*(a-1) + c*(1-b));
 826
 827                         // if sound variation is disabled, set pitch_shift to 1
 828                         if (autocvar_cl_hitsound == 1)
 829                                 pitch_shift = 1;
 830
 831                         // if pitch shift is reversed, mirror in (max-min)/2 + min
 832                         if (autocvar_cl_hitsound == 3)
 833                         {
 834                                 float mirror_value = (a-b)/2 + b;
 835                                 pitch_shift = mirror_value + (mirror_value - pitch_shift);
 836                         }
 837
 838                         LOG_TRACE("dmg total (dmg): ", ftos(unaccounted_damage), " , pitch shift: ", ftos(pitch_shift), "\n");
 839
 840                         // todo: avoid very long and very short sounds from wave stretching using different sound files? seems unnecessary
 841                         // todo: normalize sound pressure levels? seems unnecessary
 842
 843                         sound7(world, CH_INFO, SND(HIT), VOL_BASE, ATTN_NONE, pitch_shift * 100, 0);
 844                 }
 845                 unaccounted_damage = 0;
 846                 hitsound_time_prev = time;
 847         }
 848
 849         static float typehit_time_prev = 0;
 850         float typehit_time = STAT(TYPEHIT_TIME);
 851         if (COMPARE_INCREASING(typehit_time, typehit_time_prev) > autocvar_cl_hitsound_antispam_time)
 852         {
 853                 sound(world, CH_INFO, SND_TYPEHIT, VOL_BASE, ATTN_NONE);
 854                 typehit_time_prev = typehit_time;
 855         }
 856 }
 857
 858 void HUD_Crosshair()
 859 {SELFPARAM();
 860         static float rainbow_last_flicker;
 861         static vector rainbow_prev_color;
 862         entity e = self;
 863         float f, i, j;
 864         vector v;
 865         if(!scoreboard_active && !camera_active && intermission != 2 &&
 866                 spectatee_status != -1 && !csqcplayer.viewloc &&
 867                 !HUD_MinigameMenu_IsOpened() )
 868         {
 869                 if (!autocvar_crosshair_enabled) // main toggle for crosshair rendering
 870                         return;
 871
 872                 if (hud != HUD_NORMAL)
 873                 {
 874                         HUD_Crosshair_Vehicle();
 875                         return;
 876                 }
 877
 878                 string wcross_style;
 879                 float wcross_alpha, wcross_resolution;
 880                 wcross_style = autocvar_crosshair;
 881                 if (wcross_style == "0")
 882                         return;
 883                 wcross_resolution = autocvar_crosshair_size;
 884                 if (wcross_resolution == 0)
 885                         return;
 886                 wcross_alpha = autocvar_crosshair_alpha;
 887                 if (wcross_alpha == 0)
 888                         return;
 889
 890                 // TrueAim check
 891                 float shottype;
 892
 893                 // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
 894                 wcross_origin = project_3d_to_2d(view_origin + MAX_SHOT_DISTANCE * view_forward);
 895                 wcross_origin.z = 0;
 896                 if(autocvar_crosshair_hittest)
 897                 {
 898                         vector wcross_oldorigin;
 899                         wcross_oldorigin = wcross_origin;
 900                         shottype = TrueAimCheck();
 901                         if(shottype == SHOTTYPE_HITWORLD)
 902                         {
 903                                 v = wcross_origin - wcross_oldorigin;
 904                                 v.x /= vid_conwidth;
 905                                 v.y /= vid_conheight;
 906                                 if(vlen(v) > 0.01)
 907                                         shottype = SHOTTYPE_HITOBSTRUCTION;
 908                         }
 909                         if(!autocvar_crosshair_hittest_showimpact)
 910                                 wcross_origin = wcross_oldorigin;
 911                 }
 912                 else
 913                         shottype = SHOTTYPE_HITWORLD;
 914
 915                 vector wcross_color = '0 0 0', wcross_size = '0 0 0';
 916                 string wcross_name = "";
 917                 float wcross_scale, wcross_blur;
 918
 919                 if(autocvar_crosshair_per_weapon || (autocvar_crosshair_color_special == 1))
 920                 {
 921                         e = get_weaponinfo(switchingweapon);
 922                         if(e)
 923                         {
 924                                 if(autocvar_crosshair_per_weapon)
 925                                 {
 926                                         // WEAPONTODO: access these through some general settings (with non-balance config settings)
 927                                         //wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
 928                                         //if (wcross_resolution == 0)
 929                                                 //return;
 930
 931                                         //wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
 932                                         wcross_resolution *= e.w_crosshair_size;
 933                                         wcross_name = e.w_crosshair;
 934                                 }
 935                         }
 936                 }
 937
 938                 if(wcross_name == "")
 939                         wcross_name = strcat("gfx/crosshair", wcross_style);
 940
 941                 // MAIN CROSSHAIR COLOR DECISION
 942                 switch(autocvar_crosshair_color_special)
 943                 {
 944                         case 1: // crosshair_color_per_weapon
 945                         {
 946                                 if(e)
 947                                 {
 948                                         wcross_color = e.wpcolor;
 949                                         break;
 950                                 }
 951                                 else { goto normalcolor; }
 952                         }
 953
 954                         case 2: // crosshair_color_by_health
 955                         {
 956                                 float x = getstati(STAT_HEALTH);
 957
 958                                 //x = red
 959                                 //y = green
 960                                 //z = blue
 961
 962                                 wcross_color.z = 0;
 963
 964                                 if(x > 200)
 965                                 {
 966                                         wcross_color.x = 0;
 967                                         wcross_color.y = 1;
 968                                 }
 969                                 else if(x > 150)
 970                                 {
 971                                         wcross_color.x = 0.4 - (x-150)*0.02 * 0.4;
 972                                         wcross_color.y = 0.9 + (x-150)*0.02 * 0.1;
 973                                 }
 974                                 else if(x > 100)
 975                                 {
 976                                         wcross_color.x = 1 - (x-100)*0.02 * 0.6;
 977                                         wcross_color.y = 1 - (x-100)*0.02 * 0.1;
 978                                         wcross_color.z = 1 - (x-100)*0.02;
 979                                 }
 980                                 else if(x > 50)
 981                                 {
 982                                         wcross_color.x = 1;
 983                                         wcross_color.y = 1;
 984                                         wcross_color.z = 0.2 + (x-50)*0.02 * 0.8;
 985                                 }
 986                                 else if(x > 20)
 987                                 {
 988                                         wcross_color.x = 1;
 989                                         wcross_color.y = (x-20)*90/27/100;
 990                                         wcross_color.z = (x-20)*90/27/100 * 0.2;
 991                                 }
 992                                 else
 993                                 {
 994                                         wcross_color.x = 1;
 995                                         wcross_color.y = 0;
 996                                 }
 997                                 break;
 998                         }
 999
1000                         case 3: // crosshair_color_rainbow
1001                         {
1002                                 if(time >= rainbow_last_flicker)
1003                                 {
1004                                         rainbow_prev_color = randomvec() * autocvar_crosshair_color_special_rainbow_brightness;
1005                                         rainbow_last_flicker = time + autocvar_crosshair_color_special_rainbow_delay;
1006                                 }
1007                                 wcross_color = rainbow_prev_color;
1008                                 break;
1009                         }
1010                         :normalcolor
1011                         default: { wcross_color = stov(autocvar_crosshair_color); break; }
1012                 }
1013
1014                 if(autocvar_crosshair_effect_scalefade)
1015                 {
1016                         wcross_scale = wcross_resolution;
1017                         wcross_resolution = 1;
1018                 }
1019                 else
1020                 {
1021                         wcross_scale = 1;
1022                 }
1023
1024                 if(autocvar_crosshair_pickup)
1025                 {
1026                         float stat_pickup_time = STAT(LAST_PICKUP);
1027
1028                         if(pickup_crosshair_time < stat_pickup_time)
1029                         {
1030                                 if(time - stat_pickup_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1031                                         pickup_crosshair_size = 1;
1032
1033                                 pickup_crosshair_time = stat_pickup_time;
1034                         }
1035
1036                         if(pickup_crosshair_size > 0)
1037                                 pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
1038                         else
1039                                 pickup_crosshair_size = 0;
1040
1041                         wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
1042                 }
1043
1044                 // todo: make crosshair hit indication dependent on damage dealt
1045                 if(autocvar_crosshair_hitindication)
1046                 {
1047                         vector hitindication_color = ((autocvar_crosshair_color_special == 1) ? stov(autocvar_crosshair_hitindication_per_weapon_color) : stov(autocvar_crosshair_hitindication_color));
1048
1049                         if(unaccounted_damage)
1050                         {
1051                                 hitindication_crosshair_size = 1;
1052                         }
1053
1054                         if(hitindication_crosshair_size > 0)
1055                                 hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
1056                         else
1057                                 hitindication_crosshair_size = 0;
1058
1059                         wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
1060                         wcross_color.x += sin(hitindication_crosshair_size) * hitindication_color.x;
1061                         wcross_color.y += sin(hitindication_crosshair_size) * hitindication_color.y;
1062                         wcross_color.z += sin(hitindication_crosshair_size) * hitindication_color.z;
1063                 }
1064
1065                 if(shottype == SHOTTYPE_HITENEMY)
1066                         wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
1067                 if(shottype == SHOTTYPE_HITTEAM)
1068                         wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
1069
1070                 f = fabs(autocvar_crosshair_effect_time);
1071                 if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
1072                 {
1073                         wcross_changedonetime = time + f;
1074                 }
1075                 if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
1076                 {
1077                         wcross_name_changestarttime = time;
1078                         wcross_name_changedonetime = time + f;
1079                         if(wcross_name_goal_prev_prev)
1080                                 strunzone(wcross_name_goal_prev_prev);
1081                         wcross_name_goal_prev_prev = wcross_name_goal_prev;
1082                         wcross_name_goal_prev = strzone(wcross_name);
1083                         wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
1084                         wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
1085                         wcross_resolution_goal_prev = wcross_resolution;
1086                 }
1087
1088                 wcross_scale_goal_prev = wcross_scale;
1089                 wcross_alpha_goal_prev = wcross_alpha;
1090                 wcross_color_goal_prev = wcross_color;
1091
1092                 if(spectatee_status == -1 && shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
1093                 {
1094                         wcross_blur = 1;
1095                         wcross_alpha *= 0.75;
1096                 }
1097                 else
1098                         wcross_blur = 0;
1099                 // *_prev is at time-frametime
1100                 // * is at wcross_changedonetime+f
1101                 // what do we have at time?
1102                 if(time < wcross_changedonetime)
1103                 {
1104                         f = frametime / (wcross_changedonetime - time + frametime);
1105                         wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
1106                         wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
1107                         wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
1108                 }
1109
1110                 wcross_scale_prev = wcross_scale;
1111                 wcross_alpha_prev = wcross_alpha;
1112                 wcross_color_prev = wcross_color;
1113
1114                 MUTATOR_CALLHOOK(UpdateCrosshair);
1115
1116                 wcross_scale *= 1 - autocvar__menu_alpha;
1117                 wcross_alpha *= 1 - autocvar__menu_alpha;
1118                 wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1119
1120                 if(wcross_scale >= 0.001 && wcross_alpha >= 0.001)
1121                 {
1122                         // crosshair rings for weapon stats
1123                         if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
1124                         {
1125                                 // declarations and stats
1126                                 float ring_value = 0, ring_scale = 0, ring_alpha = 0, ring_inner_value = 0, ring_inner_alpha = 0;
1127                                 string ring_image = string_null, ring_inner_image = string_null;
1128                                 vector ring_rgb = '0 0 0', ring_inner_rgb = '0 0 0';
1129
1130                                 ring_scale = autocvar_crosshair_ring_size;
1131
1132                                 float weapon_clipload, weapon_clipsize;
1133                                 weapon_clipload = STAT(WEAPON_CLIPLOAD);
1134                                 weapon_clipsize = STAT(WEAPON_CLIPSIZE);
1135
1136                                 float ok_ammo_charge, ok_ammo_chargepool;
1137                                 ok_ammo_charge = STAT(OK_AMMO_CHARGE);
1138                                 ok_ammo_chargepool = STAT(OK_AMMO_CHARGEPOOL);
1139
1140                                 float vortex_charge, vortex_chargepool;
1141                                 vortex_charge = STAT(VORTEX_CHARGE);
1142                                 vortex_chargepool = STAT(VORTEX_CHARGEPOOL);
1143
1144                                 float arc_heat = STAT(ARC_HEAT);
1145
1146                                 if(vortex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
1147                                         vortex_charge_movingavg = vortex_charge;
1148
1149
1150                                 // handle the values
1151                                 if (autocvar_crosshair_ring && activeweapon == WEP_VORTEX.m_id && vortex_charge && autocvar_crosshair_ring_vortex) // ring around crosshair representing velocity-dependent damage for the vortex
1152                                 {
1153                                         if (vortex_chargepool || use_vortex_chargepool) {
1154                                                 use_vortex_chargepool = 1;
1155                                                 ring_inner_value = vortex_chargepool;
1156                                         } else {
1157                                                 vortex_charge_movingavg = (1 - autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate) * vortex_charge_movingavg + autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate * vortex_charge;
1158                                                 ring_inner_value = bound(0, autocvar_crosshair_ring_vortex_currentcharge_scale * (vortex_charge - vortex_charge_movingavg), 1);
1159                                         }
1160
1161                                         ring_inner_alpha = autocvar_crosshair_ring_vortex_inner_alpha;
1162                                         ring_inner_rgb = eX * autocvar_crosshair_ring_vortex_inner_color_red + eY * autocvar_crosshair_ring_vortex_inner_color_green + eZ * autocvar_crosshair_ring_vortex_inner_color_blue;
1163                                         ring_inner_image = "gfx/crosshair_ring_inner.tga";
1164
1165                                         // draw the outer ring to show the current charge of the weapon
1166                                         ring_value = vortex_charge;
1167                                         ring_alpha = autocvar_crosshair_ring_vortex_alpha;
1168                                         ring_rgb = wcross_color;
1169                                         ring_image = "gfx/crosshair_ring_nexgun.tga";
1170                                 }
1171                                 else if (autocvar_crosshair_ring && activeweapon == WEP_MINE_LAYER.m_id && minelayer_maxmines && autocvar_crosshair_ring_minelayer)
1172                                 {
1173                                         ring_value = bound(0, STAT(LAYED_MINES) / minelayer_maxmines, 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
1174                                         ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
1175                                         ring_rgb = wcross_color;
1176                                         ring_image = "gfx/crosshair_ring.tga";
1177                                 }
1178                                 else if (activeweapon == WEP_HAGAR.m_id && STAT(HAGAR_LOAD) && autocvar_crosshair_ring_hagar)
1179                                 {
1180                                         ring_value = bound(0, STAT(HAGAR_LOAD) / hagar_maxrockets, 1);
1181                                         ring_alpha = autocvar_crosshair_ring_hagar_alpha;
1182                                         ring_rgb = wcross_color;
1183                                         ring_image = "gfx/crosshair_ring.tga";
1184                                 }
1185                                 else if (ok_ammo_charge)
1186                                 {
1187                                         ring_value = ok_ammo_chargepool;
1188                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
1189                                         ring_rgb = wcross_color;
1190                                         ring_image = "gfx/crosshair_ring.tga";
1191                                 }
1192                                 else if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
1193                                 {
1194                                         ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
1195                                         ring_scale = autocvar_crosshair_ring_reload_size;
1196                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
1197                                         ring_rgb = wcross_color;
1198
1199                                         // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
1200                                         // if a new image for another weapon is added, add the code (and its respective file/value) here
1201                                         if ((activeweapon == WEP_RIFLE.m_id) && (weapon_clipsize == 80))
1202                                                 ring_image = "gfx/crosshair_ring_rifle.tga";
1203                                         else
1204                                                 ring_image = "gfx/crosshair_ring.tga";
1205                                 }
1206                                 else if ( autocvar_crosshair_ring && autocvar_crosshair_ring_arc && arc_heat && activeweapon == WEP_ARC.m_id )
1207                                 {
1208                                         ring_value = arc_heat;
1209                                         ring_alpha = (1-arc_heat)*autocvar_crosshair_ring_arc_cold_alpha +
1210                                                 arc_heat*autocvar_crosshair_ring_arc_hot_alpha;
1211                                         ring_rgb = (1-arc_heat)*wcross_color + arc_heat*autocvar_crosshair_ring_arc_hot_color;
1212                                         ring_image = "gfx/crosshair_ring.tga";
1213                                 }
1214
1215                                 // if in weapon switch animation, fade ring out/in
1216                                 if(autocvar_crosshair_effect_time > 0)
1217                                 {
1218                                         f = (time - wcross_name_changestarttime) / autocvar_crosshair_effect_time;
1219                                         if (f >= 1)
1220                                         {
1221                                                 wcross_ring_prev = ((ring_image) ? true : false);
1222                                         }
1223
1224                                         if(wcross_ring_prev)
1225                                         {
1226                                                 if(f < 1)
1227                                                         ring_alpha *= fabs(1 - bound(0, f, 1));
1228                                         }
1229                                         else
1230                                         {
1231                                                 if(f < 1)
1232                                                         ring_alpha *= bound(0, f, 1);
1233                                         }
1234                                 }
1235
1236                                 if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
1237                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
1238
1239                                 if (ring_value)
1240                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
1241                         }
1242
1243 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
1244                         do \
1245                         { \
1246                                 if(wcross_blur > 0) \
1247                                 { \
1248                                         for(i = -2; i <= 2; ++i) \
1249                                         for(j = -2; j <= 2; ++j) \
1250                                         M(i,j,sz,wcross_name,wcross_alpha*0.04); \
1251                                 } \
1252                                 else \
1253                                 { \
1254                                         M(0,0,sz,wcross_name,wcross_alpha); \
1255                                 } \
1256                         } \
1257                         while(0)
1258
1259 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
1260                         drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size.x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size.y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
1261
1262 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
1263                         CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
1264
1265                         if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
1266                         {
1267                                 f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
1268                                 wcross_size = draw_getimagesize(wcross_name_goal_prev_prev) * wcross_scale;
1269                                 CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
1270                                 f = 1 - f;
1271                         }
1272                         else
1273                         {
1274                                 f = 1;
1275                         }
1276                         wcross_name_alpha_goal_prev = f;
1277
1278                         wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1279                         CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
1280
1281                         if(autocvar_crosshair_dot)
1282                         {
1283                                 vector wcross_color_old;
1284                                 wcross_color_old = wcross_color;
1285
1286                                 if((autocvar_crosshair_dot_color_custom) && (autocvar_crosshair_dot_color != "0"))
1287                                         wcross_color = stov(autocvar_crosshair_dot_color);
1288
1289                                 CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
1290                                 // FIXME why don't we use wcross_alpha here?
1291                                 wcross_color = wcross_color_old;
1292                         }
1293                 }
1294         }
1295         else
1296         {
1297                 wcross_scale_prev = 0;
1298                 wcross_alpha_prev = 0;
1299                 wcross_scale_goal_prev = 0;
1300                 wcross_alpha_goal_prev = 0;
1301                 wcross_changedonetime = 0;
1302                 if(wcross_name_goal_prev)
1303                         strunzone(wcross_name_goal_prev);
1304                 wcross_name_goal_prev = string_null;
1305                 if(wcross_name_goal_prev_prev)
1306                         strunzone(wcross_name_goal_prev_prev);
1307                 wcross_name_goal_prev_prev = string_null;
1308                 wcross_name_changestarttime = 0;
1309                 wcross_name_changedonetime = 0;
1310                 wcross_name_alpha_goal_prev = 0;
1311                 wcross_name_alpha_goal_prev_prev = 0;
1312                 wcross_resolution_goal_prev = 0;
1313                 wcross_resolution_goal_prev_prev = 0;
1314         }
1315 }
1316
1317 void HUD_Draw()
1318 {
1319         vector rgb = '0 0 0';
1320         float a = 1;
1321         if (MUTATOR_CALLHOOK(HUD_Draw_overlay))
1322         {
1323                 rgb = MUTATOR_ARGV(0, vector);
1324                 a = MUTATOR_ARGV(0, float);
1325         }
1326         else if(STAT(FROZEN))
1327         {
1328                 rgb = ((STAT(REVIVE_PROGRESS)) ? ('0.25 0.90 1' + ('1 0 0' * STAT(REVIVE_PROGRESS)) + ('0 1 1' * STAT(REVIVE_PROGRESS) * -1)) : '0.25 0.90 1');
1329         }
1330         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, rgb, autocvar_hud_colorflash_alpha * a, DRAWFLAG_ADDITIVE);
1331         if(!intermission)
1332         if(STAT(NADE_TIMER) && autocvar_cl_nade_timer) // give nade top priority, as it's a matter of life and death
1333         {
1334                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(NADE_TIMER), '0.25 0.90 1' + ('1 0 0' * STAT(NADE_TIMER)) - ('0 1 1' * STAT(NADE_TIMER)), autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1335                 drawstring_aspect(eY * 0.64 * vid_conheight, ((autocvar_cl_nade_timer == 2) ? _("Nade timer") : ""), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
1336         }
1337         else if(STAT(REVIVE_PROGRESS))
1338         {
1339                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1340                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Revival progress"), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
1341         }
1342
1343         if(autocvar_r_letterbox == 0)
1344                 if(autocvar_viewsize < 120)
1345                 {
1346                         if(!(gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS))
1347                                 Accuracy_LoadLevels();
1348
1349                         HUD_Main();
1350                         HUD_DrawScoreboard();
1351                 }
1352
1353         // crosshair goes VERY LAST
1354         UpdateDamage();
1355         HUD_Crosshair();
1356         HitSound();
1357 }
1358
1359 bool ov_enabled;
1360 float oldr_nearclip;
1361 float oldr_farclip_base;
1362 float oldr_farclip_world;
1363 float oldr_novis;
1364 float oldr_useportalculling;
1365 float oldr_useinfinitefarclip;
1366
1367 void cl_notice_run();
1368 float prev_myteam;
1369 int lasthud;
1370 float vh_notice_time;
1371 void WaypointSprite_Load();
1372 void CSQC_UpdateView(float w, float h)
1373 {SELFPARAM();
1374         entity e;
1375         float fov;
1376         float f;
1377         vector vf_size, vf_min;
1378         float a;
1379
1380         execute_next_frame();
1381
1382         ++framecount;
1383
1384         stats_get();
1385         hud = STAT(HUD);
1386
1387         if(hud != HUD_NORMAL && lasthud == HUD_NORMAL)
1388                 vh_notice_time = time + autocvar_cl_vehicles_notify_time;
1389
1390         lasthud = hud;
1391
1392         if(autocvar__hud_showbinds_reload) // menu can set this one
1393         {
1394                 db_close(binddb);
1395                 binddb = db_create();
1396                 cvar_set("_hud_showbinds_reload", "0");
1397         }
1398
1399         if(checkextension("DP_CSQC_MINFPS_QUALITY"))
1400                 view_quality = getproperty(VF_MINFPS_QUALITY);
1401         else
1402                 view_quality = 1;
1403
1404         button_attack2 = PHYS_INPUT_BUTTON_ATCK2(self);
1405         button_zoom = PHYS_INPUT_BUTTON_ZOOM(self);
1406
1407         vf_size = getpropertyvec(VF_SIZE);
1408         vf_min = getpropertyvec(VF_MIN);
1409         vid_width = vf_size.x;
1410         vid_height = vf_size.y;
1411
1412         vector reticle_pos = '0 0 0', reticle_size = '0 0 0';
1413         vector splash_pos = '0 0 0', splash_size = '0 0 0';
1414
1415         WaypointSprite_Load();
1416
1417         CSQCPlayer_SetCamera();
1418
1419         if(player_localentnum <= maxclients) // is it a client?
1420                 current_player = player_localentnum - 1;
1421         else // then player_localentnum is the vehicle I'm driving
1422                 current_player = player_localnum;
1423         myteam = GetPlayerColor(current_player);
1424
1425         if(myteam != prev_myteam)
1426         {
1427                 myteamcolors = colormapPaletteColor(myteam, 1);
1428                 FOREACH(hud_panels, true, LAMBDA(it.update_time = time));
1429                 prev_myteam = myteam;
1430         }
1431
1432         ticrate = STAT(MOVEVARS_TICRATE) * STAT(MOVEVARS_TIMESCALE);
1433
1434         float is_dead = (getstati(STAT_HEALTH) <= 0);
1435
1436         // FIXME do we need this hack?
1437         if(isdemo())
1438         {
1439                 // in demos, input_buttons do not work
1440                 button_zoom = (autocvar__togglezoom == "-");
1441         }
1442         else if(button_zoom
1443                 && autocvar_cl_unpress_zoom_on_death
1444                 && (spectatee_status >= 0)
1445                 && (is_dead || intermission))
1446         {
1447                 // no zoom while dead or in intermission please
1448                 localcmd("-zoom\n");
1449                 button_zoom = false;
1450         }
1451
1452         // event chase camera
1453         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
1454         {
1455                 float vehicle_chase = (hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0));
1456                 float ons_roundlost = (gametype == MAPINFO_TYPE_ONSLAUGHT && STAT(ROUNDLOST));
1457                 entity gen = world;
1458
1459                 if(ons_roundlost)
1460                 {
1461                         entity e;
1462                         for(e = world; (e = find(e, classname, "onslaught_generator")); )
1463                         {
1464                                 if(e.health <= 0)
1465                                 {
1466                                         gen = e;
1467                                         break;
1468                                 }
1469                         }
1470                         if(!gen)
1471                                 ons_roundlost = FALSE; // don't enforce the 3rd person camera if there is no dead generator to show
1472                 }
1473                 if(WantEventchase() || (!autocvar_cl_orthoview && ons_roundlost))
1474                 {
1475                         eventchase_running = true;
1476
1477                         // make special vector since we can't use view_origin (It is one frame old as of this code, it gets set later with the results this code makes.)
1478                         vector current_view_origin = (csqcplayer ? csqcplayer.origin : pmove_org);
1479                         if(ons_roundlost) { current_view_origin = gen.origin; }
1480
1481                         // detect maximum viewoffset and use it
1482                         vector view_offset = autocvar_cl_eventchase_viewoffset;
1483                         if(vehicle_chase && autocvar_cl_eventchase_vehicle_viewoffset) { view_offset = autocvar_cl_eventchase_vehicle_viewoffset; }
1484                         if(ons_roundlost) { view_offset = autocvar_cl_eventchase_generator_viewoffset; }
1485
1486                         if(view_offset)
1487                         {
1488                                 WarpZone_TraceLine(current_view_origin, current_view_origin + view_offset + ('0 0 1' * autocvar_cl_eventchase_maxs.z), MOVE_WORLDONLY, self);
1489                                 if(trace_fraction == 1) { current_view_origin += view_offset; }
1490                                 else { current_view_origin.z += max(0, (trace_endpos.z - current_view_origin.z) - autocvar_cl_eventchase_maxs.z); }
1491                         }
1492
1493                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
1494                         // Ideally, there should be another way to enable third person cameras, such as through setproperty()
1495                         // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
1496                         if(!autocvar_chase_active) { cvar_set("chase_active", "-1"); }
1497
1498                         // make the camera smooth back
1499                         float chase_distance = autocvar_cl_eventchase_distance;
1500                         if(vehicle_chase && autocvar_cl_eventchase_vehicle_distance) { chase_distance = autocvar_cl_eventchase_vehicle_distance; }
1501                         if(ons_roundlost) { chase_distance = autocvar_cl_eventchase_generator_distance; }
1502
1503                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < chase_distance)
1504                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (chase_distance - eventchase_current_distance) * frametime; // slow down the further we get
1505                         else if(eventchase_current_distance != chase_distance)
1506                                 eventchase_current_distance = chase_distance;
1507
1508                         makevectors(view_angles);
1509
1510                         vector eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1511                         WarpZone_TraceBox(current_view_origin, autocvar_cl_eventchase_mins, autocvar_cl_eventchase_maxs, eventchase_target_origin, MOVE_WORLDONLY, self);
1512
1513                         // If the boxtrace fails, revert back to line tracing.
1514                         if(!self.viewloc)
1515                         if(trace_startsolid)
1516                         {
1517                                 eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1518                                 WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, self);
1519                                 setproperty(VF_ORIGIN, (trace_endpos - (v_forward * autocvar_cl_eventchase_mins.z)));
1520                         }
1521                         else { setproperty(VF_ORIGIN, trace_endpos); }
1522
1523                         if(!self.viewloc)
1524                                 setproperty(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
1525                 }
1526                 else if(autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
1527                 {
1528                         eventchase_running = false;
1529                         cvar_set("chase_active", "0");
1530                         eventchase_current_distance = 0; // start from 0 next time
1531                 }
1532         }
1533         // workaround for camera stuck between player's legs when using chase_active 1
1534         // because the engine stops updating the chase_active camera when the game ends
1535         else if(intermission)
1536         {
1537                 cvar_settemp("chase_active", "-1");
1538                 eventchase_current_distance = 0;
1539         }
1540
1541         // do lockview after event chase camera so that it still applies whenever necessary.
1542         if(autocvar_cl_lockview || (!autocvar_hud_cursormode && (autocvar__hud_configure && spectatee_status <= 0 || intermission > 1 || QuickMenu_IsOpened())))
1543         {
1544                 setproperty(VF_ORIGIN, freeze_org);
1545                 setproperty(VF_ANGLES, freeze_ang);
1546         }
1547         else
1548         {
1549                 freeze_org = getpropertyvec(VF_ORIGIN);
1550                 freeze_ang = getpropertyvec(VF_ANGLES);
1551         }
1552
1553         WarpZone_FixView();
1554         //WarpZone_FixPMove();
1555
1556         vector ov_org = '0 0 0';
1557         vector ov_mid = '0 0 0';
1558         vector ov_worldmin = '0 0 0';
1559         vector ov_worldmax = '0 0 0';
1560         if(autocvar_cl_orthoview)
1561         {
1562                 ov_worldmin = mi_picmin;
1563                 ov_worldmax = mi_picmax;
1564
1565                 float ov_width = (ov_worldmax.x - ov_worldmin.x);
1566                 float ov_height = (ov_worldmax.y - ov_worldmin.y);
1567                 float ov_distance = (max(vid_width, vid_height) * max(ov_width, ov_height));
1568
1569                 ov_mid = ((ov_worldmax + ov_worldmin) * 0.5);
1570                 ov_org = vec3(ov_mid.x, ov_mid.y, (ov_mid.z + ov_distance));
1571
1572                 float ov_nearest = vlen(ov_org - vec3(
1573                         bound(ov_worldmin.x, ov_org.x, ov_worldmax.x),
1574                         bound(ov_worldmin.y, ov_org.y, ov_worldmax.y),
1575                         bound(ov_worldmin.z, ov_org.z, ov_worldmax.z)
1576                 ));
1577
1578                 float ov_furthest = 0;
1579                 float dist = 0;
1580
1581                 if((dist = vlen(vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmin.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1582                 if((dist = vlen(vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmin.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1583                 if((dist = vlen(vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmin.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1584                 if((dist = vlen(vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmax.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1585                 if((dist = vlen(vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmin.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1586                 if((dist = vlen(vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmax.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1587                 if((dist = vlen(vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmax.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1588                 if((dist = vlen(vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmax.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1589
1590                 if(!ov_enabled)
1591                 {
1592                         oldr_nearclip = cvar("r_nearclip");
1593                         oldr_farclip_base = cvar("r_farclip_base");
1594                         oldr_farclip_world = cvar("r_farclip_world");
1595                         oldr_novis = cvar("r_novis");
1596                         oldr_useportalculling = cvar("r_useportalculling");
1597                         oldr_useinfinitefarclip = cvar("r_useinfinitefarclip");
1598                 }
1599
1600                 cvar_settemp("r_nearclip", ftos(ov_nearest));
1601                 cvar_settemp("r_farclip_base", ftos(ov_furthest));
1602                 cvar_settemp("r_farclip_world", "0");
1603                 cvar_settemp("r_novis", "1");
1604                 cvar_settemp("r_useportalculling", "0");
1605                 cvar_settemp("r_useinfinitefarclip", "0");
1606
1607                 setproperty(VF_ORIGIN, ov_org);
1608                 setproperty(VF_ANGLES, '90 0 0');
1609
1610                 ov_enabled = true;
1611
1612                 #if 0
1613                 LOG_INFOF("OrthoView: org = %s, angles = %s, distance = %f, nearest = %f, furthest = %f\n",
1614                         vtos(ov_org),
1615                         vtos(getpropertyvec(VF_ANGLES)),
1616                         ov_distance,
1617                         ov_nearest,
1618                         ov_furthest);
1619                 #endif
1620         }
1621         else
1622         {
1623                 if(ov_enabled)
1624                 {
1625                         cvar_set("r_nearclip", ftos(oldr_nearclip));
1626                         cvar_set("r_farclip_base", ftos(oldr_farclip_base));
1627                         cvar_set("r_farclip_world", ftos(oldr_farclip_world));
1628                         cvar_set("r_novis", ftos(oldr_novis));
1629                         cvar_set("r_useportalculling", ftos(oldr_useportalculling));
1630                         cvar_set("r_useinfinitefarclip", ftos(oldr_useinfinitefarclip));
1631                 }
1632                 ov_enabled = false;
1633         }
1634
1635         // Render the Scene
1636         view_origin = getpropertyvec(VF_ORIGIN);
1637         view_angles = getpropertyvec(VF_ANGLES);
1638         makevectors(view_angles);
1639         view_forward = v_forward;
1640         view_right = v_right;
1641         view_up = v_up;
1642
1643 #ifdef BLURTEST
1644         if(time > blurtest_time0 && time < blurtest_time1)
1645         {
1646                 float r, t;
1647
1648                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
1649                 r = t * blurtest_radius;
1650                 f = 1 / pow(t, blurtest_power) - 1;
1651
1652                 cvar_set("r_glsl_postprocess", "1");
1653                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
1654         }
1655         else
1656         {
1657                 cvar_set("r_glsl_postprocess", "0");
1658                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
1659         }
1660 #endif
1661
1662         TargetMusic_Advance();
1663         Fog_Force();
1664
1665         if(drawtime == 0)
1666                 drawframetime = 0.01666667; // when we don't know fps yet, we assume 60fps
1667         else
1668                 drawframetime = bound(0.000001, time - drawtime, 1);
1669         drawtime = time;
1670
1671         // watch for gametype changes here...
1672         // in ParseStuffCMD the cmd isn't executed yet :/
1673         // might even be better to add the gametype to TE_CSQC_INIT...?
1674         if(!postinit)
1675                 PostInit();
1676
1677         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
1678         {
1679                 if(calledhooks & HOOK_START)
1680                 {
1681                         localcmd("\ncl_hook_gameend\n");
1682                         calledhooks |= HOOK_END;
1683                 }
1684         }
1685
1686         Announcer();
1687
1688         fov = autocvar_fov;
1689         if(fov <= 59.5)
1690         {
1691                 if(!zoomscript_caught)
1692                 {
1693                         localcmd("+button9\n");
1694                         zoomscript_caught = 1;
1695                 }
1696         }
1697         else
1698         {
1699                 if(zoomscript_caught)
1700                 {
1701                         localcmd("-button9\n");
1702                         zoomscript_caught = 0;
1703                 }
1704         }
1705
1706         ColorTranslateMode = autocvar_cl_stripcolorcodes;
1707
1708         // currently switching-to weapon (for crosshair)
1709         switchingweapon = STAT(SWITCHINGWEAPON);
1710
1711         // actually active weapon (for zoom)
1712         activeweapon = getstati(STAT_ACTIVEWEAPON);
1713
1714         f = (serverflags & SERVERFLAG_TEAMPLAY);
1715         if(f != teamplay)
1716         {
1717                 teamplay = f;
1718                 HUD_InitScores();
1719         }
1720
1721         if(last_switchweapon != switchweapon)
1722         {
1723                 weapontime = time;
1724                 last_switchweapon = switchweapon;
1725                 if(button_zoom && autocvar_cl_unpress_zoom_on_weapon_switch)
1726                 {
1727                         localcmd("-zoom\n");
1728                         button_zoom = false;
1729                 }
1730                 if(autocvar_cl_unpress_attack_on_weapon_switch)
1731                 {
1732                         localcmd("-fire\n");
1733                         localcmd("-fire2\n");
1734                         button_attack2 = false;
1735                 }
1736         }
1737         if(last_activeweapon != activeweapon)
1738         {
1739                 last_activeweapon = activeweapon;
1740
1741                 e = get_weaponinfo(activeweapon);
1742                 if(e.netname != "")
1743                         localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
1744                 else
1745                         localcmd("\ncl_hook_activeweapon none\n");
1746         }
1747
1748         // ALWAYS Clear Current Scene First
1749         clearscene();
1750
1751         setproperty(VF_ORIGIN, view_origin);
1752         setproperty(VF_ANGLES, view_angles);
1753
1754         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
1755         setproperty(VF_SIZE, vf_size);
1756         setproperty(VF_MIN, vf_min);
1757
1758         // Assign Standard Viewflags
1759         // Draw the World (and sky)
1760         setproperty(VF_DRAWWORLD, 1);
1761
1762         // Set the console size vars
1763         vid_conwidth = autocvar_vid_conwidth;
1764         vid_conheight = autocvar_vid_conheight;
1765         vid_pixelheight = autocvar_vid_pixelheight;
1766
1767         if(autocvar_cl_orthoview) { setproperty(VF_FOV, GetOrthoviewFOV(ov_worldmin, ov_worldmax, ov_mid, ov_org)); }
1768         else if(csqcplayer.viewloc) { setproperty(VF_FOV, GetViewLocationFOV(110)); } // enforce 110 fov, so things dont look odd
1769         else { setproperty(VF_FOV, GetCurrentFov(fov)); }
1770
1771         // Camera for demo playback
1772         if(camera_active)
1773         {
1774                 if(autocvar_camera_enable)
1775                         CSQC_Demo_Camera();
1776                 else
1777                 {
1778                         cvar_set("chase_active", ftos(chase_active_backup));
1779                         cvar_set("cl_demo_mousegrab", "0");
1780                         camera_active = false;
1781                 }
1782         }
1783         else
1784         {
1785 #ifdef CAMERATEST
1786                 if(autocvar_camera_enable)
1787 #else
1788                 if(autocvar_camera_enable && isdemo())
1789 #endif
1790                 {
1791                         // Enable required Darkplaces cvars
1792                         chase_active_backup = autocvar_chase_active;
1793                         cvar_set("chase_active", "2");
1794                         cvar_set("cl_demo_mousegrab", "1");
1795                         camera_active = true;
1796                         camera_mode = false;
1797                 }
1798         }
1799
1800         // Draw the Crosshair
1801         setproperty(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
1802
1803         // Draw the Engine Status Bar (the default Quake HUD)
1804         setproperty(VF_DRAWENGINESBAR, 0);
1805
1806         // Update the mouse position
1807         /*
1808            mousepos_x = vid_conwidth;
1809            mousepos_y = vid_conheight;
1810            mousepos = mousepos*0.5 + getmousepos();
1811          */
1812
1813         FOREACH_ENTITY(it.draw, LAMBDA(WITH(entity, self, it, it.draw(it))));
1814
1815         addentities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
1816         renderscene();
1817
1818         // now switch to 2D drawing mode by calling a 2D drawing function
1819         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
1820         // next R_RenderScene call
1821         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
1822
1823         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
1824         if (!(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT))
1825         {
1826                 // apply night vision effect
1827                 vector tc_00, tc_01, tc_10, tc_11;
1828                 vector rgb = '0 0 0';
1829
1830                 if(!nightvision_noise)
1831                 {
1832                         nightvision_noise = new(nightvision_noise);
1833                 }
1834                 if(!nightvision_noise2)
1835                 {
1836                         nightvision_noise2 = new(nightvision_noise2);
1837                 }
1838
1839                 // color tint in yellow
1840                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
1841
1842                 // draw BG
1843                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
1844                 rgb = '1 1 1';
1845                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
1846                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
1847                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
1848                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
1849                 tc_11 = tc_01 + tc_10 - tc_00;
1850                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
1851                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
1852                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
1853                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
1854                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
1855                 R_EndPolygon();
1856
1857                 // draw FG
1858                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
1859                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
1860                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
1861                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
1862                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
1863                 tc_11 = tc_01 + tc_10 - tc_00;
1864                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
1865                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
1866                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
1867                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
1868                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
1869                 R_EndPolygon();
1870         }
1871
1872         if(autocvar_cl_reticle)
1873         {
1874                 Weapon wep = get_weaponinfo(activeweapon);
1875                 // Draw the aiming reticle for weapons that use it
1876                 // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
1877                 // It must be a persisted float for fading out to work properly (you let go of the zoom button for
1878                 // the view to go back to normal, so reticle_type would become 0 as we fade out)
1879                 if(spectatee_status || is_dead || hud != HUD_NORMAL)
1880                 {
1881                         // no zoom reticle while dead
1882                         reticle_type = 0;
1883                 }
1884                 else if(wep.wr_zoomreticle(wep) && autocvar_cl_reticle_weapon)
1885                 {
1886                         if(reticle_image != "") { reticle_type = 2; }
1887                         else { reticle_type = 0; }
1888                 }
1889                 else if(button_zoom || zoomscript_caught)
1890                 {
1891                         // normal zoom
1892                         reticle_type = 1;
1893                 }
1894
1895                 if(reticle_type)
1896                 {
1897                         if(autocvar_cl_reticle_stretch)
1898                         {
1899                                 reticle_size.x = vid_conwidth;
1900                                 reticle_size.y = vid_conheight;
1901                                 reticle_pos.x = 0;
1902                                 reticle_pos.y = 0;
1903                         }
1904                         else
1905                         {
1906                                 reticle_size.x = max(vid_conwidth, vid_conheight);
1907                                 reticle_size.y = max(vid_conwidth, vid_conheight);
1908                                 reticle_pos.x = (vid_conwidth - reticle_size.x) / 2;
1909                                 reticle_pos.y = (vid_conheight - reticle_size.y) / 2;
1910                         }
1911
1912                         if(zoomscript_caught)
1913                                 f = 1;
1914                         else
1915                                 f = current_zoomfraction;
1916
1917                         if(f)
1918                         {
1919                                 switch(reticle_type)
1920                                 {
1921                                         case 1: drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_normal_alpha, DRAWFLAG_NORMAL); break;
1922                                         case 2: drawpic(reticle_pos, reticle_image, reticle_size, '1 1 1', f * autocvar_cl_reticle_weapon_alpha, DRAWFLAG_NORMAL); break;
1923                                 }
1924                         }
1925                 }
1926         }
1927         else
1928         {
1929                 if(reticle_type != 0) { reticle_type = 0; }
1930         }
1931
1932
1933         // improved polyblend
1934         if(autocvar_hud_contents)
1935         {
1936                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
1937                 vector liquidcolor;
1938
1939                 switch(pointcontents(view_origin))
1940                 {
1941                         case CONTENT_WATER:
1942                                 liquidalpha = autocvar_hud_contents_water_alpha;
1943                                 liquidcolor = stov(autocvar_hud_contents_water_color);
1944                                 incontent = 1;
1945                                 break;
1946
1947                         case CONTENT_LAVA:
1948                                 liquidalpha = autocvar_hud_contents_lava_alpha;
1949                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
1950                                 incontent = 1;
1951                                 break;
1952
1953                         case CONTENT_SLIME:
1954                                 liquidalpha = autocvar_hud_contents_slime_alpha;
1955                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
1956                                 incontent = 1;
1957                                 break;
1958
1959                         default:
1960                                 liquidalpha = 0;
1961                                 liquidcolor = '0 0 0';
1962                                 incontent = 0;
1963                                 break;
1964                 }
1965
1966                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
1967                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
1968                         contentfadetime = autocvar_hud_contents_fadeintime;
1969                         liquidalpha_prev = liquidalpha;
1970                         liquidcolor_prev = liquidcolor;
1971                 }
1972                 else
1973                         contentfadetime = autocvar_hud_contents_fadeouttime;
1974
1975                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
1976                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
1977
1978                 if(contentavgalpha)
1979                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
1980
1981                 if(autocvar_hud_postprocessing)
1982                 {
1983                         if(autocvar_hud_contents_blur && contentavgalpha)
1984                         {
1985                                 content_blurpostprocess.x = 1;
1986                                 content_blurpostprocess.y = contentavgalpha * autocvar_hud_contents_blur;
1987                                 content_blurpostprocess.z = contentavgalpha * autocvar_hud_contents_blur_alpha;
1988                         }
1989                         else
1990                         {
1991                                 content_blurpostprocess.x = 0;
1992                                 content_blurpostprocess.y = 0;
1993                                 content_blurpostprocess.z = 0;
1994                         }
1995                 }
1996         }
1997
1998         if(autocvar_hud_damage && !STAT(FROZEN))
1999         {
2000                 splash_size.x = max(vid_conwidth, vid_conheight);
2001                 splash_size.y = max(vid_conwidth, vid_conheight);
2002                 splash_pos.x = (vid_conwidth - splash_size.x) / 2;
2003                 splash_pos.y = (vid_conheight - splash_size.y) / 2;
2004
2005                 float myhealth_flash_temp;
2006                 myhealth = getstati(STAT_HEALTH);
2007
2008                 // fade out
2009                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
2010                 // add new damage
2011                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
2012
2013                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
2014                 pain_threshold = autocvar_hud_damage_pain_threshold;
2015                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
2016                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
2017
2018                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
2019                 {
2020                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
2021                 }
2022
2023                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
2024
2025                 if(myhealth_prev < 1)
2026                 {
2027                         if(myhealth >= 1)
2028                         {
2029                                 myhealth_flash = 0; // just spawned, clear the flash immediately
2030                                 myhealth_flash_temp = 0;
2031                         }
2032                         else
2033                         {
2034                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
2035                         }
2036                 }
2037
2038                 if(spectatee_status == -1 || intermission)
2039                 {
2040                         myhealth_flash = 0; // observing, or match ended
2041                         myhealth_flash_temp = 0;
2042                 }
2043
2044                 myhealth_prev = myhealth;
2045
2046                 // IDEA: change damage color/picture based on player model for robot/alien species?
2047                 // pro: matches model better
2048                 // contra: it's not red because blood is red, but because red is an alarming color, so red should stay
2049                 // maybe different reddish pics?
2050                 if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
2051                 {
2052                         if(autocvar_cl_gentle_damage == 2)
2053                         {
2054                                 if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
2055                                         myhealth_gentlergb = eX * random() + eY * random() + eZ * random();
2056                         }
2057                         else
2058                                 myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
2059
2060                         if(myhealth_flash_temp > 0)
2061                                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
2062                 }
2063                 else if(myhealth_flash_temp > 0)
2064                         drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
2065
2066                 if(autocvar_hud_postprocessing) // we still need to set this anyway even when chase_active is set, this way it doesn't get stuck on.
2067                 {
2068                         if(autocvar_hud_damage_blur && myhealth_flash_temp)
2069                         {
2070                                 damage_blurpostprocess.x = 1;
2071                                 damage_blurpostprocess.y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
2072                                 damage_blurpostprocess.z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
2073                         }
2074                         else
2075                         {
2076                                 damage_blurpostprocess.x = 0;
2077                                 damage_blurpostprocess.y = 0;
2078                                 damage_blurpostprocess.z = 0;
2079                         }
2080                 }
2081         }
2082
2083         float e1 = (autocvar_hud_postprocessing_maxbluralpha != 0);
2084         float e2 = (autocvar_hud_powerup != 0);
2085         if(autocvar_hud_postprocessing && (e1 || e2)) // TODO: Remove this code and re-do the postprocess handling in the engine, where it properly belongs.
2086         {
2087                 // enable or disable rendering types if they are used or not
2088                 if(cvar("r_glsl_postprocess_uservec1_enable") != e1) { cvar_set("r_glsl_postprocess_uservec1_enable", ftos(e1)); }
2089                 if(cvar("r_glsl_postprocess_uservec2_enable") != e2) { cvar_set("r_glsl_postprocess_uservec2_enable", ftos(e2)); }
2090
2091                 // blur postprocess handling done first (used by hud_damage and hud_contents)
2092                 if((damage_blurpostprocess.x || content_blurpostprocess.x))
2093                 {
2094                         float blurradius = bound(0, damage_blurpostprocess.y + content_blurpostprocess.y, autocvar_hud_postprocessing_maxblurradius);
2095                         float bluralpha = bound(0, damage_blurpostprocess.z + content_blurpostprocess.z, autocvar_hud_postprocessing_maxbluralpha);
2096                         if(blurradius != old_blurradius || bluralpha != old_bluralpha) // reduce cvar_set spam as much as possible
2097                         {
2098                                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
2099                                 old_blurradius = blurradius;
2100                                 old_bluralpha = bluralpha;
2101                         }
2102                 }
2103                 else if(cvar_string("r_glsl_postprocess_uservec1") != "0 0 0 0") // reduce cvar_set spam as much as possible
2104                 {
2105                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
2106                         old_blurradius = 0;
2107                         old_bluralpha = 0;
2108                 }
2109
2110                 // edge detection postprocess handling done second (used by hud_powerup)
2111                 float sharpen_intensity = 0, strength_finished = STAT(STRENGTH_FINISHED), invincible_finished = STAT(INVINCIBLE_FINISHED);
2112                 if (strength_finished - time > 0) { sharpen_intensity += (strength_finished - time); }
2113                 if (invincible_finished - time > 0) { sharpen_intensity += (invincible_finished - time); }
2114
2115                 sharpen_intensity = bound(0, ((getstati(STAT_HEALTH) > 0) ? sharpen_intensity : 0), 5); // Check to see if player is alive (if not, set 0) - also bound to fade out starting at 5 seconds.
2116
2117                 if(autocvar_hud_powerup && sharpen_intensity > 0)
2118                 {
2119                         if(sharpen_intensity != old_sharpen_intensity) // reduce cvar_set spam as much as possible
2120                         {
2121                                 cvar_set("r_glsl_postprocess_uservec2", strcat(ftos((sharpen_intensity / 5) * autocvar_hud_powerup), " ", ftos(-sharpen_intensity * autocvar_hud_powerup), " 0 0"));
2122                                 old_sharpen_intensity = sharpen_intensity;
2123                         }
2124                 }
2125                 else if(cvar_string("r_glsl_postprocess_uservec2") != "0 0 0 0") // reduce cvar_set spam as much as possible
2126                 {
2127                         cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
2128                         old_sharpen_intensity = 0;
2129                 }
2130
2131                 if(cvar("r_glsl_postprocess") == 0)
2132                         cvar_set("r_glsl_postprocess", "2");
2133         }
2134         else if(cvar("r_glsl_postprocess") == 2)
2135                 cvar_set("r_glsl_postprocess", "0");
2136
2137         /*if(gametype == MAPINFO_TYPE_CTF)
2138           {
2139           ctf_view();
2140           } else */
2141
2142         // draw 2D entities
2143         FOREACH_ENTITY(it.draw2d, LAMBDA(WITH(entity, self, it, it.draw2d(it))));
2144         Draw_ShowNames_All();
2145         Debug_Draw();
2146
2147         scoreboard_active = HUD_WouldDrawScoreboard();
2148
2149         HUD_Draw();
2150
2151         if(NextFrameCommand)
2152         {
2153                 localcmd("\n", NextFrameCommand, "\n");
2154                 NextFrameCommand = string_null;
2155         }
2156
2157         // we must do this check AFTER a frame was rendered, or it won't work
2158         if(cs_project_is_b0rked == 0)
2159         {
2160                 string w0, h0;
2161                 w0 = ftos(autocvar_vid_conwidth);
2162                 h0 = ftos(autocvar_vid_conheight);
2163                 //setproperty(VF_VIEWPORT, '0 0 0', '640 480 0');
2164                 //setproperty(VF_FOV, '90 90 0');
2165                 setproperty(VF_ORIGIN, '0 0 0');
2166                 setproperty(VF_ANGLES, '0 0 0');
2167                 setproperty(VF_PERSPECTIVE, 1);
2168                 makevectors('0 0 0');
2169                 vector v1, v2;
2170                 cvar_set("vid_conwidth", "800");
2171                 cvar_set("vid_conheight", "600");
2172                 v1 = cs_project(v_forward);
2173                 cvar_set("vid_conwidth", "640");
2174                 cvar_set("vid_conheight", "480");
2175                 v2 = cs_project(v_forward);
2176                 if(v1 == v2)
2177                         cs_project_is_b0rked = 1;
2178                 else
2179                         cs_project_is_b0rked = -1;
2180                 cvar_set("vid_conwidth", w0);
2181                 cvar_set("vid_conheight", h0);
2182         }
2183
2184         if(autocvar__hud_configure)
2185                 HUD_Panel_Mouse();
2186         else if ( HUD_MinigameMenu_IsOpened() || minigame_isactive() )
2187                 HUD_Minigame_Mouse();
2188         else if(QuickMenu_IsOpened())
2189                 QuickMenu_Mouse();
2190         else
2191                 HUD_Radar_Mouse();
2192
2193         cl_notice_run();
2194
2195         // let's reset the view back to normal for the end
2196         setproperty(VF_MIN, '0 0 0');
2197         setproperty(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
2198 }
2199
2200
2201 // following vectors must be global to allow seamless switching between camera modes
2202 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
2203 void CSQC_Demo_Camera()
2204 {
2205         float speed, attenuation, dimensions;
2206         vector tmp, delta;
2207
2208         if( autocvar_camera_reset || !camera_mode )
2209         {
2210                 camera_offset = '0 0 0';
2211                 current_angles = '0 0 0';
2212                 camera_direction = '0 0 0';
2213                 camera_offset.z += 30;
2214                 camera_offset.x += 30 * -cos(current_angles.y * DEG2RAD);
2215                 camera_offset.y += 30 * -sin(current_angles.y * DEG2RAD);
2216                 current_origin = view_origin;
2217                 current_camera_offset  = camera_offset;
2218                 cvar_set("camera_reset", "0");
2219                 camera_mode = CAMERA_CHASE;
2220         }
2221
2222         // Camera angles
2223         if( camera_roll )
2224                 mouse_angles.z += camera_roll * autocvar_camera_speed_roll;
2225
2226         if(autocvar_camera_look_player)
2227         {
2228                 vector dir;
2229                 float n;
2230
2231                 dir = normalize(view_origin - current_position);
2232                 n = mouse_angles.z;
2233                 mouse_angles = vectoangles(dir);
2234                 mouse_angles.x = mouse_angles.x * -1;
2235                 mouse_angles.z = n;
2236         }
2237         else
2238         {
2239                 tmp = getmousepos() * 0.1;
2240                 if(vlen(tmp)>autocvar_camera_mouse_threshold)
2241                 {
2242                         mouse_angles.x += tmp.y * cos(mouse_angles.z * DEG2RAD) + (tmp.x * sin(mouse_angles.z * DEG2RAD));
2243                         mouse_angles.y -= tmp.x * cos(mouse_angles.z * DEG2RAD) + (tmp.y * -sin(mouse_angles.z * DEG2RAD));
2244                 }
2245         }
2246
2247         while (mouse_angles.x < -180) mouse_angles.x = mouse_angles.x + 360;
2248         while (mouse_angles.x > 180) mouse_angles.x = mouse_angles.x - 360;
2249         while (mouse_angles.y < -180) mouse_angles.y = mouse_angles.y + 360;
2250         while (mouse_angles.y > 180) mouse_angles.y = mouse_angles.y - 360;
2251
2252         // Fix difference when angles don't have the same sign
2253         delta = '0 0 0';
2254         if(mouse_angles.y < -60 && current_angles.y > 60)
2255                 delta = '0 360 0';
2256         if(mouse_angles.y > 60 && current_angles.y < -60)
2257                 delta = '0 -360 0';
2258
2259         if(autocvar_camera_look_player)
2260                 attenuation = autocvar_camera_look_attenuation;
2261         else
2262                 attenuation = autocvar_camera_speed_attenuation;
2263
2264         attenuation = 1 / max(1, attenuation);
2265         current_angles += (mouse_angles - current_angles + delta) * attenuation;
2266
2267         while (current_angles.x < -180) current_angles.x = current_angles.x + 360;
2268         while (current_angles.x > 180) current_angles.x = current_angles.x - 360;
2269         while (current_angles.y < -180) current_angles.y = current_angles.y + 360;
2270         while (current_angles.y > 180) current_angles.y = current_angles.y - 360;
2271
2272         // Camera position
2273         tmp = '0 0 0';
2274         dimensions = 0;
2275
2276         if( camera_direction.x )
2277         {
2278                 tmp.x = camera_direction.x * cos(current_angles.y * DEG2RAD);
2279                 tmp.y = camera_direction.x * sin(current_angles.y * DEG2RAD);
2280                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
2281                         tmp.z = camera_direction.x * -sin(current_angles.x * DEG2RAD);
2282                 ++dimensions;
2283         }
2284
2285         if( camera_direction.y )
2286         {
2287                 tmp.x += camera_direction.y * -sin(current_angles.y * DEG2RAD);
2288                 tmp.y += camera_direction.y * cos(current_angles.y * DEG2RAD) * cos(current_angles.z * DEG2RAD);
2289                 tmp.z += camera_direction.y * sin(current_angles.z * DEG2RAD);
2290                 ++dimensions;
2291         }
2292
2293         if( camera_direction.z )
2294         {
2295                 tmp.z += camera_direction.z * cos(current_angles.z * DEG2RAD);
2296                 ++dimensions;
2297         }
2298
2299         if(autocvar_camera_free)
2300                 speed = autocvar_camera_speed_free;
2301         else
2302                 speed = autocvar_camera_speed_chase;
2303
2304         if(dimensions)
2305         {
2306                 speed = speed * sqrt(1 / dimensions);
2307                 camera_offset += tmp * speed;
2308         }
2309
2310         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
2311
2312         // Camera modes
2313         if( autocvar_camera_free )
2314         {
2315                 if ( camera_mode == CAMERA_CHASE )
2316                 {
2317                         current_camera_offset = current_origin + current_camera_offset;
2318                         camera_offset = current_origin + camera_offset;
2319                 }
2320
2321                 camera_mode = CAMERA_FREE;
2322                 current_position = current_camera_offset;
2323         }
2324         else
2325         {
2326                 if ( camera_mode == CAMERA_FREE )
2327                 {
2328                         current_origin = view_origin;
2329                         camera_offset = camera_offset - current_origin;
2330                         current_camera_offset = current_camera_offset - current_origin;
2331                 }
2332
2333                 camera_mode = CAMERA_CHASE;
2334
2335                 if(autocvar_camera_chase_smoothly)
2336                         current_origin += (view_origin - current_origin) * attenuation;
2337                 else
2338                         current_origin = view_origin;
2339
2340                 current_position = current_origin + current_camera_offset;
2341         }
2342
2343         setproperty(VF_ANGLES, current_angles);
2344         setproperty(VF_ORIGIN, current_position);
2345 }