qcsrc/common/mapinfo.qc

   1 #include "mapinfo.qh"
   2 #if defined(CSQC)
   3     #include "../client/defs.qh"
   4     #include "util.qh"
   5     #include <common/weapons/_all.qh>
   6 #elif defined(MENUQC)
   7 #elif defined(SVQC)
   8     #include "util.qh"
   9     #include <common/monsters/_mod.qh>
  10 #endif
  11
  12 bool autocvar_g_mapinfo_ignore_warnings;
  13
  14 // generic string stuff
  15
  16 int _MapInfo_Cache_Active;
  17 int _MapInfo_Cache_DB_NameToIndex;
  18 int _MapInfo_Cache_Buf_IndexToMapData;
  19
  20 void MapInfo_Cache_Destroy()
  21 {
  22         if(!_MapInfo_Cache_Active)
  23                 return;
  24
  25         db_close(_MapInfo_Cache_DB_NameToIndex);
  26         buf_del(_MapInfo_Cache_Buf_IndexToMapData);
  27         _MapInfo_Cache_Active = 0;
  28 }
  29
  30 void MapInfo_Cache_Create()
  31 {
  32         MapInfo_Cache_Destroy();
  33         _MapInfo_Cache_DB_NameToIndex = db_create();
  34         _MapInfo_Cache_Buf_IndexToMapData = buf_create();
  35         _MapInfo_Cache_Active = 1;
  36 }
  37
  38 void MapInfo_Cache_Invalidate()
  39 {
  40         if(!_MapInfo_Cache_Active)
  41                 return;
  42
  43         MapInfo_Cache_Create();
  44 }
  45
  46 void MapInfo_Cache_Store()
  47 {
  48         float i;
  49         string s;
  50         if(!_MapInfo_Cache_Active)
  51                 return;
  52
  53         s = db_get(_MapInfo_Cache_DB_NameToIndex, MapInfo_Map_bspname);
  54         if(s == "")
  55         {
  56                 i = buf_getsize(_MapInfo_Cache_Buf_IndexToMapData);
  57                 db_put(_MapInfo_Cache_DB_NameToIndex, MapInfo_Map_bspname, ftos(i));
  58         }
  59         else
  60                 i = stof(s);
  61
  62         // now store all the stuff
  63         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData,   i, MapInfo_Map_bspname);
  64         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, MapInfo_Map_title);
  65         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, MapInfo_Map_titlestring);
  66         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, MapInfo_Map_description);
  67         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, MapInfo_Map_author);
  68         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, ftos(MapInfo_Map_supportedGametypes));
  69         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, ftos(MapInfo_Map_supportedFeatures));
  70         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, ftos(MapInfo_Map_flags));
  71 }
  72
  73 float MapInfo_Cache_Retrieve(string map)
  74 {
  75         float i;
  76         string s;
  77         if(!_MapInfo_Cache_Active)
  78                 return 0;
  79
  80         s = db_get(_MapInfo_Cache_DB_NameToIndex, map);
  81         if(s == "")
  82                 return 0;
  83         i = stof(s);
  84
  85         // now retrieve all the stuff
  86         MapInfo_Map_bspname = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, i);
  87         MapInfo_Map_title = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i);
  88         MapInfo_Map_titlestring = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i);
  89         MapInfo_Map_description = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i);
  90         MapInfo_Map_author = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i);
  91         MapInfo_Map_supportedGametypes = stof(bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i));
  92         MapInfo_Map_supportedFeatures = stof(bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i));
  93         MapInfo_Map_flags = stof(bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i));
  94
  95         return 1;
  96 }
  97
  98 // GLOB HANDLING (for all BSP files)
  99 float _MapInfo_globopen;
 100 float _MapInfo_globcount;
 101 float _MapInfo_globhandle;
 102 string _MapInfo_GlobItem(float i)
 103 {
 104         string s;
 105         if(!_MapInfo_globopen)
 106                 return string_null;
 107         s = search_getfilename(_MapInfo_globhandle, i);
 108         return substring(s, 5, strlen(s) - 9); // without maps/ and .bsp
 109 }
 110
 111 void MapInfo_Enumerate()
 112 {
 113         if(_MapInfo_globopen)
 114         {
 115                 search_end(_MapInfo_globhandle);
 116                 _MapInfo_globopen = 0;
 117         }
 118         MapInfo_Cache_Invalidate();
 119         _MapInfo_globhandle = search_begin("maps/*.bsp", true, true);
 120         if(_MapInfo_globhandle >= 0)
 121         {
 122                 _MapInfo_globcount = search_getsize(_MapInfo_globhandle);
 123                 _MapInfo_globopen = 1;
 124         }
 125         else
 126                 _MapInfo_globcount = 0;
 127 }
 128
 129 // filter the info by game type mask (updates MapInfo_count)
 130 //
 131 float _MapInfo_filtered;
 132 float _MapInfo_filtered_allocated;
 133 float MapInfo_FilterList_Lookup(float i)
 134 {
 135         return stof(bufstr_get(_MapInfo_filtered, i));
 136 }
 137
 138 void _MapInfo_FilterList_swap(float i, float j, entity pass)
 139 {
 140         string h;
 141         h = bufstr_get(_MapInfo_filtered, i);
 142         bufstr_set(_MapInfo_filtered, i, bufstr_get(_MapInfo_filtered, j));
 143         bufstr_set(_MapInfo_filtered, j, h);
 144 }
 145
 146 float _MapInfo_FilterList_cmp(float i, float j, entity pass)
 147 {
 148         string a, b;
 149         a = _MapInfo_GlobItem(stof(bufstr_get(_MapInfo_filtered, i)));
 150         b = _MapInfo_GlobItem(stof(bufstr_get(_MapInfo_filtered, j)));
 151         return strcasecmp(a, b);
 152 }
 153
 154 float MapInfo_FilterGametype(Gametype pGametype, int pFeatures, int pFlagsRequired, int pFlagsForbidden, bool pAbortOnGenerate)
 155 {
 156         return _MapInfo_FilterGametype(pGametype.m_flags, pFeatures, pFlagsRequired, pFlagsForbidden, pAbortOnGenerate);
 157 }
 158 float _MapInfo_FilterGametype(int pGametype, int pFeatures, int pFlagsRequired, int pFlagsForbidden, bool pAbortOnGenerate)
 159 {
 160         float i, j;
 161         if (!_MapInfo_filtered_allocated)
 162         {
 163                 _MapInfo_filtered_allocated = 1;
 164                 _MapInfo_filtered = buf_create();
 165         }
 166         MapInfo_count = 0;
 167         for(i = 0, j = -1; i < _MapInfo_globcount; ++i)
 168         {
 169                 if(MapInfo_Get_ByName(_MapInfo_GlobItem(i), 1, NULL) == 2) // if we generated one... BAIL OUT and let the caller continue in the next frame.
 170                         if(pAbortOnGenerate)
 171                         {
 172                                 LOG_TRACE("Autogenerated a .mapinfo, doing the rest later.");
 173                                 MapInfo_progress = i / _MapInfo_globcount;
 174                                 return 0;
 175                         }
 176                 if((MapInfo_Map_supportedGametypes & pGametype) != 0)
 177                 if((MapInfo_Map_supportedFeatures & pFeatures) == pFeatures)
 178                 if((MapInfo_Map_flags & pFlagsForbidden) == 0)
 179                 if((MapInfo_Map_flags & pFlagsRequired) == pFlagsRequired)
 180                         bufstr_set(_MapInfo_filtered, ++j, ftos(i));
 181         }
 182         MapInfo_count = j + 1;
 183         MapInfo_ClearTemps();
 184
 185         // sometimes the glob isn't sorted nicely, so fix it here...
 186         heapsort(MapInfo_count, _MapInfo_FilterList_swap, _MapInfo_FilterList_cmp, NULL);
 187
 188         return 1;
 189 }
 190 void MapInfo_FilterString(string sf)
 191 {
 192         // this function further filters _MapInfo_filtered, which is prepared by MapInfo_FilterGametype by string
 193         float i, j;
 194         string title;
 195
 196         for(i = 0, j = -1; i < MapInfo_count; ++i)
 197         {
 198                 if (MapInfo_Get_ByID(i))
 199                 {
 200                         // prepare for keyword filter
 201                         if (MapInfo_Map_title && strstrofs(MapInfo_Map_title, "<TITLE>", 0) == -1)
 202                                 title = MapInfo_Map_title;
 203                         else
 204                                 title = MapInfo_Map_bspname;
 205                         // keyword filter
 206                         if((strstrofs(strtolower(title), strtolower(sf), 0)) >= 0)
 207                                 bufstr_set(_MapInfo_filtered, ++j, bufstr_get(_MapInfo_filtered, i));
 208                 }
 209         }
 210         MapInfo_count = j + 1;
 211         MapInfo_ClearTemps();
 212
 213         // sometimes the glob isn't sorted nicely, so fix it here...
 214         heapsort(MapInfo_count, _MapInfo_FilterList_swap, _MapInfo_FilterList_cmp, NULL);
 215 }
 216
 217 void MapInfo_Filter_Free()
 218 {
 219         if(_MapInfo_filtered_allocated)
 220         {
 221                 buf_del(_MapInfo_filtered);
 222                 _MapInfo_filtered_allocated = 0;
 223         }
 224 }
 225
 226 // load info about the i-th map into the MapInfo_Map_* globals
 227 string MapInfo_BSPName_ByID(float i)
 228 {
 229         return _MapInfo_GlobItem(MapInfo_FilterList_Lookup(i));
 230 }
 231
 232 string unquote(string s)
 233 {
 234         float l = strlen(s);
 235         for(float i = 0; i < l; ++i)
 236         {
 237                 string ch = substring(s, i, 1);
 238                 if((ch != " ") && (ch != "\""))
 239                 {
 240                         for(float j = l - i - 1; j > 0; --j)
 241                         {
 242                                 ch = substring(s, i+j, 1);
 243                                 if(ch != " ") if(ch != "\"")
 244                                         return substring(s, i, j+1);
 245                         }
 246                         return substring(s, i, 1);
 247                 }
 248         }
 249         return "";
 250 }
 251
 252 float MapInfo_Get_ByID(float i)
 253 {
 254         if(MapInfo_Get_ByName(MapInfo_BSPName_ByID(i), 0, NULL))
 255                 return 1;
 256         return 0;
 257 }
 258
 259 string _MapInfo_Map_worldspawn_music;
 260
 261 float _MapInfo_Generate(string pFilename) // 0: failure, 1: ok ent, 2: ok bsp
 262 {
 263         string fn;
 264         float fh;
 265         string s, k, v;
 266         vector o;
 267         float i;
 268         float inWorldspawn;
 269         float r;
 270         float diameter, spawnpoints;
 271         float spawnplaces;
 272
 273         vector mapMins, mapMaxs;
 274
 275         r = 1;
 276         fn = strcat("maps/", pFilename, ".ent");
 277         fh = fopen(fn, FILE_READ);
 278         if(fh < 0)
 279         {
 280                 r = 2;
 281                 fn = strcat("maps/", pFilename, ".bsp");
 282                 fh = fopen(fn, FILE_READ);
 283         }
 284         if(fh < 0)
 285                 return 0;
 286         LOG_INFO("Analyzing ", fn, " to generate initial mapinfo");
 287
 288         inWorldspawn = 2;
 289         MapInfo_Map_flags = 0;
 290         MapInfo_Map_supportedGametypes = 0;
 291         spawnpoints = 0;
 292         spawnplaces = 0;
 293         _MapInfo_Map_worldspawn_music = "";
 294         mapMins = '0 0 0';
 295         mapMaxs = '0 0 0';
 296
 297         for (;;)
 298         {
 299                 if (!((s = fgets(fh))))
 300                         break;
 301                 if(inWorldspawn == 1)
 302                         if(startsWith(s, "}"))
 303                                 inWorldspawn = 0;
 304                 k = unquote(car(s));
 305                 v = unquote(cdr(s));
 306                 if(inWorldspawn)
 307                 {
 308                         if(k == "classname" && v == "worldspawn")
 309                                 inWorldspawn = 1;
 310                         else if(k == "author")
 311                                 MapInfo_Map_author = v;
 312                         else if(k == "_description")
 313                                 MapInfo_Map_description = v;
 314                         else if(k == "music")
 315                                 _MapInfo_Map_worldspawn_music = v;
 316                         else if(k == "noise")
 317                                 _MapInfo_Map_worldspawn_music = v;
 318                         else if(k == "message")
 319                         {
 320                                 i = strstrofs(v, " by ", 0);
 321                                 if(MapInfo_Map_author == "<AUTHOR>" && i >= 0)
 322                                 {
 323                                         MapInfo_Map_title = substring(v, 0, i);
 324                                         MapInfo_Map_author = substring(v, i + 4, strlen(v) - (i + 4));
 325                                 }
 326                                 else
 327                                         MapInfo_Map_title = v;
 328                         }
 329                 }
 330                 else
 331                 {
 332                         if(k == "origin")
 333                         {
 334                                 o = stov(strcat("'", v, "'"));
 335                                 mapMins.x = min(mapMins.x, o.x);
 336                                 mapMins.y = min(mapMins.y, o.y);
 337                                 mapMins.z = min(mapMins.z, o.z);
 338                                 mapMaxs.x = max(mapMaxs.x, o.x);
 339                                 mapMaxs.y = max(mapMaxs.y, o.y);
 340                                 mapMaxs.z = max(mapMaxs.z, o.z);
 341                         }
 342                         else if(k == "race_place")
 343                         {
 344                                 if(stof(v) > 0)
 345                                         spawnplaces = 1;
 346                         }
 347                         else if(k == "classname")
 348                         {
 349                                 if(v == "info_player_team1")
 350                                         ++spawnpoints;
 351                                 else if(v == "info_player_team2")
 352                                         ++spawnpoints;
 353                                 else if(v == "info_player_start")
 354                                         ++spawnpoints;
 355                                 else if(v == "info_player_deathmatch")
 356                                         ++spawnpoints;
 357                                 else if(v == "weapon_nex")
 358                                         { }
 359                                 else if(v == "weapon_railgun")
 360                                         { }
 361                                 else if(startsWith(v, "weapon_"))
 362                                         MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_WEAPONS;
 363                                 else if(startsWith(v, "turret_"))
 364                                         MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_TURRETS;
 365                                 else if(startsWith(v, "vehicle_"))
 366                                         MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_VEHICLES;
 367                                 else if(startsWith(v, "monster_"))
 368                                         MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_MONSTERS;
 369                                 else if(v == "target_music" || v == "trigger_music")
 370                                         _MapInfo_Map_worldspawn_music = string_null; // don't use regular BGM
 371                                 else
 372                                         FOREACH(Gametypes, true, it.m_generate_mapinfo(it, v));
 373                         }
 374                 }
 375         }
 376         if(inWorldspawn)
 377         {
 378                 LOG_WARN(fn, " ended still in worldspawn, BUG");
 379                 return 0;
 380         }
 381         diameter = vlen(mapMaxs - mapMins);
 382
 383         int twoBaseModes = 0;
 384         FOREACH(Gametypes, it.m_isTwoBaseMode(), twoBaseModes |= it.m_flags);
 385         if(twoBaseModes && (twoBaseModes &= MapInfo_Map_supportedGametypes))
 386         {
 387                 // we have a symmetrical map, don't add the modes without bases
 388         }
 389         else
 390         {
 391                 FOREACH(Gametypes, it.m_isAlwaysSupported(it, spawnpoints, diameter), MapInfo_Map_supportedGametypes |= it.m_flags);
 392         }
 393
 394         if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_RACE.m_flags)
 395         if(!spawnplaces)
 396         {
 397                 MapInfo_Map_supportedGametypes &= ~MAPINFO_TYPE_RACE.m_flags;
 398                 MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_CTS.m_flags;
 399         }
 400
 401         LOG_TRACE("-> diameter ",    ftos(diameter));
 402         LOG_TRACE(";  spawnpoints ", ftos(spawnpoints));
 403         LOG_TRACE(";  modes ",       ftos(MapInfo_Map_supportedGametypes));
 404
 405         fclose(fh);
 406
 407         return r;
 408 }
 409
 410 void _MapInfo_Map_Reset()
 411 {
 412         MapInfo_Map_title = "<TITLE>";
 413         MapInfo_Map_titlestring = "<TITLE>";
 414         MapInfo_Map_description = "<DESCRIPTION>";
 415         MapInfo_Map_author = "<AUTHOR>";
 416         MapInfo_Map_supportedGametypes = 0;
 417         MapInfo_Map_supportedFeatures = 0;
 418         MapInfo_Map_flags = 0;
 419         MapInfo_Map_clientstuff = "";
 420         MapInfo_Map_fog = "";
 421         MapInfo_Map_mins = '0 0 0';
 422         MapInfo_Map_maxs = '0 0 0';
 423 }
 424
 425 string _MapInfo_GetDefault(Gametype t)
 426 {
 427         return t.m_legacydefaults;
 428 }
 429
 430 void _MapInfo_Map_ApplyGametype(string s, Gametype pWantedType, Gametype pThisType, int load_default)
 431 {
 432         string sa;
 433         MapInfo_Map_supportedGametypes |= pThisType.m_flags;
 434         if(!(pThisType.m_flags & pWantedType.m_flags))
 435                 return;
 436
 437         if(load_default)
 438                 _MapInfo_Map_ApplyGametype(_MapInfo_GetDefault(pThisType), pWantedType, pThisType, false);
 439
 440         if(!pWantedType.frags) // these modes don't use fraglimit
 441         {
 442                 cvar_set("fraglimit", "0");
 443         }
 444         else
 445         {
 446                 sa = car(s);
 447                 if(sa != "")
 448                         cvar_set("fraglimit", sa);
 449                 s = cdr(s);
 450         }
 451
 452         sa = car(s);
 453         if(sa != "")
 454                 cvar_set("timelimit", sa);
 455         s = cdr(s);
 456
 457         if(pWantedType.m_setTeams)
 458         {
 459                 sa = car(s);
 460                 if(sa != "")
 461                         pWantedType.m_setTeams(sa);
 462                 s = cdr(s);
 463         }
 464
 465         // rc = timelimit timelimit_qualification laps laps_teamplay
 466         if(pWantedType == MAPINFO_TYPE_RACE)
 467         {
 468                 cvar_set("fraglimit", "0"); // special case!
 469
 470                 sa = car(s); if(sa == "") sa = cvar_string("timelimit");
 471                 cvar_set("g_race_qualifying_timelimit", sa);
 472                 s = cdr(s);
 473
 474                 sa = car(s);
 475                 if(sa != "")
 476                         if(cvar("g_race_teams") < 2)
 477                                 cvar_set("fraglimit", sa);
 478                 s = cdr(s);
 479
 480                 sa = car(s);
 481                 if(sa != "")
 482                         if(cvar("g_race_teams") >= 2)
 483                                 cvar_set("fraglimit", sa);
 484                 s = cdr(s);
 485         }
 486
 487         if(!pWantedType.frags) // these modes don't use fraglimit
 488         {
 489                 cvar_set("leadlimit", "0");
 490         }
 491         else
 492         {
 493                 sa = car(s);
 494                 if(sa != "")
 495                         cvar_set("leadlimit", sa);
 496                 s = cdr(s);
 497         }
 498 }
 499
 500 string _MapInfo_GetDefaultEx(Gametype t)
 501 {
 502         return t ? t.model2 : "";
 503 }
 504
 505 float _MapInfo_GetTeamPlayBool(Gametype t)
 506 {
 507         return t ? t.team : false;
 508 }
 509
 510 void _MapInfo_Map_ApplyGametypeEx(string s, Gametype pWantedType, Gametype pThisType)
 511 {
 512         MapInfo_Map_supportedGametypes |= pThisType.m_flags;
 513         if (!(pThisType.m_flags & pWantedType.m_flags))
 514                 return;
 515
 516         // reset all the cvars to their defaults
 517
 518         cvar_set("timelimit", cvar_defstring("timelimit"));
 519         cvar_set("leadlimit", cvar_defstring("leadlimit"));
 520         cvar_set("fraglimit", cvar_defstring("fraglimit"));
 521         FOREACH(Gametypes, true, it.m_parse_mapinfo(string_null, string_null));
 522
 523         string fraglimit_normal = string_null;
 524         string fraglimit_teams = string_null;
 525
 526         for (s = strcat(_MapInfo_GetDefaultEx(pWantedType), " ", s); s != ""; s = cdr(s)) {
 527                 string sa = car(s);
 528                 if (sa == "") continue;
 529                 int p = strstrofs(sa, "=", 0);
 530                 if (p < 0) {
 531                         if(!autocvar_g_mapinfo_ignore_warnings)
 532                                 LOG_WARNF("Invalid gametype setting in mapinfo for gametype %s: %s", MapInfo_Type_ToString(pWantedType), sa);
 533                         continue;
 534                 }
 535                 string k = substring(sa, 0, p);
 536                 string v = substring(sa, p + 1, -1);
 537                 bool handled = true;
 538                 switch (k) {
 539                         case "timelimit":
 540                         {
 541                                 cvar_set("timelimit", v);
 542                                 break;
 543                         }
 544                         case "leadlimit":
 545                         {
 546                                 cvar_set("leadlimit", v);
 547                                 break;
 548                         }
 549                         case "pointlimit":
 550                         case "fraglimit":
 551                         case "lives":
 552                         case "laplimit":
 553                         case "caplimit":
 554                         {
 555                                 fraglimit_normal = v;
 556                                 break;
 557                         }
 558                         case "teampointlimit":
 559                         case "teamlaplimit":
 560                         {
 561                                 fraglimit_teams = v;
 562                                 break;
 563                         }
 564                         default:
 565                         {
 566                             handled = false;
 567                             break;
 568                         }
 569                 }
 570                 FOREACH(Gametypes, true, handled |= it.m_parse_mapinfo(k, v));
 571                 if (!handled && !autocvar_g_mapinfo_ignore_warnings)
 572             LOG_WARNF("Invalid gametype setting in mapinfo for gametype %s: %s", MapInfo_Type_ToString(pWantedType), sa);
 573         }
 574
 575         if (pWantedType == MAPINFO_TYPE_RACE && cvar("g_race_teams") >= 2)
 576         {
 577                 if(fraglimit_teams)
 578                         cvar_set("fraglimit", fraglimit_teams);
 579         }
 580         else
 581         {
 582                 if(fraglimit_normal)
 583                         cvar_set("fraglimit", fraglimit_normal);
 584         }
 585 }
 586
 587 Gametype MapInfo_Type_FromString(string t)
 588 {
 589 #define deprecate(from, to) MACRO_BEGIN { \
 590         if (t == #from) { \
 591                 string replacement = #to; \
 592                 if(!autocvar_g_mapinfo_ignore_warnings) \
 593                         LOG_WARNF("MapInfo_Type_FromString (probably %s): using deprecated name '%s'. Should use '%s'.", MapInfo_Map_bspname, t, replacement); \
 594                 t = replacement; \
 595         } \
 596 } MACRO_END
 597         deprecate(nexball, nb);
 598         deprecate(freezetag, ft);
 599         deprecate(keepaway, ka);
 600         deprecate(invasion, inv);
 601         deprecate(assault, as);
 602         deprecate(race, rc);
 603         FOREACH(Gametypes, it.mdl == t, return it);
 604         return NULL;
 605 #undef deprecate
 606 }
 607
 608 string MapInfo_Type_Description(Gametype t)
 609 {
 610         return t ? t.gametype_description : "";
 611 }
 612
 613 string MapInfo_Type_ToString(Gametype t)
 614 {
 615         return t ? t.mdl : "";
 616 }
 617
 618 string MapInfo_Type_ToText(Gametype t)
 619 {
 620         /* xgettext:no-c-format */
 621         return t ? t.message : _("@!#%'n Tuba Throwing");
 622 }
 623
 624 void _MapInfo_Parse_Settemp(string pFilename, string acl, float type, string s, float recurse)
 625 {
 626         string t;
 627         float fh, o;
 628         t = car(s); s = cdr(s);
 629
 630         // limited support of "" and comments
 631         //   remove trailing and leading " of t
 632         if(substring(t, 0, 1) == "\"")
 633         {
 634                 if(substring(t, -1, 1) == "\"")
 635                         t = substring(t, 1, -2);
 636         }
 637
 638         //   remove leading " of s
 639         if(substring(s, 0, 1) == "\"")
 640         {
 641                 s = substring(s, 1, -1);
 642         }
 643         //   remove trailing " of s, and all that follows (cvar description)
 644         o = strstrofs(s, "\"", 0);
 645         if(o >= 0)
 646                 s = substring(s, 0, o);
 647
 648         //   remove // comments
 649         o = strstrofs(s, "//", 0);
 650         if(o >= 0)
 651                 s = substring(s, 0, o);
 652
 653         //   remove trailing spaces
 654         while(substring(s, -1, 1) == " ")
 655                 s = substring(s, 0, -2);
 656
 657         if(t == "#include")
 658         {
 659                 if(recurse > 0)
 660                 {
 661                         fh = fopen(s, FILE_READ);
 662                         if(fh < 0)
 663                                 LOG_WARN("Map ", pFilename, " references not existing config file ", s);
 664                         else
 665                         {
 666                                 for (;;)
 667                                 {
 668                                         if (!((s = fgets(fh))))
 669                                                 break;
 670
 671                                         // catch different sorts of comments
 672                                         if(s == "")                    // empty lines
 673                                                 continue;
 674                                         if(substring(s, 0, 1) == "#")  // UNIX style
 675                                                 continue;
 676                                         if(substring(s, 0, 2) == "//") // C++ style
 677                                                 continue;
 678                                         if(substring(s, 0, 1) == "_")  // q3map style
 679                                                 continue;
 680
 681                                         if(substring(s, 0, 4) == "set ")
 682                                                 s = substring(s, 4, -1);
 683                                         if(substring(s, 0, 5) == "seta ")
 684                                                 s = substring(s, 5, -1);
 685
 686                                         _MapInfo_Parse_Settemp(pFilename, acl, type, s, recurse - 1);
 687                                 }
 688                                 fclose(fh);
 689                         }
 690                 }
 691                 else
 692                         LOG_WARN("Map ", pFilename, " uses too many levels of inclusion");
 693         }
 694         else if(t == "")
 695                 LOG_WARN("Map ", pFilename, " contains a potentially harmful setting, ignored");
 696         else if (!cvar_value_issafe(t))
 697                 LOG_WARN("Map ", pFilename, " contains a potentially harmful setting, ignored");
 698         else if (!cvar_value_issafe(s))
 699                 LOG_WARN("Map ", pFilename, " contains a potentially harmful setting, ignored");
 700         else if(matchacl(MAPINFO_SETTEMP_ACL_SYSTEM, t) <= 0)
 701                 LOG_WARN("Map ", pFilename, " contains a potentially harmful setting, ignored");
 702         else if(matchacl(acl, t) <= 0)
 703                 LOG_WARN("Map ", pFilename, " contains a denied setting, ignored");
 704         else
 705         {
 706                 if(type == 0) // server set
 707                 {
 708                         LOG_TRACE("Applying temporary setting ", t, " := ", s);
 709                         if(cvar("g_campaign"))
 710                                 cvar_set(t, s); // this is a wrapper and is always temporary anyway; no need to backup old values then
 711                         else
 712                                 cvar_settemp(t, s);
 713                 }
 714                 else
 715                 {
 716                         LOG_TRACE("Applying temporary client setting ", t, " := ", s);
 717                         MapInfo_Map_clientstuff = strcat(
 718                                         MapInfo_Map_clientstuff, "cl_cmd settemp \"", t, "\" \"", s, "\"\n"
 719                                         );
 720                 }
 721         }
 722 }
 723
 724 float MapInfo_isRedundant(string fn, string t)
 725 {
 726         // normalize file name
 727         fn = strreplace("_", "", fn);
 728         fn = strreplace("-", "", fn);
 729
 730         // normalize visible title
 731         t = strreplace(":", "", t);
 732         t = strreplace(" ", "", t);
 733         t = strreplace("_", "", t);
 734         t = strreplace("-", "", t);
 735         t = strreplace("'", "", t);
 736         t = strdecolorize(t);
 737
 738         // we allow the visible title to have punctuation the file name does
 739         // not, but not vice versa
 740         if(!strcasecmp(fn, t))
 741                 return true;
 742
 743         return false;
 744 }
 745
 746 // load info about a map by name into the MapInfo_Map_* globals
 747 float MapInfo_Get_ByName_NoFallbacks(string pFilename, int pAllowGenerate, Gametype pGametypeToSet)
 748 {
 749         string fn;
 750         string s, t;
 751         float fh;
 752         int f, i;
 753         float r, n, p;
 754         string acl;
 755
 756         acl = MAPINFO_SETTEMP_ACL_USER;
 757
 758         if(strstrofs(pFilename, "/", 0) >= 0)
 759         {
 760                 LOG_WARN("Invalid character in map name, ignored");
 761                 return 0;
 762         }
 763
 764         if(pGametypeToSet == NULL)
 765                 if(MapInfo_Cache_Retrieve(pFilename))
 766                         return 1;
 767
 768         r = 1;
 769
 770         MapInfo_Map_bspname = pFilename;
 771
 772         // default all generic fields so they have "good" values in case something fails
 773         fn = strcat("maps/", pFilename, ".mapinfo");
 774         fh = fopen(fn, FILE_READ);
 775         if(fh < 0)
 776         {
 777                 fn = strcat("maps/autogenerated/", pFilename, ".mapinfo");
 778                 fh = fopen(fn, FILE_READ);
 779                 if(fh < 0)
 780                 {
 781                         if(!pAllowGenerate)
 782                                 return 0;
 783                         _MapInfo_Map_Reset();
 784                         r = _MapInfo_Generate(pFilename);
 785                         if(!r)
 786                                 return 0;
 787                         fh = fopen(fn, FILE_WRITE);
 788                         fputs(fh, strcat("title ", MapInfo_Map_title, "\n"));
 789                         fputs(fh, strcat("description ", MapInfo_Map_description, "\n"));
 790                         fputs(fh, strcat("author ", MapInfo_Map_author, "\n"));
 791                         if(_MapInfo_Map_worldspawn_music != "")
 792                         {
 793                                 if(
 794                                         substring(_MapInfo_Map_worldspawn_music, strlen(_MapInfo_Map_worldspawn_music) - 4, 4) == ".wav"
 795                                         ||
 796                                         substring(_MapInfo_Map_worldspawn_music, strlen(_MapInfo_Map_worldspawn_music) - 4, 4) == ".ogg"
 797                                 )
 798                                         fputs(fh, strcat("cdtrack ", substring(_MapInfo_Map_worldspawn_music, 0, strlen(_MapInfo_Map_worldspawn_music) - 4), "\n"));
 799                                 else
 800                                         fputs(fh, strcat("cdtrack ", _MapInfo_Map_worldspawn_music, "\n"));
 801                         }
 802                         else
 803                         {
 804                                 n = tokenize_console(cvar_string("g_cdtracks_remaplist"));
 805                                 s = strcat(" ", cvar_string("g_cdtracks_dontusebydefault"), " ");
 806                                 for (;;)
 807                                 {
 808                                         i = floor(random() * n);
 809                                         if(strstrofs(s, strcat(" ", argv(i), " "), 0) < 0)
 810                                                 break;
 811                                 }
 812                                 fputs(fh, strcat("cdtrack ", ftos(i + 1), "\n"));
 813                         }
 814                         if(MapInfo_Map_supportedFeatures & MAPINFO_FEATURE_WEAPONS)
 815                                 fputs(fh, "has weapons\n");
 816                         else
 817                                 fputs(fh, "// uncomment this if you added weapon pickups: has weapons\n");
 818                         if(MapInfo_Map_supportedFeatures & MAPINFO_FEATURE_TURRETS)
 819                                 fputs(fh, "has turrets\n");
 820                         else
 821                                 fputs(fh, "// uncomment this if you added turrets: has turrets\n");
 822                         if(MapInfo_Map_supportedFeatures & MAPINFO_FEATURE_VEHICLES)
 823                                 fputs(fh, "has vehicles\n");
 824                         else
 825                                 fputs(fh, "// uncomment this if you added vehicles: has vehicles\n");
 826                         if(MapInfo_Map_flags & MAPINFO_FLAG_FRUSTRATING)
 827                                 fputs(fh, "frustrating\n");
 828
 829                         FOREACH(Gametypes, MapInfo_Map_supportedGametypes & it.m_flags, {
 830                                 fputs(fh, sprintf("gametype %s // defaults: %s\n", MapInfo_Type_ToString(it), _MapInfo_GetDefaultEx(it)));
 831                         });
 832
 833                         if(fexists(strcat("scripts/", pFilename, ".arena")))
 834                                 fputs(fh, "settemp_for_type all sv_q3acompat_machineshotgunswap 1\n");
 835
 836                         if(fexists(strcat("scripts/", pFilename, ".defi")))
 837                                 fputs(fh, "settemp_for_type all sv_vq3compat 1\n");
 838
 839                         fputs(fh, "// optional: fog density red green blue alpha mindist maxdist\n");
 840                         fputs(fh, "// optional: settemp_for_type (all|gametypename) cvarname value\n");
 841                         fputs(fh, "// optional: clientsettemp_for_type (all|gametypename) cvarname value\n");
 842                         fputs(fh, "// optional: size mins_x mins_y mins_z maxs_x maxs_y maxs_z\n");
 843                         fputs(fh, "// optional: hidden\n");
 844
 845                         fclose(fh);
 846                         r = 2;
 847                         // return r;
 848                         fh = fopen(fn, FILE_READ);
 849                         if(fh < 0)
 850                                 error("... but I just wrote it!");
 851                 }
 852
 853                 if(!autocvar_g_mapinfo_ignore_warnings)
 854                         LOG_WARN("autogenerated mapinfo file ", fn, " has been loaded; please edit that file and move it to maps/", pFilename, ".mapinfo");
 855         }
 856
 857         _MapInfo_Map_Reset();
 858         for (;;)
 859         {
 860                 if (!((s = fgets(fh))))
 861                         break;
 862
 863                 // catch different sorts of comments
 864                 if(s == "")                    // empty lines
 865                         continue;
 866                 if(substring(s, 0, 1) == "#")  // UNIX style
 867                         continue;
 868                 if(substring(s, 0, 2) == "//") // C++ style
 869                         continue;
 870                 if(substring(s, 0, 1) == "_")  // q3map style
 871                         continue;
 872
 873                 p = strstrofs(s, "//", 0);
 874                 if(p >= 0)
 875                         s = substring(s, 0, p);
 876
 877                 t = car(s); s = cdr(s);
 878                 if(t == "title")
 879                         MapInfo_Map_title = s;
 880                 else if(t == "description")
 881                         MapInfo_Map_description = s;
 882                 else if(t == "author")
 883                         MapInfo_Map_author = s;
 884                 else if(t == "has")
 885                 {
 886                         t = car(s); // s = cdr(s);
 887                         if     (t == "weapons") MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_WEAPONS;
 888                         else if(t == "turrets") MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_TURRETS;
 889                         else if(t == "vehicles") MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_VEHICLES;
 890                         else if(t == "monsters") MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_MONSTERS;
 891                         else if(t == "new_toys") MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_WEAPONS;
 892                         else
 893                                 LOG_WARN("Map ", pFilename, " supports unknown feature ", t, ", ignored");
 894                 }
 895                 else if(t == "hidden")
 896                 {
 897                         MapInfo_Map_flags |= MAPINFO_FLAG_HIDDEN;
 898                 }
 899                 else if(t == "forbidden")
 900                 {
 901                         MapInfo_Map_flags |= MAPINFO_FLAG_FORBIDDEN;
 902                 }
 903                 else if(t == "frustrating")
 904                 {
 905                         MapInfo_Map_flags |= MAPINFO_FLAG_FRUSTRATING;
 906                 }
 907                 else if(t == "noautomaplist")
 908                 {
 909                         MapInfo_Map_flags |= MAPINFO_FLAG_NOAUTOMAPLIST;
 910                 }
 911                 else if(t == "gameversion_min")
 912                 {
 913                         if (cvar("gameversion") < stof(s))
 914                                 MapInfo_Map_flags |= MAPINFO_FLAG_NOAUTOMAPLIST;
 915                 }
 916                 else if(t == "type")
 917                 {
 918                         t = car(s); s = cdr(s);
 919                         Gametype f = MapInfo_Type_FromString(t);
 920                         //if(!autocvar_g_mapinfo_ignore_warnings)
 921                                 //LOG_WARN("Map ", pFilename, " contains the legacy 'type' keyword which is deprecated and will be removed in the future. Please migrate the mapinfo file to 'gametype'.");
 922                         if(f)
 923                                 _MapInfo_Map_ApplyGametype (s, pGametypeToSet, f, true);
 924                         else if(!autocvar_g_mapinfo_ignore_warnings)
 925                                 LOG_DEBUG("Map ", pFilename, " supports unknown game type ", t, ", ignored");
 926                 }
 927                 else if(t == "gametype")
 928                 {
 929                         t = car(s); s = cdr(s);
 930                         Gametype f = MapInfo_Type_FromString(t);
 931                         if(f)
 932                                 _MapInfo_Map_ApplyGametypeEx (s, pGametypeToSet, f);
 933                         else if(!autocvar_g_mapinfo_ignore_warnings)
 934                                 LOG_DEBUG("Map ", pFilename, " supports unknown game type ", t, ", ignored");
 935                 }
 936                 else if(t == "size")
 937                 {
 938                         float a, b, c, d, e;
 939                         t = car(s); s = cdr(s); a = stof(t);
 940                         t = car(s); s = cdr(s); b = stof(t);
 941                         t = car(s); s = cdr(s); c = stof(t);
 942                         t = car(s); s = cdr(s); d = stof(t);
 943                         t = car(s); s = cdr(s); e = stof(t);
 944                         if(s == "")
 945                                 LOG_WARN("Map ", pFilename, " contains an incorrect size line (not enough params), syntax: size mins_x mins_y mins_z maxs_x maxs_y maxs_z");
 946                         else
 947                         {
 948                                 t = car(s); s = cdr(s); f = stof(t);
 949                                 if(s != "")
 950                                         LOG_WARN("Map ", pFilename, " contains an incorrect size line (too many params), syntax: size mins_x mins_y mins_z maxs_x maxs_y maxs_z");
 951                                 else
 952                                 {
 953                                         if(a >= d || b >= e || c >= f)
 954                                                 LOG_WARN("Map ", pFilename, " contains an incorrect size line, mins have to be < maxs");
 955                                         else
 956                                         {
 957                                                 MapInfo_Map_mins.x = a;
 958                                                 MapInfo_Map_mins.y = b;
 959                                                 MapInfo_Map_mins.z = c;
 960                                                 MapInfo_Map_maxs.x = d;
 961                                                 MapInfo_Map_maxs.y = e;
 962                                                 MapInfo_Map_maxs.z = f;
 963                                         }
 964                                 }
 965                         }
 966                 }
 967                 else if(t == "settemp_for_type")
 968                 {
 969                         t = car(s); s = cdr(s);
 970                         bool all = t == "all";
 971                         Gametype f = NULL;
 972                         if(all || (f = MapInfo_Type_FromString(t)))
 973                         {
 974                                 if((all ? MAPINFO_TYPE_ALL : f.m_flags) & pGametypeToSet.m_flags)
 975                                 {
 976                                         _MapInfo_Parse_Settemp(pFilename, acl, 0, s, 1);
 977                                 }
 978                         }
 979                         else
 980                         {
 981                                 LOG_DEBUG("Map ", pFilename, " has a setting for unknown game type ", t, ", ignored");
 982                         }
 983                 }
 984                 else if(t == "clientsettemp_for_type")
 985                 {
 986                         t = car(s); s = cdr(s);
 987                         bool all = t == "all";
 988                         Gametype f = NULL;
 989                         if(all || (f = MapInfo_Type_FromString(t)))
 990                         {
 991                                 if((all ? MAPINFO_TYPE_ALL : f.m_flags) & pGametypeToSet.m_flags)
 992                                 {
 993                                         _MapInfo_Parse_Settemp(pFilename, acl, 1, s, 1);
 994                                 }
 995                         }
 996                         else
 997                         {
 998                                 LOG_DEBUG("Map ", pFilename, " has a client setting for unknown game type ", t, ", ignored");
 999                         }
1000                 }
1001                 else if(t == "fog")
1002                 {
1003                         if (!cvar_value_issafe(s))
1004                                 LOG_WARN("Map ", pFilename, " contains a potentially harmful fog setting, ignored");
1005                         else
1006                                 MapInfo_Map_fog = s;
1007                 }
1008                 else if(t == "cdtrack")
1009                 {
1010                         t = car(s); s = cdr(s);
1011                         // We do this only if pGametypeToSet even though this
1012                         // content is theoretically game type independent,
1013                         // because MapInfo_Map_clientstuff contains otherwise
1014                         // game type dependent stuff. That way this value stays
1015                         // empty when not setting a game type to not set any
1016                         // false expectations.
1017                         if(pGametypeToSet)
1018                         {
1019                                 if (!cvar_value_issafe(t))
1020                                         LOG_WARN("Map ", pFilename, " contains a potentially harmful cdtrack, ignored");
1021                                 else
1022                                         MapInfo_Map_clientstuff = strcat(
1023                                                 MapInfo_Map_clientstuff, "cd loop \"", t, "\"\n"
1024                                         );
1025                         }
1026                 }
1027                 else if(!autocvar_g_mapinfo_ignore_warnings)
1028                         LOG_WARN("Map ", pFilename, " provides unknown info item ", t, ", ignored");
1029         }
1030         fclose(fh);
1031
1032         if(MapInfo_Map_title == "<TITLE>")
1033                 MapInfo_Map_titlestring = MapInfo_Map_bspname;
1034         else if(MapInfo_isRedundant(MapInfo_Map_bspname, MapInfo_Map_title))
1035                 MapInfo_Map_titlestring = MapInfo_Map_title;
1036         else
1037                 MapInfo_Map_titlestring = sprintf("%s: %s", MapInfo_Map_bspname, MapInfo_Map_title);
1038
1039         MapInfo_Cache_Store();
1040         if(MapInfo_Map_supportedGametypes != 0)
1041                 return r;
1042         LOG_WARN("Map ", pFilename, " supports no game types, ignored");
1043         return 0;
1044 }
1045 int MapInfo_Get_ByName(string pFilename, float pAllowGenerate, Gametype pGametypeToSet)
1046 {
1047         int r = MapInfo_Get_ByName_NoFallbacks(pFilename, pAllowGenerate, pGametypeToSet);
1048
1049         FOREACH(Gametypes, it.m_isForcedSupported(it), _MapInfo_Map_ApplyGametypeEx("", pGametypeToSet, it));
1050
1051         if(pGametypeToSet)
1052         {
1053                 if(!(MapInfo_Map_supportedGametypes & pGametypeToSet.m_flags))
1054                 {
1055                         error("Can't select the requested game type. This should never happen as the caller should prevent it!\n");
1056                         //_MapInfo_Map_ApplyGametypeEx("", pGametypeToSet, MAPINFO_TYPE_DEATHMATCH);
1057                         //return;
1058                 }
1059         }
1060
1061         return r;
1062 }
1063
1064 float MapInfo_FindName(string s)
1065 {
1066         // if there is exactly one map of prefix s, return it
1067         // if not, return the null string
1068         // note that DP sorts glob results... so I can use a binary search
1069         float l, r, m, cmp;
1070         l = 0;
1071         r = MapInfo_count;
1072         // invariants: r is behind s, l-1 is equal or before
1073         while(l != r)
1074         {
1075                 m = floor((l + r) / 2);
1076                 MapInfo_FindName_match = _MapInfo_GlobItem(MapInfo_FilterList_Lookup(m));
1077                 cmp = strcasecmp(MapInfo_FindName_match, s);
1078                 if(cmp == 0)
1079                         return m; // found and good
1080                 if(cmp < 0)
1081                         l = m + 1; // l-1 is before s
1082                 else
1083                         r = m; // behind s
1084         }
1085         MapInfo_FindName_match = _MapInfo_GlobItem(MapInfo_FilterList_Lookup(l));
1086         MapInfo_FindName_firstResult = l;
1087         // r == l, so: l is behind s, l-1 is before
1088         // SO: if there is any, l is the one with the right prefix
1089         //     and l+1 may be one too
1090         if(l == MapInfo_count)
1091         {
1092                 MapInfo_FindName_match = string_null;
1093                 MapInfo_FindName_firstResult = -1;
1094                 return -1; // no MapInfo_FindName_match, behind last item
1095         }
1096         if(!startsWithNocase(MapInfo_FindName_match, s))
1097         {
1098                 MapInfo_FindName_match = string_null;
1099                 MapInfo_FindName_firstResult = -1;
1100                 return -1; // wrong prefix
1101         }
1102         if(l == MapInfo_count - 1)
1103                 return l; // last one, nothing can follow => unique
1104         if(startsWithNocase(_MapInfo_GlobItem(MapInfo_FilterList_Lookup(l + 1)), s))
1105         {
1106                 MapInfo_FindName_match = string_null;
1107                 return -1; // ambigous MapInfo_FindName_match
1108         }
1109         return l;
1110 }
1111
1112 string MapInfo_FixName(string s)
1113 {
1114         MapInfo_FindName(s);
1115         return MapInfo_FindName_match;
1116 }
1117
1118 int MapInfo_CurrentFeatures()
1119 {
1120         int req = 0;
1121         if(!(cvar("g_lms") || cvar("g_instagib") || cvar("g_overkill") || cvar("g_nix") || cvar("g_weaponarena") || !cvar("g_pickup_items") || cvar("g_race") || cvar("g_cts") || cvar("g_nexball")))
1122                 req |= MAPINFO_FEATURE_WEAPONS;
1123         return req;
1124 }
1125
1126 Gametype MapInfo_CurrentGametype()
1127 {
1128         Gametype prev = Gametypes_from(cvar("gamecfg"));
1129         FOREACH(Gametypes, cvar(it.netname) && it != prev, return it);
1130         return prev ? prev : MAPINFO_TYPE_DEATHMATCH;
1131 }
1132
1133 float _MapInfo_CheckMap(string s, bool gametype_only) // returns 0 if the map can't be played with the current settings, 1 otherwise
1134 {
1135         if(!MapInfo_Get_ByName(s, 1, NULL))
1136                 return 0;
1137         if((MapInfo_Map_supportedGametypes & MapInfo_CurrentGametype().m_flags) == 0)
1138                 return 0;
1139         if (gametype_only)
1140                 return 1;
1141         if((MapInfo_Map_supportedFeatures & MapInfo_CurrentFeatures()) != MapInfo_CurrentFeatures())
1142                 return 0;
1143         return 1;
1144 }
1145
1146 float MapInfo_CheckMap(string s) // returns 0 if the map can't be played with the current settings, 1 otherwise
1147 {
1148         float r;
1149         r = _MapInfo_CheckMap(s, false);
1150         MapInfo_ClearTemps();
1151         return r;
1152 }
1153
1154 void MapInfo_SwitchGameType(Gametype t)
1155 {
1156         FOREACH(Gametypes, true, cvar_set(it.netname, (it == t) ? "1" : "0"));
1157 }
1158
1159 void MapInfo_LoadMap(string s, float reinit)
1160 {
1161         MapInfo_Map_supportedGametypes = 0;
1162         // we shouldn't need this, as LoadMapSettings already fixes the gametype
1163         //if(!MapInfo_CheckMap(s))
1164         //{
1165         //      print("EMERGENCY: can't play the selected map in the given game mode. Falling back to DM.\n");
1166         //      MapInfo_SwitchGameType(MAPINFO_TYPE_DEATHMATCH.m_flags);
1167         //}
1168
1169         LOG_INFO("Switching to map ", s);
1170
1171         cvar_settemp_restore();
1172         if(reinit)
1173                 localcmd(strcat("\nmap ", s, "\n"));
1174         else
1175                 localcmd(strcat("\nchangelevel ", s, "\n"));
1176 }
1177
1178 string MapInfo_ListAllowedMaps(Gametype type, float pRequiredFlags, float pForbiddenFlags)
1179 {
1180         string out;
1181
1182         // to make absolutely sure:
1183         MapInfo_Enumerate();
1184         MapInfo_FilterGametype(type, MapInfo_CurrentFeatures(), pRequiredFlags, pForbiddenFlags, 0);
1185
1186         out = "";
1187         for(float i = 0; i < MapInfo_count; ++i)
1188                 out = strcat(out, " ", _MapInfo_GlobItem(MapInfo_FilterList_Lookup(i)));
1189         return substring(out, 1, strlen(out) - 1);
1190 }
1191
1192 string MapInfo_ListAllAllowedMaps(float pRequiredFlags, float pForbiddenFlags)
1193 {
1194         string out;
1195
1196         // to make absolutely sure:
1197         MapInfo_Enumerate();
1198         _MapInfo_FilterGametype(MAPINFO_TYPE_ALL, 0, pRequiredFlags, pForbiddenFlags, 0);
1199
1200         out = "";
1201         for(float i = 0; i < MapInfo_count; ++i)
1202                 out = strcat(out, " ", _MapInfo_GlobItem(MapInfo_FilterList_Lookup(i)));
1203
1204         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), pRequiredFlags, pForbiddenFlags, 0);
1205
1206         return substring(out, 1, strlen(out) - 1);
1207 }
1208
1209 void MapInfo_LoadMapSettings_SaveGameType(Gametype t)
1210 {
1211         MapInfo_SwitchGameType(t);
1212         cvar_set("gamecfg", ftos(t.m_id));
1213         MapInfo_LoadedGametype = t;
1214 }
1215
1216 void MapInfo_LoadMapSettings(string s) // to be called from worldspawn
1217 {
1218         Gametype t = MapInfo_CurrentGametype();
1219         MapInfo_LoadMapSettings_SaveGameType(t);
1220
1221         if(!_MapInfo_CheckMap(s, true)) // with underscore, it keeps temps
1222         {
1223                 if(cvar("g_mapinfo_allow_unsupported_modes_and_let_stuff_break"))
1224                 {
1225                         LOG_SEVERE("can't play the selected map in the given game mode. Working with only the override settings.");
1226                         _MapInfo_Map_ApplyGametypeEx("", t, t);
1227                         return; // do not call Get_ByName!
1228                 }
1229
1230                 if(MapInfo_Map_supportedGametypes == 0)
1231                 {
1232                         LOG_SEVERE("Mapinfo system is not functional at all. Assuming deathmatch.");
1233                         MapInfo_Map_supportedGametypes = MAPINFO_TYPE_DEATHMATCH.m_flags;
1234                         MapInfo_LoadMapSettings_SaveGameType(MAPINFO_TYPE_DEATHMATCH);
1235                         _MapInfo_Map_ApplyGametypeEx("", MAPINFO_TYPE_DEATHMATCH, MAPINFO_TYPE_DEATHMATCH);
1236                         return; // do not call Get_ByName!
1237                 }
1238
1239                 int _t = 1;
1240                 while(!(MapInfo_Map_supportedGametypes & 1))
1241                 {
1242                         _t <<= 1;
1243                         MapInfo_Map_supportedGametypes = floor(MapInfo_Map_supportedGametypes >> 1);
1244                 }
1245                 Gametype t_prev = t;
1246                 FOREACH(Gametypes, it.m_flags == _t, { t = it; break; });
1247
1248                 // t is now a supported mode!
1249                 LOG_WARNF("can't play the selected map in the given game mode (%s). Falling back to a supported mode (%s).", t_prev.mdl, t.mdl);
1250                 MapInfo_LoadMapSettings_SaveGameType(t);
1251         }
1252         if(!_MapInfo_CheckMap(s, false)) { // with underscore, it keeps temps
1253                 LOG_WARNF("the selected map lacks features required by current settings; playing anyway.");
1254         }
1255         MapInfo_Get_ByName(s, 1, t);
1256 }
1257
1258 void MapInfo_ClearTemps()
1259 {
1260         MapInfo_Map_bspname = string_null;
1261         MapInfo_Map_title = string_null;
1262         MapInfo_Map_titlestring = string_null;
1263         MapInfo_Map_description = string_null;
1264         MapInfo_Map_author = string_null;
1265         MapInfo_Map_clientstuff = string_null;
1266         MapInfo_Map_supportedGametypes = 0;
1267         MapInfo_Map_supportedFeatures = 0;
1268 }
1269
1270 void MapInfo_Shutdown()
1271 {
1272         MapInfo_ClearTemps();
1273         MapInfo_Filter_Free();
1274         MapInfo_Cache_Destroy();
1275         if(_MapInfo_globopen)
1276         {
1277                 search_end(_MapInfo_globhandle);
1278                 _MapInfo_globhandle = -1;
1279                 _MapInfo_globopen = false;
1280         }
1281 }
1282
1283 int MapInfo_ForbiddenFlags()
1284 {
1285         int f = MAPINFO_FLAG_FORBIDDEN;
1286
1287 #ifdef GAMEQC
1288         if (!cvar("g_maplist_allow_hidden"))
1289 #endif
1290                 f |= MAPINFO_FLAG_HIDDEN;
1291
1292         if (!cvar("g_maplist_allow_frustrating"))
1293                 f |= MAPINFO_FLAG_FRUSTRATING;
1294
1295         return f;
1296 }
1297
1298 int MapInfo_RequiredFlags()
1299 {
1300         int f = 0;
1301
1302         if(cvar("g_maplist_allow_frustrating") > 1)
1303                 f |= MAPINFO_FLAG_FRUSTRATING;
1304
1305         return f;
1306 }