qcsrc/client/view.qc

   1 #include "view.qh"
   2
   3 #include "announcer.qh"
   4 #include "hud/_mod.qh"
   5 #include "mapvoting.qh"
   6 #include "shownames.qh"
   7 #include "hud/panel/scoreboard.qh"
   8 #include "hud/panel/quickmenu.qh"
   9
  10 #include "mutators/events.qh"
  11
  12 #include <common/animdecide.qh>
  13 #include <common/ent_cs.qh>
  14 #include <common/anim.qh>
  15 #include <common/constants.qh>
  16 #include <common/debug.qh>
  17 #include <common/mapinfo.qh>
  18 #include <common/gamemodes/_mod.qh>
  19 #include <common/physics/player.qh>
  20 #include <common/stats.qh>
  21 #include <common/triggers/target/music.qh>
  22 #include <common/teams.qh>
  23
  24 #include <common/vehicles/all.qh>
  25 #include <common/weapons/_all.qh>
  26 #include <common/viewloc.qh>
  27 #include <common/minigames/cl_minigames.qh>
  28 #include <common/minigames/cl_minigames_hud.qh>
  29
  30 #include <lib/csqcmodel/cl_player.qh>
  31 #include <lib/csqcmodel/cl_model.qh>
  32 #include "csqcmodel_hooks.qh"
  33
  34 #include <lib/warpzone/client.qh>
  35 #include <lib/warpzone/common.qh>
  36
  37 #define EFMASK_CHEAP (EF_ADDITIVE | EF_DOUBLESIDED | EF_FULLBRIGHT | EF_NODEPTHTEST | EF_NODRAW | EF_NOSHADOW | EF_SELECTABLE | EF_TELEPORT_BIT)
  38
  39 float autocvar_cl_viewmodel_scale;
  40
  41 bool autocvar_cl_bobmodel;
  42 float autocvar_cl_bobmodel_speed;
  43 float autocvar_cl_bobmodel_side;
  44 float autocvar_cl_bobmodel_up;
  45
  46 float autocvar_cl_followmodel;
  47 float autocvar_cl_followmodel_speed = 0.3;
  48 float autocvar_cl_followmodel_limit = 135;
  49 float autocvar_cl_followmodel_velocity_lowpass = 0.05;
  50 float autocvar_cl_followmodel_highpass = 0.05;
  51 float autocvar_cl_followmodel_lowpass = 0.03;
  52 bool autocvar_cl_followmodel_velocity_absolute;
  53
  54 float autocvar_cl_leanmodel;
  55 float autocvar_cl_leanmodel_speed = 0.3;
  56 float autocvar_cl_leanmodel_limit = 30;
  57 float autocvar_cl_leanmodel_highpass1 = 0.2;
  58 float autocvar_cl_leanmodel_highpass = 0.2;
  59 float autocvar_cl_leanmodel_lowpass = 0.05;
  60
  61 #define avg_factor(avg_time) (1 - exp(-frametime / max(0.001, avg_time)))
  62 #define lowpass(value, frac, ref_store, ret) MACRO_BEGIN \
  63 { \
  64         ret = ref_store = ref_store * (1 - frac) + (value) * frac; \
  65 } MACRO_END
  66
  67 #define lowpass_limited(value, frac, limit, ref_store, ret) MACRO_BEGIN \
  68 { \
  69         float __ignore; lowpass(value, frac, ref_store, __ignore); \
  70         ret = ref_store = bound((value) - (limit), ref_store, (value) + (limit)); \
  71 } MACRO_END
  72
  73 #define highpass(value, frac, ref_store, ret) MACRO_BEGIN \
  74 { \
  75         float __f = 0; lowpass(value, frac, ref_store, __f); \
  76         ret = (value) - __f; \
  77 } MACRO_END
  78
  79 #define highpass_limited(value, frac, limit, ref_store, ret) MACRO_BEGIN \
  80 { \
  81         float __f = 0; lowpass_limited(value, frac, limit, ref_store, __f); \
  82         ret = (value) - __f; \
  83 } MACRO_END
  84
  85 #define lowpass2(value, frac, ref_store, ref_out) MACRO_BEGIN \
  86 { \
  87         lowpass(value.x, frac, ref_store.x, ref_out.x); \
  88         lowpass(value.y, frac, ref_store.y, ref_out.y); \
  89 } MACRO_END
  90
  91 #define highpass2(value, frac, ref_store, ref_out) MACRO_BEGIN \
  92 { \
  93         highpass(value.x, frac, ref_store.x, ref_out.x); \
  94         highpass(value.y, frac, ref_store.y, ref_out.y); \
  95 } MACRO_END
  96
  97 #define highpass2_limited(value, frac, limit, ref_store, ref_out) MACRO_BEGIN \
  98 { \
  99         highpass_limited(value.x, frac, limit, ref_store.x, ref_out.x); \
 100         highpass_limited(value.y, frac, limit, ref_store.y, ref_out.y); \
 101 } MACRO_END
 102
 103 #define lowpass3(value, frac, ref_store, ref_out) MACRO_BEGIN \
 104 { \
 105         lowpass(value.x, frac, ref_store.x, ref_out.x); \
 106         lowpass(value.y, frac, ref_store.y, ref_out.y); \
 107         lowpass(value.z, frac, ref_store.z, ref_out.z); \
 108 } MACRO_END
 109
 110 #define highpass3(value, frac, ref_store, ref_out) MACRO_BEGIN \
 111 { \
 112         highpass(value.x, frac, ref_store.x, ref_out.x); \
 113         highpass(value.y, frac, ref_store.y, ref_out.y); \
 114         highpass(value.z, frac, ref_store.z, ref_out.z); \
 115 } MACRO_END
 116
 117 void calc_followmodel_ofs(entity view)
 118 {
 119         if(cl_followmodel_time == time)
 120                 return; // cl_followmodel_ofs already calculated for this frame
 121
 122         float frac;
 123         vector gunorg = '0 0 0';
 124         static vector vel_average;
 125         static vector gunorg_prev = '0 0 0';
 126         static vector gunorg_adjustment_highpass;
 127         static vector gunorg_adjustment_lowpass;
 128
 129         vector vel;
 130         if (autocvar_cl_followmodel_velocity_absolute)
 131                 vel = view.velocity;
 132         else
 133         {
 134                 vector forward = '0 0 0', right = '0 0 0', up = '0 0 0';
 135                 MAKEVECTORS(makevectors, view_angles, forward, right, up);
 136                 vel.x = view.velocity * forward;
 137                 vel.y = view.velocity * right * -1;
 138                 vel.z = view.velocity * up;
 139         }
 140
 141         vel.x = bound(vel_average.x - autocvar_cl_followmodel_limit, vel.x, vel_average.x + autocvar_cl_followmodel_limit);
 142         vel.y = bound(vel_average.y - autocvar_cl_followmodel_limit, vel.y, vel_average.y + autocvar_cl_followmodel_limit);
 143         vel.z = bound(vel_average.z - autocvar_cl_followmodel_limit, vel.z, vel_average.z + autocvar_cl_followmodel_limit);
 144
 145         frac = avg_factor(autocvar_cl_followmodel_velocity_lowpass);
 146         lowpass3(vel, frac, vel_average, gunorg);
 147
 148         gunorg *= -autocvar_cl_followmodel_speed * 0.042;
 149
 150         // perform highpass/lowpass on the adjustment vectors (turning velocity into acceleration!)
 151         // trick: we must do the lowpass LAST, so the lowpass vector IS the final vector!
 152         frac = avg_factor(autocvar_cl_followmodel_highpass);
 153         highpass3(gunorg, frac, gunorg_adjustment_highpass, gunorg);
 154         frac = avg_factor(autocvar_cl_followmodel_lowpass);
 155         lowpass3(gunorg, frac, gunorg_adjustment_lowpass, gunorg);
 156
 157         if (autocvar_cl_followmodel_velocity_absolute)
 158         {
 159                 vector fixed_gunorg;
 160                 vector forward = '0 0 0', right = '0 0 0', up = '0 0 0';
 161                 MAKEVECTORS(makevectors, view_angles, forward, right, up);
 162                 fixed_gunorg.x = gunorg * forward;
 163                 fixed_gunorg.y = gunorg * right * -1;
 164                 fixed_gunorg.z = gunorg * up;
 165                 gunorg = fixed_gunorg;
 166         }
 167
 168         cl_followmodel_ofs = gunorg;
 169         cl_followmodel_time = time;
 170 }
 171
 172 vector leanmodel_ofs(entity view)
 173 {
 174         float frac;
 175         vector gunangles = '0 0 0';
 176         static vector gunangles_prev = '0 0 0';
 177         static vector gunangles_highpass = '0 0 0';
 178         static vector gunangles_adjustment_highpass;
 179         static vector gunangles_adjustment_lowpass;
 180
 181         if (view.csqcmodel_teleported)
 182                 gunangles_prev = view_angles;
 183
 184         // in the highpass, we _store_ the DIFFERENCE to the actual view angles...
 185         gunangles_highpass += gunangles_prev;
 186         PITCH(gunangles_highpass) += 360 * floor((PITCH(view_angles) - PITCH(gunangles_highpass)) / 360 + 0.5);
 187         YAW(gunangles_highpass) += 360 * floor((YAW(view_angles) - YAW(gunangles_highpass)) / 360 + 0.5);
 188         ROLL(gunangles_highpass) += 360 * floor((ROLL(view_angles) - ROLL(gunangles_highpass)) / 360 + 0.5);
 189         frac = avg_factor(autocvar_cl_leanmodel_highpass1);
 190         highpass2_limited(view_angles, frac, autocvar_cl_leanmodel_limit, gunangles_highpass, gunangles);
 191         gunangles_prev = view_angles;
 192         gunangles_highpass -= gunangles_prev;
 193
 194         PITCH(gunangles) *= -autocvar_cl_leanmodel_speed;
 195         YAW(gunangles) *= -autocvar_cl_leanmodel_speed;
 196
 197         // we assume here: PITCH = 0, YAW = 1, ROLL = 2
 198         frac = avg_factor(autocvar_cl_leanmodel_highpass);
 199         highpass2(gunangles, frac, gunangles_adjustment_highpass, gunangles);
 200         frac = avg_factor(autocvar_cl_leanmodel_lowpass);
 201         lowpass2(gunangles, frac, gunangles_adjustment_lowpass, gunangles);
 202
 203         gunangles.x = -gunangles.x; // pitch was inverted, now that actually matters
 204
 205         return gunangles;
 206 }
 207
 208 vector bobmodel_ofs(entity view)
 209 {
 210         bool clonground = !(view.anim_implicit_state & ANIMIMPLICITSTATE_INAIR);
 211         static bool oldonground;
 212         static float hitgroundtime;
 213         if (clonground)
 214         {
 215                 float f = time; // cl.movecmd[0].time
 216                 if (!oldonground)
 217                         hitgroundtime = f;
 218         }
 219         oldonground = clonground;
 220
 221         // calculate for swinging gun model
 222         // the gun bobs when running on the ground, but doesn't bob when you're in the air.
 223         vector gunorg = '0 0 0';
 224         static float bobmodel_scale = 0;
 225         static float time_ofs = 0; // makes the effect always restart in the same way
 226         if (clonground)
 227         {
 228                 if (time - hitgroundtime > 0.05)
 229                         bobmodel_scale = min(1, bobmodel_scale + frametime * 5);
 230         }
 231         else
 232                 bobmodel_scale = max(0, bobmodel_scale - frametime * 5);
 233
 234         float xyspeed = bound(0, vlen(vec2(view.velocity)), 400);
 235         if (bobmodel_scale && xyspeed)
 236         {
 237                 float bspeed = xyspeed * 0.01 * autocvar_cl_viewmodel_scale * bobmodel_scale;
 238                 float s = (time - time_ofs) * autocvar_cl_bobmodel_speed;
 239                 gunorg.y = bspeed * autocvar_cl_bobmodel_side * sin(s);
 240                 gunorg.z = bspeed * autocvar_cl_bobmodel_up * cos(s * 2);
 241         }
 242         else
 243                 time_ofs = time;
 244
 245         return gunorg;
 246 }
 247
 248 void viewmodel_animate(entity this)
 249 {
 250         if (autocvar_chase_active) return;
 251         if (STAT(HEALTH) <= 0) return;
 252
 253         entity view = CSQCModel_server2csqc(player_localentnum - 1);
 254
 255         if (autocvar_cl_followmodel)
 256         {
 257                 calc_followmodel_ofs(view);
 258                 this.origin += cl_followmodel_ofs;
 259         }
 260
 261         if (autocvar_cl_leanmodel)
 262                 this.angles += leanmodel_ofs(view);
 263
 264         // vertical view bobbing code
 265         // TODO: cl_bob
 266
 267         // horizontal view bobbing code
 268         // TODO: cl_bob2
 269
 270         // fall bobbing code
 271         // causes the view to swing down and back up when touching the ground
 272         // TODO: cl_bobfall
 273
 274         // gun model bobbing code
 275         if (autocvar_cl_bobmodel)
 276                 this.origin += bobmodel_ofs(view);
 277 }
 278
 279 .vector viewmodel_origin, viewmodel_angles;
 280 .float weapon_nextthink;
 281 .float weapon_eta_last;
 282 .float weapon_switchdelay;
 283
 284 .string name_last;
 285
 286 void viewmodel_draw(entity this)
 287 {
 288         if(!this.activeweapon || !autocvar_r_drawviewmodel)
 289                 return;
 290         int mask = (intermission || (STAT(HEALTH) <= 0) || autocvar_chase_active) ? 0 : MASK_NORMAL;
 291         float a = this.alpha;
 292         static bool wasinvehicle;
 293         bool invehicle = player_localentnum > maxclients;
 294         if (invehicle) a = -1;
 295         else if (wasinvehicle) a = 1;
 296         wasinvehicle = invehicle;
 297         Weapon wep = this.activeweapon;
 298         int c = entcs_GetClientColors(current_player);
 299         vector g = weaponentity_glowmod(wep, NULL, c, this);
 300         entity me = CSQCModel_server2csqc(player_localentnum - 1);
 301         int fx = ((me.csqcmodel_effects & EFMASK_CHEAP)
 302                 | EF_NODEPTHTEST)
 303                 &~ (EF_FULLBRIGHT); // can mask team color, so get rid of it
 304         for (entity e = this; e; e = e.weaponchild)
 305         {
 306                 e.drawmask = mask;
 307                 e.alpha = a;
 308                 e.colormap = 256 + c;  // colormap == 0 is black, c == 0 is white
 309                 e.glowmod = g;
 310                 e.csqcmodel_effects = fx;
 311                 CSQCModel_Effects_Apply(e);
 312         }
 313         {
 314                 string name = wep.mdl;
 315                 bool swap = name != this.name_last;
 316                 // if (swap)
 317                 {
 318                         this.name_last = name;
 319                         CL_WeaponEntity_SetModel(this, name, swap);
 320                         this.viewmodel_origin = this.origin;
 321                         this.viewmodel_angles = this.angles;
 322                 }
 323                 anim_update(this);
 324                 if (!this.animstate_override && !this.animstate_looping)
 325                         anim_set(this, this.anim_idle, true, false, false);
 326         }
 327         float f = 0; // 0..1; 0: fully active
 328         float rate = STAT(WEAPONRATEFACTOR);
 329         float eta = rate ? ((this.weapon_nextthink - time) / rate) : 0;
 330         if (eta <= 0) f = this.weapon_eta_last;
 331         else switch (this.state)
 332         {
 333                 case WS_RAISE:
 334                 {
 335                         f = eta / max(eta, this.weapon_switchdelay);
 336                         break;
 337                 }
 338                 case WS_DROP:
 339                 {
 340                         f = 1 - eta / max(eta, this.weapon_switchdelay);
 341                         break;
 342                 }
 343                 case WS_CLEAR:
 344                 {
 345                         f = 1;
 346                         break;
 347                 }
 348         }
 349         this.weapon_eta_last = f;
 350         this.origin = this.viewmodel_origin;
 351         this.angles = this.viewmodel_angles;
 352         this.angles_x = (-90 * f * f);
 353         viewmodel_animate(this);
 354         setorigin(this, this.origin);
 355 }
 356
 357 entity viewmodels[MAX_WEAPONSLOTS];
 358 STATIC_INIT(viewmodel) {
 359     for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 360         viewmodels[slot] = new(viewmodel);
 361 }
 362
 363 void Porto_Draw(entity this);
 364 STATIC_INIT(Porto)
 365 {
 366         entity e = new_pure(porto);
 367         e.draw = Porto_Draw;
 368         IL_PUSH(g_drawables, e);
 369         e.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 370 }
 371
 372 const int polyline_length = 16;
 373 .vector polyline[polyline_length];
 374 void Porto_Draw(entity this)
 375 {
 376         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 377         {
 378                 entity wepent = viewmodels[slot];
 379
 380                 if (wepent.activeweapon != WEP_PORTO) continue;
 381                 if (spectatee_status) continue;
 382                 if (WEP_CVAR(porto, secondary)) continue;
 383                 if (intermission == 1) continue;
 384                 if (intermission == 2) continue;
 385                 if (STAT(HEALTH) <= 0) continue;
 386
 387                 vector pos = view_origin;
 388                 vector dir = view_forward;
 389                 if (angles_held_status)
 390                 {
 391                         makevectors(angles_held);
 392                         dir = v_forward;
 393                 }
 394
 395                 wepent.polyline[0] = pos;
 396
 397                 int portal_number = 0, portal1_idx = 1, portal_max = 2;
 398                 int n = 1 + 2;  // 2 lines == 3 points
 399                 for (int idx = 0; idx < n && idx < polyline_length - 1; )
 400                 {
 401                         traceline(pos, pos + 65536 * dir, true, this);
 402                         dir = reflect(dir, trace_plane_normal);
 403                         pos = trace_endpos;
 404                         wepent.polyline[++idx] = pos;
 405                         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
 406                         {
 407                                 n += 1;
 408                                 continue;
 409                         }
 410                         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
 411                         {
 412                                 n = max(2, idx);
 413                                 break;
 414                         }
 415                         // check size
 416                         {
 417                                 vector ang = vectoangles2(trace_plane_normal, dir);
 418                                 ang.x = -ang.x;
 419                                 makevectors(ang);
 420                                 if (!CheckWireframeBox(this, pos - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
 421                                 {
 422                                         n = max(2, idx);
 423                                         break;
 424                                 }
 425                         }
 426                         portal_number += 1;
 427                         if (portal_number >= portal_max) break;
 428                         if (portal_number == 1) portal1_idx = idx;
 429                 }
 430                 for (int idx = 0; idx < n - 1; ++idx)
 431                 {
 432                         vector p = wepent.polyline[idx], q = wepent.polyline[idx + 1];
 433                         if (idx == 0) p -= view_up * 16;  // line from player
 434                         vector rgb = (idx < portal1_idx) ? '1 0 0' : '0 0 1';
 435                         Draw_CylindricLine(p, q, 4, "", 1, 0, rgb, 0.5, DRAWFLAG_NORMAL, view_origin);
 436                 }
 437         }
 438 }
 439
 440 float drawtime;
 441 float avgspeed;
 442 vector GetCurrentFov(float fov)
 443 {
 444         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir;
 445         float velocityzoom, curspeed;
 446         vector v;
 447
 448         zoomsensitivity = autocvar_cl_zoomsensitivity;
 449         zoomfactor = autocvar_cl_zoomfactor;
 450         if(zoomfactor < 1 || zoomfactor > 30)
 451                 zoomfactor = 2.5;
 452         zoomspeed = autocvar_cl_zoomspeed;
 453         if(zoomspeed >= 0)
 454         if(zoomspeed < 0.5 || zoomspeed > 16)
 455                         zoomspeed = 3.5;
 456
 457         zoomdir = button_zoom;
 458
 459         if(hud == HUD_NORMAL && !spectatee_status)
 460         {
 461                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 462                 {
 463                         entity wepent = viewmodels[slot];
 464                         if(wepent.switchweapon == wepent.activeweapon)
 465                         if((wepent.activeweapon == WEP_VORTEX && !WEP_CVAR(vortex, secondary)) || (wepent.activeweapon == WEP_RIFLE && !WEP_CVAR(rifle, secondary))) // do NOT use switchweapon here
 466                                 zoomdir += button_attack2;
 467                 }
 468         }
 469         if(spectatee_status > 0 || isdemo())
 470         {
 471                 if(spectatorbutton_zoom)
 472                 {
 473                         if(zoomdir)
 474                                 zoomdir = 0;
 475                         else
 476                                 zoomdir = 1;
 477                 }
 478                 // fteqcc failed twice here already, don't optimize this
 479         }
 480
 481         if(zoomdir) { zoomin_effect = 0; }
 482
 483         if(camera_active)
 484         {
 485                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 486         }
 487         else if(autocvar_cl_spawnzoom && zoomin_effect)
 488         {
 489                 float spawnzoomfactor = bound(1, autocvar_cl_spawnzoom_factor, 30);
 490
 491                 current_viewzoom += (autocvar_cl_spawnzoom_speed * (spawnzoomfactor - current_viewzoom) * drawframetime);
 492                 current_viewzoom = bound(1 / spawnzoomfactor, current_viewzoom, 1);
 493                 if(current_viewzoom == 1) { zoomin_effect = 0; }
 494         }
 495         else
 496         {
 497                 if(zoomspeed < 0) // instant zoom
 498                 {
 499                         if(zoomdir)
 500                                 current_viewzoom = 1 / zoomfactor;
 501                         else
 502                                 current_viewzoom = 1;
 503                 }
 504                 else
 505                 {
 506                         if(zoomdir)
 507                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 508                         else
 509                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 510                 }
 511         }
 512
 513         if(almost_equals(current_viewzoom, 1))
 514                 current_zoomfraction = 0;
 515         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 516                 current_zoomfraction = 1;
 517         else
 518                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 519
 520         if(zoomsensitivity < 1)
 521                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
 522         else
 523                 setsensitivityscale(1);
 524
 525         if(autocvar_cl_velocityzoom_enabled && autocvar_cl_velocityzoom_type) // _type = 0 disables velocity zoom too
 526         {
 527                 if(intermission) { curspeed = 0; }
 528                 else
 529                 {
 530
 531                         makevectors(view_angles);
 532                         v = pmove_vel;
 533                         if(csqcplayer)
 534                                 v = csqcplayer.velocity;
 535
 536                         switch(autocvar_cl_velocityzoom_type)
 537                         {
 538                                 case 3: curspeed = max(0, v_forward * v); break;
 539                                 case 2: curspeed = (v_forward * v); break;
 540                                 case 1: default: curspeed = vlen(v); break;
 541                         }
 542                 }
 543
 544                 velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoom_time), 1); // speed at which the zoom adapts to player velocity
 545                 avgspeed = avgspeed * (1 - velocityzoom) + (curspeed / autocvar_cl_velocityzoom_speed) * velocityzoom;
 546                 velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom_factor / 1) * 1);
 547
 548                 //print(ftos(avgspeed), " avgspeed, ", ftos(curspeed), " curspeed, ", ftos(velocityzoom), " return\n"); // for debugging
 549         }
 550         else
 551                 velocityzoom = 1;
 552
 553         float frustumx, frustumy, fovx, fovy;
 554         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 555         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 556         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 557         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 558
 559         return '1 0 0' * fovx + '0 1 0' * fovy;
 560 }
 561
 562 vector GetViewLocationFOV(float fov)
 563 {
 564         float frustumy = tan(fov * M_PI / 360.0) * 0.75;
 565         float frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 566         float fovx = atan2(frustumx, 1) / M_PI * 360.0;
 567         float fovy = atan2(frustumy, 1) / M_PI * 360.0;
 568         return '1 0 0' * fovx + '0 1 0' * fovy;
 569 }
 570
 571 vector GetOrthoviewFOV(vector ov_worldmin, vector ov_worldmax, vector ov_mid, vector ov_org)
 572 {
 573         float fovx, fovy;
 574         float width = (ov_worldmax.x - ov_worldmin.x);
 575         float height = (ov_worldmax.y - ov_worldmin.y);
 576         float distance_to_middle_of_world = vlen(ov_mid - ov_org);
 577         fovx = atan2(width/2, distance_to_middle_of_world) / M_PI * 360.0;
 578         fovy = atan2(height/2, distance_to_middle_of_world) / M_PI * 360.0;
 579         return '1 0 0' * fovx + '0 1 0' * fovy;
 580 }
 581
 582 // this function must match W_SetupShot!
 583 float zoomscript_caught;
 584
 585 vector wcross_origin;
 586 float wcross_scale_prev, wcross_alpha_prev;
 587 vector wcross_color_prev;
 588 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 589 vector wcross_color_goal_prev;
 590 float wcross_changedonetime;
 591
 592 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 593 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 594 float wcross_name_changestarttime, wcross_name_changedonetime;
 595 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 596
 597 float wcross_ring_prev;
 598
 599 entity trueaim;
 600 entity trueaim_rifle;
 601
 602 const float SHOTTYPE_HITTEAM = 1;
 603 const float SHOTTYPE_HITOBSTRUCTION = 2;
 604 const float SHOTTYPE_HITWORLD = 3;
 605 const float SHOTTYPE_HITENEMY = 4;
 606
 607 void TrueAim_Init()
 608 {
 609         (trueaim = new_pure(trueaim)).dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 610         (trueaim_rifle = new_pure(trueaim_rifle)).dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 611 }
 612
 613 float EnemyHitCheck()
 614 {
 615         float t, n;
 616         wcross_origin = project_3d_to_2d(trace_endpos);
 617         wcross_origin.z = 0;
 618         if(trace_ent)
 619                 n = trace_ent.entnum;
 620         else
 621                 n = trace_networkentity;
 622         if(n < 1)
 623                 return SHOTTYPE_HITWORLD;
 624         if(n > maxclients)
 625                 return SHOTTYPE_HITWORLD;
 626         t = entcs_GetTeam(n - 1);
 627         if(teamplay)
 628                 if(t == myteam)
 629                         return SHOTTYPE_HITTEAM;
 630         if(t == NUM_SPECTATOR)
 631                 return SHOTTYPE_HITWORLD;
 632         return SHOTTYPE_HITENEMY;
 633 }
 634
 635 float TrueAimCheck(entity wepent)
 636 {
 637         float nudge = 1; // added to traceline target and subtracted from result TOOD(divVerent): do we still need this? Doesn't the engine do this now for us?
 638         vector vecs, trueaimpoint, w_shotorg;
 639         vector mi, ma, dv;
 640         float shottype;
 641         entity ta;
 642         float mv;
 643
 644         mi = ma = '0 0 0';
 645         ta = trueaim;
 646         mv = MOVE_NOMONSTERS;
 647
 648         switch(wepent.activeweapon) // WEAPONTODO
 649         {
 650                 case WEP_TUBA: // no aim
 651                 case WEP_PORTO: // shoots from eye
 652                 case WEP_NEXBALL: // shoots from eye
 653                 case WEP_HOOK: // no trueaim
 654                 case WEP_MORTAR: // toss curve
 655                         return SHOTTYPE_HITWORLD;
 656                 case WEP_VORTEX:
 657                 case WEP_VAPORIZER:
 658                         mv = MOVE_NORMAL;
 659                         break;
 660                 case WEP_RIFLE:
 661                         ta = trueaim_rifle;
 662                         mv = MOVE_NORMAL;
 663                         if(zoomscript_caught)
 664                         {
 665                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 666                                 return EnemyHitCheck();
 667                         }
 668                         break;
 669                 case WEP_DEVASTATOR: // projectile has a size!
 670                         mi = '-3 -3 -3';
 671                         ma = '3 3 3';
 672                         break;
 673                 case WEP_FIREBALL: // projectile has a size!
 674                         mi = '-16 -16 -16';
 675                         ma = '16 16 16';
 676                         break;
 677                 case WEP_SEEKER: // projectile has a size!
 678                         mi = '-2 -2 -2';
 679                         ma = '2 2 2';
 680                         break;
 681                 case WEP_ELECTRO: // projectile has a size!
 682                         mi = '0 0 -3';
 683                         ma = '0 0 -3';
 684                         break;
 685         }
 686
 687         vector traceorigin = entcs_receiver(player_localentnum - 1).origin + (eZ * STAT(VIEWHEIGHT));
 688
 689         vecs = decompressShotOrigin(STAT(SHOTORG));
 690
 691         traceline(traceorigin, traceorigin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 692         trueaimpoint = trace_endpos;
 693
 694         if(vdist((trueaimpoint - traceorigin), <, g_trueaim_minrange))
 695                 trueaimpoint = traceorigin + view_forward * g_trueaim_minrange;
 696
 697         if(vecs.x > 0)
 698                 vecs.y = -vecs.y;
 699         else
 700                 vecs = '0 0 0';
 701
 702         dv = view_right * vecs.y + view_up * vecs.z;
 703         w_shotorg = traceorigin + dv;
 704
 705         // now move the vecs forward as much as requested if possible
 706         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs.x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 707         w_shotorg = trace_endpos - view_forward * nudge;
 708
 709         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 710         shottype = EnemyHitCheck();
 711         if(shottype != SHOTTYPE_HITWORLD)
 712                 return shottype;
 713
 714 #if 0
 715         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 716         // or rather, I know why, but see no fix
 717         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 718                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 719                 return SHOTTYPE_HITOBSTRUCTION;
 720 #endif
 721
 722         return SHOTTYPE_HITWORLD;
 723 }
 724
 725 void PostInit();
 726 void CSQC_Demo_Camera();
 727 float camera_mode;
 728 const float CAMERA_FREE = 1;
 729 const float CAMERA_CHASE = 2;
 730 float reticle_type;
 731 string NextFrameCommand;
 732
 733 vector freeze_org, freeze_ang;
 734 entity nightvision_noise, nightvision_noise2;
 735
 736 const float MAX_TIME_DIFF = 5;
 737 float pickup_crosshair_time, pickup_crosshair_size;
 738 float hitindication_crosshair_size;
 739 float use_vortex_chargepool;
 740
 741 float myhealth, myhealth_prev;
 742 float myhealth_flash;
 743
 744 float old_blurradius, old_bluralpha;
 745 float old_sharpen_intensity;
 746
 747 vector myhealth_gentlergb;
 748
 749 float contentavgalpha, liquidalpha_prev;
 750 vector liquidcolor_prev;
 751
 752 float eventchase_current_distance;
 753 float eventchase_running;
 754 bool WantEventchase(entity this)
 755 {
 756         if(autocvar_cl_orthoview)
 757                 return false;
 758         if(intermission)
 759                 return true;
 760         if(this.viewloc)
 761                 return true;
 762         if(spectatee_status >= 0)
 763         {
 764                 if(hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0))
 765                         return true;
 766                 if(MUTATOR_CALLHOOK(WantEventchase, this))
 767                         return true;
 768                 if(autocvar_cl_eventchase_death && (STAT(HEALTH) <= 0))
 769                 {
 770                         if(autocvar_cl_eventchase_death == 2)
 771                         {
 772                                 // don't stop eventchase once it's started (even if velocity changes afterwards)
 773                                 if(this.velocity == '0 0 0' || eventchase_running)
 774                                         return true;
 775                         }
 776                         else return true;
 777                 }
 778         }
 779         return false;
 780 }
 781
 782 void HUD_Crosshair_Vehicle(entity this)
 783 {
 784         if(hud != HUD_BUMBLEBEE_GUN)
 785         {
 786                 Vehicle info = Vehicles_from(hud);
 787                 info.vr_crosshair(info, this);
 788         }
 789 }
 790
 791 vector damage_blurpostprocess, content_blurpostprocess;
 792
 793 float unaccounted_damage = 0;
 794 void UpdateDamage()
 795 {
 796         // accumulate damage with each stat update
 797         static float damage_total_prev = 0;
 798         float damage_total = STAT(DAMAGE_DEALT_TOTAL);
 799         float unaccounted_damage_new = COMPARE_INCREASING(damage_total, damage_total_prev);
 800         damage_total_prev = damage_total;
 801
 802         static float damage_dealt_time_prev = 0;
 803         float damage_dealt_time = STAT(HIT_TIME);
 804         if (damage_dealt_time != damage_dealt_time_prev)
 805         {
 806                 unaccounted_damage += unaccounted_damage_new;
 807                 LOG_TRACE("dmg total: ", ftos(unaccounted_damage), " (+", ftos(unaccounted_damage_new), ")");
 808         }
 809         damage_dealt_time_prev = damage_dealt_time;
 810
 811         // prevent hitsound when switching spectatee
 812         static float spectatee_status_prev = 0;
 813         if (spectatee_status != spectatee_status_prev)
 814                 unaccounted_damage = 0;
 815         spectatee_status_prev = spectatee_status;
 816 }
 817
 818 void HitSound()
 819 {
 820         // varying sound pitch
 821
 822         bool have_arc = false;
 823         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 824         {
 825                 entity wepent = viewmodels[slot];
 826
 827                 if(wepent.activeweapon == WEP_ARC)
 828                         have_arc = true;
 829         }
 830
 831         static float hitsound_time_prev = 0;
 832         // HACK: the only way to get the arc to sound consistent with pitch shift is to ignore cl_hitsound_antispam_time
 833         bool arc_hack = have_arc && autocvar_cl_hitsound >= 2;
 834         if (arc_hack || COMPARE_INCREASING(time, hitsound_time_prev) > autocvar_cl_hitsound_antispam_time)
 835         {
 836                 if (autocvar_cl_hitsound && unaccounted_damage)
 837                 {
 838                         // customizable gradient function that crosses (0,a), (c,1) and asymptotically approaches b
 839                         float a = autocvar_cl_hitsound_max_pitch;
 840                         float b = autocvar_cl_hitsound_min_pitch;
 841                         float c = autocvar_cl_hitsound_nom_damage;
 842                         float x = unaccounted_damage;
 843                         float pitch_shift = (b*x*(a-1) + a*c*(1-b)) / (x*(a-1) + c*(1-b));
 844
 845                         // if sound variation is disabled, set pitch_shift to 1
 846                         if (autocvar_cl_hitsound == 1)
 847                                 pitch_shift = 1;
 848
 849                         // if pitch shift is reversed, mirror in (max-min)/2 + min
 850                         if (autocvar_cl_hitsound == 3)
 851                         {
 852                                 float mirror_value = (a-b)/2 + b;
 853                                 pitch_shift = mirror_value + (mirror_value - pitch_shift);
 854                         }
 855
 856                         LOG_TRACE("dmg total (dmg): ", ftos(unaccounted_damage), " , pitch shift: ", ftos(pitch_shift));
 857
 858                         // todo: avoid very long and very short sounds from wave stretching using different sound files? seems unnecessary
 859                         // todo: normalize sound pressure levels? seems unnecessary
 860
 861                         sound7(NULL, CH_INFO, SND(HIT), VOL_BASE, ATTN_NONE, pitch_shift * 100, 0);
 862                 }
 863                 unaccounted_damage = 0;
 864                 hitsound_time_prev = time;
 865         }
 866
 867         static float typehit_time_prev = 0;
 868         float typehit_time = STAT(TYPEHIT_TIME);
 869         if (COMPARE_INCREASING(typehit_time, typehit_time_prev) > autocvar_cl_hitsound_antispam_time)
 870         {
 871                 sound(NULL, CH_INFO, SND_TYPEHIT, VOL_BASE, ATTN_NONE);
 872                 typehit_time_prev = typehit_time;
 873         }
 874 }
 875
 876 vector crosshair_getcolor(entity this, float health_stat)
 877 {
 878         static float rainbow_last_flicker;
 879         static vector rainbow_prev_color;
 880         vector wcross_color = '0 0 0';
 881         switch(autocvar_crosshair_color_special)
 882         {
 883                 case 1: // crosshair_color_per_weapon
 884                 {
 885                         if(this != WEP_Null && hud == HUD_NORMAL)
 886                         {
 887                                 wcross_color = this.wpcolor;
 888                                 break;
 889                         }
 890                         else { goto normalcolor; }
 891                 }
 892
 893                 case 2: // crosshair_color_by_health
 894                 {
 895                         float x = health_stat;
 896
 897                         //x = red
 898                         //y = green
 899                         //z = blue
 900
 901                         wcross_color.z = 0;
 902
 903                         if(x > 200)
 904                         {
 905                                 wcross_color.x = 0;
 906                                 wcross_color.y = 1;
 907                         }
 908                         else if(x > 150)
 909                         {
 910                                 wcross_color.x = 0.4 - (x-150)*0.02 * 0.4;
 911                                 wcross_color.y = 0.9 + (x-150)*0.02 * 0.1;
 912                         }
 913                         else if(x > 100)
 914                         {
 915                                 wcross_color.x = 1 - (x-100)*0.02 * 0.6;
 916                                 wcross_color.y = 1 - (x-100)*0.02 * 0.1;
 917                                 wcross_color.z = 1 - (x-100)*0.02;
 918                         }
 919                         else if(x > 50)
 920                         {
 921                                 wcross_color.x = 1;
 922                                 wcross_color.y = 1;
 923                                 wcross_color.z = 0.2 + (x-50)*0.02 * 0.8;
 924                         }
 925                         else if(x > 20)
 926                         {
 927                                 wcross_color.x = 1;
 928                                 wcross_color.y = (x-20)*90/27/100;
 929                                 wcross_color.z = (x-20)*90/27/100 * 0.2;
 930                         }
 931                         else
 932                         {
 933                                 wcross_color.x = 1;
 934                                 wcross_color.y = 0;
 935                         }
 936                         break;
 937                 }
 938
 939                 case 3: // crosshair_color_rainbow
 940                 {
 941                         if(time >= rainbow_last_flicker)
 942                         {
 943                                 rainbow_prev_color = randomvec() * autocvar_crosshair_color_special_rainbow_brightness;
 944                                 rainbow_last_flicker = time + autocvar_crosshair_color_special_rainbow_delay;
 945                         }
 946                         wcross_color = rainbow_prev_color;
 947                         break;
 948                 }
 949 LABEL(normalcolor)
 950                 default: { wcross_color = stov(autocvar_crosshair_color); break; }
 951         }
 952
 953         return wcross_color;
 954 }
 955
 956 void HUD_Crosshair(entity this)
 957 {
 958         float f, i, j;
 959         vector v;
 960         if(!scoreboard_active && !camera_active && intermission != 2 &&
 961                 spectatee_status != -1 && !csqcplayer.viewloc && !MUTATOR_CALLHOOK(DrawCrosshair) &&
 962                 !HUD_MinigameMenu_IsOpened() )
 963         {
 964                 if (!autocvar_crosshair_enabled) // main toggle for crosshair rendering
 965                         return;
 966
 967                 if (spectatee_status > 0 && STAT(CAMERA_SPECTATOR) == 2)
 968                         return;
 969
 970                 if (hud != HUD_NORMAL)
 971                 {
 972                         HUD_Crosshair_Vehicle(this);
 973                         return;
 974                 }
 975
 976                 string wcross_style;
 977                 float wcross_alpha, wcross_resolution;
 978                 wcross_style = autocvar_crosshair;
 979                 if (wcross_style == "0")
 980                         return;
 981                 wcross_resolution = autocvar_crosshair_size;
 982                 if (wcross_resolution == 0)
 983                         return;
 984                 wcross_alpha = autocvar_crosshair_alpha;
 985                 if (wcross_alpha == 0)
 986                         return;
 987
 988                 // TrueAim check
 989                 float shottype;
 990
 991                 // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
 992                 wcross_origin = project_3d_to_2d(view_origin + MAX_SHOT_DISTANCE * view_forward);
 993                 wcross_origin.z = 0;
 994                 if(autocvar_crosshair_hittest)
 995                 {
 996                         vector wcross_oldorigin;
 997                         entity thiswep = viewmodels[0]; // TODO: unhardcode
 998                         wcross_oldorigin = wcross_origin;
 999                         shottype = TrueAimCheck(thiswep);
1000                         if(shottype == SHOTTYPE_HITWORLD)
1001                         {
1002                                 v = wcross_origin - wcross_oldorigin;
1003                                 v.x /= vid_conwidth;
1004                                 v.y /= vid_conheight;
1005                                 if(vdist(v, >, 0.01))
1006                                         shottype = SHOTTYPE_HITOBSTRUCTION;
1007                         }
1008                         if(!autocvar_crosshair_hittest_showimpact)
1009                                 wcross_origin = wcross_oldorigin;
1010                 }
1011                 else
1012                         shottype = SHOTTYPE_HITWORLD;
1013
1014                 vector wcross_color = '0 0 0', wcross_size = '0 0 0';
1015                 string wcross_name = "";
1016                 float wcross_scale, wcross_blur;
1017
1018         entity e = WEP_Null;
1019                 if(autocvar_crosshair_per_weapon || (autocvar_crosshair_color_special == 1))
1020                 {
1021                         entity wepent = viewmodels[0]; // TODO: unhardcode
1022                         e = wepent.switchingweapon;
1023                         if(e)
1024                         {
1025                                 if(autocvar_crosshair_per_weapon)
1026                                 {
1027                                         // WEAPONTODO: access these through some general settings (with non-balance config settings)
1028                                         //wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
1029                                         //if (wcross_resolution == 0)
1030                                                 //return;
1031
1032                                         //wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
1033                                         wcross_resolution *= e.w_crosshair_size;
1034                                         wcross_name = e.w_crosshair;
1035                                 }
1036                         }
1037                 }
1038
1039                 if(wcross_name == "")
1040                         wcross_name = strcat("gfx/crosshair", wcross_style);
1041
1042                 // MAIN CROSSHAIR COLOR DECISION
1043                 wcross_color = crosshair_getcolor(e, STAT(HEALTH));
1044
1045                 if(autocvar_crosshair_effect_scalefade)
1046                 {
1047                         wcross_scale = wcross_resolution;
1048                         wcross_resolution = 1;
1049                 }
1050                 else
1051                 {
1052                         wcross_scale = 1;
1053                 }
1054
1055                 if(autocvar_crosshair_pickup)
1056                 {
1057                         float stat_pickup_time = STAT(LAST_PICKUP);
1058
1059                         if(pickup_crosshair_time < stat_pickup_time)
1060                         {
1061                                 if(time - stat_pickup_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1062                                         pickup_crosshair_size = 1;
1063
1064                                 pickup_crosshair_time = stat_pickup_time;
1065                         }
1066
1067                         if(pickup_crosshair_size > 0)
1068                                 pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
1069                         else
1070                                 pickup_crosshair_size = 0;
1071
1072                         wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
1073                 }
1074
1075                 // todo: make crosshair hit indication dependent on damage dealt
1076                 if(autocvar_crosshair_hitindication)
1077                 {
1078                         vector hitindication_color = ((autocvar_crosshair_color_special == 1) ? stov(autocvar_crosshair_hitindication_per_weapon_color) : stov(autocvar_crosshair_hitindication_color));
1079
1080                         if(unaccounted_damage)
1081                         {
1082                                 hitindication_crosshair_size = 1;
1083                         }
1084
1085                         if(hitindication_crosshair_size > 0)
1086                                 hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
1087                         else
1088                                 hitindication_crosshair_size = 0;
1089
1090                         wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
1091                         wcross_color.x += sin(hitindication_crosshair_size) * hitindication_color.x;
1092                         wcross_color.y += sin(hitindication_crosshair_size) * hitindication_color.y;
1093                         wcross_color.z += sin(hitindication_crosshair_size) * hitindication_color.z;
1094                 }
1095
1096                 if(shottype == SHOTTYPE_HITENEMY)
1097                         wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
1098                 if(shottype == SHOTTYPE_HITTEAM)
1099                         wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
1100
1101                 f = fabs(autocvar_crosshair_effect_time);
1102                 if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
1103                 {
1104                         wcross_changedonetime = time + f;
1105                 }
1106                 if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
1107                 {
1108                         wcross_name_changestarttime = time;
1109                         wcross_name_changedonetime = time + f;
1110                         if(wcross_name_goal_prev_prev)
1111                                 strunzone(wcross_name_goal_prev_prev);
1112                         wcross_name_goal_prev_prev = wcross_name_goal_prev;
1113                         wcross_name_goal_prev = strzone(wcross_name);
1114                         wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
1115                         wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
1116                         wcross_resolution_goal_prev = wcross_resolution;
1117                 }
1118
1119                 wcross_scale_goal_prev = wcross_scale;
1120                 wcross_alpha_goal_prev = wcross_alpha;
1121                 wcross_color_goal_prev = wcross_color;
1122
1123                 if(spectatee_status == -1 && shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
1124                 {
1125                         wcross_blur = 1;
1126                         wcross_alpha *= 0.75;
1127                 }
1128                 else
1129                         wcross_blur = 0;
1130                 // *_prev is at time-frametime
1131                 // * is at wcross_changedonetime+f
1132                 // what do we have at time?
1133                 if(time < wcross_changedonetime)
1134                 {
1135                         f = frametime / (wcross_changedonetime - time + frametime);
1136                         wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
1137                         wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
1138                         wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
1139                 }
1140
1141                 wcross_scale_prev = wcross_scale;
1142                 wcross_alpha_prev = wcross_alpha;
1143                 wcross_color_prev = wcross_color;
1144
1145                 MUTATOR_CALLHOOK(UpdateCrosshair);
1146
1147                 wcross_scale *= 1 - autocvar__menu_alpha;
1148                 wcross_alpha *= 1 - autocvar__menu_alpha;
1149                 wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1150
1151                 if(wcross_scale >= 0.001 && wcross_alpha >= 0.001)
1152                 {
1153                         // crosshair rings for weapon stats
1154                         if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
1155                         {
1156                                 // declarations and stats
1157                                 float ring_value = 0, ring_scale = 0, ring_alpha = 0, ring_inner_value = 0, ring_inner_alpha = 0;
1158                                 string ring_image = string_null, ring_inner_image = string_null;
1159                                 vector ring_rgb = '0 0 0', ring_inner_rgb = '0 0 0';
1160
1161                                 ring_scale = autocvar_crosshair_ring_size;
1162
1163                                 float weapon_clipload, weapon_clipsize;
1164                                 weapon_clipload = STAT(WEAPON_CLIPLOAD);
1165                                 weapon_clipsize = STAT(WEAPON_CLIPSIZE);
1166
1167                                 float vortex_charge, vortex_chargepool;
1168                                 vortex_charge = STAT(VORTEX_CHARGE);
1169                                 vortex_chargepool = STAT(VORTEX_CHARGEPOOL);
1170
1171                                 float arc_heat = STAT(ARC_HEAT);
1172
1173                                 if(vortex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
1174                                         vortex_charge_movingavg = vortex_charge;
1175
1176                                 entity wepent = viewmodels[0]; // TODO: unhardcode
1177
1178                                 // handle the values
1179                                 if (autocvar_crosshair_ring && wepent.activeweapon == WEP_VORTEX && vortex_charge && autocvar_crosshair_ring_vortex) // ring around crosshair representing velocity-dependent damage for the vortex
1180                                 {
1181                                         if (vortex_chargepool || use_vortex_chargepool) {
1182                                                 use_vortex_chargepool = 1;
1183                                                 ring_inner_value = vortex_chargepool;
1184                                         } else {
1185                                                 vortex_charge_movingavg = (1 - autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate) * vortex_charge_movingavg + autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate * vortex_charge;
1186                                                 ring_inner_value = bound(0, autocvar_crosshair_ring_vortex_currentcharge_scale * (vortex_charge - vortex_charge_movingavg), 1);
1187                                         }
1188
1189                                         ring_inner_alpha = autocvar_crosshair_ring_vortex_inner_alpha;
1190                                         ring_inner_rgb = eX * autocvar_crosshair_ring_vortex_inner_color_red + eY * autocvar_crosshair_ring_vortex_inner_color_green + eZ * autocvar_crosshair_ring_vortex_inner_color_blue;
1191                                         ring_inner_image = "gfx/crosshair_ring_inner.tga";
1192
1193                                         // draw the outer ring to show the current charge of the weapon
1194                                         ring_value = vortex_charge;
1195                                         ring_alpha = autocvar_crosshair_ring_vortex_alpha;
1196                                         ring_rgb = wcross_color;
1197                                         ring_image = "gfx/crosshair_ring_nexgun.tga";
1198                                 }
1199                                 else if (autocvar_crosshair_ring && wepent.activeweapon == WEP_MINE_LAYER && WEP_CVAR(minelayer, limit) && autocvar_crosshair_ring_minelayer)
1200                                 {
1201                                         ring_value = bound(0, STAT(LAYED_MINES) / WEP_CVAR(minelayer, limit), 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
1202                                         ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
1203                                         ring_rgb = wcross_color;
1204                                         ring_image = "gfx/crosshair_ring.tga";
1205                                 }
1206                                 else if (wepent.activeweapon == WEP_HAGAR && STAT(HAGAR_LOAD) && autocvar_crosshair_ring_hagar)
1207                                 {
1208                                         ring_value = bound(0, STAT(HAGAR_LOAD) / WEP_CVAR_SEC(hagar, load_max), 1);
1209                                         ring_alpha = autocvar_crosshair_ring_hagar_alpha;
1210                                         ring_rgb = wcross_color;
1211                                         ring_image = "gfx/crosshair_ring.tga";
1212                                 }
1213                                 else if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
1214                                 {
1215                                         ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
1216                                         ring_scale = autocvar_crosshair_ring_reload_size;
1217                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
1218                                         ring_rgb = wcross_color;
1219
1220                                         // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
1221                                         // if a new image for another weapon is added, add the code (and its respective file/value) here
1222                                         if ((wepent.activeweapon == WEP_RIFLE) && (weapon_clipsize == 80))
1223                                                 ring_image = "gfx/crosshair_ring_rifle.tga";
1224                                         else
1225                                                 ring_image = "gfx/crosshair_ring.tga";
1226                                 }
1227                                 else if ( autocvar_crosshair_ring && autocvar_crosshair_ring_arc && arc_heat && wepent.activeweapon == WEP_ARC )
1228                                 {
1229                                         ring_value = arc_heat;
1230                                         ring_alpha = (1-arc_heat)*autocvar_crosshair_ring_arc_cold_alpha +
1231                                                 arc_heat*autocvar_crosshair_ring_arc_hot_alpha;
1232                                         ring_rgb = (1-arc_heat)*wcross_color + arc_heat*autocvar_crosshair_ring_arc_hot_color;
1233                                         ring_image = "gfx/crosshair_ring.tga";
1234                                 }
1235
1236                                 // if in weapon switch animation, fade ring out/in
1237                                 if(autocvar_crosshair_effect_time > 0)
1238                                 {
1239                                         f = (time - wcross_name_changestarttime) / autocvar_crosshair_effect_time;
1240                                         if (f >= 1)
1241                                         {
1242                                                 wcross_ring_prev = ((ring_image) ? true : false);
1243                                         }
1244
1245                                         if(wcross_ring_prev)
1246                                         {
1247                                                 if(f < 1)
1248                                                         ring_alpha *= fabs(1 - bound(0, f, 1));
1249                                         }
1250                                         else
1251                                         {
1252                                                 if(f < 1)
1253                                                         ring_alpha *= bound(0, f, 1);
1254                                         }
1255                                 }
1256
1257                                 if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
1258                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
1259
1260                                 if (ring_value)
1261                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
1262                         }
1263
1264 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
1265                         MACRO_BEGIN { \
1266                                 if(wcross_blur > 0) \
1267                                 { \
1268                                         for(i = -2; i <= 2; ++i) \
1269                                         for(j = -2; j <= 2; ++j) \
1270                                         M(i,j,sz,wcross_name,wcross_alpha*0.04); \
1271                                 } \
1272                                 else \
1273                                 { \
1274                                         M(0,0,sz,wcross_name,wcross_alpha); \
1275                                 } \
1276                         } MACRO_END
1277
1278 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
1279                         drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size.x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size.y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
1280
1281 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
1282                         CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
1283
1284                         if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
1285                         {
1286                                 f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
1287                                 wcross_size = draw_getimagesize(wcross_name_goal_prev_prev) * wcross_scale;
1288                                 CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
1289                                 f = 1 - f;
1290                         }
1291                         else
1292                         {
1293                                 f = 1;
1294                         }
1295                         wcross_name_alpha_goal_prev = f;
1296
1297                         wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1298                         CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
1299
1300                         if(autocvar_crosshair_dot)
1301                         {
1302                                 vector wcross_color_old;
1303                                 wcross_color_old = wcross_color;
1304
1305                                 if((autocvar_crosshair_dot_color_custom) && (autocvar_crosshair_dot_color != "0"))
1306                                         wcross_color = stov(autocvar_crosshair_dot_color);
1307
1308                                 CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
1309                                 // FIXME why don't we use wcross_alpha here?
1310                                 wcross_color = wcross_color_old;
1311                         }
1312                 }
1313         }
1314         else
1315         {
1316                 wcross_scale_prev = 0;
1317                 wcross_alpha_prev = 0;
1318                 wcross_scale_goal_prev = 0;
1319                 wcross_alpha_goal_prev = 0;
1320                 wcross_changedonetime = 0;
1321                 if(wcross_name_goal_prev)
1322                         strunzone(wcross_name_goal_prev);
1323                 wcross_name_goal_prev = string_null;
1324                 if(wcross_name_goal_prev_prev)
1325                         strunzone(wcross_name_goal_prev_prev);
1326                 wcross_name_goal_prev_prev = string_null;
1327                 wcross_name_changestarttime = 0;
1328                 wcross_name_changedonetime = 0;
1329                 wcross_name_alpha_goal_prev = 0;
1330                 wcross_name_alpha_goal_prev_prev = 0;
1331                 wcross_resolution_goal_prev = 0;
1332                 wcross_resolution_goal_prev_prev = 0;
1333         }
1334 }
1335
1336 void HUD_Draw(entity this)
1337 {
1338         // if we don't know gametype and scores yet avoid drawing the scoreboard
1339         // also in the very first frames, player state may be inconsistent so avoid drawing the hud at all
1340         // e.g. since initial player's health is 0 hud would display the hud_damage effect,
1341         // cl_deathscoreboard would show the scoreboard and so on
1342         if(!gametype)
1343                 return;
1344
1345         if(!intermission)
1346         if (MUTATOR_CALLHOOK(HUD_Draw_overlay))
1347         {
1348                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, M_ARGV(0, vector), autocvar_hud_colorflash_alpha * M_ARGV(1, float), DRAWFLAG_ADDITIVE);
1349         }
1350         else if(STAT(FROZEN))
1351         {
1352                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, ((STAT(REVIVE_PROGRESS)) ? ('0.25 0.90 1' + ('1 0 0' * STAT(REVIVE_PROGRESS)) + ('0 1 1' * STAT(REVIVE_PROGRESS) * -1)) : '0.25 0.90 1'), autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1353         }
1354         if(!intermission)
1355         if(STAT(NADE_TIMER) && autocvar_cl_nade_timer) // give nade top priority, as it's a matter of life and death
1356         {
1357                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(NADE_TIMER), '0.25 0.90 1' + ('1 0 0' * STAT(NADE_TIMER)) - ('0 1 1' * STAT(NADE_TIMER)), autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1358                 drawstring_aspect(eY * 0.64 * vid_conheight, ((autocvar_cl_nade_timer == 2) ? _("Nade timer") : ""), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
1359         }
1360         else if(STAT(CAPTURE_PROGRESS))
1361         {
1362                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(CAPTURE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1363                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Capture progress"), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
1364         }
1365         else if(STAT(REVIVE_PROGRESS))
1366         {
1367                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1368                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Revival progress"), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
1369         }
1370
1371         if(autocvar_r_letterbox == 0)
1372                 if(autocvar_viewsize < 120)
1373                 {
1374                         if(!(gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS))
1375                                 Accuracy_LoadLevels();
1376
1377                         HUD_Main();
1378                         HUD_Scale_Disable();
1379                 }
1380
1381         // crosshair goes VERY LAST
1382         UpdateDamage();
1383         HUD_Crosshair(this);
1384         HitSound();
1385 }
1386
1387 bool ov_enabled;
1388 float oldr_nearclip;
1389 float oldr_farclip_base;
1390 float oldr_farclip_world;
1391 float oldr_novis;
1392 float oldr_useportalculling;
1393 float oldr_useinfinitefarclip;
1394
1395 void cl_notice_run();
1396
1397 float prev_myteam;
1398 int lasthud;
1399 float vh_notice_time;
1400 void WaypointSprite_Load();
1401 void CSQC_UpdateView(entity this, float w, float h)
1402 {
1403     TC(int, w); TC(int, h);
1404         entity e;
1405         float fov;
1406         float f;
1407         vector vf_size, vf_min;
1408         float a;
1409
1410         execute_next_frame();
1411
1412         ++framecount;
1413
1414         stats_get();
1415         hud = STAT(HUD);
1416
1417         if(hud != HUD_NORMAL && lasthud == HUD_NORMAL)
1418                 vh_notice_time = time + autocvar_cl_vehicles_notify_time;
1419
1420         lasthud = hud;
1421
1422         HUD_Scale_Disable();
1423
1424         if(autocvar__hud_showbinds_reload) // menu can set this one
1425         {
1426                 db_close(binddb);
1427                 binddb = db_create();
1428                 cvar_set("_hud_showbinds_reload", "0");
1429         }
1430
1431         if(checkextension("DP_CSQC_MINFPS_QUALITY"))
1432                 view_quality = getproperty(VF_MINFPS_QUALITY);
1433         else
1434                 view_quality = 1;
1435
1436         button_attack2 = PHYS_INPUT_BUTTON_ATCK2(this);
1437         button_zoom = PHYS_INPUT_BUTTON_ZOOM(this);
1438
1439         vf_size = getpropertyvec(VF_SIZE);
1440         vf_min = getpropertyvec(VF_MIN);
1441         vid_width = vf_size.x;
1442         vid_height = vf_size.y;
1443
1444         vector reticle_pos = '0 0 0', reticle_size = '0 0 0';
1445         vector splash_pos = '0 0 0', splash_size = '0 0 0';
1446
1447         WaypointSprite_Load();
1448
1449         CSQCPlayer_SetCamera();
1450
1451         if(player_localentnum <= maxclients) // is it a client?
1452                 current_player = player_localentnum - 1;
1453         else // then player_localentnum is the vehicle I'm driving
1454                 current_player = player_localnum;
1455         myteam = entcs_GetTeam(current_player);
1456
1457         if(myteam != prev_myteam)
1458         {
1459                 myteamcolors = colormapPaletteColor(myteam, 1);
1460                 FOREACH(hud_panels, true, it.update_time = time);
1461                 prev_myteam = myteam;
1462         }
1463
1464         ticrate = STAT(MOVEVARS_TICRATE) * STAT(MOVEVARS_TIMESCALE);
1465
1466         float is_dead = (STAT(HEALTH) <= 0);
1467
1468         // FIXME do we need this hack?
1469         if(isdemo())
1470         {
1471                 // in demos, input_buttons do not work
1472                 button_zoom = (autocvar__togglezoom == "-");
1473         }
1474         else if(button_zoom
1475                 && autocvar_cl_unpress_zoom_on_death
1476                 && (spectatee_status >= 0)
1477                 && (is_dead || intermission))
1478         {
1479                 // no zoom while dead or in intermission please
1480                 localcmd("-zoom\n");
1481                 button_zoom = false;
1482         }
1483
1484         // event chase camera
1485         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
1486         {
1487                 if(STAT(CAMERA_SPECTATOR))
1488                 {
1489                         if(spectatee_status > 0)
1490                         {
1491                                 if(!autocvar_chase_active)
1492                                 {
1493                                         cvar_set("chase_active", "-2");
1494                                         goto skip_eventchase_death;
1495                                 }
1496                         }
1497                         else if(autocvar_chase_active == -2)
1498                                 cvar_set("chase_active", "0");
1499
1500                         if(autocvar_chase_active == -2)
1501                                 goto skip_eventchase_death;
1502                 }
1503                 else if(autocvar_chase_active == -2)
1504                         cvar_set("chase_active", "0");
1505
1506                 float vehicle_chase = (hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0));
1507
1508                 float vehicle_viewdist = 0;
1509                 vector vehicle_viewofs = '0 0 0';
1510
1511                 if(vehicle_chase)
1512                 {
1513                         if(hud != HUD_BUMBLEBEE_GUN)
1514                         {
1515                                 Vehicle info = Vehicles_from(hud);
1516                                 vehicle_viewdist = info.height;
1517                                 vehicle_viewofs = info.view_ofs;
1518                         }
1519                 }
1520
1521                 if(WantEventchase(this))
1522                 {
1523                         vector current_view_origin_override = '0 0 0';
1524                         vector view_offset_override = '0 0 0';
1525                         float chase_distance_override = 0;
1526                         bool custom_eventchase = MUTATOR_CALLHOOK(CustomizeEventchase, this);
1527                         if(custom_eventchase)
1528                         {
1529                                 current_view_origin_override = M_ARGV(0, vector);
1530                                 view_offset_override = M_ARGV(1, vector);
1531                                 chase_distance_override = M_ARGV(0, float);
1532                         }
1533                         eventchase_running = true;
1534
1535                         entity local_player = ((csqcplayer) ? csqcplayer : CSQCModel_server2csqc(player_localentnum - 1));
1536                         if(!local_player)
1537                                 local_player = this; // fall back!
1538
1539                         // make special vector since we can't use view_origin (It is one frame old as of this code, it gets set later with the results this code makes.)
1540                         vector current_view_origin = (csqcplayer ? csqcplayer.origin : pmove_org);
1541                         if (custom_eventchase)
1542                                 current_view_origin = current_view_origin_override;
1543
1544                         // detect maximum viewoffset and use it
1545                         vector view_offset = autocvar_cl_eventchase_viewoffset;
1546                         if(vehicle_chase)
1547                         {
1548                                 if(vehicle_viewofs)
1549                                         view_offset = vehicle_viewofs;
1550                                 else
1551                                         view_offset = autocvar_cl_eventchase_vehicle_viewoffset;
1552                         }
1553                         if (custom_eventchase)
1554                                 view_offset = view_offset_override;
1555
1556                         if(view_offset)
1557                         {
1558                                 WarpZone_TraceLine(current_view_origin, current_view_origin + view_offset + ('0 0 1' * autocvar_cl_eventchase_maxs.z), MOVE_WORLDONLY, this);
1559                                 if(trace_fraction == 1) { current_view_origin += view_offset; }
1560                                 else { current_view_origin.z += max(0, (trace_endpos.z - current_view_origin.z) - autocvar_cl_eventchase_maxs.z); }
1561                         }
1562
1563                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
1564                         // Ideally, there should be another way to enable third person cameras, such as through setproperty()
1565                         // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
1566                         if(!autocvar_chase_active) { cvar_set("chase_active", "-1"); }
1567
1568                         // make the camera smooth back
1569                         float chase_distance = autocvar_cl_eventchase_distance;
1570                         if(vehicle_chase)
1571                         {
1572                                 if(vehicle_viewofs)
1573                                         chase_distance = vehicle_viewdist;
1574                                 else
1575                                         chase_distance = autocvar_cl_eventchase_vehicle_distance;
1576                         }
1577                         if (custom_eventchase)
1578                                 chase_distance = chase_distance_override;
1579
1580                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < chase_distance)
1581                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (chase_distance - eventchase_current_distance) * frametime; // slow down the further we get
1582                         else if(eventchase_current_distance != chase_distance)
1583                                 eventchase_current_distance = chase_distance;
1584
1585                         makevectors(view_angles);
1586
1587                         vector eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1588                         WarpZone_TraceBox(current_view_origin, autocvar_cl_eventchase_mins, autocvar_cl_eventchase_maxs, eventchase_target_origin, MOVE_WORLDONLY, this);
1589
1590                         // If the boxtrace fails, revert back to line tracing.
1591                         if(!local_player.viewloc)
1592                         if(trace_startsolid)
1593                         {
1594                                 eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1595                                 WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, this);
1596                                 setproperty(VF_ORIGIN, (trace_endpos - (v_forward * autocvar_cl_eventchase_mins.z)));
1597                         }
1598                         else { setproperty(VF_ORIGIN, trace_endpos); }
1599
1600                         if(!local_player.viewloc)
1601                                 setproperty(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
1602                 }
1603                 else if(autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
1604                 {
1605                         eventchase_running = false;
1606                         cvar_set("chase_active", "0");
1607                         eventchase_current_distance = 0; // start from 0 next time
1608                 }
1609         }
1610         // workaround for camera stuck between player's legs when using chase_active 1
1611         // because the engine stops updating the chase_active camera when the game ends
1612         else if(intermission)
1613         {
1614                 cvar_settemp("chase_active", "-1");
1615                 eventchase_current_distance = 0;
1616         }
1617
1618         LABEL(skip_eventchase_death);
1619
1620         // do lockview after event chase camera so that it still applies whenever necessary.
1621         if(autocvar_cl_lockview || (!autocvar_hud_cursormode && (autocvar__hud_configure && spectatee_status <= 0 || intermission > 1 || QuickMenu_IsOpened())))
1622         {
1623                 setproperty(VF_ORIGIN, freeze_org);
1624                 setproperty(VF_ANGLES, freeze_ang);
1625         }
1626         else
1627         {
1628                 freeze_org = getpropertyvec(VF_ORIGIN);
1629                 freeze_ang = getpropertyvec(VF_ANGLES);
1630         }
1631
1632         WarpZone_FixView();
1633         //WarpZone_FixPMove();
1634
1635         vector ov_org = '0 0 0';
1636         vector ov_mid = '0 0 0';
1637         vector ov_worldmin = '0 0 0';
1638         vector ov_worldmax = '0 0 0';
1639         if(autocvar_cl_orthoview)
1640         {
1641                 ov_worldmin = mi_picmin;
1642                 ov_worldmax = mi_picmax;
1643
1644                 float ov_width = (ov_worldmax.x - ov_worldmin.x);
1645                 float ov_height = (ov_worldmax.y - ov_worldmin.y);
1646                 float ov_distance = (max(vid_width, vid_height) * max(ov_width, ov_height));
1647
1648                 ov_mid = ((ov_worldmax + ov_worldmin) * 0.5);
1649                 ov_org = vec3(ov_mid.x, ov_mid.y, (ov_mid.z + ov_distance));
1650
1651                 float ov_nearest = vlen(ov_org - vec3(
1652                         bound(ov_worldmin.x, ov_org.x, ov_worldmax.x),
1653                         bound(ov_worldmin.y, ov_org.y, ov_worldmax.y),
1654                         bound(ov_worldmin.z, ov_org.z, ov_worldmax.z)
1655                 ));
1656
1657                 float ov_furthest = 0;
1658                 float dist = 0;
1659
1660                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1661                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1662                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1663                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1664                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1665                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1666                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1667                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1668
1669                 if(!ov_enabled)
1670                 {
1671                         oldr_nearclip = cvar("r_nearclip");
1672                         oldr_farclip_base = cvar("r_farclip_base");
1673                         oldr_farclip_world = cvar("r_farclip_world");
1674                         oldr_novis = cvar("r_novis");
1675                         oldr_useportalculling = cvar("r_useportalculling");
1676                         oldr_useinfinitefarclip = cvar("r_useinfinitefarclip");
1677                 }
1678
1679                 cvar_settemp("r_nearclip", ftos(ov_nearest));
1680                 cvar_settemp("r_farclip_base", ftos(ov_furthest));
1681                 cvar_settemp("r_farclip_world", "0");
1682                 cvar_settemp("r_novis", "1");
1683                 cvar_settemp("r_useportalculling", "0");
1684                 cvar_settemp("r_useinfinitefarclip", "0");
1685
1686                 setproperty(VF_ORIGIN, ov_org);
1687                 setproperty(VF_ANGLES, '90 0 0');
1688
1689                 ov_enabled = true;
1690
1691                 #if 0
1692                 LOG_INFOF("OrthoView: org = %s, angles = %s, distance = %f, nearest = %f, furthest = %f\n",
1693                         vtos(ov_org),
1694                         vtos(getpropertyvec(VF_ANGLES)),
1695                         ov_distance,
1696                         ov_nearest,
1697                         ov_furthest);
1698                 #endif
1699         }
1700         else
1701         {
1702                 if(ov_enabled)
1703                 {
1704                         cvar_set("r_nearclip", ftos(oldr_nearclip));
1705                         cvar_set("r_farclip_base", ftos(oldr_farclip_base));
1706                         cvar_set("r_farclip_world", ftos(oldr_farclip_world));
1707                         cvar_set("r_novis", ftos(oldr_novis));
1708                         cvar_set("r_useportalculling", ftos(oldr_useportalculling));
1709                         cvar_set("r_useinfinitefarclip", ftos(oldr_useinfinitefarclip));
1710                 }
1711                 ov_enabled = false;
1712         }
1713
1714         // run viewmodel_draw before updating view_angles to the angles calculated by WarpZone_FixView
1715         // viewmodel_draw needs to use the view_angles set by the engine on every CSQC_UpdateView call
1716         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1717                 viewmodel_draw(viewmodels[slot]);
1718
1719         // Render the Scene
1720         view_origin = getpropertyvec(VF_ORIGIN);
1721         view_angles = getpropertyvec(VF_ANGLES);
1722         makevectors(view_angles);
1723         view_forward = v_forward;
1724         view_right = v_right;
1725         view_up = v_up;
1726
1727 #ifdef BLURTEST
1728         if(time > blurtest_time0 && time < blurtest_time1)
1729         {
1730                 float r, t;
1731
1732                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
1733                 r = t * blurtest_radius;
1734                 f = 1 / pow(t, blurtest_power) - 1;
1735
1736                 cvar_set("r_glsl_postprocess", "1");
1737                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
1738         }
1739         else
1740         {
1741                 cvar_set("r_glsl_postprocess", "0");
1742                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
1743         }
1744 #endif
1745
1746         TargetMusic_Advance();
1747         Fog_Force();
1748
1749         if(drawtime == 0)
1750                 drawframetime = 0.01666667; // when we don't know fps yet, we assume 60fps
1751         else
1752                 drawframetime = bound(0.000001, time - drawtime, 1);
1753         drawtime = time;
1754
1755         // watch for gametype changes here...
1756         // in ParseStuffCMD the cmd isn't executed yet :/
1757         // might even be better to add the gametype to TE_CSQC_INIT...?
1758         if(!postinit)
1759                 PostInit();
1760
1761         if(intermission && !gameover_time)
1762                 gameover_time = time;
1763
1764         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
1765         {
1766                 if(calledhooks & HOOK_START)
1767                 {
1768                         localcmd("\ncl_hook_gameend\n");
1769                         calledhooks |= HOOK_END;
1770                 }
1771         }
1772
1773         Announcer();
1774
1775         fov = autocvar_fov;
1776         if(fov <= 59.5)
1777         {
1778                 if(!zoomscript_caught)
1779                 {
1780                         localcmd("+button9\n");
1781                         zoomscript_caught = 1;
1782                 }
1783         }
1784         else
1785         {
1786                 if(zoomscript_caught)
1787                 {
1788                         localcmd("-button9\n");
1789                         zoomscript_caught = 0;
1790                 }
1791         }
1792
1793         ColorTranslateMode = autocvar_cl_stripcolorcodes;
1794
1795         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1796         {
1797                 entity wepent = viewmodels[slot];
1798
1799                 if(wepent.last_switchweapon != wepent.switchweapon)
1800                 {
1801                         weapontime = time;
1802                         wepent.last_switchweapon = wepent.switchweapon;
1803                         if(slot == 0 && button_zoom && autocvar_cl_unpress_zoom_on_weapon_switch)
1804                         {
1805                                 localcmd("-zoom\n");
1806                                 button_zoom = false;
1807                         }
1808                         if(slot == 0 && autocvar_cl_unpress_attack_on_weapon_switch)
1809                         {
1810                                 localcmd("-fire\n");
1811                                 localcmd("-fire2\n");
1812                                 button_attack2 = false;
1813                         }
1814                 }
1815                 if(wepent.last_activeweapon != wepent.activeweapon)
1816                 {
1817                         wepent.last_activeweapon = wepent.activeweapon;
1818
1819                         e = wepent.activeweapon;
1820                         if(e.netname != "")
1821                                 localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
1822                         else if(slot == 0)
1823                                 localcmd("\ncl_hook_activeweapon none\n");
1824                 }
1825         }
1826
1827         // ALWAYS Clear Current Scene First
1828         clearscene();
1829
1830         setproperty(VF_ORIGIN, view_origin);
1831         setproperty(VF_ANGLES, view_angles);
1832
1833         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
1834         setproperty(VF_SIZE, vf_size);
1835         setproperty(VF_MIN, vf_min);
1836
1837         // Assign Standard Viewflags
1838         // Draw the World (and sky)
1839         setproperty(VF_DRAWWORLD, 1);
1840
1841         // Set the console size vars
1842         vid_conwidth = autocvar_vid_conwidth;
1843         vid_conheight = autocvar_vid_conheight;
1844         vid_pixelheight = autocvar_vid_pixelheight;
1845
1846         if(autocvar_cl_orthoview) { setproperty(VF_FOV, GetOrthoviewFOV(ov_worldmin, ov_worldmax, ov_mid, ov_org)); }
1847         else if(csqcplayer.viewloc) { setproperty(VF_FOV, GetViewLocationFOV(110)); } // enforce 110 fov, so things dont look odd
1848         else { setproperty(VF_FOV, GetCurrentFov(fov)); }
1849
1850         if(camera_active) // Camera for demo playback
1851         {
1852                 if(autocvar_camera_enable)
1853                         CSQC_Demo_Camera();
1854                 else
1855                 {
1856                         cvar_set("chase_active", ftos(chase_active_backup));
1857                         cvar_set("cl_demo_mousegrab", "0");
1858                         camera_active = false;
1859                 }
1860         }
1861         else
1862         {
1863 #ifdef CAMERATEST
1864                 if(autocvar_camera_enable)
1865 #else
1866                 if(autocvar_camera_enable && isdemo())
1867 #endif
1868                 {
1869                         // Enable required Darkplaces cvars
1870                         chase_active_backup = autocvar_chase_active;
1871                         cvar_set("chase_active", "2");
1872                         cvar_set("cl_demo_mousegrab", "1");
1873                         camera_active = true;
1874                         camera_mode = false;
1875                 }
1876         }
1877
1878         // Draw the Crosshair
1879         setproperty(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
1880
1881         // Draw the Engine Status Bar (the default Quake HUD)
1882         setproperty(VF_DRAWENGINESBAR, 0);
1883
1884         // Update the mouse position
1885         /*
1886            mousepos_x = vid_conwidth;
1887            mousepos_y = vid_conheight;
1888            mousepos = mousepos*0.5 + getmousepos();
1889          */
1890
1891         IL_EACH(g_drawables, it.draw, it.draw(it));
1892
1893         addentities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
1894         renderscene();
1895
1896         // now switch to 2D drawing mode by calling a 2D drawing function
1897         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
1898         // next R_RenderScene call
1899         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
1900
1901         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
1902         if (!(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT))
1903         {
1904                 // apply night vision effect
1905                 vector tc_00, tc_01, tc_10, tc_11;
1906                 vector rgb = '0 0 0';
1907
1908                 if(!nightvision_noise)
1909                 {
1910                         nightvision_noise = new(nightvision_noise);
1911                 }
1912                 if(!nightvision_noise2)
1913                 {
1914                         nightvision_noise2 = new(nightvision_noise2);
1915                 }
1916
1917                 // color tint in yellow
1918                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
1919
1920                 // draw BG
1921                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
1922                 rgb = '1 1 1';
1923                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
1924                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
1925                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
1926                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
1927                 tc_11 = tc_01 + tc_10 - tc_00;
1928                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
1929                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
1930                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
1931                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
1932                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
1933                 R_EndPolygon();
1934
1935                 // draw FG
1936                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
1937                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
1938                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
1939                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
1940                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
1941                 tc_11 = tc_01 + tc_10 - tc_00;
1942                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
1943                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
1944                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
1945                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
1946                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
1947                 R_EndPolygon();
1948         }
1949
1950         if(autocvar_cl_reticle)
1951         {
1952                 string reticle_image = "";
1953                 bool wep_zoomed = false;
1954                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1955                 {
1956                         entity wepe = viewmodels[slot];
1957                         Weapon wep = wepe.activeweapon;
1958                         if(wep != WEP_Null && wep.wr_zoom)
1959                         {
1960                                 bool do_zoom = wep.wr_zoom(wep, NULL);
1961                                 if(wep.w_reticle && wep.w_reticle != "")
1962                                         reticle_image = wep.w_reticle;
1963                                 wep_zoomed += do_zoom;
1964                         }
1965                 }
1966                 // Draw the aiming reticle for weapons that use it
1967                 // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
1968                 // It must be a persisted float for fading out to work properly (you let go of the zoom button for
1969                 // the view to go back to normal, so reticle_type would become 0 as we fade out)
1970                 if(spectatee_status || is_dead || hud != HUD_NORMAL)
1971                 {
1972                         // no zoom reticle while dead
1973                         reticle_type = 0;
1974                 }
1975                 else if(wep_zoomed && autocvar_cl_reticle_weapon)
1976                 {
1977                         if(reticle_image && reticle_image != "") { reticle_type = 2; }
1978                         else { reticle_type = 0; }
1979                 }
1980                 else if(button_zoom || zoomscript_caught)
1981                 {
1982                         // normal zoom
1983                         reticle_type = 1;
1984                 }
1985
1986                 if(reticle_type)
1987                 {
1988                         if(autocvar_cl_reticle_stretch)
1989                         {
1990                                 reticle_size.x = vid_conwidth;
1991                                 reticle_size.y = vid_conheight;
1992                                 reticle_pos.x = 0;
1993                                 reticle_pos.y = 0;
1994                         }
1995                         else
1996                         {
1997                                 reticle_size.x = max(vid_conwidth, vid_conheight);
1998                                 reticle_size.y = max(vid_conwidth, vid_conheight);
1999                                 reticle_pos.x = (vid_conwidth - reticle_size.x) / 2;
2000                                 reticle_pos.y = (vid_conheight - reticle_size.y) / 2;
2001                         }
2002
2003                         if(zoomscript_caught)
2004                                 f = 1;
2005                         else
2006                                 f = current_zoomfraction;
2007
2008                         if(f)
2009                         {
2010                                 switch(reticle_type)
2011                                 {
2012                                         case 1: drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_normal_alpha, DRAWFLAG_NORMAL); break;
2013                                         case 2: drawpic(reticle_pos, reticle_image, reticle_size, '1 1 1', f * autocvar_cl_reticle_weapon_alpha, DRAWFLAG_NORMAL); break;
2014                                 }
2015                         }
2016                 }
2017         }
2018         else
2019         {
2020                 if(reticle_type != 0) { reticle_type = 0; }
2021         }
2022
2023
2024         // improved polyblend
2025         if(autocvar_hud_contents)
2026         {
2027                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
2028                 vector liquidcolor;
2029
2030                 switch(pointcontents(view_origin))
2031                 {
2032                         case CONTENT_WATER:
2033                                 liquidalpha = autocvar_hud_contents_water_alpha;
2034                                 liquidcolor = stov(autocvar_hud_contents_water_color);
2035                                 incontent = 1;
2036                                 break;
2037
2038                         case CONTENT_LAVA:
2039                                 liquidalpha = autocvar_hud_contents_lava_alpha;
2040                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
2041                                 incontent = 1;
2042                                 break;
2043
2044                         case CONTENT_SLIME:
2045                                 liquidalpha = autocvar_hud_contents_slime_alpha;
2046                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
2047                                 incontent = 1;
2048                                 break;
2049
2050                         default:
2051                                 liquidalpha = 0;
2052                                 liquidcolor = '0 0 0';
2053                                 incontent = 0;
2054                                 break;
2055                 }
2056
2057                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
2058                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
2059                         contentfadetime = autocvar_hud_contents_fadeintime;
2060                         liquidalpha_prev = liquidalpha;
2061                         liquidcolor_prev = liquidcolor;
2062                 }
2063                 else
2064                         contentfadetime = autocvar_hud_contents_fadeouttime;
2065
2066                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
2067                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
2068
2069                 if(contentavgalpha)
2070                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
2071
2072                 if(autocvar_hud_postprocessing)
2073                 {
2074                         if(autocvar_hud_contents_blur && contentavgalpha)
2075                         {
2076                                 content_blurpostprocess.x = 1;
2077                                 content_blurpostprocess.y = contentavgalpha * autocvar_hud_contents_blur;
2078                                 content_blurpostprocess.z = contentavgalpha * autocvar_hud_contents_blur_alpha;
2079                         }
2080                         else
2081                         {
2082                                 content_blurpostprocess.x = 0;
2083                                 content_blurpostprocess.y = 0;
2084                                 content_blurpostprocess.z = 0;
2085                         }
2086                 }
2087         }
2088
2089         if(autocvar_hud_damage && !STAT(FROZEN))
2090         {
2091                 splash_size.x = max(vid_conwidth, vid_conheight);
2092                 splash_size.y = max(vid_conwidth, vid_conheight);
2093                 splash_pos.x = (vid_conwidth - splash_size.x) / 2;
2094                 splash_pos.y = (vid_conheight - splash_size.y) / 2;
2095
2096                 float myhealth_flash_temp;
2097                 myhealth = STAT(HEALTH);
2098
2099                 // fade out
2100                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
2101                 // add new damage
2102                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
2103
2104                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
2105                 pain_threshold = autocvar_hud_damage_pain_threshold;
2106                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
2107                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
2108
2109                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
2110                 {
2111                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
2112                 }
2113
2114                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
2115
2116                 if(myhealth_prev < 1)
2117                 {
2118                         if(myhealth >= 1)
2119                         {
2120                                 myhealth_flash = 0; // just spawned, clear the flash immediately
2121                                 myhealth_flash_temp = 0;
2122                         }
2123                         else
2124                         {
2125                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
2126                         }
2127                 }
2128
2129                 if(spectatee_status == -1 || intermission)
2130                 {
2131                         myhealth_flash = 0; // observing, or match ended
2132                         myhealth_flash_temp = 0;
2133                 }
2134
2135                 myhealth_prev = myhealth;
2136
2137                 // IDEA: change damage color/picture based on player model for robot/alien species?
2138                 // pro: matches model better
2139                 // contra: it's not red because blood is red, but because red is an alarming color, so red should stay
2140                 // maybe different reddish pics?
2141                 if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
2142                 {
2143                         if(autocvar_cl_gentle_damage == 2)
2144                         {
2145                                 if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
2146                                         myhealth_gentlergb = eX * random() + eY * random() + eZ * random();
2147                         }
2148                         else
2149                                 myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
2150
2151                         if(myhealth_flash_temp > 0)
2152                                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
2153                 }
2154                 else if(myhealth_flash_temp > 0)
2155                         drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
2156
2157                 if(autocvar_hud_postprocessing) // we still need to set this anyway even when chase_active is set, this way it doesn't get stuck on.
2158                 {
2159                         if(autocvar_hud_damage_blur && myhealth_flash_temp)
2160                         {
2161                                 damage_blurpostprocess.x = 1;
2162                                 damage_blurpostprocess.y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
2163                                 damage_blurpostprocess.z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
2164                         }
2165                         else
2166                         {
2167                                 damage_blurpostprocess.x = 0;
2168                                 damage_blurpostprocess.y = 0;
2169                                 damage_blurpostprocess.z = 0;
2170                         }
2171                 }
2172         }
2173
2174         float e1 = (autocvar_hud_postprocessing_maxbluralpha != 0);
2175         float e2 = (autocvar_hud_powerup != 0);
2176         if(autocvar_hud_postprocessing && (e1 || e2)) // TODO: Remove this code and re-do the postprocess handling in the engine, where it properly belongs.
2177         {
2178                 // enable or disable rendering types if they are used or not
2179                 if(cvar("r_glsl_postprocess_uservec1_enable") != e1) { cvar_set("r_glsl_postprocess_uservec1_enable", ftos(e1)); }
2180                 if(cvar("r_glsl_postprocess_uservec2_enable") != e2) { cvar_set("r_glsl_postprocess_uservec2_enable", ftos(e2)); }
2181
2182                 // blur postprocess handling done first (used by hud_damage and hud_contents)
2183                 if((damage_blurpostprocess.x || content_blurpostprocess.x))
2184                 {
2185                         float blurradius = bound(0, damage_blurpostprocess.y + content_blurpostprocess.y, autocvar_hud_postprocessing_maxblurradius);
2186                         float bluralpha = bound(0, damage_blurpostprocess.z + content_blurpostprocess.z, autocvar_hud_postprocessing_maxbluralpha);
2187                         if(blurradius != old_blurradius || bluralpha != old_bluralpha) // reduce cvar_set spam as much as possible
2188                         {
2189                                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
2190                                 old_blurradius = blurradius;
2191                                 old_bluralpha = bluralpha;
2192                         }
2193                 }
2194                 else if(cvar_string("r_glsl_postprocess_uservec1") != "0 0 0 0") // reduce cvar_set spam as much as possible
2195                 {
2196                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
2197                         old_blurradius = 0;
2198                         old_bluralpha = 0;
2199                 }
2200
2201                 // edge detection postprocess handling done second (used by hud_powerup)
2202                 float sharpen_intensity = 0, strength_finished = STAT(STRENGTH_FINISHED), invincible_finished = STAT(INVINCIBLE_FINISHED);
2203                 if (strength_finished - time > 0) { sharpen_intensity += (strength_finished - time); }
2204                 if (invincible_finished - time > 0) { sharpen_intensity += (invincible_finished - time); }
2205
2206                 sharpen_intensity = bound(0, ((STAT(HEALTH) > 0) ? sharpen_intensity : 0), 5); // Check to see if player is alive (if not, set 0) - also bound to fade out starting at 5 seconds.
2207
2208                 if(autocvar_hud_powerup && sharpen_intensity > 0)
2209                 {
2210                         if(sharpen_intensity != old_sharpen_intensity) // reduce cvar_set spam as much as possible
2211                         {
2212                                 cvar_set("r_glsl_postprocess_uservec2", strcat(ftos((sharpen_intensity / 5) * autocvar_hud_powerup), " ", ftos(-sharpen_intensity * autocvar_hud_powerup), " 0 0"));
2213                                 old_sharpen_intensity = sharpen_intensity;
2214                         }
2215                 }
2216                 else if(cvar_string("r_glsl_postprocess_uservec2") != "0 0 0 0") // reduce cvar_set spam as much as possible
2217                 {
2218                         cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
2219                         old_sharpen_intensity = 0;
2220                 }
2221
2222                 if(cvar("r_glsl_postprocess") == 0)
2223                         cvar_set("r_glsl_postprocess", "2");
2224         }
2225         else if(cvar("r_glsl_postprocess") == 2)
2226                 cvar_set("r_glsl_postprocess", "0");
2227
2228         /*if(gametype == MAPINFO_TYPE_CTF)
2229           {
2230           ctf_view();
2231           } else */
2232
2233         // draw 2D entities
2234         IL_EACH(g_drawables_2d, it.draw2d, it.draw2d(it));
2235         Draw_ShowNames_All();
2236         Debug_Draw();
2237
2238         scoreboard_active = Scoreboard_WouldDraw();
2239
2240         HUD_Draw(this); // this parameter for deep vehicle function
2241
2242         if(NextFrameCommand)
2243         {
2244                 localcmd("\n", NextFrameCommand, "\n");
2245                 NextFrameCommand = string_null;
2246         }
2247
2248         // we must do this check AFTER a frame was rendered, or it won't work
2249         if(cs_project_is_b0rked == 0)
2250         {
2251                 string w0, h0;
2252                 w0 = ftos(autocvar_vid_conwidth);
2253                 h0 = ftos(autocvar_vid_conheight);
2254                 //setproperty(VF_VIEWPORT, '0 0 0', '640 480 0');
2255                 //setproperty(VF_FOV, '90 90 0');
2256                 setproperty(VF_ORIGIN, '0 0 0');
2257                 setproperty(VF_ANGLES, '0 0 0');
2258                 setproperty(VF_PERSPECTIVE, 1);
2259                 makevectors('0 0 0');
2260                 vector v1, v2;
2261                 cvar_set("vid_conwidth", "800");
2262                 cvar_set("vid_conheight", "600");
2263                 v1 = cs_project(v_forward);
2264                 cvar_set("vid_conwidth", "640");
2265                 cvar_set("vid_conheight", "480");
2266                 v2 = cs_project(v_forward);
2267                 if(v1 == v2)
2268                         cs_project_is_b0rked = 1;
2269                 else
2270                         cs_project_is_b0rked = -1;
2271                 cvar_set("vid_conwidth", w0);
2272                 cvar_set("vid_conheight", h0);
2273         }
2274
2275         if(autocvar__hud_configure)
2276                 HUD_Panel_Mouse();
2277         else if (HUD_MinigameMenu_IsOpened() || active_minigame)
2278                 HUD_Minigame_Mouse();
2279         else if(QuickMenu_IsOpened())
2280                 QuickMenu_Mouse();
2281         else
2282                 HUD_Radar_Mouse();
2283
2284         cl_notice_run();
2285         unpause_update();
2286         Net_Flush();
2287
2288         // let's reset the view back to normal for the end
2289         setproperty(VF_MIN, '0 0 0');
2290         setproperty(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
2291
2292         IL_ENDFRAME();
2293 }
2294
2295
2296 // following vectors must be global to allow seamless switching between camera modes
2297 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
2298 void CSQC_Demo_Camera()
2299 {
2300         float speed, attenuation, dimensions;
2301         vector tmp, delta;
2302
2303         if( autocvar_camera_reset || !camera_mode )
2304         {
2305                 camera_offset = '0 0 0';
2306                 current_angles = '0 0 0';
2307                 camera_direction = '0 0 0';
2308                 camera_offset.z += 30;
2309                 camera_offset.x += 30 * -cos(current_angles.y * DEG2RAD);
2310                 camera_offset.y += 30 * -sin(current_angles.y * DEG2RAD);
2311                 current_origin = view_origin;
2312                 current_camera_offset  = camera_offset;
2313                 cvar_set("camera_reset", "0");
2314                 camera_mode = CAMERA_CHASE;
2315         }
2316
2317         // Camera angles
2318         if( camera_roll )
2319                 mouse_angles.z += camera_roll * autocvar_camera_speed_roll;
2320
2321         if(autocvar_camera_look_player)
2322         {
2323                 vector dir;
2324                 float n;
2325
2326                 dir = normalize(view_origin - current_position);
2327                 n = mouse_angles.z;
2328                 mouse_angles = vectoangles(dir);
2329                 mouse_angles.x = mouse_angles.x * -1;
2330                 mouse_angles.z = n;
2331         }
2332         else
2333         {
2334                 tmp = getmousepos() * 0.1;
2335                 if(vdist(tmp, >, autocvar_camera_mouse_threshold))
2336                 {
2337                         mouse_angles.x += tmp.y * cos(mouse_angles.z * DEG2RAD) + (tmp.x * sin(mouse_angles.z * DEG2RAD));
2338                         mouse_angles.y -= tmp.x * cos(mouse_angles.z * DEG2RAD) + (tmp.y * -sin(mouse_angles.z * DEG2RAD));
2339                 }
2340         }
2341
2342         while (mouse_angles.x < -180) mouse_angles.x = mouse_angles.x + 360;
2343         while (mouse_angles.x > 180) mouse_angles.x = mouse_angles.x - 360;
2344         while (mouse_angles.y < -180) mouse_angles.y = mouse_angles.y + 360;
2345         while (mouse_angles.y > 180) mouse_angles.y = mouse_angles.y - 360;
2346
2347         // Fix difference when angles don't have the same sign
2348         delta = '0 0 0';
2349         if(mouse_angles.y < -60 && current_angles.y > 60)
2350                 delta = '0 360 0';
2351         if(mouse_angles.y > 60 && current_angles.y < -60)
2352                 delta = '0 -360 0';
2353
2354         if(autocvar_camera_look_player)
2355                 attenuation = autocvar_camera_look_attenuation;
2356         else
2357                 attenuation = autocvar_camera_speed_attenuation;
2358
2359         attenuation = 1 / max(1, attenuation);
2360         current_angles += (mouse_angles - current_angles + delta) * attenuation;
2361
2362         while (current_angles.x < -180) current_angles.x = current_angles.x + 360;
2363         while (current_angles.x > 180) current_angles.x = current_angles.x - 360;
2364         while (current_angles.y < -180) current_angles.y = current_angles.y + 360;
2365         while (current_angles.y > 180) current_angles.y = current_angles.y - 360;
2366
2367         // Camera position
2368         tmp = '0 0 0';
2369         dimensions = 0;
2370
2371         if( camera_direction.x )
2372         {
2373                 tmp.x = camera_direction.x * cos(current_angles.y * DEG2RAD);
2374                 tmp.y = camera_direction.x * sin(current_angles.y * DEG2RAD);
2375                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
2376                         tmp.z = camera_direction.x * -sin(current_angles.x * DEG2RAD);
2377                 ++dimensions;
2378         }
2379
2380         if( camera_direction.y )
2381         {
2382                 tmp.x += camera_direction.y * -sin(current_angles.y * DEG2RAD);
2383                 tmp.y += camera_direction.y * cos(current_angles.y * DEG2RAD) * cos(current_angles.z * DEG2RAD);
2384                 tmp.z += camera_direction.y * sin(current_angles.z * DEG2RAD);
2385                 ++dimensions;
2386         }
2387
2388         if( camera_direction.z )
2389         {
2390                 tmp.z += camera_direction.z * cos(current_angles.z * DEG2RAD);
2391                 ++dimensions;
2392         }
2393
2394         if(autocvar_camera_free)
2395                 speed = autocvar_camera_speed_free;
2396         else
2397                 speed = autocvar_camera_speed_chase;
2398
2399         if(dimensions)
2400         {
2401                 speed = speed * sqrt(1 / dimensions);
2402                 camera_offset += tmp * speed;
2403         }
2404
2405         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
2406
2407         // Camera modes
2408         if( autocvar_camera_free )
2409         {
2410                 if ( camera_mode == CAMERA_CHASE )
2411                 {
2412                         current_camera_offset = current_origin + current_camera_offset;
2413                         camera_offset = current_origin + camera_offset;
2414                 }
2415
2416                 camera_mode = CAMERA_FREE;
2417                 current_position = current_camera_offset;
2418         }
2419         else
2420         {
2421                 if ( camera_mode == CAMERA_FREE )
2422                 {
2423                         current_origin = view_origin;
2424                         camera_offset = camera_offset - current_origin;
2425                         current_camera_offset = current_camera_offset - current_origin;
2426                 }
2427
2428                 camera_mode = CAMERA_CHASE;
2429
2430                 if(autocvar_camera_chase_smoothly)
2431                         current_origin += (view_origin - current_origin) * attenuation;
2432                 else
2433                         current_origin = view_origin;
2434
2435                 current_position = current_origin + current_camera_offset;
2436         }
2437
2438         setproperty(VF_ANGLES, current_angles);
2439         setproperty(VF_ORIGIN, current_position);
2440 }