qcsrc/client/weapons/projectile.qc

   1 #include "projectile.qh"
   2
   3 #include "../autocvars.qh"
   4 #include "../defs.qh"
   5 #include "../main.qh"
   6 #include "../mutators/events.qh"
   7
   8 #include "../../common/constants.qh"
   9 #include "../../common/movetypes/movetypes.qh"
  10
  11 #include "../../lib/csqcmodel/interpolate.qh"
  12
  13 #include "../../lib/warpzone/anglestransform.qh"
  14
  15 .float alpha;
  16 .float scale;
  17 .vector colormod;
  18
  19 void SUB_Stop()
  20 {
  21         SELFPARAM();
  22         self.move_velocity = self.move_avelocity = '0 0 0';
  23         self.move_movetype = MOVETYPE_NONE;
  24 }
  25
  26 void Projectile_ResetTrail(entity this, vector to)
  27 {
  28         this.trail_oldorigin = to;
  29         this.trail_oldtime = time;
  30 }
  31
  32 void Projectile_DrawTrail(entity this, vector to)
  33 {
  34         vector from = this.trail_oldorigin;
  35         // float t0 = this.trail_oldtime;
  36         this.trail_oldorigin = to;
  37         this.trail_oldtime = time;
  38
  39         // force the effect even for stationary firemine
  40         if (this.cnt == PROJECTILE_FIREMINE)
  41                 if (from == to)
  42                         from.z += 1;
  43
  44         if (this.traileffect)
  45         {
  46                 particles_alphamin = particles_alphamax = particles_fade = sqrt(this.alpha);
  47                 boxparticles(particleeffectnum(Effects_from(this.traileffect)), this, from, to, this.velocity, this.velocity, 1, PARTICLES_USEALPHA | PARTICLES_USEFADE | PARTICLES_DRAWASTRAIL);
  48         }
  49 }
  50
  51 bool Projectile_isnade(int proj); // TODO: remove
  52
  53 void Projectile_Draw(entity this)
  54 {
  55         vector rot;
  56         vector trailorigin;
  57         int f;
  58         bool drawn;
  59         float t;
  60         float a;
  61
  62         f = self.move_flags;
  63
  64         if (self.count & 0x80)
  65         {
  66                 // self.move_flags &= ~FL_ONGROUND;
  67                 if (self.move_movetype == MOVETYPE_NONE || self.move_movetype == MOVETYPE_FLY)
  68                         Movetype_Physics_NoMatchServer();
  69                 // the trivial movetypes do not have to match the
  70                 // server's ticrate as they are ticrate independent
  71                 // NOTE: this assumption is only true if MOVETYPE_FLY
  72                 // projectiles detonate on impact. If they continue
  73                 // moving, we might still be ticrate dependent.
  74                 else
  75                         Movetype_Physics_MatchServer(autocvar_cl_projectiles_sloppy);
  76                 if (!(self.move_flags & FL_ONGROUND))
  77                         if (self.velocity != '0 0 0')
  78                                 self.move_angles = self.angles = vectoangles(self.velocity);
  79         }
  80         else
  81         {
  82                 InterpolateOrigin_Do(self);
  83         }
  84
  85         if (self.count & 0x80)
  86         {
  87                 drawn = (time >= self.spawntime - 0.02);
  88                 t = max(time, self.spawntime);
  89         }
  90         else
  91         {
  92                 drawn = (self.iflags & IFLAG_VALID);
  93                 t = time;
  94         }
  95
  96         if (!(f & FL_ONGROUND))
  97         {
  98                 rot = '0 0 0';
  99                 switch (self.cnt)
 100                 {
 101                         /*
 102                         case PROJECTILE_GRENADE:
 103                             rot = '-2000 0 0'; // forward
 104                             break;
 105                         */
 106                         case PROJECTILE_GRENADE_BOUNCING:
 107                                 rot = '0 -1000 0'; // sideways
 108                                 break;
 109                         case PROJECTILE_HOOKBOMB:
 110                                 rot = '1000 0 0';  // forward
 111                                 break;
 112                         default:
 113                                 break;
 114                 }
 115
 116                 if (Projectile_isnade(self.cnt))
 117                         rot = self.avelocity;
 118
 119                 self.angles = AnglesTransform_ToAngles(AnglesTransform_Multiply(AnglesTransform_FromAngles(self.angles), rot * (t - self.spawntime)));
 120         }
 121
 122         vector ang;
 123         ang = self.angles;
 124         ang.x = -ang.x;
 125         makevectors(ang);
 126
 127         a = 1 - (time - self.fade_time) * self.fade_rate;
 128         self.alpha = bound(0, self.alphamod * a, 1);
 129         if (self.alpha <= 0)
 130                 drawn = 0;
 131         self.renderflags = 0;
 132
 133         trailorigin = self.origin;
 134         switch (self.cnt)
 135         {
 136                 case PROJECTILE_GRENADE:
 137                 case PROJECTILE_GRENADE_BOUNCING:
 138                         trailorigin += v_right * 1 + v_forward * -10;
 139                         break;
 140                 default:
 141                         break;
 142         }
 143
 144         if (Projectile_isnade(self.cnt))
 145                 trailorigin += v_up * 4;
 146
 147         if (drawn)
 148                 Projectile_DrawTrail(self, trailorigin);
 149         else
 150                 Projectile_ResetTrail(self, trailorigin);
 151
 152         self.drawmask = 0;
 153
 154         if (!drawn)
 155                 return;
 156
 157         switch (self.cnt)
 158         {
 159                 // Possibly add dlights here.
 160                 default:
 161                         break;
 162         }
 163
 164         self.drawmask = MASK_NORMAL;
 165 }
 166
 167 void loopsound(entity e, int ch, string samp, float vol, float attn)
 168 {
 169         SELFPARAM();
 170         if (self.silent)
 171                 return;
 172
 173         _sound(e, ch, samp, vol, attn);
 174         e.snd_looping = ch;
 175 }
 176
 177 void Ent_RemoveProjectile()
 178 {
 179         SELFPARAM();
 180         if (self.count & 0x80)
 181         {
 182                 tracebox(self.origin, self.mins, self.maxs, self.origin + self.velocity * 0.05, MOVE_NORMAL, self);
 183                 Projectile_DrawTrail(self, trace_endpos);
 184         }
 185 }
 186
 187 NET_HANDLE(ENT_CLIENT_PROJECTILE, bool isnew)
 188 {
 189         // projectile properties:
 190         //   kind (interpolated, or clientside)
 191         //
 192         //   modelindex
 193         //   origin
 194         //   scale
 195         //   if clientside:
 196         //     velocity
 197         //     gravity
 198         //   soundindex (hardcoded list)
 199         //   effects
 200         //
 201         // projectiles don't send angles, because they always follow the velocity
 202
 203         int f = ReadByte();
 204         self.count = (f & 0x80);
 205         self.iflags = (self.iflags & IFLAG_INTERNALMASK) | IFLAG_AUTOANGLES | IFLAG_ANGLES | IFLAG_ORIGIN;
 206         self.solid = SOLID_TRIGGER;
 207         // self.effects = EF_NOMODELFLAGS;
 208
 209         // this should make collisions with bmodels more exact, but it leads to
 210         // projectiles no longer being able to lie on a bmodel
 211         self.move_nomonsters = MOVE_WORLDONLY;
 212         if (f & 0x40)
 213                 self.move_flags |= FL_ONGROUND;
 214         else
 215                 self.move_flags &= ~FL_ONGROUND;
 216
 217         if (!self.move_time)
 218         {
 219                 // for some unknown reason, we don't need to care for
 220                 // sv_gameplayfix_delayprojectiles here.
 221                 self.move_time = time;
 222                 self.spawntime = time;
 223         }
 224         else
 225         {
 226                 self.move_time = max(self.move_time, time);
 227         }
 228
 229         if (!(self.count & 0x80))
 230                 InterpolateOrigin_Undo(self);
 231
 232         if (f & 1)
 233         {
 234                 self.origin_x = ReadCoord();
 235                 self.origin_y = ReadCoord();
 236                 self.origin_z = ReadCoord();
 237                 setorigin(self, self.origin);
 238                 if (self.count & 0x80)
 239                 {
 240                         self.velocity_x = ReadCoord();
 241                         self.velocity_y = ReadCoord();
 242                         self.velocity_z = ReadCoord();
 243                         if (f & 0x10)
 244                                 self.gravity = ReadCoord();
 245                         else
 246                                 self.gravity = 0;  // none
 247                         self.move_origin = self.origin;
 248                         self.move_velocity = self.velocity;
 249                 }
 250
 251                 if (time == self.spawntime || (self.count & 0x80) || (f & 0x08))
 252                 {
 253                         self.trail_oldorigin = self.origin;
 254                         if (!(self.count & 0x80))
 255                                 InterpolateOrigin_Reset();
 256                 }
 257
 258                 if (f & 0x20)
 259                 {
 260                         self.fade_time = time + ReadByte() * ticrate;
 261                         self.fade_rate = 1 / (ReadByte() * ticrate);
 262                 }
 263                 else
 264                 {
 265                         self.fade_time = 0;
 266                         self.fade_rate = 0;
 267                 }
 268
 269                 self.team = ReadByte() - 1;
 270         }
 271
 272         if (f & 2)
 273         {
 274                 self.cnt = ReadByte();
 275
 276                 self.silent = (self.cnt & 0x80);
 277                 self.cnt = (self.cnt & 0x7F);
 278
 279                 self.scale = 1;
 280                 self.traileffect = 0;
 281                 switch (self.cnt)
 282                 {
 283                         #define CASE(id) case PROJECTILE_##id: setmodel(self, MDL_PROJECTILE_##id);
 284                         CASE(ELECTRO)            self.traileffect = EFFECT_TR_NEXUIZPLASMA.m_id; break;
 285                         CASE(ROCKET)             self.traileffect = EFFECT_TR_ROCKET.m_id; self.scale = 2; break;
 286                         CASE(CRYLINK)            self.traileffect = EFFECT_TR_CRYLINKPLASMA.m_id; break;
 287                         CASE(CRYLINK_BOUNCING)   self.traileffect = EFFECT_TR_CRYLINKPLASMA.m_id; break;
 288                         CASE(ELECTRO_BEAM)       self.traileffect = EFFECT_TR_NEXUIZPLASMA.m_id; break;
 289                         CASE(GRENADE)            self.traileffect = EFFECT_TR_GRENADE.m_id; break;
 290                         CASE(GRENADE_BOUNCING)   self.traileffect = EFFECT_TR_GRENADE.m_id; break;
 291                         CASE(MINE)               self.traileffect = EFFECT_TR_GRENADE.m_id; break;
 292                         CASE(BLASTER)            self.traileffect = EFFECT_Null.m_id; break;
 293                         CASE(HLAC)               self.traileffect = EFFECT_Null.m_id; break;
 294                         CASE(PORTO_RED)          self.traileffect = EFFECT_TR_WIZSPIKE.m_id; self.scale = 4; break;
 295                         CASE(PORTO_BLUE)         self.traileffect = EFFECT_TR_WIZSPIKE.m_id; self.scale = 4; break;
 296                         CASE(HOOKBOMB)           self.traileffect = EFFECT_TR_KNIGHTSPIKE.m_id; break;
 297                         CASE(HAGAR)              self.traileffect = EFFECT_HAGAR_ROCKET.m_id; self.scale = 0.75; break;
 298                         CASE(HAGAR_BOUNCING)     self.traileffect = EFFECT_HAGAR_ROCKET.m_id; self.scale = 0.75; break;
 299                         CASE(FIREBALL)           self.modelindex = 0; self.traileffect = EFFECT_FIREBALL.m_id; break; // particle effect is good enough
 300                         CASE(FIREMINE)           self.modelindex = 0; self.traileffect = EFFECT_FIREMINE.m_id; break; // particle effect is good enough
 301                         CASE(TAG)                self.traileffect = EFFECT_TR_ROCKET.m_id; break;
 302                         CASE(FLAC)               self.scale = 0.4; self.traileffect = EFFECT_FLAC_TRAIL.m_id; break;
 303                         CASE(SEEKER)             self.traileffect = EFFECT_SEEKER_TRAIL.m_id; break;
 304
 305                         CASE(MAGE_SPIKE)         self.traileffect = EFFECT_TR_VORESPIKE.m_id; break;
 306                         CASE(SHAMBLER_LIGHTNING) self.traileffect = EFFECT_TR_NEXUIZPLASMA.m_id; break;
 307
 308                         CASE(RAPTORBOMB)         self.gravity = 1; self.avelocity = '0 0 180'; self.traileffect = EFFECT_Null.m_id; break;
 309                         CASE(RAPTORBOMBLET)      self.gravity = 1; self.avelocity = '0 0 180'; self.traileffect = EFFECT_Null.m_id; break;
 310                         CASE(RAPTORCANNON)       self.traileffect = EFFECT_TR_CRYLINKPLASMA.m_id; break;
 311
 312                         CASE(SPIDERROCKET)       self.traileffect = EFFECT_SPIDERBOT_ROCKET_TRAIL.m_id; break;
 313                         CASE(WAKIROCKET)         self.traileffect = EFFECT_RACER_ROCKET_TRAIL.m_id; break;
 314                         CASE(WAKICANNON)         self.traileffect = EFFECT_Null.m_id; break;
 315
 316                         CASE(BUMBLE_GUN)         self.traileffect = EFFECT_TR_NEXUIZPLASMA.m_id; break;
 317                         CASE(BUMBLE_BEAM)        self.traileffect = EFFECT_TR_NEXUIZPLASMA.m_id; break;
 318
 319                         CASE(RPC)                self.traileffect = EFFECT_TR_ROCKET.m_id; break;
 320
 321                         CASE(ROCKETMINSTA_LASER) self.traileffect = EFFECT_ROCKETMINSTA_LASER(self.team).m_id; break;
 322 #undef CASE
 323                         default:
 324                                 if (MUTATOR_CALLHOOK(Ent_Projectile, self))
 325                                         break;
 326
 327                                 error("Received invalid CSQC projectile, can't work with this!");
 328                                 break;
 329                 }
 330
 331                 self.mins = '0 0 0';
 332                 self.maxs = '0 0 0';
 333                 self.colormod = '0 0 0';
 334                 self.move_touch = SUB_Stop;
 335                 self.move_movetype = MOVETYPE_TOSS;
 336                 self.alphamod = 1;
 337
 338                 switch (self.cnt)
 339                 {
 340                         case PROJECTILE_ELECTRO:
 341                                 // only new engines support sound moving with object
 342                                 loopsound(self, CH_SHOTS_SINGLE, SND(ELECTRO_FLY), VOL_BASE, ATTEN_NORM);
 343                                 self.mins = '0 0 -4';
 344                                 self.maxs = '0 0 -4';
 345                                 self.move_movetype = MOVETYPE_BOUNCE;
 346                                 self.move_touch = func_null;
 347                                 self.move_bounce_factor = g_balance_electro_secondary_bouncefactor;
 348                                 self.move_bounce_stopspeed = g_balance_electro_secondary_bouncestop;
 349                                 break;
 350                         case PROJECTILE_RPC:
 351                         case PROJECTILE_ROCKET:
 352                                 loopsound(self, CH_SHOTS_SINGLE, SND(ROCKET_FLY), VOL_BASE, ATTEN_NORM);
 353                                 self.mins = '-3 -3 -3';
 354                                 self.maxs = '3 3 3';
 355                                 break;
 356                         case PROJECTILE_GRENADE:
 357                                 self.mins = '-3 -3 -3';
 358                                 self.maxs = '3 3 3';
 359                                 break;
 360                         case PROJECTILE_GRENADE_BOUNCING:
 361                                 self.mins = '-3 -3 -3';
 362                                 self.maxs = '3 3 3';
 363                                 self.move_movetype = MOVETYPE_BOUNCE;
 364                                 self.move_touch = func_null;
 365                                 self.move_bounce_factor = g_balance_mortar_bouncefactor;
 366                                 self.move_bounce_stopspeed = g_balance_mortar_bouncestop;
 367                                 break;
 368                         case PROJECTILE_SHAMBLER_LIGHTNING:
 369                                 self.mins = '-8 -8 -8';
 370                                 self.maxs = '8 8 8';
 371                                 self.scale = 2.5;
 372                                 self.avelocity = randomvec() * 720;
 373                                 break;
 374                         case PROJECTILE_MINE:
 375                                 self.mins = '-4 -4 -4';
 376                                 self.maxs = '4 4 4';
 377                                 break;
 378                         case PROJECTILE_PORTO_RED:
 379                                 self.colormod = '2 1 1';
 380                                 self.alphamod = 0.5;
 381                                 self.move_movetype = MOVETYPE_BOUNCE;
 382                                 self.move_touch = func_null;
 383                                 break;
 384                         case PROJECTILE_PORTO_BLUE:
 385                                 self.colormod = '1 1 2';
 386                                 self.alphamod = 0.5;
 387                                 self.move_movetype = MOVETYPE_BOUNCE;
 388                                 self.move_touch = func_null;
 389                                 break;
 390                         case PROJECTILE_HAGAR_BOUNCING:
 391                                 self.move_movetype = MOVETYPE_BOUNCE;
 392                                 self.move_touch = func_null;
 393                                 break;
 394                         case PROJECTILE_CRYLINK_BOUNCING:
 395                                 self.move_movetype = MOVETYPE_BOUNCE;
 396                                 self.move_touch = func_null;
 397                                 break;
 398                         case PROJECTILE_FIREBALL:
 399                                 loopsound(self, CH_SHOTS_SINGLE, SND(FIREBALL_FLY2), VOL_BASE, ATTEN_NORM);
 400                                 self.mins = '-16 -16 -16';
 401                                 self.maxs = '16 16 16';
 402                                 break;
 403                         case PROJECTILE_FIREMINE:
 404                                 loopsound(self, CH_SHOTS_SINGLE, SND(FIREBALL_FLY), VOL_BASE, ATTEN_NORM);
 405                                 self.move_movetype = MOVETYPE_BOUNCE;
 406                                 self.move_touch = func_null;
 407                                 self.mins = '-4 -4 -4';
 408                                 self.maxs = '4 4 4';
 409                                 break;
 410                         case PROJECTILE_TAG:
 411                                 self.mins = '-2 -2 -2';
 412                                 self.maxs = '2 2 2';
 413                                 break;
 414                         case PROJECTILE_FLAC:
 415                                 self.mins = '-2 -2 -2';
 416                                 self.maxs = '2 2 2';
 417                                 break;
 418                         case PROJECTILE_SEEKER:
 419                                 loopsound(self, CH_SHOTS_SINGLE, SND(TAG_ROCKET_FLY), VOL_BASE, ATTEN_NORM);
 420                                 self.mins = '-4 -4 -4';
 421                                 self.maxs = '4 4 4';
 422                                 break;
 423                         case PROJECTILE_RAPTORBOMB:
 424                                 self.mins = '-3 -3 -3';
 425                                 self.maxs = '3 3 3';
 426                                 break;
 427                         case PROJECTILE_RAPTORBOMBLET:
 428                                 break;
 429                         case PROJECTILE_RAPTORCANNON:
 430                                 break;
 431                         case PROJECTILE_SPIDERROCKET:
 432                                 loopsound(self, CH_SHOTS_SINGLE, SND(TAG_ROCKET_FLY), VOL_BASE, ATTEN_NORM);
 433                                 break;
 434                         case PROJECTILE_WAKIROCKET:
 435                                 loopsound(self, CH_SHOTS_SINGLE, SND(TAG_ROCKET_FLY), VOL_BASE, ATTEN_NORM);
 436                                 break;
 437                         /*
 438                         case PROJECTILE_WAKICANNON:
 439                             break;
 440                         case PROJECTILE_BUMBLE_GUN:
 441                             // only new engines support sound moving with object
 442                             loopsound(self, CH_SHOTS_SINGLE, SND(ELECTRO_FLY), VOL_BASE, ATTEN_NORM);
 443                             self.mins = '0 0 -4';
 444                             self.maxs = '0 0 -4';
 445                             self.move_movetype = MOVETYPE_BOUNCE;
 446                             self.move_touch = func_null;
 447                             self.move_bounce_factor = g_balance_electro_secondary_bouncefactor;
 448                             self.move_bounce_stopspeed = g_balance_electro_secondary_bouncestop;
 449                             break;
 450                         */
 451                         default:
 452                                 break;
 453                 }
 454
 455                 MUTATOR_CALLHOOK(EditProjectile, self);
 456
 457                 setsize(self, self.mins, self.maxs);
 458         }
 459
 460         return = true;
 461
 462         if (self.gravity)
 463         {
 464                 if (self.move_movetype == MOVETYPE_FLY)
 465                         self.move_movetype = MOVETYPE_TOSS;
 466                 if (self.move_movetype == MOVETYPE_BOUNCEMISSILE)
 467                         self.move_movetype = MOVETYPE_BOUNCE;
 468         }
 469         else
 470         {
 471                 if (self.move_movetype == MOVETYPE_TOSS)
 472                         self.move_movetype = MOVETYPE_FLY;
 473                 if (self.move_movetype == MOVETYPE_BOUNCE)
 474                         self.move_movetype = MOVETYPE_BOUNCEMISSILE;
 475         }
 476
 477         if (!(self.count & 0x80))
 478                 InterpolateOrigin_Note(this);
 479
 480         self.classname = "csqcprojectile";
 481         self.draw = Projectile_Draw;
 482         self.entremove = Ent_RemoveProjectile;
 483 }
 484
 485 PRECACHE(Projectiles)
 486 {
 487         MUTATOR_CALLHOOK(PrecacheProjectiles);
 488 }