qcsrc/common/gamemodes/gamemode/keyhunt/sv_keyhunt.qc

   1 #include "sv_keyhunt.qh"
   2
   3 #include <server/command/vote.qh>
   4 #include <server/gamelog.qh>
   5 #include <server/damage.qh>
   6 #include <server/items/items.qh>
   7 #include <common/mapobjects/triggers.qh>
   8
   9 float autocvar_g_balance_keyhunt_damageforcescale;
  10 float autocvar_g_balance_keyhunt_delay_collect;
  11 float autocvar_g_balance_keyhunt_delay_damage_return;
  12 float autocvar_g_balance_keyhunt_delay_return;
  13 float autocvar_g_balance_keyhunt_delay_round;
  14 float autocvar_g_balance_keyhunt_delay_tracking;
  15 float autocvar_g_balance_keyhunt_return_when_unreachable;
  16 float autocvar_g_balance_keyhunt_dropvelocity;
  17 float autocvar_g_balance_keyhunt_maxdist;
  18 float autocvar_g_balance_keyhunt_protecttime;
  19
  20 int autocvar_g_balance_keyhunt_score_capture;
  21 int autocvar_g_balance_keyhunt_score_carrierfrag;
  22 int autocvar_g_balance_keyhunt_score_collect;
  23 int autocvar_g_balance_keyhunt_score_destroyed;
  24 int autocvar_g_balance_keyhunt_score_destroyed_ownfactor;
  25 int autocvar_g_balance_keyhunt_score_push;
  26 float autocvar_g_balance_keyhunt_throwvelocity;
  27
  28 //int autocvar_g_keyhunt_teams;
  29 int autocvar_g_keyhunt_teams_override;
  30
  31 // #define KH_PLAYER_USE_ATTACHMENT
  32 // TODO? no model exists for this
  33 // #define KH_PLAYER_USE_CARRIEDMODEL
  34
  35 #ifdef KH_PLAYER_USE_ATTACHMENT
  36 const vector KH_PLAYER_ATTACHMENT_DIST_ROTATED = '0 -4 0';
  37 const vector KH_PLAYER_ATTACHMENT_DIST = '4 0 0';
  38 const vector KH_PLAYER_ATTACHMENT = '0 0 0';
  39 const vector KH_PLAYER_ATTACHMENT_ANGLES = '0 0 0';
  40 const string KH_PLAYER_ATTACHMENT_BONE = "";
  41 #else
  42 const float KH_KEY_ZSHIFT = 22;
  43 const float KH_KEY_XYDIST = 24;
  44 const float KH_KEY_XYSPEED = 45;
  45 #endif
  46 const float KH_KEY_WP_ZSHIFT = 20;
  47
  48 const vector KH_KEY_MIN = '-10 -10 -46';
  49 const vector KH_KEY_MAX = '10 10 3';
  50 const float KH_KEY_BRIGHTNESS = 2;
  51
  52 bool kh_no_radar_circles;
  53
  54 // kh_state
  55 //     bits  0- 4: team of key 1, or 0 for no such key, or 30 for dropped, or 31 for self
  56 //     bits  5- 9: team of key 2, or 0 for no such key, or 30 for dropped, or 31 for self
  57 //     bits 10-14: team of key 3, or 0 for no such key, or 30 for dropped, or 31 for self
  58 //     bits 15-19: team of key 4, or 0 for no such key, or 30 for dropped, or 31 for self
  59 .float siren_time;  //  time delay the siren
  60 //.float stuff_time;  //  time delay to stuffcmd a cvar
  61
  62 int kh_Team_ByID(int t)
  63 {
  64         if(t == 0) return NUM_TEAM_1;
  65         if(t == 1) return NUM_TEAM_2;
  66         if(t == 2) return NUM_TEAM_3;
  67         if(t == 3) return NUM_TEAM_4;
  68         return 0;
  69 }
  70
  71 entity kh_controller;
  72 //bool kh_tracking_enabled;
  73 int kh_teams;
  74 int kh_interferemsg_team;
  75 float kh_interferemsg_time;
  76 .entity kh_next, kh_prev; // linked list
  77 .float kh_droptime;
  78 .int kh_dropperteam;
  79 .entity kh_previous_owner;
  80 .int kh_previous_owner_playerid;
  81
  82 int kh_key_dropped, kh_key_carried;
  83
  84 int kh_Key_AllOwnedByWhichTeam();
  85
  86 const int ST_KH_CAPS = 1;
  87 void kh_ScoreRules(int teams)
  88 {
  89         GameRules_scoring(teams, SFL_SORT_PRIO_PRIMARY, SFL_SORT_PRIO_PRIMARY, {
  90         field_team(ST_KH_CAPS, "caps", SFL_SORT_PRIO_SECONDARY);
  91         field(SP_KH_CAPS, "caps", SFL_SORT_PRIO_SECONDARY);
  92         field(SP_KH_PUSHES, "pushes", 0);
  93         field(SP_KH_DESTROYS, "destroyed", SFL_LOWER_IS_BETTER);
  94         field(SP_KH_PICKUPS, "pickups", 0);
  95         field(SP_KH_KCKILLS, "kckills", 0);
  96         field(SP_KH_LOSSES, "losses", SFL_LOWER_IS_BETTER);
  97         });
  98 }
  99
 100 bool kh_KeyCarrier_waypointsprite_visible_for_player(entity this, entity player, entity view)  // runs all the time
 101 {
 102         if(!IS_PLAYER(view) || DIFF_TEAM(this, view))
 103                 if(!kh_tracking_enabled)
 104                         return false;
 105
 106         return true;
 107 }
 108
 109 bool kh_Key_waypointsprite_visible_for_player(entity this, entity player, entity view)
 110 {
 111         if(!kh_tracking_enabled)
 112                 return false;
 113         if(!this.owner)
 114                 return true;
 115         if(!this.owner.owner)
 116                 return true;
 117         return false;  // draw only when key is not owned
 118 }
 119
 120 void kh_update_state()
 121 {
 122         entity key;
 123         int f;
 124         int s = 0;
 125         FOR_EACH_KH_KEY(key)
 126         {
 127                 if(key.owner)
 128                         f = key.team;
 129                 else
 130                         f = 30;
 131                 s |= (32 ** key.count) * f;
 132         }
 133
 134         FOREACH_CLIENT(true, { STAT(KH_KEYS, it) = s; });
 135
 136         FOR_EACH_KH_KEY(key)
 137         {
 138                 if(key.owner)
 139                         STAT(KH_KEYS, key.owner) |= (32 ** key.count) * 31;
 140         }
 141         //print(ftos((nextent(NULL)).kh_state), "\n");
 142 }
 143
 144
 145
 146
 147 var kh_Think_t kh_Controller_Thinkfunc;
 148 void kh_Controller_SetThink(float t, kh_Think_t func)  // runs occasionaly
 149 {
 150         kh_Controller_Thinkfunc = func;
 151         kh_controller.cnt = ceil(t);
 152         if(t == 0)
 153                 kh_controller.nextthink = time; // force
 154 }
 155 void kh_WaitForPlayers();
 156 void kh_Controller_Think(entity this)  // called a lot
 157 {
 158         if(game_stopped)
 159                 return;
 160         if(this.cnt > 0)
 161         {
 162                 if(getthink(this) != kh_WaitForPlayers)
 163                         this.cnt -= 1;
 164         }
 165         else if(this.cnt == 0)
 166         {
 167                 this.cnt -= 1;
 168                 kh_Controller_Thinkfunc();
 169         }
 170         this.nextthink = time + 1;
 171 }
 172
 173 // frags f: take from cvar * f
 174 // frags 0: no frags
 175 void kh_Scores_Event(entity player, entity key, string what, float frags_player, float frags_owner)  // update the score when a key is captured
 176 {
 177         string s;
 178         if(game_stopped)
 179                 return;
 180
 181         if(frags_player)
 182                 UpdateFrags(player, frags_player);
 183
 184         if(key && key.owner && frags_owner)
 185                 UpdateFrags(key.owner, frags_owner);
 186
 187         if(!autocvar_sv_eventlog)  //output extra info to the console or text file
 188                 return;
 189
 190         s = strcat(":keyhunt:", what, ":", ftos(player.playerid), ":", ftos(frags_player));
 191
 192         if(key && key.owner)
 193                 s = strcat(s, ":", ftos(key.owner.playerid));
 194         else
 195                 s = strcat(s, ":0");
 196
 197         s = strcat(s, ":", ftos(frags_owner), ":");
 198
 199         if(key)
 200                 s = strcat(s, key.netname);
 201
 202         GameLogEcho(s);
 203 }
 204
 205 vector kh_AttachedOrigin(entity e)  // runs when a team captures the flag, it can run 2 or 3 times.
 206 {
 207         if(e.tag_entity)
 208         {
 209                 makevectors(e.tag_entity.angles);
 210                 return e.tag_entity.origin + e.origin.x * v_forward - e.origin.y * v_right + e.origin.z * v_up;
 211         }
 212         else
 213                 return e.origin;
 214 }
 215
 216 void kh_Key_Attach(entity key)  // runs when a player picks up a key and several times when a key is assigned to a player at the start of a round
 217 {
 218 #ifdef KH_PLAYER_USE_ATTACHMENT
 219         entity first = key.owner.kh_next;
 220         if(key == first)
 221         {
 222                 setattachment(key, key.owner, KH_PLAYER_ATTACHMENT_BONE);
 223                 if(key.kh_next)
 224                 {
 225                         setattachment(key.kh_next, key, "");
 226                         setorigin(key, key.kh_next.origin - 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 227                         setorigin(key.kh_next, KH_PLAYER_ATTACHMENT_DIST_ROTATED);
 228                         key.kh_next.angles = '0 0 0';
 229                 }
 230                 else
 231                         setorigin(key, KH_PLAYER_ATTACHMENT);
 232                 key.angles = KH_PLAYER_ATTACHMENT_ANGLES;
 233         }
 234         else
 235         {
 236                 setattachment(key, key.kh_prev, "");
 237                 if(key.kh_next)
 238                         setattachment(key.kh_next, key, "");
 239                 setorigin(key, KH_PLAYER_ATTACHMENT_DIST_ROTATED);
 240                 setorigin(first, first.origin - 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 241                 key.angles = '0 0 0';
 242         }
 243 #else
 244         setattachment(key, key.owner, "");
 245         setorigin(key, '0 0 1' * KH_KEY_ZSHIFT);  // fixing x, y in think
 246         key.angles_y -= key.owner.angles.y;
 247 #endif
 248         key.flags = 0;
 249         if(IL_CONTAINS(g_items, key))
 250                 IL_REMOVE(g_items, key);
 251         key.solid = SOLID_NOT;
 252         set_movetype(key, MOVETYPE_NONE);
 253         key.team = key.owner.team;
 254         key.nextthink = time;
 255         key.damageforcescale = 0;
 256         key.takedamage = DAMAGE_NO;
 257         key.modelindex = kh_key_carried;
 258         navigation_dynamicgoal_unset(key);
 259 }
 260
 261 void kh_Key_Detach(entity key) // runs every time a key is dropped or lost. Runs several times times when all the keys are captured
 262 {
 263 #ifdef KH_PLAYER_USE_ATTACHMENT
 264         entity first = key.owner.kh_next;
 265         if(key == first)
 266         {
 267                 if(key.kh_next)
 268                 {
 269                         setattachment(key.kh_next, key.owner, KH_PLAYER_ATTACHMENT_BONE);
 270                         setorigin(key.kh_next, key.origin + 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 271                         key.kh_next.angles = KH_PLAYER_ATTACHMENT_ANGLES;
 272                 }
 273         }
 274         else
 275         {
 276                 if(key.kh_next)
 277                         setattachment(key.kh_next, key.kh_prev, "");
 278                 setorigin(first, first.origin + 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 279         }
 280         // in any case:
 281         setattachment(key, NULL, "");
 282         setorigin(key, key.owner.origin + '0 0 1' * (STAT(PL_MIN, key.owner).z - KH_KEY_MIN_z));
 283         key.angles = key.owner.angles;
 284 #else
 285         setorigin(key, key.owner.origin + key.origin.z * '0 0 1');
 286         setattachment(key, NULL, "");
 287         key.angles_y += key.owner.angles.y;
 288 #endif
 289         key.flags = FL_ITEM;
 290         if(!IL_CONTAINS(g_items, key))
 291                 IL_PUSH(g_items, key);
 292         key.solid = SOLID_TRIGGER;
 293         set_movetype(key, MOVETYPE_TOSS);
 294         key.pain_finished = time + autocvar_g_balance_keyhunt_delay_return;
 295         key.damageforcescale = autocvar_g_balance_keyhunt_damageforcescale;
 296         key.takedamage = DAMAGE_YES;
 297         // let key.team stay
 298         key.modelindex = kh_key_dropped;
 299         navigation_dynamicgoal_set(key, key.owner);
 300         key.kh_previous_owner = key.owner;
 301         key.kh_previous_owner_playerid = key.owner.playerid;
 302 }
 303
 304 void kh_Key_AssignTo(entity key, entity player)  // runs every time a key is picked up or assigned. Runs prior to kh_key_attach
 305 {
 306         if(key.owner == player)
 307                 return;
 308
 309         int ownerteam0 = kh_Key_AllOwnedByWhichTeam();
 310
 311         if(key.owner)
 312         {
 313                 kh_Key_Detach(key);
 314
 315                 // remove from linked list
 316                 if(key.kh_next)
 317                         key.kh_next.kh_prev = key.kh_prev;
 318                 key.kh_prev.kh_next = key.kh_next;
 319                 key.kh_next = NULL;
 320                 key.kh_prev = NULL;
 321
 322                 if(key.owner.kh_next == NULL)
 323                 {
 324                         // No longer a key carrier
 325                         if(!kh_no_radar_circles)
 326                                 WaypointSprite_Ping(key.owner.waypointsprite_attachedforcarrier);
 327                         WaypointSprite_DetachCarrier(key.owner);
 328                 }
 329         }
 330
 331         key.owner = player;
 332
 333         if(player)
 334         {
 335                 // insert into linked list
 336                 key.kh_next = player.kh_next;
 337                 key.kh_prev = player;
 338                 player.kh_next = key;
 339                 if(key.kh_next)
 340                         key.kh_next.kh_prev = key;
 341
 342                 kh_Key_Attach(key);
 343
 344                 if(key.kh_next == NULL)
 345                 {
 346                         // player is now a key carrier
 347                         entity wp = WaypointSprite_AttachCarrier(WP_Null, player, RADARICON_FLAGCARRIER);
 348                         wp.colormod = colormapPaletteColor(player.team - 1, 0);
 349                         player.waypointsprite_attachedforcarrier.waypointsprite_visible_for_player = kh_KeyCarrier_waypointsprite_visible_for_player;
 350                         WaypointSprite_UpdateRule(player.waypointsprite_attachedforcarrier, player.team, SPRITERULE_TEAMPLAY);
 351                         if(player.team == NUM_TEAM_1)
 352                                 WaypointSprite_UpdateSprites(player.waypointsprite_attachedforcarrier, WP_KeyCarrierRed, WP_KeyCarrierFriend, WP_KeyCarrierRed);
 353                         else if(player.team == NUM_TEAM_2)
 354                                 WaypointSprite_UpdateSprites(player.waypointsprite_attachedforcarrier, WP_KeyCarrierBlue, WP_KeyCarrierFriend, WP_KeyCarrierBlue);
 355                         else if(player.team == NUM_TEAM_3)
 356                                 WaypointSprite_UpdateSprites(player.waypointsprite_attachedforcarrier, WP_KeyCarrierYellow, WP_KeyCarrierFriend, WP_KeyCarrierYellow);
 357                         else if(player.team == NUM_TEAM_4)
 358                                 WaypointSprite_UpdateSprites(player.waypointsprite_attachedforcarrier, WP_KeyCarrierPink, WP_KeyCarrierFriend, WP_KeyCarrierPink);
 359                         if(!kh_no_radar_circles)
 360                                 WaypointSprite_Ping(player.waypointsprite_attachedforcarrier);
 361                 }
 362         }
 363
 364         // moved that here, also update if there's no player
 365         kh_update_state();
 366
 367         key.pusher = NULL;
 368
 369         int ownerteam = kh_Key_AllOwnedByWhichTeam();
 370         if(ownerteam != ownerteam0)
 371         {
 372                 entity k;
 373                 if(ownerteam != -1)
 374                 {
 375                         kh_interferemsg_time = time + 0.2;
 376                         kh_interferemsg_team = player.team;
 377
 378                         // audit all key carrier sprites, update them to "Run here"
 379                         FOR_EACH_KH_KEY(k)
 380                         {
 381                                 if (!k.owner) continue;
 382                                 entity first = WP_Null;
 383                                 FOREACH(Waypoints, it.netname == k.owner.waypointsprite_attachedforcarrier.model1, { first = it; break; });
 384                                 entity third = WP_Null;
 385                                 FOREACH(Waypoints, it.netname == k.owner.waypointsprite_attachedforcarrier.model3, { third = it; break; });
 386                                 WaypointSprite_UpdateSprites(k.owner.waypointsprite_attachedforcarrier, first, WP_KeyCarrierFinish, third);
 387                         }
 388                 }
 389                 else
 390                 {
 391                         kh_interferemsg_time = 0;
 392
 393                         // audit all key carrier sprites, update them to "Key Carrier"
 394                         FOR_EACH_KH_KEY(k)
 395                         {
 396                                 if (!k.owner) continue;
 397                                 entity first = WP_Null;
 398                                 FOREACH(Waypoints, it.netname == k.owner.waypointsprite_attachedforcarrier.model1, { first = it; break; });
 399                                 entity third = WP_Null;
 400                                 FOREACH(Waypoints, it.netname == k.owner.waypointsprite_attachedforcarrier.model3, { third = it; break; });
 401                                 WaypointSprite_UpdateSprites(k.owner.waypointsprite_attachedforcarrier, first, WP_KeyCarrierFriend, third);
 402                         }
 403                 }
 404         }
 405 }
 406
 407 void kh_Key_Damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, .entity weaponentity, vector hitloc, vector force)
 408 {
 409         if(this.owner)
 410                 return;
 411         if(ITEM_DAMAGE_NEEDKILL(deathtype))
 412         {
 413                 this.pain_finished = bound(time, time + autocvar_g_balance_keyhunt_delay_damage_return, this.pain_finished);
 414                 return;
 415         }
 416         if(force == '0 0 0')
 417                 return;
 418         if(time > this.pushltime)
 419                 if(IS_PLAYER(attacker))
 420                         this.team = attacker.team;
 421 }
 422
 423 void kh_Key_Collect(entity key, entity player)  //a player picks up a dropped key
 424 {
 425         sound(player, CH_TRIGGER, SND_KH_COLLECT, VOL_BASE, ATTEN_NORM);
 426
 427         if(key.kh_dropperteam != player.team)
 428         {
 429                 kh_Scores_Event(player, key, "collect", autocvar_g_balance_keyhunt_score_collect, 0);
 430                 GameRules_scoring_add(player, KH_PICKUPS, 1);
 431         }
 432         key.kh_dropperteam = 0;
 433         int realteam = kh_Team_ByID(key.count);
 434         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(realteam, INFO_KEYHUNT_PICKUP), player.netname);
 435
 436         kh_Key_AssignTo(key, player); // this also updates .kh_state
 437 }
 438
 439 void kh_Key_Touch(entity this, entity toucher)  // runs many, many times when a key has been dropped and can be picked up
 440 {
 441         if(game_stopped)
 442                 return;
 443
 444         if(this.owner) // already carried
 445                 return;
 446
 447         if(ITEM_TOUCH_NEEDKILL())
 448         {
 449                 this.pain_finished = bound(time, time + autocvar_g_balance_keyhunt_delay_damage_return, this.pain_finished);
 450                 return;
 451         }
 452
 453         if (!IS_PLAYER(toucher))
 454                 return;
 455         if(IS_DEAD(toucher))
 456                 return;
 457         if(toucher == this.enemy)
 458                 if(time < this.kh_droptime + autocvar_g_balance_keyhunt_delay_collect)
 459                         return;  // you just dropped it!
 460         kh_Key_Collect(this, toucher);
 461 }
 462
 463 void kh_Key_Remove(entity key)  // runs after when all the keys have been collected or when a key has been dropped for more than X seconds
 464 {
 465         entity o = key.owner;
 466         kh_Key_AssignTo(key, NULL);
 467         if(o) // it was attached
 468                 WaypointSprite_Kill(key.waypointsprite_attachedforcarrier);
 469         else // it was dropped
 470                 WaypointSprite_DetachCarrier(key);
 471
 472         // remove key from key list
 473         if (kh_worldkeylist == key)
 474                 kh_worldkeylist = kh_worldkeylist.kh_worldkeynext;
 475         else
 476         {
 477                 o = kh_worldkeylist;
 478                 while (o)
 479                 {
 480                         if (o.kh_worldkeynext == key)
 481                         {
 482                                 o.kh_worldkeynext = o.kh_worldkeynext.kh_worldkeynext;
 483                                 break;
 484                         }
 485                         o = o.kh_worldkeynext;
 486                 }
 487         }
 488
 489         delete(key);
 490
 491         kh_update_state();
 492 }
 493
 494 void kh_FinishRound()  // runs when a team captures the keys
 495 {
 496         // prepare next round
 497         kh_interferemsg_time = 0;
 498         entity key;
 499
 500         kh_no_radar_circles = true;
 501         FOR_EACH_KH_KEY(key)
 502                 kh_Key_Remove(key);
 503         kh_no_radar_circles = false;
 504
 505         Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_KEYHUNT_ROUNDSTART, autocvar_g_balance_keyhunt_delay_round);
 506         kh_Controller_SetThink(autocvar_g_balance_keyhunt_delay_round, kh_StartRound);
 507 }
 508
 509 void nades_GiveBonus(entity player, float score);
 510
 511 void kh_WinnerTeam(int winner_team)  // runs when a team wins
 512 {
 513         // all key carriers get some points
 514         entity key;
 515         float score = (NumTeams(kh_teams) - 1) * autocvar_g_balance_keyhunt_score_capture;
 516         DistributeEvenly_Init(score, NumTeams(kh_teams));
 517         // twice the score for 3 team games, three times the score for 4 team games!
 518         // note: for a win by destroying the key, this should NOT be applied
 519         FOR_EACH_KH_KEY(key)
 520         {
 521                 float f = DistributeEvenly_Get(1);
 522                 kh_Scores_Event(key.owner, key, "capture", f, 0);
 523                 GameRules_scoring_add_team(key.owner, KH_CAPS, 1);
 524                 nades_GiveBonus(key.owner, autocvar_g_nades_bonus_score_high);
 525         }
 526
 527         bool first = true;
 528         string keyowner = "";
 529         FOR_EACH_KH_KEY(key)
 530                 if(key.owner.kh_next == key)
 531                 {
 532                         if(!first)
 533                                 keyowner = strcat(keyowner, ", ");
 534                         keyowner = key.owner.netname;
 535                         first = false;
 536                 }
 537
 538         Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, APP_TEAM_NUM(winner_team, CENTER_ROUND_TEAM_WIN));
 539         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(winner_team, INFO_KEYHUNT_CAPTURE), keyowner);
 540
 541         first = true;
 542         vector firstorigin = '0 0 0', lastorigin = '0 0 0', midpoint = '0 0 0';
 543         FOR_EACH_KH_KEY(key)
 544         {
 545                 vector thisorigin = kh_AttachedOrigin(key);
 546                 //dprint("Key origin: ", vtos(thisorigin), "\n");
 547                 midpoint += thisorigin;
 548
 549                 if(!first)
 550                 {
 551                         // TODO: this effect has been replaced due to a possible crash it causes
 552                         // see https://gitlab.com/xonotic/darkplaces/issues/123
 553                         //te_lightning2(NULL, lastorigin, thisorigin);
 554                         Send_Effect(EFFECT_TR_NEXUIZPLASMA, lastorigin, thisorigin, 1);
 555                 }
 556                 lastorigin = thisorigin;
 557                 if(first)
 558                         firstorigin = thisorigin;
 559                 first = false;
 560         }
 561         if(NumTeams(kh_teams) > 2)
 562         {
 563                 //te_lightning2(NULL, lastorigin, firstorigin); // TODO see above
 564                 Send_Effect(EFFECT_TR_NEXUIZPLASMA, lastorigin, firstorigin, 1);
 565         }
 566         midpoint = midpoint * (1 / NumTeams(kh_teams));
 567         te_customflash(midpoint, 1000, 1, Team_ColorRGB(winner_team) * 0.5 + '0.5 0.5 0.5');  // make the color >=0.5 in each component
 568
 569         play2all(SND(KH_CAPTURE));
 570         kh_FinishRound();
 571 }
 572
 573 void kh_LoserTeam(int loser_team, entity lostkey)  // runs when a player pushes a flag carrier off the map
 574 {
 575         float f;
 576         entity attacker = NULL;
 577         if(lostkey.pusher)
 578                 if(lostkey.pusher.team != loser_team)
 579                         if(IS_PLAYER(lostkey.pusher))
 580                                 attacker = lostkey.pusher;
 581
 582         if(attacker)
 583         {
 584                 if(lostkey.kh_previous_owner)
 585                         kh_Scores_Event(lostkey.kh_previous_owner, NULL, "pushed", 0, -autocvar_g_balance_keyhunt_score_push);
 586                         // don't actually GIVE him the -nn points, just log
 587                 kh_Scores_Event(attacker, NULL, "push", autocvar_g_balance_keyhunt_score_push, 0);
 588                 GameRules_scoring_add(attacker, KH_PUSHES, 1);
 589                 //centerprint(attacker, "Your push is the best!"); // does this really need to exist?
 590         }
 591         else
 592         {
 593                 int players = 0;
 594                 float of = autocvar_g_balance_keyhunt_score_destroyed_ownfactor;
 595
 596                 FOREACH_CLIENT(IS_PLAYER(it) && it.team != loser_team, { ++players; });
 597
 598                 entity key;
 599                 int keys = 0;
 600                 FOR_EACH_KH_KEY(key)
 601                         if(key.owner && key.team != loser_team)
 602                                 ++keys;
 603
 604                 if(lostkey.kh_previous_owner)
 605                         kh_Scores_Event(lostkey.kh_previous_owner, NULL, "destroyed", 0, -autocvar_g_balance_keyhunt_score_destroyed);
 606                         // don't actually GIVE him the -nn points, just log
 607
 608                 if(lostkey.kh_previous_owner.playerid == lostkey.kh_previous_owner_playerid)
 609                         GameRules_scoring_add(lostkey.kh_previous_owner, KH_DESTROYS, 1);
 610
 611                 DistributeEvenly_Init(autocvar_g_balance_keyhunt_score_destroyed, keys * of + players);
 612
 613                 FOR_EACH_KH_KEY(key)
 614                         if(key.owner && key.team != loser_team)
 615                         {
 616                                 f = DistributeEvenly_Get(of);
 617                                 kh_Scores_Event(key.owner, NULL, "destroyed_holdingkey", f, 0);
 618                         }
 619
 620                 int fragsleft = DistributeEvenly_Get(players);
 621
 622                 // Now distribute these among all other teams...
 623                 int j = NumTeams(kh_teams) - 1;
 624                 for(int i = 0; i < NumTeams(kh_teams); ++i)
 625                 {
 626                         int thisteam = kh_Team_ByID(i);
 627                         if(thisteam == loser_team) // bad boy, no cookie - this WILL happen
 628                                 continue;
 629
 630                         players = 0;
 631                         FOREACH_CLIENT(IS_PLAYER(it) && it.team == thisteam, { ++players; });
 632
 633                         DistributeEvenly_Init(fragsleft, j);
 634                         fragsleft = DistributeEvenly_Get(j - 1);
 635                         DistributeEvenly_Init(DistributeEvenly_Get(1), players);
 636
 637                         FOREACH_CLIENT(IS_PLAYER(it) && it.team == thisteam, {
 638                                 f = DistributeEvenly_Get(1);
 639                                 kh_Scores_Event(it, NULL, "destroyed", f, 0);
 640                         });
 641
 642                         --j;
 643                 }
 644         }
 645
 646         int realteam = kh_Team_ByID(lostkey.count);
 647         Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, APP_TEAM_NUM(loser_team, CENTER_ROUND_TEAM_LOSS));
 648         if(attacker)
 649                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(realteam, INFO_KEYHUNT_PUSHED), attacker.netname, lostkey.kh_previous_owner.netname);
 650         else
 651                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(realteam, INFO_KEYHUNT_DESTROYED), lostkey.kh_previous_owner.netname);
 652
 653         play2all(SND(KH_DESTROY));
 654         te_tarexplosion(lostkey.origin);
 655
 656         kh_FinishRound();
 657 }
 658
 659 void kh_Key_Think(entity this)  // runs all the time
 660 {
 661         if(game_stopped)
 662                 return;
 663
 664         if(this.owner)
 665         {
 666 #ifndef KH_PLAYER_USE_ATTACHMENT
 667                 makevectors('0 1 0' * (this.cnt + (time % 360) * KH_KEY_XYSPEED));
 668                 setorigin(this, v_forward * KH_KEY_XYDIST + '0 0 1' * this.origin.z);
 669 #endif
 670         }
 671
 672         // if in nodrop or time over, end the round
 673         if(!this.owner)
 674                 if(time > this.pain_finished)
 675                         kh_LoserTeam(this.team, this);
 676
 677         if(this.owner)
 678         if(kh_Key_AllOwnedByWhichTeam() != -1)
 679         {
 680                 if(this.siren_time < time)
 681                 {
 682                         sound(this.owner, CH_TRIGGER, SND_KH_ALARM, VOL_BASE, ATTEN_NORM);  // play a simple alarm
 683                         this.siren_time = time + 2.5;  // repeat every 2.5 seconds
 684                 }
 685
 686                 entity key;
 687                 vector p = this.owner.origin;
 688                 FOR_EACH_KH_KEY(key)
 689                         if(vdist(key.owner.origin - p, >, autocvar_g_balance_keyhunt_maxdist))
 690                                 goto not_winning;
 691                 kh_WinnerTeam(this.team);
 692 LABEL(not_winning)
 693         }
 694
 695         if(kh_interferemsg_time && time > kh_interferemsg_time)
 696         {
 697                 kh_interferemsg_time = 0;
 698                 FOREACH_CLIENT(IS_PLAYER(it), {
 699                         if(it.team == kh_interferemsg_team)
 700                         {
 701                                 if(it.kh_next)
 702                                         Send_Notification(NOTIF_ONE, it, MSG_CENTER, CENTER_KEYHUNT_MEET);
 703                                 else
 704                                         Send_Notification(NOTIF_ONE, it, MSG_CENTER, CENTER_KEYHUNT_HELP);
 705                         }
 706                         else
 707                                 Send_Notification(NOTIF_ONE, it, MSG_CENTER, APP_TEAM_NUM(kh_interferemsg_team, CENTER_KEYHUNT_INTERFERE));
 708                 });
 709         }
 710
 711         this.nextthink = time + 0.05;
 712 }
 713
 714 void key_reset(entity this)
 715 {
 716         kh_Key_AssignTo(this, NULL);
 717         kh_Key_Remove(this);
 718 }
 719
 720 const string STR_ITEM_KH_KEY = "item_kh_key";
 721 void kh_Key_Spawn(entity initial_owner, float _angle, float i)  // runs every time a new flag is created, ie after all the keys have been collected
 722 {
 723         entity key = spawn();
 724         key.count = i;
 725         key.classname = STR_ITEM_KH_KEY;
 726         settouch(key, kh_Key_Touch);
 727         setthink(key, kh_Key_Think);
 728         key.nextthink = time;
 729         key.items = IT_KEY1 | IT_KEY2;
 730         key.cnt = _angle;
 731         key.angles = '0 360 0' * random();
 732         key.event_damage = kh_Key_Damage;
 733         key.takedamage = DAMAGE_YES;
 734         key.damagedbytriggers = autocvar_g_balance_keyhunt_return_when_unreachable;
 735         key.damagedbycontents = autocvar_g_balance_keyhunt_return_when_unreachable;
 736         key.modelindex = kh_key_dropped;
 737         key.model = "key";
 738         key.kh_dropperteam = 0;
 739         key.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP | DPCONTENTS_BOTCLIP;
 740         setsize(key, KH_KEY_MIN, KH_KEY_MAX);
 741         key.colormod = Team_ColorRGB(initial_owner.team) * KH_KEY_BRIGHTNESS;
 742         key.reset = key_reset;
 743         navigation_dynamicgoal_init(key, false);
 744
 745         switch(initial_owner.team)
 746         {
 747                 case NUM_TEAM_1:
 748                         key.netname = "^1red key";
 749                         break;
 750                 case NUM_TEAM_2:
 751                         key.netname = "^4blue key";
 752                         break;
 753                 case NUM_TEAM_3:
 754                         key.netname = "^3yellow key";
 755                         break;
 756                 case NUM_TEAM_4:
 757                         key.netname = "^6pink key";
 758                         break;
 759                 default:
 760                         key.netname = "NETGIER key";
 761                         break;
 762         }
 763
 764         // link into key list
 765         key.kh_worldkeynext = kh_worldkeylist;
 766         kh_worldkeylist = key;
 767
 768         Send_Notification(NOTIF_ONE, initial_owner, MSG_CENTER, APP_TEAM_NUM(initial_owner.team, CENTER_KEYHUNT_START));
 769
 770         WaypointSprite_Spawn(WP_KeyDropped, 0, 0, key, '0 0 1' * KH_KEY_WP_ZSHIFT, NULL, key.team, key, waypointsprite_attachedforcarrier, false, RADARICON_FLAG);
 771         key.waypointsprite_attachedforcarrier.waypointsprite_visible_for_player = kh_Key_waypointsprite_visible_for_player;
 772
 773         kh_Key_AssignTo(key, initial_owner);
 774 }
 775
 776 // -1 when no team completely owns all keys yet
 777 int kh_Key_AllOwnedByWhichTeam()  // constantly called. check to see if all the keys are owned by the same team
 778 {
 779         entity key;
 780         int teem = -1;
 781         int keys = NumTeams(kh_teams);
 782         FOR_EACH_KH_KEY(key)
 783         {
 784                 if(!key.owner)
 785                         return -1;
 786                 if(teem == -1)
 787                         teem = key.team;
 788                 else if(teem != key.team)
 789                         return -1;
 790                 --keys;
 791         }
 792         if(keys != 0)
 793                 return -1;
 794         return teem;
 795 }
 796
 797 void kh_Key_DropOne(entity key)
 798 {
 799         // prevent collecting this one for some time
 800         entity player = key.owner;
 801
 802         key.kh_droptime = time;
 803         key.enemy = player;
 804
 805         kh_Scores_Event(player, key, "dropkey", 0, 0);
 806         GameRules_scoring_add(player, KH_LOSSES, 1);
 807         int realteam = kh_Team_ByID(key.count);
 808         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(realteam, INFO_KEYHUNT_DROP), player.netname);
 809
 810         kh_Key_AssignTo(key, NULL);
 811         makevectors(player.v_angle);
 812         key.velocity = W_CalculateProjectileVelocity(player, player.velocity, autocvar_g_balance_keyhunt_throwvelocity * v_forward, false);
 813         key.pusher = NULL;
 814         key.pushltime = time + autocvar_g_balance_keyhunt_protecttime;
 815         key.kh_dropperteam = key.team;
 816
 817         sound(player, CH_TRIGGER, SND_KH_DROP, VOL_BASE, ATTEN_NORM);
 818 }
 819
 820 void kh_Key_DropAll(entity player, float suicide) // runs whenever a player dies
 821 {
 822         if(player.kh_next)
 823         {
 824                 entity mypusher = NULL;
 825                 if(player.pusher)
 826                         if(time < player.pushltime)
 827                                 mypusher = player.pusher;
 828
 829                 entity key;
 830                 while((key = player.kh_next))
 831                 {
 832                         kh_Scores_Event(player, key, "losekey", 0, 0);
 833                         GameRules_scoring_add(player, KH_LOSSES, 1);
 834                         int realteam = kh_Team_ByID(key.count);
 835                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(realteam, INFO_KEYHUNT_LOST), player.netname);
 836                         kh_Key_AssignTo(key, NULL);
 837                         makevectors('-1 0 0' * (45 + 45 * random()) + '0 360 0' * random());
 838                         key.velocity = W_CalculateProjectileVelocity(player, player.velocity, autocvar_g_balance_keyhunt_dropvelocity * v_forward, false);
 839                         key.pusher = mypusher;
 840                         key.pushltime = time + autocvar_g_balance_keyhunt_protecttime;
 841                         if(suicide)
 842                                 key.kh_dropperteam = player.team;
 843                 }
 844                 sound(player, CH_TRIGGER, SND_KH_DROP, VOL_BASE, ATTEN_NORM);
 845         }
 846 }
 847
 848 int kh_GetMissingTeams()
 849 {
 850         int missing_teams = 0;
 851         for(int i = 0; i < NumTeams(kh_teams); ++i)
 852         {
 853                 int teem = kh_Team_ByID(i);
 854                 int players = 0;
 855                 FOREACH_CLIENT(IS_PLAYER(it), {
 856                         if(!IS_DEAD(it) && !PHYS_INPUT_BUTTON_CHAT(it) && it.team == teem)
 857                                 ++players;
 858                 });
 859                 if (!players)
 860                         missing_teams |= (2 ** i);
 861         }
 862         return missing_teams;
 863 }
 864
 865 void kh_WaitForPlayers()  // delay start of the round until enough players are present
 866 {
 867         static int prev_missing_teams_mask;
 868         if(time < game_starttime)
 869         {
 870                 if (prev_missing_teams_mask > 0)
 871                         Kill_Notification(NOTIF_ALL, NULL, MSG_CENTER, CPID_MISSING_TEAMS);
 872                 prev_missing_teams_mask = -1;
 873                 kh_Controller_SetThink(game_starttime - time + 0.1, kh_WaitForPlayers);
 874                 return;
 875         }
 876
 877         int missing_teams_mask = kh_GetMissingTeams();
 878         if(!missing_teams_mask)
 879         {
 880                 if(prev_missing_teams_mask > 0)
 881                         Kill_Notification(NOTIF_ALL, NULL, MSG_CENTER, CPID_MISSING_TEAMS);
 882                 prev_missing_teams_mask = -1;
 883                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_KEYHUNT_ROUNDSTART, autocvar_g_balance_keyhunt_delay_round);
 884                 kh_Controller_SetThink(autocvar_g_balance_keyhunt_delay_round, kh_StartRound);
 885         }
 886         else
 887         {
 888                 if(player_count == 0)
 889                 {
 890                         if(prev_missing_teams_mask > 0)
 891                                 Kill_Notification(NOTIF_ALL, NULL, MSG_CENTER, CPID_MISSING_TEAMS);
 892                         prev_missing_teams_mask = -1;
 893                 }
 894                 else
 895                 {
 896                         if(prev_missing_teams_mask != missing_teams_mask)
 897                         {
 898                                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_MISSING_TEAMS, missing_teams_mask);
 899                                 prev_missing_teams_mask = missing_teams_mask;
 900                         }
 901                 }
 902                 kh_Controller_SetThink(1, kh_WaitForPlayers);
 903         }
 904 }
 905
 906 void kh_EnableTrackingDevice()  // runs after each round
 907 {
 908         Kill_Notification(NOTIF_ALL, NULL, MSG_CENTER, CPID_KEYHUNT);
 909         Kill_Notification(NOTIF_ALL, NULL, MSG_CENTER, CPID_KEYHUNT_OTHER);
 910
 911         kh_tracking_enabled = true;
 912 }
 913
 914 void kh_StartRound()  // runs at the start of each round
 915 {
 916         if(time < game_starttime)
 917         {
 918                 kh_Controller_SetThink(game_starttime - time + 0.1, kh_WaitForPlayers);
 919                 return;
 920         }
 921
 922         if(kh_GetMissingTeams())
 923         {
 924                 kh_Controller_SetThink(1, kh_WaitForPlayers);
 925                 return;
 926         }
 927
 928         Kill_Notification(NOTIF_ALL, NULL, MSG_CENTER, CPID_KEYHUNT);
 929         Kill_Notification(NOTIF_ALL, NULL, MSG_CENTER, CPID_KEYHUNT_OTHER);
 930
 931         for(int i = 0; i < NumTeams(kh_teams); ++i)
 932         {
 933                 int teem = kh_Team_ByID(i);
 934                 int players = 0;
 935                 entity my_player = NULL;
 936                 FOREACH_CLIENT(IS_PLAYER(it), {
 937                         if(!IS_DEAD(it) && !PHYS_INPUT_BUTTON_CHAT(it) && it.team == teem)
 938                         {
 939                                 ++players;
 940                                 if(random() * players <= 1)
 941                                         my_player = it;
 942                         }
 943                 });
 944                 kh_Key_Spawn(my_player, 360 * i / NumTeams(kh_teams), i);
 945         }
 946
 947         kh_tracking_enabled = false;
 948         Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_KEYHUNT_SCAN, autocvar_g_balance_keyhunt_delay_tracking);
 949         kh_Controller_SetThink(autocvar_g_balance_keyhunt_delay_tracking, kh_EnableTrackingDevice);
 950 }
 951
 952 float kh_HandleFrags(entity attacker, entity targ, float f)  // adds to the player score
 953 {
 954         if(attacker == targ)
 955                 return f;
 956
 957         if(targ.kh_next)
 958         {
 959                 if(attacker.team == targ.team)
 960                 {
 961                         int nk = 0;
 962                         for(entity k = targ.kh_next; k != NULL; k = k.kh_next)
 963                                 ++nk;
 964                         kh_Scores_Event(attacker, targ.kh_next, "carrierfrag", -nk * autocvar_g_balance_keyhunt_score_collect, 0);
 965                 }
 966                 else
 967                 {
 968                         kh_Scores_Event(attacker, targ.kh_next, "carrierfrag", autocvar_g_balance_keyhunt_score_carrierfrag-1, 0);
 969                         GameRules_scoring_add(attacker, KH_KCKILLS, 1);
 970                         // the frag gets added later
 971                 }
 972         }
 973
 974         return f;
 975 }
 976
 977 void kh_Initialize()  // sets up th KH environment
 978 {
 979         // setup variables
 980         kh_teams = autocvar_g_keyhunt_teams_override;
 981         if(kh_teams < 2)
 982                 kh_teams = cvar("g_keyhunt_teams"); // read the cvar directly as it gets written earlier in the same frame
 983         kh_teams = BITS(bound(2, kh_teams, 4));
 984
 985         // make a KH entity for controlling the game
 986         kh_controller = spawn();
 987         setthink(kh_controller, kh_Controller_Think);
 988         kh_Controller_SetThink(0, kh_WaitForPlayers);
 989
 990         setmodel(kh_controller, MDL_KH_KEY);
 991         kh_key_dropped = kh_controller.modelindex;
 992         /*
 993         dprint(vtos(kh_controller.mins));
 994         dprint(vtos(kh_controller.maxs));
 995         dprint("\n");
 996         */
 997 #ifdef KH_PLAYER_USE_CARRIEDMODEL
 998         setmodel(kh_controller, MDL_KH_KEY_CARRIED);
 999         kh_key_carried = kh_controller.modelindex;
1000 #else
1001         kh_key_carried = kh_key_dropped;
1002 #endif
1003
1004         kh_controller.model = "";
1005         kh_controller.modelindex = 0;
1006
1007         kh_ScoreRules(kh_teams);
1008 }
1009
1010 void kh_finalize()
1011 {
1012         // to be called before intermission
1013         kh_FinishRound();
1014         delete(kh_controller);
1015         kh_controller = NULL;
1016 }
1017
1018 // legacy bot role
1019
1020 void(entity this) havocbot_role_kh_carrier;
1021 void(entity this) havocbot_role_kh_defense;
1022 void(entity this) havocbot_role_kh_offense;
1023 void(entity this) havocbot_role_kh_freelancer;
1024
1025
1026 void havocbot_goalrating_kh(entity this, float ratingscale_team, float ratingscale_dropped, float ratingscale_enemy)
1027 {
1028         entity head;
1029         for (head = kh_worldkeylist; head; head = head.kh_worldkeynext)
1030         {
1031                 if(head.owner == this)
1032                         continue;
1033                 if(!kh_tracking_enabled)
1034                 {
1035                         // if it's carried by our team we know about it
1036                         // otherwise we have to see it to know about it
1037                         if(!head.owner || head.team != this.team)
1038                         {
1039                                 traceline(this.origin + this.view_ofs, head.origin, MOVE_NOMONSTERS, this);
1040                                 if (trace_fraction < 1 && trace_ent != head)
1041                                         continue; // skip what I can't see
1042                         }
1043                 }
1044                 if(!head.owner)
1045                         navigation_routerating(this, head, ratingscale_dropped * 10000, 100000);
1046                 else if(head.team == this.team)
1047                         navigation_routerating(this, head.owner, ratingscale_team * 10000, 100000);
1048                 else
1049                         navigation_routerating(this, head.owner, ratingscale_enemy * 10000, 100000);
1050         }
1051
1052         havocbot_goalrating_items(this, 80000, this.origin, 10000);
1053 }
1054
1055 void havocbot_role_kh_carrier(entity this)
1056 {
1057         if(IS_DEAD(this))
1058                 return;
1059
1060         if (!(this.kh_next))
1061         {
1062                 LOG_TRACE("changing role to freelancer");
1063                 this.havocbot_role = havocbot_role_kh_freelancer;
1064                 this.havocbot_role_timeout = 0;
1065                 return;
1066         }
1067
1068         if (navigation_goalrating_timeout(this))
1069         {
1070                 navigation_goalrating_start(this);
1071
1072                 if(kh_Key_AllOwnedByWhichTeam() == this.team)
1073                         havocbot_goalrating_kh(this, 10, 0.1, 0.05); // bring home
1074                 else
1075                         havocbot_goalrating_kh(this, 4, 4, 0.5); // play defensively
1076
1077                 navigation_goalrating_end(this);
1078
1079                 navigation_goalrating_timeout_set(this);
1080         }
1081 }
1082
1083 void havocbot_role_kh_defense(entity this)
1084 {
1085         if(IS_DEAD(this))
1086                 return;
1087
1088         if (this.kh_next)
1089         {
1090                 LOG_TRACE("changing role to carrier");
1091                 this.havocbot_role = havocbot_role_kh_carrier;
1092                 this.havocbot_role_timeout = 0;
1093                 return;
1094         }
1095
1096         if (!this.havocbot_role_timeout)
1097                 this.havocbot_role_timeout = time + random() * 10 + 20;
1098         if (time > this.havocbot_role_timeout)
1099         {
1100                 LOG_TRACE("changing role to freelancer");
1101                 this.havocbot_role = havocbot_role_kh_freelancer;
1102                 this.havocbot_role_timeout = 0;
1103                 return;
1104         }
1105
1106         if (navigation_goalrating_timeout(this))
1107         {
1108                 float key_owner_team;
1109                 navigation_goalrating_start(this);
1110
1111                 key_owner_team = kh_Key_AllOwnedByWhichTeam();
1112                 if(key_owner_team == this.team)
1113                         havocbot_goalrating_kh(this, 10, 0.1, 0.05); // defend key carriers
1114                 else if(key_owner_team == -1)
1115                         havocbot_goalrating_kh(this, 4, 1, 0.05); // play defensively
1116                 else
1117                         havocbot_goalrating_kh(this, 0.1, 0.1, 5); // ATTACK ANYWAY
1118
1119                 navigation_goalrating_end(this);
1120
1121                 navigation_goalrating_timeout_set(this);
1122         }
1123 }
1124
1125 void havocbot_role_kh_offense(entity this)
1126 {
1127         if(IS_DEAD(this))
1128                 return;
1129
1130         if (this.kh_next)
1131         {
1132                 LOG_TRACE("changing role to carrier");
1133                 this.havocbot_role = havocbot_role_kh_carrier;
1134                 this.havocbot_role_timeout = 0;
1135                 return;
1136         }
1137
1138         if (!this.havocbot_role_timeout)
1139                 this.havocbot_role_timeout = time + random() * 10 + 20;
1140         if (time > this.havocbot_role_timeout)
1141         {
1142                 LOG_TRACE("changing role to freelancer");
1143                 this.havocbot_role = havocbot_role_kh_freelancer;
1144                 this.havocbot_role_timeout = 0;
1145                 return;
1146         }
1147
1148         if (navigation_goalrating_timeout(this))
1149         {
1150                 float key_owner_team;
1151
1152                 navigation_goalrating_start(this);
1153
1154                 key_owner_team = kh_Key_AllOwnedByWhichTeam();
1155                 if(key_owner_team == this.team)
1156                         havocbot_goalrating_kh(this, 10, 0.1, 0.05); // defend anyway
1157                 else if(key_owner_team == -1)
1158                         havocbot_goalrating_kh(this, 0.1, 1, 2); // play offensively
1159                 else
1160                         havocbot_goalrating_kh(this, 0.1, 0.1, 5); // ATTACK! EMERGENCY!
1161
1162                 navigation_goalrating_end(this);
1163
1164                 navigation_goalrating_timeout_set(this);
1165         }
1166 }
1167
1168 void havocbot_role_kh_freelancer(entity this)
1169 {
1170         if(IS_DEAD(this))
1171                 return;
1172
1173         if (this.kh_next)
1174         {
1175                 LOG_TRACE("changing role to carrier");
1176                 this.havocbot_role = havocbot_role_kh_carrier;
1177                 this.havocbot_role_timeout = 0;
1178                 return;
1179         }
1180
1181         if (!this.havocbot_role_timeout)
1182                 this.havocbot_role_timeout = time + random() * 10 + 10;
1183         if (time > this.havocbot_role_timeout)
1184         {
1185                 if (random() < 0.5)
1186                 {
1187                         LOG_TRACE("changing role to offense");
1188                         this.havocbot_role = havocbot_role_kh_offense;
1189                 }
1190                 else
1191                 {
1192                         LOG_TRACE("changing role to defense");
1193                         this.havocbot_role = havocbot_role_kh_defense;
1194                 }
1195                 this.havocbot_role_timeout = 0;
1196                 return;
1197         }
1198
1199         if (navigation_goalrating_timeout(this))
1200         {
1201                 navigation_goalrating_start(this);
1202
1203                 int key_owner_team = kh_Key_AllOwnedByWhichTeam();
1204                 if(key_owner_team == this.team)
1205                         havocbot_goalrating_kh(this, 10, 0.1, 0.05); // defend anyway
1206                 else if(key_owner_team == -1)
1207                         havocbot_goalrating_kh(this, 1, 10, 2); // prefer dropped keys
1208                 else
1209                         havocbot_goalrating_kh(this, 0.1, 0.1, 5); // ATTACK ANYWAY
1210
1211                 navigation_goalrating_end(this);
1212
1213                 navigation_goalrating_timeout_set(this);
1214         }
1215 }
1216
1217
1218 // register this as a mutator
1219
1220 MUTATOR_HOOKFUNCTION(kh, ClientDisconnect)
1221 {
1222         entity player = M_ARGV(0, entity);
1223
1224         kh_Key_DropAll(player, true);
1225 }
1226
1227 MUTATOR_HOOKFUNCTION(kh, MakePlayerObserver)
1228 {
1229         entity player = M_ARGV(0, entity);
1230
1231         kh_Key_DropAll(player, true);
1232 }
1233
1234 MUTATOR_HOOKFUNCTION(kh, PlayerDies)
1235 {
1236         entity frag_attacker = M_ARGV(1, entity);
1237         entity frag_target = M_ARGV(2, entity);
1238
1239         if(frag_target == frag_attacker)
1240                 kh_Key_DropAll(frag_target, true);
1241         else if(IS_PLAYER(frag_attacker))
1242                 kh_Key_DropAll(frag_target, false);
1243         else
1244                 kh_Key_DropAll(frag_target, true);
1245 }
1246
1247 MUTATOR_HOOKFUNCTION(kh, GiveFragsForKill, CBC_ORDER_FIRST)
1248 {
1249         entity frag_attacker = M_ARGV(0, entity);
1250         entity frag_target = M_ARGV(1, entity);
1251         float frag_score = M_ARGV(2, float);
1252         M_ARGV(2, float) = kh_HandleFrags(frag_attacker, frag_target, frag_score);
1253 }
1254
1255 MUTATOR_HOOKFUNCTION(kh, MatchEnd)
1256 {
1257         kh_finalize();
1258 }
1259
1260 MUTATOR_HOOKFUNCTION(kh, TeamBalance_CheckAllowedTeams, CBC_ORDER_EXCLUSIVE)
1261 {
1262         M_ARGV(0, float) = kh_teams;
1263         return true;
1264 }
1265
1266 MUTATOR_HOOKFUNCTION(kh, SpectateCopy)
1267 {
1268         entity spectatee = M_ARGV(0, entity);
1269         entity client = M_ARGV(1, entity);
1270
1271         STAT(KH_KEYS, client) = STAT(KH_KEYS, spectatee);
1272 }
1273
1274 MUTATOR_HOOKFUNCTION(kh, PlayerUseKey)
1275 {
1276         entity player = M_ARGV(0, entity);
1277
1278         if(MUTATOR_RETURNVALUE == 0)
1279         {
1280                 entity k = player.kh_next;
1281                 if(k)
1282                 {
1283                         kh_Key_DropOne(k);
1284                         return true;
1285                 }
1286         }
1287 }
1288
1289 MUTATOR_HOOKFUNCTION(kh, HavocBot_ChooseRole)
1290 {
1291     entity bot = M_ARGV(0, entity);
1292
1293         if(IS_DEAD(bot))
1294                 return true;
1295
1296         float r = random() * 3;
1297         if (r < 1)
1298                 bot.havocbot_role = havocbot_role_kh_offense;
1299         else if (r < 2)
1300                 bot.havocbot_role = havocbot_role_kh_defense;
1301         else
1302                 bot.havocbot_role = havocbot_role_kh_freelancer;
1303
1304         return true;
1305 }
1306
1307 MUTATOR_HOOKFUNCTION(kh, LogDeath_AppendItemCodes)
1308 {
1309         entity player = M_ARGV(0, entity);
1310         if(player.kh_next)
1311                 M_ARGV(1, string) = strcat(M_ARGV(1, string), "K"); // item codes
1312 }
1313
1314 MUTATOR_HOOKFUNCTION(kh, DropSpecialItems)
1315 {
1316         entity frag_target = M_ARGV(0, entity);
1317
1318         kh_Key_DropAll(frag_target, false);
1319 }
1320
1321 MUTATOR_HOOKFUNCTION(kh, reset_map_global)
1322 {
1323         kh_WaitForPlayers(); // takes care of killing the "missing teams" message
1324 }