Merge remote branch 'refs/remotes/origin/fruitiex/racefixes'
[xonotic/xonotic-data.pk3dir.git] / qcsrc / common / mapinfo.qc
1 // generic string stuff
2
3 float _MapInfo_Cache_Active;
4 float _MapInfo_Cache_DB_NameToIndex;
5 float _MapInfo_Cache_Buf_IndexToMapData;
6
7 void MapInfo_Cache_Destroy()
8 {
9         if(!_MapInfo_Cache_Active)
10                 return;
11
12         db_close(_MapInfo_Cache_DB_NameToIndex);
13         buf_del(_MapInfo_Cache_Buf_IndexToMapData);
14         _MapInfo_Cache_Active = 0;
15 }
16
17 void MapInfo_Cache_Create()
18 {
19         MapInfo_Cache_Destroy();
20         _MapInfo_Cache_DB_NameToIndex = db_create();
21         _MapInfo_Cache_Buf_IndexToMapData = buf_create();
22         _MapInfo_Cache_Active = 1;
23 }
24
25 void MapInfo_Cache_Invalidate()
26 {
27         if(!_MapInfo_Cache_Active)
28                 return;
29
30         MapInfo_Cache_Create();
31 }
32
33 void MapInfo_Cache_Store()
34 {
35         float i;
36         string s;
37         if(!_MapInfo_Cache_Active)
38                 return;
39
40         s = db_get(_MapInfo_Cache_DB_NameToIndex, MapInfo_Map_bspname);
41         if(!s) // empty string is NOT valid here!
42         {
43                 i = buf_getsize(_MapInfo_Cache_Buf_IndexToMapData);
44                 db_put(_MapInfo_Cache_DB_NameToIndex, MapInfo_Map_bspname, ftos(i));
45         }
46         else
47                 i = stof(s);
48
49         // now store all the stuff
50         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData,   i, MapInfo_Map_bspname);
51         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, MapInfo_Map_title);
52         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, MapInfo_Map_description);
53         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, MapInfo_Map_author);
54         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, ftos(MapInfo_Map_supportedGametypes));
55         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, ftos(MapInfo_Map_supportedFeatures));
56         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, ftos(MapInfo_Map_flags));
57 }
58
59 float MapInfo_Cache_Retrieve(string map)
60 {
61         float i;
62         string s;
63         if(!_MapInfo_Cache_Active)
64                 return 0;
65
66         s = db_get(_MapInfo_Cache_DB_NameToIndex, map);
67         if(!s)
68                 return 0;
69         i = stof(s);
70
71         // now retrieve all the stuff
72         MapInfo_Map_bspname = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, i);
73         MapInfo_Map_title = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i);
74         MapInfo_Map_description = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i);
75         MapInfo_Map_author = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i);
76         MapInfo_Map_supportedGametypes = stof(bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i));
77         MapInfo_Map_supportedFeatures = stof(bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i));
78         MapInfo_Map_flags = stof(bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i));
79         return 1;
80 }
81
82 // GLOB HANDLING (for all BSP files)
83 float _MapInfo_globopen;
84 float _MapInfo_globcount; 
85 float _MapInfo_globhandle;
86 string _MapInfo_GlobItem(float i)
87 {
88         string s;
89         s = search_getfilename(_MapInfo_globhandle, i);
90         return substring(s, 5, strlen(s) - 9); // without maps/ and .bsp
91 }
92
93 void MapInfo_Enumerate()
94 {
95         if(_MapInfo_globopen)
96                 search_end(_MapInfo_globhandle);
97         MapInfo_Cache_Invalidate();
98         _MapInfo_globhandle = search_begin("maps/*.bsp", TRUE, TRUE);
99         _MapInfo_globcount = search_getsize(_MapInfo_globhandle);
100         _MapInfo_globopen = 1;
101 }
102
103 // filter the info by game type mask (updates MapInfo_count)
104 //
105 float _MapInfo_filtered;
106 float _MapInfo_filtered_allocated;
107 float MapInfo_FilterList_Lookup(float i)
108 {
109         return stof(bufstr_get(_MapInfo_filtered, i));
110 }
111
112 void _MapInfo_FilterList_swap(float i, float j, entity pass)
113 {
114         string h;
115         h = bufstr_get(_MapInfo_filtered, i);
116         bufstr_set(_MapInfo_filtered, i, bufstr_get(_MapInfo_filtered, j));
117         bufstr_set(_MapInfo_filtered, j, h);
118 }
119
120 float _MapInfo_FilterList_cmp(float i, float j, entity pass)
121 {
122         string a, b;
123         a = _MapInfo_GlobItem(stof(bufstr_get(_MapInfo_filtered, i)));
124         b = _MapInfo_GlobItem(stof(bufstr_get(_MapInfo_filtered, j)));
125         return strcasecmp(a, b);
126 }
127
128 float MapInfo_FilterGametype(float pGametype, float pFeatures, float pFlagsRequired, float pFlagsForbidden, float pAbortOnGenerate)
129 {
130         float i, j;
131         if not(_MapInfo_filtered_allocated)
132         {
133                 _MapInfo_filtered_allocated = 1;
134                 _MapInfo_filtered = buf_create();
135         }
136         MapInfo_count = 0;
137         for(i = 0, j = -1; i < _MapInfo_globcount; ++i)
138         {
139                 if(MapInfo_Get_ByName(_MapInfo_GlobItem(i), 1, 0) == 2) // if we generated one... BAIL OUT and let the caller continue in the next frame.
140                         if(pAbortOnGenerate)
141                         {
142                                 dprint("Autogenerated a .mapinfo, doing the rest later.\n");
143                                 MapInfo_progress = i / _MapInfo_globcount;
144                                 return 0;
145                         }
146                 if((MapInfo_Map_supportedGametypes & pGametype) != 0)
147                 if((MapInfo_Map_supportedFeatures & pFeatures) == pFeatures)
148                 if((MapInfo_Map_flags & pFlagsForbidden) == 0)
149                 if((MapInfo_Map_flags & pFlagsRequired) == pFlagsRequired)
150                         bufstr_set(_MapInfo_filtered, ++j, ftos(i));
151         }
152         MapInfo_count = j + 1;
153         MapInfo_ClearTemps();
154         
155         // sometimes the glob isn't sorted nicely, so fix it here...
156         heapsort(MapInfo_count, _MapInfo_FilterList_swap, _MapInfo_FilterList_cmp, world);
157
158         return 1;
159 }
160
161 void MapInfo_Filter_Free()
162 {
163         if(_MapInfo_filtered_allocated)
164         {
165                 buf_del(_MapInfo_filtered);
166                 _MapInfo_filtered_allocated = 0;
167         }
168 }
169
170 // load info about the i-th map into the MapInfo_Map_* globals
171 string MapInfo_BSPName_ByID(float i)
172 {
173         return _MapInfo_GlobItem(MapInfo_FilterList_Lookup(i));
174 }
175
176 string unquote(string s)
177 {
178         float i, j, l;
179         l = strlen(s);
180         j = -1;
181         for(i = 0; i < l; ++i)
182         {
183                 string ch;
184                 ch = substring(s, i, 1);
185                 if(ch != " ") if(ch != "\"")
186                 {
187                         for(j = strlen(s) - i - 1; j > 0; --j)
188                         {
189                                 ch = substring(s, i+j, 1);
190                                 if(ch != " ") if(ch != "\"")
191                                         return substring(s, i, j+1);
192                         }
193                         return substring(s, i, 1);
194                 }
195         }
196         return "";
197 }
198
199 float MapInfo_Get_ByID(float i)
200 {
201         if(MapInfo_Get_ByName(MapInfo_BSPName_ByID(i), 0, 0))
202                 return 1;
203         return 0;
204 }
205
206 string _MapInfo_Map_worldspawn_music;
207
208 float _MapInfo_Generate(string pFilename) // 0: failure, 1: ok ent, 2: ok bsp
209 {
210         string fn;
211         float fh;
212         string s, k, v;
213         vector o;
214         float i;
215         float inWorldspawn;
216         float r;
217         float twoBaseModes;
218         float diameter, spawnpoints;
219         float spawnplaces;
220
221         vector mapMins, mapMaxs;
222
223         r = 1;
224         fn = strcat("maps/", pFilename, ".ent");
225         fh = fopen(fn, FILE_READ);
226         if(fh < 0)
227         {
228                 r = 2;
229                 fn = strcat("maps/", pFilename, ".bsp");
230                 fh = fopen(fn, FILE_READ);
231         }
232         if(fh < 0)
233                 return 0;
234         print("Analyzing ", fn, " to generate initial mapinfo\n");
235
236         inWorldspawn = 2;
237         MapInfo_Map_flags = 0;
238         MapInfo_Map_supportedGametypes = 0;
239         spawnpoints = 0;
240         spawnplaces = 0;
241         _MapInfo_Map_worldspawn_music = "";
242
243         for(;;)
244         {
245                 if not((s = fgets(fh)))
246                         break;
247                 if(inWorldspawn == 1)
248                         if(startsWith(s, "}"))
249                                 inWorldspawn = 0;
250                 k = unquote(car(s));
251                 v = unquote(cdr(s));
252                 if(inWorldspawn)
253                 {
254                         if(k == "classname" && v == "worldspawn")
255                                 inWorldspawn = 1;
256                         else if(k == "author")
257                                 MapInfo_Map_author = v;
258                         else if(k == "_description")
259                                 MapInfo_Map_description = v;
260                         else if(k == "music")
261                                 _MapInfo_Map_worldspawn_music = v;
262                         else if(k == "noise")
263                                 _MapInfo_Map_worldspawn_music = v;
264                         else if(k == "message")
265                         {
266                                 i = strstrofs(v, " by ", 0);
267                                 if(MapInfo_Map_author == "<AUTHOR>" && i >= 0)
268                                 {
269                                         MapInfo_Map_title = substring(v, 0, i);
270                                         MapInfo_Map_author = substring(v, i + 4, strlen(v) - (i + 4));
271                                 }
272                                 else
273                                         MapInfo_Map_title = v;
274                         }
275                 }
276                 else
277                 {
278                         if(k == "origin")
279                         {
280                                 o = stov(strcat("'", v, "'"));
281                                 mapMins_x = min(mapMins_x, o_x);
282                                 mapMins_y = min(mapMins_y, o_y);
283                                 mapMins_z = min(mapMins_z, o_z);
284                                 mapMaxs_x = max(mapMaxs_x, o_x);
285                                 mapMaxs_y = max(mapMaxs_y, o_y);
286                                 mapMaxs_z = max(mapMaxs_z, o_z);
287                         }
288                         else if(k == "race_place")
289                         {
290                                 if(stof(v) > 0)
291                                         spawnplaces = 1;
292                         }
293                         else if(k == "classname")
294                         {
295                                 if(v == "dom_controlpoint")
296                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_DOMINATION;
297                                 else if(v == "item_flag_team2")
298                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_CTF;
299                                 else if(v == "team_CTF_blueflag")
300                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_CTF;
301                                 else if(v == "runematch_spawn_point")
302                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_RUNEMATCH;
303                                 else if(v == "target_assault_roundend")
304                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_ASSAULT;
305                                 else if(v == "onslaught_generator")
306                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_ONSLAUGHT;
307                                 else if(substring(v, 0, 8) == "nexball_" || substring(v, 0, 4) == "ball")
308                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_NEXBALL;
309                                 else if(v == "info_player_team1")
310                                         ++spawnpoints;
311                                 else if(v == "info_player_team2")
312                                         ++spawnpoints;
313                                 else if(v == "info_player_start")
314                                         ++spawnpoints;
315                                 else if(v == "info_player_deathmatch")
316                                         ++spawnpoints;
317                                 else if(v == "trigger_race_checkpoint")
318                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_RACE;
319                                 else if(v == "target_startTimer")
320                                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_CTS;
321                                 else if(v == "weapon_nex")
322                                         { }
323                                 else if(v == "weapon_railgun")
324                                         { }
325                                 else if(startsWith(v, "weapon_"))
326                                         MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_WEAPONS;
327                                 else if(v == "target_music" || v == "trigger_music")
328                                         _MapInfo_Map_worldspawn_music = string_null; // don't use regular BGM
329                         }
330                 }
331         }
332         if(inWorldspawn)
333         {
334                 print(fn, " ended still in worldspawn, BUG\n");
335                 return 0;
336         }
337         diameter = vlen(mapMaxs - mapMins);
338
339         twoBaseModes = MapInfo_Map_supportedGametypes & (MAPINFO_TYPE_CTF | MAPINFO_TYPE_ASSAULT | MAPINFO_TYPE_RACE | MAPINFO_TYPE_NEXBALL);
340         if(twoBaseModes && (MapInfo_Map_supportedGametypes == twoBaseModes))
341         {
342                 // we have a CTF-only or Assault-only map. Don't add other modes then,
343                 // as the map is too symmetric for them.
344         }
345         else
346         {
347                 MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_DEATHMATCH;      // DM always works
348                 MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_RUNEMATCH;       // Rune always works
349                 MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_LMS;             // LMS always works
350
351                 if(spawnpoints >= 8  && diameter > 4096) {
352                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_TEAM_DEATHMATCH;
353                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_CA;
354                 }
355                 if(                     diameter < 4096)
356                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_ARENA;
357                 if(spawnpoints >= 12 && diameter > 5120)
358                         MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_KEYHUNT;
359         }
360
361         if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_RACE)
362         if(!spawnplaces)
363         {
364                 MapInfo_Map_supportedGametypes &~= MAPINFO_TYPE_RACE;
365                 MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_CTS;
366         }
367
368         dprint("-> diameter ",    ftos(diameter));
369         dprint(";  spawnpoints ", ftos(spawnpoints));
370         dprint(";  modes ",       ftos(MapInfo_Map_supportedGametypes), "\n");
371
372         fclose(fh);
373
374         return r;
375 }
376
377 void _MapInfo_Map_Reset()
378 {
379         MapInfo_Map_title = "<TITLE>";
380         MapInfo_Map_description = "<DESCRIPTION>";
381         MapInfo_Map_author = "<AUTHOR>";
382         MapInfo_Map_supportedGametypes = 0;
383         MapInfo_Map_supportedFeatures = 0;
384         MapInfo_Map_flags = 0;
385         MapInfo_Map_clientstuff = "";
386         MapInfo_Map_fog = "";
387         MapInfo_Map_mins = '0 0 0';
388         MapInfo_Map_maxs = '0 0 0';
389 }
390
391 string _MapInfo_GetDefault(float t)
392 {
393         switch(t)
394         {
395                 case MAPINFO_TYPE_DEATHMATCH:      return "30 20 0";
396                 case MAPINFO_TYPE_TEAM_DEATHMATCH: return "50 20 2 0";
397                 case MAPINFO_TYPE_DOMINATION:      return "200 20 0";
398                 case MAPINFO_TYPE_CTF:             return "300 20 10 0";
399                 case MAPINFO_TYPE_RUNEMATCH:       return "200 20 0";
400                 case MAPINFO_TYPE_LMS:             return "9 20 0";
401                 case MAPINFO_TYPE_ARENA:           return "10 20 0";
402                 case MAPINFO_TYPE_CA:              return "10 20 0";
403                 case MAPINFO_TYPE_KEYHUNT:         return "1000 20 3 0";
404                 case MAPINFO_TYPE_ASSAULT:         return "20 0";
405                 case MAPINFO_TYPE_RACE:            return "20 5 7 15 0";
406                 case MAPINFO_TYPE_ONSLAUGHT:       return "20 0";
407                 case MAPINFO_TYPE_NEXBALL:         return "5 20 0";
408                 case MAPINFO_TYPE_CTS:             return "20 0 0";
409                 default:                           return "";
410         }
411 }
412
413 void _MapInfo_Map_ApplyGametype(string s, float pWantedType, float pThisType, float load_default)
414 {
415         string sa;
416         MapInfo_Map_supportedGametypes |= pThisType;
417         if(!(pThisType & pWantedType))
418                 return;
419
420         if(load_default)
421                 _MapInfo_Map_ApplyGametype(_MapInfo_GetDefault(pThisType), pWantedType, pThisType, FALSE);
422         
423         if(pWantedType == MAPINFO_TYPE_ASSAULT || pWantedType == MAPINFO_TYPE_ONSLAUGHT || pWantedType == MAPINFO_TYPE_RACE || pWantedType == MAPINFO_TYPE_CTS) // these modes don't use fraglimit
424         {
425                 cvar_set("fraglimit", "0");
426         }
427         else
428         {
429                 sa = car(s);
430                 if(sa != "")
431                         cvar_set("fraglimit", sa);
432                 s = cdr(s);
433         }
434
435         sa = car(s);
436         if(sa != "")
437                 cvar_set("timelimit", sa);
438         s = cdr(s);
439
440         if(pWantedType == MAPINFO_TYPE_TEAM_DEATHMATCH)
441         {
442                 sa = car(s);
443                 if(sa != "")
444                         cvar_set("g_tdm_teams", sa);
445                 s = cdr(s);
446         }
447
448         if(pWantedType == MAPINFO_TYPE_KEYHUNT)
449         {
450                 sa = car(s);
451                 if(sa != "")
452                         cvar_set("g_keyhunt_teams", sa);
453                 s = cdr(s);
454         }
455
456         if(pWantedType == MAPINFO_TYPE_CTF)
457         {
458                 sa = car(s);
459                 if(sa != "")
460                         if(cvar("g_ctf_win_mode") < 2)
461                                 cvar_set("fraglimit", sa);
462                 s = cdr(s);
463         }
464
465         // rc = timelimit timelimit_qualification laps laps_teamplay
466         if(pWantedType == MAPINFO_TYPE_RACE)
467         {
468                 sa = car(s); if(sa == "") sa = cvar_string("timelimit");
469                 cvar_set("g_race_qualifying_timelimit", sa);
470                 s = cdr(s);
471
472                 sa = car(s);
473                 if(sa != "")
474                         if(cvar("g_race_teams") < 2)
475                                 cvar_set("fraglimit", sa);
476                 s = cdr(s);
477
478                 sa = car(s);
479                 if(sa != "")
480                         if(cvar("g_race_teams") >= 2)
481                                 cvar_set("fraglimit", sa);
482                 s = cdr(s);
483         }
484
485         if(pWantedType == MAPINFO_TYPE_CTS)
486         {
487                 sa = car(s);
488
489                 // this is the skill of the map
490                 // not parsed by anything yet
491                 // for map databases
492                 //if(sa != "")
493                 //      cvar_set("fraglimit", sa);
494
495                 s = cdr(s);
496         }
497
498         if(pWantedType == MAPINFO_TYPE_ASSAULT || pWantedType == MAPINFO_TYPE_ONSLAUGHT || pWantedType == MAPINFO_TYPE_CTS) // these modes don't use fraglimit
499         {
500                 cvar_set("leadlimit", "0");
501         }
502         else
503         {
504                 sa = car(s);
505                 if(sa != "")
506                         cvar_set("leadlimit", sa);
507                 s = cdr(s);
508         }
509 }
510
511 string _MapInfo_GetDefaultEx(float t)
512 {
513         switch(t)
514         {
515                 case MAPINFO_TYPE_DEATHMATCH:      return "timelimit=20 pointlimit=30 leadlimit=0";
516                 case MAPINFO_TYPE_TEAM_DEATHMATCH: return "timelimit=20 pointlimit=50 teams=2 leadlimit=0";
517                 case MAPINFO_TYPE_DOMINATION:      return "timelimit=20 pointlimit=200 teams=2 leadlimit=0";
518                 case MAPINFO_TYPE_CTF:             return "timelimit=20 pointlimit=300 caplimit=10 leadlimit=0";
519                 case MAPINFO_TYPE_RUNEMATCH:       return "timelimit=20 pointlimit=200 leadlimit=0";
520                 case MAPINFO_TYPE_LMS:             return "timelimit=20 lives=9 leadlimit=0";
521                 case MAPINFO_TYPE_ARENA:           return "timelimit=20 pointlimit=10 leadlimit=0";
522                 case MAPINFO_TYPE_CA:              return "timelimit=20 pointlimit=10 leadlimit=0";
523                 case MAPINFO_TYPE_KEYHUNT:         return "timelimit=20 pointlimit=1000 teams=3 leadlimit=0";
524                 case MAPINFO_TYPE_ASSAULT:         return "timelimit=20";
525                 case MAPINFO_TYPE_RACE:            return "timelimit=20 qualifying_timelimit=5 laplimit=7 teamlaplimit=15 leadlimit=0";
526                 case MAPINFO_TYPE_ONSLAUGHT:       return "timelimit=20";
527                 case MAPINFO_TYPE_NEXBALL:         return "timelimit=20 pointlimit=5 leadlimit=0";
528                 case MAPINFO_TYPE_CTS:             return "timelimit=20 skill=-1";
529                 default:                           return "";
530         }
531 }
532
533 void _MapInfo_Map_ApplyGametypeEx(string s, float pWantedType, float pThisType)
534 {
535         string sa, k, v;
536         float p;
537         string fraglimit_normal;
538         string fraglimit_caps;
539         string fraglimit_teams;
540
541         MapInfo_Map_supportedGametypes |= pThisType;
542         if(!(pThisType & pWantedType))
543                 return;
544
545         // reset all the cvars to their defaults
546
547         cvar_set("timelimit", cvar_defstring("timelimit"));
548         cvar_set("leadlimit", cvar_defstring("leadlimit"));
549         cvar_set("fraglimit", cvar_defstring("fraglimit"));
550         cvar_set("g_tdm_teams", cvar_defstring("g_tdm_teams"));
551         cvar_set("g_keyhunt_teams", cvar_defstring("g_keyhunt_teams"));
552         cvar_set("g_domination_default_teams", cvar_defstring("g_domination_default_teams"));
553         cvar_set("g_race_qualifying_timelimit", cvar_defstring("g_race_qualifying_timelimit"));
554
555         fraglimit_normal = string_null;
556         fraglimit_caps = string_null;
557         fraglimit_teams = string_null;
558
559         s = strcat(_MapInfo_GetDefaultEx(pWantedType), " ", s);
560         while(s != "")
561         {
562                 sa = car(s);
563                 s = cdr(s);
564
565                 if(sa == "")
566                         continue;
567
568                 p = strstrofs(sa, "=", 0);
569                 if(p < 0)
570                 {
571                         k = "timelimit";
572                         v = s;
573                 }
574                 else
575                 {
576                         k = substring(sa, 0, p);
577                         v = substring(sa, p+1, -1);
578                 }
579
580                 if(k == "timelimit")
581                 {
582                         cvar_set("timelimit", v);
583                 }
584                 else if(k == "leadlimit")
585                 {
586                         cvar_set("leadlimit", v);
587                 }
588                 else if(k == "pointlimit" || k == "fraglimit" || k == "lives" || k == "laplimit")
589                 {
590                         fraglimit_normal = v;
591                 }
592                 else if(k == "caplimit")
593                 {
594                         fraglimit_caps = v;
595                 }
596                 else if(k == "teampointlimit" || k == "teamlaplimit")
597                 {
598                         fraglimit_teams = v;
599                 }
600                 else if(k == "teams")
601                 {
602                         cvar_set("g_tdm_teams", v);
603                         cvar_set("g_keyhunt_teams", v);
604                         cvar_set("g_domination_default_teams", v);
605                 }
606                 else if(k == "qualifying_timelimit")
607                 {
608                         cvar_set("g_race_qualifying_timelimit", v);
609                 }
610                 else if(k == "skill")
611                 {
612                         // ignore
613                 }
614                 else
615                 {
616                         print("Invalid gametype key in mapinfo: ", k, "\n");
617                 }
618         }
619
620         if(pWantedType == MAPINFO_TYPE_CTF && cvar("g_ctf_win_mode") < 2)
621         {
622                 if(fraglimit_caps)
623                         cvar_set("fraglimit", fraglimit_caps);
624         }
625         else if(pWantedType == MAPINFO_TYPE_RACE && cvar("g_race_teams") >= 2)
626         {
627                 if(fraglimit_teams)
628                         cvar_set("fraglimit", fraglimit_teams);
629         }
630         else
631         {
632                 if(fraglimit_normal)
633                         cvar_set("fraglimit", fraglimit_normal);
634         }
635 }
636
637 float MapInfo_Type_FromString(string t)
638 {
639         if     (t == "dm")      return MAPINFO_TYPE_DEATHMATCH;
640         else if(t == "tdm")     return MAPINFO_TYPE_TEAM_DEATHMATCH;
641         else if(t == "dom")     return MAPINFO_TYPE_DOMINATION;
642         else if(t == "ctf")     return MAPINFO_TYPE_CTF;
643         else if(t == "rune")    return MAPINFO_TYPE_RUNEMATCH;
644         else if(t == "lms")     return MAPINFO_TYPE_LMS;
645         else if(t == "arena")   return MAPINFO_TYPE_ARENA;
646         else if(t == "ca")      return MAPINFO_TYPE_CA;
647         else if(t == "kh")      return MAPINFO_TYPE_KEYHUNT;
648         else if(t == "as")      return MAPINFO_TYPE_ASSAULT;
649         else if(t == "ons")     return MAPINFO_TYPE_ONSLAUGHT;
650         else if(t == "rc")      return MAPINFO_TYPE_RACE;
651         else if(t == "nexball") return MAPINFO_TYPE_NEXBALL;
652         else if(t == "cts")     return MAPINFO_TYPE_CTS;
653         else if(t == "all")     return MAPINFO_TYPE_ALL;
654         else                    return 0;
655 }
656
657 string MapInfo_Type_ToString(float t)
658 {
659         if     (t == MAPINFO_TYPE_DEATHMATCH)      return "dm";
660         else if(t == MAPINFO_TYPE_TEAM_DEATHMATCH) return "tdm";
661         else if(t == MAPINFO_TYPE_DOMINATION)      return "dom";
662         else if(t == MAPINFO_TYPE_CTF)             return "ctf";
663         else if(t == MAPINFO_TYPE_RUNEMATCH)       return "rune";
664         else if(t == MAPINFO_TYPE_LMS)             return "lms";
665         else if(t == MAPINFO_TYPE_ARENA)           return "arena";
666         else if(t == MAPINFO_TYPE_CA)              return "ca";
667         else if(t == MAPINFO_TYPE_KEYHUNT)         return "kh";
668         else if(t == MAPINFO_TYPE_ASSAULT)         return "as";
669         else if(t == MAPINFO_TYPE_ONSLAUGHT)       return "ons";
670         else if(t == MAPINFO_TYPE_RACE)            return "rc";
671         else if(t == MAPINFO_TYPE_NEXBALL)         return "nexball";
672         else if(t == MAPINFO_TYPE_CTS)             return "cts";
673         else if(t == MAPINFO_TYPE_ALL)             return "all";
674         else                                       return "";
675 }
676
677 void _MapInfo_Parse_Settemp(string pFilename, string acl, float type, string s, float recurse)
678 {
679         string t;
680         float fh, o;
681         t = car(s); s = cdr(s);
682
683         // limited support of "" and comments
684         //   remove trailing and leading " of t
685         if(substring(t, 0, 1) == "\"")
686         {
687                 if(substring(t, -1, 1) == "\"")
688                         t = substring(t, 1, -2);
689         }
690
691         //   remove leading " of s
692         if(substring(s, 0, 1) == "\"")
693         {
694                 s = substring(s, 1, -1);
695         }
696         //   remove trailing " of s, and all that follows (cvar description)
697         o = strstrofs(s, "\"", 0);
698         if(o >= 0)
699                 s = substring(s, 0, o);
700         
701         //   remove // comments
702         o = strstrofs(s, "//", 0);
703         if(o >= 0)
704                 s = substring(s, 0, o);
705         
706         //   remove trailing spaces
707         while(substring(s, -1, 1) == " ")
708                 s = substring(s, 0, -2);
709
710         if(t == "#include")
711         {
712                 if(recurse > 0)
713                 {
714                         fh = fopen(s, FILE_READ);
715                         if(fh < 0)
716                                 print("Map ", pFilename, " references not existing config file ", s, "\n");
717                         else
718                         {
719                                 for(;;)
720                                 {
721                                         if not((s = fgets(fh)))
722                                                 break;
723
724                                         // catch different sorts of comments
725                                         if(s == "")                    // empty lines
726                                                 continue;
727                                         if(substring(s, 0, 1) == "#")  // UNIX style
728                                                 continue;
729                                         if(substring(s, 0, 2) == "//") // C++ style
730                                                 continue;
731                                         if(substring(s, 0, 1) == "_")  // q3map style
732                                                 continue;
733
734                                         if(substring(s, 0, 4) == "set ")
735                                                 s = substring(s, 4, -1);
736                                         if(substring(s, 0, 5) == "seta ")
737                                                 s = substring(s, 5, -1);
738
739                                         _MapInfo_Parse_Settemp(pFilename, acl, type, s, recurse - 1);
740                                 }
741                                 fclose(fh);
742                         }
743                 }
744                 else
745                         print("Map ", pFilename, " uses too many levels of inclusion\n");
746         }
747         else if(t == "")
748                 print("Map ", pFilename, " contains a potentially harmful setting, ignored\n");
749         else if not(cvar_value_issafe(t))
750                 print("Map ", pFilename, " contains a potentially harmful setting, ignored\n");
751         else if not (cvar_value_issafe(s))
752                 print("Map ", pFilename, " contains a potentially harmful setting, ignored\n");
753         else if(matchacl(MAPINFO_SETTEMP_ACL_SYSTEM, t) <= 0)
754                 print("Map ", pFilename, " contains a potentially harmful setting, ignored\n");
755         else if(matchacl(acl, t) <= 0)
756                 print("Map ", pFilename, " contains a denied setting, ignored\n");
757         else
758         {
759                 if(type == 0) // server set
760                 {
761                         dprint("Applying temporary setting ", t, " := ", s, "\n");
762                         if(cvar("g_campaign"))
763                                 cvar_set(t, s); // this is a wrapper and is always temporary anyway; no need to backup old values then
764                         else
765                                 cvar_settemp(t, s);
766                 }
767                 else
768                 {
769                         dprint("Applying temporary client setting ", t, " := ", s, "\n");
770                         MapInfo_Map_clientstuff = strcat(
771                                         MapInfo_Map_clientstuff, "cl_cmd settemp \"", t, "\" \"", s, "\"\n"
772                                         );
773                 }
774         }
775 }
776
777 // load info about a map by name into the MapInfo_Map_* globals
778 float MapInfo_Get_ByName(string pFilename, float pAllowGenerate, float pGametypeToSet)
779 {
780         string fn;
781         string s, t;
782         float fh, fh2;
783         float r, f, n, i, p;
784         string acl;
785
786         acl = MAPINFO_SETTEMP_ACL_USER;
787
788         if(strstrofs(pFilename, "/", 0) >= 0)
789         {
790                 print("Invalid character in map name, ignored\n");
791                 return 0;
792         }
793
794         if(pGametypeToSet == 0)
795                 if(MapInfo_Cache_Retrieve(pFilename))
796                         return 1;
797
798         r = 1;
799
800         MapInfo_Map_bspname = pFilename;
801
802         // default all generic fields so they have "good" values in case something fails
803         fn = strcat("maps/", pFilename, ".mapinfo");
804         fh = fopen(fn, FILE_READ);
805         if(fh < 0)
806         {
807                 fn = strcat("maps/autogenerated/", pFilename, ".mapinfo");
808                 fh = fopen(fn, FILE_READ);
809                 if(fh < 0)
810                 {
811                         if(!pAllowGenerate)
812                                 return 0;
813                         _MapInfo_Map_Reset();
814                         r = _MapInfo_Generate(pFilename);
815                         if(!r)
816                                 return 0;
817                         fh = fopen(fn, FILE_WRITE);
818                         fputs(fh, strcat("title ", MapInfo_Map_title, "\n"));
819                         fputs(fh, strcat("description ", MapInfo_Map_description, "\n"));
820                         fputs(fh, strcat("author ", MapInfo_Map_author, "\n"));
821                         if(_MapInfo_Map_worldspawn_music != "")
822                         {
823                                 if(
824                                         substring(_MapInfo_Map_worldspawn_music, strlen(_MapInfo_Map_worldspawn_music) - 4, 4) == ".wav"
825                                         ||
826                                         substring(_MapInfo_Map_worldspawn_music, strlen(_MapInfo_Map_worldspawn_music) - 4, 4) == ".ogg"
827                                 )
828                                         fputs(fh, strcat("cdtrack ", substring(_MapInfo_Map_worldspawn_music, 0, strlen(_MapInfo_Map_worldspawn_music) - 4), "\n"));
829                                 else
830                                         fputs(fh, strcat("cdtrack ", _MapInfo_Map_worldspawn_music, "\n"));
831                         }
832                         else
833                         {
834                                 n = tokenize_console(cvar_string("g_cdtracks_remaplist"));
835                                 s = strcat(" ", cvar_string("g_cdtracks_dontusebydefault"), " ");
836                                 for(;;)
837                                 {
838                                         i = floor(random() * n);
839                                         if(strstrofs(s, strcat(" ", argv(i), " "), 0) < 0)
840                                                 break;
841                                 }
842                                 fputs(fh, strcat("cdtrack ", ftos(i + 1), "\n"));
843                         }
844                         if(MapInfo_Map_supportedFeatures & MAPINFO_FEATURE_WEAPONS)
845                                 fputs(fh, "has weapons\n");
846                         else
847                                 fputs(fh, "// uncomment this if you added weapon pickups: has weapons\n");
848                         if(MapInfo_Map_flags & MAPINFO_FLAG_FRUSTRATING)
849                                 fputs(fh, "frustrating\n");
850
851                         for(i = 1; i <= MapInfo_Map_supportedGametypes; i *= 2)
852                                 if(MapInfo_Map_supportedGametypes & i)
853                                         fputs(fh, sprintf("gametype %s // defaults: %s\n", MapInfo_Type_ToString(i), _MapInfo_GetDefaultEx(i)));
854
855                         fh2 = fopen(strcat("scripts/", pFilename, ".arena"), FILE_READ);
856                         if(fh2 >= 0)
857                         {
858                                 fclose(fh2);
859                                 fputs(fh, "settemp_for_type all sv_q3acompat_machineshotgunswap 1\n");
860                         }
861
862                         fputs(fh, "// optional: fog density red green blue alpha mindist maxdist\n");
863                         fputs(fh, "// optional: settemp_for_type (all|gametypename) cvarname value\n");
864                         fputs(fh, "// optional: clientsettemp_for_type (all|gametypename) cvarname value\n");
865                         fputs(fh, "// optional: size mins_x mins_y mins_z maxs_x maxs_y maxs_z\n");
866                         fputs(fh, "// optional: hidden\n");
867
868                         fclose(fh);
869                         r = 2;
870                         // return r;
871                         fh = fopen(fn, FILE_READ);
872                         if(fh < 0)
873                                 error("... but I just wrote it!");
874                 }
875
876                 print("WARNING: autogenerated mapinfo file ", fn, " has been loaded; please edit that file and move it to maps/", pFilename, ".mapinfo\n");
877         }
878
879         _MapInfo_Map_Reset();
880         for(;;)
881         {
882                 if not((s = fgets(fh)))
883                         break;
884
885                 // catch different sorts of comments
886                 if(s == "")                    // empty lines
887                         continue;
888                 if(substring(s, 0, 1) == "#")  // UNIX style
889                         continue;
890                 if(substring(s, 0, 2) == "//") // C++ style
891                         continue;
892                 if(substring(s, 0, 1) == "_")  // q3map style
893                         continue;
894
895                 p = strstrofs(s, "//", 0);
896                 if(p >= 0)
897                         s = substring(s, 0, p);
898
899                 t = car(s); s = cdr(s);
900                 if(t == "title")
901                         MapInfo_Map_title = s;
902                 else if(t == "description")
903                         MapInfo_Map_description = s;
904                 else if(t == "author")
905                         MapInfo_Map_author = s;
906                 else if(t == "has")
907                 {
908                         t = car(s); s = cdr(s);
909                         if     (t == "weapons") MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_WEAPONS;
910                         else
911                                 dprint("Map ", pFilename, " supports unknown feature ", t, ", ignored\n");
912                 }
913                 else if(t == "hidden")
914                 {
915                         MapInfo_Map_flags |= MAPINFO_FLAG_HIDDEN;
916                 }
917                 else if(t == "forbidden")
918                 {
919                         MapInfo_Map_flags |= MAPINFO_FLAG_FORBIDDEN;
920                 }
921                 else if(t == "frustrating")
922                 {
923                         MapInfo_Map_flags |= MAPINFO_FLAG_FRUSTRATING;
924                 }
925                 else if(t == "type")
926                 {
927                         t = car(s); s = cdr(s);
928                         f = MapInfo_Type_FromString(t);
929                         if(f)
930                                 _MapInfo_Map_ApplyGametype (s, pGametypeToSet, f, TRUE);
931                         else
932                                 dprint("Map ", pFilename, " supports unknown game type ", t, ", ignored\n");
933                 }
934                 else if(t == "gametype")
935                 {
936                         t = car(s); s = cdr(s);
937                         f = MapInfo_Type_FromString(t);
938                         if(f)
939                                 _MapInfo_Map_ApplyGametypeEx (s, pGametypeToSet, f);
940                         else
941                                 dprint("Map ", pFilename, " supports unknown game type ", t, ", ignored\n");
942                 }
943                 else if(t == "size")
944                 {
945                         float a, b, c, d, e;
946                         t = car(s); s = cdr(s); a = stof(t);
947                         t = car(s); s = cdr(s); b = stof(t);
948                         t = car(s); s = cdr(s); c = stof(t);
949                         t = car(s); s = cdr(s); d = stof(t);
950                         t = car(s); s = cdr(s); e = stof(t);
951                         if(s == "")
952                                 print("Map ", pFilename, " contains an incorrect size line (not enough params), syntax: size mins_x mins_y mins_z maxs_x maxs_y maxs_z\n");
953                         else
954                         {
955                                 t = car(s); s = cdr(s); f = stof(t);
956                                 if(s != "")
957                                         print("Map ", pFilename, " contains an incorrect size line (too many params), syntax: size mins_x mins_y mins_z maxs_x maxs_y maxs_z\n");
958                                 else
959                                 {
960                                         if(a >= d || b >= e || c >= f)
961                                                 print("Map ", pFilename, " contains an incorrect size line, mins have to be < maxs\n");
962                                         else
963                                         {
964                                                 MapInfo_Map_mins_x = a;
965                                                 MapInfo_Map_mins_y = b;
966                                                 MapInfo_Map_mins_z = c;
967                                                 MapInfo_Map_maxs_x = d;
968                                                 MapInfo_Map_maxs_y = e;
969                                                 MapInfo_Map_maxs_z = f;
970                                         }
971                                 }
972                         }
973                 }
974                 else if(t == "settemp_for_type")
975                 {
976                         t = car(s); s = cdr(s);
977                         if((f = MapInfo_Type_FromString(t)))
978                         {
979                                 if(f & pGametypeToSet)
980                                 {
981                                         _MapInfo_Parse_Settemp(pFilename, acl, 0, s, 1);
982                                 }
983                         }
984                         else
985                         {
986                                 dprint("Map ", pFilename, " has a setting for unknown game type ", t, ", ignored\n");
987                         }
988                 }
989                 else if(t == "clientsettemp_for_type")
990                 {
991                         t = car(s); s = cdr(s);
992                         if((f = MapInfo_Type_FromString(t)))
993                         {
994                                 if(f & pGametypeToSet)
995                                 {
996                                         _MapInfo_Parse_Settemp(pFilename, acl, 1, s, 1);
997                                 }
998                         }
999                         else
1000                         {
1001                                 dprint("Map ", pFilename, " has a client setting for unknown game type ", t, ", ignored\n");
1002                         }
1003                 }
1004                 else if(t == "fog")
1005                 {
1006                         if not(cvar_value_issafe(t))
1007                                 print("Map ", pFilename, " contains a potentially harmful fog setting, ignored\n");
1008                         else
1009                                 MapInfo_Map_fog = s;
1010                 }
1011                 else if(t == "cdtrack")
1012                 {
1013                         if(pGametypeToSet)
1014                         {
1015                                 if not(cvar_value_issafe(t))
1016                                         print("Map ", pFilename, " contains a potentially harmful cdtrack, ignored\n");
1017                                 else
1018                                         MapInfo_Map_clientstuff = strcat(
1019                                                 MapInfo_Map_clientstuff, "cd loop \"", s, "\"\n"
1020                                         );
1021                         }
1022                 }
1023                 else
1024                         dprint("Map ", pFilename, " provides unknown info item ", t, ", ignored\n");
1025         }
1026         fclose(fh);
1027
1028         if(pGametypeToSet)
1029         {
1030                 if(!(MapInfo_Map_supportedGametypes & pGametypeToSet))
1031                 {
1032                         print("Can't select the requested game type. Trying anyway with stupid settings.\n");
1033                         _MapInfo_Map_ApplyGametypeEx("", pGametypeToSet, MAPINFO_TYPE_DEATHMATCH);
1034                 }
1035         }
1036
1037         MapInfo_Cache_Store();
1038         if(MapInfo_Map_supportedGametypes != 0)
1039                 return r;
1040         dprint("Map ", pFilename, " supports no game types, ignored\n");
1041         return 0;
1042 }
1043
1044 float MapInfo_FindName(string s)
1045 {
1046         // if there is exactly one map of prefix s, return it
1047         // if not, return the null string
1048         // note that DP sorts glob results... so I can use a binary search
1049         float l, r, m, cmp;
1050         l = 0;
1051         r = MapInfo_count;
1052         // invariants: r is behind s, l-1 is equal or before
1053         while(l != r)
1054         {
1055                 m = floor((l + r) / 2);
1056                 MapInfo_FindName_match = _MapInfo_GlobItem(MapInfo_FilterList_Lookup(m));
1057                 cmp = strcasecmp(MapInfo_FindName_match, s);
1058                 if(cmp == 0)
1059                         return m; // found and good
1060                 if(cmp < 0)
1061                         l = m + 1; // l-1 is before s
1062                 else
1063                         r = m; // behind s
1064         }
1065         MapInfo_FindName_match = _MapInfo_GlobItem(MapInfo_FilterList_Lookup(l));
1066         MapInfo_FindName_firstResult = l;
1067         // r == l, so: l is behind s, l-1 is before
1068         // SO: if there is any, l is the one with the right prefix
1069         //     and l+1 may be one too
1070         if(l == MapInfo_count)
1071         {
1072                 MapInfo_FindName_match = string_null;
1073                 MapInfo_FindName_firstResult = -1;
1074                 return -1; // no MapInfo_FindName_match, behind last item
1075         }
1076         if(!startsWithNocase(MapInfo_FindName_match, s))
1077         {
1078                 MapInfo_FindName_match = string_null;
1079                 MapInfo_FindName_firstResult = -1;
1080                 return -1; // wrong prefix
1081         }
1082         if(l == MapInfo_count - 1)
1083                 return l; // last one, nothing can follow => unique
1084         if(startsWithNocase(_MapInfo_GlobItem(MapInfo_FilterList_Lookup(l + 1)), s))
1085         {
1086                 MapInfo_FindName_match = string_null;
1087                 return -1; // ambigous MapInfo_FindName_match
1088         }
1089         return l;
1090 }
1091
1092 string MapInfo_FixName(string s)
1093 {
1094         MapInfo_FindName(s);
1095         return MapInfo_FindName_match;
1096 }
1097
1098 float MapInfo_CurrentFeatures()
1099 {
1100         float req;
1101         req = 0;
1102         if(!(cvar("g_lms") || cvar("g_minstagib") || cvar("g_nix") || cvar("g_weaponarena") || !cvar("g_pickup_items") || cvar("g_race") || cvar("g_cts") || cvar("g_nexball")))
1103                 req |= MAPINFO_FEATURE_WEAPONS;
1104         return req;
1105 }
1106
1107 float MapInfo_CurrentGametype()
1108 {
1109         if(cvar("g_domination"))
1110                 return MAPINFO_TYPE_DOMINATION;
1111         else if(cvar("g_ctf"))
1112                 return MAPINFO_TYPE_CTF;
1113         else if(cvar("g_runematch"))
1114                 return MAPINFO_TYPE_RUNEMATCH;
1115         else if(cvar("g_tdm"))
1116                 return MAPINFO_TYPE_TEAM_DEATHMATCH;
1117         else if(cvar("g_assault"))
1118                 return MAPINFO_TYPE_ASSAULT;
1119         else if(cvar("g_lms"))
1120                 return MAPINFO_TYPE_LMS;
1121         else if(cvar("g_arena"))
1122                 return MAPINFO_TYPE_ARENA;
1123         else if(cvar("g_ca"))
1124                 return MAPINFO_TYPE_CA; 
1125         else if(cvar("g_keyhunt"))
1126                 return MAPINFO_TYPE_KEYHUNT;
1127         else if(cvar("g_onslaught"))
1128                 return MAPINFO_TYPE_ONSLAUGHT;
1129         else if(cvar("g_race"))
1130                 return MAPINFO_TYPE_RACE;
1131         else if(cvar("g_nexball"))
1132                 return MAPINFO_TYPE_NEXBALL;
1133         else if(cvar("g_cts"))
1134                 return MAPINFO_TYPE_CTS;
1135         else
1136                 return MAPINFO_TYPE_DEATHMATCH;
1137 }
1138
1139 float _MapInfo_CheckMap(string s) // returns 0 if the map can't be played with the current settings, 1 otherwise
1140 {
1141         if(!MapInfo_Get_ByName(s, 1, 0))
1142                 return 0;
1143         if((MapInfo_Map_supportedGametypes & MapInfo_CurrentGametype()) == 0)
1144                 return 0;
1145         if((MapInfo_Map_supportedFeatures & MapInfo_CurrentFeatures()) != MapInfo_CurrentFeatures())
1146                 return 0;
1147         return 1;
1148 }
1149
1150 float MapInfo_CheckMap(string s) // returns 0 if the map can't be played with the current settings, 1 otherwise
1151 {
1152         float r;
1153         r = _MapInfo_CheckMap(s);
1154         MapInfo_ClearTemps();
1155         return r;
1156 }
1157
1158 string MapInfo_GetGameTypeCvar(float t)
1159 {
1160         switch(t)
1161         {
1162                 case MAPINFO_TYPE_DEATHMATCH: return "g_dm";
1163                 case MAPINFO_TYPE_TEAM_DEATHMATCH: return "g_tdm";
1164                 case MAPINFO_TYPE_DOMINATION: return "g_domination";
1165                 case MAPINFO_TYPE_CTF: return "g_ctf";
1166                 case MAPINFO_TYPE_RUNEMATCH: return "g_runematch";
1167                 case MAPINFO_TYPE_LMS: return "g_lms";
1168                 case MAPINFO_TYPE_ARENA: return "g_arena";
1169                 case MAPINFO_TYPE_CA: return "g_ca";
1170                 case MAPINFO_TYPE_KEYHUNT: return "g_kh";
1171                 case MAPINFO_TYPE_ASSAULT: return "g_assault";
1172                 case MAPINFO_TYPE_ONSLAUGHT: return "g_onslaught";
1173                 case MAPINFO_TYPE_RACE: return "g_race";
1174                 case MAPINFO_TYPE_NEXBALL: return "g_nexball";
1175                 case MAPINFO_TYPE_CTS: return "g_cts";
1176                 default: return "";
1177         }
1178 }
1179
1180 void MapInfo_SwitchGameType(float t)
1181 {
1182         cvar_set("gamecfg",      "0");
1183         cvar_set("g_dm",         (t == MAPINFO_TYPE_DEATHMATCH)      ? "1" : "0");
1184         cvar_set("g_tdm",        (t == MAPINFO_TYPE_TEAM_DEATHMATCH) ? "1" : "0");
1185         cvar_set("g_domination", (t == MAPINFO_TYPE_DOMINATION)      ? "1" : "0");
1186         cvar_set("g_ctf",        (t == MAPINFO_TYPE_CTF)             ? "1" : "0");
1187         cvar_set("g_runematch",  (t == MAPINFO_TYPE_RUNEMATCH)       ? "1" : "0");
1188         cvar_set("g_lms",        (t == MAPINFO_TYPE_LMS)             ? "1" : "0");
1189         cvar_set("g_arena",      (t == MAPINFO_TYPE_ARENA)           ? "1" : "0");
1190         cvar_set("g_ca",         (t == MAPINFO_TYPE_CA)              ? "1" : "0");
1191         cvar_set("g_keyhunt",    (t == MAPINFO_TYPE_KEYHUNT)         ? "1" : "0");
1192         cvar_set("g_assault",    (t == MAPINFO_TYPE_ASSAULT)         ? "1" : "0");
1193         cvar_set("g_onslaught",  (t == MAPINFO_TYPE_ONSLAUGHT)       ? "1" : "0");
1194         cvar_set("g_race",       (t == MAPINFO_TYPE_RACE)            ? "1" : "0");
1195         cvar_set("g_nexball",    (t == MAPINFO_TYPE_NEXBALL)         ? "1" : "0");
1196         cvar_set("g_cts",        (t == MAPINFO_TYPE_CTS)             ? "1" : "0");
1197 }
1198
1199 void MapInfo_LoadMap(string s)
1200 {
1201         MapInfo_Map_supportedGametypes = 0;
1202         // we shouldn't need this, as LoadMapSettings already fixes the gametype
1203         //if(!MapInfo_CheckMap(s))
1204         //{
1205         //      print("EMERGENCY: can't play the selected map in the given game mode. Falling back to DM.\n");
1206         //      MapInfo_SwitchGameType(MAPINFO_TYPE_DEATHMATCH);
1207         //}
1208         localcmd(strcat("\nsettemp_restore\nchangelevel ", s, "\n"));
1209 }
1210
1211 string MapInfo_ListAllowedMaps(float pRequiredFlags, float pForbiddenFlags)
1212 {
1213         string out;
1214         float i;
1215
1216         // to make absolutely sure:
1217         MapInfo_Enumerate();
1218         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), pRequiredFlags, pForbiddenFlags, 0);
1219
1220         out = "";
1221         for(i = 0; i < MapInfo_count; ++i)
1222                 out = strcat(out, " ", _MapInfo_GlobItem(MapInfo_FilterList_Lookup(i)));
1223         return substring(out, 1, strlen(out) - 1);
1224 }
1225
1226 void MapInfo_LoadMapSettings(string s) // to be called from worldspawn
1227 {
1228         float t, t0;
1229         if(!_MapInfo_CheckMap(s)) // with underscore, it keeps temps
1230         {
1231                 if(MapInfo_Map_supportedGametypes == 0)
1232                 {
1233                         print("Mapinfo system is not functional at all. Assuming deathmatch.\n");
1234                         MapInfo_Map_supportedGametypes = MAPINFO_TYPE_DEATHMATCH;
1235                 }
1236
1237                 t = 1;
1238                 while(!(MapInfo_Map_supportedGametypes & 1))
1239                 {
1240                         t *= 2;
1241                         MapInfo_Map_supportedGametypes = floor(MapInfo_Map_supportedGametypes / 2);
1242                 }
1243                 // t is now a supported mode!
1244                 t0 = MapInfo_CurrentGametype();
1245                 if(cvar("g_mapinfo_allow_unsupported_modes_and_let_stuff_break"))
1246                 {
1247                         print("EMERGENCY: can't play the selected map in the given game mode. Working with only the override settings.\n");
1248                         cvar_set("timelimit", "0");
1249                         cvar_set("fraglimit", "0");
1250                         cvar_set("g_tdm_teams", "2");
1251                         cvar_set("g_keyhunt_teams", "3");
1252                         cvar_set("g_race_qualifying_timelimit", "0");
1253                         cvar_set("leadlimit", "0");
1254                 }
1255                 else
1256                 {
1257                         print("EMERGENCY: can't play the selected map in the given game mode. Falling back to a supported mode.\n");
1258                         MapInfo_SwitchGameType(t);
1259                 }
1260         }
1261         cvar_settemp_restore();
1262         MapInfo_Get_ByName(s, 1, MapInfo_CurrentGametype());
1263 }
1264
1265 void MapInfo_ClearTemps()
1266 {
1267         MapInfo_Map_bspname = string_null;
1268         MapInfo_Map_title = string_null;
1269         MapInfo_Map_description = string_null;
1270         MapInfo_Map_author = string_null;
1271         MapInfo_Map_clientstuff = string_null;
1272         MapInfo_Map_supportedGametypes = 0;
1273         MapInfo_Map_supportedFeatures = 0;
1274 }
1275
1276 void MapInfo_Shutdown()
1277 {
1278         MapInfo_ClearTemps();
1279         MapInfo_Filter_Free();
1280         MapInfo_Cache_Destroy();
1281         if(_MapInfo_globopen)
1282         {
1283                 search_end(_MapInfo_globhandle);
1284                 _MapInfo_globhandle = -1;
1285                 _MapInfo_globopen = FALSE;
1286         }
1287 }
1288
1289 float MapInfo_ForbiddenFlags()
1290 {
1291         float f;
1292         f = MAPINFO_FLAG_FORBIDDEN;
1293
1294 #ifndef MENUQC
1295         if not(cvar("g_maplist_allow_hidden"))
1296 #endif
1297                 f |= MAPINFO_FLAG_HIDDEN;
1298
1299         if not(cvar("g_maplist_allow_frustrating"))
1300                 f |= MAPINFO_FLAG_FRUSTRATING;
1301
1302         return f;
1303 }
1304
1305 float MapInfo_RequiredFlags()
1306 {
1307         float f;
1308         f = 0;
1309
1310         if(cvar("g_maplist_allow_frustrating") > 1)
1311                 f |= MAPINFO_FLAG_FRUSTRATING;
1312
1313         return f;
1314 }