qcsrc/common/gamemodes/gamemode/onslaught/sv_onslaught.qc

   1 #include "sv_onslaught.qh"
   2 #include "sv_controlpoint.qh"
   3 #include "sv_generator.qh"
   4
   5 bool g_onslaught;
   6
   7 float autocvar_g_onslaught_teleport_wait;
   8 bool autocvar_g_onslaught_spawn_at_controlpoints;
   9 bool autocvar_g_onslaught_spawn_at_generator;
  10 float autocvar_g_onslaught_cp_proxydecap;
  11 float autocvar_g_onslaught_cp_proxydecap_distance = 512;
  12 float autocvar_g_onslaught_cp_proxydecap_dps = 100;
  13 float autocvar_g_onslaught_spawn_at_controlpoints_chance = 0.5;
  14 float autocvar_g_onslaught_spawn_at_controlpoints_random;
  15 float autocvar_g_onslaught_spawn_at_generator_chance;
  16 float autocvar_g_onslaught_spawn_at_generator_random;
  17 float autocvar_g_onslaught_cp_buildhealth;
  18 float autocvar_g_onslaught_cp_buildtime;
  19 float autocvar_g_onslaught_cp_health;
  20 float autocvar_g_onslaught_cp_regen;
  21 float autocvar_g_onslaught_gen_health;
  22 float autocvar_g_onslaught_shield_force = 100;
  23 float autocvar_g_onslaught_allow_vehicle_touch;
  24 float autocvar_g_onslaught_round_timelimit;
  25 float autocvar_g_onslaught_warmup;
  26 float autocvar_g_onslaught_teleport_radius;
  27 float autocvar_g_onslaught_spawn_choose;
  28 float autocvar_g_onslaught_click_radius;
  29
  30 void FixSize(entity e);
  31 entity cam;
  32
  33 // =======================
  34 // CaptureShield Functions
  35 // =======================
  36
  37 bool clientcamera_send(entity this, entity to, int sf)
  38 {
  39         WriteHeader(MSG_ENTITY, ENT_ONSCAMERA);
  40
  41         WriteVector(MSG_ENTITY, this.origin);
  42
  43         WriteAngle(MSG_ENTITY, this.angles_x);
  44         WriteAngle(MSG_ENTITY, this.angles_y);
  45         WriteAngle(MSG_ENTITY, this.angles_z);
  46
  47         return true;
  48 }
  49
  50 bool ons_CaptureShield_Customize(entity this, entity client)
  51 {
  52         entity e = WaypointSprite_getviewentity(client);
  53
  54         if(!this.enemy.isshielded && (ons_ControlPoint_Attackable(this.enemy, e.team) > 0 || this.enemy.classname != "onslaught_controlpoint")) { return false; }
  55         if(SAME_TEAM(this, e)) { return false; }
  56
  57         return true;
  58 }
  59
  60 void ons_CaptureShield_Touch(entity this, entity toucher)
  61 {
  62         if(!this.enemy.isshielded && (ons_ControlPoint_Attackable(this.enemy, toucher.team) > 0 || this.enemy.classname != "onslaught_controlpoint")) { return; }
  63         if(!IS_PLAYER(toucher)) { return; }
  64         if(SAME_TEAM(toucher, this)) { return; }
  65
  66         vector mymid = (this.absmin + this.absmax) * 0.5;
  67         vector theirmid = (toucher.absmin + toucher.absmax) * 0.5;
  68
  69         Damage(toucher, this, this, 0, DEATH_HURTTRIGGER.m_id, DMG_NOWEP, mymid, normalize(theirmid - mymid) * ons_captureshield_force);
  70
  71         if(IS_REAL_CLIENT(toucher))
  72         {
  73                 play2(toucher, SND(ONS_DAMAGEBLOCKEDBYSHIELD));
  74
  75                 if(this.enemy.classname == "onslaught_generator")
  76                         Send_Notification(NOTIF_ONE, toucher, MSG_CENTER, CENTER_ONS_GENERATOR_SHIELDED);
  77                 else
  78                         Send_Notification(NOTIF_ONE, toucher, MSG_CENTER, CENTER_ONS_CONTROLPOINT_SHIELDED);
  79         }
  80 }
  81
  82 void ons_CaptureShield_Reset(entity this)
  83 {
  84         this.colormap = this.enemy.colormap;
  85         this.team = this.enemy.team;
  86 }
  87
  88 void ons_CaptureShield_Spawn(entity generator, bool is_generator)
  89 {
  90         entity shield = new(ons_captureshield);
  91         IL_PUSH(g_onsshields, shield);
  92
  93         shield.enemy = generator;
  94         shield.team = generator.team;
  95         shield.colormap = generator.colormap;
  96         shield.reset = ons_CaptureShield_Reset;
  97         settouch(shield, ons_CaptureShield_Touch);
  98         setcefc(shield, ons_CaptureShield_Customize);
  99         shield.effects = EF_ADDITIVE;
 100         set_movetype(shield, MOVETYPE_NOCLIP);
 101         shield.solid = SOLID_TRIGGER;
 102         shield.avelocity = '7 0 11';
 103         shield.scale = 1;
 104         shield.model = ((is_generator) ? "models/onslaught/generator_shield.md3" : "models/onslaught/controlpoint_shield.md3");
 105
 106         precache_model(shield.model);
 107         setorigin(shield, generator.origin);
 108         _setmodel(shield, shield.model);
 109         setsize(shield, shield.scale * shield.mins, shield.scale * shield.maxs);
 110 }
 111
 112
 113 // ==========
 114 // Junk Pile
 115 // ==========
 116
 117 void setmodel_fixsize(entity e, Model m)
 118 {
 119         setmodel(e, m);
 120         FixSize(e);
 121 }
 122
 123 void onslaught_updatelinks()
 124 {
 125         entity l;
 126         // first check if the game has ended
 127         LOG_DEBUG("--- updatelinks ---");
 128         // mark generators as being shielded and networked
 129         for(l = ons_worldgeneratorlist; l; l = l.ons_worldgeneratornext)
 130         {
 131                 if (l.iscaptured)
 132                         LOG_DEBUG(etos(l), " (generator) belongs to team ", ftos(l.team));
 133                 else
 134                         LOG_DEBUG(etos(l), " (generator) is destroyed");
 135                 l.islinked = l.iscaptured;
 136                 l.isshielded = l.iscaptured;
 137                 l.sprite.SendFlags |= 16;
 138         }
 139         // mark points as shielded and not networked
 140         for(l = ons_worldcplist; l; l = l.ons_worldcpnext)
 141         {
 142                 l.islinked = false;
 143                 l.isshielded = true;
 144                 l.aregensneighbor = 0;
 145                 l.arecpsneighbor = 0;
 146                 LOG_DEBUG(etos(l), " (point) belongs to team ", ftos(l.team));
 147                 l.sprite.SendFlags |= 16;
 148         }
 149         // flow power outward from the generators through the network
 150         bool stop = false;
 151         while (!stop)
 152         {
 153                 stop = true;
 154                 for(l = ons_worldlinklist; l; l = l.ons_worldlinknext)
 155                 {
 156                         // if both points are captured by the same team, and only one of
 157                         // them is powered, mark the other one as powered as well
 158                         if (l.enemy.iscaptured && l.goalentity.iscaptured)
 159                                 if (l.enemy.islinked != l.goalentity.islinked)
 160                                         if(SAME_TEAM(l.enemy, l.goalentity))
 161                                         {
 162                                                 if (!l.goalentity.islinked)
 163                                                 {
 164                                                         stop = false;
 165                                                         l.goalentity.islinked = true;
 166                                                         LOG_DEBUG(etos(l), " (link) is marking ", etos(l.goalentity), " (point) because its team matches ", etos(l.enemy), " (point)");
 167                                                 }
 168                                                 else if (!l.enemy.islinked)
 169                                                 {
 170                                                         stop = false;
 171                                                         l.enemy.islinked = true;
 172                                                         LOG_DEBUG(etos(l), " (link) is marking ", etos(l.enemy), " (point) because its team matches ", etos(l.goalentity), " (point)");
 173                                                 }
 174                                         }
 175                 }
 176         }
 177         // now that we know which points are powered we can mark their neighbors
 178         // as unshielded if team differs
 179         for(l = ons_worldlinklist; l; l = l.ons_worldlinknext)
 180         {
 181                 if (l.goalentity.islinked)
 182                 {
 183                         if(DIFF_TEAM(l.goalentity, l.enemy))
 184                         {
 185                                 LOG_DEBUG(etos(l), " (link) is unshielding ", etos(l.enemy), " (point) because its team does not match ", etos(l.goalentity), " (point)");
 186                                 l.enemy.isshielded = false;
 187                         }
 188                         if(l.goalentity.classname == "onslaught_generator")
 189                                 l.enemy.aregensneighbor |= BIT(l.goalentity.team);
 190                         else
 191                                 l.enemy.arecpsneighbor |= BIT(l.goalentity.team);
 192                 }
 193                 if (l.enemy.islinked)
 194                 {
 195                         if(DIFF_TEAM(l.goalentity, l.enemy))
 196                         {
 197                                 LOG_DEBUG(etos(l), " (link) is unshielding ", etos(l.goalentity), " (point) because its team does not match ", etos(l.enemy), " (point)");
 198                                 l.goalentity.isshielded = false;
 199                         }
 200                         if(l.enemy.classname == "onslaught_generator")
 201                                 l.goalentity.aregensneighbor |= BIT(l.enemy.team);
 202                         else
 203                                 l.goalentity.arecpsneighbor |= BIT(l.enemy.team);
 204                 }
 205         }
 206         // now update the generators
 207         for(l = ons_worldgeneratorlist; l; l = l.ons_worldgeneratornext)
 208         {
 209                 if (l.isshielded)
 210                 {
 211                         LOG_DEBUG(etos(l), " (generator) is shielded");
 212                         l.takedamage = DAMAGE_NO;
 213                         if(l.bot_attack)
 214                                 IL_REMOVE(g_bot_targets, l);
 215                         l.bot_attack = false;
 216                 }
 217                 else
 218                 {
 219                         LOG_DEBUG(etos(l), " (generator) is not shielded");
 220                         l.takedamage = DAMAGE_AIM;
 221                         if(!l.bot_attack)
 222                                 IL_PUSH(g_bot_targets, l);
 223                         l.bot_attack = true;
 224                 }
 225
 226                 ons_Generator_UpdateSprite(l);
 227         }
 228         // now update the takedamage and alpha variables on control point icons
 229         for(l = ons_worldcplist; l; l = l.ons_worldcpnext)
 230         {
 231                 if (l.isshielded)
 232                 {
 233                         LOG_DEBUG(etos(l), " (point) is shielded");
 234                         if (l.goalentity)
 235                         {
 236                                 l.goalentity.takedamage = DAMAGE_NO;
 237                                 if(l.goalentity.bot_attack)
 238                                         IL_REMOVE(g_bot_targets, l.goalentity);
 239                                 l.goalentity.bot_attack = false;
 240                         }
 241                 }
 242                 else
 243                 {
 244                         LOG_DEBUG(etos(l), " (point) is not shielded");
 245                         if (l.goalentity)
 246                         {
 247                                 l.goalentity.takedamage = DAMAGE_AIM;
 248                                 if(!l.goalentity.bot_attack)
 249                                         IL_PUSH(g_bot_targets, l.goalentity);
 250                                 l.goalentity.bot_attack = true;
 251                         }
 252                 }
 253                 ons_ControlPoint_UpdateSprite(l);
 254         }
 255         IL_EACH(g_onsshields, true,
 256         {
 257                 it.team = it.enemy.team;
 258                 it.colormap = it.enemy.colormap;
 259         });
 260 }
 261
 262
 263 // ===================
 264 // Main Link Functions
 265 // ===================
 266
 267 bool ons_Link_Send(entity this, entity to, int sendflags)
 268 {
 269         WriteHeader(MSG_ENTITY, ENT_CLIENT_RADARLINK);
 270         WriteByte(MSG_ENTITY, sendflags);
 271         if(sendflags & 1)
 272         {
 273                 WriteVector(MSG_ENTITY, this.goalentity.origin);
 274         }
 275         if(sendflags & 2)
 276         {
 277                 WriteVector(MSG_ENTITY, this.enemy.origin);
 278         }
 279         if(sendflags & 4)
 280         {
 281                 WriteByte(MSG_ENTITY, this.clientcolors); // which is goalentity's color + enemy's color * 16
 282         }
 283         return true;
 284 }
 285
 286 void ons_Link_CheckUpdate(entity this)
 287 {
 288         // TODO check if the two sides have moved (currently they won't move anyway)
 289         float cc = 0, cc1 = 0, cc2 = 0;
 290
 291         if(this.goalentity.islinked || this.goalentity.iscaptured) { cc1 = (this.goalentity.team - 1) * 0x01; }
 292         if(this.enemy.islinked || this.enemy.iscaptured) { cc2 = (this.enemy.team - 1) * 0x10; }
 293
 294         cc = cc1 + cc2;
 295
 296         if(cc != this.clientcolors)
 297         {
 298                 this.clientcolors = cc;
 299                 this.SendFlags |= 4;
 300         }
 301
 302         this.nextthink = time;
 303 }
 304
 305 void ons_DelayedLinkSetup(entity this)
 306 {
 307         this.goalentity = find(NULL, targetname, this.target);
 308         this.enemy = find(NULL, targetname, this.target2);
 309         if(!this.goalentity) { objerror(this, "can not find target\n"); }
 310         if(!this.enemy) { objerror(this, "can not find target2\n"); }
 311
 312         LOG_DEBUG(etos(this.goalentity), " linked with ", etos(this.enemy));
 313         this.SendFlags |= 3;
 314         setthink(this, ons_Link_CheckUpdate);
 315         this.nextthink = time;
 316 }
 317
 318
 319 // =============================
 320 // Main Control Point Functions
 321 // =============================
 322
 323 int ons_ControlPoint_CanBeLinked(entity cp, int teamnumber)
 324 {
 325         if(cp.aregensneighbor & BIT(teamnumber)) return 2;
 326         if(cp.arecpsneighbor & BIT(teamnumber)) return 1;
 327
 328         return 0;
 329 }
 330
 331 int ons_ControlPoint_Attackable(entity cp, int teamnumber)
 332         // -2: SAME TEAM, attackable by enemy!
 333         // -1: SAME TEAM!
 334         // 0: off limits
 335         // 1: attack it
 336         // 2: touch it
 337         // 3: attack it (HIGH PRIO)
 338         // 4: touch it (HIGH PRIO)
 339 {
 340         int a;
 341
 342         if(cp.isshielded)
 343         {
 344                 return 0;
 345         }
 346         else if(cp.goalentity)
 347         {
 348                 // if there's already an icon built, nothing happens
 349                 if(cp.team == teamnumber)
 350                 {
 351                         a = ons_ControlPoint_CanBeLinked(cp, teamnumber);
 352                         if(a) // attackable by enemy?
 353                                 return -2; // EMERGENCY!
 354                         return -1;
 355                 }
 356                 // we know it can be linked, so no need to check
 357                 // but...
 358                 a = ons_ControlPoint_CanBeLinked(cp, teamnumber);
 359                 if(a == 2) // near our generator?
 360                         return 3; // EMERGENCY!
 361                 return 1;
 362         }
 363         else
 364         {
 365                 // free point
 366                 if(ons_ControlPoint_CanBeLinked(cp, teamnumber))
 367                 {
 368                         a = ons_ControlPoint_CanBeLinked(cp, teamnumber); // why was this here NUM_TEAM_1 + NUM_TEAM_2 - t
 369                         if(a == 2)
 370                                 return 4; // GET THIS ONE NOW!
 371                         else
 372                                 return 2; // TOUCH ME
 373                 }
 374         }
 375         return 0;
 376 }
 377
 378 void ons_ControlPoint_Icon_Damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, .entity weaponentity, vector hitloc, vector force)
 379 {
 380         if(damage <= 0) { return; }
 381
 382         if (this.owner.isshielded)
 383         {
 384                 // this is protected by a shield, so ignore the damage
 385                 if (time > this.pain_finished)
 386                         if (IS_PLAYER(attacker))
 387                         {
 388                                 play2(attacker, SND(ONS_DAMAGEBLOCKEDBYSHIELD));
 389                                 this.pain_finished = time + 1;
 390                                 attacker.typehitsound += 1; // play both sounds (shield is way too quiet)
 391                         }
 392
 393                 return;
 394         }
 395
 396         if(IS_PLAYER(attacker))
 397         if(time - ons_notification_time[this.team] > 10)
 398         {
 399                 play2team(this.team, SND(ONS_CONTROLPOINT_UNDERATTACK));
 400                 ons_notification_time[this.team] = time;
 401         }
 402
 403         SetResourceAmountExplicit(this, RESOURCE_HEALTH, GetResourceAmount(this, RESOURCE_HEALTH) - damage);
 404         if(this.owner.iscaptured)
 405                 WaypointSprite_UpdateHealth(this.owner.sprite, GetResourceAmount(this, RESOURCE_HEALTH));
 406         else
 407                 WaypointSprite_UpdateBuildFinished(this.owner.sprite, time + (this.max_health - GetResourceAmount(this, RESOURCE_HEALTH)) / (this.count / ONS_CP_THINKRATE));
 408         this.pain_finished = time + 1;
 409         // particles on every hit
 410         pointparticles(EFFECT_SPARKS, hitloc, force*-1, 1);
 411         //sound on every hit
 412         if (random() < 0.5)
 413                 sound(this, CH_TRIGGER, SND_ONS_HIT1, VOL_BASE+0.3, ATTEN_NORM);
 414         else
 415                 sound(this, CH_TRIGGER, SND_ONS_HIT2, VOL_BASE+0.3, ATTEN_NORM);
 416
 417         if (GetResourceAmount(this, RESOURCE_HEALTH) < 0)
 418         {
 419                 sound(this, CH_TRIGGER, SND_GRENADE_IMPACT, VOL_BASE, ATTEN_NORM);
 420                 pointparticles(EFFECT_ROCKET_EXPLODE, this.origin, '0 0 0', 1);
 421                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_ONSLAUGHT_CPDESTROYED), this.owner.message, attacker.netname);
 422
 423                 GameRules_scoring_add(attacker, ONS_TAKES, 1);
 424                 GameRules_scoring_add(attacker, SCORE, 10);
 425
 426                 this.owner.goalentity = NULL;
 427                 this.owner.islinked = false;
 428                 this.owner.iscaptured = false;
 429                 this.owner.team = 0;
 430                 this.owner.colormap = 1024;
 431
 432                 WaypointSprite_UpdateMaxHealth(this.owner.sprite, 0);
 433
 434                 onslaught_updatelinks();
 435
 436                 // Use targets now (somebody make sure this is in the right place..)
 437                 SUB_UseTargets(this.owner, this, NULL);
 438
 439                 this.owner.waslinked = this.owner.islinked;
 440                 if(this.owner.model != "models/onslaught/controlpoint_pad.md3")
 441                         setmodel_fixsize(this.owner, MDL_ONS_CP_PAD1);
 442                 //setsize(this, '-32 -32 0', '32 32 8');
 443
 444                 delete(this);
 445         }
 446
 447         this.SendFlags |= CPSF_STATUS;
 448 }
 449
 450 void ons_ControlPoint_Icon_Think(entity this)
 451 {
 452         this.nextthink = time + ONS_CP_THINKRATE;
 453
 454         if(autocvar_g_onslaught_cp_proxydecap)
 455         {
 456                 int _enemy_count = 0;
 457                 int _friendly_count = 0;
 458
 459                 FOREACH_CLIENT(IS_PLAYER(it) && !IS_DEAD(it), {
 460                         if(vdist(it.origin - this.origin, <, autocvar_g_onslaught_cp_proxydecap_distance))
 461                         {
 462                                 if(SAME_TEAM(it, this))
 463                                         ++_friendly_count;
 464                                 else
 465                                         ++_enemy_count;
 466                         }
 467                 });
 468
 469                 _friendly_count = _friendly_count * (autocvar_g_onslaught_cp_proxydecap_dps * ONS_CP_THINKRATE);
 470                 _enemy_count = _enemy_count * (autocvar_g_onslaught_cp_proxydecap_dps * ONS_CP_THINKRATE);
 471
 472                 SetResourceAmountExplicit(this, RESOURCE_HEALTH, bound(0, GetResourceAmount(this, RESOURCE_HEALTH) + (_friendly_count - _enemy_count), this.max_health));
 473                 this.SendFlags |= CPSF_STATUS;
 474                 if(GetResourceAmount(this, RESOURCE_HEALTH) <= 0)
 475                 {
 476                         ons_ControlPoint_Icon_Damage(this, this, this, 1, 0, DMG_NOWEP, this.origin, '0 0 0');
 477                         return;
 478                 }
 479         }
 480
 481         if (time > this.pain_finished + 5)
 482         {
 483                 if(GetResourceAmount(this, RESOURCE_HEALTH) < this.max_health)
 484                 {
 485                         SetResourceAmountExplicit(this, RESOURCE_HEALTH, GetResourceAmount(this, RESOURCE_HEALTH) + this.count);
 486                         if (GetResourceAmount(this, RESOURCE_HEALTH) >= this.max_health)
 487                                 SetResourceAmountExplicit(this, RESOURCE_HEALTH, this.max_health);
 488                         WaypointSprite_UpdateHealth(this.owner.sprite, GetResourceAmount(this, RESOURCE_HEALTH));
 489                 }
 490         }
 491
 492         if(this.owner.islinked != this.owner.waslinked)
 493         {
 494                 // unteam the spawnpoint if needed
 495                 int t = this.owner.team;
 496                 if(!this.owner.islinked)
 497                         this.owner.team = 0;
 498
 499                 SUB_UseTargets(this.owner, this, NULL);
 500
 501                 this.owner.team = t;
 502
 503                 this.owner.waslinked = this.owner.islinked;
 504         }
 505
 506         // damaged fx
 507         if(random() < 0.6 - GetResourceAmount(this, RESOURCE_HEALTH) / this.max_health)
 508         {
 509                 Send_Effect(EFFECT_ELECTRIC_SPARKS, this.origin + randompos('-10 -10 -20', '10 10 20'), '0 0 0', 1);
 510
 511                 if(random() > 0.8)
 512                         sound(this, CH_PAIN, SND_ONS_SPARK1, VOL_BASE, ATTEN_NORM);
 513                 else if (random() > 0.5)
 514                         sound(this, CH_PAIN, SND_ONS_SPARK2, VOL_BASE, ATTEN_NORM);
 515         }
 516 }
 517
 518 void ons_ControlPoint_Icon_BuildThink(entity this)
 519 {
 520         int a;
 521
 522         this.nextthink = time + ONS_CP_THINKRATE;
 523
 524         // only do this if there is power
 525         a = ons_ControlPoint_CanBeLinked(this.owner, this.owner.team);
 526         if(!a)
 527                 return;
 528
 529         SetResourceAmountExplicit(this, RESOURCE_HEALTH, GetResourceAmount(this, RESOURCE_HEALTH) + this.count);
 530
 531         this.SendFlags |= CPSF_STATUS;
 532
 533         if (GetResourceAmount(this, RESOURCE_HEALTH) >= this.max_health)
 534         {
 535                 SetResourceAmountExplicit(this, RESOURCE_HEALTH, this.max_health);
 536                 this.count = autocvar_g_onslaught_cp_regen * ONS_CP_THINKRATE; // slow repair rate from now on
 537                 setthink(this, ons_ControlPoint_Icon_Think);
 538                 sound(this, CH_TRIGGER, SND_ONS_CONTROLPOINT_BUILT, VOL_BASE, ATTEN_NORM);
 539                 this.owner.iscaptured = true;
 540                 this.solid = SOLID_BBOX;
 541
 542                 Send_Effect(EFFECT_CAP(this.owner.team), this.owner.origin, '0 0 0', 1);
 543
 544                 WaypointSprite_UpdateMaxHealth(this.owner.sprite, this.max_health);
 545                 WaypointSprite_UpdateHealth(this.owner.sprite, GetResourceAmount(this, RESOURCE_HEALTH));
 546
 547                 if(IS_PLAYER(this.owner.ons_toucher))
 548                 {
 549                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_ONSLAUGHT_CAPTURE, this.owner.ons_toucher.netname, this.owner.message);
 550                         Send_Notification(NOTIF_ALL_EXCEPT, this.owner.ons_toucher, MSG_CENTER, APP_TEAM_NUM(this.owner.ons_toucher.team, CENTER_ONS_CAPTURE_TEAM), this.owner.message);
 551                         Send_Notification(NOTIF_ONE, this.owner.ons_toucher, MSG_CENTER, CENTER_ONS_CAPTURE, this.owner.message);
 552                         GameRules_scoring_add(this.owner.ons_toucher, ONS_CAPS, 1);
 553                         GameRules_scoring_add_team(this.owner.ons_toucher, SCORE, 10);
 554                 }
 555
 556                 this.owner.ons_toucher = NULL;
 557
 558                 onslaught_updatelinks();
 559
 560                 // Use targets now (somebody make sure this is in the right place..)
 561                 SUB_UseTargets(this.owner, this, NULL);
 562
 563                 this.SendFlags |= CPSF_SETUP;
 564         }
 565         if(this.owner.model != MDL_ONS_CP_PAD2.model_str())
 566                 setmodel_fixsize(this.owner, MDL_ONS_CP_PAD2);
 567
 568         if(random() < 0.9 - GetResourceAmount(this, RESOURCE_HEALTH) / this.max_health)
 569                 Send_Effect(EFFECT_RAGE, this.origin + 10 * randomvec(), '0 0 -1', 1);
 570 }
 571
 572 void onslaught_controlpoint_icon_link(entity e, void(entity this) spawnproc);
 573
 574 void ons_ControlPoint_Icon_Spawn(entity cp, entity player)
 575 {
 576         entity e = new(onslaught_controlpoint_icon);
 577
 578         setsize(e, CPICON_MIN, CPICON_MAX);
 579         setorigin(e, cp.origin + CPICON_OFFSET);
 580
 581         e.owner = cp;
 582         e.max_health = autocvar_g_onslaught_cp_health;
 583         SetResourceAmountExplicit(e, RESOURCE_HEALTH, autocvar_g_onslaught_cp_buildhealth);
 584         e.solid = SOLID_NOT;
 585         e.takedamage = DAMAGE_AIM;
 586         e.bot_attack = true;
 587         IL_PUSH(g_bot_targets, e);
 588         e.event_damage = ons_ControlPoint_Icon_Damage;
 589         e.team = player.team;
 590         e.colormap = 1024 + (e.team - 1) * 17;
 591         e.count = (e.max_health - GetResourceAmount(e, RESOURCE_HEALTH)) * ONS_CP_THINKRATE / autocvar_g_onslaught_cp_buildtime; // how long it takes to build
 592
 593         sound(e, CH_TRIGGER, SND_ONS_CONTROLPOINT_BUILD, VOL_BASE, ATTEN_NORM);
 594
 595         cp.goalentity = e;
 596         cp.team = e.team;
 597         cp.colormap = e.colormap;
 598
 599         Send_Effect(EFFECT_FLAG_TOUCH(player.team), e.origin, '0 0 0', 1);
 600
 601         WaypointSprite_UpdateBuildFinished(cp.sprite, time + (e.max_health - GetResourceAmount(e, RESOURCE_HEALTH)) / (e.count / ONS_CP_THINKRATE));
 602         WaypointSprite_UpdateRule(cp.sprite,cp.team,SPRITERULE_TEAMPLAY);
 603         cp.sprite.SendFlags |= 16;
 604
 605         onslaught_controlpoint_icon_link(e, ons_ControlPoint_Icon_BuildThink);
 606 }
 607
 608 entity ons_ControlPoint_Waypoint(entity e)
 609 {
 610         if(e.team)
 611         {
 612                 int a = ons_ControlPoint_Attackable(e, e.team);
 613
 614                 if(a == -2) { return WP_OnsCPDefend; } // defend now
 615                 if(a == -1 || a == 1 || a == 2) { return WP_OnsCP; } // touch
 616                 if(a == 3 || a == 4) { return WP_OnsCPAttack; } // attack
 617         }
 618         else
 619                 return WP_OnsCP;
 620
 621         return WP_Null;
 622 }
 623
 624 void ons_ControlPoint_UpdateSprite(entity e)
 625 {
 626         entity s1 = ons_ControlPoint_Waypoint(e);
 627         WaypointSprite_UpdateSprites(e.sprite, s1, s1, s1);
 628
 629         bool sh;
 630         sh = !(ons_ControlPoint_CanBeLinked(e, NUM_TEAM_1) || ons_ControlPoint_CanBeLinked(e, NUM_TEAM_2) || ons_ControlPoint_CanBeLinked(e, NUM_TEAM_3) || ons_ControlPoint_CanBeLinked(e, NUM_TEAM_4));
 631
 632         if(e.lastteam != e.team + 2 || e.lastshielded != sh || e.iscaptured != e.lastcaptured)
 633         {
 634                 if(e.iscaptured) // don't mess up build bars!
 635                 {
 636                         if(sh)
 637                         {
 638                                 WaypointSprite_UpdateMaxHealth(e.sprite, 0);
 639                         }
 640                         else
 641                         {
 642                                 WaypointSprite_UpdateMaxHealth(e.sprite, e.goalentity.max_health);
 643                                 WaypointSprite_UpdateHealth(e.sprite, GetResourceAmount(e.goalentity, RESOURCE_HEALTH));
 644                         }
 645                 }
 646                 if(e.lastshielded)
 647                 {
 648                         if(e.team)
 649                                 WaypointSprite_UpdateTeamRadar(e.sprite, RADARICON_CONTROLPOINT, 0.5 * colormapPaletteColor(e.team - 1, false));
 650                         else
 651                                 WaypointSprite_UpdateTeamRadar(e.sprite, RADARICON_CONTROLPOINT, '0.5 0.5 0.5');
 652                 }
 653                 else
 654                 {
 655                         if(e.team)
 656                                 WaypointSprite_UpdateTeamRadar(e.sprite, RADARICON_CONTROLPOINT, colormapPaletteColor(e.team - 1, false));
 657                         else
 658                                 WaypointSprite_UpdateTeamRadar(e.sprite, RADARICON_CONTROLPOINT, '0.75 0.75 0.75');
 659                 }
 660                 WaypointSprite_Ping(e.sprite);
 661
 662                 e.lastteam = e.team + 2;
 663                 e.lastshielded = sh;
 664                 e.lastcaptured = e.iscaptured;
 665         }
 666 }
 667
 668 void ons_ControlPoint_Touch(entity this, entity toucher)
 669 {
 670         int attackable;
 671
 672         if(IS_VEHICLE(toucher) && toucher.owner)
 673         if(autocvar_g_onslaught_allow_vehicle_touch)
 674                 toucher = toucher.owner;
 675         else
 676                 return;
 677
 678         if(!IS_PLAYER(toucher)) { return; }
 679         if(STAT(FROZEN, toucher)) { return; }
 680         if(IS_DEAD(toucher)) { return; }
 681
 682         if ( SAME_TEAM(this,toucher) )
 683         if ( this.iscaptured )
 684         {
 685                 if(time <= toucher.teleport_antispam)
 686                         Send_Notification(NOTIF_ONE, toucher, MSG_CENTER, CENTER_ONS_TELEPORT_ANTISPAM, rint(toucher.teleport_antispam - time));
 687                 else
 688                         Send_Notification(NOTIF_ONE, toucher, MSG_CENTER, CENTER_ONS_TELEPORT);
 689         }
 690
 691         attackable = ons_ControlPoint_Attackable(this, toucher.team);
 692         if(attackable != 2 && attackable != 4)
 693                 return;
 694         // we've verified that this player has a legitimate claim to this point,
 695         // so start building the captured point icon (which only captures this
 696         // point if it successfully builds without being destroyed first)
 697         ons_ControlPoint_Icon_Spawn(this, toucher);
 698
 699         this.ons_toucher = toucher;
 700
 701         onslaught_updatelinks();
 702 }
 703
 704 void ons_ControlPoint_Think(entity this)
 705 {
 706         this.nextthink = time + ONS_CP_THINKRATE;
 707         CSQCMODEL_AUTOUPDATE(this);
 708 }
 709
 710 void ons_ControlPoint_Reset(entity this)
 711 {
 712         if(this.goalentity)
 713                 delete(this.goalentity);
 714
 715         this.goalentity = NULL;
 716         this.team = 0;
 717         this.colormap = 1024;
 718         this.iscaptured = false;
 719         this.islinked = false;
 720         this.isshielded = true;
 721         setthink(this, ons_ControlPoint_Think);
 722         this.ons_toucher = NULL;
 723         this.nextthink = time + ONS_CP_THINKRATE;
 724         setmodel_fixsize(this, MDL_ONS_CP_PAD1);
 725
 726         WaypointSprite_UpdateMaxHealth(this.sprite, 0);
 727         WaypointSprite_UpdateRule(this.sprite,this.team,SPRITERULE_TEAMPLAY);
 728
 729         onslaught_updatelinks();
 730
 731         SUB_UseTargets(this, this, NULL); // to reset the structures, playerspawns etc.
 732
 733         CSQCMODEL_AUTOUPDATE(this);
 734 }
 735
 736 void ons_DelayedControlPoint_Setup(entity this)
 737 {
 738         onslaught_updatelinks();
 739
 740         // captureshield setup
 741         ons_CaptureShield_Spawn(this, false);
 742
 743         CSQCMODEL_AUTOINIT(this);
 744 }
 745
 746 void ons_ControlPoint_Setup(entity cp)
 747 {
 748         // main setup
 749         cp.ons_worldcpnext = ons_worldcplist; // link control point into ons_worldcplist
 750         ons_worldcplist = cp;
 751
 752         cp.netname = "Control point";
 753         cp.team = 0;
 754         cp.solid = SOLID_BBOX;
 755         set_movetype(cp, MOVETYPE_NONE);
 756         settouch(cp, ons_ControlPoint_Touch);
 757         setthink(cp, ons_ControlPoint_Think);
 758         cp.nextthink = time + ONS_CP_THINKRATE;
 759         cp.reset = ons_ControlPoint_Reset;
 760         cp.colormap = 1024;
 761         cp.iscaptured = false;
 762         cp.islinked = false;
 763         cp.isshielded = true;
 764
 765         if(cp.message == "") { cp.message = "a"; }
 766
 767         // appearence
 768         setmodel_fixsize(cp, MDL_ONS_CP_PAD1);
 769
 770         // control point placement
 771         if((cp.spawnflags & 1) || cp.noalign) // don't drop to floor, just stay at fixed location
 772         {
 773                 cp.noalign = true;
 774                 set_movetype(cp, MOVETYPE_NONE);
 775         }
 776         else // drop to floor, automatically find a platform and set that as spawn origin
 777         {
 778                 setorigin(cp, cp.origin + '0 0 20');
 779                 cp.noalign = false;
 780                 droptofloor(cp);
 781                 set_movetype(cp, MOVETYPE_TOSS);
 782         }
 783
 784         // waypointsprites
 785         WaypointSprite_SpawnFixed(WP_Null, cp.origin + CPGEN_WAYPOINT_OFFSET, cp, sprite, RADARICON_NONE);
 786         WaypointSprite_UpdateRule(cp.sprite, cp.team, SPRITERULE_TEAMPLAY);
 787
 788         InitializeEntity(cp, ons_DelayedControlPoint_Setup, INITPRIO_SETLOCATION);
 789 }
 790
 791
 792 // =========================
 793 // Main Generator Functions
 794 // =========================
 795
 796 entity ons_Generator_Waypoint(entity e)
 797 {
 798         if (e.isshielded)
 799                 return WP_OnsGenShielded;
 800         return WP_OnsGen;
 801 }
 802
 803 void ons_Generator_UpdateSprite(entity e)
 804 {
 805         entity s1 = ons_Generator_Waypoint(e);
 806         WaypointSprite_UpdateSprites(e.sprite, s1, s1, s1);
 807
 808         if(e.lastteam != e.team + 2 || e.lastshielded != e.isshielded)
 809         {
 810                 e.lastteam = e.team + 2;
 811                 e.lastshielded = e.isshielded;
 812                 if(e.lastshielded)
 813                 {
 814                         if(e.team)
 815                                 WaypointSprite_UpdateTeamRadar(e.sprite, RADARICON_GENERATOR, 0.5 * colormapPaletteColor(e.team - 1, false));
 816                         else
 817                                 WaypointSprite_UpdateTeamRadar(e.sprite, RADARICON_GENERATOR, '0.5 0.5 0.5');
 818                 }
 819                 else
 820                 {
 821                         if(e.team)
 822                                 WaypointSprite_UpdateTeamRadar(e.sprite, RADARICON_GENERATOR, colormapPaletteColor(e.team - 1, false));
 823                         else
 824                                 WaypointSprite_UpdateTeamRadar(e.sprite, RADARICON_GENERATOR, '0.75 0.75 0.75');
 825                 }
 826                 WaypointSprite_Ping(e.sprite);
 827         }
 828 }
 829
 830 void ons_camSetup(entity this)
 831 {
 832         vector dir;
 833         vector ang = '0 0 0';
 834         vector best_ang = '0 0 0';
 835         float best_trace_fraction = 0;
 836         while(ang.y < 360)
 837         {
 838                 dir = vec2(cos(ang.y * DEG2RAD), sin(ang.y * DEG2RAD));
 839                 dir *= 500;
 840                 traceline(this.origin, this.origin - dir, MOVE_WORLDONLY, this);
 841                 if(trace_fraction > best_trace_fraction)
 842                 {
 843                         best_trace_fraction = trace_fraction;
 844                         best_ang = ang;
 845                         if(trace_fraction == 1)
 846                                 break;
 847                 }
 848                 ang.y += 90;
 849                 if(ang.y == 360)
 850                         ang.y = 45;
 851         }
 852         cam.origin = this.origin;
 853         setorigin(cam, cam.origin);
 854         cam.angles = best_ang;
 855         Net_LinkEntity(cam, false, 0, clientcamera_send);
 856
 857         FOREACH_CLIENT(true, it.clientcamera = cam;);
 858
 859         WriteByte(MSG_ALL, SVC_SETVIEWANGLES);
 860         WriteAngle(MSG_ALL, cam.angles_x);
 861         WriteAngle(MSG_ALL, cam.angles_y);
 862         WriteAngle(MSG_ALL, cam.angles_z);
 863 }
 864
 865 void ons_GeneratorDamage(entity this, entity inflictor, entity attacker, float damage, int deathtype, .entity weaponentity, vector hitloc, vector force)
 866 {
 867         if(damage <= 0) return;
 868         if(warmup_stage || game_stopped) return;
 869         if(!round_handler_IsRoundStarted()) return;
 870
 871         if (attacker != this)
 872         {
 873                 if (this.isshielded)
 874                 {
 875                         // generator is protected by a shield, so ignore the damage
 876                         if (time > this.pain_finished)
 877                                 if (IS_PLAYER(attacker))
 878                                 {
 879                                         play2(attacker, SND(ONS_DAMAGEBLOCKEDBYSHIELD));
 880                                         attacker.typehitsound += 1;
 881                                         this.pain_finished = time + 1;
 882                                 }
 883                         return;
 884                 }
 885                 if (time > this.pain_finished)
 886                 {
 887                         this.pain_finished = time + 10;
 888                         FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it) && SAME_TEAM(it, this), Send_Notification(NOTIF_ONE, it, MSG_CENTER, CENTER_GENERATOR_UNDERATTACK));
 889                         play2team(this.team, SND(ONS_GENERATOR_UNDERATTACK));
 890                 }
 891         }
 892         SetResourceAmountExplicit(this, RESOURCE_HEALTH, GetResourceAmount(this, RESOURCE_HEALTH) - damage);
 893         WaypointSprite_UpdateHealth(this.sprite, GetResourceAmount(this, RESOURCE_HEALTH));
 894         // choose an animation frame based on health
 895         this.frame = 10 * bound(0, (1 - GetResourceAmount(this, RESOURCE_HEALTH) / this.max_health), 1);
 896         // see if the generator is still functional, or dying
 897         if (GetResourceAmount(this, RESOURCE_HEALTH) > 0)
 898         {
 899                 this.lasthealth = GetResourceAmount(this, RESOURCE_HEALTH);
 900         }
 901         else
 902         {
 903                 if (attacker == this)
 904                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_ONSLAUGHT_GENDESTROYED_OVERTIME));
 905                 else
 906                 {
 907                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_ONSLAUGHT_GENDESTROYED));
 908                         GameRules_scoring_add(attacker, SCORE, 100);
 909                 }
 910                 this.iscaptured = false;
 911                 this.islinked = false;
 912                 this.isshielded = false;
 913                 this.takedamage = DAMAGE_NO; // can't be hurt anymore
 914                 this.event_damage = func_null; // won't do anything if hurt
 915                 this.count = 0; // reset counter
 916                 setthink(this, func_null);
 917                 this.nextthink = 0;
 918                 //this.think(); // do the first explosion now
 919
 920                 WaypointSprite_UpdateMaxHealth(this.sprite, 0);
 921                 WaypointSprite_Ping(this.sprite);
 922                 //WaypointSprite_Kill(this.sprite); // can't do this yet, code too poor
 923
 924                 onslaught_updatelinks();
 925
 926                 ons_camSetup(this);
 927         }
 928
 929         // Throw some flaming gibs on damage, more damage = more chance for gib
 930         if(random() < damage/220)
 931         {
 932                 sound(this, CH_TRIGGER, SND_ROCKET_IMPACT, VOL_BASE, ATTEN_NORM);
 933         }
 934         else
 935         {
 936                 // particles on every hit
 937                 Send_Effect(EFFECT_SPARKS, hitloc, force * -1, 1);
 938
 939                 //sound on every hit
 940                 if (random() < 0.5)
 941                         sound(this, CH_TRIGGER, SND_ONS_HIT1, VOL_BASE, ATTEN_NORM);
 942                 else
 943                         sound(this, CH_TRIGGER, SND_ONS_HIT2, VOL_BASE, ATTEN_NORM);
 944         }
 945
 946         this.SendFlags |= GSF_STATUS;
 947 }
 948
 949 void ons_GeneratorThink(entity this)
 950 {
 951         this.nextthink = time + GEN_THINKRATE;
 952
 953         if (game_stopped || this.isshielded || time < this.wait)
 954                 return;
 955
 956         this.wait = time + 5;
 957         FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it),
 958         {
 959                 if (SAME_TEAM(it, this))
 960                 {
 961                         Send_Notification(NOTIF_ONE, it, MSG_CENTER, CENTER_ONS_NOTSHIELDED_TEAM);
 962                         msg_entity = it;
 963                         soundto(MSG_ONE, this, CHAN_AUTO, SND(KH_ALARM), VOL_BASE, ATTEN_NONE); // FIXME: unique sound?
 964                 }
 965                 else
 966                         Send_Notification(NOTIF_ONE, it, MSG_CENTER, APP_TEAM_NUM(this.team, CENTER_ONS_NOTSHIELDED));
 967         });
 968 }
 969
 970 void ons_GeneratorReset(entity this)
 971 {
 972         this.team = this.team_saved;
 973         SetResourceAmountExplicit(this, RESOURCE_HEALTH, autocvar_g_onslaught_gen_health);
 974         this.lasthealth = this.max_health = autocvar_g_onslaught_gen_health;
 975         this.takedamage = DAMAGE_AIM;
 976         this.bot_attack = true;
 977         if(!IL_CONTAINS(g_bot_targets, this))
 978                 IL_PUSH(g_bot_targets, this);
 979         this.iscaptured = true;
 980         this.islinked = true;
 981         this.isshielded = true;
 982         this.event_damage = ons_GeneratorDamage;
 983         setthink(this, ons_GeneratorThink);
 984         this.nextthink = time + GEN_THINKRATE;
 985
 986         Net_LinkEntity(this, false, 0, generator_send);
 987
 988         this.SendFlags = GSF_SETUP; // just incase
 989         this.SendFlags |= GSF_STATUS;
 990
 991         WaypointSprite_UpdateMaxHealth(this.sprite, this.max_health);
 992         WaypointSprite_UpdateHealth(this.sprite, GetResourceAmount(this, RESOURCE_HEALTH));
 993         WaypointSprite_UpdateRule(this.sprite,this.team,SPRITERULE_TEAMPLAY);
 994
 995         onslaught_updatelinks();
 996 }
 997
 998 void ons_DelayedGeneratorSetup(entity this)
 999 {
1000         // bot waypoints
1001         waypoint_spawnforitem_force(this, this.origin);
1002         this.nearestwaypointtimeout = 0; // activate waypointing again
1003         this.bot_basewaypoint = this.nearestwaypoint;
1004
1005         // captureshield setup
1006         ons_CaptureShield_Spawn(this, true);
1007
1008         onslaught_updatelinks();
1009
1010         Net_LinkEntity(this, false, 0, generator_send);
1011 }
1012
1013
1014 void onslaught_generator_touch(entity this, entity toucher)
1015 {
1016         if ( IS_PLAYER(toucher) )
1017         if ( SAME_TEAM(this,toucher) )
1018         if ( this.iscaptured )
1019         {
1020                 Send_Notification(NOTIF_ONE, toucher, MSG_CENTER, CENTER_ONS_TELEPORT);
1021         }
1022 }
1023
1024 void ons_GeneratorSetup(entity gen) // called when spawning a generator entity on the map as a spawnfunc
1025 {
1026         // declarations
1027         int teamnumber = gen.team;
1028
1029         // main setup
1030         gen.ons_worldgeneratornext = ons_worldgeneratorlist; // link generator into ons_worldgeneratorlist
1031         ons_worldgeneratorlist = gen;
1032
1033         gen.netname = sprintf("%s generator", Team_ColoredFullName(teamnumber));
1034         gen.classname = "onslaught_generator";
1035         gen.solid = SOLID_BBOX;
1036         gen.team_saved = teamnumber;
1037         IL_PUSH(g_saved_team, gen);
1038         set_movetype(gen, MOVETYPE_NONE);
1039         gen.lasthealth = gen.max_health = autocvar_g_onslaught_gen_health;
1040         SetResourceAmountExplicit(gen, RESOURCE_HEALTH, autocvar_g_onslaught_gen_health);
1041         gen.takedamage = DAMAGE_AIM;
1042         gen.bot_attack = true;
1043         IL_PUSH(g_bot_targets, gen);
1044         gen.event_damage = ons_GeneratorDamage;
1045         gen.reset = ons_GeneratorReset;
1046         setthink(gen, ons_GeneratorThink);
1047         gen.nextthink = time + GEN_THINKRATE;
1048         gen.iscaptured = true;
1049         gen.islinked = true;
1050         gen.isshielded = true;
1051         settouch(gen, onslaught_generator_touch);
1052
1053         // appearence
1054         // model handled by CSQC
1055         setsize(gen, GENERATOR_MIN, GENERATOR_MAX);
1056         setorigin(gen, (gen.origin + CPGEN_SPAWN_OFFSET));
1057         gen.colormap = 1024 + (teamnumber - 1) * 17;
1058
1059         // generator placement
1060         droptofloor(gen);
1061
1062         // waypointsprites
1063         WaypointSprite_SpawnFixed(WP_Null, gen.origin + CPGEN_WAYPOINT_OFFSET, gen, sprite, RADARICON_NONE);
1064         WaypointSprite_UpdateRule(gen.sprite, gen.team, SPRITERULE_TEAMPLAY);
1065         WaypointSprite_UpdateMaxHealth(gen.sprite, gen.max_health);
1066         WaypointSprite_UpdateHealth(gen.sprite, GetResourceAmount(gen, RESOURCE_HEALTH));
1067
1068         InitializeEntity(gen, ons_DelayedGeneratorSetup, INITPRIO_SETLOCATION);
1069 }
1070
1071
1072 // ===============
1073 //  Round Handler
1074 // ===============
1075
1076 int total_generators;
1077 void Onslaught_count_generators()
1078 {
1079         entity e;
1080         total_generators = redowned = blueowned = yellowowned = pinkowned = 0;
1081         for(e = ons_worldgeneratorlist; e; e = e.ons_worldgeneratornext)
1082         {
1083                 ++total_generators;
1084                 redowned += (e.team == NUM_TEAM_1 && GetResourceAmount(e, RESOURCE_HEALTH) > 0);
1085                 blueowned += (e.team == NUM_TEAM_2 && GetResourceAmount(e, RESOURCE_HEALTH) > 0);
1086                 yellowowned += (e.team == NUM_TEAM_3 && GetResourceAmount(e, RESOURCE_HEALTH) > 0);
1087                 pinkowned += (e.team == NUM_TEAM_4 && GetResourceAmount(e, RESOURCE_HEALTH) > 0);
1088         }
1089 }
1090
1091 int Onslaught_GetWinnerTeam()
1092 {
1093         int winner_team = 0;
1094         if(redowned > 0)
1095                 winner_team = NUM_TEAM_1;
1096         if(blueowned > 0)
1097         {
1098                 if(winner_team) return 0;
1099                 winner_team = NUM_TEAM_2;
1100         }
1101         if(yellowowned > 0)
1102         {
1103                 if(winner_team) return 0;
1104                 winner_team = NUM_TEAM_3;
1105         }
1106         if(pinkowned > 0)
1107         {
1108                 if(winner_team) return 0;
1109                 winner_team = NUM_TEAM_4;
1110         }
1111         if(winner_team)
1112                 return winner_team;
1113         return -1; // no generators left?
1114 }
1115
1116 void nades_Clear(entity e);
1117
1118 #define ONS_OWNED_GENERATORS() ((redowned > 0) + (blueowned > 0) + (yellowowned > 0) + (pinkowned > 0))
1119 #define ONS_OWNED_GENERATORS_OK() (ONS_OWNED_GENERATORS() > 1)
1120 bool Onslaught_CheckWinner()
1121 {
1122         if ((autocvar_timelimit && time > game_starttime + autocvar_timelimit * 60) || (round_handler_GetEndTime() > 0 && round_handler_GetEndTime() - time <= 0))
1123         {
1124                 ons_stalemate = true;
1125
1126                 if (!wpforenemy_announced)
1127                 {
1128                         Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_OVERTIME_CONTROLPOINT);
1129                         sound(NULL, CH_INFO, SND_ONS_GENERATOR_DECAY, VOL_BASE, ATTEN_NONE);
1130
1131                         wpforenemy_announced = true;
1132                 }
1133
1134                 entity tmp_entity; // temporary entity
1135                 float d;
1136                 for(tmp_entity = ons_worldgeneratorlist; tmp_entity; tmp_entity = tmp_entity.ons_worldgeneratornext) if(time >= tmp_entity.ons_overtime_damagedelay)
1137                 {
1138                         // tmp_entity.max_health / 300 gives 5 minutes of overtime.
1139                         // control points reduce the overtime duration.
1140                         d = 1;
1141                         entity e;
1142                         for(e = ons_worldcplist; e; e = e.ons_worldcpnext)
1143                         {
1144                                 if(DIFF_TEAM(e, tmp_entity))
1145                                 if(e.islinked)
1146                                         d = d + 1;
1147                         }
1148
1149                         if(autocvar_g_campaign && autocvar__campaign_testrun)
1150                                 d = d * tmp_entity.max_health;
1151                         else
1152                                 d = d * tmp_entity.max_health / max(30, 60 * autocvar_timelimit_suddendeath);
1153
1154                         Damage(tmp_entity, tmp_entity, tmp_entity, d, DEATH_HURTTRIGGER.m_id, DMG_NOWEP, tmp_entity.origin, '0 0 0');
1155
1156                         tmp_entity.sprite.SendFlags |= 16;
1157
1158                         tmp_entity.ons_overtime_damagedelay = time + 1;
1159                 }
1160         }
1161         else { wpforenemy_announced = false; ons_stalemate = false; }
1162
1163         Onslaught_count_generators();
1164
1165         if(ONS_OWNED_GENERATORS_OK())
1166                 return 0;
1167
1168         int winner_team = Onslaught_GetWinnerTeam();
1169
1170         if(winner_team > 0)
1171         {
1172                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, APP_TEAM_NUM(winner_team, CENTER_ROUND_TEAM_WIN));
1173                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(winner_team, INFO_ROUND_TEAM_WIN));
1174                 TeamScore_AddToTeam(winner_team, ST_ONS_CAPS, +1);
1175         }
1176         else if(winner_team == -1)
1177         {
1178                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_ROUND_TIED);
1179                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_ROUND_TIED);
1180         }
1181
1182         ons_stalemate = false;
1183
1184         play2all(SND(CTF_CAPTURE(winner_team)));
1185
1186         round_handler_Init(7, autocvar_g_onslaught_warmup, autocvar_g_onslaught_round_timelimit);
1187
1188         FOREACH_CLIENT(IS_PLAYER(it), {
1189                 STAT(ROUNDLOST, it) = true;
1190                 it.player_blocked = true;
1191
1192                 nades_Clear(it);
1193         });
1194
1195         game_stopped = true;
1196         return 1;
1197 }
1198
1199 bool Onslaught_CheckPlayers()
1200 {
1201         return 1;
1202 }
1203
1204 void Onslaught_RoundStart()
1205 {
1206         entity tmp_entity;
1207         FOREACH_CLIENT(IS_PLAYER(it), it.player_blocked = false);
1208
1209         for(tmp_entity = ons_worldcplist; tmp_entity; tmp_entity = tmp_entity.ons_worldcpnext)
1210                 tmp_entity.sprite.SendFlags |= 16;
1211
1212         for(tmp_entity = ons_worldgeneratorlist; tmp_entity; tmp_entity = tmp_entity.ons_worldgeneratornext)
1213                 tmp_entity.sprite.SendFlags |= 16;
1214 }
1215
1216
1217 // ================
1218 // Bot player logic
1219 // ================
1220
1221 // NOTE: LEGACY CODE, needs to be re-written!
1222
1223 void havocbot_goalrating_ons_offenseitems(entity this, float ratingscale, vector org, float sradius)
1224 {
1225         bool needarmor = false, needweapons = false;
1226
1227         // Needs armor/health?
1228         if(GetResourceAmount(this, RESOURCE_HEALTH) < 100)
1229                 needarmor = true;
1230
1231         // Needs weapons?
1232         int c = 0;
1233         FOREACH(Weapons, it != WEP_Null, {
1234                 if(STAT(WEAPONS, this) & (it.m_wepset))
1235                 if(++c >= 4)
1236                         break;
1237         });
1238
1239         if(c<4)
1240                 needweapons = true;
1241
1242         if(!needweapons && !needarmor)
1243                 return;
1244
1245         LOG_DEBUG(this.netname, " needs weapons ", ftos(needweapons));
1246         LOG_DEBUG(this.netname, " needs armor ", ftos(needarmor));
1247
1248         // See what is around
1249         IL_EACH(g_items, it.bot_pickup,
1250         {
1251                 // gather health and armor only
1252                 if (it.solid)
1253                 if ( ((GetResourceAmount(it, RESOURCE_HEALTH) || GetResourceAmount(it, RESOURCE_ARMOR)) && needarmor) || (STAT(WEAPONS, it) && needweapons ) )
1254                 if (vdist(it.origin - org, <, sradius))
1255                 {
1256                         int t = it.bot_pickupevalfunc(this, it);
1257                         if (t > 0)
1258                                 navigation_routerating(this, it, t * ratingscale, 500);
1259                 }
1260         });
1261 }
1262
1263 void havocbot_role_ons_setrole(entity this, int role)
1264 {
1265         LOG_DEBUG(this.netname," switched to ");
1266         switch(role)
1267         {
1268                 case HAVOCBOT_ONS_ROLE_DEFENSE:
1269                         LOG_DEBUG("defense");
1270                         this.havocbot_role = havocbot_role_ons_defense;
1271                         this.havocbot_role_flags = HAVOCBOT_ONS_ROLE_DEFENSE;
1272                         this.havocbot_role_timeout = 0;
1273                         break;
1274                 case HAVOCBOT_ONS_ROLE_ASSISTANT:
1275                         LOG_DEBUG("assistant");
1276                         this.havocbot_role = havocbot_role_ons_assistant;
1277                         this.havocbot_role_flags = HAVOCBOT_ONS_ROLE_ASSISTANT;
1278                         this.havocbot_role_timeout = 0;
1279                         break;
1280                 case HAVOCBOT_ONS_ROLE_OFFENSE:
1281                         LOG_DEBUG("offense");
1282                         this.havocbot_role = havocbot_role_ons_offense;
1283                         this.havocbot_role_flags = HAVOCBOT_ONS_ROLE_OFFENSE;
1284                         this.havocbot_role_timeout = 0;
1285                         break;
1286         }
1287         LOG_DEBUG("");
1288 }
1289
1290 void havocbot_goalrating_ons_controlpoints_attack(entity this, float ratingscale)
1291 {
1292         entity cp, cp1, cp2, best, wp;
1293         float radius, bestvalue;
1294         int c;
1295         bool found;
1296
1297         // Filter control points
1298         for(cp2 = ons_worldcplist; cp2; cp2 = cp2.ons_worldcpnext)
1299         {
1300                 cp2.wpcost = c = 0;
1301                 cp2.wpconsidered = false;
1302
1303                 if(cp2.isshielded)
1304                         continue;
1305
1306                 // Ignore owned controlpoints
1307                 if(!((cp2.aregensneighbor & BIT(this.team)) || (cp2.arecpsneighbor & BIT(this.team))))
1308                         continue;
1309
1310                 // Count team mates interested in this control point
1311                 // (easier and cleaner than keeping counters per cp and teams)
1312                 FOREACH_CLIENT(IS_PLAYER(it), {
1313                         if(SAME_TEAM(it, this))
1314                         if(it.havocbot_role_flags & HAVOCBOT_ONS_ROLE_OFFENSE)
1315                         if(it.havocbot_ons_target == cp2)
1316                                 ++c;
1317                 });
1318
1319                 // NOTE: probably decrease the cost of attackable control points
1320                 cp2.wpcost = c;
1321                 cp2.wpconsidered = true;
1322         }
1323
1324         // We'll consider only the best case
1325         bestvalue = 99999999999;
1326         cp = NULL;
1327         for(cp1 = ons_worldcplist; cp1; cp1 = cp1.ons_worldcpnext)
1328         {
1329                 if (!cp1.wpconsidered)
1330                         continue;
1331
1332                 if(cp1.wpcost<bestvalue)
1333                 {
1334                         bestvalue = cp1.wpcost;
1335                         cp = cp1;
1336                         this.havocbot_ons_target = cp1;
1337                 }
1338         }
1339
1340         if (!cp)
1341                 return;
1342
1343         LOG_DEBUG(this.netname, " chose cp ranked ", ftos(bestvalue));
1344
1345         if(cp.goalentity)
1346         {
1347                 // Should be attacked
1348                 // Rate waypoints near it
1349                 found = false;
1350                 best = NULL;
1351                 bestvalue = 99999999999;
1352                 for(radius=0; radius<1000 && !found; radius+=500)
1353                 {
1354                         for(wp=findradius(cp.origin,radius); wp; wp=wp.chain)
1355                         {
1356                                 if(!(wp.wpflags & WAYPOINTFLAG_GENERATED))
1357                                 if(wp.classname=="waypoint")
1358                                 if(checkpvs(wp.origin,cp))
1359                                 {
1360                                         found = true;
1361                                         if(wp.cnt<bestvalue)
1362                                         {
1363                                                 best = wp;
1364                                                 bestvalue = wp.cnt;
1365                                         }
1366                                 }
1367                         }
1368                 }
1369
1370                 if(best)
1371                 {
1372                         navigation_routerating(this, best, ratingscale, 10000);
1373                         best.cnt += 1;
1374
1375                         this.havocbot_attack_time = 0;
1376                         if(checkpvs(this.origin + this.view_ofs, cp))
1377                         if(checkpvs(this.origin + this.view_ofs, best))
1378                                 this.havocbot_attack_time = time + 2;
1379                 }
1380                 else
1381                 {
1382                         navigation_routerating(this, cp, ratingscale, 10000);
1383                 }
1384                 LOG_DEBUG(this.netname, " found an attackable controlpoint at ", vtos(cp.origin));
1385         }
1386         else
1387         {
1388                 // Should be touched
1389                 LOG_DEBUG(this.netname, " found a touchable controlpoint at ", vtos(cp.origin));
1390                 found = false;
1391
1392                 // Look for auto generated waypoint
1393                 if (!bot_waypoints_for_items)
1394                 for (wp = findradius(cp.origin,100); wp; wp = wp.chain)
1395                 {
1396                         if(wp.classname=="waypoint")
1397                         {
1398                                 navigation_routerating(this, wp, ratingscale, 10000);
1399                                 found = true;
1400                         }
1401                 }
1402
1403                 // Nothing found, rate the controlpoint itself
1404                 if (!found)
1405                         navigation_routerating(this, cp, ratingscale, 10000);
1406         }
1407 }
1408
1409 bool havocbot_goalrating_ons_generator_attack(entity this, float ratingscale)
1410 {
1411         entity g, wp, bestwp;
1412         bool found;
1413         int best;
1414
1415         for(g = ons_worldgeneratorlist; g; g = g.ons_worldgeneratornext)
1416         {
1417                 if(SAME_TEAM(g, this) || g.isshielded)
1418                         continue;
1419
1420                 // Should be attacked
1421                 // Rate waypoints near it
1422                 found = false;
1423                 bestwp = NULL;
1424                 best = 99999999999;
1425
1426                 for(wp=findradius(g.origin,400); wp; wp=wp.chain)
1427                 {
1428                         if(wp.classname=="waypoint")
1429                         if(checkpvs(wp.origin,g))
1430                         {
1431                                 found = true;
1432                                 if(wp.cnt<best)
1433                                 {
1434                                         bestwp = wp;
1435                                         best = wp.cnt;
1436                                 }
1437                         }
1438                 }
1439
1440                 if(bestwp)
1441                 {
1442                         LOG_DEBUG("waypoints found around generator");
1443                         navigation_routerating(this, bestwp, ratingscale, 10000);
1444                         bestwp.cnt += 1;
1445
1446                         this.havocbot_attack_time = 0;
1447                         if(checkpvs(this.origin + this.view_ofs, g))
1448                         if(checkpvs(this.origin + this.view_ofs, bestwp))
1449                                 this.havocbot_attack_time = time + 5;
1450
1451                         return true;
1452                 }
1453                 else
1454                 {
1455                         LOG_DEBUG("generator found without waypoints around");
1456                         // if there aren't waypoints near the generator go straight to it
1457                         navigation_routerating(this, g, ratingscale, 10000);
1458                         this.havocbot_attack_time = 0;
1459                         return true;
1460                 }
1461         }
1462         return false;
1463 }
1464
1465 void havocbot_role_ons_offense(entity this)
1466 {
1467         if(IS_DEAD(this))
1468         {
1469                 this.havocbot_attack_time = 0;
1470                 havocbot_ons_reset_role(this);
1471                 return;
1472         }
1473
1474         // Set the role timeout if necessary
1475         if (!this.havocbot_role_timeout)
1476                 this.havocbot_role_timeout = time + 120;
1477
1478         if (time > this.havocbot_role_timeout)
1479         {
1480                 havocbot_ons_reset_role(this);
1481                 return;
1482         }
1483
1484         if(this.havocbot_attack_time>time)
1485                 return;
1486
1487         if (navigation_goalrating_timeout(this))
1488         {
1489                 navigation_goalrating_start(this);
1490                 havocbot_goalrating_enemyplayers(this, 20000, this.origin, 650);
1491                 if(!havocbot_goalrating_ons_generator_attack(this, 20000))
1492                         havocbot_goalrating_ons_controlpoints_attack(this, 20000);
1493                 havocbot_goalrating_ons_offenseitems(this, 10000, this.origin, 10000);
1494                 navigation_goalrating_end(this);
1495
1496                 navigation_goalrating_timeout_set(this);
1497         }
1498 }
1499
1500 void havocbot_role_ons_assistant(entity this)
1501 {
1502         havocbot_ons_reset_role(this);
1503 }
1504
1505 void havocbot_role_ons_defense(entity this)
1506 {
1507         havocbot_ons_reset_role(this);
1508 }
1509
1510 void havocbot_ons_reset_role(entity this)
1511 {
1512         if(IS_DEAD(this))
1513                 return;
1514
1515         this.havocbot_ons_target = NULL;
1516
1517         // TODO: Defend control points or generator if necessary
1518
1519         havocbot_role_ons_setrole(this, HAVOCBOT_ONS_ROLE_OFFENSE);
1520 }
1521
1522
1523 /*
1524  * Find control point or generator owned by the same team self which is nearest to pos
1525  * if max_dist is positive, only control points within this range will be considered
1526  */
1527 entity ons_Nearest_ControlPoint(entity this, vector pos, float max_dist)
1528 {
1529         entity closest_target = NULL;
1530         for(entity cp = ons_worldcplist; cp; cp = cp.ons_worldcpnext)
1531         {
1532                 if(SAME_TEAM(cp, this))
1533                 if(cp.iscaptured)
1534                 if(max_dist <= 0 || vdist(cp.origin - pos, <=, max_dist))
1535                 if(vlen2(cp.origin - pos) <= vlen2(closest_target.origin - pos) || closest_target == NULL)
1536                         closest_target = cp;
1537         }
1538         for(entity gen = ons_worldgeneratorlist; gen; gen = gen.ons_worldgeneratornext)
1539         {
1540                 if(SAME_TEAM(gen, this))
1541                 if(max_dist <= 0 || vdist(gen.origin - pos, <, max_dist))
1542                 if(vlen2(gen.origin - pos) <= vlen2(closest_target.origin - pos) || closest_target == NULL)
1543                         closest_target = gen;
1544         }
1545
1546         return closest_target;
1547 }
1548
1549 /*
1550  * Find control point or generator owned by the same team self which is nearest to pos
1551  * if max_dist is positive, only control points within this range will be considered
1552  * This function only check distances on the XY plane, disregarding Z
1553  */
1554 entity ons_Nearest_ControlPoint_2D(entity this, vector pos, float max_dist)
1555 {
1556         entity closest_target = NULL;
1557         vector delta;
1558         float smallest_distance = 0, distance;
1559
1560         for(entity cp = ons_worldcplist; cp; cp = cp.ons_worldcpnext)
1561         {
1562                 delta = cp.origin - pos;
1563                 delta_z = 0;
1564                 distance = vlen(delta);
1565
1566                 if(SAME_TEAM(cp, this))
1567                 if(cp.iscaptured)
1568                 if(max_dist <= 0 || distance <= max_dist)
1569                 if(closest_target == NULL || distance <= smallest_distance )
1570                 {
1571                         closest_target = cp;
1572                         smallest_distance = distance;
1573                 }
1574         }
1575         for(entity gen = ons_worldgeneratorlist; gen; gen = gen.ons_worldgeneratornext)
1576         {
1577                 delta = gen.origin - pos;
1578                 delta_z = 0;
1579                 distance = vlen(delta);
1580
1581                 if(SAME_TEAM(gen, this))
1582                 if(max_dist <= 0 || distance <= max_dist)
1583                 if(closest_target == NULL || distance <= smallest_distance )
1584                 {
1585                         closest_target = gen;
1586                         smallest_distance = distance;
1587                 }
1588         }
1589
1590         return closest_target;
1591 }
1592 /**
1593  * find the number of control points and generators in the same team as this
1594  */
1595 int ons_Count_SelfControlPoints(entity this)
1596 {
1597         int n = 0;
1598         for(entity cp = ons_worldcplist; cp; cp = cp.ons_worldcpnext)
1599         {
1600                 if(SAME_TEAM(cp, this))
1601                 if(cp.iscaptured)
1602                         n++;
1603         }
1604         for(entity gen = ons_worldgeneratorlist; gen; gen = gen.ons_worldgeneratornext)
1605         {
1606                 if(SAME_TEAM(gen, this))
1607                         n++;
1608         }
1609         return n;
1610 }
1611
1612 /**
1613  * Teleport player to a random position near tele_target
1614  * if tele_effects is true, teleport sound+particles are created
1615  * return false on failure
1616  */
1617 bool ons_Teleport(entity player, entity tele_target, float range, bool tele_effects)
1618 {
1619         if ( !tele_target )
1620                 return false;
1621
1622         int i;
1623         vector loc;
1624         float theta;
1625         // narrow the range for each iteration to increase chances that a spawnpoint
1626         // can be found even if there's little room around the control point
1627         float iteration_scale = 1;
1628         for(i = 0; i < 16; ++i)
1629         {
1630                 iteration_scale -= i / 16;
1631                 theta = random() * 2 * M_PI;
1632                 loc_y = sin(theta);
1633                 loc_x = cos(theta);
1634                 loc_z = 0;
1635                 loc *= random() * range * iteration_scale;
1636
1637                 loc += tele_target.origin + '0 0 128' * iteration_scale;
1638
1639                 tracebox(loc, STAT(PL_MIN, player), STAT(PL_MAX, player), loc, MOVE_NORMAL, player);
1640                 if(trace_fraction == 1.0 && !trace_startsolid)
1641                 {
1642                         traceline(tele_target.origin, loc, MOVE_NOMONSTERS, tele_target); // double check to make sure we're not spawning outside the NULL
1643                         if(trace_fraction == 1.0 && !trace_startsolid)
1644                         {
1645                                 if ( tele_effects )
1646                                 {
1647                                         Send_Effect(EFFECT_TELEPORT, player.origin, '0 0 0', 1);
1648                                         sound (player, CH_TRIGGER, SND_TELEPORT, VOL_BASE, ATTEN_NORM);
1649                                 }
1650                                 setorigin(player, loc);
1651                                 player.angles = '0 1 0' * ( theta * RAD2DEG + 180 );
1652                                 makevectors(player.angles);
1653                                 player.fixangle = true;
1654                                 player.teleport_antispam = time + autocvar_g_onslaught_teleport_wait;
1655
1656                                 if ( tele_effects )
1657                                         Send_Effect(EFFECT_TELEPORT, player.origin + v_forward * 32, '0 0 0', 1);
1658                                 return true;
1659                         }
1660                 }
1661         }
1662
1663         return false;
1664 }
1665
1666 // ==============
1667 // Hook Functions
1668 // ==============
1669
1670 MUTATOR_HOOKFUNCTION(ons, reset_map_global)
1671 {
1672         FOREACH_CLIENT(IS_PLAYER(it), {
1673                 STAT(ROUNDLOST, it) = false;
1674                 it.ons_deathloc = '0 0 0';
1675                 PutClientInServer(it);
1676                 it.clientcamera = it;
1677         });
1678         return false;
1679 }
1680
1681 MUTATOR_HOOKFUNCTION(ons, ClientDisconnect)
1682 {
1683         entity player = M_ARGV(0, entity);
1684
1685         player.ons_deathloc = '0 0 0';
1686 }
1687
1688 MUTATOR_HOOKFUNCTION(ons, MakePlayerObserver)
1689 {
1690         entity player = M_ARGV(0, entity);
1691
1692         player.ons_deathloc = '0 0 0';
1693 }
1694
1695 MUTATOR_HOOKFUNCTION(ons, PlayerSpawn)
1696 {
1697         entity player = M_ARGV(0, entity);
1698
1699         if(!round_handler_IsRoundStarted())
1700         {
1701                 player.player_blocked = true;
1702                 return false;
1703         }
1704
1705         entity l;
1706         for(l = ons_worldgeneratorlist; l; l = l.ons_worldgeneratornext)
1707         {
1708                 l.sprite.SendFlags |= 16;
1709         }
1710         for(l = ons_worldcplist; l; l = l.ons_worldcpnext)
1711         {
1712                 l.sprite.SendFlags |= 16;
1713         }
1714
1715         if(ons_stalemate) { Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_OVERTIME_CONTROLPOINT); }
1716
1717         if ( autocvar_g_onslaught_spawn_choose )
1718         if ( player.ons_spawn_by )
1719         if ( ons_Teleport(player,player.ons_spawn_by,autocvar_g_onslaught_teleport_radius,false) )
1720         {
1721                 player.ons_spawn_by = NULL;
1722                 return false;
1723         }
1724
1725         if(autocvar_g_onslaught_spawn_at_controlpoints)
1726         if(random() <= autocvar_g_onslaught_spawn_at_controlpoints_chance)
1727         {
1728                 float random_target = autocvar_g_onslaught_spawn_at_controlpoints_random;
1729                 entity tmp_entity, closest_target = NULL;
1730                 vector spawn_loc = player.ons_deathloc;
1731
1732                 // new joining player or round reset, don't bother checking
1733                 if(spawn_loc == '0 0 0') { return false; }
1734
1735                 if(random_target) { RandomSelection_Init(); }
1736
1737                 for(tmp_entity = ons_worldcplist; tmp_entity; tmp_entity = tmp_entity.ons_worldcpnext)
1738                 {
1739                         if(SAME_TEAM(tmp_entity, player))
1740                         if(random_target)
1741                                 RandomSelection_AddEnt(tmp_entity, 1, 1);
1742                         else if(vlen2(tmp_entity.origin - spawn_loc) <= vlen2(closest_target.origin - spawn_loc) || closest_target == NULL)
1743                                 closest_target = tmp_entity;
1744                 }
1745
1746                 if(random_target) { closest_target = RandomSelection_chosen_ent; }
1747
1748                 if(closest_target)
1749                 {
1750                         float i;
1751                         vector loc;
1752                         float iteration_scale = 1;
1753                         for(i = 0; i < 10; ++i)
1754                         {
1755                                 iteration_scale -= i / 10;
1756                                 loc = closest_target.origin + '0 0 96' * iteration_scale;
1757                                 loc += ('0 1 0' * random()) * 128 * iteration_scale;
1758                                 tracebox(loc, STAT(PL_MIN, player), STAT(PL_MAX, player), loc, MOVE_NORMAL, player);
1759                                 if(trace_fraction == 1.0 && !trace_startsolid)
1760                                 {
1761                                         traceline(closest_target.origin, loc, MOVE_NOMONSTERS, closest_target); // double check to make sure we're not spawning outside the NULL
1762                                         if(trace_fraction == 1.0 && !trace_startsolid)
1763                                         {
1764                                                 setorigin(player, loc);
1765                                                 player.angles = normalize(loc - closest_target.origin) * RAD2DEG;
1766                                                 return false;
1767                                         }
1768                                 }
1769                         }
1770                 }
1771         }
1772
1773         if(autocvar_g_onslaught_spawn_at_generator)
1774         if(random() <= autocvar_g_onslaught_spawn_at_generator_chance)
1775         {
1776                 float random_target = autocvar_g_onslaught_spawn_at_generator_random;
1777                 entity tmp_entity, closest_target = NULL;
1778                 vector spawn_loc = player.ons_deathloc;
1779
1780                 // new joining player or round reset, don't bother checking
1781                 if(spawn_loc == '0 0 0') { return false; }
1782
1783                 if(random_target) { RandomSelection_Init(); }
1784
1785                 for(tmp_entity = ons_worldgeneratorlist; tmp_entity; tmp_entity = tmp_entity.ons_worldgeneratornext)
1786                 {
1787                         if(random_target)
1788                                 RandomSelection_AddEnt(tmp_entity, 1, 1);
1789                         else
1790                         {
1791                                 if(SAME_TEAM(tmp_entity, player))
1792                                 if(vlen2(tmp_entity.origin - spawn_loc) <= vlen2(closest_target.origin - spawn_loc) || closest_target == NULL)
1793                                         closest_target = tmp_entity;
1794                         }
1795                 }
1796
1797                 if(random_target) { closest_target = RandomSelection_chosen_ent; }
1798
1799                 if(closest_target)
1800                 {
1801                         float i;
1802                         vector loc;
1803                         float iteration_scale = 1;
1804                         for(i = 0; i < 10; ++i)
1805                         {
1806                                 iteration_scale -= i / 10;
1807                                 loc = closest_target.origin + '0 0 128' * iteration_scale;
1808                                 loc += ('0 1 0' * random()) * 256 * iteration_scale;
1809                                 tracebox(loc, STAT(PL_MIN, player), STAT(PL_MAX, player), loc, MOVE_NORMAL, player);
1810                                 if(trace_fraction == 1.0 && !trace_startsolid)
1811                                 {
1812                                         traceline(closest_target.origin, loc, MOVE_NOMONSTERS, closest_target); // double check to make sure we're not spawning outside the NULL
1813                                         if(trace_fraction == 1.0 && !trace_startsolid)
1814                                         {
1815                                                 setorigin(player, loc);
1816                                                 player.angles = normalize(loc - closest_target.origin) * RAD2DEG;
1817                                                 return false;
1818                                         }
1819                                 }
1820                         }
1821                 }
1822         }
1823
1824         return false;
1825 }
1826
1827 MUTATOR_HOOKFUNCTION(ons, PlayerDies)
1828 {
1829         entity frag_target = M_ARGV(2, entity);
1830
1831         frag_target.ons_deathloc = frag_target.origin;
1832         entity l;
1833         for(l = ons_worldgeneratorlist; l; l = l.ons_worldgeneratornext)
1834         {
1835                 l.sprite.SendFlags |= 16;
1836         }
1837         for(l = ons_worldcplist; l; l = l.ons_worldcpnext)
1838         {
1839                 l.sprite.SendFlags |= 16;
1840         }
1841
1842         if ( autocvar_g_onslaught_spawn_choose )
1843         if ( ons_Count_SelfControlPoints(frag_target) > 1 )
1844                 stuffcmd(frag_target, "qc_cmd_cl hud clickradar\n");
1845
1846         return false;
1847 }
1848
1849 MUTATOR_HOOKFUNCTION(ons, MonsterMove)
1850 {
1851         entity mon = M_ARGV(0, entity);
1852
1853         entity e = find(NULL, targetname, mon.target);
1854         if (e != NULL)
1855                 mon.team = e.team;
1856 }
1857
1858 void ons_MonsterSpawn_Delayed(entity this)
1859 {
1860         entity own = this.owner;
1861
1862         if(!own) { delete(this); return; }
1863
1864         if(own.targetname)
1865         {
1866                 entity e = find(NULL, target, own.targetname);
1867                 if(e != NULL)
1868                 {
1869                         own.team = e.team;
1870
1871                         own.use(own, e, NULL);
1872                 }
1873         }
1874
1875         delete(this);
1876 }
1877
1878 MUTATOR_HOOKFUNCTION(ons, MonsterSpawn)
1879 {
1880         entity mon = M_ARGV(0, entity);
1881
1882         entity e = spawn();
1883         e.owner = mon;
1884         InitializeEntity(e, ons_MonsterSpawn_Delayed, INITPRIO_FINDTARGET);
1885 }
1886
1887 void ons_TurretSpawn_Delayed(entity this)
1888 {
1889         entity own = this.owner;
1890
1891         if(!own) { delete(this); return; }
1892
1893         if(own.targetname)
1894         {
1895                 entity e = find(NULL, target, own.targetname);
1896                 if(e != NULL)
1897                 {
1898                         own.team = e.team;
1899                         own.active = ACTIVE_NOT;
1900
1901                         own.use(own, e, NULL);
1902                 }
1903         }
1904
1905         delete(this);
1906 }
1907
1908 MUTATOR_HOOKFUNCTION(ons, TurretSpawn)
1909 {
1910         entity turret = M_ARGV(0, entity);
1911
1912         entity e = spawn();
1913         e.owner = turret;
1914         InitializeEntity(e, ons_TurretSpawn_Delayed, INITPRIO_FINDTARGET);
1915
1916         return false;
1917 }
1918
1919 MUTATOR_HOOKFUNCTION(ons, HavocBot_ChooseRole)
1920 {
1921         entity bot = M_ARGV(0, entity);
1922
1923         havocbot_ons_reset_role(bot);
1924         return true;
1925 }
1926
1927 MUTATOR_HOOKFUNCTION(ons, CheckAllowedTeams)
1928 {
1929         // onslaught is special
1930         for(entity tmp_entity = ons_worldgeneratorlist; tmp_entity; tmp_entity = tmp_entity.ons_worldgeneratornext)
1931         {
1932                 switch(tmp_entity.team)
1933                 {
1934                         case NUM_TEAM_1: c1 = 0; break;
1935                         case NUM_TEAM_2: c2 = 0; break;
1936                         case NUM_TEAM_3: c3 = 0; break;
1937                         case NUM_TEAM_4: c4 = 0; break;
1938                 }
1939         }
1940
1941         return true;
1942 }
1943
1944 MUTATOR_HOOKFUNCTION(ons, SpectateCopy)
1945 {
1946         entity spectatee = M_ARGV(0, entity);
1947         entity client = M_ARGV(1, entity);
1948
1949         STAT(ROUNDLOST, client) = STAT(ROUNDLOST, spectatee); // make spectators see it too
1950 }
1951
1952 MUTATOR_HOOKFUNCTION(ons, SV_ParseClientCommand)
1953 {
1954         if(MUTATOR_RETURNVALUE) // command was already handled?
1955                 return false;
1956
1957         entity player = M_ARGV(0, entity);
1958         string cmd_name = M_ARGV(1, string);
1959         int cmd_argc = M_ARGV(2, int);
1960
1961         if ( cmd_name == "ons_spawn" )
1962         {
1963                 vector pos = player.origin;
1964                 if(cmd_argc > 1)
1965                         pos_x = stof(argv(1));
1966                 if(cmd_argc > 2)
1967                         pos_y = stof(argv(2));
1968                 if(cmd_argc > 3)
1969                         pos_z = stof(argv(3));
1970
1971                 if ( IS_PLAYER(player) )
1972                 {
1973                         if ( !STAT(FROZEN, player) )
1974                         {
1975                                 entity source_point = ons_Nearest_ControlPoint(player, player.origin, autocvar_g_onslaught_teleport_radius);
1976
1977                                 if ( !source_point && GetResourceAmount(player, RESOURCE_HEALTH) > 0 )
1978                                 {
1979                                         sprint(player, "\nYou need to be next to a control point\n");
1980                                         return true;
1981                                 }
1982
1983
1984                                 entity closest_target = ons_Nearest_ControlPoint_2D(player, pos, autocvar_g_onslaught_click_radius);
1985
1986                                 if ( closest_target == NULL )
1987                                 {
1988                                         sprint(player, "\nNo control point found\n");
1989                                         return true;
1990                                 }
1991
1992                                 if ( GetResourceAmount(player, RESOURCE_HEALTH) <= 0 )
1993                                 {
1994                                         player.ons_spawn_by = closest_target;
1995                                         player.respawn_flags = player.respawn_flags | RESPAWN_FORCE;
1996                                 }
1997                                 else
1998                                 {
1999                                         if ( source_point == closest_target )
2000                                         {
2001                                                 sprint(player, "\nTeleporting to the same point\n");
2002                                                 return true;
2003                                         }
2004
2005                                         if ( !ons_Teleport(player,closest_target,autocvar_g_onslaught_teleport_radius,true) )
2006                                                 sprint(player, "\nUnable to teleport there\n");
2007                                 }
2008
2009                                 return true;
2010                         }
2011
2012                         sprint(player, "\nNo teleportation for you\n");
2013                 }
2014
2015                 return true;
2016         }
2017         return false;
2018 }
2019
2020 MUTATOR_HOOKFUNCTION(ons, PlayerUseKey)
2021 {
2022         if(MUTATOR_RETURNVALUE || game_stopped) return false;
2023
2024         entity player = M_ARGV(0, entity);
2025
2026         if((time > player.teleport_antispam) && (!IS_DEAD(player)) && !player.vehicle)
2027         {
2028                 entity source_point = ons_Nearest_ControlPoint(player, player.origin, autocvar_g_onslaught_teleport_radius);
2029                 if ( source_point )
2030                 {
2031                         stuffcmd(player, "qc_cmd_cl hud clickradar\n");
2032                         return true;
2033                 }
2034         }
2035 }
2036
2037 MUTATOR_HOOKFUNCTION(ons, PlayHitsound)
2038 {
2039         entity frag_victim = M_ARGV(0, entity);
2040
2041         return (frag_victim.classname == "onslaught_generator" && !frag_victim.isshielded)
2042                 || (frag_victim.classname == "onslaught_controlpoint_icon" && !frag_victim.owner.isshielded);
2043 }
2044
2045 MUTATOR_HOOKFUNCTION(ons, SendWaypoint)
2046 {
2047     entity wp = M_ARGV(0, entity);
2048     entity to = M_ARGV(1, entity);
2049     int sf = M_ARGV(2, int);
2050     int wp_flag = M_ARGV(3, int);
2051
2052         if(sf & 16)
2053         {
2054                 if(wp.owner.classname == "onslaught_controlpoint")
2055                 {
2056                         entity wp_owner = wp.owner;
2057                         entity e = WaypointSprite_getviewentity(to);
2058                         if(SAME_TEAM(e, wp_owner) && GetResourceAmount(wp_owner.goalentity, RESOURCE_HEALTH) >= wp_owner.goalentity.max_health) { wp_flag |= 2; }
2059                         if(!ons_ControlPoint_Attackable(wp_owner, e.team)) { wp_flag |= 2; }
2060                 }
2061                 if(wp.owner.classname == "onslaught_generator")
2062                 {
2063                         entity wp_owner = wp.owner;
2064                         if(wp_owner.isshielded && GetResourceAmount(wp_owner, RESOURCE_HEALTH) >= wp_owner.max_health) { wp_flag |= 2; }
2065                         if(GetResourceAmount(wp_owner, RESOURCE_HEALTH) <= 0) { wp_flag |= 2; }
2066                 }
2067         }
2068
2069         M_ARGV(3, int) = wp_flag;
2070 }
2071
2072 MUTATOR_HOOKFUNCTION(ons, TurretValidateTarget)
2073 {
2074         entity turret_target = M_ARGV(1, entity);
2075
2076         if(substring(turret_target.classname, 0, 10) == "onslaught_") // don't attack onslaught targets, that's the player's job!
2077         {
2078                 M_ARGV(3, float) = -3;
2079                 return true;
2080         }
2081
2082         return false;
2083 }
2084
2085 MUTATOR_HOOKFUNCTION(ons, TurretThink)
2086 {
2087     entity turret = M_ARGV(0, entity);
2088
2089         // ONS uses somewhat backwards linking.
2090         if(turret.target)
2091         {
2092                 entity e = find(NULL, targetname, turret.target);
2093                 if (e != NULL)
2094                         turret.team = e.team;
2095         }
2096
2097         if(turret.team != turret.tur_head.team)
2098                 turret_respawn(turret);
2099 }
2100
2101
2102 // ==========
2103 // Spawnfuncs
2104 // ==========
2105
2106 /*QUAKED spawnfunc_onslaught_link (0 .5 .8) (-16 -16 -16) (16 16 16)
2107   Link between control points.
2108
2109   This entity targets two different spawnfunc_onslaught_controlpoint or spawnfunc_onslaught_generator entities, and suppresses shielding on both if they are owned by different teams.
2110
2111 keys:
2112 "target" - first control point.
2113 "target2" - second control point.
2114  */
2115 spawnfunc(onslaught_link)
2116 {
2117         if(!g_onslaught) { delete(this); return; }
2118
2119         if (this.target == "" || this.target2 == "")
2120                 objerror(this, "target and target2 must be set\n");
2121
2122         this.ons_worldlinknext = ons_worldlinklist; // link into ons_worldlinklist
2123         ons_worldlinklist = this;
2124
2125         InitializeEntity(this, ons_DelayedLinkSetup, INITPRIO_FINDTARGET);
2126         Net_LinkEntity(this, false, 0, ons_Link_Send);
2127 }
2128
2129 /*QUAKED spawnfunc_onslaught_controlpoint (0 .5 .8) (-32 -32 0) (32 32 128)
2130   Control point. Be sure to give this enough clearance so that the shootable part has room to exist
2131
2132   This should link to an spawnfunc_onslaught_controlpoint entity or spawnfunc_onslaught_generator entity.
2133
2134 keys:
2135 "targetname" - name that spawnfunc_onslaught_link entities will use to target this.
2136 "target" - target any entities that are tied to this control point, such as vehicles and buildable structure entities.
2137 "message" - name of this control point (should reflect the location in the map, such as "center bridge", "north tower", etc)
2138  */
2139
2140 spawnfunc(onslaught_controlpoint)
2141 {
2142         if(!g_onslaught) { delete(this); return; }
2143
2144         ons_ControlPoint_Setup(this);
2145 }
2146
2147 /*QUAKED spawnfunc_onslaught_generator (0 .5 .8) (-32 -32 -24) (32 32 64)
2148   Base generator.
2149
2150   spawnfunc_onslaught_link entities can target this.
2151
2152 keys:
2153 "team" - team that owns this generator (5 = red, 14 = blue, etc), MUST BE SET.
2154 "targetname" - name that spawnfunc_onslaught_link entities will use to target this.
2155  */
2156 spawnfunc(onslaught_generator)
2157 {
2158         if(!g_onslaught) { delete(this); return; }
2159         if(!this.team) { objerror(this, "team must be set"); }
2160
2161         ons_GeneratorSetup(this);
2162 }
2163
2164 // scoreboard setup
2165 void ons_ScoreRules()
2166 {
2167         CheckAllowedTeams(NULL);
2168         int teams = 0;
2169         if(c1 >= 0) teams |= BIT(0);
2170         if(c2 >= 0) teams |= BIT(1);
2171         if(c3 >= 0) teams |= BIT(2);
2172         if(c4 >= 0) teams |= BIT(3);
2173         GameRules_scoring(teams, SFL_SORT_PRIO_PRIMARY, 0, {
2174             field_team(ST_ONS_CAPS, "destroyed", SFL_SORT_PRIO_PRIMARY);
2175             field(SP_ONS_CAPS, "caps", SFL_SORT_PRIO_SECONDARY);
2176             field(SP_ONS_TAKES, "takes", 0);
2177         });
2178 }
2179
2180 void ons_DelayedInit(entity this) // Do this check with a delay so we can wait for teams to be set up
2181 {
2182         ons_ScoreRules();
2183
2184         round_handler_Spawn(Onslaught_CheckPlayers, Onslaught_CheckWinner, Onslaught_RoundStart);
2185         round_handler_Init(5, autocvar_g_onslaught_warmup, autocvar_g_onslaught_round_timelimit);
2186 }
2187
2188 void ons_Initialize()
2189 {
2190         g_onslaught = true;
2191         ons_captureshield_force = autocvar_g_onslaught_shield_force;
2192
2193         cam = new(objective_camera);
2194
2195         InitializeEntity(NULL, ons_DelayedInit, INITPRIO_GAMETYPE);
2196 }