qcsrc/client/weapons/projectile.qc

   1 #include "projectile.qh"
   2
   3 #include "../autocvars.qh"
   4 #include "../defs.qh"
   5 #include "../main.qh"
   6 #include "../mutators/events.qh"
   7
   8 #include <common/constants.qh>
   9 #include <common/net_linked.qh>
  10 #include <common/physics/movetypes/movetypes.qh>
  11
  12 #include <lib/csqcmodel/interpolate.qh>
  13
  14 #include <lib/warpzone/anglestransform.qh>
  15
  16 .float alpha;
  17 .float scale;
  18 .vector colormod;
  19
  20 void SUB_Stop(entity this, entity toucher)
  21 {
  22         this.velocity = this.avelocity = '0 0 0';
  23         set_movetype(this, MOVETYPE_NONE);
  24 }
  25
  26 void Projectile_ResetTrail(entity this, vector to)
  27 {
  28         this.trail_oldorigin = to;
  29         this.trail_oldtime = time;
  30 }
  31
  32 void Projectile_DrawTrail(entity this, vector to)
  33 {
  34         vector from = this.trail_oldorigin;
  35         // float t0 = this.trail_oldtime;
  36         this.trail_oldorigin = to;
  37         this.trail_oldtime = time;
  38
  39         // force the effect even for stationary firemine
  40         if (this.cnt == PROJECTILE_FIREMINE)
  41                 if (from == to)
  42                         from.z += 1;
  43
  44         if (this.traileffect)
  45         {
  46                 particles_alphamin = particles_alphamax = particles_fade = sqrt(this.alpha);
  47                 boxparticles(particleeffectnum(Effects_from(this.traileffect)), this, from, to, this.velocity, this.velocity, 1, PARTICLES_USEALPHA | PARTICLES_USEFADE | PARTICLES_DRAWASTRAIL);
  48         }
  49 }
  50
  51 bool Projectile_isnade(int proj); // TODO: remove
  52
  53 void Projectile_Draw(entity this)
  54 {
  55         vector rot;
  56         vector trailorigin;
  57         int f;
  58         bool drawn;
  59         float t;
  60         float a;
  61
  62         f = this.flags;
  63
  64         if (this.count & 0x80)
  65         {
  66                 // UNSET_ONGROUND(this);
  67                 if (this.move_movetype == MOVETYPE_NONE || this.move_movetype == MOVETYPE_FLY)
  68                         Movetype_Physics_NoMatchServer(this);
  69                 // the trivial movetypes do not have to match the
  70                 // server's ticrate as they are ticrate independent
  71                 // NOTE: this assumption is only true if MOVETYPE_FLY
  72                 // projectiles detonate on impact. If they continue
  73                 // moving, we might still be ticrate dependent.
  74                 else
  75                         Movetype_Physics_MatchServer(this, autocvar_cl_projectiles_sloppy);
  76                 if (!IS_ONGROUND(this))
  77                         if (this.velocity != '0 0 0')
  78                                 this.angles = vectoangles(this.velocity);
  79         }
  80         else
  81         {
  82                 InterpolateOrigin_Do(this);
  83         }
  84
  85         if (this.count & 0x80)
  86         {
  87                 drawn = (time >= this.spawntime - 0.02);
  88                 t = max(time, this.spawntime);
  89         }
  90         else
  91         {
  92                 drawn = (this.iflags & IFLAG_VALID);
  93                 t = time;
  94         }
  95
  96         if (!(f & FL_ONGROUND))
  97         {
  98                 rot = '0 0 0';
  99                 switch (this.cnt)
 100                 {
 101                         /*
 102                         case PROJECTILE_GRENADE:
 103                             rot = '-2000 0 0'; // forward
 104                             break;
 105                         */
 106                         case PROJECTILE_GRENADE_BOUNCING:
 107                                 rot = '0 -1000 0'; // sideways
 108                                 break;
 109                         case PROJECTILE_HOOKBOMB:
 110                                 rot = '1000 0 0';  // forward
 111                                 break;
 112                         default:
 113                                 break;
 114                 }
 115
 116                 if (Projectile_isnade(this.cnt))
 117                         rot = this.avelocity;
 118
 119                 this.angles = AnglesTransform_ToAngles(AnglesTransform_Multiply(AnglesTransform_FromAngles(this.angles), rot * (t - this.spawntime)));
 120         }
 121
 122         vector ang;
 123         ang = this.angles;
 124         ang.x = -ang.x;
 125         makevectors(ang);
 126
 127         a = 1 - (time - this.fade_time) * this.fade_rate;
 128         this.alpha = bound(0, this.alphamod * a, 1);
 129         if (this.alpha <= 0)
 130                 drawn = 0;
 131         this.renderflags = 0;
 132
 133         trailorigin = this.origin;
 134         switch (this.cnt)
 135         {
 136                 case PROJECTILE_GRENADE:
 137                 case PROJECTILE_GRENADE_BOUNCING:
 138                         trailorigin += v_right * 1 + v_forward * -10;
 139                         break;
 140                 default:
 141                         break;
 142         }
 143
 144         if (Projectile_isnade(this.cnt))
 145                 trailorigin += v_up * 4;
 146
 147         if (drawn)
 148                 Projectile_DrawTrail(this, trailorigin);
 149         else
 150                 Projectile_ResetTrail(this, trailorigin);
 151
 152         this.drawmask = 0;
 153
 154         if (!drawn)
 155                 return;
 156
 157         switch (this.cnt)
 158         {
 159                 // Possibly add dlights here.
 160                 default:
 161                         break;
 162         }
 163
 164         this.drawmask = MASK_NORMAL;
 165 }
 166
 167 void loopsound(entity e, int ch, string samp, float vol, float attn)
 168 {
 169     TC(int, ch);
 170         if (e.silent)
 171                 return;
 172
 173         _sound(e, ch, samp, vol, attn);
 174         e.snd_looping = ch;
 175 }
 176
 177 void Ent_RemoveProjectile(entity this)
 178 {
 179         if (this.count & 0x80)
 180         {
 181                 tracebox(this.origin, this.mins, this.maxs, this.origin + this.velocity * 0.05, MOVE_NORMAL, this);
 182                 Projectile_DrawTrail(this, trace_endpos);
 183         }
 184 }
 185
 186 NET_HANDLE(ENT_CLIENT_PROJECTILE, bool isnew)
 187 {
 188         // projectile properties:
 189         //   kind (interpolated, or clientside)
 190         //
 191         //   modelindex
 192         //   origin
 193         //   scale
 194         //   if clientside:
 195         //     velocity
 196         //     gravity
 197         //   soundindex (hardcoded list)
 198         //   effects
 199         //
 200         // projectiles don't send angles, because they always follow the velocity
 201
 202         int f = ReadByte();
 203         this.count = (f & 0x80);
 204         this.flags |= FL_PROJECTILE;
 205         this.iflags = (this.iflags & IFLAG_INTERNALMASK) | IFLAG_AUTOANGLES | IFLAG_ANGLES | IFLAG_ORIGIN;
 206         this.solid = SOLID_TRIGGER;
 207         // this.effects = EF_NOMODELFLAGS;
 208
 209         // this should make collisions with bmodels more exact, but it leads to
 210         // projectiles no longer being able to lie on a bmodel
 211         this.move_nomonsters = MOVE_WORLDONLY;
 212         if (f & 0x40)
 213                 SET_ONGROUND(this);
 214         else
 215                 UNSET_ONGROUND(this);
 216
 217         if (!this.move_time)
 218         {
 219                 // for some unknown reason, we don't need to care for
 220                 // sv_gameplayfix_delayprojectiles here.
 221                 this.move_time = time;
 222                 this.spawntime = time;
 223         }
 224         else
 225         {
 226                 this.move_time = max(this.move_time, time);
 227         }
 228
 229         if (!(this.count & 0x80))
 230                 InterpolateOrigin_Undo(this);
 231
 232         if (f & 1)
 233         {
 234                 this.origin_x = ReadCoord();
 235                 this.origin_y = ReadCoord();
 236                 this.origin_z = ReadCoord();
 237                 setorigin(this, this.origin);
 238                 if (this.count & 0x80)
 239                 {
 240                         this.velocity_x = ReadCoord();
 241                         this.velocity_y = ReadCoord();
 242                         this.velocity_z = ReadCoord();
 243                         if (f & 0x10)
 244                                 this.gravity = ReadCoord();
 245                         else
 246                                 this.gravity = 0;  // none
 247                 }
 248
 249                 if (time == this.spawntime || (this.count & 0x80) || (f & 0x08))
 250                 {
 251                         this.trail_oldorigin = this.origin;
 252                         if (!(this.count & 0x80))
 253                                 InterpolateOrigin_Reset(this);
 254                 }
 255
 256                 if (f & 0x20)
 257                 {
 258                         this.fade_time = time + ReadByte() * ticrate;
 259                         this.fade_rate = 1 / (ReadByte() * ticrate);
 260                 }
 261                 else
 262                 {
 263                         this.fade_time = 0;
 264                         this.fade_rate = 0;
 265                 }
 266
 267                 this.team = ReadByte() - 1;
 268         }
 269
 270         if (f & 2)
 271         {
 272                 this.cnt = ReadByte();
 273
 274                 this.silent = (this.cnt & 0x80);
 275                 this.cnt = (this.cnt & 0x7F);
 276
 277                 this.scale = 1;
 278                 this.traileffect = 0;
 279                 switch (this.cnt)
 280                 {
 281 #define HANDLE(id) case PROJECTILE_##id: setmodel(this, MDL_PROJECTILE_##id);
 282                         HANDLE(ELECTRO)            this.traileffect = EFFECT_TR_NEXUIZPLASMA.m_id; break;
 283                         HANDLE(ROCKET)             this.traileffect = EFFECT_TR_ROCKET.m_id; this.scale = 2; break;
 284                         HANDLE(CRYLINK)            this.traileffect = EFFECT_TR_CRYLINKPLASMA.m_id; break;
 285                         HANDLE(CRYLINK_BOUNCING)   this.traileffect = EFFECT_TR_CRYLINKPLASMA.m_id; break;
 286                         HANDLE(ELECTRO_BEAM)       this.traileffect = EFFECT_TR_NEXUIZPLASMA.m_id; break;
 287                         HANDLE(GRENADE)            this.traileffect = EFFECT_TR_GRENADE.m_id; break;
 288                         HANDLE(GRENADE_BOUNCING)   this.traileffect = EFFECT_TR_GRENADE.m_id; break;
 289                         HANDLE(MINE)               this.traileffect = EFFECT_TR_GRENADE.m_id; break;
 290                         HANDLE(BLASTER)            this.traileffect = EFFECT_Null.m_id; break;
 291                         HANDLE(ARC_BOLT)           this.traileffect = EFFECT_Null.m_id; break;
 292                         HANDLE(HLAC)               this.traileffect = EFFECT_Null.m_id; break;
 293                         HANDLE(PORTO_RED)          this.traileffect = EFFECT_TR_WIZSPIKE.m_id; this.scale = 4; break;
 294                         HANDLE(PORTO_BLUE)         this.traileffect = EFFECT_TR_WIZSPIKE.m_id; this.scale = 4; break;
 295                         HANDLE(HOOKBOMB)           this.traileffect = EFFECT_TR_KNIGHTSPIKE.m_id; break;
 296                         HANDLE(HAGAR)              this.traileffect = EFFECT_HAGAR_ROCKET.m_id; this.scale = 0.75; break;
 297                         HANDLE(HAGAR_BOUNCING)     this.traileffect = EFFECT_HAGAR_ROCKET.m_id; this.scale = 0.75; break;
 298                         HANDLE(FIREBALL)           this.modelindex = 0; this.traileffect = EFFECT_FIREBALL.m_id; break; // particle effect is good enough
 299                         HANDLE(FIREMINE)           this.modelindex = 0; this.traileffect = EFFECT_FIREMINE.m_id; break; // particle effect is good enough
 300                         HANDLE(TAG)                this.traileffect = EFFECT_TR_ROCKET.m_id; break;
 301                         HANDLE(FLAC)               this.scale = 0.4; this.traileffect = EFFECT_FLAC_TRAIL.m_id; break;
 302                         HANDLE(SEEKER)             this.traileffect = EFFECT_SEEKER_TRAIL.m_id; break;
 303
 304                         HANDLE(MAGE_SPIKE)         this.traileffect = EFFECT_TR_VORESPIKE.m_id; break;
 305                         HANDLE(SHAMBLER_LIGHTNING) this.traileffect = EFFECT_TR_NEXUIZPLASMA.m_id; break;
 306
 307                         HANDLE(RAPTORBOMB)         this.gravity = 1; this.avelocity = '0 0 180'; this.traileffect = EFFECT_Null.m_id; break;
 308                         HANDLE(RAPTORBOMBLET)      this.gravity = 1; this.avelocity = '0 0 180'; this.traileffect = EFFECT_Null.m_id; break;
 309                         HANDLE(RAPTORCANNON)       this.traileffect = EFFECT_TR_CRYLINKPLASMA.m_id; break;
 310
 311                         HANDLE(SPIDERROCKET)       this.traileffect = EFFECT_SPIDERBOT_ROCKET_TRAIL.m_id; break;
 312                         HANDLE(WAKIROCKET)         this.traileffect = EFFECT_RACER_ROCKET_TRAIL.m_id; break;
 313                         HANDLE(WAKICANNON)         this.traileffect = EFFECT_Null.m_id; break;
 314
 315                         HANDLE(BUMBLE_GUN)         this.traileffect = EFFECT_TR_NEXUIZPLASMA.m_id; break;
 316                         HANDLE(BUMBLE_BEAM)        this.traileffect = EFFECT_TR_NEXUIZPLASMA.m_id; break;
 317
 318                         HANDLE(RPC)                this.traileffect = EFFECT_TR_ROCKET.m_id; break;
 319
 320                         HANDLE(ROCKETMINSTA_LASER) this.traileffect = EFFECT_ROCKETMINSTA_LASER(this.team).m_id; break;
 321 #undef HANDLE
 322                         default:
 323                                 if (MUTATOR_CALLHOOK(Ent_Projectile, this))
 324                                         break;
 325
 326                                 error("Received invalid CSQC projectile, can't work with this!");
 327                                 break;
 328                 }
 329
 330                 this.mins = '0 0 0';
 331                 this.maxs = '0 0 0';
 332                 this.colormod = '0 0 0';
 333                 settouch(this, SUB_Stop);
 334                 set_movetype(this, MOVETYPE_TOSS);
 335                 this.alphamod = 1;
 336
 337                 switch (this.cnt)
 338                 {
 339                         case PROJECTILE_ELECTRO:
 340                                 // only new engines support sound moving with object
 341                                 loopsound(this, CH_SHOTS_SINGLE, SND(ELECTRO_FLY), VOL_BASE, ATTEN_NORM);
 342                                 this.mins = '-4 -4 -4';
 343                                 this.maxs = '4 4 4';
 344                                 set_movetype(this, MOVETYPE_BOUNCE);
 345                                 settouch(this, func_null);
 346                                 this.bouncefactor = WEP_CVAR_SEC(electro, bouncefactor);
 347                                 this.bouncestop = WEP_CVAR_SEC(electro, bouncestop);
 348                                 break;
 349                         case PROJECTILE_RPC:
 350                         case PROJECTILE_ROCKET:
 351                                 loopsound(this, CH_SHOTS_SINGLE, SND(ROCKET_FLY), VOL_BASE, ATTEN_NORM);
 352                                 this.mins = '-3 -3 -3';
 353                                 this.maxs = '3 3 3';
 354                                 break;
 355                         case PROJECTILE_GRENADE:
 356                                 this.mins = '-3 -3 -3';
 357                                 this.maxs = '3 3 3';
 358                                 break;
 359                         case PROJECTILE_GRENADE_BOUNCING:
 360                                 this.mins = '-3 -3 -3';
 361                                 this.maxs = '3 3 3';
 362                                 set_movetype(this, MOVETYPE_BOUNCE);
 363                                 settouch(this, func_null);
 364                                 this.bouncefactor = WEP_CVAR(mortar, bouncefactor);
 365                                 this.bouncestop = WEP_CVAR(mortar, bouncestop);
 366                                 break;
 367                         case PROJECTILE_SHAMBLER_LIGHTNING:
 368                                 this.mins = '-8 -8 -8';
 369                                 this.maxs = '8 8 8';
 370                                 this.scale = 2.5;
 371                                 this.avelocity = randomvec() * 720;
 372                                 break;
 373                         case PROJECTILE_MINE:
 374                                 this.mins = '-4 -4 -4';
 375                                 this.maxs = '4 4 4';
 376                                 break;
 377                         case PROJECTILE_PORTO_RED:
 378                                 this.colormod = '2 1 1';
 379                                 this.alphamod = 0.5;
 380                                 set_movetype(this, MOVETYPE_BOUNCE);
 381                                 settouch(this, func_null);
 382                                 break;
 383                         case PROJECTILE_PORTO_BLUE:
 384                                 this.colormod = '1 1 2';
 385                                 this.alphamod = 0.5;
 386                                 set_movetype(this, MOVETYPE_BOUNCE);
 387                                 settouch(this, func_null);
 388                                 break;
 389                         case PROJECTILE_HAGAR_BOUNCING:
 390                                 set_movetype(this, MOVETYPE_BOUNCE);
 391                                 settouch(this, func_null);
 392                                 break;
 393                         case PROJECTILE_CRYLINK_BOUNCING:
 394                                 set_movetype(this, MOVETYPE_BOUNCE);
 395                                 settouch(this, func_null);
 396                                 break;
 397                         case PROJECTILE_FIREBALL:
 398                                 loopsound(this, CH_SHOTS_SINGLE, SND(FIREBALL_FLY2), VOL_BASE, ATTEN_NORM);
 399                                 this.mins = '-16 -16 -16';
 400                                 this.maxs = '16 16 16';
 401                                 break;
 402                         case PROJECTILE_FIREMINE:
 403                                 loopsound(this, CH_SHOTS_SINGLE, SND(FIREBALL_FLY), VOL_BASE, ATTEN_NORM);
 404                                 set_movetype(this, MOVETYPE_BOUNCE);
 405                                 settouch(this, func_null);
 406                                 this.mins = '-4 -4 -4';
 407                                 this.maxs = '4 4 4';
 408                                 break;
 409                         case PROJECTILE_TAG:
 410                                 this.mins = '-2 -2 -2';
 411                                 this.maxs = '2 2 2';
 412                                 break;
 413                         case PROJECTILE_FLAC:
 414                                 this.mins = '-2 -2 -2';
 415                                 this.maxs = '2 2 2';
 416                                 break;
 417                         case PROJECTILE_SEEKER:
 418                                 loopsound(this, CH_SHOTS_SINGLE, SND(TAG_ROCKET_FLY), VOL_BASE, ATTEN_NORM);
 419                                 this.mins = '-4 -4 -4';
 420                                 this.maxs = '4 4 4';
 421                                 break;
 422                         case PROJECTILE_RAPTORBOMB:
 423                                 this.mins = '-3 -3 -3';
 424                                 this.maxs = '3 3 3';
 425                                 break;
 426                         case PROJECTILE_RAPTORBOMBLET:
 427                                 break;
 428                         case PROJECTILE_RAPTORCANNON:
 429                                 break;
 430                         case PROJECTILE_SPIDERROCKET:
 431                                 loopsound(this, CH_SHOTS_SINGLE, SND(TAG_ROCKET_FLY), VOL_BASE, ATTEN_NORM);
 432                                 break;
 433                         case PROJECTILE_WAKIROCKET:
 434                                 loopsound(this, CH_SHOTS_SINGLE, SND(TAG_ROCKET_FLY), VOL_BASE, ATTEN_NORM);
 435                                 break;
 436                         /*
 437                         case PROJECTILE_WAKICANNON:
 438                             break;
 439                         case PROJECTILE_BUMBLE_GUN:
 440                             // only new engines support sound moving with object
 441                             loopsound(this, CH_SHOTS_SINGLE, SND(ELECTRO_FLY), VOL_BASE, ATTEN_NORM);
 442                             this.mins = '0 0 -4';
 443                             this.maxs = '0 0 -4';
 444                             this.move_movetype = MOVETYPE_BOUNCE;
 445                             settouch(this, func_null);
 446                             this.bouncefactor = WEP_CVAR_SEC(electro, bouncefactor);
 447                             this.bouncestop = WEP_CVAR_SEC(electro, bouncestop);
 448                             break;
 449                         */
 450                         default:
 451                                 break;
 452                 }
 453
 454                 MUTATOR_CALLHOOK(EditProjectile, this);
 455
 456                 setsize(this, this.mins, this.maxs);
 457         }
 458
 459         return = true;
 460
 461         if (this.gravity)
 462         {
 463                 if (this.move_movetype == MOVETYPE_FLY)
 464                         set_movetype(this, MOVETYPE_TOSS);
 465                 if (this.move_movetype == MOVETYPE_BOUNCEMISSILE)
 466                         set_movetype(this, MOVETYPE_BOUNCE);
 467         }
 468         else
 469         {
 470                 if (this.move_movetype == MOVETYPE_TOSS)
 471                         set_movetype(this, MOVETYPE_FLY);
 472                 if (this.move_movetype == MOVETYPE_BOUNCE)
 473                         set_movetype(this, MOVETYPE_BOUNCEMISSILE);
 474         }
 475
 476         if (!(this.count & 0x80))
 477                 InterpolateOrigin_Note(this);
 478
 479         this.classname = "csqcprojectile";
 480         this.draw = Projectile_Draw;
 481         if (isnew) IL_PUSH(g_drawables, this);
 482         this.entremove = Ent_RemoveProjectile;
 483 }
 484
 485 PRECACHE(Projectiles)
 486 {
 487         MUTATOR_CALLHOOK(PrecacheProjectiles);
 488 }