qcsrc/common/campaign_file.qc

   1 #if defined(CSQC)
   2 #elif defined(MENUQC)
   3 #elif defined(SVQC)
   4         #include "../dpdefs/progsdefs.qh"
   5     #include "../dpdefs/dpextensions.qh"
   6     #include "util.qh"
   7     #include "campaign_common.qh"
   8 #endif
   9
  10 // CampaignFileLoad(offset, n)
  11 // - Loads campaign level data (up to n entries starting at offset)
  12 //   into the globals
  13 // - Returns the number of entries successfully read
  14 float CampaignFile_Load(int offset, float n)
  15 {
  16         float fh;
  17         float lineno;
  18         float entlen;
  19         float i;
  20         string l, a;
  21         string fn;
  22
  23         if(n > CAMPAIGN_MAX_ENTRIES)
  24                 n = CAMPAIGN_MAX_ENTRIES;
  25
  26         campaign_offset = offset;
  27         campaign_entries = 0;
  28         campaign_title = string_null;
  29
  30         fn = language_filename(strcat("maps/campaign", campaign_name, ".txt"));
  31         fh = fopen(fn, FILE_READ);
  32         if(fh >= 0)
  33         {
  34                 for(lineno = 0; (l = fgets(fh)); )
  35                 {
  36                         if(strlen(l) == 0)
  37                                 continue; // empty line
  38                         if(substring(l, 0, 11) == "//campaign:")
  39                                 campaign_title = substring(l, 11, strlen(l) - 11);
  40                         if(substring(l, 0, 2) == "//")
  41                                 continue; // comment
  42                         if(substring(l, 0, 12) == "\"//campaign:")
  43                                 campaign_title = substring(l, 12, strlen(l) - 13);
  44                         if(substring(l, 0, 3) == "\"//")
  45                                 continue; // comment
  46                         if(lineno >= offset)
  47                         {
  48                                 entlen = tokenize(l); // using insane tokenizer for CSV
  49
  50 #define CAMPAIGN_GETARG \
  51         a = argv(++i); \
  52         if(a == ",") \
  53                 a = ""; \
  54         else \
  55                 ++i
  56 // What you're seeing here is what people will do when your compiler supports
  57 // C-style macros but no line continuations.
  58
  59                                 i = -1; // starts at -1 so I don't need postincrement; that is, i points to BEFORE the current arg!
  60                                 CAMPAIGN_GETARG; campaign_gametype[campaign_entries] = strzone(a);
  61                                 CAMPAIGN_GETARG; campaign_mapname[campaign_entries] = strzone(a);
  62                                 CAMPAIGN_GETARG; campaign_bots[campaign_entries] = stof(a);
  63                                 CAMPAIGN_GETARG; campaign_botskill[campaign_entries] = stof(a);
  64                                 CAMPAIGN_GETARG; campaign_fraglimit[campaign_entries] = stof(a);
  65                                 CAMPAIGN_GETARG; campaign_timelimit[campaign_entries] = stof(a);
  66                                 CAMPAIGN_GETARG; campaign_mutators[campaign_entries] = strzone(a);
  67                                 CAMPAIGN_GETARG; campaign_shortdesc[campaign_entries] = strzone(a);
  68                                 CAMPAIGN_GETARG; campaign_longdesc[campaign_entries] = strzone(strreplace("\\n", "\n", a));
  69
  70                                 if(i > entlen)
  71                                         error("syntax error in campaign file: line has not enough fields");
  72
  73                                 campaign_entries = campaign_entries + 1;
  74
  75                                 if(campaign_entries >= n)
  76                                         break;
  77                         }
  78                         lineno = lineno + 1;
  79                 }
  80                 fclose(fh);
  81         }
  82
  83         campaign_title = strzone(campaign_title);
  84
  85         return campaign_entries;
  86 }
  87
  88 void CampaignFile_Unload()
  89 {
  90         if(campaign_title)
  91         {
  92                 strunzone(campaign_title);
  93                 int i;
  94                 for(i = 0; i < campaign_entries; ++i)
  95                 {
  96                         strunzone(campaign_gametype[i]);
  97                         strunzone(campaign_mapname[i]);
  98                         strunzone(campaign_mutators[i]);
  99                         strunzone(campaign_shortdesc[i]);
 100                         strunzone(campaign_longdesc[i]);
 101                 }
 102                 campaign_entries = 0;
 103                 campaign_title = string_null;
 104         }
 105 }