qcsrc/common/mutators/mutator/buffs/sv_buffs.qc

   1 #include "sv_buffs.qh"
   2
   3 #include <common/mapobjects/target/music.qh>
   4 #include <common/gamemodes/_mod.qh>
   5 #include <server/items/items.qh>
   6 #include <server/main.qh>
   7
   8 void buffs_DelayedInit(entity this);
   9
  10 AUTOCVAR(g_buffs, int, -1, "Enable buffs, -1: enabled but no auto location or replacing powerups, 1: enabled and can replace them");
  11
  12 REGISTER_MUTATOR(buffs, autocvar_g_buffs)
  13 {
  14         MUTATOR_ONADD
  15         {
  16                 if(autocvar_g_buffs > 0)
  17                         InitializeEntity(NULL, buffs_DelayedInit, INITPRIO_FINDTARGET);
  18         }
  19 }
  20
  21 bool buffs_BuffModel_Customize(entity this, entity client)
  22 {
  23         entity player = WaypointSprite_getviewentity(client);
  24         entity myowner = this.owner;
  25
  26         if(myowner.alpha <= 0.5 && DIFF_TEAM(player, myowner) && myowner.alpha != 0)
  27                 return false;
  28
  29         if(MUTATOR_CALLHOOK(BuffModel_Customize, this, player))
  30                 return false;
  31
  32         if(player == myowner)
  33         {
  34                 // somewhat hide the model, but keep the glow
  35                 this.effects = 0;
  36                 this.alpha = -1;
  37         }
  38         else
  39         {
  40                 this.effects = EF_FULLBRIGHT | EF_LOWPRECISION;
  41                 this.alpha = 1;
  42         }
  43         return true;
  44 }
  45
  46 void buffs_BuffModel_Spawn(entity player)
  47 {
  48         player.buff_model = spawn();
  49         setmodel(player.buff_model, MDL_BUFF);
  50         setsize(player.buff_model, '0 0 -40', '0 0 40');
  51         setattachment(player.buff_model, player, "");
  52         setorigin(player.buff_model, '0 0 1' * (player.buff_model.maxs.z * 1));
  53         player.buff_model.owner = player;
  54         player.buff_model.scale = 0.7;
  55         player.buff_model.pflags = PFLAGS_FULLDYNAMIC;
  56         player.buff_model.light_lev = 200;
  57         setcefc(player.buff_model, buffs_BuffModel_Customize);
  58 }
  59
  60 vector buff_GlowColor(entity buff)
  61 {
  62         //if(buff.team) { return Team_ColorRGB(buff.team); }
  63         return buff.m_color;
  64 }
  65
  66 void buff_Effect(entity player, string eff)
  67 {
  68         if(!autocvar_g_buffs_effects) { return; }
  69
  70         if(time >= player.buff_effect_delay)
  71         {
  72                 Send_Effect_(eff, player.origin + ((player.mins + player.maxs) * 0.5), '0 0 0', 1);
  73                 player.buff_effect_delay = time + 0.05; // prevent spam
  74         }
  75 }
  76
  77 // buff item
  78 bool buff_Waypoint_visible_for_player(entity this, entity player, entity view)
  79 {
  80         if(!this.owner.buff_active && !this.owner.buff_activetime)
  81                 return false;
  82
  83         if (STAT(BUFFS, view))
  84         {
  85                 return CS(view).cvar_cl_buffs_autoreplace == false || STAT(BUFFS, view) != STAT(BUFFS, this.owner);
  86         }
  87
  88         return WaypointSprite_visible_for_player(this, player, view);
  89 }
  90
  91 void buff_Waypoint_Spawn(entity e)
  92 {
  93         if(autocvar_g_buffs_waypoint_distance <= 0) return;
  94
  95         entity buff = buff_FirstFromFlags(STAT(BUFFS, e));
  96         entity wp = WaypointSprite_Spawn(WP_Buff, 0, autocvar_g_buffs_waypoint_distance, e, '0 0 1' * e.maxs.z, NULL, e.team, e, buff_waypoint, true, RADARICON_Buff);
  97         wp.wp_extra = buff.m_id;
  98         WaypointSprite_UpdateTeamRadar(e.buff_waypoint, RADARICON_Buff, e.glowmod);
  99         e.buff_waypoint.waypointsprite_visible_for_player = buff_Waypoint_visible_for_player;
 100 }
 101
 102 void buff_SetCooldown(entity this, float cd)
 103 {
 104         cd = max(0, cd);
 105
 106         if(!this.buff_waypoint)
 107                 buff_Waypoint_Spawn(this);
 108
 109         if(this.buff_waypoint)
 110                 WaypointSprite_UpdateBuildFinished(this.buff_waypoint, time + cd);
 111
 112         this.buff_activetime = cd;
 113         this.buff_active = !cd;
 114 }
 115
 116 void buff_Respawn(entity this)
 117 {
 118         if(game_stopped) return;
 119
 120         vector oldbufforigin = this.origin;
 121         this.velocity = '0 0 200';
 122
 123         if(!MoveToRandomMapLocation(this, DPCONTENTS_SOLID | DPCONTENTS_CORPSE | DPCONTENTS_PLAYERCLIP, DPCONTENTS_SLIME | DPCONTENTS_LAVA | DPCONTENTS_SKY | DPCONTENTS_BODY | DPCONTENTS_DONOTENTER, Q3SURFACEFLAG_SKY,
 124                 ((autocvar_g_buffs_random_location_attempts > 0) ? autocvar_g_buffs_random_location_attempts : 10), 1024, 256))
 125         {
 126                 entity spot = SelectSpawnPoint(this, true);
 127                 setorigin(this, spot.origin);
 128                 this.velocity = ((randomvec() * 100) + '0 0 200');
 129                 this.angles = spot.angles;
 130         }
 131
 132         tracebox(this.origin, this.mins * 1.5, this.maxs * 1.5, this.origin, MOVE_NOMONSTERS, this);
 133
 134         setorigin(this, trace_endpos); // attempt to unstick
 135
 136         set_movetype(this, MOVETYPE_TOSS);
 137
 138         makevectors(this.angles);
 139         this.angles = '0 0 0';
 140         if(autocvar_g_buffs_random_lifetime > 0)
 141                 this.lifetime = time + autocvar_g_buffs_random_lifetime;
 142
 143         Send_Effect(EFFECT_ELECTRO_COMBO, oldbufforigin + ((this.mins + this.maxs) * 0.5), '0 0 0', 1);
 144         Send_Effect(EFFECT_ELECTRO_COMBO, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
 145
 146         WaypointSprite_Ping(this.buff_waypoint);
 147
 148         sound(this, CH_TRIGGER, SND_KA_RESPAWN, VOL_BASE, ATTEN_NONE); // ATTEN_NONE (it's a sound intended to be heard anywhere)
 149 }
 150
 151 void buff_Touch(entity this, entity toucher)
 152 {
 153         if(game_stopped) return;
 154
 155         if(ITEM_TOUCH_NEEDKILL())
 156         {
 157                 buff_Respawn(this);
 158                 return;
 159         }
 160
 161         if(!this.buff_active)
 162                 return;
 163
 164         if(MUTATOR_CALLHOOK(BuffTouch, this, toucher))
 165                 return;
 166         toucher = M_ARGV(1, entity);
 167
 168         if(!IS_PLAYER(toucher))
 169                 return; // incase mutator changed toucher
 170
 171         if((this.team && DIFF_TEAM(toucher, this))
 172         || (STAT(FROZEN, toucher))
 173         || (toucher.vehicle)
 174         || (time < PS(toucher).buff_shield)
 175         )
 176         {
 177                 // can't touch this
 178                 return;
 179         }
 180
 181         if (STAT(BUFFS, toucher))
 182         {
 183                 if (CS(toucher).cvar_cl_buffs_autoreplace && STAT(BUFFS, toucher) != STAT(BUFFS, this))
 184                 {
 185                         // TODO: lost-gained notification for this case
 186                         int buffid = buff_FirstFromFlags(STAT(BUFFS, toucher)).m_id;
 187                         Send_Notification(NOTIF_ONE, toucher, MSG_INFO, INFO_ITEM_BUFF_LOST, toucher.netname, buffid);
 188                         if(!IS_INDEPENDENT_PLAYER(toucher))
 189                                 Send_Notification(NOTIF_ALL_EXCEPT, toucher, MSG_INFO, INFO_ITEM_BUFF_LOST, toucher.netname, buffid);
 190
 191                         STAT(BUFFS, toucher) = 0;
 192                         //sound(toucher, CH_TRIGGER, SND_BUFF_LOST, VOL_BASE, ATTN_NORM);
 193                 }
 194                 else { return; } // do nothing
 195         }
 196
 197         this.owner = toucher;
 198         this.buff_active = false;
 199         this.lifetime = 0;
 200         entity thebuff = buff_FirstFromFlags(STAT(BUFFS, this));
 201         Send_Notification(NOTIF_ONE, toucher, MSG_MULTI, ITEM_BUFF_GOT, thebuff.m_id);
 202         if(!IS_INDEPENDENT_PLAYER(toucher))
 203                 Send_Notification(NOTIF_ALL_EXCEPT, toucher, MSG_INFO, INFO_ITEM_BUFF, toucher.netname, thebuff.m_id);
 204
 205         Send_Effect(EFFECT_ITEM_PICKUP, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
 206         sound(toucher, CH_TRIGGER, SND_SHIELD_RESPAWN, VOL_BASE, ATTN_NORM);
 207         STAT(BUFFS, toucher) |= (STAT(BUFFS, this));
 208         STAT(LAST_PICKUP, toucher) = time;
 209         float bufftime = ((this.count) ? this.count : thebuff.m_time(thebuff));
 210         if(bufftime)
 211                 STAT(BUFF_TIME, toucher) = min(time + bufftime, max(STAT(BUFF_TIME, toucher), time) + bufftime);
 212 }
 213
 214 float buff_Available(entity buff)
 215 {
 216         if (buff == BUFF_Null)
 217                 return false;
 218         if (buff == BUFF_AMMO && ((start_items & IT_UNLIMITED_AMMO) || cvar("g_melee_only")))
 219                 return false;
 220         if (buff == BUFF_VAMPIRE && cvar("g_vampire"))
 221                 return false;
 222         return cvar(strcat("g_buffs_", buff.netname));
 223 }
 224
 225 .int buff_seencount;
 226
 227 void buff_NewType(entity ent)
 228 {
 229         RandomSelection_Init();
 230         FOREACH(Buffs, buff_Available(it),
 231         {
 232                 // if it's already been chosen, give it a lower priority
 233                 float myseencount = (it.buff_seencount > 0) ? it.buff_seencount : 1; // no division by zero please!
 234                 RandomSelection_AddEnt(it, max(0.2, 1 / myseencount), 1);
 235         });
 236         entity newbuff = RandomSelection_chosen_ent;
 237         newbuff.buff_seencount += 1; // lower chances of seeing this buff again soon
 238         STAT(BUFFS, ent) = newbuff.m_itemid;
 239 }
 240
 241 void buff_Think(entity this)
 242 {
 243         if(this.buff_waypoint && autocvar_g_buffs_waypoint_distance <= 0)
 244                 WaypointSprite_Kill(this.buff_waypoint);
 245
 246         if(STAT(BUFFS, this) != this.oldbuffs)
 247         {
 248                 entity buff = buff_FirstFromFlags(STAT(BUFFS, this));
 249                 this.color = buff.m_color;
 250                 this.glowmod = buff_GlowColor(buff);
 251                 this.skin = buff.m_skin;
 252
 253                 setmodel(this, MDL_BUFF);
 254                 setsize(this, BUFF_MIN, BUFF_MAX);
 255
 256                 if(this.buff_waypoint)
 257                 {
 258                         //WaypointSprite_Disown(this.buff_waypoint, 1);
 259                         WaypointSprite_Kill(this.buff_waypoint);
 260                         buff_Waypoint_Spawn(this);
 261                         if(this.buff_activetime)
 262                                 WaypointSprite_UpdateBuildFinished(this.buff_waypoint, time + this.buff_activetime - frametime);
 263                 }
 264
 265                 this.oldbuffs = STAT(BUFFS, this);
 266         }
 267
 268         if(!game_stopped)
 269         if((round_handler_IsActive() && round_handler_IsRoundStarted()) || time >= game_starttime)
 270         if(!this.buff_activetime_updated)
 271         {
 272                 buff_SetCooldown(this, this.buff_activetime);
 273                 this.buff_activetime_updated = true;
 274         }
 275
 276         if(!this.buff_active && !this.buff_activetime)
 277         if(!this.owner || STAT(FROZEN, this.owner) || IS_DEAD(this.owner) || !this.owner.iscreature || this.owner.vehicle || !(STAT(BUFFS, this.owner) & STAT(BUFFS, this)) || this.pickup_anyway > 0 || (this.pickup_anyway >= 0 && autocvar_g_buffs_pickup_anyway))
 278         {
 279                 buff_SetCooldown(this, autocvar_g_buffs_cooldown_respawn + frametime);
 280                 this.owner = NULL;
 281                 if(autocvar_g_buffs_randomize && (!teamplay || autocvar_g_buffs_randomize_teamplay))
 282                         buff_NewType(this);
 283
 284                 if(autocvar_g_buffs_random_location || (this.spawnflags & 64))
 285                         buff_Respawn(this);
 286         }
 287
 288         if(this.buff_activetime)
 289         if(!game_stopped)
 290         if((round_handler_IsActive() && round_handler_IsRoundStarted()) || time >= game_starttime)
 291         {
 292                 this.buff_activetime = max(0, this.buff_activetime - frametime);
 293
 294                 if(!this.buff_activetime)
 295                 {
 296                         this.buff_active = true;
 297                         sound(this, CH_TRIGGER, SND_STRENGTH_RESPAWN, VOL_BASE, ATTN_NORM);
 298                         Send_Effect(EFFECT_ITEM_RESPAWN, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
 299                 }
 300         }
 301
 302         if(this.buff_active)
 303         {
 304                 if(this.team && !this.buff_waypoint)
 305                         buff_Waypoint_Spawn(this);
 306
 307                 if(this.lifetime && time >= this.lifetime)
 308                         buff_Respawn(this);
 309         }
 310
 311         this.nextthink = time;
 312         //this.angles_y = time * 110.1;
 313 }
 314
 315 void buff_Waypoint_Reset(entity this)
 316 {
 317         WaypointSprite_Kill(this.buff_waypoint);
 318
 319         if(this.buff_activetime) { buff_Waypoint_Spawn(this); }
 320 }
 321
 322 void buff_Reset(entity this)
 323 {
 324         if(autocvar_g_buffs_randomize && (!teamplay || autocvar_g_buffs_randomize_teamplay))
 325                 buff_NewType(this);
 326         this.owner = NULL;
 327         buff_SetCooldown(this, autocvar_g_buffs_cooldown_activate);
 328         buff_Waypoint_Reset(this);
 329         this.buff_activetime_updated = false;
 330
 331         if(autocvar_g_buffs_random_location || (this.spawnflags & 64))
 332                 buff_Respawn(this);
 333 }
 334
 335 bool buff_Customize(entity this, entity client)
 336 {
 337         entity player = WaypointSprite_getviewentity(client);
 338         if(!this.buff_active || (this.team && DIFF_TEAM(player, this)))
 339         {
 340                 this.alpha = 0.3;
 341                 if(this.effects & EF_FULLBRIGHT) { this.effects &= ~(EF_FULLBRIGHT); }
 342                 this.pflags = 0;
 343         }
 344         else
 345         {
 346                 this.alpha = 1;
 347                 if(!(this.effects & EF_FULLBRIGHT)) { this.effects |= EF_FULLBRIGHT; }
 348                 this.light_lev = 220 + 36 * sin(time);
 349                 this.pflags = PFLAGS_FULLDYNAMIC;
 350         }
 351         return true;
 352 }
 353
 354 void buff_Delete(entity this)
 355 {
 356         WaypointSprite_Kill(this.buff_waypoint);
 357         delete_fn(this);
 358 }
 359
 360 void buff_Init(entity this)
 361 {
 362         if(!cvar("g_buffs")) { delete(this); return; }
 363
 364         if(!teamplay && this.team) { this.team = 0; }
 365
 366         entity buff = buff_FirstFromFlags(STAT(BUFFS, this));
 367
 368         if(!STAT(BUFFS, this) || !buff_Available(buff))
 369                 buff_NewType(this);
 370
 371         this.classname = "item_buff";
 372         this.solid = SOLID_TRIGGER;
 373         this.flags = FL_ITEM;
 374         this.bot_pickup = true;
 375         this.bot_pickupevalfunc = generic_pickupevalfunc;
 376         this.bot_pickupbasevalue = 1000;
 377         IL_PUSH(g_items, this);
 378         setthink(this, buff_Think);
 379         settouch(this, buff_Touch);
 380         this.reset = buff_Reset;
 381         this.nextthink = time + 0.1;
 382         this.gravity = 1;
 383         set_movetype(this, MOVETYPE_TOSS);
 384         this.scale = 1;
 385         this.skin = buff.m_skin;
 386         this.effects = EF_FULLBRIGHT | EF_STARDUST | EF_NOSHADOW;
 387         this.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY;
 388         setcefc(this, buff_Customize);
 389         //this.gravity = 100;
 390         this.color = buff.m_color;
 391         this.glowmod = buff_GlowColor(this);
 392         buff_SetCooldown(this, autocvar_g_buffs_cooldown_activate + max(0, game_starttime - time));
 393         this.buff_active = !this.buff_activetime;
 394         this.pflags = PFLAGS_FULLDYNAMIC;
 395         this.dtor = buff_Delete;
 396
 397         if(this.spawnflags & 1)
 398                 this.noalign = true;
 399
 400         if(this.noalign)
 401                 set_movetype(this, MOVETYPE_NONE); // reset by random location
 402
 403         setmodel(this, MDL_BUFF);
 404         setsize(this, BUFF_MIN, BUFF_MAX);
 405
 406         if(cvar("g_buffs_random_location") || (this.spawnflags & 64))
 407                 buff_Respawn(this);
 408 }
 409
 410 void buff_Init_Compat(entity ent, entity replacement)
 411 {
 412         if (ent.spawnflags & 2)
 413                 ent.team = NUM_TEAM_1;
 414         else if (ent.spawnflags & 4)
 415                 ent.team = NUM_TEAM_2;
 416
 417         STAT(BUFFS, ent) = replacement.m_itemid;
 418
 419         buff_Init(ent);
 420 }
 421
 422 void buff_SpawnReplacement(entity ent, entity old)
 423 {
 424         setorigin(ent, old.origin);
 425         ent.angles = old.angles;
 426         ent.noalign = Item_ShouldKeepPosition(old);
 427
 428         buff_Init(ent);
 429 }
 430
 431 void buff_Vengeance_DelayedDamage(entity this)
 432 {
 433         if(this.enemy)
 434                 Damage(this.enemy, this.owner, this.owner, this.dmg, DEATH_BUFF.m_id, DMG_NOWEP, this.enemy.origin, '0 0 0');
 435
 436         delete(this);
 437         return;
 438 }
 439
 440 // note: only really useful in teamplay
 441 void buff_Medic_Heal(entity this)
 442 {
 443         FOREACH_CLIENT(IS_PLAYER(it) && it != this && vdist(it.origin - this.origin, <=, autocvar_g_buffs_medic_heal_range),
 444         {
 445                 if (DIFF_TEAM(it, this))
 446                 {
 447                         continue;
 448                 }
 449                 float hp = GetResource(it, RES_HEALTH);
 450                 if(hp >= autocvar_g_balance_health_regenstable)
 451                 {
 452                         continue;
 453                 }
 454                 Send_Effect(EFFECT_HEALING, it.origin, '0 0 0', 1);
 455                 SetResource(it, RES_HEALTH, bound(0, hp + autocvar_g_buffs_medic_heal_amount, autocvar_g_balance_health_regenstable));
 456         });
 457 }
 458
 459 float buff_Inferno_CalculateTime(float damg, float offset_x, float offset_y, float intersect_x, float intersect_y, float base)
 460 {
 461         return offset_y + (intersect_y - offset_y) * logn(((damg - offset_x) * ((base - 1) / intersect_x)) + 1, base);
 462 }
 463
 464 // mutator hooks
 465 MUTATOR_HOOKFUNCTION(buffs, Damage_Calculate)
 466 {
 467         entity frag_attacker = M_ARGV(1, entity);
 468         entity frag_target = M_ARGV(2, entity);
 469         float frag_deathtype = M_ARGV(3, float);
 470         float frag_damage = M_ARGV(4, float);
 471         vector frag_force = M_ARGV(6, vector);
 472
 473         if(frag_deathtype == DEATH_BUFF.m_id) { return; }
 474
 475         if(STAT(BUFFS, frag_target) & BUFF_RESISTANCE.m_itemid)
 476         {
 477                 float reduced = frag_damage * autocvar_g_buffs_resistance_blockpercent;
 478                 frag_damage = bound(0, frag_damage - reduced, frag_damage);
 479         }
 480
 481         if(STAT(BUFFS, frag_target) & BUFF_SPEED.m_itemid)
 482         if(frag_target != frag_attacker)
 483                 frag_damage *= autocvar_g_buffs_speed_damage_take;
 484
 485         if(STAT(BUFFS, frag_target) & BUFF_MEDIC.m_itemid)
 486         if((GetResource(frag_target, RES_HEALTH) - frag_damage) <= 0)
 487         if(!ITEM_DAMAGE_NEEDKILL(frag_deathtype))
 488         if(frag_attacker)
 489         if(random() <= autocvar_g_buffs_medic_survive_chance)
 490                 frag_damage = max(5, GetResource(frag_target, RES_HEALTH) - autocvar_g_buffs_medic_survive_health);
 491
 492         if(STAT(BUFFS, frag_target) & BUFF_JUMP.m_itemid)
 493         if(frag_deathtype == DEATH_FALL.m_id)
 494                 frag_damage = 0;
 495
 496         if(STAT(BUFFS, frag_target) & BUFF_VENGEANCE.m_itemid)
 497         if(frag_attacker)
 498         if(frag_attacker != frag_target)
 499         if(!ITEM_DAMAGE_NEEDKILL(frag_deathtype))
 500         {
 501                 entity dmgent = spawn();
 502
 503                 dmgent.dmg = frag_damage * autocvar_g_buffs_vengeance_damage_multiplier;
 504                 dmgent.enemy = frag_attacker;
 505                 dmgent.owner = frag_target;
 506                 setthink(dmgent, buff_Vengeance_DelayedDamage);
 507                 dmgent.nextthink = time + 0.1;
 508         }
 509
 510         if(STAT(BUFFS, frag_target) & BUFF_BASH.m_itemid)
 511         if(frag_attacker != frag_target)
 512                 frag_force = '0 0 0';
 513
 514         if(STAT(BUFFS, frag_attacker) & BUFF_BASH.m_itemid)
 515         if(frag_force)
 516         {
 517                 if(frag_attacker == frag_target)
 518                         frag_force *= autocvar_g_buffs_bash_force_self;
 519                 else
 520                         frag_force *= autocvar_g_buffs_bash_force;
 521         }
 522
 523         if(STAT(BUFFS, frag_attacker) & BUFF_DISABILITY.m_itemid)
 524         if(frag_target != frag_attacker)
 525                 frag_target.buff_disability_time = time + autocvar_g_buffs_disability_slowtime;
 526
 527         if(STAT(BUFFS, frag_target) & BUFF_INFERNO.m_itemid)
 528         {
 529                 if(frag_deathtype == DEATH_FIRE.m_id)
 530                         frag_damage = 0;
 531                 if(frag_deathtype == DEATH_LAVA.m_id)
 532                         frag_damage *= 0.5; // TODO: cvarize?
 533         }
 534
 535         if(STAT(BUFFS, frag_attacker) & BUFF_LUCK.m_itemid)
 536         if(frag_attacker != frag_target)
 537         if(autocvar_g_buffs_luck_damagemultiplier > 0)
 538         if(random() <= autocvar_g_buffs_luck_chance)
 539                 frag_damage *= autocvar_g_buffs_luck_damagemultiplier;
 540
 541         if(STAT(BUFFS, frag_attacker) & BUFF_INFERNO.m_itemid)
 542         if(frag_target != frag_attacker) {
 543                 float btime = buff_Inferno_CalculateTime(
 544                         frag_damage,
 545                         0,
 546                         autocvar_g_buffs_inferno_burntime_min_time,
 547                         autocvar_g_buffs_inferno_burntime_target_damage,
 548                         autocvar_g_buffs_inferno_burntime_target_time,
 549                         autocvar_g_buffs_inferno_burntime_factor
 550                 );
 551                 Fire_AddDamage(frag_target, frag_attacker, (frag_damage * autocvar_g_buffs_inferno_damagemultiplier), btime, DEATH_BUFF.m_id);
 552         }
 553
 554         // this... is ridiculous (TODO: fix!)
 555         if(STAT(BUFFS, frag_attacker) & BUFF_VAMPIRE.m_itemid)
 556         if(!frag_target.vehicle)
 557         if(!ITEM_DAMAGE_NEEDKILL(frag_deathtype))
 558         if(!IS_DEAD(frag_target))
 559         if(IS_PLAYER(frag_target) || IS_MONSTER(frag_target))
 560         if(frag_attacker != frag_target)
 561         if(!STAT(FROZEN, frag_target))
 562         if(frag_target.takedamage)
 563         if(DIFF_TEAM(frag_attacker, frag_target))
 564         {
 565                 float amount = bound(0, frag_damage * autocvar_g_buffs_vampire_damage_steal,
 566                         GetResource(frag_target, RES_HEALTH));
 567                 GiveResourceWithLimit(frag_attacker, RES_HEALTH, amount, g_pickup_healthsmall_max);
 568                 if (GetResource(frag_target, RES_ARMOR))
 569                 {
 570                         amount = bound(0, frag_damage * autocvar_g_buffs_vampire_damage_steal,
 571                                 GetResource(frag_target, RES_ARMOR));
 572                         GiveResourceWithLimit(frag_attacker, RES_ARMOR, amount, g_pickup_armorsmall_max);
 573                 }
 574         }
 575
 576         M_ARGV(4, float) = frag_damage;
 577         M_ARGV(6, vector) = frag_force;
 578 }
 579
 580 MUTATOR_HOOKFUNCTION(buffs, PlayerSpawn)
 581 {
 582         entity player = M_ARGV(0, entity);
 583
 584         player.oldbuffs = 0;
 585         // reset timers here to prevent them continuing after re-spawn
 586         player.buff_disability_time = 0;
 587         player.buff_disability_effect_time = 0;
 588 }
 589
 590 MUTATOR_HOOKFUNCTION(buffs, PlayerPhysics_UpdateStats)
 591 {
 592         entity player = M_ARGV(0, entity);
 593         // these automatically reset, no need to worry
 594
 595         if(STAT(BUFFS, player) & BUFF_SPEED.m_itemid)
 596                 STAT(MOVEVARS_HIGHSPEED, player) *= autocvar_g_buffs_speed_speed;
 597
 598         if(time < player.buff_disability_time)
 599                 STAT(MOVEVARS_HIGHSPEED, player) *= autocvar_g_buffs_disability_speed;
 600 }
 601
 602 MUTATOR_HOOKFUNCTION(buffs, PlayerPhysics)
 603 {
 604         entity player = M_ARGV(0, entity);
 605         // these automatically reset, no need to worry
 606
 607         if(STAT(BUFFS, player) & BUFF_JUMP.m_itemid)
 608                 STAT(MOVEVARS_JUMPVELOCITY, player) = autocvar_g_buffs_jump_height;
 609 }
 610
 611 MUTATOR_HOOKFUNCTION(buffs, MonsterMove)
 612 {
 613         entity mon = M_ARGV(0, entity);
 614
 615         if(time < mon.buff_disability_time)
 616         {
 617                 M_ARGV(1, float) *= autocvar_g_buffs_disability_speed; // run speed
 618                 M_ARGV(2, float) *= autocvar_g_buffs_disability_speed; // walk speed
 619         }
 620 }
 621
 622 MUTATOR_HOOKFUNCTION(buffs, PlayerDies)
 623 {
 624         entity frag_target = M_ARGV(2, entity);
 625
 626         if(STAT(BUFFS, frag_target))
 627         {
 628                 int buffid = buff_FirstFromFlags(STAT(BUFFS, frag_target)).m_id;
 629                 if(!IS_INDEPENDENT_PLAYER(frag_target))
 630                         Send_Notification(NOTIF_ALL_EXCEPT, frag_target, MSG_INFO, INFO_ITEM_BUFF_LOST, frag_target.netname, buffid);
 631                 STAT(BUFFS, frag_target) = 0;
 632                 STAT(BUFF_TIME, frag_target) = 0;
 633
 634                 if(frag_target.buff_model)
 635                 {
 636                         delete(frag_target.buff_model);
 637                         frag_target.buff_model = NULL;
 638                 }
 639         }
 640 }
 641
 642 MUTATOR_HOOKFUNCTION(buffs, PlayerUseKey, CBC_ORDER_FIRST)
 643 {
 644         if(MUTATOR_RETURNVALUE || game_stopped || !autocvar_g_buffs_drop) return;
 645
 646         entity player = M_ARGV(0, entity);
 647
 648         if(STAT(BUFFS, player))
 649         {
 650                 int buffid = buff_FirstFromFlags(STAT(BUFFS, player)).m_id;
 651                 Send_Notification(NOTIF_ONE, player, MSG_MULTI, ITEM_BUFF_DROP, buffid);
 652                 if(!IS_INDEPENDENT_PLAYER(player))
 653                         Send_Notification(NOTIF_ALL_EXCEPT, player, MSG_INFO, INFO_ITEM_BUFF_LOST, player.netname, buffid);
 654
 655                 STAT(BUFFS, player) = 0;
 656                 STAT(BUFF_TIME, player) = 0;
 657                 PS(player).buff_shield = time + max(0, autocvar_g_buffs_pickup_delay);
 658                 sound(player, CH_TRIGGER, SND_BUFF_LOST, VOL_BASE, ATTN_NORM);
 659                 return true;
 660         }
 661 }
 662
 663 MUTATOR_HOOKFUNCTION(buffs, ForbidThrowCurrentWeapon)
 664 {
 665         if(MUTATOR_RETURNVALUE || game_stopped) return;
 666         entity player = M_ARGV(0, entity);
 667
 668         if(STAT(BUFFS, player) & BUFF_SWAPPER.m_itemid)
 669         {
 670                 float best_distance = autocvar_g_buffs_swapper_range;
 671                 entity closest = NULL;
 672                 FOREACH_CLIENT(IS_PLAYER(it), {
 673                         if(!IS_DEAD(it) && !STAT(FROZEN, it) && !it.vehicle)
 674                         if(DIFF_TEAM(it, player))
 675                         {
 676                                 float test = vlen2(player.origin - it.origin);
 677                                 if(test <= best_distance * best_distance)
 678                                 {
 679                                         best_distance = sqrt(test);
 680                                         closest = it;
 681                                 }
 682                         }
 683                 });
 684
 685                 if(closest)
 686                 {
 687                         vector my_org, my_vel, my_ang, their_org, their_vel, their_ang;
 688
 689                         my_org = player.origin;
 690                         my_vel = player.velocity;
 691                         my_ang = player.angles;
 692                         their_org = closest.origin;
 693                         their_vel = closest.velocity;
 694                         their_ang = closest.angles;
 695
 696                         Drop_Special_Items(closest);
 697
 698                         MUTATOR_CALLHOOK(PortalTeleport, player); // initiate flag dropper
 699
 700                         setorigin(player, their_org);
 701                         setorigin(closest, my_org);
 702
 703                         closest.velocity = my_vel;
 704                         closest.angles = my_ang;
 705                         if (IS_BOT_CLIENT(closest))
 706                         {
 707                                 closest.v_angle = closest.angles;
 708                                 bot_aim_reset(closest);
 709                         }
 710                         closest.fixangle = true;
 711                         closest.oldorigin = my_org;
 712                         closest.oldvelocity = my_vel;
 713                         player.velocity = their_vel;
 714                         player.angles = their_ang;
 715                         if (IS_BOT_CLIENT(player))
 716                         {
 717                                 player.v_angle = player.angles;
 718                                 bot_aim_reset(player);
 719                         }
 720                         player.fixangle = true;
 721                         player.oldorigin = their_org;
 722                         player.oldvelocity = their_vel;
 723
 724                         // set pusher so player gets the kill if they fall into void
 725                         closest.pusher = player;
 726                         closest.pushltime = time + autocvar_g_maxpushtime;
 727                         closest.istypefrag = PHYS_INPUT_BUTTON_CHAT(closest);
 728
 729                         Send_Effect(EFFECT_ELECTRO_COMBO, their_org, '0 0 0', 1);
 730                         Send_Effect(EFFECT_ELECTRO_COMBO, my_org, '0 0 0', 1);
 731
 732                         sound(player, CH_TRIGGER, SND_KA_RESPAWN, VOL_BASE, ATTEN_NORM);
 733                         sound(closest, CH_TRIGGER, SND_KA_RESPAWN, VOL_BASE, ATTEN_NORM);
 734
 735                         // TODO: add a counter to handle how many times one can teleport, and a delay to prevent spam
 736                         STAT(BUFFS, player) = 0;
 737                         return true;
 738                 }
 739         }
 740 }
 741
 742 bool buffs_RemovePlayer(entity player)
 743 {
 744         if(player.buff_model)
 745         {
 746                 delete(player.buff_model);
 747                 player.buff_model = NULL;
 748         }
 749
 750         // also reset timers here to prevent them continuing after spectating
 751         player.buff_disability_time = 0;
 752         player.buff_disability_effect_time = 0;
 753
 754         return false;
 755 }
 756 MUTATOR_HOOKFUNCTION(buffs, MakePlayerObserver) { entity player = M_ARGV(0, entity); return buffs_RemovePlayer(player); }
 757 MUTATOR_HOOKFUNCTION(buffs, ClientDisconnect) { entity player = M_ARGV(0, entity); return buffs_RemovePlayer(player); }
 758
 759 MUTATOR_HOOKFUNCTION(buffs, CustomizeWaypoint)
 760 {
 761         entity wp = M_ARGV(0, entity);
 762         entity player = M_ARGV(1, entity);
 763
 764         entity e = WaypointSprite_getviewentity(player);
 765
 766         // if you have the invisibility powerup, sprites ALWAYS are restricted to your team
 767         // but only apply this to real players, not to spectators
 768         if((wp.owner.flags & FL_CLIENT) && (STAT(BUFFS, wp.owner) & BUFF_INVISIBLE.m_itemid) && (e == player))
 769         if(DIFF_TEAM(wp.owner, e))
 770                 return true;
 771 }
 772
 773 MUTATOR_HOOKFUNCTION(buffs, FilterItem)
 774 {
 775         if(autocvar_g_buffs < 0)
 776                 return false; // no auto replacing of entities in this mode
 777
 778         entity item = M_ARGV(0, entity);
 779
 780         if(autocvar_g_buffs_replace_powerups)
 781         {
 782                 switch(item.classname)
 783                 {
 784                         case "item_strength":
 785                         case "item_shield":
 786                         {
 787                                 entity e = spawn();
 788                                 buff_SpawnReplacement(e, item);
 789                                 return true;
 790                         }
 791                 }
 792         }
 793
 794         return false;
 795 }
 796
 797 MUTATOR_HOOKFUNCTION(buffs, WeaponRateFactor)
 798 {
 799         entity player = M_ARGV(1, entity);
 800
 801         if(STAT(BUFFS, player) & BUFF_SPEED.m_itemid)
 802                 M_ARGV(0, float) *= autocvar_g_buffs_speed_rate;
 803
 804         if(time < player.buff_disability_time)
 805                 M_ARGV(0, float) *= autocvar_g_buffs_disability_rate;
 806 }
 807
 808 MUTATOR_HOOKFUNCTION(buffs, WeaponSpeedFactor)
 809 {
 810         entity player = M_ARGV(1, entity);
 811
 812         if(STAT(BUFFS, player) & BUFF_SPEED.m_itemid)
 813                 M_ARGV(0, float) *= autocvar_g_buffs_speed_weaponspeed;
 814
 815         if(time < player.buff_disability_time)
 816                 M_ARGV(0, float) *= autocvar_g_buffs_disability_weaponspeed;
 817 }
 818
 819 .bool buff_flight_crouchheld;
 820
 821 MUTATOR_HOOKFUNCTION(buffs, PlayerPreThink)
 822 {
 823         entity player = M_ARGV(0, entity);
 824
 825         if(game_stopped || IS_DEAD(player) || frametime || !IS_PLAYER(player)) return;
 826
 827         if(STAT(BUFFS, player) & BUFF_FLIGHT.m_itemid)
 828         {
 829                 if(!PHYS_INPUT_BUTTON_CROUCH(player))
 830                         player.buff_flight_crouchheld = false;
 831                 else if(!player.buff_flight_crouchheld)
 832                 {
 833                         player.buff_flight_crouchheld = true;
 834                         player.gravity *= -1;
 835                 }
 836         }
 837
 838         if(time < player.buff_disability_time)
 839         if(time >= player.buff_disability_effect_time)
 840         {
 841                 Send_Effect(EFFECT_SMOKING, player.origin + ((player.mins + player.maxs) * 0.5), '0 0 0', 1);
 842                 player.buff_disability_effect_time = time + 0.5;
 843         }
 844
 845         // handle buff lost status
 846         // 1: notify everyone else
 847         // 2: notify carrier as well
 848         int buff_lost = 0;
 849
 850         if(STAT(BUFF_TIME, player) && STAT(BUFFS, player))
 851         if(time >= STAT(BUFF_TIME, player))
 852         {
 853                 STAT(BUFF_TIME, player) = 0;
 854                 buff_lost = 2;
 855         }
 856
 857         if(STAT(FROZEN, player)) { buff_lost = 1; }
 858
 859         if(buff_lost)
 860         {
 861                 if(STAT(BUFFS, player))
 862                 {
 863                         int buffid = buff_FirstFromFlags(STAT(BUFFS, player)).m_id;
 864                         if(buff_lost == 2)
 865                         {
 866                                 Send_Notification(NOTIF_ONE, player, MSG_MULTI, ITEM_BUFF_DROP, buffid); // TODO: special timeout message?
 867                                 sound(player, CH_TRIGGER, SND_BUFF_LOST, VOL_BASE, ATTN_NORM);
 868                         }
 869                         else if(!IS_INDEPENDENT_PLAYER(player))
 870                                 Send_Notification(NOTIF_ALL_EXCEPT, player, MSG_INFO, INFO_ITEM_BUFF_LOST, player.netname, buffid);
 871                         STAT(BUFFS, player) = 0;
 872                         PS(player).buff_shield = time + max(0, autocvar_g_buffs_pickup_delay); // always put in a delay, even if small
 873                 }
 874         }
 875
 876         if(STAT(BUFFS, player) & BUFF_MAGNET.m_itemid)
 877         {
 878                 vector pickup_size;
 879                 IL_EACH(g_items, it.itemdef,
 880                 {
 881                         if(STAT(BUFFS, it))
 882                                 pickup_size = '1 1 1' * autocvar_g_buffs_magnet_range_buff;
 883                         else
 884                                 pickup_size = '1 1 1' * autocvar_g_buffs_magnet_range_item;
 885
 886                         if(boxesoverlap(player.absmin - pickup_size, player.absmax + pickup_size, it.absmin, it.absmax))
 887                         {
 888                                 if(gettouch(it))
 889                                         gettouch(it)(it, player);
 890                         }
 891                 });
 892         }
 893
 894         if(STAT(BUFFS, player) & BUFF_AMMO.m_itemid)
 895         {
 896                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 897                 {
 898                         .entity weaponentity = weaponentities[slot];
 899                         if(player.(weaponentity).clip_size)
 900                                 player.(weaponentity).clip_load = player.(weaponentity).(weapon_load[player.(weaponentity).m_switchweapon.m_id]) = player.(weaponentity).clip_size;
 901                 }
 902         }
 903
 904         if((STAT(BUFFS, player) & BUFF_INVISIBLE.m_itemid) && (player.oldbuffs & BUFF_INVISIBLE.m_itemid))
 905                 player.alpha = ((autocvar_g_buffs_invisible_alpha) ? autocvar_g_buffs_invisible_alpha : -1); // powerups reset alpha, so we must enforce this (TODO)
 906
 907         if(STAT(BUFFS, player) & BUFF_MEDIC.m_itemid)
 908         if(time >= player.buff_medic_healtime)
 909         {
 910                 buff_Medic_Heal(player);
 911                 player.buff_medic_healtime = time + autocvar_g_buffs_medic_heal_delay;
 912         }
 913
 914 #define BUFF_ONADD(b) if ( (STAT(BUFFS, player) & (b).m_itemid) && !(player.oldbuffs & (b).m_itemid))
 915 #define BUFF_ONREM(b) if (!(STAT(BUFFS, player) & (b).m_itemid) &&  (player.oldbuffs & (b).m_itemid))
 916
 917         if(STAT(BUFFS, player) != player.oldbuffs)
 918         {
 919                 entity buff = buff_FirstFromFlags(STAT(BUFFS, player));
 920                 float bufftime = buff != BUFF_Null ? buff.m_time(buff) : 0;
 921                 if(STAT(BUFF_TIME, player) <= time) // if the player still has a buff countdown, don't reset it!
 922                         STAT(BUFF_TIME, player) = (bufftime) ? time + bufftime : 0;
 923
 924                 BUFF_ONADD(BUFF_AMMO)
 925                 {
 926                         player.buff_ammo_prev_infitems = (player.items & IT_UNLIMITED_AMMO);
 927                         player.items |= IT_UNLIMITED_AMMO;
 928
 929                         if(STAT(BUFFS, player) & BUFF_AMMO.m_itemid)
 930                         {
 931                                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 932                                 {
 933                                         .entity weaponentity = weaponentities[slot];
 934                                         if(player.(weaponentity).clip_load)
 935                                                 player.(weaponentity).buff_ammo_prev_clipload = player.(weaponentity).clip_load;
 936                                         if(player.(weaponentity).clip_size)
 937                                                 player.(weaponentity).clip_load = player.(weaponentity).(weapon_load[player.(weaponentity).m_switchweapon.m_id]) = player.(weaponentity).clip_size;
 938                                 }
 939                         }
 940                 }
 941
 942                 BUFF_ONREM(BUFF_AMMO)
 943                 {
 944                         if(player.buff_ammo_prev_infitems)
 945                                 player.items |= IT_UNLIMITED_AMMO;
 946                         else
 947                                 player.items &= ~IT_UNLIMITED_AMMO;
 948
 949                         if(STAT(BUFFS, player) & BUFF_AMMO.m_itemid)
 950                         {
 951                                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 952                                 {
 953                                         .entity weaponentity = weaponentities[slot];
 954                                         if(player.(weaponentity).buff_ammo_prev_clipload)
 955                                                 player.(weaponentity).clip_load = player.(weaponentity).buff_ammo_prev_clipload;
 956                                 }
 957                         }
 958                 }
 959
 960                 BUFF_ONADD(BUFF_INVISIBLE)
 961                 {
 962                         if(time < STAT(STRENGTH_FINISHED, player) && MUTATOR_IS_ENABLED(mutator_instagib))
 963                                 player.buff_invisible_prev_alpha = default_player_alpha; // we don't want to save the powerup's alpha, as player may lose the powerup while holding the buff
 964                         else
 965                                 player.buff_invisible_prev_alpha = player.alpha;
 966                         player.alpha = autocvar_g_buffs_invisible_alpha;
 967                 }
 968
 969                 BUFF_ONREM(BUFF_INVISIBLE)
 970                 {
 971                         if(time < STAT(STRENGTH_FINISHED, player) && MUTATOR_IS_ENABLED(mutator_instagib))
 972                                 player.alpha = autocvar_g_instagib_invis_alpha;
 973                         else
 974                                 player.alpha = player.buff_invisible_prev_alpha;
 975                 }
 976
 977                 BUFF_ONADD(BUFF_FLIGHT)
 978                 {
 979                         player.buff_flight_oldgravity = player.gravity;
 980                         if(!player.gravity)
 981                                 player.gravity = 1;
 982                 }
 983
 984                 BUFF_ONREM(BUFF_FLIGHT)
 985                         player.gravity = ((player.trigger_gravity_check) ? player.trigger_gravity_check.enemy.gravity : player.buff_flight_oldgravity);
 986
 987                 player.oldbuffs = STAT(BUFFS, player);
 988                 if(STAT(BUFFS, player))
 989                 {
 990                         if(!player.buff_model)
 991                                 buffs_BuffModel_Spawn(player);
 992
 993                         player.buff_model.color = buff.m_color;
 994                         player.buff_model.glowmod = buff_GlowColor(player.buff_model);
 995                         player.buff_model.skin = buff.m_skin;
 996
 997                         player.effects |= EF_NOSHADOW;
 998                 }
 999                 else
1000                 {
1001                         if(player.buff_model)
1002                                 delete(player.buff_model);
1003                         player.buff_model = NULL;
1004
1005                         player.effects &= ~(EF_NOSHADOW);
1006                 }
1007         }
1008
1009         if(player.buff_model)
1010         {
1011                 player.buff_model.effects = player.effects;
1012                 player.buff_model.effects |= EF_LOWPRECISION;
1013                 player.buff_model.effects = player.buff_model.effects & EFMASK_CHEAP; // eat performance
1014
1015                 player.buff_model.alpha = player.alpha;
1016         }
1017
1018 #undef BUFF_ONADD
1019 #undef BUFF_ONREM
1020 }
1021
1022 MUTATOR_HOOKFUNCTION(buffs, SpectateCopy)
1023 {
1024         entity spectatee = M_ARGV(0, entity);
1025         entity client = M_ARGV(1, entity);
1026
1027         STAT(BUFFS, client) = STAT(BUFFS, spectatee);
1028         STAT(BUFF_TIME, client) = STAT(BUFF_TIME, spectatee);
1029 }
1030
1031 MUTATOR_HOOKFUNCTION(buffs, PlayerRegen)
1032 {
1033         entity player = M_ARGV(0, entity);
1034
1035         if(STAT(BUFFS, player) & BUFF_MEDIC.m_itemid)
1036         {
1037                 M_ARGV(2, float) = autocvar_g_buffs_medic_rot; // rot_mod
1038                 M_ARGV(4, float) = M_ARGV(1, float) = autocvar_g_buffs_medic_max; // limit_mod = max_mod
1039                 M_ARGV(2, float) = autocvar_g_buffs_medic_regen; // regen_mod
1040         }
1041
1042         if(STAT(BUFFS, player) & BUFF_SPEED.m_itemid)
1043                 M_ARGV(2, float) = autocvar_g_buffs_speed_regen; // regen_mod
1044 }
1045
1046 REPLICATE(cvar_cl_buffs_autoreplace, bool, "cl_buffs_autoreplace");
1047
1048 MUTATOR_HOOKFUNCTION(buffs, BuildMutatorsString)
1049 {
1050         if(autocvar_g_buffs > 0) // only report as a mutator if they're enabled
1051                 M_ARGV(0, string) = strcat(M_ARGV(0, string), ":Buffs");
1052 }
1053
1054 MUTATOR_HOOKFUNCTION(buffs, BuildMutatorsPrettyString)
1055 {
1056         if(autocvar_g_buffs > 0)
1057                 M_ARGV(0, string) = strcat(M_ARGV(0, string), ", Buffs");
1058 }
1059
1060 void buffs_DelayedInit(entity this)
1061 {
1062         if(autocvar_g_buffs_spawn_count > 0)
1063         if(find(NULL, classname, "item_buff") == NULL)
1064         {
1065                 float i;
1066                 for(i = 0; i < autocvar_g_buffs_spawn_count; ++i)
1067                 {
1068                         entity e = spawn();
1069                         e.spawnflags |= 64; // always randomize
1070                         e.velocity = randomvec() * 250; // this gets reset anyway if random location works
1071                         buff_Init(e);
1072                 }
1073         }
1074 }