qcsrc/common/minigames/minigame/snake.qc

   1 REGISTER_MINIGAME(snake, "Snake");
   2
   3 const float SNAKE_TURN_MOVE  = 0x0100; // the snake is moving, player must control it
   4 const float SNAKE_TURN_LOSS  = 0x0200; // they did it?!
   5 const float SNAKE_TURN_WAIT  = 0x0400; // the snake is waiting for the player to make their first move and begin the game
   6 const float SNAKE_TURN_TYPE  = 0x0f00; // turn type mask
   7
   8 const int SNAKE_SF_PLAYERSCORE = MINIG_SF_CUSTOM;
   9
  10 const int SNAKE_LET_CNT = 15;
  11 const int SNAKE_NUM_CNT = 15;
  12
  13 const int SNAKE_TILE_SIZE = 15;
  14
  15 bool autocvar_sv_minigames_snake_wrap = false;
  16 float autocvar_sv_minigames_snake_delay_initial = 0.7;
  17 float autocvar_sv_minigames_snake_delay_multiplier = 50;
  18 float autocvar_sv_minigames_snake_delay_min = 0.1;
  19
  20 .int snake_score;
  21 .entity snake_head;
  22
  23 .float snake_delay;
  24 .float snake_nextmove;
  25 .vector snake_dir;
  26
  27 // find same game piece given its tile name
  28 entity snake_find_piece(entity minig, string tile)
  29 {
  30         entity e = world;
  31         while ( ( e = findentity(e,owner,minig) ) )
  32                 if ( e.classname == "minigame_board_piece" && e.netname == tile )
  33                         return e;
  34         return world;
  35 }
  36
  37 // find same game piece given its cnt
  38 entity snake_find_cnt(entity minig, int tile)
  39 {
  40         entity e = world;
  41         while ( ( e = findentity(e,owner,minig) ) )
  42                 if ( e.classname == "minigame_board_piece" && e.cnt == tile )
  43                         return e;
  44         return world;
  45 }
  46
  47 // check if the tile name is valid (15x15 grid)
  48 bool snake_valid_tile(string tile)
  49 {
  50         if ( !tile )
  51                 return false;
  52         int number = minigame_tile_number(tile);
  53         int letter = minigame_tile_letter(tile);
  54         return 0 <= number && number < SNAKE_NUM_CNT && 0 <= letter && letter < SNAKE_LET_CNT;
  55 }
  56
  57 void snake_new_mouse(entity minigame)
  58 {
  59         RandomSelection_Init();
  60         int i, j;
  61         for(i = 0; i < SNAKE_LET_CNT; ++i)
  62         for(j = 0; j < SNAKE_NUM_CNT; ++j)
  63         {
  64                 string pos = minigame_tile_buildname(i, j);
  65                 if(!snake_find_piece(minigame, pos))
  66                         RandomSelection_Add(world, 0, pos, 1, 1);
  67         }
  68
  69         entity piece = msle_spawn(minigame,"minigame_board_piece");
  70         piece.team = 1;
  71         piece.netname = strzone(RandomSelection_chosen_string);
  72         minigame_server_sendflags(piece,MINIG_SF_ALL);
  73
  74         minigame_server_sendflags(minigame,MINIG_SF_UPDATE);
  75 }
  76
  77 void snake_setup_pieces(entity minigame)
  78 {
  79         int targnum = bound(1, floor(random() * SNAKE_NUM_CNT), SNAKE_NUM_CNT - 1);
  80         int targlet = bound(1, floor(random() * SNAKE_LET_CNT), SNAKE_LET_CNT - 1);
  81
  82         entity piece = msle_spawn(minigame,"minigame_board_piece");
  83         piece.team = 1; // init default team?
  84         piece.netname = strzone(minigame_tile_buildname(targlet,targnum));
  85         piece.cnt = 1;
  86         minigame_server_sendflags(piece,MINIG_SF_ALL);
  87
  88         minigame.snake_head = piece;
  89
  90         snake_new_mouse(minigame);
  91
  92         minigame_server_sendflags(minigame,MINIG_SF_UPDATE);
  93 }
  94
  95 void snake_add_score(entity minigame, int thescore)
  96 {
  97 #ifdef SVQC
  98         if(!minigame)
  99                 return;
 100         if(minigame.minigame_players)
 101         {
 102                 minigame.minigame_players.snake_score += thescore;
 103                 minigame.minigame_players.SendFlags |= SNAKE_SF_PLAYERSCORE;
 104         }
 105 #endif
 106 }
 107
 108 void snake_move_body(entity minigame, bool ate_mouse)
 109 {
 110         entity tail = world;
 111         string tailpos = string_null;
 112         vector taildir = '0 0 0';
 113
 114         int i, pieces = 0;
 115         for(i = (SNAKE_NUM_CNT * SNAKE_LET_CNT); i >= 2; --i)
 116         {
 117                 entity piece = snake_find_cnt(minigame, i);
 118                 entity nextpiece = snake_find_cnt(minigame, i - 1);
 119                 if(!piece)
 120                         continue;
 121
 122                 pieces++;
 123
 124                 if(!tail)
 125                 {
 126                         tail = piece;
 127                         tailpos = piece.netname;
 128                         taildir = piece.snake_dir;
 129                 }
 130
 131                 if(piece.netname) { strunzone(piece.netname); }
 132                 piece.netname = strzone(nextpiece.netname);
 133                 piece.snake_dir = nextpiece.snake_dir;
 134                 minigame_server_sendflags(piece, MINIG_SF_ALL);
 135         }
 136
 137         // just a head
 138         if(!pieces)
 139         {
 140                 tail = minigame.snake_head;
 141                 tailpos = minigame.snake_head.netname;
 142                 taildir = minigame.snake_head.snake_dir;
 143         }
 144
 145         if(tail && ate_mouse)
 146         {
 147                 int newcnt = tail.cnt + 1;
 148                 minigame.snake_delay = max(autocvar_sv_minigames_snake_delay_min, autocvar_sv_minigames_snake_delay_initial - (newcnt / autocvar_sv_minigames_snake_delay_multiplier));
 149                 snake_add_score(minigame, 1);
 150
 151                 entity piece = msle_spawn(minigame,"minigame_board_piece");
 152                 piece.cnt = newcnt;
 153                 piece.team = 1;
 154                 piece.snake_dir = taildir;
 155                 piece.netname = strzone(tailpos);
 156                 minigame_server_sendflags(piece,MINIG_SF_ALL);
 157
 158                 minigame_server_sendflags(minigame,MINIG_SF_UPDATE);
 159         }
 160 }
 161
 162 void snake_move_head(entity minigame)
 163 {
 164         entity head = minigame.snake_head;
 165         string newpos;
 166
 167         if(autocvar_sv_minigames_snake_wrap)
 168                 newpos = minigame_relative_tile(head.netname, minigame.snake_dir_x, minigame.snake_dir_y, SNAKE_NUM_CNT, SNAKE_LET_CNT);
 169         else
 170         {
 171                 int myx = minigame_tile_letter(head.netname);
 172                 int myy = minigame_tile_number(head.netname);
 173
 174                 myx += minigame.snake_dir_x;
 175                 myy += minigame.snake_dir_y;
 176
 177                 newpos = minigame_tile_buildname(myx, myy);
 178         }
 179
 180         if(!snake_valid_tile(newpos) || (snake_find_piece(minigame, newpos)).cnt)
 181         {
 182                 minigame.minigame_flags = SNAKE_TURN_LOSS;
 183                 minigame_server_sendflags(minigame,MINIG_SF_UPDATE);
 184                 return;
 185         }
 186
 187         bool ate_mouse = false;
 188         entity piece = snake_find_piece(minigame, newpos);
 189         if(piece && !piece.cnt)
 190                 ate_mouse = true;
 191
 192         // move the body first, then set the new head position?
 193         snake_move_body(minigame, ate_mouse);
 194
 195         if(ate_mouse)
 196         {
 197                 if(piece.netname) { strunzone(piece.netname); }
 198                 remove(piece);
 199
 200                 snake_new_mouse(minigame);
 201         }
 202
 203         if(head.netname) { strunzone(head.netname); }
 204         head.netname = strzone(newpos);
 205         minigame_server_sendflags(head,MINIG_SF_ALL);
 206 }
 207
 208 // make a move
 209 void snake_move(entity minigame, entity player, string dxs, string dys )
 210 {
 211         if ( (minigame.minigame_flags & SNAKE_TURN_MOVE) || (minigame.minigame_flags & SNAKE_TURN_WAIT) )
 212         if ( dxs || dys )
 213         {
 214                 //if ( snake_valid_tile(pos) )
 215                 //if ( snake_find_piece(minigame, pos) )
 216                 {
 217                         int dx = ((dxs) ? bound(-1, stof(dxs), 1) : 0);
 218                         int dy = ((dys) ? bound(-1, stof(dys), 1) : 0);
 219
 220                         int myl = minigame_tile_letter(minigame.snake_head.netname);
 221                         int myn = minigame_tile_number(minigame.snake_head.netname);
 222
 223                         entity head = snake_find_piece(minigame, minigame_tile_buildname(myl + dx, myn + dy));
 224                         if(head && head.cnt == 2)
 225                                 return; // nope!
 226
 227                         if(minigame.minigame_flags & SNAKE_TURN_WAIT)
 228                                 minigame.snake_nextmove = time;
 229                         minigame.minigame_flags = SNAKE_TURN_MOVE;
 230                         minigame.snake_dir_x = dx;
 231                         minigame.snake_dir_y = dy;
 232                         minigame.snake_dir_z = 0;
 233                         minigame.snake_head.snake_dir = minigame.snake_dir;
 234                         minigame_server_sendflags(minigame.snake_head,MINIG_SF_UPDATE);
 235                         minigame_server_sendflags(minigame,MINIG_SF_UPDATE);
 236                 }
 237         }
 238 }
 239
 240 #ifdef SVQC
 241
 242
 243 // required function, handle server side events
 244 int snake_server_event(entity minigame, string event, ...)
 245 {
 246         switch(event)
 247         {
 248                 case "start":
 249                 {
 250                         snake_setup_pieces(minigame);
 251                         minigame.snake_delay = autocvar_sv_minigames_snake_delay_initial;
 252                         minigame.minigame_flags = SNAKE_TURN_WAIT;
 253                         return true;
 254                 }
 255                 case "end":
 256                 {
 257                         entity e = world;
 258                         while( (e = findentity(e, owner, minigame)) )
 259                         if(e.classname == "minigame_board_piece")
 260                         {
 261                                 if(e.netname) { strunzone(e.netname); }
 262                                 remove(e);
 263                         }
 264                         minigame.snake_head = world;
 265                         return false;
 266                 }
 267                 case "join":
 268                 {
 269                         int pl_num = minigame_count_players(minigame);
 270
 271                         // Don't allow more than 1 player
 272                         // not sure if this should be a multiplayer game (might get crazy)
 273                         if(pl_num >= 1) { return false; }
 274
 275                         // Team 1 by default
 276                         return 1;
 277                 }
 278                 case "frame":
 279                 {
 280                         if(minigame.minigame_flags & SNAKE_TURN_MOVE)
 281                         if(time >= minigame.snake_nextmove)
 282                         {
 283                                 snake_move_head(minigame);
 284                                 minigame.snake_nextmove = time + minigame.snake_delay;
 285                         }
 286                         return false;
 287                 }
 288                 case "cmd":
 289                 {
 290                         switch(argv(0))
 291                         {
 292                                 case "move":
 293                                         snake_move(minigame, ...(0,entity), ((...(1,int)) >= 2 ? argv(1) : string_null), ((...(1,int)) == 3 ? argv(2) : string_null));
 294                                         return true;
 295                         }
 296
 297                         return false;
 298                 }
 299                 case "network_send":
 300                 {
 301                         entity sent = ...(0,entity);
 302                         int sf = ...(1,int);
 303                         if ( sent.classname == "minigame_board_piece" && (sf & MINIG_SF_UPDATE) )
 304                         {
 305                                 WriteByte(MSG_ENTITY,sent.cnt);
 306                                 WriteCoord(MSG_ENTITY,sent.snake_dir_x);
 307                                 WriteCoord(MSG_ENTITY,sent.snake_dir_y);
 308                         }
 309                         else if ( sent.classname == "minigame_player" && (sf & SNAKE_SF_PLAYERSCORE ) )
 310                         {
 311                                 WriteLong(MSG_ENTITY,sent.snake_score);
 312                         }
 313                         else if ( sent.classname == "minigame" && (sf & MINIG_SF_UPDATE ) )
 314                         {
 315                                 WriteByte(MSG_ENTITY,autocvar_sv_minigames_snake_wrap);
 316                         }
 317                         return false;
 318                 }
 319         }
 320
 321         return false;
 322 }
 323
 324
 325 #elif defined(CSQC)
 326
 327 vector snake_boardpos; // HUD board position
 328 vector snake_boardsize;// HUD board size
 329
 330 bool snake_wrap;
 331
 332 // Required function, draw the game board
 333 void snake_hud_board(vector pos, vector mySize)
 334 {
 335         minigame_hud_fitsqare(pos, mySize);
 336         snake_boardpos = pos;
 337         snake_boardsize = mySize;
 338
 339         minigame_hud_simpleboard(pos,mySize,minigame_texture("snake/board"));
 340
 341         vector tile_size = minigame_hud_denormalize_size('1 1 0' / SNAKE_TILE_SIZE,pos,mySize);
 342         vector tile_pos;
 343
 344         entity tail = world;
 345         int i;
 346         for(i = (SNAKE_NUM_CNT * SNAKE_LET_CNT); i >= 2; --i)
 347         {
 348                 entity piece = snake_find_cnt(active_minigame, i);
 349                 if(piece)
 350                 {
 351                         tail = piece;
 352                         break;
 353                 }
 354         }
 355
 356         entity e;
 357         FOREACH_MINIGAME_ENTITY(e)
 358         {
 359                 if ( e.classname == "minigame_board_piece" )
 360                 {
 361                         tile_pos = minigame_tile_pos(e.netname,SNAKE_NUM_CNT,SNAKE_LET_CNT);
 362                         tile_pos = minigame_hud_denormalize(tile_pos,pos,mySize);
 363                         string thepiece = "snake/mouse";
 364                         if(e.cnt)
 365                                 thepiece = "snake/body";
 366                         if(tail && e.cnt == tail.cnt)
 367                                 thepiece = "snake/tail";
 368                         if(e.cnt == 1)
 369                         {
 370                                 int dx = minigame_tile_letter(e.netname) + e.snake_dir_x * 2;
 371                                 int dy = minigame_tile_number(e.netname) + e.snake_dir_y * 2;
 372                                 entity mouse = snake_find_piece(active_minigame, minigame_tile_buildname(dx, dy));
 373                                 thepiece = "snake/head";
 374                                 if(mouse && !mouse.cnt)
 375                                 {
 376                                         float myang = 0;
 377                                         int myx = minigame_tile_letter(e.netname);
 378                                         int myy = minigame_tile_number(e.netname);
 379                                         if(myx - 2 == dx)
 380                                                 myang = M_PI*3/2;
 381                                         if(myx + 2 == dx)
 382                                                 myang = M_PI/2;
 383                                         if(myy - 2 == dy)
 384                                                 myang = M_PI;
 385
 386                                         int newx = minigame_tile_letter(e.netname) + e.snake_dir_x;
 387                                         int newy = minigame_tile_number(e.netname) + e.snake_dir_y;
 388                                         string newpos = minigame_tile_buildname(newx, newy);
 389
 390                                         vector my_pos = minigame_tile_pos(newpos,SNAKE_NUM_CNT,SNAKE_LET_CNT);
 391                                         my_pos = minigame_hud_denormalize(my_pos,pos,mySize);
 392
 393                                         drawrotpic(my_pos, myang, minigame_texture("snake/tongue"),
 394                                                         tile_size, tile_size/2, '1 1 1',
 395                                                         panel_fg_alpha, DRAWFLAG_NORMAL );
 396                                 }
 397                         }
 398
 399                         if(e.cnt == 1 || e.cnt == tail.cnt)
 400                         {
 401                                 vector thedir = e.snake_dir;
 402                                 float theang = 0;
 403                                 if(e.cnt == tail.cnt)
 404                                 {
 405                                         int thex = minigame_tile_letter(e.netname);
 406                                         int they = minigame_tile_number(e.netname);
 407                                         entity t = snake_find_cnt(active_minigame, e.cnt - 1);
 408                                         int tx = minigame_tile_letter(t.netname);
 409                                         int ty = minigame_tile_number(t.netname);
 410
 411                                         if(thex - 1 == tx)
 412                                         {
 413                                                 thedir_y = 0;
 414                                                 thedir_x = -1;
 415                                         }
 416                                         if(they + 1 == ty)
 417                                         {
 418                                                 thedir_x = 0;
 419                                                 thedir_y = 1;
 420                                         }
 421                                         if(they - 1 == ty)
 422                                         {
 423                                                 thedir_x = 0;
 424                                                 thedir_y = -1;
 425                                         }
 426                                 }
 427
 428                                 if(thedir_y == -1)
 429                                         theang = M_PI;
 430                                 if(thedir_x == 1)
 431                                         theang = M_PI/2;
 432                                 if(thedir_x == -1)
 433                                         theang = M_PI*3/2;
 434
 435                                 drawrotpic(tile_pos, theang, minigame_texture(thepiece),
 436                                                         tile_size, tile_size/2, '1 1 1',
 437                                                         panel_fg_alpha, DRAWFLAG_NORMAL );
 438                         }
 439                         else
 440                         {
 441                                 minigame_drawpic_centered( tile_pos,
 442                                                 minigame_texture(thepiece),
 443                                                 tile_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL );
 444                         }
 445                 }
 446         }
 447
 448         if ( active_minigame.minigame_flags & SNAKE_TURN_LOSS )
 449         {
 450                 int scores = 0;
 451                 FOREACH_MINIGAME_ENTITY(e)
 452                         if(e.classname == "minigame_player")
 453                                 scores = e.snake_score;
 454
 455                 vector winfs = hud_fontsize*2;
 456                 string scores_text;
 457                 scores_text = strcat("Score: ", ftos(scores));
 458
 459                 vector win_pos = pos+eY*(mySize_y-winfs_y)/2;
 460                 vector win_sz;
 461                 win_sz = minigame_drawcolorcodedstring_wrapped(mySize_x,win_pos,
 462                         sprintf("Game over! %s", scores_text),
 463                         winfs, 0, DRAWFLAG_NORMAL, 0.5);
 464
 465                 drawfill(win_pos-eY*hud_fontsize_y,win_sz+2*eY*hud_fontsize_y,'0.3 0.3 1',0.8,DRAWFLAG_ADDITIVE);
 466
 467                 minigame_drawcolorcodedstring_wrapped(mySize_x,win_pos,
 468                         sprintf("Game over! %s", scores_text),
 469                         winfs, panel_fg_alpha, DRAWFLAG_NORMAL, 0.5);
 470         }
 471 }
 472
 473
 474 // Required function, draw the game status panel
 475 void snake_hud_status(vector pos, vector mySize)
 476 {
 477         HUD_Panel_DrawBg(1);
 478         vector ts;
 479         ts = minigame_drawstring_wrapped(mySize_x,pos,active_minigame.descriptor.message,
 480                 hud_fontsize * 2, '0.25 0.47 0.72', panel_fg_alpha, DRAWFLAG_NORMAL,0.5);
 481
 482         pos_y += ts_y;
 483         mySize_y -= ts_y;
 484
 485         vector player_fontsize = hud_fontsize * 1.75;
 486         ts_y = ( mySize_y - 2*player_fontsize_y ) / 2;
 487         ts_x = mySize_x;
 488         vector mypos;
 489         vector tile_size = '48 48 0';
 490
 491         mypos = pos;
 492         drawfill(mypos,eX*mySize_x+eY*player_fontsize_y,'1 1 1',0.5,DRAWFLAG_ADDITIVE);
 493         mypos_y += player_fontsize_y;
 494         drawfill(mypos,eX*mySize_x+eY*tile_size_y,'1 1 1',0.25,DRAWFLAG_ADDITIVE);
 495
 496         entity e;
 497         FOREACH_MINIGAME_ENTITY(e)
 498         {
 499                 if ( e.classname == "minigame_player" )
 500                 {
 501                         mypos = pos;
 502                         minigame_drawcolorcodedstring_trunc(mySize_x,mypos,
 503                                 GetPlayerName(e.minigame_playerslot-1),
 504                                 player_fontsize, panel_fg_alpha, DRAWFLAG_NORMAL);
 505
 506                         mypos_y += player_fontsize_y;
 507                         //drawpic( mypos,
 508                         //              minigame_texture("snake/piece"),
 509                         //              tile_size, '1 0 0', panel_fg_alpha, DRAWFLAG_NORMAL );
 510
 511                         //mypos_x += tile_size_x;
 512
 513                         drawstring(mypos,ftos(e.snake_score),tile_size,
 514                                            '0.7 0.84 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 515                 }
 516         }
 517 }
 518
 519 // Turn a set of flags into a help message
 520 string snake_turn_to_string(int turnflags)
 521 {
 522         if ( turnflags & SNAKE_TURN_LOSS )
 523                 return _("Game over!");
 524
 525         if ( turnflags & SNAKE_TURN_WAIT )
 526                 return _("Press an arrow key to begin the game");
 527
 528         if ( turnflags & SNAKE_TURN_MOVE )
 529                 if(snake_wrap)
 530                         return _("Avoid the snake's body, collect the mice!");
 531                 else
 532                         return _("Avoid the screen edges and the snake's body, collect the mice!");
 533
 534         return "";
 535 }
 536
 537 // Make the correct move
 538 void snake_set_direction(entity minigame, int dx, int dy)
 539 {
 540         //if ( minigame.minigame_flags == SNAKE_TURN_MOVE )
 541         //{
 542                 minigame_cmd("move ",ftos(dx), " ", ftos(dy));
 543         //}
 544 }
 545
 546 // Required function, handle client events
 547 int snake_client_event(entity minigame, string event, ...)
 548 {
 549         switch(event)
 550         {
 551                 case "activate":
 552                 {
 553                         minigame.message = snake_turn_to_string(minigame.minigame_flags);
 554                         return false;
 555                 }
 556                 case "key_pressed":
 557                 {
 558                         //if((minigame.minigame_flags & SNAKE_TURN_TEAM) == minigame_self.team)
 559                         {
 560                                 switch ( ...(0,int) )
 561                                 {
 562                                         case K_RIGHTARROW:
 563                                         case K_KP_RIGHTARROW:
 564                                                 snake_set_direction(minigame, 1, 0);
 565                                                 return true;
 566                                         case K_LEFTARROW:
 567                                         case K_KP_LEFTARROW:
 568                                                 snake_set_direction(minigame, -1, 0);
 569                                                 return true;
 570                                         case K_UPARROW:
 571                                         case K_KP_UPARROW:
 572                                                 snake_set_direction(minigame, 0, 1);
 573                                                 return true;
 574                                         case K_DOWNARROW:
 575                                         case K_KP_DOWNARROW:
 576                                                 snake_set_direction(minigame, 0, -1);
 577                                                 return true;
 578                                 }
 579                         }
 580
 581                         return false;
 582                 }
 583                 case "network_receive":
 584                 {
 585                         entity sent = ...(0,entity);
 586                         int sf = ...(1,int);
 587                         if ( sent.classname == "minigame" )
 588                         {
 589                                 if ( sf & MINIG_SF_UPDATE )
 590                                 {
 591                                         snake_wrap = ReadByte();
 592                                         sent.message = snake_turn_to_string(sent.minigame_flags);
 593                                         //if ( sent.minigame_flags & minigame_self.team )
 594                                                 minigame_prompt();
 595                                 }
 596                         }
 597                         else if(sent.classname == "minigame_board_piece")
 598                         {
 599                                 if(sf & MINIG_SF_UPDATE)
 600                                 {
 601                                         sent.cnt = ReadByte();
 602                                         sent.snake_dir_x = ReadCoord();
 603                                         sent.snake_dir_y = ReadCoord();
 604                                         sent.snake_dir_z = 0;
 605                                         if(sent.cnt == 1)
 606                                                 minigame.snake_head = sent; // hax
 607                                 }
 608                         }
 609                         else if ( sent.classname == "minigame_player" && (sf & SNAKE_SF_PLAYERSCORE ) )
 610                         {
 611                                 sent.snake_score = ReadLong();
 612                         }
 613
 614                         return false;
 615                 }
 616         }
 617
 618         return false;
 619 }
 620
 621 #endif