qcsrc/common/mapinfo.qc

   1 #include "mapinfo.qh"
   2 #if defined(CSQC)
   3     #include "../client/defs.qh"
   4     #include "util.qh"
   5     #include <common/weapons/_all.qh>
   6 #elif defined(MENUQC)
   7 #elif defined(SVQC)
   8     #include "util.qh"
   9     #include <common/monsters/_mod.qh>
  10 #endif
  11
  12 #ifdef MENUQC
  13 #define WARN_COND false
  14 #else
  15 bool autocvar_g_mapinfo_ignore_warnings;
  16 #define WARN_COND (!autocvar_g_mapinfo_ignore_warnings && MapInfo_Map_bspname == mi_shortname)
  17 #endif
  18
  19 // generic string stuff
  20
  21 int _MapInfo_Cache_Active;
  22 int _MapInfo_Cache_DB_NameToIndex;
  23 int _MapInfo_Cache_Buf_IndexToMapData;
  24
  25 void MapInfo_Cache_Destroy()
  26 {
  27         if(!_MapInfo_Cache_Active)
  28                 return;
  29
  30         db_close(_MapInfo_Cache_DB_NameToIndex);
  31         buf_del(_MapInfo_Cache_Buf_IndexToMapData);
  32         _MapInfo_Cache_Active = 0;
  33 }
  34
  35 void MapInfo_Cache_Create()
  36 {
  37         MapInfo_Cache_Destroy();
  38         _MapInfo_Cache_DB_NameToIndex = db_create();
  39         _MapInfo_Cache_Buf_IndexToMapData = buf_create();
  40         _MapInfo_Cache_Active = 1;
  41 }
  42
  43 void MapInfo_Cache_Invalidate()
  44 {
  45         if(!_MapInfo_Cache_Active)
  46                 return;
  47
  48         MapInfo_Cache_Create();
  49 }
  50
  51 void MapInfo_Cache_Store()
  52 {
  53         float i;
  54         string s;
  55         if(!_MapInfo_Cache_Active)
  56                 return;
  57
  58         s = db_get(_MapInfo_Cache_DB_NameToIndex, MapInfo_Map_bspname);
  59         if(s == "")
  60         {
  61                 i = buf_getsize(_MapInfo_Cache_Buf_IndexToMapData);
  62                 db_put(_MapInfo_Cache_DB_NameToIndex, MapInfo_Map_bspname, ftos(i));
  63         }
  64         else
  65                 i = stof(s);
  66
  67         // now store all the stuff
  68         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData,   i, MapInfo_Map_bspname);
  69         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, MapInfo_Map_title);
  70         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, MapInfo_Map_titlestring);
  71         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, MapInfo_Map_description);
  72         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, MapInfo_Map_author);
  73         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, ftos(MapInfo_Map_supportedGametypes));
  74         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, ftos(MapInfo_Map_supportedFeatures));
  75         bufstr_set(_MapInfo_Cache_Buf_IndexToMapData, ++i, ftos(MapInfo_Map_flags));
  76 }
  77
  78 float MapInfo_Cache_Retrieve(string map)
  79 {
  80         float i;
  81         string s;
  82         if(!_MapInfo_Cache_Active)
  83                 return 0;
  84
  85         s = db_get(_MapInfo_Cache_DB_NameToIndex, map);
  86         if(s == "")
  87                 return 0;
  88         i = stof(s);
  89
  90         // now retrieve all the stuff
  91         MapInfo_Map_bspname = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, i);
  92         MapInfo_Map_title = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i);
  93         MapInfo_Map_titlestring = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i);
  94         MapInfo_Map_description = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i);
  95         MapInfo_Map_author = bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i);
  96         MapInfo_Map_supportedGametypes = stof(bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i));
  97         MapInfo_Map_supportedFeatures = stof(bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i));
  98         MapInfo_Map_flags = stof(bufstr_get(_MapInfo_Cache_Buf_IndexToMapData, ++i));
  99
 100         return 1;
 101 }
 102
 103 // GLOB HANDLING (for all BSP files)
 104 float _MapInfo_globopen;
 105 float _MapInfo_globcount;
 106 float _MapInfo_globhandle;
 107 string _MapInfo_GlobItem(float i)
 108 {
 109         string s;
 110         if(!_MapInfo_globopen)
 111                 return string_null;
 112         s = search_getfilename(_MapInfo_globhandle, i);
 113         return substring(s, 5, strlen(s) - 9); // without maps/ and .bsp
 114 }
 115
 116 void MapInfo_Enumerate()
 117 {
 118         if(_MapInfo_globopen)
 119         {
 120                 search_end(_MapInfo_globhandle);
 121                 _MapInfo_globopen = 0;
 122         }
 123         MapInfo_Cache_Invalidate();
 124         _MapInfo_globhandle = search_begin("maps/*.bsp", true, true);
 125         if(_MapInfo_globhandle >= 0)
 126         {
 127                 _MapInfo_globcount = search_getsize(_MapInfo_globhandle);
 128                 _MapInfo_globopen = 1;
 129         }
 130         else
 131                 _MapInfo_globcount = 0;
 132 }
 133
 134 // filter the info by game type mask (updates MapInfo_count)
 135 //
 136 float _MapInfo_filtered;
 137 float _MapInfo_filtered_allocated;
 138 float MapInfo_FilterList_Lookup(float i)
 139 {
 140         return stof(bufstr_get(_MapInfo_filtered, i));
 141 }
 142
 143 void _MapInfo_FilterList_swap(float i, float j, entity pass)
 144 {
 145         string h;
 146         h = bufstr_get(_MapInfo_filtered, i);
 147         bufstr_set(_MapInfo_filtered, i, bufstr_get(_MapInfo_filtered, j));
 148         bufstr_set(_MapInfo_filtered, j, h);
 149 }
 150
 151 float _MapInfo_FilterList_cmp(float i, float j, entity pass)
 152 {
 153         string a, b;
 154         a = _MapInfo_GlobItem(stof(bufstr_get(_MapInfo_filtered, i)));
 155         b = _MapInfo_GlobItem(stof(bufstr_get(_MapInfo_filtered, j)));
 156         return strcasecmp(a, b);
 157 }
 158
 159 float MapInfo_FilterGametype(Gametype pGametype, int pFeatures, int pFlagsRequired, int pFlagsForbidden, bool pAbortOnGenerate)
 160 {
 161         return _MapInfo_FilterGametype(pGametype.m_flags, pFeatures, pFlagsRequired, pFlagsForbidden, pAbortOnGenerate);
 162 }
 163 float _MapInfo_FilterGametype(int pGametype, int pFeatures, int pFlagsRequired, int pFlagsForbidden, bool pAbortOnGenerate)
 164 {
 165         float i, j;
 166         if (!_MapInfo_filtered_allocated)
 167         {
 168                 _MapInfo_filtered_allocated = 1;
 169                 _MapInfo_filtered = buf_create();
 170         }
 171         MapInfo_count = 0;
 172         for(i = 0, j = -1; i < _MapInfo_globcount; ++i)
 173         {
 174                 if(MapInfo_Get_ByName(_MapInfo_GlobItem(i), 1, NULL) == 2) // if we generated one... BAIL OUT and let the caller continue in the next frame.
 175                         if(pAbortOnGenerate)
 176                         {
 177                                 LOG_TRACE("Autogenerated a .mapinfo, doing the rest later.");
 178                                 MapInfo_progress = i / _MapInfo_globcount;
 179                                 return 0;
 180                         }
 181                 if((MapInfo_Map_supportedGametypes & pGametype) != 0)
 182                 if((MapInfo_Map_supportedFeatures & pFeatures) == pFeatures)
 183                 if((MapInfo_Map_flags & pFlagsForbidden) == 0)
 184                 if((MapInfo_Map_flags & pFlagsRequired) == pFlagsRequired)
 185                         bufstr_set(_MapInfo_filtered, ++j, ftos(i));
 186         }
 187         MapInfo_count = j + 1;
 188         MapInfo_ClearTemps();
 189
 190         // sometimes the glob isn't sorted nicely, so fix it here...
 191         heapsort(MapInfo_count, _MapInfo_FilterList_swap, _MapInfo_FilterList_cmp, NULL);
 192
 193         return 1;
 194 }
 195 void MapInfo_FilterString(string sf)
 196 {
 197         // this function further filters _MapInfo_filtered, which is prepared by MapInfo_FilterGametype by string
 198         float i, j;
 199         string title;
 200
 201         for(i = 0, j = -1; i < MapInfo_count; ++i)
 202         {
 203                 if (MapInfo_Get_ByID(i))
 204                 {
 205                         // prepare for keyword filter
 206                         if (MapInfo_Map_title && strstrofs(MapInfo_Map_title, "<TITLE>", 0) == -1)
 207                                 title = MapInfo_Map_title;
 208                         else
 209                                 title = MapInfo_Map_bspname;
 210                         // keyword filter
 211                         if((strstrofs(strtolower(title), strtolower(sf), 0)) >= 0)
 212                                 bufstr_set(_MapInfo_filtered, ++j, bufstr_get(_MapInfo_filtered, i));
 213                 }
 214         }
 215         MapInfo_count = j + 1;
 216         MapInfo_ClearTemps();
 217
 218         // sometimes the glob isn't sorted nicely, so fix it here...
 219         heapsort(MapInfo_count, _MapInfo_FilterList_swap, _MapInfo_FilterList_cmp, NULL);
 220 }
 221
 222 void MapInfo_Filter_Free()
 223 {
 224         if(_MapInfo_filtered_allocated)
 225         {
 226                 buf_del(_MapInfo_filtered);
 227                 _MapInfo_filtered_allocated = 0;
 228         }
 229 }
 230
 231 // load info about the i-th map into the MapInfo_Map_* globals
 232 string MapInfo_BSPName_ByID(float i)
 233 {
 234         return _MapInfo_GlobItem(MapInfo_FilterList_Lookup(i));
 235 }
 236
 237 string unquote(string s)
 238 {
 239         float l = strlen(s);
 240         for(float i = 0; i < l; ++i)
 241         {
 242                 string ch = substring(s, i, 1);
 243                 if((ch != " ") && (ch != "\""))
 244                 {
 245                         for(float j = l - i - 1; j > 0; --j)
 246                         {
 247                                 ch = substring(s, i+j, 1);
 248                                 if(ch != " ") if(ch != "\"")
 249                                         return substring(s, i, j+1);
 250                         }
 251                         return substring(s, i, 1);
 252                 }
 253         }
 254         return "";
 255 }
 256
 257 float MapInfo_Get_ByID(float i)
 258 {
 259         if(MapInfo_Get_ByName(MapInfo_BSPName_ByID(i), 0, NULL))
 260                 return 1;
 261         return 0;
 262 }
 263
 264 string _MapInfo_Map_worldspawn_music;
 265
 266 float _MapInfo_Generate(string pFilename) // 0: failure, 1: ok ent, 2: ok bsp
 267 {
 268         string fn;
 269         float fh;
 270         string s, k, v;
 271         vector o;
 272         float i;
 273         float inWorldspawn;
 274         float r;
 275         float diameter, spawnpoints;
 276         float spawnplaces;
 277
 278         vector mapMins, mapMaxs;
 279
 280         r = 1;
 281         fn = strcat("maps/", pFilename, ".ent");
 282         fh = fopen(fn, FILE_READ);
 283         if(fh < 0)
 284         {
 285                 r = 2;
 286                 fn = strcat("maps/", pFilename, ".bsp");
 287                 fh = fopen(fn, FILE_READ);
 288         }
 289         if(fh < 0)
 290                 return 0;
 291         LOG_INFO("Analyzing ", fn, " to generate initial mapinfo");
 292
 293         inWorldspawn = 2;
 294         MapInfo_Map_flags = 0;
 295         MapInfo_Map_supportedGametypes = 0;
 296         spawnpoints = 0;
 297         spawnplaces = 0;
 298         _MapInfo_Map_worldspawn_music = "";
 299         mapMins = '0 0 0';
 300         mapMaxs = '0 0 0';
 301
 302         for (;;)
 303         {
 304                 if (!((s = fgets(fh))))
 305                         break;
 306                 if(inWorldspawn == 1)
 307                         if(startsWith(s, "}"))
 308                                 inWorldspawn = 0;
 309                 k = unquote(car(s));
 310                 v = unquote(cdr(s));
 311                 if(inWorldspawn)
 312                 {
 313                         if(k == "classname" && v == "worldspawn")
 314                                 inWorldspawn = 1;
 315                         else if(k == "author")
 316                                 MapInfo_Map_author = v;
 317                         else if(k == "_description")
 318                                 MapInfo_Map_description = v;
 319                         else if(k == "music")
 320                                 _MapInfo_Map_worldspawn_music = v;
 321                         else if(k == "noise")
 322                                 _MapInfo_Map_worldspawn_music = v;
 323                         else if(k == "message")
 324                         {
 325                                 i = strstrofs(v, " by ", 0);
 326                                 if(MapInfo_Map_author == "<AUTHOR>" && i >= 0)
 327                                 {
 328                                         MapInfo_Map_title = substring(v, 0, i);
 329                                         MapInfo_Map_author = substring(v, i + 4, strlen(v) - (i + 4));
 330                                 }
 331                                 else
 332                                         MapInfo_Map_title = v;
 333                         }
 334                 }
 335                 else
 336                 {
 337                         if(k == "origin")
 338                         {
 339                                 o = stov(strcat("'", v, "'"));
 340                                 mapMins.x = min(mapMins.x, o.x);
 341                                 mapMins.y = min(mapMins.y, o.y);
 342                                 mapMins.z = min(mapMins.z, o.z);
 343                                 mapMaxs.x = max(mapMaxs.x, o.x);
 344                                 mapMaxs.y = max(mapMaxs.y, o.y);
 345                                 mapMaxs.z = max(mapMaxs.z, o.z);
 346                         }
 347                         else if(k == "race_place")
 348                         {
 349                                 if(stof(v) > 0)
 350                                         spawnplaces = 1;
 351                         }
 352                         else if(k == "classname")
 353                         {
 354                                 if(v == "info_player_team1")
 355                                         ++spawnpoints;
 356                                 else if(v == "info_player_team2")
 357                                         ++spawnpoints;
 358                                 else if(v == "info_player_start")
 359                                         ++spawnpoints;
 360                                 else if(v == "info_player_deathmatch")
 361                                         ++spawnpoints;
 362                                 else if(v == "weapon_nex")
 363                                         { }
 364                                 else if(v == "weapon_railgun")
 365                                         { }
 366                                 else if(startsWith(v, "weapon_"))
 367                                         MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_WEAPONS;
 368                                 else if(startsWith(v, "turret_"))
 369                                         MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_TURRETS;
 370                                 else if(startsWith(v, "vehicle_"))
 371                                         MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_VEHICLES;
 372                                 else if(startsWith(v, "monster_"))
 373                                         MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_MONSTERS;
 374                                 else if(v == "target_music" || v == "trigger_music")
 375                                         _MapInfo_Map_worldspawn_music = string_null; // don't use regular BGM
 376                                 else
 377                                         FOREACH(Gametypes, true, it.m_generate_mapinfo(it, v));
 378                         }
 379                 }
 380         }
 381         if(inWorldspawn)
 382         {
 383                 LOG_WARN(fn, " ended still in worldspawn, BUG");
 384                 return 0;
 385         }
 386         diameter = vlen(mapMaxs - mapMins);
 387
 388         int twoBaseModes = 0;
 389         FOREACH(Gametypes, it.m_isTwoBaseMode(), twoBaseModes |= it.m_flags);
 390         if(twoBaseModes && (twoBaseModes &= MapInfo_Map_supportedGametypes))
 391         {
 392                 // we have a symmetrical map, don't add the modes without bases
 393         }
 394         else
 395         {
 396                 FOREACH(Gametypes, it.m_isAlwaysSupported(it, spawnpoints, diameter), MapInfo_Map_supportedGametypes |= it.m_flags);
 397         }
 398
 399         if(MapInfo_Map_supportedGametypes & MAPINFO_TYPE_RACE.m_flags)
 400         if(!spawnplaces)
 401         {
 402                 MapInfo_Map_supportedGametypes &= ~MAPINFO_TYPE_RACE.m_flags;
 403                 MapInfo_Map_supportedGametypes |= MAPINFO_TYPE_CTS.m_flags;
 404         }
 405
 406         LOG_TRACE("-> diameter ",    ftos(diameter));
 407         LOG_TRACE(";  spawnpoints ", ftos(spawnpoints));
 408         LOG_TRACE(";  modes ",       ftos(MapInfo_Map_supportedGametypes));
 409
 410         fclose(fh);
 411
 412         return r;
 413 }
 414
 415 void _MapInfo_Map_Reset()
 416 {
 417         MapInfo_Map_title = "<TITLE>";
 418         MapInfo_Map_titlestring = "<TITLE>";
 419         MapInfo_Map_description = "<DESCRIPTION>";
 420         MapInfo_Map_author = "<AUTHOR>";
 421         MapInfo_Map_supportedGametypes = 0;
 422         MapInfo_Map_supportedFeatures = 0;
 423         MapInfo_Map_flags = 0;
 424         MapInfo_Map_clientstuff = "";
 425         MapInfo_Map_fog = "";
 426         MapInfo_Map_mins = '0 0 0';
 427         MapInfo_Map_maxs = '0 0 0';
 428 }
 429
 430 string _MapInfo_GetDefault(Gametype t)
 431 {
 432         return t.m_legacydefaults;
 433 }
 434
 435 void _MapInfo_Map_ApplyGametype(string s, Gametype pWantedType, Gametype pThisType, int load_default)
 436 {
 437         string sa;
 438         MapInfo_Map_supportedGametypes |= pThisType.m_flags;
 439         if(!(pThisType.m_flags & pWantedType.m_flags))
 440                 return;
 441
 442         if(load_default)
 443                 _MapInfo_Map_ApplyGametype(_MapInfo_GetDefault(pThisType), pWantedType, pThisType, false);
 444
 445         if(!pWantedType.frags) // these modes don't use fraglimit
 446         {
 447                 cvar_set("fraglimit", "0");
 448         }
 449         else
 450         {
 451                 sa = car(s);
 452                 if(sa != "")
 453                         cvar_set("fraglimit", sa);
 454                 s = cdr(s);
 455         }
 456
 457         sa = car(s);
 458         if(sa != "")
 459                 cvar_set("timelimit", sa);
 460         s = cdr(s);
 461
 462         if(pWantedType.m_setTeams)
 463         {
 464                 sa = car(s);
 465                 if(sa != "")
 466                         pWantedType.m_setTeams(sa);
 467                 s = cdr(s);
 468         }
 469
 470         // rc = timelimit timelimit_qualification laps laps_teamplay
 471         if(pWantedType == MAPINFO_TYPE_RACE)
 472         {
 473                 cvar_set("fraglimit", "0"); // special case!
 474
 475                 sa = car(s); if(sa == "") sa = cvar_string("timelimit");
 476                 cvar_set("g_race_qualifying_timelimit", sa);
 477                 s = cdr(s);
 478
 479                 sa = car(s);
 480                 if(sa != "")
 481                         if(cvar("g_race_teams") < 2)
 482                                 cvar_set("fraglimit", sa);
 483                 s = cdr(s);
 484
 485                 sa = car(s);
 486                 if(sa != "")
 487                         if(cvar("g_race_teams") >= 2)
 488                                 cvar_set("fraglimit", sa);
 489                 s = cdr(s);
 490         }
 491
 492         if(!pWantedType.frags) // these modes don't use fraglimit
 493         {
 494                 cvar_set("leadlimit", "0");
 495         }
 496         else
 497         {
 498                 sa = car(s);
 499                 if(sa != "")
 500                         cvar_set("leadlimit", sa);
 501                 s = cdr(s);
 502         }
 503 }
 504
 505 string _MapInfo_GetDefaultEx(Gametype t)
 506 {
 507         return t ? t.model2 : "";
 508 }
 509
 510 float _MapInfo_GetTeamPlayBool(Gametype t)
 511 {
 512         return t ? t.team : false;
 513 }
 514
 515 void _MapInfo_Map_ApplyGametypeEx(string s, Gametype pWantedType, Gametype pThisType)
 516 {
 517         MapInfo_Map_supportedGametypes |= pThisType.m_flags;
 518         if (!(pThisType.m_flags & pWantedType.m_flags))
 519                 return;
 520
 521         // reset all the cvars to their defaults
 522
 523         cvar_set("timelimit", cvar_defstring("timelimit"));
 524         cvar_set("leadlimit", cvar_defstring("leadlimit"));
 525         cvar_set("fraglimit", cvar_defstring("fraglimit"));
 526         FOREACH(Gametypes, true, it.m_parse_mapinfo(string_null, string_null));
 527
 528         string fraglimit_normal = string_null;
 529         string fraglimit_teams = string_null;
 530
 531         for (s = strcat(_MapInfo_GetDefaultEx(pWantedType), " ", s); s != ""; s = cdr(s)) {
 532                 string sa = car(s);
 533                 if (sa == "") continue;
 534                 int p = strstrofs(sa, "=", 0);
 535                 if (p < 0) {
 536                         if(WARN_COND)
 537                                 LOG_WARNF("Invalid gametype setting in mapinfo for gametype %s: %s", MapInfo_Type_ToString(pWantedType), sa);
 538                         continue;
 539                 }
 540                 string k = substring(sa, 0, p);
 541                 string v = substring(sa, p + 1, -1);
 542                 bool handled = true;
 543                 switch (k) {
 544                         case "timelimit":
 545                         {
 546                                 cvar_set("timelimit", v);
 547                                 break;
 548                         }
 549                         case "leadlimit":
 550                         {
 551                                 cvar_set("leadlimit", v);
 552                                 break;
 553                         }
 554                         case "pointlimit":
 555                         case "fraglimit":
 556                         case "lives":
 557                         case "laplimit":
 558                         case "caplimit":
 559                         {
 560                                 fraglimit_normal = v;
 561                                 break;
 562                         }
 563                         case "teampointlimit":
 564                         case "teamlaplimit":
 565                         {
 566                                 fraglimit_teams = v;
 567                                 break;
 568                         }
 569                         default:
 570                         {
 571                             handled = false;
 572                             break;
 573                         }
 574                 }
 575                 FOREACH(Gametypes, true, handled |= it.m_parse_mapinfo(k, v));
 576                 if (!handled && WARN_COND)
 577             LOG_WARNF("Invalid gametype setting in mapinfo for gametype %s: %s", MapInfo_Type_ToString(pWantedType), sa);
 578         }
 579
 580         if (pWantedType == MAPINFO_TYPE_RACE && cvar("g_race_teams") >= 2)
 581         {
 582                 if(fraglimit_teams)
 583                         cvar_set("fraglimit", fraglimit_teams);
 584         }
 585         else
 586         {
 587                 if(fraglimit_normal)
 588                         cvar_set("fraglimit", fraglimit_normal);
 589         }
 590 }
 591
 592 Gametype MapInfo_Type_FromString(string gtype)
 593 {
 594         string replacement = "";
 595         switch (gtype)
 596         {
 597                 case "nexball":   replacement = "nb"; break;
 598                 case "freezetag": replacement = "ft"; break;
 599                 case "keepaway":  replacement = "ka"; break;
 600                 case "invasion":  replacement = "inv"; break;
 601                 case "assault":   replacement = "as"; break;
 602                 case "race":      replacement = "rc"; break;
 603         }
 604         if (replacement != "")
 605         {
 606                 if (WARN_COND)
 607                         LOG_WARNF("MapInfo_Type_FromString (probably %s): using deprecated name '%s'. Should use '%s'.", MapInfo_Map_bspname, gtype, replacement);
 608                 gtype = replacement;
 609         }
 610         FOREACH(Gametypes, it.mdl == gtype, return it);
 611         return NULL;
 612 }
 613
 614 string MapInfo_Type_Description(Gametype t)
 615 {
 616         return t ? t.gametype_description : "";
 617 }
 618
 619 string MapInfo_Type_ToString(Gametype t)
 620 {
 621         return t ? t.mdl : "";
 622 }
 623
 624 string MapInfo_Type_ToText(Gametype t)
 625 {
 626         /* xgettext:no-c-format */
 627         return t ? t.message : _("@!#%'n Tuba Throwing");
 628 }
 629
 630 void _MapInfo_Parse_Settemp(string pFilename, string acl, float type, string s, float recurse)
 631 {
 632         string t;
 633         float fh, o;
 634         t = car(s); s = cdr(s);
 635
 636         // limited support of "" and comments
 637         //   remove trailing and leading " of t
 638         if(substring(t, 0, 1) == "\"")
 639         {
 640                 if(substring(t, -1, 1) == "\"")
 641                         t = substring(t, 1, -2);
 642         }
 643
 644         //   remove leading " of s
 645         if(substring(s, 0, 1) == "\"")
 646         {
 647                 s = substring(s, 1, -1);
 648         }
 649         //   remove trailing " of s, and all that follows (cvar description)
 650         o = strstrofs(s, "\"", 0);
 651         if(o >= 0)
 652                 s = substring(s, 0, o);
 653
 654         //   remove // comments
 655         o = strstrofs(s, "//", 0);
 656         if(o >= 0)
 657                 s = substring(s, 0, o);
 658
 659         //   remove trailing spaces
 660         while(substring(s, -1, 1) == " ")
 661                 s = substring(s, 0, -2);
 662
 663         if(t == "#include")
 664         {
 665                 if(recurse > 0)
 666                 {
 667                         fh = fopen(s, FILE_READ);
 668                         if(fh < 0)
 669                         {
 670                                 if(WARN_COND)
 671                                         LOG_WARN("Map ", pFilename, " references not existing config file ", s);
 672                         }
 673                         else
 674                         {
 675                                 while((s = fgets(fh)))
 676                                 {
 677                                         // catch different sorts of comments
 678                                         if(s == "")                    // empty lines
 679                                                 continue;
 680                                         if(substring(s, 0, 1) == "#")  // UNIX style
 681                                                 continue;
 682                                         if(substring(s, 0, 2) == "//") // C++ style
 683                                                 continue;
 684                                         if(substring(s, 0, 1) == "_")  // q3map style
 685                                                 continue;
 686
 687                                         if(substring(s, 0, 4) == "set ")
 688                                                 s = substring(s, 4, -1);
 689                                         if(substring(s, 0, 5) == "seta ")
 690                                                 s = substring(s, 5, -1);
 691
 692                                         _MapInfo_Parse_Settemp(pFilename, acl, type, s, recurse - 1);
 693                                 }
 694                                 fclose(fh);
 695                         }
 696                 }
 697                 else if(WARN_COND)
 698                         LOG_WARN("Map ", pFilename, " uses too many levels of inclusion");
 699         }
 700         else if(t == ""
 701                 || !cvar_value_issafe(t)
 702                 || !cvar_value_issafe(s)
 703                 || matchacl(MAPINFO_SETTEMP_ACL_SYSTEM, t) <= 0)
 704         {
 705                 if (WARN_COND)
 706                         LOG_WARN("Map ", pFilename, " contains a potentially harmful setting, ignored");
 707         }
 708         else if(matchacl(acl, t) <= 0)
 709         {
 710                 if (WARN_COND)
 711                         LOG_WARN("Map ", pFilename, " contains a denied setting, ignored");
 712         }
 713         else
 714         {
 715                 if(type == 0) // server set
 716                 {
 717                         LOG_TRACE("Applying temporary setting ", t, " := ", s);
 718                 #if 0
 719                         if(cvar("g_campaign"))
 720                                 cvar_set(t, s); // this is a wrapper and is always temporary anyway; no need to backup old values then
 721                         else
 722                 #endif
 723                                 cvar_settemp(t, s);
 724                 }
 725                 else
 726                 {
 727                         LOG_TRACE("Applying temporary client setting ", t, " := ", s);
 728                         MapInfo_Map_clientstuff = strcat(
 729                                         MapInfo_Map_clientstuff, "cl_cmd settemp \"", t, "\" \"", s, "\"\n"
 730                                         );
 731                 }
 732         }
 733 }
 734
 735 float MapInfo_isRedundant(string fn, string t)
 736 {
 737         // normalize file name
 738         fn = strreplace("_", "", fn);
 739         fn = strreplace("-", "", fn);
 740
 741         // normalize visible title
 742         t = strreplace(":", "", t);
 743         t = strreplace(" ", "", t);
 744         t = strreplace("_", "", t);
 745         t = strreplace("-", "", t);
 746         t = strreplace("'", "", t);
 747         t = strdecolorize(t);
 748
 749         // we allow the visible title to have punctuation the file name does
 750         // not, but not vice versa
 751         if(!strcasecmp(fn, t))
 752                 return true;
 753
 754         return false;
 755 }
 756
 757 // load info about a map by name into the MapInfo_Map_* globals
 758 float MapInfo_Get_ByName_NoFallbacks(string pFilename, int pAllowGenerate, Gametype pGametypeToSet)
 759 {
 760         string fn;
 761         string s, t;
 762         float fh;
 763         int f, i;
 764         float r, n, p;
 765         string acl;
 766
 767         acl = MAPINFO_SETTEMP_ACL_USER;
 768
 769         if(strstrofs(pFilename, "/", 0) >= 0)
 770         {
 771                 LOG_WARN("Invalid character in map name, ignored");
 772                 return 0;
 773         }
 774
 775         if(pGametypeToSet == NULL)
 776                 if(MapInfo_Cache_Retrieve(pFilename))
 777                         return 1;
 778
 779         r = 1;
 780
 781         MapInfo_Map_bspname = pFilename;
 782
 783         // default all generic fields so they have "good" values in case something fails
 784         fn = strcat("maps/", pFilename, ".mapinfo");
 785         fh = fopen(fn, FILE_READ);
 786         if(fh < 0)
 787         {
 788                 fn = strcat("maps/autogenerated/", pFilename, ".mapinfo");
 789                 fh = fopen(fn, FILE_READ);
 790                 if(fh < 0)
 791                 {
 792                         if(!pAllowGenerate)
 793                                 return 0;
 794                         _MapInfo_Map_Reset();
 795                         r = _MapInfo_Generate(pFilename);
 796                         if(!r)
 797                                 return 0;
 798                         fh = fopen(fn, FILE_WRITE);
 799                         fputs(fh, strcat("title ", MapInfo_Map_title, "\n"));
 800                         fputs(fh, strcat("description ", MapInfo_Map_description, "\n"));
 801                         fputs(fh, strcat("author ", MapInfo_Map_author, "\n"));
 802                         if(_MapInfo_Map_worldspawn_music != "")
 803                         {
 804                                 if(
 805                                         substring(_MapInfo_Map_worldspawn_music, strlen(_MapInfo_Map_worldspawn_music) - 4, 4) == ".wav"
 806                                         ||
 807                                         substring(_MapInfo_Map_worldspawn_music, strlen(_MapInfo_Map_worldspawn_music) - 4, 4) == ".ogg"
 808                                 )
 809                                         fputs(fh, strcat("cdtrack ", substring(_MapInfo_Map_worldspawn_music, 0, strlen(_MapInfo_Map_worldspawn_music) - 4), "\n"));
 810                                 else
 811                                         fputs(fh, strcat("cdtrack ", _MapInfo_Map_worldspawn_music, "\n"));
 812                         }
 813                         else
 814                         {
 815                                 n = tokenize_console(cvar_string("g_cdtracks_remaplist"));
 816                                 s = strcat(" ", cvar_string("g_cdtracks_dontusebydefault"), " ");
 817                                 for (;;)
 818                                 {
 819                                         i = floor(random() * n);
 820                                         if(strstrofs(s, strcat(" ", argv(i), " "), 0) < 0)
 821                                                 break;
 822                                 }
 823                                 fputs(fh, strcat("cdtrack ", ftos(i + 1), "\n"));
 824                         }
 825                         if(MapInfo_Map_supportedFeatures & MAPINFO_FEATURE_WEAPONS)
 826                                 fputs(fh, "has weapons\n");
 827                         else
 828                                 fputs(fh, "// uncomment this if you added weapon pickups: has weapons\n");
 829                         if(MapInfo_Map_supportedFeatures & MAPINFO_FEATURE_TURRETS)
 830                                 fputs(fh, "has turrets\n");
 831                         else
 832                                 fputs(fh, "// uncomment this if you added turrets: has turrets\n");
 833                         if(MapInfo_Map_supportedFeatures & MAPINFO_FEATURE_VEHICLES)
 834                                 fputs(fh, "has vehicles\n");
 835                         else
 836                                 fputs(fh, "// uncomment this if you added vehicles: has vehicles\n");
 837                         if(MapInfo_Map_flags & MAPINFO_FLAG_FRUSTRATING)
 838                                 fputs(fh, "frustrating\n");
 839
 840                         FOREACH(Gametypes, MapInfo_Map_supportedGametypes & it.m_flags, {
 841                                 fputs(fh, sprintf("gametype %s // defaults: %s\n", MapInfo_Type_ToString(it), _MapInfo_GetDefaultEx(it)));
 842                         });
 843
 844                         fputs(fh, "// optional: fog density red green blue alpha mindist maxdist\n");
 845                         fputs(fh, "// optional: settemp_for_type (all|gametypename) cvarname value\n");
 846                         fputs(fh, "// optional: clientsettemp_for_type (all|gametypename) cvarname value\n");
 847                         fputs(fh, "// optional: size mins_x mins_y mins_z maxs_x maxs_y maxs_z\n");
 848                         fputs(fh, "// optional: hidden\n");
 849
 850                         fclose(fh);
 851                         r = 2;
 852                         // return r;
 853                         fh = fopen(fn, FILE_READ);
 854                         if(fh < 0)
 855                                 error("... but I just wrote it!");
 856                 }
 857
 858                 if(WARN_COND)
 859                         LOG_WARN("autogenerated mapinfo file ", fn, " has been loaded; please edit that file and move it to maps/", pFilename, ".mapinfo");
 860         }
 861
 862         _MapInfo_Map_Reset();
 863         for (;;)
 864         {
 865                 if (!((s = fgets(fh))))
 866                         break;
 867
 868                 // catch different sorts of comments
 869                 if(s == "")                    // empty lines
 870                         continue;
 871                 if(substring(s, 0, 1) == "#")  // UNIX style
 872                         continue;
 873                 if(substring(s, 0, 2) == "//") // C++ style
 874                         continue;
 875                 if(substring(s, 0, 1) == "_")  // q3map style
 876                         continue;
 877
 878                 p = strstrofs(s, "//", 0);
 879                 if(p >= 0)
 880                         s = substring(s, 0, p);
 881
 882                 t = car(s); s = cdr(s);
 883                 if(t == "title")
 884                         MapInfo_Map_title = s;
 885                 else if(t == "description")
 886                         MapInfo_Map_description = s;
 887                 else if(t == "author")
 888                         MapInfo_Map_author = s;
 889                 else if(t == "has")
 890                 {
 891                         t = car(s); // s = cdr(s);
 892                         if     (t == "weapons") MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_WEAPONS;
 893                         else if(t == "turrets") MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_TURRETS;
 894                         else if(t == "vehicles") MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_VEHICLES;
 895                         else if(t == "monsters") MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_MONSTERS;
 896                         else if(t == "new_toys") MapInfo_Map_supportedFeatures |= MAPINFO_FEATURE_WEAPONS;
 897                         else if(WARN_COND)
 898                                 LOG_WARN("Map ", pFilename, " supports unknown feature ", t, ", ignored");
 899                 }
 900                 else if(t == "hidden")
 901                 {
 902                         MapInfo_Map_flags |= MAPINFO_FLAG_HIDDEN;
 903                 }
 904                 else if(t == "forbidden")
 905                 {
 906                         MapInfo_Map_flags |= MAPINFO_FLAG_FORBIDDEN;
 907                 }
 908                 else if(t == "frustrating")
 909                 {
 910                         MapInfo_Map_flags |= MAPINFO_FLAG_FRUSTRATING;
 911                 }
 912                 else if(t == "noautomaplist")
 913                 {
 914                         MapInfo_Map_flags |= MAPINFO_FLAG_NOAUTOMAPLIST;
 915                 }
 916                 else if(t == "gameversion_min")
 917                 {
 918                         if (cvar("gameversion") < stof(s))
 919                                 MapInfo_Map_flags |= MAPINFO_FLAG_NOAUTOMAPLIST;
 920                 }
 921                 else if(t == "type")
 922                 {
 923                         t = car(s); s = cdr(s);
 924                         Gametype f = MapInfo_Type_FromString(t);
 925                         //if(WARN_COND)
 926                                 //LOG_WARN("Map ", pFilename, " contains the legacy 'type' keyword which is deprecated and will be removed in the future. Please migrate the mapinfo file to 'gametype'.");
 927                         if(f)
 928                                 _MapInfo_Map_ApplyGametype (s, pGametypeToSet, f, true);
 929                         else if(WARN_COND)
 930                                 LOG_DEBUG("Map ", pFilename, " supports unknown game type ", t, ", ignored");
 931                 }
 932                 else if(t == "gametype")
 933                 {
 934                         t = car(s); s = cdr(s);
 935                         Gametype f = MapInfo_Type_FromString(t);
 936                         if(f)
 937                                 _MapInfo_Map_ApplyGametypeEx (s, pGametypeToSet, f);
 938                         else if(WARN_COND)
 939                                 LOG_DEBUG("Map ", pFilename, " supports unknown game type ", t, ", ignored");
 940                 }
 941                 else if(t == "size")
 942                 {
 943                         float a, b, c, d, e;
 944                         t = car(s); s = cdr(s); a = stof(t);
 945                         t = car(s); s = cdr(s); b = stof(t);
 946                         t = car(s); s = cdr(s); c = stof(t);
 947                         t = car(s); s = cdr(s); d = stof(t);
 948                         t = car(s); s = cdr(s); e = stof(t);
 949                         if(s == "")
 950                         {
 951                                 if(WARN_COND)
 952                                         LOG_WARN("Map ", pFilename, " contains an incorrect size line (not enough params), syntax: size mins_x mins_y mins_z maxs_x maxs_y maxs_z");
 953                         }
 954                         else
 955                         {
 956                                 t = car(s); s = cdr(s); f = stof(t);
 957                                 if(s != "")
 958                                 {
 959                                         if(WARN_COND)
 960                                                 LOG_WARN("Map ", pFilename, " contains an incorrect size line (too many params), syntax: size mins_x mins_y mins_z maxs_x maxs_y maxs_z");
 961                                 }
 962                                 else
 963                                 {
 964                                         if(a >= d || b >= e || c >= f)
 965                                         {
 966                                                 if(WARN_COND)
 967                                                         LOG_WARN("Map ", pFilename, " contains an incorrect size line, mins have to be < maxs");
 968                                         }
 969                                         else
 970                                         {
 971                                                 MapInfo_Map_mins.x = a;
 972                                                 MapInfo_Map_mins.y = b;
 973                                                 MapInfo_Map_mins.z = c;
 974                                                 MapInfo_Map_maxs.x = d;
 975                                                 MapInfo_Map_maxs.y = e;
 976                                                 MapInfo_Map_maxs.z = f;
 977                                         }
 978                                 }
 979                         }
 980                 }
 981                 else if(t == "settemp_for_type")
 982                 {
 983                         t = car(s); s = cdr(s);
 984                         bool all = t == "all";
 985                         Gametype f = NULL;
 986                         if(all || (f = MapInfo_Type_FromString(t)))
 987                         {
 988                                 if((all ? MAPINFO_TYPE_ALL : f.m_flags) & pGametypeToSet.m_flags)
 989                                 {
 990                                         _MapInfo_Parse_Settemp(pFilename, acl, 0, s, 1);
 991                                 }
 992                         }
 993                         else
 994                         {
 995                                 LOG_DEBUG("Map ", pFilename, " has a setting for unknown game type ", t, ", ignored");
 996                         }
 997                 }
 998                 else if(t == "clientsettemp_for_type")
 999                 {
1000                         t = car(s); s = cdr(s);
1001                         bool all = t == "all";
1002                         Gametype f = NULL;
1003                         if(all || (f = MapInfo_Type_FromString(t)))
1004                         {
1005                                 if((all ? MAPINFO_TYPE_ALL : f.m_flags) & pGametypeToSet.m_flags)
1006                                 {
1007                                         _MapInfo_Parse_Settemp(pFilename, acl, 1, s, 1);
1008                                 }
1009                         }
1010                         else
1011                         {
1012                                 LOG_DEBUG("Map ", pFilename, " has a client setting for unknown game type ", t, ", ignored");
1013                         }
1014                 }
1015                 else if(t == "fog")
1016                 {
1017                         if (!cvar_value_issafe(s))
1018                         {
1019                                 if(WARN_COND)
1020                                         LOG_WARN("Map ", pFilename, " contains a potentially harmful fog setting, ignored");
1021                         }
1022                         else
1023                                 MapInfo_Map_fog = s;
1024                 }
1025                 else if(t == "cdtrack")
1026                 {
1027                         t = car(s); s = cdr(s);
1028                         // We do this only if pGametypeToSet even though this
1029                         // content is theoretically game type independent,
1030                         // because MapInfo_Map_clientstuff contains otherwise
1031                         // game type dependent stuff. That way this value stays
1032                         // empty when not setting a game type to not set any
1033                         // false expectations.
1034                         if(pGametypeToSet)
1035                         {
1036                                 if (!cvar_value_issafe(t))
1037                                 {
1038                                         if(WARN_COND)
1039                                                 LOG_WARN("Map ", pFilename, " contains a potentially harmful cdtrack, ignored");
1040                                 }
1041                                 else
1042                                         MapInfo_Map_clientstuff = strcat(
1043                                                 MapInfo_Map_clientstuff, "cd loop \"", t, "\"\n"
1044                                         );
1045                         }
1046                 }
1047                 else if(WARN_COND)
1048                         LOG_WARN("Map ", pFilename, " provides unknown info item ", t, ", ignored");
1049         }
1050         fclose(fh);
1051
1052         if(MapInfo_Map_title == "<TITLE>")
1053                 MapInfo_Map_titlestring = MapInfo_Map_bspname;
1054         else if(MapInfo_isRedundant(MapInfo_Map_bspname, MapInfo_Map_title))
1055                 MapInfo_Map_titlestring = MapInfo_Map_title;
1056         else
1057                 MapInfo_Map_titlestring = sprintf("%s: %s", MapInfo_Map_bspname, MapInfo_Map_title);
1058
1059         MapInfo_Cache_Store();
1060         if(MapInfo_Map_supportedGametypes != 0)
1061                 return r;
1062         if (WARN_COND)
1063                 LOG_WARN("Map ", pFilename, " supports no game types, ignored");
1064         return 0;
1065 }
1066 int MapInfo_Get_ByName(string pFilename, float pAllowGenerate, Gametype pGametypeToSet)
1067 {
1068         int r = MapInfo_Get_ByName_NoFallbacks(pFilename, pAllowGenerate, pGametypeToSet);
1069
1070         FOREACH(Gametypes, it.m_isForcedSupported(it), _MapInfo_Map_ApplyGametypeEx("", pGametypeToSet, it));
1071
1072         if(pGametypeToSet)
1073         {
1074                 if(!(MapInfo_Map_supportedGametypes & pGametypeToSet.m_flags))
1075                 {
1076                         error("Can't select the requested game type. This should never happen as the caller should prevent it!\n");
1077                         //_MapInfo_Map_ApplyGametypeEx("", pGametypeToSet, MAPINFO_TYPE_DEATHMATCH);
1078                         //return;
1079                 }
1080         }
1081
1082         return r;
1083 }
1084
1085 float MapInfo_FindName(string s)
1086 {
1087         // if there is exactly one map of prefix s, return it
1088         // if not, return the null string
1089         // note that DP sorts glob results... so I can use a binary search
1090         float l, r, m, cmp;
1091         l = 0;
1092         r = MapInfo_count;
1093         // invariants: r is behind s, l-1 is equal or before
1094         while(l != r)
1095         {
1096                 m = floor((l + r) / 2);
1097                 MapInfo_FindName_match = _MapInfo_GlobItem(MapInfo_FilterList_Lookup(m));
1098                 cmp = strcasecmp(MapInfo_FindName_match, s);
1099                 if(cmp == 0)
1100                         return m; // found and good
1101                 if(cmp < 0)
1102                         l = m + 1; // l-1 is before s
1103                 else
1104                         r = m; // behind s
1105         }
1106         MapInfo_FindName_match = _MapInfo_GlobItem(MapInfo_FilterList_Lookup(l));
1107         MapInfo_FindName_firstResult = l;
1108         // r == l, so: l is behind s, l-1 is before
1109         // SO: if there is any, l is the one with the right prefix
1110         //     and l+1 may be one too
1111         if(l == MapInfo_count)
1112         {
1113                 MapInfo_FindName_match = string_null;
1114                 MapInfo_FindName_firstResult = -1;
1115                 return -1; // no MapInfo_FindName_match, behind last item
1116         }
1117         if(!startsWithNocase(MapInfo_FindName_match, s))
1118         {
1119                 MapInfo_FindName_match = string_null;
1120                 MapInfo_FindName_firstResult = -1;
1121                 return -1; // wrong prefix
1122         }
1123         if(l == MapInfo_count - 1)
1124                 return l; // last one, nothing can follow => unique
1125         if(startsWithNocase(_MapInfo_GlobItem(MapInfo_FilterList_Lookup(l + 1)), s))
1126         {
1127                 MapInfo_FindName_match = string_null;
1128                 return -1; // ambigous MapInfo_FindName_match
1129         }
1130         return l;
1131 }
1132
1133 string MapInfo_FixName(string s)
1134 {
1135         MapInfo_FindName(s);
1136         return MapInfo_FindName_match;
1137 }
1138
1139 int MapInfo_CurrentFeatures()
1140 {
1141         int req = 0;
1142     // TODO: find a better way to check if weapons are required on the map
1143         if(!(cvar("g_instagib") || cvar("g_overkill") || cvar("g_nix") || cvar("g_weaponarena") || !cvar("g_pickup_items")
1144                 || cvar("g_race") || cvar("g_cts") || cvar("g_nexball") || cvar("g_ca") || cvar("g_freezetag") || cvar("g_lms")))
1145                 req |= MAPINFO_FEATURE_WEAPONS;
1146         return req;
1147 }
1148
1149 Gametype MapInfo_CurrentGametype()
1150 {
1151         Gametype prev = REGISTRY_GET(Gametypes, cvar("gamecfg"));
1152         FOREACH(Gametypes, cvar(it.netname) && it != prev, return it);
1153         return prev ? prev : MAPINFO_TYPE_DEATHMATCH;
1154 }
1155
1156 float _MapInfo_CheckMap(string s, bool gametype_only) // returns 0 if the map can't be played with the current settings, 1 otherwise
1157 {
1158         if(!MapInfo_Get_ByName(s, 1, NULL))
1159                 return 0;
1160         if((MapInfo_Map_supportedGametypes & MapInfo_CurrentGametype().m_flags) == 0)
1161                 return 0;
1162         if (gametype_only)
1163                 return 1;
1164         if((MapInfo_Map_supportedFeatures & MapInfo_CurrentFeatures()) != MapInfo_CurrentFeatures())
1165                 return 0;
1166         return 1;
1167 }
1168
1169 float MapInfo_CheckMap(string s) // returns 0 if the map can't be played with the current settings, 1 otherwise
1170 {
1171         float r;
1172         r = _MapInfo_CheckMap(s, false);
1173         MapInfo_ClearTemps();
1174         return r;
1175 }
1176
1177 void MapInfo_SwitchGameType(Gametype t)
1178 {
1179         FOREACH(Gametypes, true, cvar_set(it.netname, (it == t) ? "1" : "0"));
1180 }
1181
1182 void MapInfo_LoadMap(string s, float reinit)
1183 {
1184         MapInfo_Map_supportedGametypes = 0;
1185         // we shouldn't need this, as LoadMapSettings already fixes the gametype
1186         //if(!MapInfo_CheckMap(s))
1187         //{
1188         //      print("EMERGENCY: can't play the selected map in the given game mode. Falling back to DM.\n");
1189         //      MapInfo_SwitchGameType(MAPINFO_TYPE_DEATHMATCH.m_flags);
1190         //}
1191
1192         LOG_INFO("Switching to map ", s);
1193
1194         cvar_settemp_restore();
1195         if(reinit)
1196                 localcmd(strcat("\nmap ", s, "\n"));
1197         else
1198                 localcmd(strcat("\nchangelevel ", s, "\n"));
1199 }
1200
1201 string MapInfo_ListAllowedMaps(Gametype type, float pRequiredFlags, float pForbiddenFlags)
1202 {
1203         string out;
1204
1205         // to make absolutely sure:
1206         MapInfo_Enumerate();
1207         MapInfo_FilterGametype(type, MapInfo_CurrentFeatures(), pRequiredFlags, pForbiddenFlags, 0);
1208
1209         out = "";
1210         for(float i = 0; i < MapInfo_count; ++i)
1211                 out = strcat(out, " ", _MapInfo_GlobItem(MapInfo_FilterList_Lookup(i)));
1212         return substring(out, 1, strlen(out) - 1);
1213 }
1214
1215 string MapInfo_ListAllAllowedMaps(float pRequiredFlags, float pForbiddenFlags)
1216 {
1217         string out;
1218
1219         // to make absolutely sure:
1220         MapInfo_Enumerate();
1221         _MapInfo_FilterGametype(MAPINFO_TYPE_ALL, 0, pRequiredFlags, pForbiddenFlags, 0);
1222
1223         out = "";
1224         for(float i = 0; i < MapInfo_count; ++i)
1225                 out = strcat(out, " ", _MapInfo_GlobItem(MapInfo_FilterList_Lookup(i)));
1226
1227         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), pRequiredFlags, pForbiddenFlags, 0);
1228
1229         return substring(out, 1, strlen(out) - 1);
1230 }
1231
1232 void MapInfo_LoadMapSettings_SaveGameType(Gametype t)
1233 {
1234         MapInfo_SwitchGameType(t);
1235         cvar_set("gamecfg", ftos(t.m_id));
1236         MapInfo_LoadedGametype = t;
1237 }
1238
1239 void MapInfo_LoadMapSettings(string s) // to be called from worldspawn
1240 {
1241         Gametype t = MapInfo_CurrentGametype();
1242         MapInfo_LoadMapSettings_SaveGameType(t);
1243
1244         if(!_MapInfo_CheckMap(s, true)) // with underscore, it keeps temps
1245         {
1246                 if(cvar("g_mapinfo_allow_unsupported_modes_and_let_stuff_break"))
1247                 {
1248                         LOG_SEVERE("can't play the selected map in the given game mode. Working with only the override settings.");
1249                         _MapInfo_Map_ApplyGametypeEx("", t, t);
1250                         return; // do not call Get_ByName!
1251                 }
1252
1253                 if(MapInfo_Map_supportedGametypes == 0)
1254                 {
1255                         LOG_SEVERE("Mapinfo system is not functional at all. Assuming deathmatch.");
1256                         MapInfo_Map_supportedGametypes = MAPINFO_TYPE_DEATHMATCH.m_flags;
1257                         MapInfo_LoadMapSettings_SaveGameType(MAPINFO_TYPE_DEATHMATCH);
1258                         _MapInfo_Map_ApplyGametypeEx("", MAPINFO_TYPE_DEATHMATCH, MAPINFO_TYPE_DEATHMATCH);
1259                         return; // do not call Get_ByName!
1260                 }
1261
1262                 int _t = 1;
1263                 while(!(MapInfo_Map_supportedGametypes & 1))
1264                 {
1265                         _t <<= 1;
1266                         MapInfo_Map_supportedGametypes = floor(MapInfo_Map_supportedGametypes >> 1);
1267                 }
1268                 Gametype t_prev = t;
1269                 FOREACH(Gametypes, it.m_flags == _t, { t = it; break; });
1270
1271                 // t is now a supported mode!
1272                 LOG_WARNF("can't play the selected map in the given game mode (%s). Falling back to a supported mode (%s).", t_prev.mdl, t.mdl);
1273                 MapInfo_LoadMapSettings_SaveGameType(t);
1274         }
1275         if(!_MapInfo_CheckMap(s, false)) { // with underscore, it keeps temps
1276                 LOG_WARNF("the selected map lacks features required by current settings; playing anyway.");
1277         }
1278         MapInfo_Get_ByName(s, 1, t);
1279 }
1280
1281 void MapInfo_ClearTemps()
1282 {
1283         MapInfo_Map_bspname = string_null;
1284         MapInfo_Map_title = string_null;
1285         MapInfo_Map_titlestring = string_null;
1286         MapInfo_Map_description = string_null;
1287         MapInfo_Map_author = string_null;
1288         MapInfo_Map_clientstuff = string_null;
1289         MapInfo_Map_supportedGametypes = 0;
1290         MapInfo_Map_supportedFeatures = 0;
1291 }
1292
1293 void MapInfo_Shutdown()
1294 {
1295         MapInfo_ClearTemps();
1296         MapInfo_Filter_Free();
1297         MapInfo_Cache_Destroy();
1298         if(_MapInfo_globopen)
1299         {
1300                 search_end(_MapInfo_globhandle);
1301                 _MapInfo_globhandle = -1;
1302                 _MapInfo_globopen = false;
1303         }
1304 }
1305
1306 int MapInfo_ForbiddenFlags()
1307 {
1308         int f = MAPINFO_FLAG_FORBIDDEN;
1309
1310 #ifdef GAMEQC
1311         if (!cvar("g_maplist_allow_hidden"))
1312 #endif
1313                 f |= MAPINFO_FLAG_HIDDEN;
1314
1315         if (!cvar("g_maplist_allow_frustrating"))
1316                 f |= MAPINFO_FLAG_FRUSTRATING;
1317
1318         return f;
1319 }
1320
1321 int MapInfo_RequiredFlags()
1322 {
1323         int f = 0;
1324
1325         if(cvar("g_maplist_allow_frustrating") > 1)
1326                 f |= MAPINFO_FLAG_FRUSTRATING;
1327
1328         return f;
1329 }