qcsrc/common/ent_cs.qc

   1 #include "ent_cs.qh"
   2
   3 REGISTRY(EntCSProps, BITS(16) - 1)
   4 #define EntCSProps_from(i) _EntCSProps_from(i, NULL)
   5 REGISTER_REGISTRY(EntCSProps)
   6 REGISTRY_SORT(EntCSProps)
   7 REGISTRY_CHECK(EntCSProps)
   8 STATIC_INIT(RegisterEntCSProps_renumber) { FOREACH(EntCSProps, true, it.m_id = i); }
   9
  10 .bool m_public;
  11 .bool(entity ent, entity player) m_check;
  12 .void(entity ent, entity player) m_set;
  13 .void(int chan, entity ent) m_send;
  14 .void(entity ent) m_receive;
  15
  16 #ifdef SVQC
  17 #define ENTCS_PROP(id, ispublic, checkprop, setprop, svsend, clreceive) \
  18         bool id##_check(entity ent, entity player) { return (ent.(checkprop) != player.(checkprop)); } \
  19         void id##_set(entity ent, entity player) { setprop(ent.(checkprop), player.(checkprop)); } \
  20         void id##_send(int chan, entity ent) { LAMBDA(svsend); } \
  21         REGISTER(EntCSProps, ENTCS_PROP, id, m_id, new_pure(entcs_prop)) { \
  22                 this.m_public = ispublic; \
  23                 this.m_check = id##_check; \
  24                 this.m_set = id##_set; \
  25                 this.m_send = id##_send; \
  26         }
  27 #elif defined(CSQC)
  28 #define ENTCS_PROP(id, ispublic, checkprop, setprop, svsend, clreceive) \
  29         void id##_receive(entity ent) { LAMBDA(clreceive); } \
  30         REGISTER(EntCSProps, ENTCS_PROP, id, m_id, new_pure(entcs_prop)) { \
  31                 this.m_public = ispublic; \
  32                 this.m_receive = id##_receive; \
  33         }
  34 #endif
  35
  36 #define ENTCS_SET_NORMAL(var, x) MACRO_BEGIN \
  37         var = x; \
  38 MACRO_END
  39
  40 /** the engine player name strings are mutable! */
  41 #define ENTCS_SET_MUTABLE_STRING(var, x) MACRO_BEGIN \
  42         if (var) strunzone(var); \
  43         var = strzone(x); \
  44 MACRO_END
  45
  46 ENTCS_PROP(ENTNUM, false, sv_entnum, ENTCS_SET_NORMAL, {}, {}) /* sentinel */
  47
  48 ENTCS_PROP(ORIGIN, false, origin, ENTCS_SET_NORMAL,
  49         { WriteVector(chan, ent.origin); },
  50         { ent.has_sv_origin = true; vector v = ReadVector(); setorigin(ent, v); })
  51
  52 ENTCS_PROP(ANGLES, false, angles_y, ENTCS_SET_NORMAL,
  53         { WriteByte(chan, ent.angles.y / 360 * 256); },
  54         { vector v = '0 0 0'; v.y = ReadByte() / 256 * 360; ent.angles = v; })
  55
  56 ENTCS_PROP(HEALTH, false, health, ENTCS_SET_NORMAL,
  57         { WriteByte(chan, bound(0, ent.health / 10, 255));  /* FIXME: use a better scale? */ },
  58         { ent.healthvalue = ReadByte() * 10; })
  59
  60 ENTCS_PROP(ARMOR, false, armorvalue, ENTCS_SET_NORMAL,
  61         { WriteByte(chan, bound(0, ent.armorvalue / 10, 255));  /* FIXME: use a better scale? */ },
  62         { ent.armorvalue = ReadByte() * 10; })
  63
  64 ENTCS_PROP(NAME, true, netname, ENTCS_SET_MUTABLE_STRING,
  65         { WriteString(chan, ent.netname); },
  66         { if (ent.netname) strunzone(ent.netname); ent.netname = strzone(ReadString()); })
  67
  68 ENTCS_PROP(MODEL, true, model, ENTCS_SET_NORMAL,
  69         { WriteString(chan, ent.model); },
  70         { if (ent.model) strunzone(ent.model); ent.model = strzone(ReadString()); })
  71
  72 ENTCS_PROP(SKIN, true, skin, ENTCS_SET_NORMAL,
  73         { WriteByte(chan, ent.skin); },
  74         { ent.skin = ReadByte(); })
  75
  76 ENTCS_PROP(CLIENTCOLORS, true, clientcolors, ENTCS_SET_NORMAL,
  77         { WriteByte(chan, ent.clientcolors); },
  78         { ent.colormap = ReadByte(); })
  79
  80 ENTCS_PROP(FRAGS, true, frags, ENTCS_SET_NORMAL,
  81         { WriteShort(chan, ent.frags); },
  82         { ent.frags = ReadShort(); })
  83
  84 #ifdef SVQC
  85
  86         int ENTCS_PUBLICMASK = 0;
  87         STATIC_INIT(ENTCS_PUBLICMASK)
  88         {
  89                 FOREACH(EntCSProps, it.m_public,
  90                 {
  91                         ENTCS_PUBLICMASK |= BIT(it.m_id);
  92                 });
  93         }
  94
  95         bool _entcs_send(entity this, entity to, int sf, int chan)
  96         {
  97                 entity player = this.owner;
  98                 sf |= BIT(0); // assume private
  99                 do {
 100                         if (IS_PLAYER(player))
 101                         {
 102                                 if (radar_showennemies) break;
 103                                 if (SAME_TEAM(to, player)) break;
 104                                 if (!(IS_PLAYER(to) || to.caplayer) && time > game_starttime) break;
 105                         }
 106                         sf &= ENTCS_PUBLICMASK; // no private updates
 107                 } while (0);
 108
 109                 sf |= this.m_forceupdate;
 110                 this.m_forceupdate = 0;
 111                 if (chan == MSG_ENTITY)
 112                         WriteHeader(chan, ENT_CLIENT_ENTCS);
 113                 else
 114                         WriteHeader(chan, CLIENT_ENTCS);
 115                 WriteByte(chan, etof(player) - 1);
 116                 WriteShort(chan, sf);
 117                 FOREACH(EntCSProps, sf & BIT(it.m_id),
 118                 {
 119                         it.m_send(chan, this);
 120                 });
 121                 return true;
 122         }
 123
 124         bool entcs_send(entity this, entity to, int sf)
 125         {
 126                 return _entcs_send(this, to, sf, MSG_ENTITY);
 127         }
 128
 129         void entcs_think(entity this)
 130         {
 131                 this.nextthink = time + 0.033333333333;  // TODO: increase this to like 0.15 once the client can do smoothing
 132                 entity o = this.owner;
 133                 FOREACH(EntCSProps, it.m_check(this, o),
 134                 {
 135                         it.m_set(this, o);
 136                         this.SendFlags |= BIT(it.m_id);
 137                 });
 138             setorigin(this, this.origin);  // relink
 139         }
 140
 141         void entcs_attach(entity player)
 142         {
 143                 entity e = player.entcs = new(entcs_sender);
 144                 e.owner = player;
 145                 setthink(e, entcs_think);
 146                 e.nextthink = time;
 147                 Net_LinkEntity(e, false, 0, entcs_send);
 148                 if (!IS_REAL_CLIENT(player)) return;
 149                 FOREACH_CLIENT(true, {
 150                         assert(it.entcs);
 151                         _entcs_send(it.entcs, msg_entity = player, BITS(23), MSG_ONE);
 152                 });
 153         }
 154
 155         void entcs_detach(entity player)
 156         {
 157                 if (!player.entcs) return;
 158                 delete(player.entcs);
 159                 player.entcs = NULL;
 160         }
 161
 162 #endif
 163
 164 #ifdef CSQC
 165
 166         void Ent_RemoveEntCS(entity this)
 167         {
 168                 int n = this.sv_entnum;
 169                 entity e = entcs_receiver(n);
 170                 entcs_receiver(n, NULL);
 171                 if (e.netname) strunzone(e.netname);
 172                 e.netname = string_null;
 173                 if (e.model) strunzone(e.model);
 174                 e.model = string_null;
 175                 if (e != this) delete(e);
 176         }
 177
 178         void entcs_think(entity this)
 179         {
 180                 entity e = CSQCModel_server2csqc(this.sv_entnum);
 181                 if (e == NULL)
 182                 {
 183                         this.has_origin = this.has_sv_origin;
 184                         return;
 185                 }
 186                 this.has_origin = true;
 187                 this.origin = e.origin;
 188                 // `cl_forceplayermodels 1` sounds will be wrong until the player has been in the PVS, but so be it
 189                 if (this.model != e.model)
 190                 {
 191                         if (this.model) strunzone(this.model);
 192                         this.model = strzone(e.model);
 193                 }
 194         }
 195
 196         bool ReadEntcs(entity this)
 197         {
 198                 int n = ReadByte();
 199                 entity e = entcs_receiver(n);
 200                 if (e == NULL)
 201                 {
 202                         if (!this)
 203                                 // initial = temp
 204                                 e = new_pure(entcs_receiver);
 205                         else
 206                                 // initial = linked
 207                                 e = this;
 208                         setthink(e, entcs_think);
 209                         entcs_receiver(n, e);
 210                 }
 211                 else if (e != this && this)
 212                 {
 213                         // upgrade to linked
 214                         delete(e);
 215                         e = this;
 216                         setthink(e, entcs_think);
 217                         entcs_receiver(n, e);
 218                 }
 219
 220                 InterpolateOrigin_Undo(e);
 221                 e.sv_entnum = n;
 222                 int sf = ReadShort();
 223                 e.has_sv_origin = false;
 224                 e.m_entcs_private = boolean(sf & BIT(0));
 225                 FOREACH(EntCSProps, sf & BIT(it.m_id),
 226                 {
 227                         it.m_receive(e);
 228                 });
 229                 e.iflags |= IFLAG_ORIGIN;
 230                 InterpolateOrigin_Note(e);
 231                 getthink(e)(e);
 232                 return true;
 233         }
 234
 235         NET_HANDLE(ENT_CLIENT_ENTCS, bool isnew)
 236         {
 237                 if (isnew)
 238                 {
 239                         make_pure(this);
 240                         this.classname = "entcs_receiver";
 241                         this.entremove = Ent_RemoveEntCS;
 242                 }
 243                 return ReadEntcs(this);
 244         }
 245
 246         NET_HANDLE(CLIENT_ENTCS, bool isnew)
 247         {
 248                 return ReadEntcs(NULL);
 249         }
 250
 251 #endif