qcsrc/common/monsters/monster/shambler.qc

   1 #ifndef MENUQC
   2 bool M_Shambler(int);
   3 #endif
   4 REGISTER_MONSTER_SIMPLE(
   5 /* MON_##id   */ SHAMBLER,
   6 /* spawnflags */ MONSTER_SIZE_BROKEN | MON_FLAG_SUPERMONSTER | MON_FLAG_MELEE | MON_FLAG_RANGED,
   7 /* mins,maxs  */ '-41 -41 -31', '41 41 65',
   8 /* model      */ "shambler.mdl",
   9 /* netname    */ "shambler",
  10 /* fullname   */ _("Shambler")
  11 ) {
  12 #ifndef MENUQC
  13         this.monster_func = M_Shambler;
  14         this.monster_func(MR_PRECACHE);
  15 #endif
  16 }
  17
  18 #ifdef SVQC
  19 float autocvar_g_monster_shambler_health;
  20 float autocvar_g_monster_shambler_damageforcescale = 0.1;
  21 float autocvar_g_monster_shambler_attack_smash_damage;
  22 float autocvar_g_monster_shambler_attack_smash_range;
  23 float autocvar_g_monster_shambler_attack_claw_damage;
  24 float autocvar_g_monster_shambler_attack_lightning_damage;
  25 float autocvar_g_monster_shambler_attack_lightning_damage_zap = 15;
  26 float autocvar_g_monster_shambler_attack_lightning_force;
  27 float autocvar_g_monster_shambler_attack_lightning_radius;
  28 float autocvar_g_monster_shambler_attack_lightning_radius_zap;
  29 float autocvar_g_monster_shambler_attack_lightning_speed;
  30 float autocvar_g_monster_shambler_attack_lightning_speed_up;
  31 float autocvar_g_monster_shambler_speed_stop;
  32 float autocvar_g_monster_shambler_speed_run;
  33 float autocvar_g_monster_shambler_speed_walk;
  34
  35 /*
  36 const float shambler_anim_stand         = 0;
  37 const float shambler_anim_walk          = 1;
  38 const float shambler_anim_run           = 2;
  39 const float shambler_anim_smash         = 3;
  40 const float shambler_anim_swingr        = 4;
  41 const float shambler_anim_swingl        = 5;
  42 const float shambler_anim_magic         = 6;
  43 const float shambler_anim_pain          = 7;
  44 const float shambler_anim_death         = 8;
  45 */
  46
  47 .float shambler_lastattack; // delay attacks separately
  48
  49 void M_Shambler_Attack_Smash()
  50 {SELFPARAM();
  51         makevectors(self.angles);
  52         Send_Effect(EFFECT_EXPLOSION_MEDIUM, (self.origin + (v_forward * 150)) - ('0 0 1' * self.maxs.z), '0 0 0', 1);
  53         sound(self, CH_SHOTS, W_Sound("rocket_impact"), VOL_BASE, ATTEN_NORM);
  54
  55         // RadiusDamage does NOT support custom starting location, which means we must use this hack...
  56
  57         tracebox(self.origin + v_forward * 50, self.mins * 0.5, self.maxs * 0.5, self.origin + v_forward * autocvar_g_monster_shambler_attack_smash_range, MOVE_NORMAL, self);
  58
  59         if(trace_ent.takedamage)
  60                 Damage(trace_ent, self, self, (autocvar_g_monster_shambler_attack_smash_damage) * MONSTER_SKILLMOD(self), DEATH_MONSTER_SHAMBLER_SMASH, trace_ent.origin, normalize(trace_ent.origin - self.origin));
  61 }
  62
  63 void M_Shambler_Attack_Swing()
  64 {SELFPARAM();
  65         float r = (random() < 0.5);
  66         if(r && Monster_Attack_Melee(self.enemy, (autocvar_g_monster_shambler_attack_claw_damage), ((r) ? self.anim_melee2 : self.anim_melee3), self.attack_range, 0.8, DEATH_MONSTER_SHAMBLER_CLAW, true))
  67         {
  68                 Monster_Delay(1, 0, 0.5, M_Shambler_Attack_Swing);
  69                 self.attack_finished_single += 0.5;
  70                 self.anim_finished = self.attack_finished_single;
  71         }
  72 }
  73
  74 void M_Shambler_Attack_Lightning_Explode()
  75 {SELFPARAM();
  76         entity head;
  77
  78         sound(self, CH_SHOTS, W_Sound("electro_impact"), VOL_BASE, ATTEN_NORM);
  79         Send_Effect(EFFECT_ELECTRO_IMPACT, '0 0 0', '0 0 0', 1);
  80
  81         self.event_damage = func_null;
  82         self.takedamage = DAMAGE_NO;
  83         self.movetype = MOVETYPE_NONE;
  84         self.velocity = '0 0 0';
  85
  86         if(self.movetype == MOVETYPE_NONE)
  87                 self.velocity = self.oldvelocity;
  88
  89         RadiusDamage (self, self.realowner, (autocvar_g_monster_shambler_attack_lightning_damage), (autocvar_g_monster_shambler_attack_lightning_damage), (autocvar_g_monster_shambler_attack_lightning_radius), world, world, (autocvar_g_monster_shambler_attack_lightning_force), self.projectiledeathtype, other);
  90
  91         for(head = findradius(self.origin, (autocvar_g_monster_shambler_attack_lightning_radius_zap)); head; head = head.chain) if(head != self.realowner) if(head.takedamage)
  92         {
  93                 te_csqc_lightningarc(self.origin, head.origin);
  94                 Damage(head, self, self.realowner, (autocvar_g_monster_shambler_attack_lightning_damage_zap) * MONSTER_SKILLMOD(self), DEATH_MONSTER_SHAMBLER_ZAP, head.origin, '0 0 0');
  95         }
  96
  97         self.think = SUB_Remove;
  98         self.nextthink = time + 0.2;
  99 }
 100
 101 void M_Shambler_Attack_Lightning_Damage(entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
 102 {SELFPARAM();
 103         if (self.health <= 0)
 104                 return;
 105
 106         if (!W_CheckProjectileDamage(inflictor.realowner, self.realowner, deathtype, -1)) // no exceptions
 107                 return; // g_projectiles_damage says to halt
 108
 109         self.health = self.health - damage;
 110
 111         if (self.health <= 0)
 112                 W_PrepareExplosionByDamage(attacker, self.use);
 113 }
 114
 115 void M_Shambler_Attack_Lightning_Touch()
 116 {SELFPARAM();
 117         PROJECTILE_TOUCH;
 118
 119         self.use ();
 120 }
 121
 122 void M_Shambler_Attack_Lightning_Think()
 123 {SELFPARAM();
 124         self.nextthink = time;
 125         if (time > self.cnt)
 126         {
 127                 other = world;
 128                 M_Shambler_Attack_Lightning_Explode();
 129                 return;
 130         }
 131 }
 132
 133 void M_Shambler_Attack_Lightning()
 134 {SELFPARAM();
 135         entity gren;
 136
 137         monster_makevectors(self.enemy);
 138
 139         gren = spawn ();
 140         gren.owner = gren.realowner = self;
 141         gren.classname = "grenade";
 142         gren.bot_dodge = true;
 143         gren.bot_dodgerating = (autocvar_g_monster_shambler_attack_lightning_damage);
 144         gren.movetype = MOVETYPE_BOUNCE;
 145         PROJECTILE_MAKETRIGGER(gren);
 146         gren.projectiledeathtype = DEATH_MONSTER_SHAMBLER_ZAP;
 147         setorigin(gren, CENTER_OR_VIEWOFS(self));
 148         setsize(gren, '-8 -8 -8', '8 8 8');
 149         gren.scale = 2.5;
 150
 151         gren.cnt = time + 5;
 152         gren.nextthink = time;
 153         gren.think = M_Shambler_Attack_Lightning_Think;
 154         gren.use = M_Shambler_Attack_Lightning_Explode;
 155         gren.touch = M_Shambler_Attack_Lightning_Touch;
 156
 157         gren.takedamage = DAMAGE_YES;
 158         gren.health = 50;
 159         gren.damageforcescale = 0;
 160         gren.event_damage = M_Shambler_Attack_Lightning_Damage;
 161         gren.damagedbycontents = true;
 162         gren.missile_flags = MIF_SPLASH | MIF_ARC;
 163         W_SetupProjVelocity_Explicit(gren, v_forward, v_up, (autocvar_g_monster_shambler_attack_lightning_speed), (autocvar_g_monster_shambler_attack_lightning_speed_up), 0, 0, false);
 164
 165         gren.angles = vectoangles (gren.velocity);
 166         gren.flags = FL_PROJECTILE;
 167
 168         CSQCProjectile(gren, true, PROJECTILE_SHAMBLER_LIGHTNING, true);
 169 }
 170
 171 float M_Shambler_Attack(float attack_type)
 172 {SELFPARAM();
 173         switch(attack_type)
 174         {
 175                 case MONSTER_ATTACK_MELEE:
 176                 {
 177                         M_Shambler_Attack_Swing();
 178                         return true;
 179                 }
 180                 case MONSTER_ATTACK_RANGED:
 181                 {
 182                         float randomness = random(), enemy_len = vlen(self.enemy.origin - self.origin);
 183
 184                         if(time >= self.shambler_lastattack) // shambler doesn't attack much
 185                         if(self.flags & FL_ONGROUND)
 186                         if(randomness <= 0.5 && enemy_len <= autocvar_g_monster_shambler_attack_smash_range)
 187                         {
 188                                 setanim(self, self.anim_melee2, true, true, false);
 189                                 Monster_Delay(1, 0, 0.7, M_Shambler_Attack_Smash);
 190                                 self.attack_finished_single = time + 1.1;
 191                                 self.anim_finished = time + 1.1;
 192                                 self.state = MONSTER_ATTACK_MELEE; // kinda a melee attack
 193                                 self.shambler_lastattack = time + 3 + random() * 1.5;
 194                                 return true;
 195                         }
 196                         else if(randomness <= 0.1 && enemy_len >= autocvar_g_monster_shambler_attack_smash_range * 1.5) // small chance, don't want this spammed
 197                         {
 198                                 setanim(self, self.anim_shoot, true, true, false);
 199                                 self.state = MONSTER_ATTACK_MELEE; // maybe we should rename this to something more general
 200                                 self.attack_finished_single = time + 1.1;
 201                                 self.anim_finished = 1.1;
 202                                 self.shambler_lastattack = time + 3 + random() * 1.5;
 203                                 Monster_Delay(1, 0, 0.6, M_Shambler_Attack_Lightning);
 204                                 return true;
 205                         }
 206
 207                         return false;
 208                 }
 209         }
 210
 211         return false;
 212 }
 213
 214 void spawnfunc_monster_shambler() { Monster_Spawn(MON_SHAMBLER.monsterid); }
 215 #endif // SVQC
 216
 217 bool M_Shambler(int req)
 218 {SELFPARAM();
 219         switch(req)
 220         {
 221                 #ifdef SVQC
 222                 case MR_THINK:
 223                 {
 224                         return true;
 225                 }
 226                 case MR_PAIN:
 227                 {
 228                         self.pain_finished = time + 0.5;
 229                         setanim(self, self.anim_pain1, true, true, false);
 230                         return true;
 231                 }
 232                 case MR_DEATH:
 233                 {
 234                         setanim(self, self.anim_die1, false, true, true);
 235                         return true;
 236                 }
 237                 #endif
 238                 #ifndef MENUQC
 239                 case MR_ANIM:
 240                 {
 241                         vector none = '0 0 0';
 242                         self.anim_die1 = animfixfps(self, '8 1 0.5', none); // 2 seconds
 243                         self.anim_walk = animfixfps(self, '1 1 1', none);
 244                         self.anim_idle = animfixfps(self, '0 1 1', none);
 245                         self.anim_pain1 = animfixfps(self, '7 1 2', none); // 0.5 seconds
 246                         self.anim_melee1 = animfixfps(self, '3 1 5', none); // analyze models and set framerate
 247                         self.anim_melee2 = animfixfps(self, '4 1 5', none); // analyze models and set framerate
 248                         self.anim_melee3 = animfixfps(self, '5 1 5', none); // analyze models and set framerate
 249                         self.anim_shoot = animfixfps(self, '6 1 5', none); // analyze models and set framerate
 250                         self.anim_run = animfixfps(self, '2 1 1', none);
 251
 252                         return true;
 253                 }
 254                 #endif
 255                 #ifdef SVQC
 256                 case MR_SETUP:
 257                 {
 258                         if(!self.health) self.health = (autocvar_g_monster_shambler_health);
 259                         if(!self.attack_range) self.attack_range = 150;
 260                         if(!self.speed) { self.speed = (autocvar_g_monster_shambler_speed_walk); }
 261                         if(!self.speed2) { self.speed2 = (autocvar_g_monster_shambler_speed_run); }
 262                         if(!self.stopspeed) { self.stopspeed = (autocvar_g_monster_shambler_speed_stop); }
 263                         if(!self.damageforcescale) { self.damageforcescale = (autocvar_g_monster_shambler_damageforcescale); }
 264
 265                         self.monster_loot = spawnfunc_item_health_mega;
 266                         self.weapon = WEP_ELECTRO.m_id; // matches attacks better than WEP_VORTEX
 267
 268                         setanim(self, self.anim_shoot, false, true, true);
 269                         self.spawn_time = self.animstate_endtime;
 270                         self.spawnshieldtime = self.spawn_time;
 271                         self.monster_attackfunc = M_Shambler_Attack;
 272
 273                         return true;
 274                 }
 275                 case MR_PRECACHE:
 276                 {
 277                         return true;
 278                 }
 279                 #endif
 280         }
 281
 282         return true;
 283 }