qcsrc/common/monsters/monster/zombie.qc

   1 #include "zombie.qh"
   2
   3 #ifdef IMPLEMENTATION
   4
   5 #ifdef SVQC
   6 float autocvar_g_monster_zombie_health;
   7 float autocvar_g_monster_zombie_damageforcescale = 0.55;
   8 float autocvar_g_monster_zombie_attack_melee_damage;
   9 float autocvar_g_monster_zombie_attack_melee_delay;
  10 float autocvar_g_monster_zombie_attack_leap_damage;
  11 float autocvar_g_monster_zombie_attack_leap_force;
  12 float autocvar_g_monster_zombie_attack_leap_speed;
  13 float autocvar_g_monster_zombie_attack_leap_delay;
  14 float autocvar_g_monster_zombie_speed_stop;
  15 float autocvar_g_monster_zombie_speed_run;
  16 float autocvar_g_monster_zombie_speed_walk;
  17
  18 /*
  19 const float zombie_anim_attackleap                      = 0;
  20 const float zombie_anim_attackrun1                      = 1;
  21 const float zombie_anim_attackrun2                      = 2;
  22 const float zombie_anim_attackrun3                      = 3;
  23 const float zombie_anim_attackstanding1         = 4;
  24 const float zombie_anim_attackstanding2         = 5;
  25 const float zombie_anim_attackstanding3         = 6;
  26 const float zombie_anim_blockend                        = 7;
  27 const float zombie_anim_blockstart                      = 8;
  28 const float zombie_anim_deathback1                      = 9;
  29 const float zombie_anim_deathback2                      = 10;
  30 const float zombie_anim_deathback3                      = 11;
  31 const float zombie_anim_deathfront1                     = 12;
  32 const float zombie_anim_deathfront2                     = 13;
  33 const float zombie_anim_deathfront3                     = 14;
  34 const float zombie_anim_deathleft1                      = 15;
  35 const float zombie_anim_deathleft2                      = 16;
  36 const float zombie_anim_deathright1                     = 17;
  37 const float zombie_anim_deathright2                     = 18;
  38 const float zombie_anim_idle                            = 19;
  39 const float zombie_anim_painback1                       = 20;
  40 const float zombie_anim_painback2                       = 21;
  41 const float zombie_anim_painfront1                      = 22;
  42 const float zombie_anim_painfront2                      = 23;
  43 const float zombie_anim_runbackwards            = 24;
  44 const float zombie_anim_runbackwardsleft        = 25;
  45 const float zombie_anim_runbackwardsright       = 26;
  46 const float zombie_anim_runforward                      = 27;
  47 const float zombie_anim_runforwardleft          = 28;
  48 const float zombie_anim_runforwardright         = 29;
  49 const float zombie_anim_spawn                           = 30;
  50 */
  51
  52 .vector moveto;
  53
  54 void M_Zombie_Attack_Leap_Touch(entity this, entity toucher)
  55 {
  56         if (this.health <= 0)
  57                 return;
  58
  59         vector angles_face;
  60
  61         if(toucher.takedamage)
  62         {
  63                 angles_face = vectoangles(this.moveto - this.origin);
  64                 angles_face = normalize(angles_face) * (autocvar_g_monster_zombie_attack_leap_force);
  65                 Damage(toucher, this, this, (autocvar_g_monster_zombie_attack_leap_damage) * MONSTER_SKILLMOD(this), DEATH_MONSTER_ZOMBIE_JUMP.m_id, toucher.origin, angles_face);
  66                 settouch(this, Monster_Touch); // instantly turn it off to stop damage spam
  67                 this.state = 0;
  68         }
  69
  70         if (trace_dphitcontents)
  71         {
  72                 this.state = 0;
  73                 settouch(this, Monster_Touch);
  74         }
  75 }
  76
  77 void M_Zombie_Defend_Block_End(entity this)
  78 {
  79         if(this.health <= 0)
  80                 return;
  81
  82         setanim(this, this.anim_blockend, false, true, true);
  83         this.armorvalue = autocvar_g_monsters_armor_blockpercent;
  84 }
  85
  86 bool M_Zombie_Defend_Block(entity this)
  87 {
  88         this.armorvalue = 0.9;
  89         this.state = MONSTER_ATTACK_MELEE; // freeze monster
  90         this.attack_finished_single[0] = time + 2.1;
  91         this.anim_finished = this.attack_finished_single[0];
  92         setanim(this, this.anim_blockstart, false, true, true);
  93
  94         Monster_Delay(this, 1, 2, M_Zombie_Defend_Block_End);
  95
  96         return true;
  97 }
  98
  99 bool M_Zombie_Attack(int attack_type, entity actor, entity targ)
 100 {
 101         switch(attack_type)
 102         {
 103                 case MONSTER_ATTACK_MELEE:
 104                 {
 105                         if(random() < 0.3 && actor.health < 75 && actor.enemy.health > 10)
 106                                 return M_Zombie_Defend_Block(actor);
 107
 108                         float anim_chance = random();
 109                         vector chosen_anim;
 110
 111                         if(anim_chance < 0.33)
 112                                 chosen_anim = actor.anim_melee1;
 113                         else if(anim_chance < 0.66)
 114                                 chosen_anim = actor.anim_melee2;
 115                         else
 116                                 chosen_anim = actor.anim_melee3;
 117
 118                         return Monster_Attack_Melee(actor, actor.enemy, (autocvar_g_monster_zombie_attack_melee_damage), chosen_anim, actor.attack_range, (autocvar_g_monster_zombie_attack_melee_delay), DEATH_MONSTER_ZOMBIE_MELEE.m_id, true);
 119                 }
 120                 case MONSTER_ATTACK_RANGED:
 121                 {
 122                         makevectors(actor.angles);
 123                         return Monster_Attack_Leap(actor, actor.anim_shoot, M_Zombie_Attack_Leap_Touch, v_forward * (autocvar_g_monster_zombie_attack_leap_speed) + '0 0 200', (autocvar_g_monster_zombie_attack_leap_delay));
 124                 }
 125         }
 126
 127         return false;
 128 }
 129
 130 spawnfunc(monster_zombie) { Monster_Spawn(this, MON_ZOMBIE.monsterid); }
 131 #endif // SVQC
 132
 133 #ifdef SVQC
 134 METHOD(Zombie, mr_think, bool(Zombie this, entity actor))
 135 {
 136     TC(Zombie, this);
 137     if(time >= actor.spawn_time)
 138         actor.damageforcescale = autocvar_g_monster_zombie_damageforcescale;
 139     return true;
 140 }
 141
 142 METHOD(Zombie, mr_pain, float(Zombie this, entity actor, float damage_take, entity attacker, float deathtype))
 143 {
 144     TC(Zombie, this);
 145     actor.pain_finished = time + 0.34;
 146     setanim(actor, ((random() > 0.5) ? actor.anim_pain1 : actor.anim_pain2), true, true, false);
 147     return damage_take;
 148 }
 149
 150 METHOD(Zombie, mr_death, bool(Zombie this, entity actor))
 151 {
 152     TC(Zombie, this);
 153     actor.armorvalue = autocvar_g_monsters_armor_blockpercent;
 154
 155     setanim(actor, ((random() > 0.5) ? actor.anim_die1 : actor.anim_die2), false, true, true);
 156     return true;
 157 }
 158 #endif
 159 #ifdef GAMEQC
 160 METHOD(Zombie, mr_anim, bool(Zombie this, entity actor))
 161 {
 162     TC(Zombie, this);
 163     vector none = '0 0 0';
 164     actor.anim_die1 = animfixfps(actor, '9 1 0.5', none); // 2 seconds
 165     actor.anim_die2 = animfixfps(actor, '12 1 0.5', none); // 2 seconds
 166     actor.anim_spawn = animfixfps(actor, '30 1 3', none);
 167     actor.anim_walk = animfixfps(actor, '27 1 1', none);
 168     actor.anim_idle = animfixfps(actor, '19 1 1', none);
 169     actor.anim_pain1 = animfixfps(actor, '20 1 2', none); // 0.5 seconds
 170     actor.anim_pain2 = animfixfps(actor, '22 1 2', none); // 0.5 seconds
 171     actor.anim_melee1 = animfixfps(actor, '4 1 5', none); // analyze models and set framerate
 172     actor.anim_melee2 = animfixfps(actor, '4 1 5', none); // analyze models and set framerate
 173     actor.anim_melee3 = animfixfps(actor, '4 1 5', none); // analyze models and set framerate
 174     actor.anim_shoot = animfixfps(actor, '0 1 5', none); // analyze models and set framerate
 175     actor.anim_run = animfixfps(actor, '27 1 1', none);
 176     actor.anim_blockstart = animfixfps(actor, '8 1 1', none);
 177     actor.anim_blockend = animfixfps(actor, '7 1 1', none);
 178     return true;
 179 }
 180 #endif
 181 #ifdef SVQC
 182 METHOD(Zombie, mr_setup, bool(Zombie this, entity actor))
 183 {
 184     TC(Zombie, this);
 185     if(!actor.health) actor.health = (autocvar_g_monster_zombie_health);
 186     if(!actor.speed) { actor.speed = (autocvar_g_monster_zombie_speed_walk); }
 187     if(!actor.speed2) { actor.speed2 = (autocvar_g_monster_zombie_speed_run); }
 188     if(!actor.stopspeed) { actor.stopspeed = (autocvar_g_monster_zombie_speed_stop); }
 189
 190     if(actor.spawnflags & MONSTERFLAG_NORESPAWN)
 191         actor.spawnflags &= ~MONSTERFLAG_NORESPAWN; // zombies always respawn
 192
 193     actor.spawnflags |= MONSTER_RESPAWN_DEATHPOINT;
 194
 195     actor.monster_loot = spawnfunc_item_health_medium;
 196     actor.monster_attackfunc = M_Zombie_Attack;
 197     actor.spawnshieldtime = actor.spawn_time;
 198     actor.respawntime = 0.2;
 199     actor.damageforcescale = 0.0001; // no push while spawning
 200
 201     setanim(actor, actor.anim_spawn, false, true, true);
 202     actor.spawn_time = actor.animstate_endtime;
 203
 204     return true;
 205 }
 206
 207 METHOD(Zombie, mr_precache, bool(Zombie this))
 208 {
 209     TC(Zombie, this);
 210     return true;
 211 }
 212 #endif
 213
 214 #endif