qcsrc/common/items/inventory.qh

   1 #pragma once
   2
   3 #include "all.qh"
   4
   5 CLASS(Inventory, Object)
   6     /** Stores counts of items, the id being the index */
   7     ATTRIBARRAY(Inventory, inv_items, int, Items_MAX);
   8     /** Previous state */
   9     ATTRIB(Inventory, inventory, Inventory);
  10 ENDCLASS(Inventory)
  11
  12 /** Player inventory */
  13 .Inventory inventory;
  14
  15 REGISTER_NET_LINKED(ENT_CLIENT_INVENTORY)
  16
  17 const int Inventory_groups_major = 16;
  18 const int Inventory_groups_minor = 8; // ceil(Items_MAX / Inventory_groups_major)
  19
  20 #define G_MAJOR(id) (floor((id) / Inventory_groups_minor))
  21 #define G_MINOR(id) ((id) % Inventory_groups_minor)
  22
  23 #ifdef CSQC
  24 Inventory g_inventory;
  25 NET_HANDLE(ENT_CLIENT_INVENTORY, bool isnew)
  26 {
  27     make_pure(this);
  28     g_inventory = this;
  29     const int majorBits = ReadShort();
  30     for (int i = 0; i < Inventory_groups_major; ++i) {
  31         if (!(majorBits & BIT(i))) {
  32             continue;
  33         }
  34         const int minorBits = ReadByte();
  35         for (int j = 0; j < Inventory_groups_minor; ++j) {
  36             if (!(minorBits & BIT(j))) {
  37                 continue;
  38             }
  39             const GameItem it = Items_from(Inventory_groups_minor * i + j);
  40             .int fld = inv_items[it.m_id];
  41             int prev = this.(fld);
  42             int next = this.(fld) = ReadByte();
  43             LOG_TRACEF("%s: %.0f -> %.0f", it.m_name, prev, next);
  44         }
  45     }
  46     return true;
  47 }
  48 #endif
  49
  50 #ifdef SVQC
  51 void Inventory_Write(Inventory data)
  52 {
  53     if (!data) {
  54         WriteShort(MSG_ENTITY, 0);
  55         return;
  56     }
  57     TC(Inventory, data);
  58
  59     int majorBits = 0;
  60     FOREACH(Items, true, {
  61         .int fld = inv_items[it.m_id];
  62         const bool changed = data.inventory.(fld) != data.(fld);
  63         if (changed) {
  64             majorBits = BITSET(majorBits, BIT(G_MAJOR(it.m_id)), true);
  65         }
  66     });
  67     WriteShort(MSG_ENTITY, majorBits);
  68
  69     int minorBits = 0;
  70     int lastMaj = 0;
  71     int maj = 0;
  72     FOREACH(Items, majorBits & BIT(maj = G_MAJOR(it.m_id)), {
  73         .int fld = inv_items[it.m_id];
  74         const bool changed = data.inventory.(fld) != (data.inventory.(fld) = data.(fld));
  75         if (changed) {
  76             if (maj != lastMaj) {
  77                 lastMaj = maj;
  78 #define X() MACRO_BEGIN \
  79     if (minorBits) { \
  80         WriteByte(MSG_ENTITY, minorBits); \
  81         for (int j = 0; j < Inventory_groups_minor; ++j) { \
  82             if (!(minorBits & BIT(j))) { \
  83                 continue; \
  84             } \
  85             const entity it = Items_from(Inventory_groups_minor * maj + j); \
  86             WriteByte(MSG_ENTITY, data.inv_items[it.m_id]); \
  87         } \
  88     } \
  89 MACRO_END
  90                 X();
  91                 minorBits = 0;
  92             }
  93             minorBits = BITSET(minorBits, BIT(G_MINOR(it.m_id)), true);
  94         }
  95     });
  96     X();
  97 #undef X
  98 }
  99 #endif
 100
 101 #undef G_MAJOR
 102 #undef G_MINOR
 103
 104 #ifdef SVQC
 105 bool Inventory_Send(Inventory this, Client to, int sf)
 106 {
 107     TC(Inventory, this);
 108     WriteHeader(MSG_ENTITY, ENT_CLIENT_INVENTORY);
 109     entity e = this.owner;
 110     if (IS_SPEC(e)) e = PS(e.enemy); // TODO: how can this *ever* be the case?
 111     TC(Player, e);
 112     Inventory data = e.inventory;
 113     Inventory_Write(data);
 114     return true;
 115 }
 116
 117 void Inventory_new(entity e)
 118 {
 119     Inventory inv = NEW(Inventory), bak = NEW(Inventory);
 120     inv.inventory = bak;
 121     inv.drawonlytoclient = IS_CLIENT(e) ? e : e.m_client;
 122     Net_LinkEntity((inv.owner = e).inventory = inv, false, 0, Inventory_Send);
 123 }
 124 void Inventory_delete(entity e) { delete(e.inventory.inventory); delete(e.inventory); }
 125 void Inventory_update(entity e) { e.inventory.SendFlags = 0xFFFFFF; }
 126 #endif