qcsrc/common/minigames/cl_minigames.qc

   1 #include "cl_minigames.qh"
   2
   3 // Draw a square in the center of the avaliable area
   4 void minigame_hud_simpleboard(vector pos, vector mySize, string board_texture)
   5 {
   6         if(panel.current_panel_bg != "0" && panel.current_panel_bg != "")
   7                 draw_BorderPicture(pos - '1 1 0' * panel_bg_border,
   8                                         panel.current_panel_bg,
   9                                         mySize + '1 1 0' * 2 * panel_bg_border,
  10                                         panel_bg_color, panel_bg_alpha,
  11                                          '1 1 0' * (panel_bg_border/BORDER_MULTIPLIER));
  12         drawpic(pos, board_texture, mySize, '1 1 1', panel_bg_alpha, DRAWFLAG_NORMAL);
  13 }
  14
  15 // De-normalize (2D vector) v from relative coordinate inside pos mySize
  16 vector minigame_hud_denormalize(vector v, vector pos, vector mySize)
  17 {
  18         v_x = pos_x + v_x * mySize_x;
  19         v_y = pos_y + v_y * mySize_y;
  20         return v;
  21 }
  22 // De-normalize (2D vector) v from relative size inside pos mySize
  23 vector minigame_hud_denormalize_size(vector v, vector pos, vector mySize)
  24 {
  25         v_x = v_x * mySize_x;
  26         v_y = v_y * mySize_y;
  27         return v;
  28 }
  29
  30 // Normalize (2D vector) v to relative coordinate inside pos mySize
  31 vector minigame_hud_normalize(vector v, vector pos, vector mySize)
  32 {
  33         v_x = ( v_x - pos_x ) / mySize_x;
  34         v_y = ( v_y - pos_y ) / mySize_y;
  35         return v;
  36 }
  37
  38 // Check if the mouse is inside the given area
  39 bool minigame_hud_mouse_in(vector pos, vector sz)
  40 {
  41         return mousepos_x >= pos_x && mousepos_x < pos_x + sz_x &&
  42                mousepos_y >= pos_y && mousepos_y < pos_y + sz_y ;
  43 }
  44
  45 string minigame_texture_skin(string skinname, string name)
  46 {
  47         return sprintf("gfx/hud/%s/minigames/%s", skinname, name);
  48 }
  49 string minigame_texture(string name)
  50 {
  51         string path = minigame_texture_skin(autocvar_menu_skin,name);
  52         if ( precache_pic(path) == "" )
  53                 path = minigame_texture_skin("default", name);
  54         return path;
  55 }
  56
  57 #define FIELD(Flags, Type, Name) MSLE_CLEAN_##Type(self.Name)
  58 #define MSLE_CLEAN_String(x) strunzone(x);
  59 #define MSLE_CLEAN_Byte(x)
  60 #define MSLE_CLEAN_Char(x)
  61 #define MSLE_CLEAN_Short(x)
  62 #define MSLE_CLEAN_Long(x)
  63 #define MSLE_CLEAN_Coord(x)
  64 #define MSLE_CLEAN_Angle(x)
  65 #define MSLE_CLEAN_Float(x)
  66 #define MSLE_CLEAN_Vector(x)
  67 #define MSLE_CLEAN_Vector2D(x)
  68
  69 #define MSLE(Name,Fields) \
  70         void msle_entremove_##Name() { SELFPARAM(); strunzone(self.netname); Fields }
  71 MINIGAME_SIMPLELINKED_ENTITIES
  72 #undef MSLE
  73 #undef FIELD
  74
  75 void minigame_autoclean_entity(entity e)
  76 {
  77         LOG_DEBUG("CL Auto-cleaned: ",ftos(num_for_edict(e)), " (",e.classname,")\n");
  78         remove(e);
  79 }
  80
  81 void HUD_MinigameMenu_CurrentButton();
  82 bool auto_close_minigamemenu;
  83 void deactivate_minigame()
  84 {
  85         if ( !active_minigame )
  86                 return;
  87
  88         active_minigame.minigame_event(active_minigame,"deactivate");
  89         entity e = world;
  90         while( (e = findentity(e, owner, active_minigame)) )
  91                 if ( e.minigame_autoclean )
  92                 {
  93                         minigame_autoclean_entity(e);
  94                 }
  95
  96         minigame_self = world;
  97         active_minigame = world;
  98
  99         if ( auto_close_minigamemenu )
 100         {
 101                 HUD_MinigameMenu_Close();
 102                 auto_close_minigamemenu = 0;
 103         }
 104         else
 105                 HUD_MinigameMenu_CurrentButton();
 106 }
 107
 108 void minigame_entremove()
 109 {SELFPARAM();
 110         if ( self == active_minigame )
 111                 deactivate_minigame();
 112 }
 113
 114 void activate_minigame(entity minigame)
 115 {
 116         if ( !minigame )
 117         {
 118                 deactivate_minigame();
 119                 return;
 120         }
 121
 122         if ( !minigame.descriptor || minigame.classname != "minigame" )
 123         {
 124                 LOG_TRACE("Trying to activate unregistered minigame ",minigame.netname," in client\n");
 125                 return;
 126         }
 127
 128         if ( minigame == active_minigame )
 129                 return;
 130
 131         if ( active_minigame )
 132         {
 133                 deactivate_minigame();
 134         }
 135
 136         if ( minigame_self.owner != minigame )
 137                 minigame_self = world;
 138         active_minigame = minigame;
 139         active_minigame.minigame_event(active_minigame,"activate");
 140
 141         if ( HUD_MinigameMenu_IsOpened() )
 142                 HUD_MinigameMenu_CurrentButton();
 143         else
 144         {
 145                 auto_close_minigamemenu = 1;
 146                 HUD_MinigameMenu_Open();
 147         }
 148 }
 149
 150 void minigame_player_entremove()
 151 {SELFPARAM();
 152         if ( self.owner == active_minigame && self.minigame_playerslot == player_localentnum )
 153                 deactivate_minigame();
 154 }
 155
 156 string() ReadString_Raw = #366;
 157 string ReadString_Zoned() { return strzone(ReadString_Raw()); }
 158 #define ReadString ReadString_Zoned
 159 #define FIELD(Flags, Type,Name) if ( sf & (Flags) ) self.Name = Read##Type();
 160 #define MSLE(Name,Fields) \
 161         else if ( self.classname == #Name ) { \
 162                 if ( sf & MINIG_SF_CREATE ) { \
 163                         minigame_read_owner(); \
 164                         self.entremove = msle_entremove_##Name; \
 165                 } \
 166                 minigame_ent = self.owner; \
 167                 Fields \
 168         }
 169 void minigame_read_owner()
 170 {SELFPARAM();
 171         string owner_name = ReadString_Raw();
 172         self.owner = world;
 173         do
 174                 self.owner = find(self.owner,netname,owner_name);
 175         while ( self.owner && self.owner.classname != "minigame" );
 176         if ( !self.owner )
 177                 LOG_TRACE("Got a minigame entity without a minigame!\n");
 178 }
 179 NET_HANDLE(ENT_CLIENT_MINIGAME, bool isnew)
 180 {
 181         float sf = ReadByte();
 182         if ( sf & MINIG_SF_CREATE )
 183         {
 184                 self.classname = msle_classname(ReadShort());
 185                 self.netname = ReadString_Zoned();
 186         }
 187
 188         entity minigame_ent = world;
 189
 190         if ( self.classname == "minigame" )
 191         {
 192                 minigame_ent = self;
 193
 194                 if ( sf & MINIG_SF_CREATE )
 195                 {
 196                         self.entremove = minigame_entremove;
 197                         self.descriptor = minigame_get_descriptor(ReadString_Raw());
 198                         if ( !self.descriptor )
 199                                 LOG_TRACE("Got a minigame without a client-side descriptor!\n");
 200                         else
 201                                 self.minigame_event = self.descriptor.minigame_event;
 202                 }
 203                 if ( sf & MINIG_SF_UPDATE )
 204                         self.minigame_flags = ReadLong();
 205         }
 206         else if ( self.classname == "minigame_player" )
 207         {
 208                 float activate = 0;
 209                 if ( sf & MINIG_SF_CREATE )
 210                 {
 211                         self.entremove = minigame_player_entremove;
 212                         minigame_read_owner();
 213                         float ent = ReadLong();
 214                         self.minigame_playerslot = ent;
 215                         LOG_DEBUG("Player: ",GetPlayerName(ent-1),"\n");
 216
 217                         activate = (ent == player_localnum+1 && self.owner && self.owner != active_minigame);
 218
 219                 }
 220                 minigame_ent = self.owner;
 221
 222                 if ( sf & MINIG_SF_UPDATE )
 223                         self.team = ReadByte();
 224
 225                 if ( activate )
 226                 {
 227                         minigame_self = self;
 228                         activate_minigame(self.owner);
 229                 }
 230         }
 231         MINIGAME_SIMPLELINKED_ENTITIES
 232
 233         if ( minigame_ent )
 234                 minigame_ent.minigame_event(minigame_ent,"network_receive",self,sf);
 235
 236         if ( sf & MINIG_SF_CREATE )
 237         {
 238                 LOG_DEBUG("CL Reading entity: ",ftos(num_for_edict(self)),
 239                         " classname:",self.classname," enttype:",ftos(self.enttype) );
 240                 LOG_DEBUG(" sf:",ftos(sf)," netname:",self.netname,"\n\n");
 241         }
 242         return true;
 243 }
 244 #undef ReadString
 245 #undef FIELD
 246 #undef MSLE
 247
 248 string minigame_getWrappedLine(float w, vector theFontSize, textLengthUpToWidth_widthFunction_t tw)
 249 {
 250         int last_word;
 251         string s;
 252         int take_until;
 253         int skip = 0;
 254
 255         s = getWrappedLine_remaining;
 256
 257         if(w <= 0)
 258         {
 259                 getWrappedLine_remaining = string_null;
 260                 return s; // the line has no size ANYWAY, nothing would be displayed.
 261         }
 262
 263         take_until = textLengthUpToWidth(s, w, theFontSize, tw);
 264
 265         if ( take_until > strlen(s) )
 266                 take_until = strlen(s);
 267
 268         for ( int i = 0; i < take_until; i++ )
 269                 if ( substring(s,i,1) == "\n" )
 270                 {
 271                         take_until = i;
 272                         skip = 1;
 273                         break;
 274                 }
 275
 276         if ( take_until > 0 || skip > 0 )
 277         {
 278                 if ( skip == 0 && take_until < strlen(s) )
 279                 {
 280                         last_word = take_until;
 281                         while(last_word > 0 && substring(s, last_word, 1) != " ")
 282                                 --last_word;
 283
 284                         if ( last_word != 0 )
 285                         {
 286                                 take_until = last_word;
 287                                 skip = 1;
 288                         }
 289                 }
 290
 291                 getWrappedLine_remaining = substring(s, take_until+skip, strlen(s) - (take_until+skip));
 292                 if(getWrappedLine_remaining == "")
 293                         getWrappedLine_remaining = string_null;
 294                 else if (tw("^7", theFontSize) == 0)
 295                         getWrappedLine_remaining = strcat(find_last_color_code(substring(s, 0, take_until)), getWrappedLine_remaining);
 296                 return substring(s, 0, take_until);
 297         }
 298         else
 299         {
 300                 getWrappedLine_remaining = string_null;
 301                 return s;
 302         }
 303 }
 304
 305 vector minigame_drawstring_wrapped( float maxwidth, vector pos, string text,
 306         vector fontsize, vector color, float theAlpha, int drawflags, float align )
 307 {
 308         getWrappedLine_remaining = text;
 309         vector mypos = pos;
 310         while ( getWrappedLine_remaining )
 311         {
 312                 string line = minigame_getWrappedLine(maxwidth,fontsize,stringwidth_nocolors);
 313                 if ( line == "" )
 314                         break;
 315                 mypos_x = pos_x + (maxwidth - stringwidth_nocolors(line, fontsize)) * align;
 316                 drawstring(mypos, line, fontsize, color, theAlpha, drawflags);
 317                 mypos_y += fontsize_y;
 318         }
 319         mypos_x = maxwidth;
 320         mypos_y -= pos_y;
 321         return mypos;
 322 }
 323
 324 vector minigame_drawcolorcodedstring_wrapped( float maxwidth, vector pos,
 325         string text, vector fontsize, float theAlpha, int drawflags, float align )
 326 {
 327         getWrappedLine_remaining = text;
 328         vector mypos = pos;
 329         while ( getWrappedLine_remaining )
 330         {
 331                 string line = minigame_getWrappedLine(maxwidth,fontsize,stringwidth_colors);
 332                 if ( line == "" )
 333                         break;
 334                 mypos_x = pos_x + (maxwidth - stringwidth_colors(line, fontsize)) * align;
 335                 drawcolorcodedstring(mypos, line, fontsize, theAlpha, drawflags);
 336                 mypos_y += fontsize_y;
 337         }
 338         mypos_x = maxwidth;
 339         mypos_y -= pos_y;
 340         return mypos;
 341 }
 342
 343 void minigame_drawstring_trunc(float maxwidth, vector pos, string text,
 344         vector fontsize, vector color, float theAlpha, int drawflags )
 345 {
 346         string line = textShortenToWidth(text,maxwidth,fontsize,stringwidth_nocolors);
 347         drawstring(pos, line, fontsize, color, theAlpha, drawflags);
 348 }
 349
 350 void minigame_drawcolorcodedstring_trunc(float maxwidth, vector pos, string text,
 351         vector fontsize, float theAlpha, int drawflags )
 352 {
 353         string line = textShortenToWidth(text,maxwidth,fontsize,stringwidth_colors);
 354         drawcolorcodedstring(pos, line, fontsize, theAlpha, drawflags);
 355 }
 356
 357 void minigame_drawpic_centered( vector pos, string texture, vector sz,
 358         vector color, float thealpha, int drawflags )
 359 {
 360         drawpic( pos-sz/2, texture, sz, color, thealpha, drawflags );
 361 }
 362
 363 // Workaround because otherwise variadic arguments won't work properly
 364 // It could be a bug in the compiler or in darkplaces
 365 void minigame_cmd_workaround(float dummy, string...cmdargc)
 366 {
 367         string cmd;
 368         cmd = "cmd minigame ";
 369         float i;
 370         for ( i = 0; i < cmdargc; i++ )
 371                 cmd = strcat(cmd,...(i,string));
 372         localcmd(strcat(cmd,"\n"));
 373 }
 374
 375 // Prompt the player to play in the current minigame
 376 // (ie: it's their turn and they should get back to the minigame)
 377 void minigame_prompt()
 378 {
 379         if ( active_minigame && ! HUD_MinigameMenu_IsOpened() )
 380         {
 381                 HUD_Notify_Push(sprintf("minigames/%s/icon_notif",active_minigame.descriptor.netname),
 382                         _("It's your turn"), "");
 383         }
 384 }