qcsrc/common/mapinfo.qh

   1 #pragma once
   2
   3 bool autocvar_developer_mapper;
   4
   5 #define LOG_MAPWARN(...) MACRO_BEGIN { if (autocvar_developer_mapper) LOG_WARN(__VA_ARGS__); } MACRO_END
   6 #define LOG_MAPWARNF(...) MACRO_BEGIN { if (autocvar_developer_mapper) LOG_WARNF(__VA_ARGS__); } MACRO_END
   7
   8 #include "util.qh"
   9
  10 // info about a map that MapInfo loads
  11 string MapInfo_Map_bspname;
  12 string MapInfo_Map_title;
  13 string MapInfo_Map_titlestring; // either bspname: title or just title, depending on whether bspname is redundant
  14 string MapInfo_Map_description;
  15 string MapInfo_Map_author;
  16 string MapInfo_Map_clientstuff; // not in cache, only for map load
  17 string MapInfo_Map_fog; // not in cache, only for map load
  18 int MapInfo_Map_supportedGametypes;
  19 int MapInfo_Map_supportedFeatures;
  20 int MapInfo_Map_flags;
  21 vector MapInfo_Map_mins; // these are '0 0 0' if not supported!
  22 vector MapInfo_Map_maxs; // these are '0 0 0' if not specified!
  23
  24 int MAPINFO_TYPE_ALL;
  25 .int m_flags;
  26
  27 CLASS(Gametype, Object)
  28     ATTRIB(Gametype, m_id, int, 0);
  29     /** game type ID */
  30     ATTRIB(Gametype, items, int, 0);
  31     /** game type name as in cvar (with g_ prefix) */
  32     ATTRIB(Gametype, netname, string);
  33     /** game type short name */
  34     ATTRIB(Gametype, mdl, string);
  35     /** human readable name */
  36     ATTRIB(Gametype, message, string);
  37     /** does this gametype support teamplay? */
  38     ATTRIB(Gametype, team, bool, false);
  39     /** game type defaults */
  40     ATTRIB(Gametype, model2, string);
  41     /** game type description */
  42     ATTRIB(Gametype, gametype_description, string);
  43 #ifdef CSQC
  44     ATTRIB(Gametype, m_modicons, void(vector pos, vector mySize));
  45     ATTRIB(Gametype, m_modicons_reset, void());
  46 #endif
  47
  48     ATTRIB(Gametype, m_mutators, string);
  49     METHOD(Gametype, m_parse_mapinfo, bool(string k, string v))
  50     {
  51         return false;
  52     }
  53     METHOD(Gametype, m_generate_mapinfo, void(Gametype this, string v))
  54     {
  55         TC(Gametype, this);
  56     }
  57     METHOD(Gametype, m_isTwoBaseMode, bool())
  58     {
  59         return false;
  60     }
  61     METHOD(Gametype, m_isAlwaysSupported, bool(Gametype this, int spawnpoints, float diameter))
  62     {
  63         return false;
  64     }
  65
  66     METHOD(Gametype, describe, string(Gametype this))
  67     {
  68         TC(Gametype, this);
  69         return this.gametype_description;
  70     }
  71
  72     METHOD(Gametype, display, void(Gametype this, void(string name, string icon) returns))
  73     {
  74         TC(Gametype, this);
  75         returns(this.message, strcat("gametype_", this.mdl));
  76     }
  77
  78     METHOD(Gametype, gametype_init, void(Gametype this, string hname, string sname, string g_name, bool gteamplay, string mutators, string defaults, string gdescription))
  79     {
  80         this.netname = g_name;
  81         this.mdl = sname;
  82         this.message = hname;
  83         this.team = gteamplay;
  84         this.m_mutators = cons(sname, mutators);
  85         this.model2 = defaults;
  86         this.gametype_description = gdescription;
  87
  88         // same as `1 << m_id`
  89         MAPINFO_TYPE_ALL |= this.items = this.m_flags = (MAPINFO_TYPE_ALL + 1);
  90     }
  91 ENDCLASS(Gametype)
  92
  93 REGISTRY(Gametypes, 24)
  94 #define Gametypes_from(i) _Gametypes_from(i, NULL)
  95 REGISTER_REGISTRY(Gametypes)
  96 REGISTRY_CHECK(Gametypes)
  97 #define REGISTER_GAMETYPE(NAME, inst) REGISTER(Gametypes, MAPINFO_TYPE, NAME, m_id, inst)
  98
  99 #define IS_GAMETYPE(NAME) (MapInfo_LoadedGametype == MAPINFO_TYPE_##NAME)
 100
 101 CLASS(Deathmatch, Gametype)
 102     INIT(Deathmatch)
 103     {
 104         this.gametype_init(this, _("Deathmatch"),"dm","g_dm",false,"","timelimit=20 pointlimit=30 leadlimit=0",_("Score as many frags as you can"));
 105     }
 106     METHOD(Deathmatch, m_isAlwaysSupported, bool(Gametype this, int spawnpoints, float diameter))
 107     {
 108         return true;
 109     }
 110 ENDCLASS(Deathmatch)
 111 REGISTER_GAMETYPE(DEATHMATCH, NEW(Deathmatch));
 112
 113 CLASS(LastManStanding, Gametype)
 114     INIT(LastManStanding)
 115     {
 116         this.gametype_init(this, _("Last Man Standing"),"lms","g_lms",false,"","timelimit=20 lives=9 leadlimit=0",_("Survive and kill until the enemies have no lives left"));
 117     }
 118     METHOD(LastManStanding, m_isAlwaysSupported, bool(Gametype this, int spawnpoints, float diameter))
 119     {
 120         return true;
 121     }
 122 ENDCLASS(LastManStanding)
 123 REGISTER_GAMETYPE(LMS, NEW(LastManStanding));
 124
 125 #ifdef CSQC
 126 void HUD_Mod_Race(vector pos, vector mySize);
 127 #endif
 128 CLASS(Race, Gametype)
 129     INIT(Race)
 130     {
 131         this.gametype_init(this, _("Race"),"rc","g_race",false,"","timelimit=20 qualifying_timelimit=5 laplimit=7 teamlaplimit=15 leadlimit=0",_("Race against other players to the finish line"));
 132     }
 133     METHOD(Race, m_parse_mapinfo, bool(string k, string v))
 134     {
 135         if (!k) {
 136             cvar_set("g_race_qualifying_timelimit", cvar_defstring("g_race_qualifying_timelimit"));
 137             return true;
 138         }
 139         switch (k) {
 140             case "qualifying_timelimit":
 141                 cvar_set("g_race_qualifying_timelimit", v);
 142                 return true;
 143         }
 144         return false;
 145     }
 146     METHOD(Race, m_generate_mapinfo, void(Gametype this, string v))
 147     {
 148         if(v == "trigger_race_checkpoint")
 149             MapInfo_Map_supportedGametypes |= this.m_flags;
 150     }
 151     METHOD(Race, m_isTwoBaseMode, bool())
 152     {
 153         return true;
 154     }
 155 #ifdef CSQC
 156     ATTRIB(Race, m_modicons, void(vector pos, vector mySize), HUD_Mod_Race);
 157 #endif
 158 ENDCLASS(Race)
 159 REGISTER_GAMETYPE(RACE, NEW(Race));
 160 #define g_race IS_GAMETYPE(RACE)
 161
 162 CLASS(RaceCTS, Gametype)
 163     INIT(RaceCTS)
 164     {
 165         this.gametype_init(this, _("Race CTS"),"cts","g_cts",false,"cloaked","timelimit=20",_("Race for fastest time."));
 166     }
 167     METHOD(RaceCTS, m_generate_mapinfo, void(Gametype this, string v))
 168     {
 169         if(v == "target_startTimer")
 170             MapInfo_Map_supportedGametypes |= this.m_flags;
 171     }
 172     METHOD(RaceCTS, m_setTeams, void(string sa))
 173     {
 174         // this is the skill of the map
 175         // not parsed by anything yet
 176         // for map databases
 177         //  cvar_set("fraglimit", sa);
 178     }
 179 #ifdef CSQC
 180     ATTRIB(RaceCTS, m_modicons, void(vector pos, vector mySize), HUD_Mod_Race);
 181 #endif
 182 ENDCLASS(RaceCTS)
 183 REGISTER_GAMETYPE(CTS, NEW(RaceCTS));
 184 #define g_cts IS_GAMETYPE(CTS)
 185
 186 CLASS(TeamDeathmatch, Gametype)
 187     INIT(TeamDeathmatch)
 188     {
 189         this.gametype_init(this, _("Team Deathmatch"),"tdm","g_tdm",true,"","timelimit=20 pointlimit=50 teams=2 leadlimit=0",_("Help your team score the most frags against the enemy team"));
 190     }
 191     METHOD(TeamDeathmatch, m_parse_mapinfo, bool(string k, string v))
 192     {
 193         if (!k) {
 194             cvar_set("g_tdm_teams", cvar_defstring("g_tdm_teams"));
 195             return true;
 196         }
 197         switch (k) {
 198             case "teams":
 199                 cvar_set("g_tdm_teams", v);
 200                 return true;
 201         }
 202         return false;
 203     }
 204     METHOD(TeamDeathmatch, m_isAlwaysSupported, bool(Gametype this, int spawnpoints, float diameter))
 205     {
 206         if(spawnpoints >= 8 && diameter > 4096)
 207             return true;
 208         return false;
 209     }
 210     METHOD(TeamDeathmatch, m_setTeams, void(string sa))
 211     {
 212         cvar_set("g_tdm_teams", sa);
 213     }
 214 ENDCLASS(TeamDeathmatch)
 215 REGISTER_GAMETYPE(TEAM_DEATHMATCH, NEW(TeamDeathmatch));
 216 #define g_tdm IS_GAMETYPE(TEAM_DEATHMATCH)
 217
 218 #ifdef CSQC
 219 void HUD_Mod_CTF(vector pos, vector mySize);
 220 void HUD_Mod_CTF_Reset();
 221 #endif
 222 CLASS(CaptureTheFlag, Gametype)
 223     INIT(CaptureTheFlag)
 224     {
 225         this.gametype_init(this, _("Capture the Flag"),"ctf","g_ctf",true,"","timelimit=20 caplimit=10 leadlimit=6",_("Find and bring the enemy flag to your base to capture it, defend your base from the other team"));
 226     }
 227     METHOD(CaptureTheFlag, m_generate_mapinfo, void(Gametype this, string v))
 228     {
 229         if(v == "item_flag_team2" || v == "team_CTF_blueflag")
 230             MapInfo_Map_supportedGametypes |= this.m_flags;
 231     }
 232     METHOD(CaptureTheFlag, m_isTwoBaseMode, bool())
 233     {
 234         return true;
 235     }
 236     METHOD(CaptureTheFlag, m_setTeams, void(string sa))
 237     {
 238         cvar_set("fraglimit", sa);
 239     }
 240 #ifdef CSQC
 241     ATTRIB(CaptureTheFlag, m_modicons, void(vector pos, vector mySize), HUD_Mod_CTF);
 242     ATTRIB(CaptureTheFlag, m_modicons_reset, void(), HUD_Mod_CTF_Reset);
 243 #endif
 244 ENDCLASS(CaptureTheFlag)
 245 REGISTER_GAMETYPE(CTF, NEW(CaptureTheFlag));
 246 #define g_ctf IS_GAMETYPE(CTF)
 247
 248 #ifdef CSQC
 249 void HUD_Mod_CA(vector pos, vector mySize);
 250 #endif
 251 CLASS(ClanArena, Gametype)
 252     INIT(ClanArena)
 253     {
 254         this.gametype_init(this, _("Clan Arena"),"ca","g_ca",true,"","timelimit=20 pointlimit=10 teams=2 leadlimit=0",_("Kill all enemy teammates to win the round"));
 255     }
 256     METHOD(ClanArena, m_parse_mapinfo, bool(string k, string v))
 257     {
 258         if (!k) {
 259             cvar_set("g_ca_teams", cvar_defstring("g_ca_teams"));
 260             return true;
 261         }
 262         switch (k) {
 263             case "teams":
 264                 cvar_set("g_ca_teams", v);
 265                 return true;
 266         }
 267         return false;
 268     }
 269     METHOD(ClanArena, m_isAlwaysSupported, bool(Gametype this, int spawnpoints, float diameter))
 270     {
 271         if(spawnpoints >= 8 && diameter > 4096)
 272             return true;
 273         return false;
 274     }
 275     METHOD(ClanArena, m_setTeams, void(string sa))
 276     {
 277         cvar_set("g_ca_teams", sa);
 278     }
 279 #ifdef CSQC
 280     ATTRIB(ClanArena, m_modicons, void(vector pos, vector mySize), HUD_Mod_CA);
 281 #endif
 282 ENDCLASS(ClanArena)
 283 REGISTER_GAMETYPE(CA, NEW(ClanArena));
 284 #define g_ca IS_GAMETYPE(CA)
 285
 286 #ifdef CSQC
 287 void HUD_Mod_Dom(vector pos, vector mySize);
 288 #endif
 289 CLASS(Domination, Gametype)
 290     INIT(Domination)
 291     {
 292         this.gametype_init(this, _("Domination"),"dom","g_domination",true,"","timelimit=20 pointlimit=200 teams=2 leadlimit=0",_("Capture and defend all the control points to win"));
 293     }
 294     METHOD(Domination, m_parse_mapinfo, bool(string k, string v))
 295     {
 296         if (!k) {
 297             cvar_set("g_domination_default_teams", cvar_defstring("g_domination_default_teams"));
 298             return true;
 299         }
 300         switch (k) {
 301             case "teams":
 302                 cvar_set("g_domination_default_teams", v);
 303                 return true;
 304         }
 305         return false;
 306     }
 307     METHOD(Domination, m_generate_mapinfo, void(Gametype this, string v))
 308     {
 309         if(v == "dom_controlpoint")
 310             MapInfo_Map_supportedGametypes |= this.m_flags;
 311     }
 312 #ifdef CSQC
 313     ATTRIB(Domination, m_modicons, void(vector pos, vector mySize), HUD_Mod_Dom);
 314 #endif
 315 ENDCLASS(Domination)
 316 REGISTER_GAMETYPE(DOMINATION, NEW(Domination));
 317
 318 #ifdef CSQC
 319 void HUD_Mod_KH(vector pos, vector mySize);
 320 #endif
 321 CLASS(KeyHunt, Gametype)
 322     INIT(KeyHunt)
 323     {
 324         this.gametype_init(this, _("Key Hunt"),"kh","g_keyhunt",true,"","timelimit=20 pointlimit=1000 teams=3 leadlimit=0",_("Gather all the keys to win the round"));
 325     }
 326     METHOD(KeyHunt, m_parse_mapinfo, bool(string k, string v))
 327     {
 328         if (!k) {
 329             cvar_set("g_keyhunt_teams", cvar_defstring("g_keyhunt_teams"));
 330             return true;
 331         }
 332         switch (k) {
 333             case "teams":
 334                 cvar_set("g_keyhunt_teams", v);
 335                 return true;
 336         }
 337         return false;
 338     }
 339     METHOD(KeyHunt, m_isAlwaysSupported, bool(Gametype this, int spawnpoints, float diameter))
 340     {
 341         if(spawnpoints >= 12 && diameter > 5120)
 342             return true;
 343         return false;
 344     }
 345     METHOD(KeyHunt, m_setTeams, void(string sa))
 346     {
 347         cvar_set("g_keyhunt_teams", sa);
 348     }
 349 #ifdef CSQC
 350     ATTRIB(KeyHunt, m_modicons, void(vector pos, vector mySize), HUD_Mod_KH);
 351 #endif
 352 ENDCLASS(KeyHunt)
 353 REGISTER_GAMETYPE(KEYHUNT, NEW(KeyHunt));
 354
 355 CLASS(Assault, Gametype)
 356     INIT(Assault)
 357     {
 358         this.gametype_init(this, _("Assault"),"as","g_assault",true,"","timelimit=20",_("Destroy obstacles to find and destroy the enemy power core before time runs out"));
 359     }
 360     METHOD(Assault, m_generate_mapinfo, void(Gametype this, string v))
 361     {
 362         if(v == "target_assault_roundend")
 363             MapInfo_Map_supportedGametypes |= this.m_flags;
 364     }
 365     METHOD(Assault, m_isTwoBaseMode, bool())
 366     {
 367         return true;
 368     }
 369 ENDCLASS(Assault)
 370 REGISTER_GAMETYPE(ASSAULT, NEW(Assault));
 371 #define g_assault IS_GAMETYPE(ASSAULT)
 372
 373 CLASS(Onslaught, Gametype)
 374     INIT(Onslaught)
 375     {
 376         this.gametype_init(this, _("Onslaught"),"ons","g_onslaught",true,"","pointlimit=1 timelimit=20",_("Capture control points to reach and destroy the enemy generator"));
 377     }
 378     METHOD(Onslaught, m_generate_mapinfo, void(Gametype this, string v))
 379     {
 380         if(v == "onslaught_generator")
 381             MapInfo_Map_supportedGametypes |= this.m_flags;
 382     }
 383 ENDCLASS(Onslaught)
 384 REGISTER_GAMETYPE(ONSLAUGHT, NEW(Onslaught));
 385
 386 #ifdef CSQC
 387 void HUD_Mod_NexBall(vector pos, vector mySize);
 388 #endif
 389 CLASS(NexBall, Gametype)
 390     INIT(NexBall)
 391     {
 392         this.gametype_init(this, _("Nexball"),"nb","g_nexball",true,"","timelimit=20 pointlimit=5 leadlimit=0",_("Shoot and kick the ball into the enemies goal, keep your goal clean"));
 393     }
 394     METHOD(NexBall, m_generate_mapinfo, void(Gametype this, string v))
 395     {
 396         if(substring(v, 0, 8) == "nexball_" || substring(v, 0, 4) == "ball")
 397             MapInfo_Map_supportedGametypes |= this.m_flags;
 398     }
 399     METHOD(NexBall, m_isTwoBaseMode, bool())
 400     {
 401         return true;
 402     }
 403 #ifdef CSQC
 404     ATTRIB(NexBall, m_modicons, void(vector pos, vector mySize), HUD_Mod_NexBall);
 405 #endif
 406 ENDCLASS(NexBall)
 407 REGISTER_GAMETYPE(NEXBALL, NEW(NexBall));
 408 #define g_nexball IS_GAMETYPE(NEXBALL)
 409
 410 CLASS(FreezeTag, Gametype)
 411     INIT(FreezeTag)
 412     {
 413         this.gametype_init(this, _("Freeze Tag"),"ft","g_freezetag",true,"","timelimit=20 pointlimit=10 teams=2 leadlimit=0",_("Kill enemies to freeze them, stand next to teammates to revive them, freeze the most enemies to win"));
 414     }
 415     METHOD(FreezeTag, m_parse_mapinfo, bool(string k, string v))
 416     {
 417         if (!k) {
 418             cvar_set("g_freezetag_teams", cvar_defstring("g_freezetag_teams"));
 419             return true;
 420         }
 421         switch (k) {
 422             case "teams":
 423                 cvar_set("g_freezetag_teams", v);
 424                 return true;
 425         }
 426         return false;
 427     }
 428     METHOD(FreezeTag, m_isAlwaysSupported, bool(Gametype this, int spawnpoints, float diameter))
 429     {
 430         if(spawnpoints >= 8 && diameter > 4096)
 431             return true;
 432         return false;
 433     }
 434     METHOD(FreezeTag, m_setTeams, void(string sa))
 435     {
 436         cvar_set("g_freezetag_teams", sa);
 437     }
 438 #ifdef CSQC
 439     ATTRIB(FreezeTag, m_modicons, void(vector pos, vector mySize), HUD_Mod_CA);
 440 #endif
 441 ENDCLASS(FreezeTag)
 442 REGISTER_GAMETYPE(FREEZETAG, NEW(FreezeTag));
 443 #define g_freezetag IS_GAMETYPE(FREEZETAG)
 444
 445 #ifdef CSQC
 446 void HUD_Mod_Keepaway(vector pos, vector mySize);
 447 #endif
 448 CLASS(Keepaway, Gametype)
 449     INIT(Keepaway)
 450     {
 451         this.gametype_init(this, _("Keepaway"),"ka","g_keepaway",true,"","timelimit=20 pointlimit=30",_("Hold the ball to get points for kills"));
 452     }
 453     METHOD(Keepaway, m_isAlwaysSupported, bool(Gametype this, int spawnpoints, float diameter))
 454     {
 455         return true;
 456     }
 457 #ifdef CSQC
 458     ATTRIB(Keepaway, m_modicons, void(vector pos, vector mySize), HUD_Mod_Keepaway);
 459 #endif
 460 ENDCLASS(Keepaway)
 461 REGISTER_GAMETYPE(KEEPAWAY, NEW(Keepaway));
 462
 463 CLASS(Invasion, Gametype)
 464     INIT(Invasion)
 465     {
 466         this.gametype_init(this, _("Invasion"),"inv","g_invasion",false,"","pointlimit=50 teams=0",_("Survive against waves of monsters"));
 467     }
 468     METHOD(Invasion, m_parse_mapinfo, bool(string k, string v))
 469     {
 470         switch (k) {
 471             case "teams":
 472                 cvar_set("g_invasion_teams", v);
 473                 return true;
 474         }
 475         return false;
 476     }
 477     METHOD(Invasion, m_generate_mapinfo, void(Gametype this, string v))
 478     {
 479         if(v == "invasion_spawnpoint")
 480             MapInfo_Map_supportedGametypes |= this.m_flags;
 481     }
 482 ENDCLASS(Invasion)
 483 REGISTER_GAMETYPE(INVASION, NEW(Invasion));
 484
 485 const int MAPINFO_FEATURE_WEAPONS       = 1; // not defined for instagib-only maps
 486 const int MAPINFO_FEATURE_VEHICLES      = 2;
 487 const int MAPINFO_FEATURE_TURRETS       = 4;
 488 const int MAPINFO_FEATURE_MONSTERS      = 8;
 489
 490 const int MAPINFO_FLAG_HIDDEN           = 1; // not in lsmaps/menu/vcall/etc., can just be changed to manually
 491 const int MAPINFO_FLAG_FORBIDDEN        = 2; // don't even allow the map by a cvar setting that allows hidden maps
 492 const int MAPINFO_FLAG_FRUSTRATING      = 4; // this map is near impossible to play, enable at your own risk
 493 const int MAPINFO_FLAG_NOAUTOMAPLIST    = 8; // do not include when automatically building maplist (counts as hidden for maplist building purposes)
 494
 495 float MapInfo_count;
 496
 497 // load MapInfo_count; generate mapinfo for maps that miss them, and clear the
 498 // cache; you need to call MapInfo_FilterGametype afterwards!
 499 void MapInfo_Enumerate();
 500
 501 // filter the info by game type mask (updates MapInfo_count)
 502 float MapInfo_progress;
 503 float MapInfo_FilterGametype(Gametype gametypeFlags, float features, float pFlagsRequired, float pFlagsForbidden, float pAbortOnGenerate); // 1 on success, 0 on temporary failure (call it again next frame then; use MapInfo_progress as progress indicator)
 504 float _MapInfo_FilterGametype(int gametypeFlags, float features, float pFlagsRequired, float pFlagsForbidden, float pAbortOnGenerate); // 1 on success, 0 on temporary failure (call it again next frame then; use MapInfo_progress as progress indicator)
 505 void MapInfo_FilterString(string sf); // filter _MapInfo_filtered (created by MapInfo_FilterGametype) with keyword
 506 int MapInfo_CurrentFeatures(); // retrieves currently required features from cvars
 507 Gametype MapInfo_CurrentGametype(); // retrieves current gametype from cvars
 508 int MapInfo_ForbiddenFlags(); // retrieves current flags from cvars
 509 int MapInfo_RequiredFlags(); // retrieves current flags from cvars
 510
 511 // load info about the i-th map into the MapInfo_Map_* globals
 512 float MapInfo_Get_ByID(float i); // 1 on success, 0 on failure
 513 string MapInfo_BSPName_ByID(float i);
 514
 515 // load info about a map by name into the MapInfo_Map_* globals
 516 int MapInfo_Get_ByName(string s, float allowGenerate, Gametype gametypeToSet); // 1 on success, 0 on failure, 2 if it autogenerated a mapinfo file
 517
 518 // look for a map by a prefix, returns the actual map name on success, string_null on failure or ambigous match
 519 string MapInfo_FindName_match; // the name of the map that was found
 520 float MapInfo_FindName_firstResult; // -1 if none were found, index of first one if not unique but found (FindName then returns -1)
 521 float MapInfo_FindName(string s);
 522 string MapInfo_FixName(string s);
 523
 524 // play a map
 525 float MapInfo_CheckMap(string s); // returns 0 if the map can't be played with the current settings
 526 void MapInfo_LoadMap(string s, float reinit);
 527
 528 // list all maps for the current game type
 529 string MapInfo_ListAllowedMaps(Gametype type, float pFlagsRequired, float pFlagsForbidden);
 530 // list all allowed maps (for any game type)
 531 string MapInfo_ListAllAllowedMaps(float pFlagsRequired, float pFlagsForbidden);
 532
 533 // gets a gametype from a string
 534 string _MapInfo_GetDefaultEx(Gametype t);
 535 float _MapInfo_GetTeamPlayBool(Gametype t);
 536 Gametype MapInfo_Type_FromString(string t);
 537 string MapInfo_Type_Description(Gametype t);
 538 string MapInfo_Type_ToString(Gametype t);
 539 string MapInfo_Type_ToText(Gametype t);
 540 void MapInfo_SwitchGameType(Gametype t);
 541
 542 // to be called from worldspawn to set up cvars
 543 void MapInfo_LoadMapSettings(string s);
 544 Gametype MapInfo_LoadedGametype; // game type that was active during map load
 545
 546 void MapInfo_Cache_Destroy(); // disable caching
 547 void MapInfo_Cache_Create(); // enable caching
 548 void MapInfo_Cache_Invalidate(); // delete cache if any, but keep enabled
 549
 550 void MapInfo_ClearTemps(); // call this when done with mapinfo for this frame
 551
 552 void MapInfo_Shutdown(); // call this in the shutdown handler
 553
 554 #define MAPINFO_SETTEMP_ACL_USER cvar_string("g_mapinfo_settemp_acl")
 555 #define MAPINFO_SETTEMP_ACL_SYSTEM "-g_mapinfo_* -rcon_* -_* -g_ban* +*"