Merge branch 'master' into Lyberta/TeamplayOverhaul
[xonotic/xonotic-data.pk3dir.git] / qcsrc / common / gamemodes / gamemode / invasion / invasion.qc
1 #include "invasion.qh"
2
3 // TODO: sv_invasion
4 #ifdef SVQC
5 #include <common/monsters/sv_spawn.qh>
6 #include <common/monsters/sv_spawner.qh>
7 #include <common/monsters/sv_monsters.qh>
8
9 #include <server/teamplay.qh>
10
11 IntrusiveList g_invasion_roundends;
12 IntrusiveList g_invasion_waves;
13 IntrusiveList g_invasion_spawns;
14 STATIC_INIT(g_invasion)
15 {
16         g_invasion_roundends = IL_NEW();
17         g_invasion_waves = IL_NEW();
18         g_invasion_spawns = IL_NEW();
19 }
20
21 float autocvar_g_invasion_round_timelimit;
22 float autocvar_g_invasion_spawnpoint_spawn_delay;
23 float autocvar_g_invasion_warmup;
24 int autocvar_g_invasion_monster_count;
25 bool autocvar_g_invasion_zombies_only;
26 float autocvar_g_invasion_spawn_delay;
27
28 bool victent_present;
29 .bool inv_endreached;
30
31 bool inv_warning_shown; // spammy
32
33 void target_invasion_roundend_use(entity this, entity actor, entity trigger)
34 {
35         if(!IS_PLAYER(actor)) { return; }
36
37         actor.inv_endreached = true;
38
39         int plnum = 0;
40         int realplnum = 0;
41         // let's not count bots
42         FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it), {
43                 ++realplnum;
44                 if(it.inv_endreached)
45                         ++plnum;
46         });
47         if(plnum < ceil(realplnum * min(1, this.count))) // 70% of players
48                 return;
49
50         this.winning = true;
51 }
52
53 spawnfunc(target_invasion_roundend)
54 {
55         if(!g_invasion) { delete(this); return; }
56
57         victent_present = true; // a victory entity is present, we don't need to rely on monster count TODO: merge this with the intrusive list (can check empty)
58
59         if(!this.count) { this.count = 0.7; } // require at least 70% of the players to reach the end before triggering victory
60
61         this.use = target_invasion_roundend_use;
62
63         IL_PUSH(g_invasion_roundends, this);
64 }
65
66 spawnfunc(invasion_wave)
67 {
68         if(!g_invasion) { delete(this); return; }
69
70         IL_PUSH(g_invasion_waves, this);
71 }
72
73 spawnfunc(invasion_spawnpoint)
74 {
75         if(!g_invasion) { delete(this); return; }
76
77         this.classname = "invasion_spawnpoint";
78         IL_PUSH(g_invasion_spawns, this);
79 }
80
81 void ClearWinners();
82
83 // Invasion stage mode winning condition: If the attackers triggered a round end (by fulfilling all objectives)
84 // they win.
85 int WinningCondition_Invasion()
86 {
87         WinningConditionHelper(NULL); // set worldstatus
88
89         int status = WINNING_NO;
90
91         if(autocvar_g_invasion_type == INV_TYPE_STAGE)
92         {
93                 SetWinners(inv_endreached, true);
94
95                 int found = 0;
96                 IL_EACH(g_invasion_roundends, true,
97                 {
98                         ++found;
99                         if(it.winning)
100                         {
101                                 bprint("Invasion: round completed.\n");
102                                 // winners already set (TODO: teamplay support)
103
104                                 status = WINNING_YES;
105                                 break;
106                         }
107                 });
108
109                 if(!found)
110                         status = WINNING_YES; // just end it? TODO: should warn mapper!
111         }
112         else if(autocvar_g_invasion_type == INV_TYPE_HUNT)
113         {
114                 ClearWinners();
115
116                 int found = 0; // NOTE: this ends the round if no monsters are placed
117                 IL_EACH(g_monsters, !(it.spawnflags & MONSTERFLAG_RESPAWNED),
118                 {
119                         ++found;
120                 });
121
122                 if(found <= 0)
123                 {
124                         FOREACH_CLIENT(IS_PLAYER(it) && !IS_DEAD(it),
125                         {
126                                 it.winning = true;
127                         });
128                         status = WINNING_YES;
129                 }
130         }
131
132         return status;
133 }
134
135 Monster invasion_PickMonster(int supermonster_count)
136 {
137         RandomSelection_Init();
138
139         FOREACH(Monsters, it != MON_Null,
140         {
141                 if((it.spawnflags & MON_FLAG_HIDDEN) || (it.spawnflags & MONSTER_TYPE_PASSIVE) || (it.spawnflags & MONSTER_TYPE_FLY) || (it.spawnflags & MONSTER_TYPE_SWIM) ||
142                         (it.spawnflags & MONSTER_SIZE_QUAKE) || ((it.spawnflags & MON_FLAG_SUPERMONSTER) && supermonster_count >= 1))
143                         continue;
144                 if(autocvar_g_invasion_zombies_only && !(it.spawnflags & MONSTER_TYPE_UNDEAD))
145                         continue;
146         RandomSelection_AddEnt(it, 1, 1);
147         });
148
149         return RandomSelection_chosen_ent;
150 }
151
152 entity invasion_PickSpawn()
153 {
154         RandomSelection_Init();
155
156         IL_EACH(g_invasion_spawns, true,
157         {
158                 RandomSelection_AddEnt(it, 1, ((time < it.spawnshieldtime) ? 0.2 : 1)); // give recently used spawnpoints a very low rating
159                 it.spawnshieldtime = time + autocvar_g_invasion_spawnpoint_spawn_delay;
160         });
161
162         return RandomSelection_chosen_ent;
163 }
164
165 entity invasion_GetWaveEntity(int wavenum)
166 {
167         IL_EACH(g_invasion_waves, it.cnt == wavenum,
168         {
169                 return it; // found one
170         });
171
172         // if no specific one is found, find the last existing wave ent
173         entity best = NULL;
174         IL_EACH(g_invasion_waves, it.cnt <= wavenum,
175         {
176                 if(!best || it.cnt > best.cnt)
177                         best = it;
178         });
179
180         return best;
181 }
182
183 void invasion_SpawnChosenMonster(Monster mon)
184 {
185         entity monster;
186         entity spawn_point = invasion_PickSpawn();
187         entity wave_ent = invasion_GetWaveEntity(inv_roundcnt);
188
189         string tospawn = "";
190         if(wave_ent && wave_ent.spawnmob && wave_ent.spawnmob != "")
191         {
192                 RandomSelection_Init();
193                 FOREACH_WORD(wave_ent.spawnmob, true,
194                 {
195                         RandomSelection_AddString(it, 1, 1);
196                 });
197
198                 tospawn = RandomSelection_chosen_string;
199         }
200
201         if(spawn_point == NULL)
202         {
203                 if(!inv_warning_shown)
204                 {
205                         inv_warning_shown = true;
206                         LOG_TRACE("Warning: couldn't find any invasion_spawnpoint spawnpoints, attempting to spawn monsters in random locations");
207                 }
208                 entity e = spawn();
209                 setsize(e, mon.m_mins, mon.m_maxs);
210
211                 if(MoveToRandomMapLocation(e, DPCONTENTS_SOLID | DPCONTENTS_CORPSE | DPCONTENTS_PLAYERCLIP, DPCONTENTS_SLIME | DPCONTENTS_LAVA | DPCONTENTS_SKY | DPCONTENTS_BODY | DPCONTENTS_DONOTENTER, Q3SURFACEFLAG_SKY, 10, 1024, 256))
212                         monster = spawnmonster(e, tospawn, mon.monsterid, NULL, NULL, e.origin, false, false, 2);
213                 else
214                 {
215                         delete(e);
216                         return;
217                 }
218         }
219         else // if spawnmob field falls through (unset), fallback to mon (relying on spawnmonster for that behaviour)
220                 monster = spawnmonster(spawn(), ((spawn_point.spawnmob && spawn_point.spawnmob != "") ? spawn_point.spawnmob : tospawn), mon.monsterid, spawn_point, spawn_point, spawn_point.origin, false, false, 2);
221
222         if(!monster)
223                 return;
224
225         monster.spawnshieldtime = time;
226
227         if(spawn_point)
228         {
229                 if(spawn_point.target_range)
230                         monster.target_range = spawn_point.target_range;
231                 monster.target2 = spawn_point.target2;
232         }
233
234         if(teamplay)
235         {
236                 if(spawn_point && spawn_point.team && inv_monsters_perteam[spawn_point.team] > 0)
237                         monster.team = spawn_point.team;
238                 else
239                 {
240                         RandomSelection_Init();
241                         if(inv_monsters_perteam[NUM_TEAM_1] > 0) RandomSelection_AddFloat(NUM_TEAM_1, 1, 1);
242                         if(inv_monsters_perteam[NUM_TEAM_2] > 0) RandomSelection_AddFloat(NUM_TEAM_2, 1, 1);
243                         if(invasion_teams >= 3) if(inv_monsters_perteam[NUM_TEAM_3] > 0) { RandomSelection_AddFloat(NUM_TEAM_3, 1, 1); }
244                         if(invasion_teams >= 4) if(inv_monsters_perteam[NUM_TEAM_4] > 0) { RandomSelection_AddFloat(NUM_TEAM_4, 1, 1); }
245
246                         monster.team = RandomSelection_chosen_float;
247                 }
248
249                 monster_setupcolors(monster);
250
251                 if(monster.sprite)
252                 {
253                         WaypointSprite_UpdateTeamRadar(monster.sprite, RADARICON_DANGER, ((monster.team) ? Team_ColorRGB(monster.team) : '1 0 0'));
254
255                         monster.sprite.team = 0;
256                         monster.sprite.SendFlags |= 1;
257                 }
258         }
259
260         if(monster.monster_attack)
261                 IL_REMOVE(g_monster_targets, monster);
262         monster.monster_attack = false; // it's the player's job to kill all the monsters
263
264         if(inv_roundcnt >= inv_maxrounds)
265                 monster.spawnflags |= MONSTERFLAG_MINIBOSS; // last round spawns minibosses
266 }
267
268 void invasion_SpawnMonsters(int supermonster_count)
269 {
270         Monster chosen_monster = invasion_PickMonster(supermonster_count);
271
272         invasion_SpawnChosenMonster(chosen_monster);
273 }
274
275 bool Invasion_CheckWinner()
276 {
277         if(round_handler_GetEndTime() > 0 && round_handler_GetEndTime() - time <= 0)
278         {
279                 IL_EACH(g_monsters, true,
280                 {
281                         Monster_Remove(it);
282                 });
283                 IL_CLEAR(g_monsters);
284
285                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_ROUND_OVER);
286                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_ROUND_OVER);
287                 round_handler_Init(5, autocvar_g_invasion_warmup, autocvar_g_invasion_round_timelimit);
288                 return 1;
289         }
290
291         float total_alive_monsters = 0, supermonster_count = 0, red_alive = 0, blue_alive = 0, yellow_alive = 0, pink_alive = 0;
292
293         IL_EACH(g_monsters, it.health > 0,
294         {
295                 if((get_monsterinfo(it.monsterid)).spawnflags & MON_FLAG_SUPERMONSTER)
296                         ++supermonster_count;
297                 ++total_alive_monsters;
298
299                 if(teamplay)
300                 switch(it.team)
301                 {
302                         case NUM_TEAM_1: ++red_alive; break;
303                         case NUM_TEAM_2: ++blue_alive; break;
304                         case NUM_TEAM_3: ++yellow_alive; break;
305                         case NUM_TEAM_4: ++pink_alive; break;
306                 }
307         });
308
309         if((total_alive_monsters + inv_numkilled) < inv_maxspawned && inv_maxcurrent < inv_maxspawned)
310         {
311                 if(time >= inv_lastcheck)
312                 {
313                         invasion_SpawnMonsters(supermonster_count);
314                         inv_lastcheck = time + autocvar_g_invasion_spawn_delay;
315                 }
316
317                 return 0;
318         }
319
320         if(inv_numspawned < 1)
321                 return 0; // nothing has spawned yet
322
323         if(teamplay)
324         {
325                 if(((red_alive > 0) + (blue_alive > 0) + (yellow_alive > 0) + (pink_alive > 0)) > 1)
326                         return 0;
327         }
328         else if(inv_numkilled < inv_maxspawned)
329                 return 0;
330
331         entity winner = NULL;
332         float winning_score = 0, winner_team = 0;
333
334
335         if(teamplay)
336         {
337                 if(red_alive > 0) { winner_team = NUM_TEAM_1; }
338                 if(blue_alive > 0)
339                 if(winner_team) { winner_team = 0; }
340                 else { winner_team = NUM_TEAM_2; }
341                 if(yellow_alive > 0)
342                 if(winner_team) { winner_team = 0; }
343                 else { winner_team = NUM_TEAM_3; }
344                 if(pink_alive > 0)
345                 if(winner_team) { winner_team = 0; }
346                 else { winner_team = NUM_TEAM_4; }
347         }
348         else
349         {
350                 FOREACH_CLIENT(IS_PLAYER(it), {
351                         float cs = GameRules_scoring_add(it, KILLS, 0);
352                         if(cs > winning_score)
353                         {
354                                 winning_score = cs;
355                                 winner = it;
356                         }
357                 });
358         }
359
360         IL_EACH(g_monsters, true,
361         {
362                 Monster_Remove(it);
363         });
364         IL_CLEAR(g_monsters);
365
366         if(teamplay)
367         {
368                 if(winner_team)
369                 {
370                         Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, APP_TEAM_NUM(winner_team, CENTER_ROUND_TEAM_WIN));
371                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(winner_team, INFO_ROUND_TEAM_WIN));
372                 }
373         }
374         else if(winner)
375         {
376                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_ROUND_PLAYER_WIN, winner.netname);
377                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_ROUND_PLAYER_WIN, winner.netname);
378         }
379
380         round_handler_Init(5, autocvar_g_invasion_warmup, autocvar_g_invasion_round_timelimit);
381
382         return 1;
383 }
384
385 bool Invasion_CheckPlayers()
386 {
387         return true;
388 }
389
390 void Invasion_RoundStart()
391 {
392         int numplayers = 0;
393         FOREACH_CLIENT(IS_PLAYER(it), {
394                 it.player_blocked = false;
395                 ++numplayers;
396         });
397
398         if(inv_roundcnt < inv_maxrounds)
399                 inv_roundcnt += 1; // a limiter to stop crazy counts
400
401         inv_monsterskill = inv_roundcnt + max(1, numplayers * 0.3);
402
403         inv_maxcurrent = 0;
404         inv_numspawned = 0;
405         inv_numkilled = 0;
406
407         inv_maxspawned = rint(max(autocvar_g_invasion_monster_count, autocvar_g_invasion_monster_count * (inv_roundcnt * 0.5)));
408
409         if(teamplay)
410         {
411                 DistributeEvenly_Init(inv_maxspawned, invasion_teams);
412                 inv_monsters_perteam[NUM_TEAM_1] = DistributeEvenly_Get(1);
413                 inv_monsters_perteam[NUM_TEAM_2] = DistributeEvenly_Get(1);
414                 if(invasion_teams >= 3) inv_monsters_perteam[NUM_TEAM_3] = DistributeEvenly_Get(1);
415                 if(invasion_teams >= 4) inv_monsters_perteam[NUM_TEAM_4] = DistributeEvenly_Get(1);
416         }
417 }
418
419 MUTATOR_HOOKFUNCTION(inv, MonsterDies)
420 {
421         entity frag_target = M_ARGV(0, entity);
422         entity frag_attacker = M_ARGV(1, entity);
423
424         if(!(frag_target.spawnflags & MONSTERFLAG_RESPAWNED))
425         {
426                 if(autocvar_g_invasion_type == INV_TYPE_ROUND)
427                 {
428                         inv_numkilled += 1;
429                         inv_maxcurrent -= 1;
430                 }
431                 if(teamplay) { inv_monsters_perteam[frag_target.team] -= 1; }
432
433                 if(IS_PLAYER(frag_attacker))
434                 if(SAME_TEAM(frag_attacker, frag_target)) // in non-teamplay modes, same team = same player, so this works
435                         GameRules_scoring_add(frag_attacker, KILLS, -1);
436                 else
437                 {
438                         GameRules_scoring_add(frag_attacker, KILLS, +1);
439                         if(teamplay)
440                                 TeamScore_AddToTeam(frag_attacker.team, ST_INV_KILLS, +1);
441                 }
442         }
443 }
444
445 MUTATOR_HOOKFUNCTION(inv, MonsterSpawn)
446 {
447         entity mon = M_ARGV(0, entity);
448         mon.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_BOTCLIP | DPCONTENTS_MONSTERCLIP;
449
450         if(autocvar_g_invasion_type == INV_TYPE_HUNT)
451                 return false; // allowed
452
453         if(!(mon.spawnflags & MONSTERFLAG_SPAWNED))
454                 return true;
455
456         if(!(mon.spawnflags & MONSTERFLAG_RESPAWNED))
457         {
458                 inv_numspawned += 1;
459                 inv_maxcurrent += 1;
460         }
461
462         mon.monster_skill = inv_monsterskill;
463
464         if((get_monsterinfo(mon.monsterid)).spawnflags & MON_FLAG_SUPERMONSTER)
465                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_INVASION_SUPERMONSTER, mon.monster_name);
466 }
467
468 MUTATOR_HOOKFUNCTION(inv, SV_StartFrame)
469 {
470         if(autocvar_g_invasion_type != INV_TYPE_ROUND)
471                 return; // uses map spawned monsters
472
473         monsters_total = inv_maxspawned; // TODO: make sure numspawned never exceeds maxspawned
474         monsters_killed = inv_numkilled;
475 }
476
477 MUTATOR_HOOKFUNCTION(inv, PlayerRegen)
478 {
479         // no regeneration in invasion, regardless of the game type
480         return true;
481 }
482
483 MUTATOR_HOOKFUNCTION(inv, PlayerSpawn)
484 {
485         entity player = M_ARGV(0, entity);
486
487         if(player.bot_attack)
488                 IL_REMOVE(g_bot_targets, player);
489         player.bot_attack = false;
490 }
491
492 MUTATOR_HOOKFUNCTION(inv, Damage_Calculate)
493 {
494         entity frag_attacker = M_ARGV(1, entity);
495         entity frag_target = M_ARGV(2, entity);
496         float frag_damage = M_ARGV(4, float);
497         vector frag_force = M_ARGV(6, vector);
498
499         if(IS_PLAYER(frag_attacker) && IS_PLAYER(frag_target) && frag_attacker != frag_target)
500         {
501                 frag_damage = 0;
502                 frag_force = '0 0 0';
503
504                 M_ARGV(4, float) = frag_damage;
505                 M_ARGV(6, vector) = frag_force;
506         }
507 }
508
509 MUTATOR_HOOKFUNCTION(inv, BotShouldAttack)
510 {
511         entity targ = M_ARGV(1, entity);
512
513         if(!IS_MONSTER(targ))
514                 return true;
515 }
516
517 MUTATOR_HOOKFUNCTION(inv, SetStartItems)
518 {
519         if(autocvar_g_invasion_type == INV_TYPE_ROUND)
520         {
521                 start_health = 200;
522                 start_armorvalue = 200;
523         }
524 }
525
526 MUTATOR_HOOKFUNCTION(inv, AccuracyTargetValid)
527 {
528         entity frag_target = M_ARGV(1, entity);
529
530         if(IS_MONSTER(frag_target))
531                 return MUT_ACCADD_INVALID;
532         return MUT_ACCADD_INDIFFERENT;
533 }
534
535 MUTATOR_HOOKFUNCTION(inv, AllowMobSpawning)
536 {
537         // monster spawning disabled during an invasion
538         M_ARGV(1, string) = "You cannot spawn monsters during an invasion!";
539         return true;
540 }
541
542 MUTATOR_HOOKFUNCTION(inv, CheckRules_World)
543 {
544         if(autocvar_g_invasion_type == INV_TYPE_ROUND)
545                 return false;
546
547         M_ARGV(0, float) = WinningCondition_Invasion();
548         return true;
549 }
550
551 MUTATOR_HOOKFUNCTION(inv, TeamBalance_CheckAllowedTeams, CBC_ORDER_EXCLUSIVE)
552 {
553         M_ARGV(0, float) = invasion_teams;
554         return true;
555 }
556
557 MUTATOR_HOOKFUNCTION(inv, AllowMobButcher)
558 {
559         M_ARGV(0, string) = "This command does not work during an invasion!";
560         return true;
561 }
562
563 void invasion_ScoreRules(int inv_teams)
564 {
565         //if(inv_teams) { CheckAllowedTeams(NULL); } // Another bug?
566         GameRules_score_enabled(false);
567         GameRules_scoring(inv_teams, 0, 0, {
568             if (inv_teams) {
569             field_team(ST_INV_KILLS, "frags", SFL_SORT_PRIO_PRIMARY);
570             }
571             field(SP_KILLS, "frags", ((inv_teams) ? SFL_SORT_PRIO_SECONDARY : SFL_SORT_PRIO_PRIMARY));
572         });
573 }
574
575 void invasion_DelayedInit(entity this) // Do this check with a delay so we can wait for teams to be set up.
576 {
577         if(autocvar_g_invasion_type == INV_TYPE_HUNT || autocvar_g_invasion_type == INV_TYPE_STAGE)
578                 cvar_set("fraglimit", "0");
579
580         if(autocvar_g_invasion_teams)
581         {
582                 invasion_teams = BITS(bound(2, autocvar_g_invasion_teams, 4));
583         }
584         else
585                 invasion_teams = 0;
586
587         independent_players = 1; // to disable extra useless scores
588
589         invasion_ScoreRules(invasion_teams);
590
591         independent_players = 0;
592
593         if(autocvar_g_invasion_type == INV_TYPE_ROUND)
594         {
595                 round_handler_Spawn(Invasion_CheckPlayers, Invasion_CheckWinner, Invasion_RoundStart);
596                 round_handler_Init(5, autocvar_g_invasion_warmup, autocvar_g_invasion_round_timelimit);
597
598                 inv_roundcnt = 0;
599                 inv_maxrounds = 15; // 15?
600         }
601 }
602
603 void invasion_Initialize()
604 {
605         InitializeEntity(NULL, invasion_DelayedInit, INITPRIO_GAMETYPE);
606 }
607 #endif