qcsrc/common/command/generic.qc

   1 // =========================================================
   2 //  Generic program common command code, written by Samual
   3 //  Last updated: February 19th, 2012
   4 // =========================================================
   5
   6 // used by generic commands for better help/usage information
   7 string GetProgramCommandPrefix(void)
   8 {
   9         #ifdef SVQC
  10         return "sv_cmd";
  11         #endif
  12         #ifdef CSQC
  13         return "cl_cmd";
  14         #endif
  15         #ifdef MENUQC
  16         return "menu_cmd";
  17         #endif
  18 }
  19
  20 // used by curl command
  21 void Curl_URI_Get_Callback(float id, float status, string data)
  22 {
  23         float i;
  24         float do_exec;
  25         string do_cvar;
  26         i = id - URI_GET_CURL;
  27         do_exec = curl_uri_get_exec[i];
  28         do_cvar = curl_uri_get_cvar[i];
  29         if(status != 0)
  30         {
  31                 print(sprintf(_("error: status is %d\n"), status));
  32                 if(do_cvar)
  33                         strunzone(do_cvar);
  34                 return;
  35         }
  36         if(do_exec)
  37                 localcmd(data);
  38         if(do_cvar)
  39         {
  40                 cvar_set(do_cvar, data);
  41                 strunzone(do_cvar);
  42         }
  43         if(!do_exec && !do_cvar)
  44                 print(data);
  45 }
  46
  47
  48 // =======================
  49 //  Command Sub-Functions
  50 // =======================
  51
  52 void GenericCommand_addtolist(float request, float argc)
  53 {
  54         switch(request)
  55         {
  56                 case CMD_REQUEST_COMMAND:
  57                 {
  58                         float i;
  59
  60                         if(argc >= 2)
  61                         {
  62                                 string original_cvar = argv(1);
  63                                 string tmp_string = argv(2);
  64
  65                                 if(cvar_string(original_cvar) == "") // cvar was empty
  66                                 {
  67                                         cvar_set(original_cvar, tmp_string);
  68                                 }
  69                                 else // add it to the end of the list if the list doesn't already have it
  70                                 {
  71                                         argc = tokenizebyseparator(cvar_string(original_cvar), " ");
  72
  73                                         for(i = 0; i < argc; ++i)
  74                                                 if(argv(i) == tmp_string)
  75                                                         return; // already in list
  76
  77                                         cvar_set(original_cvar, strcat(tmp_string, " ", cvar_string(original_cvar)));
  78                                 }
  79                                 return;
  80                         }
  81                 }
  82
  83                 default:
  84                         print("Incorrect parameters for ^2addtolist^7\n");
  85                 case CMD_REQUEST_USAGE:
  86                 {
  87                         print(strcat("\nUsage:^3 ", GetProgramCommandPrefix(), " addtolist variable value"));
  88                         print("  Where 'variable' is what to add 'value' to.\n");
  89                         print("See also: ^2removefromlist^7\n");
  90                         return;
  91                 }
  92         }
  93 }
  94
  95 void GenericCommand_curl(float request, float argc)
  96 {
  97         switch(request)
  98         {
  99                 case CMD_REQUEST_COMMAND:
 100                 {
 101                         float do_exec;
 102                         string do_cvar;
 103                         float key;
 104                         float i, j;
 105                         string url;
 106                         float buf;
 107                         float r;
 108
 109                         do_exec = FALSE;
 110                         do_cvar = string_null;
 111                         key = -1;
 112
 113                         for(i = 1; i+1 < argc; ++i)
 114                         {
 115                                 if(argv(i) == "--cvar" && i+2 < argc)
 116                                 {
 117                                         ++i;
 118                                         do_cvar = strzone(argv(i));
 119                                         continue;
 120                                 }
 121                                 if(argv(i) == "--exec")
 122                                 {
 123                                         do_exec = TRUE;
 124                                         continue;
 125                                 }
 126                                 if(argv(i) == "--key" && i+2 < argc)
 127                                 {
 128                                         ++i;
 129                                         key = stof(argv(i));
 130                                         continue;
 131                                 }
 132                                 break;
 133                         }
 134
 135                         // now, argv(i) is the URL
 136                         // following args may be POST parameters
 137                         url = argv(i);
 138                         ++i;
 139                         buf = buf_create();
 140                         j = 0;
 141                         for(; i+1 < argc; i += 2)
 142                                 bufstr_set(buf, ++j, sprintf("%s=%s", uri_escape(argv(i)), uri_escape(argv(i+1))));
 143                         if(i < argc)
 144                                 bufstr_set(buf, ++j, sprintf("submit=%s", uri_escape(argv(i))));
 145
 146                         if(j == 0) // no args: GET
 147                                 r = crypto_uri_postbuf(url, URI_GET_CURL + curl_uri_get_pos, string_null, string_null, -1, key);
 148                         else // with args: POST
 149                                 r = crypto_uri_postbuf(url, URI_GET_CURL + curl_uri_get_pos, "application/x-www-form-urlencoded", "&", buf, key);
 150
 151                         if(r)
 152                         {
 153                                 curl_uri_get_exec[curl_uri_get_pos] = do_exec;
 154                                 curl_uri_get_cvar[curl_uri_get_pos] = do_cvar;
 155                                 curl_uri_get_pos = mod(curl_uri_get_pos + 1, URI_GET_CURL_END - URI_GET_CURL + 1);
 156                         }
 157                         else
 158                                 print(_("error creating curl handle\n"));
 159
 160                         buf_del(buf);
 161
 162                         return;
 163                 }
 164
 165                 default:
 166                 case CMD_REQUEST_USAGE:
 167                 {
 168                         print(strcat("\nUsage:^3 ", GetProgramCommandPrefix(), " curl [--key N] [--cvar] [--exec] URL [postargs...]"));
 169                         return;
 170                 }
 171         }
 172 }
 173
 174 void GenericCommand_dumpcommands(float request)
 175 {
 176         switch(request)
 177         {
 178                 case CMD_REQUEST_COMMAND:
 179                 {
 180                         float fh;
 181                         string filename = strcat(GetProgramCommandPrefix(), "_dump.txt");
 182                         fh = fopen(filename, FILE_WRITE);
 183
 184                         if(fh >= 0)
 185                         {
 186                                 #ifdef SVQC
 187                                         CMD_Write("dump of server console commands:\n");
 188                                         GameCommand_macro_write_aliases(fh);
 189
 190                                         CMD_Write("\ndump of networked client only commands:\n");
 191                                         ClientCommand_macro_write_aliases(fh);
 192
 193                                         CMD_Write("\ndump of common commands:\n");
 194                                         CommonCommand_macro_write_aliases(fh);
 195
 196                                         CMD_Write("\ndump of ban commands:\n");
 197                                         BanCommand_macro_write_aliases(fh);
 198                                 #endif
 199
 200                                 #ifdef CSQC
 201                                         CMD_Write("dump of client commands:\n");
 202                                         LocalCommand_macro_write_aliases(fh);
 203                                 #endif
 204
 205                                 CMD_Write("\ndump of generic commands:\n");
 206                                 GenericCommand_macro_write_aliases(fh);
 207
 208                                 print("Completed dump of aliases in ^2data/data/", GetProgramCommandPrefix(), "_dump.txt^7.\n");
 209
 210                                 fclose(fh);
 211                         }
 212                         else
 213                         {
 214                                 print("^1Error: ^7Could not dump to file!\n");
 215                         }
 216                         return;
 217                 }
 218
 219                 default:
 220                 case CMD_REQUEST_USAGE:
 221                 {
 222                         print(strcat("\nUsage:^3 ", GetProgramCommandPrefix(), " dumpcommands"));
 223                         print("  No arguments required.\n");
 224                         return;
 225                 }
 226         }
 227 }
 228
 229 void GenericCommand_maplist(float request, float argc)
 230 {
 231         switch(request)
 232         {
 233                 case CMD_REQUEST_COMMAND:
 234                 {
 235                         string tmp_string;
 236                         float i;
 237
 238                         switch(argv(1))
 239                         {
 240                                 case "add": // appends new maps to the maplist
 241                                 {
 242                                         if(argc == 3)
 243                                         {
 244                                                 if (!fexists(strcat("maps/", argv(2), ".bsp")))
 245                                                 {
 246                                                         print("maplist: ERROR: ", argv(2), " does not exist!\n");
 247                                                         break;
 248                                                 }
 249
 250                                                 if(cvar_string("g_maplist") == "")
 251                                                         cvar_set("g_maplist", argv(2));
 252                                                 else
 253                                                         cvar_set("g_maplist", strcat(argv(2), " ", cvar_string("g_maplist")));
 254
 255                                                 return;
 256                                         }
 257                                         break; // go to usage
 258                                 }
 259
 260                                 case "cleanup": // scans maplist and only adds back the ones which are really usable
 261                                 {
 262                                         MapInfo_Enumerate();
 263                                         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 264                                         argc = tokenizebyseparator(cvar_string("g_maplist"), " ");
 265
 266                                         for(i = 0; i < argc; ++i)
 267                                                 if(MapInfo_CheckMap(argv(i)))
 268                                                         tmp_string = strcat(tmp_string, " ", argv(i));
 269
 270                                         tmp_string = substring(tmp_string, 1, strlen(tmp_string) - 1);
 271                                         cvar_set("g_maplist", tmp_string);
 272
 273                                         return;
 274                                 }
 275
 276                                 case "remove": // scans maplist and only adds back whatever maps were not provided in argv(2)
 277                                 {
 278                                         if(argc == 3)
 279                                         {
 280                                                 argc = tokenizebyseparator(cvar_string("g_maplist"), " ");
 281
 282                                                 for(i = 0; i < argc; ++i)
 283                                                         if(argv(i) != argv(2))
 284                                                                 tmp_string = strcat(tmp_string, " ", argv(i));
 285
 286                                                 tmp_string = substring(tmp_string, 1, strlen(tmp_string) - 1);
 287                                                 cvar_set("g_maplist", tmp_string);
 288
 289                                                 return;
 290                                         }
 291                                         break; // go to usage
 292                                 }
 293
 294                                 case "shuffle": // randomly shuffle the maplist
 295                                 {
 296                                         cvar_set("g_maplist", shufflewords(cvar_string("g_maplist")));
 297                                         return;
 298                                 }
 299
 300                                 default: break;
 301                         }
 302                 }
 303
 304                 default:
 305                         print("Incorrect parameters for ^2maplist^7\n");
 306                 case CMD_REQUEST_USAGE:
 307                 {
 308                         print(strcat("\nUsage:^3 ", GetProgramCommandPrefix(), " maplist action [map]"));
 309                         print("  Where 'action' is the command to complete,\n");
 310                         print("  and 'map' is what it acts upon (if required).\n");
 311                         print("  Full list of commands here: \"add, cleanup, remove, shuffle.\"\n");
 312                         return;
 313                 }
 314         }
 315 }
 316
 317 void GenericCommand_nextframe(float request, float arguments, string command)
 318 {
 319         switch(request)
 320         {
 321                 case CMD_REQUEST_COMMAND:
 322                 {
 323                         queue_to_execute_next_frame(substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)));
 324                         return;
 325                 }
 326
 327                 default:
 328                 case CMD_REQUEST_USAGE:
 329                 {
 330                         print(strcat("\nUsage:^3 ", GetProgramCommandPrefix(), " nextframe command..."));
 331                         print("  Where command will be executed next frame of this VM\n");
 332                         return;
 333                 }
 334         }
 335 }
 336
 337 void GenericCommand_removefromlist(float request, float argc)
 338 {
 339         switch(request)
 340         {
 341                 case CMD_REQUEST_COMMAND:
 342                 {
 343                         if(argc == 3)
 344                         {
 345                                 float i;
 346                                 string original_cvar = argv(1);
 347                                 string removal = argv(2);
 348                                 string tmp_string;
 349
 350                                 argc = tokenizebyseparator(cvar_string(original_cvar), " ");
 351
 352                                 for(i = 0; i < argc; ++i)
 353                                         if(argv(i) != removal)
 354                                                 tmp_string = strcat(tmp_string, " ", argv(i));
 355
 356                                 tmp_string = substring(tmp_string, 1, strlen(tmp_string) - 1);
 357                                 cvar_set(original_cvar, tmp_string);
 358
 359                                 return;
 360                         }
 361                 }
 362
 363                 default:
 364                         print("Incorrect parameters for ^2removefromlist^7\n");
 365                 case CMD_REQUEST_USAGE:
 366                 {
 367                         print(strcat("\nUsage:^3 ", GetProgramCommandPrefix(), " removefromlist variable value"));
 368                         print("  Where 'variable' is what cvar to remove 'value' from.\n");
 369                         print("See also: ^2addtolist^7\n");
 370                         return;
 371                 }
 372         }
 373 }
 374
 375 void GenericCommand_settemp(float request, float argc)
 376 {
 377         switch(request)
 378         {
 379                 case CMD_REQUEST_COMMAND:
 380                 {
 381                         if(argc >= 3)
 382                         {
 383                                 if(cvar_settemp(argv(1), argv(2)))
 384                                         dprint("Creating new settemp tracker for ", argv(1), " and setting it to \"", argv(2), "\" temporarily.\n");
 385                                 else
 386                                         dprint("Already had a tracker for ", argv(1), ", updating it to \"", argv(2), "\".\n");
 387
 388                                 return;
 389                         }
 390                 }
 391
 392                 default:
 393                         print("Incorrect parameters for ^2settemp^7\n");
 394                 case CMD_REQUEST_USAGE:
 395                 {
 396                         print(strcat("\nUsage:^3 ", GetProgramCommandPrefix(), " settemp \"cvar\" \"arguments\"\n"));
 397                         print("  Where 'cvar' is the cvar you want to temporarily set with 'arguments'.\n");
 398                         print("See also: ^2settemp_restore^7\n");
 399                         return;
 400                 }
 401         }
 402 }
 403
 404 void GenericCommand_settemp_restore(float request, float argc)
 405 {
 406         switch(request)
 407         {
 408                 case CMD_REQUEST_COMMAND:
 409                 {
 410                         float i = cvar_settemp_restore();
 411
 412                         if(i)
 413                                 dprint("Restored ", ftos(i), " temporary cvar settings to their original values.\n");
 414                         else
 415                                 dprint("Nothing to restore.\n");
 416
 417                         return;
 418                 }
 419
 420                 default:
 421                 case CMD_REQUEST_USAGE:
 422                 {
 423                         print(strcat("\nUsage:^3 ", GetProgramCommandPrefix(), " settemp_restore\n"));
 424                         print("  No arguments required.\n");
 425                         print("See also: ^2settemp^7\n");
 426                         return;
 427                 }
 428         }
 429 }
 430
 431 /* use this when creating a new command, making sure to place it in alphabetical order... also,
 432 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
 433 void GenericCommand_(float request)
 434 {
 435         switch(request)
 436         {
 437                 case CMD_REQUEST_COMMAND:
 438                 {
 439
 440                         return;
 441                 }
 442
 443                 default:
 444                 case CMD_REQUEST_USAGE:
 445                 {
 446                         print(strcat("\nUsage:^3 ", GetProgramCommandPrefix(), " "));
 447                         print("  No arguments required.\n");
 448                         return;
 449                 }
 450         }
 451 }
 452 */
 453
 454 // ==================================
 455 //  Macro system for server commands
 456 // ==================================
 457
 458 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
 459 #define GENERIC_COMMANDS(request,arguments,command) \
 460         GENERIC_COMMAND("addtolist", GenericCommand_addtolist(request, arguments), "Add a string to a cvar") \
 461         GENERIC_COMMAND("curl", GenericCommand_curl(request, arguments), "Queries an URL") \
 462         GENERIC_COMMAND("dumpcommands", GenericCommand_dumpcommands(request), "Dump all commands on the program to *_cmd_dump.txt") \
 463         GENERIC_COMMAND("maplist", GenericCommand_maplist(request, arguments), "Automatic control of maplist") \
 464         GENERIC_COMMAND("nextframe", GenericCommand_nextframe(request, arguments, command), "Execute the given command next frame of this VM") \
 465         GENERIC_COMMAND("removefromlist", GenericCommand_removefromlist(request, arguments), "Remove a string from a cvar") \
 466         GENERIC_COMMAND("rpn", GenericCommand_rpn(request, arguments, command), "RPN calculator") \
 467         GENERIC_COMMAND("settemp", GenericCommand_settemp(request, arguments), "Temporarily set a value to a cvar which is restored later") \
 468         GENERIC_COMMAND("settemp_restore", GenericCommand_settemp_restore(request, arguments), "Restore all cvars set by settemp command") \
 469         /* nothing */
 470
 471 void GenericCommand_macro_help()
 472 {
 473         #define GENERIC_COMMAND(name,function,description) \
 474                 { print("  ^2", name, "^7: ", description, "\n"); }
 475
 476         GENERIC_COMMANDS(0, 0, "")
 477         #undef GENERIC_COMMAND
 478
 479         return;
 480 }
 481
 482 float GenericCommand_macro_command(float argc, string command)
 483 {
 484         #define GENERIC_COMMAND(name,function,description) \
 485                 { if(name == strtolower(argv(0))) { function; return TRUE; } }
 486
 487         GENERIC_COMMANDS(CMD_REQUEST_COMMAND, argc, command)
 488         #undef GENERIC_COMMAND
 489
 490         return FALSE;
 491 }
 492
 493 float GenericCommand_macro_usage(float argc)
 494 {
 495         #define GENERIC_COMMAND(name,function,description) \
 496                 { if(name == strtolower(argv(1))) { function; return TRUE; } }
 497
 498         GENERIC_COMMANDS(CMD_REQUEST_USAGE, argc, "")
 499         #undef GENERIC_COMMAND
 500
 501         return FALSE;
 502 }
 503
 504 void GenericCommand_macro_write_aliases(float fh)
 505 {
 506         #define GENERIC_COMMAND(name,function,description) \
 507                 { CMD_Write_Alias("qc_cmd_svmenu", name, description); }
 508
 509         GENERIC_COMMANDS(0, 0, "")
 510         #undef GENERIC_COMMAND
 511
 512         return;
 513 }
 514
 515
 516 // ===========================================
 517 //  Main Common Function For Generic Commands
 518 // ===========================================
 519 // Commands spread out among all programs (menu, client, and server)
 520
 521 float GenericCommand(string command)
 522 {
 523         float argc = tokenize_console(command);
 524         float n, j, f, i;
 525         string s, s2, c;
 526         vector rgb;
 527
 528         // Guide for working with argc arguments by example:
 529         // argc:   1    - 2      - 3     - 4
 530         // argv:   0    - 1      - 2     - 3
 531         // cmd     vote - master - login - password
 532
 533         if(GenericCommand_macro_command(argc, command)) // continue as usual and scan for normal commands
 534         {
 535                 return TRUE; // handled by one of the above GenericCommand_* functions
 536         }
 537         else if(argc >= 3 && argv(0) == "red")
 538         {
 539                 s = substring(command, argv_start_index(2), argv_end_index(-1) - argv_start_index(2));
 540                 localcmd(strcat(argv(1), " ", GenericCommand_markup(s)));
 541                 return TRUE;
 542         }
 543         else if(argc >= 3 && crc16(0, argv(0)) == 38566 && crc16(0, strcat(argv(0), argv(0), argv(0))) == 59830)
 544         {
 545                 // other test case
 546                 s = strconv(2, 0, 0, substring(command, argv_start_index(2), argv_end_index(-1) - argv_start_index(2)));
 547
 548                 n = floor(random() * 6 + 2);
 549
 550                 s2 = "";
 551                 for(i = 0; i < n; ++i)
 552                 {
 553                         s2 = strcat(s2, "AH");
 554                 }
 555
 556                 if(random() < 0.1)
 557                         s2 = strcat(substring(s2, 1, strlen(s2) - 1), "A");
 558
 559                 if(s == "")
 560                         s = s2;
 561                 else
 562                         if(random() < 0.8)
 563                                 s = strcat(s, " ", s2);
 564                         else
 565                                 s = strcat(s2, " ", s);
 566
 567                 s2 = substring(s, strlen(s) - 2, 2);
 568                 if(s2 == "AH" || s2 == "AY")
 569                         s = strcat(s, "))");
 570                 else
 571                         s = strcat(s, " ))");
 572
 573                 if(random() < 0.1)
 574                         s = substring(s, 0, strlen(s) - 1);
 575
 576                 if(random() < 0.1)
 577                         s = strconv(1, 0, 0, s);
 578
 579                 localcmd(strcat(argv(1), " ", s));
 580
 581                 return TRUE;
 582         }
 583         else if(argc >= 3 && crc16(0, argv(0)) == 3826 && crc16(0, strcat(argv(0), argv(0), argv(0))) == 55790)
 584         {
 585                 // test case for terencehill's color codes
 586                 s = strdecolorize(substring(command, argv_start_index(2), argv_end_index(-1) - argv_start_index(2)));
 587                 s2 = "";
 588
 589                 n = strlen(s);
 590                 j = ((6 * max(1, floor(strlen(s)/32 + random() * 2 - 1))) / n) * (1 - 2 * (random() > 0.5));
 591                 f = random() * 6;
 592
 593                 for(i = 0; i < n; ++i)
 594                 {
 595                         c = substring(s, i, 1);
 596
 597                         if(c == ";")
 598                                 c = ":";
 599                         else if(c == "^")
 600                         {
 601                                 c = "^^";
 602                                 if(substring(s, i+1, 1) == "^")
 603                                         ++i;
 604                         }
 605
 606                         if(c != " ")
 607                         {
 608                                 rgb = hsl_to_rgb('1 0 0' * (j * i + f) + '0 1 .5');
 609                                 c = strcat(rgb_to_hexcolor(rgb), c);
 610                         }
 611                         s2 = strcat(s2, c);
 612                 }
 613
 614                 localcmd(strcat(argv(1), " ", s2));
 615
 616                 return TRUE;
 617         }
 618
 619         return FALSE;
 620 }