qcsrc/client/view.qc

   1 #include "view.qh"
   2
   3 #include <client/announcer.qh>
   4 #include <client/csqcmodel_hooks.qh>
   5 #include <client/draw.qh>
   6 #include <client/hud/_mod.qh>
   7 #include <client/hud/panel/quickmenu.qh>
   8 #include <client/hud/panel/scoreboard.qh>
   9 #include <client/mapvoting.qh>
  10 #include <client/mutators/_mod.qh>
  11 #include <client/shownames.qh>
  12 #include <common/anim.qh>
  13 #include <common/animdecide.qh>
  14 #include <common/constants.qh>
  15 #include <common/deathtypes/all.qh>
  16 #include <common/debug.qh>
  17 #include <common/ent_cs.qh>
  18 #include <common/gamemodes/_mod.qh>
  19 #include <common/mapinfo.qh>
  20 #include <common/mapobjects/target/music.qh>
  21 #include <common/mapobjects/trigger/viewloc.qh>
  22 #include <common/minigames/cl_minigames.qh>
  23 #include <common/minigames/cl_minigames_hud.qh>
  24 #include <common/mutators/mutator/waypoints/all.qh>
  25 #include <common/net_linked.qh>
  26 #include <common/net_notice.qh>
  27 #include <common/physics/player.qh>
  28 #include <common/stats.qh>
  29 #include <common/teams.qh>
  30 #include <common/vehicles/all.qh>
  31 #include <common/viewloc.qh>
  32 #include <common/weapons/_all.qh>
  33 #include <common/weapons/weapon/tuba.qh>
  34 #include <common/wepent.qh>
  35 #include <lib/csqcmodel/cl_model.qh>
  36 #include <lib/csqcmodel/cl_player.qh>
  37 #include <lib/warpzone/client.qh>
  38 #include <lib/warpzone/common.qh>
  39
  40 float autocvar_cl_viewmodel_scale;
  41 float autocvar_cl_viewmodel_alpha = 1;
  42
  43 bool autocvar_cl_bobmodel;
  44 float autocvar_cl_bobmodel_speed;
  45 float autocvar_cl_bobmodel_side;
  46 float autocvar_cl_bobmodel_up;
  47
  48 float autocvar_cl_followmodel;
  49 float autocvar_cl_followmodel_speed = 0.3;
  50 float autocvar_cl_followmodel_limit = 135;
  51 float autocvar_cl_followmodel_velocity_lowpass = 0.05;
  52 float autocvar_cl_followmodel_highpass = 0.05;
  53 float autocvar_cl_followmodel_lowpass = 0.03;
  54 bool autocvar_cl_followmodel_velocity_absolute;
  55
  56 float autocvar_cl_leanmodel;
  57 float autocvar_cl_leanmodel_speed = 0.3;
  58 float autocvar_cl_leanmodel_limit = 30;
  59 float autocvar_cl_leanmodel_highpass1 = 0.2;
  60 float autocvar_cl_leanmodel_highpass = 0.2;
  61 float autocvar_cl_leanmodel_lowpass = 0.05;
  62
  63 #define avg_factor(avg_time) (1 - exp(-frametime / max(0.001, avg_time)))
  64
  65 #define lowpass(value, frac, ref_store, ret) \
  66         ret = ref_store = ref_store * (1 - frac) + (value) * frac;
  67
  68 #define lowpass_limited(value, frac, limit, ref_store, ret) MACRO_BEGIN \
  69         float __ignore; lowpass(value, frac, ref_store, __ignore); \
  70         ret = ref_store = bound((value) - (limit), ref_store, (value) + (limit)); \
  71 MACRO_END
  72
  73 #define highpass(value, frac, ref_store, ret) MACRO_BEGIN \
  74         float __f = 0; lowpass(value, frac, ref_store, __f); \
  75         ret = (value) - __f; \
  76 MACRO_END
  77
  78 #define highpass_limited(value, frac, limit, ref_store, ret) MACRO_BEGIN \
  79         float __f = 0; lowpass_limited(value, frac, limit, ref_store, __f); \
  80         ret = (value) - __f; \
  81 MACRO_END
  82
  83 #define lowpass2(value, frac, ref_store, ref_out) MACRO_BEGIN \
  84         lowpass(value.x, frac, ref_store.x, ref_out.x); \
  85         lowpass(value.y, frac, ref_store.y, ref_out.y); \
  86 MACRO_END
  87
  88 #define highpass2(value, frac, ref_store, ref_out) MACRO_BEGIN \
  89         highpass(value.x, frac, ref_store.x, ref_out.x); \
  90         highpass(value.y, frac, ref_store.y, ref_out.y); \
  91 MACRO_END
  92
  93 #define highpass2_limited(value, frac, limit, ref_store, ref_out) MACRO_BEGIN \
  94         highpass_limited(value.x, frac, limit, ref_store.x, ref_out.x); \
  95         highpass_limited(value.y, frac, limit, ref_store.y, ref_out.y); \
  96 MACRO_END
  97
  98 #define lowpass3(value, frac, ref_store, ref_out) MACRO_BEGIN \
  99         lowpass(value.x, frac, ref_store.x, ref_out.x); \
 100         lowpass(value.y, frac, ref_store.y, ref_out.y); \
 101         lowpass(value.z, frac, ref_store.z, ref_out.z); \
 102 MACRO_END
 103
 104 #define highpass3(value, frac, ref_store, ref_out) MACRO_BEGIN \
 105         highpass(value.x, frac, ref_store.x, ref_out.x); \
 106         highpass(value.y, frac, ref_store.y, ref_out.y); \
 107         highpass(value.z, frac, ref_store.z, ref_out.z); \
 108 MACRO_END
 109
 110 void calc_followmodel_ofs(entity view)
 111 {
 112         if(cl_followmodel_time == time)
 113                 return; // cl_followmodel_ofs already calculated for this frame
 114
 115         float frac;
 116         vector gunorg = '0 0 0';
 117         static vector vel_average;
 118         static vector gunorg_adjustment_highpass;
 119         static vector gunorg_adjustment_lowpass;
 120
 121         vector vel;
 122         if (autocvar_cl_followmodel_velocity_absolute)
 123                 vel = view.velocity;
 124         else
 125         {
 126                 vector forward, right, up;
 127                 MAKE_VECTORS(view_angles, forward, right, up);
 128                 vel.x = view.velocity * forward;
 129                 vel.y = view.velocity * right * -1;
 130                 vel.z = view.velocity * up;
 131         }
 132
 133         vel.x = bound(vel_average.x - autocvar_cl_followmodel_limit, vel.x, vel_average.x + autocvar_cl_followmodel_limit);
 134         vel.y = bound(vel_average.y - autocvar_cl_followmodel_limit, vel.y, vel_average.y + autocvar_cl_followmodel_limit);
 135         vel.z = bound(vel_average.z - autocvar_cl_followmodel_limit, vel.z, vel_average.z + autocvar_cl_followmodel_limit);
 136
 137         frac = avg_factor(autocvar_cl_followmodel_velocity_lowpass);
 138         lowpass3(vel, frac, vel_average, gunorg);
 139
 140         gunorg *= -autocvar_cl_followmodel_speed * 0.042;
 141
 142         // perform highpass/lowpass on the adjustment vectors (turning velocity into acceleration!)
 143         // trick: we must do the lowpass LAST, so the lowpass vector IS the final vector!
 144         frac = avg_factor(autocvar_cl_followmodel_highpass);
 145         highpass3(gunorg, frac, gunorg_adjustment_highpass, gunorg);
 146         frac = avg_factor(autocvar_cl_followmodel_lowpass);
 147         lowpass3(gunorg, frac, gunorg_adjustment_lowpass, gunorg);
 148
 149         if (autocvar_cl_followmodel_velocity_absolute)
 150         {
 151                 vector fixed_gunorg;
 152                 vector forward, right, up;
 153                 MAKE_VECTORS(view_angles, forward, right, up);
 154                 fixed_gunorg.x = gunorg * forward;
 155                 fixed_gunorg.y = gunorg * right * -1;
 156                 fixed_gunorg.z = gunorg * up;
 157                 gunorg = fixed_gunorg;
 158         }
 159
 160         cl_followmodel_ofs = gunorg;
 161         cl_followmodel_time = time;
 162 }
 163
 164 vector leanmodel_ofs(entity view)
 165 {
 166         float frac;
 167         vector gunangles = '0 0 0';
 168         static vector gunangles_prev = '0 0 0';
 169         static vector gunangles_highpass = '0 0 0';
 170         static vector gunangles_adjustment_highpass;
 171         static vector gunangles_adjustment_lowpass;
 172
 173         if (view.csqcmodel_teleported)
 174                 gunangles_prev = view_angles;
 175
 176         // in the highpass, we _store_ the DIFFERENCE to the actual view angles...
 177         gunangles_highpass += gunangles_prev;
 178         PITCH(gunangles_highpass) += 360 * floor((PITCH(view_angles) - PITCH(gunangles_highpass)) / 360 + 0.5);
 179         YAW(gunangles_highpass) += 360 * floor((YAW(view_angles) - YAW(gunangles_highpass)) / 360 + 0.5);
 180         ROLL(gunangles_highpass) += 360 * floor((ROLL(view_angles) - ROLL(gunangles_highpass)) / 360 + 0.5);
 181         frac = avg_factor(autocvar_cl_leanmodel_highpass1);
 182         highpass2_limited(view_angles, frac, autocvar_cl_leanmodel_limit, gunangles_highpass, gunangles);
 183         gunangles_prev = view_angles;
 184         gunangles_highpass -= gunangles_prev;
 185
 186         PITCH(gunangles) *= -autocvar_cl_leanmodel_speed;
 187         YAW(gunangles) *= -autocvar_cl_leanmodel_speed;
 188
 189         // we assume here: PITCH = 0, YAW = 1, ROLL = 2
 190         frac = avg_factor(autocvar_cl_leanmodel_highpass);
 191         highpass2(gunangles, frac, gunangles_adjustment_highpass, gunangles);
 192         frac = avg_factor(autocvar_cl_leanmodel_lowpass);
 193         lowpass2(gunangles, frac, gunangles_adjustment_lowpass, gunangles);
 194
 195         gunangles.x = -gunangles.x; // pitch was inverted, now that actually matters
 196
 197         return gunangles;
 198 }
 199
 200 vector bobmodel_ofs(entity view)
 201 {
 202         bool clonground = !(view.anim_implicit_state & ANIMIMPLICITSTATE_INAIR);
 203         static bool oldonground;
 204         static float hitgroundtime;
 205         if (clonground)
 206         {
 207                 float f = time; // cl.movecmd[0].time
 208                 if (!oldonground)
 209                         hitgroundtime = f;
 210         }
 211         oldonground = clonground;
 212
 213         // calculate for swinging gun model
 214         // the gun bobs when running on the ground, but doesn't bob when you're in the air.
 215         vector gunorg = '0 0 0';
 216         static float bobmodel_scale = 0;
 217         static float time_ofs = 0; // makes the effect always restart in the same way
 218         if (clonground)
 219         {
 220                 if (time - hitgroundtime > 0.05)
 221                         bobmodel_scale = min(1, bobmodel_scale + frametime * 5);
 222         }
 223         else
 224                 bobmodel_scale = max(0, bobmodel_scale - frametime * 5);
 225
 226         float xyspeed = bound(0, vlen(vec2(view.velocity)), 400);
 227         if (bobmodel_scale && xyspeed)
 228         {
 229                 float bspeed = xyspeed * 0.01 * autocvar_cl_viewmodel_scale * bobmodel_scale;
 230                 float s = (time - time_ofs) * autocvar_cl_bobmodel_speed;
 231                 gunorg.y = bspeed * autocvar_cl_bobmodel_side * sin(s);
 232                 gunorg.z = bspeed * autocvar_cl_bobmodel_up * cos(s * 2);
 233         }
 234         else
 235                 time_ofs = time;
 236
 237         return gunorg;
 238 }
 239
 240 void viewmodel_animate(entity this)
 241 {
 242         if (autocvar_chase_active) return;
 243         if (STAT(HEALTH) <= 0) return;
 244
 245         entity view = CSQCModel_server2csqc(player_localentnum - 1);
 246
 247         if (autocvar_cl_followmodel)
 248         {
 249                 calc_followmodel_ofs(view);
 250                 this.origin += cl_followmodel_ofs;
 251         }
 252
 253         if (autocvar_cl_leanmodel)
 254                 this.angles += leanmodel_ofs(view);
 255
 256         // vertical view bobbing code
 257         // TODO: cl_bob
 258
 259         // horizontal view bobbing code
 260         // TODO: cl_bob2
 261
 262         // fall bobbing code
 263         // causes the view to swing down and back up when touching the ground
 264         // TODO: cl_bobfall
 265
 266         // gun model bobbing code
 267         if (autocvar_cl_bobmodel)
 268                 this.origin += bobmodel_ofs(view);
 269 }
 270
 271 .vector viewmodel_origin, viewmodel_angles;
 272 .float weapon_nextthink;
 273 .float weapon_eta_last;
 274 .float weapon_switchdelay;
 275
 276 .string name_last;
 277
 278 void viewmodel_draw(entity this)
 279 {
 280         if(!this.activeweapon || !autocvar_r_drawviewmodel)
 281                 return;
 282         int mask = (intermission || (STAT(HEALTH) <= 0) || autocvar_chase_active) ? 0 : MASK_NORMAL;
 283         float a = ((autocvar_cl_viewmodel_alpha) ? bound(-1, autocvar_cl_viewmodel_alpha, this.m_alpha) : this.m_alpha);
 284         int wepskin = this.m_skin;
 285         bool invehicle = player_localentnum > maxclients;
 286         if (invehicle) a = -1;
 287         Weapon wep = this.activeweapon;
 288         int c = entcs_GetClientColors(current_player);
 289         vector g = weaponentity_glowmod(wep, NULL, c, this);
 290         entity me = CSQCModel_server2csqc(player_localentnum - 1);
 291         int fx = ((me.csqcmodel_effects & EFMASK_CHEAP)
 292                 | EF_NODEPTHTEST)
 293                 &~ (EF_FULLBRIGHT); // can mask team color, so get rid of it
 294         for (entity e = this; e; e = e.weaponchild)
 295         {
 296                 e.drawmask = mask;
 297                 e.alpha = a;
 298                 e.skin = wepskin;
 299                 e.colormap = 256 + c;  // colormap == 0 is black, c == 0 is white
 300                 e.glowmod = g;
 301                 e.csqcmodel_effects = fx;
 302                 CSQCModel_Effects_Apply(e);
 303         }
 304         if(a >= 0)
 305         {
 306                 string name = wep.mdl;
 307                 string newname = wep.wr_viewmodel(wep, this);
 308                 if(newname)
 309                         name = newname;
 310                 bool swap = name != this.name_last;
 311                 // if (swap)
 312                 {
 313                         this.name_last = name;
 314                         CL_WeaponEntity_SetModel(this, name, swap);
 315                         this.viewmodel_origin = this.origin;
 316                         this.viewmodel_angles = this.angles;
 317                 }
 318                 anim_update(this);
 319                 if ((!this.animstate_override && !this.animstate_looping) || time > this.animstate_endtime)
 320                         anim_set(this, this.anim_idle, true, false, false);
 321         }
 322         float f = 0; // 0..1; 0: fully active
 323         float rate = STAT(WEAPONRATEFACTOR);
 324         float eta = rate ? ((this.weapon_nextthink - time) / rate) : 0;
 325         if (eta <= 0) f = this.weapon_eta_last;
 326         else switch (this.state)
 327         {
 328                 case WS_RAISE:
 329                 {
 330                         f = eta / max(eta, this.weapon_switchdelay);
 331                         break;
 332                 }
 333                 case WS_DROP:
 334                 {
 335                         f = 1 - eta / max(eta, this.weapon_switchdelay);
 336                         break;
 337                 }
 338                 case WS_CLEAR:
 339                 {
 340                         f = 1;
 341                         break;
 342                 }
 343         }
 344         this.weapon_eta_last = f;
 345         this.origin = this.viewmodel_origin;
 346         this.angles = this.viewmodel_angles;
 347         this.angles_x = (-90 * f * f);
 348         viewmodel_animate(this);
 349         MUTATOR_CALLHOOK(DrawViewModel, this);
 350         setorigin(this, this.origin);
 351 }
 352
 353 STATIC_INIT(viewmodel) {
 354     for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 355         viewmodels[slot] = new(viewmodel);
 356 }
 357
 358 vector project_3d_to_2d(vector vec)
 359 {
 360         vec = cs_project(vec);
 361         if(cs_project_is_b0rked > 0)
 362         {
 363                 vec.x *= vid_conwidth / vid_width;
 364                 vec.y *= vid_conheight / vid_height;
 365         }
 366         return vec;
 367 }
 368
 369 bool projected_on_screen(vector screen_pos)
 370 {
 371         return screen_pos.z >= 0
 372                 && screen_pos.x >= 0
 373                 && screen_pos.y >= 0
 374                 && screen_pos.x < vid_conwidth
 375                 && screen_pos.y < vid_conheight;
 376 }
 377
 378 void update_mousepos()
 379 {
 380         mousepos += getmousepos() * autocvar_menu_mouse_speed;
 381         mousepos.x = bound(0, mousepos.x, vid_conwidth);
 382         mousepos.y = bound(0, mousepos.y, vid_conheight);
 383 }
 384
 385 float showfps_prevfps_time;
 386 int showfps_framecounter;
 387
 388 void fpscounter_update()
 389 {
 390         if(!STAT(SHOWFPS))
 391                 return;
 392
 393         float currentTime = gettime(GETTIME_FRAMESTART);
 394
 395         showfps_framecounter += 1;
 396         if(currentTime - showfps_prevfps_time > STAT(SHOWFPS))
 397         {
 398                 float fps = showfps_framecounter / (currentTime - showfps_prevfps_time);
 399                 showfps_framecounter = 0;
 400                 showfps_prevfps_time = currentTime;
 401
 402                 int channel = MSG_C2S;
 403                 WriteHeader(channel, fpsreport);
 404                 WriteShort(channel, bound(0, rint(fps), 65535)); // prevent insane fps values
 405         }
 406 }
 407
 408 STATIC_INIT(fpscounter_init)
 409 {
 410         float currentTime = gettime(GETTIME_FRAMESTART);
 411         showfps_prevfps_time = currentTime; // we must initialize it to avoid an instant low frame sending
 412 }
 413
 414 float avgspeed;
 415 vector GetCurrentFov(float fov)
 416 {
 417         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir;
 418         float velocityzoom, curspeed;
 419         vector v;
 420
 421         zoomsensitivity = autocvar_cl_zoomsensitivity;
 422         zoomfactor = autocvar_cl_zoomfactor;
 423         if(zoomfactor < 1 || zoomfactor > 30)
 424                 zoomfactor = 2.5;
 425         zoomspeed = autocvar_cl_zoomspeed;
 426         if (zoomspeed >= 0 && (zoomspeed < 0.5 || zoomspeed > 16))
 427                 zoomspeed = 3.5;
 428
 429         zoomdir = button_zoom;
 430
 431         if(hud == HUD_NORMAL && !spectatee_status)
 432         {
 433                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 434                 {
 435                         entity wepent = viewmodels[slot];
 436                         if(wepent.switchweapon != wepent.activeweapon)
 437                                 continue;
 438                         Weapon wep = wepent.activeweapon;
 439                         if(wep != WEP_Null && wep.wr_zoomdir)
 440                         {
 441                                 bool do_zoom = wep.wr_zoomdir(wep); // TODO: merge this with wr_zoom?
 442                                 zoomdir += do_zoom;
 443                         }
 444                 }
 445         }
 446         if(spectatee_status > 0 || isdemo())
 447         {
 448                 if(spectatorbutton_zoom)
 449                 {
 450                         if(zoomdir)
 451                                 zoomdir = 0;
 452                         else
 453                                 zoomdir = 1;
 454                 }
 455                 // fteqcc failed twice here already, don't optimize this
 456         }
 457
 458         if(zoomdir) { zoomin_effect = 0; }
 459
 460         if (spectatee_status > 0 && STAT(CAMERA_SPECTATOR) == 2)
 461         {
 462                 current_viewzoom = 1;
 463         }
 464         else if (camera_active)
 465         {
 466                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 467         }
 468         else if(autocvar_cl_spawnzoom && zoomin_effect)
 469         {
 470                 float spawnzoomfactor = bound(1, autocvar_cl_spawnzoom_factor, 30);
 471
 472                 current_viewzoom += (autocvar_cl_spawnzoom_speed * (spawnzoomfactor - current_viewzoom) * drawframetime);
 473                 current_viewzoom = bound(1 / spawnzoomfactor, current_viewzoom, 1);
 474                 if(current_viewzoom == 1) { zoomin_effect = 0; }
 475         }
 476         else
 477         {
 478                 if(zoomspeed < 0) // instant zoom
 479                 {
 480                         if(zoomdir)
 481                                 current_viewzoom = 1 / zoomfactor;
 482                         else
 483                                 current_viewzoom = 1;
 484                 }
 485                 else
 486                 {
 487                         if(zoomdir)
 488                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 489                         else
 490                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 491                 }
 492         }
 493
 494         if(almost_equals(current_viewzoom, 1))
 495                 current_zoomfraction = 0;
 496         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 497                 current_zoomfraction = 1;
 498         else
 499                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 500
 501         if(zoomsensitivity < 1)
 502                 setsensitivityscale(current_viewzoom ** (1 - zoomsensitivity));
 503         else
 504                 setsensitivityscale(1);
 505
 506         if(autocvar_cl_velocityzoom_enabled && autocvar_cl_velocityzoom_type && !autocvar_cl_lockview) // _type = 0 disables velocity zoom too
 507         {
 508                 if (intermission || (spectatee_status > 0 && STAT(CAMERA_SPECTATOR) == 2))
 509                         curspeed = 0;
 510                 else
 511                 {
 512                         vector forward, right, up;
 513                         MAKE_VECTORS(view_angles, forward, right, up);
 514                         v = pmove_vel;
 515                         if(csqcplayer)
 516                                 v = csqcplayer.velocity;
 517
 518                         switch(autocvar_cl_velocityzoom_type)
 519                         {
 520                                 case 3: curspeed = max(0, forward * v); break;
 521                                 case 2: curspeed = (forward * v); break;
 522                                 case 1: default: curspeed = vlen(v); break;
 523                         }
 524                 }
 525
 526                 velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoom_time), 1); // speed at which the zoom adapts to player velocity
 527                 avgspeed = avgspeed * (1 - velocityzoom) + (curspeed / autocvar_cl_velocityzoom_speed) * velocityzoom;
 528                 velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom_factor / 1) * 1);
 529
 530                 //print(ftos(avgspeed), " avgspeed, ", ftos(curspeed), " curspeed, ", ftos(velocityzoom), " return\n"); // for debugging
 531         }
 532         else
 533                 velocityzoom = 1;
 534
 535         float frustumx, frustumy, fovx, fovy;
 536         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 537         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 538         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 539         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 540
 541         return '1 0 0' * fovx + '0 1 0' * fovy;
 542 }
 543
 544 vector GetViewLocationFOV(float fov)
 545 {
 546         float frustumy = tan(fov * M_PI / 360.0) * 0.75;
 547         float frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 548         float fovx = atan2(frustumx, 1) / M_PI * 360.0;
 549         float fovy = atan2(frustumy, 1) / M_PI * 360.0;
 550         return '1 0 0' * fovx + '0 1 0' * fovy;
 551 }
 552
 553 vector GetOrthoviewFOV(vector ov_worldmin, vector ov_worldmax, vector ov_mid, vector ov_org)
 554 {
 555         float fovx, fovy;
 556         float width = (ov_worldmax.x - ov_worldmin.x);
 557         float height = (ov_worldmax.y - ov_worldmin.y);
 558         float distance_to_middle_of_world = vlen(ov_mid - ov_org);
 559         fovx = atan2(width/2, distance_to_middle_of_world) / M_PI * 360.0;
 560         fovy = atan2(height/2, distance_to_middle_of_world) / M_PI * 360.0;
 561         return '1 0 0' * fovx + '0 1 0' * fovy;
 562 }
 563
 564 // this function must match W_SetupShot!
 565
 566 bool minigame_wasactive;
 567
 568 float camera_mode;
 569 const float CAMERA_FREE = 1;
 570 const float CAMERA_CHASE = 2;
 571 string NextFrameCommand;
 572
 573 vector freeze_org, freeze_ang;
 574 entity nightvision_noise, nightvision_noise2;
 575
 576 float myhealth, myhealth_prev;
 577 float myhealth_flash;
 578
 579 float old_blurradius, old_bluralpha;
 580 float old_sharpen_intensity;
 581
 582 vector myhealth_gentlergb;
 583
 584 float contentavgalpha, liquidalpha_prev;
 585 vector liquidcolor_prev;
 586
 587 float eventchase_current_distance;
 588 float eventchase_running;
 589 int WantEventchase(entity this, bool want_vehiclechase)
 590 {
 591         if(autocvar_cl_orthoview)
 592                 return 0;
 593         if(STAT(GAME_STOPPED) || intermission)
 594                 return 1;
 595         if(this.viewloc)
 596                 return 1;
 597         if(spectatee_status >= 0)
 598         {
 599                 if(want_vehiclechase)
 600                         return 1;
 601                 if(MUTATOR_CALLHOOK(WantEventchase, this))
 602                         return 1;
 603                 if(autocvar_cl_eventchase_frozen && STAT(FROZEN))
 604                         return 1;
 605                 if(autocvar_cl_eventchase_death && (STAT(HEALTH) <= 0))
 606                 {
 607                         if(autocvar_cl_eventchase_death == 2)
 608                         {
 609                                 // don't stop eventchase once it's started (even if velocity changes afterwards)
 610                                 if(this.velocity == '0 0 0' || eventchase_running)
 611                                         return 1;
 612                         }
 613                         else return 1;
 614                 }
 615                 if (spectatee_status > 0 && autocvar_cl_eventchase_spectated_change)
 616                 {
 617                         if (time <= spectatee_status_changed_time + min(3, autocvar_cl_eventchase_spectated_change_time))
 618                                 return 1;
 619                         else if (eventchase_running)
 620                                 return -1; // disable chase_active while eventchase is still enabled so to avoid a glicth
 621                 }
 622         }
 623         return 0;
 624 }
 625
 626 void View_EventChase(entity this)
 627 {
 628         // event chase camera
 629         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
 630         {
 631                 if(STAT(CAMERA_SPECTATOR))
 632                 {
 633                         if(spectatee_status > 0)
 634                         {
 635                                 if(!autocvar_chase_active)
 636                                 {
 637                                         cvar_set("chase_active", "-2");
 638                                         return;
 639                                 }
 640                         }
 641                         else if(autocvar_chase_active == -2)
 642                                 cvar_set("chase_active", "0");
 643
 644                         if(autocvar_chase_active == -2)
 645                                 return;
 646                 }
 647                 else if(autocvar_chase_active == -2)
 648                         cvar_set("chase_active", "0");
 649
 650                 bool vehicle_chase = (hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0));
 651
 652                 float vehicle_viewdist = 0;
 653                 vector vehicle_viewofs = '0 0 0';
 654
 655                 if(vehicle_chase)
 656                 {
 657                         if(hud != HUD_BUMBLEBEE_GUN)
 658                         {
 659                                 Vehicle info = REGISTRY_GET(Vehicles, hud);
 660                                 vehicle_viewdist = info.height;
 661                                 vehicle_viewofs = info.view_ofs;
 662                                 if(vehicle_viewdist < 0) // when set below 0, this vehicle doesn't use third person view (gunner slots)
 663                                         vehicle_chase = false;
 664                         }
 665                         else
 666                                 vehicle_chase = false;
 667                 }
 668
 669                 int eventchase = WantEventchase(this, vehicle_chase);
 670                 if (eventchase)
 671                 {
 672                         vector current_view_origin_override = '0 0 0';
 673                         vector view_offset_override = '0 0 0';
 674                         float chase_distance_override = 0;
 675                         bool custom_eventchase = MUTATOR_CALLHOOK(CustomizeEventchase, this);
 676                         if(custom_eventchase)
 677                         {
 678                                 current_view_origin_override = M_ARGV(0, vector);
 679                                 view_offset_override = M_ARGV(1, vector);
 680                                 chase_distance_override = M_ARGV(0, float);
 681                         }
 682                         eventchase_running = true;
 683
 684                         // make special vector since we can't use view_origin (It is one frame old as of this code, it gets set later with the results this code makes.)
 685                         vector current_view_origin = (csqcplayer ? csqcplayer.origin : pmove_org);
 686                         if (custom_eventchase)
 687                                 current_view_origin = current_view_origin_override;
 688
 689                         // detect maximum viewoffset and use it
 690                         vector view_offset = autocvar_cl_eventchase_viewoffset;
 691                         if(vehicle_chase)
 692                         {
 693                                 if(vehicle_viewofs)
 694                                         view_offset = vehicle_viewofs;
 695                                 else
 696                                         view_offset = autocvar_cl_eventchase_vehicle_viewoffset;
 697                         }
 698                         if (custom_eventchase)
 699                                 view_offset = view_offset_override;
 700
 701                         if(view_offset)
 702                         {
 703                                 WarpZone_TraceLine(current_view_origin, current_view_origin + view_offset + ('0 0 1' * autocvar_cl_eventchase_maxs.z), MOVE_WORLDONLY, this);
 704                                 if(trace_fraction == 1) { current_view_origin += view_offset; }
 705                                 else { current_view_origin.z += max(0, (trace_endpos.z - current_view_origin.z) - autocvar_cl_eventchase_maxs.z); }
 706                         }
 707
 708                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
 709                         // Ideally, there should be another way to enable third person cameras, such as through setproperty()
 710                         // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
 711                         if(!autocvar_chase_active) { cvar_set("chase_active", "-1"); }
 712
 713                         // make the camera smooth back
 714                         float chase_distance = autocvar_cl_eventchase_distance;
 715                         if(vehicle_chase)
 716                         {
 717                                 if(vehicle_viewofs)
 718                                         chase_distance = vehicle_viewdist;
 719                                 else
 720                                         chase_distance = autocvar_cl_eventchase_vehicle_distance;
 721                         }
 722                         if (custom_eventchase)
 723                                 chase_distance = chase_distance_override;
 724
 725                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < chase_distance)
 726                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (chase_distance - eventchase_current_distance) * frametime; // slow down the further we get
 727                         else if(eventchase_current_distance != chase_distance)
 728                                 eventchase_current_distance = chase_distance;
 729
 730                         vector forward, right, up;
 731                         MAKE_VECTORS(view_angles, forward, right, up);
 732
 733                         vector eventchase_target_origin = (current_view_origin - (forward * eventchase_current_distance));
 734                         WarpZone_TraceBox(current_view_origin, autocvar_cl_eventchase_mins, autocvar_cl_eventchase_maxs, eventchase_target_origin, MOVE_WORLDONLY, this);
 735
 736                         // If the boxtrace fails, revert back to line tracing.
 737                         if(!this.viewloc)
 738                         if(trace_startsolid)
 739                         {
 740                                 eventchase_target_origin = (current_view_origin - (forward * eventchase_current_distance));
 741                                 WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, this);
 742                                 setproperty(VF_ORIGIN, (trace_endpos - (forward * autocvar_cl_eventchase_mins.z)));
 743                         }
 744                         else { setproperty(VF_ORIGIN, trace_endpos); }
 745
 746                         if(!this.viewloc)
 747                                 setproperty(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
 748                 }
 749
 750                 if (eventchase <= 0 && autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
 751                 {
 752                         eventchase_running = false;
 753                         cvar_set("chase_active", "0");
 754                         eventchase_current_distance = 0; // start from 0 next time
 755                 }
 756         }
 757         // workaround for camera stuck between player's legs when using chase_active 1
 758         // because the engine stops updating the chase_active camera when the game ends
 759         else if(intermission)
 760         {
 761                 cvar_settemp("chase_active", "-1");
 762                 eventchase_current_distance = 0;
 763         }
 764 }
 765
 766 vector damage_blurpostprocess, content_blurpostprocess;
 767
 768 void UpdateDamage()
 769 {
 770         // accumulate damage with each stat update
 771         static float damage_total_prev = 0;
 772         float damage_total = STAT(DAMAGE_DEALT_TOTAL);
 773         float unaccounted_damage_new = COMPARE_INCREASING(damage_total, damage_total_prev);
 774         damage_total_prev = damage_total;
 775
 776         static float damage_dealt_time_prev = 0;
 777         float damage_dealt_time = STAT(HIT_TIME);
 778         if (damage_dealt_time != damage_dealt_time_prev)
 779         {
 780                 unaccounted_damage += unaccounted_damage_new;
 781                 //LOG_TRACE("dmg total: ", ftos(unaccounted_damage), " (+", ftos(unaccounted_damage_new), ")");
 782         }
 783         damage_dealt_time_prev = damage_dealt_time;
 784
 785         // prevent hitsound when switching spectatee
 786         static float spectatee_status_prev = 0;
 787         if (spectatee_status != spectatee_status_prev)
 788                 unaccounted_damage = 0;
 789         spectatee_status_prev = spectatee_status;
 790 }
 791
 792 void HitSound()
 793 {
 794         // varying sound pitch
 795
 796         bool have_arc = false;
 797         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 798         {
 799                 entity wepent = viewmodels[slot];
 800
 801                 if(wepent.activeweapon == WEP_ARC)
 802                         have_arc = true;
 803         }
 804
 805         static float hitsound_time_prev = 0;
 806         // HACK: the only way to get the arc to sound consistent with pitch shift is to ignore cl_hitsound_antispam_time
 807         bool arc_hack = have_arc && autocvar_cl_hitsound >= 2;
 808         if (arc_hack || COMPARE_INCREASING(time, hitsound_time_prev) > autocvar_cl_hitsound_antispam_time)
 809         {
 810                 if (autocvar_cl_hitsound && unaccounted_damage)
 811                 {
 812                         // customizable gradient function that crosses (0,a), (c,1) and asymptotically approaches b
 813                         float a = autocvar_cl_hitsound_max_pitch;
 814                         float b = autocvar_cl_hitsound_min_pitch;
 815                         float c = autocvar_cl_hitsound_nom_damage;
 816                         float d = unaccounted_damage;
 817                         float pitch_shift = (b*d*(a-1) + a*c*(1-b)) / (d*(a-1) + c*(1-b));
 818
 819                         // if sound variation is disabled, set pitch_shift to 1
 820                         if (autocvar_cl_hitsound == 1)
 821                                 pitch_shift = 1;
 822
 823                         // if pitch shift is reversed, mirror in (max-min)/2 + min
 824                         if (autocvar_cl_hitsound == 3)
 825                         {
 826                                 float mirror_value = (a-b)/2 + b;
 827                                 pitch_shift = mirror_value + (mirror_value - pitch_shift);
 828                         }
 829
 830                         //LOG_TRACE("dmg total (dmg): ", ftos(unaccounted_damage), " , pitch shift: ", ftos(pitch_shift));
 831
 832                         // todo: avoid very long and very short sounds from wave stretching using different sound files? seems unnecessary
 833                         // todo: normalize sound pressure levels? seems unnecessary
 834
 835                         sound7(NULL, CH_INFO, SND(HIT), VOL_BASE, ATTN_NONE, pitch_shift * 100, 0);
 836                 }
 837                 unaccounted_damage = 0;
 838                 hitsound_time_prev = time;
 839         }
 840
 841         static float typehit_time_prev = 0;
 842         float typehit_time = STAT(TYPEHIT_TIME);
 843         if (COMPARE_INCREASING(typehit_time, typehit_time_prev) > autocvar_cl_hitsound_antispam_time)
 844         {
 845                 sound(NULL, CH_INFO, SND_TYPEHIT, VOL_BASE, ATTN_NONE);
 846                 typehit_time_prev = typehit_time;
 847         }
 848
 849         static float kill_time_prev = 0;
 850         float kill_time = STAT(KILL_TIME);
 851         if (COMPARE_INCREASING(kill_time, kill_time_prev) > autocvar_cl_hitsound_antispam_time)
 852         {
 853                 sound(NULL, CH_INFO, SND_KILL, VOL_BASE, ATTN_NONE);
 854                 kill_time_prev = kill_time;
 855         }
 856 }
 857
 858 const int MAX_SPECIALCOMMAND = 15;
 859 vector specialcommand_slots[MAX_SPECIALCOMMAND];
 860 vector specialcommand_colors[MAX_SPECIALCOMMAND];
 861 const float SPECIALCOMMAND_SPEED = 150;
 862 const float SPECIALCOMMAND_TURNSPEED = 2;
 863 const float SPECIALCOMMAND_SIZE = 0.025;
 864 const float SPECIALCOMMAND_CHANCE = 0.35;
 865 float sc_spawntime, sc_changetime;
 866 vector sc_color = '1 1 1';
 867 void SpecialCommand()
 868 {
 869         if(!STAT(MOVEVARS_SPECIALCOMMAND))
 870                 return;
 871
 872         if(time >= sc_changetime)
 873         {
 874                 sc_changetime = time + 1;
 875                 sc_color = randomvec() * 1.5;
 876                 sc_color.x = bound(0.2, sc_color.x, 0.75);
 877                 sc_color.y = bound(0.2, sc_color.y, 0.75);
 878                 sc_color.z = bound(0.2, sc_color.z, 0.75);
 879         }
 880         drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), sc_color, autocvar_hud_colorflash_alpha * bound(0.1, sc_changetime - time, 0.3), DRAWFLAG_ADDITIVE);
 881
 882         if(!precache_pic("gfx/smile"))
 883                 return; // damn party poopers
 884
 885         for(int j = MAX_SPECIALCOMMAND - 1; j >= 0; --j)
 886         {
 887                 vector slot = specialcommand_slots[j];
 888                 if(slot.y)
 889                         slot.y += SPECIALCOMMAND_SPEED * frametime;
 890                 //if(slot.z)
 891                         //slot.z = sin(SPECIALCOMMAND_TURNSPEED * M_PI * time);
 892                 if(slot.y >= vid_conheight)
 893                         slot = '0 0 0';
 894
 895                 if(slot == '0 0 0')
 896                 {
 897                         if(random() <= SPECIALCOMMAND_CHANCE && time > sc_spawntime) // low chance to spawn!
 898                         {
 899                                 slot.x = bound(0, (random() * vid_conwidth + 1), vid_conwidth);
 900                                 slot.y = 1; // start it off 0 so we can use it
 901                                 slot.z = floor(random() * REGISTRY_MAX(Weapons));
 902                                 sc_spawntime = time + bound(0.4, random(), 0.75); // prevent spawning another one for this amount of time!
 903                                 vector newcolor = randomvec() * 2;
 904                                 newcolor.x = bound(0.4, newcolor.x, 1);
 905                                 newcolor.y = bound(0.4, newcolor.y, 1);
 906                                 newcolor.z = bound(0.4, newcolor.z, 1);
 907                                 specialcommand_colors[j] = newcolor;
 908                         }
 909                 }
 910                 else
 911                 {
 912                         vector splash_size = '0 0 0';
 913                         splash_size.x = max(vid_conwidth, vid_conheight) * SPECIALCOMMAND_SIZE;
 914                         splash_size.y = max(vid_conwidth, vid_conheight) * SPECIALCOMMAND_SIZE;
 915                         entity wep = REGISTRY_GET(Weapons, slot.z);
 916                         if(wep == WEP_Null)
 917                                 drawpic(vec2(slot), "gfx/smile", vec2(splash_size), specialcommand_colors[j], 0.95, DRAWFLAG_NORMAL);
 918                         else
 919                                 drawpic_skin(vec2(slot), wep.model2, vec2(splash_size), specialcommand_colors[j], 0.95, DRAWFLAG_NORMAL);
 920                         //drawrotpic(vec2(slot), slot.z, "gfx/smile", vec2(splash_size), vec2(splash_size) / 2, specialcommand_colors[j], 0.95, DRAWFLAG_NORMAL);
 921                 }
 922
 923                 specialcommand_slots[j] = slot;
 924         }
 925 }
 926
 927 void HUD_Draw(entity this)
 928 {
 929         // if we don't know gametype and scores yet avoid drawing the scoreboard
 930         // also in the very first frames, player state may be inconsistent so avoid drawing the hud at all
 931         // e.g. since initial player's health is 0 hud would display the hud_damage effect,
 932         // cl_deathscoreboard would show the scoreboard and so on
 933         if(!gametype)
 934                 return;
 935
 936         Hud_Dynamic_Frame();
 937
 938         if(!intermission)
 939         if (MUTATOR_CALLHOOK(HUD_Draw_overlay))
 940         {
 941                 drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), M_ARGV(0, vector), autocvar_hud_colorflash_alpha * M_ARGV(1, float), DRAWFLAG_ADDITIVE);
 942         }
 943         else if(STAT(FROZEN))
 944         {
 945                 vector col = '0.25 0.90 1';
 946                 float col_fade = max(0, STAT(REVIVE_PROGRESS) * 2 - 1);
 947                 float alpha_fade = 0.3 + 0.7 * (1 - max(0, STAT(REVIVE_PROGRESS) * 4 - 3));
 948                 if(col_fade)
 949                         col += vec3(col_fade, -col_fade, -col_fade);
 950                 drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), col, autocvar_hud_colorflash_alpha * alpha_fade, DRAWFLAG_ADDITIVE);
 951         }
 952
 953         HUD_Scale_Enable();
 954         if(!intermission)
 955         if(STAT(NADE_TIMER) && autocvar_cl_nade_timer) // give nade top priority, as it's a matter of life and death
 956         {
 957                 vector col = '0.25 0.90 1' + vec3(STAT(NADE_TIMER), -STAT(NADE_TIMER), -STAT(NADE_TIMER));
 958                 DrawCircleClippedPic(vec2(0.5 * vid_conwidth, 0.6 * vid_conheight), 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(NADE_TIMER), col, autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
 959                 drawstring_aspect(eY * 0.64 * vid_conheight, ((autocvar_cl_nade_timer == 2) ? _("Nade timer") : ""), vec2(vid_conwidth, 0.025 * vid_conheight), '1 1 1', 1, DRAWFLAG_NORMAL);
 960         }
 961         else if(STAT(CAPTURE_PROGRESS))
 962         {
 963                 DrawCircleClippedPic(vec2(0.5 * vid_conwidth, 0.6 * vid_conheight), 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(CAPTURE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
 964                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Capture progress"), vec2(vid_conwidth, 0.025 * vid_conheight), '1 1 1', 1, DRAWFLAG_NORMAL);
 965         }
 966         else if(STAT(REVIVE_PROGRESS))
 967         {
 968                 DrawCircleClippedPic(vec2(0.5 * vid_conwidth, 0.6 * vid_conheight), 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
 969                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Revival progress"), vec2(vid_conwidth, 0.025 * vid_conheight), '1 1 1', 1, DRAWFLAG_NORMAL);
 970         }
 971         HUD_Scale_Disable();
 972
 973         if(autocvar_r_letterbox == 0)
 974                 if(autocvar_viewsize < 120)
 975                 {
 976                         if(!MUTATOR_CALLHOOK(DrawScoreboardAccuracy))
 977                                 Accuracy_LoadLevels();
 978
 979                         HUD_Main();
 980                         HUD_Scale_Disable();
 981                 }
 982
 983         // crosshair goes VERY LAST
 984         SpecialCommand();
 985         UpdateDamage();
 986         HUD_Crosshair(this);
 987         HitSound();
 988 }
 989
 990 void ViewLocation_Mouse()
 991 {
 992         if(spectatee_status)
 993                 return; // don't draw it as spectator!
 994
 995         viewloc_mousepos += getmousepos() * autocvar_menu_mouse_speed;
 996         viewloc_mousepos.x = bound(0, viewloc_mousepos.x, vid_conwidth);
 997         viewloc_mousepos.y = bound(0, viewloc_mousepos.y, vid_conheight);
 998
 999         //float cursor_alpha = 1 - autocvar__menu_alpha;
1000         //cursor_type = CURSOR_NORMAL;
1001         //draw_cursor(viewloc_mousepos, '0.5 0.5 0', "/cursor_move", '1 1 1', cursor_alpha);
1002 }
1003
1004 void HUD_Cursor_Show()
1005 {
1006         float cursor_alpha = 1 - autocvar__menu_alpha;
1007         if(cursor_type == CURSOR_NORMAL)
1008                 draw_cursor_normal(mousepos, '1 1 1', cursor_alpha);
1009         else if(cursor_type == CURSOR_MOVE)
1010                 draw_cursor(mousepos, '0.5 0.5 0', "/cursor_move", '1 1 1', cursor_alpha);
1011         else if(cursor_type == CURSOR_RESIZE)
1012                 draw_cursor(mousepos, '0.5 0.5 0', "/cursor_resize", '1 1 1', cursor_alpha);
1013         else if(cursor_type == CURSOR_RESIZE2)
1014                 draw_cursor(mousepos, '0.5 0.5 0', "/cursor_resize2", '1 1 1', cursor_alpha);
1015 }
1016
1017 void HUD_Mouse(entity player)
1018 {
1019         if(autocvar__menu_alpha == 1)
1020                 return;
1021
1022         if(!cursor_active)
1023         {
1024                 if(player.viewloc && (player.viewloc.spawnflags & VIEWLOC_FREEAIM))
1025                         ViewLocation_Mouse(); // NOTE: doesn't use cursormode
1026                 return;
1027         }
1028
1029         if (cursor_active == -1) // starting to display the cursor
1030         {
1031                 // since HUD_Mouse is called by CSQC_UpdateView before CSQC_InputEvent,
1032                 // in the first frame mousepos is the mouse position of the last time
1033                 // the cursor was displayed, thus we ignore it to avoid a glictch
1034                 cursor_active = 1;
1035                 return;
1036         }
1037
1038         if(!autocvar_hud_cursormode)
1039                 update_mousepos();
1040
1041         cursor_type = CURSOR_NORMAL;
1042         if(autocvar__hud_configure)
1043                 HUD_Panel_Mouse();
1044         else
1045         {
1046                 if (HUD_MinigameMenu_IsOpened())
1047                         HUD_Minigame_Mouse();
1048                 if (QuickMenu_IsOpened())
1049                         QuickMenu_Mouse();
1050                 if (HUD_Radar_Clickable())
1051                         HUD_Radar_Mouse();
1052         }
1053
1054         prevMouseClicked = mouseClicked;
1055
1056         HUD_Cursor_Show();
1057 }
1058
1059 void View_NightVision()
1060 {
1061         if(!(autocvar_r_fakelight >= 2 || autocvar_r_fullbright) || (serverflags & SERVERFLAG_ALLOW_FULLBRIGHT))
1062                 return;
1063
1064         // apply night vision effect
1065         vector tc_00, tc_01, tc_10, tc_11;
1066         vector rgb = '0 0 0';
1067         float a;
1068
1069         if(!nightvision_noise)
1070         {
1071                 nightvision_noise = new(nightvision_noise);
1072         }
1073         if(!nightvision_noise2)
1074         {
1075                 nightvision_noise2 = new(nightvision_noise2);
1076         }
1077
1078         // color tint in yellow
1079         drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
1080
1081         // draw BG
1082         a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
1083         rgb = '1 1 1';
1084         tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
1085         tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
1086         tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
1087         //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
1088         tc_11 = tc_01 + tc_10 - tc_00;
1089         R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE, true);
1090         R_PolygonVertex('0 0 0', tc_00, rgb, a);
1091         R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
1092         R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
1093         R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
1094         R_EndPolygon();
1095
1096         // draw FG
1097         a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
1098         rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
1099         tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
1100         tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
1101         tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
1102         tc_11 = tc_01 + tc_10 - tc_00;
1103         R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE, true);
1104         R_PolygonVertex('0 0 0', tc_00, rgb, a);
1105         R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
1106         R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
1107         R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
1108         R_EndPolygon();
1109 }
1110
1111 // visual overlay while in liquids
1112 // provides some effects to the postprocessing function
1113 void HUD_Contents()
1114 {
1115         if(!autocvar_hud_contents || MUTATOR_CALLHOOK(HUD_Contents))
1116                 return;
1117
1118         // improved polyblend
1119         float contentalpha_temp, incontent, liquidalpha, contentfadetime;
1120         vector liquidcolor;
1121
1122         switch(pointcontents(view_origin))
1123         {
1124                 case CONTENT_WATER:
1125                         liquidalpha = autocvar_hud_contents_water_alpha;
1126                         liquidcolor = stov(autocvar_hud_contents_water_color);
1127                         incontent = 1;
1128                         break;
1129
1130                 case CONTENT_LAVA:
1131                         liquidalpha = autocvar_hud_contents_lava_alpha;
1132                         liquidcolor = stov(autocvar_hud_contents_lava_color);
1133                         incontent = 1;
1134                         break;
1135
1136                 case CONTENT_SLIME:
1137                         liquidalpha = autocvar_hud_contents_slime_alpha;
1138                         liquidcolor = stov(autocvar_hud_contents_slime_color);
1139                         incontent = 1;
1140                         break;
1141
1142                 default:
1143                         liquidalpha = 0;
1144                         liquidcolor = '0 0 0';
1145                         incontent = 0;
1146                         break;
1147         }
1148
1149         if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
1150         { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
1151                 contentfadetime = autocvar_hud_contents_fadeintime;
1152                 liquidalpha_prev = liquidalpha;
1153                 liquidcolor_prev = liquidcolor;
1154         }
1155         else
1156                 contentfadetime = autocvar_hud_contents_fadeouttime;
1157
1158         contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
1159         contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
1160
1161         if(contentavgalpha)
1162                 drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
1163
1164         if(autocvar_hud_postprocessing)
1165         {
1166                 if(autocvar_hud_contents_blur && contentavgalpha)
1167                 {
1168                         content_blurpostprocess.x = 1;
1169                         content_blurpostprocess.y = contentavgalpha * autocvar_hud_contents_blur;
1170                         content_blurpostprocess.z = contentavgalpha * autocvar_hud_contents_blur_alpha;
1171                 }
1172                 else
1173                 {
1174                         content_blurpostprocess.x = 0;
1175                         content_blurpostprocess.y = 0;
1176                         content_blurpostprocess.z = 0;
1177                 }
1178         }
1179 }
1180
1181 // visual pain effects on the screen
1182 // provides some effects to the postprocessing function
1183 void HUD_Damage()
1184 {
1185         if(!autocvar_hud_damage || STAT(FROZEN))
1186                 return;
1187
1188         vector splash_pos = '0 0 0', splash_size = '0 0 0';
1189         splash_size.x = max(vid_conwidth, vid_conheight);
1190         splash_size.y = max(vid_conwidth, vid_conheight);
1191         splash_pos.x = (vid_conwidth - splash_size.x) / 2;
1192         splash_pos.y = (vid_conheight - splash_size.y) / 2;
1193
1194         float myhealth_flash_temp;
1195         myhealth = STAT(HEALTH);
1196
1197         // fade out
1198         myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
1199         // add new damage
1200         myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
1201
1202         float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
1203         pain_threshold = autocvar_hud_damage_pain_threshold;
1204         pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
1205         pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
1206
1207         if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
1208         {
1209                 pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
1210         }
1211
1212         myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
1213
1214         if(myhealth_prev < 1)
1215         {
1216                 if(myhealth >= 1)
1217                 {
1218                         myhealth_flash = 0; // just spawned, clear the flash immediately
1219                         myhealth_flash_temp = 0;
1220                 }
1221                 else
1222                 {
1223                         myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
1224                 }
1225         }
1226
1227         if(spectatee_status == -1 || intermission)
1228         {
1229                 myhealth_flash = 0; // observing, or match ended
1230                 myhealth_flash_temp = 0;
1231         }
1232
1233         myhealth_prev = myhealth;
1234
1235         // IDEA: change damage color/picture based on player model for robot/alien species?
1236         // pro: matches model better
1237         // contra: it's not red because blood is red, but because red is an alarming color, so red should stay
1238         // maybe different reddish pics?
1239         if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
1240         {
1241                 if(autocvar_cl_gentle_damage == 2)
1242                 {
1243                         if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
1244                                 myhealth_gentlergb = randomvec();
1245                 }
1246                 else
1247                         myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
1248
1249                 if(myhealth_flash_temp > 0)
1250                         drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
1251         }
1252         else if(myhealth_flash_temp > 0)
1253                 drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
1254
1255         if(autocvar_hud_postprocessing) // we still need to set this anyway even when chase_active is set, this way it doesn't get stuck on.
1256         {
1257                 if(autocvar_hud_damage_blur && myhealth_flash_temp)
1258                 {
1259                         damage_blurpostprocess.x = 1;
1260                         damage_blurpostprocess.y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
1261                         damage_blurpostprocess.z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
1262                 }
1263                 else
1264                 {
1265                         damage_blurpostprocess.x = 0;
1266                         damage_blurpostprocess.y = 0;
1267                         damage_blurpostprocess.z = 0;
1268                 }
1269         }
1270 }
1271
1272 void View_PostProcessing()
1273 {
1274         float e1 = (autocvar_hud_postprocessing_maxbluralpha != 0);
1275         float e2 = (autocvar_hud_powerup != 0);
1276         if(autocvar_hud_postprocessing && (e1 || e2)) // TODO: Remove this code and re-do the postprocess handling in the engine, where it properly belongs.
1277         {
1278                 // enable or disable rendering types if they are used or not
1279                 if(cvar("r_glsl_postprocess_uservec1_enable") != e1) { cvar_set("r_glsl_postprocess_uservec1_enable", ftos(e1)); }
1280                 if(cvar("r_glsl_postprocess_uservec2_enable") != e2) { cvar_set("r_glsl_postprocess_uservec2_enable", ftos(e2)); }
1281
1282                 // blur postprocess handling done first (used by hud_damage and hud_contents)
1283                 if((damage_blurpostprocess.x || content_blurpostprocess.x))
1284                 {
1285                         float blurradius = bound(0, damage_blurpostprocess.y + content_blurpostprocess.y, autocvar_hud_postprocessing_maxblurradius);
1286                         float bluralpha = bound(0, damage_blurpostprocess.z + content_blurpostprocess.z, autocvar_hud_postprocessing_maxbluralpha);
1287                         if(blurradius != old_blurradius || bluralpha != old_bluralpha) // reduce cvar_set spam as much as possible
1288                         {
1289                                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
1290                                 old_blurradius = blurradius;
1291                                 old_bluralpha = bluralpha;
1292                         }
1293                 }
1294                 else if(cvar_string("r_glsl_postprocess_uservec1") != "0 0 0 0") // reduce cvar_set spam as much as possible
1295                 {
1296                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
1297                         old_blurradius = 0;
1298                         old_bluralpha = 0;
1299                 }
1300
1301                 // edge detection postprocess handling done second (used by hud_powerup)
1302                 float sharpen_intensity = 0, strength_finished = STAT(STRENGTH_FINISHED), invincible_finished = STAT(INVINCIBLE_FINISHED);
1303                 if (strength_finished - time > 0) { sharpen_intensity += (strength_finished - time); }
1304                 if (invincible_finished - time > 0) { sharpen_intensity += (invincible_finished - time); }
1305
1306                 sharpen_intensity = bound(0, ((STAT(HEALTH) > 0) ? sharpen_intensity : 0), 5); // Check to see if player is alive (if not, set 0) - also bound to fade out starting at 5 seconds.
1307
1308                 if(autocvar_hud_powerup && sharpen_intensity > 0)
1309                 {
1310                         if(sharpen_intensity != old_sharpen_intensity) // reduce cvar_set spam as much as possible
1311                         {
1312                                 cvar_set("r_glsl_postprocess_uservec2", strcat(ftos((sharpen_intensity / 5) * autocvar_hud_powerup), " ", ftos(-sharpen_intensity * autocvar_hud_powerup), " 0 0"));
1313                                 old_sharpen_intensity = sharpen_intensity;
1314                         }
1315                 }
1316                 else if(cvar_string("r_glsl_postprocess_uservec2") != "0 0 0 0") // reduce cvar_set spam as much as possible
1317                 {
1318                         cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
1319                         old_sharpen_intensity = 0;
1320                 }
1321
1322                 if(cvar("r_glsl_postprocess") == 0)
1323                         cvar_set("r_glsl_postprocess", "2");
1324         }
1325         else if(cvar("r_glsl_postprocess") == 2)
1326                 cvar_set("r_glsl_postprocess", "0");
1327 }
1328
1329 void View_Lock()
1330 {
1331         int lock_type = autocvar_cl_lockview;
1332
1333         if (!autocvar_hud_cursormode
1334                 && ((autocvar__hud_configure && spectatee_status <= 0)
1335                         || intermission > 1
1336                         || HUD_Radar_Clickable()
1337                         || HUD_MinigameMenu_IsOpened()
1338                         || QuickMenu_IsOpened()
1339                 )
1340         )
1341                 lock_type = 1;
1342
1343         // lock_type 1: lock origin and angles
1344         // lock_type 2: lock only origin
1345         if(lock_type >= 1)
1346                 setproperty(VF_ORIGIN, freeze_org);
1347         else
1348                 freeze_org = getpropertyvec(VF_ORIGIN);
1349         if(lock_type == 1)
1350                 setproperty(VF_ANGLES, freeze_ang);
1351         else
1352                 freeze_ang = getpropertyvec(VF_ANGLES);
1353 }
1354
1355 void View_DemoCamera()
1356 {
1357         if(camera_active) // Camera for demo playback
1358         {
1359                 if(autocvar_camera_enable)
1360                         CSQC_Demo_Camera();
1361                 else
1362                 {
1363                         cvar_set("chase_active", ftos(chase_active_backup));
1364                         cvar_set("cl_demo_mousegrab", "0");
1365                         camera_active = false;
1366                 }
1367         }
1368         else
1369         {
1370 #ifdef CAMERATEST
1371                 if(autocvar_camera_enable)
1372 #else
1373                 if(autocvar_camera_enable && isdemo())
1374 #endif
1375                 {
1376                         // Enable required Darkplaces cvars
1377                         chase_active_backup = autocvar_chase_active;
1378                         cvar_set("chase_active", "2");
1379                         cvar_set("cl_demo_mousegrab", "1");
1380                         camera_active = true;
1381                         camera_mode = false;
1382                 }
1383         }
1384 }
1385
1386 #ifdef BLURTEST
1387 void View_BlurTest()
1388 {
1389         if(time > blurtest_time0 && time < blurtest_time1)
1390         {
1391                 float t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
1392                 float r = t * blurtest_radius;
1393                 float f = 1 / (t ** blurtest_power) - 1;
1394
1395                 cvar_set("r_glsl_postprocess", "1");
1396                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
1397         }
1398         else
1399         {
1400                 cvar_set("r_glsl_postprocess", "0");
1401                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
1402         }
1403 }
1404 #endif
1405
1406 void View_CheckButtonStatus()
1407 {
1408         float is_dead = (STAT(HEALTH) <= 0);
1409
1410         // FIXME do we need this hack?
1411         if(isdemo())
1412         {
1413                 // in demos, input_buttons do not work
1414                 button_zoom = (autocvar__togglezoom == "-");
1415         }
1416         else if(button_zoom
1417                 && autocvar_cl_unpress_zoom_on_death
1418                 && (spectatee_status >= 0)
1419                 && (is_dead || intermission))
1420         {
1421                 // no zoom while dead or in intermission please
1422                 localcmd("-zoom\n");
1423                 button_zoom = false;
1424         }
1425
1426         if(autocvar_fov <= 59.5)
1427         {
1428                 if(!zoomscript_caught)
1429                 {
1430                         localcmd("+button9\n");
1431                         zoomscript_caught = 1;
1432                 }
1433         }
1434         else
1435         {
1436                 if(zoomscript_caught)
1437                 {
1438                         localcmd("-button9\n");
1439                         zoomscript_caught = 0;
1440                 }
1441         }
1442
1443         if(active_minigame && HUD_MinigameMenu_IsOpened())
1444         {
1445                 if(!minigame_wasactive)
1446                 {
1447                         localcmd("+button12\n");
1448                         minigame_wasactive = true;
1449                 }
1450         }
1451         else if(minigame_wasactive)
1452         {
1453                 localcmd("-button12\n");
1454                 minigame_wasactive = false;
1455         }
1456
1457         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1458         {
1459                 entity wepent = viewmodels[slot];
1460
1461                 if(wepent.last_switchweapon != wepent.switchweapon)
1462                 {
1463                         weapontime = time;
1464                         wepent.last_switchweapon = wepent.switchweapon;
1465                         if(slot == 0 && button_zoom && autocvar_cl_unpress_zoom_on_weapon_switch)
1466                         {
1467                                 localcmd("-zoom\n");
1468                                 button_zoom = false;
1469                         }
1470                         if(slot == 0 && autocvar_cl_unpress_attack_on_weapon_switch)
1471                         {
1472                                 localcmd("-fire\n");
1473                                 localcmd("-fire2\n");
1474                                 button_attack2 = false;
1475                         }
1476                 }
1477                 if(wepent.last_activeweapon != wepent.activeweapon)
1478                 {
1479                         wepent.last_activeweapon = wepent.activeweapon;
1480
1481                         entity e = wepent.activeweapon;
1482                         if(e.netname != "")
1483                                 localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
1484                         else if(slot == 0)
1485                                 localcmd("\ncl_hook_activeweapon none\n");
1486                 }
1487         }
1488 }
1489
1490 bool ov_enabled;
1491 float oldr_nearclip;
1492 float oldr_farclip_base;
1493 float oldr_farclip_world;
1494 float oldr_novis;
1495 float oldr_useportalculling;
1496 float oldr_useinfinitefarclip;
1497 vector ov_org = '0 0 0';
1498 vector ov_mid = '0 0 0';
1499 vector ov_worldmin = '0 0 0';
1500 vector ov_worldmax = '0 0 0';
1501
1502 void View_Ortho()
1503 {
1504         ov_org = '0 0 0';
1505         ov_mid = '0 0 0';
1506         ov_worldmin = '0 0 0';
1507         ov_worldmax = '0 0 0';
1508         if(autocvar_cl_orthoview)
1509         {
1510                 ov_worldmin = mi_picmin;
1511                 ov_worldmax = mi_picmax;
1512
1513                 float ov_width = (ov_worldmax.x - ov_worldmin.x);
1514                 float ov_height = (ov_worldmax.y - ov_worldmin.y);
1515                 float ov_distance = (max(vid_width, vid_height) * max(ov_width, ov_height));
1516
1517                 ov_mid = ((ov_worldmax + ov_worldmin) * 0.5);
1518                 ov_org = vec3(ov_mid.x, ov_mid.y, (ov_mid.z + ov_distance));
1519
1520                 float ov_nearest = vlen(ov_org - vec3(
1521                         bound(ov_worldmin.x, ov_org.x, ov_worldmax.x),
1522                         bound(ov_worldmin.y, ov_org.y, ov_worldmax.y),
1523                         bound(ov_worldmin.z, ov_org.z, ov_worldmax.z)
1524                 ));
1525
1526                 float ov_furthest = 0;
1527                 float dist = 0;
1528
1529                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1530                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1531                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1532                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1533                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1534                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1535                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1536                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1537
1538                 if(!ov_enabled)
1539                 {
1540                         oldr_nearclip = cvar("r_nearclip");
1541                         oldr_farclip_base = cvar("r_farclip_base");
1542                         oldr_farclip_world = cvar("r_farclip_world");
1543                         oldr_novis = cvar("r_novis");
1544                         oldr_useportalculling = cvar("r_useportalculling");
1545                         oldr_useinfinitefarclip = cvar("r_useinfinitefarclip");
1546                 }
1547
1548                 cvar_settemp("r_nearclip", ftos(ov_nearest));
1549                 cvar_settemp("r_farclip_base", ftos(ov_furthest));
1550                 cvar_settemp("r_farclip_world", "0");
1551                 cvar_settemp("r_novis", "1");
1552                 cvar_settemp("r_useportalculling", "0");
1553                 cvar_settemp("r_useinfinitefarclip", "0");
1554
1555                 setproperty(VF_ORIGIN, ov_org);
1556                 setproperty(VF_ANGLES, '90 0 0');
1557
1558                 ov_enabled = true;
1559
1560                 #if 0
1561                 LOG_INFOF("OrthoView: org = %s, angles = %s, distance = %f, nearest = %f, furthest = %f",
1562                         vtos(ov_org),
1563                         vtos(getpropertyvec(VF_ANGLES)),
1564                         ov_distance,
1565                         ov_nearest,
1566                         ov_furthest);
1567                 #endif
1568         }
1569         else
1570         {
1571                 if(ov_enabled)
1572                 {
1573                         cvar_set("r_nearclip", ftos(oldr_nearclip));
1574                         cvar_set("r_farclip_base", ftos(oldr_farclip_base));
1575                         cvar_set("r_farclip_world", ftos(oldr_farclip_world));
1576                         cvar_set("r_novis", ftos(oldr_novis));
1577                         cvar_set("r_useportalculling", ftos(oldr_useportalculling));
1578                         cvar_set("r_useinfinitefarclip", ftos(oldr_useinfinitefarclip));
1579                 }
1580                 ov_enabled = false;
1581         }
1582 }
1583
1584 void View_UpdateFov()
1585 {
1586         vector fov;
1587         if(autocvar_cl_orthoview)
1588                 fov = GetOrthoviewFOV(ov_worldmin, ov_worldmax, ov_mid, ov_org);
1589         else if(csqcplayer.viewloc)
1590                 fov = GetViewLocationFOV(110); // enforce 110 fov, so things don't look odd
1591         else
1592                 fov = GetCurrentFov(autocvar_fov);
1593
1594         setproperty(VF_FOV, fov);
1595 }
1596
1597 void CSQC_UpdateView(entity this, float w, float h)
1598 {
1599         TC(int, w); TC(int, h);
1600
1601         execute_next_frame();
1602
1603         ++framecount;
1604
1605         stats_get();
1606         hud = STAT(HUD);
1607
1608         ReplicateVars(false);
1609         if (ReplicateVars_NOT_SENDING())
1610                 ReplicateVars_DELAY(0.8 + random() * 0.4); // no need to check cvars every frame
1611
1612         HUD_Scale_Disable();
1613
1614         if(autocvar__hud_showbinds_reload) // menu can set this one
1615         {
1616                 db_close(binddb);
1617                 binddb = db_create();
1618                 cvar_set("_hud_showbinds_reload", "0");
1619         }
1620
1621         if(checkextension("DP_CSQC_MINFPS_QUALITY"))
1622                 view_quality = getproperty(VF_MINFPS_QUALITY);
1623         else
1624                 view_quality = 1;
1625
1626         button_attack2 = PHYS_INPUT_BUTTON_ATCK2(this);
1627         button_zoom = PHYS_INPUT_BUTTON_ZOOM(this);
1628
1629         vector vf_size = getpropertyvec(VF_SIZE);
1630         vector vf_min = getpropertyvec(VF_MIN);
1631         vid_width = vf_size.x;
1632         vid_height = vf_size.y;
1633
1634         ticrate = STAT(MOVEVARS_TICRATE) * STAT(MOVEVARS_TIMESCALE);
1635
1636         if (autocvar_chase_active)
1637         {
1638                 // in first person view if r_drawviewmodel is off weapon isn't visible
1639                 // and server doesn't throw any casing
1640                 // switching to 3rd person view r_drawviewmodel is set to -1 to let know the server casings
1641                 // can be thrown for self since own weapon model is visible
1642                 if (autocvar_r_drawviewmodel == 0 && STAT(HEALTH) > 0)
1643                         cvar_set("r_drawviewmodel", "-1");
1644         }
1645         else
1646         {
1647                 if (autocvar_r_drawviewmodel < 0)
1648                         cvar_set("r_drawviewmodel", "0");
1649         }
1650
1651         WaypointSprite_Load();
1652
1653         CSQCPlayer_SetCamera();
1654
1655         if(player_localentnum <= maxclients) // is it a client?
1656                 current_player = player_localentnum - 1;
1657         else // then player_localentnum is the vehicle I'm driving
1658                 current_player = player_localnum;
1659         myteam = entcs_GetTeam(current_player);
1660
1661         // abused multiple places below
1662         entity local_player = ((csqcplayer) ? csqcplayer : CSQCModel_server2csqc(player_localentnum - 1));
1663         if(!local_player)
1664                 local_player = this; // fall back!
1665
1666         View_EventChase(local_player);
1667
1668         // do lockview after event chase camera so that it still applies whenever necessary.
1669         View_Lock();
1670
1671         WarpZone_FixView();
1672         //WarpZone_FixPMove();
1673
1674         View_Ortho();
1675
1676         // run viewmodel_draw before updating view_angles to the angles calculated by WarpZone_FixView
1677         // viewmodel_draw needs to use the view_angles set by the engine on every CSQC_UpdateView call
1678         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1679                 viewmodel_draw(viewmodels[slot]);
1680
1681         // Render the Scene
1682         view_origin = getpropertyvec(VF_ORIGIN);
1683         view_angles = getpropertyvec(VF_ANGLES);
1684         MAKE_VECTORS(view_angles, view_forward, view_right, view_up);
1685
1686 #ifdef BLURTEST
1687         View_BlurTest();
1688 #endif
1689
1690         TargetMusic_Advance();
1691         Fog_Force();
1692         fpscounter_update();
1693
1694         if(drawtime == 0)
1695                 drawframetime = 0.01666667; // when we don't know fps yet, we assume 60fps
1696         else
1697                 drawframetime = bound(0.000001, time - drawtime, 1);
1698         drawtime = time;
1699
1700         // watch for gametype changes here...
1701         // in ParseStuffCMD the cmd isn't executed yet :/
1702         // might even be better to add the gametype to TE_CSQC_INIT...?
1703         if(!postinit)
1704                 PostInit();
1705
1706         if(intermission && !intermission_time)
1707                 intermission_time = time;
1708
1709         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
1710         {
1711                 if(calledhooks & HOOK_START)
1712                 {
1713                         int gamecount = cvar("cl_matchcount");
1714                         localcmd("\ncl_hook_gameend\n");
1715                         // NOTE: using localcmd here to ensure it's executed AFTER cl_hook_gameend
1716                         // earlier versions of the game abuse the hook to set this cvar
1717                         localcmd(strcat("cl_matchcount ", itos(gamecount + 1), "\n"));
1718                         //cvar_set("cl_matchcount", itos(gamecount + 1));
1719                         calledhooks |= HOOK_END;
1720                 }
1721         }
1722
1723         Announcer();
1724
1725         View_CheckButtonStatus();
1726
1727         ColorTranslateMode = autocvar_cl_stripcolorcodes;
1728
1729         // ALWAYS Clear Current Scene First
1730         clearscene();
1731
1732         setproperty(VF_ORIGIN, view_origin);
1733         setproperty(VF_ANGLES, view_angles);
1734
1735         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
1736         setproperty(VF_SIZE, vf_size);
1737         setproperty(VF_MIN, vf_min);
1738
1739         // Assign Standard Viewflags
1740         // Draw the World (and sky)
1741         setproperty(VF_DRAWWORLD, 1);
1742
1743         // Set the console size vars
1744         vid_conwidth = autocvar_vid_conwidth;
1745         vid_conheight = autocvar_vid_conheight;
1746         vid_pixelheight = autocvar_vid_pixelheight;
1747
1748         View_UpdateFov();
1749
1750         View_DemoCamera();
1751
1752         // Draw the Crosshair
1753         setproperty(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
1754
1755         // Draw the Engine Status Bar (the default Quake HUD)
1756         setproperty(VF_DRAWENGINESBAR, 0);
1757
1758         // Update the mouse position
1759         /*
1760            mousepos_x = vid_conwidth;
1761            mousepos_y = vid_conheight;
1762            mousepos = mousepos*0.5 + getmousepos();
1763          */
1764
1765         IL_EACH(g_drawables, it.draw, it.draw(it));
1766
1767         addentities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS); // TODO: .health is used in cl_deathfade (a feature we have turned off currently)
1768         renderscene();
1769
1770         // Now the the scene has been rendered, begin with the 2D drawing functions
1771
1772         View_NightVision();
1773         DrawReticle(local_player);
1774         HUD_Contents();
1775         HUD_Damage();
1776         View_PostProcessing();
1777
1778         // draw 2D entities
1779         IL_EACH(g_drawables_2d, it.draw2d, it.draw2d(it));
1780         Draw_ShowNames_All();
1781 #if ENABLE_DEBUGDRAW
1782         Debug_Draw();
1783 #endif
1784
1785         scoreboard_active = Scoreboard_WouldDraw();
1786
1787         HUD_Draw(this); // this parameter for deep vehicle function
1788
1789         if(NextFrameCommand)
1790         {
1791                 localcmd("\n", NextFrameCommand, "\n");
1792                 NextFrameCommand = string_null;
1793         }
1794
1795         // we must do this check AFTER a frame was rendered, or it won't work
1796         if(cs_project_is_b0rked == 0)
1797         {
1798                 string w0, h0;
1799                 w0 = ftos(autocvar_vid_conwidth);
1800                 h0 = ftos(autocvar_vid_conheight);
1801                 //setproperty(VF_VIEWPORT, '0 0 0', '640 480 0');
1802                 //setproperty(VF_FOV, '90 90 0');
1803                 setproperty(VF_ORIGIN, '0 0 0');
1804                 setproperty(VF_ANGLES, '0 0 0');
1805                 setproperty(VF_PERSPECTIVE, 1);
1806                 vector forward, right, up;
1807                 MAKE_VECTORS('0 0 0', forward, right, up);
1808                 vector v1, v2;
1809                 cvar_set("vid_conwidth", "800");
1810                 cvar_set("vid_conheight", "600");
1811                 v1 = cs_project(forward);
1812                 cvar_set("vid_conwidth", "640");
1813                 cvar_set("vid_conheight", "480");
1814                 v2 = cs_project(forward);
1815                 if(v1 == v2)
1816                         cs_project_is_b0rked = 1;
1817                 else
1818                         cs_project_is_b0rked = -1;
1819                 cvar_set("vid_conwidth", w0);
1820                 cvar_set("vid_conheight", h0);
1821         }
1822
1823         HUD_Mouse(local_player);
1824
1825         cl_notice_run();
1826         unpause_update();
1827         Net_Flush();
1828
1829         // let's reset the view back to normal for the end
1830         setproperty(VF_MIN, '0 0 0');
1831         setproperty(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
1832
1833         IL_ENDFRAME();
1834 }
1835
1836
1837 // following vectors must be global to allow seamless switching between camera modes
1838 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
1839 void CSQC_Demo_Camera()
1840 {
1841         float speed, attenuation, dimensions;
1842         vector tmp, delta;
1843
1844         if( autocvar_camera_reset || !camera_mode )
1845         {
1846                 camera_offset = '0 0 0';
1847                 current_angles = '0 0 0';
1848                 camera_direction = '0 0 0';
1849                 camera_offset.z += 30;
1850                 camera_offset.x += 30 * -cos(current_angles.y * DEG2RAD);
1851                 camera_offset.y += 30 * -sin(current_angles.y * DEG2RAD);
1852                 current_origin = view_origin;
1853                 current_camera_offset  = camera_offset;
1854                 cvar_set("camera_reset", "0");
1855                 camera_mode = CAMERA_CHASE;
1856         }
1857
1858         // Camera angles
1859         if( camera_roll )
1860                 mouse_angles.z += camera_roll * autocvar_camera_speed_roll;
1861
1862         if(autocvar_camera_look_player)
1863         {
1864                 vector dir;
1865                 float n;
1866
1867                 dir = normalize(view_origin - current_position);
1868                 n = mouse_angles.z;
1869                 mouse_angles = vectoangles(dir);
1870                 mouse_angles.x = mouse_angles.x * -1;
1871                 mouse_angles.z = n;
1872         }
1873         else
1874         {
1875                 tmp = getmousepos() * 0.1;
1876                 if(vdist(tmp, >, autocvar_camera_mouse_threshold))
1877                 {
1878                         mouse_angles.x += tmp.y * cos(mouse_angles.z * DEG2RAD) + (tmp.x * sin(mouse_angles.z * DEG2RAD));
1879                         mouse_angles.y -= tmp.x * cos(mouse_angles.z * DEG2RAD) + (tmp.y * -sin(mouse_angles.z * DEG2RAD));
1880                 }
1881         }
1882
1883         while (mouse_angles.x < -180) mouse_angles.x = mouse_angles.x + 360;
1884         while (mouse_angles.x > 180) mouse_angles.x = mouse_angles.x - 360;
1885         while (mouse_angles.y < -180) mouse_angles.y = mouse_angles.y + 360;
1886         while (mouse_angles.y > 180) mouse_angles.y = mouse_angles.y - 360;
1887
1888         // Fix difference when angles don't have the same sign
1889         delta = '0 0 0';
1890         if(mouse_angles.y < -60 && current_angles.y > 60)
1891                 delta = '0 360 0';
1892         if(mouse_angles.y > 60 && current_angles.y < -60)
1893                 delta = '0 -360 0';
1894
1895         if(autocvar_camera_look_player)
1896                 attenuation = autocvar_camera_look_attenuation;
1897         else
1898                 attenuation = autocvar_camera_speed_attenuation;
1899
1900         attenuation = 1 / max(1, attenuation);
1901         current_angles += (mouse_angles - current_angles + delta) * attenuation;
1902
1903         while (current_angles.x < -180) current_angles.x = current_angles.x + 360;
1904         while (current_angles.x > 180) current_angles.x = current_angles.x - 360;
1905         while (current_angles.y < -180) current_angles.y = current_angles.y + 360;
1906         while (current_angles.y > 180) current_angles.y = current_angles.y - 360;
1907
1908         // Camera position
1909         tmp = '0 0 0';
1910         dimensions = 0;
1911
1912         if( camera_direction.x )
1913         {
1914                 tmp.x = camera_direction.x * cos(current_angles.y * DEG2RAD);
1915                 tmp.y = camera_direction.x * sin(current_angles.y * DEG2RAD);
1916                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
1917                         tmp.z = camera_direction.x * -sin(current_angles.x * DEG2RAD);
1918                 ++dimensions;
1919         }
1920
1921         if( camera_direction.y )
1922         {
1923                 tmp.x += camera_direction.y * -sin(current_angles.y * DEG2RAD);
1924                 tmp.y += camera_direction.y * cos(current_angles.y * DEG2RAD) * cos(current_angles.z * DEG2RAD);
1925                 tmp.z += camera_direction.y * sin(current_angles.z * DEG2RAD);
1926                 ++dimensions;
1927         }
1928
1929         if( camera_direction.z )
1930         {
1931                 tmp.z += camera_direction.z * cos(current_angles.z * DEG2RAD);
1932                 ++dimensions;
1933         }
1934
1935         if(autocvar_camera_free)
1936                 speed = autocvar_camera_speed_free;
1937         else
1938                 speed = autocvar_camera_speed_chase;
1939
1940         if(dimensions)
1941         {
1942                 speed = speed * sqrt(1 / dimensions);
1943                 camera_offset += tmp * speed;
1944         }
1945
1946         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
1947
1948         // Camera modes
1949         if( autocvar_camera_free )
1950         {
1951                 if ( camera_mode == CAMERA_CHASE )
1952                 {
1953                         current_camera_offset = current_origin + current_camera_offset;
1954                         camera_offset = current_origin + camera_offset;
1955                 }
1956
1957                 camera_mode = CAMERA_FREE;
1958                 current_position = current_camera_offset;
1959         }
1960         else
1961         {
1962                 if ( camera_mode == CAMERA_FREE )
1963                 {
1964                         current_origin = view_origin;
1965                         camera_offset = camera_offset - current_origin;
1966                         current_camera_offset = current_camera_offset - current_origin;
1967                 }
1968
1969                 camera_mode = CAMERA_CHASE;
1970
1971                 if(autocvar_camera_chase_smoothly)
1972                         current_origin += (view_origin - current_origin) * attenuation;
1973                 else
1974                         current_origin = view_origin;
1975
1976                 current_position = current_origin + current_camera_offset;
1977         }
1978
1979         setproperty(VF_ANGLES, current_angles);
1980         setproperty(VF_ORIGIN, current_position);
1981 }