Don't respawn frozen non-players when touching the void
[xonotic/xonotic-data.pk3dir.git] / qcsrc / common / mapobjects / trigger / jumppads.qc
1 #include "jumppads.qh"
2 // TODO: split target_push and put it in the target folder
3 #ifdef SVQC
4 #include <common/physics/movetypes/movetypes.qh>
5
6 void trigger_push_use(entity this, entity actor, entity trigger)
7 {
8         if(teamplay)
9         {
10                 this.team = actor.team;
11                 this.SendFlags |= SF_TRIGGER_UPDATE;
12         }
13 }
14 #endif
15
16 REGISTER_NET_LINKED(ENT_CLIENT_TRIGGER_PUSH)
17 REGISTER_NET_LINKED(ENT_CLIENT_TARGET_PUSH)
18
19 /*
20         trigger_push_calculatevelocity
21
22         Arguments:
23           org - origin of the object which is to be pushed
24           tgt - target entity (can be either a point or a model entity; if it is
25                 the latter, its midpoint is used)
26           ht  - jump height, measured from the higher one of org and tgt's midpoint
27           pushed_entity - object that is to be pushed
28
29         Returns: velocity for the jump
30  */
31 vector trigger_push_calculatevelocity(vector org, entity tgt, float ht, entity pushed_entity)
32 {
33         float grav, sdist, zdist, vs, vz, jumpheight;
34         vector sdir, torg;
35
36         torg = tgt.origin + (tgt.mins + tgt.maxs) * 0.5;
37
38         grav = PHYS_GRAVITY(NULL);
39         if(pushed_entity && PHYS_ENTGRAVITY(pushed_entity))
40                 grav *= PHYS_ENTGRAVITY(pushed_entity);
41
42         zdist = torg.z - org.z;
43         sdist = vlen(torg - org - zdist * '0 0 1');
44         sdir = normalize(torg - org - zdist * '0 0 1');
45
46         // how high do we need to push the player?
47         jumpheight = fabs(ht);
48         if(zdist > 0)
49                 jumpheight = jumpheight + zdist;
50
51         /*
52                 STOP.
53
54                 You will not understand the following equations anyway...
55                 But here is what I did to get them.
56
57                 I used the functions
58
59                   s(t) = t * vs
60                   z(t) = t * vz - 1/2 grav t^2
61
62                 and solved for:
63
64                   s(ti) = sdist
65                   z(ti) = zdist
66                   max(z, ti) = jumpheight
67
68                 From these three equations, you will find the three parameters vs, vz
69                 and ti.
70          */
71
72         // push him so high...
73         vz = sqrt(fabs(2 * grav * jumpheight)); // NOTE: sqrt(positive)!
74
75         // we start with downwards velocity only if it's a downjump and the jump apex should be outside the jump!
76         if(ht < 0)
77                 if(zdist < 0)
78                         vz = -vz;
79
80         vector solution;
81         solution = solve_quadratic(0.5 * grav, -vz, zdist); // equation "z(ti) = zdist"
82         // ALWAYS solvable because jumpheight >= zdist
83         if(!solution.z)
84                 solution_y = solution.x; // just in case it is not solvable due to roundoff errors, assume two equal solutions at their center (this is mainly for the usual case with ht == 0)
85         if(zdist == 0)
86                 solution_x = solution.y; // solution_x is 0 in this case, so don't use it, but rather use solution_y (which will be sqrt(0.5 * jumpheight / grav), actually)
87
88         float flighttime;
89         if(zdist < 0)
90         {
91                 // down-jump
92                 if(ht < 0)
93                 {
94                         // almost straight line type
95                         // jump apex is before the jump
96                         // we must take the larger one
97                         flighttime = solution.y;
98                 }
99                 else
100                 {
101                         // regular jump
102                         // jump apex is during the jump
103                         // we must take the larger one too
104                         flighttime = solution.y;
105                 }
106         }
107         else
108         {
109                 // up-jump
110                 if(ht < 0)
111                 {
112                         // almost straight line type
113                         // jump apex is after the jump
114                         // we must take the smaller one
115                         flighttime = solution.x;
116                 }
117                 else
118                 {
119                         // regular jump
120                         // jump apex is during the jump
121                         // we must take the larger one
122                         flighttime = solution.y;
123                 }
124         }
125         vs = sdist / flighttime;
126
127         // finally calculate the velocity
128         return sdir * vs + '0 0 1' * vz;
129 }
130
131 bool jumppad_push(entity this, entity targ)
132 {
133         if (!isPushable(targ))
134                 return false;
135
136         vector org = targ.origin;
137 #ifdef SVQC
138         if(autocvar_sv_vq3compat)
139 #elif defined(CSQC)
140         if(STAT(VQ3COMPAT))
141 #endif
142         {
143                 org.z += targ.mins_z;
144                 org.z += 1; // off by 1!
145         }
146
147         if(this.enemy)
148         {
149                 targ.velocity = trigger_push_calculatevelocity(org, this.enemy, this.height, targ);
150         }
151         else if(this.target && this.target != "")
152         {
153                 entity e;
154                 RandomSelection_Init();
155                 for(e = NULL; (e = find(e, targetname, this.target)); )
156                 {
157                         if(e.cnt)
158                                 RandomSelection_AddEnt(e, e.cnt, 1);
159                         else
160                                 RandomSelection_AddEnt(e, 1, 1);
161                 }
162                 targ.velocity = trigger_push_calculatevelocity(org, RandomSelection_chosen_ent, this.height, targ);
163         }
164         else
165         {
166                 targ.velocity = this.movedir;
167         }
168
169         UNSET_ONGROUND(targ);
170
171 #ifdef CSQC
172         if (targ.flags & FL_PROJECTILE)
173         {
174                 targ.angles = vectoangles (targ.velocity);
175                 switch(targ.move_movetype)
176                 {
177                         case MOVETYPE_FLY:
178                                 set_movetype(targ, MOVETYPE_TOSS);
179                                 targ.gravity = 1;
180                                 break;
181                         case MOVETYPE_BOUNCEMISSILE:
182                                 set_movetype(targ, MOVETYPE_BOUNCE);
183                                 targ.gravity = 1;
184                                 break;
185                 }
186         }
187 #endif
188
189 #ifdef SVQC
190         if (IS_PLAYER(targ))
191         {
192                 // reset tracking of oldvelocity for impact damage (sudden velocity changes)
193                 targ.oldvelocity = targ.velocity;
194
195                 if(this.pushltime < time)  // prevent "snorring" sound when a player hits the jumppad more than once
196                 {
197                         // flash when activated
198                         Send_Effect(EFFECT_JUMPPAD, targ.origin, targ.velocity, 1);
199                         _sound (targ, CH_TRIGGER, this.noise, VOL_BASE, ATTEN_NORM);
200                         this.pushltime = time + 0.2;
201                 }
202                 if(IS_REAL_CLIENT(targ) || IS_BOT_CLIENT(targ))
203                 {
204                         bool found = false;
205                         for(int i = 0; i < targ.jumppadcount && i < NUM_JUMPPADSUSED; ++i)
206                                 if(targ.(jumppadsused[i]) == this)
207                                         found = true;
208                         if(!found)
209                         {
210                                 targ.(jumppadsused[targ.jumppadcount % NUM_JUMPPADSUSED]) = this;
211                                 targ.jumppadcount = targ.jumppadcount + 1;
212                         }
213
214                         if(IS_REAL_CLIENT(targ))
215                         {
216                                 if(this.message)
217                                         centerprint(targ, this.message);
218                         }
219                         else
220                         {
221                                 targ.lastteleporttime = time;
222                                 targ.lastteleport_origin = targ.origin;
223                         }
224
225                         if (!IS_DEAD(targ))
226                                 animdecide_setaction(targ, ANIMACTION_JUMP, true);
227                 }
228                 else
229                         targ.jumppadcount = 1;
230
231                 // reset tracking of who pushed you into a hazard (for kill credit)
232                 targ.pushltime = 0;
233                 targ.istypefrag = 0;
234         }
235
236         if(this.enemy.target)
237                 SUB_UseTargets(this.enemy, targ, this);
238
239         if (targ.flags & FL_PROJECTILE)
240         {
241                 targ.angles = vectoangles (targ.velocity);
242                 targ.com_phys_gravity_factor = 1;
243                 switch(targ.move_movetype)
244                 {
245                         case MOVETYPE_FLY:
246                                 set_movetype(targ, MOVETYPE_TOSS);
247                                 targ.gravity = 1;
248                                 break;
249                         case MOVETYPE_BOUNCEMISSILE:
250                                 set_movetype(targ, MOVETYPE_BOUNCE);
251                                 targ.gravity = 1;
252                                 break;
253                 }
254                 UpdateCSQCProjectile(targ);
255         }
256 #endif
257
258         return true;
259 }
260
261 void trigger_push_touch(entity this, entity toucher)
262 {
263         if (this.active == ACTIVE_NOT)
264                 return;
265
266         if(this.team)
267                 if(((this.spawnflags & INVERT_TEAMS) == 0) == (DIFF_TEAM(this, toucher)))
268                         return;
269
270         EXACTTRIGGER_TOUCH(this, toucher);
271
272         noref bool success = jumppad_push(this, toucher);
273
274 #ifdef SVQC
275         if (success && (this.spawnflags & PUSH_ONCE))
276         {
277                 settouch(this, func_null);
278                 setthink(this, SUB_Remove);
279                 this.nextthink = time;
280         }
281 #endif
282 }
283
284 #ifdef SVQC
285 void trigger_push_link(entity this);
286 void trigger_push_updatelink(entity this);
287 bool trigger_push_testorigin(entity tracetest_ent, entity targ, entity jp, vector org)
288 {
289         setorigin(tracetest_ent, org);
290         tracetoss(tracetest_ent, tracetest_ent);
291         if(trace_startsolid)
292                 return false;
293
294         if (!jp.height)
295         {
296                 // since tracetoss starting from jumppad's origin often fails when target
297                 // is very close to real destination, start it directly from target's
298                 // origin instead
299                 vector ofs = '0 0 0';
300                 if (vdist(vec2(tracetest_ent.velocity), <, autocvar_sv_maxspeed))
301                         ofs = stepheightvec;
302
303                 tracetest_ent.velocity.z = 0;
304                 setorigin(tracetest_ent, targ.origin + ofs);
305                 tracetoss(tracetest_ent, tracetest_ent);
306                 if (trace_startsolid && ofs.z)
307                 {
308                         setorigin(tracetest_ent, targ.origin + ofs / 2);
309                         tracetoss(tracetest_ent, tracetest_ent);
310                         if (trace_startsolid && ofs.z)
311                         {
312                                 setorigin(tracetest_ent, targ.origin);
313                                 tracetoss(tracetest_ent, tracetest_ent);
314                                 if (trace_startsolid)
315                                         return false;
316                         }
317                 }
318         }
319         tracebox(trace_endpos, tracetest_ent.mins, tracetest_ent.maxs, trace_endpos - eZ * 1500, true, tracetest_ent);
320         return true;
321 }
322
323 bool trigger_push_testorigin_for_item(entity tracetest_ent, entity item, vector org)
324 {
325         setorigin(tracetest_ent, org);
326         tracetoss(tracetest_ent, tracetest_ent);
327
328         if(trace_startsolid)
329                 return false;
330         if (trace_ent == item)
331                 return true;
332
333         tracebox(trace_endpos, tracetest_ent.mins, tracetest_ent.maxs, trace_endpos - eZ * 1500, true, tracetest_ent);
334
335         if (trace_ent == item)
336                 return true;
337
338         return false;
339 }
340 #endif
341
342 /// if (item != NULL) returns true if the item can be reached by using this jumppad, false otherwise
343 /// if (item == NULL) tests jumppad's trajectory and eventually spawns waypoints for it (return value doesn't matter)
344 bool trigger_push_test(entity this, entity item)
345 {
346         // first calculate a typical start point for the jump
347         vector org = (this.absmin + this.absmax) * 0.5;
348         org.z = this.absmax.z - PL_MIN_CONST.z - 7;
349
350         if (this.target)
351         {
352                 int n = 0;
353 #ifdef SVQC
354                 vector vel = '0 0 0';
355 #endif
356                 for(entity t = NULL; (t = find(t, targetname, this.target)); )
357                 {
358                         ++n;
359 #ifdef SVQC
360                         if(t.move_movetype != MOVETYPE_NONE)
361                                 continue;
362
363                         entity e = spawn();
364                         setsize(e, PL_MIN_CONST, PL_MAX_CONST);
365                         e.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP | DPCONTENTS_BOTCLIP;
366                         e.velocity = trigger_push_calculatevelocity(org, t, this.height, e);
367
368                         vel = e.velocity;
369                         vector best_target = '0 0 0';
370                         vector best_org = '0 0 0';
371                         vector best_vel = '0 0 0';
372                         bool valid_best_target = false;
373                         if (item)
374                         {
375                                 if (!trigger_push_testorigin_for_item(e, item, org))
376                                 {
377                                         delete(e);
378                                         return false;
379                                 }
380                         }
381                         else
382                         {
383                                 if (trigger_push_testorigin(e, t, this, org))
384                                 {
385                                         best_target = trace_endpos;
386                                         best_org = org;
387                                         best_vel = e.velocity;
388                                         valid_best_target = true;
389                                 }
390                         }
391
392                         vector new_org;
393                         vector dist = t.origin - org;
394                         if (dist.x || dist.y) // if not perfectly vertical
395                         {
396                                 // test trajectory with different starting points, sometimes the trajectory
397                                 // starting from the jumppad origin can't reach the real destination
398                                 // and destination waypoint ends up near the jumppad itself
399                                 vector flatdir = normalize(dist - eZ * dist.z);
400                                 vector ofs = flatdir * 0.5 * min(fabs(this.absmax.x - this.absmin.x), fabs(this.absmax.y - this.absmin.y));
401                                 new_org = org + ofs;
402
403                                 LABEL(new_test)
404                                 e.velocity = trigger_push_calculatevelocity(new_org, t, this.height, e);
405                                 if (item)
406                                 {
407                                         if (!trigger_push_testorigin_for_item(e, item, new_org))
408                                         {
409                                                 delete(e);
410                                                 return false;
411                                         }
412                                 }
413                                 else
414                                 {
415                                         vel = e.velocity;
416                                         if (vdist(vec2(e.velocity), <, autocvar_sv_maxspeed))
417                                                 e.velocity = autocvar_sv_maxspeed * flatdir;
418                                         if (trigger_push_testorigin(e, t, this, new_org) && (!valid_best_target || trace_endpos.z > best_target.z + 50))
419                                         {
420                                                 best_target = trace_endpos;
421                                                 best_org = new_org;
422                                                 best_vel = vel;
423                                                 valid_best_target = true;
424                                         }
425                                 }
426                                 if (ofs && new_org != org - ofs)
427                                 {
428                                         new_org = org - ofs;
429                                         goto new_test;
430                                 }
431                         }
432
433                         if (item)
434                         {
435                                 delete(e);
436                                 return true;
437                         }
438
439                         if (valid_best_target)
440                         {
441                                 if (!(boxesoverlap(this.absmin, this.absmax + eZ * 50, best_target + PL_MIN_CONST, best_target + PL_MAX_CONST)))
442                                 {
443                                         float velxy = vlen(vec2(best_vel));
444                                         float cost = vlen(vec2(t.origin - best_org)) / velxy;
445                                         if(velxy < autocvar_sv_maxspeed)
446                                                 velxy = autocvar_sv_maxspeed;
447                                         cost += vlen(vec2(best_target - t.origin)) / velxy;
448                                         waypoint_spawnforteleporter(this, best_target, cost, e);
449                                 }
450                         }
451                         delete(e);
452 #endif
453                 }
454
455                 if(item)
456                         return false;
457
458                 if(!n)
459                 {
460                         // no dest!
461 #ifdef SVQC
462                         objerror (this, "Jumppad with nonexistant target");
463 #endif
464                         return false;
465                 }
466                 else if(n == 1)
467                 {
468                         // exactly one dest - bots love that
469                         this.enemy = find(NULL, targetname, this.target);
470                 }
471                 else
472                 {
473                         // have to use random selection every single time
474                         this.enemy = NULL;
475                 }
476         }
477 #ifdef SVQC
478         else
479         {
480                 entity e = spawn();
481                 setsize(e, PL_MIN_CONST, PL_MAX_CONST);
482                 e.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP | DPCONTENTS_BOTCLIP;
483                 setorigin(e, org);
484                 e.velocity = this.movedir;
485                 tracetoss(e, e);
486                 if (item)
487                 {
488                         bool r = (trace_ent == item);
489                         delete(e);
490                         return r;
491                 }
492                 if (!(boxesoverlap(this.absmin, this.absmax + eZ * 50, trace_endpos + PL_MIN_CONST, trace_endpos + PL_MAX_CONST)))
493                         waypoint_spawnforteleporter(this, trace_endpos, vlen(trace_endpos - org) / vlen(e.velocity), e);
494                 delete(e);
495         }
496
497         defer(this, 0.1, trigger_push_updatelink);
498 #endif
499         return true;
500 }
501
502 void trigger_push_findtarget(entity this)
503 {
504         trigger_push_test(this, NULL);
505 }
506
507 #ifdef SVQC
508 float trigger_push_send(entity this, entity to, float sf)
509 {
510         WriteHeader(MSG_ENTITY, ENT_CLIENT_TRIGGER_PUSH);
511
512         WriteByte(MSG_ENTITY, this.team);
513         WriteInt24_t(MSG_ENTITY, this.spawnflags);
514         WriteByte(MSG_ENTITY, this.active);
515         WriteCoord(MSG_ENTITY, this.height);
516
517         WriteVector(MSG_ENTITY, this.movedir);
518
519         trigger_common_write(this, true);
520
521         return true;
522 }
523
524 void trigger_push_updatelink(entity this)
525 {
526         this.SendFlags |= SF_TRIGGER_INIT;
527 }
528
529 void trigger_push_link(entity this)
530 {
531         trigger_link(this, trigger_push_send);
532 }
533
534 /*
535  * ENTITY PARAMETERS:
536  *
537  *   target:  target of jump
538  *   height:  the absolute value is the height of the highest point of the jump
539  *            trajectory above the higher one of the player and the target.
540  *            the sign indicates whether the highest point is INSIDE (positive)
541  *            or OUTSIDE (negative) of the jump trajectory. General rule: use
542  *            positive values for targets mounted on the floor, and use negative
543  *            values to target a point on the ceiling.
544  *   movedir: if target is not set, this * speed * 10 is the velocity to be reached.
545  */
546 spawnfunc(trigger_push)
547 {
548         SetMovedir(this);
549
550         trigger_init(this);
551
552         this.active = ACTIVE_ACTIVE;
553         this.use = trigger_push_use;
554         settouch(this, trigger_push_touch);
555
556         // normal push setup
557         if (!this.speed)
558                 this.speed = 1000;
559         this.movedir = this.movedir * this.speed * 10;
560
561         if (!this.noise)
562                 this.noise = "misc/jumppad.wav";
563         precache_sound (this.noise);
564
565         trigger_push_link(this); // link it now
566
567         IL_PUSH(g_jumppads, this);
568
569         // this must be called to spawn the teleport waypoints for bots
570         InitializeEntity(this, trigger_push_findtarget, INITPRIO_FINDTARGET);
571 }
572
573
574 bool target_push_send(entity this, entity to, float sf)
575 {
576         WriteHeader(MSG_ENTITY, ENT_CLIENT_TARGET_PUSH);
577
578         WriteByte(MSG_ENTITY, this.cnt);
579         WriteString(MSG_ENTITY, this.targetname);
580         WriteVector(MSG_ENTITY, this.origin);
581
582         WriteAngle(MSG_ENTITY, this.angles_x);
583         WriteAngle(MSG_ENTITY, this.angles_y);
584         WriteAngle(MSG_ENTITY, this.angles_z);
585
586         return true;
587 }
588
589 void target_push_use(entity this, entity actor, entity trigger)
590 {
591         if(trigger.classname == "trigger_push" || trigger == this)
592                 return; // WTF, why is this a thing
593
594         jumppad_push(this, actor);
595 }
596
597 void target_push_link(entity this)
598 {
599         BITSET_ASSIGN(this.effects, EF_NODEPTHTEST);
600         Net_LinkEntity(this, false, 0, target_push_send);
601         //this.SendFlags |= 1; // update
602 }
603
604 void target_push_init(entity this)
605 {
606         this.mangle = this.angles;
607         setorigin(this, this.origin);
608         target_push_link(this);
609 }
610
611 void target_push_init2(entity this)
612 {
613         if(this.target && this.target != "") // we have an old style pusher!
614         {
615                 InitializeEntity(this, trigger_push_findtarget, INITPRIO_FINDTARGET);
616                 this.use = target_push_use;
617         }
618
619         target_push_init(this); // normal push target behaviour can be combined with a legacy pusher?
620 }
621
622 spawnfunc(target_push)
623 {
624         target_push_init2(this);
625 }
626
627 spawnfunc(info_notnull)
628 {
629         target_push_init(this);
630 }
631 spawnfunc(target_position)
632 {
633         target_push_init(this);
634 }
635
636 #elif defined(CSQC)
637
638 NET_HANDLE(ENT_CLIENT_TRIGGER_PUSH, bool isnew)
639 {
640         this.classname = "jumppad";
641         int mytm = ReadByte();
642         if(mytm)
643         {
644                 this.team = mytm - 1;
645         }
646         this.spawnflags = ReadInt24_t();
647         this.active = ReadByte();
648         this.height = ReadCoord();
649
650         this.movedir = ReadVector();
651
652         trigger_common_read(this, true);
653
654         this.entremove = trigger_remove_generic;
655         this.solid = SOLID_TRIGGER;
656         settouch(this, trigger_push_touch);
657         this.move_time = time;
658         defer(this, 0.25, trigger_push_findtarget);
659
660         return true;
661 }
662
663 void target_push_remove(entity this)
664 {
665         // strfree(this.classname);
666         strfree(this.targetname);
667 }
668
669 NET_HANDLE(ENT_CLIENT_TARGET_PUSH, bool isnew)
670 {
671         this.classname = "push_target";
672         this.cnt = ReadByte();
673         this.targetname = strzone(ReadString());
674         this.origin = ReadVector();
675
676         this.angles_x = ReadAngle();
677         this.angles_y = ReadAngle();
678         this.angles_z = ReadAngle();
679
680         return = true;
681
682         setorigin(this, this.origin);
683
684         this.drawmask = MASK_NORMAL;
685         this.entremove = target_push_remove;
686 }
687 #endif