qcsrc/common/gamemodes/gamemode/nexball/nexball.qc

   1 #include "nexball.qh"
   2
   3 #ifdef CSQC
   4 int autocvar_cl_eventchase_nexball = 1;
   5
   6 REGISTER_MUTATOR(cl_nb, true);
   7
   8 MUTATOR_HOOKFUNCTION(cl_nb, WantEventchase)
   9 {
  10         if(autocvar_cl_eventchase_nexball && gametype == MAPINFO_TYPE_NEXBALL && !(WepSet_GetFromStat() & WEPSET(NEXBALL)))
  11                 return true;
  12         return false;
  13 }
  14 #endif
  15 #ifdef SVQC
  16 .float metertime = _STAT(NB_METERSTART);
  17
  18 int autocvar_g_nexball_goalleadlimit;
  19 #define autocvar_g_nexball_goallimit cvar("g_nexball_goallimit")
  20
  21 bool autocvar_g_nexball_basketball_jumppad = true;
  22 float autocvar_g_nexball_basketball_bouncefactor;
  23 float autocvar_g_nexball_basketball_bouncestop;
  24 float autocvar_g_nexball_basketball_carrier_highspeed;
  25 bool autocvar_g_nexball_basketball_meter;
  26 float autocvar_g_nexball_basketball_meter_maxpower;
  27 float autocvar_g_nexball_basketball_meter_minpower;
  28 float autocvar_g_nexball_delay_collect;
  29 float autocvar_g_nexball_delay_goal;
  30 float autocvar_g_nexball_delay_start;
  31 bool autocvar_g_nexball_football_jumppad = true;
  32 float autocvar_g_nexball_football_bouncefactor;
  33 float autocvar_g_nexball_football_bouncestop;
  34 bool autocvar_g_nexball_radar_showallplayers;
  35 bool autocvar_g_nexball_sound_bounce;
  36 int autocvar_g_nexball_trail_color;
  37 bool autocvar_g_nexball_playerclip_collisions = true;
  38
  39 float autocvar_g_nexball_safepass_turnrate;
  40 float autocvar_g_nexball_safepass_maxdist;
  41 float autocvar_g_nexball_safepass_holdtime;
  42 float autocvar_g_nexball_viewmodel_scale;
  43 float autocvar_g_nexball_tackling;
  44 vector autocvar_g_nexball_viewmodel_offset;
  45
  46 float autocvar_g_balance_nexball_primary_animtime;
  47 float autocvar_g_balance_nexball_primary_refire;
  48 float autocvar_g_balance_nexball_primary_speed;
  49 float autocvar_g_balance_nexball_secondary_animtime;
  50 float autocvar_g_balance_nexball_secondary_force;
  51 float autocvar_g_balance_nexball_secondary_lifetime;
  52 float autocvar_g_balance_nexball_secondary_refire;
  53 float autocvar_g_balance_nexball_secondary_speed;
  54
  55 void basketball_touch(entity this, entity toucher);
  56 void football_touch(entity this, entity toucher);
  57 void ResetBall(entity this);
  58 const int NBM_NONE = 0;
  59 const int NBM_FOOTBALL = 2;
  60 const int NBM_BASKETBALL = 4;
  61 float nexball_mode;
  62
  63 float OtherTeam(float t)  //works only if there are two teams on the map!
  64 {
  65         entity e;
  66         e = find(NULL, classname, "nexball_team");
  67         if(e.team == t)
  68                 e = find(e, classname, "nexball_team");
  69         return e.team;
  70 }
  71
  72 const float ST_NEXBALL_GOALS = 1;
  73 void nb_ScoreRules(int teams)
  74 {
  75         ScoreRules_basics(teams, 0, 0, true);
  76         ScoreInfo_SetLabel_TeamScore(   ST_NEXBALL_GOALS,  "goals", SFL_SORT_PRIO_PRIMARY);
  77         ScoreInfo_SetLabel_PlayerScore( SP_NEXBALL_GOALS,  "goals", SFL_SORT_PRIO_PRIMARY);
  78         ScoreInfo_SetLabel_PlayerScore(SP_NEXBALL_FAULTS, "faults", SFL_SORT_PRIO_SECONDARY | SFL_LOWER_IS_BETTER);
  79         ScoreRules_basics_end();
  80 }
  81
  82 void LogNB(string mode, entity actor)
  83 {
  84         string s;
  85         if(!autocvar_sv_eventlog)
  86                 return;
  87         s = strcat(":nexball:", mode);
  88         if(actor != NULL)
  89                 s = strcat(s, ":", ftos(actor.playerid));
  90         GameLogEcho(s);
  91 }
  92
  93 void ball_restart(entity this)
  94 {
  95         if(this.owner)
  96                 DropBall(this, this.owner.origin, '0 0 0');
  97         ResetBall(this);
  98 }
  99
 100 void nexball_setstatus(entity this)
 101 {
 102         this.items &= ~IT_KEY1;
 103         if(this.ballcarried)
 104         {
 105                 if(this.ballcarried.teamtime && (this.ballcarried.teamtime < time))
 106                 {
 107                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_NEXBALL_RETURN_HELD));
 108                         entity e = this.ballcarried;
 109                         DropBall(this.ballcarried, this.ballcarried.owner.origin, '0 0 0');
 110                         ResetBall(e);
 111                 }
 112                 else
 113                         this.items |= IT_KEY1;
 114         }
 115 }
 116
 117 void relocate_nexball(entity this)
 118 {
 119         tracebox(this.origin, BALL_MINS, BALL_MAXS, this.origin, true, this);
 120         if(trace_startsolid)
 121         {
 122                 vector o;
 123                 o = this.origin;
 124                 if(!move_out_of_solid(this))
 125                         objerror(this, "could not get out of solid at all!");
 126                 LOG_INFO("^1NOTE: this map needs FIXING. ", this.classname, " at ", vtos(o - '0 0 1'));
 127                 LOG_INFO(" needs to be moved out of solid, e.g. by '", ftos(this.origin.x - o.x));
 128                 LOG_INFO(" ", ftos(this.origin.y - o.y));
 129                 LOG_INFO(" ", ftos(this.origin.z - o.z), "'\n");
 130                 this.origin = o;
 131         }
 132 }
 133
 134 void DropOwner(entity this)
 135 {
 136         entity ownr;
 137         ownr = this.owner;
 138         DropBall(this, ownr.origin, ownr.velocity);
 139         makevectors(ownr.v_angle.y * '0 1 0');
 140         ownr.velocity += ('0 0 0.75' - v_forward) * 1000;
 141         UNSET_ONGROUND(ownr);
 142 }
 143
 144 void GiveBall(entity plyr, entity ball)
 145 {
 146         .entity weaponentity = weaponentities[0]; // TODO: find ballstealer
 147         entity ownr = ball.owner;
 148         if(ownr)
 149         {
 150                 ownr.effects &= ~autocvar_g_nexball_basketball_effects_default;
 151                 ownr.ballcarried = NULL;
 152                 if(ownr.metertime)
 153                 {
 154                         ownr.metertime = 0;
 155                         ownr.(weaponentity).state = WS_READY;
 156                 }
 157                 WaypointSprite_Kill(ownr.waypointsprite_attachedforcarrier);
 158         }
 159         else
 160         {
 161                 WaypointSprite_Kill(ball.waypointsprite_attachedforcarrier);
 162         }
 163
 164         //setattachment(ball, plyr, "");
 165         setorigin(ball, plyr.origin + plyr.view_ofs);
 166
 167         if(ball.team != plyr.team)
 168                 ball.teamtime = time + autocvar_g_nexball_basketball_delay_hold_forteam;
 169
 170         ball.owner = ball.pusher = plyr; //"owner" is set to the player carrying, "pusher" to the last player who touched it
 171         ball.team = plyr.team;
 172         plyr.ballcarried = ball;
 173         ball.nb_dropper = plyr;
 174
 175         plyr.effects |= autocvar_g_nexball_basketball_effects_default;
 176         ball.effects &= ~autocvar_g_nexball_basketball_effects_default;
 177
 178         ball.velocity = '0 0 0';
 179         set_movetype(ball, MOVETYPE_NONE);
 180         settouch(ball, func_null);
 181         ball.effects |= EF_NOSHADOW;
 182         ball.scale = 1; // scale down.
 183
 184         WaypointSprite_AttachCarrier(WP_NbBall, plyr, RADARICON_FLAGCARRIER);
 185         WaypointSprite_UpdateRule(plyr.waypointsprite_attachedforcarrier, 0, SPRITERULE_DEFAULT);
 186
 187         if(autocvar_g_nexball_basketball_delay_hold)
 188         {
 189                 setthink(ball, DropOwner);
 190                 ball.nextthink = time + autocvar_g_nexball_basketball_delay_hold;
 191         }
 192
 193         plyr.(weaponentity).weapons = plyr.weapons;
 194         plyr.(weaponentity).m_switchweapon = PS(plyr).m_weapon;
 195         plyr.weapons = WEPSET(NEXBALL);
 196         Weapon w = WEP_NEXBALL;
 197         w.wr_resetplayer(w, plyr);
 198         PS(plyr).m_switchweapon = WEP_NEXBALL;
 199         W_SwitchWeapon(plyr, WEP_NEXBALL);
 200 }
 201
 202 void DropBall(entity ball, vector org, vector vel)
 203 {
 204         ball.effects |= autocvar_g_nexball_basketball_effects_default;
 205         ball.effects &= ~EF_NOSHADOW;
 206         ball.owner.effects &= ~autocvar_g_nexball_basketball_effects_default;
 207
 208         setattachment(ball, NULL, "");
 209         setorigin(ball, org);
 210         set_movetype(ball, MOVETYPE_BOUNCE);
 211         UNSET_ONGROUND(ball);
 212         ball.scale = ball_scale;
 213         ball.velocity = vel;
 214         ball.nb_droptime = time;
 215         settouch(ball, basketball_touch);
 216         setthink(ball, ResetBall);
 217         ball.nextthink = min(time + autocvar_g_nexball_delay_idle, ball.teamtime);
 218
 219         if(ball.owner.metertime)
 220         {
 221                 ball.owner.metertime = 0;
 222                 .entity weaponentity = weaponentities[0]; // TODO: find ballstealer
 223                 ball.owner.(weaponentity).state = WS_READY;
 224         }
 225
 226         WaypointSprite_Kill(ball.owner.waypointsprite_attachedforcarrier);
 227         WaypointSprite_Spawn(WP_NbBall, 0, 0, ball, '0 0 64', NULL, ball.team, ball, waypointsprite_attachedforcarrier, false, RADARICON_FLAGCARRIER); // no health bar please
 228         WaypointSprite_UpdateRule(ball.waypointsprite_attachedforcarrier, 0, SPRITERULE_DEFAULT);
 229
 230         ball.owner.ballcarried = NULL;
 231         ball.owner = NULL;
 232 }
 233
 234 void InitBall(entity this)
 235 {
 236         if(gameover) return;
 237         UNSET_ONGROUND(this);
 238         set_movetype(this, MOVETYPE_BOUNCE);
 239         if(this.classname == "nexball_basketball")
 240                 settouch(this, basketball_touch);
 241         else if(this.classname == "nexball_football")
 242                 settouch(this, football_touch);
 243         this.cnt = 0;
 244         setthink(this, ResetBall);
 245         this.nextthink = time + autocvar_g_nexball_delay_idle + 3;
 246         this.teamtime = 0;
 247         this.pusher = NULL;
 248         this.team = false;
 249         _sound(this, CH_TRIGGER, this.noise1, VOL_BASE, ATTEN_NORM);
 250         WaypointSprite_Ping(this.waypointsprite_attachedforcarrier);
 251         LogNB("init", NULL);
 252 }
 253
 254 void ResetBall(entity this)
 255 {
 256         if(this.cnt < 2)        // step 1
 257         {
 258                 if(time == this.teamtime)
 259                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_NEXBALL_RETURN_HELD));
 260
 261                 settouch(this, func_null);
 262                 set_movetype(this, MOVETYPE_NOCLIP);
 263                 this.velocity = '0 0 0'; // just in case?
 264                 if(!this.cnt)
 265                         LogNB("resetidle", NULL);
 266                 this.cnt = 2;
 267                 this.nextthink = time;
 268         }
 269         else if(this.cnt < 4)     // step 2 and 3
 270         {
 271 //              dprint("Step ", ftos(this.cnt), ": Calculated velocity: ", vtos(this.spawnorigin - this.origin), ", time: ", ftos(time), "\n");
 272                 this.velocity = (this.spawnorigin - this.origin) * (this.cnt - 1); // 1 or 0.5 second movement
 273                 this.nextthink = time + 0.5;
 274                 this.cnt += 1;
 275         }
 276         else     // step 4
 277         {
 278 //              dprint("Step 4: time: ", ftos(time), "\n");
 279                 if(vdist(this.origin - this.spawnorigin, >, 10)) // should not happen anymore
 280                         LOG_TRACE("The ball moved too far away from its spawn origin.\nOffset: ",
 281                                    vtos(this.origin - this.spawnorigin), " Velocity: ", vtos(this.velocity), "\n");
 282                 this.velocity = '0 0 0';
 283                 setorigin(this, this.spawnorigin); // make sure it's positioned correctly anyway
 284                 set_movetype(this, MOVETYPE_NONE);
 285                 setthink(this, InitBall);
 286                 this.nextthink = max(time, game_starttime) + autocvar_g_nexball_delay_start;
 287         }
 288 }
 289
 290 void football_touch(entity this, entity toucher)
 291 {
 292         if(toucher.solid == SOLID_BSP)
 293         {
 294                 if(time > this.lastground + 0.1)
 295                 {
 296                         _sound(this, CH_TRIGGER, this.noise, VOL_BASE, ATTEN_NORM);
 297                         this.lastground = time;
 298                 }
 299                 if(this.velocity && !this.cnt)
 300                         this.nextthink = time + autocvar_g_nexball_delay_idle;
 301                 return;
 302         }
 303         if (!IS_PLAYER(toucher))
 304                 return;
 305         if(toucher.health < 1)
 306                 return;
 307         if(!this.cnt)
 308                 this.nextthink = time + autocvar_g_nexball_delay_idle;
 309
 310         this.pusher = toucher;
 311         this.team = toucher.team;
 312
 313         if(autocvar_g_nexball_football_physics == -1)   // MrBougo try 1, before decompiling Rev's original
 314         {
 315                 if(toucher.velocity)
 316                         this.velocity = toucher.velocity * 1.5 + '0 0 1' * autocvar_g_nexball_football_boost_up;
 317         }
 318         else if(autocvar_g_nexball_football_physics == 1)         // MrBougo's modded Rev style: partially independant of the height of the aiming point
 319         {
 320                 makevectors(toucher.v_angle);
 321                 this.velocity = toucher.velocity + v_forward * autocvar_g_nexball_football_boost_forward + '0 0 1' * autocvar_g_nexball_football_boost_up;
 322         }
 323         else if(autocvar_g_nexball_football_physics == 2)         // 2nd mod try: totally independant. Really playable!
 324         {
 325                 makevectors(toucher.v_angle.y * '0 1 0');
 326                 this.velocity = toucher.velocity + v_forward * autocvar_g_nexball_football_boost_forward + v_up * autocvar_g_nexball_football_boost_up;
 327         }
 328         else     // Revenant's original style (from the original mod's disassembly, acknowledged by Revenant)
 329         {
 330                 makevectors(toucher.v_angle);
 331                 this.velocity = toucher.velocity + v_forward * autocvar_g_nexball_football_boost_forward + v_up * autocvar_g_nexball_football_boost_up;
 332         }
 333         this.avelocity = -250 * v_forward;  // maybe there is a way to make it look better?
 334 }
 335
 336 void basketball_touch(entity this, entity toucher)
 337 {
 338         if(toucher.ballcarried)
 339         {
 340                 football_touch(this, toucher);
 341                 return;
 342         }
 343         if(!this.cnt && IS_PLAYER(toucher) && !STAT(FROZEN, toucher) && !IS_DEAD(toucher) && (toucher != this.nb_dropper || time > this.nb_droptime + autocvar_g_nexball_delay_collect))
 344         {
 345                 if(toucher.health <= 0)
 346                         return;
 347                 LogNB("caught", toucher);
 348                 GiveBall(toucher, this);
 349         }
 350         else if(toucher.solid == SOLID_BSP)
 351         {
 352                 _sound(this, CH_TRIGGER, this.noise, VOL_BASE, ATTEN_NORM);
 353                 if(this.velocity && !this.cnt)
 354                         this.nextthink = min(time + autocvar_g_nexball_delay_idle, this.teamtime);
 355         }
 356 }
 357
 358 void GoalTouch(entity this, entity toucher)
 359 {
 360         entity ball;
 361         float isclient, pscore, otherteam;
 362         string pname;
 363
 364         if(gameover) return;
 365         if((this.spawnflags & GOAL_TOUCHPLAYER) && toucher.ballcarried)
 366                 ball = toucher.ballcarried;
 367         else
 368                 ball = toucher;
 369         if(ball.classname != "nexball_basketball")
 370                 if(ball.classname != "nexball_football")
 371                         return;
 372         if((!ball.pusher && this.team != GOAL_OUT) || ball.cnt)
 373                 return;
 374         EXACTTRIGGER_TOUCH(this, toucher);
 375
 376
 377         if(NumTeams(nb_teams) == 2)
 378                 otherteam = OtherTeam(ball.team);
 379         else
 380                 otherteam = 0;
 381
 382         if((isclient = IS_CLIENT(ball.pusher)))
 383                 pname = ball.pusher.netname;
 384         else
 385                 pname = "Someone (?)";
 386
 387         if(ball.team == this.team)               //owngoal (regular goals)
 388         {
 389                 LogNB("owngoal", ball.pusher);
 390                 bprint("Boo! ", pname, "^7 scored a goal against their own team!\n");
 391                 pscore = -1;
 392         }
 393         else if(this.team == GOAL_FAULT)
 394         {
 395                 LogNB("fault", ball.pusher);
 396                 if(NumTeams(nb_teams) == 2)
 397                         bprint(Team_ColoredFullName(otherteam), " gets a point due to ", pname, "^7's silliness.\n");
 398                 else
 399                         bprint(Team_ColoredFullName(ball.team), " loses a point due to ", pname, "^7's silliness.\n");
 400                 pscore = -1;
 401         }
 402         else if(this.team == GOAL_OUT)
 403         {
 404                 LogNB("out", ball.pusher);
 405                 if((this.spawnflags & GOAL_TOUCHPLAYER) && ball.owner)
 406                         bprint(pname, "^7 went out of bounds.\n");
 407                 else
 408                         bprint("The ball was returned.\n");
 409                 pscore = 0;
 410         }
 411         else                                                       //score
 412         {
 413                 LogNB(strcat("goal:", ftos(this.team)), ball.pusher);
 414                 bprint("Goaaaaal! ", pname, "^7 scored a point for the ", Team_ColoredFullName(ball.team), ".\n");
 415                 pscore = 1;
 416         }
 417
 418         _sound(ball, CH_TRIGGER, this.noise, VOL_BASE, ATTEN_NONE);
 419
 420         if(ball.team && pscore)
 421         {
 422                 if(NumTeams(nb_teams) == 2 && pscore < 0)
 423                         TeamScore_AddToTeam(otherteam, ST_NEXBALL_GOALS, -pscore);
 424                 else
 425                         TeamScore_AddToTeam(ball.team, ST_NEXBALL_GOALS, pscore);
 426         }
 427         if(isclient)
 428         {
 429                 if(pscore > 0)
 430                         PlayerScore_Add(ball.pusher, SP_NEXBALL_GOALS, pscore);
 431                 else if(pscore < 0)
 432                         PlayerScore_Add(ball.pusher, SP_NEXBALL_FAULTS, -pscore);
 433         }
 434
 435         if(ball.owner)  // Happens on spawnflag GOAL_TOUCHPLAYER
 436                 DropBall(ball, ball.owner.origin, ball.owner.velocity);
 437
 438         WaypointSprite_Ping(ball.waypointsprite_attachedforcarrier);
 439
 440         ball.cnt = 1;
 441         setthink(ball, ResetBall);
 442         if(ball.classname == "nexball_basketball")
 443                 settouch(ball, football_touch); // better than func_null: football control until the ball gets reset
 444         ball.nextthink = time + autocvar_g_nexball_delay_goal * (this.team != GOAL_OUT);
 445 }
 446
 447 //=======================//
 448 //         team ents       //
 449 //=======================//
 450 spawnfunc(nexball_team)
 451 {
 452         if(!g_nexball)
 453         {
 454                 delete(this);
 455                 return;
 456         }
 457         this.team = this.cnt + 1;
 458 }
 459
 460 void nb_spawnteam(string teamname, float teamcolor)
 461 {
 462         LOG_TRACE("^2spawned team ", teamname);
 463         entity e = new(nexball_team);
 464         e.netname = teamname;
 465         e.cnt = teamcolor;
 466         e.team = e.cnt + 1;
 467         //nb_teams += 1;
 468 }
 469
 470 void nb_spawnteams()
 471 {
 472         bool t_red = false, t_blue = false, t_yellow = false, t_pink = false;
 473         entity e;
 474         for(e = NULL; (e = find(e, classname, "nexball_goal"));)
 475         {
 476                 switch(e.team)
 477                 {
 478                 case NUM_TEAM_1:
 479                         if(!t_red)
 480                         {
 481                                 nb_spawnteam("Red", e.team-1)   ;
 482                                 nb_teams |= BIT(0);
 483                                 t_red = true;
 484                         }
 485                         break;
 486                 case NUM_TEAM_2:
 487                         if(!t_blue)
 488                         {
 489                                 nb_spawnteam("Blue", e.team-1)  ;
 490                                 t_blue = true;
 491                                 nb_teams |= BIT(1);
 492                         }
 493                         break;
 494                 case NUM_TEAM_3:
 495                         if(!t_yellow)
 496                         {
 497                                 nb_spawnteam("Yellow", e.team-1);
 498                                 t_yellow = true;
 499                                 nb_teams |= BIT(2);
 500                         }
 501                         break;
 502                 case NUM_TEAM_4:
 503                         if(!t_pink)
 504                         {
 505                                 nb_spawnteam("Pink", e.team-1)  ;
 506                                 t_pink = true;
 507                                 nb_teams |= BIT(3);
 508                         }
 509                         break;
 510                 }
 511         }
 512 }
 513
 514 void nb_delayedinit(entity this)
 515 {
 516         if(find(NULL, classname, "nexball_team") == NULL)
 517                 nb_spawnteams();
 518         nb_ScoreRules(nb_teams);
 519 }
 520
 521
 522 //=======================//
 523 //        spawnfuncs       //
 524 //=======================//
 525
 526 void SpawnBall(entity this)
 527 {
 528         if(!g_nexball) { delete(this); return; }
 529
 530 //      balls += 4; // using the remaining bits to count balls will leave more than the max edict count, so it's fine
 531
 532         if(this.model == "")
 533         {
 534                 this.model = "models/nexball/ball.md3";
 535                 this.scale = 1.3;
 536         }
 537
 538         precache_model(this.model);
 539         _setmodel(this, this.model);
 540         setsize(this, BALL_MINS, BALL_MAXS);
 541         ball_scale = this.scale;
 542
 543         relocate_nexball(this);
 544         this.spawnorigin = this.origin;
 545
 546         this.effects = this.effects | EF_LOWPRECISION;
 547
 548         if(cvar(strcat("g_", this.classname, "_trail")))  //nexball_basketball :p
 549         {
 550                 this.glow_color = autocvar_g_nexball_trail_color;
 551                 this.glow_trail = true;
 552         }
 553
 554         set_movetype(this, MOVETYPE_FLY);
 555
 556         if(autocvar_g_nexball_playerclip_collisions)
 557         {
 558                 this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID | DPCONTENTS_PLAYERCLIP;
 559                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 560         }
 561
 562         if(!autocvar_g_nexball_sound_bounce)
 563                 this.noise = "";
 564         else if(this.noise == "")
 565                 this.noise = strzone(SND(NB_BOUNCE));
 566         //bounce sound placeholder (FIXME)
 567         if(this.noise1 == "")
 568                 this.noise1 = strzone(SND(NB_DROP));
 569         //ball drop sound placeholder (FIXME)
 570         if(this.noise2 == "")
 571                 this.noise2 = strzone(SND(NB_STEAL));
 572         //stealing sound placeholder (FIXME)
 573         if(this.noise) precache_sound(this.noise);
 574         precache_sound(this.noise1);
 575         precache_sound(this.noise2);
 576
 577         WaypointSprite_AttachCarrier(WP_NbBall, this, RADARICON_FLAGCARRIER); // the ball's team is not set yet, no rule update needed
 578
 579         this.reset = ball_restart;
 580         setthink(this, InitBall);
 581         this.nextthink = game_starttime + autocvar_g_nexball_delay_start;
 582 }
 583
 584 spawnfunc(nexball_basketball)
 585 {
 586         nexball_mode |= NBM_BASKETBALL;
 587         this.classname = "nexball_basketball";
 588         if (!(balls & BALL_BASKET))
 589         {
 590                 /*
 591                 CVTOV(g_nexball_basketball_effects_default);
 592                 CVTOV(g_nexball_basketball_delay_hold);
 593                 CVTOV(g_nexball_basketball_delay_hold_forteam);
 594                 CVTOV(g_nexball_basketball_teamsteal);
 595                 */
 596                 autocvar_g_nexball_basketball_effects_default = autocvar_g_nexball_basketball_effects_default & BALL_EFFECTMASK;
 597         }
 598         if(!this.effects)
 599                 this.effects = autocvar_g_nexball_basketball_effects_default;
 600         this.solid = SOLID_TRIGGER;
 601         this.pushable = autocvar_g_nexball_basketball_jumppad;
 602         balls |= BALL_BASKET;
 603         this.bouncefactor = autocvar_g_nexball_basketball_bouncefactor;
 604         this.bouncestop = autocvar_g_nexball_basketball_bouncestop;
 605         SpawnBall(this);
 606 }
 607
 608 spawnfunc(nexball_football)
 609 {
 610         nexball_mode |= NBM_FOOTBALL;
 611         this.classname = "nexball_football";
 612         this.solid = SOLID_TRIGGER;
 613         balls |= BALL_FOOT;
 614         this.pushable = autocvar_g_nexball_football_jumppad;
 615         this.bouncefactor = autocvar_g_nexball_football_bouncefactor;
 616         this.bouncestop = autocvar_g_nexball_football_bouncestop;
 617         SpawnBall(this);
 618 }
 619
 620 bool nb_Goal_Customize(entity this, entity client)
 621 {
 622         entity e = WaypointSprite_getviewentity(client);
 623         entity wp_owner = this.owner;
 624         if(SAME_TEAM(e, wp_owner)) { return false; }
 625
 626         return true;
 627 }
 628
 629 void SpawnGoal(entity this)
 630 {
 631         if(!g_nexball) { delete(this); return; }
 632
 633         EXACTTRIGGER_INIT;
 634
 635         if(this.team != GOAL_OUT && Team_TeamToNumber(this.team) != -1)
 636         {
 637                 entity wp = WaypointSprite_SpawnFixed(WP_NbGoal, (this.absmin + this.absmax) * 0.5, this, sprite, RADARICON_NONE);
 638                 wp.colormod = ((this.team) ? Team_ColorRGB(this.team) : '1 0.5 0');
 639                 setcefc(this.sprite, nb_Goal_Customize);
 640         }
 641
 642         this.classname = "nexball_goal";
 643         if(this.noise == "")
 644                 this.noise = "ctf/respawn.wav";
 645         precache_sound(this.noise);
 646         settouch(this, GoalTouch);
 647 }
 648
 649 spawnfunc(nexball_redgoal)
 650 {
 651         this.team = NUM_TEAM_1;
 652         SpawnGoal(this);
 653 }
 654 spawnfunc(nexball_bluegoal)
 655 {
 656         this.team = NUM_TEAM_2;
 657         SpawnGoal(this);
 658 }
 659 spawnfunc(nexball_yellowgoal)
 660 {
 661         this.team = NUM_TEAM_3;
 662         SpawnGoal(this);
 663 }
 664 spawnfunc(nexball_pinkgoal)
 665 {
 666         this.team = NUM_TEAM_4;
 667         SpawnGoal(this);
 668 }
 669
 670 spawnfunc(nexball_fault)
 671 {
 672         this.team = GOAL_FAULT;
 673         if(this.noise == "")
 674                 this.noise = strzone(SND(TYPEHIT));
 675         SpawnGoal(this);
 676 }
 677
 678 spawnfunc(nexball_out)
 679 {
 680         this.team = GOAL_OUT;
 681         if(this.noise == "")
 682                 this.noise = strzone(SND(TYPEHIT));
 683         SpawnGoal(this);
 684 }
 685
 686 //
 687 //Spawnfuncs preserved for compatibility
 688 //
 689
 690 spawnfunc(ball)
 691 {
 692         spawnfunc_nexball_football(this);
 693 }
 694 spawnfunc(ball_football)
 695 {
 696         spawnfunc_nexball_football(this);
 697 }
 698 spawnfunc(ball_basketball)
 699 {
 700         spawnfunc_nexball_basketball(this);
 701 }
 702 // The "red goal" is defended by blue team. A ball in there counts as a point for red.
 703 spawnfunc(ball_redgoal)
 704 {
 705         spawnfunc_nexball_bluegoal(this);       // I blame Revenant
 706 }
 707 spawnfunc(ball_bluegoal)
 708 {
 709         spawnfunc_nexball_redgoal(this);        // but he didn't mean to cause trouble :p
 710 }
 711 spawnfunc(ball_fault)
 712 {
 713         spawnfunc_nexball_fault(this);
 714 }
 715 spawnfunc(ball_bound)
 716 {
 717         spawnfunc_nexball_out(this);
 718 }
 719
 720 //=======================//
 721 //        Weapon code     //
 722 //=======================//
 723
 724
 725 void W_Nexball_Think(entity this)
 726 {
 727         //dprint("W_Nexball_Think\n");
 728         //vector new_dir = steerlib_arrive(this.enemy.origin, 2500);
 729         vector new_dir = normalize(this.enemy.origin + '0 0 50' - this.origin);
 730         vector old_dir = normalize(this.velocity);
 731         float _speed = vlen(this.velocity);
 732         vector new_vel = normalize(old_dir + (new_dir * autocvar_g_nexball_safepass_turnrate)) * _speed;
 733         //vector new_vel = (new_dir * autocvar_g_nexball_safepass_turnrate
 734
 735         this.velocity = new_vel;
 736
 737         this.nextthink = time;
 738 }
 739
 740 void W_Nexball_Touch(entity this, entity toucher)
 741 {
 742         entity ball, attacker;
 743         attacker = this.owner;
 744         //this.think = func_null;
 745         //this.enemy = NULL;
 746
 747         PROJECTILE_TOUCH(this, toucher);
 748         if(attacker.team != toucher.team || autocvar_g_nexball_basketball_teamsteal)
 749                 if((ball = toucher.ballcarried) && !STAT(FROZEN, toucher) && !IS_DEAD(toucher) && (IS_PLAYER(attacker)))
 750                 {
 751                         toucher.velocity = toucher.velocity + normalize(this.velocity) * toucher.damageforcescale * autocvar_g_balance_nexball_secondary_force;
 752                         UNSET_ONGROUND(toucher);
 753                         if(!attacker.ballcarried)
 754                         {
 755                                 LogNB("stole", attacker);
 756                                 _sound(toucher, CH_TRIGGER, ball.noise2, VOL_BASE, ATTEN_NORM);
 757
 758                                 if(SAME_TEAM(attacker, toucher) && time > attacker.teamkill_complain)
 759                                 {
 760                                         attacker.teamkill_complain = time + 5;
 761                                         attacker.teamkill_soundtime = time + 0.4;
 762                                         attacker.teamkill_soundsource = toucher;
 763                                 }
 764
 765                                 GiveBall(attacker, toucher.ballcarried);
 766                         }
 767                 }
 768         delete(this);
 769 }
 770
 771 void W_Nexball_Attack(entity actor, .entity weaponentity, float t)
 772 {
 773         entity ball;
 774         float mul, mi, ma;
 775         if(!(ball = actor.ballcarried))
 776                 return;
 777
 778         W_SetupShot(actor, weaponentity, false, 4, SND_NB_SHOOT1, CH_WEAPON_A, 0);
 779         tracebox(w_shotorg, BALL_MINS, BALL_MAXS, w_shotorg, MOVE_WORLDONLY, NULL);
 780         if(trace_startsolid)
 781         {
 782                 if(actor.metertime)
 783                         actor.metertime = 0; // Shot failed, hide the power meter
 784                 return;
 785         }
 786
 787         //Calculate multiplier
 788         if(t < 0)
 789                 mul = 1;
 790         else
 791         {
 792                 mi = autocvar_g_nexball_basketball_meter_minpower;
 793                 ma = max(mi, autocvar_g_nexball_basketball_meter_maxpower); // avoid confusion
 794                 //One triangle wave period with 1 as max
 795                 mul = 2 * (t % g_nexball_meter_period) / g_nexball_meter_period;
 796                 if(mul > 1)
 797                         mul = 2 - mul;
 798                 mul = mi + (ma - mi) * mul; // range from the minimal power to the maximal power
 799         }
 800
 801         DropBall(ball, w_shotorg, W_CalculateProjectileVelocity(actor, actor.velocity, w_shotdir * autocvar_g_balance_nexball_primary_speed * mul, false));
 802
 803
 804         //TODO: use the speed_up cvar too ??
 805 }
 806
 807 vector trigger_push_calculatevelocity(vector org, entity tgt, float ht);
 808
 809 void W_Nexball_Attack2(entity actor, .entity weaponentity)
 810 {
 811         if(actor.ballcarried.enemy)
 812         {
 813                 entity _ball = actor.ballcarried;
 814                 W_SetupShot(actor, weaponentity, false, 4, SND_NB_SHOOT1, CH_WEAPON_A, 0);
 815                 DropBall(_ball, w_shotorg, trigger_push_calculatevelocity(_ball.origin, _ball.enemy, 32));
 816                 setthink(_ball, W_Nexball_Think);
 817                 _ball.nextthink = time;
 818                 return;
 819         }
 820
 821         if(!autocvar_g_nexball_tackling)
 822                 return;
 823
 824         W_SetupShot(actor, weaponentity, false, 2, SND_NB_SHOOT2, CH_WEAPON_A, 0);
 825         entity missile = new(ballstealer);
 826
 827         missile.owner = actor;
 828
 829         set_movetype(missile, MOVETYPE_FLY);
 830         PROJECTILE_MAKETRIGGER(missile);
 831
 832         //setmodel(missile, "models/elaser.mdl");  // precision set below
 833         setsize(missile, '0 0 0', '0 0 0');
 834         setorigin(missile, w_shotorg);
 835
 836         W_SetupProjVelocity_Basic(missile, autocvar_g_balance_nexball_secondary_speed, 0);
 837         missile.angles = vectoangles(missile.velocity);
 838         settouch(missile, W_Nexball_Touch);
 839         setthink(missile, SUB_Remove);
 840         missile.nextthink = time + autocvar_g_balance_nexball_secondary_lifetime; //FIXME: use a distance instead?
 841
 842         missile.effects = EF_BRIGHTFIELD | EF_LOWPRECISION;
 843         missile.flags = FL_PROJECTILE;
 844         IL_PUSH(g_projectiles, missile);
 845         IL_PUSH(g_bot_dodge, missile);
 846
 847         CSQCProjectile(missile, true, PROJECTILE_ELECTRO, true);
 848 }
 849
 850 bool ball_customize(entity this, entity client)
 851 {
 852         if(!this.owner)
 853         {
 854                 this.effects &= ~EF_FLAME;
 855                 this.scale = 1;
 856                 setcefc(this, func_null);
 857                 return true;
 858         }
 859
 860         if(client == this.owner)
 861         {
 862                 this.scale = autocvar_g_nexball_viewmodel_scale;
 863                 if(this.enemy)
 864                         this.effects |= EF_FLAME;
 865                 else
 866                         this.effects &= ~EF_FLAME;
 867         }
 868         else
 869         {
 870                 this.effects &= ~EF_FLAME;
 871                 this.scale = 1;
 872         }
 873
 874         return true;
 875 }
 876
 877 METHOD(BallStealer, wr_think, void(BallStealer thiswep, entity actor, .entity weaponentity, int fire))
 878 {
 879     TC(BallStealer, thiswep);
 880     if(fire & 1)
 881         if(weapon_prepareattack(thiswep, actor, weaponentity, false, autocvar_g_balance_nexball_primary_refire))
 882             if(autocvar_g_nexball_basketball_meter)
 883             {
 884                 if(actor.ballcarried && !actor.metertime)
 885                     actor.metertime = time;
 886                 else
 887                     weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, autocvar_g_balance_nexball_primary_animtime, w_ready);
 888             }
 889             else
 890             {
 891                 W_Nexball_Attack(actor, weaponentity, -1);
 892                 weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, autocvar_g_balance_nexball_primary_animtime, w_ready);
 893             }
 894     if(fire & 2)
 895         if(weapon_prepareattack(thiswep, actor, weaponentity, true, autocvar_g_balance_nexball_secondary_refire))
 896         {
 897             W_Nexball_Attack2(actor, weaponentity);
 898             weapon_thinkf(actor, weaponentity, WFRAME_FIRE2, autocvar_g_balance_nexball_secondary_animtime, w_ready);
 899         }
 900
 901     if(!(fire & 1) && actor.metertime && actor.ballcarried)
 902     {
 903         W_Nexball_Attack(actor, weaponentity, time - actor.metertime);
 904         // DropBall or stealing will set metertime back to 0
 905         weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, autocvar_g_balance_nexball_primary_animtime, w_ready);
 906     }
 907 }
 908
 909 METHOD(BallStealer, wr_setup, void(BallStealer this, entity actor))
 910 {
 911     TC(BallStealer, this);
 912     //weapon_setup(WEP_PORTO.m_id);
 913 }
 914
 915 METHOD(BallStealer, wr_checkammo1, bool(BallStealer this, entity actor))
 916 {
 917     TC(BallStealer, this);
 918     return true;
 919 }
 920
 921 METHOD(BallStealer, wr_checkammo2, bool(BallStealer this, entity actor))
 922 {
 923     TC(BallStealer, this);
 924     return true;
 925 }
 926
 927 void nb_DropBall(entity player)
 928 {
 929         if(player.ballcarried && g_nexball)
 930                 DropBall(player.ballcarried, player.origin, player.velocity);
 931 }
 932
 933 MUTATOR_HOOKFUNCTION(nb, ClientDisconnect)
 934 {
 935         entity player = M_ARGV(0, entity);
 936
 937         nb_DropBall(player);
 938 }
 939
 940 MUTATOR_HOOKFUNCTION(nb, PlayerDies)
 941 {
 942         entity frag_target = M_ARGV(2, entity);
 943
 944         nb_DropBall(frag_target);
 945 }
 946
 947 MUTATOR_HOOKFUNCTION(nb, MakePlayerObserver)
 948 {
 949         entity player = M_ARGV(0, entity);
 950
 951         nb_DropBall(player);
 952         return false;
 953 }
 954
 955 MUTATOR_HOOKFUNCTION(nb, PlayerPreThink)
 956 {
 957         entity player = M_ARGV(0, entity);
 958
 959         makevectors(player.v_angle);
 960         if(nexball_mode & NBM_BASKETBALL)
 961         {
 962                 if(player.ballcarried)
 963                 {
 964                         // 'view ball'
 965                         player.ballcarried.velocity = player.velocity;
 966                         setcefc(player.ballcarried, ball_customize);
 967
 968                         vector org = player.origin + player.view_ofs +
 969                                           v_forward * autocvar_g_nexball_viewmodel_offset.x +
 970                                           v_right * autocvar_g_nexball_viewmodel_offset.y +
 971                                           v_up * autocvar_g_nexball_viewmodel_offset.z;
 972                         setorigin(player.ballcarried, org);
 973
 974                         // 'safe passing'
 975                         if(autocvar_g_nexball_safepass_maxdist)
 976                         {
 977                                 if(player.ballcarried.wait < time && player.ballcarried.enemy)
 978                                 {
 979                                         //centerprint(player, sprintf("Lost lock on %s", player.ballcarried.enemy.netname));
 980                                         player.ballcarried.enemy = NULL;
 981                                 }
 982
 983
 984                                 //tracebox(player.origin + player.view_ofs, '-2 -2 -2', '2 2 2', player.origin + player.view_ofs + v_forward * autocvar_g_nexball_safepass_maxdist);
 985                                 crosshair_trace(player);
 986                                 if( trace_ent &&
 987                                         IS_CLIENT(trace_ent) &&
 988                                         !IS_DEAD(trace_ent) &&
 989                                         trace_ent.team == player.team &&
 990                                         vdist(trace_ent.origin - player.origin, <=, autocvar_g_nexball_safepass_maxdist) )
 991                                 {
 992
 993                                         //if(player.ballcarried.enemy != trace_ent)
 994                                         //      centerprint(player, sprintf("Locked to %s", trace_ent.netname));
 995                                         player.ballcarried.enemy = trace_ent;
 996                                         player.ballcarried.wait = time + autocvar_g_nexball_safepass_holdtime;
 997
 998
 999                                 }
1000                         }
1001                 }
1002                 else
1003                 {
1004                         .entity weaponentity = weaponentities[0]; // TODO
1005                         if(player.(weaponentity).weapons)
1006                         {
1007                                 player.weapons = player.(weaponentity).weapons;
1008                                 Weapon w = WEP_NEXBALL;
1009                                 w.wr_resetplayer(w, player);
1010                                 PS(player).m_switchweapon = player.(weaponentity).m_switchweapon;
1011                                 W_SwitchWeapon(player, PS(player).m_switchweapon);
1012
1013                                 player.(weaponentity).weapons = '0 0 0';
1014                         }
1015                 }
1016
1017         }
1018
1019         nexball_setstatus(player);
1020 }
1021
1022 MUTATOR_HOOKFUNCTION(nb, SpectateCopy)
1023 {
1024         entity spectatee = M_ARGV(0, entity);
1025         entity client = M_ARGV(1, entity);
1026
1027         client.metertime = spectatee.metertime;
1028 }
1029
1030 MUTATOR_HOOKFUNCTION(nb, PlayerSpawn)
1031 {
1032         entity player = M_ARGV(0, entity);
1033
1034         player.metertime = 0;
1035         .entity weaponentity = weaponentities[0];
1036         player.(weaponentity).weapons = '0 0 0';
1037
1038         if (nexball_mode & NBM_BASKETBALL)
1039                 player.weapons |= WEPSET(NEXBALL);
1040         else
1041                 player.weapons = '0 0 0';
1042
1043         return false;
1044 }
1045
1046 .float stat_sv_airspeedlimit_nonqw;
1047 .float stat_sv_maxspeed;
1048
1049 MUTATOR_HOOKFUNCTION(nb, PlayerPhysics)
1050 {
1051         entity player = M_ARGV(0, entity);
1052
1053         if(player.ballcarried)
1054         {
1055                 player.stat_sv_airspeedlimit_nonqw *= autocvar_g_nexball_basketball_carrier_highspeed;
1056                 player.stat_sv_maxspeed *= autocvar_g_nexball_basketball_carrier_highspeed;
1057         }
1058 }
1059
1060 MUTATOR_HOOKFUNCTION(nb, ForbidThrowCurrentWeapon)
1061 {
1062         entity player = M_ARGV(0, entity);
1063
1064         return PS(player).m_weapon == WEP_NEXBALL;
1065 }
1066
1067 MUTATOR_HOOKFUNCTION(nb, ForbidDropCurrentWeapon)
1068 {
1069         entity player = M_ARGV(0, entity);
1070
1071         return PS(player).m_weapon == WEP_MORTAR; // TODO: what is this for?
1072 }
1073
1074 MUTATOR_HOOKFUNCTION(nb, FilterItem)
1075 {
1076         entity item = M_ARGV(0, entity);
1077
1078         if(item.classname == "droppedweapon")
1079         if(item.weapon == WEP_NEXBALL.m_id)
1080                 return true;
1081
1082         return false;
1083 }
1084
1085 MUTATOR_HOOKFUNCTION(nb, ItemTouch)
1086 {
1087         entity item = M_ARGV(0, entity);
1088         entity toucher = M_ARGV(1, entity);
1089
1090         if(item.weapon && toucher.ballcarried)
1091                 return MUT_ITEMTOUCH_RETURN; // no new weapons for you, mister!
1092
1093         return MUT_ITEMTOUCH_CONTINUE;
1094 }
1095
1096 MUTATOR_HOOKFUNCTION(nb, CheckAllowedTeams)
1097 {
1098         M_ARGV(1, string) = "nexball_team";
1099         return true;
1100 }
1101
1102 MUTATOR_HOOKFUNCTION(nb, WantWeapon)
1103 {
1104         M_ARGV(1, float) = 0; // weapon is set a few lines later, apparently
1105         return true;
1106 }
1107
1108 MUTATOR_HOOKFUNCTION(nb, DropSpecialItems)
1109 {
1110         entity frag_target = M_ARGV(0, entity);
1111
1112         if(frag_target.ballcarried)
1113                 DropBall(frag_target.ballcarried, frag_target.origin, frag_target.velocity);
1114
1115         return false;
1116 }
1117
1118 MUTATOR_HOOKFUNCTION(nb, SendWaypoint)
1119 {
1120         M_ARGV(2, int) &= ~0x80;
1121 }
1122
1123 REGISTER_MUTATOR(nb, g_nexball)
1124 {
1125         MUTATOR_ONADD
1126         {
1127                 g_nexball_meter_period = autocvar_g_nexball_meter_period;
1128                 if(g_nexball_meter_period <= 0)
1129                         g_nexball_meter_period = 2; // avoid division by zero etc. due to silly users
1130                 g_nexball_meter_period = rint(g_nexball_meter_period * 32) / 32; //Round to 1/32ths to send as a byte multiplied by 32
1131
1132                 // General settings
1133                 /*
1134                 CVTOV(g_nexball_football_boost_forward);   //100
1135                 CVTOV(g_nexball_football_boost_up);             //200
1136                 CVTOV(g_nexball_delay_idle);                       //10
1137                 CVTOV(g_nexball_football_physics);               //0
1138                 */
1139                 radar_showennemies = autocvar_g_nexball_radar_showallplayers;
1140
1141                 InitializeEntity(NULL, nb_delayedinit, INITPRIO_GAMETYPE);
1142                 WEP_NEXBALL.spawnflags &= ~WEP_FLAG_MUTATORBLOCKED;
1143
1144                 ActivateTeamplay();
1145                 SetLimits(autocvar_g_nexball_goallimit, autocvar_g_nexball_goalleadlimit, autocvar_timelimit_override, -1);
1146                 have_team_spawns = -1; // request team spawns
1147         }
1148
1149         MUTATOR_ONROLLBACK_OR_REMOVE
1150         {
1151                 WEP_NEXBALL.spawnflags |= WEP_FLAG_MUTATORBLOCKED;
1152                 // we actually cannot roll back nb_delayedinit here
1153                 // BUT: we don't need to! If this gets called, adding always
1154                 // succeeds.
1155         }
1156
1157         MUTATOR_ONREMOVE
1158         {
1159                 LOG_INFO("This is a game type and it cannot be removed at runtime.");
1160                 return -1;
1161         }
1162
1163         return 0;
1164 }
1165
1166 #endif