Rename t_items.qc to items.qc
[xonotic/xonotic-data.pk3dir.git] / qcsrc / common / ent_cs.qc
1 #include "ent_cs.qh"
2 #include <common/gamemodes/_mod.qh>
3 #include <common/resources.qh>
4 #ifdef SVQC
5 #include <server/resources.qh>
6 #endif
7
8 REGISTRY(EntCSProps, BITS(16) - 1)
9 REGISTER_REGISTRY(EntCSProps)
10 REGISTRY_SORT(EntCSProps)
11 REGISTRY_CHECK(EntCSProps)
12
13 REGISTRY_DEFINE_GET(EntCSProps, NULL)
14 STATIC_INIT(EntCSProps_renumber) { FOREACH(EntCSProps, true, it.m_id = i); }
15
16 // these entcs_props ids need to be referenced directly
17 int ENTCS_PROP_ENTNUM_id = 0;
18 int ENTCS_PROP_ORIGIN_id = 0;
19 STATIC_INIT(EntCSProps_setglobalids)
20 {
21         FOREACH(EntCSProps, true, {
22                 if (it.registered_id == "ENTCS_PROP_ENTNUM")
23                         ENTCS_PROP_ENTNUM_id = it.m_id;
24                 if (it.registered_id == "ENTCS_PROP_ORIGIN")
25                         ENTCS_PROP_ORIGIN_id = it.m_id;
26         });
27 }
28
29 #ifdef SVQC
30 // Force an origin update, for player sounds
31 void entcs_force_origin(entity player)
32 {
33         CS(player).entcs.m_forceupdate = BIT(ENTCS_PROP_ORIGIN_id);
34 }
35 #endif
36
37 .bool m_public;
38 .bool(entity ent, entity player) m_check;
39 .void(entity ent, entity player) m_set;
40 .void(int chan, entity ent) m_send;
41 .void(entity ent) m_receive;
42
43 #ifdef SVQC
44 #define _ENTCS_PROP(id, ispublic, checkprop, checkprop_pl, setprop, svsend, clreceive) \
45         void id##_set(entity ent, entity player) { setprop(ent.(checkprop), player.(checkprop_pl)); } \
46         void id##_send(int chan, entity ent) { LAMBDA(svsend); } \
47         REGISTER(EntCSProps, ENTCS_PROP, id, m_id, new_pure(entcs_prop)) { \
48                 this.m_public = ispublic; \
49                 this.m_check = id##_check; \
50                 this.m_set = id##_set; \
51                 this.m_send = id##_send; \
52         }
53
54 #define ENTCS_PROP(id, ispublic, checkprop, checkprop_pl, setprop, svsend, clreceive) \
55         bool id##_check(entity ent, entity player) { return (ent.(checkprop) != player.(checkprop_pl)); } \
56         _ENTCS_PROP(id, ispublic, checkprop, checkprop_pl, setprop, svsend, clreceive)
57
58 #define ENTCS_PROP_CODED(id, ispublic, checkprop, checkprop_pl, setprop, decfactor, svsend, clreceive) \
59         bool id##_check(entity ent, entity player) { \
60                 return (floor(ent.(checkprop)) / decfactor != floor(player.(checkprop_pl)) / decfactor); \
61         } \
62         _ENTCS_PROP(id, ispublic, checkprop, checkprop_pl, setprop, svsend, clreceive)
63
64 #elif defined(CSQC)
65 #define ENTCS_PROP(id, ispublic, checkprop, checkprop_pl, setprop, svsend, clreceive) \
66         void id##_receive(entity ent) { LAMBDA(clreceive); } \
67         REGISTER(EntCSProps, ENTCS_PROP, id, m_id, new_pure(entcs_prop)) { \
68                 this.m_public = ispublic; \
69                 this.m_receive = id##_receive; \
70         }
71
72 #define ENTCS_PROP_CODED(id, ispublic, checkprop, checkprop_pl, setprop, decfactor, svsend, clreceive) \
73         ENTCS_PROP(id, ispublic, checkprop, checkprop_pl, setprop, svsend, clreceive)
74 #endif
75
76 #ifdef SVQC
77 #define ENTCS_PROP_RESOURCE(id, ispublic, checkprop, setprop, decfactor, svsend, clreceive) \
78         bool id##_check(entity ent, entity player) { \
79                 return (floor(GetResource(ent, checkprop) / decfactor) != floor(GetResource(player, checkprop) / decfactor)); \
80         } \
81         void id##_set(entity ent, entity player) { SetResourceExplicit(ent, checkprop, GetResource(player, checkprop)); } \
82         void id##_send(int chan, entity ent) { LAMBDA(svsend); } \
83         REGISTER(EntCSProps, ENTCS_PROP, id, m_id, new_pure(entcs_prop)) { \
84                 this.m_public = ispublic; \
85                 this.m_check = id##_check; \
86                 this.m_set = id##_set; \
87                 this.m_send = id##_send; \
88         }
89 #elif defined(CSQC)
90 #define ENTCS_PROP_RESOURCE(id, ispublic, checkprop, setprop, decfactor, svsend, clreceive) \
91         void id##_receive(entity ent) { LAMBDA(clreceive); } \
92         REGISTER(EntCSProps, ENTCS_PROP, id, m_id, new_pure(entcs_prop)) { \
93                 this.m_public = ispublic; \
94                 this.m_receive = id##_receive; \
95         }
96 #endif
97
98 #define ENTCS_SET_NORMAL(var, x) MACRO_BEGIN \
99         var = x; \
100 MACRO_END
101
102 /** the engine player name strings are mutable! */
103 #define ENTCS_SET_MUTABLE_STRING(var, x) MACRO_BEGIN \
104         strcpy(var, x); \
105 MACRO_END
106
107 ENTCS_PROP(ENTNUM, false, sv_entnum, sv_entnum, ENTCS_SET_NORMAL, {}, {}) /* sentinel */
108
109 ENTCS_PROP(ORIGIN, false, origin, origin, ENTCS_SET_NORMAL,
110         { WriteVector(chan, ent.origin); },
111         { ent.has_sv_origin = true; vector v = ReadVector(); setorigin(ent, v); })
112
113 #define DEC_FACTOR (360 / 32)
114 ENTCS_PROP_CODED(ANGLES, false, angles_y, angles_y, ENTCS_SET_NORMAL, DEC_FACTOR,
115         { WriteByte(chan, ent.angles.y / DEC_FACTOR); },
116         { vector v = '0 0 0'; v.y = ReadByte() * DEC_FACTOR; ent.angles = v; })
117 #undef DEC_FACTOR
118
119 // FIXME: use a better scale?
120 #define DEC_FACTOR 10
121 ENTCS_PROP_RESOURCE(HEALTH, false, RES_HEALTH, ENTCS_SET_NORMAL, DEC_FACTOR,
122         { WriteByte(chan, bound(0, GetResource(ent, RES_HEALTH) / DEC_FACTOR, 255)); },
123         { ent.healthvalue = ReadByte() * DEC_FACTOR; })
124
125 ENTCS_PROP_RESOURCE(ARMOR, false, RES_ARMOR, ENTCS_SET_NORMAL, DEC_FACTOR,
126         { WriteByte(chan, bound(0, GetResource(ent, RES_ARMOR) / DEC_FACTOR, 255)); },
127         { SetResourceExplicit(ent, RES_ARMOR, ReadByte() * DEC_FACTOR); })
128 #undef DEC_FACTOR
129
130 ENTCS_PROP(NAME, true, netname, netname, ENTCS_SET_MUTABLE_STRING,
131         { WriteString(chan, ent.netname); },
132         { strcpy(ent.netname, ReadString()); })
133
134 ENTCS_PROP(MODEL, true, model, model, ENTCS_SET_NORMAL,
135         { WriteString(chan, ent.model); },
136         { strcpy(ent.model, ReadString()); })
137
138 ENTCS_PROP(SKIN, true, skin, skin, ENTCS_SET_NORMAL,
139         { WriteByte(chan, ent.skin); },
140         { ent.skin = ReadByte(); })
141
142 ENTCS_PROP(CLIENTCOLORS, true, clientcolors, clientcolors, ENTCS_SET_NORMAL,
143         { WriteByte(chan, ent.clientcolors); },
144         { ent.colormap = ReadByte(); })
145
146 ENTCS_PROP(FRAGS, true, frags, frags, ENTCS_SET_NORMAL,
147         { WriteShort(chan, ent.frags); },
148         { ent.frags = ReadShort(); })
149
150 // use sv_solid to avoid changing solidity state of entcs entities
151 ENTCS_PROP(SOLID, true, sv_solid, solid, ENTCS_SET_NORMAL,
152         { WriteByte(chan, ent.sv_solid); },
153         { ent.sv_solid = ReadByte(); })
154
155 #ifdef SVQC
156
157         int ENTCS_PUBLICMASK = 0;
158         STATIC_INIT(ENTCS_PUBLICMASK)
159         {
160                 FOREACH(EntCSProps, it.m_public,
161                 {
162                         ENTCS_PUBLICMASK |= BIT(it.m_id);
163                 });
164         }
165
166         bool _entcs_send(entity this, entity to, int sf, int chan)
167         {
168                 entity player = this.owner;
169                 sf |= BIT(ENTCS_PROP_ENTNUM_id); // assume private
170                 do {
171                         if (IS_PLAYER(player))
172                         {
173                                 if (radar_showennemies) break;
174                                 if (SAME_TEAM(to, player)) break;
175                                 if (!(IS_PLAYER(to) || to.caplayer) && time > game_starttime) break;
176                         }
177                         sf &= ENTCS_PUBLICMASK; // no private updates
178                 } while (0);
179
180                 sf |= this.m_forceupdate;
181                 this.m_forceupdate = 0;
182                 if (chan == MSG_ENTITY)
183                         WriteHeader(chan, ENT_CLIENT_ENTCS);
184                 else
185                         WriteHeader(chan, CLIENT_ENTCS);
186                 WriteByte(chan, etof(player) - 1);
187                 WriteShort(chan, sf);
188                 FOREACH(EntCSProps, sf & BIT(it.m_id),
189                 {
190                         it.m_send(chan, this);
191                 });
192                 return true;
193         }
194
195         bool entcs_send(entity this, entity to, int sf)
196         {
197                 return _entcs_send(this, to, sf, MSG_ENTITY);
198         }
199
200         void entcs_think(entity this)
201         {
202                 this.nextthink = time + 0.033333333333;  // TODO: increase this to like 0.15 once the client can do smoothing
203                 entity player = this.owner;
204                 FOREACH(EntCSProps, it.m_check(this, player),
205                 {
206                         it.m_set(this, player);
207                         this.SendFlags |= BIT(it.m_id);
208                 });
209                 setorigin(this, this.origin); // relink
210         }
211
212         void entcs_attach(entity player)
213         {
214                 entity e = CS(player).entcs = new(entcs_sender);
215                 e.owner = player;
216                 setthink(e, entcs_think);
217                 e.nextthink = time;
218                 Net_LinkEntity(e, false, 0, entcs_send);
219                 if (!IS_REAL_CLIENT(player)) return;
220                 FOREACH_CLIENT(true, {
221                         assert(CS(it).entcs);
222                         _entcs_send(CS(it).entcs, msg_entity = player, BITS(23), MSG_ONE);
223                 });
224         }
225
226         void entcs_detach(entity player)
227         {
228                 if (!CS(player).entcs) return;
229                 delete(CS(player).entcs);
230                 CS(player).entcs = NULL;
231         }
232
233 #endif
234
235 #ifdef CSQC
236
237         void Ent_RemoveEntCS(entity this)
238         {
239                 int n = this.sv_entnum;
240                 entity e = entcs_receiver(n);
241                 entcs_receiver(n, NULL);
242                 strfree(e.netname);
243                 strfree(e.model);
244                 if (e != this) delete(e);
245         }
246
247         void entcs_think(entity this)
248         {
249                 entity e = CSQCModel_server2csqc(this.sv_entnum);
250                 if (e == NULL)
251                 {
252                         this.has_origin = this.has_sv_origin;
253                         return;
254                 }
255                 this.has_origin = true;
256                 this.origin = e.origin;
257                 // `cl_forceplayermodels 1` sounds will be wrong until the player has been in the PVS, but so be it
258                 if (this.model != e.model)
259                 {
260                         strcpy(this.model, e.model);
261                 }
262         }
263
264         bool ReadEntcs(entity this)
265         {
266                 int n = ReadByte();
267                 entity e = entcs_receiver(n);
268                 if (e == NULL)
269                 {
270                         if (!this)
271                                 // initial = temp
272                                 e = new_pure(entcs_receiver);
273                         else
274                                 // initial = linked
275                                 e = this;
276                         setthink(e, entcs_think);
277                         entcs_receiver(n, e);
278                 }
279                 else if (e != this && this)
280                 {
281                         // upgrade to linked
282                         delete(e);
283                         e = this;
284                         setthink(e, entcs_think);
285                         entcs_receiver(n, e);
286                 }
287
288                 InterpolateOrigin_Undo(e);
289                 e.sv_entnum = n;
290                 int sf = ReadShort();
291                 e.has_sv_origin = false;
292                 e.m_entcs_private = boolean(sf & BIT(ENTCS_PROP_ENTNUM_id));
293                 FOREACH(EntCSProps, sf & BIT(it.m_id),
294                 {
295                         it.m_receive(e);
296                 });
297                 e.iflags |= IFLAG_ORIGIN;
298                 InterpolateOrigin_Note(e);
299                 getthink(e)(e);
300                 return true;
301         }
302
303         NET_HANDLE(ENT_CLIENT_ENTCS, bool isnew)
304         {
305                 if (isnew)
306                 {
307                         make_pure(this);
308                         this.classname = "entcs_receiver";
309                         this.entremove = Ent_RemoveEntCS;
310                 }
311                 return ReadEntcs(this);
312         }
313
314         NET_HANDLE(CLIENT_ENTCS, bool isnew)
315         {
316                 return ReadEntcs(NULL);
317         }
318
319 #endif