qcsrc/common/minigames/minigame/bd.qc

   1 REGISTER_MINIGAME(bd, "Bulldozer");
   2
   3 const int BD_TURN_MOVE  = 0x0100; // player must move the bulldozer
   4 const int BD_TURN_WIN   = 0x0200; // victory
   5 const int BD_TURN_LOSS  = 0x0400; // they did it?!
   6 const int BD_TURN_EDIT  = 0x0800; // editing mode
   7 const int BD_TURN_TYPE  = 0x0f00; // turn type mask
   8
   9 const int BD_SF_PLAYERMOVES = MINIG_SF_CUSTOM;
  10
  11 // 240 tiles...
  12 const int BD_LET_CNT = 20;
  13 const int BD_NUM_CNT = 20;
  14
  15 const int BD_TILE_SIZE = 20;
  16
  17 const int BD_TEAMS = 1;
  18
  19 .vector bd_dir;
  20
  21 .int bd_moves;
  22
  23 .string bd_levelname;
  24 .string bd_nextlevel;
  25
  26 #ifdef SVQC
  27 .bool bd_canedit;
  28 #endif
  29
  30 .int bd_tiletype;
  31 const int BD_TILE_DOZER = 1;
  32 const int BD_TILE_TARGET = 2;
  33 const int BD_TILE_BOULDER = 3;
  34 const int BD_TILE_BRICK1 = 4;
  35 const int BD_TILE_BRICK2 = 5;
  36 const int BD_TILE_BRICK3 = 6;
  37 const int BD_TILE_BRICK4 = 7;
  38 const int BD_TILE_BRICK5 = 8;
  39 const int BD_TILE_BRICK6 = 9;
  40 const int BD_TILE_BRICK7 = 10;
  41 const int BD_TILE_BRICK8 = 11;
  42 const int BD_TILE_LAST = 11;
  43
  44 string autocvar_sv_minigames_bulldozer_startlevel = "level1";
  45
  46 // find same game piece given its tile name
  47 entity bd_find_piece(entity minig, string tile, bool check_target)
  48 {
  49         entity e = NULL;
  50         while ( ( e = findentity(e,owner,minig) ) )
  51                 if ( e.classname == "minigame_board_piece" && e.netname == tile && ((check_target) ? e.bd_tiletype == BD_TILE_TARGET : e.bd_tiletype != BD_TILE_TARGET) )
  52                         return e;
  53         return NULL;
  54 }
  55
  56 // check if the tile name is valid (15x15 grid)
  57 bool bd_valid_tile(string tile)
  58 {
  59         if ( !tile )
  60                 return false;
  61         int number = minigame_tile_number(tile);
  62         int letter = minigame_tile_letter(tile);
  63         return 0 <= number && number < BD_NUM_CNT && 0 <= letter && letter < BD_LET_CNT;
  64 }
  65
  66 entity bd_find_dozer(entity minig)
  67 {
  68         entity e = NULL;
  69         while ( ( e = findentity(e,owner,minig) ) )
  70                 if ( e.classname == "minigame_board_piece" && e.bd_tiletype == BD_TILE_DOZER )
  71                         return e;
  72         return NULL;
  73 }
  74
  75 void bd_check_winner(entity minig)
  76 {
  77         int total = 0, valid = 0;
  78         entity e = NULL;
  79         while ( ( e = findentity(e,owner,minig) ) )
  80                 if ( e.classname == "minigame_board_piece" && e.bd_tiletype == BD_TILE_TARGET )
  81                 {
  82                         ++total;
  83                         if(bd_find_piece(minig, e.netname, false).bd_tiletype == BD_TILE_BOULDER)
  84                                 ++valid;
  85                 }
  86
  87         if(valid >= total)
  88         {
  89                 minig.minigame_flags = BD_TURN_WIN;
  90                 minigame_server_sendflags(minig,MINIG_SF_UPDATE);
  91         }
  92 }
  93
  94 bool bd_canfill(int ttype)
  95 {
  96         switch(ttype)
  97         {
  98                 case BD_TILE_BRICK8:
  99                 case BD_TILE_BRICK7:
 100                 case BD_TILE_BRICK6:
 101                 case BD_TILE_BRICK5:
 102                 case BD_TILE_BRICK4:
 103                 case BD_TILE_BRICK3:
 104                 case BD_TILE_BRICK2:
 105                 case BD_TILE_BRICK1: return true;
 106         }
 107
 108         return false;
 109 }
 110
 111 bool bd_move_dozer(entity minigame, entity dozer)
 112 {
 113         if(!dozer.bd_dir_x && !dozer.bd_dir_y)
 114                 return false; // nope!
 115
 116         int myx = minigame_tile_letter(dozer.netname);
 117         int myy = minigame_tile_number(dozer.netname);
 118
 119         myx += dozer.bd_dir_x;
 120         myy += dozer.bd_dir_y;
 121
 122         string newpos = minigame_tile_buildname(myx, myy);
 123         entity hit = bd_find_piece(minigame, newpos, false);
 124
 125         if(!bd_valid_tile(newpos))
 126                 return false;
 127
 128         if(hit)
 129         switch(hit.bd_tiletype)
 130         {
 131                 case BD_TILE_DOZER: // wtf, but let's do this incase
 132                 case BD_TILE_BRICK8:
 133                 case BD_TILE_BRICK7:
 134                 case BD_TILE_BRICK6:
 135                 case BD_TILE_BRICK5:
 136                 case BD_TILE_BRICK4:
 137                 case BD_TILE_BRICK3:
 138                 case BD_TILE_BRICK2:
 139                 case BD_TILE_BRICK1: return false;
 140                 case BD_TILE_BOULDER:
 141                 {
 142                         string testpos;
 143                         int tx = minigame_tile_letter(hit.netname);
 144                         int ty = minigame_tile_number(hit.netname);
 145
 146                         tx += dozer.bd_dir_x;
 147                         ty += dozer.bd_dir_y;
 148
 149                         testpos = minigame_tile_buildname(tx, ty);
 150                         entity testhit = bd_find_piece(minigame, testpos, false);
 151
 152                         if(!bd_valid_tile(testpos) || testhit)
 153                                 return false;
 154
 155                         if(hit.netname) { strunzone(hit.netname); }
 156                         hit.netname = strzone(testpos);
 157                         minigame_server_sendflags(hit,MINIG_SF_UPDATE);
 158                         break;
 159                 }
 160         }
 161
 162         if(dozer.netname) { strunzone(dozer.netname); }
 163         dozer.netname = strzone(newpos);
 164
 165         return true;
 166 }
 167
 168 // make a move
 169 void bd_move(entity minigame, entity player, string dir)
 170 {
 171         if ( minigame.minigame_flags & BD_TURN_MOVE )
 172         if ( dir )
 173         {
 174                 //if ( bd_valid_tile(pos) )
 175                 //if ( bd_find_piece(minigame, pos, false) )
 176                 {
 177                         entity dozer = bd_find_dozer(minigame);
 178                         if(!dozer)
 179                         {
 180                                 LOG_INFO("Dozer wasn't found!\n");
 181                                 return; // should not happen... TODO: end match?
 182                         }
 183
 184                         int dxs = 0, dys = 0;
 185                         string thedir = strtolower(dir);
 186                         if(thedir == "up" || thedir == "u") { dxs = 0; dys = 1; }
 187                         if(thedir == "down" || thedir == "dn" || thedir == "d") { dxs = 0; dys = -1; }
 188                         if(thedir == "left" || thedir == "lt" || thedir == "l") { dxs = -1; dys = 0; }
 189                         if(thedir == "right" || thedir == "rt" || thedir == "r") { dxs = 1; dys = 0; }
 190
 191                         int dx = bound(-1, dxs, 1);
 192                         int dy = bound(-1, dys, 1);
 193
 194                         int moved = 0;
 195                         entity e = NULL;
 196                         while ( ( e = findentity(e,owner,minigame) ) )
 197                                 if ( e.classname == "minigame_board_piece" && e.bd_tiletype == BD_TILE_DOZER )
 198                                 {
 199                                         e.bd_dir_x = dx;
 200                                         e.bd_dir_y = dy;
 201                                         e.bd_dir_z = 0;
 202
 203                                         if(bd_move_dozer(minigame, e))
 204                                                 ++moved;
 205
 206                                         minigame_server_sendflags(e,MINIG_SF_UPDATE); // update anyway
 207                                 }
 208
 209                         if(moved)
 210                                 player.bd_moves++;
 211
 212                         bd_check_winner(minigame);
 213
 214                         minigame_server_sendflags(player,BD_SF_PLAYERMOVES);
 215                         minigame_server_sendflags(minigame,MINIG_SF_UPDATE);
 216                 }
 217         }
 218 }
 219
 220 // editor
 221 void bd_editor_place(entity minigame, entity player, string pos, int thetile, string thedir)
 222 {
 223         if ( minigame.minigame_flags & BD_TURN_EDIT )
 224         if ( pos && thetile )
 225         {
 226                 if ( bd_valid_tile(pos) )
 227                 {
 228                         entity found_piece = bd_find_piece(minigame, pos, false);
 229                         entity targ = bd_find_piece(minigame, pos, true);
 230
 231                         if(found_piece.bd_tiletype == BD_TILE_DOZER && thedir != "")
 232                         {
 233                                 int dxs = 0, dys = 0;
 234                                 string newdir = strtolower(thedir);
 235                                 if(newdir == "up" || newdir == "u") { dxs = 0; dys = 1; }
 236                                 if(newdir == "down" || newdir == "dn" || newdir == "d") { dxs = 0; dys = -1; }
 237                                 if(newdir == "left" || newdir == "lt" || newdir == "l") { dxs = -1; dys = 0; }
 238                                 if(newdir == "right" || newdir == "rt" || newdir == "r") { dxs = 1; dys = 0; }
 239
 240                                 int dx = bound(-1, dxs, 1);
 241                                 int dy = bound(-1, dys, 1);
 242
 243                                 found_piece.bd_dir_x = dx;
 244                                 found_piece.bd_dir_y = dy;
 245                                 found_piece.bd_dir_z = 0;
 246                                 minigame_server_sendflags(found_piece,MINIG_SF_UPDATE); // update anyway
 247                                 return;
 248                         }
 249
 250                         //entity dozer = bd_find_dozer(minigame);
 251                         //if(dozer && thetile == BD_TILE_DOZER && pos != dozer.netname)
 252                                 //return; // nice try
 253
 254                         if(found_piece || (targ && thetile != BD_TILE_BOULDER))
 255                         {
 256                                 entity piece = bd_find_piece(minigame, pos, false);
 257                                 if(!piece) piece = bd_find_piece(minigame, pos, true);
 258                                 if(!piece)
 259                                         return; // how?!
 260
 261                                 if(piece.netname) { strunzone(piece.netname); }
 262                                 delete(piece);
 263                                 minigame_server_sendflags(minigame,MINIG_SF_UPDATE);
 264                                 return;
 265                         }
 266
 267                         entity piece = msle_spawn(minigame,"minigame_board_piece");
 268                         piece.team = 1;
 269                         piece.netname = strzone(pos);
 270                         piece.bd_tiletype = thetile;
 271                         piece.bd_dir = '0 -1 0';
 272                         minigame_server_sendflags(piece,MINIG_SF_UPDATE);
 273
 274                         minigame_server_sendflags(minigame,MINIG_SF_UPDATE);
 275                 }
 276         }
 277 }
 278
 279 void bd_do_move(entity minigame, entity player, string dir, string thetile, string thedir)
 280 {
 281         if(minigame.minigame_flags & BD_TURN_MOVE)
 282                 bd_move(minigame, player, dir);
 283
 284         if(minigame.minigame_flags & BD_TURN_EDIT)
 285                 bd_editor_place(minigame, player, dir, stof(thetile), thedir);
 286 }
 287
 288 void bd_fill_recurse(entity minigame, entity player, int thetype, int letter, int number)
 289 {
 290         string pos = minigame_tile_buildname(letter,number);
 291         if(!bd_valid_tile(pos))
 292                 return;
 293         if(bd_find_piece(minigame, pos, false) || bd_find_piece(minigame, pos, true))
 294                 return;
 295
 296         bd_editor_place(minigame, player, pos, thetype, "");
 297
 298         bd_fill_recurse(minigame, player, thetype, letter - 1, number);
 299         bd_fill_recurse(minigame, player, thetype, letter + 1, number);
 300         bd_fill_recurse(minigame, player, thetype, letter, number - 1);
 301         bd_fill_recurse(minigame, player, thetype, letter, number + 1);
 302 }
 303
 304 void bd_unfill_recurse(entity minigame, entity player, int thetype, int letter, int number)
 305 {
 306         string pos = minigame_tile_buildname(letter,number);
 307         if(!bd_valid_tile(pos))
 308                 return;
 309
 310         entity targ = bd_find_piece(minigame, pos, true);
 311         entity piece = bd_find_piece(minigame, pos, false);
 312
 313         if(targ && thetype == targ.bd_tiletype)
 314         {
 315                 if(targ.netname) { strunzone(targ.netname); }
 316                 delete(targ);
 317         }
 318         else if(piece && thetype == piece.bd_tiletype)
 319         {
 320                 if(piece.netname) { strunzone(piece.netname); }
 321                 delete(piece);
 322         }
 323         else return;
 324
 325         bd_unfill_recurse(minigame, player, thetype, letter - 1, number);
 326         bd_unfill_recurse(minigame, player, thetype, letter + 1, number);
 327         bd_unfill_recurse(minigame, player, thetype, letter, number - 1);
 328         bd_unfill_recurse(minigame, player, thetype, letter, number + 1);
 329 }
 330
 331 void bd_do_fill(entity minigame, entity player, string dir, string thetile)
 332 {
 333 #ifdef SVQC
 334         if(!player.minigame_players.bd_canedit)
 335         {
 336                 sprint(player.minigame_players, "You're not allowed to edit levels, sorry!\n");
 337                 return;
 338         }
 339 #endif
 340
 341         if(minigame.minigame_flags & BD_TURN_EDIT)
 342         {
 343                 int thetype = stof(thetile);
 344
 345                 entity targ = bd_find_piece(minigame, dir, true);
 346                 entity piece = bd_find_piece(minigame, dir, false);
 347
 348                 if(!bd_canfill(thetype) || (piece || targ))
 349                 {
 350                         int killtype = 0;
 351
 352                         if(targ) { killtype = targ.bd_tiletype; }
 353                         if(piece) { killtype = piece.bd_tiletype; }
 354
 355                         if(killtype)
 356                         {
 357                                 int letter = minigame_tile_letter(dir);
 358                                 int number = minigame_tile_number(dir);
 359                                 bd_unfill_recurse(minigame, player, killtype, letter, number);
 360                         }
 361
 362                         return;
 363                 }
 364
 365                 int letter = minigame_tile_letter(dir);
 366                 int number = minigame_tile_number(dir);
 367
 368                 bd_fill_recurse(minigame, player, thetype, letter, number);
 369         }
 370 }
 371
 372 void bd_reset_moves(entity minigame)
 373 {
 374         entity e;
 375 #ifdef SVQC
 376         for(e = minigame.minigame_players; e; e = e.list_next)
 377 #elif defined(CSQC)
 378         e = NULL;
 379         while( (e = findentity(e,owner,minigame)) )
 380                 if ( e.classname == "minigame_player" )
 381 #endif
 382                 {
 383                         e.bd_moves = 0;
 384                         minigame_server_sendflags(e,BD_SF_PLAYERMOVES);
 385                 }
 386 }
 387
 388 void bd_load_level(entity minigame);
 389 void bd_setup_pieces(entity minigame)
 390 {
 391         entity e = NULL;
 392         while( (e = findentity(e, owner, minigame)) )
 393                 if(e.classname == "minigame_board_piece")
 394                 {
 395                         if(e.netname) { strunzone(e.netname); }
 396                         delete(e);
 397                 }
 398
 399         bd_load_level(minigame);
 400 }
 401
 402 void bd_do_next_match(entity minigame, entity player)
 403 {
 404         minigame.minigame_flags = BD_TURN_MOVE;
 405         minigame_server_sendflags(minigame,MINIG_SF_UPDATE);
 406
 407         if(minigame.bd_nextlevel && minigame.bd_nextlevel != "")
 408         {
 409                 if(minigame.bd_levelname) { strunzone(minigame.bd_levelname); }
 410                 minigame.bd_levelname = strzone(minigame.bd_nextlevel);
 411         }
 412
 413         bd_setup_pieces(minigame);
 414
 415         bd_reset_moves(minigame);
 416 }
 417
 418 void bd_set_next_match(entity minigame, string next)
 419 {
 420         if(minigame.bd_nextlevel) { strunzone(minigame.bd_nextlevel); }
 421         minigame.bd_nextlevel = strzone(next);
 422 }
 423
 424 void bd_next_match(entity minigame, entity player, string next)
 425 {
 426         if(minigame.minigame_flags & BD_TURN_WIN)
 427                 bd_do_next_match(minigame, player);
 428         if(minigame.minigame_flags & BD_TURN_EDIT)
 429                 bd_set_next_match(minigame, next);
 430 }
 431
 432 // request a new match
 433 void bd_restart_match(entity minigame, entity player)
 434 {
 435         minigame.minigame_flags = BD_TURN_MOVE;
 436         minigame_server_sendflags(minigame,MINIG_SF_UPDATE);
 437
 438         bd_setup_pieces(minigame);
 439
 440         bd_reset_moves(minigame);
 441 }
 442
 443 void bd_activate_editor(entity minigame, entity player)
 444 {
 445 #ifdef SVQC
 446         if(!player.minigame_players.bd_canedit)
 447         {
 448                 sprint(player.minigame_players, "You're not allowed to edit levels, sorry!\n");
 449                 return;
 450         }
 451 #endif
 452
 453         minigame.minigame_flags = BD_TURN_EDIT;
 454         minigame_server_sendflags(minigame,MINIG_SF_UPDATE);
 455
 456         bd_reset_moves(minigame);
 457
 458         bd_setup_pieces(minigame);
 459 }
 460
 461 string bd_save_piece(entity minigame, entity e)
 462 {
 463         string bd_string = "";
 464
 465         bd_string = strcat(bd_string, "\"", e.netname, "\" ");
 466         bd_string = strcat(bd_string, ftos(e.bd_tiletype), " ");
 467         bd_string = strcat(bd_string, sprintf("\"%.9v\"", e.bd_dir));
 468
 469         return bd_string;
 470 }
 471
 472 void bd_set_nextlevel(entity minigame, string s)
 473 {
 474         tokenize_console(s);
 475
 476         if(minigame.bd_nextlevel) { strunzone(minigame.bd_nextlevel); }
 477         minigame.bd_nextlevel = strzone(argv(2));
 478 }
 479
 480 entity bd_load_piece(entity minigame, string s)
 481 {
 482         // separate pieces between the ; symbols
 483         string bd_string = s;
 484
 485         tokenize_console(bd_string);
 486
 487         entity e = msle_spawn(minigame,"minigame_board_piece");
 488         e.team = 1;
 489         e.bd_dir = '0 -1 0';
 490
 491         int argv_num = 0;
 492         e.netname = strzone(argv(argv_num)); ++argv_num;
 493         e.bd_tiletype = stof(argv(argv_num)); ++argv_num;
 494         e.bd_dir = stov(argv(argv_num)); ++argv_num;
 495
 496         minigame_server_sendflags(e,MINIG_SF_ALL);
 497
 498         return e;
 499 }
 500
 501 bool bd_save_level(entity minigame)
 502 {
 503         if(minigame.bd_levelname && minigame.bd_levelname != "")
 504         {
 505                 int target_count = 0, boulder_count = 0;
 506                 entity piece = NULL;
 507                 while((piece = findentity(piece,owner,minigame)))
 508                 if(piece.classname == "minigame_board_piece")
 509                         if(piece.bd_tiletype == BD_TILE_BOULDER)
 510                                 ++boulder_count;
 511                         else if(piece.bd_tiletype == BD_TILE_TARGET)
 512                                 ++target_count;
 513
 514                 if(boulder_count != target_count)
 515                 {
 516                         LOG_INFO("Not enough targets or boulders, fix your level!\n");
 517                         return false;
 518                 }
 519
 520                 // saves all objects to the database file
 521                 string file_name;
 522                 float file_get;
 523
 524                 file_name = strcat("minigames/bulldozer/storage_", minigame.bd_levelname, ".txt");
 525                 file_get = fopen(file_name, FILE_WRITE);
 526                 fputs(file_get, strcat("// bulldozer storage \"", minigame.bd_levelname, "\" last updated ", strftime(true, "%d-%m-%Y %H:%M:%S"), "\n"));
 527
 528                 if(minigame.bd_nextlevel && minigame.bd_nextlevel != "" && fexists(strcat("minigames/bulldozer/storage_", minigame.bd_nextlevel, ".txt")))
 529                         fputs(file_get, strcat("nextlevel = \"", minigame.bd_nextlevel, "\"\n"));
 530
 531                 entity e = NULL;
 532                 while ( ( e = findentity(e,owner,minigame) ) )
 533                 if ( e.classname == "minigame_board_piece" )
 534                 {
 535                         // use a line of text for each object, listing all properties
 536                         fputs(file_get, strcat(bd_save_piece(minigame, e), "\n"));
 537                 }
 538                 fclose(file_get);
 539
 540                 return true;
 541         }
 542
 543         return false;
 544 }
 545
 546 void bd_load_level(entity minigame)
 547 {
 548         // loads all items from the database file
 549         string file_read, file_name;
 550         float file_get;
 551
 552         file_name = strcat("minigames/bulldozer/storage_", minigame.bd_levelname, ".txt");
 553         file_get = fopen(file_name, FILE_READ);
 554         if(file_get < 0)
 555         {
 556                 LOG_INFO("^3BULLDOZER: ^7could not find storage file ^3", file_name, "^7, no items were loaded\n");
 557         }
 558         else
 559         {
 560                 for(;;)
 561                 {
 562                         file_read = fgets(file_get);
 563                         if(file_read == "")
 564                                 break;
 565                         if(substring(file_read, 0, 2) == "//")
 566                                 continue;
 567                         if(substring(file_read, 0, 1) == "#")
 568                                 continue;
 569                         if(substring(file_read, 0, 9) == "nextlevel")
 570                         {
 571                                 bd_set_nextlevel(minigame, file_read);
 572                                 continue;
 573                         }
 574
 575                         entity e;
 576                         e = bd_load_piece(minigame, file_read);
 577                 }
 578         }
 579         fclose(file_get);
 580 }
 581
 582 void bd_close_editor(entity minigame, entity player)
 583 {
 584 #ifdef SVQC
 585         if(!player.minigame_players.bd_canedit)
 586         {
 587                 sprint(player.minigame_players, "You're not allowed to edit levels, sorry!\n");
 588                 return;
 589         }
 590 #endif
 591
 592         entity dozer = bd_find_dozer(minigame);
 593         if(!dozer)
 594         {
 595                 LOG_INFO("You need to place a bulldozer on the level to save it!\n");
 596                 return;
 597         }
 598
 599         if(bd_save_level(minigame))
 600         {
 601                 minigame.minigame_flags = BD_TURN_MOVE;
 602                 minigame_server_sendflags(minigame,MINIG_SF_UPDATE);
 603         }
 604         else
 605         {
 606                 LOG_INFO("You need to set the level name!\n");
 607                 return;
 608         }
 609 }
 610
 611 #ifdef SVQC
 612
 613 // required function, handle server side events
 614 int bd_server_event(entity minigame, string event, ...)
 615 {
 616         switch(event)
 617         {
 618                 case "start":
 619                 {
 620                         if(minigame.bd_levelname) { strunzone(minigame.bd_levelname); }
 621                         minigame.bd_levelname = strzone(autocvar_sv_minigames_bulldozer_startlevel);
 622                         bd_setup_pieces(minigame);
 623                         minigame.minigame_flags = BD_TURN_MOVE;
 624
 625                         return true;
 626                 }
 627                 case "end":
 628                 {
 629                         entity e = NULL;
 630                         while( (e = findentity(e, owner, minigame)) )
 631                         if(e.classname == "minigame_board_piece")
 632                         {
 633                                 if(e.netname) { strunzone(e.netname); }
 634                                 delete(e);
 635                         }
 636
 637                         if(minigame.bd_nextlevel) { strunzone(minigame.bd_nextlevel); }
 638                         if(minigame.bd_levelname) { strunzone(minigame.bd_levelname); }
 639                         return false;
 640                 }
 641                 case "join":
 642                 {
 643                         int pl_num = minigame_count_players(minigame);
 644
 645                         if(pl_num >= BD_TEAMS) { return false; }
 646
 647                         return 1;
 648                 }
 649                 case "cmd":
 650                 {
 651                         switch(argv(0))
 652                         {
 653                                 case "move":
 654                                         bd_do_move(minigame, ...(0,entity), ((...(1,int)) >= 2 ? argv(1) : string_null), ((...(1,int)) >= 3 ? argv(2) : string_null), ((...(1,int)) >= 4 ? argv(3) : string_null));
 655                                         return true;
 656                                 case "next":
 657                                         bd_next_match(minigame,...(0,entity), ((...(1,int) >= 2 ? argv(1) : string_null)));
 658                                         return true;
 659                                 case "restart":
 660                                         bd_restart_match(minigame,...(0,entity));
 661                                         return true;
 662                                 case "edit":
 663                                         bd_activate_editor(minigame,...(0,entity));
 664                                         return true;
 665                                 case "save":
 666                                         bd_close_editor(minigame,...(0,entity));
 667                                         return true;
 668                                 case "fill":
 669                                         bd_do_fill(minigame, ...(0,entity), ((...(1,int)) >= 2 ? argv(1) : string_null), ((...(1,int)) >= 3 ? argv(2) : string_null));
 670                                         return true;
 671                         }
 672
 673                         return false;
 674                 }
 675                 case "network_send":
 676                 {
 677                         entity sent = ...(0,entity);
 678                         int sf = ...(1,int);
 679                         if ( sent.classname == "minigame_board_piece" && (sf & MINIG_SF_UPDATE) )
 680                         {
 681                                 int letter = minigame_tile_letter(sent.netname);
 682                                 int number = minigame_tile_number(sent.netname);
 683
 684                                 WriteByte(MSG_ENTITY,letter);
 685                                 WriteByte(MSG_ENTITY,number);
 686
 687                                 WriteByte(MSG_ENTITY,sent.bd_tiletype);
 688
 689                                 int dx = sent.bd_dir_x;
 690                                 int dy = sent.bd_dir_y;
 691                                 if(dx == -1) dx = 2;
 692                                 if(dy == -1) dy = 2;
 693                                 WriteByte(MSG_ENTITY,dx);
 694                                 WriteByte(MSG_ENTITY,dy);
 695                         }
 696                         else if(sent.classname == "minigame_player" && (sf & BD_SF_PLAYERMOVES))
 697                                 WriteShort(MSG_ENTITY,sent.bd_moves);
 698                         return false;
 699                 }
 700         }
 701
 702         return false;
 703 }
 704
 705
 706 #elif defined(CSQC)
 707
 708 int bd_curr_tile;
 709 string bd_curr_pos;
 710
 711 .entity bd_enemy;
 712 .bool bd_hide;
 713
 714 vector bd_boardpos; // HUD board position
 715 vector bd_boardsize;// HUD board size
 716
 717 string bd_get_tile_pic(int tileid)
 718 {
 719         switch(tileid)
 720         {
 721                 case BD_TILE_BOULDER: return "bd/boulder";
 722                 case BD_TILE_BRICK1: return "bd/brick1";
 723                 case BD_TILE_BRICK2: return "bd/brick2";
 724                 case BD_TILE_BRICK3: return "bd/brick3";
 725                 case BD_TILE_BRICK4: return "bd/brick4";
 726                 case BD_TILE_BRICK5: return "bd/brick5";
 727                 case BD_TILE_BRICK6: return "bd/brick6";
 728                 case BD_TILE_BRICK7: return "bd/brick7";
 729                 case BD_TILE_BRICK8: return "bd/brick8";
 730                 case BD_TILE_TARGET: return "bd/target";
 731                 case BD_TILE_DOZER: return "bd/dozer";
 732         }
 733
 734         return string_null;
 735 }
 736
 737 // Required function, draw the game board
 738 void bd_hud_board(vector pos, vector mySize)
 739 {
 740         minigame_hud_fitsqare(pos, mySize);
 741         bd_boardpos = pos;
 742         bd_boardsize = mySize;
 743
 744         minigame_hud_simpleboard(pos,mySize,minigame_texture("bd/board"));
 745
 746         vector tile_size = minigame_hud_denormalize_size('1 1 0' / BD_TILE_SIZE,pos,mySize);
 747         vector tile_pos;
 748
 749         entity e;
 750         FOREACH_MINIGAME_ENTITY(e)
 751         {
 752                 if(e.classname == "minigame_board_piece")
 753                 {
 754                         if(e.bd_tiletype == BD_TILE_TARGET)
 755                         {
 756                                 e.bd_enemy = NULL;
 757                                 e.bd_enemy = bd_find_piece(active_minigame, e.netname, false);
 758                         }
 759                         else if(e.bd_tiletype == BD_TILE_BOULDER)
 760                         {
 761                                 e.bd_hide = false; // reset either way
 762                                 e.bd_hide = ((bd_find_piece(active_minigame, e.netname, true)) != NULL);
 763                         }
 764                 }
 765         }
 766         FOREACH_MINIGAME_ENTITY(e)
 767         {
 768                 if ( e.classname == "minigame_board_piece" )
 769                 {
 770                         if(e.bd_tiletype != BD_TILE_DOZER && !e.bd_hide) // hide boulders
 771                         {
 772                                 tile_pos = minigame_tile_pos(e.netname,BD_NUM_CNT,BD_LET_CNT);
 773                                 tile_pos = minigame_hud_denormalize(tile_pos,pos,mySize);
 774
 775                                 string thepiece = bd_get_tile_pic(e.bd_tiletype);
 776
 777                                 if(e.bd_enemy)
 778                                         thepiece = "bd/boulder_target";
 779
 780                                 minigame_drawpic_centered( tile_pos,
 781                                                 minigame_texture(thepiece),
 782                                                 tile_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL );
 783                         }
 784                 }
 785         }
 786
 787         // draw dozers on top, always
 788         FOREACH_MINIGAME_ENTITY(e)
 789         {
 790                 if ( e.classname == "minigame_board_piece" && e.bd_tiletype == BD_TILE_DOZER )
 791                 {
 792                         tile_pos = minigame_tile_pos(e.netname,BD_NUM_CNT,BD_LET_CNT);
 793                         tile_pos = minigame_hud_denormalize(tile_pos,pos,mySize);
 794
 795                         vector thedir = e.bd_dir;
 796                         float theang = 0;
 797
 798                         if(thedir_y == -1) { theang = M_PI; }
 799                         if(thedir_x == 1) { theang = M_PI/2; }
 800                         if(thedir_x == -1) { theang = M_PI*3/2; }
 801
 802                         drawrotpic(tile_pos, theang, minigame_texture("bd/dozer"),
 803                                                 tile_size, tile_size/2, '1 1 1',
 804                                                 panel_fg_alpha, DRAWFLAG_NORMAL );
 805                 }
 806         }
 807
 808         if(active_minigame.minigame_flags & BD_TURN_EDIT)
 809         if(bd_valid_tile(bd_curr_pos))
 810         {
 811                 entity piece = bd_find_piece(active_minigame, bd_curr_pos, false);
 812                 entity targ = bd_find_piece(active_minigame, bd_curr_pos, true);
 813                 string thepiece = ((piece || (targ && bd_curr_tile != BD_TILE_BOULDER)) ? "bd/delete" : bd_get_tile_pic(bd_curr_tile));
 814
 815                 tile_pos = minigame_tile_pos(bd_curr_pos,BD_LET_CNT,BD_NUM_CNT);
 816                 tile_pos = minigame_hud_denormalize(tile_pos,pos,mySize);
 817                 if(bd_curr_tile == BD_TILE_DOZER)
 818                 {
 819                         drawrotpic(tile_pos, M_PI, minigame_texture("bd/dozer"),
 820                                                 tile_size, tile_size/2, '1 1 1',
 821                                                 panel_fg_alpha/2, DRAWFLAG_NORMAL );
 822                 }
 823                 else
 824                 {
 825                         minigame_drawpic_centered( tile_pos,
 826                                         minigame_texture(thepiece),
 827                                         tile_size, '1 1 1', panel_fg_alpha/2, DRAWFLAG_NORMAL );
 828                 }
 829         }
 830
 831         if ( (active_minigame.minigame_flags & BD_TURN_LOSS) || (active_minigame.minigame_flags & BD_TURN_WIN) )
 832         {
 833                 vector winfs = hud_fontsize*2;
 834                 string victory_text = "Game over!";
 835
 836                 if(active_minigame.minigame_flags & BD_TURN_WIN)
 837                         victory_text = "Well done! Click 'Next Level' to continue";
 838
 839                 vector win_pos = pos+eY*(mySize_y-winfs_y)/2;
 840                 vector win_sz;
 841                 win_sz = minigame_drawcolorcodedstring_wrapped(mySize_x,win_pos,
 842                         sprintf("%s", victory_text),
 843                         winfs, 0, DRAWFLAG_NORMAL, 0.5);
 844
 845                 drawfill(win_pos-eY*hud_fontsize_y,win_sz+2*eY*hud_fontsize_y,'0.3 0.3 1',0.8,DRAWFLAG_ADDITIVE);
 846
 847                 minigame_drawcolorcodedstring_wrapped(mySize_x,win_pos,
 848                         sprintf("%s", victory_text),
 849                         winfs, panel_fg_alpha, DRAWFLAG_NORMAL, 0.5);
 850         }
 851 }
 852
 853
 854 // Required function, draw the game status panel
 855 void bd_hud_status(vector pos, vector mySize)
 856 {
 857         HUD_Panel_DrawBg();
 858         vector ts;
 859         ts = minigame_drawstring_wrapped(mySize_x,pos,active_minigame.descriptor.message,
 860                 hud_fontsize * 2, '0.25 0.47 0.72', panel_fg_alpha, DRAWFLAG_NORMAL,0.5);
 861
 862         pos_y += ts_y;
 863         mySize_y -= ts_y;
 864
 865         vector player_fontsize = hud_fontsize * 1.75;
 866         ts_y = ( mySize_y - 2*player_fontsize_y ) / BD_TEAMS;
 867         ts_x = mySize_x;
 868         vector mypos;
 869         vector tile_size = '48 48 0';
 870
 871         mypos = pos;
 872         drawfill(mypos,eX*mySize_x+eY*player_fontsize_y,'1 1 1',0.5,DRAWFLAG_ADDITIVE);
 873         mypos_y += player_fontsize_y;
 874         drawfill(mypos,eX*mySize_x+eY*tile_size_y,'1 1 1',0.25,DRAWFLAG_ADDITIVE);
 875
 876         entity e;
 877         FOREACH_MINIGAME_ENTITY(e)
 878         {
 879                 if ( e.classname == "minigame_player" )
 880                 {
 881                         mypos = pos;
 882                         minigame_drawcolorcodedstring_trunc(mySize_x,mypos,
 883                                 entcs_GetName(e.minigame_playerslot-1),
 884                                 player_fontsize, panel_fg_alpha, DRAWFLAG_NORMAL);
 885
 886                         mypos_y += player_fontsize_y;
 887                         string thepiece = "bd/dozer";
 888                         if(active_minigame.minigame_flags & BD_TURN_EDIT)
 889                                 thepiece = bd_get_tile_pic(bd_curr_tile);
 890                         drawpic( mypos,
 891                                         minigame_texture(thepiece),
 892                                         tile_size * 0.7, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL );
 893
 894                         mypos_x += tile_size_x;
 895
 896                         drawstring(mypos,ftos(e.bd_moves),tile_size,
 897                                            '0.7 0.84 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 898                 }
 899         }
 900 }
 901
 902 // Turn a set of flags into a help message
 903 string bd_turn_to_string(int turnflags)
 904 {
 905         if ( turnflags & BD_TURN_LOSS )
 906                 return _("Better luck next time!");
 907
 908         if ( turnflags & BD_TURN_WIN )
 909                 if(random() > 0.5)
 910                         return _("Tubular! Press \"Next Level\" to continue!");
 911                 else
 912                         return _("Wicked! Press \"Next Level\" to continue!");
 913
 914         if( turnflags & BD_TURN_EDIT )
 915                 return _("Press the space bar to change your currently selected tile");
 916
 917         if ( turnflags & BD_TURN_MOVE )
 918                 return _("Push the boulders onto the targets");
 919
 920         return "";
 921 }
 922
 923 // Make the correct move
 924 void bd_make_move(entity minigame, string dir)
 925 {
 926         if ( minigame.minigame_flags == BD_TURN_MOVE )
 927         {
 928                 minigame_cmd("move ", dir);
 929         }
 930 }
 931
 932 void bd_editor_make_move(entity minigame, string dir)
 933 {
 934         if ( minigame.minigame_flags == BD_TURN_EDIT )
 935         {
 936                 minigame_cmd("move ", bd_curr_pos, " ", ftos(bd_curr_tile), " ", dir);
 937         }
 938 }
 939
 940 void bd_editor_fill(entity minigame)
 941 {
 942         if ( minigame.minigame_flags == BD_TURN_EDIT )
 943         {
 944                 minigame_cmd("fill ", bd_curr_pos, " ", ftos(bd_curr_tile));
 945         }
 946 }
 947
 948 void bd_set_curr_pos(string s)
 949 {
 950         if ( bd_curr_pos )
 951                 strunzone(bd_curr_pos);
 952         if ( s )
 953                 s = strzone(s);
 954         bd_curr_pos = s;
 955 }
 956
 957 bool bd_normal_move(entity minigame, int themove)
 958 {
 959         switch ( themove )
 960         {
 961                 case K_RIGHTARROW:
 962                 case K_KP_RIGHTARROW:
 963                         bd_make_move(minigame, "r");
 964                         return true;
 965                 case K_LEFTARROW:
 966                 case K_KP_LEFTARROW:
 967                         bd_make_move(minigame, "l");
 968                         return true;
 969                 case K_UPARROW:
 970                 case K_KP_UPARROW:
 971                         bd_make_move(minigame, "u");
 972                         return true;
 973                 case K_DOWNARROW:
 974                 case K_KP_DOWNARROW:
 975                         bd_make_move(minigame, "d");
 976                         return true;
 977         }
 978
 979         return false;
 980 }
 981
 982 bool bd_change_dozer_angle(entity minigame)
 983 {
 984         entity dozer = bd_find_piece(minigame, bd_curr_pos, false);
 985         if(!dozer || dozer.bd_tiletype != BD_TILE_DOZER)
 986                 return false;
 987
 988         string thedir = "";
 989         vector dir = dozer.bd_dir;
 990         if(dir.x == 0 && dir.y == 0) { thedir = "r"; }
 991
 992         if(dir.x == 0 && dir.y == 1) { thedir = "r"; }
 993         if(dir.x == 0 && dir.y ==-1) { thedir = "l"; }
 994         if(dir.x ==-1 && dir.y == 0) { thedir = "u"; }
 995         if(dir.x == 1 && dir.y == 0) { thedir = "d"; }
 996
 997         bd_editor_make_move(minigame, thedir);
 998         return true;
 999 }
1000
1001 bool bd_editor_move(entity minigame, int themove)
1002 {
1003         switch ( themove )
1004         {
1005                 case K_RIGHTARROW:
1006                 case K_KP_RIGHTARROW:
1007                         if ( ! bd_curr_pos )
1008                                 bd_set_curr_pos("a3");
1009                         else
1010                                 bd_set_curr_pos(minigame_relative_tile(bd_curr_pos,1,0,BD_NUM_CNT,BD_LET_CNT));
1011                         return true;
1012                 case K_LEFTARROW:
1013                 case K_KP_LEFTARROW:
1014                         if ( ! bd_curr_pos )
1015                                 bd_set_curr_pos("c3");
1016                         else
1017                                 bd_set_curr_pos(minigame_relative_tile(bd_curr_pos,-1,0,BD_NUM_CNT,BD_LET_CNT));
1018                         return true;
1019                 case K_UPARROW:
1020                 case K_KP_UPARROW:
1021                         if ( ! bd_curr_pos )
1022                                 bd_set_curr_pos("a1");
1023                         else
1024                                 bd_set_curr_pos(minigame_relative_tile(bd_curr_pos,0,1,BD_NUM_CNT,BD_LET_CNT));
1025                         return true;
1026                 case K_DOWNARROW:
1027                 case K_KP_DOWNARROW:
1028                         if ( ! bd_curr_pos )
1029                                 bd_set_curr_pos("a3");
1030                         else
1031                                 bd_set_curr_pos(minigame_relative_tile(bd_curr_pos,0,-1,BD_NUM_CNT,BD_LET_CNT));
1032                         return true;
1033                 case K_ENTER:
1034                 case K_KP_ENTER:
1035                         bd_editor_make_move(minigame, "");
1036                         return true;
1037                 case K_SPACE:
1038                         if(bd_change_dozer_angle(minigame))
1039                                 return true;
1040                         bd_curr_tile += 1;
1041                         if(bd_curr_tile > BD_TILE_LAST)
1042                                 bd_curr_tile = 1;
1043                         return true;
1044         }
1045
1046         return false;
1047 }
1048
1049 // Required function, handle client events
1050 int bd_client_event(entity minigame, string event, ...)
1051 {
1052         switch(event)
1053         {
1054                 case "activate":
1055                 {
1056                         minigame.message = bd_turn_to_string(minigame.minigame_flags);
1057                         bd_set_curr_pos("");
1058                         bd_curr_tile = BD_TILE_BRICK1;
1059                         return false;
1060                 }
1061                 case "key_pressed":
1062                 {
1063                         if(minigame.minigame_flags & BD_TURN_MOVE)
1064                         {
1065                                 if(bd_normal_move(minigame, ...(0,int)))
1066                                         return true;
1067                         }
1068
1069                         if(minigame.minigame_flags & BD_TURN_EDIT)
1070                         {
1071                                 if(bd_editor_move(minigame, ...(0,int)))
1072                                         return true;
1073                         }
1074
1075                         return false;
1076                 }
1077                 case "mouse_pressed":
1078                 {
1079                         if(minigame.minigame_flags & BD_TURN_EDIT)
1080                         {
1081                                 if(...(0,int) == K_MOUSE1)
1082                                 {
1083                                         bd_editor_make_move(minigame, "");
1084                                         return true;
1085                                 }
1086
1087                                 if(...(0,int) == K_MOUSE2)
1088                                 {
1089                                         bd_editor_fill(minigame);
1090                                         return true;
1091                                 }
1092                         }
1093
1094                         return false;
1095                 }
1096                 case "mouse_moved":
1097                 {
1098                         if(minigame.minigame_flags & BD_TURN_EDIT)
1099                         {
1100                                 vector mouse_pos = minigame_hud_normalize(mousepos,bd_boardpos,bd_boardsize);
1101                                 bd_set_curr_pos(minigame_tile_name(mouse_pos,BD_LET_CNT,BD_NUM_CNT));
1102                                 if ( ! bd_valid_tile(bd_curr_pos) )
1103                                         bd_set_curr_pos("");
1104                         }
1105                         return true;
1106                 }
1107                 case "network_receive":
1108                 {
1109                         entity sent = ...(0,entity);
1110                         int sf = ...(1,int);
1111                         if ( sent.classname == "minigame" )
1112                         {
1113                                 if ( sf & MINIG_SF_UPDATE )
1114                                 {
1115                                         sent.message = bd_turn_to_string(sent.minigame_flags);
1116                                         //if ( sent.minigame_flags & minigame_self.team )
1117                                                 minigame_prompt();
1118                                 }
1119                         }
1120                         else if(sent.classname == "minigame_board_piece")
1121                         {
1122                                 if(sf & MINIG_SF_UPDATE)
1123                                 {
1124                                         int letter = ReadByte();
1125                                         int number = ReadByte();
1126                                         if(sent.netname) { strunzone(sent.netname); }
1127                                         sent.netname = strzone(minigame_tile_buildname(letter, number));
1128
1129                                         sent.bd_tiletype = ReadByte();
1130
1131                                         int dx = ReadByte();
1132                                         int dy = ReadByte();
1133
1134                                         if(dx == 2) dx = -1;
1135                                         if(dy == 2) dy = -1;
1136
1137                                         sent.bd_dir_x = dx;
1138                                         sent.bd_dir_y = dy;
1139                                         sent.bd_dir_z = 0;
1140                                 }
1141                         }
1142                         else if(sent.classname == "minigame_player" && (sf & BD_SF_PLAYERMOVES))
1143                                 sent.bd_moves = ReadShort(); // make this a byte when possible
1144
1145                         return false;
1146                 }
1147                 case "menu_show":
1148                 {
1149                         HUD_MinigameMenu_CustomEntry(...(0,entity),_("Next Level"),"next");
1150                         HUD_MinigameMenu_CustomEntry(...(0,entity),_("Restart"),"restart");
1151                         HUD_MinigameMenu_CustomEntry(...(0,entity),_("Editor"),"edit");
1152                         HUD_MinigameMenu_CustomEntry(...(0,entity),_("Save"),"save");
1153                         return false;
1154                 }
1155                 case "menu_click":
1156                 {
1157                         if(...(0,string) == "next")
1158                                 minigame_cmd("next");
1159                         if(...(0,string) == "restart")
1160                                 minigame_cmd("restart");
1161                         if(...(0,string) == "edit")
1162                                 minigame_cmd("edit");
1163                         if(...(0,string) == "save")
1164                                 minigame_cmd("save");
1165                         return false;
1166                 }
1167         }
1168
1169         return false;
1170 }
1171
1172 #endif