qcsrc/common/mutators/mutator/campcheck/campcheck.qc

   1 #ifdef IMPLEMENTATION
   2 float autocvar_g_campcheck_damage;
   3 float autocvar_g_campcheck_distance;
   4 float autocvar_g_campcheck_interval;
   5
   6 REGISTER_MUTATOR(campcheck, cvar("g_campcheck"));
   7
   8 .float campcheck_nextcheck;
   9 .float campcheck_traveled_distance;
  10
  11 MUTATOR_HOOKFUNCTION(campcheck, PlayerDies)
  12 {
  13         entity frag_target = M_ARGV(2, entity);
  14
  15         Kill_Notification(NOTIF_ONE, frag_target, MSG_CENTER, CPID_CAMPCHECK);
  16 }
  17
  18 MUTATOR_HOOKFUNCTION(campcheck, PlayerDamage_Calculate)
  19 {
  20         entity frag_attacker = M_ARGV(1, entity);
  21         entity frag_target = M_ARGV(2, entity);
  22
  23         if(IS_PLAYER(frag_target))
  24         if(IS_PLAYER(frag_attacker))
  25         if(frag_attacker != frag_target)
  26         {
  27                 frag_target.campcheck_traveled_distance = autocvar_g_campcheck_distance;
  28                 frag_attacker.campcheck_traveled_distance = autocvar_g_campcheck_distance;
  29         }
  30 }
  31
  32 MUTATOR_HOOKFUNCTION(campcheck, PlayerPreThink)
  33 {
  34         entity player = M_ARGV(0, entity);
  35
  36         if(!gameover)
  37         if(!warmup_stage) // don't consider it camping during warmup?
  38         if(time >= game_starttime)
  39         if(IS_PLAYER(player))
  40         if(IS_REAL_CLIENT(player)) // bots may camp, but that's no reason to constantly kill them
  41         if(!IS_DEAD(player))
  42         if(!STAT(FROZEN, player))
  43         if(!PHYS_INPUT_BUTTON_CHAT(player))
  44         if(autocvar_g_campcheck_interval)
  45         {
  46                 vector dist;
  47
  48                 // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
  49                 dist = player.prevorigin - player.origin;
  50                 dist.z = 0;
  51                 player.campcheck_traveled_distance += fabs(vlen(dist));
  52
  53                 if((autocvar_g_campaign && !campaign_bots_may_start) || (time < game_starttime) || (round_handler_IsActive() && !round_handler_IsRoundStarted()))
  54                 {
  55                         player.campcheck_nextcheck = time + autocvar_g_campcheck_interval * 2;
  56                         player.campcheck_traveled_distance = 0;
  57                 }
  58
  59                 if(time > player.campcheck_nextcheck)
  60                 {
  61                         if(player.campcheck_traveled_distance < autocvar_g_campcheck_distance)
  62                         {
  63                                 Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_CAMPCHECK);
  64                                 if(player.vehicle)
  65                                         Damage(player.vehicle, NULL, NULL, autocvar_g_campcheck_damage * 2, DEATH_CAMP.m_id, player.vehicle.origin, '0 0 0');
  66                                 else
  67                                         Damage(player, NULL, NULL, bound(0, autocvar_g_campcheck_damage, player.health + player.armorvalue * autocvar_g_balance_armor_blockpercent + 5), DEATH_CAMP.m_id, player.origin, '0 0 0');
  68                         }
  69                         player.campcheck_nextcheck = time + autocvar_g_campcheck_interval;
  70                         player.campcheck_traveled_distance = 0;
  71                 }
  72
  73                 return;
  74         }
  75
  76         player.campcheck_nextcheck = time + autocvar_g_campcheck_interval; // one of the above checks failed, so keep the timer up to date
  77 }
  78
  79 MUTATOR_HOOKFUNCTION(campcheck, PlayerSpawn)
  80 {
  81         entity player = M_ARGV(0, entity);
  82
  83         player.campcheck_nextcheck = time + autocvar_g_campcheck_interval * 2;
  84         player.campcheck_traveled_distance = 0;
  85 }
  86
  87 MUTATOR_HOOKFUNCTION(campcheck, BuildMutatorsString)
  88 {
  89         M_ARGV(0, string) = strcat(M_ARGV(0, string), ":CampCheck");;
  90 }
  91 #endif