qcsrc/common/mapinfo.qc

   1 #include "mapinfo.qh"
   2 #if defined(CSQC)
   3     #include "../client/defs.qh"
   4     #include "util.qh"
   5     #include <common/weapons/_all.qh>
   6 #elif defined(MENUQC)
   7 #elif defined(SVQC)
   8     #include "util.qh"
   9     #include <common/monsters/_mod.qh>
  10 #endif
  11
  12 bool autocvar_g_mapinfo_ignore_warnings;
  13
  14 // generic string stuff
  15
  16 int _MapInfo_Cache_Active;
  17 int _MapInfo_Cache_DB_NameToIndex;
  18 int _MapInfo_Cache_Buf_IndexToMapData;
  19
  20 void MapInfo_Cache_Destroy()
  21 {
  22         if(!_MapInfo_Cache_Active)
  23                 return;
  24
  25         db_close(_MapInfo_Cache_DB_NameToIndex);
  26         buf_del(_MapInfo_Cache_Buf_IndexToMapData);
  27         _MapInfo_Cache_Active = 0;
  28 }
  29
  30 void MapInfo_Cache_Create()
  31 {
  32         MapInfo_Cache_Destroy();
  33         _MapInfo_Cache_DB_NameToIndex = db_create();
  34         _MapInfo_Cache_Buf_IndexToMapData = buf_create();
  35         _MapInfo_Cache_Active = 1;
  36 }
  37
  38 void MapInfo_Cache_Invalidate()
  39 {
  40         if(!_MapInfo_Cache_Active)
  41                 return;
  42
  43         MapInfo_Cache_Create();
  44 }
  45
  46 void MapInfo_Cache_Store()
  47 {
  48         float i;
  49         string s;
  50         if(!_MapInfo_Cache_Active)
  51                 return;
  52
  53         s = db_get(_MapInfo_Cache_DB_NameToIndex, MapInfo_Map_bspname);
  54         if(s == "")
  55         {
  56                 i = buf_getsize(_MapInfo_Cache_Buf_IndexToMapData);
  57                 db_put(_MapInfo_Cache_DB_NameToIndex, MapInfo_Map_bspname, ftos(i));
  58         }
  59         else
  60                 i = stof(s);
  61
  62         // now store all the stuff
  63         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData,   i, MapInfo_Map_bspname);
  64         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, MapInfo_Map_title);
  65         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, MapInfo_Map_titlestring);
  66         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, MapInfo_Map_description);
  67         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, MapInfo_Map_author);
  68         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, ftos(MapInfo_Map_supportedGametypes));
  69         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, ftos(MapInfo_Map_supportedFeatures));
  70         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, ftos(MapInfo_Map_flags));
  71 }
  72
  73 float MapInfo_Cache_Retrieve(string map)
  74 {
  75         float i;
  76         string s;
  77         if(!_MapInfo_Cache_Active)
  78                 return 0;
  79
  80         s = db_get(_MapInfo_Cache_DB_NameToIndex, map);
  81         if(s == "")
  82                 return 0;
  83         i = stof(s);
  84
  85         // now retrieve all the stuff
  86         MapInfo_Map_bspname = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, i);
  87         MapInfo_Map_title = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i);
  88         MapInfo_Map_titlestring = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i);
  89         MapInfo_Map_description = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i);
  90         MapInfo_Map_author = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i);
  91         MapInfo_Map_supportedGametypes = stof(bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i));
  92         MapInfo_Map_supportedFeatures = stof(bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i));
  93         MapInfo_Map_flags = stof(bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i));
  94
  95         return 1;
  96 }
  97
  98 // GLOB HANDLING (for all BSP files)
  99 float _MapInfo_globopen;
 100 float _MapInfo_globcount;
 101 float _MapInfo_globhandle;
 102 string _MapInfo_GlobItem(float i)
 103 {
 104         string s;
 105         if(!_MapInfo_globopen)
 106                 return string_null;
 107         s = search_getfilename(_MapInfo_globhandle, i);
 108         return substring(s, 5, strlen(s) - 9); // without maps/ and .bsp
 109 }
 110
 111 void MapInfo_Enumerate()
 112 {
 113         if(_MapInfo_globopen)
 114         {
 115                 search_end(_MapInfo_globhandle);
 116                 _MapInfo_globopen = 0;
 117         }
 118         MapInfo_Cache_Invalidate();
 119         _MapInfo_globhandle = search_begin("maps/*.bsp", true, true);
 120         if(_MapInfo_globhandle >= 0)
 121         {
 122                 _MapInfo_globcount = search_getsize(_MapInfo_globhandle);
 123                 _MapInfo_globopen = 1;
 124         }
 125         else
 126                 _MapInfo_globcount = 0;
 127 }
 128
 129 // filter the info by game type mask (updates MapInfo_count)
 130 //
 131 float _MapInfo_filtered;
 132 float _MapInfo_filtered_allocated;
 133 float MapInfo_FilterList_Lookup(float i)
 134 {
 135         return stof(bufstr_get(_MapInfo_filtered, i));
 136 }
 137
 138 void _MapInfo_FilterList_swap(float i, float j, entity pass)
 139 {
 140         string h;
 141         h = bufstr_get(_MapInfo_filtered, i);
 142         bufstr_set(_MapInfo_filtered, i, bufstr_get(_MapInfo_filtered, j));
 143         bufstr_set(_MapInfo_filtered, j, h);
 144 }
 145
 146 float _MapInfo_FilterList_cmp(float i, float j, entity pass)
 147 {
 148         string a, b;
 149         a = _MapInfo_GlobItem(stof(bufstr_get(_MapInfo_filtered, i)));
 150         b = _MapInfo_GlobItem(stof(bufstr_get(_MapInfo_filtered, j)));
 151         return strcasecmp(a, b);
 152 }
 153
 154 float MapInfo_FilterGametype(Gametype pGametype, int pFeatures, int pFlagsRequired, int pFlagsForbidden, bool pAbortOnGenerate)
 155 {
 156         return _MapInfo_FilterGametype(pGametype.m_flags, pFeatures, pFlagsRequired, pFlagsForbidden, pAbortOnGenerate);
 157 }
 158 float _MapInfo_FilterGametype(int pGametype, int pFeatures, int pFlagsRequired, int pFlagsForbidden, bool pAbortOnGenerate)
 159 {
 160         float i, j;
 161         if (!_MapInfo_filtered_allocated)
 162         {
 163                 _MapInfo_filtered_allocated = 1;
 164                 _MapInfo_filtered = buf_create();
 165         }
 166         MapInfo_count = 0;
 167         for(i = 0, j = -1; i < _MapInfo_globcount; ++i)
 168         {
 169                 if(MapInfo_Get_ByName(_MapInfo_GlobItem(i), 1, NULL) == 2) // if we generated one... BAIL OUT and let the caller continue in the next frame.
 170                         if(pAbortOnGenerate)
 171                         {
 172                                 LOG_TRACE("Autogenerated a .mapinfo, doing the rest later.");
 173                                 MapInfo_progress = i / _MapInfo_globcount;
 174                                 return 0;
 175                         }
 176                 if((MapInfo_Map_supportedGametypes & pGametype) != 0)
 177                 if((MapInfo_Map_supportedFeatures & pFeatures) == pFeatures)
 178                 if((MapInfo_Map_flags & pFlagsForbidden) == 0)
 179                 if((MapInfo_Map_flags & pFlagsRequired) == pFlagsRequired)
 180                         bufstr_set(_MapInfo_filtered, ++j, ftos(i));
 181         }
 182         MapInfo_count = j + 1;
 183         MapInfo_ClearTemps();
 184
 185         // sometimes the glob isn't sorted nicely, so fix it here...
 186         heapsort(MapInfo_count, _MapInfo_FilterList_swap, _MapInfo_FilterList_cmp, NULL);
 187
 188         return 1;
 189 }
 190 void MapInfo_FilterString(string sf)
 191 {
 192         // this function further filters _MapInfo_filtered, which is prepared by MapInfo_FilterGametype by string
 193         float i, j;
 194         string title;
 195
 196         for(i = 0, j = -1; i < MapInfo_count; ++i)
 197         {
 198                 if (MapInfo_Get_ByID(i))
 199                 {
 200                         // prepare for keyword filter
 201                         if (MapInfo_Map_title && strstrofs(MapInfo_Map_title, "<TITLE>", 0) == -1)
 202                                 title = MapInfo_Map_title;
 203                         else
 204                                 title = MapInfo_Map_bspname;
 205                         // keyword filter
 206                         if((strstrofs(strtolower(title), strtolower(sf), 0)) >= 0)
 207                                 bufstr_set(_MapInfo_filtered, ++j, bufstr_get(_MapInfo_filtered, i));
 208                 }
 209         }
 210         MapInfo_count = j + 1;
 211         MapInfo_ClearTemps();
 212
 213         // sometimes the glob isn't sorted nicely, so fix it here...
 214         heapsort(MapInfo_count, _MapInfo_FilterList_swap, _MapInfo_FilterList_cmp, NULL);
 215 }
 216
 217 void MapInfo_Filter_Free()
 218 {
 219         if(_MapInfo_filtered_allocated)
 220         {
 221                 buf_del(_MapInfo_filtered);
 222                 _MapInfo_filtered_allocated = 0;
 223         }
 224 }
 225
 226 // load info about the i-th map into the MapInfo_Map_* globals
 227 string MapInfo_BSPName_ByID(float i)
 228 {
 229         return _MapInfo_GlobItem(MapInfo_FilterList_Lookup(i));
 230 }
 231
 232 string unquote(string s)
 233 {
 234         float l = strlen(s);
 235         for(float i = 0; i < l; ++i)
 236         {
 237                 string ch = substring(s, i, 1);
 238                 if((ch != " ") && (ch != "\""))
 239                 {
 240                         for(float j = l - i - 1; j > 0; --j)
 241                         {
 242                                 ch = substring(s, i+j, 1);
 243                                 if(ch != " ") if(ch != "\"")
 244                                         return substring(s, i, j+1);
 245                         }
 246                         return substring(s, i, 1);
 247                 }
 248         }
 249         return "";
 250 }
 251
 252 float MapInfo_Get_ByID(float i)
 253 {
 254         if(MapInfo_Get_ByName(MapInfo_BSPName_ByID(i), 0, NULL))
 255                 return 1;
 256         return 0;
 257 }
 258
 259 string _MapInfo_Map_worldspawn_music;
 260
 261 float _MapInfo_Generate(string pFilename) // 0: failure, 1: ok ent, 2: ok bsp
 262 {
 263         string fn;
 264         float fh;
 265         string s, k, v;
 266         vector o;
 267         float i;
 268         float inWorldspawn;
 269         float r;
 270         float diameter, spawnpoints;
 271         float spawnplaces;
 272
 273         vector mapMins, mapMaxs;
 274
 275         r = 1;
 276         fn = strcat("maps/", pFilename, ".ent");
 277         fh = fopen(fn, FILE_READ);
 278         if(fh < 0)
 279         {
 280                 r = 2;
 281                 fn = strcat("maps/", pFilename, ".bsp");
 282                 fh = fopen(fn, FILE_READ);
 283         }
 284         if(fh < 0)
 285                 return 0;
 286         LOG_INFO("Analyzing ", fn, " to generate initial mapinfo");
 287
 288         inWorldspawn = 2;
 289         MapInfo_Map_flags = 0;
 290         MapInfo_Map_supportedGametypes = 0;
 291         spawnpoints = 0;
 292         spawnplaces = 0;
 293         _MapInfo_Map_worldspawn_music = "";
 294         mapMins = '0 0 0';
 295         mapMaxs = '0 0 0';
 296
 297         for (;;)
 298         {
 299                 if (!((s = fgets(fh))))
 300                         break;
 301                 if(inWorldspawn == 1)
 302                         if(startsWith(s, "}"))
 303                                 inWorldspawn = 0;
 304                 k = unquote(car(s));
 305                 v = unquote(cdr(s));
 306                 if(inWorldspawn)
 307                 {
 308                         if(k == "classname" && v == "worldspawn")
 309                                 inWorldspawn = 1;
 310                         else if(k == "author")
 311                                 MapInfo_Map_author = v;
 312                         else if(k == "_description")
 313                                 MapInfo_Map_description = v;
 314                         else if(k == "music")
 315                                 _MapInfo_Map_worldspawn_music = v;
 316                         else if(k == "noise")
 317                                 _MapInfo_Map_worldspawn_music = v;
 318                         else if(k == "message")
 319                         {
 320                                 i = strstrofs(v, " by ", 0);
 321                                 if(MapInfo_Map_author == "<AUTHOR>" && i >= 0)
 322                                 {
 323                                         MapInfo_Map_title = substring(v, 0, i);
 324                                         MapInfo_Map_author = substring(v, i + 4, strlen(v) - (i + 4));
 325                                 }
 326                                 else
 327                                         MapInfo_Map_title = v;
 328                         }
 329                 }
 330                 else
 331                 {
 332                         if(k == "origin")
 333                         {
 334                                 o = stov(strcat("'", v, "'"));
 335                                 mapMins.x = min(mapMins.x, o.x);
 336                                 mapMins.y = min(mapMins.y, o.y);
 337                                 mapMins.z = min(mapMins.z, o.z);
 338                                 mapMaxs.x = max(mapMaxs.x, o.x);
 339                                 mapMaxs.y = max(mapMaxs.y, o.y);
 340                                 mapMaxs.z = max(mapMaxs.z, o.z);
 341                         }
 342                         else if(k == "race_place")
 343                         {
 344                                 if(stof(v) > 0)
 345                                         spawnplaces = 1;
 346                         }
 347                         else if(k == "classname")
 348                         {
 349                                 if(v == "info_player_team1")
 350                                         ++spawnpoints;
 351                                 else if(v == "info_player_team2")
 352                                         ++spawnpoints;
 353                                 else if(v == "info_player_start")
 354                                         ++spawnpoints;
 355                                 else if(v == "info_player_deathmatch")
 356                                         ++spawnpoints;
 357                                 else if(v == "weapon_nex")
 358                                         { }
 359                                 else if(v == "weapon_railgun")
 360                                         { }
 361                                 else if(startsWith(v, "weapon_"))
 362                                         MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_WEAPONS;
 363                                 else if(startsWith(v, "turret_"))
 364                                         MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_TURRETS;
 365                                 else if(startsWith(v, "vehicle_"))
 366                                         MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_VEHICLES;
 367                                 else if(startsWith(v, "monster_"))
 368                                         MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_MONSTERS;
 369                                 else if(v == "target_music" || v == "trigger_music")
 370                                         _MapInfo_Map_worldspawn_music = string_null; // don't use regular BGM
 371                                 else
 372                                         FOREACH(Gametypes, true, it.m_generate_mapinfo(it, v));
 373                         }
 374                 }
 375         }
 376         if(inWorldspawn)
 377         {
 378                 LOG_WARN(fn, " ended still in worldspawn, BUG");
 379                 return 0;
 380         }
 381         diameter = vlen(mapMaxs - mapMins);
 382
 383         int twoBaseModes = 0;
 384         FOREACH(Gametypes, it.m_isTwoBaseMode(), twoBaseModes |= it.m_flags);
 385         if(twoBaseModes && (twoBaseModes &= MapInfo_Map_supportedGametypes))
 386         {
 387                 // we have a symmetrical map, don't add the modes without bases
 388         }
 389         else
 390         {
 391                 FOREACH(Gametypes, it.m_isAlwaysSupported(it, spawnpoints, diameter), MapInfo_Map_supportedGametypes |= it.m_flags);
 392         }
 393
 394         if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_RACE.m_flags)
 395         if(!spawnplaces)
 396         {
 397                 MapInfo_Map_supportedGametypes &= ~MAPINFO_TYPE_RACE.m_flags;
 398                 MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_CTS.m_flags;
 399         }
 400
 401         LOG_TRACE("-> diameter ",    ftos(diameter));
 402         LOG_TRACE(";  spawnpoints ", ftos(spawnpoints));
 403         LOG_TRACE(";  modes ",       ftos(MapInfo_Map_supportedGametypes));
 404
 405         fclose(fh);
 406
 407         return r;
 408 }
 409
 410 void _MapInfo_Map_Reset()
 411 {
 412         MapInfo_Map_title = "<TITLE>";
 413         MapInfo_Map_titlestring = "<TITLE>";
 414         MapInfo_Map_description = "<DESCRIPTION>";
 415         MapInfo_Map_author = "<AUTHOR>";
 416         MapInfo_Map_supportedGametypes = 0;
 417         MapInfo_Map_supportedFeatures = 0;
 418         MapInfo_Map_flags = 0;
 419         MapInfo_Map_clientstuff = "";
 420         MapInfo_Map_fog = "";
 421         MapInfo_Map_mins = '0 0 0';
 422         MapInfo_Map_maxs = '0 0 0';
 423 }
 424
 425 string _MapInfo_GetDefault(Gametype t)
 426 {
 427         return t.m_legacydefaults;
 428 }
 429
 430 void _MapInfo_Map_ApplyGametype(string s, Gametype pWantedType, Gametype pThisType, int load_default)
 431 {
 432         string sa;
 433         MapInfo_Map_supportedGametypes |= pThisType.m_flags;
 434         if(!(pThisType.m_flags & pWantedType.m_flags))
 435                 return;
 436
 437         if(load_default)
 438                 _MapInfo_Map_ApplyGametype(_MapInfo_GetDefault(pThisType), pWantedType, pThisType, false);
 439
 440         if(!pWantedType.frags) // these modes don't use fraglimit
 441         {
 442                 cvar_set("fraglimit", "0");
 443         }
 444         else
 445         {
 446                 sa = car(s);
 447                 if(sa != "")
 448                         cvar_set("fraglimit", sa);
 449                 s = cdr(s);
 450         }
 451
 452         sa = car(s);
 453         if(sa != "")
 454                 cvar_set("timelimit", sa);
 455         s = cdr(s);
 456
 457         if(pWantedType.m_setTeams)
 458         {
 459                 sa = car(s);
 460                 if(sa != "")
 461                         pWantedType.m_setTeams(sa);
 462                 s = cdr(s);
 463         }
 464
 465         // rc = timelimit timelimit_qualification laps laps_teamplay
 466         if(pWantedType == MAPINFO_TYPE_RACE)
 467         {
 468                 cvar_set("fraglimit", "0"); // special case!
 469
 470                 sa = car(s); if(sa == "") sa = cvar_string("timelimit");
 471                 cvar_set("g_race_qualifying_timelimit", sa);
 472                 s = cdr(s);
 473
 474                 sa = car(s);
 475                 if(sa != "")
 476                         if(cvar("g_race_teams") < 2)
 477                                 cvar_set("fraglimit", sa);
 478                 s = cdr(s);
 479
 480                 sa = car(s);
 481                 if(sa != "")
 482                         if(cvar("g_race_teams") >= 2)
 483                                 cvar_set("fraglimit", sa);
 484                 s = cdr(s);
 485         }
 486
 487         if(!pWantedType.frags) // these modes don't use fraglimit
 488         {
 489                 cvar_set("leadlimit", "0");
 490         }
 491         else
 492         {
 493                 sa = car(s);
 494                 if(sa != "")
 495                         cvar_set("leadlimit", sa);
 496                 s = cdr(s);
 497         }
 498 }
 499
 500 string _MapInfo_GetDefaultEx(Gametype t)
 501 {
 502         return t ? t.model2 : "";
 503 }
 504
 505 float _MapInfo_GetTeamPlayBool(Gametype t)
 506 {
 507         return t ? t.team : false;
 508 }
 509
 510 void _MapInfo_Map_ApplyGametypeEx(string s, Gametype pWantedType, Gametype pThisType)
 511 {
 512         MapInfo_Map_supportedGametypes |= pThisType.m_flags;
 513         if (!(pThisType.m_flags & pWantedType.m_flags))
 514                 return;
 515
 516         // reset all the cvars to their defaults
 517
 518         cvar_set("timelimit", cvar_defstring("timelimit"));
 519         cvar_set("leadlimit", cvar_defstring("leadlimit"));
 520         cvar_set("fraglimit", cvar_defstring("fraglimit"));
 521         FOREACH(Gametypes, true, it.m_parse_mapinfo(string_null, string_null));
 522
 523         string fraglimit_normal = string_null;
 524         string fraglimit_teams = string_null;
 525
 526         for (s = strcat(_MapInfo_GetDefaultEx(pWantedType), " ", s); s != ""; s = cdr(s)) {
 527                 string sa = car(s);
 528                 if (sa == "") continue;
 529                 int p = strstrofs(sa, "=", 0);
 530                 if (p < 0) {
 531                         if(!autocvar_g_mapinfo_ignore_warnings)
 532                                 LOG_WARNF("Invalid gametype setting in mapinfo for gametype %s: %s", MapInfo_Type_ToString(pWantedType), sa);
 533                         continue;
 534                 }
 535                 string k = substring(sa, 0, p);
 536                 string v = substring(sa, p + 1, -1);
 537                 bool handled = true;
 538                 switch (k) {
 539                         case "timelimit":
 540                         {
 541                                 cvar_set("timelimit", v);
 542                                 break;
 543                         }
 544                         case "leadlimit":
 545                         {
 546                                 cvar_set("leadlimit", v);
 547                                 break;
 548                         }
 549                         case "pointlimit":
 550                         case "fraglimit":
 551                         case "lives":
 552                         case "laplimit":
 553                         case "caplimit":
 554                         {
 555                                 fraglimit_normal = v;
 556                                 break;
 557                         }
 558                         case "teampointlimit":
 559                         case "teamlaplimit":
 560                         {
 561                                 fraglimit_teams = v;
 562                                 break;
 563                         }
 564                         default:
 565                         {
 566                             handled = false;
 567                             break;
 568                         }
 569                 }
 570                 FOREACH(Gametypes, true, handled |= it.m_parse_mapinfo(k, v));
 571                 if (!handled && !autocvar_g_mapinfo_ignore_warnings)
 572             LOG_WARNF("Invalid gametype setting in mapinfo for gametype %s: %s", MapInfo_Type_ToString(pWantedType), sa);
 573         }
 574
 575         if (pWantedType == MAPINFO_TYPE_RACE && cvar("g_race_teams") >= 2)
 576         {
 577                 if(fraglimit_teams)
 578                         cvar_set("fraglimit", fraglimit_teams);
 579         }
 580         else
 581         {
 582                 if(fraglimit_normal)
 583                         cvar_set("fraglimit", fraglimit_normal);
 584         }
 585 }
 586
 587 Gametype MapInfo_Type_FromString(string t)
 588 {
 589 #define deprecate(from, to) MACRO_BEGIN { \
 590         if (t == #from) { \
 591                 string replacement = #to; \
 592                 if(!autocvar_g_mapinfo_ignore_warnings) \
 593                         LOG_WARNF("MapInfo_Type_FromString (probably %s): using deprecated name '%s'. Should use '%s'.", MapInfo_Map_bspname, t, replacement); \
 594                 t = replacement; \
 595         } \
 596 } MACRO_END
 597         deprecate(nexball, nb);
 598         deprecate(freezetag, ft);
 599         deprecate(keepaway, ka);
 600         deprecate(invasion, inv);
 601         deprecate(assault, as);
 602         deprecate(race, rc);
 603         FOREACH(Gametypes, it.mdl == t, return it);
 604         return NULL;
 605 #undef deprecate
 606 }
 607
 608 string MapInfo_Type_Description(Gametype t)
 609 {
 610         return t ? t.gametype_description : "";
 611 }
 612
 613 string MapInfo_Type_ToString(Gametype t)
 614 {
 615         return t ? t.mdl : "";
 616 }
 617
 618 string MapInfo_Type_ToText(Gametype t)
 619 {
 620         /* xgettext:no-c-format */
 621         return t ? t.message : _("@!#%'n Tuba Throwing");
 622 }
 623
 624 void _MapInfo_Parse_Settemp(string pFilename, string acl, float type, string s, float recurse)
 625 {
 626         string t;
 627         float fh, o;
 628         t = car(s); s = cdr(s);
 629
 630         // limited support of "" and comments
 631         //   remove trailing and leading " of t
 632         if(substring(t, 0, 1) == "\"")
 633         {
 634                 if(substring(t, -1, 1) == "\"")
 635                         t = substring(t, 1, -2);
 636         }
 637
 638         //   remove leading " of s
 639         if(substring(s, 0, 1) == "\"")
 640         {
 641                 s = substring(s, 1, -1);
 642         }
 643         //   remove trailing " of s, and all that follows (cvar description)
 644         o = strstrofs(s, "\"", 0);
 645         if(o >= 0)
 646                 s = substring(s, 0, o);
 647
 648         //   remove // comments
 649         o = strstrofs(s, "//", 0);
 650         if(o >= 0)
 651                 s = substring(s, 0, o);
 652
 653         //   remove trailing spaces
 654         while(substring(s, -1, 1) == " ")
 655                 s = substring(s, 0, -2);
 656
 657         if(t == "#include")
 658         {
 659                 if(recurse > 0)
 660                 {
 661                         fh = fopen(s, FILE_READ);
 662                         if(fh < 0)
 663                                 LOG_WARN("Map ", pFilename, " references not existing config file ", s);
 664                         else
 665                         {
 666                                 for (;;)
 667                                 {
 668                                         if (!((s = fgets(fh))))
 669                                                 break;
 670
 671                                         // catch different sorts of comments
 672                                         if(s == "")                    // empty lines
 673                                                 continue;
 674                                         if(substring(s, 0, 1) == "#")  // UNIX style
 675                                                 continue;
 676                                         if(substring(s, 0, 2) == "//") // C++ style
 677                                                 continue;
 678                                         if(substring(s, 0, 1) == "_")  // q3map style
 679                                                 continue;
 680
 681                                         if(substring(s, 0, 4) == "set ")
 682                                                 s = substring(s, 4, -1);
 683                                         if(substring(s, 0, 5) == "seta ")
 684                                                 s = substring(s, 5, -1);
 685
 686                                         _MapInfo_Parse_Settemp(pFilename, acl, type, s, recurse - 1);
 687                                 }
 688                                 fclose(fh);
 689                         }
 690                 }
 691                 else
 692                         LOG_WARN("Map ", pFilename, " uses too many levels of inclusion");
 693         }
 694         else if(t == "")
 695                 LOG_WARN("Map ", pFilename, " contains a potentially harmful setting, ignored");
 696         else if (!cvar_value_issafe(t))
 697                 LOG_WARN("Map ", pFilename, " contains a potentially harmful setting, ignored");
 698         else if (!cvar_value_issafe(s))
 699                 LOG_WARN("Map ", pFilename, " contains a potentially harmful setting, ignored");
 700         else if(matchacl(MAPINFO_SETTEMP_ACL_SYSTEM, t) <= 0)
 701                 LOG_WARN("Map ", pFilename, " contains a potentially harmful setting, ignored");
 702         else if(matchacl(acl, t) <= 0)
 703                 LOG_WARN("Map ", pFilename, " contains a denied setting, ignored");
 704         else
 705         {
 706                 if(type == 0) // server set
 707                 {
 708                         LOG_TRACE("Applying temporary setting ", t, " := ", s);
 709                         if(cvar("g_campaign"))
 710                                 cvar_set(t, s); // this is a wrapper and is always temporary anyway; no need to backup old values then
 711                         else
 712                                 cvar_settemp(t, s);
 713                 }
 714                 else
 715                 {
 716                         LOG_TRACE("Applying temporary client setting ", t, " := ", s);
 717                         MapInfo_Map_clientstuff = strcat(
 718                                         MapInfo_Map_clientstuff, "cl_cmd settemp \"", t, "\" \"", s, "\"\n"
 719                                         );
 720                 }
 721         }
 722 }
 723
 724 float MapInfo_isRedundant(string fn, string t)
 725 {
 726         // normalize file name
 727         fn = strreplace("_", "-", fn);
 728
 729         // normalize visible title
 730         t = strreplace(": ", "-", t);
 731         t = strreplace(":", "-", t);
 732         t = strreplace(" ", "-", t);
 733         t = strreplace("_", "-", t);
 734         t = strreplace("'", "-", t);
 735
 736         if(!strcasecmp(fn, t))
 737                 return true;
 738
 739         // we allow the visible title to have punctuation the file name does
 740         // not, but not vice versa
 741         t = strreplace("-", "", t);
 742
 743         if(!strcasecmp(fn, t))
 744                 return true;
 745
 746         return false;
 747 }
 748
 749 // load info about a map by name into the MapInfo_Map_* globals
 750 float MapInfo_Get_ByName_NoFallbacks(string pFilename, int pAllowGenerate, Gametype pGametypeToSet)
 751 {
 752         string fn;
 753         string s, t;
 754         float fh;
 755         int f, i;
 756         float r, n, p;
 757         string acl;
 758
 759         acl = MAPINFO_SETTEMP_ACL_USER;
 760
 761         if(strstrofs(pFilename, "/", 0) >= 0)
 762         {
 763                 LOG_WARN("Invalid character in map name, ignored");
 764                 return 0;
 765         }
 766
 767         if(pGametypeToSet == NULL)
 768                 if(MapInfo_Cache_Retrieve(pFilename))
 769                         return 1;
 770
 771         r = 1;
 772
 773         MapInfo_Map_bspname = pFilename;
 774
 775         // default all generic fields so they have "good" values in case something fails
 776         fn = strcat("maps/", pFilename, ".mapinfo");
 777         fh = fopen(fn, FILE_READ);
 778         if(fh < 0)
 779         {
 780                 fn = strcat("maps/autogenerated/", pFilename, ".mapinfo");
 781                 fh = fopen(fn, FILE_READ);
 782                 if(fh < 0)
 783                 {
 784                         if(!pAllowGenerate)
 785                                 return 0;
 786                         _MapInfo_Map_Reset();
 787                         r = _MapInfo_Generate(pFilename);
 788                         if(!r)
 789                                 return 0;
 790                         fh = fopen(fn, FILE_WRITE);
 791                         fputs(fh, strcat("title ", MapInfo_Map_title, "\n"));
 792                         fputs(fh, strcat("description ", MapInfo_Map_description, "\n"));
 793                         fputs(fh, strcat("author ", MapInfo_Map_author, "\n"));
 794                         if(_MapInfo_Map_worldspawn_music != "")
 795                         {
 796                                 if(
 797                                         substring(_MapInfo_Map_worldspawn_music, strlen(_MapInfo_Map_worldspawn_music) - 4, 4) == ".wav"
 798                                         ||
 799                                         substring(_MapInfo_Map_worldspawn_music, strlen(_MapInfo_Map_worldspawn_music) - 4, 4) == ".ogg"
 800                                 )
 801                                         fputs(fh, strcat("cdtrack ", substring(_MapInfo_Map_worldspawn_music, 0, strlen(_MapInfo_Map_worldspawn_music) - 4), "\n"));
 802                                 else
 803                                         fputs(fh, strcat("cdtrack ", _MapInfo_Map_worldspawn_music, "\n"));
 804                         }
 805                         else
 806                         {
 807                                 n = tokenize_console(cvar_string("g_cdtracks_remaplist"));
 808                                 s = strcat(" ", cvar_string("g_cdtracks_dontusebydefault"), " ");
 809                                 for (;;)
 810                                 {
 811                                         i = floor(random() * n);
 812                                         if(strstrofs(s, strcat(" ", argv(i), " "), 0) < 0)
 813                                                 break;
 814                                 }
 815                                 fputs(fh, strcat("cdtrack ", ftos(i + 1), "\n"));
 816                         }
 817                         if(MapInfo_Map_supportedFeatures & MAPINFO_FEATURE_WEAPONS)
 818                                 fputs(fh, "has weapons\n");
 819                         else
 820                                 fputs(fh, "// uncomment this if you added weapon pickups: has weapons\n");
 821                         if(MapInfo_Map_supportedFeatures & MAPINFO_FEATURE_TURRETS)
 822                                 fputs(fh, "has turrets\n");
 823                         else
 824                                 fputs(fh, "// uncomment this if you added turrets: has turrets\n");
 825                         if(MapInfo_Map_supportedFeatures & MAPINFO_FEATURE_VEHICLES)
 826                                 fputs(fh, "has vehicles\n");
 827                         else
 828                                 fputs(fh, "// uncomment this if you added vehicles: has vehicles\n");
 829                         if(MapInfo_Map_flags & MAPINFO_FLAG_FRUSTRATING)
 830                                 fputs(fh, "frustrating\n");
 831
 832                         FOREACH(Gametypes, MapInfo_Map_supportedGametypes & it.m_flags, {
 833                                 fputs(fh, sprintf("gametype %s // defaults: %s\n", MapInfo_Type_ToString(it), _MapInfo_GetDefaultEx(it)));
 834                         });
 835
 836                         if(fexists(strcat("scripts/", pFilename, ".arena")))
 837                                 fputs(fh, "settemp_for_type all sv_q3acompat_machineshotgunswap 1\n");
 838
 839                         if(fexists(strcat("scripts/", pFilename, ".defi")))
 840                                 fputs(fh, "settemp_for_type all sv_vq3compat 1\n");
 841
 842                         fputs(fh, "// optional: fog density red green blue alpha mindist maxdist\n");
 843                         fputs(fh, "// optional: settemp_for_type (all|gametypename) cvarname value\n");
 844                         fputs(fh, "// optional: clientsettemp_for_type (all|gametypename) cvarname value\n");
 845                         fputs(fh, "// optional: size mins_x mins_y mins_z maxs_x maxs_y maxs_z\n");
 846                         fputs(fh, "// optional: hidden\n");
 847
 848                         fclose(fh);
 849                         r = 2;
 850                         // return r;
 851                         fh = fopen(fn, FILE_READ);
 852                         if(fh < 0)
 853                                 error("... but I just wrote it!");
 854                 }
 855
 856                 if(!autocvar_g_mapinfo_ignore_warnings)
 857                         LOG_WARN("autogenerated mapinfo file ", fn, " has been loaded; please edit that file and move it to maps/", pFilename, ".mapinfo");
 858         }
 859
 860         _MapInfo_Map_Reset();
 861         for (;;)
 862         {
 863                 if (!((s = fgets(fh))))
 864                         break;
 865
 866                 // catch different sorts of comments
 867                 if(s == "")                    // empty lines
 868                         continue;
 869                 if(substring(s, 0, 1) == "#")  // UNIX style
 870                         continue;
 871                 if(substring(s, 0, 2) == "//") // C++ style
 872                         continue;
 873                 if(substring(s, 0, 1) == "_")  // q3map style
 874                         continue;
 875
 876                 p = strstrofs(s, "//", 0);
 877                 if(p >= 0)
 878                         s = substring(s, 0, p);
 879
 880                 t = car(s); s = cdr(s);
 881                 if(t == "title")
 882                         MapInfo_Map_title = s;
 883                 else if(t == "description")
 884                         MapInfo_Map_description = s;
 885                 else if(t == "author")
 886                         MapInfo_Map_author = s;
 887                 else if(t == "has")
 888                 {
 889                         t = car(s); // s = cdr(s);
 890                         if     (t == "weapons") MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_WEAPONS;
 891                         else if(t == "turrets") MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_TURRETS;
 892                         else if(t == "vehicles") MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_VEHICLES;
 893                         else if(t == "monsters") MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_MONSTERS;
 894                         else if(t == "new_toys") MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_WEAPONS;
 895                         else
 896                                 LOG_WARN("Map ", pFilename, " supports unknown feature ", t, ", ignored");
 897                 }
 898                 else if(t == "hidden")
 899                 {
 900                         MapInfo_Map_flags |= MAPINFO_FLAG_HIDDEN;
 901                 }
 902                 else if(t == "forbidden")
 903                 {
 904                         MapInfo_Map_flags |= MAPINFO_FLAG_FORBIDDEN;
 905                 }
 906                 else if(t == "frustrating")
 907                 {
 908                         MapInfo_Map_flags |= MAPINFO_FLAG_FRUSTRATING;
 909                 }
 910                 else if(t == "noautomaplist")
 911                 {
 912                         MapInfo_Map_flags |= MAPINFO_FLAG_NOAUTOMAPLIST;
 913                 }
 914                 else if(t == "gameversion_min")
 915                 {
 916                         if (cvar("gameversion") < stof(s))
 917                                 MapInfo_Map_flags |= MAPINFO_FLAG_NOAUTOMAPLIST;
 918                 }
 919                 else if(t == "type")
 920                 {
 921                         t = car(s); s = cdr(s);
 922                         Gametype f = MapInfo_Type_FromString(t);
 923                         //if(!autocvar_g_mapinfo_ignore_warnings)
 924                                 //LOG_WARN("Map ", pFilename, " contains the legacy 'type' keyword which is deprecated and will be removed in the future. Please migrate the mapinfo file to 'gametype'.");
 925                         if(f)
 926                                 _MapInfo_Map_ApplyGametype (s, pGametypeToSet, f, true);
 927                         else if(!autocvar_g_mapinfo_ignore_warnings)
 928                                 LOG_DEBUG("Map ", pFilename, " supports unknown game type ", t, ", ignored");
 929                 }
 930                 else if(t == "gametype")
 931                 {
 932                         t = car(s); s = cdr(s);
 933                         Gametype f = MapInfo_Type_FromString(t);
 934                         if(f)
 935                                 _MapInfo_Map_ApplyGametypeEx (s, pGametypeToSet, f);
 936                         else if(!autocvar_g_mapinfo_ignore_warnings)
 937                                 LOG_DEBUG("Map ", pFilename, " supports unknown game type ", t, ", ignored");
 938                 }
 939                 else if(t == "size")
 940                 {
 941                         float a, b, c, d, e;
 942                         t = car(s); s = cdr(s); a = stof(t);
 943                         t = car(s); s = cdr(s); b = stof(t);
 944                         t = car(s); s = cdr(s); c = stof(t);
 945                         t = car(s); s = cdr(s); d = stof(t);
 946                         t = car(s); s = cdr(s); e = stof(t);
 947                         if(s == "")
 948                                 LOG_WARN("Map ", pFilename, " contains an incorrect size line (not enough params), syntax: size mins_x mins_y mins_z maxs_x maxs_y maxs_z");
 949                         else
 950                         {
 951                                 t = car(s); s = cdr(s); f = stof(t);
 952                                 if(s != "")
 953                                         LOG_WARN("Map ", pFilename, " contains an incorrect size line (too many params), syntax: size mins_x mins_y mins_z maxs_x maxs_y maxs_z");
 954                                 else
 955                                 {
 956                                         if(a >= d || b >= e || c >= f)
 957                                                 LOG_WARN("Map ", pFilename, " contains an incorrect size line, mins have to be < maxs");
 958                                         else
 959                                         {
 960                                                 MapInfo_Map_mins.x = a;
 961                                                 MapInfo_Map_mins.y = b;
 962                                                 MapInfo_Map_mins.z = c;
 963                                                 MapInfo_Map_maxs.x = d;
 964                                                 MapInfo_Map_maxs.y = e;
 965                                                 MapInfo_Map_maxs.z = f;
 966                                         }
 967                                 }
 968                         }
 969                 }
 970                 else if(t == "settemp_for_type")
 971                 {
 972                         t = car(s); s = cdr(s);
 973                         bool all = t == "all";
 974                         Gametype f = NULL;
 975                         if(all || (f = MapInfo_Type_FromString(t)))
 976                         {
 977                                 if((all ? MAPINFO_TYPE_ALL : f.m_flags) & pGametypeToSet.m_flags)
 978                                 {
 979                                         _MapInfo_Parse_Settemp(pFilename, acl, 0, s, 1);
 980                                 }
 981                         }
 982                         else
 983                         {
 984                                 LOG_DEBUG("Map ", pFilename, " has a setting for unknown game type ", t, ", ignored");
 985                         }
 986                 }
 987                 else if(t == "clientsettemp_for_type")
 988                 {
 989                         t = car(s); s = cdr(s);
 990                         bool all = t == "all";
 991                         Gametype f = NULL;
 992                         if(all || (f = MapInfo_Type_FromString(t)))
 993                         {
 994                                 if((all ? MAPINFO_TYPE_ALL : f.m_flags) & pGametypeToSet.m_flags)
 995                                 {
 996                                         _MapInfo_Parse_Settemp(pFilename, acl, 1, s, 1);
 997                                 }
 998                         }
 999                         else
1000                         {
1001                                 LOG_DEBUG("Map ", pFilename, " has a client setting for unknown game type ", t, ", ignored");
1002                         }
1003                 }
1004                 else if(t == "fog")
1005                 {
1006                         if (!cvar_value_issafe(s))
1007                                 LOG_WARN("Map ", pFilename, " contains a potentially harmful fog setting, ignored");
1008                         else
1009                                 MapInfo_Map_fog = s;
1010                 }
1011                 else if(t == "cdtrack")
1012                 {
1013                         t = car(s); s = cdr(s);
1014                         // We do this only if pGametypeToSet even though this
1015                         // content is theoretically game type independent,
1016                         // because MapInfo_Map_clientstuff contains otherwise
1017                         // game type dependent stuff. That way this value stays
1018                         // empty when not setting a game type to not set any
1019                         // false expectations.
1020                         if(pGametypeToSet)
1021                         {
1022                                 if (!cvar_value_issafe(t))
1023                                         LOG_WARN("Map ", pFilename, " contains a potentially harmful cdtrack, ignored");
1024                                 else
1025                                         MapInfo_Map_clientstuff = strcat(
1026                                                 MapInfo_Map_clientstuff, "cd loop \"", t, "\"\n"
1027                                         );
1028                         }
1029                 }
1030                 else if(!autocvar_g_mapinfo_ignore_warnings)
1031                         LOG_WARN("Map ", pFilename, " provides unknown info item ", t, ", ignored");
1032         }
1033         fclose(fh);
1034
1035         if(MapInfo_Map_title == "<TITLE>")
1036                 MapInfo_Map_titlestring = MapInfo_Map_bspname;
1037         else if(MapInfo_isRedundant(MapInfo_Map_bspname, MapInfo_Map_title))
1038                 MapInfo_Map_titlestring = MapInfo_Map_title;
1039         else
1040                 MapInfo_Map_titlestring = sprintf("%s: %s", MapInfo_Map_bspname, MapInfo_Map_title);
1041
1042         MapInfo_Cache_Store();
1043         if(MapInfo_Map_supportedGametypes != 0)
1044                 return r;
1045         LOG_WARN("Map ", pFilename, " supports no game types, ignored");
1046         return 0;
1047 }
1048 int MapInfo_Get_ByName(string pFilename, float pAllowGenerate, Gametype pGametypeToSet)
1049 {
1050         int r = MapInfo_Get_ByName_NoFallbacks(pFilename, pAllowGenerate, pGametypeToSet);
1051
1052         FOREACH(Gametypes, it.m_isForcedSupported(it), _MapInfo_Map_ApplyGametypeEx("", pGametypeToSet, it));
1053
1054         if(pGametypeToSet)
1055         {
1056                 if(!(MapInfo_Map_supportedGametypes & pGametypeToSet.m_flags))
1057                 {
1058                         error("Can't select the requested game type. This should never happen as the caller should prevent it!\n");
1059                         //_MapInfo_Map_ApplyGametypeEx("", pGametypeToSet, MAPINFO_TYPE_DEATHMATCH);
1060                         //return;
1061                 }
1062         }
1063
1064         return r;
1065 }
1066
1067 float MapInfo_FindName(string s)
1068 {
1069         // if there is exactly one map of prefix s, return it
1070         // if not, return the null string
1071         // note that DP sorts glob results... so I can use a binary search
1072         float l, r, m, cmp;
1073         l = 0;
1074         r = MapInfo_count;
1075         // invariants: r is behind s, l-1 is equal or before
1076         while(l != r)
1077         {
1078                 m = floor((l + r) / 2);
1079                 MapInfo_FindName_match = _MapInfo_GlobItem(MapInfo_FilterList_Lookup(m));
1080                 cmp = strcasecmp(MapInfo_FindName_match, s);
1081                 if(cmp == 0)
1082                         return m; // found and good
1083                 if(cmp < 0)
1084                         l = m + 1; // l-1 is before s
1085                 else
1086                         r = m; // behind s
1087         }
1088         MapInfo_FindName_match = _MapInfo_GlobItem(MapInfo_FilterList_Lookup(l));
1089         MapInfo_FindName_firstResult = l;
1090         // r == l, so: l is behind s, l-1 is before
1091         // SO: if there is any, l is the one with the right prefix
1092         //     and l+1 may be one too
1093         if(l == MapInfo_count)
1094         {
1095                 MapInfo_FindName_match = string_null;
1096                 MapInfo_FindName_firstResult = -1;
1097                 return -1; // no MapInfo_FindName_match, behind last item
1098         }
1099         if(!startsWithNocase(MapInfo_FindName_match, s))
1100         {
1101                 MapInfo_FindName_match = string_null;
1102                 MapInfo_FindName_firstResult = -1;
1103                 return -1; // wrong prefix
1104         }
1105         if(l == MapInfo_count - 1)
1106                 return l; // last one, nothing can follow => unique
1107         if(startsWithNocase(_MapInfo_GlobItem(MapInfo_FilterList_Lookup(l + 1)), s))
1108         {
1109                 MapInfo_FindName_match = string_null;
1110                 return -1; // ambigous MapInfo_FindName_match
1111         }
1112         return l;
1113 }
1114
1115 string MapInfo_FixName(string s)
1116 {
1117         MapInfo_FindName(s);
1118         return MapInfo_FindName_match;
1119 }
1120
1121 int MapInfo_CurrentFeatures()
1122 {
1123         int req = 0;
1124         if(!(cvar("g_lms") || cvar("g_instagib") || cvar("g_overkill") || cvar("g_nix") || cvar("g_weaponarena") || !cvar("g_pickup_items") || cvar("g_race") || cvar("g_cts") || cvar("g_nexball")))
1125                 req |= MAPINFO_FEATURE_WEAPONS;
1126         return req;
1127 }
1128
1129 Gametype MapInfo_CurrentGametype()
1130 {
1131         Gametype prev = Gametypes_from(cvar("gamecfg"));
1132         FOREACH(Gametypes, cvar(it.netname) && it != prev, return it);
1133         return prev ? prev : MAPINFO_TYPE_DEATHMATCH;
1134 }
1135
1136 float _MapInfo_CheckMap(string s, bool gametype_only) // returns 0 if the map can't be played with the current settings, 1 otherwise
1137 {
1138         if(!MapInfo_Get_ByName(s, 1, NULL))
1139                 return 0;
1140         if((MapInfo_Map_supportedGametypes & MapInfo_CurrentGametype().m_flags) == 0)
1141                 return 0;
1142         if (gametype_only)
1143                 return 1;
1144         if((MapInfo_Map_supportedFeatures & MapInfo_CurrentFeatures()) != MapInfo_CurrentFeatures())
1145                 return 0;
1146         return 1;
1147 }
1148
1149 float MapInfo_CheckMap(string s) // returns 0 if the map can't be played with the current settings, 1 otherwise
1150 {
1151         float r;
1152         r = _MapInfo_CheckMap(s, false);
1153         MapInfo_ClearTemps();
1154         return r;
1155 }
1156
1157 void MapInfo_SwitchGameType(Gametype t)
1158 {
1159         FOREACH(Gametypes, true, cvar_set(it.netname, (it == t) ? "1" : "0"));
1160 }
1161
1162 void MapInfo_LoadMap(string s, float reinit)
1163 {
1164         MapInfo_Map_supportedGametypes = 0;
1165         // we shouldn't need this, as LoadMapSettings already fixes the gametype
1166         //if(!MapInfo_CheckMap(s))
1167         //{
1168         //      print("EMERGENCY: can't play the selected map in the given game mode. Falling back to DM.\n");
1169         //      MapInfo_SwitchGameType(MAPINFO_TYPE_DEATHMATCH.m_flags);
1170         //}
1171
1172         LOG_INFO("Switching to map ", s);
1173
1174         cvar_settemp_restore();
1175         if(reinit)
1176                 localcmd(strcat("\nmap ", s, "\n"));
1177         else
1178                 localcmd(strcat("\nchangelevel ", s, "\n"));
1179 }
1180
1181 string MapInfo_ListAllowedMaps(Gametype type, float pRequiredFlags, float pForbiddenFlags)
1182 {
1183         string out;
1184
1185         // to make absolutely sure:
1186         MapInfo_Enumerate();
1187         MapInfo_FilterGametype(type, MapInfo_CurrentFeatures(), pRequiredFlags, pForbiddenFlags, 0);
1188
1189         out = "";
1190         for(float i = 0; i < MapInfo_count; ++i)
1191                 out = strcat(out, " ", _MapInfo_GlobItem(MapInfo_FilterList_Lookup(i)));
1192         return substring(out, 1, strlen(out) - 1);
1193 }
1194
1195 string MapInfo_ListAllAllowedMaps(float pRequiredFlags, float pForbiddenFlags)
1196 {
1197         string out;
1198
1199         // to make absolutely sure:
1200         MapInfo_Enumerate();
1201         _MapInfo_FilterGametype(MAPINFO_TYPE_ALL, 0, pRequiredFlags, pForbiddenFlags, 0);
1202
1203         out = "";
1204         for(float i = 0; i < MapInfo_count; ++i)
1205                 out = strcat(out, " ", _MapInfo_GlobItem(MapInfo_FilterList_Lookup(i)));
1206
1207         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), pRequiredFlags, pForbiddenFlags, 0);
1208
1209         return substring(out, 1, strlen(out) - 1);
1210 }
1211
1212 void MapInfo_LoadMapSettings_SaveGameType(Gametype t)
1213 {
1214         MapInfo_SwitchGameType(t);
1215         cvar_set("gamecfg", ftos(t.m_id));
1216         MapInfo_LoadedGametype = t;
1217 }
1218
1219 void MapInfo_LoadMapSettings(string s) // to be called from worldspawn
1220 {
1221         Gametype t = MapInfo_CurrentGametype();
1222         MapInfo_LoadMapSettings_SaveGameType(t);
1223
1224         if(!_MapInfo_CheckMap(s, true)) // with underscore, it keeps temps
1225         {
1226                 if(cvar("g_mapinfo_allow_unsupported_modes_and_let_stuff_break"))
1227                 {
1228                         LOG_SEVERE("can't play the selected map in the given game mode. Working with only the override settings.");
1229                         _MapInfo_Map_ApplyGametypeEx("", t, t);
1230                         return; // do not call Get_ByName!
1231                 }
1232
1233                 if(MapInfo_Map_supportedGametypes == 0)
1234                 {
1235                         LOG_SEVERE("Mapinfo system is not functional at all. Assuming deathmatch.");
1236                         MapInfo_Map_supportedGametypes = MAPINFO_TYPE_DEATHMATCH.m_flags;
1237                         MapInfo_LoadMapSettings_SaveGameType(MAPINFO_TYPE_DEATHMATCH);
1238                         _MapInfo_Map_ApplyGametypeEx("", MAPINFO_TYPE_DEATHMATCH, MAPINFO_TYPE_DEATHMATCH);
1239                         return; // do not call Get_ByName!
1240                 }
1241
1242                 int _t = 1;
1243                 while(!(MapInfo_Map_supportedGametypes & 1))
1244                 {
1245                         _t <<= 1;
1246                         MapInfo_Map_supportedGametypes = floor(MapInfo_Map_supportedGametypes >> 1);
1247                 }
1248                 Gametype t_prev = t;
1249                 FOREACH(Gametypes, it.m_flags == _t, { t = it; break; });
1250
1251                 // t is now a supported mode!
1252                 LOG_WARNF("can't play the selected map in the given game mode (%s). Falling back to a supported mode (%s).", t_prev.mdl, t.mdl);
1253                 MapInfo_LoadMapSettings_SaveGameType(t);
1254         }
1255         if(!_MapInfo_CheckMap(s, false)) { // with underscore, it keeps temps
1256                 LOG_WARNF("the selected map lacks features required by current settings; playing anyway.");
1257         }
1258         MapInfo_Get_ByName(s, 1, t);
1259 }
1260
1261 void MapInfo_ClearTemps()
1262 {
1263         MapInfo_Map_bspname = string_null;
1264         MapInfo_Map_title = string_null;
1265         MapInfo_Map_titlestring = string_null;
1266         MapInfo_Map_description = string_null;
1267         MapInfo_Map_author = string_null;
1268         MapInfo_Map_clientstuff = string_null;
1269         MapInfo_Map_supportedGametypes = 0;
1270         MapInfo_Map_supportedFeatures = 0;
1271 }
1272
1273 void MapInfo_Shutdown()
1274 {
1275         MapInfo_ClearTemps();
1276         MapInfo_Filter_Free();
1277         MapInfo_Cache_Destroy();
1278         if(_MapInfo_globopen)
1279         {
1280                 search_end(_MapInfo_globhandle);
1281                 _MapInfo_globhandle = -1;
1282                 _MapInfo_globopen = false;
1283         }
1284 }
1285
1286 int MapInfo_ForbiddenFlags()
1287 {
1288         int f = MAPINFO_FLAG_FORBIDDEN;
1289
1290 #ifdef GAMEQC
1291         if (!cvar("g_maplist_allow_hidden"))
1292 #endif
1293                 f |= MAPINFO_FLAG_HIDDEN;
1294
1295         if (!cvar("g_maplist_allow_frustrating"))
1296                 f |= MAPINFO_FLAG_FRUSTRATING;
1297
1298         return f;
1299 }
1300
1301 int MapInfo_RequiredFlags()
1302 {
1303         int f = 0;
1304
1305         if(cvar("g_maplist_allow_frustrating") > 1)
1306                 f |= MAPINFO_FLAG_FRUSTRATING;
1307
1308         return f;
1309 }