qcsrc/common/gamemodes/gamemode/freezetag/freezetag.qc

   1 #include "freezetag.qh"
   2
   3 // TODO: sv_freezetag
   4 #ifdef SVQC
   5 #include <server/resources.qh>
   6
   7 float autocvar_g_freezetag_frozen_maxtime;
   8 float autocvar_g_freezetag_revive_clearspeed;
   9 float autocvar_g_freezetag_round_timelimit;
  10 //int autocvar_g_freezetag_teams;
  11 int autocvar_g_freezetag_teams_override;
  12 float autocvar_g_freezetag_warmup;
  13
  14 void freezetag_count_alive_players()
  15 {
  16         total_players = redalive = bluealive = yellowalive = pinkalive = 0;
  17         FOREACH_CLIENT(IS_PLAYER(it), {
  18                 switch(it.team)
  19                 {
  20                         case NUM_TEAM_1: ++total_players; if(STAT(FROZEN, it) != 1 && GetResourceAmount(it, RESOURCE_HEALTH) >= 1) ++redalive; break;
  21                         case NUM_TEAM_2: ++total_players; if(STAT(FROZEN, it) != 1 && GetResourceAmount(it, RESOURCE_HEALTH) >= 1) ++bluealive; break;
  22                         case NUM_TEAM_3: ++total_players; if(STAT(FROZEN, it) != 1 && GetResourceAmount(it, RESOURCE_HEALTH) >= 1) ++yellowalive; break;
  23                         case NUM_TEAM_4: ++total_players; if(STAT(FROZEN, it) != 1 && GetResourceAmount(it, RESOURCE_HEALTH) >= 1) ++pinkalive; break;
  24                 }
  25         });
  26         FOREACH_CLIENT(IS_REAL_CLIENT(it), {
  27                 STAT(REDALIVE, it) = redalive;
  28                 STAT(BLUEALIVE, it) = bluealive;
  29                 STAT(YELLOWALIVE, it) = yellowalive;
  30                 STAT(PINKALIVE, it) = pinkalive;
  31         });
  32
  33         eliminatedPlayers.SendFlags |= 1;
  34 }
  35 #define FREEZETAG_ALIVE_TEAMS() ((redalive > 0) + (bluealive > 0) + (yellowalive > 0) + (pinkalive > 0))
  36 #define FREEZETAG_ALIVE_TEAMS_OK() (FREEZETAG_ALIVE_TEAMS() == NumTeams(freezetag_teams))
  37
  38 float freezetag_CheckTeams()
  39 {
  40         static float prev_missing_teams_mask;
  41         if(FREEZETAG_ALIVE_TEAMS_OK())
  42         {
  43                 if(prev_missing_teams_mask > 0)
  44                         Kill_Notification(NOTIF_ALL, NULL, MSG_CENTER, CPID_MISSING_TEAMS);
  45                 prev_missing_teams_mask = -1;
  46                 return 1;
  47         }
  48         if(total_players == 0)
  49         {
  50                 if(prev_missing_teams_mask > 0)
  51                         Kill_Notification(NOTIF_ALL, NULL, MSG_CENTER, CPID_MISSING_TEAMS);
  52                 prev_missing_teams_mask = -1;
  53                 return 0;
  54         }
  55         int missing_teams_mask = 0;
  56         if(freezetag_teams & BIT(0))
  57                 missing_teams_mask += (!redalive) * 1;
  58         if(freezetag_teams & BIT(1))
  59                 missing_teams_mask += (!bluealive) * 2;
  60         if(freezetag_teams & BIT(2))
  61                 missing_teams_mask += (!yellowalive) * 4;
  62         if(freezetag_teams & BIT(3))
  63                 missing_teams_mask += (!pinkalive) * 8;
  64         if(prev_missing_teams_mask != missing_teams_mask)
  65         {
  66                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_MISSING_TEAMS, missing_teams_mask);
  67                 prev_missing_teams_mask = missing_teams_mask;
  68         }
  69         return 0;
  70 }
  71
  72 float freezetag_getWinnerTeam()
  73 {
  74         float winner_team = 0;
  75         if(redalive >= 1)
  76                 winner_team = NUM_TEAM_1;
  77         if(bluealive >= 1)
  78         {
  79                 if(winner_team) return 0;
  80                 winner_team = NUM_TEAM_2;
  81         }
  82         if(yellowalive >= 1)
  83         {
  84                 if(winner_team) return 0;
  85                 winner_team = NUM_TEAM_3;
  86         }
  87         if(pinkalive >= 1)
  88         {
  89                 if(winner_team) return 0;
  90                 winner_team = NUM_TEAM_4;
  91         }
  92         if(winner_team)
  93                 return winner_team;
  94         return -1; // no player left
  95 }
  96
  97 void nades_Clear(entity);
  98 void nades_GiveBonus(entity player, float score);
  99
 100 float freezetag_CheckWinner()
 101 {
 102         if(round_handler_GetEndTime() > 0 && round_handler_GetEndTime() - time <= 0)
 103         {
 104                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_ROUND_OVER);
 105                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_ROUND_OVER);
 106                 FOREACH_CLIENT(IS_PLAYER(it), {
 107                         it.freezetag_frozen_timeout = 0;
 108                         nades_Clear(it);
 109                 });
 110                 game_stopped = true;
 111                 round_handler_Init(5, autocvar_g_freezetag_warmup, autocvar_g_freezetag_round_timelimit);
 112                 return 1;
 113         }
 114
 115         if(FREEZETAG_ALIVE_TEAMS() > 1)
 116                 return 0;
 117
 118         int winner_team = freezetag_getWinnerTeam();
 119         if(winner_team > 0)
 120         {
 121                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, APP_TEAM_NUM(winner_team, CENTER_ROUND_TEAM_WIN));
 122                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(winner_team, INFO_ROUND_TEAM_WIN));
 123                 TeamScore_AddToTeam(winner_team, ST_SCORE, +1);
 124         }
 125         else if(winner_team == -1)
 126         {
 127                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_ROUND_TIED);
 128                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_ROUND_TIED);
 129         }
 130
 131         FOREACH_CLIENT(IS_PLAYER(it), {
 132                 it.freezetag_frozen_timeout = 0;
 133                 nades_Clear(it);
 134         });
 135
 136         game_stopped = true;
 137         round_handler_Init(5, autocvar_g_freezetag_warmup, autocvar_g_freezetag_round_timelimit);
 138         return 1;
 139 }
 140
 141 entity freezetag_LastPlayerForTeam(entity this)
 142 {
 143         entity last_pl = NULL;
 144         FOREACH_CLIENT(IS_PLAYER(it) && it != this && SAME_TEAM(it, this), {
 145                 if (!STAT(FROZEN, it) && GetResourceAmount(it, RESOURCE_HEALTH) >= 1)
 146                 {
 147                         if (!last_pl)
 148                                 last_pl = it;
 149                         else
 150                                 return NULL;
 151                 }
 152         });
 153         return last_pl;
 154 }
 155
 156 void freezetag_LastPlayerForTeam_Notify(entity this)
 157 {
 158         if(round_handler_IsActive())
 159         if(round_handler_IsRoundStarted())
 160         {
 161                 entity pl = freezetag_LastPlayerForTeam(this);
 162                 if(pl)
 163                         Send_Notification(NOTIF_ONE, pl, MSG_CENTER, CENTER_ALONE);
 164         }
 165 }
 166
 167 void freezetag_Add_Score(entity targ, entity attacker)
 168 {
 169         if(attacker == targ)
 170         {
 171                 // you froze your own dumb targ
 172                 // counted as "suicide" already
 173                 GameRules_scoring_add(targ, SCORE, -1);
 174         }
 175         else if(IS_PLAYER(attacker))
 176         {
 177                 // got frozen by an enemy
 178                 // counted as "kill" and "death" already
 179                 GameRules_scoring_add(targ, SCORE, -1);
 180                 GameRules_scoring_add(attacker, SCORE, +1);
 181         }
 182         // else nothing - got frozen by the game type rules themselves
 183 }
 184
 185 // to be called when the player is frozen by freezetag (on death, spectator join etc), gives the score
 186 void freezetag_Freeze(entity targ, entity attacker)
 187 {
 188         if(STAT(FROZEN, targ))
 189                 return;
 190
 191         if(autocvar_g_freezetag_frozen_maxtime > 0)
 192                 targ.freezetag_frozen_timeout = time + autocvar_g_freezetag_frozen_maxtime;
 193
 194         Freeze(targ, 0, 1, true);
 195
 196         freezetag_count_alive_players();
 197
 198         freezetag_Add_Score(targ, attacker);
 199 }
 200
 201 float freezetag_isEliminated(entity e)
 202 {
 203         if(IS_PLAYER(e) && (STAT(FROZEN, e) == 1 || IS_DEAD(e)))
 204                 return true;
 205         return false;
 206 }
 207
 208
 209 // ================
 210 // Bot player logic
 211 // ================
 212
 213 void(entity this) havocbot_role_ft_freeing;
 214 void(entity this) havocbot_role_ft_offense;
 215
 216 void havocbot_goalrating_freeplayers(entity this, float ratingscale, vector org, float sradius)
 217 {
 218         float t;
 219         FOREACH_CLIENT(IS_PLAYER(it) && it != this && SAME_TEAM(it, this), {
 220                 if (STAT(FROZEN, it) == 1)
 221                 {
 222                         if(vdist(it.origin - org, >, sradius))
 223                                 continue;
 224                         navigation_routerating(this, it, ratingscale, 2000);
 225                 }
 226                 else if(vdist(it.origin - org, >, 400)) // avoid gathering all teammates in one place
 227                 {
 228                         // If teamate is not frozen still seek them out as fight better
 229                         // in a group.
 230                         t = 0.2 * 150 / (GetResourceAmount(this, RESOURCE_HEALTH) + GetResourceAmount(this, RESOURCE_ARMOR));
 231                         navigation_routerating(this, it, t * ratingscale, 2000);
 232                 }
 233         });
 234 }
 235
 236 void havocbot_role_ft_offense(entity this)
 237 {
 238         if(IS_DEAD(this))
 239                 return;
 240
 241         if (!this.havocbot_role_timeout)
 242                 this.havocbot_role_timeout = time + random() * 10 + 20;
 243
 244         // Count how many players on team are unfrozen.
 245         int unfrozen = 0;
 246         FOREACH_CLIENT(IS_PLAYER(it) && SAME_TEAM(it, this) && !(STAT(FROZEN, it) != 1), { unfrozen++; });
 247
 248         // If only one left on team or if role has timed out then start trying to free players.
 249         if (((unfrozen == 0) && (!STAT(FROZEN, this))) || (time > this.havocbot_role_timeout))
 250         {
 251                 LOG_TRACE("changing role to freeing");
 252                 this.havocbot_role = havocbot_role_ft_freeing;
 253                 this.havocbot_role_timeout = 0;
 254                 return;
 255         }
 256
 257         if (navigation_goalrating_timeout(this))
 258         {
 259                 navigation_goalrating_start(this);
 260                 havocbot_goalrating_items(this, 10000, this.origin, 10000);
 261                 havocbot_goalrating_enemyplayers(this, 20000, this.origin, 10000);
 262                 havocbot_goalrating_freeplayers(this, 9000, this.origin, 10000);
 263                 havocbot_goalrating_waypoints(this, 1, this.origin, 3000);
 264                 navigation_goalrating_end(this);
 265
 266                 navigation_goalrating_timeout_set(this);
 267         }
 268 }
 269
 270 void havocbot_role_ft_freeing(entity this)
 271 {
 272         if(IS_DEAD(this))
 273                 return;
 274
 275         if (!this.havocbot_role_timeout)
 276                 this.havocbot_role_timeout = time + random() * 10 + 20;
 277
 278         if (time > this.havocbot_role_timeout)
 279         {
 280                 LOG_TRACE("changing role to offense");
 281                 this.havocbot_role = havocbot_role_ft_offense;
 282                 this.havocbot_role_timeout = 0;
 283                 return;
 284         }
 285
 286         if (navigation_goalrating_timeout(this))
 287         {
 288                 navigation_goalrating_start(this);
 289                 havocbot_goalrating_items(this, 8000, this.origin, 10000);
 290                 havocbot_goalrating_enemyplayers(this, 10000, this.origin, 10000);
 291                 havocbot_goalrating_freeplayers(this, 20000, this.origin, 10000);
 292                 havocbot_goalrating_waypoints(this, 1, this.origin, 3000);
 293                 navigation_goalrating_end(this);
 294
 295                 navigation_goalrating_timeout_set(this);
 296         }
 297 }
 298
 299
 300 // ==============
 301 // Hook Functions
 302 // ==============
 303
 304 void ft_RemovePlayer(entity this)
 305 {
 306         SetResourceAmountExplicit(this, RESOURCE_HEALTH, 0); // neccessary to update correctly alive stats
 307         if(!STAT(FROZEN, this))
 308                 freezetag_LastPlayerForTeam_Notify(this);
 309         Unfreeze(this);
 310         freezetag_count_alive_players();
 311 }
 312
 313 MUTATOR_HOOKFUNCTION(ft, ClientDisconnect)
 314 {
 315         entity player = M_ARGV(0, entity);
 316
 317         ft_RemovePlayer(player);
 318         return true;
 319 }
 320
 321 MUTATOR_HOOKFUNCTION(ft, MakePlayerObserver)
 322 {
 323         entity player = M_ARGV(0, entity);
 324
 325         ft_RemovePlayer(player);
 326 }
 327
 328 MUTATOR_HOOKFUNCTION(ft, PlayerDies)
 329 {
 330         entity frag_attacker = M_ARGV(1, entity);
 331         entity frag_target = M_ARGV(2, entity);
 332         float frag_deathtype = M_ARGV(3, float);
 333
 334         if(round_handler_IsActive())
 335         if(round_handler_CountdownRunning())
 336         {
 337                 if(STAT(FROZEN, frag_target))
 338                         Unfreeze(frag_target);
 339                 freezetag_count_alive_players();
 340                 return true; // let the player die so that he can respawn whenever he wants
 341         }
 342
 343         // Cases DEATH_TEAMCHANGE and DEATH_AUTOTEAMCHANGE are needed to fix a bug whe
 344         // you succeed changing team through the menu: you both really die (gibbing) and get frozen
 345         if(ITEM_DAMAGE_NEEDKILL(frag_deathtype)
 346                 || frag_deathtype == DEATH_TEAMCHANGE.m_id || frag_deathtype == DEATH_AUTOTEAMCHANGE.m_id)
 347         {
 348                 // let the player die, he will be automatically frozen when he respawns
 349                 if(STAT(FROZEN, frag_target) != 1)
 350                 {
 351                         freezetag_Add_Score(frag_target, frag_attacker);
 352                         freezetag_count_alive_players();
 353                         freezetag_LastPlayerForTeam_Notify(frag_target);
 354                 }
 355                 else
 356                         Unfreeze(frag_target); // remove ice
 357                 SetResourceAmountExplicit(frag_target, RESOURCE_HEALTH, 0); // Unfreeze resets health
 358                 frag_target.freezetag_frozen_timeout = -2; // freeze on respawn
 359                 return true;
 360         }
 361
 362         if(STAT(FROZEN, frag_target))
 363                 return true;
 364
 365         freezetag_Freeze(frag_target, frag_attacker);
 366         freezetag_LastPlayerForTeam_Notify(frag_target);
 367
 368         if(frag_attacker == frag_target || frag_attacker == NULL)
 369         {
 370                 if(IS_PLAYER(frag_target))
 371                         Send_Notification(NOTIF_ONE, frag_target, MSG_CENTER, CENTER_FREEZETAG_SELF);
 372                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_FREEZETAG_SELF, frag_target.netname);
 373         }
 374         else
 375         {
 376                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_FREEZETAG_FREEZE, frag_target.netname, frag_attacker.netname);
 377         }
 378
 379         return true;
 380 }
 381
 382 MUTATOR_HOOKFUNCTION(ft, PlayerSpawn)
 383 {
 384         entity player = M_ARGV(0, entity);
 385
 386         if(player.freezetag_frozen_timeout == -1) // if PlayerSpawn is called by reset_map_players
 387                 return true; // do nothing, round is starting right now
 388
 389         if(player.freezetag_frozen_timeout == -2) // player was dead
 390         {
 391                 freezetag_Freeze(player, NULL);
 392                 return true;
 393         }
 394
 395         freezetag_count_alive_players();
 396
 397         if(round_handler_IsActive())
 398         if(round_handler_IsRoundStarted())
 399         {
 400                 Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_FREEZETAG_SPAWN_LATE);
 401                 freezetag_Freeze(player, NULL);
 402         }
 403
 404         return true;
 405 }
 406
 407 MUTATOR_HOOKFUNCTION(ft, reset_map_players)
 408 {
 409         FOREACH_CLIENT(IS_PLAYER(it), {
 410                 CS(it).killcount = 0;
 411                 it.freezetag_frozen_timeout = -1;
 412                 PutClientInServer(it);
 413                 it.freezetag_frozen_timeout = 0;
 414         });
 415         freezetag_count_alive_players();
 416         return true;
 417 }
 418
 419 MUTATOR_HOOKFUNCTION(ft, GiveFragsForKill, CBC_ORDER_FIRST)
 420 {
 421         M_ARGV(2, float) = 0; // no frags counted in Freeze Tag
 422         return true;
 423 }
 424
 425 MUTATOR_HOOKFUNCTION(ft, Unfreeze)
 426 {
 427         entity targ = M_ARGV(0, entity);
 428         targ.freezetag_frozen_time = 0;
 429         targ.freezetag_frozen_timeout = 0;
 430
 431         freezetag_count_alive_players();
 432 }
 433
 434 MUTATOR_HOOKFUNCTION(ft, PlayerPreThink, CBC_ORDER_FIRST)
 435 {
 436         if(game_stopped)
 437                 return true;
 438
 439         if(round_handler_IsActive())
 440         if(!round_handler_IsRoundStarted())
 441                 return true;
 442
 443         int n;
 444         entity o = NULL;
 445         entity player = M_ARGV(0, entity);
 446         //if(STAT(FROZEN, player))
 447         //if(player.freezetag_frozen_timeout > 0 && time < player.freezetag_frozen_timeout)
 448                 //player.iceblock.alpha = ICE_MIN_ALPHA + (ICE_MAX_ALPHA - ICE_MIN_ALPHA) * (player.freezetag_frozen_timeout - time) / (player.freezetag_frozen_timeout - player.freezetag_frozen_time);
 449
 450         if(player.freezetag_frozen_timeout > 0 && time >= player.freezetag_frozen_timeout)
 451                 n = -1;
 452         else
 453         {
 454                 vector revive_extra_size = '1 1 1' * autocvar_g_freezetag_revive_extra_size;
 455                 n = 0;
 456                 FOREACH_CLIENT(IS_PLAYER(it) && it != player, {
 457                         if(STAT(FROZEN, it) == 0)
 458                         if(!IS_DEAD(it))
 459                         if(SAME_TEAM(it, player))
 460                         if(boxesoverlap(player.absmin - revive_extra_size, player.absmax + revive_extra_size, it.absmin, it.absmax))
 461                         {
 462                                 if(!o)
 463                                         o = it;
 464                                 if(STAT(FROZEN, player) == 1)
 465                                         it.reviving = true;
 466                                 ++n;
 467                         }
 468                 });
 469
 470         }
 471
 472         if(n && STAT(FROZEN, player) == 1) // OK, there is at least one teammate reviving us
 473         {
 474                 STAT(REVIVE_PROGRESS, player) = bound(0, STAT(REVIVE_PROGRESS, player) + frametime * max(1/60, autocvar_g_freezetag_revive_speed), 1);
 475                 SetResourceAmountExplicit(player, RESOURCE_HEALTH, max(1, STAT(REVIVE_PROGRESS, player) * ((warmup_stage) ? warmup_start_health : start_health)));
 476
 477                 if(STAT(REVIVE_PROGRESS, player) >= 1)
 478                 {
 479                         Unfreeze(player);
 480                         freezetag_count_alive_players();
 481
 482                         if(n == -1)
 483                         {
 484                                 Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_FREEZETAG_AUTO_REVIVED, autocvar_g_freezetag_frozen_maxtime);
 485                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_FREEZETAG_AUTO_REVIVED, player.netname, autocvar_g_freezetag_frozen_maxtime);
 486                                 return true;
 487                         }
 488
 489                         // EVERY team mate nearby gets a point (even if multiple!)
 490                         FOREACH_CLIENT(IS_PLAYER(it) && it.reviving, {
 491                                 GameRules_scoring_add(it, FREEZETAG_REVIVALS, +1);
 492                                 GameRules_scoring_add(it, SCORE, +1);
 493                                 nades_GiveBonus(it,autocvar_g_nades_bonus_score_low);
 494                         });
 495
 496                         Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_FREEZETAG_REVIVED, o.netname);
 497                         Send_Notification(NOTIF_ONE, o, MSG_CENTER, CENTER_FREEZETAG_REVIVE, player.netname);
 498                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_FREEZETAG_REVIVED, player.netname, o.netname);
 499                 }
 500
 501                 FOREACH_CLIENT(IS_PLAYER(it) && it.reviving, {
 502                         STAT(REVIVE_PROGRESS, it) = STAT(REVIVE_PROGRESS, player);
 503                         it.reviving = false;
 504                 });
 505         }
 506         else if(!n && STAT(FROZEN, player) == 1) // only if no teammate is nearby will we reset
 507         {
 508                 STAT(REVIVE_PROGRESS, player) = bound(0, STAT(REVIVE_PROGRESS, player) - frametime * autocvar_g_freezetag_revive_clearspeed, 1);
 509                 SetResourceAmountExplicit(player, RESOURCE_HEALTH, max(1, STAT(REVIVE_PROGRESS, player) * ((warmup_stage) ? warmup_start_health : start_health)));
 510         }
 511         else if(!n && !STAT(FROZEN, player))
 512         {
 513                 STAT(REVIVE_PROGRESS, player) = 0; // thawing nobody
 514         }
 515
 516         return true;
 517 }
 518
 519 MUTATOR_HOOKFUNCTION(ft, SetStartItems)
 520 {
 521         start_items &= ~IT_UNLIMITED_AMMO;
 522         //start_health       = warmup_start_health       = cvar("g_lms_start_health");
 523         //start_armorvalue   = warmup_start_armorvalue   = cvar("g_lms_start_armor");
 524         start_ammo_shells  = warmup_start_ammo_shells  = cvar("g_lms_start_ammo_shells");
 525         start_ammo_nails   = warmup_start_ammo_nails   = cvar("g_lms_start_ammo_nails");
 526         start_ammo_rockets = warmup_start_ammo_rockets = cvar("g_lms_start_ammo_rockets");
 527         start_ammo_cells   = warmup_start_ammo_cells   = cvar("g_lms_start_ammo_cells");
 528         start_ammo_plasma  = warmup_start_ammo_plasma  = cvar("g_lms_start_ammo_plasma");
 529         start_ammo_fuel    = warmup_start_ammo_fuel    = cvar("g_lms_start_ammo_fuel");
 530 }
 531
 532 MUTATOR_HOOKFUNCTION(ft, HavocBot_ChooseRole)
 533 {
 534         entity bot = M_ARGV(0, entity);
 535
 536         if (!IS_DEAD(bot))
 537         {
 538                 if (random() < 0.5)
 539                         bot.havocbot_role = havocbot_role_ft_freeing;
 540                 else
 541                         bot.havocbot_role = havocbot_role_ft_offense;
 542         }
 543
 544         return true;
 545 }
 546
 547 MUTATOR_HOOKFUNCTION(ft, CheckAllowedTeams, CBC_ORDER_EXCLUSIVE)
 548 {
 549         M_ARGV(0, float) = freezetag_teams;
 550 }
 551
 552 MUTATOR_HOOKFUNCTION(ft, SetWeaponArena)
 553 {
 554         // most weapons arena
 555         if(M_ARGV(0, string) == "0" || M_ARGV(0, string) == "")
 556                 M_ARGV(0, string) = "most";
 557 }
 558
 559 MUTATOR_HOOKFUNCTION(ft, FragCenterMessage)
 560 {
 561         entity frag_attacker = M_ARGV(0, entity);
 562         entity frag_target = M_ARGV(1, entity);
 563         //float frag_deathtype = M_ARGV(2, float);
 564         int kill_count_to_attacker = M_ARGV(3, int);
 565         int kill_count_to_target = M_ARGV(4, int);
 566
 567         if(STAT(FROZEN, frag_target))
 568                 return; // target was already frozen, so this is just pushing them off the cliff
 569
 570         Send_Notification(NOTIF_ONE, frag_attacker, MSG_CHOICE, CHOICE_FRAG_FREEZE, frag_target.netname, kill_count_to_attacker, (IS_BOT_CLIENT(frag_target) ? -1 : CS(frag_target).ping));
 571         Send_Notification(NOTIF_ONE, frag_target, MSG_CHOICE, CHOICE_FRAGGED_FREEZE, frag_attacker.netname, kill_count_to_target,
 572                 GetResourceAmount(frag_attacker, RESOURCE_HEALTH), GetResourceAmount(frag_attacker, RESOURCE_ARMOR), (IS_BOT_CLIENT(frag_attacker) ? -1 : CS(frag_attacker).ping));
 573
 574         return true;
 575 }
 576
 577 void freezetag_Initialize()
 578 {
 579         freezetag_teams = autocvar_g_freezetag_teams_override;
 580         if(freezetag_teams < 2)
 581                 freezetag_teams = cvar("g_freezetag_teams"); // read the cvar directly as it gets written earlier in the same frame
 582
 583         freezetag_teams = BITS(bound(2, freezetag_teams, 4));
 584         GameRules_scoring(freezetag_teams, SFL_SORT_PRIO_PRIMARY, SFL_SORT_PRIO_PRIMARY, {
 585                 field(SP_FREEZETAG_REVIVALS, "revivals", 0);
 586         });
 587
 588         round_handler_Spawn(freezetag_CheckTeams, freezetag_CheckWinner, func_null);
 589         round_handler_Init(5, autocvar_g_freezetag_warmup, autocvar_g_freezetag_round_timelimit);
 590
 591         EliminatedPlayers_Init(freezetag_isEliminated);
 592 }
 593 #endif