qcsrc/common/monsters/monster/shambler.qc

   1 #ifndef SHAMBLER_H
   2 #define SHAMBLER_H
   3
   4 #ifndef MENUQC
   5 MODEL(MON_SHAMBLER, "models/monsters/shambler.mdl");
   6 #endif
   7
   8 CLASS(Shambler, Monster)
   9     ATTRIB(Shambler, spawnflags, int, MONSTER_SIZE_BROKEN | MON_FLAG_SUPERMONSTER | MON_FLAG_MELEE | MON_FLAG_RANGED);
  10     ATTRIB(Shambler, mins, vector, '-41 -41 -31');
  11     ATTRIB(Shambler, maxs, vector, '41 41 65');
  12 #ifndef MENUQC
  13     ATTRIB(Shambler, m_model, Model, MDL_MON_SHAMBLER);
  14 #endif
  15     ATTRIB(Shambler, netname, string, "shambler");
  16     ATTRIB(Shambler, monster_name, string, _("Shambler"));
  17 ENDCLASS(Shambler)
  18
  19 REGISTER_MONSTER(SHAMBLER, NEW(Shambler)) {
  20 #ifndef MENUQC
  21     this.mr_precache(this);
  22 #endif
  23 }
  24
  25 #endif
  26
  27 #ifdef IMPLEMENTATION
  28
  29 #ifdef SVQC
  30 float autocvar_g_monster_shambler_health;
  31 float autocvar_g_monster_shambler_damageforcescale = 0.1;
  32 float autocvar_g_monster_shambler_attack_smash_damage;
  33 float autocvar_g_monster_shambler_attack_smash_range;
  34 float autocvar_g_monster_shambler_attack_claw_damage;
  35 float autocvar_g_monster_shambler_attack_lightning_damage;
  36 float autocvar_g_monster_shambler_attack_lightning_damage_zap = 15;
  37 float autocvar_g_monster_shambler_attack_lightning_force;
  38 float autocvar_g_monster_shambler_attack_lightning_radius;
  39 float autocvar_g_monster_shambler_attack_lightning_radius_zap;
  40 float autocvar_g_monster_shambler_attack_lightning_speed;
  41 float autocvar_g_monster_shambler_attack_lightning_speed_up;
  42 float autocvar_g_monster_shambler_speed_stop;
  43 float autocvar_g_monster_shambler_speed_run;
  44 float autocvar_g_monster_shambler_speed_walk;
  45
  46 /*
  47 const float shambler_anim_stand         = 0;
  48 const float shambler_anim_walk          = 1;
  49 const float shambler_anim_run           = 2;
  50 const float shambler_anim_smash         = 3;
  51 const float shambler_anim_swingr        = 4;
  52 const float shambler_anim_swingl        = 5;
  53 const float shambler_anim_magic         = 6;
  54 const float shambler_anim_pain          = 7;
  55 const float shambler_anim_death         = 8;
  56 */
  57
  58 .float shambler_lastattack; // delay attacks separately
  59
  60 void M_Shambler_Attack_Smash()
  61 {SELFPARAM();
  62         makevectors(self.angles);
  63         Send_Effect(EFFECT_EXPLOSION_MEDIUM, (self.origin + (v_forward * 150)) - ('0 0 1' * self.maxs.z), '0 0 0', 1);
  64         sound(self, CH_SHOTS, SND_ROCKET_IMPACT, VOL_BASE, ATTEN_NORM);
  65
  66         // RadiusDamage does NOT support custom starting location, which means we must use this hack...
  67
  68         tracebox(self.origin + v_forward * 50, self.mins * 0.5, self.maxs * 0.5, self.origin + v_forward * autocvar_g_monster_shambler_attack_smash_range, MOVE_NORMAL, self);
  69
  70         if(trace_ent.takedamage)
  71                 Damage(trace_ent, self, self, (autocvar_g_monster_shambler_attack_smash_damage) * MONSTER_SKILLMOD(self), DEATH_MONSTER_SHAMBLER_SMASH, trace_ent.origin, normalize(trace_ent.origin - self.origin));
  72 }
  73
  74 void M_Shambler_Attack_Swing()
  75 {SELFPARAM();
  76         float r = (random() < 0.5);
  77         if(r && Monster_Attack_Melee(self.enemy, (autocvar_g_monster_shambler_attack_claw_damage), ((r) ? self.anim_melee2 : self.anim_melee3), self.attack_range, 0.8, DEATH_MONSTER_SHAMBLER_CLAW, true))
  78         {
  79                 Monster_Delay(1, 0, 0.5, M_Shambler_Attack_Swing);
  80                 self.attack_finished_single += 0.5;
  81                 self.anim_finished = self.attack_finished_single;
  82         }
  83 }
  84
  85 void M_Shambler_Attack_Lightning_Explode()
  86 {SELFPARAM();
  87         entity head;
  88
  89         sound(self, CH_SHOTS, SND_ELECTRO_IMPACT, VOL_BASE, ATTEN_NORM);
  90         Send_Effect(EFFECT_ELECTRO_IMPACT, '0 0 0', '0 0 0', 1);
  91
  92         self.event_damage = func_null;
  93         self.takedamage = DAMAGE_NO;
  94         self.movetype = MOVETYPE_NONE;
  95         self.velocity = '0 0 0';
  96
  97         if(self.movetype == MOVETYPE_NONE)
  98                 self.velocity = self.oldvelocity;
  99
 100         RadiusDamage (self, self.realowner, (autocvar_g_monster_shambler_attack_lightning_damage), (autocvar_g_monster_shambler_attack_lightning_damage), (autocvar_g_monster_shambler_attack_lightning_radius), world, world, (autocvar_g_monster_shambler_attack_lightning_force), self.projectiledeathtype, other);
 101
 102         for(head = findradius(self.origin, (autocvar_g_monster_shambler_attack_lightning_radius_zap)); head; head = head.chain) if(head != self.realowner) if(head.takedamage)
 103         {
 104                 te_csqc_lightningarc(self.origin, head.origin);
 105                 Damage(head, self, self.realowner, (autocvar_g_monster_shambler_attack_lightning_damage_zap) * MONSTER_SKILLMOD(self), DEATH_MONSTER_SHAMBLER_ZAP, head.origin, '0 0 0');
 106         }
 107
 108         self.think = SUB_Remove;
 109         self.nextthink = time + 0.2;
 110 }
 111
 112 void M_Shambler_Attack_Lightning_Damage(entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
 113 {SELFPARAM();
 114         if (self.health <= 0)
 115                 return;
 116
 117         if (!W_CheckProjectileDamage(inflictor.realowner, self.realowner, deathtype, -1)) // no exceptions
 118                 return; // g_projectiles_damage says to halt
 119
 120         self.health = self.health - damage;
 121
 122         if (self.health <= 0)
 123                 W_PrepareExplosionByDamage(attacker, self.use);
 124 }
 125
 126 void M_Shambler_Attack_Lightning_Touch()
 127 {SELFPARAM();
 128         PROJECTILE_TOUCH;
 129
 130         self.use ();
 131 }
 132
 133 void M_Shambler_Attack_Lightning_Think()
 134 {SELFPARAM();
 135         self.nextthink = time;
 136         if (time > self.cnt)
 137         {
 138                 other = world;
 139                 M_Shambler_Attack_Lightning_Explode();
 140                 return;
 141         }
 142 }
 143
 144 void M_Shambler_Attack_Lightning()
 145 {SELFPARAM();
 146         entity gren;
 147
 148         monster_makevectors(self.enemy);
 149
 150         gren = spawn ();
 151         gren.owner = gren.realowner = self;
 152         gren.classname = "grenade";
 153         gren.bot_dodge = true;
 154         gren.bot_dodgerating = (autocvar_g_monster_shambler_attack_lightning_damage);
 155         gren.movetype = MOVETYPE_BOUNCE;
 156         PROJECTILE_MAKETRIGGER(gren);
 157         gren.projectiledeathtype = DEATH_MONSTER_SHAMBLER_ZAP;
 158         setorigin(gren, CENTER_OR_VIEWOFS(self));
 159         setsize(gren, '-8 -8 -8', '8 8 8');
 160         gren.scale = 2.5;
 161
 162         gren.cnt = time + 5;
 163         gren.nextthink = time;
 164         gren.think = M_Shambler_Attack_Lightning_Think;
 165         gren.use = M_Shambler_Attack_Lightning_Explode;
 166         gren.touch = M_Shambler_Attack_Lightning_Touch;
 167
 168         gren.takedamage = DAMAGE_YES;
 169         gren.health = 50;
 170         gren.damageforcescale = 0;
 171         gren.event_damage = M_Shambler_Attack_Lightning_Damage;
 172         gren.damagedbycontents = true;
 173         gren.missile_flags = MIF_SPLASH | MIF_ARC;
 174         W_SetupProjVelocity_Explicit(gren, v_forward, v_up, (autocvar_g_monster_shambler_attack_lightning_speed), (autocvar_g_monster_shambler_attack_lightning_speed_up), 0, 0, false);
 175
 176         gren.angles = vectoangles (gren.velocity);
 177         gren.flags = FL_PROJECTILE;
 178
 179         CSQCProjectile(gren, true, PROJECTILE_SHAMBLER_LIGHTNING, true);
 180 }
 181
 182 float M_Shambler_Attack(float attack_type, entity targ)
 183 {SELFPARAM();
 184         switch(attack_type)
 185         {
 186                 case MONSTER_ATTACK_MELEE:
 187                 {
 188                         M_Shambler_Attack_Swing();
 189                         return true;
 190                 }
 191                 case MONSTER_ATTACK_RANGED:
 192                 {
 193                         float randomness = random(), enemy_len = vlen(self.enemy.origin - self.origin);
 194
 195                         if(time >= self.shambler_lastattack) // shambler doesn't attack much
 196                         if(self.flags & FL_ONGROUND)
 197                         if(randomness <= 0.5 && enemy_len <= autocvar_g_monster_shambler_attack_smash_range)
 198                         {
 199                                 setanim(self, self.anim_melee2, true, true, false);
 200                                 Monster_Delay(1, 0, 0.7, M_Shambler_Attack_Smash);
 201                                 self.attack_finished_single = time + 1.1;
 202                                 self.anim_finished = time + 1.1;
 203                                 self.state = MONSTER_ATTACK_MELEE; // kinda a melee attack
 204                                 self.shambler_lastattack = time + 3 + random() * 1.5;
 205                                 return true;
 206                         }
 207                         else if(randomness <= 0.1 && enemy_len >= autocvar_g_monster_shambler_attack_smash_range * 1.5) // small chance, don't want this spammed
 208                         {
 209                                 setanim(self, self.anim_shoot, true, true, false);
 210                                 self.state = MONSTER_ATTACK_MELEE; // maybe we should rename this to something more general
 211                                 self.attack_finished_single = time + 1.1;
 212                                 self.anim_finished = 1.1;
 213                                 self.shambler_lastattack = time + 3 + random() * 1.5;
 214                                 Monster_Delay(1, 0, 0.6, M_Shambler_Attack_Lightning);
 215                                 return true;
 216                         }
 217
 218                         return false;
 219                 }
 220         }
 221
 222         return false;
 223 }
 224
 225 spawnfunc(monster_shambler) { Monster_Spawn(MON_SHAMBLER.monsterid); }
 226 #endif // SVQC
 227
 228                 #ifdef SVQC
 229                 METHOD(Shambler, mr_think, bool(Shambler thismon))
 230                 {
 231                         return true;
 232                 }
 233                 METHOD(Shambler, mr_pain, bool(Shambler thismon))
 234                 {
 235                         SELFPARAM();
 236                         self.pain_finished = time + 0.5;
 237                         setanim(self, self.anim_pain1, true, true, false);
 238                         return true;
 239                 }
 240                 METHOD(Shambler, mr_death, bool(Shambler thismon))
 241                 {
 242                         SELFPARAM();
 243                         setanim(self, self.anim_die1, false, true, true);
 244                         return true;
 245                 }
 246                 #endif
 247                 #ifndef MENUQC
 248                 METHOD(Shambler, mr_anim, bool(Shambler thismon))
 249                 {
 250                         SELFPARAM();
 251                         vector none = '0 0 0';
 252                         self.anim_die1 = animfixfps(self, '8 1 0.5', none); // 2 seconds
 253                         self.anim_walk = animfixfps(self, '1 1 1', none);
 254                         self.anim_idle = animfixfps(self, '0 1 1', none);
 255                         self.anim_pain1 = animfixfps(self, '7 1 2', none); // 0.5 seconds
 256                         self.anim_melee1 = animfixfps(self, '3 1 5', none); // analyze models and set framerate
 257                         self.anim_melee2 = animfixfps(self, '4 1 5', none); // analyze models and set framerate
 258                         self.anim_melee3 = animfixfps(self, '5 1 5', none); // analyze models and set framerate
 259                         self.anim_shoot = animfixfps(self, '6 1 5', none); // analyze models and set framerate
 260                         self.anim_run = animfixfps(self, '2 1 1', none);
 261
 262                         return true;
 263                 }
 264                 #endif
 265                 #ifdef SVQC
 266                 METHOD(Shambler, mr_setup, bool(Shambler thismon))
 267                 {
 268                         SELFPARAM();
 269                         if(!self.health) self.health = (autocvar_g_monster_shambler_health);
 270                         if(!self.attack_range) self.attack_range = 150;
 271                         if(!self.speed) { self.speed = (autocvar_g_monster_shambler_speed_walk); }
 272                         if(!self.speed2) { self.speed2 = (autocvar_g_monster_shambler_speed_run); }
 273                         if(!self.stopspeed) { self.stopspeed = (autocvar_g_monster_shambler_speed_stop); }
 274                         if(!self.damageforcescale) { self.damageforcescale = (autocvar_g_monster_shambler_damageforcescale); }
 275
 276                         self.monster_loot = spawnfunc_item_health_mega;
 277                         self.weapon = WEP_ELECTRO.m_id; // matches attacks better than WEP_VORTEX
 278
 279                         setanim(self, self.anim_shoot, false, true, true);
 280                         self.spawn_time = self.animstate_endtime;
 281                         self.spawnshieldtime = self.spawn_time;
 282                         self.monster_attackfunc = M_Shambler_Attack;
 283
 284                         return true;
 285                 }
 286                 METHOD(Shambler, mr_precache, bool(Shambler thismon))
 287                 {
 288                         return true;
 289                 }
 290                 #endif
 291
 292 #endif