qcsrc/common/gamemodes/gamemode/cts/sv_cts.qc

   1 #include "sv_cts.qh"
   2
   3 #include <server/race.qh>
   4 #include <server/gamelog.qh>
   5 #include <server/items.qh>
   6
   7 float autocvar_g_cts_finish_kill_delay;
   8 bool autocvar_g_cts_selfdamage;
   9 bool autocvar_g_cts_removeprojectiles;
  10
  11 // legacy bot roles
  12 .float race_checkpoint;
  13 void havocbot_role_cts(entity this)
  14 {
  15         if(IS_DEAD(this))
  16                 return;
  17
  18         if (navigation_goalrating_timeout(this))
  19         {
  20                 navigation_goalrating_start(this);
  21
  22                 bool raw_touch_check = true;
  23                 int cp = this.race_checkpoint;
  24
  25                 LABEL(search_racecheckpoints)
  26                 IL_EACH(g_racecheckpoints, true,
  27                 {
  28                         if(it.cnt == cp || cp == -1)
  29                         {
  30                                 // redirect bot to next goal if it touched the waypoint of an untouchable checkpoint
  31                                 // e.g. checkpoint in front of Stormkeep's warpzone
  32                                 // the same workaround is applied in Race game mode
  33                                 if (raw_touch_check && vdist(this.origin - it.nearestwaypoint.origin, <, 30))
  34                                 {
  35                                         cp = race_NextCheckpoint(cp);
  36                                         raw_touch_check = false;
  37                                         goto search_racecheckpoints;
  38                                 }
  39                                 navigation_routerating(this, it, 1000000, 5000);
  40                         }
  41                 });
  42
  43                 navigation_goalrating_end(this);
  44
  45                 navigation_goalrating_timeout_set(this);
  46         }
  47 }
  48
  49 void cts_ScoreRules()
  50 {
  51     GameRules_score_enabled(false);
  52     GameRules_scoring(0, 0, 0, {
  53         if (g_race_qualifying) {
  54             field(SP_RACE_FASTEST, "fastest", SFL_SORT_PRIO_PRIMARY | SFL_LOWER_IS_BETTER | SFL_TIME);
  55         } else {
  56             field(SP_RACE_LAPS, "laps", SFL_SORT_PRIO_PRIMARY);
  57             field(SP_RACE_TIME, "time", SFL_SORT_PRIO_SECONDARY | SFL_LOWER_IS_BETTER | SFL_TIME);
  58             field(SP_RACE_FASTEST, "fastest", SFL_LOWER_IS_BETTER | SFL_TIME);
  59         }
  60     });
  61 }
  62
  63 void cts_EventLog(string mode, entity actor) // use an alias for easy changing and quick editing later
  64 {
  65         if(autocvar_sv_eventlog)
  66                 GameLogEcho(strcat(":cts:", mode, ":", ((actor != NULL) ? (strcat(":", ftos(actor.playerid))) : "")));
  67 }
  68
  69 MUTATOR_HOOKFUNCTION(cts, PlayerPhysics)
  70 {
  71         entity player = M_ARGV(0, entity);
  72         float dt = M_ARGV(1, float);
  73
  74         player.race_movetime_frac += dt;
  75         float f = floor(player.race_movetime_frac);
  76         player.race_movetime_frac -= f;
  77         player.race_movetime_count += f;
  78         player.race_movetime = player.race_movetime_frac + player.race_movetime_count;
  79
  80         if(IS_PLAYER(player))
  81         {
  82                 if (player.race_penalty)
  83                         if (time > player.race_penalty)
  84                                 player.race_penalty = 0;
  85                 if(player.race_penalty)
  86                 {
  87                         player.velocity = '0 0 0';
  88                         set_movetype(player, MOVETYPE_NONE);
  89                         player.disableclientprediction = 2;
  90                 }
  91         }
  92
  93         // force kbd movement for fairness
  94         float wishspeed;
  95         vector wishvel;
  96
  97         // if record times matter
  98         // ensure nothing EVIL is being done (i.e. div0_evade)
  99         // this hinders joystick users though
 100         // but it still gives SOME analog control
 101         wishvel.x = fabs(CS(player).movement.x);
 102         wishvel.y = fabs(CS(player).movement.y);
 103         if(wishvel.x != 0 && wishvel.y != 0 && wishvel.x != wishvel.y)
 104         {
 105                 wishvel.z = 0;
 106                 wishspeed = vlen(wishvel);
 107                 if(wishvel.x >= 2 * wishvel.y)
 108                 {
 109                         // pure X motion
 110                         if(CS(player).movement.x > 0)
 111                                 CS(player).movement_x = wishspeed;
 112                         else
 113                                 CS(player).movement_x = -wishspeed;
 114                         CS(player).movement_y = 0;
 115                 }
 116                 else if(wishvel.y >= 2 * wishvel.x)
 117                 {
 118                         // pure Y motion
 119                         CS(player).movement_x = 0;
 120                         if(CS(player).movement.y > 0)
 121                                 CS(player).movement_y = wishspeed;
 122                         else
 123                                 CS(player).movement_y = -wishspeed;
 124                 }
 125                 else
 126                 {
 127                         // diagonal
 128                         if(CS(player).movement.x > 0)
 129                                 CS(player).movement_x = M_SQRT1_2 * wishspeed;
 130                         else
 131                                 CS(player).movement_x = -M_SQRT1_2 * wishspeed;
 132                         if(CS(player).movement.y > 0)
 133                                 CS(player).movement_y = M_SQRT1_2 * wishspeed;
 134                         else
 135                                 CS(player).movement_y = -M_SQRT1_2 * wishspeed;
 136                 }
 137         }
 138 }
 139
 140 MUTATOR_HOOKFUNCTION(cts, reset_map_global)
 141 {
 142         float s;
 143
 144         Score_NicePrint(NULL);
 145
 146         race_ClearRecords();
 147         PlayerScore_Sort(race_place, 0, 1, 0);
 148
 149         FOREACH_CLIENT(true, {
 150                 if(it.race_place)
 151                 {
 152                         s = GameRules_scoring_add(it, RACE_FASTEST, 0);
 153                         if(!s)
 154                                 it.race_place = 0;
 155                 }
 156                 cts_EventLog(ftos(it.race_place), it);
 157         });
 158
 159         if(g_race_qualifying == 2)
 160         {
 161                 g_race_qualifying = 0;
 162                 independent_players = 0;
 163                 cvar_set("fraglimit", ftos(race_fraglimit));
 164                 cvar_set("leadlimit", ftos(race_leadlimit));
 165                 cvar_set("timelimit", ftos(race_timelimit));
 166                 cts_ScoreRules();
 167         }
 168 }
 169
 170 MUTATOR_HOOKFUNCTION(cts, ClientConnect)
 171 {
 172         entity player = M_ARGV(0, entity);
 173
 174         race_PreparePlayer(player);
 175         player.race_checkpoint = -1;
 176
 177         if(IS_REAL_CLIENT(player))
 178         {
 179                 string rr = CTS_RECORD;
 180
 181                 msg_entity = player;
 182                 race_send_recordtime(MSG_ONE);
 183                 race_send_speedaward(MSG_ONE);
 184
 185                 speedaward_alltimebest = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed")));
 186                 speedaward_alltimebest_holder = uid2name(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/crypto_idfp")));
 187                 race_send_speedaward_alltimebest(MSG_ONE);
 188
 189                 float i;
 190                 int m = min(RANKINGS_CNT, autocvar_g_cts_send_rankings_cnt);
 191                 race_send_rankings_cnt(MSG_ONE);
 192                 for (i = 1; i <= m; ++i)
 193                 {
 194                         race_SendRankings(i, 0, 0, MSG_ONE);
 195                 }
 196         }
 197 }
 198
 199 MUTATOR_HOOKFUNCTION(cts, AbortSpeedrun)
 200 {
 201         entity player = M_ARGV(0, entity);
 202
 203         if(autocvar_g_allow_checkpoints)
 204                 race_PreparePlayer(player); // nice try
 205 }
 206
 207 MUTATOR_HOOKFUNCTION(cts, MakePlayerObserver)
 208 {
 209         entity player = M_ARGV(0, entity);
 210
 211         if(GameRules_scoring_add(player, RACE_FASTEST, 0))
 212                 player.frags = FRAGS_PLAYER_OUT_OF_GAME;
 213         else
 214                 player.frags = FRAGS_SPECTATOR;
 215
 216         race_PreparePlayer(player);
 217         player.race_checkpoint = -1;
 218 }
 219
 220 MUTATOR_HOOKFUNCTION(cts, PlayerSpawn)
 221 {
 222         entity player = M_ARGV(0, entity);
 223         entity spawn_spot = M_ARGV(1, entity);
 224
 225         if(spawn_spot.target == "")
 226                 // Emergency: this wasn't a real spawnpoint. Can this ever happen?
 227                 race_PreparePlayer(player);
 228
 229         // if we need to respawn, do it right
 230         player.race_respawn_checkpoint = player.race_checkpoint;
 231         player.race_respawn_spotref = spawn_spot;
 232
 233         player.race_place = 0;
 234 }
 235
 236 MUTATOR_HOOKFUNCTION(cts, PutClientInServer)
 237 {
 238         entity player = M_ARGV(0, entity);
 239
 240         if(IS_PLAYER(player))
 241         if(!game_stopped)
 242         {
 243                 if(CS(player).killcount == FRAGS_SPECTATOR /* initial spawn */ || g_race_qualifying) // spawn
 244                         race_PreparePlayer(player);
 245                 else // respawn
 246                         race_RetractPlayer(player);
 247
 248                 race_AbandonRaceCheck(player);
 249         }
 250 }
 251
 252 MUTATOR_HOOKFUNCTION(cts, PlayerDies)
 253 {
 254         entity frag_target = M_ARGV(2, entity);
 255
 256         frag_target.respawn_flags |= RESPAWN_FORCE;
 257         race_AbandonRaceCheck(frag_target);
 258
 259         if(autocvar_g_cts_removeprojectiles)
 260         {
 261                 IL_EACH(g_projectiles, it.owner == frag_target && (it.flags & FL_PROJECTILE),
 262                 {
 263                         delete(it);
 264                 });
 265         }
 266 }
 267
 268 MUTATOR_HOOKFUNCTION(cts, HavocBot_ChooseRole)
 269 {
 270         entity bot = M_ARGV(0, entity);
 271
 272         bot.havocbot_role = havocbot_role_cts;
 273         return true;
 274 }
 275
 276 MUTATOR_HOOKFUNCTION(cts, GetPressedKeys)
 277 {
 278         entity player = M_ARGV(0, entity);
 279
 280         if(CS(player).cvar_cl_allow_uidtracking == 1 && CS(player).cvar_cl_allow_uid2name == 1)
 281         {
 282                 if (!player.stored_netname)
 283                         player.stored_netname = strzone(uid2name(player.crypto_idfp));
 284                 if(player.stored_netname != player.netname)
 285                 {
 286                         db_put(ServerProgsDB, strcat("/uid2name/", player.crypto_idfp), player.netname);
 287                         strcpy(player.stored_netname, player.netname);
 288                 }
 289         }
 290
 291         if (!IS_OBSERVER(player))
 292         {
 293                 if(vdist(player.velocity - player.velocity_z * '0 0 1', >, speedaward_speed))
 294                 {
 295                         speedaward_speed = vlen(player.velocity - player.velocity_z * '0 0 1');
 296                         speedaward_holder = player.netname;
 297                         speedaward_uid = player.crypto_idfp;
 298                         speedaward_lastupdate = time;
 299                 }
 300                 if (speedaward_speed > speedaward_lastsent && time - speedaward_lastupdate > 1)
 301                 {
 302                         string rr = CTS_RECORD;
 303                         race_send_speedaward(MSG_ALL);
 304                         speedaward_lastsent = speedaward_speed;
 305                         if (speedaward_speed > speedaward_alltimebest && speedaward_uid != "")
 306                         {
 307                                 speedaward_alltimebest = speedaward_speed;
 308                                 speedaward_alltimebest_holder = speedaward_holder;
 309                                 speedaward_alltimebest_uid = speedaward_uid;
 310                                 db_put(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed"), ftos(speedaward_alltimebest));
 311                                 db_put(ServerProgsDB, strcat(GetMapname(), rr, "speed/crypto_idfp"), speedaward_alltimebest_uid);
 312                                 race_send_speedaward_alltimebest(MSG_ALL);
 313                         }
 314                 }
 315         }
 316 }
 317
 318 MUTATOR_HOOKFUNCTION(cts, ForbidThrowCurrentWeapon)
 319 {
 320         // no weapon dropping in CTS
 321         return true;
 322 }
 323
 324 MUTATOR_HOOKFUNCTION(cts, FilterItem)
 325 {
 326         entity item = M_ARGV(0, entity);
 327
 328         if (Item_IsLoot(item))
 329         {
 330                 return true;
 331         }
 332 }
 333
 334 MUTATOR_HOOKFUNCTION(cts, Damage_Calculate)
 335 {
 336         entity frag_attacker = M_ARGV(1, entity);
 337         entity frag_target = M_ARGV(2, entity);
 338         float frag_deathtype = M_ARGV(3, float);
 339         float frag_damage = M_ARGV(4, float);
 340
 341         if(frag_target == frag_attacker || frag_deathtype == DEATH_FALL.m_id)
 342         if(!autocvar_g_cts_selfdamage)
 343         {
 344                 frag_damage = 0;
 345                 M_ARGV(4, float) = frag_damage;
 346         }
 347 }
 348
 349 MUTATOR_HOOKFUNCTION(cts, ForbidPlayerScore_Clear)
 350 {
 351         return true; // in CTS, you don't lose score by observing
 352 }
 353
 354 MUTATOR_HOOKFUNCTION(cts, GetRecords)
 355 {
 356         int record_page = M_ARGV(0, int);
 357         string ret_string = M_ARGV(1, string);
 358
 359         for(int i = record_page * 200; i < MapInfo_count && i < record_page * 200 + 200; ++i)
 360         {
 361                 if(MapInfo_Get_ByID(i))
 362                 {
 363                         float r = race_readTime(MapInfo_Map_bspname, 1);
 364
 365                         if(!r)
 366                                 continue;
 367
 368                         string h = race_readName(MapInfo_Map_bspname, 1);
 369                         ret_string = strcat(ret_string, strpad(32, MapInfo_Map_bspname), " ", strpad(-8, TIME_ENCODED_TOSTRING(r)), " ", h, "\n");
 370                 }
 371         }
 372
 373         M_ARGV(1, string) = ret_string;
 374 }
 375
 376 MUTATOR_HOOKFUNCTION(cts, ClientKill)
 377 {
 378         M_ARGV(1, float) = 0; // kill delay
 379 }
 380
 381 MUTATOR_HOOKFUNCTION(cts, Race_FinalCheckpoint)
 382 {
 383         entity player = M_ARGV(0, entity);
 384
 385         // useful to prevent cheating by running back to the start line and starting out with more speed
 386         if(autocvar_g_cts_finish_kill_delay)
 387                 ClientKill_Silent(player, autocvar_g_cts_finish_kill_delay);
 388 }
 389
 390 MUTATOR_HOOKFUNCTION(cts, HideTeamNagger)
 391 {
 392         return true; // doesn't work so well (but isn't cts a teamless mode?)
 393 }
 394
 395 MUTATOR_HOOKFUNCTION(cts, FixClientCvars)
 396 {
 397         entity player = M_ARGV(0, entity);
 398
 399         stuffcmd(player, "cl_cmd settemp cl_movecliptokeyboard 2\n");
 400 }
 401
 402 MUTATOR_HOOKFUNCTION(cts, WantWeapon)
 403 {
 404         M_ARGV(1, float) = (M_ARGV(0, entity) == WEP_SHOTGUN); // want weapon = weapon info
 405         M_ARGV(3, bool) = true; // want mutator blocked
 406         return true;
 407 }
 408
 409 MUTATOR_HOOKFUNCTION(cts, ForbidDropCurrentWeapon)
 410 {
 411         return true;
 412 }
 413
 414 void cts_Initialize()
 415 {
 416         cts_ScoreRules();
 417 }