qcsrc/common/items/inventory.qh

   1 #pragma once
   2
   3 #include "all.qh"
   4
   5 CLASS(Inventory, Object)
   6     /** Stores counts of items, the id being the index */
   7     ATTRIBARRAY(Inventory, inv_items, int, Items_MAX);
   8     /** Previous state */
   9     ATTRIB(Inventory, inventory, Inventory);
  10 ENDCLASS(Inventory)
  11
  12 /** Player inventory */
  13 .Inventory inventory;
  14
  15 REGISTER_NET_LINKED(ENT_CLIENT_INVENTORY)
  16
  17 const int Inventory_groups_major = 16;
  18 const int Inventory_groups_minor = 8; // ceil(Items_MAX / Inventory_groups_major)
  19
  20 #define G_MAJOR(id) (floor((id) / Inventory_groups_minor))
  21 #define G_MINOR(id) ((id) % Inventory_groups_minor)
  22
  23 #ifdef CSQC
  24 NET_HANDLE(ENT_CLIENT_INVENTORY, bool isnew)
  25 {
  26     make_pure(this);
  27     const int majorBits = ReadShort();
  28     for (int i = 0; i < Inventory_groups_major; ++i) {
  29         if (!(majorBits & BIT(i))) {
  30             continue;
  31         }
  32         const int minorBits = ReadByte();
  33         for (int j = 0; j < Inventory_groups_minor; ++j) {
  34             if (!(minorBits & BIT(j))) {
  35                 continue;
  36             }
  37             const GameItem it = Items_from(Inventory_groups_minor * i + j);
  38             .int fld = inv_items[it.m_id];
  39             int prev = this.(fld);
  40             int next = this.(fld) = ReadByte();
  41             LOG_TRACEF("%s: %.0f -> %.0f", it.m_name, prev, next);
  42         }
  43     }
  44     return true;
  45 }
  46 #endif
  47
  48 #ifdef SVQC
  49 void Inventory_Write(Inventory data)
  50 {
  51     if (!data) {
  52         WriteShort(MSG_ENTITY, 0);
  53         return;
  54     }
  55     TC(Inventory, data);
  56
  57     int majorBits = 0;
  58     FOREACH(Items, true, {
  59         .int fld = inv_items[it.m_id];
  60         const bool changed = data.inventory.(fld) != data.(fld);
  61         if (changed) {
  62             majorBits = BITSET(majorBits, BIT(G_MAJOR(it.m_id)), true);
  63         }
  64     });
  65     WriteShort(MSG_ENTITY, majorBits);
  66
  67     int minorBits = 0;
  68     int lastMaj = 0;
  69     int maj = 0;
  70     FOREACH(Items, majorBits & BIT(maj = G_MAJOR(it.m_id)), {
  71         .int fld = inv_items[it.m_id];
  72         const bool changed = data.inventory.(fld) != (data.inventory.(fld) = data.(fld));
  73         if (changed) {
  74             if (maj != lastMaj) {
  75                 lastMaj = maj;
  76 #define X() MACRO_BEGIN \
  77     if (minorBits) { \
  78         WriteByte(MSG_ENTITY, minorBits); \
  79         for (int j = 0; j < Inventory_groups_minor; ++j) { \
  80             if (!(minorBits & BIT(j))) { \
  81                 continue; \
  82             } \
  83             const entity it = Items_from(Inventory_groups_minor * maj + j); \
  84             WriteByte(MSG_ENTITY, data.inv_items[it.m_id]); \
  85         } \
  86     } \
  87 MACRO_END
  88                 X();
  89                 minorBits = 0;
  90             }
  91             minorBits = BITSET(minorBits, BIT(G_MINOR(it.m_id)), true);
  92         }
  93     });
  94     X();
  95 #undef X
  96 }
  97 #endif
  98
  99 #undef G_MAJOR
 100 #undef G_MINOR
 101
 102 #ifdef SVQC
 103 bool Inventory_Send(Inventory this, Client to, int sf)
 104 {
 105     TC(Inventory, this);
 106     WriteHeader(MSG_ENTITY, ENT_CLIENT_INVENTORY);
 107     entity e = this.owner;
 108     if (IS_SPEC(e)) e = e.enemy;
 109     TC(Player, e);
 110     Inventory data = e.inventory;
 111     Inventory_Write(data);
 112     return true;
 113 }
 114
 115 void Inventory_new(entity e)
 116 {
 117     Inventory inv = NEW(Inventory), bak = NEW(Inventory);
 118     inv.inventory = bak;
 119     inv.drawonlytoclient = e;
 120     Net_LinkEntity((inv.owner = e).inventory = inv, false, 0, Inventory_Send);
 121 }
 122 void Inventory_delete(entity e) { delete(e.inventory.inventory); delete(e.inventory); }
 123 void Inventory_update(entity e) { e.inventory.SendFlags = 0xFFFFFF; }
 124 #endif