Merge branch 'master' into terencehill/bot_ai
[xonotic/xonotic-data.pk3dir.git] / qcsrc / common / gamemodes / gamemode / onslaught / sv_onslaught.qc
1 #include "sv_onslaught.qh"
2 #include "sv_controlpoint.qh"
3 #include "sv_generator.qh"
4
5 bool g_onslaught;
6
7 float autocvar_g_onslaught_teleport_wait;
8 bool autocvar_g_onslaught_spawn_at_controlpoints;
9 bool autocvar_g_onslaught_spawn_at_generator;
10 float autocvar_g_onslaught_cp_proxydecap;
11 float autocvar_g_onslaught_cp_proxydecap_distance = 512;
12 float autocvar_g_onslaught_cp_proxydecap_dps = 100;
13 float autocvar_g_onslaught_spawn_at_controlpoints_chance = 0.5;
14 float autocvar_g_onslaught_spawn_at_controlpoints_random;
15 float autocvar_g_onslaught_spawn_at_generator_chance;
16 float autocvar_g_onslaught_spawn_at_generator_random;
17 float autocvar_g_onslaught_cp_buildhealth;
18 float autocvar_g_onslaught_cp_buildtime;
19 float autocvar_g_onslaught_cp_health;
20 float autocvar_g_onslaught_cp_regen;
21 float autocvar_g_onslaught_gen_health;
22 float autocvar_g_onslaught_shield_force = 100;
23 float autocvar_g_onslaught_allow_vehicle_touch;
24 float autocvar_g_onslaught_round_timelimit;
25 float autocvar_g_onslaught_warmup;
26 float autocvar_g_onslaught_teleport_radius;
27 float autocvar_g_onslaught_spawn_choose;
28 float autocvar_g_onslaught_click_radius;
29
30 void FixSize(entity e);
31 entity cam;
32
33 // =======================
34 // CaptureShield Functions
35 // =======================
36
37 bool clientcamera_send(entity this, entity to, int sf)
38 {
39         WriteHeader(MSG_ENTITY, ENT_ONSCAMERA);
40
41         WriteVector(MSG_ENTITY, this.origin);
42
43         WriteAngle(MSG_ENTITY, this.angles_x);
44         WriteAngle(MSG_ENTITY, this.angles_y);
45         WriteAngle(MSG_ENTITY, this.angles_z);
46
47         return true;
48 }
49
50 bool ons_CaptureShield_Customize(entity this, entity client)
51 {
52         entity e = WaypointSprite_getviewentity(client);
53
54         if(!this.enemy.isshielded && (ons_ControlPoint_Attackable(this.enemy, e.team) > 0 || this.enemy.classname != "onslaught_controlpoint")) { return false; }
55         if(SAME_TEAM(this, e)) { return false; }
56
57         return true;
58 }
59
60 void ons_CaptureShield_Touch(entity this, entity toucher)
61 {
62         if(!this.enemy.isshielded && (ons_ControlPoint_Attackable(this.enemy, toucher.team) > 0 || this.enemy.classname != "onslaught_controlpoint")) { return; }
63         if(!IS_PLAYER(toucher)) { return; }
64         if(SAME_TEAM(toucher, this)) { return; }
65
66         vector mymid = (this.absmin + this.absmax) * 0.5;
67         vector theirmid = (toucher.absmin + toucher.absmax) * 0.5;
68
69         Damage(toucher, this, this, 0, DEATH_HURTTRIGGER.m_id, DMG_NOWEP, mymid, normalize(theirmid - mymid) * ons_captureshield_force);
70
71         if(IS_REAL_CLIENT(toucher))
72         {
73                 play2(toucher, SND(ONS_DAMAGEBLOCKEDBYSHIELD));
74
75                 if(this.enemy.classname == "onslaught_generator")
76                         Send_Notification(NOTIF_ONE, toucher, MSG_CENTER, CENTER_ONS_GENERATOR_SHIELDED);
77                 else
78                         Send_Notification(NOTIF_ONE, toucher, MSG_CENTER, CENTER_ONS_CONTROLPOINT_SHIELDED);
79         }
80 }
81
82 void ons_CaptureShield_Reset(entity this)
83 {
84         this.colormap = this.enemy.colormap;
85         this.team = this.enemy.team;
86 }
87
88 void ons_CaptureShield_Spawn(entity generator, bool is_generator)
89 {
90         entity shield = new(ons_captureshield);
91         IL_PUSH(g_onsshields, shield);
92
93         shield.enemy = generator;
94         shield.team = generator.team;
95         shield.colormap = generator.colormap;
96         shield.reset = ons_CaptureShield_Reset;
97         settouch(shield, ons_CaptureShield_Touch);
98         setcefc(shield, ons_CaptureShield_Customize);
99         shield.effects = EF_ADDITIVE;
100         set_movetype(shield, MOVETYPE_NOCLIP);
101         shield.solid = SOLID_TRIGGER;
102         shield.avelocity = '7 0 11';
103         shield.scale = 1;
104         shield.model = ((is_generator) ? "models/onslaught/generator_shield.md3" : "models/onslaught/controlpoint_shield.md3");
105
106         precache_model(shield.model);
107         setorigin(shield, generator.origin);
108         _setmodel(shield, shield.model);
109         setsize(shield, shield.scale * shield.mins, shield.scale * shield.maxs);
110 }
111
112
113 // ==========
114 // Junk Pile
115 // ==========
116
117 void setmodel_fixsize(entity e, Model m)
118 {
119         setmodel(e, m);
120         FixSize(e);
121 }
122
123 void onslaught_updatelinks()
124 {
125         entity l;
126         // first check if the game has ended
127         LOG_DEBUG("--- updatelinks ---");
128         // mark generators as being shielded and networked
129         for(l = ons_worldgeneratorlist; l; l = l.ons_worldgeneratornext)
130         {
131                 if (l.iscaptured)
132                         LOG_DEBUG(etos(l), " (generator) belongs to team ", ftos(l.team));
133                 else
134                         LOG_DEBUG(etos(l), " (generator) is destroyed");
135                 l.islinked = l.iscaptured;
136                 l.isshielded = l.iscaptured;
137                 l.sprite.SendFlags |= 16;
138         }
139         // mark points as shielded and not networked
140         for(l = ons_worldcplist; l; l = l.ons_worldcpnext)
141         {
142                 l.islinked = false;
143                 l.isshielded = true;
144                 l.aregensneighbor = 0;
145                 l.arecpsneighbor = 0;
146                 LOG_DEBUG(etos(l), " (point) belongs to team ", ftos(l.team));
147                 l.sprite.SendFlags |= 16;
148         }
149         // flow power outward from the generators through the network
150         bool stop = false;
151         while (!stop)
152         {
153                 stop = true;
154                 for(l = ons_worldlinklist; l; l = l.ons_worldlinknext)
155                 {
156                         // if both points are captured by the same team, and only one of
157                         // them is powered, mark the other one as powered as well
158                         if (l.enemy.iscaptured && l.goalentity.iscaptured)
159                                 if (l.enemy.islinked != l.goalentity.islinked)
160                                         if(SAME_TEAM(l.enemy, l.goalentity))
161                                         {
162                                                 if (!l.goalentity.islinked)
163                                                 {
164                                                         stop = false;
165                                                         l.goalentity.islinked = true;
166                                                         LOG_DEBUG(etos(l), " (link) is marking ", etos(l.goalentity), " (point) because its team matches ", etos(l.enemy), " (point)");
167                                                 }
168                                                 else if (!l.enemy.islinked)
169                                                 {
170                                                         stop = false;
171                                                         l.enemy.islinked = true;
172                                                         LOG_DEBUG(etos(l), " (link) is marking ", etos(l.enemy), " (point) because its team matches ", etos(l.goalentity), " (point)");
173                                                 }
174                                         }
175                 }
176         }
177         // now that we know which points are powered we can mark their neighbors
178         // as unshielded if team differs
179         for(l = ons_worldlinklist; l; l = l.ons_worldlinknext)
180         {
181                 if (l.goalentity.islinked)
182                 {
183                         if(DIFF_TEAM(l.goalentity, l.enemy))
184                         {
185                                 LOG_DEBUG(etos(l), " (link) is unshielding ", etos(l.enemy), " (point) because its team does not match ", etos(l.goalentity), " (point)");
186                                 l.enemy.isshielded = false;
187                         }
188                         if(l.goalentity.classname == "onslaught_generator")
189                                 l.enemy.aregensneighbor |= BIT(l.goalentity.team);
190                         else
191                                 l.enemy.arecpsneighbor |= BIT(l.goalentity.team);
192                 }
193                 if (l.enemy.islinked)
194                 {
195                         if(DIFF_TEAM(l.goalentity, l.enemy))
196                         {
197                                 LOG_DEBUG(etos(l), " (link) is unshielding ", etos(l.goalentity), " (point) because its team does not match ", etos(l.enemy), " (point)");
198                                 l.goalentity.isshielded = false;
199                         }
200                         if(l.enemy.classname == "onslaught_generator")
201                                 l.goalentity.aregensneighbor |= BIT(l.enemy.team);
202                         else
203                                 l.goalentity.arecpsneighbor |= BIT(l.enemy.team);
204                 }
205         }
206         // now update the generators
207         for(l = ons_worldgeneratorlist; l; l = l.ons_worldgeneratornext)
208         {
209                 if (l.isshielded)
210                 {
211                         LOG_DEBUG(etos(l), " (generator) is shielded");
212                         l.takedamage = DAMAGE_NO;
213                         if(l.bot_attack)
214                                 IL_REMOVE(g_bot_targets, l);
215                         l.bot_attack = false;
216                 }
217                 else
218                 {
219                         LOG_DEBUG(etos(l), " (generator) is not shielded");
220                         l.takedamage = DAMAGE_AIM;
221                         if(!l.bot_attack)
222                                 IL_PUSH(g_bot_targets, l);
223                         l.bot_attack = true;
224                 }
225
226                 ons_Generator_UpdateSprite(l);
227         }
228         // now update the takedamage and alpha variables on control point icons
229         for(l = ons_worldcplist; l; l = l.ons_worldcpnext)
230         {
231                 if (l.isshielded)
232                 {
233                         LOG_DEBUG(etos(l), " (point) is shielded");
234                         if (l.goalentity)
235                         {
236                                 l.goalentity.takedamage = DAMAGE_NO;
237                                 if(l.goalentity.bot_attack)
238                                         IL_REMOVE(g_bot_targets, l.goalentity);
239                                 l.goalentity.bot_attack = false;
240                         }
241                 }
242                 else
243                 {
244                         LOG_DEBUG(etos(l), " (point) is not shielded");
245                         if (l.goalentity)
246                         {
247                                 l.goalentity.takedamage = DAMAGE_AIM;
248                                 if(!l.goalentity.bot_attack)
249                                         IL_PUSH(g_bot_targets, l.goalentity);
250                                 l.goalentity.bot_attack = true;
251                         }
252                 }
253                 ons_ControlPoint_UpdateSprite(l);
254         }
255         IL_EACH(g_onsshields, true,
256         {
257                 it.team = it.enemy.team;
258                 it.colormap = it.enemy.colormap;
259         });
260 }
261
262
263 // ===================
264 // Main Link Functions
265 // ===================
266
267 bool ons_Link_Send(entity this, entity to, int sendflags)
268 {
269         WriteHeader(MSG_ENTITY, ENT_CLIENT_RADARLINK);
270         WriteByte(MSG_ENTITY, sendflags);
271         if(sendflags & 1)
272         {
273                 WriteVector(MSG_ENTITY, this.goalentity.origin);
274         }
275         if(sendflags & 2)
276         {
277                 WriteVector(MSG_ENTITY, this.enemy.origin);
278         }
279         if(sendflags & 4)
280         {
281                 WriteByte(MSG_ENTITY, this.clientcolors); // which is goalentity's color + enemy's color * 16
282         }
283         return true;
284 }
285
286 void ons_Link_CheckUpdate(entity this)
287 {
288         // TODO check if the two sides have moved (currently they won't move anyway)
289         float cc = 0, cc1 = 0, cc2 = 0;
290
291         if(this.goalentity.islinked || this.goalentity.iscaptured) { cc1 = (this.goalentity.team - 1) * 0x01; }
292         if(this.enemy.islinked || this.enemy.iscaptured) { cc2 = (this.enemy.team - 1) * 0x10; }
293
294         cc = cc1 + cc2;
295
296         if(cc != this.clientcolors)
297         {
298                 this.clientcolors = cc;
299                 this.SendFlags |= 4;
300         }
301
302         this.nextthink = time;
303 }
304
305 void ons_DelayedLinkSetup(entity this)
306 {
307         this.goalentity = find(NULL, targetname, this.target);
308         this.enemy = find(NULL, targetname, this.target2);
309         if(!this.goalentity) { objerror(this, "can not find target\n"); }
310         if(!this.enemy) { objerror(this, "can not find target2\n"); }
311
312         LOG_DEBUG(etos(this.goalentity), " linked with ", etos(this.enemy));
313         this.SendFlags |= 3;
314         setthink(this, ons_Link_CheckUpdate);
315         this.nextthink = time;
316 }
317
318
319 // =============================
320 // Main Control Point Functions
321 // =============================
322
323 int ons_ControlPoint_CanBeLinked(entity cp, int teamnumber)
324 {
325         if(cp.aregensneighbor & BIT(teamnumber)) return 2;
326         if(cp.arecpsneighbor & BIT(teamnumber)) return 1;
327
328         return 0;
329 }
330
331 int ons_ControlPoint_Attackable(entity cp, int teamnumber)
332         // -2: SAME TEAM, attackable by enemy!
333         // -1: SAME TEAM!
334         // 0: off limits
335         // 1: attack it
336         // 2: touch it
337         // 3: attack it (HIGH PRIO)
338         // 4: touch it (HIGH PRIO)
339 {
340         int a;
341
342         if(cp.isshielded)
343         {
344                 return 0;
345         }
346         else if(cp.goalentity)
347         {
348                 // if there's already an icon built, nothing happens
349                 if(cp.team == teamnumber)
350                 {
351                         a = ons_ControlPoint_CanBeLinked(cp, teamnumber);
352                         if(a) // attackable by enemy?
353                                 return -2; // EMERGENCY!
354                         return -1;
355                 }
356                 // we know it can be linked, so no need to check
357                 // but...
358                 a = ons_ControlPoint_CanBeLinked(cp, teamnumber);
359                 if(a == 2) // near our generator?
360                         return 3; // EMERGENCY!
361                 return 1;
362         }
363         else
364         {
365                 // free point
366                 if(ons_ControlPoint_CanBeLinked(cp, teamnumber))
367                 {
368                         a = ons_ControlPoint_CanBeLinked(cp, teamnumber); // why was this here NUM_TEAM_1 + NUM_TEAM_2 - t
369                         if(a == 2)
370                                 return 4; // GET THIS ONE NOW!
371                         else
372                                 return 2; // TOUCH ME
373                 }
374         }
375         return 0;
376 }
377
378 void ons_ControlPoint_Icon_Damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, .entity weaponentity, vector hitloc, vector force)
379 {
380         if(damage <= 0) { return; }
381
382         if (this.owner.isshielded)
383         {
384                 // this is protected by a shield, so ignore the damage
385                 if (time > this.pain_finished)
386                         if (IS_PLAYER(attacker))
387                         {
388                                 play2(attacker, SND(ONS_DAMAGEBLOCKEDBYSHIELD));
389                                 this.pain_finished = time + 1;
390                                 attacker.typehitsound += 1; // play both sounds (shield is way too quiet)
391                         }
392
393                 return;
394         }
395
396         if(IS_PLAYER(attacker))
397         if(time - ons_notification_time[this.team] > 10)
398         {
399                 play2team(this.team, SND(ONS_CONTROLPOINT_UNDERATTACK));
400                 ons_notification_time[this.team] = time;
401         }
402
403         TakeResource(this, RESOURCE_HEALTH, damage);
404         if(this.owner.iscaptured)
405                 WaypointSprite_UpdateHealth(this.owner.sprite, GetResourceAmount(this, RESOURCE_HEALTH));
406         else
407                 WaypointSprite_UpdateBuildFinished(this.owner.sprite, time + (this.max_health - GetResourceAmount(this, RESOURCE_HEALTH)) / (this.count / ONS_CP_THINKRATE));
408         this.pain_finished = time + 1;
409         // particles on every hit
410         pointparticles(EFFECT_SPARKS, hitloc, force*-1, 1);
411         //sound on every hit
412         if (random() < 0.5)
413                 sound(this, CH_TRIGGER, SND_ONS_HIT1, VOL_BASE+0.3, ATTEN_NORM);
414         else
415                 sound(this, CH_TRIGGER, SND_ONS_HIT2, VOL_BASE+0.3, ATTEN_NORM);
416
417         if (GetResourceAmount(this, RESOURCE_HEALTH) < 0)
418         {
419                 sound(this, CH_TRIGGER, SND_GRENADE_IMPACT, VOL_BASE, ATTEN_NORM);
420                 pointparticles(EFFECT_ROCKET_EXPLODE, this.origin, '0 0 0', 1);
421                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_ONSLAUGHT_CPDESTROYED), this.owner.message, attacker.netname);
422
423                 GameRules_scoring_add(attacker, ONS_TAKES, 1);
424                 GameRules_scoring_add(attacker, SCORE, 10);
425
426                 this.owner.goalentity = NULL;
427                 this.owner.islinked = false;
428                 this.owner.iscaptured = false;
429                 this.owner.team = 0;
430                 this.owner.colormap = 1024;
431
432                 WaypointSprite_UpdateMaxHealth(this.owner.sprite, 0);
433
434                 onslaught_updatelinks();
435
436                 // Use targets now (somebody make sure this is in the right place..)
437                 SUB_UseTargets(this.owner, this, NULL);
438
439                 this.owner.waslinked = this.owner.islinked;
440                 if(this.owner.model != "models/onslaught/controlpoint_pad.md3")
441                         setmodel_fixsize(this.owner, MDL_ONS_CP_PAD1);
442                 //setsize(this, '-32 -32 0', '32 32 8');
443
444                 delete(this);
445         }
446
447         this.SendFlags |= CPSF_STATUS;
448 }
449
450 bool ons_ControlPoint_Icon_Heal(entity targ, entity inflictor, float amount, float limit)
451 {
452         float hlth = GetResourceAmount(targ, RESOURCE_HEALTH);
453         float true_limit = ((limit != RESOURCE_LIMIT_NONE) ? limit : targ.max_health);
454         if (hlth <= 0 || hlth >= true_limit)
455                 return false;
456
457         GiveResourceWithLimit(targ, RESOURCE_HEALTH, amount, true_limit);
458         hlth = GetResourceAmount(targ, RESOURCE_HEALTH);
459         if(targ.owner.iscaptured)
460                 WaypointSprite_UpdateHealth(targ.owner.sprite, hlth);
461         else
462                 WaypointSprite_UpdateBuildFinished(targ.owner.sprite, time + (targ.max_health - hlth) / (targ.count / ONS_CP_THINKRATE));
463         targ.SendFlags |= CPSF_STATUS;
464         return true;
465 }
466
467 void ons_ControlPoint_Icon_Think(entity this)
468 {
469         this.nextthink = time + ONS_CP_THINKRATE;
470
471         if(autocvar_g_onslaught_cp_proxydecap)
472         {
473                 int _enemy_count = 0;
474                 int _friendly_count = 0;
475
476                 FOREACH_CLIENT(IS_PLAYER(it) && !IS_DEAD(it), {
477                         if(vdist(it.origin - this.origin, <, autocvar_g_onslaught_cp_proxydecap_distance))
478                         {
479                                 if(SAME_TEAM(it, this))
480                                         ++_friendly_count;
481                                 else
482                                         ++_enemy_count;
483                         }
484                 });
485
486                 _friendly_count = _friendly_count * (autocvar_g_onslaught_cp_proxydecap_dps * ONS_CP_THINKRATE);
487                 _enemy_count = _enemy_count * (autocvar_g_onslaught_cp_proxydecap_dps * ONS_CP_THINKRATE);
488
489                 GiveResourceWithLimit(this, RESOURCE_HEALTH, (_friendly_count - _enemy_count), this.max_health);
490                 this.SendFlags |= CPSF_STATUS;
491                 if(GetResourceAmount(this, RESOURCE_HEALTH) <= 0)
492                 {
493                         ons_ControlPoint_Icon_Damage(this, this, this, 1, 0, DMG_NOWEP, this.origin, '0 0 0');
494                         return;
495                 }
496         }
497
498         if (time > this.pain_finished + 5)
499         {
500                 if(GetResourceAmount(this, RESOURCE_HEALTH) < this.max_health)
501                 {
502                         GiveResourceWithLimit(this, RESOURCE_HEALTH, this.count, this.max_health);
503                         WaypointSprite_UpdateHealth(this.owner.sprite, GetResourceAmount(this, RESOURCE_HEALTH));
504                 }
505         }
506
507         if(this.owner.islinked != this.owner.waslinked)
508         {
509                 // unteam the spawnpoint if needed
510                 int t = this.owner.team;
511                 if(!this.owner.islinked)
512                         this.owner.team = 0;
513
514                 SUB_UseTargets(this.owner, this, NULL);
515
516                 this.owner.team = t;
517
518                 this.owner.waslinked = this.owner.islinked;
519         }
520
521         // damaged fx
522         if(random() < 0.6 - GetResourceAmount(this, RESOURCE_HEALTH) / this.max_health)
523         {
524                 Send_Effect(EFFECT_ELECTRIC_SPARKS, this.origin + randompos('-10 -10 -20', '10 10 20'), '0 0 0', 1);
525
526                 if(random() > 0.8)
527                         sound(this, CH_PAIN, SND_ONS_SPARK1, VOL_BASE, ATTEN_NORM);
528                 else if (random() > 0.5)
529                         sound(this, CH_PAIN, SND_ONS_SPARK2, VOL_BASE, ATTEN_NORM);
530         }
531 }
532
533 void ons_ControlPoint_Icon_BuildThink(entity this)
534 {
535         int a;
536
537         this.nextthink = time + ONS_CP_THINKRATE;
538
539         // only do this if there is power
540         a = ons_ControlPoint_CanBeLinked(this.owner, this.owner.team);
541         if(!a)
542                 return;
543
544         GiveResource(this, RESOURCE_HEALTH, this.count);
545
546         this.SendFlags |= CPSF_STATUS;
547
548         if (GetResourceAmount(this, RESOURCE_HEALTH) >= this.max_health)
549         {
550                 SetResourceAmountExplicit(this, RESOURCE_HEALTH, this.max_health);
551                 this.count = autocvar_g_onslaught_cp_regen * ONS_CP_THINKRATE; // slow repair rate from now on
552                 setthink(this, ons_ControlPoint_Icon_Think);
553                 sound(this, CH_TRIGGER, SND_ONS_CONTROLPOINT_BUILT, VOL_BASE, ATTEN_NORM);
554                 this.owner.iscaptured = true;
555                 this.solid = SOLID_BBOX;
556
557                 Send_Effect(EFFECT_CAP(this.owner.team), this.owner.origin, '0 0 0', 1);
558
559                 WaypointSprite_UpdateMaxHealth(this.owner.sprite, this.max_health);
560                 WaypointSprite_UpdateHealth(this.owner.sprite, GetResourceAmount(this, RESOURCE_HEALTH));
561
562                 if(IS_PLAYER(this.owner.ons_toucher))
563                 {
564                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_ONSLAUGHT_CAPTURE, this.owner.ons_toucher.netname, this.owner.message);
565                         Send_Notification(NOTIF_ALL_EXCEPT, this.owner.ons_toucher, MSG_CENTER, APP_TEAM_NUM(this.owner.ons_toucher.team, CENTER_ONS_CAPTURE_TEAM), this.owner.message);
566                         Send_Notification(NOTIF_ONE, this.owner.ons_toucher, MSG_CENTER, CENTER_ONS_CAPTURE, this.owner.message);
567                         GameRules_scoring_add(this.owner.ons_toucher, ONS_CAPS, 1);
568                         GameRules_scoring_add_team(this.owner.ons_toucher, SCORE, 10);
569                 }
570
571                 this.owner.ons_toucher = NULL;
572
573                 onslaught_updatelinks();
574
575                 // Use targets now (somebody make sure this is in the right place..)
576                 SUB_UseTargets(this.owner, this, NULL);
577
578                 this.SendFlags |= CPSF_SETUP;
579         }
580         if(this.owner.model != MDL_ONS_CP_PAD2.model_str())
581                 setmodel_fixsize(this.owner, MDL_ONS_CP_PAD2);
582
583         if(random() < 0.9 - GetResourceAmount(this, RESOURCE_HEALTH) / this.max_health)
584                 Send_Effect(EFFECT_RAGE, this.origin + 10 * randomvec(), '0 0 -1', 1);
585 }
586
587 void onslaught_controlpoint_icon_link(entity e, void(entity this) spawnproc);
588
589 void ons_ControlPoint_Icon_Spawn(entity cp, entity player)
590 {
591         entity e = new(onslaught_controlpoint_icon);
592
593         setsize(e, CPICON_MIN, CPICON_MAX);
594         setorigin(e, cp.origin + CPICON_OFFSET);
595
596         e.owner = cp;
597         e.max_health = autocvar_g_onslaught_cp_health;
598         SetResourceAmountExplicit(e, RESOURCE_HEALTH, autocvar_g_onslaught_cp_buildhealth);
599         e.solid = SOLID_NOT;
600         e.takedamage = DAMAGE_AIM;
601         e.bot_attack = true;
602         IL_PUSH(g_bot_targets, e);
603         e.event_damage = ons_ControlPoint_Icon_Damage;
604         e.event_heal = ons_ControlPoint_Icon_Heal;
605         e.team = player.team;
606         e.colormap = 1024 + (e.team - 1) * 17;
607         e.count = (e.max_health - GetResourceAmount(e, RESOURCE_HEALTH)) * ONS_CP_THINKRATE / autocvar_g_onslaught_cp_buildtime; // how long it takes to build
608
609         sound(e, CH_TRIGGER, SND_ONS_CONTROLPOINT_BUILD, VOL_BASE, ATTEN_NORM);
610
611         cp.goalentity = e;
612         cp.team = e.team;
613         cp.colormap = e.colormap;
614
615         Send_Effect(EFFECT_FLAG_TOUCH(player.team), e.origin, '0 0 0', 1);
616
617         WaypointSprite_UpdateBuildFinished(cp.sprite, time + (e.max_health - GetResourceAmount(e, RESOURCE_HEALTH)) / (e.count / ONS_CP_THINKRATE));
618         WaypointSprite_UpdateRule(cp.sprite,cp.team,SPRITERULE_TEAMPLAY);
619         cp.sprite.SendFlags |= 16;
620
621         onslaught_controlpoint_icon_link(e, ons_ControlPoint_Icon_BuildThink);
622 }
623
624 entity ons_ControlPoint_Waypoint(entity e)
625 {
626         if(e.team)
627         {
628                 int a = ons_ControlPoint_Attackable(e, e.team);
629
630                 if(a == -2) { return WP_OnsCPDefend; } // defend now
631                 if(a == -1 || a == 1 || a == 2) { return WP_OnsCP; } // touch
632                 if(a == 3 || a == 4) { return WP_OnsCPAttack; } // attack
633         }
634         else
635                 return WP_OnsCP;
636
637         return WP_Null;
638 }
639
640 void ons_ControlPoint_UpdateSprite(entity e)
641 {
642         entity s1 = ons_ControlPoint_Waypoint(e);
643         WaypointSprite_UpdateSprites(e.sprite, s1, s1, s1);
644
645         bool sh;
646         sh = !(ons_ControlPoint_CanBeLinked(e, NUM_TEAM_1) || ons_ControlPoint_CanBeLinked(e, NUM_TEAM_2) || ons_ControlPoint_CanBeLinked(e, NUM_TEAM_3) || ons_ControlPoint_CanBeLinked(e, NUM_TEAM_4));
647
648         if(e.lastteam != e.team + 2 || e.lastshielded != sh || e.iscaptured != e.lastcaptured)
649         {
650                 if(e.iscaptured) // don't mess up build bars!
651                 {
652                         if(sh)
653                         {
654                                 WaypointSprite_UpdateMaxHealth(e.sprite, 0);
655                         }
656                         else
657                         {
658                                 WaypointSprite_UpdateMaxHealth(e.sprite, e.goalentity.max_health);
659                                 WaypointSprite_UpdateHealth(e.sprite, GetResourceAmount(e.goalentity, RESOURCE_HEALTH));
660                         }
661                 }
662                 if(e.lastshielded)
663                 {
664                         if(e.team)
665                                 WaypointSprite_UpdateTeamRadar(e.sprite, RADARICON_CONTROLPOINT, 0.5 * colormapPaletteColor(e.team - 1, false));
666                         else
667                                 WaypointSprite_UpdateTeamRadar(e.sprite, RADARICON_CONTROLPOINT, '0.5 0.5 0.5');
668                 }
669                 else
670                 {
671                         if(e.team)
672                                 WaypointSprite_UpdateTeamRadar(e.sprite, RADARICON_CONTROLPOINT, colormapPaletteColor(e.team - 1, false));
673                         else
674                                 WaypointSprite_UpdateTeamRadar(e.sprite, RADARICON_CONTROLPOINT, '0.75 0.75 0.75');
675                 }
676                 WaypointSprite_Ping(e.sprite);
677
678                 e.lastteam = e.team + 2;
679                 e.lastshielded = sh;
680                 e.lastcaptured = e.iscaptured;
681         }
682 }
683
684 void ons_ControlPoint_Touch(entity this, entity toucher)
685 {
686         int attackable;
687
688         if(IS_VEHICLE(toucher) && toucher.owner)
689         if(autocvar_g_onslaught_allow_vehicle_touch)
690                 toucher = toucher.owner;
691         else
692                 return;
693
694         if(!IS_PLAYER(toucher)) { return; }
695         if(STAT(FROZEN, toucher)) { return; }
696         if(IS_DEAD(toucher)) { return; }
697
698         if ( SAME_TEAM(this,toucher) )
699         if ( this.iscaptured )
700         {
701                 if(time <= toucher.teleport_antispam)
702                         Send_Notification(NOTIF_ONE, toucher, MSG_CENTER, CENTER_ONS_TELEPORT_ANTISPAM, rint(toucher.teleport_antispam - time));
703                 else
704                         Send_Notification(NOTIF_ONE, toucher, MSG_CENTER, CENTER_ONS_TELEPORT);
705         }
706
707         attackable = ons_ControlPoint_Attackable(this, toucher.team);
708         if(attackable != 2 && attackable != 4)
709                 return;
710         // we've verified that this player has a legitimate claim to this point,
711         // so start building the captured point icon (which only captures this
712         // point if it successfully builds without being destroyed first)
713         ons_ControlPoint_Icon_Spawn(this, toucher);
714
715         this.ons_toucher = toucher;
716
717         onslaught_updatelinks();
718 }
719
720 void ons_ControlPoint_Think(entity this)
721 {
722         this.nextthink = time + ONS_CP_THINKRATE;
723         CSQCMODEL_AUTOUPDATE(this);
724 }
725
726 void ons_ControlPoint_Reset(entity this)
727 {
728         if(this.goalentity)
729                 delete(this.goalentity);
730
731         this.goalentity = NULL;
732         this.team = 0;
733         this.colormap = 1024;
734         this.iscaptured = false;
735         this.islinked = false;
736         this.isshielded = true;
737         setthink(this, ons_ControlPoint_Think);
738         this.ons_toucher = NULL;
739         this.nextthink = time + ONS_CP_THINKRATE;
740         setmodel_fixsize(this, MDL_ONS_CP_PAD1);
741
742         WaypointSprite_UpdateMaxHealth(this.sprite, 0);
743         WaypointSprite_UpdateRule(this.sprite,this.team,SPRITERULE_TEAMPLAY);
744
745         onslaught_updatelinks();
746
747         SUB_UseTargets(this, this, NULL); // to reset the structures, playerspawns etc.
748
749         CSQCMODEL_AUTOUPDATE(this);
750 }
751
752 void ons_DelayedControlPoint_Setup(entity this)
753 {
754         onslaught_updatelinks();
755
756         // captureshield setup
757         ons_CaptureShield_Spawn(this, false);
758
759         CSQCMODEL_AUTOINIT(this);
760 }
761
762 void ons_ControlPoint_Setup(entity cp)
763 {
764         // main setup
765         cp.ons_worldcpnext = ons_worldcplist; // link control point into ons_worldcplist
766         ons_worldcplist = cp;
767
768         cp.netname = "Control point";
769         cp.team = 0;
770         cp.solid = SOLID_BBOX;
771         set_movetype(cp, MOVETYPE_NONE);
772         settouch(cp, ons_ControlPoint_Touch);
773         setthink(cp, ons_ControlPoint_Think);
774         cp.nextthink = time + ONS_CP_THINKRATE;
775         cp.reset = ons_ControlPoint_Reset;
776         cp.colormap = 1024;
777         cp.iscaptured = false;
778         cp.islinked = false;
779         cp.isshielded = true;
780
781         if(cp.message == "") { cp.message = "a"; }
782
783         // appearence
784         setmodel_fixsize(cp, MDL_ONS_CP_PAD1);
785
786         // control point placement
787         if((cp.spawnflags & 1) || cp.noalign) // don't drop to floor, just stay at fixed location
788         {
789                 cp.noalign = true;
790                 set_movetype(cp, MOVETYPE_NONE);
791         }
792         else // drop to floor, automatically find a platform and set that as spawn origin
793         {
794                 setorigin(cp, cp.origin + '0 0 20');
795                 cp.noalign = false;
796                 droptofloor(cp);
797                 set_movetype(cp, MOVETYPE_TOSS);
798         }
799
800         // waypointsprites
801         WaypointSprite_SpawnFixed(WP_Null, cp.origin + CPGEN_WAYPOINT_OFFSET, cp, sprite, RADARICON_NONE);
802         WaypointSprite_UpdateRule(cp.sprite, cp.team, SPRITERULE_TEAMPLAY);
803
804         InitializeEntity(cp, ons_DelayedControlPoint_Setup, INITPRIO_SETLOCATION);
805 }
806
807
808 // =========================
809 // Main Generator Functions
810 // =========================
811
812 entity ons_Generator_Waypoint(entity e)
813 {
814         if (e.isshielded)
815                 return WP_OnsGenShielded;
816         return WP_OnsGen;
817 }
818
819 void ons_Generator_UpdateSprite(entity e)
820 {
821         entity s1 = ons_Generator_Waypoint(e);
822         WaypointSprite_UpdateSprites(e.sprite, s1, s1, s1);
823
824         if(e.lastteam != e.team + 2 || e.lastshielded != e.isshielded)
825         {
826                 e.lastteam = e.team + 2;
827                 e.lastshielded = e.isshielded;
828                 if(e.lastshielded)
829                 {
830                         if(e.team)
831                                 WaypointSprite_UpdateTeamRadar(e.sprite, RADARICON_GENERATOR, 0.5 * colormapPaletteColor(e.team - 1, false));
832                         else
833                                 WaypointSprite_UpdateTeamRadar(e.sprite, RADARICON_GENERATOR, '0.5 0.5 0.5');
834                 }
835                 else
836                 {
837                         if(e.team)
838                                 WaypointSprite_UpdateTeamRadar(e.sprite, RADARICON_GENERATOR, colormapPaletteColor(e.team - 1, false));
839                         else
840                                 WaypointSprite_UpdateTeamRadar(e.sprite, RADARICON_GENERATOR, '0.75 0.75 0.75');
841                 }
842                 WaypointSprite_Ping(e.sprite);
843         }
844 }
845
846 void ons_camSetup(entity this)
847 {
848         vector dir;
849         vector ang = '0 0 0';
850         vector best_ang = '0 0 0';
851         float best_trace_fraction = 0;
852         while(ang.y < 360)
853         {
854                 dir = vec2(cos(ang.y * DEG2RAD), sin(ang.y * DEG2RAD));
855                 dir *= 500;
856                 traceline(this.origin, this.origin - dir, MOVE_WORLDONLY, this);
857                 if(trace_fraction > best_trace_fraction)
858                 {
859                         best_trace_fraction = trace_fraction;
860                         best_ang = ang;
861                         if(trace_fraction == 1)
862                                 break;
863                 }
864                 ang.y += 90;
865                 if(ang.y == 360)
866                         ang.y = 45;
867         }
868         cam.origin = this.origin;
869         setorigin(cam, cam.origin);
870         cam.angles = best_ang;
871         Net_LinkEntity(cam, false, 0, clientcamera_send);
872
873         FOREACH_CLIENT(true, it.clientcamera = cam;);
874
875         WriteByte(MSG_ALL, SVC_SETVIEWANGLES);
876         WriteAngle(MSG_ALL, cam.angles_x);
877         WriteAngle(MSG_ALL, cam.angles_y);
878         WriteAngle(MSG_ALL, cam.angles_z);
879 }
880
881 void ons_GeneratorDamage(entity this, entity inflictor, entity attacker, float damage, int deathtype, .entity weaponentity, vector hitloc, vector force)
882 {
883         if(damage <= 0) return;
884         if(warmup_stage || game_stopped) return;
885         if(!round_handler_IsRoundStarted()) return;
886
887         if (attacker != this)
888         {
889                 if (this.isshielded)
890                 {
891                         // generator is protected by a shield, so ignore the damage
892                         if (time > this.pain_finished)
893                                 if (IS_PLAYER(attacker))
894                                 {
895                                         play2(attacker, SND(ONS_DAMAGEBLOCKEDBYSHIELD));
896                                         attacker.typehitsound += 1;
897                                         this.pain_finished = time + 1;
898                                 }
899                         return;
900                 }
901                 if (time > this.pain_finished)
902                 {
903                         this.pain_finished = time + 10;
904                         FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it) && SAME_TEAM(it, this), Send_Notification(NOTIF_ONE, it, MSG_CENTER, CENTER_GENERATOR_UNDERATTACK));
905                         play2team(this.team, SND(ONS_GENERATOR_UNDERATTACK));
906                 }
907         }
908         TakeResource(this, RESOURCE_HEALTH, damage);
909         float hlth = GetResourceAmount(this, RESOURCE_HEALTH);
910         WaypointSprite_UpdateHealth(this.sprite, hlth);
911         // choose an animation frame based on health
912         this.frame = 10 * bound(0, (1 - hlth / this.max_health), 1);
913         // see if the generator is still functional, or dying
914         if (hlth > 0)
915         {
916                 this.lasthealth = hlth;
917         }
918         else
919         {
920                 if (attacker == this)
921                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_ONSLAUGHT_GENDESTROYED_OVERTIME));
922                 else
923                 {
924                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_ONSLAUGHT_GENDESTROYED));
925                         GameRules_scoring_add(attacker, SCORE, 100);
926                 }
927                 this.iscaptured = false;
928                 this.islinked = false;
929                 this.isshielded = false;
930                 this.takedamage = DAMAGE_NO; // can't be hurt anymore
931                 this.event_damage = func_null; // won't do anything if hurt
932                 this.event_heal = func_null;
933                 this.count = 0; // reset counter
934                 setthink(this, func_null);
935                 this.nextthink = 0;
936                 //this.think(); // do the first explosion now
937
938                 WaypointSprite_UpdateMaxHealth(this.sprite, 0);
939                 WaypointSprite_Ping(this.sprite);
940                 //WaypointSprite_Kill(this.sprite); // can't do this yet, code too poor
941
942                 onslaught_updatelinks();
943
944                 ons_camSetup(this);
945         }
946
947         // Throw some flaming gibs on damage, more damage = more chance for gib
948         if(random() < damage/220)
949         {
950                 sound(this, CH_TRIGGER, SND_ROCKET_IMPACT, VOL_BASE, ATTEN_NORM);
951         }
952         else
953         {
954                 // particles on every hit
955                 Send_Effect(EFFECT_SPARKS, hitloc, force * -1, 1);
956
957                 //sound on every hit
958                 if (random() < 0.5)
959                         sound(this, CH_TRIGGER, SND_ONS_HIT1, VOL_BASE, ATTEN_NORM);
960                 else
961                         sound(this, CH_TRIGGER, SND_ONS_HIT2, VOL_BASE, ATTEN_NORM);
962         }
963
964         this.SendFlags |= GSF_STATUS;
965 }
966
967 bool ons_GeneratorHeal(entity targ, entity inflictor, float amount, float limit)
968 {
969         float true_limit = ((limit != RESOURCE_LIMIT_NONE) ? limit : targ.max_health);
970         float hlth = GetResourceAmount(targ, RESOURCE_HEALTH);
971         if (hlth <= 0 || hlth >= true_limit)
972                 return false;
973
974         GiveResourceWithLimit(targ, RESOURCE_HEALTH, amount, true_limit);
975         hlth = GetResourceAmount(targ, RESOURCE_HEALTH);
976         WaypointSprite_UpdateHealth(targ.sprite, hlth);
977         targ.frame = 10 * bound(0, (1 - hlth / targ.max_health), 1);
978         targ.lasthealth = hlth;
979         targ.SendFlags |= GSF_STATUS;
980         return true;
981 }
982
983 void ons_GeneratorThink(entity this)
984 {
985         this.nextthink = time + GEN_THINKRATE;
986
987         if (game_stopped || this.isshielded || time < this.wait)
988                 return;
989
990         this.wait = time + 5;
991         FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it),
992         {
993                 if (SAME_TEAM(it, this))
994                 {
995                         Send_Notification(NOTIF_ONE, it, MSG_CENTER, CENTER_ONS_NOTSHIELDED_TEAM);
996                         msg_entity = it;
997                         soundto(MSG_ONE, this, CHAN_AUTO, SND(KH_ALARM), VOL_BASE, ATTEN_NONE); // FIXME: unique sound?
998                 }
999                 else
1000                         Send_Notification(NOTIF_ONE, it, MSG_CENTER, APP_TEAM_NUM(this.team, CENTER_ONS_NOTSHIELDED));
1001         });
1002 }
1003
1004 void ons_GeneratorReset(entity this)
1005 {
1006         this.team = this.team_saved;
1007         SetResourceAmountExplicit(this, RESOURCE_HEALTH, autocvar_g_onslaught_gen_health);
1008         this.lasthealth = this.max_health = autocvar_g_onslaught_gen_health;
1009         this.takedamage = DAMAGE_AIM;
1010         this.bot_attack = true;
1011         if(!IL_CONTAINS(g_bot_targets, this))
1012                 IL_PUSH(g_bot_targets, this);
1013         this.iscaptured = true;
1014         this.islinked = true;
1015         this.isshielded = true;
1016         this.event_damage = ons_GeneratorDamage;
1017         this.event_heal = ons_GeneratorHeal;
1018         setthink(this, ons_GeneratorThink);
1019         this.nextthink = time + GEN_THINKRATE;
1020
1021         Net_LinkEntity(this, false, 0, generator_send);
1022
1023         this.SendFlags = GSF_SETUP; // just incase
1024         this.SendFlags |= GSF_STATUS;
1025
1026         WaypointSprite_UpdateMaxHealth(this.sprite, this.max_health);
1027         WaypointSprite_UpdateHealth(this.sprite, GetResourceAmount(this, RESOURCE_HEALTH));
1028         WaypointSprite_UpdateRule(this.sprite,this.team,SPRITERULE_TEAMPLAY);
1029
1030         onslaught_updatelinks();
1031 }
1032
1033 void ons_DelayedGeneratorSetup(entity this)
1034 {
1035         // bot waypoints
1036         waypoint_spawnforitem_force(this, this.origin);
1037         this.nearestwaypointtimeout = 0; // activate waypointing again
1038         this.bot_basewaypoint = this.nearestwaypoint;
1039
1040         // captureshield setup
1041         ons_CaptureShield_Spawn(this, true);
1042
1043         onslaught_updatelinks();
1044
1045         Net_LinkEntity(this, false, 0, generator_send);
1046 }
1047
1048
1049 void onslaught_generator_touch(entity this, entity toucher)
1050 {
1051         if ( IS_PLAYER(toucher) )
1052         if ( SAME_TEAM(this,toucher) )
1053         if ( this.iscaptured )
1054         {
1055                 Send_Notification(NOTIF_ONE, toucher, MSG_CENTER, CENTER_ONS_TELEPORT);
1056         }
1057 }
1058
1059 void ons_GeneratorSetup(entity gen) // called when spawning a generator entity on the map as a spawnfunc
1060 {
1061         // declarations
1062         int teamnumber = gen.team;
1063
1064         // main setup
1065         gen.ons_worldgeneratornext = ons_worldgeneratorlist; // link generator into ons_worldgeneratorlist
1066         ons_worldgeneratorlist = gen;
1067
1068         gen.netname = sprintf("%s generator", Team_ColoredFullName(teamnumber));
1069         gen.classname = "onslaught_generator";
1070         gen.solid = SOLID_BBOX;
1071         gen.team_saved = teamnumber;
1072         IL_PUSH(g_saved_team, gen);
1073         set_movetype(gen, MOVETYPE_NONE);
1074         gen.lasthealth = gen.max_health = autocvar_g_onslaught_gen_health;
1075         SetResourceAmountExplicit(gen, RESOURCE_HEALTH, autocvar_g_onslaught_gen_health);
1076         gen.takedamage = DAMAGE_AIM;
1077         gen.bot_attack = true;
1078         IL_PUSH(g_bot_targets, gen);
1079         gen.event_damage = ons_GeneratorDamage;
1080         gen.event_heal = ons_GeneratorHeal;
1081         gen.reset = ons_GeneratorReset;
1082         setthink(gen, ons_GeneratorThink);
1083         gen.nextthink = time + GEN_THINKRATE;
1084         gen.iscaptured = true;
1085         gen.islinked = true;
1086         gen.isshielded = true;
1087         settouch(gen, onslaught_generator_touch);
1088
1089         // appearence
1090         // model handled by CSQC
1091         setsize(gen, GENERATOR_MIN, GENERATOR_MAX);
1092         setorigin(gen, (gen.origin + CPGEN_SPAWN_OFFSET));
1093         gen.colormap = 1024 + (teamnumber - 1) * 17;
1094
1095         // generator placement
1096         droptofloor(gen);
1097
1098         // waypointsprites
1099         WaypointSprite_SpawnFixed(WP_Null, gen.origin + CPGEN_WAYPOINT_OFFSET, gen, sprite, RADARICON_NONE);
1100         WaypointSprite_UpdateRule(gen.sprite, gen.team, SPRITERULE_TEAMPLAY);
1101         WaypointSprite_UpdateMaxHealth(gen.sprite, gen.max_health);
1102         WaypointSprite_UpdateHealth(gen.sprite, GetResourceAmount(gen, RESOURCE_HEALTH));
1103
1104         InitializeEntity(gen, ons_DelayedGeneratorSetup, INITPRIO_SETLOCATION);
1105 }
1106
1107
1108 // ===============
1109 //  Round Handler
1110 // ===============
1111
1112 int total_generators;
1113 void Onslaught_count_generators()
1114 {
1115         entity e;
1116         total_generators = 0;
1117         for (int i = 1; i <= NUM_TEAMS; ++i)
1118         {
1119                 Team_SetNumberOfControlPoints(Team_GetTeamFromIndex(i), 0);
1120         }
1121         for(e = ons_worldgeneratorlist; e; e = e.ons_worldgeneratornext)
1122         {
1123                 ++total_generators;
1124                 if (GetResourceAmount(e, RESOURCE_HEALTH) < 1)
1125                 {
1126                         continue;
1127                 }
1128                 entity team_ = Entity_GetTeam(e);
1129                 int num_control_points = Team_GetNumberOfControlPoints(team_);
1130                 ++num_control_points;
1131                 Team_SetNumberOfControlPoints(team_, num_control_points);
1132         }
1133 }
1134
1135 int Onslaught_GetWinnerTeam()
1136 {
1137         int winner_team = 0;
1138         if (Team_GetNumberOfControlPoints(Team_GetTeamFromIndex(1)) >= 1)
1139         {
1140                 winner_team = NUM_TEAM_1;
1141         }
1142         for (int i = 2; i <= NUM_TEAMS; ++i)
1143         {
1144                 if (Team_GetNumberOfControlPoints(Team_GetTeamFromIndex(i)) >= 1)
1145                 {
1146                         if (winner_team != 0)
1147                         {
1148                                 return 0;
1149                         }
1150                         winner_team = Team_IndexToTeam(i);
1151                 }
1152         }
1153         if (winner_team)
1154         {
1155                 return winner_team;
1156         }
1157         return -1; // no generators left?
1158 }
1159
1160 void nades_Clear(entity e);
1161
1162 bool Onslaught_CheckWinner()
1163 {
1164         if ((autocvar_timelimit && time > game_starttime + autocvar_timelimit * 60) || (round_handler_GetEndTime() > 0 && round_handler_GetEndTime() - time <= 0))
1165         {
1166                 ons_stalemate = true;
1167
1168                 if (!wpforenemy_announced)
1169                 {
1170                         Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_OVERTIME_CONTROLPOINT);
1171                         sound(NULL, CH_INFO, SND_ONS_GENERATOR_DECAY, VOL_BASE, ATTEN_NONE);
1172
1173                         wpforenemy_announced = true;
1174                 }
1175
1176                 entity tmp_entity; // temporary entity
1177                 float d;
1178                 for(tmp_entity = ons_worldgeneratorlist; tmp_entity; tmp_entity = tmp_entity.ons_worldgeneratornext) if(time >= tmp_entity.ons_overtime_damagedelay)
1179                 {
1180                         // tmp_entity.max_health / 300 gives 5 minutes of overtime.
1181                         // control points reduce the overtime duration.
1182                         d = 1;
1183                         entity e;
1184                         for(e = ons_worldcplist; e; e = e.ons_worldcpnext)
1185                         {
1186                                 if(DIFF_TEAM(e, tmp_entity))
1187                                 if(e.islinked)
1188                                         d = d + 1;
1189                         }
1190
1191                         if(autocvar_g_campaign && autocvar__campaign_testrun)
1192                                 d = d * tmp_entity.max_health;
1193                         else
1194                                 d = d * tmp_entity.max_health / max(30, 60 * autocvar_timelimit_suddendeath);
1195
1196                         Damage(tmp_entity, tmp_entity, tmp_entity, d, DEATH_HURTTRIGGER.m_id, DMG_NOWEP, tmp_entity.origin, '0 0 0');
1197
1198                         tmp_entity.sprite.SendFlags |= 16;
1199
1200                         tmp_entity.ons_overtime_damagedelay = time + 1;
1201                 }
1202         }
1203         else { wpforenemy_announced = false; ons_stalemate = false; }
1204
1205         Onslaught_count_generators();
1206
1207         if (Team_GetNumberOfTeamsWithControlPoints() > 1)
1208         {
1209                 return 0;
1210         }
1211
1212         int winner_team = Onslaught_GetWinnerTeam();
1213
1214         if(winner_team > 0)
1215         {
1216                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, APP_TEAM_NUM(winner_team, CENTER_ROUND_TEAM_WIN));
1217                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(winner_team, INFO_ROUND_TEAM_WIN));
1218                 TeamScore_AddToTeam(winner_team, ST_ONS_CAPS, +1);
1219         }
1220         else if(winner_team == -1)
1221         {
1222                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_ROUND_TIED);
1223                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_ROUND_TIED);
1224         }
1225
1226         ons_stalemate = false;
1227
1228         play2all(SND(CTF_CAPTURE(winner_team)));
1229
1230         round_handler_Init(7, autocvar_g_onslaught_warmup, autocvar_g_onslaught_round_timelimit);
1231
1232         FOREACH_CLIENT(IS_PLAYER(it), {
1233                 STAT(ROUNDLOST, it) = true;
1234                 it.player_blocked = true;
1235
1236                 nades_Clear(it);
1237         });
1238
1239         game_stopped = true;
1240         return 1;
1241 }
1242
1243 bool Onslaught_CheckPlayers()
1244 {
1245         return 1;
1246 }
1247
1248 void Onslaught_RoundStart()
1249 {
1250         entity tmp_entity;
1251         FOREACH_CLIENT(IS_PLAYER(it), it.player_blocked = false);
1252
1253         for(tmp_entity = ons_worldcplist; tmp_entity; tmp_entity = tmp_entity.ons_worldcpnext)
1254                 tmp_entity.sprite.SendFlags |= 16;
1255
1256         for(tmp_entity = ons_worldgeneratorlist; tmp_entity; tmp_entity = tmp_entity.ons_worldgeneratornext)
1257                 tmp_entity.sprite.SendFlags |= 16;
1258 }
1259
1260
1261 // ================
1262 // Bot player logic
1263 // ================
1264
1265 // NOTE: LEGACY CODE, needs to be re-written!
1266
1267 void havocbot_role_ons_setrole(entity this, int role)
1268 {
1269         switch(role)
1270         {
1271                 case HAVOCBOT_ONS_ROLE_DEFENSE:
1272                         LOG_DEBUG(this.netname, " switched to defense");
1273                         this.havocbot_role = havocbot_role_ons_defense;
1274                         this.havocbot_role_timeout = 0;
1275                         break;
1276                 case HAVOCBOT_ONS_ROLE_ASSISTANT:
1277                         LOG_DEBUG(this.netname, " switched to assistant");
1278                         this.havocbot_role = havocbot_role_ons_assistant;
1279                         this.havocbot_role_timeout = 0;
1280                         break;
1281                 case HAVOCBOT_ONS_ROLE_OFFENSE:
1282                         LOG_DEBUG(this.netname, " switched to offense");
1283                         this.havocbot_role = havocbot_role_ons_offense;
1284                         this.havocbot_role_timeout = 0;
1285                         break;
1286         }
1287 }
1288
1289 void havocbot_goalrating_ons_controlpoints_attack(entity this, float ratingscale)
1290 {
1291         entity cp, cp1, cp2, best, wp;
1292         float radius, bestvalue;
1293         int c;
1294         bool found;
1295
1296         // Filter control points
1297         for(cp2 = ons_worldcplist; cp2; cp2 = cp2.ons_worldcpnext)
1298         {
1299                 cp2.wpcost = c = 0;
1300                 cp2.wpconsidered = false;
1301
1302                 if(cp2.isshielded)
1303                         continue;
1304
1305                 // Ignore owned controlpoints
1306                 if(!((cp2.aregensneighbor & BIT(this.team)) || (cp2.arecpsneighbor & BIT(this.team))))
1307                         continue;
1308
1309                 // Count team mates interested in this control point
1310                 // (easier and cleaner than keeping counters per cp and teams)
1311                 FOREACH_CLIENT(it != this && IS_PLAYER(it), {
1312                         if(SAME_TEAM(it, this))
1313                         if(it.havocbot_role == havocbot_role_ons_offense)
1314                         if(it.havocbot_ons_target == cp2)
1315                                 ++c;
1316                 });
1317
1318                 // NOTE: probably decrease the cost of attackable control points
1319                 cp2.wpcost = c;
1320                 cp2.wpconsidered = true;
1321         }
1322
1323         // We'll consider only the best case
1324         bestvalue = FLOAT_MAX;
1325         cp = NULL;
1326         for(cp1 = ons_worldcplist; cp1; cp1 = cp1.ons_worldcpnext)
1327         {
1328                 if (!cp1.wpconsidered)
1329                         continue;
1330
1331                 if(cp1.wpcost<bestvalue)
1332                 {
1333                         bestvalue = cp1.wpcost;
1334                         cp = cp1;
1335                         this.havocbot_ons_target = cp1;
1336                 }
1337         }
1338
1339         if (!cp)
1340                 return;
1341
1342         LOG_DEBUG(this.netname, " chose cp ranked ", ftos(bestvalue));
1343
1344         if(cp.goalentity)
1345         {
1346                 // Should be attacked
1347                 // Rate waypoints near it
1348                 found = false;
1349                 best = NULL;
1350                 bestvalue = FLOAT_MAX;
1351                 for (radius = 500; radius <= 1000 && !found; radius += 500)
1352                 {
1353                         IL_EACH(g_waypoints, vdist(cp.origin - it.origin, <, radius),
1354                         {
1355                                 if (!(it.wpflags & WAYPOINTFLAG_GENERATED) && checkpvs(it.origin, cp))
1356                                 {
1357                                         found = true;
1358                                         if (it.cnt < bestvalue)
1359                                         {
1360                                                 best = it;
1361                                                 bestvalue = it.cnt;
1362                                         }
1363                                 }
1364                         });
1365                 }
1366
1367                 if(best)
1368                 {
1369                         navigation_routerating(this, best, ratingscale, 10000);
1370                         best.cnt += 1;
1371
1372                         this.havocbot_attack_time = 0;
1373                         if(checkpvs(this.origin + this.view_ofs, cp))
1374                         if(checkpvs(this.origin + this.view_ofs, best))
1375                                 this.havocbot_attack_time = time + 2;
1376                 }
1377                 else
1378                 {
1379                         navigation_routerating(this, cp, ratingscale, 10000);
1380                 }
1381                 LOG_DEBUG(this.netname, " found an attackable controlpoint at ", vtos(cp.origin));
1382         }
1383         else
1384         {
1385                 // Should be touched
1386                 LOG_DEBUG(this.netname, " found a touchable controlpoint at ", vtos(cp.origin));
1387                 navigation_routerating(this, cp, ratingscale * 2, 10000);
1388         }
1389 }
1390
1391 bool havocbot_goalrating_ons_generator_attack(entity this, float ratingscale)
1392 {
1393         entity g, wp, bestwp;
1394         bool found;
1395         int bestvalue;
1396
1397         for(g = ons_worldgeneratorlist; g; g = g.ons_worldgeneratornext)
1398         {
1399                 if(SAME_TEAM(g, this) || g.isshielded)
1400                         continue;
1401
1402                 // Should be attacked
1403                 // Rate waypoints near it
1404                 found = false;
1405                 bestwp = NULL;
1406                 bestvalue = FLOAT_MAX;
1407
1408                 IL_EACH(g_waypoints, vdist(g.origin - it.origin, <, 400),
1409                 {
1410                         if (checkpvs(it.origin, g))
1411                         {
1412                                 found = true;
1413                                 if (it.cnt < bestvalue)
1414                                 {
1415                                         bestwp = it;
1416                                         bestvalue = it.cnt;
1417                                 }
1418                         }
1419                 });
1420
1421                 if(bestwp)
1422                 {
1423                         LOG_DEBUG("waypoints found around generator");
1424                         navigation_routerating(this, bestwp, ratingscale, 10000);
1425                         bestwp.cnt += 1;
1426
1427                         this.havocbot_attack_time = 0;
1428                         if(checkpvs(this.origin + this.view_ofs, g))
1429                         if(checkpvs(this.origin + this.view_ofs, bestwp))
1430                                 this.havocbot_attack_time = time + 5;
1431
1432                         return true;
1433                 }
1434                 else
1435                 {
1436                         LOG_DEBUG("generator found without waypoints around");
1437                         // if there aren't waypoints near the generator go straight to it
1438                         navigation_routerating(this, g, ratingscale, 10000);
1439                         this.havocbot_attack_time = 0;
1440                         return true;
1441                 }
1442         }
1443         return false;
1444 }
1445
1446 void havocbot_role_ons_offense(entity this)
1447 {
1448         if(IS_DEAD(this))
1449         {
1450                 this.havocbot_attack_time = 0;
1451                 havocbot_ons_reset_role(this);
1452                 return;
1453         }
1454
1455         // Set the role timeout if necessary
1456         if (!this.havocbot_role_timeout)
1457                 this.havocbot_role_timeout = time + 120;
1458
1459         if (time > this.havocbot_role_timeout)
1460         {
1461                 havocbot_ons_reset_role(this);
1462                 return;
1463         }
1464
1465         if(this.havocbot_attack_time>time)
1466                 return;
1467
1468         if (navigation_goalrating_timeout(this))
1469         {
1470                 navigation_goalrating_start(this);
1471                 havocbot_goalrating_enemyplayers(this, 20000, this.origin, 650);
1472                 if(!havocbot_goalrating_ons_generator_attack(this, 10000))
1473                         havocbot_goalrating_ons_controlpoints_attack(this, 10000);
1474                 havocbot_goalrating_items(this, 25000, this.origin, 10000);
1475                 navigation_goalrating_end(this);
1476
1477                 navigation_goalrating_timeout_set(this);
1478         }
1479 }
1480
1481 void havocbot_role_ons_assistant(entity this)
1482 {
1483         havocbot_ons_reset_role(this);
1484 }
1485
1486 void havocbot_role_ons_defense(entity this)
1487 {
1488         havocbot_ons_reset_role(this);
1489 }
1490
1491 void havocbot_ons_reset_role(entity this)
1492 {
1493         if(IS_DEAD(this))
1494                 return;
1495
1496         this.havocbot_ons_target = NULL;
1497
1498         // TODO: Defend control points or generator if necessary
1499
1500         havocbot_role_ons_setrole(this, HAVOCBOT_ONS_ROLE_OFFENSE);
1501 }
1502
1503
1504 /*
1505  * Find control point or generator owned by the same team self which is nearest to pos
1506  * if max_dist is positive, only control points within this range will be considered
1507  */
1508 entity ons_Nearest_ControlPoint(entity this, vector pos, float max_dist)
1509 {
1510         entity closest_target = NULL;
1511         for(entity cp = ons_worldcplist; cp; cp = cp.ons_worldcpnext)
1512         {
1513                 if(SAME_TEAM(cp, this))
1514                 if(cp.iscaptured)
1515                 if(max_dist <= 0 || vdist(cp.origin - pos, <=, max_dist))
1516                 if(vlen2(cp.origin - pos) <= vlen2(closest_target.origin - pos) || closest_target == NULL)
1517                         closest_target = cp;
1518         }
1519         for(entity gen = ons_worldgeneratorlist; gen; gen = gen.ons_worldgeneratornext)
1520         {
1521                 if(SAME_TEAM(gen, this))
1522                 if(max_dist <= 0 || vdist(gen.origin - pos, <, max_dist))
1523                 if(vlen2(gen.origin - pos) <= vlen2(closest_target.origin - pos) || closest_target == NULL)
1524                         closest_target = gen;
1525         }
1526
1527         return closest_target;
1528 }
1529
1530 /*
1531  * Find control point or generator owned by the same team self which is nearest to pos
1532  * if max_dist is positive, only control points within this range will be considered
1533  * This function only check distances on the XY plane, disregarding Z
1534  */
1535 entity ons_Nearest_ControlPoint_2D(entity this, vector pos, float max_dist)
1536 {
1537         entity closest_target = NULL;
1538         vector delta;
1539         float smallest_distance = 0, distance;
1540
1541         for(entity cp = ons_worldcplist; cp; cp = cp.ons_worldcpnext)
1542         {
1543                 delta = cp.origin - pos;
1544                 delta_z = 0;
1545                 distance = vlen(delta);
1546
1547                 if(SAME_TEAM(cp, this))
1548                 if(cp.iscaptured)
1549                 if(max_dist <= 0 || distance <= max_dist)
1550                 if(closest_target == NULL || distance <= smallest_distance )
1551                 {
1552                         closest_target = cp;
1553                         smallest_distance = distance;
1554                 }
1555         }
1556         for(entity gen = ons_worldgeneratorlist; gen; gen = gen.ons_worldgeneratornext)
1557         {
1558                 delta = gen.origin - pos;
1559                 delta_z = 0;
1560                 distance = vlen(delta);
1561
1562                 if(SAME_TEAM(gen, this))
1563                 if(max_dist <= 0 || distance <= max_dist)
1564                 if(closest_target == NULL || distance <= smallest_distance )
1565                 {
1566                         closest_target = gen;
1567                         smallest_distance = distance;
1568                 }
1569         }
1570
1571         return closest_target;
1572 }
1573 /**
1574  * find the number of control points and generators in the same team as this
1575  */
1576 int ons_Count_SelfControlPoints(entity this)
1577 {
1578         int n = 0;
1579         for(entity cp = ons_worldcplist; cp; cp = cp.ons_worldcpnext)
1580         {
1581                 if(SAME_TEAM(cp, this))
1582                 if(cp.iscaptured)
1583                         n++;
1584         }
1585         for(entity gen = ons_worldgeneratorlist; gen; gen = gen.ons_worldgeneratornext)
1586         {
1587                 if(SAME_TEAM(gen, this))
1588                         n++;
1589         }
1590         return n;
1591 }
1592
1593 /**
1594  * Teleport player to a random position near tele_target
1595  * if tele_effects is true, teleport sound+particles are created
1596  * return false on failure
1597  */
1598 bool ons_Teleport(entity player, entity tele_target, float range, bool tele_effects)
1599 {
1600         if ( !tele_target )
1601                 return false;
1602
1603         int i;
1604         vector loc;
1605         float theta;
1606         // narrow the range for each iteration to increase chances that a spawnpoint
1607         // can be found even if there's little room around the control point
1608         float iteration_scale = 1;
1609         for(i = 0; i < 16; ++i)
1610         {
1611                 iteration_scale -= i / 16;
1612                 theta = random() * 2 * M_PI;
1613                 loc_y = sin(theta);
1614                 loc_x = cos(theta);
1615                 loc_z = 0;
1616                 loc *= random() * range * iteration_scale;
1617
1618                 loc += tele_target.origin + '0 0 128' * iteration_scale;
1619
1620                 tracebox(loc, STAT(PL_MIN, player), STAT(PL_MAX, player), loc, MOVE_NORMAL, player);
1621                 if(trace_fraction == 1.0 && !trace_startsolid)
1622                 {
1623                         traceline(tele_target.origin, loc, MOVE_NOMONSTERS, tele_target); // double check to make sure we're not spawning outside the NULL
1624                         if(trace_fraction == 1.0 && !trace_startsolid)
1625                         {
1626                                 if ( tele_effects )
1627                                 {
1628                                         Send_Effect(EFFECT_TELEPORT, player.origin, '0 0 0', 1);
1629                                         sound (player, CH_TRIGGER, SND_TELEPORT, VOL_BASE, ATTEN_NORM);
1630                                 }
1631                                 setorigin(player, loc);
1632                                 player.angles = '0 1 0' * ( theta * RAD2DEG + 180 );
1633                                 makevectors(player.angles);
1634                                 player.fixangle = true;
1635                                 player.teleport_antispam = time + autocvar_g_onslaught_teleport_wait;
1636
1637                                 if ( tele_effects )
1638                                         Send_Effect(EFFECT_TELEPORT, player.origin + v_forward * 32, '0 0 0', 1);
1639                                 return true;
1640                         }
1641                 }
1642         }
1643
1644         return false;
1645 }
1646
1647 // ==============
1648 // Hook Functions
1649 // ==============
1650
1651 MUTATOR_HOOKFUNCTION(ons, reset_map_global)
1652 {
1653         FOREACH_CLIENT(IS_PLAYER(it), {
1654                 STAT(ROUNDLOST, it) = false;
1655                 it.ons_deathloc = '0 0 0';
1656                 PutClientInServer(it);
1657                 it.clientcamera = it;
1658         });
1659         return false;
1660 }
1661
1662 MUTATOR_HOOKFUNCTION(ons, ClientDisconnect)
1663 {
1664         entity player = M_ARGV(0, entity);
1665
1666         player.ons_deathloc = '0 0 0';
1667 }
1668
1669 MUTATOR_HOOKFUNCTION(ons, MakePlayerObserver)
1670 {
1671         entity player = M_ARGV(0, entity);
1672
1673         player.ons_deathloc = '0 0 0';
1674 }
1675
1676 MUTATOR_HOOKFUNCTION(ons, PlayerSpawn)
1677 {
1678         entity player = M_ARGV(0, entity);
1679
1680         if(!round_handler_IsRoundStarted())
1681         {
1682                 player.player_blocked = true;
1683                 return false;
1684         }
1685
1686         entity l;
1687         for(l = ons_worldgeneratorlist; l; l = l.ons_worldgeneratornext)
1688         {
1689                 l.sprite.SendFlags |= 16;
1690         }
1691         for(l = ons_worldcplist; l; l = l.ons_worldcpnext)
1692         {
1693                 l.sprite.SendFlags |= 16;
1694         }
1695
1696         if(ons_stalemate) { Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_OVERTIME_CONTROLPOINT); }
1697
1698         if ( autocvar_g_onslaught_spawn_choose )
1699         if ( player.ons_spawn_by )
1700         if ( ons_Teleport(player,player.ons_spawn_by,autocvar_g_onslaught_teleport_radius,false) )
1701         {
1702                 player.ons_spawn_by = NULL;
1703                 return false;
1704         }
1705
1706         if(autocvar_g_onslaught_spawn_at_controlpoints)
1707         if(random() <= autocvar_g_onslaught_spawn_at_controlpoints_chance)
1708         {
1709                 float random_target = autocvar_g_onslaught_spawn_at_controlpoints_random;
1710                 entity tmp_entity, closest_target = NULL;
1711                 vector spawn_loc = player.ons_deathloc;
1712
1713                 // new joining player or round reset, don't bother checking
1714                 if(spawn_loc == '0 0 0') { return false; }
1715
1716                 if(random_target) { RandomSelection_Init(); }
1717
1718                 for(tmp_entity = ons_worldcplist; tmp_entity; tmp_entity = tmp_entity.ons_worldcpnext)
1719                 {
1720                         if(SAME_TEAM(tmp_entity, player))
1721                         if(random_target)
1722                                 RandomSelection_AddEnt(tmp_entity, 1, 1);
1723                         else if(vlen2(tmp_entity.origin - spawn_loc) <= vlen2(closest_target.origin - spawn_loc) || closest_target == NULL)
1724                                 closest_target = tmp_entity;
1725                 }
1726
1727                 if(random_target) { closest_target = RandomSelection_chosen_ent; }
1728
1729                 if(closest_target)
1730                 {
1731                         float i;
1732                         vector loc;
1733                         float iteration_scale = 1;
1734                         for(i = 0; i < 10; ++i)
1735                         {
1736                                 iteration_scale -= i / 10;
1737                                 loc = closest_target.origin + '0 0 96' * iteration_scale;
1738                                 loc += ('0 1 0' * random()) * 128 * iteration_scale;
1739                                 tracebox(loc, STAT(PL_MIN, player), STAT(PL_MAX, player), loc, MOVE_NORMAL, player);
1740                                 if(trace_fraction == 1.0 && !trace_startsolid)
1741                                 {
1742                                         traceline(closest_target.origin, loc, MOVE_NOMONSTERS, closest_target); // double check to make sure we're not spawning outside the NULL
1743                                         if(trace_fraction == 1.0 && !trace_startsolid)
1744                                         {
1745                                                 setorigin(player, loc);
1746                                                 player.angles = normalize(loc - closest_target.origin) * RAD2DEG;
1747                                                 return false;
1748                                         }
1749                                 }
1750                         }
1751                 }
1752         }
1753
1754         if(autocvar_g_onslaught_spawn_at_generator)
1755         if(random() <= autocvar_g_onslaught_spawn_at_generator_chance)
1756         {
1757                 float random_target = autocvar_g_onslaught_spawn_at_generator_random;
1758                 entity tmp_entity, closest_target = NULL;
1759                 vector spawn_loc = player.ons_deathloc;
1760
1761                 // new joining player or round reset, don't bother checking
1762                 if(spawn_loc == '0 0 0') { return false; }
1763
1764                 if(random_target) { RandomSelection_Init(); }
1765
1766                 for(tmp_entity = ons_worldgeneratorlist; tmp_entity; tmp_entity = tmp_entity.ons_worldgeneratornext)
1767                 {
1768                         if(random_target)
1769                                 RandomSelection_AddEnt(tmp_entity, 1, 1);
1770                         else
1771                         {
1772                                 if(SAME_TEAM(tmp_entity, player))
1773                                 if(vlen2(tmp_entity.origin - spawn_loc) <= vlen2(closest_target.origin - spawn_loc) || closest_target == NULL)
1774                                         closest_target = tmp_entity;
1775                         }
1776                 }
1777
1778                 if(random_target) { closest_target = RandomSelection_chosen_ent; }
1779
1780                 if(closest_target)
1781                 {
1782                         float i;
1783                         vector loc;
1784                         float iteration_scale = 1;
1785                         for(i = 0; i < 10; ++i)
1786                         {
1787                                 iteration_scale -= i / 10;
1788                                 loc = closest_target.origin + '0 0 128' * iteration_scale;
1789                                 loc += ('0 1 0' * random()) * 256 * iteration_scale;
1790                                 tracebox(loc, STAT(PL_MIN, player), STAT(PL_MAX, player), loc, MOVE_NORMAL, player);
1791                                 if(trace_fraction == 1.0 && !trace_startsolid)
1792                                 {
1793                                         traceline(closest_target.origin, loc, MOVE_NOMONSTERS, closest_target); // double check to make sure we're not spawning outside the NULL
1794                                         if(trace_fraction == 1.0 && !trace_startsolid)
1795                                         {
1796                                                 setorigin(player, loc);
1797                                                 player.angles = normalize(loc - closest_target.origin) * RAD2DEG;
1798                                                 return false;
1799                                         }
1800                                 }
1801                         }
1802                 }
1803         }
1804
1805         return false;
1806 }
1807
1808 MUTATOR_HOOKFUNCTION(ons, PlayerDies)
1809 {
1810         entity frag_target = M_ARGV(2, entity);
1811
1812         frag_target.ons_deathloc = frag_target.origin;
1813         entity l;
1814         for(l = ons_worldgeneratorlist; l; l = l.ons_worldgeneratornext)
1815         {
1816                 l.sprite.SendFlags |= 16;
1817         }
1818         for(l = ons_worldcplist; l; l = l.ons_worldcpnext)
1819         {
1820                 l.sprite.SendFlags |= 16;
1821         }
1822
1823         if ( autocvar_g_onslaught_spawn_choose )
1824         if ( ons_Count_SelfControlPoints(frag_target) > 1 )
1825                 stuffcmd(frag_target, "qc_cmd_cl hud clickradar\n");
1826
1827         return false;
1828 }
1829
1830 MUTATOR_HOOKFUNCTION(ons, MonsterMove)
1831 {
1832         entity mon = M_ARGV(0, entity);
1833
1834         entity e = find(NULL, targetname, mon.target);
1835         if (e != NULL)
1836                 mon.team = e.team;
1837 }
1838
1839 void ons_MonsterSpawn_Delayed(entity this)
1840 {
1841         entity own = this.owner;
1842
1843         if(!own) { delete(this); return; }
1844
1845         if(own.targetname)
1846         {
1847                 entity e = find(NULL, target, own.targetname);
1848                 if(e != NULL)
1849                 {
1850                         own.team = e.team;
1851
1852                         own.use(own, e, NULL);
1853                 }
1854         }
1855
1856         delete(this);
1857 }
1858
1859 MUTATOR_HOOKFUNCTION(ons, MonsterSpawn)
1860 {
1861         entity mon = M_ARGV(0, entity);
1862
1863         entity e = spawn();
1864         e.owner = mon;
1865         InitializeEntity(e, ons_MonsterSpawn_Delayed, INITPRIO_FINDTARGET);
1866 }
1867
1868 void ons_TurretSpawn_Delayed(entity this)
1869 {
1870         entity own = this.owner;
1871
1872         if(!own) { delete(this); return; }
1873
1874         if(own.targetname)
1875         {
1876                 entity e = find(NULL, target, own.targetname);
1877                 if(e != NULL)
1878                 {
1879                         own.team = e.team;
1880                         own.active = ACTIVE_NOT;
1881
1882                         own.use(own, e, NULL);
1883                 }
1884         }
1885
1886         delete(this);
1887 }
1888
1889 MUTATOR_HOOKFUNCTION(ons, TurretSpawn)
1890 {
1891         entity turret = M_ARGV(0, entity);
1892
1893         entity e = spawn();
1894         e.owner = turret;
1895         InitializeEntity(e, ons_TurretSpawn_Delayed, INITPRIO_FINDTARGET);
1896
1897         return false;
1898 }
1899
1900 MUTATOR_HOOKFUNCTION(ons, HavocBot_ChooseRole)
1901 {
1902         entity bot = M_ARGV(0, entity);
1903
1904         havocbot_ons_reset_role(bot);
1905         return true;
1906 }
1907
1908 MUTATOR_HOOKFUNCTION(ons, TeamBalance_CheckAllowedTeams)
1909 {
1910         // onslaught is special
1911         for(entity tmp_entity = ons_worldgeneratorlist; tmp_entity; tmp_entity = tmp_entity.ons_worldgeneratornext)
1912         {
1913                 if (Team_IsValidTeam(tmp_entity.team))
1914                 {
1915                         M_ARGV(0, float) |= Team_TeamToBit(tmp_entity.team);
1916                 }
1917         }
1918
1919         return true;
1920 }
1921
1922 MUTATOR_HOOKFUNCTION(ons, SpectateCopy)
1923 {
1924         entity spectatee = M_ARGV(0, entity);
1925         entity client = M_ARGV(1, entity);
1926
1927         STAT(ROUNDLOST, client) = STAT(ROUNDLOST, spectatee); // make spectators see it too
1928 }
1929
1930 MUTATOR_HOOKFUNCTION(ons, SV_ParseClientCommand)
1931 {
1932         if(MUTATOR_RETURNVALUE) // command was already handled?
1933                 return false;
1934
1935         entity player = M_ARGV(0, entity);
1936         string cmd_name = M_ARGV(1, string);
1937         int cmd_argc = M_ARGV(2, int);
1938
1939         if ( cmd_name == "ons_spawn" )
1940         {
1941                 vector pos = player.origin;
1942                 if(cmd_argc > 1)
1943                         pos_x = stof(argv(1));
1944                 if(cmd_argc > 2)
1945                         pos_y = stof(argv(2));
1946                 if(cmd_argc > 3)
1947                         pos_z = stof(argv(3));
1948
1949                 if ( IS_PLAYER(player) )
1950                 {
1951                         if ( !STAT(FROZEN, player) )
1952                         {
1953                                 entity source_point = ons_Nearest_ControlPoint(player, player.origin, autocvar_g_onslaught_teleport_radius);
1954
1955                                 if ( !source_point && GetResourceAmount(player, RESOURCE_HEALTH) > 0 )
1956                                 {
1957                                         sprint(player, "\nYou need to be next to a control point\n");
1958                                         return true;
1959                                 }
1960
1961
1962                                 entity closest_target = ons_Nearest_ControlPoint_2D(player, pos, autocvar_g_onslaught_click_radius);
1963
1964                                 if ( closest_target == NULL )
1965                                 {
1966                                         sprint(player, "\nNo control point found\n");
1967                                         return true;
1968                                 }
1969
1970                                 if ( GetResourceAmount(player, RESOURCE_HEALTH) <= 0 )
1971                                 {
1972                                         player.ons_spawn_by = closest_target;
1973                                         player.respawn_flags = player.respawn_flags | RESPAWN_FORCE;
1974                                 }
1975                                 else
1976                                 {
1977                                         if ( source_point == closest_target )
1978                                         {
1979                                                 sprint(player, "\nTeleporting to the same point\n");
1980                                                 return true;
1981                                         }
1982
1983                                         if ( !ons_Teleport(player,closest_target,autocvar_g_onslaught_teleport_radius,true) )
1984                                                 sprint(player, "\nUnable to teleport there\n");
1985                                 }
1986
1987                                 return true;
1988                         }
1989
1990                         sprint(player, "\nNo teleportation for you\n");
1991                 }
1992
1993                 return true;
1994         }
1995         return false;
1996 }
1997
1998 MUTATOR_HOOKFUNCTION(ons, PlayerUseKey)
1999 {
2000         if(MUTATOR_RETURNVALUE || game_stopped) return false;
2001
2002         entity player = M_ARGV(0, entity);
2003
2004         if((time > player.teleport_antispam) && (!IS_DEAD(player)) && !player.vehicle)
2005         {
2006                 entity source_point = ons_Nearest_ControlPoint(player, player.origin, autocvar_g_onslaught_teleport_radius);
2007                 if ( source_point )
2008                 {
2009                         stuffcmd(player, "qc_cmd_cl hud clickradar\n");
2010                         return true;
2011                 }
2012         }
2013 }
2014
2015 MUTATOR_HOOKFUNCTION(ons, PlayHitsound)
2016 {
2017         entity frag_victim = M_ARGV(0, entity);
2018
2019         return (frag_victim.classname == "onslaught_generator" && !frag_victim.isshielded)
2020                 || (frag_victim.classname == "onslaught_controlpoint_icon" && !frag_victim.owner.isshielded);
2021 }
2022
2023 MUTATOR_HOOKFUNCTION(ons, SendWaypoint)
2024 {
2025     entity wp = M_ARGV(0, entity);
2026     entity to = M_ARGV(1, entity);
2027     int sf = M_ARGV(2, int);
2028     int wp_flag = M_ARGV(3, int);
2029
2030         if(sf & 16)
2031         {
2032                 if(wp.owner.classname == "onslaught_controlpoint")
2033                 {
2034                         entity wp_owner = wp.owner;
2035                         entity e = WaypointSprite_getviewentity(to);
2036                         if(SAME_TEAM(e, wp_owner) && GetResourceAmount(wp_owner.goalentity, RESOURCE_HEALTH) >= wp_owner.goalentity.max_health) { wp_flag |= 2; }
2037                         if(!ons_ControlPoint_Attackable(wp_owner, e.team)) { wp_flag |= 2; }
2038                 }
2039                 if(wp.owner.classname == "onslaught_generator")
2040                 {
2041                         entity wp_owner = wp.owner;
2042                         if(wp_owner.isshielded && GetResourceAmount(wp_owner, RESOURCE_HEALTH) >= wp_owner.max_health) { wp_flag |= 2; }
2043                         if(GetResourceAmount(wp_owner, RESOURCE_HEALTH) <= 0) { wp_flag |= 2; }
2044                 }
2045         }
2046
2047         M_ARGV(3, int) = wp_flag;
2048 }
2049
2050 MUTATOR_HOOKFUNCTION(ons, TurretValidateTarget)
2051 {
2052         entity turret_target = M_ARGV(1, entity);
2053
2054         if(substring(turret_target.classname, 0, 10) == "onslaught_") // don't attack onslaught targets, that's the player's job!
2055         {
2056                 M_ARGV(3, float) = -3;
2057                 return true;
2058         }
2059
2060         return false;
2061 }
2062
2063 MUTATOR_HOOKFUNCTION(ons, TurretThink)
2064 {
2065     entity turret = M_ARGV(0, entity);
2066
2067         // ONS uses somewhat backwards linking.
2068         if(turret.target)
2069         {
2070                 entity e = find(NULL, targetname, turret.target);
2071                 if (e != NULL)
2072                         turret.team = e.team;
2073         }
2074
2075         if(turret.team != turret.tur_head.team)
2076                 turret_respawn(turret);
2077 }
2078
2079
2080 // ==========
2081 // Spawnfuncs
2082 // ==========
2083
2084 /*QUAKED spawnfunc_onslaught_link (0 .5 .8) (-16 -16 -16) (16 16 16)
2085   Link between control points.
2086
2087   This entity targets two different spawnfunc_onslaught_controlpoint or spawnfunc_onslaught_generator entities, and suppresses shielding on both if they are owned by different teams.
2088
2089 keys:
2090 "target" - first control point.
2091 "target2" - second control point.
2092  */
2093 spawnfunc(onslaught_link)
2094 {
2095         if(!g_onslaught) { delete(this); return; }
2096
2097         if (this.target == "" || this.target2 == "")
2098                 objerror(this, "target and target2 must be set\n");
2099
2100         this.ons_worldlinknext = ons_worldlinklist; // link into ons_worldlinklist
2101         ons_worldlinklist = this;
2102
2103         InitializeEntity(this, ons_DelayedLinkSetup, INITPRIO_FINDTARGET);
2104         Net_LinkEntity(this, false, 0, ons_Link_Send);
2105 }
2106
2107 /*QUAKED spawnfunc_onslaught_controlpoint (0 .5 .8) (-32 -32 0) (32 32 128)
2108   Control point. Be sure to give this enough clearance so that the shootable part has room to exist
2109
2110   This should link to an spawnfunc_onslaught_controlpoint entity or spawnfunc_onslaught_generator entity.
2111
2112 keys:
2113 "targetname" - name that spawnfunc_onslaught_link entities will use to target this.
2114 "target" - target any entities that are tied to this control point, such as vehicles and buildable structure entities.
2115 "message" - name of this control point (should reflect the location in the map, such as "center bridge", "north tower", etc)
2116  */
2117
2118 spawnfunc(onslaught_controlpoint)
2119 {
2120         if(!g_onslaught) { delete(this); return; }
2121
2122         ons_ControlPoint_Setup(this);
2123 }
2124
2125 /*QUAKED spawnfunc_onslaught_generator (0 .5 .8) (-32 -32 -24) (32 32 64)
2126   Base generator.
2127
2128   spawnfunc_onslaught_link entities can target this.
2129
2130 keys:
2131 "team" - team that owns this generator (5 = red, 14 = blue, etc), MUST BE SET.
2132 "targetname" - name that spawnfunc_onslaught_link entities will use to target this.
2133  */
2134 spawnfunc(onslaught_generator)
2135 {
2136         if(!g_onslaught) { delete(this); return; }
2137         if(!this.team) { objerror(this, "team must be set"); }
2138
2139         ons_GeneratorSetup(this);
2140 }
2141
2142 // scoreboard setup
2143 void ons_ScoreRules()
2144 {
2145         entity balance = TeamBalance_CheckAllowedTeams(NULL);
2146         int teams = TeamBalance_GetAllowedTeams(balance);
2147         TeamBalance_Destroy(balance);
2148         GameRules_scoring(teams, SFL_SORT_PRIO_PRIMARY, 0, {
2149             field_team(ST_ONS_CAPS, "destroyed", SFL_SORT_PRIO_PRIMARY);
2150             field(SP_ONS_CAPS, "caps", SFL_SORT_PRIO_SECONDARY);
2151             field(SP_ONS_TAKES, "takes", 0);
2152         });
2153 }
2154
2155 void ons_DelayedInit(entity this) // Do this check with a delay so we can wait for teams to be set up
2156 {
2157         ons_ScoreRules();
2158
2159         round_handler_Spawn(Onslaught_CheckPlayers, Onslaught_CheckWinner, Onslaught_RoundStart);
2160         round_handler_Init(5, autocvar_g_onslaught_warmup, autocvar_g_onslaught_round_timelimit);
2161 }
2162
2163 void ons_Initialize()
2164 {
2165         g_onslaught = true;
2166         ons_captureshield_force = autocvar_g_onslaught_shield_force;
2167
2168         cam = new(objective_camera);
2169
2170         InitializeEntity(NULL, ons_DelayedInit, INITPRIO_GAMETYPE);
2171 }