qcsrc/common/gamemodes/gamemode/lms/sv_lms.qc

   1 #include "sv_lms.qh"
   2
   3 #include <common/mutators/mutator/instagib/items.qh>
   4 #include <server/campaign.qh>
   5 #include <server/command/_mod.qh>
   6 #include <server/world.qh>
   7 #include <server/items/items.qh>
   8
   9 int autocvar_g_lms_extra_lives;
  10 bool autocvar_g_lms_join_anytime;
  11 int autocvar_g_lms_last_join;
  12 bool autocvar_g_lms_regenerate;
  13
  14 // main functions
  15 int LMS_NewPlayerLives()
  16 {
  17         int fl = floor(autocvar_fraglimit);
  18         if(fl == 0 || fl > 999)
  19                 fl = 999;
  20
  21         // first player has left the game for dying too much? Nobody else can get in.
  22         if(lms_lowest_lives < 1)
  23                 return 0;
  24
  25         if(!autocvar_g_lms_join_anytime)
  26                 if(lms_lowest_lives < fl - max(0, floor(autocvar_g_lms_last_join)))
  27                         return 0;
  28
  29         return bound(1, lms_lowest_lives, fl);
  30 }
  31
  32 void ClearWinners();
  33
  34 // LMS winning condition: game terminates if and only if there's at most one
  35 // one player who's living lives. Top two scores being equal cancels the time
  36 // limit.
  37 int WinningCondition_LMS()
  38 {
  39         entity first_player = NULL;
  40         int totalplayers = 0;
  41         FOREACH_CLIENT(IS_PLAYER(it) && it.frags != FRAGS_PLAYER_OUT_OF_GAME, {
  42                 if (!totalplayers)
  43                         first_player = it;
  44                 ++totalplayers;
  45         });
  46
  47         if (totalplayers)
  48         {
  49                 if (totalplayers > 1)
  50                 {
  51                         // two or more active players - continue with the game
  52
  53                         if (autocvar_g_campaign)
  54                         {
  55                                 FOREACH_CLIENT(IS_REAL_CLIENT(it), {
  56                                         float pl_lives = GameRules_scoring_add(it, LMS_LIVES, 0);
  57                                         if (!pl_lives)
  58                                                 return WINNING_YES; // human player lost, game over
  59                                         break;
  60                                 });
  61                         }
  62                 }
  63                 else
  64                 {
  65                         // exactly one player?
  66
  67                         ClearWinners();
  68                         SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
  69
  70                         if (LMS_NewPlayerLives())
  71                         {
  72                                 // game still running (that is, nobody got removed from the game by a frag yet)? then continue
  73                                 return WINNING_NO;
  74                         }
  75                         else
  76                         {
  77                                 // a winner!
  78                                 // and assign him his first place
  79                                 GameRules_scoring_add(first_player, LMS_RANK, 1);
  80                                 if(warmup_stage)
  81                                         return WINNING_NO;
  82                                 else
  83                                         return WINNING_YES;
  84                         }
  85                 }
  86         }
  87         else
  88         {
  89                 // nobody is playing at all...
  90                 if (LMS_NewPlayerLives())
  91                 {
  92                         // wait for players...
  93                 }
  94                 else
  95                 {
  96                         // SNAFU (maybe a draw game?)
  97                         ClearWinners();
  98                         LOG_TRACE("No players, ending game.");
  99                         return WINNING_YES;
 100                 }
 101         }
 102
 103         // When we get here, we have at least two players who are actually LIVING,
 104         // now check if the top two players have equal score.
 105         WinningConditionHelper(NULL);
 106
 107         ClearWinners();
 108         if(WinningConditionHelper_winner)
 109                 WinningConditionHelper_winner.winning = true;
 110         if(WinningConditionHelper_topscore == WinningConditionHelper_secondscore)
 111                 return WINNING_NEVER;
 112
 113         // Top two have different scores? Way to go for our beloved TIMELIMIT!
 114         return WINNING_NO;
 115 }
 116
 117 // mutator hooks
 118 MUTATOR_HOOKFUNCTION(lms, reset_map_global)
 119 {
 120         lms_lowest_lives = 999;
 121 }
 122
 123 MUTATOR_HOOKFUNCTION(lms, reset_map_players)
 124 {
 125         FOREACH_CLIENT(true, {
 126                 TRANSMUTE(Player, it);
 127                 it.frags = FRAGS_PLAYER;
 128                 GameRules_scoring_add(it, LMS_LIVES, LMS_NewPlayerLives());
 129                 PutClientInServer(it);
 130         });
 131 }
 132
 133 // FIXME add support for sv_ready_restart_after_countdown
 134 // that is find a way to respawn/reset players IN GAME without setting lives to 0
 135 MUTATOR_HOOKFUNCTION(lms, ReadLevelCvars)
 136 {
 137         // incompatible
 138         sv_ready_restart_after_countdown = 0;
 139 }
 140
 141 MUTATOR_HOOKFUNCTION(lms, PutClientInServer)
 142 {
 143         entity player = M_ARGV(0, entity);
 144
 145         if(player.frags == FRAGS_SPECTATOR)
 146                 TRANSMUTE(Observer, player);
 147         else
 148         {
 149                 float tl = GameRules_scoring_add(player, LMS_LIVES, 0);
 150                 if(tl < lms_lowest_lives)
 151                         lms_lowest_lives = tl;
 152                 if(tl <= 0)
 153                         TRANSMUTE(Observer, player);
 154                 if(warmup_stage)
 155                         GameRules_scoring_add(player, LMS_RANK, -GameRules_scoring_add(player, LMS_RANK, 0));
 156         }
 157 }
 158
 159 MUTATOR_HOOKFUNCTION(lms, ForbidSpawn)
 160 {
 161         entity player = M_ARGV(0, entity);
 162
 163         if(warmup_stage)
 164                 return false;
 165         if(player.frags == FRAGS_SPECTATOR || GameRules_scoring_add(player, LMS_LIVES, 0) <= 0)
 166         {
 167                 Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_LMS_NOLIVES);
 168                 return true;
 169         }
 170         return false;
 171 }
 172
 173 MUTATOR_HOOKFUNCTION(lms, PlayerDies)
 174 {
 175         entity frag_target = M_ARGV(2, entity);
 176
 177         frag_target.respawn_flags |= RESPAWN_FORCE;
 178 }
 179
 180 void lms_RemovePlayer(entity player)
 181 {
 182         static int quitters = 0;
 183         float player_rank = GameRules_scoring_add(player, LMS_RANK, 0);
 184         if (!player_rank)
 185         {
 186                 if (player.lms_spectate_warning < 2)
 187                 {
 188                         if(IS_BOT_CLIENT(player))
 189                                 bot_clear(player);
 190                         player.frags = FRAGS_PLAYER_OUT_OF_GAME;
 191                         int pl_cnt = 0;
 192                         FOREACH_CLIENT(IS_PLAYER(it) && it.frags != FRAGS_PLAYER_OUT_OF_GAME, {
 193                                 pl_cnt++;
 194                         });
 195                         GameRules_scoring_add(player, LMS_RANK, pl_cnt + 1);
 196                 }
 197                 else
 198                 {
 199                         FOREACH_CLIENT(true, {
 200                                 if (it.frags == FRAGS_PLAYER_OUT_OF_GAME)
 201                                 {
 202                                         float it_rank = GameRules_scoring_add(it, LMS_RANK, 0);
 203                                         if (it_rank > player_rank && it_rank <= 256)
 204                                                 GameRules_scoring_add(it, LMS_RANK, -1);
 205                                 }
 206                                 else if (it.frags != FRAGS_SPECTATOR)
 207                                 {
 208                                         float tl = GameRules_scoring_add(it, LMS_LIVES, 0);
 209                                         if(tl < lms_lowest_lives)
 210                                                 lms_lowest_lives = tl;
 211                                 }
 212                         });
 213                         GameRules_scoring_add(player, LMS_RANK, 665 - quitters); // different from 666
 214                         if(!warmup_stage)
 215                         {
 216                                 GameRules_scoring_add(player, LMS_LIVES, -GameRules_scoring_add(player, LMS_LIVES, 0));
 217                                 ++quitters;
 218                         }
 219                         player.frags = FRAGS_PLAYER_OUT_OF_GAME;
 220                         TRANSMUTE(Observer, player);
 221                 }
 222         }
 223
 224         if (CS(player).killcount != FRAGS_SPECTATOR && player.lms_spectate_warning < 3)
 225         {
 226                 if (GameRules_scoring_add(player, LMS_RANK, 0) > 0 && player.lms_spectate_warning < 2)
 227                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_LMS_NOLIVES, player.netname);
 228                 else
 229                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_LMS_FORFEIT, player.netname);
 230         }
 231 }
 232
 233 MUTATOR_HOOKFUNCTION(lms, ClientDisconnect)
 234 {
 235         entity player = M_ARGV(0, entity);
 236
 237         // no further message other than the disconnect message
 238         player.lms_spectate_warning = 3;
 239
 240         lms_RemovePlayer(player);
 241 }
 242
 243 MUTATOR_HOOKFUNCTION(lms, MakePlayerObserver)
 244 {
 245         entity player = M_ARGV(0, entity);
 246
 247         if (!IS_PLAYER(player))
 248                 return true;
 249
 250         lms_RemovePlayer(player);
 251         return true;  // prevent team reset
 252 }
 253
 254 MUTATOR_HOOKFUNCTION(lms, ClientConnect)
 255 {
 256         entity player = M_ARGV(0, entity);
 257
 258         if(GameRules_scoring_add(player, LMS_LIVES, LMS_NewPlayerLives()) <= 0)
 259         {
 260                 GameRules_scoring_add(player, LMS_RANK, 666); // mark as forced spectator for the hud code
 261                 player.frags = FRAGS_SPECTATOR;
 262         }
 263 }
 264
 265 // FIXME LMS doesn't allow clients to spectate due to its particular implementation
 266 MUTATOR_HOOKFUNCTION(lms, AutoJoinOnConnection)
 267 {
 268         if(autocvar_g_campaign)
 269                 return false;
 270         return true;
 271 }
 272
 273 MUTATOR_HOOKFUNCTION(lms, PlayerPreThink)
 274 {
 275         entity player = M_ARGV(0, entity);
 276
 277         if(player.deadflag == DEAD_DYING)
 278                 player.deadflag = DEAD_RESPAWNING;
 279 }
 280
 281 MUTATOR_HOOKFUNCTION(lms, PlayerRegen)
 282 {
 283         if(autocvar_g_lms_regenerate)
 284                 return false;
 285         return true;
 286 }
 287
 288 MUTATOR_HOOKFUNCTION(lms, ForbidThrowCurrentWeapon)
 289 {
 290         // forbode!
 291         return true;
 292 }
 293
 294 MUTATOR_HOOKFUNCTION(lms, GiveFragsForKill)
 295 {
 296         entity frag_target = M_ARGV(1, entity);
 297
 298         if (!warmup_stage)
 299         {
 300                 // remove a life
 301                 int tl = GameRules_scoring_add(frag_target, LMS_LIVES, -1);
 302                 if(tl < lms_lowest_lives)
 303                         lms_lowest_lives = tl;
 304                 if(tl <= 0)
 305                 {
 306                         int pl_cnt = 0;
 307                         FOREACH_CLIENT(IS_PLAYER(it) && it.frags != FRAGS_PLAYER_OUT_OF_GAME, {
 308                                 pl_cnt++;
 309                         });
 310                         if(IS_BOT_CLIENT(frag_target))
 311                                 bot_clear(frag_target);
 312                         frag_target.frags = FRAGS_PLAYER_OUT_OF_GAME;
 313                         GameRules_scoring_add(frag_target, LMS_RANK, pl_cnt);
 314                 }
 315         }
 316         M_ARGV(2, float) = 0; // frag score
 317
 318         return true;
 319 }
 320
 321 MUTATOR_HOOKFUNCTION(lms, SetStartItems)
 322 {
 323         start_items &= ~(IT_UNLIMITED_AMMO | IT_UNLIMITED_SUPERWEAPONS);
 324         start_health       = warmup_start_health       = cvar("g_lms_start_health");
 325         start_armorvalue   = warmup_start_armorvalue   = cvar("g_lms_start_armor");
 326         start_ammo_shells  = warmup_start_ammo_shells  = cvar("g_lms_start_ammo_shells");
 327         start_ammo_nails   = warmup_start_ammo_nails   = cvar("g_lms_start_ammo_nails");
 328         start_ammo_rockets = warmup_start_ammo_rockets = cvar("g_lms_start_ammo_rockets");
 329         start_ammo_cells   = warmup_start_ammo_cells   = cvar("g_lms_start_ammo_cells");
 330         start_ammo_plasma  = warmup_start_ammo_plasma  = cvar("g_lms_start_ammo_plasma");
 331         start_ammo_fuel    = warmup_start_ammo_fuel    = cvar("g_lms_start_ammo_fuel");
 332 }
 333
 334 MUTATOR_HOOKFUNCTION(lms, ForbidPlayerScore_Clear)
 335 {
 336         // don't clear player score
 337         return true;
 338 }
 339
 340 MUTATOR_HOOKFUNCTION(lms, FilterItemDefinition)
 341 {
 342         entity definition = M_ARGV(0, entity);
 343
 344         if (autocvar_g_lms_extra_lives && definition == ITEM_ExtraLife)
 345         {
 346                 return false;
 347         }
 348         return true;
 349 }
 350
 351 void lms_extralife(entity this)
 352 {
 353         StartItem(this, ITEM_ExtraLife);
 354 }
 355
 356 MUTATOR_HOOKFUNCTION(lms, OnEntityPreSpawn)
 357 {
 358         if (MUTATOR_RETURNVALUE) return false;
 359         if (!autocvar_g_powerups) return false;
 360         if (!autocvar_g_lms_extra_lives) return false;
 361
 362         entity ent = M_ARGV(0, entity);
 363
 364         // Can't use .itemdef here
 365         if (ent.classname != "item_health_mega") return false;
 366
 367         entity e = spawn();
 368         setthink(e, lms_extralife);
 369
 370         e.nextthink = time + 0.1;
 371         e.spawnflags = ent.spawnflags;
 372         e.noalign = ent.noalign;
 373         setorigin(e, ent.origin);
 374
 375         return true;
 376 }
 377
 378 MUTATOR_HOOKFUNCTION(lms, ItemTouch)
 379 {
 380         if(MUTATOR_RETURNVALUE) return false;
 381
 382         entity item = M_ARGV(0, entity);
 383         entity toucher = M_ARGV(1, entity);
 384
 385         if(item.itemdef == ITEM_ExtraLife)
 386         {
 387                 Send_Notification(NOTIF_ONE, toucher, MSG_CENTER, CENTER_EXTRALIVES, autocvar_g_lms_extra_lives);
 388                 GameRules_scoring_add(toucher, LMS_LIVES, autocvar_g_lms_extra_lives);
 389                 return MUT_ITEMTOUCH_PICKUP;
 390         }
 391
 392         return MUT_ITEMTOUCH_CONTINUE;
 393 }
 394
 395 MUTATOR_HOOKFUNCTION(lms, Bot_FixCount, CBC_ORDER_EXCLUSIVE)
 396 {
 397         FOREACH_CLIENT(IS_REAL_CLIENT(it), {
 398                 ++M_ARGV(0, int); // activerealplayers
 399                 ++M_ARGV(1, int); // realplayers
 400         });
 401
 402         return true;
 403 }
 404
 405 MUTATOR_HOOKFUNCTION(lms, ClientCommand_Spectate)
 406 {
 407         entity player = M_ARGV(0, entity);
 408
 409         if(warmup_stage || player.lms_spectate_warning)
 410         {
 411                 // for the forfeit message...
 412                 player.lms_spectate_warning = 2;
 413         }
 414         else
 415         {
 416                 if(player.frags != FRAGS_SPECTATOR && player.frags != FRAGS_PLAYER_OUT_OF_GAME)
 417                 {
 418                         player.lms_spectate_warning = 1;
 419                         sprint(player, "WARNING: you won't be able to enter the game again after spectating in LMS. Use the same command again to spectate anyway.\n");
 420                 }
 421                 return MUT_SPECCMD_RETURN;
 422         }
 423         return MUT_SPECCMD_CONTINUE;
 424 }
 425
 426 MUTATOR_HOOKFUNCTION(lms, CheckRules_World)
 427 {
 428         M_ARGV(0, float) = WinningCondition_LMS();
 429         return true;
 430 }
 431
 432 MUTATOR_HOOKFUNCTION(lms, SetWeaponArena)
 433 {
 434         if(M_ARGV(0, string) == "0" || M_ARGV(0, string) == "")
 435                 M_ARGV(0, string) = autocvar_g_lms_weaponarena;
 436 }
 437
 438 MUTATOR_HOOKFUNCTION(lms, GetPlayerStatus)
 439 {
 440         return true;
 441 }
 442
 443 MUTATOR_HOOKFUNCTION(lms, AddPlayerScore)
 444 {
 445         if(game_stopped)
 446         if(M_ARGV(0, entity) == SP_LMS_RANK) // score field
 447                 return true; // allow writing to this field in intermission as it is needed for newly joining players
 448 }
 449
 450 void lms_Initialize()
 451 {
 452         lms_lowest_lives = 999;
 453 }