qcsrc/common/gamemodes/gamemode/lms/sv_lms.qc

   1 #include "sv_lms.qh"
   2
   3 #include <common/mutators/mutator/instagib/items.qh>
   4 #include <server/campaign.qh>
   5 #include <server/command/_mod.qh>
   6 #include <server/world.qh>
   7 #include <server/items/items.qh>
   8
   9 int autocvar_g_lms_extra_lives;
  10 bool autocvar_g_lms_join_anytime;
  11 int autocvar_g_lms_last_join;
  12 bool autocvar_g_lms_regenerate;
  13
  14 // main functions
  15 int LMS_NewPlayerLives()
  16 {
  17         int fl = floor(autocvar_fraglimit);
  18         if(fl == 0 || fl > 999)
  19                 fl = 999;
  20
  21         // first player has left the game for dying too much? Nobody else can get in.
  22         if(lms_lowest_lives < 1)
  23                 return 0;
  24
  25         if(!autocvar_g_lms_join_anytime)
  26                 if(lms_lowest_lives < fl - max(0, floor(autocvar_g_lms_last_join)))
  27                         return 0;
  28
  29         return bound(1, lms_lowest_lives, fl);
  30 }
  31
  32 void ClearWinners();
  33
  34 // LMS winning condition: game terminates if and only if there's at most one
  35 // one player who's living lives. Top two scores being equal cancels the time
  36 // limit.
  37 int WinningCondition_LMS()
  38 {
  39         entity first_player = NULL;
  40         int totalplayers = 0;
  41         FOREACH_CLIENT(IS_PLAYER(it) && it.frags != FRAGS_PLAYER_OUT_OF_GAME, {
  42                 if (!totalplayers)
  43                         first_player = it;
  44                 ++totalplayers;
  45         });
  46
  47         if (totalplayers)
  48         {
  49                 if (totalplayers > 1)
  50                 {
  51                         // two or more active players - continue with the game
  52
  53                         if (autocvar_g_campaign)
  54                         {
  55                                 FOREACH_CLIENT(IS_REAL_CLIENT(it), {
  56                                         float pl_lives = GameRules_scoring_add(it, LMS_LIVES, 0);
  57                                         if (!pl_lives)
  58                                                 return WINNING_YES; // human player lost, game over
  59                                         break;
  60                                 });
  61                         }
  62                 }
  63                 else
  64                 {
  65                         // exactly one player?
  66
  67                         ClearWinners();
  68                         SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
  69
  70                         if (LMS_NewPlayerLives())
  71                         {
  72                                 // game still running (that is, nobody got removed from the game by a frag yet)? then continue
  73                                 return WINNING_NO;
  74                         }
  75                         else
  76                         {
  77                                 // a winner!
  78                                 // and assign him his first place
  79                                 GameRules_scoring_add(first_player, LMS_RANK, 1);
  80                                 if(warmup_stage)
  81                                         return WINNING_NO;
  82                                 else
  83                                         return WINNING_YES;
  84                         }
  85                 }
  86         }
  87         else
  88         {
  89                 // nobody is playing at all...
  90                 if (LMS_NewPlayerLives())
  91                 {
  92                         // wait for players...
  93                 }
  94                 else
  95                 {
  96                         // SNAFU (maybe a draw game?)
  97                         ClearWinners();
  98                         LOG_TRACE("No players, ending game.");
  99                         return WINNING_YES;
 100                 }
 101         }
 102
 103         // When we get here, we have at least two players who are actually LIVING,
 104         // now check if the top two players have equal score.
 105         WinningConditionHelper(NULL);
 106
 107         ClearWinners();
 108         if(WinningConditionHelper_winner)
 109                 WinningConditionHelper_winner.winning = true;
 110         if(WinningConditionHelper_topscore == WinningConditionHelper_secondscore)
 111                 return WINNING_NEVER;
 112
 113         // Top two have different scores? Way to go for our beloved TIMELIMIT!
 114         return WINNING_NO;
 115 }
 116
 117 // mutator hooks
 118 MUTATOR_HOOKFUNCTION(lms, reset_map_global)
 119 {
 120         lms_lowest_lives = 999;
 121 }
 122
 123 MUTATOR_HOOKFUNCTION(lms, reset_map_players)
 124 {
 125         FOREACH_CLIENT(true, {
 126                 TRANSMUTE(Player, it);
 127                 it.frags = FRAGS_PLAYER;
 128                 GameRules_scoring_add(it, LMS_LIVES, LMS_NewPlayerLives());
 129                 PutClientInServer(it);
 130         });
 131 }
 132
 133 // FIXME add support for sv_ready_restart_after_countdown
 134 // that is find a way to respawn/reset players IN GAME without setting lives to 0
 135 MUTATOR_HOOKFUNCTION(lms, ReadLevelCvars)
 136 {
 137         // incompatible
 138         sv_ready_restart_after_countdown = 0;
 139 }
 140
 141 MUTATOR_HOOKFUNCTION(lms, PutClientInServer)
 142 {
 143         entity player = M_ARGV(0, entity);
 144
 145         if(player.frags == FRAGS_SPECTATOR)
 146                 TRANSMUTE(Observer, player);
 147         else
 148         {
 149                 float tl = GameRules_scoring_add(player, LMS_LIVES, 0);
 150                 if(tl < lms_lowest_lives)
 151                         lms_lowest_lives = tl;
 152                 if(tl <= 0)
 153                         TRANSMUTE(Observer, player);
 154                 if(warmup_stage)
 155                         GameRules_scoring_add(player, LMS_RANK, -GameRules_scoring_add(player, LMS_RANK, 0));
 156         }
 157 }
 158
 159 MUTATOR_HOOKFUNCTION(lms, ForbidSpawn)
 160 {
 161         entity player = M_ARGV(0, entity);
 162
 163         if(warmup_stage)
 164                 return false;
 165         if(player.frags == FRAGS_SPECTATOR || GameRules_scoring_add(player, LMS_LIVES, 0) <= 0)
 166         {
 167                 Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_LMS_NOLIVES);
 168                 return true;
 169         }
 170         return false;
 171 }
 172
 173 MUTATOR_HOOKFUNCTION(lms, PlayerDies)
 174 {
 175         entity frag_target = M_ARGV(2, entity);
 176
 177         float tl = GameRules_scoring_add(frag_target, LMS_LIVES, 0);
 178         if (tl <= 0)
 179         {
 180                 frag_target.respawn_flags = RESPAWN_SILENT;
 181                 // prevent unwanted sudden rejoin as spectator and movement of spectator camera
 182                 frag_target.respawn_time = time + 2;
 183         }
 184         frag_target.respawn_flags |= RESPAWN_FORCE;
 185 }
 186
 187 void lms_RemovePlayer(entity player)
 188 {
 189         static int quitters = 0;
 190         float player_rank = GameRules_scoring_add(player, LMS_RANK, 0);
 191         if (!player_rank)
 192         {
 193                 if (player.lms_spectate_warning < 2)
 194                 {
 195                         player.frags = FRAGS_PLAYER_OUT_OF_GAME;
 196                         int pl_cnt = 0;
 197                         FOREACH_CLIENT(IS_PLAYER(it) && it.frags != FRAGS_PLAYER_OUT_OF_GAME, {
 198                                 pl_cnt++;
 199                         });
 200                         GameRules_scoring_add(player, LMS_RANK, pl_cnt + 1);
 201                 }
 202                 else
 203                 {
 204                         FOREACH_CLIENT(true, {
 205                                 if (it.frags == FRAGS_PLAYER_OUT_OF_GAME)
 206                                 {
 207                                         float it_rank = GameRules_scoring_add(it, LMS_RANK, 0);
 208                                         if (it_rank > player_rank && it_rank <= 256)
 209                                                 GameRules_scoring_add(it, LMS_RANK, -1);
 210                                 }
 211                                 else if (it.frags != FRAGS_SPECTATOR)
 212                                 {
 213                                         float tl = GameRules_scoring_add(it, LMS_LIVES, 0);
 214                                         if(tl < lms_lowest_lives)
 215                                                 lms_lowest_lives = tl;
 216                                 }
 217                         });
 218                         GameRules_scoring_add(player, LMS_RANK, 665 - quitters); // different from 666
 219                         if(!warmup_stage)
 220                         {
 221                                 GameRules_scoring_add(player, LMS_LIVES, -GameRules_scoring_add(player, LMS_LIVES, 0));
 222                                 ++quitters;
 223                         }
 224                         player.frags = FRAGS_PLAYER_OUT_OF_GAME;
 225                         TRANSMUTE(Observer, player);
 226                 }
 227         }
 228
 229         if (CS(player).killcount != FRAGS_SPECTATOR && player.lms_spectate_warning < 3)
 230         {
 231                 if (GameRules_scoring_add(player, LMS_RANK, 0) > 0 && player.lms_spectate_warning < 2)
 232                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_LMS_NOLIVES, player.netname);
 233                 else
 234                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_LMS_FORFEIT, player.netname);
 235         }
 236 }
 237
 238 MUTATOR_HOOKFUNCTION(lms, ClientDisconnect)
 239 {
 240         entity player = M_ARGV(0, entity);
 241
 242         // no further message other than the disconnect message
 243         player.lms_spectate_warning = 3;
 244
 245         lms_RemovePlayer(player);
 246 }
 247
 248 MUTATOR_HOOKFUNCTION(lms, MakePlayerObserver)
 249 {
 250         entity player = M_ARGV(0, entity);
 251
 252         if (!IS_PLAYER(player))
 253                 return true;
 254
 255         lms_RemovePlayer(player);
 256         return true;  // prevent team reset
 257 }
 258
 259 MUTATOR_HOOKFUNCTION(lms, ClientConnect)
 260 {
 261         entity player = M_ARGV(0, entity);
 262
 263         if(GameRules_scoring_add(player, LMS_LIVES, LMS_NewPlayerLives()) <= 0)
 264         {
 265                 GameRules_scoring_add(player, LMS_RANK, 666); // mark as forced spectator for the hud code
 266                 player.frags = FRAGS_SPECTATOR;
 267         }
 268 }
 269
 270 // FIXME LMS doesn't allow clients to spectate due to its particular implementation
 271 MUTATOR_HOOKFUNCTION(lms, AutoJoinOnConnection)
 272 {
 273         if(autocvar_g_campaign)
 274                 return false;
 275         return true;
 276 }
 277
 278 MUTATOR_HOOKFUNCTION(lms, PlayerPreThink)
 279 {
 280         entity player = M_ARGV(0, entity);
 281
 282         if(player.deadflag == DEAD_DYING)
 283                 player.deadflag = DEAD_RESPAWNING;
 284 }
 285
 286 MUTATOR_HOOKFUNCTION(lms, PlayerRegen)
 287 {
 288         if(autocvar_g_lms_regenerate)
 289                 return false;
 290         return true;
 291 }
 292
 293 MUTATOR_HOOKFUNCTION(lms, ForbidThrowCurrentWeapon)
 294 {
 295         // forbode!
 296         return true;
 297 }
 298
 299 MUTATOR_HOOKFUNCTION(lms, GiveFragsForKill)
 300 {
 301         entity frag_target = M_ARGV(1, entity);
 302
 303         if (!warmup_stage)
 304         {
 305                 // remove a life
 306                 int tl = GameRules_scoring_add(frag_target, LMS_LIVES, -1);
 307                 if(tl < lms_lowest_lives)
 308                         lms_lowest_lives = tl;
 309                 if(tl <= 0)
 310                 {
 311                         int pl_cnt = 0;
 312                         FOREACH_CLIENT(IS_PLAYER(it) && it.frags != FRAGS_PLAYER_OUT_OF_GAME, {
 313                                 pl_cnt++;
 314                         });
 315                         frag_target.frags = FRAGS_PLAYER_OUT_OF_GAME;
 316                         GameRules_scoring_add(frag_target, LMS_RANK, pl_cnt);
 317                 }
 318         }
 319         M_ARGV(2, float) = 0; // frag score
 320
 321         return true;
 322 }
 323
 324 MUTATOR_HOOKFUNCTION(lms, SetStartItems)
 325 {
 326         start_items &= ~(IT_UNLIMITED_AMMO | IT_UNLIMITED_SUPERWEAPONS);
 327         start_health       = warmup_start_health       = cvar("g_lms_start_health");
 328         start_armorvalue   = warmup_start_armorvalue   = cvar("g_lms_start_armor");
 329         start_ammo_shells  = warmup_start_ammo_shells  = cvar("g_lms_start_ammo_shells");
 330         start_ammo_nails   = warmup_start_ammo_nails   = cvar("g_lms_start_ammo_nails");
 331         start_ammo_rockets = warmup_start_ammo_rockets = cvar("g_lms_start_ammo_rockets");
 332         start_ammo_cells   = warmup_start_ammo_cells   = cvar("g_lms_start_ammo_cells");
 333         start_ammo_plasma  = warmup_start_ammo_plasma  = cvar("g_lms_start_ammo_plasma");
 334         start_ammo_fuel    = warmup_start_ammo_fuel    = cvar("g_lms_start_ammo_fuel");
 335 }
 336
 337 MUTATOR_HOOKFUNCTION(lms, ForbidPlayerScore_Clear)
 338 {
 339         // don't clear player score
 340         return true;
 341 }
 342
 343 MUTATOR_HOOKFUNCTION(lms, FilterItemDefinition)
 344 {
 345         entity definition = M_ARGV(0, entity);
 346
 347         if (autocvar_g_lms_extra_lives && definition == ITEM_ExtraLife)
 348         {
 349                 return false;
 350         }
 351         return true;
 352 }
 353
 354 void lms_extralife(entity this)
 355 {
 356         StartItem(this, ITEM_ExtraLife);
 357 }
 358
 359 MUTATOR_HOOKFUNCTION(lms, OnEntityPreSpawn)
 360 {
 361         if (MUTATOR_RETURNVALUE) return false;
 362         if (!autocvar_g_powerups) return false;
 363         if (!autocvar_g_lms_extra_lives) return false;
 364
 365         entity ent = M_ARGV(0, entity);
 366
 367         // Can't use .itemdef here
 368         if (ent.classname != "item_health_mega") return false;
 369
 370         entity e = spawn();
 371         setthink(e, lms_extralife);
 372
 373         e.nextthink = time + 0.1;
 374         e.spawnflags = ent.spawnflags;
 375         e.noalign = ent.noalign;
 376         setorigin(e, ent.origin);
 377
 378         return true;
 379 }
 380
 381 MUTATOR_HOOKFUNCTION(lms, ItemTouch)
 382 {
 383         if(MUTATOR_RETURNVALUE) return false;
 384
 385         entity item = M_ARGV(0, entity);
 386         entity toucher = M_ARGV(1, entity);
 387
 388         if(item.itemdef == ITEM_ExtraLife)
 389         {
 390                 Send_Notification(NOTIF_ONE, toucher, MSG_CENTER, CENTER_EXTRALIVES, autocvar_g_lms_extra_lives);
 391                 GameRules_scoring_add(toucher, LMS_LIVES, autocvar_g_lms_extra_lives);
 392                 return MUT_ITEMTOUCH_PICKUP;
 393         }
 394
 395         return MUT_ITEMTOUCH_CONTINUE;
 396 }
 397
 398 MUTATOR_HOOKFUNCTION(lms, Bot_FixCount, CBC_ORDER_EXCLUSIVE)
 399 {
 400         FOREACH_CLIENT(IS_REAL_CLIENT(it), {
 401                 ++M_ARGV(0, int); // activerealplayers
 402                 ++M_ARGV(1, int); // realplayers
 403         });
 404
 405         return true;
 406 }
 407
 408 MUTATOR_HOOKFUNCTION(lms, ClientCommand_Spectate)
 409 {
 410         entity player = M_ARGV(0, entity);
 411
 412         if(warmup_stage || player.lms_spectate_warning)
 413         {
 414                 // for the forfeit message...
 415                 player.lms_spectate_warning = 2;
 416         }
 417         else
 418         {
 419                 if(player.frags != FRAGS_SPECTATOR && player.frags != FRAGS_PLAYER_OUT_OF_GAME)
 420                 {
 421                         player.lms_spectate_warning = 1;
 422                         sprint(player, "WARNING: you won't be able to enter the game again after spectating in LMS. Use the same command again to spectate anyway.\n");
 423                 }
 424                 return MUT_SPECCMD_RETURN;
 425         }
 426         return MUT_SPECCMD_CONTINUE;
 427 }
 428
 429 MUTATOR_HOOKFUNCTION(lms, CheckRules_World)
 430 {
 431         M_ARGV(0, float) = WinningCondition_LMS();
 432         return true;
 433 }
 434
 435 MUTATOR_HOOKFUNCTION(lms, SetWeaponArena)
 436 {
 437         if(M_ARGV(0, string) == "0" || M_ARGV(0, string) == "")
 438                 M_ARGV(0, string) = autocvar_g_lms_weaponarena;
 439 }
 440
 441 MUTATOR_HOOKFUNCTION(lms, GetPlayerStatus)
 442 {
 443         return true;
 444 }
 445
 446 MUTATOR_HOOKFUNCTION(lms, AddPlayerScore)
 447 {
 448         if(game_stopped)
 449         if(M_ARGV(0, entity) == SP_LMS_RANK) // score field
 450                 return true; // allow writing to this field in intermission as it is needed for newly joining players
 451 }
 452
 453 void lms_Initialize()
 454 {
 455         lms_lowest_lives = 999;
 456 }