qcsrc/common/minigames/minigame/bd.qc

   1 REGISTER_MINIGAME(bd, "Bulldozer");
   2
   3 const int BD_TURN_MOVE  = 0x0100; // player must move the bulldozer
   4 const int BD_TURN_WIN   = 0x0200; // victory
   5 const int BD_TURN_LOSS  = 0x0400; // they did it?!
   6 const int BD_TURN_EDIT  = 0x0800; // editing mode
   7 const int BD_TURN_TYPE  = 0x0f00; // turn type mask
   8
   9 const int BD_SF_PLAYERMOVES = MINIG_SF_CUSTOM;
  10
  11 // 240 tiles...
  12 const int BD_LET_CNT = 20;
  13 const int BD_NUM_CNT = 20;
  14
  15 const int BD_TILE_SIZE = 20;
  16
  17 const int BD_TEAMS = 1;
  18
  19 .vector bd_dir;
  20
  21 .int bd_moves;
  22
  23 .string bd_levelname;
  24 .string bd_nextlevel;
  25
  26 #ifdef SVQC
  27 .bool bd_canedit;
  28 #endif
  29
  30 .int bd_tiletype;
  31 const int BD_TILE_DOZER = 1;
  32 const int BD_TILE_TARGET = 2;
  33 const int BD_TILE_BOULDER = 3;
  34 const int BD_TILE_BRICK1 = 4;
  35 const int BD_TILE_BRICK2 = 5;
  36 const int BD_TILE_BRICK3 = 6;
  37 const int BD_TILE_BRICK4 = 7;
  38 const int BD_TILE_BRICK5 = 8;
  39 const int BD_TILE_BRICK6 = 9;
  40 const int BD_TILE_BRICK7 = 10;
  41 const int BD_TILE_BRICK8 = 11;
  42 const int BD_TILE_LAST = 11;
  43
  44 string autocvar_sv_minigames_bulldozer_startlevel = "level1";
  45
  46 // find same game piece given its tile name
  47 entity bd_find_piece(entity minig, string tile, bool check_target)
  48 {
  49         entity e = world;
  50         while ( ( e = findentity(e,owner,minig) ) )
  51                 if ( e.classname == "minigame_board_piece" && e.netname == tile && ((check_target) ? e.bd_tiletype == BD_TILE_TARGET : e.bd_tiletype != BD_TILE_TARGET) )
  52                         return e;
  53         return world;
  54 }
  55
  56 // check if the tile name is valid (15x15 grid)
  57 bool bd_valid_tile(string tile)
  58 {
  59         if ( !tile )
  60                 return false;
  61         int number = minigame_tile_number(tile);
  62         int letter = minigame_tile_letter(tile);
  63         return 0 <= number && number < BD_NUM_CNT && 0 <= letter && letter < BD_LET_CNT;
  64 }
  65
  66 entity bd_find_dozer(entity minig)
  67 {
  68         entity e = world;
  69         while ( ( e = findentity(e,owner,minig) ) )
  70                 if ( e.classname == "minigame_board_piece" && e.bd_tiletype == BD_TILE_DOZER )
  71                         return e;
  72         return world;
  73 }
  74
  75 void bd_check_winner(entity minig)
  76 {
  77         int total = 0, valid = 0;
  78         entity e = world;
  79         while ( ( e = findentity(e,owner,minig) ) )
  80                 if ( e.classname == "minigame_board_piece" && e.bd_tiletype == BD_TILE_TARGET )
  81                 {
  82                         ++total;
  83                         if(bd_find_piece(minig, e.netname, false).bd_tiletype == BD_TILE_BOULDER)
  84                                 ++valid;
  85                 }
  86
  87         if(valid >= total)
  88         {
  89                 minig.minigame_flags = BD_TURN_WIN;
  90                 minigame_server_sendflags(minig,MINIG_SF_UPDATE);
  91         }
  92 }
  93
  94 bool bd_canfill(int ttype)
  95 {
  96         switch(ttype)
  97         {
  98                 case BD_TILE_BRICK8:
  99                 case BD_TILE_BRICK7:
 100                 case BD_TILE_BRICK6:
 101                 case BD_TILE_BRICK5:
 102                 case BD_TILE_BRICK4:
 103                 case BD_TILE_BRICK3:
 104                 case BD_TILE_BRICK2:
 105                 case BD_TILE_BRICK1: return true;
 106         }
 107
 108         return false;
 109 }
 110
 111 bool bd_move_dozer(entity minigame, entity dozer)
 112 {
 113         if(!dozer.bd_dir_x && !dozer.bd_dir_y)
 114                 return false; // nope!
 115
 116         int myx = minigame_tile_letter(dozer.netname);
 117         int myy = minigame_tile_number(dozer.netname);
 118
 119         myx += dozer.bd_dir_x;
 120         myy += dozer.bd_dir_y;
 121
 122         string newpos = minigame_tile_buildname(myx, myy);
 123         entity hit = bd_find_piece(minigame, newpos, false);
 124
 125         if(!bd_valid_tile(newpos))
 126                 return false;
 127
 128         if(hit)
 129         switch(hit.bd_tiletype)
 130         {
 131                 case BD_TILE_DOZER: // wtf, but let's do this incase
 132                 case BD_TILE_BRICK8:
 133                 case BD_TILE_BRICK7:
 134                 case BD_TILE_BRICK6:
 135                 case BD_TILE_BRICK5:
 136                 case BD_TILE_BRICK4:
 137                 case BD_TILE_BRICK3:
 138                 case BD_TILE_BRICK2:
 139                 case BD_TILE_BRICK1: return false;
 140                 case BD_TILE_BOULDER:
 141                 {
 142                         string testpos;
 143                         int tx = minigame_tile_letter(hit.netname);
 144                         int ty = minigame_tile_number(hit.netname);
 145
 146                         tx += dozer.bd_dir_x;
 147                         ty += dozer.bd_dir_y;
 148
 149                         testpos = minigame_tile_buildname(tx, ty);
 150                         entity testhit = bd_find_piece(minigame, testpos, false);
 151
 152                         if(!bd_valid_tile(testpos) || testhit)
 153                                 return false;
 154
 155                         if(hit.netname) { strunzone(hit.netname); }
 156                         hit.netname = strzone(testpos);
 157                         minigame_server_sendflags(hit,MINIG_SF_UPDATE);
 158                         break;
 159                 }
 160         }
 161
 162         if(dozer.netname) { strunzone(dozer.netname); }
 163         dozer.netname = strzone(newpos);
 164
 165         return true;
 166 }
 167
 168 // make a move
 169 void bd_move(entity minigame, entity player, string dir)
 170 {
 171         if ( minigame.minigame_flags & BD_TURN_MOVE )
 172         if ( dir )
 173         {
 174                 //if ( bd_valid_tile(pos) )
 175                 //if ( bd_find_piece(minigame, pos, false) )
 176                 {
 177                         entity dozer = bd_find_dozer(minigame);
 178                         if(!dozer)
 179                         {
 180                                 LOG_INFO("Dozer wasn't found!\n");
 181                                 return; // should not happen... TODO: end match?
 182                         }
 183
 184                         int dxs = 0, dys = 0;
 185                         string thedir = strtolower(dir);
 186                         if(thedir == "up" || thedir == "u") { dxs = 0; dys = 1; }
 187                         if(thedir == "down" || thedir == "dn" || thedir == "d") { dxs = 0; dys = -1; }
 188                         if(thedir == "left" || thedir == "lt" || thedir == "l") { dxs = -1; dys = 0; }
 189                         if(thedir == "right" || thedir == "rt" || thedir == "r") { dxs = 1; dys = 0; }
 190
 191                         int dx = bound(-1, dxs, 1);
 192                         int dy = bound(-1, dys, 1);
 193
 194                         dozer.bd_dir_x = dx;
 195                         dozer.bd_dir_y = dy;
 196                         dozer.bd_dir_z = 0;
 197
 198                         if(bd_move_dozer(minigame, dozer))
 199                                 player.bd_moves++;
 200
 201                         bd_check_winner(minigame);
 202
 203                         minigame_server_sendflags(dozer,MINIG_SF_UPDATE); // update anyway
 204                         minigame_server_sendflags(player,BD_SF_PLAYERMOVES);
 205                         minigame_server_sendflags(minigame,MINIG_SF_UPDATE);
 206                 }
 207         }
 208 }
 209
 210 // editor
 211 void bd_editor_place(entity minigame, entity player, string pos, int thetile, string thedir)
 212 {
 213         if ( minigame.minigame_flags & BD_TURN_EDIT )
 214         if ( pos && thetile )
 215         {
 216                 if ( bd_valid_tile(pos) )
 217                 {
 218                         entity found_piece = bd_find_piece(minigame, pos, false);
 219                         entity targ = bd_find_piece(minigame, pos, true);
 220
 221                         if(found_piece.bd_tiletype == BD_TILE_DOZER && thedir != "")
 222                         {
 223                                 int dxs = 0, dys = 0;
 224                                 string newdir = strtolower(thedir);
 225                                 if(newdir == "up" || newdir == "u") { dxs = 0; dys = 1; }
 226                                 if(newdir == "down" || newdir == "dn" || newdir == "d") { dxs = 0; dys = -1; }
 227                                 if(newdir == "left" || newdir == "lt" || newdir == "l") { dxs = -1; dys = 0; }
 228                                 if(newdir == "right" || newdir == "rt" || newdir == "r") { dxs = 1; dys = 0; }
 229
 230                                 int dx = bound(-1, dxs, 1);
 231                                 int dy = bound(-1, dys, 1);
 232
 233                                 found_piece.bd_dir_x = dx;
 234                                 found_piece.bd_dir_y = dy;
 235                                 found_piece.bd_dir_z = 0;
 236                                 minigame_server_sendflags(found_piece,MINIG_SF_UPDATE); // update anyway
 237                                 return;
 238                         }
 239
 240                         entity dozer = bd_find_dozer(minigame);
 241                         if(dozer && thetile == BD_TILE_DOZER && pos != dozer.netname)
 242                                 return; // nice try
 243
 244                         if(found_piece || (targ && thetile != BD_TILE_BOULDER))
 245                         {
 246                                 entity piece = bd_find_piece(minigame, pos, false);
 247                                 if(!piece) piece = bd_find_piece(minigame, pos, true);
 248                                 if(!piece)
 249                                         return; // how?!
 250
 251                                 if(piece.netname) { strunzone(piece.netname); }
 252                                 remove(piece);
 253                                 minigame_server_sendflags(minigame,MINIG_SF_UPDATE);
 254                                 return;
 255                         }
 256
 257                         entity piece = msle_spawn(minigame,"minigame_board_piece");
 258                         piece.team = 1;
 259                         piece.netname = strzone(pos);
 260                         piece.bd_tiletype = thetile;
 261                         piece.bd_dir = '0 -1 0';
 262                         minigame_server_sendflags(piece,MINIG_SF_UPDATE);
 263
 264                         minigame_server_sendflags(minigame,MINIG_SF_UPDATE);
 265                 }
 266         }
 267 }
 268
 269 void bd_do_move(entity minigame, entity player, string dir, string thetile, string thedir)
 270 {
 271         if(minigame.minigame_flags & BD_TURN_MOVE)
 272                 bd_move(minigame, player, dir);
 273
 274         if(minigame.minigame_flags & BD_TURN_EDIT)
 275                 bd_editor_place(minigame, player, dir, stof(thetile), thedir);
 276 }
 277
 278 void bd_fill_recurse(entity minigame, entity player, int thetype, int letter, int number)
 279 {
 280         string pos = minigame_tile_buildname(letter,number);
 281         if(!bd_valid_tile(pos))
 282                 return;
 283         if(bd_find_piece(minigame, pos, false) || bd_find_piece(minigame, pos, true))
 284                 return;
 285
 286         bd_editor_place(minigame, player, pos, thetype, "");
 287
 288         bd_fill_recurse(minigame, player, thetype, letter - 1, number);
 289         bd_fill_recurse(minigame, player, thetype, letter + 1, number);
 290         bd_fill_recurse(minigame, player, thetype, letter, number - 1);
 291         bd_fill_recurse(minigame, player, thetype, letter, number + 1);
 292 }
 293
 294 void bd_unfill_recurse(entity minigame, entity player, int thetype, int letter, int number)
 295 {
 296         string pos = minigame_tile_buildname(letter,number);
 297         if(!bd_valid_tile(pos))
 298                 return;
 299
 300         entity targ = bd_find_piece(minigame, pos, true);
 301         entity piece = bd_find_piece(minigame, pos, false);
 302
 303         if(targ && thetype == targ.bd_tiletype)
 304         {
 305                 if(targ.netname) { strunzone(targ.netname); }
 306                 remove(targ);
 307         }
 308         else if(piece && thetype == piece.bd_tiletype)
 309         {
 310                 if(piece.netname) { strunzone(piece.netname); }
 311                 remove(piece);
 312         }
 313         else return;
 314
 315         bd_unfill_recurse(minigame, player, thetype, letter - 1, number);
 316         bd_unfill_recurse(minigame, player, thetype, letter + 1, number);
 317         bd_unfill_recurse(minigame, player, thetype, letter, number - 1);
 318         bd_unfill_recurse(minigame, player, thetype, letter, number + 1);
 319 }
 320
 321 void bd_do_fill(entity minigame, entity player, string dir, string thetile)
 322 {
 323         if(minigame.minigame_flags & BD_TURN_EDIT)
 324         {
 325                 int thetype = stof(thetile);
 326
 327                 entity targ = bd_find_piece(minigame, dir, true);
 328                 entity piece = bd_find_piece(minigame, dir, false);
 329
 330                 if(!bd_canfill(thetype) || (piece || targ))
 331                 {
 332                         int killtype = 0;
 333
 334                         if(targ) { killtype = targ.bd_tiletype; }
 335                         if(piece) { killtype = piece.bd_tiletype; }
 336
 337                         if(killtype)
 338                         {
 339                                 int letter = minigame_tile_letter(dir);
 340                                 int number = minigame_tile_number(dir);
 341                                 bd_unfill_recurse(minigame, player, killtype, letter, number);
 342                         }
 343
 344                         return;
 345                 }
 346
 347                 int letter = minigame_tile_letter(dir);
 348                 int number = minigame_tile_number(dir);
 349
 350                 bd_fill_recurse(minigame, player, thetype, letter, number);
 351         }
 352 }
 353
 354 void bd_reset_moves(entity minigame)
 355 {
 356         entity e;
 357 #ifdef SVQC
 358         for(e = minigame.minigame_players; e; e = e.list_next)
 359 #elif defined(CSQC)
 360         e = world;
 361         while( (e = findentity(e,owner,minigame)) )
 362                 if ( e.classname == "minigame_player" )
 363 #endif
 364                 {
 365                         e.bd_moves = 0;
 366                         minigame_server_sendflags(e,BD_SF_PLAYERMOVES);
 367                 }
 368 }
 369
 370 void bd_load_level(entity minigame);
 371 void bd_setup_pieces(entity minigame)
 372 {
 373         entity e = world;
 374         while( (e = findentity(e, owner, minigame)) )
 375                 if(e.classname == "minigame_board_piece")
 376                 {
 377                         if(e.netname) { strunzone(e.netname); }
 378                         remove(e);
 379                 }
 380
 381         bd_load_level(minigame);
 382 }
 383
 384 void bd_do_next_match(entity minigame, entity player)
 385 {
 386         minigame.minigame_flags = BD_TURN_MOVE;
 387         minigame_server_sendflags(minigame,MINIG_SF_UPDATE);
 388
 389         if(minigame.bd_nextlevel && minigame.bd_nextlevel != "")
 390         {
 391                 if(minigame.bd_levelname) { strunzone(minigame.bd_levelname); }
 392                 minigame.bd_levelname = strzone(minigame.bd_nextlevel);
 393         }
 394
 395         bd_setup_pieces(minigame);
 396
 397         bd_reset_moves(minigame);
 398 }
 399
 400 void bd_set_next_match(entity minigame, string next)
 401 {
 402         if(minigame.bd_nextlevel) { strunzone(minigame.bd_nextlevel); }
 403         minigame.bd_nextlevel = strzone(next);
 404 }
 405
 406 void bd_next_match(entity minigame, entity player, string next)
 407 {
 408         if(minigame.minigame_flags & BD_TURN_WIN)
 409                 bd_do_next_match(minigame, player);
 410         if(minigame.minigame_flags & BD_TURN_EDIT)
 411                 bd_set_next_match(minigame, next);
 412 }
 413
 414 // request a new match
 415 void bd_restart_match(entity minigame, entity player)
 416 {
 417         minigame.minigame_flags = BD_TURN_MOVE;
 418         minigame_server_sendflags(minigame,MINIG_SF_UPDATE);
 419
 420         bd_setup_pieces(minigame);
 421
 422         bd_reset_moves(minigame);
 423 }
 424
 425 void bd_activate_editor(entity minigame, entity player)
 426 {
 427 #ifdef SVQC
 428         if(!player.minigame_players.bd_canedit)
 429         {
 430                 sprint(player.minigame_players, "You're not allowed to edit levels, sorry!\n");
 431                 return;
 432         }
 433 #endif
 434
 435         minigame.minigame_flags = BD_TURN_EDIT;
 436         minigame_server_sendflags(minigame,MINIG_SF_UPDATE);
 437
 438         bd_reset_moves(minigame);
 439
 440         bd_setup_pieces(minigame);
 441 }
 442
 443 string bd_save_piece(entity minigame, entity e)
 444 {
 445         string bd_string = "";
 446
 447         bd_string = strcat(bd_string, "\"", e.netname, "\" ");
 448         bd_string = strcat(bd_string, ftos(e.bd_tiletype), " ");
 449         bd_string = strcat(bd_string, sprintf("\"%.9v\"", e.bd_dir));
 450
 451         return bd_string;
 452 }
 453
 454 void bd_set_nextlevel(entity minigame, string s)
 455 {
 456         tokenize_console(s);
 457
 458         if(minigame.bd_nextlevel) { strunzone(minigame.bd_nextlevel); }
 459         minigame.bd_nextlevel = strzone(argv(2));
 460 }
 461
 462 entity bd_load_piece(entity minigame, string s)
 463 {
 464         // separate pieces between the ; symbols
 465         string bd_string = s;
 466
 467         tokenize_console(bd_string);
 468
 469         entity e = msle_spawn(minigame,"minigame_board_piece");
 470         e.team = 1;
 471         e.bd_dir = '0 -1 0';
 472
 473         int argv_num = 0;
 474         e.netname = strzone(argv(argv_num)); ++argv_num;
 475         e.bd_tiletype = stof(argv(argv_num)); ++argv_num;
 476         e.bd_dir = stov(argv(argv_num)); ++argv_num;
 477
 478         minigame_server_sendflags(e,MINIG_SF_ALL);
 479
 480         return e;
 481 }
 482
 483 bool bd_save_level(entity minigame)
 484 {
 485         if(minigame.bd_levelname && minigame.bd_levelname != "")
 486         {
 487                 int target_count = 0, boulder_count = 0;
 488                 entity piece = world;
 489                 while((piece = findentity(piece,owner,minigame)))
 490                 if(piece.classname == "minigame_board_piece")
 491                         if(piece.bd_tiletype == BD_TILE_BOULDER)
 492                                 ++boulder_count;
 493                         else if(piece.bd_tiletype == BD_TILE_TARGET)
 494                                 ++target_count;
 495
 496                 if(boulder_count != target_count)
 497                 {
 498                         LOG_INFO("Not enough targets or boulders, fix your level!\n");
 499                         return false;
 500                 }
 501
 502                 // saves all objects to the database file
 503                 string file_name;
 504                 float file_get;
 505
 506                 file_name = strcat("minigames/bulldozer/storage_", minigame.bd_levelname, ".txt");
 507                 file_get = fopen(file_name, FILE_WRITE);
 508                 fputs(file_get, strcat("// bulldozer storage \"", minigame.bd_levelname, "\" last updated ", strftime(true, "%d-%m-%Y %H:%M:%S"), "\n"));
 509
 510                 if(minigame.bd_nextlevel && minigame.bd_nextlevel != "" && fexists(strcat("minigames/bulldozer/storage_", minigame.bd_nextlevel, ".txt")))
 511                         fputs(file_get, strcat("nextlevel = \"", minigame.bd_nextlevel, "\"\n"));
 512
 513                 entity e = world;
 514                 while ( ( e = findentity(e,owner,minigame) ) )
 515                 if ( e.classname == "minigame_board_piece" )
 516                 {
 517                         // use a line of text for each object, listing all properties
 518                         fputs(file_get, strcat(bd_save_piece(minigame, e), "\n"));
 519                 }
 520                 fclose(file_get);
 521
 522                 return true;
 523         }
 524
 525         return false;
 526 }
 527
 528 void bd_load_level(entity minigame)
 529 {
 530         // loads all items from the database file
 531         string file_read, file_name;
 532         float file_get;
 533
 534         file_name = strcat("minigames/bulldozer/storage_", minigame.bd_levelname, ".txt");
 535         file_get = fopen(file_name, FILE_READ);
 536         if(file_get < 0)
 537         {
 538                 LOG_INFO("^3BULLDOZER: ^7could not find storage file ^3", file_name, "^7, no items were loaded\n");
 539         }
 540         else
 541         {
 542                 for(;;)
 543                 {
 544                         file_read = fgets(file_get);
 545                         if(file_read == "")
 546                                 break;
 547                         if(substring(file_read, 0, 2) == "//")
 548                                 continue;
 549                         if(substring(file_read, 0, 1) == "#")
 550                                 continue;
 551                         if(substring(file_read, 0, 9) == "nextlevel")
 552                         {
 553                                 bd_set_nextlevel(minigame, file_read);
 554                                 continue;
 555                         }
 556
 557                         entity e;
 558                         e = bd_load_piece(minigame, file_read);
 559                 }
 560         }
 561         fclose(file_get);
 562 }
 563
 564 void bd_close_editor(entity minigame)
 565 {
 566         entity dozer = bd_find_dozer(minigame);
 567         if(!dozer)
 568         {
 569                 LOG_INFO("You need to place a bulldozer on the level to save it!\n");
 570                 return;
 571         }
 572
 573         if(bd_save_level(minigame))
 574         {
 575                 minigame.minigame_flags = BD_TURN_MOVE;
 576                 minigame_server_sendflags(minigame,MINIG_SF_UPDATE);
 577         }
 578         else
 579         {
 580                 LOG_INFO("You need to set the level name!\n");
 581                 return;
 582         }
 583 }
 584
 585 #ifdef SVQC
 586
 587 // required function, handle server side events
 588 int bd_server_event(entity minigame, string event, ...)
 589 {
 590         switch(event)
 591         {
 592                 case "start":
 593                 {
 594                         if(minigame.bd_levelname) { strunzone(minigame.bd_levelname); }
 595                         minigame.bd_levelname = strzone(autocvar_sv_minigames_bulldozer_startlevel);
 596                         bd_setup_pieces(minigame);
 597                         minigame.minigame_flags = BD_TURN_MOVE;
 598
 599                         return true;
 600                 }
 601                 case "end":
 602                 {
 603                         entity e = world;
 604                         while( (e = findentity(e, owner, minigame)) )
 605                         if(e.classname == "minigame_board_piece")
 606                         {
 607                                 if(e.netname) { strunzone(e.netname); }
 608                                 remove(e);
 609                         }
 610
 611                         if(minigame.bd_nextlevel) { strunzone(minigame.bd_nextlevel); }
 612                         if(minigame.bd_levelname) { strunzone(minigame.bd_levelname); }
 613                         return false;
 614                 }
 615                 case "join":
 616                 {
 617                         int pl_num = minigame_count_players(minigame);
 618
 619                         if(pl_num >= BD_TEAMS) { return false; }
 620
 621                         return 1;
 622                 }
 623                 case "cmd":
 624                 {
 625                         switch(argv(0))
 626                         {
 627                                 case "move":
 628                                         bd_do_move(minigame, ...(0,entity), ((...(1,int)) >= 2 ? argv(1) : string_null), ((...(1,int)) >= 3 ? argv(2) : string_null), ((...(1,int)) >= 4 ? argv(3) : string_null));
 629                                         return true;
 630                                 case "next":
 631                                         bd_next_match(minigame,...(0,entity), ((...(1,int) >= 2 ? argv(1) : string_null)));
 632                                         return true;
 633                                 case "restart":
 634                                         bd_restart_match(minigame,...(0,entity));
 635                                         return true;
 636                                 case "edit":
 637                                         bd_activate_editor(minigame,...(0,entity));
 638                                         return true;
 639                                 case "save":
 640                                         bd_close_editor(minigame);
 641                                         return true;
 642                                 case "fill":
 643                                         bd_do_fill(minigame, ...(0,entity), ((...(1,int)) >= 2 ? argv(1) : string_null), ((...(1,int)) >= 3 ? argv(2) : string_null));
 644                                         return true;
 645                         }
 646
 647                         return false;
 648                 }
 649                 case "network_send":
 650                 {
 651                         entity sent = ...(0,entity);
 652                         int sf = ...(1,int);
 653                         if ( sent.classname == "minigame_board_piece" && (sf & MINIG_SF_UPDATE) )
 654                         {
 655                                 int letter = minigame_tile_letter(sent.netname);
 656                                 int number = minigame_tile_number(sent.netname);
 657
 658                                 WriteByte(MSG_ENTITY,letter);
 659                                 WriteByte(MSG_ENTITY,number);
 660
 661                                 WriteByte(MSG_ENTITY,sent.bd_tiletype);
 662
 663                                 int dx = sent.bd_dir_x;
 664                                 int dy = sent.bd_dir_y;
 665                                 if(dx == -1) dx = 2;
 666                                 if(dy == -1) dy = 2;
 667                                 WriteByte(MSG_ENTITY,dx);
 668                                 WriteByte(MSG_ENTITY,dy);
 669                         }
 670                         else if(sent.classname == "minigame_player" && (sf & BD_SF_PLAYERMOVES))
 671                                 WriteShort(MSG_ENTITY,sent.bd_moves);
 672                         return false;
 673                 }
 674         }
 675
 676         return false;
 677 }
 678
 679
 680 #elif defined(CSQC)
 681
 682 int bd_curr_tile;
 683 string bd_curr_pos;
 684
 685 .entity bd_enemy;
 686 .bool bd_hide;
 687
 688 vector bd_boardpos; // HUD board position
 689 vector bd_boardsize;// HUD board size
 690
 691 string bd_get_tile_pic(int tileid)
 692 {
 693         switch(tileid)
 694         {
 695                 case BD_TILE_BOULDER: return "bd/boulder";
 696                 case BD_TILE_BRICK1: return "bd/brick1";
 697                 case BD_TILE_BRICK2: return "bd/brick2";
 698                 case BD_TILE_BRICK3: return "bd/brick3";
 699                 case BD_TILE_BRICK4: return "bd/brick4";
 700                 case BD_TILE_BRICK5: return "bd/brick5";
 701                 case BD_TILE_BRICK6: return "bd/brick6";
 702                 case BD_TILE_BRICK7: return "bd/brick7";
 703                 case BD_TILE_BRICK8: return "bd/brick8";
 704                 case BD_TILE_TARGET: return "bd/target";
 705                 case BD_TILE_DOZER: return "bd/dozer";
 706         }
 707
 708         return string_null;
 709 }
 710
 711 // Required function, draw the game board
 712 void bd_hud_board(vector pos, vector mySize)
 713 {
 714         minigame_hud_fitsqare(pos, mySize);
 715         bd_boardpos = pos;
 716         bd_boardsize = mySize;
 717
 718         minigame_hud_simpleboard(pos,mySize,minigame_texture("bd/board"));
 719
 720         vector tile_size = minigame_hud_denormalize_size('1 1 0' / BD_TILE_SIZE,pos,mySize);
 721         vector tile_pos;
 722
 723         entity e;
 724         FOREACH_MINIGAME_ENTITY(e)
 725         {
 726                 if(e.classname == "minigame_board_piece")
 727                 {
 728                         if(e.bd_tiletype == BD_TILE_TARGET)
 729                         {
 730                                 e.bd_enemy = world;
 731                                 e.bd_enemy = bd_find_piece(active_minigame, e.netname, false);
 732                         }
 733                         else if(e.bd_tiletype == BD_TILE_BOULDER)
 734                         {
 735                                 e.bd_hide = false; // reset either way
 736                                 e.bd_hide = ((bd_find_piece(active_minigame, e.netname, true)) != world);
 737                         }
 738                 }
 739         }
 740         FOREACH_MINIGAME_ENTITY(e)
 741         {
 742                 if ( e.classname == "minigame_board_piece" )
 743                 {
 744                         if(e.bd_tiletype != BD_TILE_DOZER && !e.bd_hide) // hide boulders
 745                         {
 746                                 tile_pos = minigame_tile_pos(e.netname,BD_NUM_CNT,BD_LET_CNT);
 747                                 tile_pos = minigame_hud_denormalize(tile_pos,pos,mySize);
 748
 749                                 string thepiece = bd_get_tile_pic(e.bd_tiletype);
 750
 751                                 if(e.bd_enemy)
 752                                         thepiece = "bd/boulder_target";
 753
 754                                 minigame_drawpic_centered( tile_pos,
 755                                                 minigame_texture(thepiece),
 756                                                 tile_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL );
 757                         }
 758                 }
 759         }
 760
 761         // draw dozers on top, always
 762         FOREACH_MINIGAME_ENTITY(e)
 763         {
 764                 if ( e.classname == "minigame_board_piece" && e.bd_tiletype == BD_TILE_DOZER )
 765                 {
 766                         tile_pos = minigame_tile_pos(e.netname,BD_NUM_CNT,BD_LET_CNT);
 767                         tile_pos = minigame_hud_denormalize(tile_pos,pos,mySize);
 768
 769                         vector thedir = e.bd_dir;
 770                         float theang = 0;
 771
 772                         if(thedir_y == -1) { theang = M_PI; }
 773                         if(thedir_x == 1) { theang = M_PI/2; }
 774                         if(thedir_x == -1) { theang = M_PI*3/2; }
 775
 776                         drawrotpic(tile_pos, theang, minigame_texture("bd/dozer"),
 777                                                 tile_size, tile_size/2, '1 1 1',
 778                                                 panel_fg_alpha, DRAWFLAG_NORMAL );
 779                 }
 780         }
 781
 782         if(active_minigame.minigame_flags & BD_TURN_EDIT)
 783         if(bd_valid_tile(bd_curr_pos))
 784         {
 785                 entity piece = bd_find_piece(active_minigame, bd_curr_pos, false);
 786                 entity targ = bd_find_piece(active_minigame, bd_curr_pos, true);
 787                 string thepiece = ((piece || (targ && bd_curr_tile != BD_TILE_BOULDER)) ? "bd/delete" : bd_get_tile_pic(bd_curr_tile));
 788
 789                 tile_pos = minigame_tile_pos(bd_curr_pos,BD_LET_CNT,BD_NUM_CNT);
 790                 tile_pos = minigame_hud_denormalize(tile_pos,pos,mySize);
 791                 if(bd_curr_tile == BD_TILE_DOZER)
 792                 {
 793                         drawrotpic(tile_pos, M_PI, minigame_texture("bd/dozer"),
 794                                                 tile_size, tile_size/2, '1 1 1',
 795                                                 panel_fg_alpha/2, DRAWFLAG_NORMAL );
 796                 }
 797                 else
 798                 {
 799                         minigame_drawpic_centered( tile_pos,
 800                                         minigame_texture(thepiece),
 801                                         tile_size, '1 1 1', panel_fg_alpha/2, DRAWFLAG_NORMAL );
 802                 }
 803         }
 804
 805         if ( (active_minigame.minigame_flags & BD_TURN_LOSS) || (active_minigame.minigame_flags & BD_TURN_WIN) )
 806         {
 807                 vector winfs = hud_fontsize*2;
 808                 string victory_text = "Game over!";
 809
 810                 if(active_minigame.minigame_flags & BD_TURN_WIN)
 811                         victory_text = "Well done! Click 'Next Level' to continue";
 812
 813                 vector win_pos = pos+eY*(mySize_y-winfs_y)/2;
 814                 vector win_sz;
 815                 win_sz = minigame_drawcolorcodedstring_wrapped(mySize_x,win_pos,
 816                         sprintf("%s", victory_text),
 817                         winfs, 0, DRAWFLAG_NORMAL, 0.5);
 818
 819                 drawfill(win_pos-eY*hud_fontsize_y,win_sz+2*eY*hud_fontsize_y,'0.3 0.3 1',0.8,DRAWFLAG_ADDITIVE);
 820
 821                 minigame_drawcolorcodedstring_wrapped(mySize_x,win_pos,
 822                         sprintf("%s", victory_text),
 823                         winfs, panel_fg_alpha, DRAWFLAG_NORMAL, 0.5);
 824         }
 825 }
 826
 827
 828 // Required function, draw the game status panel
 829 void bd_hud_status(vector pos, vector mySize)
 830 {
 831         HUD_Panel_DrawBg(1);
 832         vector ts;
 833         ts = minigame_drawstring_wrapped(mySize_x,pos,active_minigame.descriptor.message,
 834                 hud_fontsize * 2, '0.25 0.47 0.72', panel_fg_alpha, DRAWFLAG_NORMAL,0.5);
 835
 836         pos_y += ts_y;
 837         mySize_y -= ts_y;
 838
 839         vector player_fontsize = hud_fontsize * 1.75;
 840         ts_y = ( mySize_y - 2*player_fontsize_y ) / BD_TEAMS;
 841         ts_x = mySize_x;
 842         vector mypos;
 843         vector tile_size = '48 48 0';
 844
 845         mypos = pos;
 846         drawfill(mypos,eX*mySize_x+eY*player_fontsize_y,'1 1 1',0.5,DRAWFLAG_ADDITIVE);
 847         mypos_y += player_fontsize_y;
 848         drawfill(mypos,eX*mySize_x+eY*tile_size_y,'1 1 1',0.25,DRAWFLAG_ADDITIVE);
 849
 850         entity e;
 851         FOREACH_MINIGAME_ENTITY(e)
 852         {
 853                 if ( e.classname == "minigame_player" )
 854                 {
 855                         mypos = pos;
 856                         minigame_drawcolorcodedstring_trunc(mySize_x,mypos,
 857                                 entcs_GetName(e.minigame_playerslot-1),
 858                                 player_fontsize, panel_fg_alpha, DRAWFLAG_NORMAL);
 859
 860                         mypos_y += player_fontsize_y;
 861                         string thepiece = "bd/dozer";
 862                         if(active_minigame.minigame_flags & BD_TURN_EDIT)
 863                                 thepiece = bd_get_tile_pic(bd_curr_tile);
 864                         drawpic( mypos,
 865                                         minigame_texture(thepiece),
 866                                         tile_size * 0.7, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL );
 867
 868                         mypos_x += tile_size_x;
 869
 870                         drawstring(mypos,ftos(e.bd_moves),tile_size,
 871                                            '0.7 0.84 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 872                 }
 873         }
 874 }
 875
 876 // Turn a set of flags into a help message
 877 string bd_turn_to_string(int turnflags)
 878 {
 879         if ( turnflags & BD_TURN_LOSS )
 880                 return _("Better luck next time!");
 881
 882         if ( turnflags & BD_TURN_WIN )
 883                 if(random() > 0.5)
 884                         return _("Tubular! Press \"Next Level\" to continue!");
 885                 else
 886                         return _("Wicked! Press \"Next Level\" to continue!");
 887
 888         if( turnflags & BD_TURN_EDIT )
 889                 return _("Press the space bar to change your currently selected tile");
 890
 891         if ( turnflags & BD_TURN_MOVE )
 892                 return _("Push the boulders onto the targets");
 893
 894         return "";
 895 }
 896
 897 // Make the correct move
 898 void bd_make_move(entity minigame, string dir)
 899 {
 900         if ( minigame.minigame_flags == BD_TURN_MOVE )
 901         {
 902                 minigame_cmd("move ", dir);
 903         }
 904 }
 905
 906 void bd_editor_make_move(entity minigame, string dir)
 907 {
 908         if ( minigame.minigame_flags == BD_TURN_EDIT )
 909         {
 910                 minigame_cmd("move ", bd_curr_pos, " ", ftos(bd_curr_tile), " ", dir);
 911         }
 912 }
 913
 914 void bd_editor_fill(entity minigame)
 915 {
 916         if ( minigame.minigame_flags == BD_TURN_EDIT )
 917         {
 918                 minigame_cmd("fill ", bd_curr_pos, " ", ftos(bd_curr_tile));
 919         }
 920 }
 921
 922 void bd_set_curr_pos(string s)
 923 {
 924         if ( bd_curr_pos )
 925                 strunzone(bd_curr_pos);
 926         if ( s )
 927                 s = strzone(s);
 928         bd_curr_pos = s;
 929 }
 930
 931 bool bd_normal_move(entity minigame, int themove)
 932 {
 933         switch ( themove )
 934         {
 935                 case K_RIGHTARROW:
 936                 case K_KP_RIGHTARROW:
 937                         bd_make_move(minigame, "r");
 938                         return true;
 939                 case K_LEFTARROW:
 940                 case K_KP_LEFTARROW:
 941                         bd_make_move(minigame, "l");
 942                         return true;
 943                 case K_UPARROW:
 944                 case K_KP_UPARROW:
 945                         bd_make_move(minigame, "u");
 946                         return true;
 947                 case K_DOWNARROW:
 948                 case K_KP_DOWNARROW:
 949                         bd_make_move(minigame, "d");
 950                         return true;
 951         }
 952
 953         return false;
 954 }
 955
 956 bool bd_change_dozer_angle(entity minigame)
 957 {
 958         entity dozer = bd_find_piece(minigame, bd_curr_pos, false);
 959         if(!dozer || dozer.bd_tiletype != BD_TILE_DOZER)
 960                 return false;
 961
 962         string thedir = "";
 963         vector dir = dozer.bd_dir;
 964         if(dir.x == 0 && dir.y == 0) { thedir = "r"; }
 965
 966         if(dir.x == 0 && dir.y == 1) { thedir = "r"; }
 967         if(dir.x == 0 && dir.y ==-1) { thedir = "l"; }
 968         if(dir.x ==-1 && dir.y == 0) { thedir = "u"; }
 969         if(dir.x == 1 && dir.y == 0) { thedir = "d"; }
 970
 971         bd_editor_make_move(minigame, thedir);
 972         return true;
 973 }
 974
 975 bool bd_editor_move(entity minigame, int themove)
 976 {
 977         switch ( themove )
 978         {
 979                 case K_RIGHTARROW:
 980                 case K_KP_RIGHTARROW:
 981                         if ( ! bd_curr_pos )
 982                                 bd_set_curr_pos("a3");
 983                         else
 984                                 bd_set_curr_pos(minigame_relative_tile(bd_curr_pos,1,0,BD_NUM_CNT,BD_LET_CNT));
 985                         return true;
 986                 case K_LEFTARROW:
 987                 case K_KP_LEFTARROW:
 988                         if ( ! bd_curr_pos )
 989                                 bd_set_curr_pos("c3");
 990                         else
 991                                 bd_set_curr_pos(minigame_relative_tile(bd_curr_pos,-1,0,BD_NUM_CNT,BD_LET_CNT));
 992                         return true;
 993                 case K_UPARROW:
 994                 case K_KP_UPARROW:
 995                         if ( ! bd_curr_pos )
 996                                 bd_set_curr_pos("a1");
 997                         else
 998                                 bd_set_curr_pos(minigame_relative_tile(bd_curr_pos,0,1,BD_NUM_CNT,BD_LET_CNT));
 999                         return true;
1000                 case K_DOWNARROW:
1001                 case K_KP_DOWNARROW:
1002                         if ( ! bd_curr_pos )
1003                                 bd_set_curr_pos("a3");
1004                         else
1005                                 bd_set_curr_pos(minigame_relative_tile(bd_curr_pos,0,-1,BD_NUM_CNT,BD_LET_CNT));
1006                         return true;
1007                 case K_ENTER:
1008                 case K_KP_ENTER:
1009                         bd_editor_make_move(minigame, "");
1010                         return true;
1011                 case K_SPACE:
1012                         if(bd_change_dozer_angle(minigame))
1013                                 return true;
1014                         bd_curr_tile += 1;
1015                         if(bd_curr_tile > BD_TILE_LAST)
1016                                 bd_curr_tile = 1;
1017                         return true;
1018         }
1019
1020         return false;
1021 }
1022
1023 // Required function, handle client events
1024 int bd_client_event(entity minigame, string event, ...)
1025 {
1026         switch(event)
1027         {
1028                 case "activate":
1029                 {
1030                         minigame.message = bd_turn_to_string(minigame.minigame_flags);
1031                         bd_set_curr_pos("");
1032                         bd_curr_tile = BD_TILE_BRICK1;
1033                         return false;
1034                 }
1035                 case "key_pressed":
1036                 {
1037                         if(minigame.minigame_flags & BD_TURN_MOVE)
1038                         {
1039                                 if(bd_normal_move(minigame, ...(0,int)))
1040                                         return true;
1041                         }
1042
1043                         if(minigame.minigame_flags & BD_TURN_EDIT)
1044                         {
1045                                 if(bd_editor_move(minigame, ...(0,int)))
1046                                         return true;
1047                         }
1048
1049                         return false;
1050                 }
1051                 case "mouse_pressed":
1052                 {
1053                         if(minigame.minigame_flags & BD_TURN_EDIT)
1054                         {
1055                                 if(...(0,int) == K_MOUSE1)
1056                                 {
1057                                         bd_editor_make_move(minigame, "");
1058                                         return true;
1059                                 }
1060
1061                                 if(...(0,int) == K_MOUSE2)
1062                                 {
1063                                         bd_editor_fill(minigame);
1064                                         return true;
1065                                 }
1066                         }
1067
1068                         return false;
1069                 }
1070                 case "mouse_moved":
1071                 {
1072                         if(minigame.minigame_flags & BD_TURN_EDIT)
1073                         {
1074                                 vector mouse_pos = minigame_hud_normalize(mousepos,bd_boardpos,bd_boardsize);
1075                                 bd_set_curr_pos(minigame_tile_name(mouse_pos,BD_LET_CNT,BD_NUM_CNT));
1076                                 if ( ! bd_valid_tile(bd_curr_pos) )
1077                                         bd_set_curr_pos("");
1078                         }
1079                         return true;
1080                 }
1081                 case "network_receive":
1082                 {
1083                         entity sent = ...(0,entity);
1084                         int sf = ...(1,int);
1085                         if ( sent.classname == "minigame" )
1086                         {
1087                                 if ( sf & MINIG_SF_UPDATE )
1088                                 {
1089                                         sent.message = bd_turn_to_string(sent.minigame_flags);
1090                                         //if ( sent.minigame_flags & minigame_self.team )
1091                                                 minigame_prompt();
1092                                 }
1093                         }
1094                         else if(sent.classname == "minigame_board_piece")
1095                         {
1096                                 if(sf & MINIG_SF_UPDATE)
1097                                 {
1098                                         int letter = ReadByte();
1099                                         int number = ReadByte();
1100                                         if(sent.netname) { strunzone(sent.netname); }
1101                                         sent.netname = strzone(minigame_tile_buildname(letter, number));
1102
1103                                         sent.bd_tiletype = ReadByte();
1104
1105                                         int dx = ReadByte();
1106                                         int dy = ReadByte();
1107
1108                                         if(dx == 2) dx = -1;
1109                                         if(dy == 2) dy = -1;
1110
1111                                         sent.bd_dir_x = dx;
1112                                         sent.bd_dir_y = dy;
1113                                         sent.bd_dir_z = 0;
1114                                 }
1115                         }
1116                         else if(sent.classname == "minigame_player" && (sf & BD_SF_PLAYERMOVES))
1117                                 sent.bd_moves = ReadShort(); // make this a byte when possible
1118
1119                         return false;
1120                 }
1121                 case "menu_show":
1122                 {
1123                         HUD_MinigameMenu_CustomEntry(...(0,entity),_("Next Level"),"next");
1124                         HUD_MinigameMenu_CustomEntry(...(0,entity),_("Restart"),"restart");
1125                         HUD_MinigameMenu_CustomEntry(...(0,entity),_("Editor"),"edit");
1126                         HUD_MinigameMenu_CustomEntry(...(0,entity),_("Save"),"save");
1127                         return false;
1128                 }
1129                 case "menu_click":
1130                 {
1131                         if(...(0,string) == "next")
1132                                 minigame_cmd("next");
1133                         if(...(0,string) == "restart")
1134                                 minigame_cmd("restart");
1135                         if(...(0,string) == "edit")
1136                                 minigame_cmd("edit");
1137                         if(...(0,string) == "save")
1138                                 minigame_cmd("save");
1139                         return false;
1140                 }
1141         }
1142
1143         return false;
1144 }
1145
1146 #endif